gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 our $cgi = new CGI;
  22 our $version = "++GIT_VERSION++";
  23 our $my_url = $cgi->url();
  24 our $my_uri = $cgi->url(-absolute => 1);
  25
  26 # core git executable to use
  27 # this can just be "git" if your webserver has a sensible PATH
  28 our $GIT = "++GIT_BINDIR++/git";
  29
  30 # absolute fs-path which will be prepended to the project path
  31 #our $projectroot = "/pub/scm";
  32 our $projectroot = "++GITWEB_PROJECTROOT++";
  33
  34 # target of the home link on top of all pages
  35 our $home_link = $my_uri || "/";
  36
  37 # string of the home link on top of all pages
  38 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  39
  40 # name of your site or organization to appear in page titles
  41 # replace this with something more descriptive for clearer bookmarks
  42 our $site_name = "++GITWEB_SITENAME++"
  43                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  44
  45 # filename of html text to include at top of each page
  46 our $site_header = "++GITWEB_SITE_HEADER++";
  47 # html text to include at home page
  48 our $home_text = "++GITWEB_HOMETEXT++";
  49 # filename of html text to include at bottom of each page
  50 our $site_footer = "++GITWEB_SITE_FOOTER++";
  51
  52 # URI of stylesheets
  53 our @stylesheets = ("++GITWEB_CSS++");
  54 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  55 our $stylesheet = undef;
  56 # URI of GIT logo (72x27 size)
  57 our $logo = "++GITWEB_LOGO++";
  58 # URI of GIT favicon, assumed to be image/png type
  59 our $favicon = "++GITWEB_FAVICON++";
  60
  61 # URI and label (title) of GIT logo link
  62 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
  63 #our $logo_label = "git documentation";
  64 our $logo_url = "http://git.or.cz/";
  65 our $logo_label = "git homepage";
  66
  67 # source of projects list
  68 our $projects_list = "++GITWEB_LIST++";
  69
  70 # show repository only if this file exists
  71 # (only effective if this variable evaluates to true)
  72 our $export_ok = "++GITWEB_EXPORT_OK++";
  73
  74 # only allow viewing of repositories also shown on the overview page
  75 our $strict_export = "++GITWEB_STRICT_EXPORT++";
  76
  77 # list of git base URLs used for URL to where fetch project from,
  78 # i.e. full URL is "$git_base_url/$project"
  79 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
  80
  81 # default blob_plain mimetype and default charset for text/plain blob
  82 our $default_blob_plain_mimetype = 'text/plain';
  83 our $default_text_plain_charset  = undef;
  84
  85 # file to use for guessing MIME types before trying /etc/mime.types
  86 # (relative to the current git repository)
  87 our $mimetypes_file = undef;
  88
  89 # You define site-wide feature defaults here; override them with
  90 # $GITWEB_CONFIG as necessary.
  91 our %feature = (
  92         # feature => {
  93         #       'sub' => feature-sub (subroutine),
  94         #       'override' => allow-override (boolean),
  95         #       'default' => [ default options...] (array reference)}
  96         #
  97         # if feature is overridable (it means that allow-override has true value,
  98         # then feature-sub will be called with default options as parameters;
  99         # return value of feature-sub indicates if to enable specified feature
 100         #
 101         # use gitweb_check_feature(<feature>) to check if <feature> is enabled
 102
 103         # Enable the 'blame' blob view, showing the last commit that modified
 104         # each line in the file. This can be very CPU-intensive.
 105
 106         # To enable system wide have in $GITWEB_CONFIG
 107         # $feature{'blame'}{'default'} = [1];
 108         # To have project specific config enable override in $GITWEB_CONFIG
 109         # $feature{'blame'}{'override'} = 1;
 110         # and in project config gitweb.blame = 0|1;
 111         'blame' => {
 112                 'sub' => \&feature_blame,
 113                 'override' => 0,
 114                 'default' => [0]},
 115
 116         # Enable the 'snapshot' link, providing a compressed tarball of any
 117         # tree. This can potentially generate high traffic if you have large
 118         # project.
 119
 120         # To disable system wide have in $GITWEB_CONFIG
 121         # $feature{'snapshot'}{'default'} = [undef];
 122         # To have project specific config enable override in $GITWEB_CONFIG
 123         # $feature{'blame'}{'override'} = 1;
 124         # and in project config gitweb.snapshot = none|gzip|bzip2;
 125         'snapshot' => {
 126                 'sub' => \&feature_snapshot,
 127                 'override' => 0,
 128                 #         => [content-encoding, suffix, program]
 129                 'default' => ['x-gzip', 'gz', 'gzip']},
 130
 131         # Enable the pickaxe search, which will list the commits that modified
 132         # a given string in a file. This can be practical and quite faster
 133         # alternative to 'blame', but still potentially CPU-intensive.
 134
 135         # To enable system wide have in $GITWEB_CONFIG
 136         # $feature{'pickaxe'}{'default'} = [1];
 137         # To have project specific config enable override in $GITWEB_CONFIG
 138         # $feature{'pickaxe'}{'override'} = 1;
 139         # and in project config gitweb.pickaxe = 0|1;
 140         'pickaxe' => {
 141                 'sub' => \&feature_pickaxe,
 142                 'override' => 0,
 143                 'default' => [1]},
 144
 145         # Make gitweb use an alternative format of the URLs which can be
 146         # more readable and natural-looking: project name is embedded
 147         # directly in the path and the query string contains other
 148         # auxiliary information. All gitweb installations recognize
 149         # URL in either format; this configures in which formats gitweb
 150         # generates links.
 151
 152         # To enable system wide have in $GITWEB_CONFIG
 153         # $feature{'pathinfo'}{'default'} = [1];
 154         # Project specific override is not supported.
 155
 156         # Note that you will need to change the default location of CSS,
 157         # favicon, logo and possibly other files to an absolute URL. Also,
 158         # if gitweb.cgi serves as your indexfile, you will need to force
 159         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 160         'pathinfo' => {
 161                 'override' => 0,
 162                 'default' => [0]},
 163
 164         # Make gitweb consider projects in project root subdirectories
 165         # to be forks of existing projects. Given project $projname.git,
 166         # projects matching $projname/*.git will not be shown in the main
 167         # projects list, instead a '+' mark will be added to $projname
 168         # there and a 'forks' view will be enabled for the project, listing
 169         # all the forks. This feature is supported only if project list
 170         # is taken from a directory, not file.
 171
 172         # To enable system wide have in $GITWEB_CONFIG
 173         # $feature{'forks'}{'default'} = [1];
 174         # Project specific override is not supported.
 175         'forks' => {
 176                 'override' => 0,
 177                 'default' => [0]},
 178 );
 179
 180 sub gitweb_check_feature {
 181         my ($name) = @_;
 182         return unless exists $feature{$name};
 183         my ($sub, $override, @defaults) = (
 184                 $feature{$name}{'sub'},
 185                 $feature{$name}{'override'},
 186                 @{$feature{$name}{'default'}});
 187         if (!$override) { return @defaults; }
 188         if (!defined $sub) {
 189                 warn "feature $name is not overrideable";
 190                 return @defaults;
 191         }
 192         return $sub->(@defaults);
 193 }
 194
 195 sub feature_blame {
 196         my ($val) = git_get_project_config('blame', '--bool');
 197
 198         if ($val eq 'true') {
 199                 return 1;
 200         } elsif ($val eq 'false') {
 201                 return 0;
 202         }
 203
 204         return $_[0];
 205 }
 206
 207 sub feature_snapshot {
 208         my ($ctype, $suffix, $command) = @_;
 209
 210         my ($val) = git_get_project_config('snapshot');
 211
 212         if ($val eq 'gzip') {
 213                 return ('x-gzip', 'gz', 'gzip');
 214         } elsif ($val eq 'bzip2') {
 215                 return ('x-bzip2', 'bz2', 'bzip2');
 216         } elsif ($val eq 'none') {
 217                 return ();
 218         }
 219
 220         return ($ctype, $suffix, $command);
 221 }
 222
 223 sub gitweb_have_snapshot {
 224         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
 225         my $have_snapshot = (defined $ctype && defined $suffix);
 226
 227         return $have_snapshot;
 228 }
 229
 230 sub feature_pickaxe {
 231         my ($val) = git_get_project_config('pickaxe', '--bool');
 232
 233         if ($val eq 'true') {
 234                 return (1);
 235         } elsif ($val eq 'false') {
 236                 return (0);
 237         }
 238
 239         return ($_[0]);
 240 }
 241
 242 # checking HEAD file with -e is fragile if the repository was
 243 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 244 # and then pruned.
 245 sub check_head_link {
 246         my ($dir) = @_;
 247         my $headfile = "$dir/HEAD";
 248         return ((-e $headfile) ||
 249                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 250 }
 251
 252 sub check_export_ok {
 253         my ($dir) = @_;
 254         return (check_head_link($dir) &&
 255                 (!$export_ok || -e "$dir/$export_ok"));
 256 }
 257
 258 # rename detection options for git-diff and git-diff-tree
 259 # - default is '-M', with the cost proportional to
 260 #   (number of removed files) * (number of new files).
 261 # - more costly is '-C' (or '-C', '-M'), with the cost proportional to
 262 #   (number of changed files + number of removed files) * (number of new files)
 263 # - even more costly is '-C', '--find-copies-harder' with cost
 264 #   (number of files in the original tree) * (number of new files)
 265 # - one might want to include '-B' option, e.g. '-B', '-M'
 266 our @diff_opts = ('-M'); # taken from git_commit
 267
 268 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 269 do $GITWEB_CONFIG if -e $GITWEB_CONFIG;
 270
 271 # version of the core git binary
 272 our $git_version = qx($GIT --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 273
 274 $projects_list ||= $projectroot;
 275
 276 # ======================================================================
 277 # input validation and dispatch
 278 our $action = $cgi->param('a');
 279 if (defined $action) {
 280         if ($action =~ m/[^0-9a-zA-Z\.\-_]/) {
 281                 die_error(undef, "Invalid action parameter");
 282         }
 283 }
 284
 285 # parameters which are pathnames
 286 our $project = $cgi->param('p');
 287 if (defined $project) {
 288         if (!validate_pathname($project) ||
 289             !(-d "$projectroot/$project") ||
 290             !check_head_link("$projectroot/$project") ||
 291             ($export_ok && !(-e "$projectroot/$project/$export_ok")) ||
 292             ($strict_export && !project_in_list($project))) {
 293                 undef $project;
 294                 die_error(undef, "No such project");
 295         }
 296 }
 297
 298 our $file_name = $cgi->param('f');
 299 if (defined $file_name) {
 300         if (!validate_pathname($file_name)) {
 301                 die_error(undef, "Invalid file parameter");
 302         }
 303 }
 304
 305 our $file_parent = $cgi->param('fp');
 306 if (defined $file_parent) {
 307         if (!validate_pathname($file_parent)) {
 308                 die_error(undef, "Invalid file parent parameter");
 309         }
 310 }
 311
 312 # parameters which are refnames
 313 our $hash = $cgi->param('h');
 314 if (defined $hash) {
 315         if (!validate_refname($hash)) {
 316                 die_error(undef, "Invalid hash parameter");
 317         }
 318 }
 319
 320 our $hash_parent = $cgi->param('hp');
 321 if (defined $hash_parent) {
 322         if (!validate_refname($hash_parent)) {
 323                 die_error(undef, "Invalid hash parent parameter");
 324         }
 325 }
 326
 327 our $hash_base = $cgi->param('hb');
 328 if (defined $hash_base) {
 329         if (!validate_refname($hash_base)) {
 330                 die_error(undef, "Invalid hash base parameter");
 331         }
 332 }
 333
 334 our $hash_parent_base = $cgi->param('hpb');
 335 if (defined $hash_parent_base) {
 336         if (!validate_refname($hash_parent_base)) {
 337                 die_error(undef, "Invalid hash parent base parameter");
 338         }
 339 }
 340
 341 # other parameters
 342 our $page = $cgi->param('pg');
 343 if (defined $page) {
 344         if ($page =~ m/[^0-9]/) {
 345                 die_error(undef, "Invalid page parameter");
 346         }
 347 }
 348
 349 our $searchtext = $cgi->param('s');
 350 if (defined $searchtext) {
 351         if ($searchtext =~ m/[^a-zA-Z0-9_\.\/\-\+\:\@ ]/) {
 352                 die_error(undef, "Invalid search parameter");
 353         }
 354         $searchtext = quotemeta $searchtext;
 355 }
 356
 357 our $searchtype = $cgi->param('st');
 358 if (defined $searchtype) {
 359         if ($searchtype =~ m/[^a-z]/) {
 360                 die_error(undef, "Invalid searchtype parameter");
 361         }
 362 }
 363
 364 # now read PATH_INFO and use it as alternative to parameters
 365 sub evaluate_path_info {
 366         return if defined $project;
 367         my $path_info = $ENV{"PATH_INFO"};
 368         return if !$path_info;
 369         $path_info =~ s,^/+,,;
 370         return if !$path_info;
 371         # find which part of PATH_INFO is project
 372         $project = $path_info;
 373         $project =~ s,/+$,,;
 374         while ($project && !check_head_link("$projectroot/$project")) {
 375                 $project =~ s,/*[^/]*$,,;
 376         }
 377         # validate project
 378         $project = validate_pathname($project);
 379         if (!$project ||
 380             ($export_ok && !-e "$projectroot/$project/$export_ok") ||
 381             ($strict_export && !project_in_list($project))) {
 382                 undef $project;
 383                 return;
 384         }
 385         # do not change any parameters if an action is given using the query string
 386         return if $action;
 387         $path_info =~ s,^$project/*,,;
 388         my ($refname, $pathname) = split(/:/, $path_info, 2);
 389         if (defined $pathname) {
 390                 # we got "project.git/branch:filename" or "project.git/branch:dir/"
 391                 # we could use git_get_type(branch:pathname), but it needs $git_dir
 392                 $pathname =~ s,^/+,,;
 393                 if (!$pathname || substr($pathname, -1) eq "/") {
 394                         $action  ||= "tree";
 395                         $pathname =~ s,/$,,;
 396                 } else {
 397                         $action  ||= "blob_plain";
 398                 }
 399                 $hash_base ||= validate_refname($refname);
 400                 $file_name ||= validate_pathname($pathname);
 401         } elsif (defined $refname) {
 402                 # we got "project.git/branch"
 403                 $action ||= "shortlog";
 404                 $hash   ||= validate_refname($refname);
 405         }
 406 }
 407 evaluate_path_info();
 408
 409 # path to the current git repository
 410 our $git_dir;
 411 $git_dir = "$projectroot/$project" if $project;
 412
 413 # dispatch
 414 my %actions = (
 415         "blame" => \&git_blame2,
 416         "blobdiff" => \&git_blobdiff,
 417         "blobdiff_plain" => \&git_blobdiff_plain,
 418         "blob" => \&git_blob,
 419         "blob_plain" => \&git_blob_plain,
 420         "commitdiff" => \&git_commitdiff,
 421         "commitdiff_plain" => \&git_commitdiff_plain,
 422         "commit" => \&git_commit,
 423         "forks" => \&git_forks,
 424         "heads" => \&git_heads,
 425         "history" => \&git_history,
 426         "log" => \&git_log,
 427         "rss" => \&git_rss,
 428         "atom" => \&git_atom,
 429         "search" => \&git_search,
 430         "search_help" => \&git_search_help,
 431         "shortlog" => \&git_shortlog,
 432         "summary" => \&git_summary,
 433         "tag" => \&git_tag,
 434         "tags" => \&git_tags,
 435         "tree" => \&git_tree,
 436         "snapshot" => \&git_snapshot,
 437         # those below don't need $project
 438         "opml" => \&git_opml,
 439         "project_list" => \&git_project_list,
 440         "project_index" => \&git_project_index,
 441 );
 442
 443 if (defined $project) {
 444         $action ||= 'summary';
 445 } else {
 446         $action ||= 'project_list';
 447 }
 448 if (!defined($actions{$action})) {
 449         die_error(undef, "Unknown action");
 450 }
 451 if ($action !~ m/^(opml|project_list|project_index)$/ &&
 452     !$project) {
 453         die_error(undef, "Project needed");
 454 }
 455 $actions{$action}->();
 456 exit;
 457
 458 ## ======================================================================
 459 ## action links
 460
 461 sub href(%) {
 462         my %params = @_;
 463         # default is to use -absolute url() i.e. $my_uri
 464         my $href = $params{-full} ? $my_url : $my_uri;
 465
 466         # XXX: Warning: If you touch this, check the search form for updating,
 467         # too.
 468
 469         my @mapping = (
 470                 project => "p",
 471                 action => "a",
 472                 file_name => "f",
 473                 file_parent => "fp",
 474                 hash => "h",
 475                 hash_parent => "hp",
 476                 hash_base => "hb",
 477                 hash_parent_base => "hpb",
 478                 page => "pg",
 479                 order => "o",
 480                 searchtext => "s",
 481                 searchtype => "st",
 482         );
 483         my %mapping = @mapping;
 484
 485         $params{'project'} = $project unless exists $params{'project'};
 486
 487         my ($use_pathinfo) = gitweb_check_feature('pathinfo');
 488         if ($use_pathinfo) {
 489                 # use PATH_INFO for project name
 490                 $href .= "/$params{'project'}" if defined $params{'project'};
 491                 delete $params{'project'};
 492
 493                 # Summary just uses the project path URL
 494                 if (defined $params{'action'} && $params{'action'} eq 'summary') {
 495                         delete $params{'action'};
 496                 }
 497         }
 498
 499         # now encode the parameters explicitly
 500         my @result = ();
 501         for (my $i = 0; $i < @mapping; $i += 2) {
 502                 my ($name, $symbol) = ($mapping[$i], $mapping[$i+1]);
 503                 if (defined $params{$name}) {
 504                         push @result, $symbol . "=" . esc_param($params{$name});
 505                 }
 506         }
 507         $href .= "?" . join(';', @result) if scalar @result;
 508
 509         return $href;
 510 }
 511
 512
 513 ## ======================================================================
 514 ## validation, quoting/unquoting and escaping
 515
 516 sub validate_pathname {
 517         my $input = shift || return undef;
 518
 519         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
 520         # at the beginning, at the end, and between slashes.
 521         # also this catches doubled slashes
 522         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
 523                 return undef;
 524         }
 525         # no null characters
 526         if ($input =~ m!\0!) {
 527                 return undef;
 528         }
 529         return $input;
 530 }
 531
 532 sub validate_refname {
 533         my $input = shift || return undef;
 534
 535         # textual hashes are O.K.
 536         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
 537                 return $input;
 538         }
 539         # it must be correct pathname
 540         $input = validate_pathname($input)
 541                 or return undef;
 542         # restrictions on ref name according to git-check-ref-format
 543         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
 544                 return undef;
 545         }
 546         return $input;
 547 }
 548
 549 # very thin wrapper for decode("utf8", $str, Encode::FB_DEFAULT);
 550 sub to_utf8 {
 551         my $str = shift;
 552         return decode("utf8", $str, Encode::FB_DEFAULT);
 553 }
 554
 555 # quote unsafe chars, but keep the slash, even when it's not
 556 # correct, but quoted slashes look too horrible in bookmarks
 557 sub esc_param {
 558         my $str = shift;
 559         $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
 560         $str =~ s/\+/%2B/g;
 561         $str =~ s/ /\+/g;
 562         return $str;
 563 }
 564
 565 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
 566 sub esc_url {
 567         my $str = shift;
 568         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
 569         $str =~ s/\+/%2B/g;
 570         $str =~ s/ /\+/g;
 571         return $str;
 572 }
 573
 574 # replace invalid utf8 character with SUBSTITUTION sequence
 575 sub esc_html ($;%) {
 576         my $str = shift;
 577         my %opts = @_;
 578
 579         $str = to_utf8($str);
 580         $str = escapeHTML($str);
 581         if ($opts{'-nbsp'}) {
 582                 $str =~ s/ /&nbsp;/g;
 583         }
 584         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
 585         return $str;
 586 }
 587
 588 # quote control characters and escape filename to HTML
 589 sub esc_path {
 590         my $str = shift;
 591         my %opts = @_;
 592
 593         $str = to_utf8($str);
 594         $str = escapeHTML($str);
 595         if ($opts{'-nbsp'}) {
 596                 $str =~ s/ /&nbsp;/g;
 597         }
 598         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
 599         return $str;
 600 }
 601
 602 # Make control characters "printable", using character escape codes (CEC)
 603 sub quot_cec {
 604         my $cntrl = shift;
 605         my %es = ( # character escape codes, aka escape sequences
 606                    "\t" => '\t',   # tab            (HT)
 607                    "\n" => '\n',   # line feed      (LF)
 608                    "\r" => '\r',   # carrige return (CR)
 609                    "\f" => '\f',   # form feed      (FF)
 610                    "\b" => '\b',   # backspace      (BS)
 611                    "\a" => '\a',   # alarm (bell)   (BEL)
 612                    "\e" => '\e',   # escape         (ESC)
 613                    "\013" => '\v', # vertical tab   (VT)
 614                    "\000" => '\0', # nul character  (NUL)
 615                    );
 616         my $chr = ( (exists $es{$cntrl})
 617                     ? $es{$cntrl}
 618                     : sprintf('\%03o', ord($cntrl)) );
 619         return "<span class=\"cntrl\">$chr</span>";
 620 }
 621
 622 # Alternatively use unicode control pictures codepoints,
 623 # Unicode "printable representation" (PR)
 624 sub quot_upr {
 625         my $cntrl = shift;
 626         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
 627         return "<span class=\"cntrl\">$chr</span>";
 628 }
 629
 630 # git may return quoted and escaped filenames
 631 sub unquote {
 632         my $str = shift;
 633
 634         sub unq {
 635                 my $seq = shift;
 636                 my %es = ( # character escape codes, aka escape sequences
 637                         't' => "\t",   # tab            (HT, TAB)
 638                         'n' => "\n",   # newline        (NL)
 639                         'r' => "\r",   # return         (CR)
 640                         'f' => "\f",   # form feed      (FF)
 641                         'b' => "\b",   # backspace      (BS)
 642                         'a' => "\a",   # alarm (bell)   (BEL)
 643                         'e' => "\e",   # escape         (ESC)
 644                         'v' => "\013", # vertical tab   (VT)
 645                 );
 646
 647                 if ($seq =~ m/^[0-7]{1,3}$/) {
 648                         # octal char sequence
 649                         return chr(oct($seq));
 650                 } elsif (exists $es{$seq}) {
 651                         # C escape sequence, aka character escape code
 652                         return $es{$seq}
 653                 }
 654                 # quoted ordinary character
 655                 return $seq;
 656         }
 657
 658         if ($str =~ m/^"(.*)"$/) {
 659                 # needs unquoting
 660                 $str = $1;
 661                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
 662         }
 663         return $str;
 664 }
 665
 666 # escape tabs (convert tabs to spaces)
 667 sub untabify {
 668         my $line = shift;
 669
 670         while ((my $pos = index($line, "\t")) != -1) {
 671                 if (my $count = (8 - ($pos % 8))) {
 672                         my $spaces = ' ' x $count;
 673                         $line =~ s/\t/$spaces/;
 674                 }
 675         }
 676
 677         return $line;
 678 }
 679
 680 sub project_in_list {
 681         my $project = shift;
 682         my @list = git_get_projects_list();
 683         return @list && scalar(grep { $_->{'path'} eq $project } @list);
 684 }
 685
 686 ## ----------------------------------------------------------------------
 687 ## HTML aware string manipulation
 688
 689 sub chop_str {
 690         my $str = shift;
 691         my $len = shift;
 692         my $add_len = shift || 10;
 693
 694         # allow only $len chars, but don't cut a word if it would fit in $add_len
 695         # if it doesn't fit, cut it if it's still longer than the dots we would add
 696         $str =~ m/^(.{0,$len}[^ \/\-_:\.@]{0,$add_len})(.*)/;
 697         my $body = $1;
 698         my $tail = $2;
 699         if (length($tail) > 4) {
 700                 $tail = " ...";
 701                 $body =~ s/&[^;]*$//; # remove chopped character entities
 702         }
 703         return "$body$tail";
 704 }
 705
 706 ## ----------------------------------------------------------------------
 707 ## functions returning short strings
 708
 709 # CSS class for given age value (in seconds)
 710 sub age_class {
 711         my $age = shift;
 712
 713         if ($age < 60*60*2) {
 714                 return "age0";
 715         } elsif ($age < 60*60*24*2) {
 716                 return "age1";
 717         } else {
 718                 return "age2";
 719         }
 720 }
 721
 722 # convert age in seconds to "nn units ago" string
 723 sub age_string {
 724         my $age = shift;
 725         my $age_str;
 726
 727         if ($age > 60*60*24*365*2) {
 728                 $age_str = (int $age/60/60/24/365);
 729                 $age_str .= " years ago";
 730         } elsif ($age > 60*60*24*(365/12)*2) {
 731                 $age_str = int $age/60/60/24/(365/12);
 732                 $age_str .= " months ago";
 733         } elsif ($age > 60*60*24*7*2) {
 734                 $age_str = int $age/60/60/24/7;
 735                 $age_str .= " weeks ago";
 736         } elsif ($age > 60*60*24*2) {
 737                 $age_str = int $age/60/60/24;
 738                 $age_str .= " days ago";
 739         } elsif ($age > 60*60*2) {
 740                 $age_str = int $age/60/60;
 741                 $age_str .= " hours ago";
 742         } elsif ($age > 60*2) {
 743                 $age_str = int $age/60;
 744                 $age_str .= " min ago";
 745         } elsif ($age > 2) {
 746                 $age_str = int $age;
 747                 $age_str .= " sec ago";
 748         } else {
 749                 $age_str .= " right now";
 750         }
 751         return $age_str;
 752 }
 753
 754 # convert file mode in octal to symbolic file mode string
 755 sub mode_str {
 756         my $mode = oct shift;
 757
 758         if (S_ISDIR($mode & S_IFMT)) {
 759                 return 'drwxr-xr-x';
 760         } elsif (S_ISLNK($mode)) {
 761                 return 'lrwxrwxrwx';
 762         } elsif (S_ISREG($mode)) {
 763                 # git cares only about the executable bit
 764                 if ($mode & S_IXUSR) {
 765                         return '-rwxr-xr-x';
 766                 } else {
 767                         return '-rw-r--r--';
 768                 };
 769         } else {
 770                 return '----------';
 771         }
 772 }
 773
 774 # convert file mode in octal to file type string
 775 sub file_type {
 776         my $mode = shift;
 777
 778         if ($mode !~ m/^[0-7]+$/) {
 779                 return $mode;
 780         } else {
 781                 $mode = oct $mode;
 782         }
 783
 784         if (S_ISDIR($mode & S_IFMT)) {
 785                 return "directory";
 786         } elsif (S_ISLNK($mode)) {
 787                 return "symlink";
 788         } elsif (S_ISREG($mode)) {
 789                 return "file";
 790         } else {
 791                 return "unknown";
 792         }
 793 }
 794
 795 # convert file mode in octal to file type description string
 796 sub file_type_long {
 797         my $mode = shift;
 798
 799         if ($mode !~ m/^[0-7]+$/) {
 800                 return $mode;
 801         } else {
 802                 $mode = oct $mode;
 803         }
 804
 805         if (S_ISDIR($mode & S_IFMT)) {
 806                 return "directory";
 807         } elsif (S_ISLNK($mode)) {
 808                 return "symlink";
 809         } elsif (S_ISREG($mode)) {
 810                 if ($mode & S_IXUSR) {
 811                         return "executable";
 812                 } else {
 813                         return "file";
 814                 };
 815         } else {
 816                 return "unknown";
 817         }
 818 }
 819
 820
 821 ## ----------------------------------------------------------------------
 822 ## functions returning short HTML fragments, or transforming HTML fragments
 823 ## which don't beling to other sections
 824
 825 # format line of commit message.
 826 sub format_log_line_html {
 827         my $line = shift;
 828
 829         $line = esc_html($line, -nbsp=>1);
 830         if ($line =~ m/([0-9a-fA-F]{40})/) {
 831                 my $hash_text = $1;
 832                 if (git_get_type($hash_text) eq "commit") {
 833                         my $link =
 834                                 $cgi->a({-href => href(action=>"commit", hash=>$hash_text),
 835                                         -class => "text"}, $hash_text);
 836                         $line =~ s/$hash_text/$link/;
 837                 }
 838         }
 839         return $line;
 840 }
 841
 842 # format marker of refs pointing to given object
 843 sub format_ref_marker {
 844         my ($refs, $id) = @_;
 845         my $markers = '';
 846
 847         if (defined $refs->{$id}) {
 848                 foreach my $ref (@{$refs->{$id}}) {
 849                         my ($type, $name) = qw();
 850                         # e.g. tags/v2.6.11 or heads/next
 851                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
 852                                 $type = $1;
 853                                 $name = $2;
 854                         } else {
 855                                 $type = "ref";
 856                                 $name = $ref;
 857                         }
 858
 859                         $markers .= " <span class=\"$type\">" . esc_html($name) . "</span>";
 860                 }
 861         }
 862
 863         if ($markers) {
 864                 return ' <span class="refs">'. $markers . '</span>';
 865         } else {
 866                 return "";
 867         }
 868 }
 869
 870 # format, perhaps shortened and with markers, title line
 871 sub format_subject_html {
 872         my ($long, $short, $href, $extra) = @_;
 873         $extra = '' unless defined($extra);
 874
 875         if (length($short) < length($long)) {
 876                 return $cgi->a({-href => $href, -class => "list subject",
 877                                 -title => to_utf8($long)},
 878                        esc_html($short) . $extra);
 879         } else {
 880                 return $cgi->a({-href => $href, -class => "list subject"},
 881                        esc_html($long)  . $extra);
 882         }
 883 }
 884
 885 # format patch (diff) line (rather not to be used for diff headers)
 886 sub format_diff_line {
 887         my $line = shift;
 888         my ($from, $to) = @_;
 889         my $char = substr($line, 0, 1);
 890         my $diff_class = "";
 891
 892         chomp $line;
 893
 894         if ($char eq '+') {
 895                 $diff_class = " add";
 896         } elsif ($char eq "-") {
 897                 $diff_class = " rem";
 898         } elsif ($char eq "@") {
 899                 $diff_class = " chunk_header";
 900         } elsif ($char eq "\\") {
 901                 $diff_class = " incomplete";
 902         }
 903         $line = untabify($line);
 904         if ($from && $to && $line =~ m/^\@{2} /) {
 905                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
 906                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
 907
 908                 $from_lines = 0 unless defined $from_lines;
 909                 $to_lines   = 0 unless defined $to_lines;
 910
 911                 if ($from->{'href'}) {
 912                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
 913                                              -class=>"list"}, $from_text);
 914                 }
 915                 if ($to->{'href'}) {
 916                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
 917                                              -class=>"list"}, $to_text);
 918                 }
 919                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
 920                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
 921                 return "<div class=\"diff$diff_class\">$line</div>\n";
 922         }
 923         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
 924 }
 925
 926 ## ----------------------------------------------------------------------
 927 ## git utility subroutines, invoking git commands
 928
 929 # returns path to the core git executable and the --git-dir parameter as list
 930 sub git_cmd {
 931         return $GIT, '--git-dir='.$git_dir;
 932 }
 933
 934 # returns path to the core git executable and the --git-dir parameter as string
 935 sub git_cmd_str {
 936         return join(' ', git_cmd());
 937 }
 938
 939 # get HEAD ref of given project as hash
 940 sub git_get_head_hash {
 941         my $project = shift;
 942         my $o_git_dir = $git_dir;
 943         my $retval = undef;
 944         $git_dir = "$projectroot/$project";
 945         if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
 946                 my $head = <$fd>;
 947                 close $fd;
 948                 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
 949                         $retval = $1;
 950                 }
 951         }
 952         if (defined $o_git_dir) {
 953                 $git_dir = $o_git_dir;
 954         }
 955         return $retval;
 956 }
 957
 958 # get type of given object
 959 sub git_get_type {
 960         my $hash = shift;
 961
 962         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
 963         my $type = <$fd>;
 964         close $fd or return;
 965         chomp $type;
 966         return $type;
 967 }
 968
 969 sub git_get_project_config {
 970         my ($key, $type) = @_;
 971
 972         return unless ($key);
 973         $key =~ s/^gitweb\.//;
 974         return if ($key =~ m/\W/);
 975
 976         my @x = (git_cmd(), 'repo-config');
 977         if (defined $type) { push @x, $type; }
 978         push @x, "--get";
 979         push @x, "gitweb.$key";
 980         my $val = qx(@x);
 981         chomp $val;
 982         return ($val);
 983 }
 984
 985 # get hash of given path at given ref
 986 sub git_get_hash_by_path {
 987         my $base = shift;
 988         my $path = shift || return undef;
 989         my $type = shift;
 990
 991         $path =~ s,/+$,,;
 992
 993         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
 994                 or die_error(undef, "Open git-ls-tree failed");
 995         my $line = <$fd>;
 996         close $fd or return undef;
 997
 998         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 999         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
1000         if (defined $type && $type ne $2) {
1001                 # type doesn't match
1002                 return undef;
1003         }
1004         return $3;
1005 }
1006
1007 ## ......................................................................
1008 ## git utility functions, directly accessing git repository
1009
1010 sub git_get_project_description {
1011         my $path = shift;
1012
1013         open my $fd, "$projectroot/$path/description" or return undef;
1014         my $descr = <$fd>;
1015         close $fd;
1016         chomp $descr;
1017         return $descr;
1018 }
1019
1020 sub git_get_project_url_list {
1021         my $path = shift;
1022
1023         open my $fd, "$projectroot/$path/cloneurl" or return;
1024         my @git_project_url_list = map { chomp; $_ } <$fd>;
1025         close $fd;
1026
1027         return wantarray ? @git_project_url_list : \@git_project_url_list;
1028 }
1029
1030 sub git_get_projects_list {
1031         my ($filter) = @_;
1032         my @list;
1033
1034         $filter ||= '';
1035         $filter =~ s/\.git$//;
1036
1037         if (-d $projects_list) {
1038                 # search in directory
1039                 my $dir = $projects_list . ($filter ? "/$filter" : '');
1040                 # remove the trailing "/"
1041                 $dir =~ s!/+$!!;
1042                 my $pfxlen = length("$dir");
1043
1044                 my ($check_forks) = gitweb_check_feature('forks');
1045
1046                 File::Find::find({
1047                         follow_fast => 1, # follow symbolic links
1048                         dangling_symlinks => 0, # ignore dangling symlinks, silently
1049                         wanted => sub {
1050                                 # skip project-list toplevel, if we get it.
1051                                 return if (m!^[/.]$!);
1052                                 # only directories can be git repositories
1053                                 return unless (-d $_);
1054
1055                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
1056                                 # we check related file in $projectroot
1057                                 if ($check_forks and $subdir =~ m#/.#) {
1058                                         $File::Find::prune = 1;
1059                                 } elsif (check_export_ok("$projectroot/$filter/$subdir")) {
1060                                         push @list, { path => ($filter ? "$filter/" : '') . $subdir };
1061                                         $File::Find::prune = 1;
1062                                 }
1063                         },
1064                 }, "$dir");
1065
1066         } elsif (-f $projects_list) {
1067                 # read from file(url-encoded):
1068                 # 'git%2Fgit.git Linus+Torvalds'
1069                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1070                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1071                 open my ($fd), $projects_list or return;
1072                 while (my $line = <$fd>) {
1073                         chomp $line;
1074                         my ($path, $owner) = split ' ', $line;
1075                         $path = unescape($path);
1076                         $owner = unescape($owner);
1077                         if (!defined $path) {
1078                                 next;
1079                         }
1080                         if ($filter ne '') {
1081                                 # looking for forks;
1082                                 my $pfx = substr($path, 0, length($filter));
1083                                 if ($pfx ne $filter) {
1084                                         next;
1085                                 }
1086                                 my $sfx = substr($path, length($filter));
1087                                 if ($sfx !~ /^\/.*\.git$/) {
1088                                         next;
1089                                 }
1090                         }
1091                         if (check_export_ok("$projectroot/$path")) {
1092                                 my $pr = {
1093                                         path => $path,
1094                                         owner => to_utf8($owner),
1095                                 };
1096                                 push @list, $pr
1097                         }
1098                 }
1099                 close $fd;
1100         }
1101         @list = sort {$a->{'path'} cmp $b->{'path'}} @list;
1102         return @list;
1103 }
1104
1105 sub git_get_project_owner {
1106         my $project = shift;
1107         my $owner;
1108
1109         return undef unless $project;
1110
1111         # read from file (url-encoded):
1112         # 'git%2Fgit.git Linus+Torvalds'
1113         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1114         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1115         if (-f $projects_list) {
1116                 open (my $fd , $projects_list);
1117                 while (my $line = <$fd>) {
1118                         chomp $line;
1119                         my ($pr, $ow) = split ' ', $line;
1120                         $pr = unescape($pr);
1121                         $ow = unescape($ow);
1122                         if ($pr eq $project) {
1123                                 $owner = to_utf8($ow);
1124                                 last;
1125                         }
1126                 }
1127                 close $fd;
1128         }
1129         if (!defined $owner) {
1130                 $owner = get_file_owner("$projectroot/$project");
1131         }
1132
1133         return $owner;
1134 }
1135
1136 sub git_get_last_activity {
1137         my ($path) = @_;
1138         my $fd;
1139
1140         $git_dir = "$projectroot/$path";
1141         open($fd, "-|", git_cmd(), 'for-each-ref',
1142              '--format=%(refname) %(committer)',
1143              '--sort=-committerdate',
1144              'refs/heads') or return;
1145         my $most_recent = <$fd>;
1146         close $fd or return;
1147         if ($most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
1148                 my $timestamp = $1;
1149                 my $age = time - $timestamp;
1150                 return ($age, age_string($age));
1151         }
1152 }
1153
1154 sub git_get_references {
1155         my $type = shift || "";
1156         my %refs;
1157         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
1158         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
1159         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
1160                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
1161                 or return;
1162
1163         while (my $line = <$fd>) {
1164                 chomp $line;
1165                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type/?[^^]+)!) {
1166                         if (defined $refs{$1}) {
1167                                 push @{$refs{$1}}, $2;
1168                         } else {
1169                                 $refs{$1} = [ $2 ];
1170                         }
1171                 }
1172         }
1173         close $fd or return;
1174         return \%refs;
1175 }
1176
1177 sub git_get_rev_name_tags {
1178         my $hash = shift || return undef;
1179
1180         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
1181                 or return;
1182         my $name_rev = <$fd>;
1183         close $fd;
1184
1185         if ($name_rev =~ m|^$hash tags/(.*)$|) {
1186                 return $1;
1187         } else {
1188                 # catches also '$hash undefined' output
1189                 return undef;
1190         }
1191 }
1192
1193 ## ----------------------------------------------------------------------
1194 ## parse to hash functions
1195
1196 sub parse_date {
1197         my $epoch = shift;
1198         my $tz = shift || "-0000";
1199
1200         my %date;
1201         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
1202         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
1203         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
1204         $date{'hour'} = $hour;
1205         $date{'minute'} = $min;
1206         $date{'mday'} = $mday;
1207         $date{'day'} = $days[$wday];
1208         $date{'month'} = $months[$mon];
1209         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
1210                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
1211         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
1212                              $mday, $months[$mon], $hour ,$min;
1213         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
1214                              1900+$year, $mon, $mday, $hour ,$min, $sec;
1215
1216         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
1217         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
1218         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
1219         $date{'hour_local'} = $hour;
1220         $date{'minute_local'} = $min;
1221         $date{'tz_local'} = $tz;
1222         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
1223                                   1900+$year, $mon+1, $mday,
1224                                   $hour, $min, $sec, $tz);
1225         return %date;
1226 }
1227
1228 sub parse_tag {
1229         my $tag_id = shift;
1230         my %tag;
1231         my @comment;
1232
1233         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
1234         $tag{'id'} = $tag_id;
1235         while (my $line = <$fd>) {
1236                 chomp $line;
1237                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
1238                         $tag{'object'} = $1;
1239                 } elsif ($line =~ m/^type (.+)$/) {
1240                         $tag{'type'} = $1;
1241                 } elsif ($line =~ m/^tag (.+)$/) {
1242                         $tag{'name'} = $1;
1243                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
1244                         $tag{'author'} = $1;
1245                         $tag{'epoch'} = $2;
1246                         $tag{'tz'} = $3;
1247                 } elsif ($line =~ m/--BEGIN/) {
1248                         push @comment, $line;
1249                         last;
1250                 } elsif ($line eq "") {
1251                         last;
1252                 }
1253         }
1254         push @comment, <$fd>;
1255         $tag{'comment'} = \@comment;
1256         close $fd or return;
1257         if (!defined $tag{'name'}) {
1258                 return
1259         };
1260         return %tag
1261 }
1262
1263 sub parse_commit {
1264         my $commit_id = shift;
1265         my $commit_text = shift;
1266
1267         my @commit_lines;
1268         my %co;
1269
1270         if (defined $commit_text) {
1271                 @commit_lines = @$commit_text;
1272         } else {
1273                 local $/ = "\0";
1274                 open my $fd, "-|", git_cmd(), "rev-list",
1275                         "--header", "--parents", "--max-count=1",
1276                         $commit_id, "--"
1277                         or return;
1278                 @commit_lines = split '\n', <$fd>;
1279                 close $fd or return;
1280                 pop @commit_lines;
1281         }
1282         my $header = shift @commit_lines;
1283         if (!($header =~ m/^[0-9a-fA-F]{40}/)) {
1284                 return;
1285         }
1286         ($co{'id'}, my @parents) = split ' ', $header;
1287         $co{'parents'} = \@parents;
1288         $co{'parent'} = $parents[0];
1289         while (my $line = shift @commit_lines) {
1290                 last if $line eq "\n";
1291                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
1292                         $co{'tree'} = $1;
1293                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
1294                         $co{'author'} = $1;
1295                         $co{'author_epoch'} = $2;
1296                         $co{'author_tz'} = $3;
1297                         if ($co{'author'} =~ m/^([^<]+) </) {
1298                                 $co{'author_name'} = $1;
1299                         } else {
1300                                 $co{'author_name'} = $co{'author'};
1301                         }
1302                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
1303                         $co{'committer'} = $1;
1304                         $co{'committer_epoch'} = $2;
1305                         $co{'committer_tz'} = $3;
1306                         $co{'committer_name'} = $co{'committer'};
1307                         $co{'committer_name'} =~ s/ <.*//;
1308                 }
1309         }
1310         if (!defined $co{'tree'}) {
1311                 return;
1312         };
1313
1314         foreach my $title (@commit_lines) {
1315                 $title =~ s/^    //;
1316                 if ($title ne "") {
1317                         $co{'title'} = chop_str($title, 80, 5);
1318                         # remove leading stuff of merges to make the interesting part visible
1319                         if (length($title) > 50) {
1320                                 $title =~ s/^Automatic //;
1321                                 $title =~ s/^merge (of|with) /Merge ... /i;
1322                                 if (length($title) > 50) {
1323                                         $title =~ s/(http|rsync):\/\///;
1324                                 }
1325                                 if (length($title) > 50) {
1326                                         $title =~ s/(master|www|rsync)\.//;
1327                                 }
1328                                 if (length($title) > 50) {
1329                                         $title =~ s/kernel.org:?//;
1330                                 }
1331                                 if (length($title) > 50) {
1332                                         $title =~ s/\/pub\/scm//;
1333                                 }
1334                         }
1335                         $co{'title_short'} = chop_str($title, 50, 5);
1336                         last;
1337                 }
1338         }
1339         if ($co{'title'} eq "") {
1340                 $co{'title'} = $co{'title_short'} = '(no commit message)';
1341         }
1342         # remove added spaces
1343         foreach my $line (@commit_lines) {
1344                 $line =~ s/^    //;
1345         }
1346         $co{'comment'} = \@commit_lines;
1347
1348         my $age = time - $co{'committer_epoch'};
1349         $co{'age'} = $age;
1350         $co{'age_string'} = age_string($age);
1351         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
1352         if ($age > 60*60*24*7*2) {
1353                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1354                 $co{'age_string_age'} = $co{'age_string'};
1355         } else {
1356                 $co{'age_string_date'} = $co{'age_string'};
1357                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1358         }
1359         return %co;
1360 }
1361
1362 # parse ref from ref_file, given by ref_id, with given type
1363 sub parse_ref {
1364         my $ref_file = shift;
1365         my $ref_id = shift;
1366         my $type = shift || git_get_type($ref_id);
1367         my %ref_item;
1368
1369         $ref_item{'type'} = $type;
1370         $ref_item{'id'} = $ref_id;
1371         $ref_item{'epoch'} = 0;
1372         $ref_item{'age'} = "unknown";
1373         if ($type eq "tag") {
1374                 my %tag = parse_tag($ref_id);
1375                 $ref_item{'comment'} = $tag{'comment'};
1376                 if ($tag{'type'} eq "commit") {
1377                         my %co = parse_commit($tag{'object'});
1378                         $ref_item{'epoch'} = $co{'committer_epoch'};
1379                         $ref_item{'age'} = $co{'age_string'};
1380                 } elsif (defined($tag{'epoch'})) {
1381                         my $age = time - $tag{'epoch'};
1382                         $ref_item{'epoch'} = $tag{'epoch'};
1383                         $ref_item{'age'} = age_string($age);
1384                 }
1385                 $ref_item{'reftype'} = $tag{'type'};
1386                 $ref_item{'name'} = $tag{'name'};
1387                 $ref_item{'refid'} = $tag{'object'};
1388         } elsif ($type eq "commit"){
1389                 my %co = parse_commit($ref_id);
1390                 $ref_item{'reftype'} = "commit";
1391                 $ref_item{'name'} = $ref_file;
1392                 $ref_item{'title'} = $co{'title'};
1393                 $ref_item{'refid'} = $ref_id;
1394                 $ref_item{'epoch'} = $co{'committer_epoch'};
1395                 $ref_item{'age'} = $co{'age_string'};
1396         } else {
1397                 $ref_item{'reftype'} = $type;
1398                 $ref_item{'name'} = $ref_file;
1399                 $ref_item{'refid'} = $ref_id;
1400         }
1401
1402         return %ref_item;
1403 }
1404
1405 # parse line of git-diff-tree "raw" output
1406 sub parse_difftree_raw_line {
1407         my $line = shift;
1408         my %res;
1409
1410         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
1411         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
1412         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
1413                 $res{'from_mode'} = $1;
1414                 $res{'to_mode'} = $2;
1415                 $res{'from_id'} = $3;
1416                 $res{'to_id'} = $4;
1417                 $res{'status'} = $5;
1418                 $res{'similarity'} = $6;
1419                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
1420                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
1421                 } else {
1422                         $res{'file'} = unquote($7);
1423                 }
1424         }
1425         # 'c512b523472485aef4fff9e57b229d9d243c967f'
1426         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
1427                 $res{'commit'} = $1;
1428         }
1429
1430         return wantarray ? %res : \%res;
1431 }
1432
1433 # parse line of git-ls-tree output
1434 sub parse_ls_tree_line ($;%) {
1435         my $line = shift;
1436         my %opts = @_;
1437         my %res;
1438
1439         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1440         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
1441
1442         $res{'mode'} = $1;
1443         $res{'type'} = $2;
1444         $res{'hash'} = $3;
1445         if ($opts{'-z'}) {
1446                 $res{'name'} = $4;
1447         } else {
1448                 $res{'name'} = unquote($4);
1449         }
1450
1451         return wantarray ? %res : \%res;
1452 }
1453
1454 ## ......................................................................
1455 ## parse to array of hashes functions
1456
1457 sub git_get_heads_list {
1458         my $limit = shift;
1459         my @headslist;
1460
1461         open my $fd, '-|', git_cmd(), 'for-each-ref',
1462                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
1463                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
1464                 'refs/heads'
1465                 or return;
1466         while (my $line = <$fd>) {
1467                 my %ref_item;
1468
1469                 chomp $line;
1470                 my ($refinfo, $committerinfo) = split(/\0/, $line);
1471                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
1472                 my ($committer, $epoch, $tz) =
1473                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
1474                 $name =~ s!^refs/heads/!!;
1475
1476                 $ref_item{'name'}  = $name;
1477                 $ref_item{'id'}    = $hash;
1478                 $ref_item{'title'} = $title || '(no commit message)';
1479                 $ref_item{'epoch'} = $epoch;
1480                 if ($epoch) {
1481                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1482                 } else {
1483                         $ref_item{'age'} = "unknown";
1484                 }
1485
1486                 push @headslist, \%ref_item;
1487         }
1488         close $fd;
1489
1490         return wantarray ? @headslist : \@headslist;
1491 }
1492
1493 sub git_get_tags_list {
1494         my $limit = shift;
1495         my @tagslist;
1496
1497         open my $fd, '-|', git_cmd(), 'for-each-ref',
1498                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
1499                 '--format=%(objectname) %(objecttype) %(refname) '.
1500                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
1501                 'refs/tags'
1502                 or return;
1503         while (my $line = <$fd>) {
1504                 my %ref_item;
1505
1506                 chomp $line;
1507                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
1508                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
1509                 my ($creator, $epoch, $tz) =
1510                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
1511                 $name =~ s!^refs/tags/!!;
1512
1513                 $ref_item{'type'} = $type;
1514                 $ref_item{'id'} = $id;
1515                 $ref_item{'name'} = $name;
1516                 if ($type eq "tag") {
1517                         $ref_item{'subject'} = $title;
1518                         $ref_item{'reftype'} = $reftype;
1519                         $ref_item{'refid'}   = $refid;
1520                 } else {
1521                         $ref_item{'reftype'} = $type;
1522                         $ref_item{'refid'}   = $id;
1523                 }
1524
1525                 if ($type eq "tag" || $type eq "commit") {
1526                         $ref_item{'epoch'} = $epoch;
1527                         if ($epoch) {
1528                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1529                         } else {
1530                                 $ref_item{'age'} = "unknown";
1531                         }
1532                 }
1533
1534                 push @tagslist, \%ref_item;
1535         }
1536         close $fd;
1537
1538         return wantarray ? @tagslist : \@tagslist;
1539 }
1540
1541 ## ----------------------------------------------------------------------
1542 ## filesystem-related functions
1543
1544 sub get_file_owner {
1545         my $path = shift;
1546
1547         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
1548         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
1549         if (!defined $gcos) {
1550                 return undef;
1551         }
1552         my $owner = $gcos;
1553         $owner =~ s/[,;].*$//;
1554         return to_utf8($owner);
1555 }
1556
1557 ## ......................................................................
1558 ## mimetype related functions
1559
1560 sub mimetype_guess_file {
1561         my $filename = shift;
1562         my $mimemap = shift;
1563         -r $mimemap or return undef;
1564
1565         my %mimemap;
1566         open(MIME, $mimemap) or return undef;
1567         while (<MIME>) {
1568                 next if m/^#/; # skip comments
1569                 my ($mime, $exts) = split(/\t+/);
1570                 if (defined $exts) {
1571                         my @exts = split(/\s+/, $exts);
1572                         foreach my $ext (@exts) {
1573                                 $mimemap{$ext} = $mime;
1574                         }
1575                 }
1576         }
1577         close(MIME);
1578
1579         $filename =~ /\.([^.]*)$/;
1580         return $mimemap{$1};
1581 }
1582
1583 sub mimetype_guess {
1584         my $filename = shift;
1585         my $mime;
1586         $filename =~ /\./ or return undef;
1587
1588         if ($mimetypes_file) {
1589                 my $file = $mimetypes_file;
1590                 if ($file !~ m!^/!) { # if it is relative path
1591                         # it is relative to project
1592                         $file = "$projectroot/$project/$file";
1593                 }
1594                 $mime = mimetype_guess_file($filename, $file);
1595         }
1596         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
1597         return $mime;
1598 }
1599
1600 sub blob_mimetype {
1601         my $fd = shift;
1602         my $filename = shift;
1603
1604         if ($filename) {
1605                 my $mime = mimetype_guess($filename);
1606                 $mime and return $mime;
1607         }
1608
1609         # just in case
1610         return $default_blob_plain_mimetype unless $fd;
1611
1612         if (-T $fd) {
1613                 return 'text/plain' .
1614                        ($default_text_plain_charset ? '; charset='.$default_text_plain_charset : '');
1615         } elsif (! $filename) {
1616                 return 'application/octet-stream';
1617         } elsif ($filename =~ m/\.png$/i) {
1618                 return 'image/png';
1619         } elsif ($filename =~ m/\.gif$/i) {
1620                 return 'image/gif';
1621         } elsif ($filename =~ m/\.jpe?g$/i) {
1622                 return 'image/jpeg';
1623         } else {
1624                 return 'application/octet-stream';
1625         }
1626 }
1627
1628 ## ======================================================================
1629 ## functions printing HTML: header, footer, error page
1630
1631 sub git_header_html {
1632         my $status = shift || "200 OK";
1633         my $expires = shift;
1634
1635         my $title = "$site_name";
1636         if (defined $project) {
1637                 $title .= " - $project";
1638                 if (defined $action) {
1639                         $title .= "/$action";
1640                         if (defined $file_name) {
1641                                 $title .= " - " . esc_path($file_name);
1642                                 if ($action eq "tree" && $file_name !~ m|/$|) {
1643                                         $title .= "/";
1644                                 }
1645                         }
1646                 }
1647         }
1648         my $content_type;
1649         # require explicit support from the UA if we are to send the page as
1650         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
1651         # we have to do this because MSIE sometimes globs '*/*', pretending to
1652         # support xhtml+xml but choking when it gets what it asked for.
1653         if (defined $cgi->http('HTTP_ACCEPT') &&
1654             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
1655             $cgi->Accept('application/xhtml+xml') != 0) {
1656                 $content_type = 'application/xhtml+xml';
1657         } else {
1658                 $content_type = 'text/html';
1659         }
1660         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
1661                            -status=> $status, -expires => $expires);
1662         print <<EOF;
1663 <?xml version="1.0" encoding="utf-8"?>
1664 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1665 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
1666 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
1667 <!-- git core binaries version $git_version -->
1668 <head>
1669 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
1670 <meta name="generator" content="gitweb/$version git/$git_version"/>
1671 <meta name="robots" content="index, nofollow"/>
1672 <title>$title</title>
1673 EOF
1674 # print out each stylesheet that exist
1675         if (defined $stylesheet) {
1676 #provides backwards capability for those people who define style sheet in a config file
1677                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1678         } else {
1679                 foreach my $stylesheet (@stylesheets) {
1680                         next unless $stylesheet;
1681                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1682                 }
1683         }
1684         if (defined $project) {
1685                 printf('<link rel="alternate" title="%s log RSS feed" '.
1686                        'href="%s" type="application/rss+xml" />'."\n",
1687                        esc_param($project), href(action=>"rss"));
1688                 printf('<link rel="alternate" title="%s log Atom feed" '.
1689                        'href="%s" type="application/atom+xml" />'."\n",
1690                        esc_param($project), href(action=>"atom"));
1691         } else {
1692                 printf('<link rel="alternate" title="%s projects list" '.
1693                        'href="%s" type="text/plain; charset=utf-8"/>'."\n",
1694                        $site_name, href(project=>undef, action=>"project_index"));
1695                 printf('<link rel="alternate" title="%s projects feeds" '.
1696                        'href="%s" type="text/x-opml"/>'."\n",
1697                        $site_name, href(project=>undef, action=>"opml"));
1698         }
1699         if (defined $favicon) {
1700                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png"/>\n);
1701         }
1702
1703         print "</head>\n" .
1704               "<body>\n";
1705
1706         if (-f $site_header) {
1707                 open (my $fd, $site_header);
1708                 print <$fd>;
1709                 close $fd;
1710         }
1711
1712         print "<div class=\"page_header\">\n" .
1713               $cgi->a({-href => esc_url($logo_url),
1714                        -title => $logo_label},
1715                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
1716         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
1717         if (defined $project) {
1718                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
1719                 if (defined $action) {
1720                         print " / $action";
1721                 }
1722                 print "\n";
1723                 if (!defined $searchtext) {
1724                         $searchtext = "";
1725                 }
1726                 my $search_hash;
1727                 if (defined $hash_base) {
1728                         $search_hash = $hash_base;
1729                 } elsif (defined $hash) {
1730                         $search_hash = $hash;
1731                 } else {
1732                         $search_hash = "HEAD";
1733                 }
1734                 $cgi->param("a", "search");
1735                 $cgi->param("h", $search_hash);
1736                 $cgi->param("p", $project);
1737                 print $cgi->startform(-method => "get", -action => $my_uri) .
1738                       "<div class=\"search\">\n" .
1739                       $cgi->hidden(-name => "p") . "\n" .
1740                       $cgi->hidden(-name => "a") . "\n" .
1741                       $cgi->hidden(-name => "h") . "\n" .
1742                       $cgi->popup_menu(-name => 'st', -default => 'commit',
1743                                        -values => ['commit', 'author', 'committer', 'pickaxe']) .
1744                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
1745                       " search:\n",
1746                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
1747                       "</div>" .
1748                       $cgi->end_form() . "\n";
1749         }
1750         print "</div>\n";
1751 }
1752
1753 sub git_footer_html {
1754         print "<div class=\"page_footer\">\n";
1755         if (defined $project) {
1756                 my $descr = git_get_project_description($project);
1757                 if (defined $descr) {
1758                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
1759                 }
1760                 print $cgi->a({-href => href(action=>"rss"),
1761                               -class => "rss_logo"}, "RSS") . " ";
1762                 print $cgi->a({-href => href(action=>"atom"),
1763                               -class => "rss_logo"}, "Atom") . "\n";
1764         } else {
1765                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
1766                               -class => "rss_logo"}, "OPML") . " ";
1767                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
1768                               -class => "rss_logo"}, "TXT") . "\n";
1769         }
1770         print "</div>\n" ;
1771
1772         if (-f $site_footer) {
1773                 open (my $fd, $site_footer);
1774                 print <$fd>;
1775                 close $fd;
1776         }
1777
1778         print "</body>\n" .
1779               "</html>";
1780 }
1781
1782 sub die_error {
1783         my $status = shift || "403 Forbidden";
1784         my $error = shift || "Malformed query, file missing or permission denied";
1785
1786         git_header_html($status);
1787         print <<EOF;
1788 <div class="page_body">
1789 <br /><br />
1790 $status - $error
1791 <br />
1792 </div>
1793 EOF
1794         git_footer_html();
1795         exit;
1796 }
1797
1798 ## ----------------------------------------------------------------------
1799 ## functions printing or outputting HTML: navigation
1800
1801 sub git_print_page_nav {
1802         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
1803         $extra = '' if !defined $extra; # pager or formats
1804
1805         my @navs = qw(summary shortlog log commit commitdiff tree);
1806         if ($suppress) {
1807                 @navs = grep { $_ ne $suppress } @navs;
1808         }
1809
1810         my %arg = map { $_ => {action=>$_} } @navs;
1811         if (defined $head) {
1812                 for (qw(commit commitdiff)) {
1813                         $arg{$_}{hash} = $head;
1814                 }
1815                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
1816                         for (qw(shortlog log)) {
1817                                 $arg{$_}{hash} = $head;
1818                         }
1819                 }
1820         }
1821         $arg{tree}{hash} = $treehead if defined $treehead;
1822         $arg{tree}{hash_base} = $treebase if defined $treebase;
1823
1824         print "<div class=\"page_nav\">\n" .
1825                 (join " | ",
1826                  map { $_ eq $current ?
1827                        $_ : $cgi->a({-href => href(%{$arg{$_}})}, "$_")
1828                  } @navs);
1829         print "<br/>\n$extra<br/>\n" .
1830               "</div>\n";
1831 }
1832
1833 sub format_paging_nav {
1834         my ($action, $hash, $head, $page, $nrevs) = @_;
1835         my $paging_nav;
1836
1837
1838         if ($hash ne $head || $page) {
1839                 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
1840         } else {
1841                 $paging_nav .= "HEAD";
1842         }
1843
1844         if ($page > 0) {
1845                 $paging_nav .= " &sdot; " .
1846                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page-1),
1847                                  -accesskey => "p", -title => "Alt-p"}, "prev");
1848         } else {
1849                 $paging_nav .= " &sdot; prev";
1850         }
1851
1852         if ($nrevs >= (100 * ($page+1)-1)) {
1853                 $paging_nav .= " &sdot; " .
1854                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page+1),
1855                                  -accesskey => "n", -title => "Alt-n"}, "next");
1856         } else {
1857                 $paging_nav .= " &sdot; next";
1858         }
1859
1860         return $paging_nav;
1861 }
1862
1863 ## ......................................................................
1864 ## functions printing or outputting HTML: div
1865
1866 sub git_print_header_div {
1867         my ($action, $title, $hash, $hash_base) = @_;
1868         my %args = ();
1869
1870         $args{action} = $action;
1871         $args{hash} = $hash if $hash;
1872         $args{hash_base} = $hash_base if $hash_base;
1873
1874         print "<div class=\"header\">\n" .
1875               $cgi->a({-href => href(%args), -class => "title"},
1876               $title ? $title : $action) .
1877               "\n</div>\n";
1878 }
1879
1880 #sub git_print_authorship (\%) {
1881 sub git_print_authorship {
1882         my $co = shift;
1883
1884         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
1885         print "<div class=\"author_date\">" .
1886               esc_html($co->{'author_name'}) .
1887               " [$ad{'rfc2822'}";
1888         if ($ad{'hour_local'} < 6) {
1889                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
1890                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1891         } else {
1892                 printf(" (%02d:%02d %s)",
1893                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1894         }
1895         print "]</div>\n";
1896 }
1897
1898 sub git_print_page_path {
1899         my $name = shift;
1900         my $type = shift;
1901         my $hb = shift;
1902
1903
1904         print "<div class=\"page_path\">";
1905         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
1906                       -title => 'tree root'}, "[$project]");
1907         print " / ";
1908         if (defined $name) {
1909                 my @dirname = split '/', $name;
1910                 my $basename = pop @dirname;
1911                 my $fullname = '';
1912
1913                 foreach my $dir (@dirname) {
1914                         $fullname .= ($fullname ? '/' : '') . $dir;
1915                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
1916                                                      hash_base=>$hb),
1917                                       -title => esc_html($fullname)}, esc_path($dir));
1918                         print " / ";
1919                 }
1920                 if (defined $type && $type eq 'blob') {
1921                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
1922                                                      hash_base=>$hb),
1923                                       -title => esc_html($name)}, esc_path($basename));
1924                 } elsif (defined $type && $type eq 'tree') {
1925                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
1926                                                      hash_base=>$hb),
1927                                       -title => esc_html($name)}, esc_path($basename));
1928                         print " / ";
1929                 } else {
1930                         print esc_path($basename);
1931                 }
1932         }
1933         print "<br/></div>\n";
1934 }
1935
1936 # sub git_print_log (\@;%) {
1937 sub git_print_log ($;%) {
1938         my $log = shift;
1939         my %opts = @_;
1940
1941         if ($opts{'-remove_title'}) {
1942                 # remove title, i.e. first line of log
1943                 shift @$log;
1944         }
1945         # remove leading empty lines
1946         while (defined $log->[0] && $log->[0] eq "") {
1947                 shift @$log;
1948         }
1949
1950         # print log
1951         my $signoff = 0;
1952         my $empty = 0;
1953         foreach my $line (@$log) {
1954                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
1955                         $signoff = 1;
1956                         $empty = 0;
1957                         if (! $opts{'-remove_signoff'}) {
1958                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
1959                                 next;
1960                         } else {
1961                                 # remove signoff lines
1962                                 next;
1963                         }
1964                 } else {
1965                         $signoff = 0;
1966                 }
1967
1968                 # print only one empty line
1969                 # do not print empty line after signoff
1970                 if ($line eq "") {
1971                         next if ($empty || $signoff);
1972                         $empty = 1;
1973                 } else {
1974                         $empty = 0;
1975                 }
1976
1977                 print format_log_line_html($line) . "<br/>\n";
1978         }
1979
1980         if ($opts{'-final_empty_line'}) {
1981                 # end with single empty line
1982                 print "<br/>\n" unless $empty;
1983         }
1984 }
1985
1986 # print tree entry (row of git_tree), but without encompassing <tr> element
1987 sub git_print_tree_entry {
1988         my ($t, $basedir, $hash_base, $have_blame) = @_;
1989
1990         my %base_key = ();
1991         $base_key{hash_base} = $hash_base if defined $hash_base;
1992
1993         # The format of a table row is: mode list link.  Where mode is
1994         # the mode of the entry, list is the name of the entry, an href,
1995         # and link is the action links of the entry.
1996
1997         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
1998         if ($t->{'type'} eq "blob") {
1999                 print "<td class=\"list\">" .
2000                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2001                                                file_name=>"$basedir$t->{'name'}", %base_key),
2002                                 -class => "list"}, esc_path($t->{'name'})) . "</td>\n";
2003                 print "<td class=\"link\">";
2004                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2005                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2006                               "blob");
2007                 if ($have_blame) {
2008                         print " | " .
2009                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
2010                                                            file_name=>"$basedir$t->{'name'}", %base_key)},
2011                                             "blame");
2012                 }
2013                 if (defined $hash_base) {
2014                         print " | " .
2015                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2016                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
2017                                       "history");
2018                 }
2019                 print " | " .
2020                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
2021                                                file_name=>"$basedir$t->{'name'}")},
2022                                 "raw");
2023                 print "</td>\n";
2024
2025         } elsif ($t->{'type'} eq "tree") {
2026                 print "<td class=\"list\">";
2027                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2028                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2029                               esc_path($t->{'name'}));
2030                 print "</td>\n";
2031                 print "<td class=\"link\">";
2032                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2033                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2034                               "tree");
2035                 if (defined $hash_base) {
2036                         print " | " .
2037                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2038                                                      file_name=>"$basedir$t->{'name'}")},
2039                                       "history");
2040                 }
2041                 print "</td>\n";
2042         }
2043 }
2044
2045 ## ......................................................................
2046 ## functions printing large fragments of HTML
2047
2048 sub git_difftree_body {
2049         my ($difftree, $hash, $parent) = @_;
2050         my ($have_blame) = gitweb_check_feature('blame');
2051         print "<div class=\"list_head\">\n";
2052         if ($#{$difftree} > 10) {
2053                 print(($#{$difftree} + 1) . " files changed:\n");
2054         }
2055         print "</div>\n";
2056
2057         print "<table class=\"diff_tree\">\n";
2058         my $alternate = 1;
2059         my $patchno = 0;
2060         foreach my $line (@{$difftree}) {
2061                 my %diff = parse_difftree_raw_line($line);
2062
2063                 if ($alternate) {
2064                         print "<tr class=\"dark\">\n";
2065                 } else {
2066                         print "<tr class=\"light\">\n";
2067                 }
2068                 $alternate ^= 1;
2069
2070                 my ($to_mode_oct, $to_mode_str, $to_file_type);
2071                 my ($from_mode_oct, $from_mode_str, $from_file_type);
2072                 if ($diff{'to_mode'} ne ('0' x 6)) {
2073                         $to_mode_oct = oct $diff{'to_mode'};
2074                         if (S_ISREG($to_mode_oct)) { # only for regular file
2075                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
2076                         }
2077                         $to_file_type = file_type($diff{'to_mode'});
2078                 }
2079                 if ($diff{'from_mode'} ne ('0' x 6)) {
2080                         $from_mode_oct = oct $diff{'from_mode'};
2081                         if (S_ISREG($to_mode_oct)) { # only for regular file
2082                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
2083                         }
2084                         $from_file_type = file_type($diff{'from_mode'});
2085                 }
2086
2087                 if ($diff{'status'} eq "A") { # created
2088                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
2089                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
2090                         $mode_chng   .= "]</span>";
2091                         print "<td>";
2092                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2093                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2094                                       -class => "list"}, esc_path($diff{'file'}));
2095                         print "</td>\n";
2096                         print "<td>$mode_chng</td>\n";
2097                         print "<td class=\"link\">";
2098                         if ($action eq 'commitdiff') {
2099                                 # link to patch
2100                                 $patchno++;
2101                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2102                                 print " | ";
2103                         }
2104                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2105                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2106                                       "blob") . " | ";
2107                         print "</td>\n";
2108
2109                 } elsif ($diff{'status'} eq "D") { # deleted
2110                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
2111                         print "<td>";
2112                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2113                                                      hash_base=>$parent, file_name=>$diff{'file'}),
2114                                        -class => "list"}, esc_path($diff{'file'}));
2115                         print "</td>\n";
2116                         print "<td>$mode_chng</td>\n";
2117                         print "<td class=\"link\">";
2118                         if ($action eq 'commitdiff') {
2119                                 # link to patch
2120                                 $patchno++;
2121                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2122                                 print " | ";
2123                         }
2124                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2125                                                      hash_base=>$parent, file_name=>$diff{'file'})},
2126                                       "blob") . " | ";
2127                         if ($have_blame) {
2128                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
2129                                                              file_name=>$diff{'file'})},
2130                                               "blame") . " | ";
2131                         }
2132                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
2133                                                      file_name=>$diff{'file'})},
2134                                       "history");
2135                         print "</td>\n";
2136
2137                 } elsif ($diff{'status'} eq "M" || $diff{'status'} eq "T") { # modified, or type changed
2138                         my $mode_chnge = "";
2139                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2140                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
2141                                 if ($from_file_type != $to_file_type) {
2142                                         $mode_chnge .= " from $from_file_type to $to_file_type";
2143                                 }
2144                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
2145                                         if ($from_mode_str && $to_mode_str) {
2146                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
2147                                         } elsif ($to_mode_str) {
2148                                                 $mode_chnge .= " mode: $to_mode_str";
2149                                         }
2150                                 }
2151                                 $mode_chnge .= "]</span>\n";
2152                         }
2153                         print "<td>";
2154                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2155                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2156                                       -class => "list"}, esc_path($diff{'file'}));
2157                         print "</td>\n";
2158                         print "<td>$mode_chnge</td>\n";
2159                         print "<td class=\"link\">";
2160                         if ($action eq 'commitdiff') {
2161                                 # link to patch
2162                                 $patchno++;
2163                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2164                                       " | ";
2165                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2166                                 # "commit" view and modified file (not onlu mode changed)
2167                                 print $cgi->a({-href => href(action=>"blobdiff",
2168                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2169                                                              hash_base=>$hash, hash_parent_base=>$parent,
2170                                                              file_name=>$diff{'file'})},
2171                                               "diff") .
2172                                       " | ";
2173                         }
2174                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2175                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2176                                        "blob") . " | ";
2177                         if ($have_blame) {
2178                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
2179                                                              file_name=>$diff{'file'})},
2180                                               "blame") . " | ";
2181                         }
2182                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2183                                                      file_name=>$diff{'file'})},
2184                                       "history");
2185                         print "</td>\n";
2186
2187                 } elsif ($diff{'status'} eq "R" || $diff{'status'} eq "C") { # renamed or copied
2188                         my %status_name = ('R' => 'moved', 'C' => 'copied');
2189                         my $nstatus = $status_name{$diff{'status'}};
2190                         my $mode_chng = "";
2191                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2192                                 # mode also for directories, so we cannot use $to_mode_str
2193                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
2194                         }
2195                         print "<td>" .
2196                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2197                                                      hash=>$diff{'to_id'}, file_name=>$diff{'to_file'}),
2198                                       -class => "list"}, esc_path($diff{'to_file'})) . "</td>\n" .
2199                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
2200                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
2201                                                      hash=>$diff{'from_id'}, file_name=>$diff{'from_file'}),
2202                                       -class => "list"}, esc_path($diff{'from_file'})) .
2203                               " with " . (int $diff{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
2204                               "<td class=\"link\">";
2205                         if ($action eq 'commitdiff') {
2206                                 # link to patch
2207                                 $patchno++;
2208                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2209                                       " | ";
2210                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2211                                 # "commit" view and modified file (not only pure rename or copy)
2212                                 print $cgi->a({-href => href(action=>"blobdiff",
2213                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2214                                                              hash_base=>$hash, hash_parent_base=>$parent,
2215                                                              file_name=>$diff{'to_file'}, file_parent=>$diff{'from_file'})},
2216                                               "diff") .
2217                                       " | ";
2218                         }
2219                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2220                                                      hash_base=>$parent, file_name=>$diff{'to_file'})},
2221                                       "blob") . " | ";
2222                         if ($have_blame) {
2223                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
2224                                                              file_name=>$diff{'to_file'})},
2225                                               "blame") . " | ";
2226                         }
2227                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2228                                                     file_name=>$diff{'to_file'})},
2229                                       "history");
2230                         print "</td>\n";
2231
2232                 } # we should not encounter Unmerged (U) or Unknown (X) status
2233                 print "</tr>\n";
2234         }
2235         print "</table>\n";
2236 }
2237
2238 sub git_patchset_body {
2239         my ($fd, $difftree, $hash, $hash_parent) = @_;
2240
2241         my $patch_idx = 0;
2242         my $patch_line;
2243         my $diffinfo;
2244         my (%from, %to);
2245         my ($from_id, $to_id);
2246
2247         print "<div class=\"patchset\">\n";
2248
2249         # skip to first patch
2250         while ($patch_line = <$fd>) {
2251                 chomp $patch_line;
2252
2253                 last if ($patch_line =~ m/^diff /);
2254         }
2255
2256  PATCH:
2257         while ($patch_line) {
2258                 my @diff_header;
2259
2260                 # git diff header
2261                 #assert($patch_line =~ m/^diff /) if DEBUG;
2262                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
2263                 push @diff_header, $patch_line;
2264
2265                 # extended diff header
2266         EXTENDED_HEADER:
2267                 while ($patch_line = <$fd>) {
2268                         chomp $patch_line;
2269
2270                         last EXTENDED_HEADER if ($patch_line =~ m/^--- /);
2271
2272                         if ($patch_line =~ m/^index ([0-9a-fA-F]{40})..([0-9a-fA-F]{40})/) {
2273                                 $from_id = $1;
2274                                 $to_id   = $2;
2275                         }
2276
2277                         push @diff_header, $patch_line;
2278                 }
2279                 #last PATCH unless $patch_line;
2280                 my $last_patch_line = $patch_line;
2281
2282                 # check if current patch belong to current raw line
2283                 # and parse raw git-diff line if needed
2284                 if (defined $diffinfo &&
2285                     $diffinfo->{'from_id'} eq $from_id &&
2286                     $diffinfo->{'to_id'}   eq $to_id) {
2287                         # this is split patch
2288                         print "<div class=\"patch cont\">\n";
2289                 } else {
2290                         # advance raw git-diff output if needed
2291                         $patch_idx++ if defined $diffinfo;
2292
2293                         # read and prepare patch information
2294                         if (ref($difftree->[$patch_idx]) eq "HASH") {
2295                                 # pre-parsed (or generated by hand)
2296                                 $diffinfo = $difftree->[$patch_idx];
2297                         } else {
2298                                 $diffinfo = parse_difftree_raw_line($difftree->[$patch_idx]);
2299                         }
2300                         $from{'file'} = $diffinfo->{'from_file'} || $diffinfo->{'file'};
2301                         $to{'file'}   = $diffinfo->{'to_file'}   || $diffinfo->{'file'};
2302                         if ($diffinfo->{'status'} ne "A") { # not new (added) file
2303                                 $from{'href'} = href(action=>"blob", hash_base=>$hash_parent,
2304                                                      hash=>$diffinfo->{'from_id'},
2305                                                      file_name=>$from{'file'});
2306                         }
2307                         if ($diffinfo->{'status'} ne "D") { # not deleted file
2308                                 $to{'href'} = href(action=>"blob", hash_base=>$hash,
2309                                                    hash=>$diffinfo->{'to_id'},
2310                                                    file_name=>$to{'file'});
2311                         }
2312                         # this is first patch for raw difftree line with $patch_idx index
2313                         # we index @$difftree array from 0, but number patches from 1
2314                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
2315                 }
2316
2317                 # print "git diff" header
2318                 $patch_line = shift @diff_header;
2319                 $patch_line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2320                 if ($from{'href'}) {
2321                         $patch_line .= $cgi->a({-href => $from{'href'}, -class => "path"},
2322                                                'a/' . esc_path($from{'file'}));
2323                 } else { # file was added
2324                         $patch_line .= 'a/' . esc_path($from{'file'});
2325                 }
2326                 $patch_line .= ' ';
2327                 if ($to{'href'}) {
2328                         $patch_line .= $cgi->a({-href => $to{'href'}, -class => "path"},
2329                                                'b/' . esc_path($to{'file'}));
2330                 } else { # file was deleted
2331                         $patch_line .= 'b/' . esc_path($to{'file'});
2332                 }
2333                 print "<div class=\"diff header\">$patch_line</div>\n";
2334
2335                 # print extended diff header
2336                 print "<div class=\"diff extended_header\">\n" if (@diff_header > 0);
2337         EXTENDED_HEADER:
2338                 foreach $patch_line (@diff_header) {
2339                         # match <path>
2340                         if ($patch_line =~ s!^((copy|rename) from ).*$!$1! && $from{'href'}) {
2341                                 $patch_line .= $cgi->a({-href=>$from{'href'}, -class=>"path"},
2342                                                         esc_path($from{'file'}));
2343                         }
2344                         if ($patch_line =~ s!^((copy|rename) to ).*$!$1! && $to{'href'}) {
2345                                 $patch_line = $cgi->a({-href=>$to{'href'}, -class=>"path"},
2346                                                       esc_path($to{'file'}));
2347                         }
2348                         # match <mode>
2349                         if ($patch_line =~ m/\s(\d{6})$/) {
2350                                 $patch_line .= '<span class="info"> (' .
2351                                                file_type_long($1) .
2352                                                ')</span>';
2353                         }
2354                         # match <hash>
2355                         if ($patch_line =~ m/^index/) {
2356                                 my ($from_link, $to_link);
2357                                 if ($from{'href'}) {
2358                                         $from_link = $cgi->a({-href=>$from{'href'}, -class=>"hash"},
2359                                                              substr($diffinfo->{'from_id'},0,7));
2360                                 } else {
2361                                         $from_link = '0' x 7;
2362                                 }
2363                                 if ($to{'href'}) {
2364                                         $to_link = $cgi->a({-href=>$to{'href'}, -class=>"hash"},
2365                                                            substr($diffinfo->{'to_id'},0,7));
2366                                 } else {
2367                                         $to_link = '0' x 7;
2368                                 }
2369                                 #affirm {
2370                                 #       my ($from_hash, $to_hash) =
2371                                 #               ($patch_line =~ m/^index ([0-9a-fA-F]{40})..([0-9a-fA-F]{40})/);
2372                                 #       my ($from_id, $to_id) =
2373                                 #               ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2374                                 #       ($from_hash eq $from_id) && ($to_hash eq $to_id);
2375                                 #} if DEBUG;
2376                                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2377                                 $patch_line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2378                         }
2379                         print $patch_line . "<br/>\n";
2380                 }
2381                 print "</div>\n"  if (@diff_header > 0); # class="diff extended_header"
2382
2383                 # from-file/to-file diff header
2384                 $patch_line = $last_patch_line;
2385                 #assert($patch_line =~ m/^---/) if DEBUG;
2386                 if ($from{'href'}) {
2387                         $patch_line = '--- a/' .
2388                                       $cgi->a({-href=>$from{'href'}, -class=>"path"},
2389                                               esc_path($from{'file'}));
2390                 }
2391                 print "<div class=\"diff from_file\">$patch_line</div>\n";
2392
2393                 $patch_line = <$fd>;
2394                 #last PATCH unless $patch_line;
2395                 chomp $patch_line;
2396
2397                 #assert($patch_line =~ m/^+++/) if DEBUG;
2398                 if ($to{'href'}) {
2399                         $patch_line = '+++ b/' .
2400                                       $cgi->a({-href=>$to{'href'}, -class=>"path"},
2401                                               esc_path($to{'file'}));
2402                 }
2403                 print "<div class=\"diff to_file\">$patch_line</div>\n";
2404
2405                 # the patch itself
2406         LINE:
2407                 while ($patch_line = <$fd>) {
2408                         chomp $patch_line;
2409
2410                         next PATCH if ($patch_line =~ m/^diff /);
2411
2412                         print format_diff_line($patch_line, \%from, \%to);
2413                 }
2414
2415         } continue {
2416                 print "</div>\n"; # class="patch"
2417         }
2418
2419         print "</div>\n"; # class="patchset"
2420 }
2421
2422 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
2423
2424 sub git_project_list_body {
2425         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
2426
2427         my ($check_forks) = gitweb_check_feature('forks');
2428
2429         my @projects;
2430         foreach my $pr (@$projlist) {
2431                 my (@aa) = git_get_last_activity($pr->{'path'});
2432                 unless (@aa) {
2433                         next;
2434                 }
2435                 ($pr->{'age'}, $pr->{'age_string'}) = @aa;
2436                 if (!defined $pr->{'descr'}) {
2437                         my $descr = git_get_project_description($pr->{'path'}) || "";
2438                         $pr->{'descr'} = chop_str($descr, 25, 5);
2439                 }
2440                 if (!defined $pr->{'owner'}) {
2441                         $pr->{'owner'} = get_file_owner("$projectroot/$pr->{'path'}") || "";
2442                 }
2443                 if ($check_forks) {
2444                         my $pname = $pr->{'path'};
2445                         if (($pname =~ s/\.git$//) &&
2446                             ($pname !~ /\/$/) &&
2447                             (-d "$projectroot/$pname")) {
2448                                 $pr->{'forks'} = "-d $projectroot/$pname";
2449                         }
2450                         else {
2451                                 $pr->{'forks'} = 0;
2452                         }
2453                 }
2454                 push @projects, $pr;
2455         }
2456
2457         $order ||= "project";
2458         $from = 0 unless defined $from;
2459         $to = $#projects if (!defined $to || $#projects < $to);
2460
2461         print "<table class=\"project_list\">\n";
2462         unless ($no_header) {
2463                 print "<tr>\n";
2464                 if ($check_forks) {
2465                         print "<th></th>\n";
2466                 }
2467                 if ($order eq "project") {
2468                         @projects = sort {$a->{'path'} cmp $b->{'path'}} @projects;
2469                         print "<th>Project</th>\n";
2470                 } else {
2471                         print "<th>" .
2472                               $cgi->a({-href => href(project=>undef, order=>'project'),
2473                                        -class => "header"}, "Project") .
2474                               "</th>\n";
2475                 }
2476                 if ($order eq "descr") {
2477                         @projects = sort {$a->{'descr'} cmp $b->{'descr'}} @projects;
2478                         print "<th>Description</th>\n";
2479                 } else {
2480                         print "<th>" .
2481                               $cgi->a({-href => href(project=>undef, order=>'descr'),
2482                                        -class => "header"}, "Description") .
2483                               "</th>\n";
2484                 }
2485                 if ($order eq "owner") {
2486                         @projects = sort {$a->{'owner'} cmp $b->{'owner'}} @projects;
2487                         print "<th>Owner</th>\n";
2488                 } else {
2489                         print "<th>" .
2490                               $cgi->a({-href => href(project=>undef, order=>'owner'),
2491                                        -class => "header"}, "Owner") .
2492                               "</th>\n";
2493                 }
2494                 if ($order eq "age") {
2495                         @projects = sort {$a->{'age'} <=> $b->{'age'}} @projects;
2496                         print "<th>Last Change</th>\n";
2497                 } else {
2498                         print "<th>" .
2499                               $cgi->a({-href => href(project=>undef, order=>'age'),
2500                                        -class => "header"}, "Last Change") .
2501                               "</th>\n";
2502                 }
2503                 print "<th></th>\n" .
2504                       "</tr>\n";
2505         }
2506         my $alternate = 1;
2507         for (my $i = $from; $i <= $to; $i++) {
2508                 my $pr = $projects[$i];
2509                 if ($alternate) {
2510                         print "<tr class=\"dark\">\n";
2511                 } else {
2512                         print "<tr class=\"light\">\n";
2513                 }
2514                 $alternate ^= 1;
2515                 if ($check_forks) {
2516                         print "<td>";
2517                         if ($pr->{'forks'}) {
2518                                 print "<!-- $pr->{'forks'} -->\n";
2519                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
2520                         }
2521                         print "</td>\n";
2522                 }
2523                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
2524                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
2525                       "<td>" . esc_html($pr->{'descr'}) . "</td>\n" .
2526                       "<td><i>" . chop_str($pr->{'owner'}, 15) . "</i></td>\n";
2527                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
2528                       $pr->{'age_string'} . "</td>\n" .
2529                       "<td class=\"link\">" .
2530                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
2531                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
2532                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
2533                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
2534                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
2535                       "</td>\n" .
2536                       "</tr>\n";
2537         }
2538         if (defined $extra) {
2539                 print "<tr>\n";
2540                 if ($check_forks) {
2541                         print "<td></td>\n";
2542                 }
2543                 print "<td colspan=\"5\">$extra</td>\n" .
2544                       "</tr>\n";
2545         }
2546         print "</table>\n";
2547 }
2548
2549 sub git_shortlog_body {
2550         # uses global variable $project
2551         my ($revlist, $from, $to, $refs, $extra) = @_;
2552
2553         $from = 0 unless defined $from;
2554         $to = $#{$revlist} if (!defined $to || $#{$revlist} < $to);
2555
2556         print "<table class=\"shortlog\" cellspacing=\"0\">\n";
2557         my $alternate = 1;
2558         for (my $i = $from; $i <= $to; $i++) {
2559                 my $commit = $revlist->[$i];
2560                 #my $ref = defined $refs ? format_ref_marker($refs, $commit) : '';
2561                 my $ref = format_ref_marker($refs, $commit);
2562                 my %co = parse_commit($commit);
2563                 if ($alternate) {
2564                         print "<tr class=\"dark\">\n";
2565                 } else {
2566                         print "<tr class=\"light\">\n";
2567                 }
2568                 $alternate ^= 1;
2569                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
2570                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2571                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 10)) . "</i></td>\n" .
2572                       "<td>";
2573                 print format_subject_html($co{'title'}, $co{'title_short'},
2574                                           href(action=>"commit", hash=>$commit), $ref);
2575                 print "</td>\n" .
2576                       "<td class=\"link\">" .
2577                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
2578                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
2579                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
2580                 if (gitweb_have_snapshot()) {
2581                         print " | " . $cgi->a({-href => href(action=>"snapshot", hash=>$commit)}, "snapshot");
2582                 }
2583                 print "</td>\n" .
2584                       "</tr>\n";
2585         }
2586         if (defined $extra) {
2587                 print "<tr>\n" .
2588                       "<td colspan=\"4\">$extra</td>\n" .
2589                       "</tr>\n";
2590         }
2591         print "</table>\n";
2592 }
2593
2594 sub git_history_body {
2595         # Warning: assumes constant type (blob or tree) during history
2596         my ($revlist, $from, $to, $refs, $hash_base, $ftype, $extra) = @_;
2597
2598         $from = 0 unless defined $from;
2599         $to = $#{$revlist} unless (defined $to && $to <= $#{$revlist});
2600
2601         print "<table class=\"history\" cellspacing=\"0\">\n";
2602         my $alternate = 1;
2603         for (my $i = $from; $i <= $to; $i++) {
2604                 if ($revlist->[$i] !~ m/^([0-9a-fA-F]{40})/) {
2605                         next;
2606                 }
2607
2608                 my $commit = $1;
2609                 my %co = parse_commit($commit);
2610                 if (!%co) {
2611                         next;
2612                 }
2613
2614                 my $ref = format_ref_marker($refs, $commit);
2615
2616                 if ($alternate) {
2617                         print "<tr class=\"dark\">\n";
2618                 } else {
2619                         print "<tr class=\"light\">\n";
2620                 }
2621                 $alternate ^= 1;
2622                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2623                       # shortlog uses      chop_str($co{'author_name'}, 10)
2624                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 3)) . "</i></td>\n" .
2625                       "<td>";
2626                 # originally git_history used chop_str($co{'title'}, 50)
2627                 print format_subject_html($co{'title'}, $co{'title_short'},
2628                                           href(action=>"commit", hash=>$commit), $ref);
2629                 print "</td>\n" .
2630                       "<td class=\"link\">" .
2631                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
2632                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
2633
2634                 if ($ftype eq 'blob') {
2635                         my $blob_current = git_get_hash_by_path($hash_base, $file_name);
2636                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
2637                         if (defined $blob_current && defined $blob_parent &&
2638                                         $blob_current ne $blob_parent) {
2639                                 print " | " .
2640                                         $cgi->a({-href => href(action=>"blobdiff",
2641                                                                hash=>$blob_current, hash_parent=>$blob_parent,
2642                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
2643                                                                file_name=>$file_name)},
2644                                                 "diff to current");
2645                         }
2646                 }
2647                 print "</td>\n" .
2648                       "</tr>\n";
2649         }
2650         if (defined $extra) {
2651                 print "<tr>\n" .
2652                       "<td colspan=\"4\">$extra</td>\n" .
2653                       "</tr>\n";
2654         }
2655         print "</table>\n";
2656 }
2657
2658 sub git_tags_body {
2659         # uses global variable $project
2660         my ($taglist, $from, $to, $extra) = @_;
2661         $from = 0 unless defined $from;
2662         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
2663
2664         print "<table class=\"tags\" cellspacing=\"0\">\n";
2665         my $alternate = 1;
2666         for (my $i = $from; $i <= $to; $i++) {
2667                 my $entry = $taglist->[$i];
2668                 my %tag = %$entry;
2669                 my $comment = $tag{'subject'};
2670                 my $comment_short;
2671                 if (defined $comment) {
2672                         $comment_short = chop_str($comment, 30, 5);
2673                 }
2674                 if ($alternate) {
2675                         print "<tr class=\"dark\">\n";
2676                 } else {
2677                         print "<tr class=\"light\">\n";
2678                 }
2679                 $alternate ^= 1;
2680                 print "<td><i>$tag{'age'}</i></td>\n" .
2681                       "<td>" .
2682                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
2683                                -class => "list name"}, esc_html($tag{'name'})) .
2684                       "</td>\n" .
2685                       "<td>";
2686                 if (defined $comment) {
2687                         print format_subject_html($comment, $comment_short,
2688                                                   href(action=>"tag", hash=>$tag{'id'}));
2689                 }
2690                 print "</td>\n" .
2691                       "<td class=\"selflink\">";
2692                 if ($tag{'type'} eq "tag") {
2693                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
2694                 } else {
2695                         print "&nbsp;";
2696                 }
2697                 print "</td>\n" .
2698                       "<td class=\"link\">" . " | " .
2699                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
2700                 if ($tag{'reftype'} eq "commit") {
2701                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'name'})}, "shortlog") .
2702                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'name'})}, "log");
2703                 } elsif ($tag{'reftype'} eq "blob") {
2704                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
2705                 }
2706                 print "</td>\n" .
2707                       "</tr>";
2708         }
2709         if (defined $extra) {
2710                 print "<tr>\n" .
2711                       "<td colspan=\"5\">$extra</td>\n" .
2712                       "</tr>\n";
2713         }
2714         print "</table>\n";
2715 }
2716
2717 sub git_heads_body {
2718         # uses global variable $project
2719         my ($headlist, $head, $from, $to, $extra) = @_;
2720         $from = 0 unless defined $from;
2721         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
2722
2723         print "<table class=\"heads\" cellspacing=\"0\">\n";
2724         my $alternate = 1;
2725         for (my $i = $from; $i <= $to; $i++) {
2726                 my $entry = $headlist->[$i];
2727                 my %ref = %$entry;
2728                 my $curr = $ref{'id'} eq $head;
2729                 if ($alternate) {
2730                         print "<tr class=\"dark\">\n";
2731                 } else {
2732                         print "<tr class=\"light\">\n";
2733                 }
2734                 $alternate ^= 1;
2735                 print "<td><i>$ref{'age'}</i></td>\n" .
2736                       ($curr ? "<td class=\"current_head\">" : "<td>") .
2737                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'}),
2738                                -class => "list name"},esc_html($ref{'name'})) .
2739                       "</td>\n" .
2740                       "<td class=\"link\">" .
2741                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'})}, "shortlog") . " | " .
2742                       $cgi->a({-href => href(action=>"log", hash=>$ref{'name'})}, "log") . " | " .
2743                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'name'}, hash_base=>$ref{'name'})}, "tree") .
2744                       "</td>\n" .
2745                       "</tr>";
2746         }
2747         if (defined $extra) {
2748                 print "<tr>\n" .
2749                       "<td colspan=\"3\">$extra</td>\n" .
2750                       "</tr>\n";
2751         }
2752         print "</table>\n";
2753 }
2754
2755 ## ======================================================================
2756 ## ======================================================================
2757 ## actions
2758
2759 sub git_project_list {
2760         my $order = $cgi->param('o');
2761         if (defined $order && $order !~ m/project|descr|owner|age/) {
2762                 die_error(undef, "Unknown order parameter");
2763         }
2764
2765         my @list = git_get_projects_list();
2766         if (!@list) {
2767                 die_error(undef, "No projects found");
2768         }
2769
2770         git_header_html();
2771         if (-f $home_text) {
2772                 print "<div class=\"index_include\">\n";
2773                 open (my $fd, $home_text);
2774                 print <$fd>;
2775                 close $fd;
2776                 print "</div>\n";
2777         }
2778         git_project_list_body(\@list, $order);
2779         git_footer_html();
2780 }
2781
2782 sub git_forks {
2783         my $order = $cgi->param('o');
2784         if (defined $order && $order !~ m/project|descr|owner|age/) {
2785                 die_error(undef, "Unknown order parameter");
2786         }
2787
2788         my @list = git_get_projects_list($project);
2789         if (!@list) {
2790                 die_error(undef, "No forks found");
2791         }
2792
2793         git_header_html();
2794         git_print_page_nav('','');
2795         git_print_header_div('summary', "$project forks");
2796         git_project_list_body(\@list, $order);
2797         git_footer_html();
2798 }
2799
2800 sub git_project_index {
2801         my @projects = git_get_projects_list($project);
2802
2803         print $cgi->header(
2804                 -type => 'text/plain',
2805                 -charset => 'utf-8',
2806                 -content_disposition => 'inline; filename="index.aux"');
2807
2808         foreach my $pr (@projects) {
2809                 if (!exists $pr->{'owner'}) {
2810                         $pr->{'owner'} = get_file_owner("$projectroot/$project");
2811                 }
2812
2813                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
2814                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
2815                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2816                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2817                 $path  =~ s/ /\+/g;
2818                 $owner =~ s/ /\+/g;
2819
2820                 print "$path $owner\n";
2821         }
2822 }
2823
2824 sub git_summary {
2825         my $descr = git_get_project_description($project) || "none";
2826         my $head = git_get_head_hash($project);
2827         my %co = parse_commit($head);
2828         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
2829
2830         my $owner = git_get_project_owner($project);
2831
2832         my $refs = git_get_references();
2833         my @taglist  = git_get_tags_list(15);
2834         my @headlist = git_get_heads_list(15);
2835         my @forklist;
2836         my ($check_forks) = gitweb_check_feature('forks');
2837
2838         if ($check_forks) {
2839                 @forklist = git_get_projects_list($project);
2840         }
2841
2842         git_header_html();
2843         git_print_page_nav('summary','', $head);
2844
2845         print "<div class=\"title\">&nbsp;</div>\n";
2846         print "<table cellspacing=\"0\">\n" .
2847               "<tr><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
2848               "<tr><td>owner</td><td>$owner</td></tr>\n" .
2849               "<tr><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
2850         # use per project git URL list in $projectroot/$project/cloneurl
2851         # or make project git URL from git base URL and project name
2852         my $url_tag = "URL";
2853         my @url_list = git_get_project_url_list($project);
2854         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
2855         foreach my $git_url (@url_list) {
2856                 next unless $git_url;
2857                 print "<tr><td>$url_tag</td><td>$git_url</td></tr>\n";
2858                 $url_tag = "";
2859         }
2860         print "</table>\n";
2861
2862         if (-s "$projectroot/$project/README.html") {
2863                 if (open my $fd, "$projectroot/$project/README.html") {
2864                         print "<div class=\"title\">readme</div>\n";
2865                         print $_ while (<$fd>);
2866                         close $fd;
2867                 }
2868         }
2869
2870         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=17",
2871                 git_get_head_hash($project), "--"
2872                 or die_error(undef, "Open git-rev-list failed");
2873         my @revlist = map { chomp; $_ } <$fd>;
2874         close $fd;
2875         git_print_header_div('shortlog');
2876         git_shortlog_body(\@revlist, 0, 15, $refs,
2877                           $cgi->a({-href => href(action=>"shortlog")}, "..."));
2878
2879         if (@taglist) {
2880                 git_print_header_div('tags');
2881                 git_tags_body(\@taglist, 0, 15,
2882                               $cgi->a({-href => href(action=>"tags")}, "..."));
2883         }
2884
2885         if (@headlist) {
2886                 git_print_header_div('heads');
2887                 git_heads_body(\@headlist, $head, 0, 15,
2888                                $cgi->a({-href => href(action=>"heads")}, "..."));
2889         }
2890
2891         if (@forklist) {
2892                 git_print_header_div('forks');
2893                 git_project_list_body(\@forklist, undef, 0, 15,
2894                                       $cgi->a({-href => href(action=>"forks")}, "..."),
2895                                       'noheader');
2896         }
2897
2898         git_footer_html();
2899 }
2900
2901 sub git_tag {
2902         my $head = git_get_head_hash($project);
2903         git_header_html();
2904         git_print_page_nav('','', $head,undef,$head);
2905         my %tag = parse_tag($hash);
2906         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
2907         print "<div class=\"title_text\">\n" .
2908               "<table cellspacing=\"0\">\n" .
2909               "<tr>\n" .
2910               "<td>object</td>\n" .
2911               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2912                                $tag{'object'}) . "</td>\n" .
2913               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2914                                               $tag{'type'}) . "</td>\n" .
2915               "</tr>\n";
2916         if (defined($tag{'author'})) {
2917                 my %ad = parse_date($tag{'epoch'}, $tag{'tz'});
2918                 print "<tr><td>author</td><td>" . esc_html($tag{'author'}) . "</td></tr>\n";
2919                 print "<tr><td></td><td>" . $ad{'rfc2822'} .
2920                         sprintf(" (%02d:%02d %s)", $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'}) .
2921                         "</td></tr>\n";
2922         }
2923         print "</table>\n\n" .
2924               "</div>\n";
2925         print "<div class=\"page_body\">";
2926         my $comment = $tag{'comment'};
2927         foreach my $line (@$comment) {
2928                 chomp $line;
2929                 print esc_html($line, -nbsp=>1) . "<br/>\n";
2930         }
2931         print "</div>\n";
2932         git_footer_html();
2933 }
2934
2935 sub git_blame2 {
2936         my $fd;
2937         my $ftype;
2938
2939         my ($have_blame) = gitweb_check_feature('blame');
2940         if (!$have_blame) {
2941                 die_error('403 Permission denied', "Permission denied");
2942         }
2943         die_error('404 Not Found', "File name not defined") if (!$file_name);
2944         $hash_base ||= git_get_head_hash($project);
2945         die_error(undef, "Couldn't find base commit") unless ($hash_base);
2946         my %co = parse_commit($hash_base)
2947                 or die_error(undef, "Reading commit failed");
2948         if (!defined $hash) {
2949                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
2950                         or die_error(undef, "Error looking up file");
2951         }
2952         $ftype = git_get_type($hash);
2953         if ($ftype !~ "blob") {
2954                 die_error("400 Bad Request", "Object is not a blob");
2955         }
2956         open ($fd, "-|", git_cmd(), "blame", '-p', '--',
2957               $file_name, $hash_base)
2958                 or die_error(undef, "Open git-blame failed");
2959         git_header_html();
2960         my $formats_nav =
2961                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2962                         "blob") .
2963                 " | " .
2964                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2965                         "history") .
2966                 " | " .
2967                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
2968                         "HEAD");
2969         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
2970         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
2971         git_print_page_path($file_name, $ftype, $hash_base);
2972         my @rev_color = (qw(light2 dark2));
2973         my $num_colors = scalar(@rev_color);
2974         my $current_color = 0;
2975         my $last_rev;
2976         print <<HTML;
2977 <div class="page_body">
2978 <table class="blame">
2979 <tr><th>Commit</th><th>Line</th><th>Data</th></tr>
2980 HTML
2981         my %metainfo = ();
2982         while (1) {
2983                 $_ = <$fd>;
2984                 last unless defined $_;
2985                 my ($full_rev, $orig_lineno, $lineno, $group_size) =
2986                     /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/;
2987                 if (!exists $metainfo{$full_rev}) {
2988                         $metainfo{$full_rev} = {};
2989                 }
2990                 my $meta = $metainfo{$full_rev};
2991                 while (<$fd>) {
2992                         last if (s/^\t//);
2993                         if (/^(\S+) (.*)$/) {
2994                                 $meta->{$1} = $2;
2995                         }
2996                 }
2997                 my $data = $_;
2998                 chomp $data;
2999                 my $rev = substr($full_rev, 0, 8);
3000                 my $author = $meta->{'author'};
3001                 my %date = parse_date($meta->{'author-time'},
3002                                       $meta->{'author-tz'});
3003                 my $date = $date{'iso-tz'};
3004                 if ($group_size) {
3005                         $current_color = ++$current_color % $num_colors;
3006                 }
3007                 print "<tr class=\"$rev_color[$current_color]\">\n";
3008                 if ($group_size) {
3009                         print "<td class=\"sha1\"";
3010                         print " title=\"". esc_html($author) . ", $date\"";
3011                         print " rowspan=\"$group_size\"" if ($group_size > 1);
3012                         print ">";
3013                         print $cgi->a({-href => href(action=>"commit",
3014                                                      hash=>$full_rev,
3015                                                      file_name=>$file_name)},
3016                                       esc_html($rev));
3017                         print "</td>\n";
3018                 }
3019                 my $blamed = href(action => 'blame',
3020                                   file_name => $meta->{'filename'},
3021                                   hash_base => $full_rev);
3022                 print "<td class=\"linenr\">";
3023                 print $cgi->a({ -href => "$blamed#l$orig_lineno",
3024                                 -id => "l$lineno",
3025                                 -class => "linenr" },
3026                               esc_html($lineno));
3027                 print "</td>";
3028                 print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
3029                 print "</tr>\n";
3030         }
3031         print "</table>\n";
3032         print "</div>";
3033         close $fd
3034                 or print "Reading blob failed\n";
3035         git_footer_html();
3036 }
3037
3038 sub git_blame {
3039         my $fd;
3040
3041         my ($have_blame) = gitweb_check_feature('blame');
3042         if (!$have_blame) {
3043                 die_error('403 Permission denied', "Permission denied");
3044         }
3045         die_error('404 Not Found', "File name not defined") if (!$file_name);
3046         $hash_base ||= git_get_head_hash($project);
3047         die_error(undef, "Couldn't find base commit") unless ($hash_base);
3048         my %co = parse_commit($hash_base)
3049                 or die_error(undef, "Reading commit failed");
3050         if (!defined $hash) {
3051                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
3052                         or die_error(undef, "Error lookup file");
3053         }
3054         open ($fd, "-|", git_cmd(), "annotate", '-l', '-t', '-r', $file_name, $hash_base)
3055                 or die_error(undef, "Open git-annotate failed");
3056         git_header_html();
3057         my $formats_nav =
3058                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3059                         "blob") .
3060                 " | " .
3061                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3062                         "history") .
3063                 " | " .
3064                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
3065                         "HEAD");
3066         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3067         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3068         git_print_page_path($file_name, 'blob', $hash_base);
3069         print "<div class=\"page_body\">\n";
3070         print <<HTML;
3071 <table class="blame">
3072   <tr>
3073     <th>Commit</th>
3074     <th>Age</th>
3075     <th>Author</th>
3076     <th>Line</th>
3077     <th>Data</th>
3078   </tr>
3079 HTML
3080         my @line_class = (qw(light dark));
3081         my $line_class_len = scalar (@line_class);
3082         my $line_class_num = $#line_class;
3083         while (my $line = <$fd>) {
3084                 my $long_rev;
3085                 my $short_rev;
3086                 my $author;
3087                 my $time;
3088                 my $lineno;
3089                 my $data;
3090                 my $age;
3091                 my $age_str;
3092                 my $age_class;
3093
3094                 chomp $line;
3095                 $line_class_num = ($line_class_num + 1) % $line_class_len;
3096
3097                 if ($line =~ m/^([0-9a-fA-F]{40})\t\(\s*([^\t]+)\t(\d+) [+-]\d\d\d\d\t(\d+)\)(.*)$/) {
3098                         $long_rev = $1;
3099                         $author   = $2;
3100                         $time     = $3;
3101                         $lineno   = $4;
3102                         $data     = $5;
3103                 } else {
3104                         print qq(  <tr><td colspan="5" class="error">Unable to parse: $line</td></tr>\n);
3105                         next;
3106                 }
3107                 $short_rev  = substr ($long_rev, 0, 8);
3108                 $age        = time () - $time;
3109                 $age_str    = age_string ($age);
3110                 $age_str    =~ s/ /&nbsp;/g;
3111                 $age_class  = age_class($age);
3112                 $author     = esc_html ($author);
3113                 $author     =~ s/ /&nbsp;/g;
3114
3115                 $data = untabify($data);
3116                 $data = esc_html ($data);
3117
3118                 print <<HTML;
3119   <tr class="$line_class[$line_class_num]">
3120     <td class="sha1"><a href="${\href (action=>"commit", hash=>$long_rev)}" class="text">$short_rev..</a></td>
3121     <td class="$age_class">$age_str</td>
3122     <td>$author</td>
3123     <td class="linenr"><a id="$lineno" href="#$lineno" class="linenr">$lineno</a></td>
3124     <td class="pre">$data</td>
3125   </tr>
3126 HTML
3127         } # while (my $line = <$fd>)
3128         print "</table>\n\n";
3129         close $fd
3130                 or print "Reading blob failed.\n";
3131         print "</div>";
3132         git_footer_html();
3133 }
3134
3135 sub git_tags {
3136         my $head = git_get_head_hash($project);
3137         git_header_html();
3138         git_print_page_nav('','', $head,undef,$head);
3139         git_print_header_div('summary', $project);
3140
3141         my @tagslist = git_get_tags_list();
3142         if (@tagslist) {
3143                 git_tags_body(\@tagslist);
3144         }
3145         git_footer_html();
3146 }
3147
3148 sub git_heads {
3149         my $head = git_get_head_hash($project);
3150         git_header_html();
3151         git_print_page_nav('','', $head,undef,$head);
3152         git_print_header_div('summary', $project);
3153
3154         my @headslist = git_get_heads_list();
3155         if (@headslist) {
3156                 git_heads_body(\@headslist, $head);
3157         }
3158         git_footer_html();
3159 }
3160
3161 sub git_blob_plain {
3162         my $expires;
3163
3164         if (!defined $hash) {
3165                 if (defined $file_name) {
3166                         my $base = $hash_base || git_get_head_hash($project);
3167                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3168                                 or die_error(undef, "Error lookup file");
3169                 } else {
3170                         die_error(undef, "No file name defined");
3171                 }
3172         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3173                 # blobs defined by non-textual hash id's can be cached
3174                 $expires = "+1d";
3175         }
3176
3177         my $type = shift;
3178         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3179                 or die_error(undef, "Couldn't cat $file_name, $hash");
3180
3181         $type ||= blob_mimetype($fd, $file_name);
3182
3183         # save as filename, even when no $file_name is given
3184         my $save_as = "$hash";
3185         if (defined $file_name) {
3186                 $save_as = $file_name;
3187         } elsif ($type =~ m/^text\//) {
3188                 $save_as .= '.txt';
3189         }
3190
3191         print $cgi->header(
3192                 -type => "$type",
3193                 -expires=>$expires,
3194                 -content_disposition => 'inline; filename="' . "$save_as" . '"');
3195         undef $/;
3196         binmode STDOUT, ':raw';
3197         print <$fd>;
3198         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3199         $/ = "\n";
3200         close $fd;
3201 }
3202
3203 sub git_blob {
3204         my $expires;
3205
3206         if (!defined $hash) {
3207                 if (defined $file_name) {
3208                         my $base = $hash_base || git_get_head_hash($project);
3209                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3210                                 or die_error(undef, "Error lookup file");
3211                 } else {
3212                         die_error(undef, "No file name defined");
3213                 }
3214         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3215                 # blobs defined by non-textual hash id's can be cached
3216                 $expires = "+1d";
3217         }
3218
3219         my ($have_blame) = gitweb_check_feature('blame');
3220         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3221                 or die_error(undef, "Couldn't cat $file_name, $hash");
3222         my $mimetype = blob_mimetype($fd, $file_name);
3223         if ($mimetype !~ m/^text\//) {
3224                 close $fd;
3225                 return git_blob_plain($mimetype);
3226         }
3227         git_header_html(undef, $expires);
3228         my $formats_nav = '';
3229         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3230                 if (defined $file_name) {
3231                         if ($have_blame) {
3232                                 $formats_nav .=
3233                                         $cgi->a({-href => href(action=>"blame", hash_base=>$hash_base,
3234                                                                hash=>$hash, file_name=>$file_name)},
3235                                                 "blame") .
3236                                         " | ";
3237                         }
3238                         $formats_nav .=
3239                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3240                                                        hash=>$hash, file_name=>$file_name)},
3241                                         "history") .
3242                                 " | " .
3243                                 $cgi->a({-href => href(action=>"blob_plain",
3244                                                        hash=>$hash, file_name=>$file_name)},
3245                                         "raw") .
3246                                 " | " .
3247                                 $cgi->a({-href => href(action=>"blob",
3248                                                        hash_base=>"HEAD", file_name=>$file_name)},
3249                                         "HEAD");
3250                 } else {
3251                         $formats_nav .=
3252                                 $cgi->a({-href => href(action=>"blob_plain", hash=>$hash)}, "raw");
3253                 }
3254                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3255                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3256         } else {
3257                 print "<div class=\"page_nav\">\n" .
3258                       "<br/><br/></div>\n" .
3259                       "<div class=\"title\">$hash</div>\n";
3260         }
3261         git_print_page_path($file_name, "blob", $hash_base);
3262         print "<div class=\"page_body\">\n";
3263         my $nr;
3264         while (my $line = <$fd>) {
3265                 chomp $line;
3266                 $nr++;
3267                 $line = untabify($line);
3268                 printf "<div class=\"pre\"><a id=\"l%i\" href=\"#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
3269                        $nr, $nr, $nr, esc_html($line, -nbsp=>1);
3270         }
3271         close $fd
3272                 or print "Reading blob failed.\n";
3273         print "</div>";
3274         git_footer_html();
3275 }
3276
3277 sub git_tree {
3278         my $have_snapshot = gitweb_have_snapshot();
3279
3280         if (!defined $hash_base) {
3281                 $hash_base = "HEAD";
3282         }
3283         if (!defined $hash) {
3284                 if (defined $file_name) {
3285                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
3286                 } else {
3287                         $hash = $hash_base;
3288                 }
3289         }
3290         $/ = "\0";
3291         open my $fd, "-|", git_cmd(), "ls-tree", '-z', $hash
3292                 or die_error(undef, "Open git-ls-tree failed");
3293         my @entries = map { chomp; $_ } <$fd>;
3294         close $fd or die_error(undef, "Reading tree failed");
3295         $/ = "\n";
3296
3297         my $refs = git_get_references();
3298         my $ref = format_ref_marker($refs, $hash_base);
3299         git_header_html();
3300         my $basedir = '';
3301         my ($have_blame) = gitweb_check_feature('blame');
3302         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3303                 my @views_nav = ();
3304                 if (defined $file_name) {
3305                         push @views_nav,
3306                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3307                                                        hash=>$hash, file_name=>$file_name)},
3308                                         "history"),
3309                                 $cgi->a({-href => href(action=>"tree",
3310                                                        hash_base=>"HEAD", file_name=>$file_name)},
3311                                         "HEAD"),
3312                 }
3313                 if ($have_snapshot) {
3314                         # FIXME: Should be available when we have no hash base as well.
3315                         push @views_nav,
3316                                 $cgi->a({-href => href(action=>"snapshot", hash=>$hash)},
3317                                         "snapshot");
3318                 }
3319                 git_print_page_nav('tree','', $hash_base, undef, undef, join(' | ', @views_nav));
3320                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
3321         } else {
3322                 undef $hash_base;
3323                 print "<div class=\"page_nav\">\n";
3324                 print "<br/><br/></div>\n";
3325                 print "<div class=\"title\">$hash</div>\n";
3326         }
3327         if (defined $file_name) {
3328                 $basedir = $file_name;
3329                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
3330                         $basedir .= '/';
3331                 }
3332         }
3333         git_print_page_path($file_name, 'tree', $hash_base);
3334         print "<div class=\"page_body\">\n";
3335         print "<table cellspacing=\"0\">\n";
3336         my $alternate = 1;
3337         # '..' (top directory) link if possible
3338         if (defined $hash_base &&
3339             defined $file_name && $file_name =~ m![^/]+$!) {
3340                 if ($alternate) {
3341                         print "<tr class=\"dark\">\n";
3342                 } else {
3343                         print "<tr class=\"light\">\n";
3344                 }
3345                 $alternate ^= 1;
3346
3347                 my $up = $file_name;
3348                 $up =~ s!/?[^/]+$!!;
3349                 undef $up unless $up;
3350                 # based on git_print_tree_entry
3351                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
3352                 print '<td class="list">';
3353                 print $cgi->a({-href => href(action=>"tree", hash_base=>$hash_base,
3354                                              file_name=>$up)},
3355                               "..");
3356                 print "</td>\n";
3357                 print "<td class=\"link\"></td>\n";
3358
3359                 print "</tr>\n";
3360         }
3361         foreach my $line (@entries) {
3362                 my %t = parse_ls_tree_line($line, -z => 1);
3363
3364                 if ($alternate) {
3365                         print "<tr class=\"dark\">\n";
3366                 } else {
3367                         print "<tr class=\"light\">\n";
3368                 }
3369                 $alternate ^= 1;
3370
3371                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
3372
3373                 print "</tr>\n";
3374         }
3375         print "</table>\n" .
3376               "</div>";
3377         git_footer_html();
3378 }
3379
3380 sub git_snapshot {
3381         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
3382         my $have_snapshot = (defined $ctype && defined $suffix);
3383         if (!$have_snapshot) {
3384                 die_error('403 Permission denied', "Permission denied");
3385         }
3386
3387         if (!defined $hash) {
3388                 $hash = git_get_head_hash($project);
3389         }
3390
3391         my $filename = basename($project) . "-$hash.tar.$suffix";
3392
3393         print $cgi->header(
3394                 -type => 'application/x-tar',
3395                 -content_encoding => $ctype,
3396                 -content_disposition => 'inline; filename="' . "$filename" . '"',
3397                 -status => '200 OK');
3398
3399         my $git = git_cmd_str();
3400         my $name = $project;
3401         $name =~ s/\047/\047\\\047\047/g;
3402         open my $fd, "-|",
3403         "$git archive --format=tar --prefix=\'$name\'/ $hash | $command"
3404                 or die_error(undef, "Execute git-tar-tree failed.");
3405         binmode STDOUT, ':raw';
3406         print <$fd>;
3407         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3408         close $fd;
3409
3410 }
3411
3412 sub git_log {
3413         my $head = git_get_head_hash($project);
3414         if (!defined $hash) {
3415                 $hash = $head;
3416         }
3417         if (!defined $page) {
3418                 $page = 0;
3419         }
3420         my $refs = git_get_references();
3421
3422         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3423         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
3424                 or die_error(undef, "Open git-rev-list failed");
3425         my @revlist = map { chomp; $_ } <$fd>;
3426         close $fd;
3427
3428         my $paging_nav = format_paging_nav('log', $hash, $head, $page, $#revlist);
3429
3430         git_header_html();
3431         git_print_page_nav('log','', $hash,undef,undef, $paging_nav);
3432
3433         if (!@revlist) {
3434                 my %co = parse_commit($hash);
3435
3436                 git_print_header_div('summary', $project);
3437                 print "<div class=\"page_body\"> Last change $co{'age_string'}.<br/><br/></div>\n";
3438         }
3439         for (my $i = ($page * 100); $i <= $#revlist; $i++) {
3440                 my $commit = $revlist[$i];
3441                 my $ref = format_ref_marker($refs, $commit);
3442                 my %co = parse_commit($commit);
3443                 next if !%co;
3444                 my %ad = parse_date($co{'author_epoch'});
3445                 git_print_header_div('commit',
3446                                "<span class=\"age\">$co{'age_string'}</span>" .
3447                                esc_html($co{'title'}) . $ref,
3448                                $commit);
3449                 print "<div class=\"title_text\">\n" .
3450                       "<div class=\"log_link\">\n" .
3451                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
3452                       " | " .
3453                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
3454                       " | " .
3455                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
3456                       "<br/>\n" .
3457                       "</div>\n" .
3458                       "<i>" . esc_html($co{'author_name'}) .  " [$ad{'rfc2822'}]</i><br/>\n" .
3459                       "</div>\n";
3460
3461                 print "<div class=\"log_body\">\n";
3462                 git_print_log($co{'comment'}, -final_empty_line=> 1);
3463                 print "</div>\n";
3464         }
3465         git_footer_html();
3466 }
3467
3468 sub git_commit {
3469         $hash ||= $hash_base || "HEAD";
3470         my %co = parse_commit($hash);
3471         if (!%co) {
3472                 die_error(undef, "Unknown commit object");
3473         }
3474         my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3475         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
3476
3477         my $parent = $co{'parent'};
3478         if (!defined $parent) {
3479                 $parent = "--root";
3480         }
3481         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
3482                 @diff_opts, $parent, $hash, "--"
3483                 or die_error(undef, "Open git-diff-tree failed");
3484         my @difftree = map { chomp; $_ } <$fd>;
3485         close $fd or die_error(undef, "Reading git-diff-tree failed");
3486
3487         # non-textual hash id's can be cached
3488         my $expires;
3489         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3490                 $expires = "+1d";
3491         }
3492         my $refs = git_get_references();
3493         my $ref = format_ref_marker($refs, $co{'id'});
3494
3495         my $have_snapshot = gitweb_have_snapshot();
3496
3497         my @views_nav = ();
3498         if (defined $file_name && defined $co{'parent'}) {
3499                 push @views_nav,
3500                         $cgi->a({-href => href(action=>"blame", hash_parent=>$parent, file_name=>$file_name)},
3501                                 "blame");
3502         }
3503         git_header_html(undef, $expires);
3504         git_print_page_nav('commit', '',
3505                            $hash, $co{'tree'}, $hash,
3506                            join (' | ', @views_nav));
3507
3508         if (defined $co{'parent'}) {
3509                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
3510         } else {
3511                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
3512         }
3513         print "<div class=\"title_text\">\n" .
3514               "<table cellspacing=\"0\">\n";
3515         print "<tr><td>author</td><td>" . esc_html($co{'author'}) . "</td></tr>\n".
3516               "<tr>" .
3517               "<td></td><td> $ad{'rfc2822'}";
3518         if ($ad{'hour_local'} < 6) {
3519                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3520                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3521         } else {
3522                 printf(" (%02d:%02d %s)",
3523                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3524         }
3525         print "</td>" .
3526               "</tr>\n";
3527         print "<tr><td>committer</td><td>" . esc_html($co{'committer'}) . "</td></tr>\n";
3528         print "<tr><td></td><td> $cd{'rfc2822'}" .
3529               sprintf(" (%02d:%02d %s)", $cd{'hour_local'}, $cd{'minute_local'}, $cd{'tz_local'}) .
3530               "</td></tr>\n";
3531         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
3532         print "<tr>" .
3533               "<td>tree</td>" .
3534               "<td class=\"sha1\">" .
3535               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
3536                        class => "list"}, $co{'tree'}) .
3537               "</td>" .
3538               "<td class=\"link\">" .
3539               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
3540                       "tree");
3541         if ($have_snapshot) {
3542                 print " | " .
3543                       $cgi->a({-href => href(action=>"snapshot", hash=>$hash)}, "snapshot");
3544         }
3545         print "</td>" .
3546               "</tr>\n";
3547         my $parents = $co{'parents'};
3548         foreach my $par (@$parents) {
3549                 print "<tr>" .
3550                       "<td>parent</td>" .
3551                       "<td class=\"sha1\">" .
3552                       $cgi->a({-href => href(action=>"commit", hash=>$par),
3553                                class => "list"}, $par) .
3554                       "</td>" .
3555                       "<td class=\"link\">" .
3556                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
3557                       " | " .
3558                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
3559                       "</td>" .
3560                       "</tr>\n";
3561         }
3562         print "</table>".
3563               "</div>\n";
3564
3565         print "<div class=\"page_body\">\n";
3566         git_print_log($co{'comment'});
3567         print "</div>\n";
3568
3569         git_difftree_body(\@difftree, $hash, $parent);
3570
3571         git_footer_html();
3572 }
3573
3574 sub git_blobdiff {
3575         my $format = shift || 'html';
3576
3577         my $fd;
3578         my @difftree;
3579         my %diffinfo;
3580         my $expires;
3581
3582         # preparing $fd and %diffinfo for git_patchset_body
3583         # new style URI
3584         if (defined $hash_base && defined $hash_parent_base) {
3585                 if (defined $file_name) {
3586                         # read raw output
3587                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3588                                 $hash_parent_base, $hash_base,
3589                                 "--", $file_name
3590                                 or die_error(undef, "Open git-diff-tree failed");
3591                         @difftree = map { chomp; $_ } <$fd>;
3592                         close $fd
3593                                 or die_error(undef, "Reading git-diff-tree failed");
3594                         @difftree
3595                                 or die_error('404 Not Found', "Blob diff not found");
3596
3597                 } elsif (defined $hash &&
3598                          $hash =~ /[0-9a-fA-F]{40}/) {
3599                         # try to find filename from $hash
3600
3601                         # read filtered raw output
3602                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3603                                 $hash_parent_base, $hash_base, "--"
3604                                 or die_error(undef, "Open git-diff-tree failed");
3605                         @difftree =
3606                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
3607                                 # $hash == to_id
3608                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
3609                                 map { chomp; $_ } <$fd>;
3610                         close $fd
3611                                 or die_error(undef, "Reading git-diff-tree failed");
3612                         @difftree
3613                                 or die_error('404 Not Found', "Blob diff not found");
3614
3615                 } else {
3616                         die_error('404 Not Found', "Missing one of the blob diff parameters");
3617                 }
3618
3619                 if (@difftree > 1) {
3620                         die_error('404 Not Found', "Ambiguous blob diff specification");
3621                 }
3622
3623                 %diffinfo = parse_difftree_raw_line($difftree[0]);
3624                 $file_parent ||= $diffinfo{'from_file'} || $file_name || $diffinfo{'file'};
3625                 $file_name   ||= $diffinfo{'to_file'}   || $diffinfo{'file'};
3626
3627                 $hash_parent ||= $diffinfo{'from_id'};
3628                 $hash        ||= $diffinfo{'to_id'};
3629
3630                 # non-textual hash id's can be cached
3631                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
3632                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
3633                         $expires = '+1d';
3634                 }
3635
3636                 # open patch output
3637                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3638                         '-p', $hash_parent_base, $hash_base,
3639                         "--", $file_name
3640                         or die_error(undef, "Open git-diff-tree failed");
3641         }
3642
3643         # old/legacy style URI
3644         if (!%diffinfo && # if new style URI failed
3645             defined $hash && defined $hash_parent) {
3646                 # fake git-diff-tree raw output
3647                 $diffinfo{'from_mode'} = $diffinfo{'to_mode'} = "blob";
3648                 $diffinfo{'from_id'} = $hash_parent;
3649                 $diffinfo{'to_id'}   = $hash;
3650                 if (defined $file_name) {
3651                         if (defined $file_parent) {
3652                                 $diffinfo{'status'} = '2';
3653                                 $diffinfo{'from_file'} = $file_parent;
3654                                 $diffinfo{'to_file'}   = $file_name;
3655                         } else { # assume not renamed
3656                                 $diffinfo{'status'} = '1';
3657                                 $diffinfo{'from_file'} = $file_name;
3658                                 $diffinfo{'to_file'}   = $file_name;
3659                         }
3660                 } else { # no filename given
3661                         $diffinfo{'status'} = '2';
3662                         $diffinfo{'from_file'} = $hash_parent;
3663                         $diffinfo{'to_file'}   = $hash;
3664                 }
3665
3666                 # non-textual hash id's can be cached
3667                 if ($hash =~ m/^[0-9a-fA-F]{40}$/ &&
3668                     $hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3669                         $expires = '+1d';
3670                 }
3671
3672                 # open patch output
3673                 open $fd, "-|", git_cmd(), "diff", '-p', @diff_opts,
3674                         $hash_parent, $hash, "--"
3675                         or die_error(undef, "Open git-diff failed");
3676         } else  {
3677                 die_error('404 Not Found', "Missing one of the blob diff parameters")
3678                         unless %diffinfo;
3679         }
3680
3681         # header
3682         if ($format eq 'html') {
3683                 my $formats_nav =
3684                         $cgi->a({-href => href(action=>"blobdiff_plain",
3685                                                hash=>$hash, hash_parent=>$hash_parent,
3686                                                hash_base=>$hash_base, hash_parent_base=>$hash_parent_base,
3687                                                file_name=>$file_name, file_parent=>$file_parent)},
3688                                 "raw");
3689                 git_header_html(undef, $expires);
3690                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3691                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3692                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3693                 } else {
3694                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
3695                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
3696                 }
3697                 if (defined $file_name) {
3698                         git_print_page_path($file_name, "blob", $hash_base);
3699                 } else {
3700                         print "<div class=\"page_path\"></div>\n";
3701                 }
3702
3703         } elsif ($format eq 'plain') {
3704                 print $cgi->header(
3705                         -type => 'text/plain',
3706                         -charset => 'utf-8',
3707                         -expires => $expires,
3708                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
3709
3710                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3711
3712         } else {
3713                 die_error(undef, "Unknown blobdiff format");
3714         }
3715
3716         # patch
3717         if ($format eq 'html') {
3718                 print "<div class=\"page_body\">\n";
3719
3720                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
3721                 close $fd;
3722
3723                 print "</div>\n"; # class="page_body"
3724                 git_footer_html();
3725
3726         } else {
3727                 while (my $line = <$fd>) {
3728                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
3729                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
3730
3731                         print $line;
3732
3733                         last if $line =~ m!^\+\+\+!;
3734                 }
3735                 local $/ = undef;
3736                 print <$fd>;
3737                 close $fd;
3738         }
3739 }
3740
3741 sub git_blobdiff_plain {
3742         git_blobdiff('plain');
3743 }
3744
3745 sub git_commitdiff {
3746         my $format = shift || 'html';
3747         $hash ||= $hash_base || "HEAD";
3748         my %co = parse_commit($hash);
3749         if (!%co) {
3750                 die_error(undef, "Unknown commit object");
3751         }
3752
3753         # we need to prepare $formats_nav before any parameter munging
3754         my $formats_nav;
3755         if ($format eq 'html') {
3756                 $formats_nav =
3757                         $cgi->a({-href => href(action=>"commitdiff_plain",
3758                                                hash=>$hash, hash_parent=>$hash_parent)},
3759                                 "raw");
3760
3761                 if (defined $hash_parent) {
3762                         # commitdiff with two commits given
3763                         my $hash_parent_short = $hash_parent;
3764                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3765                                 $hash_parent_short = substr($hash_parent, 0, 7);
3766                         }
3767                         $formats_nav .=
3768                                 ' (from: ' .
3769                                 $cgi->a({-href => href(action=>"commitdiff",
3770                                                        hash=>$hash_parent)},
3771                                         esc_html($hash_parent_short)) .
3772                                 ')';
3773                 } elsif (!$co{'parent'}) {
3774                         # --root commitdiff
3775                         $formats_nav .= ' (initial)';
3776                 } elsif (scalar @{$co{'parents'}} == 1) {
3777                         # single parent commit
3778                         $formats_nav .=
3779                                 ' (parent: ' .
3780                                 $cgi->a({-href => href(action=>"commitdiff",
3781                                                        hash=>$co{'parent'})},
3782                                         esc_html(substr($co{'parent'}, 0, 7))) .
3783                                 ')';
3784                 } else {
3785                         # merge commit
3786                         $formats_nav .=
3787                                 ' (merge: ' .
3788                                 join(' ', map {
3789                                         $cgi->a({-href => href(action=>"commitdiff",
3790                                                                hash=>$_)},
3791                                                 esc_html(substr($_, 0, 7)));
3792                                 } @{$co{'parents'}} ) .
3793                                 ')';
3794                 }
3795         }
3796
3797         if (!defined $hash_parent) {
3798                 $hash_parent = $co{'parent'} || '--root';
3799         }
3800
3801         # read commitdiff
3802         my $fd;
3803         my @difftree;
3804         if ($format eq 'html') {
3805                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3806                         "--no-commit-id", "--patch-with-raw", "--full-index",
3807                         $hash_parent, $hash, "--"
3808                         or die_error(undef, "Open git-diff-tree failed");
3809
3810                 while (my $line = <$fd>) {
3811                         chomp $line;
3812                         # empty line ends raw part of diff-tree output
3813                         last unless $line;
3814                         push @difftree, $line;
3815                 }
3816
3817         } elsif ($format eq 'plain') {
3818                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3819                         '-p', $hash_parent, $hash, "--"
3820                         or die_error(undef, "Open git-diff-tree failed");
3821
3822         } else {
3823                 die_error(undef, "Unknown commitdiff format");
3824         }
3825
3826         # non-textual hash id's can be cached
3827         my $expires;
3828         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3829                 $expires = "+1d";
3830         }
3831
3832         # write commit message
3833         if ($format eq 'html') {
3834                 my $refs = git_get_references();
3835                 my $ref = format_ref_marker($refs, $co{'id'});
3836
3837                 git_header_html(undef, $expires);
3838                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
3839                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
3840                 git_print_authorship(\%co);
3841                 print "<div class=\"page_body\">\n";
3842                 if (@{$co{'comment'}} > 1) {
3843                         print "<div class=\"log\">\n";
3844                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
3845                         print "</div>\n"; # class="log"
3846                 }
3847
3848         } elsif ($format eq 'plain') {
3849                 my $refs = git_get_references("tags");
3850                 my $tagname = git_get_rev_name_tags($hash);
3851                 my $filename = basename($project) . "-$hash.patch";
3852
3853                 print $cgi->header(
3854                         -type => 'text/plain',
3855                         -charset => 'utf-8',
3856                         -expires => $expires,
3857                         -content_disposition => 'inline; filename="' . "$filename" . '"');
3858                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3859                 print <<TEXT;
3860 From: $co{'author'}
3861 Date: $ad{'rfc2822'} ($ad{'tz_local'})
3862 Subject: $co{'title'}
3863 TEXT
3864                 print "X-Git-Tag: $tagname\n" if $tagname;
3865                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3866
3867                 foreach my $line (@{$co{'comment'}}) {
3868                         print "$line\n";
3869                 }
3870                 print "---\n\n";
3871         }
3872
3873         # write patch
3874         if ($format eq 'html') {
3875                 git_difftree_body(\@difftree, $hash, $hash_parent);
3876                 print "<br/>\n";
3877
3878                 git_patchset_body($fd, \@difftree, $hash, $hash_parent);
3879                 close $fd;
3880                 print "</div>\n"; # class="page_body"
3881                 git_footer_html();
3882
3883         } elsif ($format eq 'plain') {
3884                 local $/ = undef;
3885                 print <$fd>;
3886                 close $fd
3887                         or print "Reading git-diff-tree failed\n";
3888         }
3889 }
3890
3891 sub git_commitdiff_plain {
3892         git_commitdiff('plain');
3893 }
3894
3895 sub git_history {
3896         if (!defined $hash_base) {
3897                 $hash_base = git_get_head_hash($project);
3898         }
3899         if (!defined $page) {
3900                 $page = 0;
3901         }
3902         my $ftype;
3903         my %co = parse_commit($hash_base);
3904         if (!%co) {
3905                 die_error(undef, "Unknown commit object");
3906         }
3907
3908         my $refs = git_get_references();
3909         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3910
3911         if (!defined $hash && defined $file_name) {
3912                 $hash = git_get_hash_by_path($hash_base, $file_name);
3913         }
3914         if (defined $hash) {
3915                 $ftype = git_get_type($hash);
3916         }
3917
3918         open my $fd, "-|",
3919                 git_cmd(), "rev-list", $limit, "--full-history", $hash_base, "--", $file_name
3920                         or die_error(undef, "Open git-rev-list-failed");
3921         my @revlist = map { chomp; $_ } <$fd>;
3922         close $fd
3923                 or die_error(undef, "Reading git-rev-list failed");
3924
3925         my $paging_nav = '';
3926         if ($page > 0) {
3927                 $paging_nav .=
3928                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3929                                                file_name=>$file_name)},
3930                                 "first");
3931                 $paging_nav .= " &sdot; " .
3932                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3933                                                file_name=>$file_name, page=>$page-1),
3934                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3935         } else {
3936                 $paging_nav .= "first";
3937                 $paging_nav .= " &sdot; prev";
3938         }
3939         if ($#revlist >= (100 * ($page+1)-1)) {
3940                 $paging_nav .= " &sdot; " .
3941                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3942                                                file_name=>$file_name, page=>$page+1),
3943                                  -accesskey => "n", -title => "Alt-n"}, "next");
3944         } else {
3945                 $paging_nav .= " &sdot; next";
3946         }
3947         my $next_link = '';
3948         if ($#revlist >= (100 * ($page+1)-1)) {
3949                 $next_link =
3950                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3951                                                file_name=>$file_name, page=>$page+1),
3952                                  -title => "Alt-n"}, "next");
3953         }
3954
3955         git_header_html();
3956         git_print_page_nav('history','', $hash_base,$co{'tree'},$hash_base, $paging_nav);
3957         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3958         git_print_page_path($file_name, $ftype, $hash_base);
3959
3960         git_history_body(\@revlist, ($page * 100), $#revlist,
3961                          $refs, $hash_base, $ftype, $next_link);
3962
3963         git_footer_html();
3964 }
3965
3966 sub git_search {
3967         if (!defined $searchtext) {
3968                 die_error(undef, "Text field empty");
3969         }
3970         if (!defined $hash) {
3971                 $hash = git_get_head_hash($project);
3972         }
3973         my %co = parse_commit($hash);
3974         if (!%co) {
3975                 die_error(undef, "Unknown commit object");
3976         }
3977
3978         $searchtype ||= 'commit';
3979         if ($searchtype eq 'pickaxe') {
3980                 # pickaxe may take all resources of your box and run for several minutes
3981                 # with every query - so decide by yourself how public you make this feature
3982                 my ($have_pickaxe) = gitweb_check_feature('pickaxe');
3983                 if (!$have_pickaxe) {
3984                         die_error('403 Permission denied', "Permission denied");
3985                 }
3986         }
3987
3988         git_header_html();
3989         git_print_page_nav('','', $hash,$co{'tree'},$hash);
3990         git_print_header_div('commit', esc_html($co{'title'}), $hash);
3991
3992         print "<table cellspacing=\"0\">\n";
3993         my $alternate = 1;
3994         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
3995                 $/ = "\0";
3996                 open my $fd, "-|", git_cmd(), "rev-list",
3997                         "--header", "--parents", $hash, "--"
3998                         or next;
3999                 while (my $commit_text = <$fd>) {
4000                         if (!grep m/$searchtext/i, $commit_text) {
4001                                 next;
4002                         }
4003                         if ($searchtype eq 'author' && !grep m/\nauthor .*$searchtext/i, $commit_text) {
4004                                 next;
4005                         }
4006                         if ($searchtype eq 'committer' && !grep m/\ncommitter .*$searchtext/i, $commit_text) {
4007                                 next;
4008                         }
4009                         my @commit_lines = split "\n", $commit_text;
4010                         my %co = parse_commit(undef, \@commit_lines);
4011                         if (!%co) {
4012                                 next;
4013                         }
4014                         if ($alternate) {
4015                                 print "<tr class=\"dark\">\n";
4016                         } else {
4017                                 print "<tr class=\"light\">\n";
4018                         }
4019                         $alternate ^= 1;
4020                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4021                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
4022                               "<td>" .
4023                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}), -class => "list subject"},
4024                                        esc_html(chop_str($co{'title'}, 50)) . "<br/>");
4025                         my $comment = $co{'comment'};
4026                         foreach my $line (@$comment) {
4027                                 if ($line =~ m/^(.*)($searchtext)(.*)$/i) {
4028                                         my $lead = esc_html($1) || "";
4029                                         $lead = chop_str($lead, 30, 10);
4030                                         my $match = esc_html($2) || "";
4031                                         my $trail = esc_html($3) || "";
4032                                         $trail = chop_str($trail, 30, 10);
4033                                         my $text = "$lead<span class=\"match\">$match</span>$trail";
4034                                         print chop_str($text, 80, 5) . "<br/>\n";
4035                                 }
4036                         }
4037                         print "</td>\n" .
4038                               "<td class=\"link\">" .
4039                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4040                               " | " .
4041                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4042                         print "</td>\n" .
4043                               "</tr>\n";
4044                 }
4045                 close $fd;
4046         }
4047
4048         if ($searchtype eq 'pickaxe') {
4049                 $/ = "\n";
4050                 my $git_command = git_cmd_str();
4051                 open my $fd, "-|", "$git_command rev-list $hash | " .
4052                         "$git_command diff-tree -r --stdin -S\'$searchtext\'";
4053                 undef %co;
4054                 my @files;
4055                 while (my $line = <$fd>) {
4056                         if (%co && $line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)\t(.*)$/) {
4057                                 my %set;
4058                                 $set{'file'} = $6;
4059                                 $set{'from_id'} = $3;
4060                                 $set{'to_id'} = $4;
4061                                 $set{'id'} = $set{'to_id'};
4062                                 if ($set{'id'} =~ m/0{40}/) {
4063                                         $set{'id'} = $set{'from_id'};
4064                                 }
4065                                 if ($set{'id'} =~ m/0{40}/) {
4066                                         next;
4067                                 }
4068                                 push @files, \%set;
4069                         } elsif ($line =~ m/^([0-9a-fA-F]{40})$/){
4070                                 if (%co) {
4071                                         if ($alternate) {
4072                                                 print "<tr class=\"dark\">\n";
4073                                         } else {
4074                                                 print "<tr class=\"light\">\n";
4075                                         }
4076                                         $alternate ^= 1;
4077                                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4078                                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
4079                                               "<td>" .
4080                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4081                                                       -class => "list subject"},
4082                                                       esc_html(chop_str($co{'title'}, 50)) . "<br/>");
4083                                         while (my $setref = shift @files) {
4084                                                 my %set = %$setref;
4085                                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
4086                                                                              hash=>$set{'id'}, file_name=>$set{'file'}),
4087                                                               -class => "list"},
4088                                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
4089                                                       "<br/>\n";
4090                                         }
4091                                         print "</td>\n" .
4092                                               "<td class=\"link\">" .
4093                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4094                                               " | " .
4095                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4096                                         print "</td>\n" .
4097                                               "</tr>\n";
4098                                 }
4099                                 %co = parse_commit($1);
4100                         }
4101                 }
4102                 close $fd;
4103         }
4104         print "</table>\n";
4105         git_footer_html();
4106 }
4107
4108 sub git_search_help {
4109         git_header_html();
4110         git_print_page_nav('','', $hash,$hash,$hash);
4111         print <<EOT;
4112 <dl>
4113 <dt><b>commit</b></dt>
4114 <dd>The commit messages and authorship information will be scanned for the given string.</dd>
4115 <dt><b>author</b></dt>
4116 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given string.</dd>
4117 <dt><b>committer</b></dt>
4118 <dd>Name and e-mail of the committer and date of commit will be scanned for the given string.</dd>
4119 EOT
4120         my ($have_pickaxe) = gitweb_check_feature('pickaxe');
4121         if ($have_pickaxe) {
4122                 print <<EOT;
4123 <dt><b>pickaxe</b></dt>
4124 <dd>All commits that caused the string to appear or disappear from any file (changes that
4125 added, removed or "modified" the string) will be listed. This search can take a while and
4126 takes a lot of strain on the server, so please use it wisely.</dd>
4127 EOT
4128         }
4129         print "</dl>\n";
4130         git_footer_html();
4131 }
4132
4133 sub git_shortlog {
4134         my $head = git_get_head_hash($project);
4135         if (!defined $hash) {
4136                 $hash = $head;
4137         }
4138         if (!defined $page) {
4139                 $page = 0;
4140         }
4141         my $refs = git_get_references();
4142
4143         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
4144         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
4145                 or die_error(undef, "Open git-rev-list failed");
4146         my @revlist = map { chomp; $_ } <$fd>;
4147         close $fd;
4148
4149         my $paging_nav = format_paging_nav('shortlog', $hash, $head, $page, $#revlist);
4150         my $next_link = '';
4151         if ($#revlist >= (100 * ($page+1)-1)) {
4152                 $next_link =
4153                         $cgi->a({-href => href(action=>"shortlog", hash=>$hash, page=>$page+1),
4154                                  -title => "Alt-n"}, "next");
4155         }
4156
4157
4158         git_header_html();
4159         git_print_page_nav('shortlog','', $hash,$hash,$hash, $paging_nav);
4160         git_print_header_div('summary', $project);
4161
4162         git_shortlog_body(\@revlist, ($page * 100), $#revlist, $refs, $next_link);
4163
4164         git_footer_html();
4165 }
4166
4167 ## ......................................................................
4168 ## feeds (RSS, Atom; OPML)
4169
4170 sub git_feed {
4171         my $format = shift || 'atom';
4172         my ($have_blame) = gitweb_check_feature('blame');
4173
4174         # Atom: http://www.atomenabled.org/developers/syndication/
4175         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
4176         if ($format ne 'rss' && $format ne 'atom') {
4177                 die_error(undef, "Unknown web feed format");
4178         }
4179
4180         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
4181         my $head = $hash || 'HEAD';
4182         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=150",
4183                 $head, "--", (defined $file_name ? $file_name : ())
4184                 or die_error(undef, "Open git-rev-list failed");
4185         my @revlist = map { chomp; $_ } <$fd>;
4186         close $fd or die_error(undef, "Reading git-rev-list failed");
4187
4188         my %latest_commit;
4189         my %latest_date;
4190         my $content_type = "application/$format+xml";
4191         if (defined $cgi->http('HTTP_ACCEPT') &&
4192                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
4193                 # browser (feed reader) prefers text/xml
4194                 $content_type = 'text/xml';
4195         }
4196         if (defined($revlist[0])) {
4197                 %latest_commit = parse_commit($revlist[0]);
4198                 %latest_date   = parse_date($latest_commit{'committer_epoch'});
4199                 print $cgi->header(
4200                         -type => $content_type,
4201                         -charset => 'utf-8',
4202                         -last_modified => $latest_date{'rfc2822'});
4203         } else {
4204                 print $cgi->header(
4205                         -type => $content_type,
4206                         -charset => 'utf-8');
4207         }
4208
4209         # Optimization: skip generating the body if client asks only
4210         # for Last-Modified date.
4211         return if ($cgi->request_method() eq 'HEAD');
4212
4213         # header variables
4214         my $title = "$site_name - $project/$action";
4215         my $feed_type = 'log';
4216         if (defined $hash) {
4217                 $title .= " - '$hash'";
4218                 $feed_type = 'branch log';
4219                 if (defined $file_name) {
4220                         $title .= " :: $file_name";
4221                         $feed_type = 'history';
4222                 }
4223         } elsif (defined $file_name) {
4224                 $title .= " - $file_name";
4225                 $feed_type = 'history';
4226         }
4227         $title .= " $feed_type";
4228         my $descr = git_get_project_description($project);
4229         if (defined $descr) {
4230                 $descr = esc_html($descr);
4231         } else {
4232                 $descr = "$project " .
4233                          ($format eq 'rss' ? 'RSS' : 'Atom') .
4234                          " feed";
4235         }
4236         my $owner = git_get_project_owner($project);
4237         $owner = esc_html($owner);
4238
4239         #header
4240         my $alt_url;
4241         if (defined $file_name) {
4242                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
4243         } elsif (defined $hash) {
4244                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
4245         } else {
4246                 $alt_url = href(-full=>1, action=>"summary");
4247         }
4248         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
4249         if ($format eq 'rss') {
4250                 print <<XML;
4251 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
4252 <channel>
4253 XML
4254                 print "<title>$title</title>\n" .
4255                       "<link>$alt_url</link>\n" .
4256                       "<description>$descr</description>\n" .
4257                       "<language>en</language>\n";
4258         } elsif ($format eq 'atom') {
4259                 print <<XML;
4260 <feed xmlns="http://www.w3.org/2005/Atom">
4261 XML
4262                 print "<title>$title</title>\n" .
4263                       "<subtitle>$descr</subtitle>\n" .
4264                       '<link rel="alternate" type="text/html" href="' .
4265                       $alt_url . '" />' . "\n" .
4266                       '<link rel="self" type="' . $content_type . '" href="' .
4267                       $cgi->self_url() . '" />' . "\n" .
4268                       "<id>" . href(-full=>1) . "</id>\n" .
4269                       # use project owner for feed author
4270                       "<author><name>$owner</name></author>\n";
4271                 if (defined $favicon) {
4272                         print "<icon>" . esc_url($favicon) . "</icon>\n";
4273                 }
4274                 if (defined $logo_url) {
4275                         # not twice as wide as tall: 72 x 27 pixels
4276                         print "<logo>" . esc_url($logo_url) . "</logo>\n";
4277                 }
4278                 if (! %latest_date) {
4279                         # dummy date to keep the feed valid until commits trickle in:
4280                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
4281                 } else {
4282                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
4283                 }
4284         }
4285
4286         # contents
4287         for (my $i = 0; $i <= $#revlist; $i++) {
4288                 my $commit = $revlist[$i];
4289                 my %co = parse_commit($commit);
4290                 # we read 150, we always show 30 and the ones more recent than 48 hours
4291                 if (($i >= 20) && ((time - $co{'committer_epoch'}) > 48*60*60)) {
4292                         last;
4293                 }
4294                 my %cd = parse_date($co{'committer_epoch'});
4295
4296                 # get list of changed files
4297                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
4298                         $co{'parent'}, $co{'id'}, "--", (defined $file_name ? $file_name : ())
4299                         or next;
4300                 my @difftree = map { chomp; $_ } <$fd>;
4301                 close $fd
4302                         or next;
4303
4304                 # print element (entry, item)
4305                 my $co_url = href(-full=>1, action=>"commit", hash=>$commit);
4306                 if ($format eq 'rss') {
4307                         print "<item>\n" .
4308                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
4309                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
4310                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
4311                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
4312                               "<link>$co_url</link>\n" .
4313                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
4314                               "<content:encoded>" .
4315                               "<![CDATA[\n";
4316                 } elsif ($format eq 'atom') {
4317                         print "<entry>\n" .
4318                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
4319                               "<updated>$cd{'iso-8601'}</updated>\n" .
4320                               "<author><name>" . esc_html($co{'author_name'}) . "</name></author>\n" .
4321                               # use committer for contributor
4322                               "<contributor><name>" . esc_html($co{'committer_name'}) . "</name></contributor>\n" .
4323                               "<published>$cd{'iso-8601'}</published>\n" .
4324                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
4325                               "<id>$co_url</id>\n" .
4326                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
4327                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
4328                 }
4329                 my $comment = $co{'comment'};
4330                 print "<pre>\n";
4331                 foreach my $line (@$comment) {
4332                         $line = esc_html($line);
4333                         print "$line\n";
4334                 }
4335                 print "</pre><ul>\n";
4336                 foreach my $difftree_line (@difftree) {
4337                         my %difftree = parse_difftree_raw_line($difftree_line);
4338                         next if !$difftree{'from_id'};
4339
4340                         my $file = $difftree{'file'} || $difftree{'to_file'};
4341
4342                         print "<li>" .
4343                               "[" .
4344                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
4345                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
4346                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
4347                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
4348                                       -title => "diff"}, 'D');
4349                         if ($have_blame) {
4350                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
4351                                                              file_name=>$file, hash_base=>$commit),
4352                                               -title => "blame"}, 'B');
4353                         }
4354                         # if this is not a feed of a file history
4355                         if (!defined $file_name || $file_name ne $file) {
4356                                 print $cgi->a({-href => href(-full=>1, action=>"history",
4357                                                              file_name=>$file, hash=>$commit),
4358                                               -title => "history"}, 'H');
4359                         }
4360                         $file = esc_path($file);
4361                         print "] ".
4362                               "$file</li>\n";
4363                 }
4364                 if ($format eq 'rss') {
4365                         print "</ul>]]>\n" .
4366                               "</content:encoded>\n" .
4367                               "</item>\n";
4368                 } elsif ($format eq 'atom') {
4369                         print "</ul>\n</div>\n" .
4370                               "</content>\n" .
4371                               "</entry>\n";
4372                 }
4373         }
4374
4375         # end of feed
4376         if ($format eq 'rss') {
4377                 print "</channel>\n</rss>\n";
4378         }       elsif ($format eq 'atom') {
4379                 print "</feed>\n";
4380         }
4381 }
4382
4383 sub git_rss {
4384         git_feed('rss');
4385 }
4386
4387 sub git_atom {
4388         git_feed('atom');
4389 }
4390
4391 sub git_opml {
4392         my @list = git_get_projects_list();
4393
4394         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
4395         print <<XML;
4396 <?xml version="1.0" encoding="utf-8"?>
4397 <opml version="1.0">
4398 <head>
4399   <title>$site_name OPML Export</title>
4400 </head>
4401 <body>
4402 <outline text="git RSS feeds">
4403 XML
4404
4405         foreach my $pr (@list) {
4406                 my %proj = %$pr;
4407                 my $head = git_get_head_hash($proj{'path'});
4408                 if (!defined $head) {
4409                         next;
4410                 }
4411                 $git_dir = "$projectroot/$proj{'path'}";
4412                 my %co = parse_commit($head);
4413                 if (!%co) {
4414                         next;
4415                 }
4416
4417                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
4418                 my $rss  = "$my_url?p=$proj{'path'};a=rss";
4419                 my $html = "$my_url?p=$proj{'path'};a=summary";
4420                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
4421         }
4422         print <<XML;
4423 </outline>
4424 </body>
4425 </opml>
4426 XML
4427 }