perl/Git.pm

   1 =head1 NAME
   2
   3 Git - Perl interface to the Git version control system
   4
   5 =cut
   6
   7
   8 package Git;
   9
  10 use 5.008;
  11 use strict;
  12
  13
  14 BEGIN {
  15
  16 our ($VERSION, @ISA, @EXPORT, @EXPORT_OK);
  17
  18 # Totally unstable API.
  19 $VERSION = '0.01';
  20
  21
  22 =head1 SYNOPSIS
  23
  24   use Git;
  25
  26   my $version = Git::command_oneline('version');
  27
  28   git_cmd_try { Git::command_noisy('update-server-info') }
  29               '%s failed w/ code %d';
  30
  31   my $repo = Git->repository (Directory => '/srv/git/cogito.git');
  32
  33
  34   my @revs = $repo->command('rev-list', '--since=last monday', '--all');
  35
  36   my ($fh, $c) = $repo->command_output_pipe('rev-list', '--since=last monday', '--all');
  37   my $lastrev = <$fh>; chomp $lastrev;
  38   $repo->command_close_pipe($fh, $c);
  39
  40   my $lastrev = $repo->command_oneline( [ 'rev-list', '--all' ],
  41                                         STDERR => 0 );
  42
  43   my $sha1 = $repo->hash_and_insert_object('file.txt');
  44   my $tempfile = tempfile();
  45   my $size = $repo->cat_blob($sha1, $tempfile);
  46
  47 =cut
  48
  49
  50 require Exporter;
  51
  52 @ISA = qw(Exporter);
  53
  54 @EXPORT = qw(git_cmd_try);
  55
  56 # Methods which can be called as standalone functions as well:
  57 @EXPORT_OK = qw(command command_oneline command_noisy
  58                 command_output_pipe command_input_pipe command_close_pipe
  59                 command_bidi_pipe command_close_bidi_pipe
  60                 version exec_path html_path hash_object git_cmd_try
  61                 remote_refs
  62                 temp_acquire temp_release temp_reset temp_path);
  63
  64
  65 =head1 DESCRIPTION
  66
  67 This module provides Perl scripts easy way to interface the Git version control
  68 system. The modules have an easy and well-tested way to call arbitrary Git
  69 commands; in the future, the interface will also provide specialized methods
  70 for doing easily operations which are not totally trivial to do over
  71 the generic command interface.
  72
  73 While some commands can be executed outside of any context (e.g. 'version'
  74 or 'init'), most operations require a repository context, which in practice
  75 means getting an instance of the Git object using the repository() constructor.
  76 (In the future, we will also get a new_repository() constructor.) All commands
  77 called as methods of the object are then executed in the context of the
  78 repository.
  79
  80 Part of the "repository state" is also information about path to the attached
  81 working copy (unless you work with a bare repository). You can also navigate
  82 inside of the working copy using the C<wc_chdir()> method. (Note that
  83 the repository object is self-contained and will not change working directory
  84 of your process.)
  85
  86 TODO: In the future, we might also do
  87
  88         my $remoterepo = $repo->remote_repository (Name => 'cogito', Branch => 'master');
  89         $remoterepo ||= Git->remote_repository ('http://git.or.cz/cogito.git/');
  90         my @refs = $remoterepo->refs();
  91
  92 Currently, the module merely wraps calls to external Git tools. In the future,
  93 it will provide a much faster way to interact with Git by linking directly
  94 to libgit. This should be completely opaque to the user, though (performance
  95 increase notwithstanding).
  96
  97 =cut
  98
  99
 100 use Carp qw(carp croak); # but croak is bad - throw instead
 101 use Error qw(:try);
 102 use Cwd qw(abs_path cwd);
 103 use IPC::Open2 qw(open2);
 104 use Fcntl qw(SEEK_SET SEEK_CUR);
 105 }
 106
 107
 108 =head1 CONSTRUCTORS
 109
 110 =over 4
 111
 112 =item repository ( OPTIONS )
 113
 114 =item repository ( DIRECTORY )
 115
 116 =item repository ()
 117
 118 Construct a new repository object.
 119 C<OPTIONS> are passed in a hash like fashion, using key and value pairs.
 120 Possible options are:
 121
 122 B<Repository> - Path to the Git repository.
 123
 124 B<WorkingCopy> - Path to the associated working copy; not strictly required
 125 as many commands will happily crunch on a bare repository.
 126
 127 B<WorkingSubdir> - Subdirectory in the working copy to work inside.
 128 Just left undefined if you do not want to limit the scope of operations.
 129
 130 B<Directory> - Path to the Git working directory in its usual setup.
 131 The C<.git> directory is searched in the directory and all the parent
 132 directories; if found, C<WorkingCopy> is set to the directory containing
 133 it and C<Repository> to the C<.git> directory itself. If no C<.git>
 134 directory was found, the C<Directory> is assumed to be a bare repository,
 135 C<Repository> is set to point at it and C<WorkingCopy> is left undefined.
 136 If the C<$GIT_DIR> environment variable is set, things behave as expected
 137 as well.
 138
 139 You should not use both C<Directory> and either of C<Repository> and
 140 C<WorkingCopy> - the results of that are undefined.
 141
 142 Alternatively, a directory path may be passed as a single scalar argument
 143 to the constructor; it is equivalent to setting only the C<Directory> option
 144 field.
 145
 146 Calling the constructor with no options whatsoever is equivalent to
 147 calling it with C<< Directory => '.' >>. In general, if you are building
 148 a standard porcelain command, simply doing C<< Git->repository() >> should
 149 do the right thing and setup the object to reflect exactly where the user
 150 is right now.
 151
 152 =cut
 153
 154 sub repository {
 155         my $class = shift;
 156         my @args = @_;
 157         my %opts = ();
 158         my $self;
 159
 160         if (defined $args[0]) {
 161                 if ($#args % 2 != 1) {
 162                         # Not a hash.
 163                         $#args == 0 or throw Error::Simple("bad usage");
 164                         %opts = ( Directory => $args[0] );
 165                 } else {
 166                         %opts = @args;
 167                 }
 168         }
 169
 170         if (not defined $opts{Repository} and not defined $opts{WorkingCopy}
 171                 and not defined $opts{Directory}) {
 172                 $opts{Directory} = '.';
 173         }
 174
 175         if (defined $opts{Directory}) {
 176                 -d $opts{Directory} or throw Error::Simple("Directory not found: $opts{Directory} $!");
 177
 178                 my $search = Git->repository(WorkingCopy => $opts{Directory});
 179                 my $dir;
 180                 try {
 181                         $dir = $search->command_oneline(['rev-parse', '--git-dir'],
 182                                                         STDERR => 0);
 183                 } catch Git::Error::Command with {
 184                         $dir = undef;
 185                 };
 186
 187                 if ($dir) {
 188                         $dir =~ m#^/# or $dir = $opts{Directory} . '/' . $dir;
 189                         $opts{Repository} = abs_path($dir);
 190
 191                         # If --git-dir went ok, this shouldn't die either.
 192                         my $prefix = $search->command_oneline('rev-parse', '--show-prefix');
 193                         $dir = abs_path($opts{Directory}) . '/';
 194                         if ($prefix) {
 195                                 if (substr($dir, -length($prefix)) ne $prefix) {
 196                                         throw Error::Simple("rev-parse confused me - $dir does not have trailing $prefix");
 197                                 }
 198                                 substr($dir, -length($prefix)) = '';
 199                         }
 200                         $opts{WorkingCopy} = $dir;
 201                         $opts{WorkingSubdir} = $prefix;
 202
 203                 } else {
 204                         # A bare repository? Let's see...
 205                         $dir = $opts{Directory};
 206
 207                         unless (-d "$dir/refs" and -d "$dir/objects" and -e "$dir/HEAD") {
 208                                 # Mimic git-rev-parse --git-dir error message:
 209                                 throw Error::Simple("fatal: Not a git repository: $dir");
 210                         }
 211                         my $search = Git->repository(Repository => $dir);
 212                         try {
 213                                 $search->command('symbolic-ref', 'HEAD');
 214                         } catch Git::Error::Command with {
 215                                 # Mimic git-rev-parse --git-dir error message:
 216                                 throw Error::Simple("fatal: Not a git repository: $dir");
 217                         }
 218
 219                         $opts{Repository} = abs_path($dir);
 220                 }
 221
 222                 delete $opts{Directory};
 223         }
 224
 225         $self = { opts => \%opts };
 226         bless $self, $class;
 227 }
 228
 229 =back
 230
 231 =head1 METHODS
 232
 233 =over 4
 234
 235 =item command ( COMMAND [, ARGUMENTS... ] )
 236
 237 =item command ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 238
 239 Execute the given Git C<COMMAND> (specify it without the 'git-'
 240 prefix), optionally with the specified extra C<ARGUMENTS>.
 241
 242 The second more elaborate form can be used if you want to further adjust
 243 the command execution. Currently, only one option is supported:
 244
 245 B<STDERR> - How to deal with the command's error output. By default (C<undef>)
 246 it is delivered to the caller's C<STDERR>. A false value (0 or '') will cause
 247 it to be thrown away. If you want to process it, you can get it in a filehandle
 248 you specify, but you must be extremely careful; if the error output is not
 249 very short and you want to read it in the same process as where you called
 250 C<command()>, you are set up for a nice deadlock!
 251
 252 The method can be called without any instance or on a specified Git repository
 253 (in that case the command will be run in the repository context).
 254
 255 In scalar context, it returns all the command output in a single string
 256 (verbatim).
 257
 258 In array context, it returns an array containing lines printed to the
 259 command's stdout (without trailing newlines).
 260
 261 In both cases, the command's stdin and stderr are the same as the caller's.
 262
 263 =cut
 264
 265 sub command {
 266         my ($fh, $ctx) = command_output_pipe(@_);
 267
 268         if (not defined wantarray) {
 269                 # Nothing to pepper the possible exception with.
 270                 _cmd_close($fh, $ctx);
 271
 272         } elsif (not wantarray) {
 273                 local $/;
 274                 my $text = <$fh>;
 275                 try {
 276                         _cmd_close($fh, $ctx);
 277                 } catch Git::Error::Command with {
 278                         # Pepper with the output:
 279                         my $E = shift;
 280                         $E->{'-outputref'} = \$text;
 281                         throw $E;
 282                 };
 283                 return $text;
 284
 285         } else {
 286                 my @lines = <$fh>;
 287                 defined and chomp for @lines;
 288                 try {
 289                         _cmd_close($fh, $ctx);
 290                 } catch Git::Error::Command with {
 291                         my $E = shift;
 292                         $E->{'-outputref'} = \@lines;
 293                         throw $E;
 294                 };
 295                 return @lines;
 296         }
 297 }
 298
 299
 300 =item command_oneline ( COMMAND [, ARGUMENTS... ] )
 301
 302 =item command_oneline ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 303
 304 Execute the given C<COMMAND> in the same way as command()
 305 does but always return a scalar string containing the first line
 306 of the command's standard output.
 307
 308 =cut
 309
 310 sub command_oneline {
 311         my ($fh, $ctx) = command_output_pipe(@_);
 312
 313         my $line = <$fh>;
 314         defined $line and chomp $line;
 315         try {
 316                 _cmd_close($fh, $ctx);
 317         } catch Git::Error::Command with {
 318                 # Pepper with the output:
 319                 my $E = shift;
 320                 $E->{'-outputref'} = \$line;
 321                 throw $E;
 322         };
 323         return $line;
 324 }
 325
 326
 327 =item command_output_pipe ( COMMAND [, ARGUMENTS... ] )
 328
 329 =item command_output_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 330
 331 Execute the given C<COMMAND> in the same way as command()
 332 does but return a pipe filehandle from which the command output can be
 333 read.
 334
 335 The function can return C<($pipe, $ctx)> in array context.
 336 See C<command_close_pipe()> for details.
 337
 338 =cut
 339
 340 sub command_output_pipe {
 341         _command_common_pipe('-|', @_);
 342 }
 343
 344
 345 =item command_input_pipe ( COMMAND [, ARGUMENTS... ] )
 346
 347 =item command_input_pipe ( [ COMMAND, ARGUMENTS... ], { Opt => Val ... } )
 348
 349 Execute the given C<COMMAND> in the same way as command_output_pipe()
 350 does but return an input pipe filehandle instead; the command output
 351 is not captured.
 352
 353 The function can return C<($pipe, $ctx)> in array context.
 354 See C<command_close_pipe()> for details.
 355
 356 =cut
 357
 358 sub command_input_pipe {
 359         _command_common_pipe('|-', @_);
 360 }
 361
 362
 363 =item command_close_pipe ( PIPE [, CTX ] )
 364
 365 Close the C<PIPE> as returned from C<command_*_pipe()>, checking
 366 whether the command finished successfully. The optional C<CTX> argument
 367 is required if you want to see the command name in the error message,
 368 and it is the second value returned by C<command_*_pipe()> when
 369 called in array context. The call idiom is:
 370
 371         my ($fh, $ctx) = $r->command_output_pipe('status');
 372         while (<$fh>) { ... }
 373         $r->command_close_pipe($fh, $ctx);
 374
 375 Note that you should not rely on whatever actually is in C<CTX>;
 376 currently it is simply the command name but in future the context might
 377 have more complicated structure.
 378
 379 =cut
 380
 381 sub command_close_pipe {
 382         my ($self, $fh, $ctx) = _maybe_self(@_);
 383         $ctx ||= '<unknown>';
 384         _cmd_close($fh, $ctx);
 385 }
 386
 387 =item command_bidi_pipe ( COMMAND [, ARGUMENTS... ] )
 388
 389 Execute the given C<COMMAND> in the same way as command_output_pipe()
 390 does but return both an input pipe filehandle and an output pipe filehandle.
 391
 392 The function will return return C<($pid, $pipe_in, $pipe_out, $ctx)>.
 393 See C<command_close_bidi_pipe()> for details.
 394
 395 =cut
 396
 397 sub command_bidi_pipe {
 398         my ($pid, $in, $out);
 399         my ($self) = _maybe_self(@_);
 400         local %ENV = %ENV;
 401         my $cwd_save = undef;
 402         if ($self) {
 403                 shift;
 404                 $cwd_save = cwd();
 405                 _setup_git_cmd_env($self);
 406         }
 407         $pid = open2($in, $out, 'git', @_);
 408         chdir($cwd_save) if $cwd_save;
 409         return ($pid, $in, $out, join(' ', @_));
 410 }
 411
 412 =item command_close_bidi_pipe ( PID, PIPE_IN, PIPE_OUT [, CTX] )
 413
 414 Close the C<PIPE_IN> and C<PIPE_OUT> as returned from C<command_bidi_pipe()>,
 415 checking whether the command finished successfully. The optional C<CTX>
 416 argument is required if you want to see the command name in the error message,
 417 and it is the fourth value returned by C<command_bidi_pipe()>.  The call idiom
 418 is:
 419
 420         my ($pid, $in, $out, $ctx) = $r->command_bidi_pipe('cat-file --batch-check');
 421         print "000000000\n" $out;
 422         while (<$in>) { ... }
 423         $r->command_close_bidi_pipe($pid, $in, $out, $ctx);
 424
 425 Note that you should not rely on whatever actually is in C<CTX>;
 426 currently it is simply the command name but in future the context might
 427 have more complicated structure.
 428
 429 =cut
 430
 431 sub command_close_bidi_pipe {
 432         local $?;
 433         my ($pid, $in, $out, $ctx) = @_;
 434         foreach my $fh ($in, $out) {
 435                 unless (close $fh) {
 436                         if ($!) {
 437                                 carp "error closing pipe: $!";
 438                         } elsif ($? >> 8) {
 439                                 throw Git::Error::Command($ctx, $? >>8);
 440                         }
 441                 }
 442         }
 443
 444         waitpid $pid, 0;
 445
 446         if ($? >> 8) {
 447                 throw Git::Error::Command($ctx, $? >>8);
 448         }
 449 }
 450
 451
 452 =item command_noisy ( COMMAND [, ARGUMENTS... ] )
 453
 454 Execute the given C<COMMAND> in the same way as command() does but do not
 455 capture the command output - the standard output is not redirected and goes
 456 to the standard output of the caller application.
 457
 458 While the method is called command_noisy(), you might want to as well use
 459 it for the most silent Git commands which you know will never pollute your
 460 stdout but you want to avoid the overhead of the pipe setup when calling them.
 461
 462 The function returns only after the command has finished running.
 463
 464 =cut
 465
 466 sub command_noisy {
 467         my ($self, $cmd, @args) = _maybe_self(@_);
 468         _check_valid_cmd($cmd);
 469
 470         my $pid = fork;
 471         if (not defined $pid) {
 472                 throw Error::Simple("fork failed: $!");
 473         } elsif ($pid == 0) {
 474                 _cmd_exec($self, $cmd, @args);
 475         }
 476         if (waitpid($pid, 0) > 0 and $?>>8 != 0) {
 477                 throw Git::Error::Command(join(' ', $cmd, @args), $? >> 8);
 478         }
 479 }
 480
 481
 482 =item version ()
 483
 484 Return the Git version in use.
 485
 486 =cut
 487
 488 sub version {
 489         my $verstr = command_oneline('--version');
 490         $verstr =~ s/^git version //;
 491         $verstr;
 492 }
 493
 494
 495 =item exec_path ()
 496
 497 Return path to the Git sub-command executables (the same as
 498 C<git --exec-path>). Useful mostly only internally.
 499
 500 =cut
 501
 502 sub exec_path { command_oneline('--exec-path') }
 503
 504
 505 =item html_path ()
 506
 507 Return path to the Git html documentation (the same as
 508 C<git --html-path>). Useful mostly only internally.
 509
 510 =cut
 511
 512 sub html_path { command_oneline('--html-path') }
 513
 514
 515 =item repo_path ()
 516
 517 Return path to the git repository. Must be called on a repository instance.
 518
 519 =cut
 520
 521 sub repo_path { $_[0]->{opts}->{Repository} }
 522
 523
 524 =item wc_path ()
 525
 526 Return path to the working copy. Must be called on a repository instance.
 527
 528 =cut
 529
 530 sub wc_path { $_[0]->{opts}->{WorkingCopy} }
 531
 532
 533 =item wc_subdir ()
 534
 535 Return path to the subdirectory inside of a working copy. Must be called
 536 on a repository instance.
 537
 538 =cut
 539
 540 sub wc_subdir { $_[0]->{opts}->{WorkingSubdir} ||= '' }
 541
 542
 543 =item wc_chdir ( SUBDIR )
 544
 545 Change the working copy subdirectory to work within. The C<SUBDIR> is
 546 relative to the working copy root directory (not the current subdirectory).
 547 Must be called on a repository instance attached to a working copy
 548 and the directory must exist.
 549
 550 =cut
 551
 552 sub wc_chdir {
 553         my ($self, $subdir) = @_;
 554         $self->wc_path()
 555                 or throw Error::Simple("bare repository");
 556
 557         -d $self->wc_path().'/'.$subdir
 558                 or throw Error::Simple("subdir not found: $subdir $!");
 559         # Of course we will not "hold" the subdirectory so anyone
 560         # can delete it now and we will never know. But at least we tried.
 561
 562         $self->{opts}->{WorkingSubdir} = $subdir;
 563 }
 564
 565
 566 =item config ( VARIABLE )
 567
 568 Retrieve the configuration C<VARIABLE> in the same manner as C<config>
 569 does. In scalar context requires the variable to be set only one time
 570 (exception is thrown otherwise), in array context returns allows the
 571 variable to be set multiple times and returns all the values.
 572
 573 This currently wraps command('config') so it is not so fast.
 574
 575 =cut
 576
 577 sub config {
 578         my ($self, $var) = _maybe_self(@_);
 579
 580         try {
 581                 my @cmd = ('config');
 582                 unshift @cmd, $self if $self;
 583                 if (wantarray) {
 584                         return command(@cmd, '--get-all', $var);
 585                 } else {
 586                         return command_oneline(@cmd, '--get', $var);
 587                 }
 588         } catch Git::Error::Command with {
 589                 my $E = shift;
 590                 if ($E->value() == 1) {
 591                         # Key not found.
 592                         return;
 593                 } else {
 594                         throw $E;
 595                 }
 596         };
 597 }
 598
 599
 600 =item config_bool ( VARIABLE )
 601
 602 Retrieve the bool configuration C<VARIABLE>. The return value
 603 is usable as a boolean in perl (and C<undef> if it's not defined,
 604 of course).
 605
 606 This currently wraps command('config') so it is not so fast.
 607
 608 =cut
 609
 610 sub config_bool {
 611         my ($self, $var) = _maybe_self(@_);
 612
 613         try {
 614                 my @cmd = ('config', '--bool', '--get', $var);
 615                 unshift @cmd, $self if $self;
 616                 my $val = command_oneline(@cmd);
 617                 return undef unless defined $val;
 618                 return $val eq 'true';
 619         } catch Git::Error::Command with {
 620                 my $E = shift;
 621                 if ($E->value() == 1) {
 622                         # Key not found.
 623                         return undef;
 624                 } else {
 625                         throw $E;
 626                 }
 627         };
 628 }
 629
 630 =item config_int ( VARIABLE )
 631
 632 Retrieve the integer configuration C<VARIABLE>. The return value
 633 is simple decimal number.  An optional value suffix of 'k', 'm',
 634 or 'g' in the config file will cause the value to be multiplied
 635 by 1024, 1048576 (1024^2), or 1073741824 (1024^3) prior to output.
 636 It would return C<undef> if configuration variable is not defined,
 637
 638 This currently wraps command('config') so it is not so fast.
 639
 640 =cut
 641
 642 sub config_int {
 643         my ($self, $var) = _maybe_self(@_);
 644
 645         try {
 646                 my @cmd = ('config', '--int', '--get', $var);
 647                 unshift @cmd, $self if $self;
 648                 return command_oneline(@cmd);
 649         } catch Git::Error::Command with {
 650                 my $E = shift;
 651                 if ($E->value() == 1) {
 652                         # Key not found.
 653                         return undef;
 654                 } else {
 655                         throw $E;
 656                 }
 657         };
 658 }
 659
 660 =item get_colorbool ( NAME )
 661
 662 Finds if color should be used for NAMEd operation from the configuration,
 663 and returns boolean (true for "use color", false for "do not use color").
 664
 665 =cut
 666
 667 sub get_colorbool {
 668         my ($self, $var) = @_;
 669         my $stdout_to_tty = (-t STDOUT) ? "true" : "false";
 670         my $use_color = $self->command_oneline('config', '--get-colorbool',
 671                                                $var, $stdout_to_tty);
 672         return ($use_color eq 'true');
 673 }
 674
 675 =item get_color ( SLOT, COLOR )
 676
 677 Finds color for SLOT from the configuration, while defaulting to COLOR,
 678 and returns the ANSI color escape sequence:
 679
 680         print $repo->get_color("color.interactive.prompt", "underline blue white");
 681         print "some text";
 682         print $repo->get_color("", "normal");
 683
 684 =cut
 685
 686 sub get_color {
 687         my ($self, $slot, $default) = @_;
 688         my $color = $self->command_oneline('config', '--get-color', $slot, $default);
 689         if (!defined $color) {
 690                 $color = "";
 691         }
 692         return $color;
 693 }
 694
 695 =item remote_refs ( REPOSITORY [, GROUPS [, REFGLOBS ] ] )
 696
 697 This function returns a hashref of refs stored in a given remote repository.
 698 The hash is in the format C<refname =\> hash>. For tags, the C<refname> entry
 699 contains the tag object while a C<refname^{}> entry gives the tagged objects.
 700
 701 C<REPOSITORY> has the same meaning as the appropriate C<git-ls-remote>
 702 argument; either an URL or a remote name (if called on a repository instance).
 703 C<GROUPS> is an optional arrayref that can contain 'tags' to return all the
 704 tags and/or 'heads' to return all the heads. C<REFGLOB> is an optional array
 705 of strings containing a shell-like glob to further limit the refs returned in
 706 the hash; the meaning is again the same as the appropriate C<git-ls-remote>
 707 argument.
 708
 709 This function may or may not be called on a repository instance. In the former
 710 case, remote names as defined in the repository are recognized as repository
 711 specifiers.
 712
 713 =cut
 714
 715 sub remote_refs {
 716         my ($self, $repo, $groups, $refglobs) = _maybe_self(@_);
 717         my @args;
 718         if (ref $groups eq 'ARRAY') {
 719                 foreach (@$groups) {
 720                         if ($_ eq 'heads') {
 721                                 push (@args, '--heads');
 722                         } elsif ($_ eq 'tags') {
 723                                 push (@args, '--tags');
 724                         } else {
 725                                 # Ignore unknown groups for future
 726                                 # compatibility
 727                         }
 728                 }
 729         }
 730         push (@args, $repo);
 731         if (ref $refglobs eq 'ARRAY') {
 732                 push (@args, @$refglobs);
 733         }
 734
 735         my @self = $self ? ($self) : (); # Ultra trickery
 736         my ($fh, $ctx) = Git::command_output_pipe(@self, 'ls-remote', @args);
 737         my %refs;
 738         while (<$fh>) {
 739                 chomp;
 740                 my ($hash, $ref) = split(/\t/, $_, 2);
 741                 $refs{$ref} = $hash;
 742         }
 743         Git::command_close_pipe(@self, $fh, $ctx);
 744         return \%refs;
 745 }
 746
 747
 748 =item ident ( TYPE | IDENTSTR )
 749
 750 =item ident_person ( TYPE | IDENTSTR | IDENTARRAY )
 751
 752 This suite of functions retrieves and parses ident information, as stored
 753 in the commit and tag objects or produced by C<var GIT_type_IDENT> (thus
 754 C<TYPE> can be either I<author> or I<committer>; case is insignificant).
 755
 756 The C<ident> method retrieves the ident information from C<git var>
 757 and either returns it as a scalar string or as an array with the fields parsed.
 758 Alternatively, it can take a prepared ident string (e.g. from the commit
 759 object) and just parse it.
 760
 761 C<ident_person> returns the person part of the ident - name and email;
 762 it can take the same arguments as C<ident> or the array returned by C<ident>.
 763
 764 The synopsis is like:
 765
 766         my ($name, $email, $time_tz) = ident('author');
 767         "$name <$email>" eq ident_person('author');
 768         "$name <$email>" eq ident_person($name);
 769         $time_tz =~ /^\d+ [+-]\d{4}$/;
 770
 771 =cut
 772
 773 sub ident {
 774         my ($self, $type) = _maybe_self(@_);
 775         my $identstr;
 776         if (lc $type eq lc 'committer' or lc $type eq lc 'author') {
 777                 my @cmd = ('var', 'GIT_'.uc($type).'_IDENT');
 778                 unshift @cmd, $self if $self;
 779                 $identstr = command_oneline(@cmd);
 780         } else {
 781                 $identstr = $type;
 782         }
 783         if (wantarray) {
 784                 return $identstr =~ /^(.*) <(.*)> (\d+ [+-]\d{4})$/;
 785         } else {
 786                 return $identstr;
 787         }
 788 }
 789
 790 sub ident_person {
 791         my ($self, @ident) = _maybe_self(@_);
 792         $#ident == 0 and @ident = $self ? $self->ident($ident[0]) : ident($ident[0]);
 793         return "$ident[0] <$ident[1]>";
 794 }
 795
 796
 797 =item hash_object ( TYPE, FILENAME )
 798
 799 Compute the SHA1 object id of the given C<FILENAME> considering it is
 800 of the C<TYPE> object type (C<blob>, C<commit>, C<tree>).
 801
 802 The method can be called without any instance or on a specified Git repository,
 803 it makes zero difference.
 804
 805 The function returns the SHA1 hash.
 806
 807 =cut
 808
 809 # TODO: Support for passing FILEHANDLE instead of FILENAME
 810 sub hash_object {
 811         my ($self, $type, $file) = _maybe_self(@_);
 812         command_oneline('hash-object', '-t', $type, $file);
 813 }
 814
 815
 816 =item hash_and_insert_object ( FILENAME )
 817
 818 Compute the SHA1 object id of the given C<FILENAME> and add the object to the
 819 object database.
 820
 821 The function returns the SHA1 hash.
 822
 823 =cut
 824
 825 # TODO: Support for passing FILEHANDLE instead of FILENAME
 826 sub hash_and_insert_object {
 827         my ($self, $filename) = @_;
 828
 829         carp "Bad filename \"$filename\"" if $filename =~ /[\r\n]/;
 830
 831         $self->_open_hash_and_insert_object_if_needed();
 832         my ($in, $out) = ($self->{hash_object_in}, $self->{hash_object_out});
 833
 834         unless (print $out $filename, "\n") {
 835                 $self->_close_hash_and_insert_object();
 836                 throw Error::Simple("out pipe went bad");
 837         }
 838
 839         chomp(my $hash = <$in>);
 840         unless (defined($hash)) {
 841                 $self->_close_hash_and_insert_object();
 842                 throw Error::Simple("in pipe went bad");
 843         }
 844
 845         return $hash;
 846 }
 847
 848 sub _open_hash_and_insert_object_if_needed {
 849         my ($self) = @_;
 850
 851         return if defined($self->{hash_object_pid});
 852
 853         ($self->{hash_object_pid}, $self->{hash_object_in},
 854          $self->{hash_object_out}, $self->{hash_object_ctx}) =
 855                 $self->command_bidi_pipe(qw(hash-object -w --stdin-paths --no-filters));
 856 }
 857
 858 sub _close_hash_and_insert_object {
 859         my ($self) = @_;
 860
 861         return unless defined($self->{hash_object_pid});
 862
 863         my @vars = map { 'hash_object_' . $_ } qw(pid in out ctx);
 864
 865         command_close_bidi_pipe(@$self{@vars});
 866         delete @$self{@vars};
 867 }
 868
 869 =item cat_blob ( SHA1, FILEHANDLE )
 870
 871 Prints the contents of the blob identified by C<SHA1> to C<FILEHANDLE> and
 872 returns the number of bytes printed.
 873
 874 =cut
 875
 876 sub cat_blob {
 877         my ($self, $sha1, $fh) = @_;
 878
 879         $self->_open_cat_blob_if_needed();
 880         my ($in, $out) = ($self->{cat_blob_in}, $self->{cat_blob_out});
 881
 882         unless (print $out $sha1, "\n") {
 883                 $self->_close_cat_blob();
 884                 throw Error::Simple("out pipe went bad");
 885         }
 886
 887         my $description = <$in>;
 888         if ($description =~ / missing$/) {
 889                 carp "$sha1 doesn't exist in the repository";
 890                 return -1;
 891         }
 892
 893         if ($description !~ /^[0-9a-fA-F]{40} \S+ (\d+)$/) {
 894                 carp "Unexpected result returned from git cat-file";
 895                 return -1;
 896         }
 897
 898         my $size = $1;
 899
 900         my $blob;
 901         my $bytesRead = 0;
 902
 903         while (1) {
 904                 my $bytesLeft = $size - $bytesRead;
 905                 last unless $bytesLeft;
 906
 907                 my $bytesToRead = $bytesLeft < 1024 ? $bytesLeft : 1024;
 908                 my $read = read($in, $blob, $bytesToRead, $bytesRead);
 909                 unless (defined($read)) {
 910                         $self->_close_cat_blob();
 911                         throw Error::Simple("in pipe went bad");
 912                 }
 913
 914                 $bytesRead += $read;
 915         }
 916
 917         # Skip past the trailing newline.
 918         my $newline;
 919         my $read = read($in, $newline, 1);
 920         unless (defined($read)) {
 921                 $self->_close_cat_blob();
 922                 throw Error::Simple("in pipe went bad");
 923         }
 924         unless ($read == 1 && $newline eq "\n") {
 925                 $self->_close_cat_blob();
 926                 throw Error::Simple("didn't find newline after blob");
 927         }
 928
 929         unless (print $fh $blob) {
 930                 $self->_close_cat_blob();
 931                 throw Error::Simple("couldn't write to passed in filehandle");
 932         }
 933
 934         return $size;
 935 }
 936
 937 sub _open_cat_blob_if_needed {
 938         my ($self) = @_;
 939
 940         return if defined($self->{cat_blob_pid});
 941
 942         ($self->{cat_blob_pid}, $self->{cat_blob_in},
 943          $self->{cat_blob_out}, $self->{cat_blob_ctx}) =
 944                 $self->command_bidi_pipe(qw(cat-file --batch));
 945 }
 946
 947 sub _close_cat_blob {
 948         my ($self) = @_;
 949
 950         return unless defined($self->{cat_blob_pid});
 951
 952         my @vars = map { 'cat_blob_' . $_ } qw(pid in out ctx);
 953
 954         command_close_bidi_pipe(@$self{@vars});
 955         delete @$self{@vars};
 956 }
 957
 958
 959 { # %TEMP_* Lexical Context
 960
 961 my (%TEMP_FILEMAP, %TEMP_FILES);
 962
 963 =item temp_acquire ( NAME )
 964
 965 Attempts to retreive the temporary file mapped to the string C<NAME>. If an
 966 associated temp file has not been created this session or was closed, it is
 967 created, cached, and set for autoflush and binmode.
 968
 969 Internally locks the file mapped to C<NAME>. This lock must be released with
 970 C<temp_release()> when the temp file is no longer needed. Subsequent attempts
 971 to retrieve temporary files mapped to the same C<NAME> while still locked will
 972 cause an error. This locking mechanism provides a weak guarantee and is not
 973 threadsafe. It does provide some error checking to help prevent temp file refs
 974 writing over one another.
 975
 976 In general, the L<File::Handle> returned should not be closed by consumers as
 977 it defeats the purpose of this caching mechanism. If you need to close the temp
 978 file handle, then you should use L<File::Temp> or another temp file faculty
 979 directly. If a handle is closed and then requested again, then a warning will
 980 issue.
 981
 982 =cut
 983
 984 sub temp_acquire {
 985         my $temp_fd = _temp_cache(@_);
 986
 987         $TEMP_FILES{$temp_fd}{locked} = 1;
 988         $temp_fd;
 989 }
 990
 991 =item temp_release ( NAME )
 992
 993 =item temp_release ( FILEHANDLE )
 994
 995 Releases a lock acquired through C<temp_acquire()>. Can be called either with
 996 the C<NAME> mapping used when acquiring the temp file or with the C<FILEHANDLE>
 997 referencing a locked temp file.
 998
 999 Warns if an attempt is made to release a file that is not locked.
1000
1001 The temp file will be truncated before being released. This can help to reduce
1002 disk I/O where the system is smart enough to detect the truncation while data
1003 is in the output buffers. Beware that after the temp file is released and
1004 truncated, any operations on that file may fail miserably until it is
1005 re-acquired. All contents are lost between each release and acquire mapped to
1006 the same string.
1007
1008 =cut
1009
1010 sub temp_release {
1011         my ($self, $temp_fd, $trunc) = _maybe_self(@_);
1012
1013         if (exists $TEMP_FILEMAP{$temp_fd}) {
1014                 $temp_fd = $TEMP_FILES{$temp_fd};
1015         }
1016         unless ($TEMP_FILES{$temp_fd}{locked}) {
1017                 carp "Attempt to release temp file '",
1018                         $temp_fd, "' that has not been locked";
1019         }
1020         temp_reset($temp_fd) if $trunc and $temp_fd->opened;
1021
1022         $TEMP_FILES{$temp_fd}{locked} = 0;
1023         undef;
1024 }
1025
1026 sub _temp_cache {
1027         my ($self, $name) = _maybe_self(@_);
1028
1029         _verify_require();
1030
1031         my $temp_fd = \$TEMP_FILEMAP{$name};
1032         if (defined $$temp_fd and $$temp_fd->opened) {
1033                 if ($TEMP_FILES{$$temp_fd}{locked}) {
1034                         throw Error::Simple("Temp file with moniker '" .
1035                                 $name . "' already in use");
1036                 }
1037         } else {
1038                 if (defined $$temp_fd) {
1039                         # then we're here because of a closed handle.
1040                         carp "Temp file '", $name,
1041                                 "' was closed. Opening replacement.";
1042                 }
1043                 my $fname;
1044
1045                 my $tmpdir;
1046                 if (defined $self) {
1047                         $tmpdir = $self->repo_path();
1048                 }
1049
1050                 ($$temp_fd, $fname) = File::Temp->tempfile(
1051                         'Git_XXXXXX', UNLINK => 1, DIR => $tmpdir,
1052                         ) or throw Error::Simple("couldn't open new temp file");
1053
1054                 $$temp_fd->autoflush;
1055                 binmode $$temp_fd;
1056                 $TEMP_FILES{$$temp_fd}{fname} = $fname;
1057         }
1058         $$temp_fd;
1059 }
1060
1061 sub _verify_require {
1062         eval { require File::Temp; require File::Spec; };
1063         $@ and throw Error::Simple($@);
1064 }
1065
1066 =item temp_reset ( FILEHANDLE )
1067
1068 Truncates and resets the position of the C<FILEHANDLE>.
1069
1070 =cut
1071
1072 sub temp_reset {
1073         my ($self, $temp_fd) = _maybe_self(@_);
1074
1075         truncate $temp_fd, 0
1076                 or throw Error::Simple("couldn't truncate file");
1077         sysseek($temp_fd, 0, SEEK_SET) and seek($temp_fd, 0, SEEK_SET)
1078                 or throw Error::Simple("couldn't seek to beginning of file");
1079         sysseek($temp_fd, 0, SEEK_CUR) == 0 and tell($temp_fd) == 0
1080                 or throw Error::Simple("expected file position to be reset");
1081 }
1082
1083 =item temp_path ( NAME )
1084
1085 =item temp_path ( FILEHANDLE )
1086
1087 Returns the filename associated with the given tempfile.
1088
1089 =cut
1090
1091 sub temp_path {
1092         my ($self, $temp_fd) = _maybe_self(@_);
1093
1094         if (exists $TEMP_FILEMAP{$temp_fd}) {
1095                 $temp_fd = $TEMP_FILEMAP{$temp_fd};
1096         }
1097         $TEMP_FILES{$temp_fd}{fname};
1098 }
1099
1100 sub END {
1101         unlink values %TEMP_FILEMAP if %TEMP_FILEMAP;
1102 }
1103
1104 } # %TEMP_* Lexical Context
1105
1106 =back
1107
1108 =head1 ERROR HANDLING
1109
1110 All functions are supposed to throw Perl exceptions in case of errors.
1111 See the L<Error> module on how to catch those. Most exceptions are mere
1112 L<Error::Simple> instances.
1113
1114 However, the C<command()>, C<command_oneline()> and C<command_noisy()>
1115 functions suite can throw C<Git::Error::Command> exceptions as well: those are
1116 thrown when the external command returns an error code and contain the error
1117 code as well as access to the captured command's output. The exception class
1118 provides the usual C<stringify> and C<value> (command's exit code) methods and
1119 in addition also a C<cmd_output> method that returns either an array or a
1120 string with the captured command output (depending on the original function
1121 call context; C<command_noisy()> returns C<undef>) and $<cmdline> which
1122 returns the command and its arguments (but without proper quoting).
1123
1124 Note that the C<command_*_pipe()> functions cannot throw this exception since
1125 it has no idea whether the command failed or not. You will only find out
1126 at the time you C<close> the pipe; if you want to have that automated,
1127 use C<command_close_pipe()>, which can throw the exception.
1128
1129 =cut
1130
1131 {
1132         package Git::Error::Command;
1133
1134         @Git::Error::Command::ISA = qw(Error);
1135
1136         sub new {
1137                 my $self = shift;
1138                 my $cmdline = '' . shift;
1139                 my $value = 0 + shift;
1140                 my $outputref = shift;
1141                 my(@args) = ();
1142
1143                 local $Error::Depth = $Error::Depth + 1;
1144
1145                 push(@args, '-cmdline', $cmdline);
1146                 push(@args, '-value', $value);
1147                 push(@args, '-outputref', $outputref);
1148
1149                 $self->SUPER::new(-text => 'command returned error', @args);
1150         }
1151
1152         sub stringify {
1153                 my $self = shift;
1154                 my $text = $self->SUPER::stringify;
1155                 $self->cmdline() . ': ' . $text . ': ' . $self->value() . "\n";
1156         }
1157
1158         sub cmdline {
1159                 my $self = shift;
1160                 $self->{'-cmdline'};
1161         }
1162
1163         sub cmd_output {
1164                 my $self = shift;
1165                 my $ref = $self->{'-outputref'};
1166                 defined $ref or undef;
1167                 if (ref $ref eq 'ARRAY') {
1168                         return @$ref;
1169                 } else { # SCALAR
1170                         return $$ref;
1171                 }
1172         }
1173 }
1174
1175 =over 4
1176
1177 =item git_cmd_try { CODE } ERRMSG
1178
1179 This magical statement will automatically catch any C<Git::Error::Command>
1180 exceptions thrown by C<CODE> and make your program die with C<ERRMSG>
1181 on its lips; the message will have %s substituted for the command line
1182 and %d for the exit status. This statement is useful mostly for producing
1183 more user-friendly error messages.
1184
1185 In case of no exception caught the statement returns C<CODE>'s return value.
1186
1187 Note that this is the only auto-exported function.
1188
1189 =cut
1190
1191 sub git_cmd_try(&$) {
1192         my ($code, $errmsg) = @_;
1193         my @result;
1194         my $err;
1195         my $array = wantarray;
1196         try {
1197                 if ($array) {
1198                         @result = &$code;
1199                 } else {
1200                         $result[0] = &$code;
1201                 }
1202         } catch Git::Error::Command with {
1203                 my $E = shift;
1204                 $err = $errmsg;
1205                 $err =~ s/\%s/$E->cmdline()/ge;
1206                 $err =~ s/\%d/$E->value()/ge;
1207                 # We can't croak here since Error.pm would mangle
1208                 # that to Error::Simple.
1209         };
1210         $err and croak $err;
1211         return $array ? @result : $result[0];
1212 }
1213
1214
1215 =back
1216
1217 =head1 COPYRIGHT
1218
1219 Copyright 2006 by Petr Baudis E<lt>pasky@suse.czE<gt>.
1220
1221 This module is free software; it may be used, copied, modified
1222 and distributed under the terms of the GNU General Public Licence,
1223 either version 2, or (at your option) any later version.
1224
1225 =cut
1226
1227
1228 # Take raw method argument list and return ($obj, @args) in case
1229 # the method was called upon an instance and (undef, @args) if
1230 # it was called directly.
1231 sub _maybe_self {
1232         UNIVERSAL::isa($_[0], 'Git') ? @_ : (undef, @_);
1233 }
1234
1235 # Check if the command id is something reasonable.
1236 sub _check_valid_cmd {
1237         my ($cmd) = @_;
1238         $cmd =~ /^[a-z0-9A-Z_-]+$/ or throw Error::Simple("bad command: $cmd");
1239 }
1240
1241 # Common backend for the pipe creators.
1242 sub _command_common_pipe {
1243         my $direction = shift;
1244         my ($self, @p) = _maybe_self(@_);
1245         my (%opts, $cmd, @args);
1246         if (ref $p[0]) {
1247                 ($cmd, @args) = @{shift @p};
1248                 %opts = ref $p[0] ? %{$p[0]} : @p;
1249         } else {
1250                 ($cmd, @args) = @p;
1251         }
1252         _check_valid_cmd($cmd);
1253
1254         my $fh;
1255         if ($^O eq 'MSWin32') {
1256                 # ActiveState Perl
1257                 #defined $opts{STDERR} and
1258                 #       warn 'ignoring STDERR option - running w/ ActiveState';
1259                 $direction eq '-|' or
1260                         die 'input pipe for ActiveState not implemented';
1261                 # the strange construction with *ACPIPE is just to
1262                 # explain the tie below that we want to bind to
1263                 # a handle class, not scalar. It is not known if
1264                 # it is something specific to ActiveState Perl or
1265                 # just a Perl quirk.
1266                 tie (*ACPIPE, 'Git::activestate_pipe', $cmd, @args);
1267                 $fh = *ACPIPE;
1268
1269         } else {
1270                 my $pid = open($fh, $direction);
1271                 if (not defined $pid) {
1272                         throw Error::Simple("open failed: $!");
1273                 } elsif ($pid == 0) {
1274                         if (defined $opts{STDERR}) {
1275                                 close STDERR;
1276                         }
1277                         if ($opts{STDERR}) {
1278                                 open (STDERR, '>&', $opts{STDERR})
1279                                         or die "dup failed: $!";
1280                         }
1281                         _cmd_exec($self, $cmd, @args);
1282                 }
1283         }
1284         return wantarray ? ($fh, join(' ', $cmd, @args)) : $fh;
1285 }
1286
1287 # When already in the subprocess, set up the appropriate state
1288 # for the given repository and execute the git command.
1289 sub _cmd_exec {
1290         my ($self, @args) = @_;
1291         _setup_git_cmd_env($self);
1292         _execv_git_cmd(@args);
1293         die qq[exec "@args" failed: $!];
1294 }
1295
1296 # set up the appropriate state for git command
1297 sub _setup_git_cmd_env {
1298         my $self = shift;
1299         if ($self) {
1300                 $self->repo_path() and $ENV{'GIT_DIR'} = $self->repo_path();
1301                 $self->repo_path() and $self->wc_path()
1302                         and $ENV{'GIT_WORK_TREE'} = $self->wc_path();
1303                 $self->wc_path() and chdir($self->wc_path());
1304                 $self->wc_subdir() and chdir($self->wc_subdir());
1305         }
1306 }
1307
1308 # Execute the given Git command ($_[0]) with arguments ($_[1..])
1309 # by searching for it at proper places.
1310 sub _execv_git_cmd { exec('git', @_); }
1311
1312 # Close pipe to a subprocess.
1313 sub _cmd_close {
1314         my ($fh, $ctx) = @_;
1315         if (not close $fh) {
1316                 if ($!) {
1317                         # It's just close, no point in fatalities
1318                         carp "error closing pipe: $!";
1319                 } elsif ($? >> 8) {
1320                         # The caller should pepper this.
1321                         throw Git::Error::Command($ctx, $? >> 8);
1322                 }
1323                 # else we might e.g. closed a live stream; the command
1324                 # dying of SIGPIPE would drive us here.
1325         }
1326 }
1327
1328
1329 sub DESTROY {
1330         my ($self) = @_;
1331         $self->_close_hash_and_insert_object();
1332         $self->_close_cat_blob();
1333 }
1334
1335
1336 # Pipe implementation for ActiveState Perl.
1337
1338 package Git::activestate_pipe;
1339 use strict;
1340
1341 sub TIEHANDLE {
1342         my ($class, @params) = @_;
1343         # FIXME: This is probably horrible idea and the thing will explode
1344         # at the moment you give it arguments that require some quoting,
1345         # but I have no ActiveState clue... --pasky
1346         # Let's just hope ActiveState Perl does at least the quoting
1347         # correctly.
1348         my @data = qx{git @params};
1349         bless { i => 0, data => \@data }, $class;
1350 }
1351
1352 sub READLINE {
1353         my $self = shift;
1354         if ($self->{i} >= scalar @{$self->{data}}) {
1355                 return undef;
1356         }
1357         my $i = $self->{i};
1358         if (wantarray) {
1359                 $self->{i} = $#{$self->{'data'}} + 1;
1360                 return splice(@{$self->{'data'}}, $i);
1361         }
1362         $self->{i} = $i + 1;
1363         return $self->{'data'}->[ $i ];
1364 }
1365
1366 sub CLOSE {
1367         my $self = shift;
1368         delete $self->{data};
1369         delete $self->{i};
1370 }
1371
1372 sub EOF {
1373         my $self = shift;
1374         return ($self->{i} >= scalar @{$self->{data}});
1375 }
1376
1377
1378 1; # Famous last words