![[tokkee]](http://tokkee.org/images/avatar.png){kind=avatar}
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
59 my ($SVN);
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 'blame' => [ \&Git::SVN::Log::cmd_blame,
190 "Show what revision and author last modified each line of a file",
191 {} ],
192 );
194 my $cmd;
195 for (my $i = 0; $i < @ARGV; $i++) {
196 if (defined $cmd{$ARGV[$i]}) {
197 $cmd = $ARGV[$i];
198 splice @ARGV, $i, 1;
199 last;
200 }
201 };
203 # make sure we're always running at the top-level working directory
204 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
205 unless (-d $ENV{GIT_DIR}) {
206 if ($git_dir_user_set) {
207 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
208 "but it is not a directory\n";
209 }
210 my $git_dir = delete $ENV{GIT_DIR};
211 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
212 unless (length $cdup) {
213 die "Already at toplevel, but $git_dir ",
214 "not found '$cdup'\n";
215 }
216 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
217 unless (-d $git_dir) {
218 die "$git_dir still not found after going to ",
219 "'$cdup'\n";
220 }
221 $ENV{GIT_DIR} = $git_dir;
222 }
223 }
225 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
227 read_repo_config(\%opts);
228 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
229 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
230 'minimize-connections' => \$Git::SVN::Migration::_minimize,
231 'id|i=s' => \$Git::SVN::default_ref_id,
232 'svn-remote|remote|R=s' => sub {
233 $Git::SVN::no_reuse_existing = 1;
234 $Git::SVN::default_repo_id = $_[1] });
235 exit 1 if (!$rv && $cmd && $cmd ne 'log');
237 usage(0) if $_help;
238 version() if $_version;
239 usage(1) unless defined $cmd;
240 load_authors() if $_authors;
242 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
243 Git::SVN::Migration::migration_check();
244 }
245 Git::SVN::init_vars();
246 eval {
247 Git::SVN::verify_remotes_sanity();
248 $cmd{$cmd}->[0]->(@ARGV);
249 };
250 fatal $@ if $@;
251 post_fetch_checkout();
252 exit 0;
254 ####################### primary functions ######################
255 sub usage {
256 my $exit = shift || 0;
257 my $fd = $exit ? \*STDERR : \*STDOUT;
258 print $fd <<"";
259 git-svn - bidirectional operations between a single Subversion tree and git
260 Usage: $0 <command> [options] [arguments]\n
262 print $fd "Available commands:\n" unless $cmd;
264 foreach (sort keys %cmd) {
265 next if $cmd && $cmd ne $_;
266 next if /^multi-/; # don't show deprecated commands
267 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
268 foreach (sort keys %{$cmd{$_}->[2]}) {
269 # mixed-case options are for .git/config only
270 next if /[A-Z]/ && /^[a-z]+$/i;
271 # prints out arguments as they should be passed:
272 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
273 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
274 "--$_" : "-$_" }
275 split /\|/,$_)," $x\n";
276 }
277 }
278 print $fd <<"";
279 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
280 arbitrary identifier if you're tracking multiple SVN branches/repositories in
281 one git repository and want to keep them separate. See git-svn(1) for more
282 information.
284 exit $exit;
285 }
287 sub version {
288 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
289 exit 0;
290 }
292 sub do_git_init_db {
293 unless (-d $ENV{GIT_DIR}) {
294 my @init_db = ('init');
295 push @init_db, "--template=$_template" if defined $_template;
296 if (defined $_shared) {
297 if ($_shared =~ /[a-z]/) {
298 push @init_db, "--shared=$_shared";
299 } else {
300 push @init_db, "--shared";
301 }
302 }
303 command_noisy(@init_db);
304 }
305 my $set;
306 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
307 foreach my $i (keys %icv) {
308 die "'$set' and '$i' cannot both be set\n" if $set;
309 next unless defined $icv{$i};
310 command_noisy('config', "$pfx.$i", $icv{$i});
311 $set = $i;
312 }
313 }
315 sub init_subdir {
316 my $repo_path = shift or return;
317 mkpath([$repo_path]) unless -d $repo_path;
318 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
319 $ENV{GIT_DIR} = '.git';
320 }
322 sub cmd_clone {
323 my ($url, $path) = @_;
324 if (!defined $path &&
325 (defined $_trunk || defined $_branches || defined $_tags ||
326 defined $_stdlayout) &&
327 $url !~ m#^[a-z\+]+://#) {
328 $path = $url;
329 }
330 $path = basename($url) if !defined $path || !length $path;
331 cmd_init($url, $path);
332 Git::SVN::fetch_all($Git::SVN::default_repo_id);
333 }
335 sub cmd_init {
336 if (defined $_stdlayout) {
337 $_trunk = 'trunk' if (!defined $_trunk);
338 $_tags = 'tags' if (!defined $_tags);
339 $_branches = 'branches' if (!defined $_branches);
340 }
341 if (defined $_trunk || defined $_branches || defined $_tags) {
342 return cmd_multi_init(@_);
343 }
344 my $url = shift or die "SVN repository location required ",
345 "as a command-line argument\n";
346 init_subdir(@_);
347 do_git_init_db();
349 Git::SVN->init($url);
350 }
352 sub cmd_fetch {
353 if (grep /^\d+=./, @_) {
354 die "'<rev>=<commit>' fetch arguments are ",
355 "no longer supported.\n";
356 }
357 my ($remote) = @_;
358 if (@_ > 1) {
359 die "Usage: $0 fetch [--all] [svn-remote]\n";
360 }
361 $remote ||= $Git::SVN::default_repo_id;
362 if ($_fetch_all) {
363 cmd_multi_fetch();
364 } else {
365 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
366 }
367 }
369 sub cmd_set_tree {
370 my (@commits) = @_;
371 if ($_stdin || !@commits) {
372 print "Reading from stdin...\n";
373 @commits = ();
374 while (<STDIN>) {
375 if (/\b($sha1_short)\b/o) {
376 unshift @commits, $1;
377 }
378 }
379 }
380 my @revs;
381 foreach my $c (@commits) {
382 my @tmp = command('rev-parse',$c);
383 if (scalar @tmp == 1) {
384 push @revs, $tmp[0];
385 } elsif (scalar @tmp > 1) {
386 push @revs, reverse(command('rev-list',@tmp));
387 } else {
388 fatal "Failed to rev-parse $c";
389 }
390 }
391 my $gs = Git::SVN->new;
392 my ($r_last, $cmt_last) = $gs->last_rev_commit;
393 $gs->fetch;
394 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
395 fatal "There are new revisions that were fetched ",
396 "and need to be merged (or acknowledged) ",
397 "before committing.\nlast rev: $r_last\n",
398 " current: $gs->{last_rev}";
399 }
400 $gs->set_tree($_) foreach @revs;
401 print "Done committing ",scalar @revs," revisions to SVN\n";
402 unlink $gs->{index};
403 }
405 sub cmd_dcommit {
406 my $head = shift;
407 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
408 'Cannot dcommit with a dirty index. Commit your changes first, '
409 . "or stash them with `git stash'.\n";
410 $head ||= 'HEAD';
411 my @refs;
412 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
413 print "Committing to $url ...\n";
414 unless ($gs) {
415 die "Unable to determine upstream SVN information from ",
416 "$head history\n";
417 }
418 my $last_rev;
419 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
420 if ($_no_rebase && scalar(@$linear_refs) > 1) {
421 warn "Attempting to commit more than one change while ",
422 "--no-rebase is enabled.\n",
423 "If these changes depend on each other, re-running ",
424 "without --no-rebase may be required."
425 }
426 while (1) {
427 my $d = shift @$linear_refs or last;
428 unless (defined $last_rev) {
429 (undef, $last_rev, undef) = cmt_metadata("$d~1");
430 unless (defined $last_rev) {
431 fatal "Unable to extract revision information ",
432 "from commit $d~1";
433 }
434 }
435 if ($_dry_run) {
436 print "diff-tree $d~1 $d\n";
437 } else {
438 my $cmt_rev;
439 my %ed_opts = ( r => $last_rev,
440 log => get_commit_entry($d)->{log},
441 ra => Git::SVN::Ra->new($gs->full_url),
442 config => SVN::Core::config_get_config(
443 $Git::SVN::Ra::config_dir
444 ),
445 tree_a => "$d~1",
446 tree_b => $d,
447 editor_cb => sub {
448 print "Committed r$_[0]\n";
449 $cmt_rev = $_[0];
450 },
451 svn_path => '');
452 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
453 print "No changes\n$d~1 == $d\n";
454 } elsif ($parents->{$d} && @{$parents->{$d}}) {
455 $gs->{inject_parents_dcommit}->{$cmt_rev} =
456 $parents->{$d};
457 }
458 $_fetch_all ? $gs->fetch_all : $gs->fetch;
459 $last_rev = $cmt_rev;
460 next if $_no_rebase;
462 # we always want to rebase against the current HEAD,
463 # not any head that was passed to us
464 my @diff = command('diff-tree', $d,
465 $gs->refname, '--');
466 my @finish;
467 if (@diff) {
468 @finish = rebase_cmd();
469 print STDERR "W: $d and ", $gs->refname,
470 " differ, using @finish:\n",
471 join("\n", @diff), "\n";
472 } else {
473 print "No changes between current HEAD and ",
474 $gs->refname,
475 "\nResetting to the latest ",
476 $gs->refname, "\n";
477 @finish = qw/reset --mixed/;
478 }
479 command_noisy(@finish, $gs->refname);
480 if (@diff) {
481 @refs = ();
482 my ($url_, $rev_, $uuid_, $gs_) =
483 working_head_info($head, \@refs);
484 my ($linear_refs_, $parents_) =
485 linearize_history($gs_, \@refs);
486 if (scalar(@$linear_refs) !=
487 scalar(@$linear_refs_)) {
488 fatal "# of revisions changed ",
489 "\nbefore:\n",
490 join("\n", @$linear_refs),
491 "\n\nafter:\n",
492 join("\n", @$linear_refs_), "\n",
493 'If you are attempting to commit ',
494 "merges, try running:\n\t",
495 'git rebase --interactive',
496 '--preserve-merges ',
497 $gs->refname,
498 "\nBefore dcommitting";
499 }
500 if ($url_ ne $url) {
501 fatal "URL mismatch after rebase: ",
502 "$url_ != $url";
503 }
504 if ($uuid_ ne $uuid) {
505 fatal "uuid mismatch after rebase: ",
506 "$uuid_ != $uuid";
507 }
508 # remap parents
509 my (%p, @l, $i);
510 for ($i = 0; $i < scalar @$linear_refs; $i++) {
511 my $new = $linear_refs_->[$i] or next;
512 $p{$new} =
513 $parents->{$linear_refs->[$i]};
514 push @l, $new;
515 }
516 $parents = \%p;
517 $linear_refs = \@l;
518 }
519 }
520 }
521 unlink $gs->{index};
522 }
524 sub cmd_find_rev {
525 my $revision_or_hash = shift;
526 my $result;
527 if ($revision_or_hash =~ /^r\d+$/) {
528 my $head = shift;
529 $head ||= 'HEAD';
530 my @refs;
531 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
532 unless ($gs) {
533 die "Unable to determine upstream SVN information from ",
534 "$head history\n";
535 }
536 my $desired_revision = substr($revision_or_hash, 1);
537 $result = $gs->rev_map_get($desired_revision);
538 } else {
539 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
540 $result = $rev;
541 }
542 print "$result\n" if $result;
543 }
545 sub cmd_rebase {
546 command_noisy(qw/update-index --refresh/);
547 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
548 unless ($gs) {
549 die "Unable to determine upstream SVN information from ",
550 "working tree history\n";
551 }
552 if (command(qw/diff-index HEAD --/)) {
553 print STDERR "Cannot rebase with uncommited changes:\n";
554 command_noisy('status');
555 exit 1;
556 }
557 unless ($_local) {
558 # rebase will checkout for us, so no need to do it explicitly
559 $_no_checkout = 'true';
560 $_fetch_all ? $gs->fetch_all : $gs->fetch;
561 }
562 command_noisy(rebase_cmd(), $gs->refname);
563 }
565 sub cmd_show_ignore {
566 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
567 $gs ||= Git::SVN->new;
568 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
569 $gs->prop_walk($gs->{path}, $r, sub {
570 my ($gs, $path, $props) = @_;
571 print STDOUT "\n# $path\n";
572 my $s = $props->{'svn:ignore'} or return;
573 $s =~ s/[\r\n]+/\n/g;
574 chomp $s;
575 $s =~ s#^#$path#gm;
576 print STDOUT "$s\n";
577 });
578 }
580 sub cmd_show_externals {
581 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
582 $gs ||= Git::SVN->new;
583 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
584 $gs->prop_walk($gs->{path}, $r, sub {
585 my ($gs, $path, $props) = @_;
586 print STDOUT "\n# $path\n";
587 my $s = $props->{'svn:externals'} or return;
588 $s =~ s/[\r\n]+/\n/g;
589 chomp $s;
590 $s =~ s#^#$path#gm;
591 print STDOUT "$s\n";
592 });
593 }
595 sub cmd_create_ignore {
596 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
597 $gs ||= Git::SVN->new;
598 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
599 $gs->prop_walk($gs->{path}, $r, sub {
600 my ($gs, $path, $props) = @_;
601 # $path is of the form /path/to/dir/
602 my $ignore = '.' . $path . '.gitignore';
603 my $s = $props->{'svn:ignore'} or return;
604 open(GITIGNORE, '>', $ignore)
605 or fatal("Failed to open `$ignore' for writing: $!");
606 $s =~ s/[\r\n]+/\n/g;
607 chomp $s;
608 # Prefix all patterns so that the ignore doesn't apply
609 # to sub-directories.
610 $s =~ s#^#/#gm;
611 print GITIGNORE "$s\n";
612 close(GITIGNORE)
613 or fatal("Failed to close `$ignore': $!");
614 command_noisy('add', $ignore);
615 });
616 }
618 sub canonicalize_path {
619 my ($path) = @_;
620 my $dot_slash_added = 0;
621 if (substr($path, 0, 1) ne "/") {
622 $path = "./" . $path;
623 $dot_slash_added = 1;
624 }
625 # File::Spec->canonpath doesn't collapse x/../y into y (for a
626 # good reason), so let's do this manually.
627 $path =~ s#/+#/#g;
628 $path =~ s#/\.(?:/|$)#/#g;
629 $path =~ s#/[^/]+/\.\.##g;
630 $path =~ s#/$##g;
631 $path =~ s#^\./## if $dot_slash_added;
632 return $path;
633 }
635 # get_svnprops(PATH)
636 # ------------------
637 # Helper for cmd_propget and cmd_proplist below.
638 sub get_svnprops {
639 my $path = shift;
640 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
641 $gs ||= Git::SVN->new;
643 # prefix THE PATH by the sub-directory from which the user
644 # invoked us.
645 $path = $cmd_dir_prefix . $path;
646 fatal("No such file or directory: $path") unless -e $path;
647 my $is_dir = -d $path ? 1 : 0;
648 $path = $gs->{path} . '/' . $path;
650 # canonicalize the path (otherwise libsvn will abort or fail to
651 # find the file)
652 $path = canonicalize_path($path);
654 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
655 my $props;
656 if ($is_dir) {
657 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
658 }
659 else {
660 (undef, $props) = $gs->ra->get_file($path, $r, undef);
661 }
662 return $props;
663 }
665 # cmd_propget (PROP, PATH)
666 # ------------------------
667 # Print the SVN property PROP for PATH.
668 sub cmd_propget {
669 my ($prop, $path) = @_;
670 $path = '.' if not defined $path;
671 usage(1) if not defined $prop;
672 my $props = get_svnprops($path);
673 if (not defined $props->{$prop}) {
674 fatal("`$path' does not have a `$prop' SVN property.");
675 }
676 print $props->{$prop} . "\n";
677 }
679 # cmd_proplist (PATH)
680 # -------------------
681 # Print the list of SVN properties for PATH.
682 sub cmd_proplist {
683 my $path = shift;
684 $path = '.' if not defined $path;
685 my $props = get_svnprops($path);
686 print "Properties on '$path':\n";
687 foreach (sort keys %{$props}) {
688 print " $_\n";
689 }
690 }
692 sub cmd_multi_init {
693 my $url = shift;
694 unless (defined $_trunk || defined $_branches || defined $_tags) {
695 usage(1);
696 }
698 # there are currently some bugs that prevent multi-init/multi-fetch
699 # setups from working well without this.
700 $Git::SVN::_minimize_url = 1;
702 $_prefix = '' unless defined $_prefix;
703 if (defined $url) {
704 $url =~ s#/+$##;
705 init_subdir(@_);
706 }
707 do_git_init_db();
708 if (defined $_trunk) {
709 my $trunk_ref = $_prefix . 'trunk';
710 # try both old-style and new-style lookups:
711 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
712 unless ($gs_trunk) {
713 my ($trunk_url, $trunk_path) =
714 complete_svn_url($url, $_trunk);
715 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
716 undef, $trunk_ref);
717 }
718 }
719 return unless defined $_branches || defined $_tags;
720 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
721 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
722 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
723 }
725 sub cmd_multi_fetch {
726 my $remotes = Git::SVN::read_all_remotes();
727 foreach my $repo_id (sort keys %$remotes) {
728 if ($remotes->{$repo_id}->{url}) {
729 Git::SVN::fetch_all($repo_id, $remotes);
730 }
731 }
732 }
734 # this command is special because it requires no metadata
735 sub cmd_commit_diff {
736 my ($ta, $tb, $url) = @_;
737 my $usage = "Usage: $0 commit-diff -r<revision> ".
738 "<tree-ish> <tree-ish> [<URL>]";
739 fatal($usage) if (!defined $ta || !defined $tb);
740 my $svn_path;
741 if (!defined $url) {
742 my $gs = eval { Git::SVN->new };
743 if (!$gs) {
744 fatal("Needed URL or usable git-svn --id in ",
745 "the command-line\n", $usage);
746 }
747 $url = $gs->{url};
748 $svn_path = $gs->{path};
749 }
750 unless (defined $_revision) {
751 fatal("-r|--revision is a required argument\n", $usage);
752 }
753 if (defined $_message && defined $_file) {
754 fatal("Both --message/-m and --file/-F specified ",
755 "for the commit message.\n",
756 "I have no idea what you mean");
757 }
758 if (defined $_file) {
759 $_message = file_to_s($_file);
760 } else {
761 $_message ||= get_commit_entry($tb)->{log};
762 }
763 my $ra ||= Git::SVN::Ra->new($url);
764 $svn_path ||= $ra->{svn_path};
765 my $r = $_revision;
766 if ($r eq 'HEAD') {
767 $r = $ra->get_latest_revnum;
768 } elsif ($r !~ /^\d+$/) {
769 die "revision argument: $r not understood by git-svn\n";
770 }
771 my %ed_opts = ( r => $r,
772 log => $_message,
773 ra => $ra,
774 tree_a => $ta,
775 tree_b => $tb,
776 editor_cb => sub { print "Committed r$_[0]\n" },
777 svn_path => $svn_path );
778 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
779 print "No changes\n$ta == $tb\n";
780 }
781 }
783 sub cmd_info {
784 my $path = canonicalize_path(shift or ".");
785 unless (scalar(@_) == 0) {
786 die "Too many arguments specified\n";
787 }
789 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
791 if (!$file_type && !$diff_status) {
792 print STDERR "$path: (Not a versioned resource)\n\n";
793 return;
794 }
796 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
797 unless ($gs) {
798 die "Unable to determine upstream SVN information from ",
799 "working tree history\n";
800 }
801 my $full_url = $url . ($path eq "." ? "" : "/$path");
803 if ($_url) {
804 print $full_url, "\n";
805 return;
806 }
808 my $result = "Path: $path\n";
809 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
810 $result .= "URL: " . $full_url . "\n";
812 eval {
813 my $repos_root = $gs->repos_root;
814 Git::SVN::remove_username($repos_root);
815 $result .= "Repository Root: $repos_root\n";
816 };
817 if ($@) {
818 $result .= "Repository Root: (offline)\n";
819 }
820 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
821 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
823 $result .= "Node Kind: " .
824 ($file_type eq "dir" ? "directory" : "file") . "\n";
826 my $schedule = $diff_status eq "A"
827 ? "add"
828 : ($diff_status eq "D" ? "delete" : "normal");
829 $result .= "Schedule: $schedule\n";
831 if ($diff_status eq "A") {
832 print $result, "\n";
833 return;
834 }
836 my ($lc_author, $lc_rev, $lc_date_utc);
837 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
838 my $log = command_output_pipe(@args);
839 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
840 while (<$log>) {
841 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
842 $lc_author = $1;
843 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
844 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
845 (undef, $lc_rev, undef) = ::extract_metadata($1);
846 }
847 }
848 close $log;
850 Git::SVN::Log::set_local_timezone();
852 $result .= "Last Changed Author: $lc_author\n";
853 $result .= "Last Changed Rev: $lc_rev\n";
854 $result .= "Last Changed Date: " .
855 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
857 if ($file_type ne "dir") {
858 my $text_last_updated_date =
859 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
860 $result .=
861 "Text Last Updated: " .
862 Git::SVN::Log::format_svn_date($text_last_updated_date) .
863 "\n";
864 my $checksum;
865 if ($diff_status eq "D") {
866 my ($fh, $ctx) =
867 command_output_pipe(qw(cat-file blob), "HEAD:$path");
868 if ($file_type eq "link") {
869 my $file_name = <$fh>;
870 $checksum = md5sum("link $file_name");
871 } else {
872 $checksum = md5sum($fh);
873 }
874 command_close_pipe($fh, $ctx);
875 } elsif ($file_type eq "link") {
876 my $file_name =
877 command(qw(cat-file blob), "HEAD:$path");
878 $checksum =
879 md5sum("link " . $file_name);
880 } else {
881 open FILE, "<", $path or die $!;
882 $checksum = md5sum(\*FILE);
883 close FILE or die $!;
884 }
885 $result .= "Checksum: " . $checksum . "\n";
886 }
888 print $result, "\n";
889 }
891 ########################### utility functions #########################
893 sub rebase_cmd {
894 my @cmd = qw/rebase/;
895 push @cmd, '-v' if $_verbose;
896 push @cmd, qw/--merge/ if $_merge;
897 push @cmd, "--strategy=$_strategy" if $_strategy;
898 @cmd;
899 }
901 sub post_fetch_checkout {
902 return if $_no_checkout;
903 my $gs = $Git::SVN::_head or return;
904 return if verify_ref('refs/heads/master^0');
906 my $valid_head = verify_ref('HEAD^0');
907 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
908 return if ($valid_head || !verify_ref('HEAD^0'));
910 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
911 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
912 return if -f $index;
914 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
915 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
916 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
917 print STDERR "Checked out HEAD:\n ",
918 $gs->full_url, " r", $gs->last_rev, "\n";
919 }
921 sub complete_svn_url {
922 my ($url, $path) = @_;
923 $path =~ s#/+$##;
924 if ($path !~ m#^[a-z\+]+://#) {
925 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
926 fatal("E: '$path' is not a complete URL ",
927 "and a separate URL is not specified");
928 }
929 return ($url, $path);
930 }
931 return ($path, '');
932 }
934 sub complete_url_ls_init {
935 my ($ra, $repo_path, $switch, $pfx) = @_;
936 unless ($repo_path) {
937 print STDERR "W: $switch not specified\n";
938 return;
939 }
940 $repo_path =~ s#/+$##;
941 if ($repo_path =~ m#^[a-z\+]+://#) {
942 $ra = Git::SVN::Ra->new($repo_path);
943 $repo_path = '';
944 } else {
945 $repo_path =~ s#^/+##;
946 unless ($ra) {
947 fatal("E: '$repo_path' is not a complete URL ",
948 "and a separate URL is not specified");
949 }
950 }
951 my $url = $ra->{url};
952 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
953 my $k = "svn-remote.$gs->{repo_id}.url";
954 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
955 if ($orig_url && ($orig_url ne $gs->{url})) {
956 die "$k already set: $orig_url\n",
957 "wanted to set to: $gs->{url}\n";
958 }
959 command_oneline('config', $k, $gs->{url}) unless $orig_url;
960 my $remote_path = "$ra->{svn_path}/$repo_path/*";
961 $remote_path =~ s#/+#/#g;
962 $remote_path =~ s#^/##g;
963 my ($n) = ($switch =~ /^--(\w+)/);
964 if (length $pfx && $pfx !~ m#/$#) {
965 die "--prefix='$pfx' must have a trailing slash '/'\n";
966 }
967 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
968 "$remote_path:refs/remotes/$pfx*");
969 }
971 sub verify_ref {
972 my ($ref) = @_;
973 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
974 { STDERR => 0 }); };
975 }
977 sub get_tree_from_treeish {
978 my ($treeish) = @_;
979 # $treeish can be a symbolic ref, too:
980 my $type = command_oneline(qw/cat-file -t/, $treeish);
981 my $expected;
982 while ($type eq 'tag') {
983 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
984 }
985 if ($type eq 'commit') {
986 $expected = (grep /^tree /, command(qw/cat-file commit/,
987 $treeish))[0];
988 ($expected) = ($expected =~ /^tree ($sha1)$/o);
989 die "Unable to get tree from $treeish\n" unless $expected;
990 } elsif ($type eq 'tree') {
991 $expected = $treeish;
992 } else {
993 die "$treeish is a $type, expected tree, tag or commit\n";
994 }
995 return $expected;
996 }
998 sub get_commit_entry {
999 my ($treeish) = shift;
1000 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1001 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1002 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1003 open my $log_fh, '>', $commit_editmsg or croak $!;
1005 my $type = command_oneline(qw/cat-file -t/, $treeish);
1006 if ($type eq 'commit' || $type eq 'tag') {
1007 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1008 $type, $treeish);
1009 my $in_msg = 0;
1010 while (<$msg_fh>) {
1011 if (!$in_msg) {
1012 $in_msg = 1 if (/^\s*$/);
1013 } elsif (/^git-svn-id: /) {
1014 # skip this for now, we regenerate the
1015 # correct one on re-fetch anyways
1016 # TODO: set *:merge properties or like...
1017 } else {
1018 print $log_fh $_ or croak $!;
1019 }
1020 }
1021 command_close_pipe($msg_fh, $ctx);
1022 }
1023 close $log_fh or croak $!;
1025 if ($_edit || ($type eq 'tree')) {
1026 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1027 # TODO: strip out spaces, comments, like git-commit.sh
1028 system($editor, $commit_editmsg);
1029 }
1030 rename $commit_editmsg, $commit_msg or croak $!;
1031 open $log_fh, '<', $commit_msg or croak $!;
1032 { local $/; chomp($log_entry{log} = <$log_fh>); }
1033 close $log_fh or croak $!;
1034 unlink $commit_msg;
1035 \%log_entry;
1036 }
1038 sub s_to_file {
1039 my ($str, $file, $mode) = @_;
1040 open my $fd,'>',$file or croak $!;
1041 print $fd $str,"\n" or croak $!;
1042 close $fd or croak $!;
1043 chmod ($mode &~ umask, $file) if (defined $mode);
1044 }
1046 sub file_to_s {
1047 my $file = shift;
1048 open my $fd,'<',$file or croak "$!: file: $file\n";
1049 local $/;
1050 my $ret = <$fd>;
1051 close $fd or croak $!;
1052 $ret =~ s/\s*$//s;
1053 return $ret;
1054 }
1056 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1057 sub load_authors {
1058 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1059 my $log = $cmd eq 'log';
1060 while (<$authors>) {
1061 chomp;
1062 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1063 my ($user, $name, $email) = ($1, $2, $3);
1064 if ($log) {
1065 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1066 } else {
1067 $users{$user} = [$name, $email];
1068 }
1069 }
1070 close $authors or croak $!;
1071 }
1073 # convert GetOpt::Long specs for use by git-config
1074 sub read_repo_config {
1075 return unless -d $ENV{GIT_DIR};
1076 my $opts = shift;
1077 my @config_only;
1078 foreach my $o (keys %$opts) {
1079 # if we have mixedCase and a long option-only, then
1080 # it's a config-only variable that we don't need for
1081 # the command-line.
1082 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1083 my $v = $opts->{$o};
1084 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1085 $key =~ s/-//g;
1086 my $arg = 'git-config';
1087 $arg .= ' --int' if ($o =~ /[:=]i$/);
1088 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1089 if (ref $v eq 'ARRAY') {
1090 chomp(my @tmp = `$arg --get-all svn.$key`);
1091 @$v = @tmp if @tmp;
1092 } else {
1093 chomp(my $tmp = `$arg --get svn.$key`);
1094 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1095 $$v = $tmp;
1096 }
1097 }
1098 }
1099 delete @$opts{@config_only} if @config_only;
1100 }
1102 sub extract_metadata {
1103 my $id = shift or return (undef, undef, undef);
1104 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1105 \s([a-f\d\-]+)$/x);
1106 if (!defined $rev || !$uuid || !$url) {
1107 # some of the original repositories I made had
1108 # identifiers like this:
1109 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1110 }
1111 return ($url, $rev, $uuid);
1112 }
1114 sub cmt_metadata {
1115 return extract_metadata((grep(/^git-svn-id: /,
1116 command(qw/cat-file commit/, shift)))[-1]);
1117 }
1119 sub working_head_info {
1120 my ($head, $refs) = @_;
1121 my @args = ('log', '--no-color', '--first-parent');
1122 my ($fh, $ctx) = command_output_pipe(@args, $head);
1123 my $hash;
1124 my %max;
1125 while (<$fh>) {
1126 if ( m{^commit ($::sha1)$} ) {
1127 unshift @$refs, $hash if $hash and $refs;
1128 $hash = $1;
1129 next;
1130 }
1131 next unless s{^\s*(git-svn-id:)}{$1};
1132 my ($url, $rev, $uuid) = extract_metadata($_);
1133 if (defined $url && defined $rev) {
1134 next if $max{$url} and $max{$url} < $rev;
1135 if (my $gs = Git::SVN->find_by_url($url)) {
1136 my $c = $gs->rev_map_get($rev);
1137 if ($c && $c eq $hash) {
1138 close $fh; # break the pipe
1139 return ($url, $rev, $uuid, $gs);
1140 } else {
1141 $max{$url} ||= $gs->rev_map_max;
1142 }
1143 }
1144 }
1145 }
1146 command_close_pipe($fh, $ctx);
1147 (undef, undef, undef, undef);
1148 }
1150 sub read_commit_parents {
1151 my ($parents, $c) = @_;
1152 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1153 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1154 @{$parents->{$c}} = split(/ /, $p);
1155 }
1157 sub linearize_history {
1158 my ($gs, $refs) = @_;
1159 my %parents;
1160 foreach my $c (@$refs) {
1161 read_commit_parents(\%parents, $c);
1162 }
1164 my @linear_refs;
1165 my %skip = ();
1166 my $last_svn_commit = $gs->last_commit;
1167 foreach my $c (reverse @$refs) {
1168 next if $c eq $last_svn_commit;
1169 last if $skip{$c};
1171 unshift @linear_refs, $c;
1172 $skip{$c} = 1;
1174 # we only want the first parent to diff against for linear
1175 # history, we save the rest to inject when we finalize the
1176 # svn commit
1177 my $fp_a = verify_ref("$c~1");
1178 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1179 if (!$fp_a || !$fp_b) {
1180 die "Commit $c\n",
1181 "has no parent commit, and therefore ",
1182 "nothing to diff against.\n",
1183 "You should be working from a repository ",
1184 "originally created by git-svn\n";
1185 }
1186 if ($fp_a ne $fp_b) {
1187 die "$c~1 = $fp_a, however parsing commit $c ",
1188 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1189 }
1191 foreach my $p (@{$parents{$c}}) {
1192 $skip{$p} = 1;
1193 }
1194 }
1195 (\@linear_refs, \%parents);
1196 }
1198 sub find_file_type_and_diff_status {
1199 my ($path) = @_;
1200 return ('dir', '') if $path eq '.';
1202 my $diff_output =
1203 command_oneline(qw(diff --cached --name-status --), $path) || "";
1204 my $diff_status = (split(' ', $diff_output))[0] || "";
1206 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1208 return (undef, undef) if !$diff_status && !$ls_tree;
1210 if ($diff_status eq "A") {
1211 return ("link", $diff_status) if -l $path;
1212 return ("dir", $diff_status) if -d $path;
1213 return ("file", $diff_status);
1214 }
1216 my $mode = (split(' ', $ls_tree))[0] || "";
1218 return ("link", $diff_status) if $mode eq "120000";
1219 return ("dir", $diff_status) if $mode eq "040000";
1220 return ("file", $diff_status);
1221 }
1223 sub md5sum {
1224 my $arg = shift;
1225 my $ref = ref $arg;
1226 my $md5 = Digest::MD5->new();
1227 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1228 $md5->addfile($arg) or croak $!;
1229 } elsif ($ref eq 'SCALAR') {
1230 $md5->add($$arg) or croak $!;
1231 } elsif (!$ref) {
1232 $md5->add($arg) or croak $!;
1233 } else {
1234 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1235 }
1236 return $md5->hexdigest();
1237 }
1239 package Git::SVN;
1240 use strict;
1241 use warnings;
1242 use Fcntl qw/:DEFAULT :seek/;
1243 use constant rev_map_fmt => 'NH40';
1244 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1245 $_repack $_repack_flags $_use_svm_props $_head
1246 $_use_svnsync_props $no_reuse_existing $_minimize_url
1247 $_use_log_author/;
1248 use Carp qw/croak/;
1249 use File::Path qw/mkpath/;
1250 use File::Copy qw/copy/;
1251 use IPC::Open3;
1253 my ($_gc_nr, $_gc_period);
1255 # properties that we do not log:
1256 my %SKIP_PROP;
1257 BEGIN {
1258 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1259 svn:special svn:executable
1260 svn:entry:committed-rev
1261 svn:entry:last-author
1262 svn:entry:uuid
1263 svn:entry:committed-date/;
1265 # some options are read globally, but can be overridden locally
1266 # per [svn-remote "..."] section. Command-line options will *NOT*
1267 # override options set in an [svn-remote "..."] section
1268 no strict 'refs';
1269 for my $option (qw/follow_parent no_metadata use_svm_props
1270 use_svnsync_props/) {
1271 my $key = $option;
1272 $key =~ tr/_//d;
1273 my $prop = "-$option";
1274 *$option = sub {
1275 my ($self) = @_;
1276 return $self->{$prop} if exists $self->{$prop};
1277 my $k = "svn-remote.$self->{repo_id}.$key";
1278 eval { command_oneline(qw/config --get/, $k) };
1279 if ($@) {
1280 $self->{$prop} = ${"Git::SVN::_$option"};
1281 } else {
1282 my $v = command_oneline(qw/config --bool/,$k);
1283 $self->{$prop} = $v eq 'false' ? 0 : 1;
1284 }
1285 return $self->{$prop};
1286 }
1287 }
1288 }
1290 my (%LOCKFILES, %INDEX_FILES);
1291 END {
1292 unlink keys %LOCKFILES if %LOCKFILES;
1293 unlink keys %INDEX_FILES if %INDEX_FILES;
1294 }
1296 sub resolve_local_globs {
1297 my ($url, $fetch, $glob_spec) = @_;
1298 return unless defined $glob_spec;
1299 my $ref = $glob_spec->{ref};
1300 my $path = $glob_spec->{path};
1301 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1302 next unless m#^refs/remotes/$ref->{regex}$#;
1303 my $p = $1;
1304 my $pathname = desanitize_refname($path->full_path($p));
1305 my $refname = desanitize_refname($ref->full_path($p));
1306 if (my $existing = $fetch->{$pathname}) {
1307 if ($existing ne $refname) {
1308 die "Refspec conflict:\n",
1309 "existing: refs/remotes/$existing\n",
1310 " globbed: refs/remotes/$refname\n";
1311 }
1312 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1313 $u =~ s!^\Q$url\E(/|$)!! or die
1314 "refs/remotes/$refname: '$url' not found in '$u'\n";
1315 if ($pathname ne $u) {
1316 warn "W: Refspec glob conflict ",
1317 "(ref: refs/remotes/$refname):\n",
1318 "expected path: $pathname\n",
1319 " real path: $u\n",
1320 "Continuing ahead with $u\n";
1321 next;
1322 }
1323 } else {
1324 $fetch->{$pathname} = $refname;
1325 }
1326 }
1327 }
1329 sub parse_revision_argument {
1330 my ($base, $head) = @_;
1331 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1332 return ($base, $head);
1333 }
1334 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1335 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1336 return ($head, $head) if ($::_revision eq 'HEAD');
1337 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1338 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1339 die "revision argument: $::_revision not understood by git-svn\n";
1340 }
1342 sub fetch_all {
1343 my ($repo_id, $remotes) = @_;
1344 if (ref $repo_id) {
1345 my $gs = $repo_id;
1346 $repo_id = undef;
1347 $repo_id = $gs->{repo_id};
1348 }
1349 $remotes ||= read_all_remotes();
1350 my $remote = $remotes->{$repo_id} or
1351 die "[svn-remote \"$repo_id\"] unknown\n";
1352 my $fetch = $remote->{fetch};
1353 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1354 my (@gs, @globs);
1355 my $ra = Git::SVN::Ra->new($url);
1356 my $uuid = $ra->get_uuid;
1357 my $head = $ra->get_latest_revnum;
1358 my $base = defined $fetch ? $head : 0;
1360 # read the max revs for wildcard expansion (branches/*, tags/*)
1361 foreach my $t (qw/branches tags/) {
1362 defined $remote->{$t} or next;
1363 push @globs, $remote->{$t};
1364 my $max_rev = eval { tmp_config(qw/--int --get/,
1365 "svn-remote.$repo_id.${t}-maxRev") };
1366 if (defined $max_rev && ($max_rev < $base)) {
1367 $base = $max_rev;
1368 } elsif (!defined $max_rev) {
1369 $base = 0;
1370 }
1371 }
1373 if ($fetch) {
1374 foreach my $p (sort keys %$fetch) {
1375 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1376 my $lr = $gs->rev_map_max;
1377 if (defined $lr) {
1378 $base = $lr if ($lr < $base);
1379 }
1380 push @gs, $gs;
1381 }
1382 }
1384 ($base, $head) = parse_revision_argument($base, $head);
1385 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1386 }
1388 sub read_all_remotes {
1389 my $r = {};
1390 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1391 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1392 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1393 $local_ref =~ s{^/}{};
1394 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1395 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1396 $r->{$1}->{url} = $2;
1397 } elsif (m!^(.+)\.(branches|tags)=
1398 (.*):refs/remotes/(.+)\s*$/!x) {
1399 my ($p, $g) = ($3, $4);
1400 my $rs = $r->{$1}->{$2} = {
1401 t => $2,
1402 remote => $1,
1403 path => Git::SVN::GlobSpec->new($p),
1404 ref => Git::SVN::GlobSpec->new($g) };
1405 if (length($rs->{ref}->{right}) != 0) {
1406 die "The '*' glob character must be the last ",
1407 "character of '$g'\n";
1408 }
1409 }
1410 }
1411 $r;
1412 }
1414 sub init_vars {
1415 $_gc_nr = $_gc_period = 1000;
1416 if (defined $_repack || defined $_repack_flags) {
1417 warn "Repack options are obsolete; they have no effect.\n";
1418 }
1419 }
1421 sub verify_remotes_sanity {
1422 return unless -d $ENV{GIT_DIR};
1423 my %seen;
1424 foreach (command(qw/config -l/)) {
1425 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1426 if ($seen{$1}) {
1427 die "Remote ref refs/remote/$1 is tracked by",
1428 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1429 "Please resolve this ambiguity in ",
1430 "your git configuration file before ",
1431 "continuing\n";
1432 }
1433 $seen{$1} = $_;
1434 }
1435 }
1436 }
1438 # we allow more chars than remotes2config.sh...
1439 sub sanitize_remote_name {
1440 my ($name) = @_;
1441 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1442 $name;
1443 }
1445 sub find_existing_remote {
1446 my ($url, $remotes) = @_;
1447 return undef if $no_reuse_existing;
1448 my $existing;
1449 foreach my $repo_id (keys %$remotes) {
1450 my $u = $remotes->{$repo_id}->{url} or next;
1451 next if $u ne $url;
1452 $existing = $repo_id;
1453 last;
1454 }
1455 $existing;
1456 }
1458 sub init_remote_config {
1459 my ($self, $url, $no_write) = @_;
1460 $url =~ s!/+$!!; # strip trailing slash
1461 my $r = read_all_remotes();
1462 my $existing = find_existing_remote($url, $r);
1463 if ($existing) {
1464 unless ($no_write) {
1465 print STDERR "Using existing ",
1466 "[svn-remote \"$existing\"]\n";
1467 }
1468 $self->{repo_id} = $existing;
1469 } elsif ($_minimize_url) {
1470 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1471 $existing = find_existing_remote($min_url, $r);
1472 if ($existing) {
1473 unless ($no_write) {
1474 print STDERR "Using existing ",
1475 "[svn-remote \"$existing\"]\n";
1476 }
1477 $self->{repo_id} = $existing;
1478 }
1479 if ($min_url ne $url) {
1480 unless ($no_write) {
1481 print STDERR "Using higher level of URL: ",
1482 "$url => $min_url\n";
1483 }
1484 my $old_path = $self->{path};
1485 $self->{path} = $url;
1486 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1487 if (length $old_path) {
1488 $self->{path} .= "/$old_path";
1489 }
1490 $url = $min_url;
1491 }
1492 }
1493 my $orig_url;
1494 if (!$existing) {
1495 # verify that we aren't overwriting anything:
1496 $orig_url = eval {
1497 command_oneline('config', '--get',
1498 "svn-remote.$self->{repo_id}.url")
1499 };
1500 if ($orig_url && ($orig_url ne $url)) {
1501 die "svn-remote.$self->{repo_id}.url already set: ",
1502 "$orig_url\nwanted to set to: $url\n";
1503 }
1504 }
1505 my ($xrepo_id, $xpath) = find_ref($self->refname);
1506 if (defined $xpath) {
1507 die "svn-remote.$xrepo_id.fetch already set to track ",
1508 "$xpath:refs/remotes/", $self->refname, "\n";
1509 }
1510 unless ($no_write) {
1511 command_noisy('config',
1512 "svn-remote.$self->{repo_id}.url", $url);
1513 $self->{path} =~ s{^/}{};
1514 command_noisy('config', '--add',
1515 "svn-remote.$self->{repo_id}.fetch",
1516 "$self->{path}:".$self->refname);
1517 }
1518 $self->{url} = $url;
1519 }
1521 sub find_by_url { # repos_root and, path are optional
1522 my ($class, $full_url, $repos_root, $path) = @_;
1524 return undef unless defined $full_url;
1525 remove_username($full_url);
1526 remove_username($repos_root) if defined $repos_root;
1527 my $remotes = read_all_remotes();
1528 if (defined $full_url && defined $repos_root && !defined $path) {
1529 $path = $full_url;
1530 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1531 }
1532 foreach my $repo_id (keys %$remotes) {
1533 my $u = $remotes->{$repo_id}->{url} or next;
1534 remove_username($u);
1535 next if defined $repos_root && $repos_root ne $u;
1537 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1538 foreach (qw/branches tags/) {
1539 resolve_local_globs($u, $fetch,
1540 $remotes->{$repo_id}->{$_});
1541 }
1542 my $p = $path;
1543 unless (defined $p) {
1544 $p = $full_url;
1545 $p =~ s#^\Q$u\E(?:/|$)## or next;
1546 }
1547 foreach my $f (keys %$fetch) {
1548 next if $f ne $p;
1549 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1550 }
1551 }
1552 undef;
1553 }
1555 sub init {
1556 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1557 my $self = _new($class, $repo_id, $ref_id, $path);
1558 if (defined $url) {
1559 $self->init_remote_config($url, $no_write);
1560 }
1561 $self;
1562 }
1564 sub find_ref {
1565 my ($ref_id) = @_;
1566 foreach (command(qw/config -l/)) {
1567 next unless m!^svn-remote\.(.+)\.fetch=
1568 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1569 my ($repo_id, $path, $ref) = ($1, $2, $3);
1570 if ($ref eq $ref_id) {
1571 $path = '' if ($path =~ m#^\./?#);
1572 return ($repo_id, $path);
1573 }
1574 }
1575 (undef, undef, undef);
1576 }
1578 sub new {
1579 my ($class, $ref_id, $repo_id, $path) = @_;
1580 if (defined $ref_id && !defined $repo_id && !defined $path) {
1581 ($repo_id, $path) = find_ref($ref_id);
1582 if (!defined $repo_id) {
1583 die "Could not find a \"svn-remote.*.fetch\" key ",
1584 "in the repository configuration matching: ",
1585 "refs/remotes/$ref_id\n";
1586 }
1587 }
1588 my $self = _new($class, $repo_id, $ref_id, $path);
1589 if (!defined $self->{path} || !length $self->{path}) {
1590 my $fetch = command_oneline('config', '--get',
1591 "svn-remote.$repo_id.fetch",
1592 ":refs/remotes/$ref_id\$") or
1593 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1594 "\":refs/remotes/$ref_id\$\" in config\n";
1595 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1596 }
1597 $self->{url} = command_oneline('config', '--get',
1598 "svn-remote.$repo_id.url") or
1599 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1600 $self->rebuild;
1601 $self;
1602 }
1604 sub refname {
1605 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1607 # It cannot end with a slash /, we'll throw up on this because
1608 # SVN can't have directories with a slash in their name, either:
1609 if ($refname =~ m{/$}) {
1610 die "ref: '$refname' ends with a trailing slash, this is ",
1611 "not permitted by git nor Subversion\n";
1612 }
1614 # It cannot have ASCII control character space, tilde ~, caret ^,
1615 # colon :, question-mark ?, asterisk *, space, or open bracket [
1616 # anywhere.
1617 #
1618 # Additionally, % must be escaped because it is used for escaping
1619 # and we want our escaped refname to be reversible
1620 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1622 # no slash-separated component can begin with a dot .
1623 # /.* becomes /%2E*
1624 $refname =~ s{/\.}{/%2E}g;
1626 # It cannot have two consecutive dots .. anywhere
1627 # .. becomes %2E%2E
1628 $refname =~ s{\.\.}{%2E%2E}g;
1630 return $refname;
1631 }
1633 sub desanitize_refname {
1634 my ($refname) = @_;
1635 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1636 return $refname;
1637 }
1639 sub svm_uuid {
1640 my ($self) = @_;
1641 return $self->{svm}->{uuid} if $self->svm;
1642 $self->ra;
1643 unless ($self->{svm}) {
1644 die "SVM UUID not cached, and reading remotely failed\n";
1645 }
1646 $self->{svm}->{uuid};
1647 }
1649 sub svm {
1650 my ($self) = @_;
1651 return $self->{svm} if $self->{svm};
1652 my $svm;
1653 # see if we have it in our config, first:
1654 eval {
1655 my $section = "svn-remote.$self->{repo_id}";
1656 $svm = {
1657 source => tmp_config('--get', "$section.svm-source"),
1658 uuid => tmp_config('--get', "$section.svm-uuid"),
1659 replace => tmp_config('--get', "$section.svm-replace"),
1660 }
1661 };
1662 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1663 $self->{svm} = $svm;
1664 }
1665 $self->{svm};
1666 }
1668 sub _set_svm_vars {
1669 my ($self, $ra) = @_;
1670 return $ra if $self->svm;
1672 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1673 "(svm:source, svm:uuid) ",
1674 "from the following URLs:\n" );
1675 sub read_svm_props {
1676 my ($self, $ra, $path, $r) = @_;
1677 my $props = ($ra->get_dir($path, $r))[2];
1678 my $src = $props->{'svm:source'};
1679 my $uuid = $props->{'svm:uuid'};
1680 return undef if (!$src || !$uuid);
1682 chomp($src, $uuid);
1684 $uuid =~ m{^[0-9a-f\-]{30,}$}
1685 or die "doesn't look right - svm:uuid is '$uuid'\n";
1687 # the '!' is used to mark the repos_root!/relative/path
1688 $src =~ s{/?!/?}{/};
1689 $src =~ s{/+$}{}; # no trailing slashes please
1690 # username is of no interest
1691 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1693 my $replace = $ra->{url};
1694 $replace .= "/$path" if length $path;
1696 my $section = "svn-remote.$self->{repo_id}";
1697 tmp_config("$section.svm-source", $src);
1698 tmp_config("$section.svm-replace", $replace);
1699 tmp_config("$section.svm-uuid", $uuid);
1700 $self->{svm} = {
1701 source => $src,
1702 uuid => $uuid,
1703 replace => $replace
1704 };
1705 }
1707 my $r = $ra->get_latest_revnum;
1708 my $path = $self->{path};
1709 my %tried;
1710 while (length $path) {
1711 unless ($tried{"$self->{url}/$path"}) {
1712 return $ra if $self->read_svm_props($ra, $path, $r);
1713 $tried{"$self->{url}/$path"} = 1;
1714 }
1715 $path =~ s#/?[^/]+$##;
1716 }
1717 die "Path: '$path' should be ''\n" if $path ne '';
1718 return $ra if $self->read_svm_props($ra, $path, $r);
1719 $tried{"$self->{url}/$path"} = 1;
1721 if ($ra->{repos_root} eq $self->{url}) {
1722 die @err, (map { " $_\n" } keys %tried), "\n";
1723 }
1725 # nope, make sure we're connected to the repository root:
1726 my $ok;
1727 my @tried_b;
1728 $path = $ra->{svn_path};
1729 $ra = Git::SVN::Ra->new($ra->{repos_root});
1730 while (length $path) {
1731 unless ($tried{"$ra->{url}/$path"}) {
1732 $ok = $self->read_svm_props($ra, $path, $r);
1733 last if $ok;
1734 $tried{"$ra->{url}/$path"} = 1;
1735 }
1736 $path =~ s#/?[^/]+$##;
1737 }
1738 die "Path: '$path' should be ''\n" if $path ne '';
1739 $ok ||= $self->read_svm_props($ra, $path, $r);
1740 $tried{"$ra->{url}/$path"} = 1;
1741 if (!$ok) {
1742 die @err, (map { " $_\n" } keys %tried), "\n";
1743 }
1744 Git::SVN::Ra->new($self->{url});
1745 }
1747 sub svnsync {
1748 my ($self) = @_;
1749 return $self->{svnsync} if $self->{svnsync};
1751 if ($self->no_metadata) {
1752 die "Can't have both 'noMetadata' and ",
1753 "'useSvnsyncProps' options set!\n";
1754 }
1755 if ($self->rewrite_root) {
1756 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1757 "options set!\n";
1758 }
1760 my $svnsync;
1761 # see if we have it in our config, first:
1762 eval {
1763 my $section = "svn-remote.$self->{repo_id}";
1765 my $url = tmp_config('--get', "$section.svnsync-url");
1766 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1767 die "doesn't look right - svn:sync-from-url is '$url'\n";
1769 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
1770 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1771 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1773 $svnsync = { url => $url, uuid => $uuid }
1774 };
1775 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1776 return $self->{svnsync} = $svnsync;
1777 }
1779 my $err = "useSvnsyncProps set, but failed to read " .
1780 "svnsync property: svn:sync-from-";
1781 my $rp = $self->ra->rev_proplist(0);
1783 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1784 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
1785 die "doesn't look right - svn:sync-from-url is '$url'\n";
1787 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1788 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}) or
1789 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1791 my $section = "svn-remote.$self->{repo_id}";
1792 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1793 tmp_config('--add', "$section.svnsync-url", $url);
1794 return $self->{svnsync} = { url => $url, uuid => $uuid };
1795 }
1797 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1798 # remote lookup (useful for 'git svn log').
1799 sub ra_uuid {
1800 my ($self) = @_;
1801 unless ($self->{ra_uuid}) {
1802 my $key = "svn-remote.$self->{repo_id}.uuid";
1803 my $uuid = eval { tmp_config('--get', $key) };
1804 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1805 $self->{ra_uuid} = $uuid;
1806 } else {
1807 die "ra_uuid called without URL\n" unless $self->{url};
1808 $self->{ra_uuid} = $self->ra->get_uuid;
1809 tmp_config('--add', $key, $self->{ra_uuid});
1810 }
1811 }
1812 $self->{ra_uuid};
1813 }
1815 sub _set_repos_root {
1816 my ($self, $repos_root) = @_;
1817 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1818 $repos_root ||= $self->ra->{repos_root};
1819 tmp_config($k, $repos_root);
1820 $repos_root;
1821 }
1823 sub repos_root {
1824 my ($self) = @_;
1825 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1826 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1827 }
1829 sub ra {
1830 my ($self) = shift;
1831 my $ra = Git::SVN::Ra->new($self->{url});
1832 $self->_set_repos_root($ra->{repos_root});
1833 if ($self->use_svm_props && !$self->{svm}) {
1834 if ($self->no_metadata) {
1835 die "Can't have both 'noMetadata' and ",
1836 "'useSvmProps' options set!\n";
1837 } elsif ($self->use_svnsync_props) {
1838 die "Can't have both 'useSvnsyncProps' and ",
1839 "'useSvmProps' options set!\n";
1840 }
1841 $ra = $self->_set_svm_vars($ra);
1842 $self->{-want_revprops} = 1;
1843 }
1844 $ra;
1845 }
1847 sub rel_path {
1848 my ($self) = @_;
1849 my $repos_root = $self->ra->{repos_root};
1850 return $self->{path} if ($self->{url} eq $repos_root);
1851 my $url = $self->{url} .
1852 (length $self->{path} ? "/$self->{path}" : $self->{path});
1853 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1854 $url;
1855 }
1857 # prop_walk(PATH, REV, SUB)
1858 # -------------------------
1859 # Recursively traverse PATH at revision REV and invoke SUB for each
1860 # directory that contains a SVN property. SUB will be invoked as
1861 # follows: &SUB(gs, path, props); where `gs' is this instance of
1862 # Git::SVN, `path' the path to the directory where the properties
1863 # `props' were found. The `path' will be relative to point of checkout,
1864 # that is, if url://repo/trunk is the current Git branch, and that
1865 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1866 # as `path' (note the trailing `/').
1867 sub prop_walk {
1868 my ($self, $path, $rev, $sub) = @_;
1870 $path =~ s#^/##;
1871 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1872 $path =~ s#^/*#/#g;
1873 my $p = $path;
1874 # Strip the irrelevant part of the path.
1875 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1876 # Ensure the path is terminated by a `/'.
1877 $p =~ s#/*$#/#;
1879 # The properties contain all the internal SVN stuff nobody
1880 # (usually) cares about.
1881 my $interesting_props = 0;
1882 foreach (keys %{$props}) {
1883 # If it doesn't start with `svn:', it must be a
1884 # user-defined property.
1885 ++$interesting_props and next if $_ !~ /^svn:/;
1886 # FIXME: Fragile, if SVN adds new public properties,
1887 # this needs to be updated.
1888 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1889 |eol-style|mime-type
1890 |externals|needs-lock)$/x;
1891 }
1892 &$sub($self, $p, $props) if $interesting_props;
1894 foreach (sort keys %$dirent) {
1895 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1896 $self->prop_walk($path . '/' . $_, $rev, $sub);
1897 }
1898 }
1900 sub last_rev { ($_[0]->last_rev_commit)[0] }
1901 sub last_commit { ($_[0]->last_rev_commit)[1] }
1903 # returns the newest SVN revision number and newest commit SHA1
1904 sub last_rev_commit {
1905 my ($self) = @_;
1906 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1907 return ($self->{last_rev}, $self->{last_commit});
1908 }
1909 my $c = ::verify_ref($self->refname.'^0');
1910 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1911 my $rev = (::cmt_metadata($c))[1];
1912 if (defined $rev) {
1913 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1914 return ($rev, $c);
1915 }
1916 }
1917 my $map_path = $self->map_path;
1918 unless (-e $map_path) {
1919 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1920 return (undef, undef);
1921 }
1922 my ($rev, $commit) = $self->rev_map_max(1);
1923 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1924 return ($rev, $commit);
1925 }
1927 sub get_fetch_range {
1928 my ($self, $min, $max) = @_;
1929 $max ||= $self->ra->get_latest_revnum;
1930 $min ||= $self->rev_map_max;
1931 (++$min, $max);
1932 }
1934 sub tmp_config {
1935 my (@args) = @_;
1936 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1937 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1938 if (! -f $config && -f $old_def_config) {
1939 rename $old_def_config, $config or
1940 die "Failed rename $old_def_config => $config: $!\n";
1941 }
1942 my $old_config = $ENV{GIT_CONFIG};
1943 $ENV{GIT_CONFIG} = $config;
1944 $@ = undef;
1945 my @ret = eval {
1946 unless (-f $config) {
1947 mkfile($config);
1948 open my $fh, '>', $config or
1949 die "Can't open $config: $!\n";
1950 print $fh "; This file is used internally by ",
1951 "git-svn\n" or die
1952 "Couldn't write to $config: $!\n";
1953 print $fh "; You should not have to edit it\n" or
1954 die "Couldn't write to $config: $!\n";
1955 close $fh or die "Couldn't close $config: $!\n";
1956 }
1957 command('config', @args);
1958 };
1959 my $err = $@;
1960 if (defined $old_config) {
1961 $ENV{GIT_CONFIG} = $old_config;
1962 } else {
1963 delete $ENV{GIT_CONFIG};
1964 }
1965 die $err if $err;
1966 wantarray ? @ret : $ret[0];
1967 }
1969 sub tmp_index_do {
1970 my ($self, $sub) = @_;
1971 my $old_index = $ENV{GIT_INDEX_FILE};
1972 $ENV{GIT_INDEX_FILE} = $self->{index};
1973 $@ = undef;
1974 my @ret = eval {
1975 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1976 mkpath([$dir]) unless -d $dir;
1977 &$sub;
1978 };
1979 my $err = $@;
1980 if (defined $old_index) {
1981 $ENV{GIT_INDEX_FILE} = $old_index;
1982 } else {
1983 delete $ENV{GIT_INDEX_FILE};
1984 }
1985 die $err if $err;
1986 wantarray ? @ret : $ret[0];
1987 }
1989 sub assert_index_clean {
1990 my ($self, $treeish) = @_;
1992 $self->tmp_index_do(sub {
1993 command_noisy('read-tree', $treeish) unless -e $self->{index};
1994 my $x = command_oneline('write-tree');
1995 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1996 /^tree ($::sha1)/mo);
1997 return if $y eq $x;
1999 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2000 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2001 command_noisy('read-tree', $treeish);
2002 $x = command_oneline('write-tree');
2003 if ($y ne $x) {
2004 ::fatal "trees ($treeish) $y != $x\n",
2005 "Something is seriously wrong...";
2006 }
2007 });
2008 }
2010 sub get_commit_parents {
2011 my ($self, $log_entry) = @_;
2012 my (%seen, @ret, @tmp);
2013 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2014 if (my $ip = $self->{inject_parents}) {
2015 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2016 push @tmp, $commit;
2017 }
2018 }
2019 if (my $cur = ::verify_ref($self->refname.'^0')) {
2020 push @tmp, $cur;
2021 }
2022 if (my $ipd = $self->{inject_parents_dcommit}) {
2023 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2024 push @tmp, @$commit;
2025 }
2026 }
2027 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2028 while (my $p = shift @tmp) {
2029 next if $seen{$p};
2030 $seen{$p} = 1;
2031 push @ret, $p;
2032 # MAXPARENT is defined to 16 in commit-tree.c:
2033 last if @ret >= 16;
2034 }
2035 if (@tmp) {
2036 die "r$log_entry->{revision}: No room for parents:\n\t",
2037 join("\n\t", @tmp), "\n";
2038 }
2039 @ret;
2040 }
2042 sub rewrite_root {
2043 my ($self) = @_;
2044 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2045 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2046 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2047 if ($rwr) {
2048 $rwr =~ s#/+$##;
2049 if ($rwr !~ m#^[a-z\+]+://#) {
2050 die "$rwr is not a valid URL (key: $k)\n";
2051 }
2052 }
2053 $self->{-rewrite_root} = $rwr;
2054 }
2056 sub metadata_url {
2057 my ($self) = @_;
2058 ($self->rewrite_root || $self->{url}) .
2059 (length $self->{path} ? '/' . $self->{path} : '');
2060 }
2062 sub full_url {
2063 my ($self) = @_;
2064 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2065 }
2068 sub set_commit_header_env {
2069 my ($log_entry) = @_;
2070 my %env;
2071 foreach my $ned (qw/NAME EMAIL DATE/) {
2072 foreach my $ac (qw/AUTHOR COMMITTER/) {
2073 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2074 }
2075 }
2077 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2078 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2079 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2081 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2082 ? $log_entry->{commit_name}
2083 : $log_entry->{name};
2084 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2085 ? $log_entry->{commit_email}
2086 : $log_entry->{email};
2087 \%env;
2088 }
2090 sub restore_commit_header_env {
2091 my ($env) = @_;
2092 foreach my $ned (qw/NAME EMAIL DATE/) {
2093 foreach my $ac (qw/AUTHOR COMMITTER/) {
2094 my $k = "GIT_${ac}_${ned}";
2095 if (defined $env->{$k}) {
2096 $ENV{$k} = $env->{$k};
2097 } else {
2098 delete $ENV{$k};
2099 }
2100 }
2101 }
2102 }
2104 sub gc {
2105 command_noisy('gc', '--auto');
2106 };
2108 sub do_git_commit {
2109 my ($self, $log_entry) = @_;
2110 my $lr = $self->last_rev;
2111 if (defined $lr && $lr >= $log_entry->{revision}) {
2112 die "Last fetched revision of ", $self->refname,
2113 " was r$lr, but we are about to fetch: ",
2114 "r$log_entry->{revision}!\n";
2115 }
2116 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2117 croak "$log_entry->{revision} = $c already exists! ",
2118 "Why are we refetching it?\n";
2119 }
2120 my $old_env = set_commit_header_env($log_entry);
2121 my $tree = $log_entry->{tree};
2122 if (!defined $tree) {
2123 $tree = $self->tmp_index_do(sub {
2124 command_oneline('write-tree') });
2125 }
2126 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2128 my @exec = ('git-commit-tree', $tree);
2129 foreach ($self->get_commit_parents($log_entry)) {
2130 push @exec, '-p', $_;
2131 }
2132 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2133 or croak $!;
2134 print $msg_fh $log_entry->{log} or croak $!;
2135 restore_commit_header_env($old_env);
2136 unless ($self->no_metadata) {
2137 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2138 or croak $!;
2139 }
2140 $msg_fh->flush == 0 or croak $!;
2141 close $msg_fh or croak $!;
2142 chomp(my $commit = do { local $/; <$out_fh> });
2143 close $out_fh or croak $!;
2144 waitpid $pid, 0;
2145 croak $? if $?;
2146 if ($commit !~ /^$::sha1$/o) {
2147 die "Failed to commit, invalid sha1: $commit\n";
2148 }
2150 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2152 $self->{last_rev} = $log_entry->{revision};
2153 $self->{last_commit} = $commit;
2154 print "r$log_entry->{revision}";
2155 if (defined $log_entry->{svm_revision}) {
2156 print " (\@$log_entry->{svm_revision})";
2157 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2158 0, $self->svm_uuid);
2159 }
2160 print " = $commit ($self->{ref_id})\n";
2161 if (--$_gc_nr == 0) {
2162 $_gc_nr = $_gc_period;
2163 gc();
2164 }
2165 return $commit;
2166 }
2168 sub match_paths {
2169 my ($self, $paths, $r) = @_;
2170 return 1 if $self->{path} eq '';
2171 if (my $path = $paths->{"/$self->{path}"}) {
2172 return ($path->{action} eq 'D') ? 0 : 1;
2173 }
2174 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2175 if (grep /$self->{path_regex}/, keys %$paths) {
2176 return 1;
2177 }
2178 my $c = '';
2179 foreach (split m#/#, $self->{path}) {
2180 $c .= "/$_";
2181 next unless ($paths->{$c} &&
2182 ($paths->{$c}->{action} =~ /^[AR]$/));
2183 if ($self->ra->check_path($self->{path}, $r) ==
2184 $SVN::Node::dir) {
2185 return 1;
2186 }
2187 }
2188 return 0;
2189 }
2191 sub find_parent_branch {
2192 my ($self, $paths, $rev) = @_;
2193 return undef unless $self->follow_parent;
2194 unless (defined $paths) {
2195 my $err_handler = $SVN::Error::handler;
2196 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2197 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2198 $paths =
2199 Git::SVN::Ra::dup_changed_paths($_[0]) });
2200 $SVN::Error::handler = $err_handler;
2201 }
2202 return undef unless defined $paths;
2204 # look for a parent from another branch:
2205 my @b_path_components = split m#/#, $self->rel_path;
2206 my @a_path_components;
2207 my $i;
2208 while (@b_path_components) {
2209 $i = $paths->{'/'.join('/', @b_path_components)};
2210 last if $i && defined $i->{copyfrom_path};
2211 unshift(@a_path_components, pop(@b_path_components));
2212 }
2213 return undef unless defined $i && defined $i->{copyfrom_path};
2214 my $branch_from = $i->{copyfrom_path};
2215 if (@a_path_components) {
2216 print STDERR "branch_from: $branch_from => ";
2217 $branch_from .= '/'.join('/', @a_path_components);
2218 print STDERR $branch_from, "\n";
2219 }
2220 my $r = $i->{copyfrom_rev};
2221 my $repos_root = $self->ra->{repos_root};
2222 my $url = $self->ra->{url};
2223 my $new_url = $repos_root . $branch_from;
2224 print STDERR "Found possible branch point: ",
2225 "$new_url => ", $self->full_url, ", $r\n";
2226 $branch_from =~ s#^/##;
2227 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2228 unless ($gs) {
2229 my $ref_id = $self->{ref_id};
2230 $ref_id =~ s/\@\d+$//;
2231 $ref_id .= "\@$r";
2232 # just grow a tail if we're not unique enough :x
2233 $ref_id .= '-' while find_ref($ref_id);
2234 print STDERR "Initializing parent: $ref_id\n";
2235 my ($u, $p) = ($new_url, '');
2236 if ($u =~ s#^\Q$url\E(/|$)##) {
2237 $p = $u;
2238 $u = $url;
2239 }
2240 $gs = Git::SVN->init($u, $p, $self->{repo_id}, $ref_id, 1);
2241 }
2242 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2243 if (!defined $r0 || !defined $parent) {
2244 my ($base, $head) = parse_revision_argument(0, $r);
2245 if ($base <= $r) {
2246 $gs->fetch($base, $r);
2247 }
2248 ($r0, $parent) = $gs->last_rev_commit;
2249 }
2250 if (defined $r0 && defined $parent) {
2251 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2252 my $ed;
2253 if ($self->ra->can_do_switch) {
2254 $self->assert_index_clean($parent);
2255 print STDERR "Following parent with do_switch\n";
2256 # do_switch works with svn/trunk >= r22312, but that
2257 # is not included with SVN 1.4.3 (the latest version
2258 # at the moment), so we can't rely on it
2259 $self->{last_commit} = $parent;
2260 $ed = SVN::Git::Fetcher->new($self);
2261 $gs->ra->gs_do_switch($r0, $rev, $gs,
2262 $self->full_url, $ed)
2263 or die "SVN connection failed somewhere...\n";
2264 } elsif ($self->ra->trees_match($new_url, $r0,
2265 $self->full_url, $rev)) {
2266 print STDERR "Trees match:\n",
2267 " $new_url\@$r0\n",
2268 " ${\$self->full_url}\@$rev\n",
2269 "Following parent with no changes\n";
2270 $self->tmp_index_do(sub {
2271 command_noisy('read-tree', $parent);
2272 });
2273 $self->{last_commit} = $parent;
2274 } else {
2275 print STDERR "Following parent with do_update\n";
2276 $ed = SVN::Git::Fetcher->new($self);
2277 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2278 or die "SVN connection failed somewhere...\n";
2279 }
2280 print STDERR "Successfully followed parent\n";
2281 return $self->make_log_entry($rev, [$parent], $ed);
2282 }
2283 return undef;
2284 }
2286 sub do_fetch {
2287 my ($self, $paths, $rev) = @_;
2288 my $ed;
2289 my ($last_rev, @parents);
2290 if (my $lc = $self->last_commit) {
2291 # we can have a branch that was deleted, then re-added
2292 # under the same name but copied from another path, in
2293 # which case we'll have multiple parents (we don't
2294 # want to break the original ref, nor lose copypath info):
2295 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2296 push @{$log_entry->{parents}}, $lc;
2297 return $log_entry;
2298 }
2299 $ed = SVN::Git::Fetcher->new($self);
2300 $last_rev = $self->{last_rev};
2301 $ed->{c} = $lc;
2302 @parents = ($lc);
2303 } else {
2304 $last_rev = $rev;
2305 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2306 return $log_entry;
2307 }
2308 $ed = SVN::Git::Fetcher->new($self);
2309 }
2310 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2311 die "SVN connection failed somewhere...\n";
2312 }
2313 $self->make_log_entry($rev, \@parents, $ed);
2314 }
2316 sub get_untracked {
2317 my ($self, $ed) = @_;
2318 my @out;
2319 my $h = $ed->{empty};
2320 foreach (sort keys %$h) {
2321 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2322 push @out, " $act: " . uri_encode($_);
2323 warn "W: $act: $_\n";
2324 }
2325 foreach my $t (qw/dir_prop file_prop/) {
2326 $h = $ed->{$t} or next;
2327 foreach my $path (sort keys %$h) {
2328 my $ppath = $path eq '' ? '.' : $path;
2329 foreach my $prop (sort keys %{$h->{$path}}) {
2330 next if $SKIP_PROP{$prop};
2331 my $v = $h->{$path}->{$prop};
2332 my $t_ppath_prop = "$t: " .
2333 uri_encode($ppath) . ' ' .
2334 uri_encode($prop);
2335 if (defined $v) {
2336 push @out, " +$t_ppath_prop " .
2337 uri_encode($v);
2338 } else {
2339 push @out, " -$t_ppath_prop";
2340 }
2341 }
2342 }
2343 }
2344 foreach my $t (qw/absent_file absent_directory/) {
2345 $h = $ed->{$t} or next;
2346 foreach my $parent (sort keys %$h) {
2347 foreach my $path (sort @{$h->{$parent}}) {
2348 push @out, " $t: " .
2349 uri_encode("$parent/$path");
2350 warn "W: $t: $parent/$path ",
2351 "Insufficient permissions?\n";
2352 }
2353 }
2354 }
2355 \@out;
2356 }
2358 sub parse_svn_date {
2359 my $date = shift || return '+0000 1970-01-01 00:00:00';
2360 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2361 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2362 croak "Unable to parse date: $date\n";
2363 "+0000 $Y-$m-$d $H:$M:$S";
2364 }
2366 sub check_author {
2367 my ($author) = @_;
2368 if (!defined $author || length $author == 0) {
2369 $author = '(no author)';
2370 }
2371 if (defined $::_authors && ! defined $::users{$author}) {
2372 die "Author: $author not defined in $::_authors file\n";
2373 }
2374 $author;
2375 }
2377 sub make_log_entry {
2378 my ($self, $rev, $parents, $ed) = @_;
2379 my $untracked = $self->get_untracked($ed);
2381 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2382 print $un "r$rev\n" or croak $!;
2383 print $un $_, "\n" foreach @$untracked;
2384 my %log_entry = ( parents => $parents || [], revision => $rev,
2385 log => '');
2387 my $headrev;
2388 my $logged = delete $self->{logged_rev_props};
2389 if (!$logged || $self->{-want_revprops}) {
2390 my $rp = $self->ra->rev_proplist($rev);
2391 foreach (sort keys %$rp) {
2392 my $v = $rp->{$_};
2393 if (/^svn:(author|date|log)$/) {
2394 $log_entry{$1} = $v;
2395 } elsif ($_ eq 'svm:headrev') {
2396 $headrev = $v;
2397 } else {
2398 print $un " rev_prop: ", uri_encode($_), ' ',
2399 uri_encode($v), "\n";
2400 }
2401 }
2402 } else {
2403 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2404 }
2405 close $un or croak $!;
2407 $log_entry{date} = parse_svn_date($log_entry{date});
2408 $log_entry{log} .= "\n";
2409 my $author = $log_entry{author} = check_author($log_entry{author});
2410 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2411 : ($author, undef);
2413 my ($commit_name, $commit_email) = ($name, $email);
2414 if ($_use_log_author) {
2415 my $name_field;
2416 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2417 $name_field = $1;
2418 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2419 $name_field = $1;
2420 }
2421 if (!defined $name_field) {
2422 #
2423 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2424 ($name, $email) = ($1, $2);
2425 } elsif ($name_field =~ /(.*)@/) {
2426 ($name, $email) = ($1, $name_field);
2427 } else {
2428 ($name, $email) = ($name_field, 'unknown');
2429 }
2430 }
2431 if (defined $headrev && $self->use_svm_props) {
2432 if ($self->rewrite_root) {
2433 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2434 "options set!\n";
2435 }
2436 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2437 # we don't want "SVM: initializing mirror for junk" ...
2438 return undef if $r == 0;
2439 my $svm = $self->svm;
2440 if ($uuid ne $svm->{uuid}) {
2441 die "UUID mismatch on SVM path:\n",
2442 "expected: $svm->{uuid}\n",
2443 " got: $uuid\n";
2444 }
2445 my $full_url = $self->full_url;
2446 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2447 die "Failed to replace '$svm->{replace}' with ",
2448 "'$svm->{source}' in $full_url\n";
2449 # throw away username for storing in records
2450 remove_username($full_url);
2451 $log_entry{metadata} = "$full_url\@$r $uuid";
2452 $log_entry{svm_revision} = $r;
2453 $email ||= "$author\@$uuid";
2454 $commit_email ||= "$author\@$uuid";
2455 } elsif ($self->use_svnsync_props) {
2456 my $full_url = $self->svnsync->{url};
2457 $full_url .= "/$self->{path}" if length $self->{path};
2458 remove_username($full_url);
2459 my $uuid = $self->svnsync->{uuid};
2460 $log_entry{metadata} = "$full_url\@$rev $uuid";
2461 $email ||= "$author\@$uuid";
2462 $commit_email ||= "$author\@$uuid";
2463 } else {
2464 my $url = $self->metadata_url;
2465 remove_username($url);
2466 $log_entry{metadata} = "$url\@$rev " .
2467 $self->ra->get_uuid;
2468 $email ||= "$author\@" . $self->ra->get_uuid;
2469 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2470 }
2471 $log_entry{name} = $name;
2472 $log_entry{email} = $email;
2473 $log_entry{commit_name} = $commit_name;
2474 $log_entry{commit_email} = $commit_email;
2475 \%log_entry;
2476 }
2478 sub fetch {
2479 my ($self, $min_rev, $max_rev, @parents) = @_;
2480 my ($last_rev, $last_commit) = $self->last_rev_commit;
2481 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2482 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2483 }
2485 sub set_tree_cb {
2486 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2487 $self->{inject_parents} = { $rev => $tree };
2488 $self->fetch(undef, undef);
2489 }
2491 sub set_tree {
2492 my ($self, $tree) = (shift, shift);
2493 my $log_entry = ::get_commit_entry($tree);
2494 unless ($self->{last_rev}) {
2495 fatal("Must have an existing revision to commit");
2496 }
2497 my %ed_opts = ( r => $self->{last_rev},
2498 log => $log_entry->{log},
2499 ra => $self->ra,
2500 tree_a => $self->{last_commit},
2501 tree_b => $tree,
2502 editor_cb => sub {
2503 $self->set_tree_cb($log_entry, $tree, @_) },
2504 svn_path => $self->{path} );
2505 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2506 print "No changes\nr$self->{last_rev} = $tree\n";
2507 }
2508 }
2510 sub rebuild_from_rev_db {
2511 my ($self, $path) = @_;
2512 my $r = -1;
2513 open my $fh, '<', $path or croak "open: $!";
2514 while (<$fh>) {
2515 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2516 chomp($_);
2517 ++$r;
2518 next if $_ eq ('0' x 40);
2519 $self->rev_map_set($r, $_);
2520 print "r$r = $_\n";
2521 }
2522 close $fh or croak "close: $!";
2523 unlink $path or croak "unlink: $!";
2524 }
2526 sub rebuild {
2527 my ($self) = @_;
2528 my $map_path = $self->map_path;
2529 return if (-e $map_path && ! -z $map_path);
2530 return unless ::verify_ref($self->refname.'^0');
2531 if ($self->use_svm_props || $self->no_metadata) {
2532 my $rev_db = $self->rev_db_path;
2533 $self->rebuild_from_rev_db($rev_db);
2534 if ($self->use_svm_props) {
2535 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2536 $self->rebuild_from_rev_db($svm_rev_db);
2537 }
2538 $self->unlink_rev_db_symlink;
2539 return;
2540 }
2541 print "Rebuilding $map_path ...\n";
2542 my ($log, $ctx) =
2543 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2544 $self->refname, '--');
2545 my $full_url = $self->full_url;
2546 remove_username($full_url);
2547 my $svn_uuid = $self->ra_uuid;
2548 my $c;
2549 while (<$log>) {
2550 if ( m{^commit ($::sha1)$} ) {
2551 $c = $1;
2552 next;
2553 }
2554 next unless s{^\s*(git-svn-id:)}{$1};
2555 my ($url, $rev, $uuid) = ::extract_metadata($_);
2556 remove_username($url);
2558 # ignore merges (from set-tree)
2559 next if (!defined $rev || !$uuid);
2561 # if we merged or otherwise started elsewhere, this is
2562 # how we break out of it
2563 if (($uuid ne $svn_uuid) ||
2564 ($full_url && $url && ($url ne $full_url))) {
2565 next;
2566 }
2568 $self->rev_map_set($rev, $c);
2569 print "r$rev = $c\n";
2570 }
2571 command_close_pipe($log, $ctx);
2572 print "Done rebuilding $map_path\n";
2573 my $rev_db_path = $self->rev_db_path;
2574 if (-f $self->rev_db_path) {
2575 unlink $self->rev_db_path or croak "unlink: $!";
2576 }
2577 $self->unlink_rev_db_symlink;
2578 }
2580 # rev_map:
2581 # Tie::File seems to be prone to offset errors if revisions get sparse,
2582 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2583 # one of my favorite modules is out :< Next up would be one of the DBM
2584 # modules, but I'm not sure which is most portable...
2585 #
2586 # This is the replacement for the rev_db format, which was too big
2587 # and inefficient for large repositories with a lot of sparse history
2588 # (mainly tags)
2589 #
2590 # The format is this:
2591 # - 24 bytes for every record,
2592 # * 4 bytes for the integer representing an SVN revision number
2593 # * 20 bytes representing the sha1 of a git commit
2594 # - No empty padding records like the old format
2595 # (except the last record, which can be overwritten)
2596 # - new records are written append-only since SVN revision numbers
2597 # increase monotonically
2598 # - lookups on SVN revision number are done via a binary search
2599 # - Piping the file to xxd -c24 is a good way of dumping it for
2600 # viewing or editing (piped back through xxd -r), should the need
2601 # ever arise.
2602 # - The last record can be padding revision with an all-zero sha1
2603 # This is used to optimize fetch performance when using multiple
2604 # "fetch" directives in .git/config
2605 #
2606 # These files are disposable unless noMetadata or useSvmProps is set
2608 sub _rev_map_set {
2609 my ($fh, $rev, $commit) = @_;
2611 my $size = (stat($fh))[7];
2612 ($size % 24) == 0 or croak "inconsistent size: $size";
2614 my $wr_offset = 0;
2615 if ($size > 0) {
2616 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2617 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2618 $read == 24 or croak "read only $read bytes (!= 24)";
2619 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2620 if ($last_commit eq ('0' x40)) {
2621 if ($size >= 48) {
2622 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2623 $read = sysread($fh, $buf, 24) or
2624 croak "read: $!";
2625 $read == 24 or
2626 croak "read only $read bytes (!= 24)";
2627 ($last_rev, $last_commit) =
2628 unpack(rev_map_fmt, $buf);
2629 if ($last_commit eq ('0' x40)) {
2630 croak "inconsistent .rev_map\n";
2631 }
2632 }
2633 if ($last_rev >= $rev) {
2634 croak "last_rev is higher!: $last_rev >= $rev";
2635 }
2636 $wr_offset = -24;
2637 }
2638 }
2639 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2640 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2641 croak "write: $!";
2642 }
2644 sub mkfile {
2645 my ($path) = @_;
2646 unless (-e $path) {
2647 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2648 mkpath([$dir]) unless -d $dir;
2649 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2650 close $fh or die "Couldn't close (create) $path: $!\n";
2651 }
2652 }
2654 sub rev_map_set {
2655 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2656 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2657 my $db = $self->map_path($uuid);
2658 my $db_lock = "$db.lock";
2659 my $sig;
2660 if ($update_ref) {
2661 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2662 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2663 }
2664 mkfile($db);
2666 $LOCKFILES{$db_lock} = 1;
2667 my $sync;
2668 # both of these options make our .rev_db file very, very important
2669 # and we can't afford to lose it because rebuild() won't work
2670 if ($self->use_svm_props || $self->no_metadata) {
2671 $sync = 1;
2672 copy($db, $db_lock) or die "rev_map_set(@_): ",
2673 "Failed to copy: ",
2674 "$db => $db_lock ($!)\n";
2675 } else {
2676 rename $db, $db_lock or die "rev_map_set(@_): ",
2677 "Failed to rename: ",
2678 "$db => $db_lock ($!)\n";
2679 }
2681 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2682 or croak "Couldn't open $db_lock: $!\n";
2683 _rev_map_set($fh, $rev, $commit);
2684 if ($sync) {
2685 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2686 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2687 }
2688 close $fh or croak $!;
2689 if ($update_ref) {
2690 $_head = $self;
2691 command_noisy('update-ref', '-m', "r$rev",
2692 $self->refname, $commit);
2693 }
2694 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2695 "$db_lock => $db ($!)\n";
2696 delete $LOCKFILES{$db_lock};
2697 if ($update_ref) {
2698 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2699 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2700 kill $sig, $$ if defined $sig;
2701 }
2702 }
2704 # If want_commit, this will return an array of (rev, commit) where
2705 # commit _must_ be a valid commit in the archive.
2706 # Otherwise, it'll return the max revision (whether or not the
2707 # commit is valid or just a 0x40 placeholder).
2708 sub rev_map_max {
2709 my ($self, $want_commit) = @_;
2710 $self->rebuild;
2711 my $map_path = $self->map_path;
2712 stat $map_path or return $want_commit ? (0, undef) : 0;
2713 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2714 my $size = (stat($fh))[7];
2715 ($size % 24) == 0 or croak "inconsistent size: $size";
2717 if ($size == 0) {
2718 close $fh or croak "close: $!";
2719 return $want_commit ? (0, undef) : 0;
2720 }
2722 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2723 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2724 my ($r, $c) = unpack(rev_map_fmt, $buf);
2725 if ($want_commit && $c eq ('0' x40)) {
2726 if ($size < 48) {
2727 return $want_commit ? (0, undef) : 0;
2728 }
2729 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2730 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2731 ($r, $c) = unpack(rev_map_fmt, $buf);
2732 if ($c eq ('0'x40)) {
2733 croak "Penultimate record is all-zeroes in $map_path";
2734 }
2735 }
2736 close $fh or croak "close: $!";
2737 $want_commit ? ($r, $c) : $r;
2738 }
2740 sub rev_map_get {
2741 my ($self, $rev, $uuid) = @_;
2742 my $map_path = $self->map_path($uuid);
2743 return undef unless -e $map_path;
2745 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2746 my $size = (stat($fh))[7];
2747 ($size % 24) == 0 or croak "inconsistent size: $size";
2749 if ($size == 0) {
2750 close $fh or croak "close: $fh";
2751 return undef;
2752 }
2754 my ($l, $u) = (0, $size - 24);
2755 my ($r, $c, $buf);
2757 while ($l <= $u) {
2758 my $i = int(($l/24 + $u/24) / 2) * 24;
2759 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2760 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2761 my ($r, $c) = unpack('NH40', $buf);
2763 if ($r < $rev) {
2764 $l = $i + 24;
2765 } elsif ($r > $rev) {
2766 $u = $i - 24;
2767 } else { # $r == $rev
2768 close($fh) or croak "close: $!";
2769 return $c eq ('0' x 40) ? undef : $c;
2770 }
2771 }
2772 close($fh) or croak "close: $!";
2773 undef;
2774 }
2776 # Finds the first svn revision that exists on (if $eq_ok is true) or
2777 # before $rev for the current branch. It will not search any lower
2778 # than $min_rev. Returns the git commit hash and svn revision number
2779 # if found, else (undef, undef).
2780 sub find_rev_before {
2781 my ($self, $rev, $eq_ok, $min_rev) = @_;
2782 --$rev unless $eq_ok;
2783 $min_rev ||= 1;
2784 while ($rev >= $min_rev) {
2785 if (my $c = $self->rev_map_get($rev)) {
2786 return ($rev, $c);
2787 }
2788 --$rev;
2789 }
2790 return (undef, undef);
2791 }
2793 # Finds the first svn revision that exists on (if $eq_ok is true) or
2794 # after $rev for the current branch. It will not search any higher
2795 # than $max_rev. Returns the git commit hash and svn revision number
2796 # if found, else (undef, undef).
2797 sub find_rev_after {
2798 my ($self, $rev, $eq_ok, $max_rev) = @_;
2799 ++$rev unless $eq_ok;
2800 $max_rev ||= $self->rev_map_max;
2801 while ($rev <= $max_rev) {
2802 if (my $c = $self->rev_map_get($rev)) {
2803 return ($rev, $c);
2804 }
2805 ++$rev;
2806 }
2807 return (undef, undef);
2808 }
2810 sub _new {
2811 my ($class, $repo_id, $ref_id, $path) = @_;
2812 unless (defined $repo_id && length $repo_id) {
2813 $repo_id = $Git::SVN::default_repo_id;
2814 }
2815 unless (defined $ref_id && length $ref_id) {
2816 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2817 }
2818 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2819 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2820 $_[3] = $path = '' unless (defined $path);
2821 mkpath(["$ENV{GIT_DIR}/svn"]);
2822 bless {
2823 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2824 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2825 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2826 }
2828 # for read-only access of old .rev_db formats
2829 sub unlink_rev_db_symlink {
2830 my ($self) = @_;
2831 my $link = $self->rev_db_path;
2832 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2833 if (-l $link) {
2834 unlink $link or croak "unlink: $link failed!";
2835 }
2836 }
2838 sub rev_db_path {
2839 my ($self, $uuid) = @_;
2840 my $db_path = $self->map_path($uuid);
2841 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2842 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2843 $db_path;
2844 }
2846 # the new replacement for .rev_db
2847 sub map_path {
2848 my ($self, $uuid) = @_;
2849 $uuid ||= $self->ra_uuid;
2850 "$self->{map_root}.$uuid";
2851 }
2853 sub uri_encode {
2854 my ($f) = @_;
2855 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2856 $f
2857 }
2859 sub remove_username {
2860 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2861 }
2863 package Git::SVN::Prompt;
2864 use strict;
2865 use warnings;
2866 require SVN::Core;
2867 use vars qw/$_no_auth_cache $_username/;
2869 sub simple {
2870 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2871 $may_save = undef if $_no_auth_cache;
2872 $default_username = $_username if defined $_username;
2873 if (defined $default_username && length $default_username) {
2874 if (defined $realm && length $realm) {
2875 print STDERR "Authentication realm: $realm\n";
2876 STDERR->flush;
2877 }
2878 $cred->username($default_username);
2879 } else {
2880 username($cred, $realm, $may_save, $pool);
2881 }
2882 $cred->password(_read_password("Password for '" .
2883 $cred->username . "': ", $realm));
2884 $cred->may_save($may_save);
2885 $SVN::_Core::SVN_NO_ERROR;
2886 }
2888 sub ssl_server_trust {
2889 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2890 $may_save = undef if $_no_auth_cache;
2891 print STDERR "Error validating server certificate for '$realm':\n";
2892 {
2893 no warnings 'once';
2894 # All variables SVN::Auth::SSL::* are used only once,
2895 # so we're shutting up Perl warnings about this.
2896 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2897 print STDERR " - The certificate is not issued ",
2898 "by a trusted authority. Use the\n",
2899 " fingerprint to validate ",
2900 "the certificate manually!\n";
2901 }
2902 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2903 print STDERR " - The certificate hostname ",
2904 "does not match.\n";
2905 }
2906 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2907 print STDERR " - The certificate is not yet valid.\n";
2908 }
2909 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2910 print STDERR " - The certificate has expired.\n";
2911 }
2912 if ($failures & $SVN::Auth::SSL::OTHER) {
2913 print STDERR " - The certificate has ",
2914 "an unknown error.\n";
2915 }
2916 } # no warnings 'once'
2917 printf STDERR
2918 "Certificate information:\n".
2919 " - Hostname: %s\n".
2920 " - Valid: from %s until %s\n".
2921 " - Issuer: %s\n".
2922 " - Fingerprint: %s\n",
2923 map $cert_info->$_, qw(hostname valid_from valid_until
2924 issuer_dname fingerprint);
2925 my $choice;
2926 prompt:
2927 print STDERR $may_save ?
2928 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2929 "(R)eject or accept (t)emporarily? ";
2930 STDERR->flush;
2931 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2932 if ($choice =~ /^t$/i) {
2933 $cred->may_save(undef);
2934 } elsif ($choice =~ /^r$/i) {
2935 return -1;
2936 } elsif ($may_save && $choice =~ /^p$/i) {
2937 $cred->may_save($may_save);
2938 } else {
2939 goto prompt;
2940 }
2941 $cred->accepted_failures($failures);
2942 $SVN::_Core::SVN_NO_ERROR;
2943 }
2945 sub ssl_client_cert {
2946 my ($cred, $realm, $may_save, $pool) = @_;
2947 $may_save = undef if $_no_auth_cache;
2948 print STDERR "Client certificate filename: ";
2949 STDERR->flush;
2950 chomp(my $filename = <STDIN>);
2951 $cred->cert_file($filename);
2952 $cred->may_save($may_save);
2953 $SVN::_Core::SVN_NO_ERROR;
2954 }
2956 sub ssl_client_cert_pw {
2957 my ($cred, $realm, $may_save, $pool) = @_;
2958 $may_save = undef if $_no_auth_cache;
2959 $cred->password(_read_password("Password: ", $realm));
2960 $cred->may_save($may_save);
2961 $SVN::_Core::SVN_NO_ERROR;
2962 }
2964 sub username {
2965 my ($cred, $realm, $may_save, $pool) = @_;
2966 $may_save = undef if $_no_auth_cache;
2967 if (defined $realm && length $realm) {
2968 print STDERR "Authentication realm: $realm\n";
2969 }
2970 my $username;
2971 if (defined $_username) {
2972 $username = $_username;
2973 } else {
2974 print STDERR "Username: ";
2975 STDERR->flush;
2976 chomp($username = <STDIN>);
2977 }
2978 $cred->username($username);
2979 $cred->may_save($may_save);
2980 $SVN::_Core::SVN_NO_ERROR;
2981 }
2983 sub _read_password {
2984 my ($prompt, $realm) = @_;
2985 print STDERR $prompt;
2986 STDERR->flush;
2987 require Term::ReadKey;
2988 Term::ReadKey::ReadMode('noecho');
2989 my $password = '';
2990 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2991 last if $key =~ /[\012\015]/; # \n\r
2992 $password .= $key;
2993 }
2994 Term::ReadKey::ReadMode('restore');
2995 print STDERR "\n";
2996 STDERR->flush;
2997 $password;
2998 }
3000 package SVN::Git::Fetcher;
3001 use vars qw/@ISA/;
3002 use strict;
3003 use warnings;
3004 use Carp qw/croak/;
3005 use IO::File qw//;
3007 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3008 sub new {
3009 my ($class, $git_svn) = @_;
3010 my $self = SVN::Delta::Editor->new;
3011 bless $self, $class;
3012 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
3013 $self->{empty} = {};
3014 $self->{dir_prop} = {};
3015 $self->{file_prop} = {};
3016 $self->{absent_dir} = {};
3017 $self->{absent_file} = {};
3018 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3019 $self;
3020 }
3022 sub set_path_strip {
3023 my ($self, $path) = @_;
3024 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3025 }
3027 sub open_root {
3028 { path => '' };
3029 }
3031 sub open_directory {
3032 my ($self, $path, $pb, $rev) = @_;
3033 { path => $path };
3034 }
3036 sub git_path {
3037 my ($self, $path) = @_;
3038 if ($self->{path_strip}) {
3039 $path =~ s!$self->{path_strip}!! or
3040 die "Failed to strip path '$path' ($self->{path_strip})\n";
3041 }
3042 $path;
3043 }
3045 sub delete_entry {
3046 my ($self, $path, $rev, $pb) = @_;
3048 my $gpath = $self->git_path($path);
3049 return undef if ($gpath eq '');
3051 # remove entire directories.
3052 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3053 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3054 -r --name-only -z/,
3055 $self->{c}, '--', $gpath);
3056 local $/ = "\0";
3057 while (<$ls>) {
3058 chomp;
3059 $self->{gii}->remove($_);
3060 print "\tD\t$_\n" unless $::_q;
3061 }
3062 print "\tD\t$gpath/\n" unless $::_q;
3063 command_close_pipe($ls, $ctx);
3064 $self->{empty}->{$path} = 0
3065 } else {
3066 $self->{gii}->remove($gpath);
3067 print "\tD\t$gpath\n" unless $::_q;
3068 }
3069 undef;
3070 }
3072 sub open_file {
3073 my ($self, $path, $pb, $rev) = @_;
3074 my $gpath = $self->git_path($path);
3075 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3076 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3077 unless (defined $mode && defined $blob) {
3078 die "$path was not found in commit $self->{c} (r$rev)\n";
3079 }
3080 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3081 pool => SVN::Pool->new, action => 'M' };
3082 }
3084 sub add_file {
3085 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3086 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3087 delete $self->{empty}->{$dir};
3088 { path => $path, mode_a => 100644, mode_b => 100644,
3089 pool => SVN::Pool->new, action => 'A' };
3090 }
3092 sub add_directory {
3093 my ($self, $path, $cp_path, $cp_rev) = @_;
3094 my $gpath = $self->git_path($path);
3095 if ($gpath eq '') {
3096 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3097 -r --name-only -z/,
3098 $self->{c});
3099 local $/ = "\0";
3100 while (<$ls>) {
3101 chomp;
3102 $self->{gii}->remove($_);
3103 print "\tD\t$_\n" unless $::_q;
3104 }
3105 command_close_pipe($ls, $ctx);
3106 $self->{empty}->{$path} = 0;
3107 }
3108 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3109 delete $self->{empty}->{$dir};
3110 $self->{empty}->{$path} = 1;
3111 { path => $path };
3112 }
3114 sub change_dir_prop {
3115 my ($self, $db, $prop, $value) = @_;
3116 $self->{dir_prop}->{$db->{path}} ||= {};
3117 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3118 undef;
3119 }
3121 sub absent_directory {
3122 my ($self, $path, $pb) = @_;
3123 $self->{absent_dir}->{$pb->{path}} ||= [];
3124 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3125 undef;
3126 }
3128 sub absent_file {
3129 my ($self, $path, $pb) = @_;
3130 $self->{absent_file}->{$pb->{path}} ||= [];
3131 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3132 undef;
3133 }
3135 sub change_file_prop {
3136 my ($self, $fb, $prop, $value) = @_;
3137 if ($prop eq 'svn:executable') {
3138 if ($fb->{mode_b} != 120000) {
3139 $fb->{mode_b} = defined $value ? 100755 : 100644;
3140 }
3141 } elsif ($prop eq 'svn:special') {
3142 $fb->{mode_b} = defined $value ? 120000 : 100644;
3143 } else {
3144 $self->{file_prop}->{$fb->{path}} ||= {};
3145 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3146 }
3147 undef;
3148 }
3150 sub apply_textdelta {
3151 my ($self, $fb, $exp) = @_;
3152 my $fh = IO::File->new_tmpfile;
3153 $fh->autoflush(1);
3154 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3155 # (but $base does not,) so dup() it for reading in close_file
3156 open my $dup, '<&', $fh or croak $!;
3157 my $base = IO::File->new_tmpfile;
3158 $base->autoflush(1);
3159 if ($fb->{blob}) {
3160 defined (my $pid = fork) or croak $!;
3161 if (!$pid) {
3162 open STDOUT, '>&', $base or croak $!;
3163 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3164 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3165 }
3166 waitpid $pid, 0;
3167 croak $? if $?;
3169 if (defined $exp) {
3170 seek $base, 0, 0 or croak $!;
3171 my $got = ::md5sum($base);
3172 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3173 "expected: $exp\n",
3174 " got: $got\n" if ($got ne $exp);
3175 }
3176 }
3177 seek $base, 0, 0 or croak $!;
3178 $fb->{fh} = $dup;
3179 $fb->{base} = $base;
3180 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3181 }
3183 sub close_file {
3184 my ($self, $fb, $exp) = @_;
3185 my $hash;
3186 my $path = $self->git_path($fb->{path});
3187 if (my $fh = $fb->{fh}) {
3188 if (defined $exp) {
3189 seek($fh, 0, 0) or croak $!;
3190 my $got = ::md5sum($fh);
3191 if ($got ne $exp) {
3192 die "Checksum mismatch: $path\n",
3193 "expected: $exp\n got: $got\n";
3194 }
3195 }
3196 sysseek($fh, 0, 0) or croak $!;
3197 if ($fb->{mode_b} == 120000) {
3198 eval {
3199 sysread($fh, my $buf, 5) == 5 or croak $!;
3200 $buf eq 'link ' or die "$path has mode 120000",
3201 " but is not a link";
3202 };
3203 if ($@) {
3204 warn "$@\n";
3205 sysseek($fh, 0, 0) or croak $!;
3206 }
3207 }
3208 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3209 if (!$pid) {
3210 open STDIN, '<&', $fh or croak $!;
3211 exec qw/git-hash-object -w --stdin/ or croak $!;
3212 }
3213 chomp($hash = do { local $/; <$out> });
3214 close $out or croak $!;
3215 close $fh or croak $!;
3216 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3217 close $fb->{base} or croak $!;
3218 } else {
3219 $hash = $fb->{blob} or die "no blob information\n";
3220 }
3221 $fb->{pool}->clear;
3222 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3223 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3224 undef;
3225 }
3227 sub abort_edit {
3228 my $self = shift;
3229 $self->{nr} = $self->{gii}->{nr};
3230 delete $self->{gii};
3231 $self->SUPER::abort_edit(@_);
3232 }
3234 sub close_edit {
3235 my $self = shift;
3236 $self->{git_commit_ok} = 1;
3237 $self->{nr} = $self->{gii}->{nr};
3238 delete $self->{gii};
3239 $self->SUPER::close_edit(@_);
3240 }
3242 package SVN::Git::Editor;
3243 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3244 use strict;
3245 use warnings;
3246 use Carp qw/croak/;
3247 use IO::File;
3249 sub new {
3250 my ($class, $opts) = @_;
3251 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3252 die "$_ required!\n" unless (defined $opts->{$_});
3253 }
3255 my $pool = SVN::Pool->new;
3256 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3257 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3258 $opts->{r}, $mods);
3260 # $opts->{ra} functions should not be used after this:
3261 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3262 $opts->{editor_cb}, $pool);
3263 my $self = SVN::Delta::Editor->new(@ce, $pool);
3264 bless $self, $class;
3265 foreach (qw/svn_path r tree_a tree_b/) {
3266 $self->{$_} = $opts->{$_};
3267 }
3268 $self->{url} = $opts->{ra}->{url};
3269 $self->{mods} = $mods;
3270 $self->{types} = $types;
3271 $self->{pool} = $pool;
3272 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3273 $self->{rm} = { };
3274 $self->{path_prefix} = length $self->{svn_path} ?
3275 "$self->{svn_path}/" : '';
3276 return $self;
3277 }
3279 sub generate_diff {
3280 my ($tree_a, $tree_b) = @_;
3281 my @diff_tree = qw(diff-tree -z -r);
3282 if ($_cp_similarity) {
3283 push @diff_tree, "-C$_cp_similarity";
3284 } else {
3285 push @diff_tree, '-C';
3286 }
3287 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3288 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3289 push @diff_tree, $tree_a, $tree_b;
3290 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3291 local $/ = "\0";
3292 my $state = 'meta';
3293 my @mods;
3294 while (<$diff_fh>) {
3295 chomp $_; # this gets rid of the trailing "\0"
3296 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3297 $::sha1\s($::sha1)\s
3298 ([MTCRAD])\d*$/xo) {
3299 push @mods, { mode_a => $1, mode_b => $2,
3300 sha1_b => $3, chg => $4 };
3301 if ($4 =~ /^(?:C|R)$/) {
3302 $state = 'file_a';
3303 } else {
3304 $state = 'file_b';
3305 }
3306 } elsif ($state eq 'file_a') {
3307 my $x = $mods[$#mods] or croak "Empty array\n";
3308 if ($x->{chg} !~ /^(?:C|R)$/) {
3309 croak "Error parsing $_, $x->{chg}\n";
3310 }
3311 $x->{file_a} = $_;
3312 $state = 'file_b';
3313 } elsif ($state eq 'file_b') {
3314 my $x = $mods[$#mods] or croak "Empty array\n";
3315 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3316 croak "Error parsing $_, $x->{chg}\n";
3317 }
3318 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3319 croak "Error parsing $_, $x->{chg}\n";
3320 }
3321 $x->{file_b} = $_;
3322 $state = 'meta';
3323 } else {
3324 croak "Error parsing $_\n";
3325 }
3326 }
3327 command_close_pipe($diff_fh, $ctx);
3328 \@mods;
3329 }
3331 sub check_diff_paths {
3332 my ($ra, $pfx, $rev, $mods) = @_;
3333 my %types;
3334 $pfx .= '/' if length $pfx;
3336 sub type_diff_paths {
3337 my ($ra, $types, $path, $rev) = @_;
3338 my @p = split m#/+#, $path;
3339 my $c = shift @p;
3340 unless (defined $types->{$c}) {
3341 $types->{$c} = $ra->check_path($c, $rev);
3342 }
3343 while (@p) {
3344 $c .= '/' . shift @p;
3345 next if defined $types->{$c};
3346 $types->{$c} = $ra->check_path($c, $rev);
3347 }
3348 }
3350 foreach my $m (@$mods) {
3351 foreach my $f (qw/file_a file_b/) {
3352 next unless defined $m->{$f};
3353 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3354 if (length $pfx.$dir && ! defined $types{$dir}) {
3355 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3356 }
3357 }
3358 }
3359 \%types;
3360 }
3362 sub split_path {
3363 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3364 }
3366 sub repo_path {
3367 my ($self, $path) = @_;
3368 $self->{path_prefix}.(defined $path ? $path : '');
3369 }
3371 sub url_path {
3372 my ($self, $path) = @_;
3373 if ($self->{url} =~ m#^https?://#) {
3374 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3375 }
3376 $self->{url} . '/' . $self->repo_path($path);
3377 }
3379 sub rmdirs {
3380 my ($self) = @_;
3381 my $rm = $self->{rm};
3382 delete $rm->{''}; # we never delete the url we're tracking
3383 return unless %$rm;
3385 foreach (keys %$rm) {
3386 my @d = split m#/#, $_;
3387 my $c = shift @d;
3388 $rm->{$c} = 1;
3389 while (@d) {
3390 $c .= '/' . shift @d;
3391 $rm->{$c} = 1;
3392 }
3393 }
3394 delete $rm->{$self->{svn_path}};
3395 delete $rm->{''}; # we never delete the url we're tracking
3396 return unless %$rm;
3398 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3399 $self->{tree_b});
3400 local $/ = "\0";
3401 while (<$fh>) {
3402 chomp;
3403 my @dn = split m#/#, $_;
3404 while (pop @dn) {
3405 delete $rm->{join '/', @dn};
3406 }
3407 unless (%$rm) {
3408 close $fh;
3409 return;
3410 }
3411 }
3412 command_close_pipe($fh, $ctx);
3414 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3415 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3416 $self->close_directory($bat->{$d}, $p);
3417 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3418 print "\tD+\t$d/\n" unless $::_q;
3419 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3420 delete $bat->{$d};
3421 }
3422 }
3424 sub open_or_add_dir {
3425 my ($self, $full_path, $baton) = @_;
3426 my $t = $self->{types}->{$full_path};
3427 if (!defined $t) {
3428 die "$full_path not known in r$self->{r} or we have a bug!\n";
3429 }
3430 {
3431 no warnings 'once';
3432 # SVN::Node::none and SVN::Node::file are used only once,
3433 # so we're shutting up Perl's warnings about them.
3434 if ($t == $SVN::Node::none) {
3435 return $self->add_directory($full_path, $baton,
3436 undef, -1, $self->{pool});
3437 } elsif ($t == $SVN::Node::dir) {
3438 return $self->open_directory($full_path, $baton,
3439 $self->{r}, $self->{pool});
3440 } # no warnings 'once'
3441 print STDERR "$full_path already exists in repository at ",
3442 "r$self->{r} and it is not a directory (",
3443 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3444 } # no warnings 'once'
3445 exit 1;
3446 }
3448 sub ensure_path {
3449 my ($self, $path) = @_;
3450 my $bat = $self->{bat};
3451 my $repo_path = $self->repo_path($path);
3452 return $bat->{''} unless (length $repo_path);
3453 my @p = split m#/+#, $repo_path;
3454 my $c = shift @p;
3455 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3456 while (@p) {
3457 my $c0 = $c;
3458 $c .= '/' . shift @p;
3459 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3460 }
3461 return $bat->{$c};
3462 }
3464 sub A {
3465 my ($self, $m) = @_;
3466 my ($dir, $file) = split_path($m->{file_b});
3467 my $pbat = $self->ensure_path($dir);
3468 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3469 undef, -1);
3470 print "\tA\t$m->{file_b}\n" unless $::_q;
3471 $self->chg_file($fbat, $m);
3472 $self->close_file($fbat,undef,$self->{pool});
3473 }
3475 sub C {
3476 my ($self, $m) = @_;
3477 my ($dir, $file) = split_path($m->{file_b});
3478 my $pbat = $self->ensure_path($dir);
3479 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3480 $self->url_path($m->{file_a}), $self->{r});
3481 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3482 $self->chg_file($fbat, $m);
3483 $self->close_file($fbat,undef,$self->{pool});
3484 }
3486 sub delete_entry {
3487 my ($self, $path, $pbat) = @_;
3488 my $rpath = $self->repo_path($path);
3489 my ($dir, $file) = split_path($rpath);
3490 $self->{rm}->{$dir} = 1;
3491 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3492 }
3494 sub R {
3495 my ($self, $m) = @_;
3496 my ($dir, $file) = split_path($m->{file_b});
3497 my $pbat = $self->ensure_path($dir);
3498 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3499 $self->url_path($m->{file_a}), $self->{r});
3500 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3501 $self->chg_file($fbat, $m);
3502 $self->close_file($fbat,undef,$self->{pool});
3504 ($dir, $file) = split_path($m->{file_a});
3505 $pbat = $self->ensure_path($dir);
3506 $self->delete_entry($m->{file_a}, $pbat);
3507 }
3509 sub M {
3510 my ($self, $m) = @_;
3511 my ($dir, $file) = split_path($m->{file_b});
3512 my $pbat = $self->ensure_path($dir);
3513 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3514 $pbat,$self->{r},$self->{pool});
3515 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3516 $self->chg_file($fbat, $m);
3517 $self->close_file($fbat,undef,$self->{pool});
3518 }
3520 sub T { shift->M(@_) }
3522 sub change_file_prop {
3523 my ($self, $fbat, $pname, $pval) = @_;
3524 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3525 }
3527 sub chg_file {
3528 my ($self, $fbat, $m) = @_;
3529 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3530 $self->change_file_prop($fbat,'svn:executable','*');
3531 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3532 $self->change_file_prop($fbat,'svn:executable',undef);
3533 }
3534 my $fh = IO::File->new_tmpfile or croak $!;
3535 if ($m->{mode_b} =~ /^120/) {
3536 print $fh 'link ' or croak $!;
3537 $self->change_file_prop($fbat,'svn:special','*');
3538 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3539 $self->change_file_prop($fbat,'svn:special',undef);
3540 }
3541 defined(my $pid = fork) or croak $!;
3542 if (!$pid) {
3543 open STDOUT, '>&', $fh or croak $!;
3544 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3545 }
3546 waitpid $pid, 0;
3547 croak $? if $?;
3548 $fh->flush == 0 or croak $!;
3549 seek $fh, 0, 0 or croak $!;
3551 my $exp = ::md5sum($fh);
3552 seek $fh, 0, 0 or croak $!;
3554 my $pool = SVN::Pool->new;
3555 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3556 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3557 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3558 $pool->clear;
3560 close $fh or croak $!;
3561 }
3563 sub D {
3564 my ($self, $m) = @_;
3565 my ($dir, $file) = split_path($m->{file_b});
3566 my $pbat = $self->ensure_path($dir);
3567 print "\tD\t$m->{file_b}\n" unless $::_q;
3568 $self->delete_entry($m->{file_b}, $pbat);
3569 }
3571 sub close_edit {
3572 my ($self) = @_;
3573 my ($p,$bat) = ($self->{pool}, $self->{bat});
3574 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3575 next if $_ eq '';
3576 $self->close_directory($bat->{$_}, $p);
3577 }
3578 $self->close_directory($bat->{''}, $p);
3579 $self->SUPER::close_edit($p);
3580 $p->clear;
3581 }
3583 sub abort_edit {
3584 my ($self) = @_;
3585 $self->SUPER::abort_edit($self->{pool});
3586 }
3588 sub DESTROY {
3589 my $self = shift;
3590 $self->SUPER::DESTROY(@_);
3591 $self->{pool}->clear;
3592 }
3594 # this drives the editor
3595 sub apply_diff {
3596 my ($self) = @_;
3597 my $mods = $self->{mods};
3598 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3599 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3600 my $f = $m->{chg};
3601 if (defined $o{$f}) {
3602 $self->$f($m);
3603 } else {
3604 fatal("Invalid change type: $f");
3605 }
3606 }
3607 $self->rmdirs if $_rmdir;
3608 if (@$mods == 0) {
3609 $self->abort_edit;
3610 } else {
3611 $self->close_edit;
3612 }
3613 return scalar @$mods;
3614 }
3616 package Git::SVN::Ra;
3617 use vars qw/@ISA $config_dir $_log_window_size/;
3618 use strict;
3619 use warnings;
3620 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3622 BEGIN {
3623 # enforce temporary pool usage for some simple functions
3624 no strict 'refs';
3625 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3626 my $SUPER = "SUPER::$f";
3627 *$f = sub {
3628 my $self = shift;
3629 my $pool = SVN::Pool->new;
3630 my @ret = $self->$SUPER(@_,$pool);
3631 $pool->clear;
3632 wantarray ? @ret : $ret[0];
3633 };
3634 }
3635 }
3637 sub _auth_providers () {
3638 [
3639 SVN::Client::get_simple_provider(),
3640 SVN::Client::get_ssl_server_trust_file_provider(),
3641 SVN::Client::get_simple_prompt_provider(
3642 \&Git::SVN::Prompt::simple, 2),
3643 SVN::Client::get_ssl_client_cert_file_provider(),
3644 SVN::Client::get_ssl_client_cert_prompt_provider(
3645 \&Git::SVN::Prompt::ssl_client_cert, 2),
3646 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3647 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3648 SVN::Client::get_username_provider(),
3649 SVN::Client::get_ssl_server_trust_prompt_provider(
3650 \&Git::SVN::Prompt::ssl_server_trust),
3651 SVN::Client::get_username_prompt_provider(
3652 \&Git::SVN::Prompt::username, 2)
3653 ]
3654 }
3656 sub escape_uri_only {
3657 my ($uri) = @_;
3658 my @tmp;
3659 foreach (split m{/}, $uri) {
3660 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3661 push @tmp, $_;
3662 }
3663 join('/', @tmp);
3664 }
3666 sub escape_url {
3667 my ($url) = @_;
3668 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3669 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3670 $url = "$scheme://$domain$uri";
3671 }
3672 $url;
3673 }
3675 sub new {
3676 my ($class, $url) = @_;
3677 $url =~ s!/+$!!;
3678 return $RA if ($RA && $RA->{url} eq $url);
3680 SVN::_Core::svn_config_ensure($config_dir, undef);
3681 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3682 my $config = SVN::Core::config_get_config($config_dir);
3683 $RA = undef;
3684 my $dont_store_passwords = 1;
3685 my $conf_t = ${$config}{'config'};
3686 {
3687 no warnings 'once';
3688 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3689 # produces warnings that variables are used only once.
3690 # I had not found the better way to shut them up, so
3691 # the warnings of type 'once' are disabled in this block.
3692 if (SVN::_Core::svn_config_get_bool($conf_t,
3693 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3694 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3695 1) == 0) {
3696 SVN::_Core::svn_auth_set_parameter($baton,
3697 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3698 bless (\$dont_store_passwords, "_p_void"));
3699 }
3700 if (SVN::_Core::svn_config_get_bool($conf_t,
3701 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3702 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3703 1) == 0) {
3704 $Git::SVN::Prompt::_no_auth_cache = 1;
3705 }
3706 } # no warnings 'once'
3707 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3708 config => $config,
3709 pool => SVN::Pool->new,
3710 auth_provider_callbacks => $callbacks);
3711 $self->{url} = $url;
3712 $self->{svn_path} = $url;
3713 $self->{repos_root} = $self->get_repos_root;
3714 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3715 $self->{cache} = { check_path => { r => 0, data => {} },
3716 get_dir => { r => 0, data => {} } };
3717 $RA = bless $self, $class;
3718 }
3720 sub check_path {
3721 my ($self, $path, $r) = @_;
3722 my $cache = $self->{cache}->{check_path};
3723 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3724 return $cache->{data}->{$path};
3725 }
3726 my $pool = SVN::Pool->new;
3727 my $t = $self->SUPER::check_path($path, $r, $pool);
3728 $pool->clear;
3729 if ($r != $cache->{r}) {
3730 %{$cache->{data}} = ();
3731 $cache->{r} = $r;
3732 }
3733 $cache->{data}->{$path} = $t;
3734 }
3736 sub get_dir {
3737 my ($self, $dir, $r) = @_;
3738 my $cache = $self->{cache}->{get_dir};
3739 if ($r == $cache->{r}) {
3740 if (my $x = $cache->{data}->{$dir}) {
3741 return wantarray ? @$x : $x->[0];
3742 }
3743 }
3744 my $pool = SVN::Pool->new;
3745 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3746 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3747 $pool->clear;
3748 if ($r != $cache->{r}) {
3749 %{$cache->{data}} = ();
3750 $cache->{r} = $r;
3751 }
3752 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3753 wantarray ? (\%dirents, $r, $props) : \%dirents;
3754 }
3756 sub DESTROY {
3757 # do not call the real DESTROY since we store ourselves in $RA
3758 }
3760 sub get_log {
3761 my ($self, @args) = @_;
3762 my $pool = SVN::Pool->new;
3763 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3764 my $ret = $self->SUPER::get_log(@args, $pool);
3765 $pool->clear;
3766 $ret;
3767 }
3769 sub trees_match {
3770 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3771 my $ctx = SVN::Client->new(auth => _auth_providers);
3772 my $out = IO::File->new_tmpfile;
3774 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3775 # $ctx->diff(), so we'll create a default one
3776 my $pool = SVN::Pool->new_default_sub;
3778 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3779 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3780 $out->flush;
3781 my $ret = (($out->stat)[7] == 0);
3782 close $out or croak $!;
3784 $ret;
3785 }
3787 sub get_commit_editor {
3788 my ($self, $log, $cb, $pool) = @_;
3789 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3790 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3791 }
3793 sub gs_do_update {
3794 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3795 my $new = ($rev_a == $rev_b);
3796 my $path = $gs->{path};
3798 if ($new && -e $gs->{index}) {
3799 unlink $gs->{index} or die
3800 "Couldn't unlink index: $gs->{index}: $!\n";
3801 }
3802 my $pool = SVN::Pool->new;
3803 $editor->set_path_strip($path);
3804 my (@pc) = split m#/#, $path;
3805 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3806 1, $editor, $pool);
3807 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3809 # Since we can't rely on svn_ra_reparent being available, we'll
3810 # just have to do some magic with set_path to make it so
3811 # we only want a partial path.
3812 my $sp = '';
3813 my $final = join('/', @pc);
3814 while (@pc) {
3815 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3816 $sp .= '/' if length $sp;
3817 $sp .= shift @pc;
3818 }
3819 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3821 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3823 $reporter->finish_report($pool);
3824 $pool->clear;
3825 $editor->{git_commit_ok};
3826 }
3828 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3829 # svn_ra_reparent didn't work before 1.4)
3830 sub gs_do_switch {
3831 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3832 my $path = $gs->{path};
3833 my $pool = SVN::Pool->new;
3835 my $full_url = $self->{url};
3836 my $old_url = $full_url;
3837 $full_url .= '/' . escape_uri_only($path) if length $path;
3838 my ($ra, $reparented);
3839 if ($old_url ne $full_url) {
3840 if ($old_url !~ m#^svn(\+ssh)?://#) {
3841 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3842 $pool);
3843 $self->{url} = $full_url;
3844 $reparented = 1;
3845 } else {
3846 $_[0] = undef;
3847 $self = undef;
3848 $RA = undef;
3849 $ra = Git::SVN::Ra->new($full_url);
3850 $ra_invalid = 1;
3851 }
3852 }
3853 $ra ||= $self;
3854 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3855 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3856 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3857 $reporter->finish_report($pool);
3859 if ($reparented) {
3860 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3861 $self->{url} = $old_url;
3862 }
3864 $pool->clear;
3865 $editor->{git_commit_ok};
3866 }
3868 sub longest_common_path {
3869 my ($gsv, $globs) = @_;
3870 my %common;
3871 my $common_max = scalar @$gsv;
3873 foreach my $gs (@$gsv) {
3874 my @tmp = split m#/#, $gs->{path};
3875 my $p = '';
3876 foreach (@tmp) {
3877 $p .= length($p) ? "/$_" : $_;
3878 $common{$p} ||= 0;
3879 $common{$p}++;
3880 }
3881 }
3882 $globs ||= [];
3883 $common_max += scalar @$globs;
3884 foreach my $glob (@$globs) {
3885 my @tmp = split m#/#, $glob->{path}->{left};
3886 my $p = '';
3887 foreach (@tmp) {
3888 $p .= length($p) ? "/$_" : $_;
3889 $common{$p} ||= 0;
3890 $common{$p}++;
3891 }
3892 }
3894 my $longest_path = '';
3895 foreach (sort {length $b <=> length $a} keys %common) {
3896 if ($common{$_} == $common_max) {
3897 $longest_path = $_;
3898 last;
3899 }
3900 }
3901 $longest_path;
3902 }
3904 sub gs_fetch_loop_common {
3905 my ($self, $base, $head, $gsv, $globs) = @_;
3906 return if ($base > $head);
3907 my $inc = $_log_window_size;
3908 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3909 my $longest_path = longest_common_path($gsv, $globs);
3910 my $ra_url = $self->{url};
3911 while (1) {
3912 my %revs;
3913 my $err;
3914 my $err_handler = $SVN::Error::handler;
3915 $SVN::Error::handler = sub {
3916 ($err) = @_;
3917 skip_unknown_revs($err);
3918 };
3919 sub _cb {
3920 my ($paths, $r, $author, $date, $log) = @_;
3921 [ dup_changed_paths($paths),
3922 { author => $author, date => $date, log => $log } ];
3923 }
3924 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3925 sub { $revs{$_[1]} = _cb(@_) });
3926 if ($err && $max >= $head) {
3927 print STDERR "Path '$longest_path' ",
3928 "was probably deleted:\n",
3929 $err->expanded_message,
3930 "\nWill attempt to follow ",
3931 "revisions r$min .. r$max ",
3932 "committed before the deletion\n";
3933 my $hi = $max;
3934 while (--$hi >= $min) {
3935 my $ok;
3936 $self->get_log([$longest_path], $min, $hi,
3937 0, 1, 1, sub {
3938 $ok ||= $_[1];
3939 $revs{$_[1]} = _cb(@_) });
3940 if ($ok) {
3941 print STDERR "r$min .. r$ok OK\n";
3942 last;
3943 }
3944 }
3945 }
3946 $SVN::Error::handler = $err_handler;
3948 my %exists = map { $_->{path} => $_ } @$gsv;
3949 foreach my $r (sort {$a <=> $b} keys %revs) {
3950 my ($paths, $logged) = @{$revs{$r}};
3952 foreach my $gs ($self->match_globs(\%exists, $paths,
3953 $globs, $r)) {
3954 if ($gs->rev_map_max >= $r) {
3955 next;
3956 }
3957 next unless $gs->match_paths($paths, $r);
3958 $gs->{logged_rev_props} = $logged;
3959 if (my $last_commit = $gs->last_commit) {
3960 $gs->assert_index_clean($last_commit);
3961 }
3962 my $log_entry = $gs->do_fetch($paths, $r);
3963 if ($log_entry) {
3964 $gs->do_git_commit($log_entry);
3965 }
3966 $INDEX_FILES{$gs->{index}} = 1;
3967 }
3968 foreach my $g (@$globs) {
3969 my $k = "svn-remote.$g->{remote}." .
3970 "$g->{t}-maxRev";
3971 Git::SVN::tmp_config($k, $r);
3972 }
3973 if ($ra_invalid) {
3974 $_[0] = undef;
3975 $self = undef;
3976 $RA = undef;
3977 $self = Git::SVN::Ra->new($ra_url);
3978 $ra_invalid = undef;
3979 }
3980 }
3981 # pre-fill the .rev_db since it'll eventually get filled in
3982 # with '0' x40 if something new gets committed
3983 foreach my $gs (@$gsv) {
3984 next if $gs->rev_map_max >= $max;
3985 next if defined $gs->rev_map_get($max);
3986 $gs->rev_map_set($max, 0 x40);
3987 }
3988 foreach my $g (@$globs) {
3989 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3990 Git::SVN::tmp_config($k, $max);
3991 }
3992 last if $max >= $head;
3993 $min = $max + 1;
3994 $max += $inc;
3995 $max = $head if ($max > $head);
3996 }
3997 Git::SVN::gc();
3998 }
4000 sub match_globs {
4001 my ($self, $exists, $paths, $globs, $r) = @_;
4003 sub get_dir_check {
4004 my ($self, $exists, $g, $r) = @_;
4005 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
4006 return unless scalar @x == 3;
4007 my $dirents = $x[0];
4008 foreach my $de (keys %$dirents) {
4009 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4010 my $p = $g->{path}->full_path($de);
4011 next if $exists->{$p};
4012 next if (length $g->{path}->{right} &&
4013 ($self->check_path($p, $r) !=
4014 $SVN::Node::dir));
4015 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4016 $g->{ref}->full_path($de), 1);
4017 }
4018 }
4019 foreach my $g (@$globs) {
4020 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4021 if ($path->{action} =~ /^[AR]$/) {
4022 get_dir_check($self, $exists, $g, $r);
4023 }
4024 }
4025 foreach (keys %$paths) {
4026 if (/$g->{path}->{left_regex}/ &&
4027 !/$g->{path}->{regex}/) {
4028 next if $paths->{$_}->{action} !~ /^[AR]$/;
4029 get_dir_check($self, $exists, $g, $r);
4030 }
4031 next unless /$g->{path}->{regex}/;
4032 my $p = $1;
4033 my $pathname = $g->{path}->full_path($p);
4034 next if $exists->{$pathname};
4035 next if ($self->check_path($pathname, $r) !=
4036 $SVN::Node::dir);
4037 $exists->{$pathname} = Git::SVN->init(
4038 $self->{url}, $pathname, undef,
4039 $g->{ref}->full_path($p), 1);
4040 }
4041 my $c = '';
4042 foreach (split m#/#, $g->{path}->{left}) {
4043 $c .= "/$_";
4044 next unless ($paths->{$c} &&
4045 ($paths->{$c}->{action} =~ /^[AR]$/));
4046 get_dir_check($self, $exists, $g, $r);
4047 }
4048 }
4049 values %$exists;
4050 }
4052 sub minimize_url {
4053 my ($self) = @_;
4054 return $self->{url} if ($self->{url} eq $self->{repos_root});
4055 my $url = $self->{repos_root};
4056 my @components = split(m!/!, $self->{svn_path});
4057 my $c = '';
4058 do {
4059 $url .= "/$c" if length $c;
4060 eval { (ref $self)->new($url)->get_latest_revnum };
4061 } while ($@ && ($c = shift @components));
4062 $url;
4063 }
4065 sub can_do_switch {
4066 my $self = shift;
4067 unless (defined $can_do_switch) {
4068 my $pool = SVN::Pool->new;
4069 my $rep = eval {
4070 $self->do_switch(1, '', 0, $self->{url},
4071 SVN::Delta::Editor->new, $pool);
4072 };
4073 if ($@) {
4074 $can_do_switch = 0;
4075 } else {
4076 $rep->abort_report($pool);
4077 $can_do_switch = 1;
4078 }
4079 $pool->clear;
4080 }
4081 $can_do_switch;
4082 }
4084 sub skip_unknown_revs {
4085 my ($err) = @_;
4086 my $errno = $err->apr_err();
4087 # Maybe the branch we're tracking didn't
4088 # exist when the repo started, so it's
4089 # not an error if it doesn't, just continue
4090 #
4091 # Wonderfully consistent library, eh?
4092 # 160013 - svn:// and file://
4093 # 175002 - http(s)://
4094 # 175007 - http(s):// (this repo required authorization, too...)
4095 # More codes may be discovered later...
4096 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4097 my $err_key = $err->expanded_message;
4098 # revision numbers change every time, filter them out
4099 $err_key =~ s/\d+/\0/g;
4100 $err_key = "$errno\0$err_key";
4101 unless ($ignored_err{$err_key}) {
4102 warn "W: Ignoring error from SVN, path probably ",
4103 "does not exist: ($errno): ",
4104 $err->expanded_message,"\n";
4105 warn "W: Do not be alarmed at the above message ",
4106 "git-svn is just searching aggressively for ",
4107 "old history.\n",
4108 "This may take a while on large repositories\n";
4109 $ignored_err{$err_key} = 1;
4110 }
4111 return;
4112 }
4113 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4114 }
4116 # svn_log_changed_path_t objects passed to get_log are likely to be
4117 # overwritten even if only the refs are copied to an external variable,
4118 # so we should dup the structures in their entirety. Using an externally
4119 # passed pool (instead of our temporary and quickly cleared pool in
4120 # Git::SVN::Ra) does not help matters at all...
4121 sub dup_changed_paths {
4122 my ($paths) = @_;
4123 return undef unless $paths;
4124 my %ret;
4125 foreach my $p (keys %$paths) {
4126 my $i = $paths->{$p};
4127 my %s = map { $_ => $i->$_ }
4128 qw/copyfrom_path copyfrom_rev action/;
4129 $ret{$p} = \%s;
4130 }
4131 \%ret;
4132 }
4134 package Git::SVN::Log;
4135 use strict;
4136 use warnings;
4137 use POSIX qw/strftime/;
4138 use constant commit_log_separator => ('-' x 72) . "\n";
4139 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4140 %rusers $show_commit $incremental/;
4141 my $l_fmt;
4143 sub cmt_showable {
4144 my ($c) = @_;
4145 return 1 if defined $c->{r};
4147 # big commit message got truncated by the 16k pretty buffer in rev-list
4148 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4149 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4150 @{$c->{l}} = ();
4151 my @log = command(qw/cat-file commit/, $c->{c});
4153 # shift off the headers
4154 shift @log while ($log[0] ne '');
4155 shift @log;
4157 # TODO: make $c->{l} not have a trailing newline in the future
4158 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4160 (undef, $c->{r}, undef) = ::extract_metadata(
4161 (grep(/^git-svn-id: /, @log))[-1]);
4162 }
4163 return defined $c->{r};
4164 }
4166 sub log_use_color {
4167 return $color || Git->repository->get_colorbool('color.diff');
4168 }
4170 sub git_svn_log_cmd {
4171 my ($r_min, $r_max, @args) = @_;
4172 my $head = 'HEAD';
4173 my (@files, @log_opts);
4174 foreach my $x (@args) {
4175 if ($x eq '--' || @files) {
4176 push @files, $x;
4177 } else {
4178 if (::verify_ref("$x^0")) {
4179 $head = $x;
4180 } else {
4181 push @log_opts, $x;
4182 }
4183 }
4184 }
4186 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4187 $gs ||= Git::SVN->_new;
4188 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4189 $gs->refname);
4190 push @cmd, '-r' unless $non_recursive;
4191 push @cmd, qw/--raw --name-status/ if $verbose;
4192 push @cmd, '--color' if log_use_color();
4193 push @cmd, @log_opts;
4194 if (defined $r_max && $r_max == $r_min) {
4195 push @cmd, '--max-count=1';
4196 if (my $c = $gs->rev_map_get($r_max)) {
4197 push @cmd, $c;
4198 }
4199 } elsif (defined $r_max) {
4200 if ($r_max < $r_min) {
4201 ($r_min, $r_max) = ($r_max, $r_min);
4202 }
4203 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4204 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4205 # If there are no commits in the range, both $c_max and $c_min
4206 # will be undefined. If there is at least 1 commit in the
4207 # range, both will be defined.
4208 return () if !defined $c_min || !defined $c_max;
4209 if ($c_min eq $c_max) {
4210 push @cmd, '--max-count=1', $c_min;
4211 } else {
4212 push @cmd, '--boundary', "$c_min..$c_max";
4213 }
4214 }
4215 return (@cmd, @files);
4216 }
4218 # adapted from pager.c
4219 sub config_pager {
4220 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4221 if (!defined $pager) {
4222 $pager = 'less';
4223 } elsif (length $pager == 0 || $pager eq 'cat') {
4224 $pager = undef;
4225 }
4226 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4227 }
4229 sub run_pager {
4230 return unless -t *STDOUT && defined $pager;
4231 pipe my $rfd, my $wfd or return;
4232 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4233 if (!$pid) {
4234 open STDOUT, '>&', $wfd or
4235 ::fatal "Can't redirect to stdout: $!";
4236 return;
4237 }
4238 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4239 $ENV{LESS} ||= 'FRSX';
4240 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4241 }
4243 sub format_svn_date {
4244 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4245 }
4247 sub parse_git_date {
4248 my ($t, $tz) = @_;
4249 # Date::Parse isn't in the standard Perl distro :(
4250 if ($tz =~ s/^\+//) {
4251 $t += tz_to_s_offset($tz);
4252 } elsif ($tz =~ s/^\-//) {
4253 $t -= tz_to_s_offset($tz);
4254 }
4255 return $t;
4256 }
4258 sub set_local_timezone {
4259 if (defined $TZ) {
4260 $ENV{TZ} = $TZ;
4261 } else {
4262 delete $ENV{TZ};
4263 }
4264 }
4266 sub tz_to_s_offset {
4267 my ($tz) = @_;
4268 $tz =~ s/(\d\d)$//;
4269 return ($1 * 60) + ($tz * 3600);
4270 }
4272 sub get_author_info {
4273 my ($dest, $author, $t, $tz) = @_;
4274 $author =~ s/(?:^\s*|\s*$)//g;
4275 $dest->{a_raw} = $author;
4276 my $au;
4277 if ($::_authors) {
4278 $au = $rusers{$author} || undef;
4279 }
4280 if (!$au) {
4281 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4282 }
4283 $dest->{t} = $t;
4284 $dest->{tz} = $tz;
4285 $dest->{a} = $au;
4286 $dest->{t_utc} = parse_git_date($t, $tz);
4287 }
4289 sub process_commit {
4290 my ($c, $r_min, $r_max, $defer) = @_;
4291 if (defined $r_min && defined $r_max) {
4292 if ($r_min == $c->{r} && $r_min == $r_max) {
4293 show_commit($c);
4294 return 0;
4295 }
4296 return 1 if $r_min == $r_max;
4297 if ($r_min < $r_max) {
4298 # we need to reverse the print order
4299 return 0 if (defined $limit && --$limit < 0);
4300 push @$defer, $c;
4301 return 1;
4302 }
4303 if ($r_min != $r_max) {
4304 return 1 if ($r_min < $c->{r});
4305 return 1 if ($r_max > $c->{r});
4306 }
4307 }
4308 return 0 if (defined $limit && --$limit < 0);
4309 show_commit($c);
4310 return 1;
4311 }
4313 sub show_commit {
4314 my $c = shift;
4315 if ($oneline) {
4316 my $x = "\n";
4317 if (my $l = $c->{l}) {
4318 while ($l->[0] =~ /^\s*$/) { shift @$l }
4319 $x = $l->[0];
4320 }
4321 $l_fmt ||= 'A' . length($c->{r});
4322 print 'r',pack($l_fmt, $c->{r}),' | ';
4323 print "$c->{c} | " if $show_commit;
4324 print $x;
4325 } else {
4326 show_commit_normal($c);
4327 }
4328 }
4330 sub show_commit_changed_paths {
4331 my ($c) = @_;
4332 return unless $c->{changed};
4333 print "Changed paths:\n", @{$c->{changed}};
4334 }
4336 sub show_commit_normal {
4337 my ($c) = @_;
4338 print commit_log_separator, "r$c->{r} | ";
4339 print "$c->{c} | " if $show_commit;
4340 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4341 my $nr_line = 0;
4343 if (my $l = $c->{l}) {
4344 while ($l->[$#$l] eq "\n" && $#$l > 0
4345 && $l->[($#$l - 1)] eq "\n") {
4346 pop @$l;
4347 }
4348 $nr_line = scalar @$l;
4349 if (!$nr_line) {
4350 print "1 line\n\n\n";
4351 } else {
4352 if ($nr_line == 1) {
4353 $nr_line = '1 line';
4354 } else {
4355 $nr_line .= ' lines';
4356 }
4357 print $nr_line, "\n";
4358 show_commit_changed_paths($c);
4359 print "\n";
4360 print $_ foreach @$l;
4361 }
4362 } else {
4363 print "1 line\n";
4364 show_commit_changed_paths($c);
4365 print "\n";
4367 }
4368 foreach my $x (qw/raw stat diff/) {
4369 if ($c->{$x}) {
4370 print "\n";
4371 print $_ foreach @{$c->{$x}}
4372 }
4373 }
4374 }
4376 sub cmd_show_log {
4377 my (@args) = @_;
4378 my ($r_min, $r_max);
4379 my $r_last = -1; # prevent dupes
4380 set_local_timezone();
4381 if (defined $::_revision) {
4382 if ($::_revision =~ /^(\d+):(\d+)$/) {
4383 ($r_min, $r_max) = ($1, $2);
4384 } elsif ($::_revision =~ /^\d+$/) {
4385 $r_min = $r_max = $::_revision;
4386 } else {
4387 ::fatal "-r$::_revision is not supported, use ",
4388 "standard 'git log' arguments instead";
4389 }
4390 }
4392 config_pager();
4393 @args = git_svn_log_cmd($r_min, $r_max, @args);
4394 if (!@args) {
4395 print commit_log_separator unless $incremental || $oneline;
4396 return;
4397 }
4398 my $log = command_output_pipe(@args);
4399 run_pager();
4400 my (@k, $c, $d, $stat);
4401 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4402 while (<$log>) {
4403 if (/^${esc_color}commit -?($::sha1_short)/o) {
4404 my $cmt = $1;
4405 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4406 $r_last = $c->{r};
4407 process_commit($c, $r_min, $r_max, \@k) or
4408 goto out;
4409 }
4410 $d = undef;
4411 $c = { c => $cmt };
4412 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4413 get_author_info($c, $1, $2, $3);
4414 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4415 # ignore
4416 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4417 push @{$c->{raw}}, $_;
4418 } elsif (/^${esc_color}[ACRMDT]\t/) {
4419 # we could add $SVN->{svn_path} here, but that requires
4420 # remote access at the moment (repo_path_split)...
4421 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4422 push @{$c->{changed}}, $_;
4423 } elsif (/^${esc_color}diff /o) {
4424 $d = 1;
4425 push @{$c->{diff}}, $_;
4426 } elsif ($d) {
4427 push @{$c->{diff}}, $_;
4428 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4429 $esc_color*[\+\-]*$esc_color$/x) {
4430 $stat = 1;
4431 push @{$c->{stat}}, $_;
4432 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4433 push @{$c->{stat}}, $_;
4434 $stat = undef;
4435 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4436 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4437 } elsif (s/^${esc_color} //o) {
4438 push @{$c->{l}}, $_;
4439 }
4440 }
4441 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4442 $r_last = $c->{r};
4443 process_commit($c, $r_min, $r_max, \@k);
4444 }
4445 if (@k) {
4446 ($r_min, $r_max) = ($r_max, $r_min);
4447 process_commit($_, $r_min, $r_max) foreach reverse @k;
4448 }
4449 out:
4450 close $log;
4451 print commit_log_separator unless $incremental || $oneline;
4452 }
4454 sub cmd_blame {
4455 my $path = shift;
4457 config_pager();
4458 run_pager();
4460 my ($fh, $ctx) = command_output_pipe('blame', @_, $path);
4461 while (my $line = <$fh>) {
4462 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
4463 my (undef, $rev, undef) = ::cmt_metadata($1);
4464 $rev = sprintf('%-10s', $rev);
4465 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
4466 }
4467 print $line;
4468 }
4469 command_close_pipe($fh, $ctx);
4470 }
4472 package Git::SVN::Migration;
4473 # these version numbers do NOT correspond to actual version numbers
4474 # of git nor git-svn. They are just relative.
4475 #
4476 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4477 #
4478 # v1 layout: .git/$id/info/url, refs/remotes/$id
4479 #
4480 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4481 #
4482 # v3 layout: .git/svn/$id, refs/remotes/$id
4483 # - info/url may remain for backwards compatibility
4484 # - this is what we migrate up to this layout automatically,
4485 # - this will be used by git svn init on single branches
4486 # v3.1 layout (auto migrated):
4487 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4488 # for backwards compatibility
4489 #
4490 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4491 # - this is only created for newly multi-init-ed
4492 # repositories. Similar in spirit to the
4493 # --use-separate-remotes option in git-clone (now default)
4494 # - we do not automatically migrate to this (following
4495 # the example set by core git)
4496 #
4497 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4498 # - newer, more-efficient format that uses 24-bytes per record
4499 # with no filler space.
4500 # - use xxd -c24 < .rev_map.$UUID to view and debug
4501 # - This is a one-way migration, repositories updated to the
4502 # new format will not be able to use old git-svn without
4503 # rebuilding the .rev_db. Rebuilding the rev_db is not
4504 # possible if noMetadata or useSvmProps are set; but should
4505 # be no problem for users that use the (sensible) defaults.
4506 use strict;
4507 use warnings;
4508 use Carp qw/croak/;
4509 use File::Path qw/mkpath/;
4510 use File::Basename qw/dirname basename/;
4511 use vars qw/$_minimize/;
4513 sub migrate_from_v0 {
4514 my $git_dir = $ENV{GIT_DIR};
4515 return undef unless -d $git_dir;
4516 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4517 my $migrated = 0;
4518 while (<$fh>) {
4519 chomp;
4520 my ($id, $orig_ref) = ($_, $_);
4521 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4522 next unless -f "$git_dir/$id/info/url";
4523 my $new_ref = "refs/remotes/$id";
4524 if (::verify_ref("$new_ref^0")) {
4525 print STDERR "W: $orig_ref is probably an old ",
4526 "branch used by an ancient version of ",
4527 "git-svn.\n",
4528 "However, $new_ref also exists.\n",
4529 "We will not be able ",
4530 "to use this branch until this ",
4531 "ambiguity is resolved.\n";
4532 next;
4533 }
4534 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4535 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4536 command_noisy('update-ref', $new_ref, $orig_ref);
4537 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4538 $migrated++;
4539 }
4540 command_close_pipe($fh, $ctx);
4541 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4542 $migrated;
4543 }
4545 sub migrate_from_v1 {
4546 my $git_dir = $ENV{GIT_DIR};
4547 my $migrated = 0;
4548 return $migrated unless -d $git_dir;
4549 my $svn_dir = "$git_dir/svn";
4551 # just in case somebody used 'svn' as their $id at some point...
4552 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4554 print STDERR "Migrating from a git-svn v1 layout...\n";
4555 mkpath([$svn_dir]);
4556 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4557 "$svn_dir\n\t(required for this version ",
4558 "($::VERSION) of git-svn) does not. exist\n";
4559 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4560 while (<$fh>) {
4561 my $x = $_;
4562 next unless $x =~ s#^refs/remotes/##;
4563 chomp $x;
4564 next unless -f "$git_dir/$x/info/url";
4565 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4566 next unless $u;
4567 my $dn = dirname("$git_dir/svn/$x");
4568 mkpath([$dn]) unless -d $dn;
4569 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4570 mkpath(["$git_dir/svn/svn"]);
4571 print STDERR " - $git_dir/$x/info => ",
4572 "$git_dir/svn/$x/info\n";
4573 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4574 croak "$!: $x";
4575 # don't worry too much about these, they probably
4576 # don't exist with repos this old (save for index,
4577 # and we can easily regenerate that)
4578 foreach my $f (qw/unhandled.log index .rev_db/) {
4579 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4580 }
4581 } else {
4582 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4583 rename "$git_dir/$x", "$git_dir/svn/$x" or
4584 croak "$!: $x";
4585 }
4586 $migrated++;
4587 }
4588 command_close_pipe($fh, $ctx);
4589 print STDERR "Done migrating from a git-svn v1 layout\n";
4590 $migrated;
4591 }
4593 sub read_old_urls {
4594 my ($l_map, $pfx, $path) = @_;
4595 my @dir;
4596 foreach (<$path/*>) {
4597 if (-r "$_/info/url") {
4598 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4599 my $ref_id = $pfx . basename $_;
4600 my $url = ::file_to_s("$_/info/url");
4601 $l_map->{$ref_id} = $url;
4602 } elsif (-d $_) {
4603 push @dir, $_;
4604 }
4605 }
4606 foreach (@dir) {
4607 my $x = $_;
4608 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4609 read_old_urls($l_map, $x, $_);
4610 }
4611 }
4613 sub migrate_from_v2 {
4614 my @cfg = command(qw/config -l/);
4615 return if grep /^svn-remote\..+\.url=/, @cfg;
4616 my %l_map;
4617 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4618 my $migrated = 0;
4620 foreach my $ref_id (sort keys %l_map) {
4621 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4622 if ($@) {
4623 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4624 }
4625 $migrated++;
4626 }
4627 $migrated;
4628 }
4630 sub minimize_connections {
4631 my $r = Git::SVN::read_all_remotes();
4632 my $new_urls = {};
4633 my $root_repos = {};
4634 foreach my $repo_id (keys %$r) {
4635 my $url = $r->{$repo_id}->{url} or next;
4636 my $fetch = $r->{$repo_id}->{fetch} or next;
4637 my $ra = Git::SVN::Ra->new($url);
4639 # skip existing cases where we already connect to the root
4640 if (($ra->{url} eq $ra->{repos_root}) ||
4641 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4642 $repo_id)) {
4643 $root_repos->{$ra->{url}} = $repo_id;
4644 next;
4645 }
4647 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4648 my $root_path = $ra->{url};
4649 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4650 foreach my $path (keys %$fetch) {
4651 my $ref_id = $fetch->{$path};
4652 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4654 # make sure we can read when connecting to
4655 # a higher level of a repository
4656 my ($last_rev, undef) = $gs->last_rev_commit;
4657 if (!defined $last_rev) {
4658 $last_rev = eval {
4659 $root_ra->get_latest_revnum;
4660 };
4661 next if $@;
4662 }
4663 my $new = $root_path;
4664 $new .= length $path ? "/$path" : '';
4665 eval {
4666 $root_ra->get_log([$new], $last_rev, $last_rev,
4667 0, 0, 1, sub { });
4668 };
4669 next if $@;
4670 $new_urls->{$ra->{repos_root}}->{$new} =
4671 { ref_id => $ref_id,
4672 old_repo_id => $repo_id,
4673 old_path => $path };
4674 }
4675 }
4677 my @emptied;
4678 foreach my $url (keys %$new_urls) {
4679 # see if we can re-use an existing [svn-remote "repo_id"]
4680 # instead of creating a(n ugly) new section:
4681 my $repo_id = $root_repos->{$url} ||
4682 Git::SVN::sanitize_remote_name($url);
4684 my $fetch = $new_urls->{$url};
4685 foreach my $path (keys %$fetch) {
4686 my $x = $fetch->{$path};
4687 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4688 my $pfx = "svn-remote.$x->{old_repo_id}";
4690 my $old_fetch = quotemeta("$x->{old_path}:".
4691 "refs/remotes/$x->{ref_id}");
4692 command_noisy(qw/config --unset/,
4693 "$pfx.fetch", '^'. $old_fetch . '$');
4694 delete $r->{$x->{old_repo_id}}->
4695 {fetch}->{$x->{old_path}};
4696 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4697 command_noisy(qw/config --unset/,
4698 "$pfx.url");
4699 push @emptied, $x->{old_repo_id}
4700 }
4701 }
4702 }
4703 if (@emptied) {
4704 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4705 "$ENV{GIT_DIR}/config";
4706 print STDERR <<EOF;
4707 The following [svn-remote] sections in your config file ($file) are empty
4708 and can be safely removed:
4709 EOF
4710 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4711 }
4712 }
4714 sub migration_check {
4715 migrate_from_v0();
4716 migrate_from_v1();
4717 migrate_from_v2();
4718 minimize_connections() if $_minimize;
4719 }
4721 package Git::IndexInfo;
4722 use strict;
4723 use warnings;
4724 use Git qw/command_input_pipe command_close_pipe/;
4726 sub new {
4727 my ($class) = @_;
4728 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4729 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4730 }
4732 sub remove {
4733 my ($self, $path) = @_;
4734 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4735 return ++$self->{nr};
4736 }
4737 undef;
4738 }
4740 sub update {
4741 my ($self, $mode, $hash, $path) = @_;
4742 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4743 return ++$self->{nr};
4744 }
4745 undef;
4746 }
4748 sub DESTROY {
4749 my ($self) = @_;
4750 command_close_pipe($self->{gui}, $self->{ctx});
4751 }
4753 package Git::SVN::GlobSpec;
4754 use strict;
4755 use warnings;
4757 sub new {
4758 my ($class, $glob) = @_;
4759 my $re = $glob;
4760 $re =~ s!/+$!!g; # no need for trailing slashes
4761 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4762 my ($left, $right) = ($1, $2);
4763 if ($nr > 1) {
4764 die "Only one '*' wildcard expansion ",
4765 "is supported (got $nr): '$glob'\n";
4766 } elsif ($nr == 0) {
4767 die "One '*' is needed for glob: '$glob'\n";
4768 }
4769 $re = quotemeta($left) . $re . quotemeta($right);
4770 if (length $left && !($left =~ s!/+$!!g)) {
4771 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4772 }
4773 if (length $right && !($right =~ s!^/+!!g)) {
4774 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4775 }
4776 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4777 bless { left => $left, right => $right, left_regex => $left_re,
4778 regex => qr/$re/, glob => $glob }, $class;
4779 }
4781 sub full_path {
4782 my ($self, $path) = @_;
4783 return (length $self->{left} ? "$self->{left}/" : '') .
4784 $path . (length $self->{right} ? "/$self->{right}" : '');
4785 }
4787 __END__
4789 Data structures:
4792 $remotes = { # returned by read_all_remotes()
4793 'svn' => {
4794 # svn-remote.svn.url=https://svn.musicpd.org
4795 url => 'https://svn.musicpd.org',
4796 # svn-remote.svn.fetch=mpd/trunk:trunk
4797 fetch => {
4798 'mpd/trunk' => 'trunk',
4799 },
4800 # svn-remote.svn.tags=mpd/tags/*:tags/*
4801 tags => {
4802 path => {
4803 left => 'mpd/tags',
4804 right => '',
4805 regex => qr!mpd/tags/([^/]+)$!,
4806 glob => 'tags/*',
4807 },
4808 ref => {
4809 left => 'tags',
4810 right => '',
4811 regex => qr!tags/([^/]+)$!,
4812 glob => 'tags/*',
4813 },
4814 }
4815 }
4816 };
4818 $log_entry hashref as returned by libsvn_log_entry()
4819 {
4820 log => 'whitespace-formatted log entry
4821 ', # trailing newline is preserved
4822 revision => '8', # integer
4823 date => '2004-02-24T17:01:44.108345Z', # commit date
4824 author => 'committer name'
4825 };
4828 # this is generated by generate_diff();
4829 @mods = array of diff-index line hashes, each element represents one line
4830 of diff-index output
4832 diff-index line ($m hash)
4833 {
4834 mode_a => first column of diff-index output, no leading ':',
4835 mode_b => second column of diff-index output,
4836 sha1_b => sha1sum of the final blob,
4837 chg => change type [MCRADT],
4838 file_a => original file name of a file (iff chg is 'C' or 'R')
4839 file_b => new/current file name of a file (any chg)
4840 }
4841 ;
4843 # retval of read_url_paths{,_all}();
4844 $l_map = {
4845 # repository root url
4846 'https://svn.musicpd.org' => {
4847 # repository path # GIT_SVN_ID
4848 'mpd/trunk' => 'trunk',
4849 'mpd/tags/0.11.5' => 'tags/0.11.5',
4850 },
4851 }
4853 Notes:
4854 I don't trust the each() function on unless I created %hash myself
4855 because the internal iterator may not have started at base.