1ae0b15a97e7e4c7a736e74e1f7a70777979a2e4
1 # Configure fcntl.h.
2 dnl Copyright (C) 2006, 2007, 2009 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
7 dnl Written by Paul Eggert.
9 AC_DEFUN([gl_FCNTL_H],
10 [
11 AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
12 dnl Persuade glibc <fcntl.h> to define O_NOATIME and O_NOFOLLOW.
13 AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
14 AC_CACHE_CHECK([for working fcntl.h], [gl_cv_header_working_fcntl_h],
15 [AC_RUN_IFELSE(
16 [AC_LANG_PROGRAM(
17 [[#include <sys/types.h>
18 #include <sys/stat.h>
19 #include <unistd.h>
20 #include <fcntl.h>
21 #ifndef O_NOATIME
22 #define O_NOATIME 0
23 #endif
24 #ifndef O_NOFOLLOW
25 #define O_NOFOLLOW 0
26 #endif
27 static int const constants[] =
28 {
29 O_CREAT, O_EXCL, O_NOCTTY, O_TRUNC, O_APPEND,
30 O_NONBLOCK, O_SYNC, O_ACCMODE, O_RDONLY, O_RDWR, O_WRONLY
31 };
32 ]],
33 [[
34 int status = !constants;
35 {
36 static char const sym[] = "conftest.sym";
37 if (symlink (".", sym) != 0
38 || close (open (sym, O_RDONLY | O_NOFOLLOW)) == 0)
39 status |= 32;
40 }
41 {
42 static char const file[] = "confdefs.h";
43 int fd = open (file, O_RDONLY | O_NOATIME);
44 char c;
45 struct stat st0, st1;
46 if (fd < 0
47 || fstat (fd, &st0) != 0
48 || sleep (1) != 0
49 || read (fd, &c, 1) != 1
50 || close (fd) != 0
51 || stat (file, &st1) != 0
52 || st0.st_atime != st1.st_atime)
53 status |= 64;
54 }
55 return status;]])],
56 [gl_cv_header_working_fcntl_h=yes],
57 [case $? in #(
58 32) gl_cv_header_working_fcntl_h='no (bad O_NOFOLLOW)';; #(
59 64) gl_cv_header_working_fcntl_h='no (bad O_NOATIME)';; #(
60 96) gl_cv_header_working_fcntl_h='no (bad O_NOATIME, O_NOFOLLOW)';; #(
61 *) gl_cv_header_working_fcntl_h='no';;
62 esac],
63 [gl_cv_header_working_fcntl_h=cross-compiling])])
65 case $gl_cv_header_working_fcntl_h in #(
66 *O_NOATIME* | no | cross-compiling) ac_val=0;; #(
67 *) ac_val=1;;
68 esac
69 AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOATIME], [$ac_val],
70 [Define to 1 if O_NOATIME works.])
72 case $gl_cv_header_working_fcntl_h in #(
73 *O_NOFOLLOW* | no | cross-compiling) ac_val=0;; #(
74 *) ac_val=1;;
75 esac
76 AC_DEFINE_UNQUOTED([HAVE_WORKING_O_NOFOLLOW], [$ac_val],
77 [Define to 1 if O_NOFOLLOW works.])
79 gl_CHECK_NEXT_HEADERS([fcntl.h])
80 FCNTL_H='fcntl.h'
81 AC_SUBST([FCNTL_H])
82 ])
84 AC_DEFUN([gl_FCNTL_MODULE_INDICATOR],
85 [
86 dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
87 AC_REQUIRE([gl_FCNTL_H_DEFAULTS])
88 GNULIB_[]m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])=1
89 ])
91 AC_DEFUN([gl_FCNTL_H_DEFAULTS],
92 [
93 GNULIB_OPEN=0; AC_SUBST([GNULIB_OPEN])
94 dnl Assume proper GNU behavior unless another module says otherwise.
95 REPLACE_OPEN=0; AC_SUBST([REPLACE_OPEN])
96 ])