1 project('ncmpc', 'c',
2 version: '0.28',
3 default_options: [
4 'c_std=c99',
5 ],
6 license: 'GPLv2+',
7 )
9 cc = meson.get_compiler('c')
11 conf = configuration_data()
12 conf.set_quoted('PACKAGE', meson.project_name())
13 conf.set_quoted('VERSION', meson.project_version())
14 conf.set_quoted('SYSCONFDIR', join_paths(get_option('prefix'), get_option('sysconfdir')))
15 conf.set_quoted('LOCALE_DIR', join_paths(get_option('prefix'), get_option('localedir')))
17 mini = get_option('mini')
18 conf.set('NCMPC_MINI', mini)
20 enable_locale = get_option('locale')
21 if enable_locale == 'false' or mini
22 enable_locale = false
23 elif cc.has_header('locale.h')
24 enable_locale = true
25 elif enable_locale == 'auto'
26 enable_locale = false
27 else
28 error('locale.h not found')
29 endif
30 conf.set('ENABLE_LOCALE', enable_locale)
32 enable_nls = get_option('nls')
33 if enable_nls == 'false' or mini
34 enable_nls = false
35 elif cc.has_header('libintl.h')
36 enable_nls = true
37 elif enable_nls == 'auto'
38 enable_nls = false
39 else
40 error('libintl.h not found')
41 endif
42 conf.set('ENABLE_NLS', enable_nls)
43 if enable_nls
44 conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
45 subdir('po')
46 endif
48 if get_option('tcp')
49 conf.set('ENABLE_TCP', true)
50 conf.set('HAVE_GETADDRINFO', cc.has_function('getaddrinfo'))
51 endif
53 async_connect = get_option('async_connect')
54 conf.set('ENABLE_ASYNC_CONNECT', async_connect)
56 conf.set('ENABLE_MULTIBYTE', get_option('multibyte'))
58 curses = get_option('curses')
59 if curses == 'ncursesw'
60 curses_dep = dependency('ncursesw')
61 elif curses == 'ncurses'
62 curses_dep = dependency('ncurses')
63 else
64 curses_dep = dependency('ncursesw', required: false)
65 if curses_dep.found()
66 curses = 'ncursesw'
67 else
68 curses_dep = dependency('ncurses', required: false)
70 if curses_dep.found()
71 curses = 'ncurses'
72 else
73 # TODO: find other curses implementation (pdcurses?)
74 endif
75 endif
76 endif
78 if curses == 'ncursesw'
79 conf.set('HAVE_NCURSESW', true)
80 curses_enhanced = true
81 curses_color = true
82 if cc.has_header('ncursesw/curses.h', dependencies: curses_dep)
83 conf.set('HAVE_NCURSESW_CURSES_H', true)
84 elif cc.has_header('ncursesw.h', dependencies: curses_dep)
85 conf.set('HAVE_NCURSESW_H', true)
86 else
87 error('No ncursesw header found')
88 endif
89 elif curses == 'ncurses'
90 conf.set('HAVE_NCURSES', true)
91 curses_enhanced = true
92 curses_color = true
93 if cc.has_header('ncurses/curses.h', dependencies: curses_dep)
94 conf.set('HAVE_NCURSES_CURSES_H', true)
95 elif cc.has_header('ncurses.h', dependencies: curses_dep)
96 conf.set('HAVE_NCURSES_H', true)
97 else
98 error('No ncurses header found')
99 endif
100 else
101 if cc.has_header('curses.h', dependencies: curses_dep)
102 conf.set('HAVE_CURSES_H', true)
104 # TODO: test this with pdcurses
105 curses_enhanced = cc.has_header_symbol('curses.h', '_XOPEN_CURSES', dependencies: curses_dep)
106 curses_color = curses_enhanced or cc.has_header_symbol('curses.h', 'COLOR_PAIR', dependencies: curses_dep)
107 else
108 error('No curses header found')
109 endif
110 endif
111 conf.set('HAVE_CURSES_ENHANCED', curses_enhanced)
113 enable_mouse = get_option('mouse')
114 if enable_mouse == 'false'
115 enable_mouse = false
116 elif cc.has_function('getmouse', dependencies: curses_dep)
117 enable_mouse = true
118 elif enable_mouse == 'auto'
119 enable_mouse = false
120 else
121 error('getmouse() not available')
122 endif
123 conf.set('HAVE_GETMOUSE', enable_mouse)
125 enable_lirc = get_option('lirc')
126 if enable_lirc == 'false'
127 enable_lirc = false
128 lirc_dep = []
129 else
130 lirc_dep = dependency('lirc', required: false)
131 if not lirc_dep.found()
132 lirc_dep = dependency('liblircclient0', required: false)
133 endif
135 if lirc_dep.found()
136 enable_lirc = true
137 elif enable_lirc == 'auto'
138 enable_lirc = false
139 else
140 error('liblirc not found')
141 endif
142 endif
143 conf.set('ENABLE_LIRC', enable_lirc)
145 conf.set('ENABLE_COLORS', curses_color)
147 common_cflags = [
148 ]
150 test_cflags = [
151 '-Wall',
152 '-Wextra',
153 '-Wno-deprecated-declarations',
154 '-Wmissing-prototypes',
155 '-Wshadow',
156 '-Wpointer-arith',
157 '-Wstrict-prototypes',
158 '-Wcast-qual',
159 '-Wwrite-strings',
160 '-fvisibility=hidden',
161 ]
163 test_ldflags = [
164 ]
166 if get_option('buildtype') != 'debug'
167 test_cflags += [
168 '-ffunction-sections',
169 '-fdata-sections',
170 ]
171 test_ldflags += [
172 '-Wl,--gc-sections',
173 ]
174 endif
176 foreach f: test_cflags
177 if cc.has_argument(f)
178 common_cflags += [ f ]
179 endif
180 endforeach
182 add_global_arguments(common_cflags, language: 'c')
184 foreach f: test_ldflags
185 if cc.has_argument(f)
186 add_global_link_arguments(f, language: 'c')
187 endif
188 endforeach
190 glib_dep = dependency('glib-2.0', version: '>= 2.30')
191 libmpdclient_dep = dependency('libmpdclient', version: '>= 2.9')
193 inc = include_directories(
194 'src',
196 # for the generated config.h
197 '.',
198 )
200 sources = []
202 need_screen_text = false
203 need_plugin_library = false
205 if host_machine.system() != 'windows'
206 sources += [
207 'src/signals.c',
208 ]
209 endif
211 if not mini
212 sources += [
213 'src/db_completion.c',
214 'src/xterm_title.c',
215 'src/hscroll.c',
216 'src/match.c',
217 'src/conf.c',
218 ]
219 endif
221 if async_connect
222 sources += [
223 'src/net/socket.c',
224 'src/net/resolver.c',
225 'src/net/async_connect.c',
226 'src/net/async_rconnect.c',
227 'src/aconnect.c',
228 ]
229 endif
231 if enable_lirc
232 sources += [
233 'src/lirc.c',
234 ]
235 endif
237 enable_help_screen = get_option('help_screen') and not mini
238 conf.set('ENABLE_HELP_SCREEN', enable_help_screen)
239 if enable_help_screen
240 sources += ['src/screen_help.c']
241 endif
243 enable_artist_screen = get_option('artist_screen') and not mini
244 conf.set('ENABLE_ARTIST_SCREEN', enable_artist_screen)
245 if enable_artist_screen
246 sources += ['src/screen_artist.c']
247 endif
249 enable_search_screen = get_option('search_screen') and not mini
250 conf.set('ENABLE_SEARCH_SCREEN', enable_search_screen)
251 if enable_search_screen
252 sources += ['src/screen_search.c']
253 endif
255 enable_song_screen = get_option('song_screen') and not mini
256 conf.set('ENABLE_SONG_SCREEN', enable_song_screen)
257 if enable_song_screen
258 sources += ['src/screen_song.c']
259 endif
261 enable_keydef_screen = get_option('key_screen') and not mini
262 conf.set('ENABLE_KEYDEF_SCREEN', enable_keydef_screen)
263 if enable_keydef_screen
264 sources += ['src/screen_keydef.c']
265 endif
267 enable_lyrics_screen = get_option('lyrics_screen') and not mini
268 conf.set('ENABLE_LYRICS_SCREEN', enable_lyrics_screen)
269 if enable_lyrics_screen
270 sources += ['src/screen_lyrics.c', 'src/lyrics.c']
272 lyrics_plugin_dir = join_paths(get_option('prefix'), get_option('libdir'), meson.project_name(), 'lyrics')
273 conf.set_quoted('LYRICS_PLUGIN_DIR', lyrics_plugin_dir)
274 install_data(
275 'lyrics/10-hd.sh',
276 'lyrics/20-lyricwiki.rb',
277 install_dir: lyrics_plugin_dir)
279 need_screen_text = true
280 need_plugin_library = true
281 endif
283 enable_outputs_screen = get_option('outputs_screen') and not mini
284 conf.set('ENABLE_OUTPUTS_SCREEN', enable_outputs_screen)
285 if enable_outputs_screen
286 sources += ['src/screen_outputs.c']
287 endif
289 enable_chat_screen = get_option('chat_screen') and not mini
290 conf.set('ENABLE_CHAT_SCREEN', enable_chat_screen)
291 if enable_chat_screen
292 sources += ['src/screen_chat.c']
293 need_screen_text = true
294 endif
296 if need_screen_text
297 sources += ['src/screen_text.c']
298 endif
300 if need_plugin_library
301 if host_machine.system() == 'windows'
302 error('Plugins not yet compatible with Windows')
303 endif
305 sources += ['src/plugin.c']
306 endif
308 if host_machine.system() == 'windows'
309 subdir('src/win')
310 endif
312 ncmpc = executable('ncmpc',
313 'src/main.c',
314 'src/gidle.c',
315 'src/mpdclient.c',
316 'src/callbacks.c',
317 'src/playlist.c',
318 'src/filelist.c',
319 'src/options.c',
320 'src/command.c',
321 'src/keyboard.c',
322 'src/ncu.c',
323 'src/player_command.c',
324 'src/title_bar.c',
325 'src/progress_bar.c',
326 'src/status_bar.c',
327 'src/screen.c',
328 'src/screen_init.c',
329 'src/screen_paint.c',
330 'src/screen_utils.c',
331 'src/screen_status.c',
332 'src/screen_list.c',
333 'src/screen_find.c',
334 'src/screen_client.c',
335 'src/screen_queue.c',
336 'src/screen_browser.c',
337 'src/screen_file.c',
338 'src/list_window.c',
339 'src/save_playlist.c',
340 'src/song_paint.c',
341 'src/colors.c',
342 'src/charset.c',
343 'src/wreadln.c',
344 'src/strfsong.c',
345 'src/time_format.c',
346 'src/utils.c',
347 sources,
348 include_directories: inc,
349 dependencies: [
350 glib_dep,
351 curses_dep,
352 lirc_dep,
353 libmpdclient_dep,
354 ],
355 install: true
356 )
358 configure_file(output: 'config.h', configuration: conf)
360 install_man('doc/ncmpc.1')
362 docdir = join_paths(get_option('datadir'), 'doc', meson.project_name())
363 install_data('AUTHORS', 'COPYING', 'NEWS', 'README.rst',
364 'doc/config.sample',
365 'doc/keys.sample',
366 'doc/ncmpc.lirc',
367 install_dir: docdir)
369 if not mini
370 subdir('test')
371 endif
373 if get_option('documentation')
374 doxygen = find_program('doxygen', required: false)
375 if doxygen.found()
376 subdir('doc')
377 endif
378 endif