gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99 # URI of GIT logo (72x27 size)
 100 our $logo = "++GITWEB_LOGO++";
 101 # URI of GIT favicon, assumed to be image/png type
 102 our $favicon = "++GITWEB_FAVICON++";
 103 # URI of gitweb.js (JavaScript code for gitweb)
 104 our $javascript = "++GITWEB_JS++";
 105
 106 # URI and label (title) of GIT logo link
 107 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 108 #our $logo_label = "git documentation";
 109 our $logo_url = "http://git-scm.com/";
 110 our $logo_label = "git homepage";
 111
 112 # source of projects list
 113 our $projects_list = "++GITWEB_LIST++";
 114
 115 # the width (in characters) of the projects list "Description" column
 116 our $projects_list_description_width = 25;
 117
 118 # default order of projects list
 119 # valid values are none, project, descr, owner, and age
 120 our $default_projects_order = "project";
 121
 122 # show repository only if this file exists
 123 # (only effective if this variable evaluates to true)
 124 our $export_ok = "++GITWEB_EXPORT_OK++";
 125
 126 # show repository only if this subroutine returns true
 127 # when given the path to the project, for example:
 128 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 129 our $export_auth_hook = undef;
 130
 131 # only allow viewing of repositories also shown on the overview page
 132 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 133
 134 # list of git base URLs used for URL to where fetch project from,
 135 # i.e. full URL is "$git_base_url/$project"
 136 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 137
 138 # default blob_plain mimetype and default charset for text/plain blob
 139 our $default_blob_plain_mimetype = 'text/plain';
 140 our $default_text_plain_charset  = undef;
 141
 142 # file to use for guessing MIME types before trying /etc/mime.types
 143 # (relative to the current git repository)
 144 our $mimetypes_file = undef;
 145
 146 # assume this charset if line contains non-UTF-8 characters;
 147 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 148 # for which encoding all byte sequences are valid, for example
 149 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 150 # could be even 'utf-8' for the old behavior)
 151 our $fallback_encoding = 'latin1';
 152
 153 # rename detection options for git-diff and git-diff-tree
 154 # - default is '-M', with the cost proportional to
 155 #   (number of removed files) * (number of new files).
 156 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 157 #   (number of changed files + number of removed files) * (number of new files)
 158 # - even more costly is '-C', '--find-copies-harder' with cost
 159 #   (number of files in the original tree) * (number of new files)
 160 # - one might want to include '-B' option, e.g. '-B', '-M'
 161 our @diff_opts = ('-M'); # taken from git_commit
 162
 163 # Disables features that would allow repository owners to inject script into
 164 # the gitweb domain.
 165 our $prevent_xss = 0;
 166
 167 # Path to the highlight executable to use (must be the one from
 168 # http://www.andre-simon.de due to assumptions about parameters and output).
 169 # Useful if highlight is not installed on your webserver's PATH.
 170 # [Default: highlight]
 171 our $highlight_bin = "++HIGHLIGHT_BIN++";
 172
 173 # information about snapshot formats that gitweb is capable of serving
 174 our %known_snapshot_formats = (
 175         # name => {
 176         #       'display' => display name,
 177         #       'type' => mime type,
 178         #       'suffix' => filename suffix,
 179         #       'format' => --format for git-archive,
 180         #       'compressor' => [compressor command and arguments]
 181         #                       (array reference, optional)
 182         #       'disabled' => boolean (optional)}
 183         #
 184         'tgz' => {
 185                 'display' => 'tar.gz',
 186                 'type' => 'application/x-gzip',
 187                 'suffix' => '.tar.gz',
 188                 'format' => 'tar',
 189                 'compressor' => ['gzip']},
 190
 191         'tbz2' => {
 192                 'display' => 'tar.bz2',
 193                 'type' => 'application/x-bzip2',
 194                 'suffix' => '.tar.bz2',
 195                 'format' => 'tar',
 196                 'compressor' => ['bzip2']},
 197
 198         'txz' => {
 199                 'display' => 'tar.xz',
 200                 'type' => 'application/x-xz',
 201                 'suffix' => '.tar.xz',
 202                 'format' => 'tar',
 203                 'compressor' => ['xz'],
 204                 'disabled' => 1},
 205
 206         'zip' => {
 207                 'display' => 'zip',
 208                 'type' => 'application/x-zip',
 209                 'suffix' => '.zip',
 210                 'format' => 'zip'},
 211 );
 212
 213 # Aliases so we understand old gitweb.snapshot values in repository
 214 # configuration.
 215 our %known_snapshot_format_aliases = (
 216         'gzip'  => 'tgz',
 217         'bzip2' => 'tbz2',
 218         'xz'    => 'txz',
 219
 220         # backward compatibility: legacy gitweb config support
 221         'x-gzip' => undef, 'gz' => undef,
 222         'x-bzip2' => undef, 'bz2' => undef,
 223         'x-zip' => undef, '' => undef,
 224 );
 225
 226 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 227 # are changed, it may be appropriate to change these values too via
 228 # $GITWEB_CONFIG.
 229 our %avatar_size = (
 230         'default' => 16,
 231         'double'  => 32
 232 );
 233
 234 # Used to set the maximum load that we will still respond to gitweb queries.
 235 # If server load exceed this value then return "503 server busy" error.
 236 # If gitweb cannot determined server load, it is taken to be 0.
 237 # Leave it undefined (or set to 'undef') to turn off load checking.
 238 our $maxload = 300;
 239
 240 # configuration for 'highlight' (http://www.andre-simon.de/)
 241 # match by basename
 242 our %highlight_basename = (
 243         #'Program' => 'py',
 244         #'Library' => 'py',
 245         'SConstruct' => 'py', # SCons equivalent of Makefile
 246         'Makefile' => 'make',
 247 );
 248 # match by extension
 249 our %highlight_ext = (
 250         # main extensions, defining name of syntax;
 251         # see files in /usr/share/highlight/langDefs/ directory
 252         map { $_ => $_ }
 253                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl),
 254         # alternate extensions, see /etc/highlight/filetypes.conf
 255         'h' => 'c',
 256         map { $_ => 'cpp' } qw(cxx c++ cc),
 257         map { $_ => 'php' } qw(php3 php4),
 258         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 259         'mak' => 'make',
 260         map { $_ => 'xml' } qw(xhtml html htm),
 261 );
 262
 263 # You define site-wide feature defaults here; override them with
 264 # $GITWEB_CONFIG as necessary.
 265 our %feature = (
 266         # feature => {
 267         #       'sub' => feature-sub (subroutine),
 268         #       'override' => allow-override (boolean),
 269         #       'default' => [ default options...] (array reference)}
 270         #
 271         # if feature is overridable (it means that allow-override has true value),
 272         # then feature-sub will be called with default options as parameters;
 273         # return value of feature-sub indicates if to enable specified feature
 274         #
 275         # if there is no 'sub' key (no feature-sub), then feature cannot be
 276         # overridden
 277         #
 278         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 279         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 280         # is enabled
 281
 282         # Enable the 'blame' blob view, showing the last commit that modified
 283         # each line in the file. This can be very CPU-intensive.
 284
 285         # To enable system wide have in $GITWEB_CONFIG
 286         # $feature{'blame'}{'default'} = [1];
 287         # To have project specific config enable override in $GITWEB_CONFIG
 288         # $feature{'blame'}{'override'} = 1;
 289         # and in project config gitweb.blame = 0|1;
 290         'blame' => {
 291                 'sub' => sub { feature_bool('blame', @_) },
 292                 'override' => 0,
 293                 'default' => [0]},
 294
 295         # Enable the 'snapshot' link, providing a compressed archive of any
 296         # tree. This can potentially generate high traffic if you have large
 297         # project.
 298
 299         # Value is a list of formats defined in %known_snapshot_formats that
 300         # you wish to offer.
 301         # To disable system wide have in $GITWEB_CONFIG
 302         # $feature{'snapshot'}{'default'} = [];
 303         # To have project specific config enable override in $GITWEB_CONFIG
 304         # $feature{'snapshot'}{'override'} = 1;
 305         # and in project config, a comma-separated list of formats or "none"
 306         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 307         'snapshot' => {
 308                 'sub' => \&feature_snapshot,
 309                 'override' => 0,
 310                 'default' => ['tgz']},
 311
 312         # Enable text search, which will list the commits which match author,
 313         # committer or commit text to a given string.  Enabled by default.
 314         # Project specific override is not supported.
 315         'search' => {
 316                 'override' => 0,
 317                 'default' => [1]},
 318
 319         # Enable grep search, which will list the files in currently selected
 320         # tree containing the given string. Enabled by default. This can be
 321         # potentially CPU-intensive, of course.
 322
 323         # To enable system wide have in $GITWEB_CONFIG
 324         # $feature{'grep'}{'default'} = [1];
 325         # To have project specific config enable override in $GITWEB_CONFIG
 326         # $feature{'grep'}{'override'} = 1;
 327         # and in project config gitweb.grep = 0|1;
 328         'grep' => {
 329                 'sub' => sub { feature_bool('grep', @_) },
 330                 'override' => 0,
 331                 'default' => [1]},
 332
 333         # Enable the pickaxe search, which will list the commits that modified
 334         # a given string in a file. This can be practical and quite faster
 335         # alternative to 'blame', but still potentially CPU-intensive.
 336
 337         # To enable system wide have in $GITWEB_CONFIG
 338         # $feature{'pickaxe'}{'default'} = [1];
 339         # To have project specific config enable override in $GITWEB_CONFIG
 340         # $feature{'pickaxe'}{'override'} = 1;
 341         # and in project config gitweb.pickaxe = 0|1;
 342         'pickaxe' => {
 343                 'sub' => sub { feature_bool('pickaxe', @_) },
 344                 'override' => 0,
 345                 'default' => [1]},
 346
 347         # Enable showing size of blobs in a 'tree' view, in a separate
 348         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 349
 350         # To disable system wide have in $GITWEB_CONFIG
 351         # $feature{'show-sizes'}{'default'} = [0];
 352         # To have project specific config enable override in $GITWEB_CONFIG
 353         # $feature{'show-sizes'}{'override'} = 1;
 354         # and in project config gitweb.showsizes = 0|1;
 355         'show-sizes' => {
 356                 'sub' => sub { feature_bool('showsizes', @_) },
 357                 'override' => 0,
 358                 'default' => [1]},
 359
 360         # Make gitweb use an alternative format of the URLs which can be
 361         # more readable and natural-looking: project name is embedded
 362         # directly in the path and the query string contains other
 363         # auxiliary information. All gitweb installations recognize
 364         # URL in either format; this configures in which formats gitweb
 365         # generates links.
 366
 367         # To enable system wide have in $GITWEB_CONFIG
 368         # $feature{'pathinfo'}{'default'} = [1];
 369         # Project specific override is not supported.
 370
 371         # Note that you will need to change the default location of CSS,
 372         # favicon, logo and possibly other files to an absolute URL. Also,
 373         # if gitweb.cgi serves as your indexfile, you will need to force
 374         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 375         'pathinfo' => {
 376                 'override' => 0,
 377                 'default' => [0]},
 378
 379         # Make gitweb consider projects in project root subdirectories
 380         # to be forks of existing projects. Given project $projname.git,
 381         # projects matching $projname/*.git will not be shown in the main
 382         # projects list, instead a '+' mark will be added to $projname
 383         # there and a 'forks' view will be enabled for the project, listing
 384         # all the forks. If project list is taken from a file, forks have
 385         # to be listed after the main project.
 386
 387         # To enable system wide have in $GITWEB_CONFIG
 388         # $feature{'forks'}{'default'} = [1];
 389         # Project specific override is not supported.
 390         'forks' => {
 391                 'override' => 0,
 392                 'default' => [0]},
 393
 394         # Insert custom links to the action bar of all project pages.
 395         # This enables you mainly to link to third-party scripts integrating
 396         # into gitweb; e.g. git-browser for graphical history representation
 397         # or custom web-based repository administration interface.
 398
 399         # The 'default' value consists of a list of triplets in the form
 400         # (label, link, position) where position is the label after which
 401         # to insert the link and link is a format string where %n expands
 402         # to the project name, %f to the project path within the filesystem,
 403         # %h to the current hash (h gitweb parameter) and %b to the current
 404         # hash base (hb gitweb parameter); %% expands to %.
 405
 406         # To enable system wide have in $GITWEB_CONFIG e.g.
 407         # $feature{'actions'}{'default'} = [('graphiclog',
 408         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 409         # Project specific override is not supported.
 410         'actions' => {
 411                 'override' => 0,
 412                 'default' => []},
 413
 414         # Allow gitweb scan project content tags described in ctags/
 415         # of project repository, and display the popular Web 2.0-ish
 416         # "tag cloud" near the project list. Note that this is something
 417         # COMPLETELY different from the normal Git tags.
 418
 419         # gitweb by itself can show existing tags, but it does not handle
 420         # tagging itself; you need an external application for that.
 421         # For an example script, check Girocco's cgi/tagproj.cgi.
 422         # You may want to install the HTML::TagCloud Perl module to get
 423         # a pretty tag cloud instead of just a list of tags.
 424
 425         # To enable system wide have in $GITWEB_CONFIG
 426         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 427         # Project specific override is not supported.
 428         'ctags' => {
 429                 'override' => 0,
 430                 'default' => [0]},
 431
 432         # The maximum number of patches in a patchset generated in patch
 433         # view. Set this to 0 or undef to disable patch view, or to a
 434         # negative number to remove any limit.
 435
 436         # To disable system wide have in $GITWEB_CONFIG
 437         # $feature{'patches'}{'default'} = [0];
 438         # To have project specific config enable override in $GITWEB_CONFIG
 439         # $feature{'patches'}{'override'} = 1;
 440         # and in project config gitweb.patches = 0|n;
 441         # where n is the maximum number of patches allowed in a patchset.
 442         'patches' => {
 443                 'sub' => \&feature_patches,
 444                 'override' => 0,
 445                 'default' => [16]},
 446
 447         # Avatar support. When this feature is enabled, views such as
 448         # shortlog or commit will display an avatar associated with
 449         # the email of the committer(s) and/or author(s).
 450
 451         # Currently available providers are gravatar and picon.
 452         # If an unknown provider is specified, the feature is disabled.
 453
 454         # Gravatar depends on Digest::MD5.
 455         # Picon currently relies on the indiana.edu database.
 456
 457         # To enable system wide have in $GITWEB_CONFIG
 458         # $feature{'avatar'}{'default'} = ['<provider>'];
 459         # where <provider> is either gravatar or picon.
 460         # To have project specific config enable override in $GITWEB_CONFIG
 461         # $feature{'avatar'}{'override'} = 1;
 462         # and in project config gitweb.avatar = <provider>;
 463         'avatar' => {
 464                 'sub' => \&feature_avatar,
 465                 'override' => 0,
 466                 'default' => ['']},
 467
 468         # Enable displaying how much time and how many git commands
 469         # it took to generate and display page.  Disabled by default.
 470         # Project specific override is not supported.
 471         'timed' => {
 472                 'override' => 0,
 473                 'default' => [0]},
 474
 475         # Enable turning some links into links to actions which require
 476         # JavaScript to run (like 'blame_incremental').  Not enabled by
 477         # default.  Project specific override is currently not supported.
 478         'javascript-actions' => {
 479                 'override' => 0,
 480                 'default' => [0]},
 481
 482         # Syntax highlighting support. This is based on Daniel Svensson's
 483         # and Sham Chukoury's work in gitweb-xmms2.git.
 484         # It requires the 'highlight' program present in $PATH,
 485         # and therefore is disabled by default.
 486
 487         # To enable system wide have in $GITWEB_CONFIG
 488         # $feature{'highlight'}{'default'} = [1];
 489
 490         'highlight' => {
 491                 'sub' => sub { feature_bool('highlight', @_) },
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable displaying of remote heads in the heads list
 496
 497         # To enable system wide have in $GITWEB_CONFIG
 498         # $feature{'remote_heads'}{'default'} = [1];
 499         # To have project specific config enable override in $GITWEB_CONFIG
 500         # $feature{'remote_heads'}{'override'} = 1;
 501         # and in project config gitweb.remote_heads = 0|1;
 502         'remote_heads' => {
 503                 'sub' => sub { feature_bool('remote_heads', @_) },
 504                 'override' => 0,
 505                 'default' => [0]},
 506 );
 507
 508 sub gitweb_get_feature {
 509         my ($name) = @_;
 510         return unless exists $feature{$name};
 511         my ($sub, $override, @defaults) = (
 512                 $feature{$name}{'sub'},
 513                 $feature{$name}{'override'},
 514                 @{$feature{$name}{'default'}});
 515         # project specific override is possible only if we have project
 516         our $git_dir; # global variable, declared later
 517         if (!$override || !defined $git_dir) {
 518                 return @defaults;
 519         }
 520         if (!defined $sub) {
 521                 warn "feature $name is not overridable";
 522                 return @defaults;
 523         }
 524         return $sub->(@defaults);
 525 }
 526
 527 # A wrapper to check if a given feature is enabled.
 528 # With this, you can say
 529 #
 530 #   my $bool_feat = gitweb_check_feature('bool_feat');
 531 #   gitweb_check_feature('bool_feat') or somecode;
 532 #
 533 # instead of
 534 #
 535 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 536 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 537 #
 538 sub gitweb_check_feature {
 539         return (gitweb_get_feature(@_))[0];
 540 }
 541
 542
 543 sub feature_bool {
 544         my $key = shift;
 545         my ($val) = git_get_project_config($key, '--bool');
 546
 547         if (!defined $val) {
 548                 return ($_[0]);
 549         } elsif ($val eq 'true') {
 550                 return (1);
 551         } elsif ($val eq 'false') {
 552                 return (0);
 553         }
 554 }
 555
 556 sub feature_snapshot {
 557         my (@fmts) = @_;
 558
 559         my ($val) = git_get_project_config('snapshot');
 560
 561         if ($val) {
 562                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 563         }
 564
 565         return @fmts;
 566 }
 567
 568 sub feature_patches {
 569         my @val = (git_get_project_config('patches', '--int'));
 570
 571         if (@val) {
 572                 return @val;
 573         }
 574
 575         return ($_[0]);
 576 }
 577
 578 sub feature_avatar {
 579         my @val = (git_get_project_config('avatar'));
 580
 581         return @val ? @val : @_;
 582 }
 583
 584 # checking HEAD file with -e is fragile if the repository was
 585 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 586 # and then pruned.
 587 sub check_head_link {
 588         my ($dir) = @_;
 589         my $headfile = "$dir/HEAD";
 590         return ((-e $headfile) ||
 591                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 592 }
 593
 594 sub check_export_ok {
 595         my ($dir) = @_;
 596         return (check_head_link($dir) &&
 597                 (!$export_ok || -e "$dir/$export_ok") &&
 598                 (!$export_auth_hook || $export_auth_hook->($dir)));
 599 }
 600
 601 # process alternate names for backward compatibility
 602 # filter out unsupported (unknown) snapshot formats
 603 sub filter_snapshot_fmts {
 604         my @fmts = @_;
 605
 606         @fmts = map {
 607                 exists $known_snapshot_format_aliases{$_} ?
 608                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 609         @fmts = grep {
 610                 exists $known_snapshot_formats{$_} &&
 611                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 612 }
 613
 614 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 615 sub evaluate_gitweb_config {
 616         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 617         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 618         # die if there are errors parsing config file
 619         if (-e $GITWEB_CONFIG) {
 620                 do $GITWEB_CONFIG;
 621                 die $@ if $@;
 622         } elsif (-e $GITWEB_CONFIG_SYSTEM) {
 623                 do $GITWEB_CONFIG_SYSTEM;
 624                 die $@ if $@;
 625         }
 626 }
 627
 628 # Get loadavg of system, to compare against $maxload.
 629 # Currently it requires '/proc/loadavg' present to get loadavg;
 630 # if it is not present it returns 0, which means no load checking.
 631 sub get_loadavg {
 632         if( -e '/proc/loadavg' ){
 633                 open my $fd, '<', '/proc/loadavg'
 634                         or return 0;
 635                 my @load = split(/\s+/, scalar <$fd>);
 636                 close $fd;
 637
 638                 # The first three columns measure CPU and IO utilization of the last one,
 639                 # five, and 10 minute periods.  The fourth column shows the number of
 640                 # currently running processes and the total number of processes in the m/n
 641                 # format.  The last column displays the last process ID used.
 642                 return $load[0] || 0;
 643         }
 644         # additional checks for load average should go here for things that don't export
 645         # /proc/loadavg
 646
 647         return 0;
 648 }
 649
 650 # version of the core git binary
 651 our $git_version;
 652 sub evaluate_git_version {
 653         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 654         $number_of_git_cmds++;
 655 }
 656
 657 sub check_loadavg {
 658         if (defined $maxload && get_loadavg() > $maxload) {
 659                 die_error(503, "The load average on the server is too high");
 660         }
 661 }
 662
 663 # ======================================================================
 664 # input validation and dispatch
 665
 666 # input parameters can be collected from a variety of sources (presently, CGI
 667 # and PATH_INFO), so we define an %input_params hash that collects them all
 668 # together during validation: this allows subsequent uses (e.g. href()) to be
 669 # agnostic of the parameter origin
 670
 671 our %input_params = ();
 672
 673 # input parameters are stored with the long parameter name as key. This will
 674 # also be used in the href subroutine to convert parameters to their CGI
 675 # equivalent, and since the href() usage is the most frequent one, we store
 676 # the name -> CGI key mapping here, instead of the reverse.
 677 #
 678 # XXX: Warning: If you touch this, check the search form for updating,
 679 # too.
 680
 681 our @cgi_param_mapping = (
 682         project => "p",
 683         action => "a",
 684         file_name => "f",
 685         file_parent => "fp",
 686         hash => "h",
 687         hash_parent => "hp",
 688         hash_base => "hb",
 689         hash_parent_base => "hpb",
 690         page => "pg",
 691         order => "o",
 692         searchtext => "s",
 693         searchtype => "st",
 694         snapshot_format => "sf",
 695         extra_options => "opt",
 696         search_use_regexp => "sr",
 697         # this must be last entry (for manipulation from JavaScript)
 698         javascript => "js"
 699 );
 700 our %cgi_param_mapping = @cgi_param_mapping;
 701
 702 # we will also need to know the possible actions, for validation
 703 our %actions = (
 704         "blame" => \&git_blame,
 705         "blame_incremental" => \&git_blame_incremental,
 706         "blame_data" => \&git_blame_data,
 707         "blobdiff" => \&git_blobdiff,
 708         "blobdiff_plain" => \&git_blobdiff_plain,
 709         "blob" => \&git_blob,
 710         "blob_plain" => \&git_blob_plain,
 711         "commitdiff" => \&git_commitdiff,
 712         "commitdiff_plain" => \&git_commitdiff_plain,
 713         "commit" => \&git_commit,
 714         "forks" => \&git_forks,
 715         "heads" => \&git_heads,
 716         "history" => \&git_history,
 717         "log" => \&git_log,
 718         "patch" => \&git_patch,
 719         "patches" => \&git_patches,
 720         "remotes" => \&git_remotes,
 721         "rss" => \&git_rss,
 722         "atom" => \&git_atom,
 723         "search" => \&git_search,
 724         "search_help" => \&git_search_help,
 725         "shortlog" => \&git_shortlog,
 726         "summary" => \&git_summary,
 727         "tag" => \&git_tag,
 728         "tags" => \&git_tags,
 729         "tree" => \&git_tree,
 730         "snapshot" => \&git_snapshot,
 731         "object" => \&git_object,
 732         # those below don't need $project
 733         "opml" => \&git_opml,
 734         "project_list" => \&git_project_list,
 735         "project_index" => \&git_project_index,
 736 );
 737
 738 # finally, we have the hash of allowed extra_options for the commands that
 739 # allow them
 740 our %allowed_options = (
 741         "--no-merges" => [ qw(rss atom log shortlog history) ],
 742 );
 743
 744 # fill %input_params with the CGI parameters. All values except for 'opt'
 745 # should be single values, but opt can be an array. We should probably
 746 # build an array of parameters that can be multi-valued, but since for the time
 747 # being it's only this one, we just single it out
 748 sub evaluate_query_params {
 749         our $cgi;
 750
 751         while (my ($name, $symbol) = each %cgi_param_mapping) {
 752                 if ($symbol eq 'opt') {
 753                         $input_params{$name} = [ $cgi->param($symbol) ];
 754                 } else {
 755                         $input_params{$name} = $cgi->param($symbol);
 756                 }
 757         }
 758 }
 759
 760 # now read PATH_INFO and update the parameter list for missing parameters
 761 sub evaluate_path_info {
 762         return if defined $input_params{'project'};
 763         return if !$path_info;
 764         $path_info =~ s,^/+,,;
 765         return if !$path_info;
 766
 767         # find which part of PATH_INFO is project
 768         my $project = $path_info;
 769         $project =~ s,/+$,,;
 770         while ($project && !check_head_link("$projectroot/$project")) {
 771                 $project =~ s,/*[^/]*$,,;
 772         }
 773         return unless $project;
 774         $input_params{'project'} = $project;
 775
 776         # do not change any parameters if an action is given using the query string
 777         return if $input_params{'action'};
 778         $path_info =~ s,^\Q$project\E/*,,;
 779
 780         # next, check if we have an action
 781         my $action = $path_info;
 782         $action =~ s,/.*$,,;
 783         if (exists $actions{$action}) {
 784                 $path_info =~ s,^$action/*,,;
 785                 $input_params{'action'} = $action;
 786         }
 787
 788         # list of actions that want hash_base instead of hash, but can have no
 789         # pathname (f) parameter
 790         my @wants_base = (
 791                 'tree',
 792                 'history',
 793         );
 794
 795         # we want to catch, among others
 796         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 797         my ($parentrefname, $parentpathname, $refname, $pathname) =
 798                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 799
 800         # first, analyze the 'current' part
 801         if (defined $pathname) {
 802                 # we got "branch:filename" or "branch:dir/"
 803                 # we could use git_get_type(branch:pathname), but:
 804                 # - it needs $git_dir
 805                 # - it does a git() call
 806                 # - the convention of terminating directories with a slash
 807                 #   makes it superfluous
 808                 # - embedding the action in the PATH_INFO would make it even
 809                 #   more superfluous
 810                 $pathname =~ s,^/+,,;
 811                 if (!$pathname || substr($pathname, -1) eq "/") {
 812                         $input_params{'action'} ||= "tree";
 813                         $pathname =~ s,/$,,;
 814                 } else {
 815                         # the default action depends on whether we had parent info
 816                         # or not
 817                         if ($parentrefname) {
 818                                 $input_params{'action'} ||= "blobdiff_plain";
 819                         } else {
 820                                 $input_params{'action'} ||= "blob_plain";
 821                         }
 822                 }
 823                 $input_params{'hash_base'} ||= $refname;
 824                 $input_params{'file_name'} ||= $pathname;
 825         } elsif (defined $refname) {
 826                 # we got "branch". In this case we have to choose if we have to
 827                 # set hash or hash_base.
 828                 #
 829                 # Most of the actions without a pathname only want hash to be
 830                 # set, except for the ones specified in @wants_base that want
 831                 # hash_base instead. It should also be noted that hand-crafted
 832                 # links having 'history' as an action and no pathname or hash
 833                 # set will fail, but that happens regardless of PATH_INFO.
 834                 if (defined $parentrefname) {
 835                         # if there is parent let the default be 'shortlog' action
 836                         # (for http://git.example.com/repo.git/A..B links); if there
 837                         # is no parent, dispatch will detect type of object and set
 838                         # action appropriately if required (if action is not set)
 839                         $input_params{'action'} ||= "shortlog";
 840                 }
 841                 if ($input_params{'action'} &&
 842                     grep { $_ eq $input_params{'action'} } @wants_base) {
 843                         $input_params{'hash_base'} ||= $refname;
 844                 } else {
 845                         $input_params{'hash'} ||= $refname;
 846                 }
 847         }
 848
 849         # next, handle the 'parent' part, if present
 850         if (defined $parentrefname) {
 851                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 852                 # someproject/blobdiff/oldrev..newrev:/filename
 853                 if ($parentpathname) {
 854                         $parentpathname =~ s,^/+,,;
 855                         $parentpathname =~ s,/$,,;
 856                         $input_params{'file_parent'} ||= $parentpathname;
 857                 } else {
 858                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 859                 }
 860                 # we assume that hash_parent_base is wanted if a path was specified,
 861                 # or if the action wants hash_base instead of hash
 862                 if (defined $input_params{'file_parent'} ||
 863                         grep { $_ eq $input_params{'action'} } @wants_base) {
 864                         $input_params{'hash_parent_base'} ||= $parentrefname;
 865                 } else {
 866                         $input_params{'hash_parent'} ||= $parentrefname;
 867                 }
 868         }
 869
 870         # for the snapshot action, we allow URLs in the form
 871         # $project/snapshot/$hash.ext
 872         # where .ext determines the snapshot and gets removed from the
 873         # passed $refname to provide the $hash.
 874         #
 875         # To be able to tell that $refname includes the format extension, we
 876         # require the following two conditions to be satisfied:
 877         # - the hash input parameter MUST have been set from the $refname part
 878         #   of the URL (i.e. they must be equal)
 879         # - the snapshot format MUST NOT have been defined already (e.g. from
 880         #   CGI parameter sf)
 881         # It's also useless to try any matching unless $refname has a dot,
 882         # so we check for that too
 883         if (defined $input_params{'action'} &&
 884                 $input_params{'action'} eq 'snapshot' &&
 885                 defined $refname && index($refname, '.') != -1 &&
 886                 $refname eq $input_params{'hash'} &&
 887                 !defined $input_params{'snapshot_format'}) {
 888                 # We loop over the known snapshot formats, checking for
 889                 # extensions. Allowed extensions are both the defined suffix
 890                 # (which includes the initial dot already) and the snapshot
 891                 # format key itself, with a prepended dot
 892                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 893                         my $hash = $refname;
 894                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 895                                 next;
 896                         }
 897                         my $sfx = $1;
 898                         # a valid suffix was found, so set the snapshot format
 899                         # and reset the hash parameter
 900                         $input_params{'snapshot_format'} = $fmt;
 901                         $input_params{'hash'} = $hash;
 902                         # we also set the format suffix to the one requested
 903                         # in the URL: this way a request for e.g. .tgz returns
 904                         # a .tgz instead of a .tar.gz
 905                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 906                         last;
 907                 }
 908         }
 909 }
 910
 911 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 912      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 913      $searchtext, $search_regexp);
 914 sub evaluate_and_validate_params {
 915         our $action = $input_params{'action'};
 916         if (defined $action) {
 917                 if (!validate_action($action)) {
 918                         die_error(400, "Invalid action parameter");
 919                 }
 920         }
 921
 922         # parameters which are pathnames
 923         our $project = $input_params{'project'};
 924         if (defined $project) {
 925                 if (!validate_project($project)) {
 926                         undef $project;
 927                         die_error(404, "No such project");
 928                 }
 929         }
 930
 931         our $file_name = $input_params{'file_name'};
 932         if (defined $file_name) {
 933                 if (!validate_pathname($file_name)) {
 934                         die_error(400, "Invalid file parameter");
 935                 }
 936         }
 937
 938         our $file_parent = $input_params{'file_parent'};
 939         if (defined $file_parent) {
 940                 if (!validate_pathname($file_parent)) {
 941                         die_error(400, "Invalid file parent parameter");
 942                 }
 943         }
 944
 945         # parameters which are refnames
 946         our $hash = $input_params{'hash'};
 947         if (defined $hash) {
 948                 if (!validate_refname($hash)) {
 949                         die_error(400, "Invalid hash parameter");
 950                 }
 951         }
 952
 953         our $hash_parent = $input_params{'hash_parent'};
 954         if (defined $hash_parent) {
 955                 if (!validate_refname($hash_parent)) {
 956                         die_error(400, "Invalid hash parent parameter");
 957                 }
 958         }
 959
 960         our $hash_base = $input_params{'hash_base'};
 961         if (defined $hash_base) {
 962                 if (!validate_refname($hash_base)) {
 963                         die_error(400, "Invalid hash base parameter");
 964                 }
 965         }
 966
 967         our @extra_options = @{$input_params{'extra_options'}};
 968         # @extra_options is always defined, since it can only be (currently) set from
 969         # CGI, and $cgi->param() returns the empty array in array context if the param
 970         # is not set
 971         foreach my $opt (@extra_options) {
 972                 if (not exists $allowed_options{$opt}) {
 973                         die_error(400, "Invalid option parameter");
 974                 }
 975                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 976                         die_error(400, "Invalid option parameter for this action");
 977                 }
 978         }
 979
 980         our $hash_parent_base = $input_params{'hash_parent_base'};
 981         if (defined $hash_parent_base) {
 982                 if (!validate_refname($hash_parent_base)) {
 983                         die_error(400, "Invalid hash parent base parameter");
 984                 }
 985         }
 986
 987         # other parameters
 988         our $page = $input_params{'page'};
 989         if (defined $page) {
 990                 if ($page =~ m/[^0-9]/) {
 991                         die_error(400, "Invalid page parameter");
 992                 }
 993         }
 994
 995         our $searchtype = $input_params{'searchtype'};
 996         if (defined $searchtype) {
 997                 if ($searchtype =~ m/[^a-z]/) {
 998                         die_error(400, "Invalid searchtype parameter");
 999                 }
1000         }
1001
1002         our $search_use_regexp = $input_params{'search_use_regexp'};
1003
1004         our $searchtext = $input_params{'searchtext'};
1005         our $search_regexp;
1006         if (defined $searchtext) {
1007                 if (length($searchtext) < 2) {
1008                         die_error(403, "At least two characters are required for search parameter");
1009                 }
1010                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1011         }
1012 }
1013
1014 # path to the current git repository
1015 our $git_dir;
1016 sub evaluate_git_dir {
1017         our $git_dir = "$projectroot/$project" if $project;
1018 }
1019
1020 our (@snapshot_fmts, $git_avatar);
1021 sub configure_gitweb_features {
1022         # list of supported snapshot formats
1023         our @snapshot_fmts = gitweb_get_feature('snapshot');
1024         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1025
1026         # check that the avatar feature is set to a known provider name,
1027         # and for each provider check if the dependencies are satisfied.
1028         # if the provider name is invalid or the dependencies are not met,
1029         # reset $git_avatar to the empty string.
1030         our ($git_avatar) = gitweb_get_feature('avatar');
1031         if ($git_avatar eq 'gravatar') {
1032                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1033         } elsif ($git_avatar eq 'picon') {
1034                 # no dependencies
1035         } else {
1036                 $git_avatar = '';
1037         }
1038 }
1039
1040 # custom error handler: 'die <message>' is Internal Server Error
1041 sub handle_errors_html {
1042         my $msg = shift; # it is already HTML escaped
1043
1044         # to avoid infinite loop where error occurs in die_error,
1045         # change handler to default handler, disabling handle_errors_html
1046         set_message("Error occured when inside die_error:\n$msg");
1047
1048         # you cannot jump out of die_error when called as error handler;
1049         # the subroutine set via CGI::Carp::set_message is called _after_
1050         # HTTP headers are already written, so it cannot write them itself
1051         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1052 }
1053 set_message(\&handle_errors_html);
1054
1055 # dispatch
1056 sub dispatch {
1057         if (!defined $action) {
1058                 if (defined $hash) {
1059                         $action = git_get_type($hash);
1060                 } elsif (defined $hash_base && defined $file_name) {
1061                         $action = git_get_type("$hash_base:$file_name");
1062                 } elsif (defined $project) {
1063                         $action = 'summary';
1064                 } else {
1065                         $action = 'project_list';
1066                 }
1067         }
1068         if (!defined($actions{$action})) {
1069                 die_error(400, "Unknown action");
1070         }
1071         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1072             !$project) {
1073                 die_error(400, "Project needed");
1074         }
1075         $actions{$action}->();
1076 }
1077
1078 sub reset_timer {
1079         our $t0 = [ gettimeofday() ]
1080                 if defined $t0;
1081         our $number_of_git_cmds = 0;
1082 }
1083
1084 sub run_request {
1085         reset_timer();
1086
1087         evaluate_uri();
1088         evaluate_gitweb_config();
1089         evaluate_git_version();
1090         check_loadavg();
1091
1092         # $projectroot and $projects_list might be set in gitweb config file
1093         $projects_list ||= $projectroot;
1094
1095         evaluate_query_params();
1096         evaluate_path_info();
1097         evaluate_and_validate_params();
1098         evaluate_git_dir();
1099
1100         configure_gitweb_features();
1101
1102         dispatch();
1103 }
1104
1105 our $is_last_request = sub { 1 };
1106 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1107 our $CGI = 'CGI';
1108 our $cgi;
1109 sub configure_as_fcgi {
1110         require CGI::Fast;
1111         our $CGI = 'CGI::Fast';
1112
1113         my $request_number = 0;
1114         # let each child service 100 requests
1115         our $is_last_request = sub { ++$request_number > 100 };
1116 }
1117 sub evaluate_argv {
1118         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1119         configure_as_fcgi()
1120                 if $script_name =~ /\.fcgi$/;
1121
1122         return unless (@ARGV);
1123
1124         require Getopt::Long;
1125         Getopt::Long::GetOptions(
1126                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1127                 'nproc|n=i' => sub {
1128                         my ($arg, $val) = @_;
1129                         return unless eval { require FCGI::ProcManager; 1; };
1130                         my $proc_manager = FCGI::ProcManager->new({
1131                                 n_processes => $val,
1132                         });
1133                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1134                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1135                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1136                 },
1137         );
1138 }
1139
1140 sub run {
1141         evaluate_argv();
1142
1143         $pre_listen_hook->()
1144                 if $pre_listen_hook;
1145
1146  REQUEST:
1147         while ($cgi = $CGI->new()) {
1148                 $pre_dispatch_hook->()
1149                         if $pre_dispatch_hook;
1150
1151                 run_request();
1152
1153                 $post_dispatch_hook->()
1154                         if $post_dispatch_hook;
1155
1156                 last REQUEST if ($is_last_request->());
1157         }
1158
1159  DONE_GITWEB:
1160         1;
1161 }
1162
1163 run();
1164
1165 if (defined caller) {
1166         # wrapped in a subroutine processing requests,
1167         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1168         return;
1169 } else {
1170         # pure CGI script, serving single request
1171         exit;
1172 }
1173
1174 ## ======================================================================
1175 ## action links
1176
1177 # possible values of extra options
1178 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1179 # -replay => 1      - start from a current view (replay with modifications)
1180 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1181 sub href {
1182         my %params = @_;
1183         # default is to use -absolute url() i.e. $my_uri
1184         my $href = $params{-full} ? $my_url : $my_uri;
1185
1186         $params{'project'} = $project unless exists $params{'project'};
1187
1188         if ($params{-replay}) {
1189                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1190                         if (!exists $params{$name}) {
1191                                 $params{$name} = $input_params{$name};
1192                         }
1193                 }
1194         }
1195
1196         my $use_pathinfo = gitweb_check_feature('pathinfo');
1197         if (defined $params{'project'} &&
1198             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1199                 # try to put as many parameters as possible in PATH_INFO:
1200                 #   - project name
1201                 #   - action
1202                 #   - hash_parent or hash_parent_base:/file_parent
1203                 #   - hash or hash_base:/filename
1204                 #   - the snapshot_format as an appropriate suffix
1205
1206                 # When the script is the root DirectoryIndex for the domain,
1207                 # $href here would be something like http://gitweb.example.com/
1208                 # Thus, we strip any trailing / from $href, to spare us double
1209                 # slashes in the final URL
1210                 $href =~ s,/$,,;
1211
1212                 # Then add the project name, if present
1213                 $href .= "/".esc_url($params{'project'});
1214                 delete $params{'project'};
1215
1216                 # since we destructively absorb parameters, we keep this
1217                 # boolean that remembers if we're handling a snapshot
1218                 my $is_snapshot = $params{'action'} eq 'snapshot';
1219
1220                 # Summary just uses the project path URL, any other action is
1221                 # added to the URL
1222                 if (defined $params{'action'}) {
1223                         $href .= "/".esc_url($params{'action'}) unless $params{'action'} eq 'summary';
1224                         delete $params{'action'};
1225                 }
1226
1227                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1228                 # stripping nonexistent or useless pieces
1229                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1230                         || $params{'hash_parent'} || $params{'hash'});
1231                 if (defined $params{'hash_base'}) {
1232                         if (defined $params{'hash_parent_base'}) {
1233                                 $href .= esc_url($params{'hash_parent_base'});
1234                                 # skip the file_parent if it's the same as the file_name
1235                                 if (defined $params{'file_parent'}) {
1236                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1237                                                 delete $params{'file_parent'};
1238                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1239                                                 $href .= ":/".esc_url($params{'file_parent'});
1240                                                 delete $params{'file_parent'};
1241                                         }
1242                                 }
1243                                 $href .= "..";
1244                                 delete $params{'hash_parent'};
1245                                 delete $params{'hash_parent_base'};
1246                         } elsif (defined $params{'hash_parent'}) {
1247                                 $href .= esc_url($params{'hash_parent'}). "..";
1248                                 delete $params{'hash_parent'};
1249                         }
1250
1251                         $href .= esc_url($params{'hash_base'});
1252                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1253                                 $href .= ":/".esc_url($params{'file_name'});
1254                                 delete $params{'file_name'};
1255                         }
1256                         delete $params{'hash'};
1257                         delete $params{'hash_base'};
1258                 } elsif (defined $params{'hash'}) {
1259                         $href .= esc_url($params{'hash'});
1260                         delete $params{'hash'};
1261                 }
1262
1263                 # If the action was a snapshot, we can absorb the
1264                 # snapshot_format parameter too
1265                 if ($is_snapshot) {
1266                         my $fmt = $params{'snapshot_format'};
1267                         # snapshot_format should always be defined when href()
1268                         # is called, but just in case some code forgets, we
1269                         # fall back to the default
1270                         $fmt ||= $snapshot_fmts[0];
1271                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1272                         delete $params{'snapshot_format'};
1273                 }
1274         }
1275
1276         # now encode the parameters explicitly
1277         my @result = ();
1278         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1279                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1280                 if (defined $params{$name}) {
1281                         if (ref($params{$name}) eq "ARRAY") {
1282                                 foreach my $par (@{$params{$name}}) {
1283                                         push @result, $symbol . "=" . esc_param($par);
1284                                 }
1285                         } else {
1286                                 push @result, $symbol . "=" . esc_param($params{$name});
1287                         }
1288                 }
1289         }
1290         $href .= "?" . join(';', @result) if scalar @result;
1291
1292         return $href;
1293 }
1294
1295
1296 ## ======================================================================
1297 ## validation, quoting/unquoting and escaping
1298
1299 sub validate_action {
1300         my $input = shift || return undef;
1301         return undef unless exists $actions{$input};
1302         return $input;
1303 }
1304
1305 sub validate_project {
1306         my $input = shift || return undef;
1307         if (!validate_pathname($input) ||
1308                 !(-d "$projectroot/$input") ||
1309                 !check_export_ok("$projectroot/$input") ||
1310                 ($strict_export && !project_in_list($input))) {
1311                 return undef;
1312         } else {
1313                 return $input;
1314         }
1315 }
1316
1317 sub validate_pathname {
1318         my $input = shift || return undef;
1319
1320         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1321         # at the beginning, at the end, and between slashes.
1322         # also this catches doubled slashes
1323         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1324                 return undef;
1325         }
1326         # no null characters
1327         if ($input =~ m!\0!) {
1328                 return undef;
1329         }
1330         return $input;
1331 }
1332
1333 sub validate_refname {
1334         my $input = shift || return undef;
1335
1336         # textual hashes are O.K.
1337         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1338                 return $input;
1339         }
1340         # it must be correct pathname
1341         $input = validate_pathname($input)
1342                 or return undef;
1343         # restrictions on ref name according to git-check-ref-format
1344         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1345                 return undef;
1346         }
1347         return $input;
1348 }
1349
1350 # decode sequences of octets in utf8 into Perl's internal form,
1351 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1352 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1353 sub to_utf8 {
1354         my $str = shift;
1355         return undef unless defined $str;
1356         if (utf8::valid($str)) {
1357                 utf8::decode($str);
1358                 return $str;
1359         } else {
1360                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1361         }
1362 }
1363
1364 # quote unsafe chars, but keep the slash, even when it's not
1365 # correct, but quoted slashes look too horrible in bookmarks
1366 sub esc_param {
1367         my $str = shift;
1368         return undef unless defined $str;
1369         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1370         $str =~ s/ /\+/g;
1371         return $str;
1372 }
1373
1374 # quote unsafe chars in whole URL, so some characters cannot be quoted
1375 sub esc_url {
1376         my $str = shift;
1377         return undef unless defined $str;
1378         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1379         $str =~ s/ /\+/g;
1380         return $str;
1381 }
1382
1383 # replace invalid utf8 character with SUBSTITUTION sequence
1384 sub esc_html {
1385         my $str = shift;
1386         my %opts = @_;
1387
1388         return undef unless defined $str;
1389
1390         $str = to_utf8($str);
1391         $str = $cgi->escapeHTML($str);
1392         if ($opts{'-nbsp'}) {
1393                 $str =~ s/ /&nbsp;/g;
1394         }
1395         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1396         return $str;
1397 }
1398
1399 # quote control characters and escape filename to HTML
1400 sub esc_path {
1401         my $str = shift;
1402         my %opts = @_;
1403
1404         return undef unless defined $str;
1405
1406         $str = to_utf8($str);
1407         $str = $cgi->escapeHTML($str);
1408         if ($opts{'-nbsp'}) {
1409                 $str =~ s/ /&nbsp;/g;
1410         }
1411         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1412         return $str;
1413 }
1414
1415 # Make control characters "printable", using character escape codes (CEC)
1416 sub quot_cec {
1417         my $cntrl = shift;
1418         my %opts = @_;
1419         my %es = ( # character escape codes, aka escape sequences
1420                 "\t" => '\t',   # tab            (HT)
1421                 "\n" => '\n',   # line feed      (LF)
1422                 "\r" => '\r',   # carrige return (CR)
1423                 "\f" => '\f',   # form feed      (FF)
1424                 "\b" => '\b',   # backspace      (BS)
1425                 "\a" => '\a',   # alarm (bell)   (BEL)
1426                 "\e" => '\e',   # escape         (ESC)
1427                 "\013" => '\v', # vertical tab   (VT)
1428                 "\000" => '\0', # nul character  (NUL)
1429         );
1430         my $chr = ( (exists $es{$cntrl})
1431                     ? $es{$cntrl}
1432                     : sprintf('\%2x', ord($cntrl)) );
1433         if ($opts{-nohtml}) {
1434                 return $chr;
1435         } else {
1436                 return "<span class=\"cntrl\">$chr</span>";
1437         }
1438 }
1439
1440 # Alternatively use unicode control pictures codepoints,
1441 # Unicode "printable representation" (PR)
1442 sub quot_upr {
1443         my $cntrl = shift;
1444         my %opts = @_;
1445
1446         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1447         if ($opts{-nohtml}) {
1448                 return $chr;
1449         } else {
1450                 return "<span class=\"cntrl\">$chr</span>";
1451         }
1452 }
1453
1454 # git may return quoted and escaped filenames
1455 sub unquote {
1456         my $str = shift;
1457
1458         sub unq {
1459                 my $seq = shift;
1460                 my %es = ( # character escape codes, aka escape sequences
1461                         't' => "\t",   # tab            (HT, TAB)
1462                         'n' => "\n",   # newline        (NL)
1463                         'r' => "\r",   # return         (CR)
1464                         'f' => "\f",   # form feed      (FF)
1465                         'b' => "\b",   # backspace      (BS)
1466                         'a' => "\a",   # alarm (bell)   (BEL)
1467                         'e' => "\e",   # escape         (ESC)
1468                         'v' => "\013", # vertical tab   (VT)
1469                 );
1470
1471                 if ($seq =~ m/^[0-7]{1,3}$/) {
1472                         # octal char sequence
1473                         return chr(oct($seq));
1474                 } elsif (exists $es{$seq}) {
1475                         # C escape sequence, aka character escape code
1476                         return $es{$seq};
1477                 }
1478                 # quoted ordinary character
1479                 return $seq;
1480         }
1481
1482         if ($str =~ m/^"(.*)"$/) {
1483                 # needs unquoting
1484                 $str = $1;
1485                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1486         }
1487         return $str;
1488 }
1489
1490 # escape tabs (convert tabs to spaces)
1491 sub untabify {
1492         my $line = shift;
1493
1494         while ((my $pos = index($line, "\t")) != -1) {
1495                 if (my $count = (8 - ($pos % 8))) {
1496                         my $spaces = ' ' x $count;
1497                         $line =~ s/\t/$spaces/;
1498                 }
1499         }
1500
1501         return $line;
1502 }
1503
1504 sub project_in_list {
1505         my $project = shift;
1506         my @list = git_get_projects_list();
1507         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1508 }
1509
1510 ## ----------------------------------------------------------------------
1511 ## HTML aware string manipulation
1512
1513 # Try to chop given string on a word boundary between position
1514 # $len and $len+$add_len. If there is no word boundary there,
1515 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1516 # (marking chopped part) would be longer than given string.
1517 sub chop_str {
1518         my $str = shift;
1519         my $len = shift;
1520         my $add_len = shift || 10;
1521         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1522
1523         # Make sure perl knows it is utf8 encoded so we don't
1524         # cut in the middle of a utf8 multibyte char.
1525         $str = to_utf8($str);
1526
1527         # allow only $len chars, but don't cut a word if it would fit in $add_len
1528         # if it doesn't fit, cut it if it's still longer than the dots we would add
1529         # remove chopped character entities entirely
1530
1531         # when chopping in the middle, distribute $len into left and right part
1532         # return early if chopping wouldn't make string shorter
1533         if ($where eq 'center') {
1534                 return $str if ($len + 5 >= length($str)); # filler is length 5
1535                 $len = int($len/2);
1536         } else {
1537                 return $str if ($len + 4 >= length($str)); # filler is length 4
1538         }
1539
1540         # regexps: ending and beginning with word part up to $add_len
1541         my $endre = qr/.{$len}\w{0,$add_len}/;
1542         my $begre = qr/\w{0,$add_len}.{$len}/;
1543
1544         if ($where eq 'left') {
1545                 $str =~ m/^(.*?)($begre)$/;
1546                 my ($lead, $body) = ($1, $2);
1547                 if (length($lead) > 4) {
1548                         $lead = " ...";
1549                 }
1550                 return "$lead$body";
1551
1552         } elsif ($where eq 'center') {
1553                 $str =~ m/^($endre)(.*)$/;
1554                 my ($left, $str)  = ($1, $2);
1555                 $str =~ m/^(.*?)($begre)$/;
1556                 my ($mid, $right) = ($1, $2);
1557                 if (length($mid) > 5) {
1558                         $mid = " ... ";
1559                 }
1560                 return "$left$mid$right";
1561
1562         } else {
1563                 $str =~ m/^($endre)(.*)$/;
1564                 my $body = $1;
1565                 my $tail = $2;
1566                 if (length($tail) > 4) {
1567                         $tail = "... ";
1568                 }
1569                 return "$body$tail";
1570         }
1571 }
1572
1573 # takes the same arguments as chop_str, but also wraps a <span> around the
1574 # result with a title attribute if it does get chopped. Additionally, the
1575 # string is HTML-escaped.
1576 sub chop_and_escape_str {
1577         my ($str) = @_;
1578
1579         my $chopped = chop_str(@_);
1580         if ($chopped eq $str) {
1581                 return esc_html($chopped);
1582         } else {
1583                 $str =~ s/[[:cntrl:]]/?/g;
1584                 return $cgi->span({-title=>$str}, esc_html($chopped));
1585         }
1586 }
1587
1588 ## ----------------------------------------------------------------------
1589 ## functions returning short strings
1590
1591 # CSS class for given age value (in seconds)
1592 sub age_class {
1593         my $age = shift;
1594
1595         if (!defined $age) {
1596                 return "noage";
1597         } elsif ($age < 60*60*2) {
1598                 return "age0";
1599         } elsif ($age < 60*60*24*2) {
1600                 return "age1";
1601         } else {
1602                 return "age2";
1603         }
1604 }
1605
1606 # convert age in seconds to "nn units ago" string
1607 sub age_string {
1608         my $age = shift;
1609         my $age_str;
1610
1611         if ($age > 60*60*24*365*2) {
1612                 $age_str = (int $age/60/60/24/365);
1613                 $age_str .= " years ago";
1614         } elsif ($age > 60*60*24*(365/12)*2) {
1615                 $age_str = int $age/60/60/24/(365/12);
1616                 $age_str .= " months ago";
1617         } elsif ($age > 60*60*24*7*2) {
1618                 $age_str = int $age/60/60/24/7;
1619                 $age_str .= " weeks ago";
1620         } elsif ($age > 60*60*24*2) {
1621                 $age_str = int $age/60/60/24;
1622                 $age_str .= " days ago";
1623         } elsif ($age > 60*60*2) {
1624                 $age_str = int $age/60/60;
1625                 $age_str .= " hours ago";
1626         } elsif ($age > 60*2) {
1627                 $age_str = int $age/60;
1628                 $age_str .= " min ago";
1629         } elsif ($age > 2) {
1630                 $age_str = int $age;
1631                 $age_str .= " sec ago";
1632         } else {
1633                 $age_str .= " right now";
1634         }
1635         return $age_str;
1636 }
1637
1638 use constant {
1639         S_IFINVALID => 0030000,
1640         S_IFGITLINK => 0160000,
1641 };
1642
1643 # submodule/subproject, a commit object reference
1644 sub S_ISGITLINK {
1645         my $mode = shift;
1646
1647         return (($mode & S_IFMT) == S_IFGITLINK)
1648 }
1649
1650 # convert file mode in octal to symbolic file mode string
1651 sub mode_str {
1652         my $mode = oct shift;
1653
1654         if (S_ISGITLINK($mode)) {
1655                 return 'm---------';
1656         } elsif (S_ISDIR($mode & S_IFMT)) {
1657                 return 'drwxr-xr-x';
1658         } elsif (S_ISLNK($mode)) {
1659                 return 'lrwxrwxrwx';
1660         } elsif (S_ISREG($mode)) {
1661                 # git cares only about the executable bit
1662                 if ($mode & S_IXUSR) {
1663                         return '-rwxr-xr-x';
1664                 } else {
1665                         return '-rw-r--r--';
1666                 };
1667         } else {
1668                 return '----------';
1669         }
1670 }
1671
1672 # convert file mode in octal to file type string
1673 sub file_type {
1674         my $mode = shift;
1675
1676         if ($mode !~ m/^[0-7]+$/) {
1677                 return $mode;
1678         } else {
1679                 $mode = oct $mode;
1680         }
1681
1682         if (S_ISGITLINK($mode)) {
1683                 return "submodule";
1684         } elsif (S_ISDIR($mode & S_IFMT)) {
1685                 return "directory";
1686         } elsif (S_ISLNK($mode)) {
1687                 return "symlink";
1688         } elsif (S_ISREG($mode)) {
1689                 return "file";
1690         } else {
1691                 return "unknown";
1692         }
1693 }
1694
1695 # convert file mode in octal to file type description string
1696 sub file_type_long {
1697         my $mode = shift;
1698
1699         if ($mode !~ m/^[0-7]+$/) {
1700                 return $mode;
1701         } else {
1702                 $mode = oct $mode;
1703         }
1704
1705         if (S_ISGITLINK($mode)) {
1706                 return "submodule";
1707         } elsif (S_ISDIR($mode & S_IFMT)) {
1708                 return "directory";
1709         } elsif (S_ISLNK($mode)) {
1710                 return "symlink";
1711         } elsif (S_ISREG($mode)) {
1712                 if ($mode & S_IXUSR) {
1713                         return "executable";
1714                 } else {
1715                         return "file";
1716                 };
1717         } else {
1718                 return "unknown";
1719         }
1720 }
1721
1722
1723 ## ----------------------------------------------------------------------
1724 ## functions returning short HTML fragments, or transforming HTML fragments
1725 ## which don't belong to other sections
1726
1727 # format line of commit message.
1728 sub format_log_line_html {
1729         my $line = shift;
1730
1731         $line = esc_html($line, -nbsp=>1);
1732         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1733                 $cgi->a({-href => href(action=>"object", hash=>$1),
1734                                         -class => "text"}, $1);
1735         }eg;
1736
1737         return $line;
1738 }
1739
1740 # format marker of refs pointing to given object
1741
1742 # the destination action is chosen based on object type and current context:
1743 # - for annotated tags, we choose the tag view unless it's the current view
1744 #   already, in which case we go to shortlog view
1745 # - for other refs, we keep the current view if we're in history, shortlog or
1746 #   log view, and select shortlog otherwise
1747 sub format_ref_marker {
1748         my ($refs, $id) = @_;
1749         my $markers = '';
1750
1751         if (defined $refs->{$id}) {
1752                 foreach my $ref (@{$refs->{$id}}) {
1753                         # this code exploits the fact that non-lightweight tags are the
1754                         # only indirect objects, and that they are the only objects for which
1755                         # we want to use tag instead of shortlog as action
1756                         my ($type, $name) = qw();
1757                         my $indirect = ($ref =~ s/\^\{\}$//);
1758                         # e.g. tags/v2.6.11 or heads/next
1759                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1760                                 $type = $1;
1761                                 $name = $2;
1762                         } else {
1763                                 $type = "ref";
1764                                 $name = $ref;
1765                         }
1766
1767                         my $class = $type;
1768                         $class .= " indirect" if $indirect;
1769
1770                         my $dest_action = "shortlog";
1771
1772                         if ($indirect) {
1773                                 $dest_action = "tag" unless $action eq "tag";
1774                         } elsif ($action =~ /^(history|(short)?log)$/) {
1775                                 $dest_action = $action;
1776                         }
1777
1778                         my $dest = "";
1779                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1780                         $dest .= $ref;
1781
1782                         my $link = $cgi->a({
1783                                 -href => href(
1784                                         action=>$dest_action,
1785                                         hash=>$dest
1786                                 )}, $name);
1787
1788                         $markers .= " <span class=\"$class\" title=\"$ref\">" .
1789                                 $link . "</span>";
1790                 }
1791         }
1792
1793         if ($markers) {
1794                 return ' <span class="refs">'. $markers . '</span>';
1795         } else {
1796                 return "";
1797         }
1798 }
1799
1800 # format, perhaps shortened and with markers, title line
1801 sub format_subject_html {
1802         my ($long, $short, $href, $extra) = @_;
1803         $extra = '' unless defined($extra);
1804
1805         if (length($short) < length($long)) {
1806                 $long =~ s/[[:cntrl:]]/?/g;
1807                 return $cgi->a({-href => $href, -class => "list subject",
1808                                 -title => to_utf8($long)},
1809                        esc_html($short)) . $extra;
1810         } else {
1811                 return $cgi->a({-href => $href, -class => "list subject"},
1812                        esc_html($long)) . $extra;
1813         }
1814 }
1815
1816 # Rather than recomputing the url for an email multiple times, we cache it
1817 # after the first hit. This gives a visible benefit in views where the avatar
1818 # for the same email is used repeatedly (e.g. shortlog).
1819 # The cache is shared by all avatar engines (currently gravatar only), which
1820 # are free to use it as preferred. Since only one avatar engine is used for any
1821 # given page, there's no risk for cache conflicts.
1822 our %avatar_cache = ();
1823
1824 # Compute the picon url for a given email, by using the picon search service over at
1825 # http://www.cs.indiana.edu/picons/search.html
1826 sub picon_url {
1827         my $email = lc shift;
1828         if (!$avatar_cache{$email}) {
1829                 my ($user, $domain) = split('@', $email);
1830                 $avatar_cache{$email} =
1831                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1832                         "$domain/$user/" .
1833                         "users+domains+unknown/up/single";
1834         }
1835         return $avatar_cache{$email};
1836 }
1837
1838 # Compute the gravatar url for a given email, if it's not in the cache already.
1839 # Gravatar stores only the part of the URL before the size, since that's the
1840 # one computationally more expensive. This also allows reuse of the cache for
1841 # different sizes (for this particular engine).
1842 sub gravatar_url {
1843         my $email = lc shift;
1844         my $size = shift;
1845         $avatar_cache{$email} ||=
1846                 "http://www.gravatar.com/avatar/" .
1847                         Digest::MD5::md5_hex($email) . "?s=";
1848         return $avatar_cache{$email} . $size;
1849 }
1850
1851 # Insert an avatar for the given $email at the given $size if the feature
1852 # is enabled.
1853 sub git_get_avatar {
1854         my ($email, %opts) = @_;
1855         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1856         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1857         $opts{-size} ||= 'default';
1858         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1859         my $url = "";
1860         if ($git_avatar eq 'gravatar') {
1861                 $url = gravatar_url($email, $size);
1862         } elsif ($git_avatar eq 'picon') {
1863                 $url = picon_url($email);
1864         }
1865         # Other providers can be added by extending the if chain, defining $url
1866         # as needed. If no variant puts something in $url, we assume avatars
1867         # are completely disabled/unavailable.
1868         if ($url) {
1869                 return $pre_white .
1870                        "<img width=\"$size\" " .
1871                             "class=\"avatar\" " .
1872                             "src=\"$url\" " .
1873                             "alt=\"\" " .
1874                        "/>" . $post_white;
1875         } else {
1876                 return "";
1877         }
1878 }
1879
1880 sub format_search_author {
1881         my ($author, $searchtype, $displaytext) = @_;
1882         my $have_search = gitweb_check_feature('search');
1883
1884         if ($have_search) {
1885                 my $performed = "";
1886                 if ($searchtype eq 'author') {
1887                         $performed = "authored";
1888                 } elsif ($searchtype eq 'committer') {
1889                         $performed = "committed";
1890                 }
1891
1892                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1893                                 searchtext=>$author,
1894                                 searchtype=>$searchtype), class=>"list",
1895                                 title=>"Search for commits $performed by $author"},
1896                                 $displaytext);
1897
1898         } else {
1899                 return $displaytext;
1900         }
1901 }
1902
1903 # format the author name of the given commit with the given tag
1904 # the author name is chopped and escaped according to the other
1905 # optional parameters (see chop_str).
1906 sub format_author_html {
1907         my $tag = shift;
1908         my $co = shift;
1909         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1910         return "<$tag class=\"author\">" .
1911                format_search_author($co->{'author_name'}, "author",
1912                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1913                        $author) .
1914                "</$tag>";
1915 }
1916
1917 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1918 sub format_git_diff_header_line {
1919         my $line = shift;
1920         my $diffinfo = shift;
1921         my ($from, $to) = @_;
1922
1923         if ($diffinfo->{'nparents'}) {
1924                 # combined diff
1925                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1926                 if ($to->{'href'}) {
1927                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1928                                          esc_path($to->{'file'}));
1929                 } else { # file was deleted (no href)
1930                         $line .= esc_path($to->{'file'});
1931                 }
1932         } else {
1933                 # "ordinary" diff
1934                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1935                 if ($from->{'href'}) {
1936                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1937                                          'a/' . esc_path($from->{'file'}));
1938                 } else { # file was added (no href)
1939                         $line .= 'a/' . esc_path($from->{'file'});
1940                 }
1941                 $line .= ' ';
1942                 if ($to->{'href'}) {
1943                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1944                                          'b/' . esc_path($to->{'file'}));
1945                 } else { # file was deleted
1946                         $line .= 'b/' . esc_path($to->{'file'});
1947                 }
1948         }
1949
1950         return "<div class=\"diff header\">$line</div>\n";
1951 }
1952
1953 # format extended diff header line, before patch itself
1954 sub format_extended_diff_header_line {
1955         my $line = shift;
1956         my $diffinfo = shift;
1957         my ($from, $to) = @_;
1958
1959         # match <path>
1960         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1961                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1962                                        esc_path($from->{'file'}));
1963         }
1964         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1965                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1966                                  esc_path($to->{'file'}));
1967         }
1968         # match single <mode>
1969         if ($line =~ m/\s(\d{6})$/) {
1970                 $line .= '<span class="info"> (' .
1971                          file_type_long($1) .
1972                          ')</span>';
1973         }
1974         # match <hash>
1975         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1976                 # can match only for combined diff
1977                 $line = 'index ';
1978                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1979                         if ($from->{'href'}[$i]) {
1980                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1981                                                   -class=>"hash"},
1982                                                  substr($diffinfo->{'from_id'}[$i],0,7));
1983                         } else {
1984                                 $line .= '0' x 7;
1985                         }
1986                         # separator
1987                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1988                 }
1989                 $line .= '..';
1990                 if ($to->{'href'}) {
1991                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1992                                          substr($diffinfo->{'to_id'},0,7));
1993                 } else {
1994                         $line .= '0' x 7;
1995                 }
1996
1997         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1998                 # can match only for ordinary diff
1999                 my ($from_link, $to_link);
2000                 if ($from->{'href'}) {
2001                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2002                                              substr($diffinfo->{'from_id'},0,7));
2003                 } else {
2004                         $from_link = '0' x 7;
2005                 }
2006                 if ($to->{'href'}) {
2007                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2008                                            substr($diffinfo->{'to_id'},0,7));
2009                 } else {
2010                         $to_link = '0' x 7;
2011                 }
2012                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2013                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2014         }
2015
2016         return $line . "<br/>\n";
2017 }
2018
2019 # format from-file/to-file diff header
2020 sub format_diff_from_to_header {
2021         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2022         my $line;
2023         my $result = '';
2024
2025         $line = $from_line;
2026         #assert($line =~ m/^---/) if DEBUG;
2027         # no extra formatting for "^--- /dev/null"
2028         if (! $diffinfo->{'nparents'}) {
2029                 # ordinary (single parent) diff
2030                 if ($line =~ m!^--- "?a/!) {
2031                         if ($from->{'href'}) {
2032                                 $line = '--- a/' .
2033                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2034                                                 esc_path($from->{'file'}));
2035                         } else {
2036                                 $line = '--- a/' .
2037                                         esc_path($from->{'file'});
2038                         }
2039                 }
2040                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2041
2042         } else {
2043                 # combined diff (merge commit)
2044                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2045                         if ($from->{'href'}[$i]) {
2046                                 $line = '--- ' .
2047                                         $cgi->a({-href=>href(action=>"blobdiff",
2048                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2049                                                              hash_parent_base=>$parents[$i],
2050                                                              file_parent=>$from->{'file'}[$i],
2051                                                              hash=>$diffinfo->{'to_id'},
2052                                                              hash_base=>$hash,
2053                                                              file_name=>$to->{'file'}),
2054                                                  -class=>"path",
2055                                                  -title=>"diff" . ($i+1)},
2056                                                 $i+1) .
2057                                         '/' .
2058                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2059                                                 esc_path($from->{'file'}[$i]));
2060                         } else {
2061                                 $line = '--- /dev/null';
2062                         }
2063                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2064                 }
2065         }
2066
2067         $line = $to_line;
2068         #assert($line =~ m/^\+\+\+/) if DEBUG;
2069         # no extra formatting for "^+++ /dev/null"
2070         if ($line =~ m!^\+\+\+ "?b/!) {
2071                 if ($to->{'href'}) {
2072                         $line = '+++ b/' .
2073                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2074                                         esc_path($to->{'file'}));
2075                 } else {
2076                         $line = '+++ b/' .
2077                                 esc_path($to->{'file'});
2078                 }
2079         }
2080         $result .= qq!<div class="diff to_file">$line</div>\n!;
2081
2082         return $result;
2083 }
2084
2085 # create note for patch simplified by combined diff
2086 sub format_diff_cc_simplified {
2087         my ($diffinfo, @parents) = @_;
2088         my $result = '';
2089
2090         $result .= "<div class=\"diff header\">" .
2091                    "diff --cc ";
2092         if (!is_deleted($diffinfo)) {
2093                 $result .= $cgi->a({-href => href(action=>"blob",
2094                                                   hash_base=>$hash,
2095                                                   hash=>$diffinfo->{'to_id'},
2096                                                   file_name=>$diffinfo->{'to_file'}),
2097                                     -class => "path"},
2098                                    esc_path($diffinfo->{'to_file'}));
2099         } else {
2100                 $result .= esc_path($diffinfo->{'to_file'});
2101         }
2102         $result .= "</div>\n" . # class="diff header"
2103                    "<div class=\"diff nodifferences\">" .
2104                    "Simple merge" .
2105                    "</div>\n"; # class="diff nodifferences"
2106
2107         return $result;
2108 }
2109
2110 # format patch (diff) line (not to be used for diff headers)
2111 sub format_diff_line {
2112         my $line = shift;
2113         my ($from, $to) = @_;
2114         my $diff_class = "";
2115
2116         chomp $line;
2117
2118         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2119                 # combined diff
2120                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2121                 if ($line =~ m/^\@{3}/) {
2122                         $diff_class = " chunk_header";
2123                 } elsif ($line =~ m/^\\/) {
2124                         $diff_class = " incomplete";
2125                 } elsif ($prefix =~ tr/+/+/) {
2126                         $diff_class = " add";
2127                 } elsif ($prefix =~ tr/-/-/) {
2128                         $diff_class = " rem";
2129                 }
2130         } else {
2131                 # assume ordinary diff
2132                 my $char = substr($line, 0, 1);
2133                 if ($char eq '+') {
2134                         $diff_class = " add";
2135                 } elsif ($char eq '-') {
2136                         $diff_class = " rem";
2137                 } elsif ($char eq '@') {
2138                         $diff_class = " chunk_header";
2139                 } elsif ($char eq "\\") {
2140                         $diff_class = " incomplete";
2141                 }
2142         }
2143         $line = untabify($line);
2144         if ($from && $to && $line =~ m/^\@{2} /) {
2145                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2146                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2147
2148                 $from_lines = 0 unless defined $from_lines;
2149                 $to_lines   = 0 unless defined $to_lines;
2150
2151                 if ($from->{'href'}) {
2152                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2153                                              -class=>"list"}, $from_text);
2154                 }
2155                 if ($to->{'href'}) {
2156                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2157                                              -class=>"list"}, $to_text);
2158                 }
2159                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2160                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2161                 return "<div class=\"diff$diff_class\">$line</div>\n";
2162         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2163                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2164                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2165
2166                 @from_text = split(' ', $ranges);
2167                 for (my $i = 0; $i < @from_text; ++$i) {
2168                         ($from_start[$i], $from_nlines[$i]) =
2169                                 (split(',', substr($from_text[$i], 1)), 0);
2170                 }
2171
2172                 $to_text   = pop @from_text;
2173                 $to_start  = pop @from_start;
2174                 $to_nlines = pop @from_nlines;
2175
2176                 $line = "<span class=\"chunk_info\">$prefix ";
2177                 for (my $i = 0; $i < @from_text; ++$i) {
2178                         if ($from->{'href'}[$i]) {
2179                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2180                                                   -class=>"list"}, $from_text[$i]);
2181                         } else {
2182                                 $line .= $from_text[$i];
2183                         }
2184                         $line .= " ";
2185                 }
2186                 if ($to->{'href'}) {
2187                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2188                                           -class=>"list"}, $to_text);
2189                 } else {
2190                         $line .= $to_text;
2191                 }
2192                 $line .= " $prefix</span>" .
2193                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2194                 return "<div class=\"diff$diff_class\">$line</div>\n";
2195         }
2196         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2197 }
2198
2199 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2200 # linked.  Pass the hash of the tree/commit to snapshot.
2201 sub format_snapshot_links {
2202         my ($hash) = @_;
2203         my $num_fmts = @snapshot_fmts;
2204         if ($num_fmts > 1) {
2205                 # A parenthesized list of links bearing format names.
2206                 # e.g. "snapshot (_tar.gz_ _zip_)"
2207                 return "snapshot (" . join(' ', map
2208                         $cgi->a({
2209                                 -href => href(
2210                                         action=>"snapshot",
2211                                         hash=>$hash,
2212                                         snapshot_format=>$_
2213                                 )
2214                         }, $known_snapshot_formats{$_}{'display'})
2215                 , @snapshot_fmts) . ")";
2216         } elsif ($num_fmts == 1) {
2217                 # A single "snapshot" link whose tooltip bears the format name.
2218                 # i.e. "_snapshot_"
2219                 my ($fmt) = @snapshot_fmts;
2220                 return
2221                         $cgi->a({
2222                                 -href => href(
2223                                         action=>"snapshot",
2224                                         hash=>$hash,
2225                                         snapshot_format=>$fmt
2226                                 ),
2227                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2228                         }, "snapshot");
2229         } else { # $num_fmts == 0
2230                 return undef;
2231         }
2232 }
2233
2234 ## ......................................................................
2235 ## functions returning values to be passed, perhaps after some
2236 ## transformation, to other functions; e.g. returning arguments to href()
2237
2238 # returns hash to be passed to href to generate gitweb URL
2239 # in -title key it returns description of link
2240 sub get_feed_info {
2241         my $format = shift || 'Atom';
2242         my %res = (action => lc($format));
2243
2244         # feed links are possible only for project views
2245         return unless (defined $project);
2246         # some views should link to OPML, or to generic project feed,
2247         # or don't have specific feed yet (so they should use generic)
2248         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2249
2250         my $branch;
2251         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2252         # from tag links; this also makes possible to detect branch links
2253         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2254             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2255                 $branch = $1;
2256         }
2257         # find log type for feed description (title)
2258         my $type = 'log';
2259         if (defined $file_name) {
2260                 $type  = "history of $file_name";
2261                 $type .= "/" if ($action eq 'tree');
2262                 $type .= " on '$branch'" if (defined $branch);
2263         } else {
2264                 $type = "log of $branch" if (defined $branch);
2265         }
2266
2267         $res{-title} = $type;
2268         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2269         $res{'file_name'} = $file_name;
2270
2271         return %res;
2272 }
2273
2274 ## ----------------------------------------------------------------------
2275 ## git utility subroutines, invoking git commands
2276
2277 # returns path to the core git executable and the --git-dir parameter as list
2278 sub git_cmd {
2279         $number_of_git_cmds++;
2280         return $GIT, '--git-dir='.$git_dir;
2281 }
2282
2283 # quote the given arguments for passing them to the shell
2284 # quote_command("command", "arg 1", "arg with ' and ! characters")
2285 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2286 # Try to avoid using this function wherever possible.
2287 sub quote_command {
2288         return join(' ',
2289                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2290 }
2291
2292 # get HEAD ref of given project as hash
2293 sub git_get_head_hash {
2294         return git_get_full_hash(shift, 'HEAD');
2295 }
2296
2297 sub git_get_full_hash {
2298         return git_get_hash(@_);
2299 }
2300
2301 sub git_get_short_hash {
2302         return git_get_hash(@_, '--short=7');
2303 }
2304
2305 sub git_get_hash {
2306         my ($project, $hash, @options) = @_;
2307         my $o_git_dir = $git_dir;
2308         my $retval = undef;
2309         $git_dir = "$projectroot/$project";
2310         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2311             '--verify', '-q', @options, $hash) {
2312                 $retval = <$fd>;
2313                 chomp $retval if defined $retval;
2314                 close $fd;
2315         }
2316         if (defined $o_git_dir) {
2317                 $git_dir = $o_git_dir;
2318         }
2319         return $retval;
2320 }
2321
2322 # get type of given object
2323 sub git_get_type {
2324         my $hash = shift;
2325
2326         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2327         my $type = <$fd>;
2328         close $fd or return;
2329         chomp $type;
2330         return $type;
2331 }
2332
2333 # repository configuration
2334 our $config_file = '';
2335 our %config;
2336
2337 # store multiple values for single key as anonymous array reference
2338 # single values stored directly in the hash, not as [ <value> ]
2339 sub hash_set_multi {
2340         my ($hash, $key, $value) = @_;
2341
2342         if (!exists $hash->{$key}) {
2343                 $hash->{$key} = $value;
2344         } elsif (!ref $hash->{$key}) {
2345                 $hash->{$key} = [ $hash->{$key}, $value ];
2346         } else {
2347                 push @{$hash->{$key}}, $value;
2348         }
2349 }
2350
2351 # return hash of git project configuration
2352 # optionally limited to some section, e.g. 'gitweb'
2353 sub git_parse_project_config {
2354         my $section_regexp = shift;
2355         my %config;
2356
2357         local $/ = "\0";
2358
2359         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2360                 or return;
2361
2362         while (my $keyval = <$fh>) {
2363                 chomp $keyval;
2364                 my ($key, $value) = split(/\n/, $keyval, 2);
2365
2366                 hash_set_multi(\%config, $key, $value)
2367                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2368         }
2369         close $fh;
2370
2371         return %config;
2372 }
2373
2374 # convert config value to boolean: 'true' or 'false'
2375 # no value, number > 0, 'true' and 'yes' values are true
2376 # rest of values are treated as false (never as error)
2377 sub config_to_bool {
2378         my $val = shift;
2379
2380         return 1 if !defined $val;             # section.key
2381
2382         # strip leading and trailing whitespace
2383         $val =~ s/^\s+//;
2384         $val =~ s/\s+$//;
2385
2386         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2387                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2388 }
2389
2390 # convert config value to simple decimal number
2391 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2392 # to be multiplied by 1024, 1048576, or 1073741824
2393 sub config_to_int {
2394         my $val = shift;
2395
2396         # strip leading and trailing whitespace
2397         $val =~ s/^\s+//;
2398         $val =~ s/\s+$//;
2399
2400         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2401                 $unit = lc($unit);
2402                 # unknown unit is treated as 1
2403                 return $num * ($unit eq 'g' ? 1073741824 :
2404                                $unit eq 'm' ?    1048576 :
2405                                $unit eq 'k' ?       1024 : 1);
2406         }
2407         return $val;
2408 }
2409
2410 # convert config value to array reference, if needed
2411 sub config_to_multi {
2412         my $val = shift;
2413
2414         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2415 }
2416
2417 sub git_get_project_config {
2418         my ($key, $type) = @_;
2419
2420         return unless defined $git_dir;
2421
2422         # key sanity check
2423         return unless ($key);
2424         $key =~ s/^gitweb\.//;
2425         return if ($key =~ m/\W/);
2426
2427         # type sanity check
2428         if (defined $type) {
2429                 $type =~ s/^--//;
2430                 $type = undef
2431                         unless ($type eq 'bool' || $type eq 'int');
2432         }
2433
2434         # get config
2435         if (!defined $config_file ||
2436             $config_file ne "$git_dir/config") {
2437                 %config = git_parse_project_config('gitweb');
2438                 $config_file = "$git_dir/config";
2439         }
2440
2441         # check if config variable (key) exists
2442         return unless exists $config{"gitweb.$key"};
2443
2444         # ensure given type
2445         if (!defined $type) {
2446                 return $config{"gitweb.$key"};
2447         } elsif ($type eq 'bool') {
2448                 # backward compatibility: 'git config --bool' returns true/false
2449                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2450         } elsif ($type eq 'int') {
2451                 return config_to_int($config{"gitweb.$key"});
2452         }
2453         return $config{"gitweb.$key"};
2454 }
2455
2456 # get hash of given path at given ref
2457 sub git_get_hash_by_path {
2458         my $base = shift;
2459         my $path = shift || return undef;
2460         my $type = shift;
2461
2462         $path =~ s,/+$,,;
2463
2464         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2465                 or die_error(500, "Open git-ls-tree failed");
2466         my $line = <$fd>;
2467         close $fd or return undef;
2468
2469         if (!defined $line) {
2470                 # there is no tree or hash given by $path at $base
2471                 return undef;
2472         }
2473
2474         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2475         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2476         if (defined $type && $type ne $2) {
2477                 # type doesn't match
2478                 return undef;
2479         }
2480         return $3;
2481 }
2482
2483 # get path of entry with given hash at given tree-ish (ref)
2484 # used to get 'from' filename for combined diff (merge commit) for renames
2485 sub git_get_path_by_hash {
2486         my $base = shift || return;
2487         my $hash = shift || return;
2488
2489         local $/ = "\0";
2490
2491         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2492                 or return undef;
2493         while (my $line = <$fd>) {
2494                 chomp $line;
2495
2496                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2497                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2498                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2499                         close $fd;
2500                         return $1;
2501                 }
2502         }
2503         close $fd;
2504         return undef;
2505 }
2506
2507 ## ......................................................................
2508 ## git utility functions, directly accessing git repository
2509
2510 sub git_get_project_description {
2511         my $path = shift;
2512
2513         $git_dir = "$projectroot/$path";
2514         open my $fd, '<', "$git_dir/description"
2515                 or return git_get_project_config('description');
2516         my $descr = <$fd>;
2517         close $fd;
2518         if (defined $descr) {
2519                 chomp $descr;
2520         }
2521         return $descr;
2522 }
2523
2524 sub git_get_project_ctags {
2525         my $path = shift;
2526         my $ctags = {};
2527
2528         $git_dir = "$projectroot/$path";
2529         opendir my $dh, "$git_dir/ctags"
2530                 or return $ctags;
2531         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2532                 open my $ct, '<', $_ or next;
2533                 my $val = <$ct>;
2534                 chomp $val;
2535                 close $ct;
2536                 my $ctag = $_; $ctag =~ s#.*/##;
2537                 $ctags->{$ctag} = $val;
2538         }
2539         closedir $dh;
2540         $ctags;
2541 }
2542
2543 sub git_populate_project_tagcloud {
2544         my $ctags = shift;
2545
2546         # First, merge different-cased tags; tags vote on casing
2547         my %ctags_lc;
2548         foreach (keys %$ctags) {
2549                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2550                 if (not $ctags_lc{lc $_}->{topcount}
2551                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2552                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2553                         $ctags_lc{lc $_}->{topname} = $_;
2554                 }
2555         }
2556
2557         my $cloud;
2558         if (eval { require HTML::TagCloud; 1; }) {
2559                 $cloud = HTML::TagCloud->new;
2560                 foreach (sort keys %ctags_lc) {
2561                         # Pad the title with spaces so that the cloud looks
2562                         # less crammed.
2563                         my $title = $ctags_lc{$_}->{topname};
2564                         $title =~ s/ /&nbsp;/g;
2565                         $title =~ s/^/&nbsp;/g;
2566                         $title =~ s/$/&nbsp;/g;
2567                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2568                 }
2569         } else {
2570                 $cloud = \%ctags_lc;
2571         }
2572         $cloud;
2573 }
2574
2575 sub git_show_project_tagcloud {
2576         my ($cloud, $count) = @_;
2577         print STDERR ref($cloud)."..\n";
2578         if (ref $cloud eq 'HTML::TagCloud') {
2579                 return $cloud->html_and_css($count);
2580         } else {
2581                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2582                 return '<p align="center">' . join (', ', map {
2583                         "<a href=\"$home_link?by_tag=$_\">$cloud->{$_}->{topname}</a>"
2584                 } splice(@tags, 0, $count)) . '</p>';
2585         }
2586 }
2587
2588 sub git_get_project_url_list {
2589         my $path = shift;
2590
2591         $git_dir = "$projectroot/$path";
2592         open my $fd, '<', "$git_dir/cloneurl"
2593                 or return wantarray ?
2594                 @{ config_to_multi(git_get_project_config('url')) } :
2595                    config_to_multi(git_get_project_config('url'));
2596         my @git_project_url_list = map { chomp; $_ } <$fd>;
2597         close $fd;
2598
2599         return wantarray ? @git_project_url_list : \@git_project_url_list;
2600 }
2601
2602 sub git_get_projects_list {
2603         my ($filter) = @_;
2604         my @list;
2605
2606         $filter ||= '';
2607         $filter =~ s/\.git$//;
2608
2609         my $check_forks = gitweb_check_feature('forks');
2610
2611         if (-d $projects_list) {
2612                 # search in directory
2613                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2614                 # remove the trailing "/"
2615                 $dir =~ s!/+$!!;
2616                 my $pfxlen = length("$dir");
2617                 my $pfxdepth = ($dir =~ tr!/!!);
2618
2619                 File::Find::find({
2620                         follow_fast => 1, # follow symbolic links
2621                         follow_skip => 2, # ignore duplicates
2622                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2623                         wanted => sub {
2624                                 # global variables
2625                                 our $project_maxdepth;
2626                                 our $projectroot;
2627                                 # skip project-list toplevel, if we get it.
2628                                 return if (m!^[/.]$!);
2629                                 # only directories can be git repositories
2630                                 return unless (-d $_);
2631                                 # don't traverse too deep (Find is super slow on os x)
2632                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2633                                         $File::Find::prune = 1;
2634                                         return;
2635                                 }
2636
2637                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2638                                 # we check related file in $projectroot
2639                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2640                                 if (check_export_ok("$projectroot/$path")) {
2641                                         push @list, { path => $path };
2642                                         $File::Find::prune = 1;
2643                                 }
2644                         },
2645                 }, "$dir");
2646
2647         } elsif (-f $projects_list) {
2648                 # read from file(url-encoded):
2649                 # 'git%2Fgit.git Linus+Torvalds'
2650                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2651                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2652                 my %paths;
2653                 open my $fd, '<', $projects_list or return;
2654         PROJECT:
2655                 while (my $line = <$fd>) {
2656                         chomp $line;
2657                         my ($path, $owner) = split ' ', $line;
2658                         $path = unescape($path);
2659                         $owner = unescape($owner);
2660                         if (!defined $path) {
2661                                 next;
2662                         }
2663                         if ($filter ne '') {
2664                                 # looking for forks;
2665                                 my $pfx = substr($path, 0, length($filter));
2666                                 if ($pfx ne $filter) {
2667                                         next PROJECT;
2668                                 }
2669                                 my $sfx = substr($path, length($filter));
2670                                 if ($sfx !~ /^\/.*\.git$/) {
2671                                         next PROJECT;
2672                                 }
2673                         } elsif ($check_forks) {
2674                         PATH:
2675                                 foreach my $filter (keys %paths) {
2676                                         # looking for forks;
2677                                         my $pfx = substr($path, 0, length($filter));
2678                                         if ($pfx ne $filter) {
2679                                                 next PATH;
2680                                         }
2681                                         my $sfx = substr($path, length($filter));
2682                                         if ($sfx !~ /^\/.*\.git$/) {
2683                                                 next PATH;
2684                                         }
2685                                         # is a fork, don't include it in
2686                                         # the list
2687                                         next PROJECT;
2688                                 }
2689                         }
2690                         if (check_export_ok("$projectroot/$path")) {
2691                                 my $pr = {
2692                                         path => $path,
2693                                         owner => to_utf8($owner),
2694                                 };
2695                                 push @list, $pr;
2696                                 (my $forks_path = $path) =~ s/\.git$//;
2697                                 $paths{$forks_path}++;
2698                         }
2699                 }
2700                 close $fd;
2701         }
2702         return @list;
2703 }
2704
2705 our $gitweb_project_owner = undef;
2706 sub git_get_project_list_from_file {
2707
2708         return if (defined $gitweb_project_owner);
2709
2710         $gitweb_project_owner = {};
2711         # read from file (url-encoded):
2712         # 'git%2Fgit.git Linus+Torvalds'
2713         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2714         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2715         if (-f $projects_list) {
2716                 open(my $fd, '<', $projects_list);
2717                 while (my $line = <$fd>) {
2718                         chomp $line;
2719                         my ($pr, $ow) = split ' ', $line;
2720                         $pr = unescape($pr);
2721                         $ow = unescape($ow);
2722                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2723                 }
2724                 close $fd;
2725         }
2726 }
2727
2728 sub git_get_project_owner {
2729         my $project = shift;
2730         my $owner;
2731
2732         return undef unless $project;
2733         $git_dir = "$projectroot/$project";
2734
2735         if (!defined $gitweb_project_owner) {
2736                 git_get_project_list_from_file();
2737         }
2738
2739         if (exists $gitweb_project_owner->{$project}) {
2740                 $owner = $gitweb_project_owner->{$project};
2741         }
2742         if (!defined $owner){
2743                 $owner = git_get_project_config('owner');
2744         }
2745         if (!defined $owner) {
2746                 $owner = get_file_owner("$git_dir");
2747         }
2748
2749         return $owner;
2750 }
2751
2752 sub git_get_last_activity {
2753         my ($path) = @_;
2754         my $fd;
2755
2756         $git_dir = "$projectroot/$path";
2757         open($fd, "-|", git_cmd(), 'for-each-ref',
2758              '--format=%(committer)',
2759              '--sort=-committerdate',
2760              '--count=1',
2761              'refs/heads') or return;
2762         my $most_recent = <$fd>;
2763         close $fd or return;
2764         if (defined $most_recent &&
2765             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2766                 my $timestamp = $1;
2767                 my $age = time - $timestamp;
2768                 return ($age, age_string($age));
2769         }
2770         return (undef, undef);
2771 }
2772
2773 # Implementation note: when a single remote is wanted, we cannot use 'git
2774 # remote show -n' because that command always work (assuming it's a remote URL
2775 # if it's not defined), and we cannot use 'git remote show' because that would
2776 # try to make a network roundtrip. So the only way to find if that particular
2777 # remote is defined is to walk the list provided by 'git remote -v' and stop if
2778 # and when we find what we want.
2779 sub git_get_remotes_list {
2780         my $wanted = shift;
2781         my %remotes = ();
2782
2783         open my $fd, '-|' , git_cmd(), 'remote', '-v';
2784         return unless $fd;
2785         while (my $remote = <$fd>) {
2786                 chomp $remote;
2787                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
2788                 next if $wanted and not $remote eq $wanted;
2789                 my ($url, $key) = ($1, $2);
2790
2791                 $remotes{$remote} ||= { 'heads' => () };
2792                 $remotes{$remote}{$key} = $url;
2793         }
2794         close $fd or return;
2795         return wantarray ? %remotes : \%remotes;
2796 }
2797
2798 # Takes a hash of remotes as first parameter and fills it by adding the
2799 # available remote heads for each of the indicated remotes.
2800 sub fill_remote_heads {
2801         my $remotes = shift;
2802         my @heads = map { "remotes/$_" } keys %$remotes;
2803         my @remoteheads = git_get_heads_list(undef, @heads);
2804         foreach my $remote (keys %$remotes) {
2805                 $remotes->{$remote}{'heads'} = [ grep {
2806                         $_->{'name'} =~ s!^$remote/!!
2807                         } @remoteheads ];
2808         }
2809 }
2810
2811 sub git_get_references {
2812         my $type = shift || "";
2813         my %refs;
2814         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2815         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2816         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2817                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2818                 or return;
2819
2820         while (my $line = <$fd>) {
2821                 chomp $line;
2822                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2823                         if (defined $refs{$1}) {
2824                                 push @{$refs{$1}}, $2;
2825                         } else {
2826                                 $refs{$1} = [ $2 ];
2827                         }
2828                 }
2829         }
2830         close $fd or return;
2831         return \%refs;
2832 }
2833
2834 sub git_get_rev_name_tags {
2835         my $hash = shift || return undef;
2836
2837         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2838                 or return;
2839         my $name_rev = <$fd>;
2840         close $fd;
2841
2842         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2843                 return $1;
2844         } else {
2845                 # catches also '$hash undefined' output
2846                 return undef;
2847         }
2848 }
2849
2850 ## ----------------------------------------------------------------------
2851 ## parse to hash functions
2852
2853 sub parse_date {
2854         my $epoch = shift;
2855         my $tz = shift || "-0000";
2856
2857         my %date;
2858         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2859         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2860         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2861         $date{'hour'} = $hour;
2862         $date{'minute'} = $min;
2863         $date{'mday'} = $mday;
2864         $date{'day'} = $days[$wday];
2865         $date{'month'} = $months[$mon];
2866         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2867                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2868         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2869                              $mday, $months[$mon], $hour ,$min;
2870         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2871                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2872
2873         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2874         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2875         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2876         $date{'hour_local'} = $hour;
2877         $date{'minute_local'} = $min;
2878         $date{'tz_local'} = $tz;
2879         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2880                                   1900+$year, $mon+1, $mday,
2881                                   $hour, $min, $sec, $tz);
2882         return %date;
2883 }
2884
2885 sub parse_tag {
2886         my $tag_id = shift;
2887         my %tag;
2888         my @comment;
2889
2890         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2891         $tag{'id'} = $tag_id;
2892         while (my $line = <$fd>) {
2893                 chomp $line;
2894                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2895                         $tag{'object'} = $1;
2896                 } elsif ($line =~ m/^type (.+)$/) {
2897                         $tag{'type'} = $1;
2898                 } elsif ($line =~ m/^tag (.+)$/) {
2899                         $tag{'name'} = $1;
2900                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2901                         $tag{'author'} = $1;
2902                         $tag{'author_epoch'} = $2;
2903                         $tag{'author_tz'} = $3;
2904                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2905                                 $tag{'author_name'}  = $1;
2906                                 $tag{'author_email'} = $2;
2907                         } else {
2908                                 $tag{'author_name'} = $tag{'author'};
2909                         }
2910                 } elsif ($line =~ m/--BEGIN/) {
2911                         push @comment, $line;
2912                         last;
2913                 } elsif ($line eq "") {
2914                         last;
2915                 }
2916         }
2917         push @comment, <$fd>;
2918         $tag{'comment'} = \@comment;
2919         close $fd or return;
2920         if (!defined $tag{'name'}) {
2921                 return
2922         };
2923         return %tag
2924 }
2925
2926 sub parse_commit_text {
2927         my ($commit_text, $withparents) = @_;
2928         my @commit_lines = split '\n', $commit_text;
2929         my %co;
2930
2931         pop @commit_lines; # Remove '\0'
2932
2933         if (! @commit_lines) {
2934                 return;
2935         }
2936
2937         my $header = shift @commit_lines;
2938         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2939                 return;
2940         }
2941         ($co{'id'}, my @parents) = split ' ', $header;
2942         while (my $line = shift @commit_lines) {
2943                 last if $line eq "\n";
2944                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2945                         $co{'tree'} = $1;
2946                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2947                         push @parents, $1;
2948                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2949                         $co{'author'} = to_utf8($1);
2950                         $co{'author_epoch'} = $2;
2951                         $co{'author_tz'} = $3;
2952                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2953                                 $co{'author_name'}  = $1;
2954                                 $co{'author_email'} = $2;
2955                         } else {
2956                                 $co{'author_name'} = $co{'author'};
2957                         }
2958                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
2959                         $co{'committer'} = to_utf8($1);
2960                         $co{'committer_epoch'} = $2;
2961                         $co{'committer_tz'} = $3;
2962                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
2963                                 $co{'committer_name'}  = $1;
2964                                 $co{'committer_email'} = $2;
2965                         } else {
2966                                 $co{'committer_name'} = $co{'committer'};
2967                         }
2968                 }
2969         }
2970         if (!defined $co{'tree'}) {
2971                 return;
2972         };
2973         $co{'parents'} = \@parents;
2974         $co{'parent'} = $parents[0];
2975
2976         foreach my $title (@commit_lines) {
2977                 $title =~ s/^    //;
2978                 if ($title ne "") {
2979                         $co{'title'} = chop_str($title, 80, 5);
2980                         # remove leading stuff of merges to make the interesting part visible
2981                         if (length($title) > 50) {
2982                                 $title =~ s/^Automatic //;
2983                                 $title =~ s/^merge (of|with) /Merge ... /i;
2984                                 if (length($title) > 50) {
2985                                         $title =~ s/(http|rsync):\/\///;
2986                                 }
2987                                 if (length($title) > 50) {
2988                                         $title =~ s/(master|www|rsync)\.//;
2989                                 }
2990                                 if (length($title) > 50) {
2991                                         $title =~ s/kernel.org:?//;
2992                                 }
2993                                 if (length($title) > 50) {
2994                                         $title =~ s/\/pub\/scm//;
2995                                 }
2996                         }
2997                         $co{'title_short'} = chop_str($title, 50, 5);
2998                         last;
2999                 }
3000         }
3001         if (! defined $co{'title'} || $co{'title'} eq "") {
3002                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3003         }
3004         # remove added spaces
3005         foreach my $line (@commit_lines) {
3006                 $line =~ s/^    //;
3007         }
3008         $co{'comment'} = \@commit_lines;
3009
3010         my $age = time - $co{'committer_epoch'};
3011         $co{'age'} = $age;
3012         $co{'age_string'} = age_string($age);
3013         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3014         if ($age > 60*60*24*7*2) {
3015                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3016                 $co{'age_string_age'} = $co{'age_string'};
3017         } else {
3018                 $co{'age_string_date'} = $co{'age_string'};
3019                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3020         }
3021         return %co;
3022 }
3023
3024 sub parse_commit {
3025         my ($commit_id) = @_;
3026         my %co;
3027
3028         local $/ = "\0";
3029
3030         open my $fd, "-|", git_cmd(), "rev-list",
3031                 "--parents",
3032                 "--header",
3033                 "--max-count=1",
3034                 $commit_id,
3035                 "--",
3036                 or die_error(500, "Open git-rev-list failed");
3037         %co = parse_commit_text(<$fd>, 1);
3038         close $fd;
3039
3040         return %co;
3041 }
3042
3043 sub parse_commits {
3044         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3045         my @cos;
3046
3047         $maxcount ||= 1;
3048         $skip ||= 0;
3049
3050         local $/ = "\0";
3051
3052         open my $fd, "-|", git_cmd(), "rev-list",
3053                 "--header",
3054                 @args,
3055                 ("--max-count=" . $maxcount),
3056                 ("--skip=" . $skip),
3057                 @extra_options,
3058                 $commit_id,
3059                 "--",
3060                 ($filename ? ($filename) : ())
3061                 or die_error(500, "Open git-rev-list failed");
3062         while (my $line = <$fd>) {
3063                 my %co = parse_commit_text($line);
3064                 push @cos, \%co;
3065         }
3066         close $fd;
3067
3068         return wantarray ? @cos : \@cos;
3069 }
3070
3071 # parse line of git-diff-tree "raw" output
3072 sub parse_difftree_raw_line {
3073         my $line = shift;
3074         my %res;
3075
3076         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3077         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3078         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3079                 $res{'from_mode'} = $1;
3080                 $res{'to_mode'} = $2;
3081                 $res{'from_id'} = $3;
3082                 $res{'to_id'} = $4;
3083                 $res{'status'} = $5;
3084                 $res{'similarity'} = $6;
3085                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3086                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3087                 } else {
3088                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3089                 }
3090         }
3091         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3092         # combined diff (for merge commit)
3093         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3094                 $res{'nparents'}  = length($1);
3095                 $res{'from_mode'} = [ split(' ', $2) ];
3096                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3097                 $res{'from_id'} = [ split(' ', $3) ];
3098                 $res{'to_id'} = pop @{$res{'from_id'}};
3099                 $res{'status'} = [ split('', $4) ];
3100                 $res{'to_file'} = unquote($5);
3101         }
3102         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3103         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3104                 $res{'commit'} = $1;
3105         }
3106
3107         return wantarray ? %res : \%res;
3108 }
3109
3110 # wrapper: return parsed line of git-diff-tree "raw" output
3111 # (the argument might be raw line, or parsed info)
3112 sub parsed_difftree_line {
3113         my $line_or_ref = shift;
3114
3115         if (ref($line_or_ref) eq "HASH") {
3116                 # pre-parsed (or generated by hand)
3117                 return $line_or_ref;
3118         } else {
3119                 return parse_difftree_raw_line($line_or_ref);
3120         }
3121 }
3122
3123 # parse line of git-ls-tree output
3124 sub parse_ls_tree_line {
3125         my $line = shift;
3126         my %opts = @_;
3127         my %res;
3128
3129         if ($opts{'-l'}) {
3130                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3131                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3132
3133                 $res{'mode'} = $1;
3134                 $res{'type'} = $2;
3135                 $res{'hash'} = $3;
3136                 $res{'size'} = $4;
3137                 if ($opts{'-z'}) {
3138                         $res{'name'} = $5;
3139                 } else {
3140                         $res{'name'} = unquote($5);
3141                 }
3142         } else {
3143                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3144                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3145
3146                 $res{'mode'} = $1;
3147                 $res{'type'} = $2;
3148                 $res{'hash'} = $3;
3149                 if ($opts{'-z'}) {
3150                         $res{'name'} = $4;
3151                 } else {
3152                         $res{'name'} = unquote($4);
3153                 }
3154         }
3155
3156         return wantarray ? %res : \%res;
3157 }
3158
3159 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3160 sub parse_from_to_diffinfo {
3161         my ($diffinfo, $from, $to, @parents) = @_;
3162
3163         if ($diffinfo->{'nparents'}) {
3164                 # combined diff
3165                 $from->{'file'} = [];
3166                 $from->{'href'} = [];
3167                 fill_from_file_info($diffinfo, @parents)
3168                         unless exists $diffinfo->{'from_file'};
3169                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3170                         $from->{'file'}[$i] =
3171                                 defined $diffinfo->{'from_file'}[$i] ?
3172                                         $diffinfo->{'from_file'}[$i] :
3173                                         $diffinfo->{'to_file'};
3174                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3175                                 $from->{'href'}[$i] = href(action=>"blob",
3176                                                            hash_base=>$parents[$i],
3177                                                            hash=>$diffinfo->{'from_id'}[$i],
3178                                                            file_name=>$from->{'file'}[$i]);
3179                         } else {
3180                                 $from->{'href'}[$i] = undef;
3181                         }
3182                 }
3183         } else {
3184                 # ordinary (not combined) diff
3185                 $from->{'file'} = $diffinfo->{'from_file'};
3186                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3187                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3188                                                hash=>$diffinfo->{'from_id'},
3189                                                file_name=>$from->{'file'});
3190                 } else {
3191                         delete $from->{'href'};
3192                 }
3193         }
3194
3195         $to->{'file'} = $diffinfo->{'to_file'};
3196         if (!is_deleted($diffinfo)) { # file exists in result
3197                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3198                                      hash=>$diffinfo->{'to_id'},
3199                                      file_name=>$to->{'file'});
3200         } else {
3201                 delete $to->{'href'};
3202         }
3203 }
3204
3205 ## ......................................................................
3206 ## parse to array of hashes functions
3207
3208 sub git_get_heads_list {
3209         my ($limit, @classes) = @_;
3210         @classes = ('heads') unless @classes;
3211         my @patterns = map { "refs/$_" } @classes;
3212         my @headslist;
3213
3214         open my $fd, '-|', git_cmd(), 'for-each-ref',
3215                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3216                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3217                 @patterns
3218                 or return;
3219         while (my $line = <$fd>) {
3220                 my %ref_item;
3221
3222                 chomp $line;
3223                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3224                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3225                 my ($committer, $epoch, $tz) =
3226                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3227                 $ref_item{'fullname'}  = $name;
3228                 $name =~ s!^refs/(?:head|remote)s/!!;
3229
3230                 $ref_item{'name'}  = $name;
3231                 $ref_item{'id'}    = $hash;
3232                 $ref_item{'title'} = $title || '(no commit message)';
3233                 $ref_item{'epoch'} = $epoch;
3234                 if ($epoch) {
3235                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3236                 } else {
3237                         $ref_item{'age'} = "unknown";
3238                 }
3239
3240                 push @headslist, \%ref_item;
3241         }
3242         close $fd;
3243
3244         return wantarray ? @headslist : \@headslist;
3245 }
3246
3247 sub git_get_tags_list {
3248         my $limit = shift;
3249         my @tagslist;
3250
3251         open my $fd, '-|', git_cmd(), 'for-each-ref',
3252                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3253                 '--format=%(objectname) %(objecttype) %(refname) '.
3254                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3255                 'refs/tags'
3256                 or return;
3257         while (my $line = <$fd>) {
3258                 my %ref_item;
3259
3260                 chomp $line;
3261                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3262                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3263                 my ($creator, $epoch, $tz) =
3264                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3265                 $ref_item{'fullname'} = $name;
3266                 $name =~ s!^refs/tags/!!;
3267
3268                 $ref_item{'type'} = $type;
3269                 $ref_item{'id'} = $id;
3270                 $ref_item{'name'} = $name;
3271                 if ($type eq "tag") {
3272                         $ref_item{'subject'} = $title;
3273                         $ref_item{'reftype'} = $reftype;
3274                         $ref_item{'refid'}   = $refid;
3275                 } else {
3276                         $ref_item{'reftype'} = $type;
3277                         $ref_item{'refid'}   = $id;
3278                 }
3279
3280                 if ($type eq "tag" || $type eq "commit") {
3281                         $ref_item{'epoch'} = $epoch;
3282                         if ($epoch) {
3283                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3284                         } else {
3285                                 $ref_item{'age'} = "unknown";
3286                         }
3287                 }
3288
3289                 push @tagslist, \%ref_item;
3290         }
3291         close $fd;
3292
3293         return wantarray ? @tagslist : \@tagslist;
3294 }
3295
3296 ## ----------------------------------------------------------------------
3297 ## filesystem-related functions
3298
3299 sub get_file_owner {
3300         my $path = shift;
3301
3302         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3303         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3304         if (!defined $gcos) {
3305                 return undef;
3306         }
3307         my $owner = $gcos;
3308         $owner =~ s/[,;].*$//;
3309         return to_utf8($owner);
3310 }
3311
3312 # assume that file exists
3313 sub insert_file {
3314         my $filename = shift;
3315
3316         open my $fd, '<', $filename;
3317         print map { to_utf8($_) } <$fd>;
3318         close $fd;
3319 }
3320
3321 ## ......................................................................
3322 ## mimetype related functions
3323
3324 sub mimetype_guess_file {
3325         my $filename = shift;
3326         my $mimemap = shift;
3327         -r $mimemap or return undef;
3328
3329         my %mimemap;
3330         open(my $mh, '<', $mimemap) or return undef;
3331         while (<$mh>) {
3332                 next if m/^#/; # skip comments
3333                 my ($mimetype, $exts) = split(/\t+/);
3334                 if (defined $exts) {
3335                         my @exts = split(/\s+/, $exts);
3336                         foreach my $ext (@exts) {
3337                                 $mimemap{$ext} = $mimetype;
3338                         }
3339                 }
3340         }
3341         close($mh);
3342
3343         $filename =~ /\.([^.]*)$/;
3344         return $mimemap{$1};
3345 }
3346
3347 sub mimetype_guess {
3348         my $filename = shift;
3349         my $mime;
3350         $filename =~ /\./ or return undef;
3351
3352         if ($mimetypes_file) {
3353                 my $file = $mimetypes_file;
3354                 if ($file !~ m!^/!) { # if it is relative path
3355                         # it is relative to project
3356                         $file = "$projectroot/$project/$file";
3357                 }
3358                 $mime = mimetype_guess_file($filename, $file);
3359         }
3360         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3361         return $mime;
3362 }
3363
3364 sub blob_mimetype {
3365         my $fd = shift;
3366         my $filename = shift;
3367
3368         if ($filename) {
3369                 my $mime = mimetype_guess($filename);
3370                 $mime and return $mime;
3371         }
3372
3373         # just in case
3374         return $default_blob_plain_mimetype unless $fd;
3375
3376         if (-T $fd) {
3377                 return 'text/plain';
3378         } elsif (! $filename) {
3379                 return 'application/octet-stream';
3380         } elsif ($filename =~ m/\.png$/i) {
3381                 return 'image/png';
3382         } elsif ($filename =~ m/\.gif$/i) {
3383                 return 'image/gif';
3384         } elsif ($filename =~ m/\.jpe?g$/i) {
3385                 return 'image/jpeg';
3386         } else {
3387                 return 'application/octet-stream';
3388         }
3389 }
3390
3391 sub blob_contenttype {
3392         my ($fd, $file_name, $type) = @_;
3393
3394         $type ||= blob_mimetype($fd, $file_name);
3395         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3396                 $type .= "; charset=$default_text_plain_charset";
3397         }
3398
3399         return $type;
3400 }
3401
3402 # guess file syntax for syntax highlighting; return undef if no highlighting
3403 # the name of syntax can (in the future) depend on syntax highlighter used
3404 sub guess_file_syntax {
3405         my ($highlight, $mimetype, $file_name) = @_;
3406         return undef unless ($highlight && defined $file_name);
3407         my $basename = basename($file_name, '.in');
3408         return $highlight_basename{$basename}
3409                 if exists $highlight_basename{$basename};
3410
3411         $basename =~ /\.([^.]*)$/;
3412         my $ext = $1 or return undef;
3413         return $highlight_ext{$ext}
3414                 if exists $highlight_ext{$ext};
3415
3416         return undef;
3417 }
3418
3419 # run highlighter and return FD of its output,
3420 # or return original FD if no highlighting
3421 sub run_highlighter {
3422         my ($fd, $highlight, $syntax) = @_;
3423         return $fd unless ($highlight && defined $syntax);
3424
3425         close $fd
3426                 or die_error(404, "Reading blob failed");
3427         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3428                   quote_command($highlight_bin).
3429                   " --xhtml --fragment --syntax $syntax |"
3430                 or die_error(500, "Couldn't open file or run syntax highlighter");
3431         return $fd;
3432 }
3433
3434 ## ======================================================================
3435 ## functions printing HTML: header, footer, error page
3436
3437 sub get_page_title {
3438         my $title = to_utf8($site_name);
3439
3440         return $title unless (defined $project);
3441         $title .= " - " . to_utf8($project);
3442
3443         return $title unless (defined $action);
3444         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3445
3446         return $title unless (defined $file_name);
3447         $title .= " - " . esc_path($file_name);
3448         if ($action eq "tree" && $file_name !~ m|/$|) {
3449                 $title .= "/";
3450         }
3451
3452         return $title;
3453 }
3454
3455 sub git_header_html {
3456         my $status = shift || "200 OK";
3457         my $expires = shift;
3458         my %opts = @_;
3459
3460         my $title = get_page_title();
3461         my $content_type;
3462         # require explicit support from the UA if we are to send the page as
3463         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3464         # we have to do this because MSIE sometimes globs '*/*', pretending to
3465         # support xhtml+xml but choking when it gets what it asked for.
3466         if (defined $cgi->http('HTTP_ACCEPT') &&
3467             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3468             $cgi->Accept('application/xhtml+xml') != 0) {
3469                 $content_type = 'application/xhtml+xml';
3470         } else {
3471                 $content_type = 'text/html';
3472         }
3473         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3474                            -status=> $status, -expires => $expires)
3475                 unless ($opts{'-no_http_header'});
3476         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3477         print <<EOF;
3478 <?xml version="1.0" encoding="utf-8"?>
3479 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3480 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3481 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3482 <!-- git core binaries version $git_version -->
3483 <head>
3484 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3485 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3486 <meta name="robots" content="index, nofollow"/>
3487 <title>$title</title>
3488 EOF
3489         # the stylesheet, favicon etc urls won't work correctly with path_info
3490         # unless we set the appropriate base URL
3491         if ($ENV{'PATH_INFO'}) {
3492                 print "<base href=\"".esc_url($base_url)."\" />\n";
3493         }
3494         # print out each stylesheet that exist, providing backwards capability
3495         # for those people who defined $stylesheet in a config file
3496         if (defined $stylesheet) {
3497                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3498         } else {
3499                 foreach my $stylesheet (@stylesheets) {
3500                         next unless $stylesheet;
3501                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3502                 }
3503         }
3504         if (defined $project) {
3505                 my %href_params = get_feed_info();
3506                 if (!exists $href_params{'-title'}) {
3507                         $href_params{'-title'} = 'log';
3508                 }
3509
3510                 foreach my $format qw(RSS Atom) {
3511                         my $type = lc($format);
3512                         my %link_attr = (
3513                                 '-rel' => 'alternate',
3514                                 '-title' => "$project - $href_params{'-title'} - $format feed",
3515                                 '-type' => "application/$type+xml"
3516                         );
3517
3518                         $href_params{'action'} = $type;
3519                         $link_attr{'-href'} = href(%href_params);
3520                         print "<link ".
3521                               "rel=\"$link_attr{'-rel'}\" ".
3522                               "title=\"$link_attr{'-title'}\" ".
3523                               "href=\"$link_attr{'-href'}\" ".
3524                               "type=\"$link_attr{'-type'}\" ".
3525                               "/>\n";
3526
3527                         $href_params{'extra_options'} = '--no-merges';
3528                         $link_attr{'-href'} = href(%href_params);
3529                         $link_attr{'-title'} .= ' (no merges)';
3530                         print "<link ".
3531                               "rel=\"$link_attr{'-rel'}\" ".
3532                               "title=\"$link_attr{'-title'}\" ".
3533                               "href=\"$link_attr{'-href'}\" ".
3534                               "type=\"$link_attr{'-type'}\" ".
3535                               "/>\n";
3536                 }
3537
3538         } else {
3539                 printf('<link rel="alternate" title="%s projects list" '.
3540                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3541                        $site_name, href(project=>undef, action=>"project_index"));
3542                 printf('<link rel="alternate" title="%s projects feeds" '.
3543                        'href="%s" type="text/x-opml" />'."\n",
3544                        $site_name, href(project=>undef, action=>"opml"));
3545         }
3546         if (defined $favicon) {
3547                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png" />\n);
3548         }
3549
3550         print "</head>\n" .
3551               "<body>\n";
3552
3553         if (defined $site_header && -f $site_header) {
3554                 insert_file($site_header);
3555         }
3556
3557         print "<div class=\"page_header\">\n" .
3558               $cgi->a({-href => esc_url($logo_url),
3559                        -title => $logo_label},
3560                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
3561         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3562         if (defined $project) {
3563                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3564                 if (defined $action) {
3565                         my $action_print = $action ;
3566                         if (defined $opts{-action_extra}) {
3567                                 $action_print = $cgi->a({-href => href(action=>$action)},
3568                                         $action);
3569                         }
3570                         print " / $action_print";
3571                 }
3572                 if (defined $opts{-action_extra}) {
3573                         print " / $opts{-action_extra}";
3574                 }
3575                 print "\n";
3576         }
3577         print "</div>\n";
3578
3579         my $have_search = gitweb_check_feature('search');
3580         if (defined $project && $have_search) {
3581                 if (!defined $searchtext) {
3582                         $searchtext = "";
3583                 }
3584                 my $search_hash;
3585                 if (defined $hash_base) {
3586                         $search_hash = $hash_base;
3587                 } elsif (defined $hash) {
3588                         $search_hash = $hash;
3589                 } else {
3590                         $search_hash = "HEAD";
3591                 }
3592                 my $action = $my_uri;
3593                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3594                 if ($use_pathinfo) {
3595                         $action .= "/".esc_url($project);
3596                 }
3597                 print $cgi->startform(-method => "get", -action => $action) .
3598                       "<div class=\"search\">\n" .
3599                       (!$use_pathinfo &&
3600                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3601                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3602                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3603                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3604                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3605                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3606                       " search:\n",
3607                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3608                       "<span title=\"Extended regular expression\">" .
3609                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3610                                      -checked => $search_use_regexp) .
3611                       "</span>" .
3612                       "</div>" .
3613                       $cgi->end_form() . "\n";
3614         }
3615 }
3616
3617 sub git_footer_html {
3618         my $feed_class = 'rss_logo';
3619
3620         print "<div class=\"page_footer\">\n";
3621         if (defined $project) {
3622                 my $descr = git_get_project_description($project);
3623                 if (defined $descr) {
3624                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3625                 }
3626
3627                 my %href_params = get_feed_info();
3628                 if (!%href_params) {
3629                         $feed_class .= ' generic';
3630                 }
3631                 $href_params{'-title'} ||= 'log';
3632
3633                 foreach my $format qw(RSS Atom) {
3634                         $href_params{'action'} = lc($format);
3635                         print $cgi->a({-href => href(%href_params),
3636                                       -title => "$href_params{'-title'} $format feed",
3637                                       -class => $feed_class}, $format)."\n";
3638                 }
3639
3640         } else {
3641                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3642                               -class => $feed_class}, "OPML") . " ";
3643                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3644                               -class => $feed_class}, "TXT") . "\n";
3645         }
3646         print "</div>\n"; # class="page_footer"
3647
3648         if (defined $t0 && gitweb_check_feature('timed')) {
3649                 print "<div id=\"generating_info\">\n";
3650                 print 'This page took '.
3651                       '<span id="generating_time" class="time_span">'.
3652                       tv_interval($t0, [ gettimeofday() ]).
3653                       ' seconds </span>'.
3654                       ' and '.
3655                       '<span id="generating_cmd">'.
3656                       $number_of_git_cmds.
3657                       '</span> git commands '.
3658                       " to generate.\n";
3659                 print "</div>\n"; # class="page_footer"
3660         }
3661
3662         if (defined $site_footer && -f $site_footer) {
3663                 insert_file($site_footer);
3664         }
3665
3666         print qq!<script type="text/javascript" src="$javascript"></script>\n!;
3667         if (defined $action &&
3668             $action eq 'blame_incremental') {
3669                 print qq!<script type="text/javascript">\n!.
3670                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3671                       qq!           "!. href() .qq!");\n!.
3672                       qq!</script>\n!;
3673         } elsif (gitweb_check_feature('javascript-actions')) {
3674                 print qq!<script type="text/javascript">\n!.
3675                       qq!window.onload = fixLinks;\n!.
3676                       qq!</script>\n!;
3677         }
3678
3679         print "</body>\n" .
3680               "</html>";
3681 }
3682
3683 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3684 # Example: die_error(404, 'Hash not found')
3685 # By convention, use the following status codes (as defined in RFC 2616):
3686 # 400: Invalid or missing CGI parameters, or
3687 #      requested object exists but has wrong type.
3688 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3689 #      this server or project.
3690 # 404: Requested object/revision/project doesn't exist.
3691 # 500: The server isn't configured properly, or
3692 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3693 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3694 # 503: The server is currently unavailable (because it is overloaded,
3695 #      or down for maintenance).  Generally, this is a temporary state.
3696 sub die_error {
3697         my $status = shift || 500;
3698         my $error = esc_html(shift) || "Internal Server Error";
3699         my $extra = shift;
3700         my %opts = @_;
3701
3702         my %http_responses = (
3703                 400 => '400 Bad Request',
3704                 403 => '403 Forbidden',
3705                 404 => '404 Not Found',
3706                 500 => '500 Internal Server Error',
3707                 503 => '503 Service Unavailable',
3708         );
3709         git_header_html($http_responses{$status}, undef, %opts);
3710         print <<EOF;
3711 <div class="page_body">
3712 <br /><br />
3713 $status - $error
3714 <br />
3715 EOF
3716         if (defined $extra) {
3717                 print "<hr />\n" .
3718                       "$extra\n";
3719         }
3720         print "</div>\n";
3721
3722         git_footer_html();
3723         goto DONE_GITWEB
3724                 unless ($opts{'-error_handler'});
3725 }
3726
3727 ## ----------------------------------------------------------------------
3728 ## functions printing or outputting HTML: navigation
3729
3730 sub git_print_page_nav {
3731         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3732         $extra = '' if !defined $extra; # pager or formats
3733
3734         my @navs = qw(summary shortlog log commit commitdiff tree);
3735         if ($suppress) {
3736                 @navs = grep { $_ ne $suppress } @navs;
3737         }
3738
3739         my %arg = map { $_ => {action=>$_} } @navs;
3740         if (defined $head) {
3741                 for (qw(commit commitdiff)) {
3742                         $arg{$_}{'hash'} = $head;
3743                 }
3744                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3745                         for (qw(shortlog log)) {
3746                                 $arg{$_}{'hash'} = $head;
3747                         }
3748                 }
3749         }
3750
3751         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3752         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3753
3754         my @actions = gitweb_get_feature('actions');
3755         my %repl = (
3756                 '%' => '%',
3757                 'n' => $project,         # project name
3758                 'f' => $git_dir,         # project path within filesystem
3759                 'h' => $treehead || '',  # current hash ('h' parameter)
3760                 'b' => $treebase || '',  # hash base ('hb' parameter)
3761         );
3762         while (@actions) {
3763                 my ($label, $link, $pos) = splice(@actions,0,3);
3764                 # insert
3765                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3766                 # munch munch
3767                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3768                 $arg{$label}{'_href'} = $link;
3769         }
3770
3771         print "<div class=\"page_nav\">\n" .
3772                 (join " | ",
3773                  map { $_ eq $current ?
3774                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3775                  } @navs);
3776         print "<br/>\n$extra<br/>\n" .
3777               "</div>\n";
3778 }
3779
3780 # returns a submenu for the nagivation of the refs views (tags, heads,
3781 # remotes) with the current view disabled and the remotes view only
3782 # available if the feature is enabled
3783 sub format_ref_views {
3784         my ($current) = @_;
3785         my @ref_views = qw{tags heads};
3786         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
3787         return join " | ", map {
3788                 $_ eq $current ? $_ :
3789                 $cgi->a({-href => href(action=>$_)}, $_)
3790         } @ref_views
3791 }
3792
3793 sub format_paging_nav {
3794         my ($action, $page, $has_next_link) = @_;
3795         my $paging_nav;
3796
3797
3798         if ($page > 0) {
3799                 $paging_nav .=
3800                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3801                         " &sdot; " .
3802                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3803                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3804         } else {
3805                 $paging_nav .= "first &sdot; prev";
3806         }
3807
3808         if ($has_next_link) {
3809                 $paging_nav .= " &sdot; " .
3810                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3811                                  -accesskey => "n", -title => "Alt-n"}, "next");
3812         } else {
3813                 $paging_nav .= " &sdot; next";
3814         }
3815
3816         return $paging_nav;
3817 }
3818
3819 ## ......................................................................
3820 ## functions printing or outputting HTML: div
3821
3822 sub git_print_header_div {
3823         my ($action, $title, $hash, $hash_base) = @_;
3824         my %args = ();
3825
3826         $args{'action'} = $action;
3827         $args{'hash'} = $hash if $hash;
3828         $args{'hash_base'} = $hash_base if $hash_base;
3829
3830         print "<div class=\"header\">\n" .
3831               $cgi->a({-href => href(%args), -class => "title"},
3832               $title ? $title : $action) .
3833               "\n</div>\n";
3834 }
3835
3836 sub format_repo_url {
3837         my ($name, $url) = @_;
3838         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
3839 }
3840
3841 # Group output by placing it in a DIV element and adding a header.
3842 # Options for start_div() can be provided by passing a hash reference as the
3843 # first parameter to the function.
3844 # Options to git_print_header_div() can be provided by passing an array
3845 # reference. This must follow the options to start_div if they are present.
3846 # The content can be a scalar, which is output as-is, a scalar reference, which
3847 # is output after html escaping, an IO handle passed either as *handle or
3848 # *handle{IO}, or a function reference. In the latter case all following
3849 # parameters will be taken as argument to the content function call.
3850 sub git_print_section {
3851         my ($div_args, $header_args, $content);
3852         my $arg = shift;
3853         if (ref($arg) eq 'HASH') {
3854                 $div_args = $arg;
3855                 $arg = shift;
3856         }
3857         if (ref($arg) eq 'ARRAY') {
3858                 $header_args = $arg;
3859                 $arg = shift;
3860         }
3861         $content = $arg;
3862
3863         print $cgi->start_div($div_args);
3864         git_print_header_div(@$header_args);
3865
3866         if (ref($content) eq 'CODE') {
3867                 $content->(@_);
3868         } elsif (ref($content) eq 'SCALAR') {
3869                 print esc_html($$content);
3870         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
3871                 print <$content>;
3872         } elsif (!ref($content) && defined($content)) {
3873                 print $content;
3874         }
3875
3876         print $cgi->end_div;
3877 }
3878
3879 sub print_local_time {
3880         print format_local_time(@_);
3881 }
3882
3883 sub format_local_time {
3884         my $localtime = '';
3885         my %date = @_;
3886         if ($date{'hour_local'} < 6) {
3887                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3888                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3889         } else {
3890                 $localtime .= sprintf(" (%02d:%02d %s)",
3891                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3892         }
3893
3894         return $localtime;
3895 }
3896
3897 # Outputs the author name and date in long form
3898 sub git_print_authorship {
3899         my $co = shift;
3900         my %opts = @_;
3901         my $tag = $opts{-tag} || 'div';
3902         my $author = $co->{'author_name'};
3903
3904         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3905         print "<$tag class=\"author_date\">" .
3906               format_search_author($author, "author", esc_html($author)) .
3907               " [$ad{'rfc2822'}";
3908         print_local_time(%ad) if ($opts{-localtime});
3909         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3910                   . "</$tag>\n";
3911 }
3912
3913 # Outputs table rows containing the full author or committer information,
3914 # in the format expected for 'commit' view (& similar).
3915 # Parameters are a commit hash reference, followed by the list of people
3916 # to output information for. If the list is empty it defaults to both
3917 # author and committer.
3918 sub git_print_authorship_rows {
3919         my $co = shift;
3920         # too bad we can't use @people = @_ || ('author', 'committer')
3921         my @people = @_;
3922         @people = ('author', 'committer') unless @people;
3923         foreach my $who (@people) {
3924                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3925                 print "<tr><td>$who</td><td>" .
3926                       format_search_author($co->{"${who}_name"}, $who,
3927                                esc_html($co->{"${who}_name"})) . " " .
3928                       format_search_author($co->{"${who}_email"}, $who,
3929                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3930                       "</td><td rowspan=\"2\">" .
3931                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3932                       "</td></tr>\n" .
3933                       "<tr>" .
3934                       "<td></td><td> $wd{'rfc2822'}";
3935                 print_local_time(%wd);
3936                 print "</td>" .
3937                       "</tr>\n";
3938         }
3939 }
3940
3941 sub git_print_page_path {
3942         my $name = shift;
3943         my $type = shift;
3944         my $hb = shift;
3945
3946
3947         print "<div class=\"page_path\">";
3948         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3949                       -title => 'tree root'}, to_utf8("[$project]"));
3950         print " / ";
3951         if (defined $name) {
3952                 my @dirname = split '/', $name;
3953                 my $basename = pop @dirname;
3954                 my $fullname = '';
3955
3956                 foreach my $dir (@dirname) {
3957                         $fullname .= ($fullname ? '/' : '') . $dir;
3958                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
3959                                                      hash_base=>$hb),
3960                                       -title => $fullname}, esc_path($dir));
3961                         print " / ";
3962                 }
3963                 if (defined $type && $type eq 'blob') {
3964                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
3965                                                      hash_base=>$hb),
3966                                       -title => $name}, esc_path($basename));
3967                 } elsif (defined $type && $type eq 'tree') {
3968                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
3969                                                      hash_base=>$hb),
3970                                       -title => $name}, esc_path($basename));
3971                         print " / ";
3972                 } else {
3973                         print esc_path($basename);
3974                 }
3975         }
3976         print "<br/></div>\n";
3977 }
3978
3979 sub git_print_log {
3980         my $log = shift;
3981         my %opts = @_;
3982
3983         if ($opts{'-remove_title'}) {
3984                 # remove title, i.e. first line of log
3985                 shift @$log;
3986         }
3987         # remove leading empty lines
3988         while (defined $log->[0] && $log->[0] eq "") {
3989                 shift @$log;
3990         }
3991
3992         # print log
3993         my $signoff = 0;
3994         my $empty = 0;
3995         foreach my $line (@$log) {
3996                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
3997                         $signoff = 1;
3998                         $empty = 0;
3999                         if (! $opts{'-remove_signoff'}) {
4000                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4001                                 next;
4002                         } else {
4003                                 # remove signoff lines
4004                                 next;
4005                         }
4006                 } else {
4007                         $signoff = 0;
4008                 }
4009
4010                 # print only one empty line
4011                 # do not print empty line after signoff
4012                 if ($line eq "") {
4013                         next if ($empty || $signoff);
4014                         $empty = 1;
4015                 } else {
4016                         $empty = 0;
4017                 }
4018
4019                 print format_log_line_html($line) . "<br/>\n";
4020         }
4021
4022         if ($opts{'-final_empty_line'}) {
4023                 # end with single empty line
4024                 print "<br/>\n" unless $empty;
4025         }
4026 }
4027
4028 # return link target (what link points to)
4029 sub git_get_link_target {
4030         my $hash = shift;
4031         my $link_target;
4032
4033         # read link
4034         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4035                 or return;
4036         {
4037                 local $/ = undef;
4038                 $link_target = <$fd>;
4039         }
4040         close $fd
4041                 or return;
4042
4043         return $link_target;
4044 }
4045
4046 # given link target, and the directory (basedir) the link is in,
4047 # return target of link relative to top directory (top tree);
4048 # return undef if it is not possible (including absolute links).
4049 sub normalize_link_target {
4050         my ($link_target, $basedir) = @_;
4051
4052         # absolute symlinks (beginning with '/') cannot be normalized
4053         return if (substr($link_target, 0, 1) eq '/');
4054
4055         # normalize link target to path from top (root) tree (dir)
4056         my $path;
4057         if ($basedir) {
4058                 $path = $basedir . '/' . $link_target;
4059         } else {
4060                 # we are in top (root) tree (dir)
4061                 $path = $link_target;
4062         }
4063
4064         # remove //, /./, and /../
4065         my @path_parts;
4066         foreach my $part (split('/', $path)) {
4067                 # discard '.' and ''
4068                 next if (!$part || $part eq '.');
4069                 # handle '..'
4070                 if ($part eq '..') {
4071                         if (@path_parts) {
4072                                 pop @path_parts;
4073                         } else {
4074                                 # link leads outside repository (outside top dir)
4075                                 return;
4076                         }
4077                 } else {
4078                         push @path_parts, $part;
4079                 }
4080         }
4081         $path = join('/', @path_parts);
4082
4083         return $path;
4084 }
4085
4086 # print tree entry (row of git_tree), but without encompassing <tr> element
4087 sub git_print_tree_entry {
4088         my ($t, $basedir, $hash_base, $have_blame) = @_;
4089
4090         my %base_key = ();
4091         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4092
4093         # The format of a table row is: mode list link.  Where mode is
4094         # the mode of the entry, list is the name of the entry, an href,
4095         # and link is the action links of the entry.
4096
4097         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4098         if (exists $t->{'size'}) {
4099                 print "<td class=\"size\">$t->{'size'}</td>\n";
4100         }
4101         if ($t->{'type'} eq "blob") {
4102                 print "<td class=\"list\">" .
4103                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4104                                                file_name=>"$basedir$t->{'name'}", %base_key),
4105                                 -class => "list"}, esc_path($t->{'name'}));
4106                 if (S_ISLNK(oct $t->{'mode'})) {
4107                         my $link_target = git_get_link_target($t->{'hash'});
4108                         if ($link_target) {
4109                                 my $norm_target = normalize_link_target($link_target, $basedir);
4110                                 if (defined $norm_target) {
4111                                         print " -> " .
4112                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4113                                                                      file_name=>$norm_target),
4114                                                        -title => $norm_target}, esc_path($link_target));
4115                                 } else {
4116                                         print " -> " . esc_path($link_target);
4117                                 }
4118                         }
4119                 }
4120                 print "</td>\n";
4121                 print "<td class=\"link\">";
4122                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4123                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4124                               "blob");
4125                 if ($have_blame) {
4126                         print " | " .
4127                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4128                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4129                                       "blame");
4130                 }
4131                 if (defined $hash_base) {
4132                         print " | " .
4133                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4134                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4135                                       "history");
4136                 }
4137                 print " | " .
4138                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4139                                                file_name=>"$basedir$t->{'name'}")},
4140                                 "raw");
4141                 print "</td>\n";
4142
4143         } elsif ($t->{'type'} eq "tree") {
4144                 print "<td class=\"list\">";
4145                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4146                                              file_name=>"$basedir$t->{'name'}",
4147                                              %base_key)},
4148                               esc_path($t->{'name'}));
4149                 print "</td>\n";
4150                 print "<td class=\"link\">";
4151                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4152                                              file_name=>"$basedir$t->{'name'}",
4153                                              %base_key)},
4154                               "tree");
4155                 if (defined $hash_base) {
4156                         print " | " .
4157                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4158                                                      file_name=>"$basedir$t->{'name'}")},
4159                                       "history");
4160                 }
4161                 print "</td>\n";
4162         } else {
4163                 # unknown object: we can only present history for it
4164                 # (this includes 'commit' object, i.e. submodule support)
4165                 print "<td class=\"list\">" .
4166                       esc_path($t->{'name'}) .
4167                       "</td>\n";
4168                 print "<td class=\"link\">";
4169                 if (defined $hash_base) {
4170                         print $cgi->a({-href => href(action=>"history",
4171                                                      hash_base=>$hash_base,
4172                                                      file_name=>"$basedir$t->{'name'}")},
4173                                       "history");
4174                 }
4175                 print "</td>\n";
4176         }
4177 }
4178
4179 ## ......................................................................
4180 ## functions printing large fragments of HTML
4181
4182 # get pre-image filenames for merge (combined) diff
4183 sub fill_from_file_info {
4184         my ($diff, @parents) = @_;
4185
4186         $diff->{'from_file'} = [ ];
4187         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4188         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4189                 if ($diff->{'status'}[$i] eq 'R' ||
4190                     $diff->{'status'}[$i] eq 'C') {
4191                         $diff->{'from_file'}[$i] =
4192                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4193                 }
4194         }
4195
4196         return $diff;
4197 }
4198
4199 # is current raw difftree line of file deletion
4200 sub is_deleted {
4201         my $diffinfo = shift;
4202
4203         return $diffinfo->{'to_id'} eq ('0' x 40);
4204 }
4205
4206 # does patch correspond to [previous] difftree raw line
4207 # $diffinfo  - hashref of parsed raw diff format
4208 # $patchinfo - hashref of parsed patch diff format
4209 #              (the same keys as in $diffinfo)
4210 sub is_patch_split {
4211         my ($diffinfo, $patchinfo) = @_;
4212
4213         return defined $diffinfo && defined $patchinfo
4214                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4215 }
4216
4217
4218 sub git_difftree_body {
4219         my ($difftree, $hash, @parents) = @_;
4220         my ($parent) = $parents[0];
4221         my $have_blame = gitweb_check_feature('blame');
4222         print "<div class=\"list_head\">\n";
4223         if ($#{$difftree} > 10) {
4224                 print(($#{$difftree} + 1) . " files changed:\n");
4225         }
4226         print "</div>\n";
4227
4228         print "<table class=\"" .
4229               (@parents > 1 ? "combined " : "") .
4230               "diff_tree\">\n";
4231
4232         # header only for combined diff in 'commitdiff' view
4233         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4234         if ($has_header) {
4235                 # table header
4236                 print "<thead><tr>\n" .
4237                        "<th></th><th></th>\n"; # filename, patchN link
4238                 for (my $i = 0; $i < @parents; $i++) {
4239                         my $par = $parents[$i];
4240                         print "<th>" .
4241                               $cgi->a({-href => href(action=>"commitdiff",
4242                                                      hash=>$hash, hash_parent=>$par),
4243                                        -title => 'commitdiff to parent number ' .
4244                                                   ($i+1) . ': ' . substr($par,0,7)},
4245                                       $i+1) .
4246                               "&nbsp;</th>\n";
4247                 }
4248                 print "</tr></thead>\n<tbody>\n";
4249         }
4250
4251         my $alternate = 1;
4252         my $patchno = 0;
4253         foreach my $line (@{$difftree}) {
4254                 my $diff = parsed_difftree_line($line);
4255
4256                 if ($alternate) {
4257                         print "<tr class=\"dark\">\n";
4258                 } else {
4259                         print "<tr class=\"light\">\n";
4260                 }
4261                 $alternate ^= 1;
4262
4263                 if (exists $diff->{'nparents'}) { # combined diff
4264
4265                         fill_from_file_info($diff, @parents)
4266                                 unless exists $diff->{'from_file'};
4267
4268                         if (!is_deleted($diff)) {
4269                                 # file exists in the result (child) commit
4270                                 print "<td>" .
4271                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4272                                                              file_name=>$diff->{'to_file'},
4273                                                              hash_base=>$hash),
4274                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4275                                       "</td>\n";
4276                         } else {
4277                                 print "<td>" .
4278                                       esc_path($diff->{'to_file'}) .
4279                                       "</td>\n";
4280                         }
4281
4282                         if ($action eq 'commitdiff') {
4283                                 # link to patch
4284                                 $patchno++;
4285                                 print "<td class=\"link\">" .
4286                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4287                                       " | " .
4288                                       "</td>\n";
4289                         }
4290
4291                         my $has_history = 0;
4292                         my $not_deleted = 0;
4293                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4294                                 my $hash_parent = $parents[$i];
4295                                 my $from_hash = $diff->{'from_id'}[$i];
4296                                 my $from_path = $diff->{'from_file'}[$i];
4297                                 my $status = $diff->{'status'}[$i];
4298
4299                                 $has_history ||= ($status ne 'A');
4300                                 $not_deleted ||= ($status ne 'D');
4301
4302                                 if ($status eq 'A') {
4303                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4304                                 } elsif ($status eq 'D') {
4305                                         print "<td class=\"link\">" .
4306                                               $cgi->a({-href => href(action=>"blob",
4307                                                                      hash_base=>$hash,
4308                                                                      hash=>$from_hash,
4309                                                                      file_name=>$from_path)},
4310                                                       "blob" . ($i+1)) .
4311                                               " | </td>\n";
4312                                 } else {
4313                                         if ($diff->{'to_id'} eq $from_hash) {
4314                                                 print "<td class=\"link nochange\">";
4315                                         } else {
4316                                                 print "<td class=\"link\">";
4317                                         }
4318                                         print $cgi->a({-href => href(action=>"blobdiff",
4319                                                                      hash=>$diff->{'to_id'},
4320                                                                      hash_parent=>$from_hash,
4321                                                                      hash_base=>$hash,
4322                                                                      hash_parent_base=>$hash_parent,
4323                                                                      file_name=>$diff->{'to_file'},
4324                                                                      file_parent=>$from_path)},
4325                                                       "diff" . ($i+1)) .
4326                                               " | </td>\n";
4327                                 }
4328                         }
4329
4330                         print "<td class=\"link\">";
4331                         if ($not_deleted) {
4332                                 print $cgi->a({-href => href(action=>"blob",
4333                                                              hash=>$diff->{'to_id'},
4334                                                              file_name=>$diff->{'to_file'},
4335                                                              hash_base=>$hash)},
4336                                               "blob");
4337                                 print " | " if ($has_history);
4338                         }
4339                         if ($has_history) {
4340                                 print $cgi->a({-href => href(action=>"history",
4341                                                              file_name=>$diff->{'to_file'},
4342                                                              hash_base=>$hash)},
4343                                               "history");
4344                         }
4345                         print "</td>\n";
4346
4347                         print "</tr>\n";
4348                         next; # instead of 'else' clause, to avoid extra indent
4349                 }
4350                 # else ordinary diff
4351
4352                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4353                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4354                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4355                         $to_mode_oct = oct $diff->{'to_mode'};
4356                         if (S_ISREG($to_mode_oct)) { # only for regular file
4357                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4358                         }
4359                         $to_file_type = file_type($diff->{'to_mode'});
4360                 }
4361                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4362                         $from_mode_oct = oct $diff->{'from_mode'};
4363                         if (S_ISREG($to_mode_oct)) { # only for regular file
4364                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4365                         }
4366                         $from_file_type = file_type($diff->{'from_mode'});
4367                 }
4368
4369                 if ($diff->{'status'} eq "A") { # created
4370                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4371                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4372                         $mode_chng   .= "]</span>";
4373                         print "<td>";
4374                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4375                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4376                                       -class => "list"}, esc_path($diff->{'file'}));
4377                         print "</td>\n";
4378                         print "<td>$mode_chng</td>\n";
4379                         print "<td class=\"link\">";
4380                         if ($action eq 'commitdiff') {
4381                                 # link to patch
4382                                 $patchno++;
4383                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4384                                 print " | ";
4385                         }
4386                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4387                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4388                                       "blob");
4389                         print "</td>\n";
4390
4391                 } elsif ($diff->{'status'} eq "D") { # deleted
4392                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4393                         print "<td>";
4394                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4395                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4396                                        -class => "list"}, esc_path($diff->{'file'}));
4397                         print "</td>\n";
4398                         print "<td>$mode_chng</td>\n";
4399                         print "<td class=\"link\">";
4400                         if ($action eq 'commitdiff') {
4401                                 # link to patch
4402                                 $patchno++;
4403                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4404                                 print " | ";
4405                         }
4406                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4407                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4408                                       "blob") . " | ";
4409                         if ($have_blame) {
4410                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4411                                                              file_name=>$diff->{'file'})},
4412                                               "blame") . " | ";
4413                         }
4414                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4415                                                      file_name=>$diff->{'file'})},
4416                                       "history");
4417                         print "</td>\n";
4418
4419                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4420                         my $mode_chnge = "";
4421                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4422                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4423                                 if ($from_file_type ne $to_file_type) {
4424                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4425                                 }
4426                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4427                                         if ($from_mode_str && $to_mode_str) {
4428                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4429                                         } elsif ($to_mode_str) {
4430                                                 $mode_chnge .= " mode: $to_mode_str";
4431                                         }
4432                                 }
4433                                 $mode_chnge .= "]</span>\n";
4434                         }
4435                         print "<td>";
4436                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4437                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4438                                       -class => "list"}, esc_path($diff->{'file'}));
4439                         print "</td>\n";
4440                         print "<td>$mode_chnge</td>\n";
4441                         print "<td class=\"link\">";
4442                         if ($action eq 'commitdiff') {
4443                                 # link to patch
4444                                 $patchno++;
4445                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4446                                       " | ";
4447                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4448                                 # "commit" view and modified file (not onlu mode changed)
4449                                 print $cgi->a({-href => href(action=>"blobdiff",
4450                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4451                                                              hash_base=>$hash, hash_parent_base=>$parent,
4452                                                              file_name=>$diff->{'file'})},
4453                                               "diff") .
4454                                       " | ";
4455                         }
4456                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4457                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4458                                        "blob") . " | ";
4459                         if ($have_blame) {
4460                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4461                                                              file_name=>$diff->{'file'})},
4462                                               "blame") . " | ";
4463                         }
4464                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4465                                                      file_name=>$diff->{'file'})},
4466                                       "history");
4467                         print "</td>\n";
4468
4469                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4470                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4471                         my $nstatus = $status_name{$diff->{'status'}};
4472                         my $mode_chng = "";
4473                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4474                                 # mode also for directories, so we cannot use $to_mode_str
4475                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4476                         }
4477                         print "<td>" .
4478                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4479                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4480                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4481                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4482                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4483                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4484                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4485                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4486                               "<td class=\"link\">";
4487                         if ($action eq 'commitdiff') {
4488                                 # link to patch
4489                                 $patchno++;
4490                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4491                                       " | ";
4492                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4493                                 # "commit" view and modified file (not only pure rename or copy)
4494                                 print $cgi->a({-href => href(action=>"blobdiff",
4495                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4496                                                              hash_base=>$hash, hash_parent_base=>$parent,
4497                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4498                                               "diff") .
4499                                       " | ";
4500                         }
4501                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4502                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4503                                       "blob") . " | ";
4504                         if ($have_blame) {
4505                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4506                                                              file_name=>$diff->{'to_file'})},
4507                                               "blame") . " | ";
4508                         }
4509                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4510                                                     file_name=>$diff->{'to_file'})},
4511                                       "history");
4512                         print "</td>\n";
4513
4514                 } # we should not encounter Unmerged (U) or Unknown (X) status
4515                 print "</tr>\n";
4516         }
4517         print "</tbody>" if $has_header;
4518         print "</table>\n";
4519 }
4520
4521 sub git_patchset_body {
4522         my ($fd, $difftree, $hash, @hash_parents) = @_;
4523         my ($hash_parent) = $hash_parents[0];
4524
4525         my $is_combined = (@hash_parents > 1);
4526         my $patch_idx = 0;
4527         my $patch_number = 0;
4528         my $patch_line;
4529         my $diffinfo;
4530         my $to_name;
4531         my (%from, %to);
4532
4533         print "<div class=\"patchset\">\n";
4534
4535         # skip to first patch
4536         while ($patch_line = <$fd>) {
4537                 chomp $patch_line;
4538
4539                 last if ($patch_line =~ m/^diff /);
4540         }
4541
4542  PATCH:
4543         while ($patch_line) {
4544
4545                 # parse "git diff" header line
4546                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4547                         # $1 is from_name, which we do not use
4548                         $to_name = unquote($2);
4549                         $to_name =~ s!^b/!!;
4550                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4551                         # $1 is 'cc' or 'combined', which we do not use
4552                         $to_name = unquote($2);
4553                 } else {
4554                         $to_name = undef;
4555                 }
4556
4557                 # check if current patch belong to current raw line
4558                 # and parse raw git-diff line if needed
4559                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4560                         # this is continuation of a split patch
4561                         print "<div class=\"patch cont\">\n";
4562                 } else {
4563                         # advance raw git-diff output if needed
4564                         $patch_idx++ if defined $diffinfo;
4565
4566                         # read and prepare patch information
4567                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4568
4569                         # compact combined diff output can have some patches skipped
4570                         # find which patch (using pathname of result) we are at now;
4571                         if ($is_combined) {
4572                                 while ($to_name ne $diffinfo->{'to_file'}) {
4573                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4574                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4575                                               "</div>\n";  # class="patch"
4576
4577                                         $patch_idx++;
4578                                         $patch_number++;
4579
4580                                         last if $patch_idx > $#$difftree;
4581                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4582                                 }
4583                         }
4584
4585                         # modifies %from, %to hashes
4586                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4587
4588                         # this is first patch for raw difftree line with $patch_idx index
4589                         # we index @$difftree array from 0, but number patches from 1
4590                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4591                 }
4592
4593                 # git diff header
4594                 #assert($patch_line =~ m/^diff /) if DEBUG;
4595                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4596                 $patch_number++;
4597                 # print "git diff" header
4598                 print format_git_diff_header_line($patch_line, $diffinfo,
4599                                                   \%from, \%to);
4600
4601                 # print extended diff header
4602                 print "<div class=\"diff extended_header\">\n";
4603         EXTENDED_HEADER:
4604                 while ($patch_line = <$fd>) {
4605                         chomp $patch_line;
4606
4607                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4608
4609                         print format_extended_diff_header_line($patch_line, $diffinfo,
4610                                                                \%from, \%to);
4611                 }
4612                 print "</div>\n"; # class="diff extended_header"
4613
4614                 # from-file/to-file diff header
4615                 if (! $patch_line) {
4616                         print "</div>\n"; # class="patch"
4617                         last PATCH;
4618                 }
4619                 next PATCH if ($patch_line =~ m/^diff /);
4620                 #assert($patch_line =~ m/^---/) if DEBUG;
4621
4622                 my $last_patch_line = $patch_line;
4623                 $patch_line = <$fd>;
4624                 chomp $patch_line;
4625                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4626
4627                 print format_diff_from_to_header($last_patch_line, $patch_line,
4628                                                  $diffinfo, \%from, \%to,
4629                                                  @hash_parents);
4630
4631                 # the patch itself
4632         LINE:
4633                 while ($patch_line = <$fd>) {
4634                         chomp $patch_line;
4635
4636                         next PATCH if ($patch_line =~ m/^diff /);
4637
4638                         print format_diff_line($patch_line, \%from, \%to);
4639                 }
4640
4641         } continue {
4642                 print "</div>\n"; # class="patch"
4643         }
4644
4645         # for compact combined (--cc) format, with chunk and patch simplification
4646         # the patchset might be empty, but there might be unprocessed raw lines
4647         for (++$patch_idx if $patch_number > 0;
4648              $patch_idx < @$difftree;
4649              ++$patch_idx) {
4650                 # read and prepare patch information
4651                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4652
4653                 # generate anchor for "patch" links in difftree / whatchanged part
4654                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4655                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4656                       "</div>\n";  # class="patch"
4657
4658                 $patch_number++;
4659         }
4660
4661         if ($patch_number == 0) {
4662                 if (@hash_parents > 1) {
4663                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4664                 } else {
4665                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4666                 }
4667         }
4668
4669         print "</div>\n"; # class="patchset"
4670 }
4671
4672 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4673
4674 # fills project list info (age, description, owner, forks) for each
4675 # project in the list, removing invalid projects from returned list
4676 # NOTE: modifies $projlist, but does not remove entries from it
4677 sub fill_project_list_info {
4678         my ($projlist, $check_forks) = @_;
4679         my @projects;
4680
4681         my $show_ctags = gitweb_check_feature('ctags');
4682  PROJECT:
4683         foreach my $pr (@$projlist) {
4684                 my (@activity) = git_get_last_activity($pr->{'path'});
4685                 unless (@activity) {
4686                         next PROJECT;
4687                 }
4688                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4689                 if (!defined $pr->{'descr'}) {
4690                         my $descr = git_get_project_description($pr->{'path'}) || "";
4691                         $descr = to_utf8($descr);
4692                         $pr->{'descr_long'} = $descr;
4693                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4694                 }
4695                 if (!defined $pr->{'owner'}) {
4696                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4697                 }
4698                 if ($check_forks) {
4699                         my $pname = $pr->{'path'};
4700                         if (($pname =~ s/\.git$//) &&
4701                             ($pname !~ /\/$/) &&
4702                             (-d "$projectroot/$pname")) {
4703                                 $pr->{'forks'} = "-d $projectroot/$pname";
4704                         } else {
4705                                 $pr->{'forks'} = 0;
4706                         }
4707                 }
4708                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4709                 push @projects, $pr;
4710         }
4711
4712         return @projects;
4713 }
4714
4715 # print 'sort by' <th> element, generating 'sort by $name' replay link
4716 # if that order is not selected
4717 sub print_sort_th {
4718         print format_sort_th(@_);
4719 }
4720
4721 sub format_sort_th {
4722         my ($name, $order, $header) = @_;
4723         my $sort_th = "";
4724         $header ||= ucfirst($name);
4725
4726         if ($order eq $name) {
4727                 $sort_th .= "<th>$header</th>\n";
4728         } else {
4729                 $sort_th .= "<th>" .
4730                             $cgi->a({-href => href(-replay=>1, order=>$name),
4731                                      -class => "header"}, $header) .
4732                             "</th>\n";
4733         }
4734
4735         return $sort_th;
4736 }
4737
4738 sub git_project_list_body {
4739         # actually uses global variable $project
4740         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4741
4742         my $check_forks = gitweb_check_feature('forks');
4743         my @projects = fill_project_list_info($projlist, $check_forks);
4744
4745         $order ||= $default_projects_order;
4746         $from = 0 unless defined $from;
4747         $to = $#projects if (!defined $to || $#projects < $to);
4748
4749         my %order_info = (
4750                 project => { key => 'path', type => 'str' },
4751                 descr => { key => 'descr_long', type => 'str' },
4752                 owner => { key => 'owner', type => 'str' },
4753                 age => { key => 'age', type => 'num' }
4754         );
4755         my $oi = $order_info{$order};
4756         if ($oi->{'type'} eq 'str') {
4757                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4758         } else {
4759                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4760         }
4761
4762         my $show_ctags = gitweb_check_feature('ctags');
4763         if ($show_ctags) {
4764                 my %ctags;
4765                 foreach my $p (@projects) {
4766                         foreach my $ct (keys %{$p->{'ctags'}}) {
4767                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4768                         }
4769                 }
4770                 my $cloud = git_populate_project_tagcloud(\%ctags);
4771                 print git_show_project_tagcloud($cloud, 64);
4772         }
4773
4774         print "<table class=\"project_list\">\n";
4775         unless ($no_header) {
4776                 print "<tr>\n";
4777                 if ($check_forks) {
4778                         print "<th></th>\n";
4779                 }
4780                 print_sort_th('project', $order, 'Project');
4781                 print_sort_th('descr', $order, 'Description');
4782                 print_sort_th('owner', $order, 'Owner');
4783                 print_sort_th('age', $order, 'Last Change');
4784                 print "<th></th>\n" . # for links
4785                       "</tr>\n";
4786         }
4787         my $alternate = 1;
4788         my $tagfilter = $cgi->param('by_tag');
4789         for (my $i = $from; $i <= $to; $i++) {
4790                 my $pr = $projects[$i];
4791
4792                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4793                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4794                         and not $pr->{'descr_long'} =~ /$searchtext/;
4795                 # Weed out forks or non-matching entries of search
4796                 if ($check_forks) {
4797                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4798                         $forkbase="^$forkbase" if $forkbase;
4799                         next if not $searchtext and not $tagfilter and $show_ctags
4800                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4801                 }
4802
4803                 if ($alternate) {
4804                         print "<tr class=\"dark\">\n";
4805                 } else {
4806                         print "<tr class=\"light\">\n";
4807                 }
4808                 $alternate ^= 1;
4809                 if ($check_forks) {
4810                         print "<td>";
4811                         if ($pr->{'forks'}) {
4812                                 print "<!-- $pr->{'forks'} -->\n";
4813                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4814                         }
4815                         print "</td>\n";
4816                 }
4817                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4818                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4819                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4820                                         -class => "list", -title => $pr->{'descr_long'}},
4821                                         esc_html($pr->{'descr'})) . "</td>\n" .
4822                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4823                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4824                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4825                       "<td class=\"link\">" .
4826                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4827                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4828                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4829                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4830                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4831                       "</td>\n" .
4832                       "</tr>\n";
4833         }
4834         if (defined $extra) {
4835                 print "<tr>\n";
4836                 if ($check_forks) {
4837                         print "<td></td>\n";
4838                 }
4839                 print "<td colspan=\"5\">$extra</td>\n" .
4840                       "</tr>\n";
4841         }
4842         print "</table>\n";
4843 }
4844
4845 sub git_log_body {
4846         # uses global variable $project
4847         my ($commitlist, $from, $to, $refs, $extra) = @_;
4848
4849         $from = 0 unless defined $from;
4850         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4851
4852         for (my $i = 0; $i <= $to; $i++) {
4853                 my %co = %{$commitlist->[$i]};
4854                 next if !%co;
4855                 my $commit = $co{'id'};
4856                 my $ref = format_ref_marker($refs, $commit);
4857                 my %ad = parse_date($co{'author_epoch'});
4858                 git_print_header_div('commit',
4859                                "<span class=\"age\">$co{'age_string'}</span>" .
4860                                esc_html($co{'title'}) . $ref,
4861                                $commit);
4862                 print "<div class=\"title_text\">\n" .
4863                       "<div class=\"log_link\">\n" .
4864                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4865                       " | " .
4866                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4867                       " | " .
4868                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4869                       "<br/>\n" .
4870                       "</div>\n";
4871                       git_print_authorship(\%co, -tag => 'span');
4872                       print "<br/>\n</div>\n";
4873
4874                 print "<div class=\"log_body\">\n";
4875                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4876                 print "</div>\n";
4877         }
4878         if ($extra) {
4879                 print "<div class=\"page_nav\">\n";
4880                 print "$extra\n";
4881                 print "</div>\n";
4882         }
4883 }
4884
4885 sub git_shortlog_body {
4886         # uses global variable $project
4887         my ($commitlist, $from, $to, $refs, $extra) = @_;
4888
4889         $from = 0 unless defined $from;
4890         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4891
4892         print "<table class=\"shortlog\">\n";
4893         my $alternate = 1;
4894         for (my $i = $from; $i <= $to; $i++) {
4895                 my %co = %{$commitlist->[$i]};
4896                 my $commit = $co{'id'};
4897                 my $ref = format_ref_marker($refs, $commit);
4898                 if ($alternate) {
4899                         print "<tr class=\"dark\">\n";
4900                 } else {
4901                         print "<tr class=\"light\">\n";
4902                 }
4903                 $alternate ^= 1;
4904                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4905                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4906                       format_author_html('td', \%co, 10) . "<td>";
4907                 print format_subject_html($co{'title'}, $co{'title_short'},
4908                                           href(action=>"commit", hash=>$commit), $ref);
4909                 print "</td>\n" .
4910                       "<td class=\"link\">" .
4911                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4912                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4913                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4914                 my $snapshot_links = format_snapshot_links($commit);
4915                 if (defined $snapshot_links) {
4916                         print " | " . $snapshot_links;
4917                 }
4918                 print "</td>\n" .
4919                       "</tr>\n";
4920         }
4921         if (defined $extra) {
4922                 print "<tr>\n" .
4923                       "<td colspan=\"4\">$extra</td>\n" .
4924                       "</tr>\n";
4925         }
4926         print "</table>\n";
4927 }
4928
4929 sub git_history_body {
4930         # Warning: assumes constant type (blob or tree) during history
4931         my ($commitlist, $from, $to, $refs, $extra,
4932             $file_name, $file_hash, $ftype) = @_;
4933
4934         $from = 0 unless defined $from;
4935         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4936
4937         print "<table class=\"history\">\n";
4938         my $alternate = 1;
4939         for (my $i = $from; $i <= $to; $i++) {
4940                 my %co = %{$commitlist->[$i]};
4941                 if (!%co) {
4942                         next;
4943                 }
4944                 my $commit = $co{'id'};
4945
4946                 my $ref = format_ref_marker($refs, $commit);
4947
4948                 if ($alternate) {
4949                         print "<tr class=\"dark\">\n";
4950                 } else {
4951                         print "<tr class=\"light\">\n";
4952                 }
4953                 $alternate ^= 1;
4954                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4955         # shortlog:   format_author_html('td', \%co, 10)
4956                       format_author_html('td', \%co, 15, 3) . "<td>";
4957                 # originally git_history used chop_str($co{'title'}, 50)
4958                 print format_subject_html($co{'title'}, $co{'title_short'},
4959                                           href(action=>"commit", hash=>$commit), $ref);
4960                 print "</td>\n" .
4961                       "<td class=\"link\">" .
4962                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
4963                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
4964
4965                 if ($ftype eq 'blob') {
4966                         my $blob_current = $file_hash;
4967                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
4968                         if (defined $blob_current && defined $blob_parent &&
4969                                         $blob_current ne $blob_parent) {
4970                                 print " | " .
4971                                         $cgi->a({-href => href(action=>"blobdiff",
4972                                                                hash=>$blob_current, hash_parent=>$blob_parent,
4973                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
4974                                                                file_name=>$file_name)},
4975                                                 "diff to current");
4976                         }
4977                 }
4978                 print "</td>\n" .
4979                       "</tr>\n";
4980         }
4981         if (defined $extra) {
4982                 print "<tr>\n" .
4983                       "<td colspan=\"4\">$extra</td>\n" .
4984                       "</tr>\n";
4985         }
4986         print "</table>\n";
4987 }
4988
4989 sub git_tags_body {
4990         # uses global variable $project
4991         my ($taglist, $from, $to, $extra) = @_;
4992         $from = 0 unless defined $from;
4993         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
4994
4995         print "<table class=\"tags\">\n";
4996         my $alternate = 1;
4997         for (my $i = $from; $i <= $to; $i++) {
4998                 my $entry = $taglist->[$i];
4999                 my %tag = %$entry;
5000                 my $comment = $tag{'subject'};
5001                 my $comment_short;
5002                 if (defined $comment) {
5003                         $comment_short = chop_str($comment, 30, 5);
5004                 }
5005                 if ($alternate) {
5006                         print "<tr class=\"dark\">\n";
5007                 } else {
5008                         print "<tr class=\"light\">\n";
5009                 }
5010                 $alternate ^= 1;
5011                 if (defined $tag{'age'}) {
5012                         print "<td><i>$tag{'age'}</i></td>\n";
5013                 } else {
5014                         print "<td></td>\n";
5015                 }
5016                 print "<td>" .
5017                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5018                                -class => "list name"}, esc_html($tag{'name'})) .
5019                       "</td>\n" .
5020                       "<td>";
5021                 if (defined $comment) {
5022                         print format_subject_html($comment, $comment_short,
5023                                                   href(action=>"tag", hash=>$tag{'id'}));
5024                 }
5025                 print "</td>\n" .
5026                       "<td class=\"selflink\">";
5027                 if ($tag{'type'} eq "tag") {
5028                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5029                 } else {
5030                         print "&nbsp;";
5031                 }
5032                 print "</td>\n" .
5033                       "<td class=\"link\">" . " | " .
5034                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5035                 if ($tag{'reftype'} eq "commit") {
5036                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5037                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5038                 } elsif ($tag{'reftype'} eq "blob") {
5039                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5040                 }
5041                 print "</td>\n" .
5042                       "</tr>";
5043         }
5044         if (defined $extra) {
5045                 print "<tr>\n" .
5046                       "<td colspan=\"5\">$extra</td>\n" .
5047                       "</tr>\n";
5048         }
5049         print "</table>\n";
5050 }
5051
5052 sub git_heads_body {
5053         # uses global variable $project
5054         my ($headlist, $head, $from, $to, $extra) = @_;
5055         $from = 0 unless defined $from;
5056         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5057
5058         print "<table class=\"heads\">\n";
5059         my $alternate = 1;
5060         for (my $i = $from; $i <= $to; $i++) {
5061                 my $entry = $headlist->[$i];
5062                 my %ref = %$entry;
5063                 my $curr = $ref{'id'} eq $head;
5064                 if ($alternate) {
5065                         print "<tr class=\"dark\">\n";
5066                 } else {
5067                         print "<tr class=\"light\">\n";
5068                 }
5069                 $alternate ^= 1;
5070                 print "<td><i>$ref{'age'}</i></td>\n" .
5071                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5072                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5073                                -class => "list name"},esc_html($ref{'name'})) .
5074                       "</td>\n" .
5075                       "<td class=\"link\">" .
5076                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5077                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5078                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5079                       "</td>\n" .
5080                       "</tr>";
5081         }
5082         if (defined $extra) {
5083                 print "<tr>\n" .
5084                       "<td colspan=\"3\">$extra</td>\n" .
5085                       "</tr>\n";
5086         }
5087         print "</table>\n";
5088 }
5089
5090 # Display a single remote block
5091 sub git_remote_block {
5092         my ($remote, $rdata, $limit, $head) = @_;
5093
5094         my $heads = $rdata->{'heads'};
5095         my $fetch = $rdata->{'fetch'};
5096         my $push = $rdata->{'push'};
5097
5098         my $urls_table = "<table class=\"projects_list\">\n" ;
5099
5100         if (defined $fetch) {
5101                 if ($fetch eq $push) {
5102                         $urls_table .= format_repo_url("URL", $fetch);
5103                 } else {
5104                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5105                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5106                 }
5107         } elsif (defined $push) {
5108                 $urls_table .= format_repo_url("Push URL", $push);
5109         } else {
5110                 $urls_table .= format_repo_url("", "No remote URL");
5111         }
5112
5113         $urls_table .= "</table>\n";
5114
5115         my $dots;
5116         if (defined $limit && $limit < @$heads) {
5117                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5118         }
5119
5120         print $urls_table;
5121         git_heads_body($heads, $head, 0, $limit, $dots);
5122 }
5123
5124 # Display a list of remote names with the respective fetch and push URLs
5125 sub git_remotes_list {
5126         my ($remotedata, $limit) = @_;
5127         print "<table class=\"heads\">\n";
5128         my $alternate = 1;
5129         my @remotes = sort keys %$remotedata;
5130
5131         my $limited = $limit && $limit < @remotes;
5132
5133         $#remotes = $limit - 1 if $limited;
5134
5135         while (my $remote = shift @remotes) {
5136                 my $rdata = $remotedata->{$remote};
5137                 my $fetch = $rdata->{'fetch'};
5138                 my $push = $rdata->{'push'};
5139                 if ($alternate) {
5140                         print "<tr class=\"dark\">\n";
5141                 } else {
5142                         print "<tr class=\"light\">\n";
5143                 }
5144                 $alternate ^= 1;
5145                 print "<td>" .
5146                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5147                                -class=> "list name"},esc_html($remote)) .
5148                       "</td>";
5149                 print "<td class=\"link\">" .
5150                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5151                       " | " .
5152                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5153                       "</td>";
5154
5155                 print "</tr>\n";
5156         }
5157
5158         if ($limited) {
5159                 print "<tr>\n" .
5160                       "<td colspan=\"3\">" .
5161                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5162                       "</td>\n" . "</tr>\n";
5163         }
5164
5165         print "</table>";
5166 }
5167
5168 # Display remote heads grouped by remote, unless there are too many
5169 # remotes, in which case we only display the remote names
5170 sub git_remotes_body {
5171         my ($remotedata, $limit, $head) = @_;
5172         if ($limit and $limit < keys %$remotedata) {
5173                 git_remotes_list($remotedata, $limit);
5174         } else {
5175                 fill_remote_heads($remotedata);
5176                 while (my ($remote, $rdata) = each %$remotedata) {
5177                         git_print_section({-class=>"remote", -id=>$remote},
5178                                 ["remotes", $remote, $remote], sub {
5179                                         git_remote_block($remote, $rdata, $limit, $head);
5180                                 });
5181                 }
5182         }
5183 }
5184
5185 sub git_search_grep_body {
5186         my ($commitlist, $from, $to, $extra) = @_;
5187         $from = 0 unless defined $from;
5188         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5189
5190         print "<table class=\"commit_search\">\n";
5191         my $alternate = 1;
5192         for (my $i = $from; $i <= $to; $i++) {
5193                 my %co = %{$commitlist->[$i]};
5194                 if (!%co) {
5195                         next;
5196                 }
5197                 my $commit = $co{'id'};
5198                 if ($alternate) {
5199                         print "<tr class=\"dark\">\n";
5200                 } else {
5201                         print "<tr class=\"light\">\n";
5202                 }
5203                 $alternate ^= 1;
5204                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5205                       format_author_html('td', \%co, 15, 5) .
5206                       "<td>" .
5207                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5208                                -class => "list subject"},
5209                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5210                 my $comment = $co{'comment'};
5211                 foreach my $line (@$comment) {
5212                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5213                                 my ($lead, $match, $trail) = ($1, $2, $3);
5214                                 $match = chop_str($match, 70, 5, 'center');
5215                                 my $contextlen = int((80 - length($match))/2);
5216                                 $contextlen = 30 if ($contextlen > 30);
5217                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5218                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5219
5220                                 $lead  = esc_html($lead);
5221                                 $match = esc_html($match);
5222                                 $trail = esc_html($trail);
5223
5224                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5225                         }
5226                 }
5227                 print "</td>\n" .
5228                       "<td class=\"link\">" .
5229                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5230                       " | " .
5231                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5232                       " | " .
5233                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5234                 print "</td>\n" .
5235                       "</tr>\n";
5236         }
5237         if (defined $extra) {
5238                 print "<tr>\n" .
5239                       "<td colspan=\"3\">$extra</td>\n" .
5240                       "</tr>\n";
5241         }
5242         print "</table>\n";
5243 }
5244
5245 ## ======================================================================
5246 ## ======================================================================
5247 ## actions
5248
5249 sub git_project_list {
5250         my $order = $input_params{'order'};
5251         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5252                 die_error(400, "Unknown order parameter");
5253         }
5254
5255         my @list = git_get_projects_list();
5256         if (!@list) {
5257                 die_error(404, "No projects found");
5258         }
5259
5260         git_header_html();
5261         if (defined $home_text && -f $home_text) {
5262                 print "<div class=\"index_include\">\n";
5263                 insert_file($home_text);
5264                 print "</div>\n";
5265         }
5266         print $cgi->startform(-method => "get") .
5267               "<p class=\"projsearch\">Search:\n" .
5268               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5269               "</p>" .
5270               $cgi->end_form() . "\n";
5271         git_project_list_body(\@list, $order);
5272         git_footer_html();
5273 }
5274
5275 sub git_forks {
5276         my $order = $input_params{'order'};
5277         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5278                 die_error(400, "Unknown order parameter");
5279         }
5280
5281         my @list = git_get_projects_list($project);
5282         if (!@list) {
5283                 die_error(404, "No forks found");
5284         }
5285
5286         git_header_html();
5287         git_print_page_nav('','');
5288         git_print_header_div('summary', "$project forks");
5289         git_project_list_body(\@list, $order);
5290         git_footer_html();
5291 }
5292
5293 sub git_project_index {
5294         my @projects = git_get_projects_list($project);
5295
5296         print $cgi->header(
5297                 -type => 'text/plain',
5298                 -charset => 'utf-8',
5299                 -content_disposition => 'inline; filename="index.aux"');
5300
5301         foreach my $pr (@projects) {
5302                 if (!exists $pr->{'owner'}) {
5303                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5304                 }
5305
5306                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5307                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5308                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5309                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5310                 $path  =~ s/ /\+/g;
5311                 $owner =~ s/ /\+/g;
5312
5313                 print "$path $owner\n";
5314         }
5315 }
5316
5317 sub git_summary {
5318         my $descr = git_get_project_description($project) || "none";
5319         my %co = parse_commit("HEAD");
5320         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5321         my $head = $co{'id'};
5322         my $remote_heads = gitweb_check_feature('remote_heads');
5323
5324         my $owner = git_get_project_owner($project);
5325
5326         my $refs = git_get_references();
5327         # These get_*_list functions return one more to allow us to see if
5328         # there are more ...
5329         my @taglist  = git_get_tags_list(16);
5330         my @headlist = git_get_heads_list(16);
5331         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5332         my @forklist;
5333         my $check_forks = gitweb_check_feature('forks');
5334
5335         if ($check_forks) {
5336                 @forklist = git_get_projects_list($project);
5337         }
5338
5339         git_header_html();
5340         git_print_page_nav('summary','', $head);
5341
5342         print "<div class=\"title\">&nbsp;</div>\n";
5343         print "<table class=\"projects_list\">\n" .
5344               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5345               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5346         if (defined $cd{'rfc2822'}) {
5347                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
5348         }
5349
5350         # use per project git URL list in $projectroot/$project/cloneurl
5351         # or make project git URL from git base URL and project name
5352         my $url_tag = "URL";
5353         my @url_list = git_get_project_url_list($project);
5354         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5355         foreach my $git_url (@url_list) {
5356                 next unless $git_url;
5357                 print format_repo_url($url_tag, $git_url);
5358                 $url_tag = "";
5359         }
5360
5361         # Tag cloud
5362         my $show_ctags = gitweb_check_feature('ctags');
5363         if ($show_ctags) {
5364                 my $ctags = git_get_project_ctags($project);
5365                 my $cloud = git_populate_project_tagcloud($ctags);
5366                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
5367                 print "</td>\n<td>" unless %$ctags;
5368                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
5369                 print "</td>\n<td>" if %$ctags;
5370                 print git_show_project_tagcloud($cloud, 48);
5371                 print "</td></tr>";
5372         }
5373
5374         print "</table>\n";
5375
5376         # If XSS prevention is on, we don't include README.html.
5377         # TODO: Allow a readme in some safe format.
5378         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5379                 print "<div class=\"title\">readme</div>\n" .
5380                       "<div class=\"readme\">\n";
5381                 insert_file("$projectroot/$project/README.html");
5382                 print "\n</div>\n"; # class="readme"
5383         }
5384
5385         # we need to request one more than 16 (0..15) to check if
5386         # those 16 are all
5387         my @commitlist = $head ? parse_commits($head, 17) : ();
5388         if (@commitlist) {
5389                 git_print_header_div('shortlog');
5390                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5391                                   $#commitlist <=  15 ? undef :
5392                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5393         }
5394
5395         if (@taglist) {
5396                 git_print_header_div('tags');
5397                 git_tags_body(\@taglist, 0, 15,
5398                               $#taglist <=  15 ? undef :
5399                               $cgi->a({-href => href(action=>"tags")}, "..."));
5400         }
5401
5402         if (@headlist) {
5403                 git_print_header_div('heads');
5404                 git_heads_body(\@headlist, $head, 0, 15,
5405                                $#headlist <= 15 ? undef :
5406                                $cgi->a({-href => href(action=>"heads")}, "..."));
5407         }
5408
5409         if (%remotedata) {
5410                 git_print_header_div('remotes');
5411                 git_remotes_body(\%remotedata, 15, $head);
5412         }
5413
5414         if (@forklist) {
5415                 git_print_header_div('forks');
5416                 git_project_list_body(\@forklist, 'age', 0, 15,
5417                                       $#forklist <= 15 ? undef :
5418                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5419                                       'no_header');
5420         }
5421
5422         git_footer_html();
5423 }
5424
5425 sub git_tag {
5426         my %tag = parse_tag($hash);
5427
5428         if (! %tag) {
5429                 die_error(404, "Unknown tag object");
5430         }
5431
5432         my $head = git_get_head_hash($project);
5433         git_header_html();
5434         git_print_page_nav('','', $head,undef,$head);
5435         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5436         print "<div class=\"title_text\">\n" .
5437               "<table class=\"object_header\">\n" .
5438               "<tr>\n" .
5439               "<td>object</td>\n" .
5440               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5441                                $tag{'object'}) . "</td>\n" .
5442               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5443                                               $tag{'type'}) . "</td>\n" .
5444               "</tr>\n";
5445         if (defined($tag{'author'})) {
5446                 git_print_authorship_rows(\%tag, 'author');
5447         }
5448         print "</table>\n\n" .
5449               "</div>\n";
5450         print "<div class=\"page_body\">";
5451         my $comment = $tag{'comment'};
5452         foreach my $line (@$comment) {
5453                 chomp $line;
5454                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5455         }
5456         print "</div>\n";
5457         git_footer_html();
5458 }
5459
5460 sub git_blame_common {
5461         my $format = shift || 'porcelain';
5462         if ($format eq 'porcelain' && $cgi->param('js')) {
5463                 $format = 'incremental';
5464                 $action = 'blame_incremental'; # for page title etc
5465         }
5466
5467         # permissions
5468         gitweb_check_feature('blame')
5469                 or die_error(403, "Blame view not allowed");
5470
5471         # error checking
5472         die_error(400, "No file name given") unless $file_name;
5473         $hash_base ||= git_get_head_hash($project);
5474         die_error(404, "Couldn't find base commit") unless $hash_base;
5475         my %co = parse_commit($hash_base)
5476                 or die_error(404, "Commit not found");
5477         my $ftype = "blob";
5478         if (!defined $hash) {
5479                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5480                         or die_error(404, "Error looking up file");
5481         } else {
5482                 $ftype = git_get_type($hash);
5483                 if ($ftype !~ "blob") {
5484                         die_error(400, "Object is not a blob");
5485                 }
5486         }
5487
5488         my $fd;
5489         if ($format eq 'incremental') {
5490                 # get file contents (as base)
5491                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5492                         or die_error(500, "Open git-cat-file failed");
5493         } elsif ($format eq 'data') {
5494                 # run git-blame --incremental
5495                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5496                         $hash_base, "--", $file_name
5497                         or die_error(500, "Open git-blame --incremental failed");
5498         } else {
5499                 # run git-blame --porcelain
5500                 open $fd, "-|", git_cmd(), "blame", '-p',
5501                         $hash_base, '--', $file_name
5502                         or die_error(500, "Open git-blame --porcelain failed");
5503         }
5504
5505         # incremental blame data returns early
5506         if ($format eq 'data') {
5507                 print $cgi->header(
5508                         -type=>"text/plain", -charset => "utf-8",
5509                         -status=> "200 OK");
5510                 local $| = 1; # output autoflush
5511                 print while <$fd>;
5512                 close $fd
5513                         or print "ERROR $!\n";
5514
5515                 print 'END';
5516                 if (defined $t0 && gitweb_check_feature('timed')) {
5517                         print ' '.
5518                               tv_interval($t0, [ gettimeofday() ]).
5519                               ' '.$number_of_git_cmds;
5520                 }
5521                 print "\n";
5522
5523                 return;
5524         }
5525
5526         # page header
5527         git_header_html();
5528         my $formats_nav =
5529                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5530                         "blob") .
5531                 " | ";
5532         if ($format eq 'incremental') {
5533                 $formats_nav .=
5534                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5535                                 "blame") . " (non-incremental)";
5536         } else {
5537                 $formats_nav .=
5538                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5539                                 "blame") . " (incremental)";
5540         }
5541         $formats_nav .=
5542                 " | " .
5543                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5544                         "history") .
5545                 " | " .
5546                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5547                         "HEAD");
5548         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5549         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5550         git_print_page_path($file_name, $ftype, $hash_base);
5551
5552         # page body
5553         if ($format eq 'incremental') {
5554                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5555                       "This page requires JavaScript to run.\n Use ".
5556                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5557                               'this page').
5558                       " instead.\n".
5559                       "</b></center></div>\n</noscript>\n";
5560
5561                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5562         }
5563
5564         print qq!<div class="page_body">\n!;
5565         print qq!<div id="progress_info">... / ...</div>\n!
5566                 if ($format eq 'incremental');
5567         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5568               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5569               qq!<thead>\n!.
5570               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5571               qq!</thead>\n!.
5572               qq!<tbody>\n!;
5573
5574         my @rev_color = qw(light dark);
5575         my $num_colors = scalar(@rev_color);
5576         my $current_color = 0;
5577
5578         if ($format eq 'incremental') {
5579                 my $color_class = $rev_color[$current_color];
5580
5581                 #contents of a file
5582                 my $linenr = 0;
5583         LINE:
5584                 while (my $line = <$fd>) {
5585                         chomp $line;
5586                         $linenr++;
5587
5588                         print qq!<tr id="l$linenr" class="$color_class">!.
5589                               qq!<td class="sha1"><a href=""> </a></td>!.
5590                               qq!<td class="linenr">!.
5591                               qq!<a class="linenr" href="">$linenr</a></td>!;
5592                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5593                         print qq!</tr>\n!;
5594                 }
5595
5596         } else { # porcelain, i.e. ordinary blame
5597                 my %metainfo = (); # saves information about commits
5598
5599                 # blame data
5600         LINE:
5601                 while (my $line = <$fd>) {
5602                         chomp $line;
5603                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5604                         # no <lines in group> for subsequent lines in group of lines
5605                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5606                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5607                         if (!exists $metainfo{$full_rev}) {
5608                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5609                         }
5610                         my $meta = $metainfo{$full_rev};
5611                         my $data;
5612                         while ($data = <$fd>) {
5613                                 chomp $data;
5614                                 last if ($data =~ s/^\t//); # contents of line
5615                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5616                                         $meta->{$1} = $2 unless exists $meta->{$1};
5617                                 }
5618                                 if ($data =~ /^previous /) {
5619                                         $meta->{'nprevious'}++;
5620                                 }
5621                         }
5622                         my $short_rev = substr($full_rev, 0, 8);
5623                         my $author = $meta->{'author'};
5624                         my %date =
5625                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5626                         my $date = $date{'iso-tz'};
5627                         if ($group_size) {
5628                                 $current_color = ($current_color + 1) % $num_colors;
5629                         }
5630                         my $tr_class = $rev_color[$current_color];
5631                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5632                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5633                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5634                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5635                         if ($group_size) {
5636                                 print "<td class=\"sha1\"";
5637                                 print " title=\"". esc_html($author) . ", $date\"";
5638                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5639                                 print ">";
5640                                 print $cgi->a({-href => href(action=>"commit",
5641                                                              hash=>$full_rev,
5642                                                              file_name=>$file_name)},
5643                                               esc_html($short_rev));
5644                                 if ($group_size >= 2) {
5645                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5646                                         if (@author_initials) {
5647                                                 print "<br />" .
5648                                                       esc_html(join('', @author_initials));
5649                                                 #           or join('.', ...)
5650                                         }
5651                                 }
5652                                 print "</td>\n";
5653                         }
5654                         # 'previous' <sha1 of parent commit> <filename at commit>
5655                         if (exists $meta->{'previous'} &&
5656                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5657                                 $meta->{'parent'} = $1;
5658                                 $meta->{'file_parent'} = unquote($2);
5659                         }
5660                         my $linenr_commit =
5661                                 exists($meta->{'parent'}) ?
5662                                 $meta->{'parent'} : $full_rev;
5663                         my $linenr_filename =
5664                                 exists($meta->{'file_parent'}) ?
5665                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5666                         my $blamed = href(action => 'blame',
5667                                           file_name => $linenr_filename,
5668                                           hash_base => $linenr_commit);
5669                         print "<td class=\"linenr\">";
5670                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5671                                         -class => "linenr" },
5672                                       esc_html($lineno));
5673                         print "</td>";
5674                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5675                         print "</tr>\n";
5676                 } # end while
5677
5678         }
5679
5680         # footer
5681         print "</tbody>\n".
5682               "</table>\n"; # class="blame"
5683         print "</div>\n";   # class="blame_body"
5684         close $fd
5685                 or print "Reading blob failed\n";
5686
5687         git_footer_html();
5688 }
5689
5690 sub git_blame {
5691         git_blame_common();
5692 }
5693
5694 sub git_blame_incremental {
5695         git_blame_common('incremental');
5696 }
5697
5698 sub git_blame_data {
5699         git_blame_common('data');
5700 }
5701
5702 sub git_tags {
5703         my $head = git_get_head_hash($project);
5704         git_header_html();
5705         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
5706         git_print_header_div('summary', $project);
5707
5708         my @tagslist = git_get_tags_list();
5709         if (@tagslist) {
5710                 git_tags_body(\@tagslist);
5711         }
5712         git_footer_html();
5713 }
5714
5715 sub git_heads {
5716         my $head = git_get_head_hash($project);
5717         git_header_html();
5718         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
5719         git_print_header_div('summary', $project);
5720
5721         my @headslist = git_get_heads_list();
5722         if (@headslist) {
5723                 git_heads_body(\@headslist, $head);
5724         }
5725         git_footer_html();
5726 }
5727
5728 # used both for single remote view and for list of all the remotes
5729 sub git_remotes {
5730         gitweb_check_feature('remote_heads')
5731                 or die_error(403, "Remote heads view is disabled");
5732
5733         my $head = git_get_head_hash($project);
5734         my $remote = $input_params{'hash'};
5735
5736         my $remotedata = git_get_remotes_list($remote);
5737         die_error(500, "Unable to get remote information") unless defined $remotedata;
5738
5739         unless (%$remotedata) {
5740                 die_error(404, defined $remote ?
5741                         "Remote $remote not found" :
5742                         "No remotes found");
5743         }
5744
5745         git_header_html(undef, undef, -action_extra => $remote);
5746         git_print_page_nav('', '',  $head, undef, $head,
5747                 format_ref_views($remote ? '' : 'remotes'));
5748
5749         fill_remote_heads($remotedata);
5750         if (defined $remote) {
5751                 git_print_header_div('remotes', "$remote remote for $project");
5752                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
5753         } else {
5754                 git_print_header_div('summary', "$project remotes");
5755                 git_remotes_body($remotedata, undef, $head);
5756         }
5757
5758         git_footer_html();
5759 }
5760
5761 sub git_blob_plain {
5762         my $type = shift;
5763         my $expires;
5764
5765         if (!defined $hash) {
5766                 if (defined $file_name) {
5767                         my $base = $hash_base || git_get_head_hash($project);
5768                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5769                                 or die_error(404, "Cannot find file");
5770                 } else {
5771                         die_error(400, "No file name defined");
5772                 }
5773         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5774                 # blobs defined by non-textual hash id's can be cached
5775                 $expires = "+1d";
5776         }
5777
5778         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5779                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5780
5781         # content-type (can include charset)
5782         $type = blob_contenttype($fd, $file_name, $type);
5783
5784         # "save as" filename, even when no $file_name is given
5785         my $save_as = "$hash";
5786         if (defined $file_name) {
5787                 $save_as = $file_name;
5788         } elsif ($type =~ m/^text\//) {
5789                 $save_as .= '.txt';
5790         }
5791
5792         # With XSS prevention on, blobs of all types except a few known safe
5793         # ones are served with "Content-Disposition: attachment" to make sure
5794         # they don't run in our security domain.  For certain image types,
5795         # blob view writes an <img> tag referring to blob_plain view, and we
5796         # want to be sure not to break that by serving the image as an
5797         # attachment (though Firefox 3 doesn't seem to care).
5798         my $sandbox = $prevent_xss &&
5799                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5800
5801         print $cgi->header(
5802                 -type => $type,
5803                 -expires => $expires,
5804                 -content_disposition =>
5805                         ($sandbox ? 'attachment' : 'inline')
5806                         . '; filename="' . $save_as . '"');
5807         local $/ = undef;
5808         binmode STDOUT, ':raw';
5809         print <$fd>;
5810         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5811         close $fd;
5812 }
5813
5814 sub git_blob {
5815         my $expires;
5816
5817         if (!defined $hash) {
5818                 if (defined $file_name) {
5819                         my $base = $hash_base || git_get_head_hash($project);
5820                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5821                                 or die_error(404, "Cannot find file");
5822                 } else {
5823                         die_error(400, "No file name defined");
5824                 }
5825         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5826                 # blobs defined by non-textual hash id's can be cached
5827                 $expires = "+1d";
5828         }
5829
5830         my $have_blame = gitweb_check_feature('blame');
5831         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5832                 or die_error(500, "Couldn't cat $file_name, $hash");
5833         my $mimetype = blob_mimetype($fd, $file_name);
5834         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
5835         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5836                 close $fd;
5837                 return git_blob_plain($mimetype);
5838         }
5839         # we can have blame only for text/* mimetype
5840         $have_blame &&= ($mimetype =~ m!^text/!);
5841
5842         my $highlight = gitweb_check_feature('highlight');
5843         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
5844         $fd = run_highlighter($fd, $highlight, $syntax)
5845                 if $syntax;
5846
5847         git_header_html(undef, $expires);
5848         my $formats_nav = '';
5849         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5850                 if (defined $file_name) {
5851                         if ($have_blame) {
5852                                 $formats_nav .=
5853                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5854                                                 "blame") .
5855                                         " | ";
5856                         }
5857                         $formats_nav .=
5858                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5859                                         "history") .
5860                                 " | " .
5861                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5862                                         "raw") .
5863                                 " | " .
5864                                 $cgi->a({-href => href(action=>"blob",
5865                                                        hash_base=>"HEAD", file_name=>$file_name)},
5866                                         "HEAD");
5867                 } else {
5868                         $formats_nav .=
5869                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5870                                         "raw");
5871                 }
5872                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5873                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5874         } else {
5875                 print "<div class=\"page_nav\">\n" .
5876                       "<br/><br/></div>\n" .
5877                       "<div class=\"title\">$hash</div>\n";
5878         }
5879         git_print_page_path($file_name, "blob", $hash_base);
5880         print "<div class=\"page_body\">\n";
5881         if ($mimetype =~ m!^image/!) {
5882                 print qq!<img type="$mimetype"!;
5883                 if ($file_name) {
5884                         print qq! alt="$file_name" title="$file_name"!;
5885                 }
5886                 print qq! src="! .
5887                       href(action=>"blob_plain", hash=>$hash,
5888                            hash_base=>$hash_base, file_name=>$file_name) .
5889                       qq!" />\n!;
5890         } else {
5891                 my $nr;
5892                 while (my $line = <$fd>) {
5893                         chomp $line;
5894                         $nr++;
5895                         $line = untabify($line);
5896                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
5897                                $nr, href(-replay => 1), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
5898                 }
5899         }
5900         close $fd
5901                 or print "Reading blob failed.\n";
5902         print "</div>";
5903         git_footer_html();
5904 }
5905
5906 sub git_tree {
5907         if (!defined $hash_base) {
5908                 $hash_base = "HEAD";
5909         }
5910         if (!defined $hash) {
5911                 if (defined $file_name) {
5912                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5913                 } else {
5914                         $hash = $hash_base;
5915                 }
5916         }
5917         die_error(404, "No such tree") unless defined($hash);
5918
5919         my $show_sizes = gitweb_check_feature('show-sizes');
5920         my $have_blame = gitweb_check_feature('blame');
5921
5922         my @entries = ();
5923         {
5924                 local $/ = "\0";
5925                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5926                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5927                         or die_error(500, "Open git-ls-tree failed");
5928                 @entries = map { chomp; $_ } <$fd>;
5929                 close $fd
5930                         or die_error(404, "Reading tree failed");
5931         }
5932
5933         my $refs = git_get_references();
5934         my $ref = format_ref_marker($refs, $hash_base);
5935         git_header_html();
5936         my $basedir = '';
5937         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5938                 my @views_nav = ();
5939                 if (defined $file_name) {
5940                         push @views_nav,
5941                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5942                                         "history"),
5943                                 $cgi->a({-href => href(action=>"tree",
5944                                                        hash_base=>"HEAD", file_name=>$file_name)},
5945                                         "HEAD"),
5946                 }
5947                 my $snapshot_links = format_snapshot_links($hash);
5948                 if (defined $snapshot_links) {
5949                         # FIXME: Should be available when we have no hash base as well.
5950                         push @views_nav, $snapshot_links;
5951                 }
5952                 git_print_page_nav('tree','', $hash_base, undef, undef,
5953                                    join(' | ', @views_nav));
5954                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
5955         } else {
5956                 undef $hash_base;
5957                 print "<div class=\"page_nav\">\n";
5958                 print "<br/><br/></div>\n";
5959                 print "<div class=\"title\">$hash</div>\n";
5960         }
5961         if (defined $file_name) {
5962                 $basedir = $file_name;
5963                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
5964                         $basedir .= '/';
5965                 }
5966                 git_print_page_path($file_name, 'tree', $hash_base);
5967         }
5968         print "<div class=\"page_body\">\n";
5969         print "<table class=\"tree\">\n";
5970         my $alternate = 1;
5971         # '..' (top directory) link if possible
5972         if (defined $hash_base &&
5973             defined $file_name && $file_name =~ m![^/]+$!) {
5974                 if ($alternate) {
5975                         print "<tr class=\"dark\">\n";
5976                 } else {
5977                         print "<tr class=\"light\">\n";
5978                 }
5979                 $alternate ^= 1;
5980
5981                 my $up = $file_name;
5982                 $up =~ s!/?[^/]+$!!;
5983                 undef $up unless $up;
5984                 # based on git_print_tree_entry
5985                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
5986                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
5987                 print '<td class="list">';
5988                 print $cgi->a({-href => href(action=>"tree",
5989                                              hash_base=>$hash_base,
5990                                              file_name=>$up)},
5991                               "..");
5992                 print "</td>\n";
5993                 print "<td class=\"link\"></td>\n";
5994
5995                 print "</tr>\n";
5996         }
5997         foreach my $line (@entries) {
5998                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
5999
6000                 if ($alternate) {
6001                         print "<tr class=\"dark\">\n";
6002                 } else {
6003                         print "<tr class=\"light\">\n";
6004                 }
6005                 $alternate ^= 1;
6006
6007                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6008
6009                 print "</tr>\n";
6010         }
6011         print "</table>\n" .
6012               "</div>";
6013         git_footer_html();
6014 }
6015
6016 sub snapshot_name {
6017         my ($project, $hash) = @_;
6018
6019         # path/to/project.git  -> project
6020         # path/to/project/.git -> project
6021         my $name = to_utf8($project);
6022         $name =~ s,([^/])/*\.git$,$1,;
6023         $name = basename($name);
6024         # sanitize name
6025         $name =~ s/[[:cntrl:]]/?/g;
6026
6027         my $ver = $hash;
6028         if ($hash =~ /^[0-9a-fA-F]+$/) {
6029                 # shorten SHA-1 hash
6030                 my $full_hash = git_get_full_hash($project, $hash);
6031                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6032                         $ver = git_get_short_hash($project, $hash);
6033                 }
6034         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6035                 # tags don't need shortened SHA-1 hash
6036                 $ver = $1;
6037         } else {
6038                 # branches and other need shortened SHA-1 hash
6039                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6040                         $ver = $1;
6041                 }
6042                 $ver .= '-' . git_get_short_hash($project, $hash);
6043         }
6044         # in case of hierarchical branch names
6045         $ver =~ s!/!.!g;
6046
6047         # name = project-version_string
6048         $name = "$name-$ver";
6049
6050         return wantarray ? ($name, $name) : $name;
6051 }
6052
6053 sub git_snapshot {
6054         my $format = $input_params{'snapshot_format'};
6055         if (!@snapshot_fmts) {
6056                 die_error(403, "Snapshots not allowed");
6057         }
6058         # default to first supported snapshot format
6059         $format ||= $snapshot_fmts[0];
6060         if ($format !~ m/^[a-z0-9]+$/) {
6061                 die_error(400, "Invalid snapshot format parameter");
6062         } elsif (!exists($known_snapshot_formats{$format})) {
6063                 die_error(400, "Unknown snapshot format");
6064         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6065                 die_error(403, "Snapshot format not allowed");
6066         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6067                 die_error(403, "Unsupported snapshot format");
6068         }
6069
6070         my $type = git_get_type("$hash^{}");
6071         if (!$type) {
6072                 die_error(404, 'Object does not exist');
6073         }  elsif ($type eq 'blob') {
6074                 die_error(400, 'Object is not a tree-ish');
6075         }
6076
6077         my ($name, $prefix) = snapshot_name($project, $hash);
6078         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6079         my $cmd = quote_command(
6080                 git_cmd(), 'archive',
6081                 "--format=$known_snapshot_formats{$format}{'format'}",
6082                 "--prefix=$prefix/", $hash);
6083         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6084                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6085         }
6086
6087         $filename =~ s/(["\\])/\\$1/g;
6088         print $cgi->header(
6089                 -type => $known_snapshot_formats{$format}{'type'},
6090                 -content_disposition => 'inline; filename="' . $filename . '"',
6091                 -status => '200 OK');
6092
6093         open my $fd, "-|", $cmd
6094                 or die_error(500, "Execute git-archive failed");
6095         binmode STDOUT, ':raw';
6096         print <$fd>;
6097         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6098         close $fd;
6099 }
6100
6101 sub git_log_generic {
6102         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6103
6104         my $head = git_get_head_hash($project);
6105         if (!defined $base) {
6106                 $base = $head;
6107         }
6108         if (!defined $page) {
6109                 $page = 0;
6110         }
6111         my $refs = git_get_references();
6112
6113         my $commit_hash = $base;
6114         if (defined $parent) {
6115                 $commit_hash = "$parent..$base";
6116         }
6117         my @commitlist =
6118                 parse_commits($commit_hash, 101, (100 * $page),
6119                               defined $file_name ? ($file_name, "--full-history") : ());
6120
6121         my $ftype;
6122         if (!defined $file_hash && defined $file_name) {
6123                 # some commits could have deleted file in question,
6124                 # and not have it in tree, but one of them has to have it
6125                 for (my $i = 0; $i < @commitlist; $i++) {
6126                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6127                         last if defined $file_hash;
6128                 }
6129         }
6130         if (defined $file_hash) {
6131                 $ftype = git_get_type($file_hash);
6132         }
6133         if (defined $file_name && !defined $ftype) {
6134                 die_error(500, "Unknown type of object");
6135         }
6136         my %co;
6137         if (defined $file_name) {
6138                 %co = parse_commit($base)
6139                         or die_error(404, "Unknown commit object");
6140         }
6141
6142
6143         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6144         my $next_link = '';
6145         if ($#commitlist >= 100) {
6146                 $next_link =
6147                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6148                                  -accesskey => "n", -title => "Alt-n"}, "next");
6149         }
6150         my $patch_max = gitweb_get_feature('patches');
6151         if ($patch_max && !defined $file_name) {
6152                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6153                         $paging_nav .= " &sdot; " .
6154                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6155                                         "patches");
6156                 }
6157         }
6158
6159         git_header_html();
6160         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6161         if (defined $file_name) {
6162                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6163         } else {
6164                 git_print_header_div('summary', $project)
6165         }
6166         git_print_page_path($file_name, $ftype, $hash_base)
6167                 if (defined $file_name);
6168
6169         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6170                      $file_name, $file_hash, $ftype);
6171
6172         git_footer_html();
6173 }
6174
6175 sub git_log {
6176         git_log_generic('log', \&git_log_body,
6177                         $hash, $hash_parent);
6178 }
6179
6180 sub git_commit {
6181         $hash ||= $hash_base || "HEAD";
6182         my %co = parse_commit($hash)
6183             or die_error(404, "Unknown commit object");
6184
6185         my $parent  = $co{'parent'};
6186         my $parents = $co{'parents'}; # listref
6187
6188         # we need to prepare $formats_nav before any parameter munging
6189         my $formats_nav;
6190         if (!defined $parent) {
6191                 # --root commitdiff
6192                 $formats_nav .= '(initial)';
6193         } elsif (@$parents == 1) {
6194                 # single parent commit
6195                 $formats_nav .=
6196                         '(parent: ' .
6197                         $cgi->a({-href => href(action=>"commit",
6198                                                hash=>$parent)},
6199                                 esc_html(substr($parent, 0, 7))) .
6200                         ')';
6201         } else {
6202                 # merge commit
6203                 $formats_nav .=
6204                         '(merge: ' .
6205                         join(' ', map {
6206                                 $cgi->a({-href => href(action=>"commit",
6207                                                        hash=>$_)},
6208                                         esc_html(substr($_, 0, 7)));
6209                         } @$parents ) .
6210                         ')';
6211         }
6212         if (gitweb_check_feature('patches') && @$parents <= 1) {
6213                 $formats_nav .= " | " .
6214                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6215                                 "patch");
6216         }
6217
6218         if (!defined $parent) {
6219                 $parent = "--root";
6220         }
6221         my @difftree;
6222         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6223                 @diff_opts,
6224                 (@$parents <= 1 ? $parent : '-c'),
6225                 $hash, "--"
6226                 or die_error(500, "Open git-diff-tree failed");
6227         @difftree = map { chomp; $_ } <$fd>;
6228         close $fd or die_error(404, "Reading git-diff-tree failed");
6229
6230         # non-textual hash id's can be cached
6231         my $expires;
6232         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6233                 $expires = "+1d";
6234         }
6235         my $refs = git_get_references();
6236         my $ref = format_ref_marker($refs, $co{'id'});
6237
6238         git_header_html(undef, $expires);
6239         git_print_page_nav('commit', '',
6240                            $hash, $co{'tree'}, $hash,
6241                            $formats_nav);
6242
6243         if (defined $co{'parent'}) {
6244                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6245         } else {
6246                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6247         }
6248         print "<div class=\"title_text\">\n" .
6249               "<table class=\"object_header\">\n";
6250         git_print_authorship_rows(\%co);
6251         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6252         print "<tr>" .
6253               "<td>tree</td>" .
6254               "<td class=\"sha1\">" .
6255               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6256                        class => "list"}, $co{'tree'}) .
6257               "</td>" .
6258               "<td class=\"link\">" .
6259               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6260                       "tree");
6261         my $snapshot_links = format_snapshot_links($hash);
6262         if (defined $snapshot_links) {
6263                 print " | " . $snapshot_links;
6264         }
6265         print "</td>" .
6266               "</tr>\n";
6267
6268         foreach my $par (@$parents) {
6269                 print "<tr>" .
6270                       "<td>parent</td>" .
6271                       "<td class=\"sha1\">" .
6272                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6273                                class => "list"}, $par) .
6274                       "</td>" .
6275                       "<td class=\"link\">" .
6276                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6277                       " | " .
6278                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6279                       "</td>" .
6280                       "</tr>\n";
6281         }
6282         print "</table>".
6283               "</div>\n";
6284
6285         print "<div class=\"page_body\">\n";
6286         git_print_log($co{'comment'});
6287         print "</div>\n";
6288
6289         git_difftree_body(\@difftree, $hash, @$parents);
6290
6291         git_footer_html();
6292 }
6293
6294 sub git_object {
6295         # object is defined by:
6296         # - hash or hash_base alone
6297         # - hash_base and file_name
6298         my $type;
6299
6300         # - hash or hash_base alone
6301         if ($hash || ($hash_base && !defined $file_name)) {
6302                 my $object_id = $hash || $hash_base;
6303
6304                 open my $fd, "-|", quote_command(
6305                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6306                         or die_error(404, "Object does not exist");
6307                 $type = <$fd>;
6308                 chomp $type;
6309                 close $fd
6310                         or die_error(404, "Object does not exist");
6311
6312         # - hash_base and file_name
6313         } elsif ($hash_base && defined $file_name) {
6314                 $file_name =~ s,/+$,,;
6315
6316                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6317                         or die_error(404, "Base object does not exist");
6318
6319                 # here errors should not hapen
6320                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6321                         or die_error(500, "Open git-ls-tree failed");
6322                 my $line = <$fd>;
6323                 close $fd;
6324
6325                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6326                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6327                         die_error(404, "File or directory for given base does not exist");
6328                 }
6329                 $type = $2;
6330                 $hash = $3;
6331         } else {
6332                 die_error(400, "Not enough information to find object");
6333         }
6334
6335         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6336                                           hash=>$hash, hash_base=>$hash_base,
6337                                           file_name=>$file_name),
6338                              -status => '302 Found');
6339 }
6340
6341 sub git_blobdiff {
6342         my $format = shift || 'html';
6343
6344         my $fd;
6345         my @difftree;
6346         my %diffinfo;
6347         my $expires;
6348
6349         # preparing $fd and %diffinfo for git_patchset_body
6350         # new style URI
6351         if (defined $hash_base && defined $hash_parent_base) {
6352                 if (defined $file_name) {
6353                         # read raw output
6354                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6355                                 $hash_parent_base, $hash_base,
6356                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6357                                 or die_error(500, "Open git-diff-tree failed");
6358                         @difftree = map { chomp; $_ } <$fd>;
6359                         close $fd
6360                                 or die_error(404, "Reading git-diff-tree failed");
6361                         @difftree
6362                                 or die_error(404, "Blob diff not found");
6363
6364                 } elsif (defined $hash &&
6365                          $hash =~ /[0-9a-fA-F]{40}/) {
6366                         # try to find filename from $hash
6367
6368                         # read filtered raw output
6369                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6370                                 $hash_parent_base, $hash_base, "--"
6371                                 or die_error(500, "Open git-diff-tree failed");
6372                         @difftree =
6373                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6374                                 # $hash == to_id
6375                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6376                                 map { chomp; $_ } <$fd>;
6377                         close $fd
6378                                 or die_error(404, "Reading git-diff-tree failed");
6379                         @difftree
6380                                 or die_error(404, "Blob diff not found");
6381
6382                 } else {
6383                         die_error(400, "Missing one of the blob diff parameters");
6384                 }
6385
6386                 if (@difftree > 1) {
6387                         die_error(400, "Ambiguous blob diff specification");
6388                 }
6389
6390                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6391                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6392                 $file_name   ||= $diffinfo{'to_file'};
6393
6394                 $hash_parent ||= $diffinfo{'from_id'};
6395                 $hash        ||= $diffinfo{'to_id'};
6396
6397                 # non-textual hash id's can be cached
6398                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6399                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6400                         $expires = '+1d';
6401                 }
6402
6403                 # open patch output
6404                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6405                         '-p', ($format eq 'html' ? "--full-index" : ()),
6406                         $hash_parent_base, $hash_base,
6407                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6408                         or die_error(500, "Open git-diff-tree failed");
6409         }
6410
6411         # old/legacy style URI -- not generated anymore since 1.4.3.
6412         if (!%diffinfo) {
6413                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6414         }
6415
6416         # header
6417         if ($format eq 'html') {
6418                 my $formats_nav =
6419                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6420                                 "raw");
6421                 git_header_html(undef, $expires);
6422                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6423                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6424                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6425                 } else {
6426                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6427                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
6428                 }
6429                 if (defined $file_name) {
6430                         git_print_page_path($file_name, "blob", $hash_base);
6431                 } else {
6432                         print "<div class=\"page_path\"></div>\n";
6433                 }
6434
6435         } elsif ($format eq 'plain') {
6436                 print $cgi->header(
6437                         -type => 'text/plain',
6438                         -charset => 'utf-8',
6439                         -expires => $expires,
6440                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6441
6442                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6443
6444         } else {
6445                 die_error(400, "Unknown blobdiff format");
6446         }
6447
6448         # patch
6449         if ($format eq 'html') {
6450                 print "<div class=\"page_body\">\n";
6451
6452                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6453                 close $fd;
6454
6455                 print "</div>\n"; # class="page_body"
6456                 git_footer_html();
6457
6458         } else {
6459                 while (my $line = <$fd>) {
6460                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6461                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6462
6463                         print $line;
6464
6465                         last if $line =~ m!^\+\+\+!;
6466                 }
6467                 local $/ = undef;
6468                 print <$fd>;
6469                 close $fd;
6470         }
6471 }
6472
6473 sub git_blobdiff_plain {
6474         git_blobdiff('plain');
6475 }
6476
6477 sub git_commitdiff {
6478         my %params = @_;
6479         my $format = $params{-format} || 'html';
6480
6481         my ($patch_max) = gitweb_get_feature('patches');
6482         if ($format eq 'patch') {
6483                 die_error(403, "Patch view not allowed") unless $patch_max;
6484         }
6485
6486         $hash ||= $hash_base || "HEAD";
6487         my %co = parse_commit($hash)
6488             or die_error(404, "Unknown commit object");
6489
6490         # choose format for commitdiff for merge
6491         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6492                 $hash_parent = '--cc';
6493         }
6494         # we need to prepare $formats_nav before almost any parameter munging
6495         my $formats_nav;
6496         if ($format eq 'html') {
6497                 $formats_nav =
6498                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6499                                 "raw");
6500                 if ($patch_max && @{$co{'parents'}} <= 1) {
6501                         $formats_nav .= " | " .
6502                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6503                                         "patch");
6504                 }
6505
6506                 if (defined $hash_parent &&
6507                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6508                         # commitdiff with two commits given
6509                         my $hash_parent_short = $hash_parent;
6510                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6511                                 $hash_parent_short = substr($hash_parent, 0, 7);
6512                         }
6513                         $formats_nav .=
6514                                 ' (from';
6515                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6516                                 if ($co{'parents'}[$i] eq $hash_parent) {
6517                                         $formats_nav .= ' parent ' . ($i+1);
6518                                         last;
6519                                 }
6520                         }
6521                         $formats_nav .= ': ' .
6522                                 $cgi->a({-href => href(action=>"commitdiff",
6523                                                        hash=>$hash_parent)},
6524                                         esc_html($hash_parent_short)) .
6525                                 ')';
6526                 } elsif (!$co{'parent'}) {
6527                         # --root commitdiff
6528                         $formats_nav .= ' (initial)';
6529                 } elsif (scalar @{$co{'parents'}} == 1) {
6530                         # single parent commit
6531                         $formats_nav .=
6532                                 ' (parent: ' .
6533                                 $cgi->a({-href => href(action=>"commitdiff",
6534                                                        hash=>$co{'parent'})},
6535                                         esc_html(substr($co{'parent'}, 0, 7))) .
6536                                 ')';
6537                 } else {
6538                         # merge commit
6539                         if ($hash_parent eq '--cc') {
6540                                 $formats_nav .= ' | ' .
6541                                         $cgi->a({-href => href(action=>"commitdiff",
6542                                                                hash=>$hash, hash_parent=>'-c')},
6543                                                 'combined');
6544                         } else { # $hash_parent eq '-c'
6545                                 $formats_nav .= ' | ' .
6546                                         $cgi->a({-href => href(action=>"commitdiff",
6547                                                                hash=>$hash, hash_parent=>'--cc')},
6548                                                 'compact');
6549                         }
6550                         $formats_nav .=
6551                                 ' (merge: ' .
6552                                 join(' ', map {
6553                                         $cgi->a({-href => href(action=>"commitdiff",
6554                                                                hash=>$_)},
6555                                                 esc_html(substr($_, 0, 7)));
6556                                 } @{$co{'parents'}} ) .
6557                                 ')';
6558                 }
6559         }
6560
6561         my $hash_parent_param = $hash_parent;
6562         if (!defined $hash_parent_param) {
6563                 # --cc for multiple parents, --root for parentless
6564                 $hash_parent_param =
6565                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6566         }
6567
6568         # read commitdiff
6569         my $fd;
6570         my @difftree;
6571         if ($format eq 'html') {
6572                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6573                         "--no-commit-id", "--patch-with-raw", "--full-index",
6574                         $hash_parent_param, $hash, "--"
6575                         or die_error(500, "Open git-diff-tree failed");
6576
6577                 while (my $line = <$fd>) {
6578                         chomp $line;
6579                         # empty line ends raw part of diff-tree output
6580                         last unless $line;
6581                         push @difftree, scalar parse_difftree_raw_line($line);
6582                 }
6583
6584         } elsif ($format eq 'plain') {
6585                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6586                         '-p', $hash_parent_param, $hash, "--"
6587                         or die_error(500, "Open git-diff-tree failed");
6588         } elsif ($format eq 'patch') {
6589                 # For commit ranges, we limit the output to the number of
6590                 # patches specified in the 'patches' feature.
6591                 # For single commits, we limit the output to a single patch,
6592                 # diverging from the git-format-patch default.
6593                 my @commit_spec = ();
6594                 if ($hash_parent) {
6595                         if ($patch_max > 0) {
6596                                 push @commit_spec, "-$patch_max";
6597                         }
6598                         push @commit_spec, '-n', "$hash_parent..$hash";
6599                 } else {
6600                         if ($params{-single}) {
6601                                 push @commit_spec, '-1';
6602                         } else {
6603                                 if ($patch_max > 0) {
6604                                         push @commit_spec, "-$patch_max";
6605                                 }
6606                                 push @commit_spec, "-n";
6607                         }
6608                         push @commit_spec, '--root', $hash;
6609                 }
6610                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6611                         '--encoding=utf8', '--stdout', @commit_spec
6612                         or die_error(500, "Open git-format-patch failed");
6613         } else {
6614                 die_error(400, "Unknown commitdiff format");
6615         }
6616
6617         # non-textual hash id's can be cached
6618         my $expires;
6619         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6620                 $expires = "+1d";
6621         }
6622
6623         # write commit message
6624         if ($format eq 'html') {
6625                 my $refs = git_get_references();
6626                 my $ref = format_ref_marker($refs, $co{'id'});
6627
6628                 git_header_html(undef, $expires);
6629                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6630                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6631                 print "<div class=\"title_text\">\n" .
6632                       "<table class=\"object_header\">\n";
6633                 git_print_authorship_rows(\%co);
6634                 print "</table>".
6635                       "</div>\n";
6636                 print "<div class=\"page_body\">\n";
6637                 if (@{$co{'comment'}} > 1) {
6638                         print "<div class=\"log\">\n";
6639                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6640                         print "</div>\n"; # class="log"
6641                 }
6642
6643         } elsif ($format eq 'plain') {
6644                 my $refs = git_get_references("tags");
6645                 my $tagname = git_get_rev_name_tags($hash);
6646                 my $filename = basename($project) . "-$hash.patch";
6647
6648                 print $cgi->header(
6649                         -type => 'text/plain',
6650                         -charset => 'utf-8',
6651                         -expires => $expires,
6652                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6653                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6654                 print "From: " . to_utf8($co{'author'}) . "\n";
6655                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6656                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6657
6658                 print "X-Git-Tag: $tagname\n" if $tagname;
6659                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6660
6661                 foreach my $line (@{$co{'comment'}}) {
6662                         print to_utf8($line) . "\n";
6663                 }
6664                 print "---\n\n";
6665         } elsif ($format eq 'patch') {
6666                 my $filename = basename($project) . "-$hash.patch";
6667
6668                 print $cgi->header(
6669                         -type => 'text/plain',
6670                         -charset => 'utf-8',
6671                         -expires => $expires,
6672                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6673         }
6674
6675         # write patch
6676         if ($format eq 'html') {
6677                 my $use_parents = !defined $hash_parent ||
6678                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6679                 git_difftree_body(\@difftree, $hash,
6680                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6681                 print "<br/>\n";
6682
6683                 git_patchset_body($fd, \@difftree, $hash,
6684                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6685                 close $fd;
6686                 print "</div>\n"; # class="page_body"
6687                 git_footer_html();
6688
6689         } elsif ($format eq 'plain') {
6690                 local $/ = undef;
6691                 print <$fd>;
6692                 close $fd
6693                         or print "Reading git-diff-tree failed\n";
6694         } elsif ($format eq 'patch') {
6695                 local $/ = undef;
6696                 print <$fd>;
6697                 close $fd
6698                         or print "Reading git-format-patch failed\n";
6699         }
6700 }
6701
6702 sub git_commitdiff_plain {
6703         git_commitdiff(-format => 'plain');
6704 }
6705
6706 # format-patch-style patches
6707 sub git_patch {
6708         git_commitdiff(-format => 'patch', -single => 1);
6709 }
6710
6711 sub git_patches {
6712         git_commitdiff(-format => 'patch');
6713 }
6714
6715 sub git_history {
6716         git_log_generic('history', \&git_history_body,
6717                         $hash_base, $hash_parent_base,
6718                         $file_name, $hash);
6719 }
6720
6721 sub git_search {
6722         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6723         if (!defined $searchtext) {
6724                 die_error(400, "Text field is empty");
6725         }
6726         if (!defined $hash) {
6727                 $hash = git_get_head_hash($project);
6728         }
6729         my %co = parse_commit($hash);
6730         if (!%co) {
6731                 die_error(404, "Unknown commit object");
6732         }
6733         if (!defined $page) {
6734                 $page = 0;
6735         }
6736
6737         $searchtype ||= 'commit';
6738         if ($searchtype eq 'pickaxe') {
6739                 # pickaxe may take all resources of your box and run for several minutes
6740                 # with every query - so decide by yourself how public you make this feature
6741                 gitweb_check_feature('pickaxe')
6742                     or die_error(403, "Pickaxe is disabled");
6743         }
6744         if ($searchtype eq 'grep') {
6745                 gitweb_check_feature('grep')
6746                     or die_error(403, "Grep is disabled");
6747         }
6748
6749         git_header_html();
6750
6751         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6752                 my $greptype;
6753                 if ($searchtype eq 'commit') {
6754                         $greptype = "--grep=";
6755                 } elsif ($searchtype eq 'author') {
6756                         $greptype = "--author=";
6757                 } elsif ($searchtype eq 'committer') {
6758                         $greptype = "--committer=";
6759                 }
6760                 $greptype .= $searchtext;
6761                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6762                                                $greptype, '--regexp-ignore-case',
6763                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6764
6765                 my $paging_nav = '';
6766                 if ($page > 0) {
6767                         $paging_nav .=
6768                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6769                                                        searchtext=>$searchtext,
6770                                                        searchtype=>$searchtype)},
6771                                         "first");
6772                         $paging_nav .= " &sdot; " .
6773                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6774                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6775                 } else {
6776                         $paging_nav .= "first";
6777                         $paging_nav .= " &sdot; prev";
6778                 }
6779                 my $next_link = '';
6780                 if ($#commitlist >= 100) {
6781                         $next_link =
6782                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6783                                          -accesskey => "n", -title => "Alt-n"}, "next");
6784                         $paging_nav .= " &sdot; $next_link";
6785                 } else {
6786                         $paging_nav .= " &sdot; next";
6787                 }
6788
6789                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6790                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6791                 if ($page == 0 && !@commitlist) {
6792                         print "<p>No match.</p>\n";
6793                 } else {
6794                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
6795                 }
6796         }
6797
6798         if ($searchtype eq 'pickaxe') {
6799                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6800                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6801
6802                 print "<table class=\"pickaxe search\">\n";
6803                 my $alternate = 1;
6804                 local $/ = "\n";
6805                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6806                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6807                         ($search_use_regexp ? '--pickaxe-regex' : ());
6808                 undef %co;
6809                 my @files;
6810                 while (my $line = <$fd>) {
6811                         chomp $line;
6812                         next unless $line;
6813
6814                         my %set = parse_difftree_raw_line($line);
6815                         if (defined $set{'commit'}) {
6816                                 # finish previous commit
6817                                 if (%co) {
6818                                         print "</td>\n" .
6819                                               "<td class=\"link\">" .
6820                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6821                                               " | " .
6822                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6823                                         print "</td>\n" .
6824                                               "</tr>\n";
6825                                 }
6826
6827                                 if ($alternate) {
6828                                         print "<tr class=\"dark\">\n";
6829                                 } else {
6830                                         print "<tr class=\"light\">\n";
6831                                 }
6832                                 $alternate ^= 1;
6833                                 %co = parse_commit($set{'commit'});
6834                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6835                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6836                                       "<td><i>$author</i></td>\n" .
6837                                       "<td>" .
6838                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6839                                               -class => "list subject"},
6840                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6841                         } elsif (defined $set{'to_id'}) {
6842                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6843
6844                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6845                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6846                                               -class => "list"},
6847                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6848                                       "<br/>\n";
6849                         }
6850                 }
6851                 close $fd;
6852
6853                 # finish last commit (warning: repetition!)
6854                 if (%co) {
6855                         print "</td>\n" .
6856                               "<td class=\"link\">" .
6857                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6858                               " | " .
6859                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6860                         print "</td>\n" .
6861                               "</tr>\n";
6862                 }
6863
6864                 print "</table>\n";
6865         }
6866
6867         if ($searchtype eq 'grep') {
6868                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6869                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6870
6871                 print "<table class=\"grep_search\">\n";
6872                 my $alternate = 1;
6873                 my $matches = 0;
6874                 local $/ = "\n";
6875                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6876                         $search_use_regexp ? ('-E', '-i') : '-F',
6877                         $searchtext, $co{'tree'};
6878                 my $lastfile = '';
6879                 while (my $line = <$fd>) {
6880                         chomp $line;
6881                         my ($file, $lno, $ltext, $binary);
6882                         last if ($matches++ > 1000);
6883                         if ($line =~ /^Binary file (.+) matches$/) {
6884                                 $file = $1;
6885                                 $binary = 1;
6886                         } else {
6887                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6888                         }
6889                         if ($file ne $lastfile) {
6890                                 $lastfile and print "</td></tr>\n";
6891                                 if ($alternate++) {
6892                                         print "<tr class=\"dark\">\n";
6893                                 } else {
6894                                         print "<tr class=\"light\">\n";
6895                                 }
6896                                 print "<td class=\"list\">".
6897                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6898                                                                file_name=>"$file"),
6899                                                 -class => "list"}, esc_path($file));
6900                                 print "</td><td>\n";
6901                                 $lastfile = $file;
6902                         }
6903                         if ($binary) {
6904                                 print "<div class=\"binary\">Binary file</div>\n";
6905                         } else {
6906                                 $ltext = untabify($ltext);
6907                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6908                                         $ltext = esc_html($1, -nbsp=>1);
6909                                         $ltext .= '<span class="match">';
6910                                         $ltext .= esc_html($2, -nbsp=>1);
6911                                         $ltext .= '</span>';
6912                                         $ltext .= esc_html($3, -nbsp=>1);
6913                                 } else {
6914                                         $ltext = esc_html($ltext, -nbsp=>1);
6915                                 }
6916                                 print "<div class=\"pre\">" .
6917                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6918                                                                file_name=>"$file").'#l'.$lno,
6919                                                 -class => "linenr"}, sprintf('%4i', $lno))
6920                                         . ' ' .  $ltext . "</div>\n";
6921                         }
6922                 }
6923                 if ($lastfile) {
6924                         print "</td></tr>\n";
6925                         if ($matches > 1000) {
6926                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6927                         }
6928                 } else {
6929                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6930                 }
6931                 close $fd;
6932
6933                 print "</table>\n";
6934         }
6935         git_footer_html();
6936 }
6937
6938 sub git_search_help {
6939         git_header_html();
6940         git_print_page_nav('','', $hash,$hash,$hash);
6941         print <<EOT;
6942 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6943 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6944 the pattern entered is recognized as the POSIX extended
6945 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6946 insensitive).</p>
6947 <dl>
6948 <dt><b>commit</b></dt>
6949 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
6950 EOT
6951         my $have_grep = gitweb_check_feature('grep');
6952         if ($have_grep) {
6953                 print <<EOT;
6954 <dt><b>grep</b></dt>
6955 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
6956     a different one) are searched for the given pattern. On large trees, this search can take
6957 a while and put some strain on the server, so please use it with some consideration. Note that
6958 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
6959 case-sensitive.</dd>
6960 EOT
6961         }
6962         print <<EOT;
6963 <dt><b>author</b></dt>
6964 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
6965 <dt><b>committer</b></dt>
6966 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
6967 EOT
6968         my $have_pickaxe = gitweb_check_feature('pickaxe');
6969         if ($have_pickaxe) {
6970                 print <<EOT;
6971 <dt><b>pickaxe</b></dt>
6972 <dd>All commits that caused the string to appear or disappear from any file (changes that
6973 added, removed or "modified" the string) will be listed. This search can take a while and
6974 takes a lot of strain on the server, so please use it wisely. Note that since you may be
6975 interested even in changes just changing the case as well, this search is case sensitive.</dd>
6976 EOT
6977         }
6978         print "</dl>\n";
6979         git_footer_html();
6980 }
6981
6982 sub git_shortlog {
6983         git_log_generic('shortlog', \&git_shortlog_body,
6984                         $hash, $hash_parent);
6985 }
6986
6987 ## ......................................................................
6988 ## feeds (RSS, Atom; OPML)
6989
6990 sub git_feed {
6991         my $format = shift || 'atom';
6992         my $have_blame = gitweb_check_feature('blame');
6993
6994         # Atom: http://www.atomenabled.org/developers/syndication/
6995         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
6996         if ($format ne 'rss' && $format ne 'atom') {
6997                 die_error(400, "Unknown web feed format");
6998         }
6999
7000         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7001         my $head = $hash || 'HEAD';
7002         my @commitlist = parse_commits($head, 150, 0, $file_name);
7003
7004         my %latest_commit;
7005         my %latest_date;
7006         my $content_type = "application/$format+xml";
7007         if (defined $cgi->http('HTTP_ACCEPT') &&
7008                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7009                 # browser (feed reader) prefers text/xml
7010                 $content_type = 'text/xml';
7011         }
7012         if (defined($commitlist[0])) {
7013                 %latest_commit = %{$commitlist[0]};
7014                 my $latest_epoch = $latest_commit{'committer_epoch'};
7015                 %latest_date   = parse_date($latest_epoch);
7016                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7017                 if (defined $if_modified) {
7018                         my $since;
7019                         if (eval { require HTTP::Date; 1; }) {
7020                                 $since = HTTP::Date::str2time($if_modified);
7021                         } elsif (eval { require Time::ParseDate; 1; }) {
7022                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7023                         }
7024                         if (defined $since && $latest_epoch <= $since) {
7025                                 print $cgi->header(
7026                                         -type => $content_type,
7027                                         -charset => 'utf-8',
7028                                         -last_modified => $latest_date{'rfc2822'},
7029                                         -status => '304 Not Modified');
7030                                 return;
7031                         }
7032                 }
7033                 print $cgi->header(
7034                         -type => $content_type,
7035                         -charset => 'utf-8',
7036                         -last_modified => $latest_date{'rfc2822'});
7037         } else {
7038                 print $cgi->header(
7039                         -type => $content_type,
7040                         -charset => 'utf-8');
7041         }
7042
7043         # Optimization: skip generating the body if client asks only
7044         # for Last-Modified date.
7045         return if ($cgi->request_method() eq 'HEAD');
7046
7047         # header variables
7048         my $title = "$site_name - $project/$action";
7049         my $feed_type = 'log';
7050         if (defined $hash) {
7051                 $title .= " - '$hash'";
7052                 $feed_type = 'branch log';
7053                 if (defined $file_name) {
7054                         $title .= " :: $file_name";
7055                         $feed_type = 'history';
7056                 }
7057         } elsif (defined $file_name) {
7058                 $title .= " - $file_name";
7059                 $feed_type = 'history';
7060         }
7061         $title .= " $feed_type";
7062         my $descr = git_get_project_description($project);
7063         if (defined $descr) {
7064                 $descr = esc_html($descr);
7065         } else {
7066                 $descr = "$project " .
7067                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7068                          " feed";
7069         }
7070         my $owner = git_get_project_owner($project);
7071         $owner = esc_html($owner);
7072
7073         #header
7074         my $alt_url;
7075         if (defined $file_name) {
7076                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7077         } elsif (defined $hash) {
7078                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7079         } else {
7080                 $alt_url = href(-full=>1, action=>"summary");
7081         }
7082         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7083         if ($format eq 'rss') {
7084                 print <<XML;
7085 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7086 <channel>
7087 XML
7088                 print "<title>$title</title>\n" .
7089                       "<link>$alt_url</link>\n" .
7090                       "<description>$descr</description>\n" .
7091                       "<language>en</language>\n" .
7092                       # project owner is responsible for 'editorial' content
7093                       "<managingEditor>$owner</managingEditor>\n";
7094                 if (defined $logo || defined $favicon) {
7095                         # prefer the logo to the favicon, since RSS
7096                         # doesn't allow both
7097                         my $img = esc_url($logo || $favicon);
7098                         print "<image>\n" .
7099                               "<url>$img</url>\n" .
7100                               "<title>$title</title>\n" .
7101                               "<link>$alt_url</link>\n" .
7102                               "</image>\n";
7103                 }
7104                 if (%latest_date) {
7105                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7106                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7107                 }
7108                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7109         } elsif ($format eq 'atom') {
7110                 print <<XML;
7111 <feed xmlns="http://www.w3.org/2005/Atom">
7112 XML
7113                 print "<title>$title</title>\n" .
7114                       "<subtitle>$descr</subtitle>\n" .
7115                       '<link rel="alternate" type="text/html" href="' .
7116                       $alt_url . '" />' . "\n" .
7117                       '<link rel="self" type="' . $content_type . '" href="' .
7118                       $cgi->self_url() . '" />' . "\n" .
7119                       "<id>" . href(-full=>1) . "</id>\n" .
7120                       # use project owner for feed author
7121                       "<author><name>$owner</name></author>\n";
7122                 if (defined $favicon) {
7123                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7124                 }
7125                 if (defined $logo_url) {
7126                         # not twice as wide as tall: 72 x 27 pixels
7127                         print "<logo>" . esc_url($logo) . "</logo>\n";
7128                 }
7129                 if (! %latest_date) {
7130                         # dummy date to keep the feed valid until commits trickle in:
7131                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7132                 } else {
7133                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7134                 }
7135                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7136         }
7137
7138         # contents
7139         for (my $i = 0; $i <= $#commitlist; $i++) {
7140                 my %co = %{$commitlist[$i]};
7141                 my $commit = $co{'id'};
7142                 # we read 150, we always show 30 and the ones more recent than 48 hours
7143                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7144                         last;
7145                 }
7146                 my %cd = parse_date($co{'author_epoch'});
7147
7148                 # get list of changed files
7149                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7150                         $co{'parent'} || "--root",
7151                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7152                         or next;
7153                 my @difftree = map { chomp; $_ } <$fd>;
7154                 close $fd
7155                         or next;
7156
7157                 # print element (entry, item)
7158                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7159                 if ($format eq 'rss') {
7160                         print "<item>\n" .
7161                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7162                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7163                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7164                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7165                               "<link>$co_url</link>\n" .
7166                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7167                               "<content:encoded>" .
7168                               "<![CDATA[\n";
7169                 } elsif ($format eq 'atom') {
7170                         print "<entry>\n" .
7171                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7172                               "<updated>$cd{'iso-8601'}</updated>\n" .
7173                               "<author>\n" .
7174                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7175                         if ($co{'author_email'}) {
7176                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7177                         }
7178                         print "</author>\n" .
7179                               # use committer for contributor
7180                               "<contributor>\n" .
7181                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7182                         if ($co{'committer_email'}) {
7183                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7184                         }
7185                         print "</contributor>\n" .
7186                               "<published>$cd{'iso-8601'}</published>\n" .
7187                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7188                               "<id>$co_url</id>\n" .
7189                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7190                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7191                 }
7192                 my $comment = $co{'comment'};
7193                 print "<pre>\n";
7194                 foreach my $line (@$comment) {
7195                         $line = esc_html($line);
7196                         print "$line\n";
7197                 }
7198                 print "</pre><ul>\n";
7199                 foreach my $difftree_line (@difftree) {
7200                         my %difftree = parse_difftree_raw_line($difftree_line);
7201                         next if !$difftree{'from_id'};
7202
7203                         my $file = $difftree{'file'} || $difftree{'to_file'};
7204
7205                         print "<li>" .
7206                               "[" .
7207                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7208                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7209                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7210                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7211                                       -title => "diff"}, 'D');
7212                         if ($have_blame) {
7213                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7214                                                              file_name=>$file, hash_base=>$commit),
7215                                               -title => "blame"}, 'B');
7216                         }
7217                         # if this is not a feed of a file history
7218                         if (!defined $file_name || $file_name ne $file) {
7219                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7220                                                              file_name=>$file, hash=>$commit),
7221                                               -title => "history"}, 'H');
7222                         }
7223                         $file = esc_path($file);
7224                         print "] ".
7225                               "$file</li>\n";
7226                 }
7227                 if ($format eq 'rss') {
7228                         print "</ul>]]>\n" .
7229                               "</content:encoded>\n" .
7230                               "</item>\n";
7231                 } elsif ($format eq 'atom') {
7232                         print "</ul>\n</div>\n" .
7233                               "</content>\n" .
7234                               "</entry>\n";
7235                 }
7236         }
7237
7238         # end of feed
7239         if ($format eq 'rss') {
7240                 print "</channel>\n</rss>\n";
7241         } elsif ($format eq 'atom') {
7242                 print "</feed>\n";
7243         }
7244 }
7245
7246 sub git_rss {
7247         git_feed('rss');
7248 }
7249
7250 sub git_atom {
7251         git_feed('atom');
7252 }
7253
7254 sub git_opml {
7255         my @list = git_get_projects_list();
7256
7257         print $cgi->header(
7258                 -type => 'text/xml',
7259                 -charset => 'utf-8',
7260                 -content_disposition => 'inline; filename="opml.xml"');
7261
7262         print <<XML;
7263 <?xml version="1.0" encoding="utf-8"?>
7264 <opml version="1.0">
7265 <head>
7266   <title>$site_name OPML Export</title>
7267 </head>
7268 <body>
7269 <outline text="git RSS feeds">
7270 XML
7271
7272         foreach my $pr (@list) {
7273                 my %proj = %$pr;
7274                 my $head = git_get_head_hash($proj{'path'});
7275                 if (!defined $head) {
7276                         next;
7277                 }
7278                 $git_dir = "$projectroot/$proj{'path'}";
7279                 my %co = parse_commit($head);
7280                 if (!%co) {
7281                         next;
7282                 }
7283
7284                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7285                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7286                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7287                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7288         }
7289         print <<XML;
7290 </outline>
7291 </body>
7292 </opml>
7293 XML
7294 }