perl/Git.pm

   1 =head1 NAME
   2
   3 Git - Perl interface to the Git version control system
   4
   5 =cut
   6
   7
   8 package Git;
   9
  10 use strict;
  11
  12
  13 BEGIN {
  14
  15 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK);
  16
  17 # Totally unstable API.
  18 $VERSION = '0.01';
  19
  20
  21 =head1 SYNOPSIS
  22
  23   use Git;
  24
  25   my $version = Git::command_oneline('version');
  26
  27   git_cmd_try { Git::command_noisy('update-server-info') }
  28               '%s failed w/ code %d';
  29
  30   my $repo = Git->repository (Directory => '/srv/git/cogito.git');
  31
  32
  33   my @revs = $repo->command('rev-list', '--since=last monday', '--all');
  34
  35   my ($fh, $c) = $repo->command_output_pipe('rev-list', '--since=last monday', '--all');
  36   my $lastrev = <$fh>; chomp $lastrev;
  37   $repo->command_close_pipe($fh, $c);
  38
  39   my $lastrev = $repo->command_oneline( [ 'rev-list', '--all' ],
  40                                         STDERR => 0 );
  41
  42 =cut
  43
  44
  45 require Exporter;
  46
  47 @ISA = qw(Exporter);
  48
  49 @EXPORT = qw(git_cmd_try);
  50
  51 # Methods which can be called as standalone functions as well:
  52 @EXPORT_OK = qw(command command_oneline command_noisy
  53                 command_output_pipe command_input_pipe command_close_pipe
  54                 version exec_path hash_object git_cmd_try);
  55
  56
  57 =head1 DESCRIPTION
  58
  59 This module provides Perl scripts easy way to interface the Git version control
  60 system. The modules have an easy and well-tested way to call arbitrary Git
  61 commands; in the future, the interface will also provide specialized methods
  62 for doing easily operations which are not totally trivial to do over
  63 the generic command interface.
  64
  65 While some commands can be executed outside of any context (e.g. 'version'
  66 or 'init'), most operations require a repository context, which in practice
  67 means getting an instance of the Git object using the repository() constructor.
  68 (In the future, we will also get a new_repository() constructor.) All commands
  69 called as methods of the object are then executed in the context of the
  70 repository.
  71
  72 Part of the "repository state" is also information about path to the attached
  73 working copy (unless you work with a bare repository). You can also navigate
  74 inside of the working copy using the C<wc_chdir()> method. (Note that
  75 the repository object is self-contained and will not change working directory
  76 of your process.)
  77
  78 TODO: In the future, we might also do
  79
  80         my $remoterepo = $repo->remote_repository (Name => 'cogito', Branch => 'master');
  81         $remoterepo ||= Git->remote_repository ('http://git.or.cz/cogito.git/');
  82         my @refs = $remoterepo->refs();
  83
  84 Currently, the module merely wraps calls to external Git tools. In the future,
  85 it will provide a much faster way to interact with Git by linking directly
  86 to libgit. This should be completely opaque to the user, though (performance
  87 increate nonwithstanding).
  88
  89 =cut
  90
  91
  92 use Carp qw(carp croak); # but croak is bad - throw instead
  93 use Error qw(:try);
  94 use Cwd qw(abs_path);
  95
  96 }
  97
  98
  99 =head1 CONSTRUCTORS
 100
 101 =over 4
 102
 103 =item repository ( OPTIONS )
 104
 105 =item repository ( DIRECTORY )
 106
 107 =item repository ()
 108
 109 Construct a new repository object.
 110 C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
 111 Possible options are:
 112
 113 B<Repository> - Path to the Git repository.
 114
 115 B<WorkingCopy> - Path to the associated working copy; not strictly required
 116 as many commands will happily crunch on a bare repository.
 117
 118 B<WorkingSubdir> - Subdirectory in the working copy to work inside.
 119 Just left undefined if you do not want to limit the scope of operations.
 120
 121 B<Directory> - Path to the Git working directory in its usual setup.
 122 The C<.git> directory is searched in the directory and all the parent
 123 directories; if found, C<WorkingCopy> is set to the directory containing
 124 it and C<Repository> to the C<.git> directory itself. If no C<.git>
 125 directory was found, the C<Directory> is assumed to be a bare repository,
 126 C<Repository> is set to point at it and C<WorkingCopy> is left undefined.
 127 If the C<$GIT_DIR> environment variable is set, things behave as expected
 128 as well.
 129
 130 You should not use both C<Directory> and either of C<Repository> and
 131 C<WorkingCopy> - the results of that are undefined.
 132
 133 Alternatively, a directory path may be passed as a single scalar argument
 134 to the constructor; it is equivalent to setting only the C<Directory> option
 135 field.
 136
 137 Calling the constructor with no options whatsoever is equivalent to
 138 calling it with C<< Directory => '.' >>. In general, if you are building
 139 a standard porcelain command, simply doing C<< Git->repository() >> should
 140 do the right thing and setup the object to reflect exactly where the user
 141 is right now.
 142
 143 =cut
 144
 145 sub repository {
 146         my $class = shift;
 147         my @args = @_;
 148         my %opts = ();
 149         my $self;
 150
 151         if (defined $args[0]) {
 152                 if ($#args % 2 != 1) {
 153                         # Not a hash.
 154                         $#args == 0 or throw Error::Simple("bad usage");
 155                         %opts = ( Directory => $args[0] );
 156                 } else {
 157                         %opts = @args;
 158                 }
 159         }
 160
 161         if (not defined $opts{Repository} and not defined $opts{WorkingCopy}) {
 162                 $opts{Directory} ||= '.';
 163         }
 164
 165         if ($opts{Directory}) {
 166                 -d $opts{Directory} or throw Error::Simple("Directory not found: $!");
 167
 168                 my $search = Git->repository(WorkingCopy => $opts{Directory});
 169                 my $dir;
 170                 try {
 171                         $dir = $search->command_oneline(['rev-parse', '--git-dir'],
 172                                                         STDERR => 0);
 173                 } catch Git::Error::Command with {
 174                         $dir = undef;
 175                 };
 176
 177                 if ($dir) {
 178                         $dir =~ m#^/# or $dir = $opts{Directory} . '/' . $dir;
 179                         $opts{Repository} = $dir;
 180
 181                         # If --git-dir went ok, this shouldn't die either.
 182                         my $prefix = $search->command_oneline('rev-parse', '--show-prefix');
 183                         $dir = abs_path($opts{Directory}) . '/';
 184                         if ($prefix) {
 185                                 if (substr($dir, -length($prefix)) ne $prefix) {
 186                                         throw Error::Simple("rev-parse confused me - $dir does not have trailing $prefix");
 187                                 }
 188                                 substr($dir, -length($prefix)) = '';
 189                         }
 190                         $opts{WorkingCopy} = $dir;
 191                         $opts{WorkingSubdir} = $prefix;
 192
 193                 } else {
 194                         # A bare repository? Let's see...
 195                         $dir = $opts{Directory};
 196
 197                         unless (-d "$dir/refs" and -d "$dir/objects" and -e "$dir/HEAD") {
 198                                 # Mimick git-rev-parse --git-dir error message:
 199                                 throw Error::Simple('fatal: Not a git repository');
 200                         }
 201                         my $search = Git->repository(Repository => $dir);
 202                         try {
 203                                 $search->command('symbolic-ref', 'HEAD');
 204                         } catch Git::Error::Command with {
 205                                 # Mimick git-rev-parse --git-dir error message:
 206                                 throw Error::Simple('fatal: Not a git repository');
 207                         }
 208
 209                         $opts{Repository} = abs_path($dir);
 210                 }
 211
 212                 delete $opts{Directory};
 213         }
 214
 215         $self = { opts => \%opts };
 216         bless $self, $class;
 217 }
 218
 219
 220 =back
 221
 222 =head1 METHODS
 223
 224 =over 4
 225
 226 =item command ( COMMAND [, ARGUMENTS... ] )
 227
 228 =item command ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 229
 230 Execute the given Git C<COMMAND> (specify it without the 'git-'
 231 prefix), optionally with the specified extra C<ARGUMENTS>.
 232
 233 The second more elaborate form can be used if you want to further adjust
 234 the command execution. Currently, only one option is supported:
 235
 236 B<STDERR> - How to deal with the command's error output. By default (C<undef>)
 237 it is delivered to the caller's C<STDERR>. A false value (0 or '') will cause
 238 it to be thrown away. If you want to process it, you can get it in a filehandle
 239 you specify, but you must be extremely careful; if the error output is not
 240 very short and you want to read it in the same process as where you called
 241 C<command()>, you are set up for a nice deadlock!
 242
 243 The method can be called without any instance or on a specified Git repository
 244 (in that case the command will be run in the repository context).
 245
 246 In scalar context, it returns all the command output in a single string
 247 (verbatim).
 248
 249 In array context, it returns an array containing lines printed to the
 250 command's stdout (without trailing newlines).
 251
 252 In both cases, the command's stdin and stderr are the same as the caller's.
 253
 254 =cut
 255
 256 sub command {
 257         my ($fh, $ctx) = command_output_pipe(@_);
 258
 259         if (not defined wantarray) {
 260                 # Nothing to pepper the possible exception with.
 261                 _cmd_close($fh, $ctx);
 262
 263         } elsif (not wantarray) {
 264                 local $/;
 265                 my $text = <$fh>;
 266                 try {
 267                         _cmd_close($fh, $ctx);
 268                 } catch Git::Error::Command with {
 269                         # Pepper with the output:
 270                         my $E = shift;
 271                         $E->{'-outputref'} = \$text;
 272                         throw $E;
 273                 };
 274                 return $text;
 275
 276         } else {
 277                 my @lines = <$fh>;
 278                 defined and chomp for @lines;
 279                 try {
 280                         _cmd_close($fh, $ctx);
 281                 } catch Git::Error::Command with {
 282                         my $E = shift;
 283                         $E->{'-outputref'} = \@lines;
 284                         throw $E;
 285                 };
 286                 return @lines;
 287         }
 288 }
 289
 290
 291 =item command_oneline ( COMMAND [, ARGUMENTS... ] )
 292
 293 =item command_oneline ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 294
 295 Execute the given C<COMMAND> in the same way as command()
 296 does but always return a scalar string containing the first line
 297 of the command's standard output.
 298
 299 =cut
 300
 301 sub command_oneline {
 302         my ($fh, $ctx) = command_output_pipe(@_);
 303
 304         my $line = <$fh>;
 305         defined $line and chomp $line;
 306         try {
 307                 _cmd_close($fh, $ctx);
 308         } catch Git::Error::Command with {
 309                 # Pepper with the output:
 310                 my $E = shift;
 311                 $E->{'-outputref'} = \$line;
 312                 throw $E;
 313         };
 314         return $line;
 315 }
 316
 317
 318 =item command_output_pipe ( COMMAND [, ARGUMENTS... ] )
 319
 320 =item command_output_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 321
 322 Execute the given C<COMMAND> in the same way as command()
 323 does but return a pipe filehandle from which the command output can be
 324 read.
 325
 326 The function can return C<($pipe, $ctx)> in array context.
 327 See C<command_close_pipe()> for details.
 328
 329 =cut
 330
 331 sub command_output_pipe {
 332         _command_common_pipe('-|', @_);
 333 }
 334
 335
 336 =item command_input_pipe ( COMMAND [, ARGUMENTS... ] )
 337
 338 =item command_input_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 339
 340 Execute the given C<COMMAND> in the same way as command_output_pipe()
 341 does but return an input pipe filehandle instead; the command output
 342 is not captured.
 343
 344 The function can return C<($pipe, $ctx)> in array context.
 345 See C<command_close_pipe()> for details.
 346
 347 =cut
 348
 349 sub command_input_pipe {
 350         _command_common_pipe('|-', @_);
 351 }
 352
 353
 354 =item command_close_pipe ( PIPE [, CTX ] )
 355
 356 Close the C<PIPE> as returned from C<command_*_pipe()>, checking
 357 whether the command finished successfully. The optional C<CTX> argument
 358 is required if you want to see the command name in the error message,
 359 and it is the second value returned by C<command_*_pipe()> when
 360 called in array context. The call idiom is:
 361
 362         my ($fh, $ctx) = $r->command_output_pipe('status');
 363         while (<$fh>) { ... }
 364         $r->command_close_pipe($fh, $ctx);
 365
 366 Note that you should not rely on whatever actually is in C<CTX>;
 367 currently it is simply the command name but in future the context might
 368 have more complicated structure.
 369
 370 =cut
 371
 372 sub command_close_pipe {
 373         my ($self, $fh, $ctx) = _maybe_self(@_);
 374         $ctx ||= '<unknown>';
 375         _cmd_close($fh, $ctx);
 376 }
 377
 378
 379 =item command_noisy ( COMMAND [, ARGUMENTS... ] )
 380
 381 Execute the given C<COMMAND> in the same way as command() does but do not
 382 capture the command output - the standard output is not redirected and goes
 383 to the standard output of the caller application.
 384
 385 While the method is called command_noisy(), you might want to as well use
 386 it for the most silent Git commands which you know will never pollute your
 387 stdout but you want to avoid the overhead of the pipe setup when calling them.
 388
 389 The function returns only after the command has finished running.
 390
 391 =cut
 392
 393 sub command_noisy {
 394         my ($self, $cmd, @args) = _maybe_self(@_);
 395         _check_valid_cmd($cmd);
 396
 397         my $pid = fork;
 398         if (not defined $pid) {
 399                 throw Error::Simple("fork failed: $!");
 400         } elsif ($pid == 0) {
 401                 _cmd_exec($self, $cmd, @args);
 402         }
 403         if (waitpid($pid, 0) > 0 and $?>>8 != 0) {
 404                 throw Git::Error::Command(join(' ', $cmd, @args), $? >> 8);
 405         }
 406 }
 407
 408
 409 =item version ()
 410
 411 Return the Git version in use.
 412
 413 =cut
 414
 415 sub version {
 416         my $verstr = command_oneline('--version');
 417         $verstr =~ s/^git version //;
 418         $verstr;
 419 }
 420
 421
 422 =item exec_path ()
 423
 424 Return path to the Git sub-command executables (the same as
 425 C<git --exec-path>). Useful mostly only internally.
 426
 427 =cut
 428
 429 sub exec_path { command_oneline('--exec-path') }
 430
 431
 432 =item repo_path ()
 433
 434 Return path to the git repository. Must be called on a repository instance.
 435
 436 =cut
 437
 438 sub repo_path { $_[0]->{opts}->{Repository} }
 439
 440
 441 =item wc_path ()
 442
 443 Return path to the working copy. Must be called on a repository instance.
 444
 445 =cut
 446
 447 sub wc_path { $_[0]->{opts}->{WorkingCopy} }
 448
 449
 450 =item wc_subdir ()
 451
 452 Return path to the subdirectory inside of a working copy. Must be called
 453 on a repository instance.
 454
 455 =cut
 456
 457 sub wc_subdir { $_[0]->{opts}->{WorkingSubdir} ||= '' }
 458
 459
 460 =item wc_chdir ( SUBDIR )
 461
 462 Change the working copy subdirectory to work within. The C<SUBDIR> is
 463 relative to the working copy root directory (not the current subdirectory).
 464 Must be called on a repository instance attached to a working copy
 465 and the directory must exist.
 466
 467 =cut
 468
 469 sub wc_chdir {
 470         my ($self, $subdir) = @_;
 471         $self->wc_path()
 472                 or throw Error::Simple("bare repository");
 473
 474         -d $self->wc_path().'/'.$subdir
 475                 or throw Error::Simple("subdir not found: $!");
 476         # Of course we will not "hold" the subdirectory so anyone
 477         # can delete it now and we will never know. But at least we tried.
 478
 479         $self->{opts}->{WorkingSubdir} = $subdir;
 480 }
 481
 482
 483 =item config ( VARIABLE )
 484
 485 Retrieve the configuration C<VARIABLE> in the same manner as C<config>
 486 does. In scalar context requires the variable to be set only one time
 487 (exception is thrown otherwise), in array context returns allows the
 488 variable to be set multiple times and returns all the values.
 489
 490 Must be called on a repository instance.
 491
 492 This currently wraps command('config') so it is not so fast.
 493
 494 =cut
 495
 496 sub config {
 497         my ($self, $var) = @_;
 498         $self->repo_path()
 499                 or throw Error::Simple("not a repository");
 500
 501         try {
 502                 if (wantarray) {
 503                         return $self->command('config', '--get-all', $var);
 504                 } else {
 505                         return $self->command_oneline('config', '--get', $var);
 506                 }
 507         } catch Git::Error::Command with {
 508                 my $E = shift;
 509                 if ($E->value() == 1) {
 510                         # Key not found.
 511                         return undef;
 512                 } else {
 513                         throw $E;
 514                 }
 515         };
 516 }
 517
 518
 519 =item config_bool ( VARIABLE )
 520
 521 Retrieve the bool configuration C<VARIABLE>. The return value
 522 is usable as a boolean in perl (and C<undef> if it's not defined,
 523 of course).
 524
 525 Must be called on a repository instance.
 526
 527 This currently wraps command('config') so it is not so fast.
 528
 529 =cut
 530
 531 sub config_bool {
 532         my ($self, $var) = @_;
 533         $self->repo_path()
 534                 or throw Error::Simple("not a repository");
 535
 536         try {
 537                 my $val = $self->command_oneline('config', '--bool', '--get',
 538                                               $var);
 539                 return undef unless defined $val;
 540                 return $val eq 'true';
 541         } catch Git::Error::Command with {
 542                 my $E = shift;
 543                 if ($E->value() == 1) {
 544                         # Key not found.
 545                         return undef;
 546                 } else {
 547                         throw $E;
 548                 }
 549         };
 550 }
 551
 552
 553 =item ident ( TYPE | IDENTSTR )
 554
 555 =item ident_person ( TYPE | IDENTSTR | IDENTARRAY )
 556
 557 This suite of functions retrieves and parses ident information, as stored
 558 in the commit and tag objects or produced by C<var GIT_type_IDENT> (thus
 559 C<TYPE> can be either I<author> or I<committer>; case is insignificant).
 560
 561 The C<ident> method retrieves the ident information from C<git-var>
 562 and either returns it as a scalar string or as an array with the fields parsed.
 563 Alternatively, it can take a prepared ident string (e.g. from the commit
 564 object) and just parse it.
 565
 566 C<ident_person> returns the person part of the ident - name and email;
 567 it can take the same arguments as C<ident> or the array returned by C<ident>.
 568
 569 The synopsis is like:
 570
 571         my ($name, $email, $time_tz) = ident('author');
 572         "$name <$email>" eq ident_person('author');
 573         "$name <$email>" eq ident_person($name);
 574         $time_tz =~ /^\d+ [+-]\d{4}$/;
 575
 576 Both methods must be called on a repository instance.
 577
 578 =cut
 579
 580 sub ident {
 581         my ($self, $type) = @_;
 582         my $identstr;
 583         if (lc $type eq lc 'committer' or lc $type eq lc 'author') {
 584                 $identstr = $self->command_oneline('var', 'GIT_'.uc($type).'_IDENT');
 585         } else {
 586                 $identstr = $type;
 587         }
 588         if (wantarray) {
 589                 return $identstr =~ /^(.*) <(.*)> (\d+ [+-]\d{4})$/;
 590         } else {
 591                 return $identstr;
 592         }
 593 }
 594
 595 sub ident_person {
 596         my ($self, @ident) = @_;
 597         $#ident == 0 and @ident = $self->ident($ident[0]);
 598         return "$ident[0] <$ident[1]>";
 599 }
 600
 601
 602 =item hash_object ( TYPE, FILENAME )
 603
 604 Compute the SHA1 object id of the given C<FILENAME> (or data waiting in
 605 C<FILEHANDLE>) considering it is of the C<TYPE> object type (C<blob>,
 606 C<commit>, C<tree>).
 607
 608 The method can be called without any instance or on a specified Git repository,
 609 it makes zero difference.
 610
 611 The function returns the SHA1 hash.
 612
 613 =cut
 614
 615 # TODO: Support for passing FILEHANDLE instead of FILENAME
 616 sub hash_object {
 617         my ($self, $type, $file) = _maybe_self(@_);
 618         command_oneline('hash-object', '-t', $type, $file);
 619 }
 620
 621
 622
 623 =back
 624
 625 =head1 ERROR HANDLING
 626
 627 All functions are supposed to throw Perl exceptions in case of errors.
 628 See the L<Error> module on how to catch those. Most exceptions are mere
 629 L<Error::Simple> instances.
 630
 631 However, the C<command()>, C<command_oneline()> and C<command_noisy()>
 632 functions suite can throw C<Git::Error::Command> exceptions as well: those are
 633 thrown when the external command returns an error code and contain the error
 634 code as well as access to the captured command's output. The exception class
 635 provides the usual C<stringify> and C<value> (command's exit code) methods and
 636 in addition also a C<cmd_output> method that returns either an array or a
 637 string with the captured command output (depending on the original function
 638 call context; C<command_noisy()> returns C<undef>) and $<cmdline> which
 639 returns the command and its arguments (but without proper quoting).
 640
 641 Note that the C<command_*_pipe()> functions cannot throw this exception since
 642 it has no idea whether the command failed or not. You will only find out
 643 at the time you C<close> the pipe; if you want to have that automated,
 644 use C<command_close_pipe()>, which can throw the exception.
 645
 646 =cut
 647
 648 {
 649         package Git::Error::Command;
 650
 651         @Git::Error::Command::ISA = qw(Error);
 652
 653         sub new {
 654                 my $self = shift;
 655                 my $cmdline = '' . shift;
 656                 my $value = 0 + shift;
 657                 my $outputref = shift;
 658                 my(@args) = ();
 659
 660                 local $Error::Depth = $Error::Depth + 1;
 661
 662                 push(@args, '-cmdline', $cmdline);
 663                 push(@args, '-value', $value);
 664                 push(@args, '-outputref', $outputref);
 665
 666                 $self->SUPER::new(-text => 'command returned error', @args);
 667         }
 668
 669         sub stringify {
 670                 my $self = shift;
 671                 my $text = $self->SUPER::stringify;
 672                 $self->cmdline() . ': ' . $text . ': ' . $self->value() . "\n";
 673         }
 674
 675         sub cmdline {
 676                 my $self = shift;
 677                 $self->{'-cmdline'};
 678         }
 679
 680         sub cmd_output {
 681                 my $self = shift;
 682                 my $ref = $self->{'-outputref'};
 683                 defined $ref or undef;
 684                 if (ref $ref eq 'ARRAY') {
 685                         return @$ref;
 686                 } else { # SCALAR
 687                         return $$ref;
 688                 }
 689         }
 690 }
 691
 692 =over 4
 693
 694 =item git_cmd_try { CODE } ERRMSG
 695
 696 This magical statement will automatically catch any C<Git::Error::Command>
 697 exceptions thrown by C<CODE> and make your program die with C<ERRMSG>
 698 on its lips; the message will have %s substituted for the command line
 699 and %d for the exit status. This statement is useful mostly for producing
 700 more user-friendly error messages.
 701
 702 In case of no exception caught the statement returns C<CODE>'s return value.
 703
 704 Note that this is the only auto-exported function.
 705
 706 =cut
 707
 708 sub git_cmd_try(&$) {
 709         my ($code, $errmsg) = @_;
 710         my @result;
 711         my $err;
 712         my $array = wantarray;
 713         try {
 714                 if ($array) {
 715                         @result = &$code;
 716                 } else {
 717                         $result[0] = &$code;
 718                 }
 719         } catch Git::Error::Command with {
 720                 my $E = shift;
 721                 $err = $errmsg;
 722                 $err =~ s/\%s/$E->cmdline()/ge;
 723                 $err =~ s/\%d/$E->value()/ge;
 724                 # We can't croak here since Error.pm would mangle
 725                 # that to Error::Simple.
 726         };
 727         $err and croak $err;
 728         return $array ? @result : $result[0];
 729 }
 730
 731
 732 =back
 733
 734 =head1 COPYRIGHT
 735
 736 Copyright 2006 by Petr Baudis E<lt>pasky@suse.czE<gt>.
 737
 738 This module is free software; it may be used, copied, modified
 739 and distributed under the terms of the GNU General Public Licence,
 740 either version 2, or (at your option) any later version.
 741
 742 =cut
 743
 744
 745 # Take raw method argument list and return ($obj, @args) in case
 746 # the method was called upon an instance and (undef, @args) if
 747 # it was called directly.
 748 sub _maybe_self {
 749         # This breaks inheritance. Oh well.
 750         ref $_[0] eq 'Git' ? @_ : (undef, @_);
 751 }
 752
 753 # Check if the command id is something reasonable.
 754 sub _check_valid_cmd {
 755         my ($cmd) = @_;
 756         $cmd =~ /^[a-z0-9A-Z_-]+$/ or throw Error::Simple("bad command: $cmd");
 757 }
 758
 759 # Common backend for the pipe creators.
 760 sub _command_common_pipe {
 761         my $direction = shift;
 762         my ($self, @p) = _maybe_self(@_);
 763         my (%opts, $cmd, @args);
 764         if (ref $p[0]) {
 765                 ($cmd, @args) = @{shift @p};
 766                 %opts = ref $p[0] ? %{$p[0]} : @p;
 767         } else {
 768                 ($cmd, @args) = @p;
 769         }
 770         _check_valid_cmd($cmd);
 771
 772         my $fh;
 773         if ($^O eq 'MSWin32') {
 774                 # ActiveState Perl
 775                 #defined $opts{STDERR} and
 776                 #       warn 'ignoring STDERR option - running w/ ActiveState';
 777                 $direction eq '-|' or
 778                         die 'input pipe for ActiveState not implemented';
 779                 # the strange construction with *ACPIPE is just to
 780                 # explain the tie below that we want to bind to
 781                 # a handle class, not scalar. It is not known if
 782                 # it is something specific to ActiveState Perl or
 783                 # just a Perl quirk.
 784                 tie (*ACPIPE, 'Git::activestate_pipe', $cmd, @args);
 785                 $fh = *ACPIPE;
 786
 787         } else {
 788                 my $pid = open($fh, $direction);
 789                 if (not defined $pid) {
 790                         throw Error::Simple("open failed: $!");
 791                 } elsif ($pid == 0) {
 792                         if (defined $opts{STDERR}) {
 793                                 close STDERR;
 794                         }
 795                         if ($opts{STDERR}) {
 796                                 open (STDERR, '>&', $opts{STDERR})
 797                                         or die "dup failed: $!";
 798                         }
 799                         _cmd_exec($self, $cmd, @args);
 800                 }
 801         }
 802         return wantarray ? ($fh, join(' ', $cmd, @args)) : $fh;
 803 }
 804
 805 # When already in the subprocess, set up the appropriate state
 806 # for the given repository and execute the git command.
 807 sub _cmd_exec {
 808         my ($self, @args) = @_;
 809         if ($self) {
 810                 $self->repo_path() and $ENV{'GIT_DIR'} = $self->repo_path();
 811                 $self->wc_path() and chdir($self->wc_path());
 812                 $self->wc_subdir() and chdir($self->wc_subdir());
 813         }
 814         _execv_git_cmd(@args);
 815         die qq[exec "@args" failed: $!];
 816 }
 817
 818 # Execute the given Git command ($_[0]) with arguments ($_[1..])
 819 # by searching for it at proper places.
 820 sub _execv_git_cmd { exec('git', @_); }
 821
 822 # Close pipe to a subprocess.
 823 sub _cmd_close {
 824         my ($fh, $ctx) = @_;
 825         if (not close $fh) {
 826                 if ($!) {
 827                         # It's just close, no point in fatalities
 828                         carp "error closing pipe: $!";
 829                 } elsif ($? >> 8) {
 830                         # The caller should pepper this.
 831                         throw Git::Error::Command($ctx, $? >> 8);
 832                 }
 833                 # else we might e.g. closed a live stream; the command
 834                 # dying of SIGPIPE would drive us here.
 835         }
 836 }
 837
 838
 839 sub DESTROY { }
 840
 841
 842 # Pipe implementation for ActiveState Perl.
 843
 844 package Git::activestate_pipe;
 845 use strict;
 846
 847 sub TIEHANDLE {
 848         my ($class, @params) = @_;
 849         # FIXME: This is probably horrible idea and the thing will explode
 850         # at the moment you give it arguments that require some quoting,
 851         # but I have no ActiveState clue... --pasky
 852         # Let's just hope ActiveState Perl does at least the quoting
 853         # correctly.
 854         my @data = qx{git @params};
 855         bless { i => 0, data => \@data }, $class;
 856 }
 857
 858 sub READLINE {
 859         my $self = shift;
 860         if ($self->{i} >= scalar @{$self->{data}}) {
 861                 return undef;
 862         }
 863         my $i = $self->{i};
 864         if (wantarray) {
 865                 $self->{i} = $#{$self->{'data'}} + 1;
 866                 return splice(@{$self->{'data'}}, $i);
 867         }
 868         $self->{i} = $i + 1;
 869         return $self->{'data'}->[ $i ];
 870 }
 871
 872 sub CLOSE {
 873         my $self = shift;
 874         delete $self->{data};
 875         delete $self->{i};
 876 }
 877
 878 sub EOF {
 879         my $self = shift;
 880         return ($self->{i} >= scalar @{$self->{data}});
 881 }
 882
 883
 884 1; # Famous last words