![[tokkee]](http://tokkee.org/images/avatar.png){kind=avatar}
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $SVN_URL
8 $GIT_SVN_INDEX $GIT_SVN
9 $GIT_DIR $GIT_SVN_DIR $REVDB
10 $_follow_parent $sha1 $sha1_short $_revision
11 $_cp_remote $_upgrade $_rmdir $_q $_cp_similarity
12 $_find_copies_harder $_l $_authors %users/;
13 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
14 $VERSION = '@@GIT_VERSION@@';
16 $ENV{GIT_DIR} ||= '.git';
17 $Git::SVN::default_repo_id = 'git-svn';
18 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
20 my $LC_ALL = $ENV{LC_ALL};
21 $Git::SVN::Log::TZ = $ENV{TZ};
22 # make sure the svn binary gives consistent output between locales and TZs:
23 $ENV{TZ} = 'UTC';
24 $ENV{LC_ALL} = 'C';
25 $| = 1; # unbuffer STDOUT
27 sub fatal (@) { print STDERR @_; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use IO::File qw//;
39 use File::Basename qw/dirname basename/;
40 use File::Path qw/mkpath/;
41 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
42 use IPC::Open3;
43 use Git;
45 BEGIN {
46 my $s;
47 foreach (qw/command command_oneline command_noisy command_output_pipe
48 command_input_pipe command_close_pipe/) {
49 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
50 "*Git::SVN::Migration::$_ = ".
51 "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
52 }
53 eval $s;
54 }
56 my ($SVN);
58 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
59 $sha1 = qr/[a-f\d]{40}/;
60 $sha1_short = qr/[a-f\d]{4,40}/;
61 my ($_stdin, $_help, $_edit,
62 $_repack, $_repack_nr, $_repack_flags,
63 $_message, $_file, $_no_metadata,
64 $_template, $_shared,
65 $_version, $_upgrade,
66 $_merge, $_strategy, $_dry_run,
67 $_prefix);
69 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
70 'config-dir=s' => \$Git::SVN::Ra::config_dir,
71 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
72 my %fc_opts = ( 'follow-parent|follow' => \$_follow_parent,
73 'authors-file|A=s' => \$_authors,
74 'repack:i' => \$_repack,
75 'no-metadata' => \$_no_metadata,
76 'quiet|q' => \$_q,
77 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
78 %remote_opts );
80 my ($_trunk, $_tags, $_branches);
81 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
82 'tags|t=s' => \$_tags,
83 'branches|b=s' => \$_branches );
84 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
85 my %cmt_opts = ( 'edit|e' => \$_edit,
86 'rmdir' => \$_rmdir,
87 'find-copies-harder' => \$_find_copies_harder,
88 'l=i' => \$_l,
89 'copy-similarity|C=i'=> \$_cp_similarity
90 );
92 my %cmd = (
93 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
94 { 'revision|r=s' => \$_revision, %fc_opts } ],
95 init => [ \&cmd_init, "Initialize a repo for tracking" .
96 " (requires URL argument)",
97 \%init_opts ],
98 dcommit => [ \&cmd_dcommit,
99 'Commit several diffs to merge with upstream',
100 { 'merge|m|M' => \$_merge,
101 'strategy|s=s' => \$_strategy,
102 'dry-run|n' => \$_dry_run,
103 %cmt_opts, %fc_opts } ],
104 'set-tree' => [ \&cmd_set_tree,
105 "Set an SVN repository to a git tree-ish",
106 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
107 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
108 { 'revision|r=i' => \$_revision } ],
109 rebuild => [ \&cmd_rebuild, "Rebuild git-svn metadata (after git clone)",
110 { 'copy-remote|remote=s' => \$_cp_remote,
111 'upgrade' => \$_upgrade } ],
112 'multi-init' => [ \&cmd_multi_init,
113 'Initialize multiple trees (like git-svnimport)',
114 { %multi_opts, %init_opts, %remote_opts,
115 'revision|r=i' => \$_revision,
116 'prefix=s' => \$_prefix,
117 } ],
118 'multi-fetch' => [ \&cmd_multi_fetch,
119 'Fetch multiple trees (like git-svnimport)',
120 \%fc_opts ],
121 'migrate' => [ sub { },
122 # no-op, we automatically run this anyways,
123 'Migrate configuration/metadata/layout from
124 previous versions of git-svn',
125 \%remote_opts ],
126 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
127 { 'limit=i' => \$Git::SVN::Log::limit,
128 'revision|r=s' => \$_revision,
129 'verbose|v' => \$Git::SVN::Log::verbose,
130 'incremental' => \$Git::SVN::Log::incremental,
131 'oneline' => \$Git::SVN::Log::oneline,
132 'show-commit' => \$Git::SVN::Log::show_commit,
133 'non-recursive' => \$Git::SVN::Log::non_recursive,
134 'authors-file|A=s' => \$_authors,
135 'color' => \$Git::SVN::Log::color,
136 'pager=s' => \$Git::SVN::Log::pager,
137 } ],
138 'commit-diff' => [ \&cmd_commit_diff,
139 'Commit a diff between two trees',
140 { 'message|m=s' => \$_message,
141 'file|F=s' => \$_file,
142 'revision|r=s' => \$_revision,
143 %cmt_opts } ],
144 );
146 my $cmd;
147 for (my $i = 0; $i < @ARGV; $i++) {
148 if (defined $cmd{$ARGV[$i]}) {
149 $cmd = $ARGV[$i];
150 splice @ARGV, $i, 1;
151 last;
152 }
153 };
155 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
157 read_repo_config(\%opts);
158 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
159 'version|V' => \$_version,
160 'minimize-connections' =>
161 \$Git::SVN::Migration::_minimize,
162 'id|i=s' => \$Git::SVN::default_ref_id);
163 exit 1 if (!$rv && $cmd ne 'log');
165 usage(0) if $_help;
166 version() if $_version;
167 usage(1) unless defined $cmd;
168 load_authors() if $_authors;
169 unless ($cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/) {
170 Git::SVN::Migration::migration_check();
171 }
172 eval {
173 Git::SVN::verify_remotes_sanity();
174 $cmd{$cmd}->[0]->(@ARGV);
175 };
176 fatal $@ if $@;
177 exit 0;
179 ####################### primary functions ######################
180 sub usage {
181 my $exit = shift || 0;
182 my $fd = $exit ? \*STDERR : \*STDOUT;
183 print $fd <<"";
184 git-svn - bidirectional operations between a single Subversion tree and git
185 Usage: $0 <command> [options] [arguments]\n
187 print $fd "Available commands:\n" unless $cmd;
189 foreach (sort keys %cmd) {
190 next if $cmd && $cmd ne $_;
191 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
192 foreach (keys %{$cmd{$_}->[2]}) {
193 # prints out arguments as they should be passed:
194 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
195 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
196 "--$_" : "-$_" }
197 split /\|/,$_)," $x\n";
198 }
199 }
200 print $fd <<"";
201 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
202 arbitrary identifier if you're tracking multiple SVN branches/repositories in
203 one git repository and want to keep them separate. See git-svn(1) for more
204 information.
206 exit $exit;
207 }
209 sub version {
210 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
211 exit 0;
212 }
214 sub cmd_rebuild {
215 my $url = shift;
216 my $gs = $url ? Git::SVN->init($url)
217 : eval { Git::SVN->new };
218 $gs ||= Git::SVN->_new;
219 if (!verify_ref($gs->refname.'^0')) {
220 $gs->copy_remote_ref;
221 }
223 my ($rev_list, $ctx) = command_output_pipe("rev-list", $gs->refname);
224 my $latest;
225 my $svn_uuid;
226 while (<$rev_list>) {
227 chomp;
228 my $c = $_;
229 fatal "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
230 my ($url, $rev, $uuid) = cmt_metadata($c);
232 # ignore merges (from set-tree)
233 next if (!defined $rev || !$uuid);
235 # if we merged or otherwise started elsewhere, this is
236 # how we break out of it
237 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
238 ($gs->{url} && $url && ($url ne $gs->{url}))) {
239 next;
240 }
242 unless (defined $latest) {
243 if (!$gs->{url} && !$url) {
244 fatal "SVN repository location required\n";
245 }
246 $gs = Git::SVN->init($url);
247 $latest = $rev;
248 }
249 $gs->rev_db_set($rev, $c);
250 print "r$rev = $c\n";
251 }
252 command_close_pipe($rev_list, $ctx);
253 }
255 sub do_git_init_db {
256 unless (-d $ENV{GIT_DIR}) {
257 my @init_db = ('init');
258 push @init_db, "--template=$_template" if defined $_template;
259 push @init_db, "--shared" if defined $_shared;
260 command_noisy(@init_db);
261 }
262 }
264 sub cmd_init {
265 my $url = shift or die "SVN repository location required " .
266 "as a command-line argument\n";
267 if (my $repo_path = shift) {
268 unless (-d $repo_path) {
269 mkpath([$repo_path]);
270 }
271 chdir $repo_path or croak $!;
272 $ENV{GIT_DIR} = $repo_path . "/.git";
273 }
274 do_git_init_db();
276 Git::SVN->init($url);
277 }
279 sub cmd_fetch {
280 if (@_) {
281 die "Additional fetch arguments are no longer supported.\n",
282 "Use --follow-parent if you have moved/copied directories
283 instead.\n";
284 }
285 my $gs = Git::SVN->new;
286 $gs->fetch(parse_revision_argument());
287 if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
288 command_noisy(qw(update-ref refs/heads/master),
289 $gs->{last_commit});
290 }
291 }
293 sub cmd_set_tree {
294 my (@commits) = @_;
295 if ($_stdin || !@commits) {
296 print "Reading from stdin...\n";
297 @commits = ();
298 while (<STDIN>) {
299 if (/\b($sha1_short)\b/o) {
300 unshift @commits, $1;
301 }
302 }
303 }
304 my @revs;
305 foreach my $c (@commits) {
306 my @tmp = command('rev-parse',$c);
307 if (scalar @tmp == 1) {
308 push @revs, $tmp[0];
309 } elsif (scalar @tmp > 1) {
310 push @revs, reverse(command('rev-list',@tmp));
311 } else {
312 fatal "Failed to rev-parse $c\n";
313 }
314 }
315 my $gs = Git::SVN->new;
316 my ($r_last, $cmt_last) = $gs->last_rev_commit;
317 $gs->fetch;
318 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
319 fatal "There are new revisions that were fetched ",
320 "and need to be merged (or acknowledged) ",
321 "before committing.\nlast rev: $r_last\n",
322 " current: $gs->{last_rev}\n";
323 }
324 $gs->set_tree($_) foreach @revs;
325 print "Done committing ",scalar @revs," revisions to SVN\n";
326 }
328 sub cmd_dcommit {
329 my $head = shift;
330 my $gs = Git::SVN->new;
331 $head ||= 'HEAD';
332 my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
333 my $last_rev;
334 foreach my $d (reverse @refs) {
335 if (!verify_ref("$d~1")) {
336 fatal "Commit $d\n",
337 "has no parent commit, and therefore ",
338 "nothing to diff against.\n",
339 "You should be working from a repository ",
340 "originally created by git-svn\n";
341 }
342 unless (defined $last_rev) {
343 (undef, $last_rev, undef) = cmt_metadata("$d~1");
344 unless (defined $last_rev) {
345 fatal "Unable to extract revision information ",
346 "from commit $d~1\n";
347 }
348 }
349 if ($_dry_run) {
350 print "diff-tree $d~1 $d\n";
351 } else {
352 my %ed_opts = ( r => $last_rev,
353 log => get_commit_entry($d)->{log},
354 ra => $gs->ra,
355 tree_a => "$d~1",
356 tree_b => $d,
357 editor_cb => sub {
358 print "Committed r$_[0]\n";
359 $last_rev = $_[0]; },
360 svn_path => $gs->{path} );
361 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
362 print "No changes\n$d~1 == $d\n";
363 }
364 }
365 }
366 return if $_dry_run;
367 $gs->fetch;
368 # we always want to rebase against the current HEAD, not any
369 # head that was passed to us
370 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
371 my @finish;
372 if (@diff) {
373 @finish = qw/rebase/;
374 push @finish, qw/--merge/ if $_merge;
375 push @finish, "--strategy=$_strategy" if $_strategy;
376 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
377 "using @finish:\n", "@diff";
378 } else {
379 print "No changes between current HEAD and ",
380 $gs->refname, "\nResetting to the latest ",
381 $gs->refname, "\n";
382 @finish = qw/reset --mixed/;
383 }
384 command_noisy(@finish, $gs->refname);
385 }
387 sub cmd_show_ignore {
388 my $gs = Git::SVN->new;
389 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
390 $gs->traverse_ignore(\*STDOUT, '', $r);
391 }
393 sub cmd_multi_init {
394 my $url = shift;
395 unless (defined $_trunk || defined $_branches || defined $_tags) {
396 usage(1);
397 }
398 do_git_init_db();
399 $_prefix = '' unless defined $_prefix;
400 $url =~ s#/+$## if defined $url;
401 if (defined $_trunk) {
402 my $trunk_ref = $_prefix . 'trunk';
403 # try both old-style and new-style lookups:
404 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
405 unless ($gs_trunk) {
406 my ($trunk_url, $trunk_path) =
407 complete_svn_url($url, $_trunk);
408 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
409 undef, $trunk_ref);
410 }
411 }
412 return unless defined $_branches || defined $_tags;
413 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
414 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
415 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
416 }
418 sub cmd_multi_fetch {
419 my $remotes = Git::SVN::read_all_remotes();
420 foreach my $repo_id (sort keys %$remotes) {
421 my $url = $remotes->{$repo_id}->{url} or next;
422 my $fetch = $remotes->{$repo_id}->{fetch} or next;
423 Git::SVN::fetch_all($repo_id, $url, $fetch);
424 }
425 }
427 # this command is special because it requires no metadata
428 sub cmd_commit_diff {
429 my ($ta, $tb, $url) = @_;
430 my $usage = "Usage: $0 commit-diff -r<revision> ".
431 "<tree-ish> <tree-ish> [<URL>]\n";
432 fatal($usage) if (!defined $ta || !defined $tb);
433 my $svn_path;
434 if (!defined $url) {
435 my $gs = eval { Git::SVN->new };
436 if (!$gs) {
437 fatal("Needed URL or usable git-svn --id in ",
438 "the command-line\n", $usage);
439 }
440 $url = $gs->{url};
441 $svn_path = $gs->{path};
442 }
443 unless (defined $_revision) {
444 fatal("-r|--revision is a required argument\n", $usage);
445 }
446 if (defined $_message && defined $_file) {
447 fatal("Both --message/-m and --file/-F specified ",
448 "for the commit message.\n",
449 "I have no idea what you mean\n");
450 }
451 if (defined $_file) {
452 $_message = file_to_s($_file);
453 } else {
454 $_message ||= get_commit_entry($tb)->{log};
455 }
456 my $ra ||= Git::SVN::Ra->new($url);
457 $svn_path ||= $ra->{svn_path};
458 my $r = $_revision;
459 if ($r eq 'HEAD') {
460 $r = $ra->get_latest_revnum;
461 } elsif ($r !~ /^\d+$/) {
462 die "revision argument: $r not understood by git-svn\n";
463 }
464 my %ed_opts = ( r => $r,
465 log => $_message,
466 ra => $ra,
467 tree_a => $ta,
468 tree_b => $tb,
469 editor_cb => sub { print "Committed r$_[0]\n" },
470 svn_path => $svn_path );
471 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
472 print "No changes\n$ta == $tb\n";
473 }
474 }
476 ########################### utility functions #########################
478 sub parse_revision_argument {
479 if (!defined $_revision || $_revision eq 'BASE:HEAD') {
480 return (undef, undef);
481 }
482 return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
483 return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
484 return (undef, $1) if ($_revision =~ /^BASE:(\d+)$/);
485 return ($1, undef) if ($_revision =~ /^(\d+):HEAD$/);
486 die "revision argument: $_revision not understood by git-svn\n",
487 "Try using the command-line svn client instead\n";
488 }
490 sub complete_svn_url {
491 my ($url, $path) = @_;
492 $path =~ s#/+$##;
493 if ($path !~ m#^[a-z\+]+://#) {
494 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
495 fatal("E: '$path' is not a complete URL ",
496 "and a separate URL is not specified\n");
497 }
498 return ($url, $path);
499 }
500 return ($path, '');
501 }
503 sub complete_url_ls_init {
504 my ($ra, $repo_path, $switch, $pfx) = @_;
505 unless ($repo_path) {
506 print STDERR "W: $switch not specified\n";
507 return;
508 }
509 $repo_path =~ s#/+$##;
510 if ($repo_path =~ m#^[a-z\+]+://#) {
511 $ra = Git::SVN::Ra->new($repo_path);
512 $repo_path = '';
513 } else {
514 $repo_path =~ s#^/+##;
515 unless ($ra) {
516 fatal("E: '$repo_path' is not a complete URL ",
517 "and a separate URL is not specified\n");
518 }
519 }
520 my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
521 my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
522 my $url = $ra->{url};
523 foreach my $d (sort keys %$dirent) {
524 next if ($dirent->{$d}->kind != $SVN::Node::dir);
525 my $path = "$repo_path/$d";
526 my $ref = "$pfx$d";
527 my $gs = eval { Git::SVN->new($ref) };
528 # don't try to init already existing refs
529 unless ($gs) {
530 print "init $url/$path => $ref\n";
531 Git::SVN->init($url, $path, undef, $ref);
532 }
533 }
534 }
536 sub verify_ref {
537 my ($ref) = @_;
538 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
539 { STDERR => 0 }); };
540 }
542 sub get_tree_from_treeish {
543 my ($treeish) = @_;
544 # $treeish can be a symbolic ref, too:
545 my $type = command_oneline(qw/cat-file -t/, $treeish);
546 my $expected;
547 while ($type eq 'tag') {
548 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
549 }
550 if ($type eq 'commit') {
551 $expected = (grep /^tree /, command(qw/cat-file commit/,
552 $treeish))[0];
553 ($expected) = ($expected =~ /^tree ($sha1)$/o);
554 die "Unable to get tree from $treeish\n" unless $expected;
555 } elsif ($type eq 'tree') {
556 $expected = $treeish;
557 } else {
558 die "$treeish is a $type, expected tree, tag or commit\n";
559 }
560 return $expected;
561 }
563 sub get_commit_entry {
564 my ($treeish) = shift;
565 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
566 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
567 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
568 open my $log_fh, '>', $commit_editmsg or croak $!;
570 my $type = command_oneline(qw/cat-file -t/, $treeish);
571 if ($type eq 'commit' || $type eq 'tag') {
572 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
573 $type, $treeish);
574 my $in_msg = 0;
575 while (<$msg_fh>) {
576 if (!$in_msg) {
577 $in_msg = 1 if (/^\s*$/);
578 } elsif (/^git-svn-id: /) {
579 # skip this for now, we regenerate the
580 # correct one on re-fetch anyways
581 # TODO: set *:merge properties or like...
582 } else {
583 print $log_fh $_ or croak $!;
584 }
585 }
586 command_close_pipe($msg_fh, $ctx);
587 }
588 close $log_fh or croak $!;
590 if ($_edit || ($type eq 'tree')) {
591 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
592 # TODO: strip out spaces, comments, like git-commit.sh
593 system($editor, $commit_editmsg);
594 }
595 rename $commit_editmsg, $commit_msg or croak $!;
596 open $log_fh, '<', $commit_msg or croak $!;
597 { local $/; chomp($log_entry{log} = <$log_fh>); }
598 close $log_fh or croak $!;
599 unlink $commit_msg;
600 \%log_entry;
601 }
603 sub s_to_file {
604 my ($str, $file, $mode) = @_;
605 open my $fd,'>',$file or croak $!;
606 print $fd $str,"\n" or croak $!;
607 close $fd or croak $!;
608 chmod ($mode &~ umask, $file) if (defined $mode);
609 }
611 sub file_to_s {
612 my $file = shift;
613 open my $fd,'<',$file or croak "$!: file: $file\n";
614 local $/;
615 my $ret = <$fd>;
616 close $fd or croak $!;
617 $ret =~ s/\s*$//s;
618 return $ret;
619 }
621 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
622 sub load_authors {
623 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
624 my $log = $cmd eq 'log';
625 while (<$authors>) {
626 chomp;
627 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
628 my ($user, $name, $email) = ($1, $2, $3);
629 if ($log) {
630 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
631 } else {
632 $users{$user} = [$name, $email];
633 }
634 }
635 close $authors or croak $!;
636 }
638 # convert GetOpt::Long specs for use by git-config
639 sub read_repo_config {
640 return unless -d $ENV{GIT_DIR};
641 my $opts = shift;
642 foreach my $o (keys %$opts) {
643 my $v = $opts->{$o};
644 my ($key) = ($o =~ /^([a-z\-]+)/);
645 $key =~ s/-//g;
646 my $arg = 'git-config';
647 $arg .= ' --int' if ($o =~ /[:=]i$/);
648 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
649 if (ref $v eq 'ARRAY') {
650 chomp(my @tmp = `$arg --get-all svn.$key`);
651 @$v = @tmp if @tmp;
652 } else {
653 chomp(my $tmp = `$arg --get svn.$key`);
654 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
655 $$v = $tmp;
656 }
657 }
658 }
659 }
661 sub extract_metadata {
662 my $id = shift or return (undef, undef, undef);
663 my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
664 \s([a-f\d\-]+)$/x);
665 if (!defined $rev || !$uuid || !$url) {
666 # some of the original repositories I made had
667 # identifiers like this:
668 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
669 }
670 return ($url, $rev, $uuid);
671 }
673 sub cmt_metadata {
674 return extract_metadata((grep(/^git-svn-id: /,
675 command(qw/cat-file commit/, shift)))[-1]);
676 }
678 package Git::SVN;
679 use strict;
680 use warnings;
681 use vars qw/$default_repo_id $default_ref_id/;
682 use Carp qw/croak/;
683 use File::Path qw/mkpath/;
684 use IPC::Open3;
686 # properties that we do not log:
687 my %SKIP_PROP;
688 BEGIN {
689 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
690 svn:special svn:executable
691 svn:entry:committed-rev
692 svn:entry:last-author
693 svn:entry:uuid
694 svn:entry:committed-date/;
695 }
697 sub fetch_all {
698 my ($repo_id, $url, $fetch) = @_;
699 my @gs;
700 my $ra = Git::SVN::Ra->new($url);
701 my $head = $ra->get_latest_revnum;
702 my $base = $head;
703 my $new_remote;
704 foreach my $p (sort keys %$fetch) {
705 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
706 my $lr = $gs->last_rev;
707 if (defined $lr) {
708 $base = $lr if ($lr < $base);
709 } else {
710 $new_remote = 1;
711 }
712 push @gs, $gs;
713 }
714 $base = 0 if $new_remote;
715 return if (++$base > $head);
716 $ra->gs_fetch_loop_common($base, $head, @gs);
717 }
719 sub read_all_remotes {
720 my $r = {};
721 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
722 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
723 $r->{$1}->{fetch}->{$2} = $3;
724 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
725 $r->{$1}->{url} = $2;
726 }
727 }
728 $r;
729 }
731 sub verify_remotes_sanity {
732 return unless -d $ENV{GIT_DIR};
733 my %seen;
734 foreach (command(qw/config -l/)) {
735 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
736 if ($seen{$1}) {
737 die "Remote ref refs/remote/$1 is tracked by",
738 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
739 "Please resolve this ambiguity in ",
740 "your git configuration file before ",
741 "continuing\n";
742 }
743 $seen{$1} = $_;
744 }
745 }
746 }
748 # we allow more chars than remotes2config.sh...
749 sub sanitize_remote_name {
750 my ($name) = @_;
751 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
752 $name;
753 }
755 sub find_existing_remote {
756 my ($url, $remotes) = @_;
757 my $existing;
758 foreach my $repo_id (keys %$remotes) {
759 my $u = $remotes->{$repo_id}->{url} or next;
760 next if $u ne $url;
761 $existing = $repo_id;
762 last;
763 }
764 $existing;
765 }
767 sub init_remote_config {
768 my ($self, $url) = @_;
769 $url =~ s!/+$!!; # strip trailing slash
770 my $r = read_all_remotes();
771 my $existing = find_existing_remote($url, $r);
772 if ($existing) {
773 print STDERR "Using existing ",
774 "[svn-remote \"$existing\"]\n";
775 $self->{repo_id} = $existing;
776 } else {
777 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
778 $existing = find_existing_remote($min_url, $r);
779 if ($existing) {
780 print STDERR "Using existing ",
781 "[svn-remote \"$existing\"]\n";
782 $self->{repo_id} = $existing;
783 }
784 if ($min_url ne $url) {
785 print STDERR "Using higher level of URL: ",
786 "$url => $min_url\n";
787 my $old_path = $self->{path};
788 $self->{path} = $url;
789 $self->{path} =~ s!^\Q$min_url\E/*!!;
790 if (length $old_path) {
791 $self->{path} .= "/$old_path";
792 }
793 $url = $min_url;
794 }
795 }
796 my $orig_url;
797 if (!$existing) {
798 # verify that we aren't overwriting anything:
799 $orig_url = eval {
800 command_oneline('config', '--get',
801 "svn-remote.$self->{repo_id}.url")
802 };
803 if ($orig_url && ($orig_url ne $url)) {
804 die "svn-remote.$self->{repo_id}.url already set: ",
805 "$orig_url\nwanted to set to: $url\n";
806 }
807 }
808 my ($xrepo_id, $xpath) = find_ref($self->refname);
809 if (defined $xpath) {
810 die "svn-remote.$xrepo_id.fetch already set to track ",
811 "$xpath:refs/remotes/", $self->refname, "\n";
812 }
813 command_noisy('config',
814 "svn-remote.$self->{repo_id}.url", $url);
815 command_noisy('config', '--add',
816 "svn-remote.$self->{repo_id}.fetch",
817 "$self->{path}:".$self->refname);
818 $self->{url} = $url;
819 }
821 sub init {
822 my ($class, $url, $path, $repo_id, $ref_id) = @_;
823 my $self = _new($class, $repo_id, $ref_id, $path);
824 if (defined $url) {
825 $self->init_remote_config($url);
826 }
827 $self;
828 }
830 sub find_ref {
831 my ($ref_id) = @_;
832 foreach (command(qw/config -l/)) {
833 next unless m!^svn-remote\.(.+)\.fetch=
834 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
835 my ($repo_id, $path, $ref) = ($1, $2, $3);
836 if ($ref eq $ref_id) {
837 $path = '' if ($path =~ m#^\./?#);
838 return ($repo_id, $path);
839 }
840 }
841 (undef, undef, undef);
842 }
844 sub new {
845 my ($class, $ref_id, $repo_id, $path) = @_;
846 if (defined $ref_id && !defined $repo_id && !defined $path) {
847 ($repo_id, $path) = find_ref($ref_id);
848 if (!defined $repo_id) {
849 die "Could not find a \"svn-remote.*.fetch\" key ",
850 "in the repository configuration matching: ",
851 "refs/remotes/$ref_id\n";
852 }
853 }
854 my $self = _new($class, $repo_id, $ref_id, $path);
855 if (!defined $self->{path} || !length $self->{path}) {
856 my $fetch = command_oneline('config', '--get',
857 "svn-remote.$repo_id.fetch",
858 ":refs/remotes/$ref_id\$") or
859 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
860 "\":refs/remotes/$ref_id\$\" in config\n";
861 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
862 }
863 $self->{url} = command_oneline('config', '--get',
864 "svn-remote.$repo_id.url") or
865 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
866 $self;
867 }
869 sub refname { "refs/remotes/$_[0]->{ref_id}" }
871 sub ra {
872 my ($self) = shift;
873 $self->{ra} ||= Git::SVN::Ra->new($self->{url});
874 }
876 sub rel_path {
877 my ($self) = @_;
878 my $repos_root = $self->ra->{repos_root};
879 return $self->{path} if ($self->{url} eq $repos_root);
880 my $url = $self->{url} .
881 (length $self->{path} ? "/$self->{path}" : $self->{path});
882 $url =~ s!^\Q$repos_root\E/*!!g;
883 $url;
884 }
886 sub copy_remote_ref {
887 my ($self) = @_;
888 my $origin = $::_cp_remote ? $::_cp_remote : 'origin';
889 my $ref = $self->refname;
890 if (command('ls-remote', $origin, $ref)) {
891 command_noisy('fetch', $origin, "$ref:$ref");
892 } elsif ($::_cp_remote && !$::_upgrade) {
893 die "Unable to find remote reference: $ref on $origin\n";
894 }
895 }
897 sub traverse_ignore {
898 my ($self, $fh, $path, $r) = @_;
899 $path =~ s#^/+##g;
900 my ($dirent, undef, $props) = $self->ra->get_dir($path, $r);
901 my $p = $path;
902 $p =~ s#^\Q$self->{ra}->{svn_path}\E/##;
903 print $fh length $p ? "\n# $p\n" : "\n# /\n";
904 if (my $s = $props->{'svn:ignore'}) {
905 $s =~ s/[\r\n]+/\n/g;
906 chomp $s;
907 if (length $p == 0) {
908 $s =~ s#\n#\n/$p#g;
909 print $fh "/$s\n";
910 } else {
911 $s =~ s#\n#\n/$p/#g;
912 print $fh "/$p/$s\n";
913 }
914 }
915 foreach (sort keys %$dirent) {
916 next if $dirent->{$_}->kind != $SVN::Node::dir;
917 $self->traverse_ignore($fh, "$path/$_", $r);
918 }
919 }
921 sub last_rev { ($_[0]->last_rev_commit)[0] }
922 sub last_commit { ($_[0]->last_rev_commit)[1] }
924 # returns the newest SVN revision number and newest commit SHA1
925 sub last_rev_commit {
926 my ($self) = @_;
927 if (defined $self->{last_rev} && defined $self->{last_commit}) {
928 return ($self->{last_rev}, $self->{last_commit});
929 }
930 my $c = ::verify_ref($self->refname.'^0');
931 if ($c) {
932 my $rev = (::cmt_metadata($c))[1];
933 if (defined $rev) {
934 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
935 return ($rev, $c);
936 }
937 }
938 my $offset = -41; # from tail
939 my $rl;
940 open my $fh, '<', $self->{db_path} or
941 croak "$self->{db_path} not readable: $!\n";
942 seek $fh, $offset, 2;
943 $rl = readline $fh;
944 defined $rl or return (undef, undef);
945 chomp $rl;
946 while ($c ne $rl && tell $fh != 0) {
947 $offset -= 41;
948 seek $fh, $offset, 2;
949 $rl = readline $fh;
950 defined $rl or return (undef, undef);
951 chomp $rl;
952 }
953 my $rev = tell $fh;
954 croak $! if ($rev < 0);
955 $rev = ($rev - 41) / 41;
956 close $fh or croak $!;
957 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
958 return ($rev, $c);
959 }
961 sub get_fetch_range {
962 my ($self, $min, $max) = @_;
963 $max ||= $self->ra->get_latest_revnum;
964 $min ||= $self->last_rev || 0;
965 (++$min, $max);
966 }
968 sub tmp_index_do {
969 my ($self, $sub) = @_;
970 my $old_index = $ENV{GIT_INDEX_FILE};
971 $ENV{GIT_INDEX_FILE} = $self->{index};
972 my @ret = &$sub;
973 if ($old_index) {
974 $ENV{GIT_INDEX_FILE} = $old_index;
975 } else {
976 delete $ENV{GIT_INDEX_FILE};
977 }
978 wantarray ? @ret : $ret[0];
979 }
981 sub assert_index_clean {
982 my ($self, $treeish) = @_;
984 $self->tmp_index_do(sub {
985 command_noisy('read-tree', $treeish) unless -e $self->{index};
986 my $x = command_oneline('write-tree');
987 my ($y) = (command(qw/cat-file commit/, $treeish) =~
988 /^tree ($::sha1)/mo);
989 if ($y ne $x) {
990 unlink $self->{index} or croak $!;
991 command_noisy('read-tree', $treeish);
992 }
993 $x = command_oneline('write-tree');
994 if ($y ne $x) {
995 ::fatal "trees ($treeish) $y != $x\n",
996 "Something is seriously wrong...\n";
997 }
998 });
999 }
1001 sub get_commit_parents {
1002 my ($self, $log_entry) = @_;
1003 my (%seen, @ret, @tmp);
1004 # legacy support for 'set-tree'; this is only used by set_tree_cb:
1005 if (my $ip = $self->{inject_parents}) {
1006 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1007 push @tmp, $commit;
1008 }
1009 }
1010 if (my $cur = ::verify_ref($self->refname.'^0')) {
1011 push @tmp, $cur;
1012 }
1013 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1014 while (my $p = shift @tmp) {
1015 next if $seen{$p};
1016 $seen{$p} = 1;
1017 push @ret, $p;
1018 # MAXPARENT is defined to 16 in commit-tree.c:
1019 last if @ret >= 16;
1020 }
1021 if (@tmp) {
1022 die "r$log_entry->{revision}: No room for parents:\n\t",
1023 join("\n\t", @tmp), "\n";
1024 }
1025 @ret;
1026 }
1028 sub full_url {
1029 my ($self) = @_;
1030 $self->ra->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1031 }
1033 sub do_git_commit {
1034 my ($self, $log_entry) = @_;
1035 if (my $c = $self->rev_db_get($log_entry->{revision})) {
1036 croak "$log_entry->{revision} = $c already exists! ",
1037 "Why are we refetching it?\n";
1038 }
1039 my $author = $log_entry->{author};
1040 my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1041 : ($author, "$author\@".$self->ra->uuid));
1042 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1043 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1044 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1046 my $tree = $log_entry->{tree};
1047 if (!defined $tree) {
1048 $tree = $self->tmp_index_do(sub {
1049 command_oneline('write-tree') });
1050 }
1051 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1053 my @exec = ('git-commit-tree', $tree);
1054 foreach ($self->get_commit_parents($log_entry)) {
1055 push @exec, '-p', $_;
1056 }
1057 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1058 or croak $!;
1059 print $msg_fh $log_entry->{log} or croak $!;
1060 print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1061 $log_entry->{revision}, ' ',
1062 $self->ra->uuid, "\n" or croak $!;
1063 $msg_fh->flush == 0 or croak $!;
1064 close $msg_fh or croak $!;
1065 chomp(my $commit = do { local $/; <$out_fh> });
1066 close $out_fh or croak $!;
1067 waitpid $pid, 0;
1068 croak $? if $?;
1069 if ($commit !~ /^$::sha1$/o) {
1070 die "Failed to commit, invalid sha1: $commit\n";
1071 }
1073 command_noisy('update-ref',$self->refname, $commit);
1074 $self->rev_db_set($log_entry->{revision}, $commit);
1076 $self->{last_rev} = $log_entry->{revision};
1077 $self->{last_commit} = $commit;
1078 print "r$log_entry->{revision} = $commit\n";
1079 return $commit;
1080 }
1082 sub revisions_eq {
1083 my ($self, $r0, $r1) = @_;
1084 return 1 if $r0 == $r1;
1085 my $nr = 0;
1086 $self->ra->get_log([$self->{path}], $r0, $r1,
1087 0, 0, 1, sub { $nr++ });
1088 return 0 if ($nr > 1);
1089 return 1;
1090 }
1092 sub find_parent_branch {
1093 my ($self, $paths, $rev) = @_;
1094 return undef unless $::_follow_parent;
1095 unless (defined $paths) {
1096 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
1097 sub { $paths = dup_changed_paths($_[0]) });
1098 }
1099 return undef unless defined $paths;
1101 # look for a parent from another branch:
1102 my @b_path_components = split m#/#, $self->rel_path;
1103 my @a_path_components;
1104 my $i;
1105 while (@b_path_components) {
1106 $i = $paths->{'/'.join('/', @b_path_components)};
1107 last if $i;
1108 unshift(@a_path_components, pop(@b_path_components));
1109 }
1110 goto not_found unless defined $i;
1111 my $branch_from = $i->{copyfrom_path} or goto not_found;
1112 if (@a_path_components) {
1113 print STDERR "branch_from: $branch_from => ";
1114 $branch_from .= '/'.join('/', @a_path_components);
1115 print STDERR $branch_from, "\n";
1116 }
1117 my $r = $i->{copyfrom_rev};
1118 my $repos_root = $self->ra->{repos_root};
1119 my $url = $self->ra->{url};
1120 my $new_url = $repos_root . $branch_from;
1121 print STDERR "Found possible branch point: ",
1122 "$new_url => ", $self->full_url, ", $r\n";
1123 $branch_from =~ s#^/##;
1124 my $remotes = read_all_remotes();
1125 my $gs;
1126 foreach my $repo_id (keys %$remotes) {
1127 my $u = $remotes->{$repo_id}->{url} or next;
1128 next if $url ne $u;
1129 my $fetch = $remotes->{$repo_id}->{fetch};
1130 foreach my $f (keys %$fetch) {
1131 next if $f ne $branch_from;
1132 $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1133 last;
1134 }
1135 last if $gs;
1136 }
1137 unless ($gs) {
1138 my $ref_id = $branch_from;
1139 $ref_id .= "\@$r" if find_ref($ref_id);
1140 # just grow a tail if we're not unique enough :x
1141 $ref_id .= '-' while find_ref($ref_id);
1142 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1143 }
1144 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1145 if ($::_follow_parent && (!defined $r0 || !defined $parent)) {
1146 $gs->fetch(0, $r);
1147 ($r0, $parent) = $gs->last_rev_commit;
1148 }
1149 if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1150 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1151 $self->assert_index_clean($parent);
1152 my $ed;
1153 if ($self->ra->can_do_switch) {
1154 print STDERR "Following parent with do_switch\n";
1155 # do_switch works with svn/trunk >= r22312, but that
1156 # is not included with SVN 1.4.3 (the latest version
1157 # at the moment), so we can't rely on it
1158 $self->{last_commit} = $parent;
1159 $ed = SVN::Git::Fetcher->new($self);
1160 $gs->ra->gs_do_switch($r0, $rev, $gs->{path}, 1,
1161 $self->full_url, $ed)
1162 or die "SVN connection failed somewhere...\n";
1163 } else {
1164 print STDERR "Following parent with do_update\n";
1165 $ed = SVN::Git::Fetcher->new($self);
1166 $self->ra->gs_do_update($rev, $rev, $self->{path},
1167 1, $ed)
1168 or die "SVN connection failed somewhere...\n";
1169 }
1170 $ed->{new_fetch} = 1;
1171 return $self->make_log_entry($rev, [$parent], $ed);
1172 }
1173 not_found:
1174 print STDERR "Branch parent for path: '/",
1175 $self->rel_path, "' @ r$rev not found:\n";
1176 return undef unless $paths;
1177 print STDERR "Changed paths:\n";
1178 foreach my $x (sort keys %$paths) {
1179 my $p = $paths->{$x};
1180 print STDERR "\t$p->{action}\t$x";
1181 if ($p->{copyfrom_path}) {
1182 print STDERR "(from $p->{copyfrom_path}: ",
1183 "$p->{copyfrom_rev})";
1184 }
1185 print STDERR "\n";
1186 }
1187 print STDERR '-'x72, "\n";
1188 return undef;
1189 }
1191 sub do_fetch {
1192 my ($self, $paths, $rev) = @_;
1193 my $ed;
1194 my ($last_rev, @parents);
1195 if ($self->{last_commit}) {
1196 $ed = SVN::Git::Fetcher->new($self);
1197 $last_rev = $self->{last_rev};
1198 $ed->{c} = $self->{last_commit};
1199 @parents = ($self->{last_commit});
1200 } else {
1201 $last_rev = $rev;
1202 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1203 return $log_entry;
1204 }
1205 $ed = SVN::Git::Fetcher->new($self);
1206 $ed->{new_fetch} = 1;
1207 }
1208 unless ($self->ra->gs_do_update($last_rev, $rev,
1209 $self->{path}, 1, $ed)) {
1210 die "SVN connection failed somewhere...\n";
1211 }
1212 $self->make_log_entry($rev, \@parents, $ed);
1213 }
1215 sub get_untracked {
1216 my ($self, $ed) = @_;
1217 my @out;
1218 my $h = $ed->{empty};
1219 foreach (sort keys %$h) {
1220 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1221 push @out, " $act: " . uri_encode($_);
1222 warn "W: $act: $_\n";
1223 }
1224 foreach my $t (qw/dir_prop file_prop/) {
1225 $h = $ed->{$t} or next;
1226 foreach my $path (sort keys %$h) {
1227 my $ppath = $path eq '' ? '.' : $path;
1228 foreach my $prop (sort keys %{$h->{$path}}) {
1229 next if $SKIP_PROP{$prop};
1230 my $v = $h->{$path}->{$prop};
1231 my $t_ppath_prop = "$t: " .
1232 uri_encode($ppath) . ' ' .
1233 uri_encode($prop);
1234 if (defined $v) {
1235 push @out, " +$t_ppath_prop " .
1236 uri_encode($v);
1237 } else {
1238 push @out, " -$t_ppath_prop";
1239 }
1240 }
1241 }
1242 }
1243 foreach my $t (qw/absent_file absent_directory/) {
1244 $h = $ed->{$t} or next;
1245 foreach my $parent (sort keys %$h) {
1246 foreach my $path (sort @{$h->{$parent}}) {
1247 push @out, " $t: " .
1248 uri_encode("$parent/$path");
1249 warn "W: $t: $parent/$path ",
1250 "Insufficient permissions?\n";
1251 }
1252 }
1253 }
1254 \@out;
1255 }
1257 sub parse_svn_date {
1258 my $date = shift || return '+0000 1970-01-01 00:00:00';
1259 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1260 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1261 croak "Unable to parse date: $date\n";
1262 "+0000 $Y-$m-$d $H:$M:$S";
1263 }
1265 sub check_author {
1266 my ($author) = @_;
1267 if (!defined $author || length $author == 0) {
1268 $author = '(no author)';
1269 }
1270 if (defined $::_authors && ! defined $::users{$author}) {
1271 die "Author: $author not defined in $::_authors file\n";
1272 }
1273 $author;
1274 }
1276 sub make_log_entry {
1277 my ($self, $rev, $parents, $ed) = @_;
1278 my $untracked = $self->get_untracked($ed);
1280 return undef if (! $ed->{new_fetch} && ! $ed->{nr} && ! @$untracked);
1282 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1283 print $un "r$rev\n" or croak $!;
1284 print $un $_, "\n" foreach @$untracked;
1285 my %log_entry = ( parents => $parents || [], revision => $rev,
1286 log => '');
1287 my $rp = $self->ra->rev_proplist($rev);
1288 foreach (sort keys %$rp) {
1289 my $v = $rp->{$_};
1290 if (/^svn:(author|date|log)$/) {
1291 $log_entry{$1} = $v;
1292 } else {
1293 print $un " rev_prop: ", uri_encode($_), ' ',
1294 uri_encode($v), "\n";
1295 }
1296 }
1297 close $un or croak $!;
1299 $log_entry{date} = parse_svn_date($log_entry{date});
1300 $log_entry{author} = check_author($log_entry{author});
1301 $log_entry{log} .= "\n";
1302 \%log_entry;
1303 }
1305 sub fetch {
1306 my ($self, $min_rev, $max_rev, @parents) = @_;
1307 my ($last_rev, $last_commit) = $self->last_rev_commit;
1308 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1309 return if ($base > $head);
1310 $self->ra->gs_fetch_loop_common($base, $head, $self);
1311 }
1313 sub set_tree_cb {
1314 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1315 # TODO: enable and test optimized commits:
1316 if (0 && $rev == ($self->{last_rev} + 1)) {
1317 $log_entry->{revision} = $rev;
1318 $log_entry->{author} = $author;
1319 $self->do_git_commit($log_entry, "$rev=$tree");
1320 } else {
1321 $self->{inject_parents} = { $rev => $tree };
1322 $self->fetch(undef, undef);
1323 }
1324 }
1326 sub set_tree {
1327 my ($self, $tree) = (shift, shift);
1328 my $log_entry = ::get_commit_entry($tree);
1329 unless ($self->{last_rev}) {
1330 fatal("Must have an existing revision to commit\n");
1331 }
1332 my %ed_opts = ( r => $self->{last_rev},
1333 log => $log_entry->{log},
1334 ra => $self->ra,
1335 tree_a => $self->{last_commit},
1336 tree_b => $tree,
1337 editor_cb => sub {
1338 $self->set_tree_cb($log_entry, $tree, @_) },
1339 svn_path => $self->{path} );
1340 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1341 print "No changes\nr$self->{last_rev} = $tree\n";
1342 }
1343 }
1345 # rev_db:
1346 # Tie::File seems to be prone to offset errors if revisions get sparse,
1347 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
1348 # one of my favorite modules is out :< Next up would be one of the DBM
1349 # modules, but I'm not sure which is most portable... So I'll just
1350 # go with something that's plain-text, but still capable of
1351 # being randomly accessed. So here's my ultra-simple fixed-width
1352 # database. All records are 40 characters + "\n", so it's easy to seek
1353 # to a revision: (41 * rev) is the byte offset.
1354 # A record of 40 0s denotes an empty revision.
1355 # And yes, it's still pretty fast (faster than Tie::File).
1357 sub rev_db_set {
1358 my ($self, $rev, $commit) = @_;
1359 length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1360 open my $fh, '+<', $self->{db_path} or croak $!;
1361 my $offset = $rev * 41;
1362 # assume that append is the common case:
1363 seek $fh, 0, 2 or croak $!;
1364 my $pos = tell $fh;
1365 if ($pos < $offset) {
1366 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41)
1367 or croak $!;
1368 }
1369 seek $fh, $offset, 0 or croak $!;
1370 print $fh $commit,"\n" or croak $!;
1371 close $fh or croak $!;
1372 }
1374 sub rev_db_get {
1375 my ($self, $rev) = @_;
1376 my $ret;
1377 my $offset = $rev * 41;
1378 open my $fh, '<', $self->{db_path} or croak $!;
1379 if (seek $fh, $offset, 0) {
1380 $ret = readline $fh;
1381 if (defined $ret) {
1382 chomp $ret;
1383 $ret = undef if ($ret =~ /^0{40}$/);
1384 }
1385 }
1386 close $fh or croak $!;
1387 $ret;
1388 }
1390 sub find_rev_before {
1391 my ($self, $rev, $eq_ok) = @_;
1392 --$rev unless $eq_ok;
1393 while ($rev > 0) {
1394 if (my $c = $self->rev_db_get($rev)) {
1395 return ($rev, $c);
1396 }
1397 --$rev;
1398 }
1399 return (undef, undef);
1400 }
1402 sub _new {
1403 my ($class, $repo_id, $ref_id, $path) = @_;
1404 unless (defined $repo_id && length $repo_id) {
1405 $repo_id = $Git::SVN::default_repo_id;
1406 }
1407 unless (defined $ref_id && length $ref_id) {
1408 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1409 }
1410 $_[1] = $repo_id = sanitize_remote_name($repo_id);
1411 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1412 $_[3] = $path = '' unless (defined $path);
1413 mkpath([$dir]);
1414 unless (-f "$dir/.rev_db") {
1415 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1416 close $fh or croak $!;
1417 }
1418 bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1419 path => $path,
1420 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1421 }
1423 sub uri_encode {
1424 my ($f) = @_;
1425 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1426 $f
1427 }
1429 package Git::SVN::Prompt;
1430 use strict;
1431 use warnings;
1432 require SVN::Core;
1433 use vars qw/$_no_auth_cache $_username/;
1435 sub simple {
1436 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1437 $may_save = undef if $_no_auth_cache;
1438 $default_username = $_username if defined $_username;
1439 if (defined $default_username && length $default_username) {
1440 if (defined $realm && length $realm) {
1441 print STDERR "Authentication realm: $realm\n";
1442 STDERR->flush;
1443 }
1444 $cred->username($default_username);
1445 } else {
1446 username($cred, $realm, $may_save, $pool);
1447 }
1448 $cred->password(_read_password("Password for '" .
1449 $cred->username . "': ", $realm));
1450 $cred->may_save($may_save);
1451 $SVN::_Core::SVN_NO_ERROR;
1452 }
1454 sub ssl_server_trust {
1455 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1456 $may_save = undef if $_no_auth_cache;
1457 print STDERR "Error validating server certificate for '$realm':\n";
1458 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1459 print STDERR " - The certificate is not issued by a trusted ",
1460 "authority. Use the\n",
1461 " fingerprint to validate the certificate manually!\n";
1462 }
1463 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1464 print STDERR " - The certificate hostname does not match.\n";
1465 }
1466 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1467 print STDERR " - The certificate is not yet valid.\n";
1468 }
1469 if ($failures & $SVN::Auth::SSL::EXPIRED) {
1470 print STDERR " - The certificate has expired.\n";
1471 }
1472 if ($failures & $SVN::Auth::SSL::OTHER) {
1473 print STDERR " - The certificate has an unknown error.\n";
1474 }
1475 printf STDERR
1476 "Certificate information:\n".
1477 " - Hostname: %s\n".
1478 " - Valid: from %s until %s\n".
1479 " - Issuer: %s\n".
1480 " - Fingerprint: %s\n",
1481 map $cert_info->$_, qw(hostname valid_from valid_until
1482 issuer_dname fingerprint);
1483 my $choice;
1484 prompt:
1485 print STDERR $may_save ?
1486 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1487 "(R)eject or accept (t)emporarily? ";
1488 STDERR->flush;
1489 $choice = lc(substr(<STDIN> || 'R', 0, 1));
1490 if ($choice =~ /^t$/i) {
1491 $cred->may_save(undef);
1492 } elsif ($choice =~ /^r$/i) {
1493 return -1;
1494 } elsif ($may_save && $choice =~ /^p$/i) {
1495 $cred->may_save($may_save);
1496 } else {
1497 goto prompt;
1498 }
1499 $cred->accepted_failures($failures);
1500 $SVN::_Core::SVN_NO_ERROR;
1501 }
1503 sub ssl_client_cert {
1504 my ($cred, $realm, $may_save, $pool) = @_;
1505 $may_save = undef if $_no_auth_cache;
1506 print STDERR "Client certificate filename: ";
1507 STDERR->flush;
1508 chomp(my $filename = <STDIN>);
1509 $cred->cert_file($filename);
1510 $cred->may_save($may_save);
1511 $SVN::_Core::SVN_NO_ERROR;
1512 }
1514 sub ssl_client_cert_pw {
1515 my ($cred, $realm, $may_save, $pool) = @_;
1516 $may_save = undef if $_no_auth_cache;
1517 $cred->password(_read_password("Password: ", $realm));
1518 $cred->may_save($may_save);
1519 $SVN::_Core::SVN_NO_ERROR;
1520 }
1522 sub username {
1523 my ($cred, $realm, $may_save, $pool) = @_;
1524 $may_save = undef if $_no_auth_cache;
1525 if (defined $realm && length $realm) {
1526 print STDERR "Authentication realm: $realm\n";
1527 }
1528 my $username;
1529 if (defined $_username) {
1530 $username = $_username;
1531 } else {
1532 print STDERR "Username: ";
1533 STDERR->flush;
1534 chomp($username = <STDIN>);
1535 }
1536 $cred->username($username);
1537 $cred->may_save($may_save);
1538 $SVN::_Core::SVN_NO_ERROR;
1539 }
1541 sub _read_password {
1542 my ($prompt, $realm) = @_;
1543 print STDERR $prompt;
1544 STDERR->flush;
1545 require Term::ReadKey;
1546 Term::ReadKey::ReadMode('noecho');
1547 my $password = '';
1548 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1549 last if $key =~ /[\012\015]/; # \n\r
1550 $password .= $key;
1551 }
1552 Term::ReadKey::ReadMode('restore');
1553 print STDERR "\n";
1554 STDERR->flush;
1555 $password;
1556 }
1558 package main;
1560 sub uri_encode {
1561 my ($f) = @_;
1562 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1563 $f
1564 }
1566 sub uri_decode {
1567 my ($f) = @_;
1568 $f =~ tr/+/ /;
1569 $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
1570 $f
1571 }
1573 {
1574 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1575 $SVN::Node::dir.$SVN::Node::unknown.
1576 $SVN::Node::none.$SVN::Node::file.
1577 $SVN::Node::dir.$SVN::Node::unknown.
1578 $SVN::Auth::SSL::CNMISMATCH.
1579 $SVN::Auth::SSL::NOTYETVALID.
1580 $SVN::Auth::SSL::EXPIRED.
1581 $SVN::Auth::SSL::UNKNOWNCA.
1582 $SVN::Auth::SSL::OTHER;
1583 }
1585 package SVN::Git::Fetcher;
1586 use vars qw/@ISA/;
1587 use strict;
1588 use warnings;
1589 use Carp qw/croak/;
1590 use IO::File qw//;
1592 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1593 sub new {
1594 my ($class, $git_svn) = @_;
1595 my $self = SVN::Delta::Editor->new;
1596 bless $self, $class;
1597 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1598 $self->{empty} = {};
1599 $self->{dir_prop} = {};
1600 $self->{file_prop} = {};
1601 $self->{absent_dir} = {};
1602 $self->{absent_file} = {};
1603 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1604 require Digest::MD5;
1605 $self;
1606 }
1608 sub set_path_strip {
1609 my ($self, $path) = @_;
1610 $self->{path_strip} = qr/^\Q$path\E\/?/;
1611 }
1613 sub open_root {
1614 { path => '' };
1615 }
1617 sub open_directory {
1618 my ($self, $path, $pb, $rev) = @_;
1619 { path => $path };
1620 }
1622 sub git_path {
1623 my ($self, $path) = @_;
1624 if ($self->{path_strip}) {
1625 $path =~ s!$self->{path_strip}!! or
1626 die "Failed to strip path '$path' ($self->{path_strip})\n";
1627 }
1628 $path;
1629 }
1631 sub delete_entry {
1632 my ($self, $path, $rev, $pb) = @_;
1634 my $gpath = $self->git_path($path);
1635 # remove entire directories.
1636 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1637 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1638 -r --name-only -z/,
1639 $self->{c}, '--', $gpath);
1640 local $/ = "\0";
1641 while (<$ls>) {
1642 chomp;
1643 $self->{gii}->remove($_);
1644 print "\tD\t$_\n" unless $self->{q};
1645 }
1646 print "\tD\t$gpath/\n" unless $self->{q};
1647 command_close_pipe($ls, $ctx);
1648 $self->{empty}->{$path} = 0
1649 } else {
1650 $self->{gii}->remove($gpath);
1651 print "\tD\t$gpath\n" unless $self->{q};
1652 }
1653 undef;
1654 }
1656 sub open_file {
1657 my ($self, $path, $pb, $rev) = @_;
1658 my $gpath = $self->git_path($path);
1659 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1660 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1661 unless (defined $mode && defined $blob) {
1662 die "$path was not found in commit $self->{c} (r$rev)\n";
1663 }
1664 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1665 pool => SVN::Pool->new, action => 'M' };
1666 }
1668 sub add_file {
1669 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1670 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1671 delete $self->{empty}->{$dir};
1672 { path => $path, mode_a => 100644, mode_b => 100644,
1673 pool => SVN::Pool->new, action => 'A' };
1674 }
1676 sub add_directory {
1677 my ($self, $path, $cp_path, $cp_rev) = @_;
1678 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1679 delete $self->{empty}->{$dir};
1680 $self->{empty}->{$path} = 1;
1681 { path => $path };
1682 }
1684 sub change_dir_prop {
1685 my ($self, $db, $prop, $value) = @_;
1686 $self->{dir_prop}->{$db->{path}} ||= {};
1687 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1688 undef;
1689 }
1691 sub absent_directory {
1692 my ($self, $path, $pb) = @_;
1693 $self->{absent_dir}->{$pb->{path}} ||= [];
1694 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1695 undef;
1696 }
1698 sub absent_file {
1699 my ($self, $path, $pb) = @_;
1700 $self->{absent_file}->{$pb->{path}} ||= [];
1701 push @{$self->{absent_file}->{$pb->{path}}}, $path;
1702 undef;
1703 }
1705 sub change_file_prop {
1706 my ($self, $fb, $prop, $value) = @_;
1707 if ($prop eq 'svn:executable') {
1708 if ($fb->{mode_b} != 120000) {
1709 $fb->{mode_b} = defined $value ? 100755 : 100644;
1710 }
1711 } elsif ($prop eq 'svn:special') {
1712 $fb->{mode_b} = defined $value ? 120000 : 100644;
1713 } else {
1714 $self->{file_prop}->{$fb->{path}} ||= {};
1715 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1716 }
1717 undef;
1718 }
1720 sub apply_textdelta {
1721 my ($self, $fb, $exp) = @_;
1722 my $fh = IO::File->new_tmpfile;
1723 $fh->autoflush(1);
1724 # $fh gets auto-closed() by SVN::TxDelta::apply(),
1725 # (but $base does not,) so dup() it for reading in close_file
1726 open my $dup, '<&', $fh or croak $!;
1727 my $base = IO::File->new_tmpfile;
1728 $base->autoflush(1);
1729 if ($fb->{blob}) {
1730 defined (my $pid = fork) or croak $!;
1731 if (!$pid) {
1732 open STDOUT, '>&', $base or croak $!;
1733 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1734 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1735 }
1736 waitpid $pid, 0;
1737 croak $? if $?;
1739 if (defined $exp) {
1740 seek $base, 0, 0 or croak $!;
1741 my $md5 = Digest::MD5->new;
1742 $md5->addfile($base);
1743 my $got = $md5->hexdigest;
1744 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1745 "expected: $exp\n",
1746 " got: $got\n" if ($got ne $exp);
1747 }
1748 }
1749 seek $base, 0, 0 or croak $!;
1750 $fb->{fh} = $dup;
1751 $fb->{base} = $base;
1752 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1753 }
1755 sub close_file {
1756 my ($self, $fb, $exp) = @_;
1757 my $hash;
1758 my $path = $self->git_path($fb->{path});
1759 if (my $fh = $fb->{fh}) {
1760 seek($fh, 0, 0) or croak $!;
1761 my $md5 = Digest::MD5->new;
1762 $md5->addfile($fh);
1763 my $got = $md5->hexdigest;
1764 die "Checksum mismatch: $path\n",
1765 "expected: $exp\n got: $got\n" if ($got ne $exp);
1766 seek($fh, 0, 0) or croak $!;
1767 if ($fb->{mode_b} == 120000) {
1768 read($fh, my $buf, 5) == 5 or croak $!;
1769 $buf eq 'link ' or die "$path has mode 120000",
1770 "but is not a link\n";
1771 }
1772 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1773 if (!$pid) {
1774 open STDIN, '<&', $fh or croak $!;
1775 exec qw/git-hash-object -w --stdin/ or croak $!;
1776 }
1777 chomp($hash = do { local $/; <$out> });
1778 close $out or croak $!;
1779 close $fh or croak $!;
1780 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1781 close $fb->{base} or croak $!;
1782 } else {
1783 $hash = $fb->{blob} or die "no blob information\n";
1784 }
1785 $fb->{pool}->clear;
1786 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1787 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1788 undef;
1789 }
1791 sub abort_edit {
1792 my $self = shift;
1793 $self->{nr} = $self->{gii}->{nr};
1794 delete $self->{gii};
1795 $self->SUPER::abort_edit(@_);
1796 }
1798 sub close_edit {
1799 my $self = shift;
1800 $self->{git_commit_ok} = 1;
1801 $self->{nr} = $self->{gii}->{nr};
1802 delete $self->{gii};
1803 $self->SUPER::close_edit(@_);
1804 }
1806 package SVN::Git::Editor;
1807 use vars qw/@ISA/;
1808 use strict;
1809 use warnings;
1810 use Carp qw/croak/;
1811 use IO::File;
1813 sub new {
1814 my ($class, $opts) = @_;
1815 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
1816 die "$_ required!\n" unless (defined $opts->{$_});
1817 }
1819 my $pool = SVN::Pool->new;
1820 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
1821 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
1822 $opts->{r}, $mods);
1824 # $opts->{ra} functions should not be used after this:
1825 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
1826 $opts->{editor_cb}, $pool);
1827 my $self = SVN::Delta::Editor->new(@ce, $pool);
1828 bless $self, $class;
1829 foreach (qw/svn_path r tree_a tree_b/) {
1830 $self->{$_} = $opts->{$_};
1831 }
1832 $self->{url} = $opts->{ra}->{url};
1833 $self->{mods} = $mods;
1834 $self->{types} = $types;
1835 $self->{pool} = $pool;
1836 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1837 $self->{rm} = { };
1838 $self->{path_prefix} = length $self->{svn_path} ?
1839 "$self->{svn_path}/" : '';
1840 require Digest::MD5;
1841 return $self;
1842 }
1844 sub generate_diff {
1845 my ($tree_a, $tree_b) = @_;
1846 my @diff_tree = qw(diff-tree -z -r);
1847 if ($::_cp_similarity) {
1848 push @diff_tree, "-C$::_cp_similarity";
1849 } else {
1850 push @diff_tree, '-C';
1851 }
1852 push @diff_tree, '--find-copies-harder' if $::_find_copies_harder;
1853 push @diff_tree, "-l$::_l" if defined $::_l;
1854 push @diff_tree, $tree_a, $tree_b;
1855 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1856 local $/ = "\0";
1857 my $state = 'meta';
1858 my @mods;
1859 while (<$diff_fh>) {
1860 chomp $_; # this gets rid of the trailing "\0"
1861 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1862 $::sha1\s($::sha1)\s
1863 ([MTCRAD])\d*$/xo) {
1864 push @mods, { mode_a => $1, mode_b => $2,
1865 sha1_b => $3, chg => $4 };
1866 if ($4 =~ /^(?:C|R)$/) {
1867 $state = 'file_a';
1868 } else {
1869 $state = 'file_b';
1870 }
1871 } elsif ($state eq 'file_a') {
1872 my $x = $mods[$#mods] or croak "Empty array\n";
1873 if ($x->{chg} !~ /^(?:C|R)$/) {
1874 croak "Error parsing $_, $x->{chg}\n";
1875 }
1876 $x->{file_a} = $_;
1877 $state = 'file_b';
1878 } elsif ($state eq 'file_b') {
1879 my $x = $mods[$#mods] or croak "Empty array\n";
1880 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1881 croak "Error parsing $_, $x->{chg}\n";
1882 }
1883 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1884 croak "Error parsing $_, $x->{chg}\n";
1885 }
1886 $x->{file_b} = $_;
1887 $state = 'meta';
1888 } else {
1889 croak "Error parsing $_\n";
1890 }
1891 }
1892 command_close_pipe($diff_fh, $ctx);
1893 \@mods;
1894 }
1896 sub check_diff_paths {
1897 my ($ra, $pfx, $rev, $mods) = @_;
1898 my %types;
1899 $pfx .= '/' if length $pfx;
1901 sub type_diff_paths {
1902 my ($ra, $types, $path, $rev) = @_;
1903 my @p = split m#/+#, $path;
1904 my $c = shift @p;
1905 unless (defined $types->{$c}) {
1906 $types->{$c} = $ra->check_path($c, $rev);
1907 }
1908 while (@p) {
1909 $c .= '/' . shift @p;
1910 next if defined $types->{$c};
1911 $types->{$c} = $ra->check_path($c, $rev);
1912 }
1913 }
1915 foreach my $m (@$mods) {
1916 foreach my $f (qw/file_a file_b/) {
1917 next unless defined $m->{$f};
1918 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
1919 if (length $pfx.$dir && ! defined $types{$dir}) {
1920 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
1921 }
1922 }
1923 }
1924 \%types;
1925 }
1927 sub split_path {
1928 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1929 }
1931 sub repo_path {
1932 my ($self, $path) = @_;
1933 $self->{path_prefix}.(defined $path ? $path : '');
1934 }
1936 sub url_path {
1937 my ($self, $path) = @_;
1938 $self->{url} . '/' . $self->repo_path($path);
1939 }
1941 sub rmdirs {
1942 my ($self) = @_;
1943 my $rm = $self->{rm};
1944 delete $rm->{''}; # we never delete the url we're tracking
1945 return unless %$rm;
1947 foreach (keys %$rm) {
1948 my @d = split m#/#, $_;
1949 my $c = shift @d;
1950 $rm->{$c} = 1;
1951 while (@d) {
1952 $c .= '/' . shift @d;
1953 $rm->{$c} = 1;
1954 }
1955 }
1956 delete $rm->{$self->{svn_path}};
1957 delete $rm->{''}; # we never delete the url we're tracking
1958 return unless %$rm;
1960 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
1961 $self->{tree_b});
1962 local $/ = "\0";
1963 while (<$fh>) {
1964 chomp;
1965 my @dn = split m#/#, $_;
1966 while (pop @dn) {
1967 delete $rm->{join '/', @dn};
1968 }
1969 unless (%$rm) {
1970 close $fh;
1971 return;
1972 }
1973 }
1974 command_close_pipe($fh, $ctx);
1976 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1977 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1978 $self->close_directory($bat->{$d}, $p);
1979 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1980 print "\tD+\t$d/\n" unless $::_q;
1981 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1982 delete $bat->{$d};
1983 }
1984 }
1986 sub open_or_add_dir {
1987 my ($self, $full_path, $baton) = @_;
1988 my $t = $self->{types}->{$full_path};
1989 if (!defined $t) {
1990 die "$full_path not known in r$self->{r} or we have a bug!\n";
1991 }
1992 if ($t == $SVN::Node::none) {
1993 return $self->add_directory($full_path, $baton,
1994 undef, -1, $self->{pool});
1995 } elsif ($t == $SVN::Node::dir) {
1996 return $self->open_directory($full_path, $baton,
1997 $self->{r}, $self->{pool});
1998 }
1999 print STDERR "$full_path already exists in repository at ",
2000 "r$self->{r} and it is not a directory (",
2001 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2002 exit 1;
2003 }
2005 sub ensure_path {
2006 my ($self, $path) = @_;
2007 my $bat = $self->{bat};
2008 my $repo_path = $self->repo_path($path);
2009 return $bat->{''} unless (length $repo_path);
2010 my @p = split m#/+#, $repo_path;
2011 my $c = shift @p;
2012 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2013 while (@p) {
2014 my $c0 = $c;
2015 $c .= '/' . shift @p;
2016 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2017 }
2018 return $bat->{$c};
2019 }
2021 sub A {
2022 my ($self, $m) = @_;
2023 my ($dir, $file) = split_path($m->{file_b});
2024 my $pbat = $self->ensure_path($dir);
2025 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2026 undef, -1);
2027 print "\tA\t$m->{file_b}\n" unless $::_q;
2028 $self->chg_file($fbat, $m);
2029 $self->close_file($fbat,undef,$self->{pool});
2030 }
2032 sub C {
2033 my ($self, $m) = @_;
2034 my ($dir, $file) = split_path($m->{file_b});
2035 my $pbat = $self->ensure_path($dir);
2036 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2037 $self->url_path($m->{file_a}), $self->{r});
2038 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2039 $self->chg_file($fbat, $m);
2040 $self->close_file($fbat,undef,$self->{pool});
2041 }
2043 sub delete_entry {
2044 my ($self, $path, $pbat) = @_;
2045 my $rpath = $self->repo_path($path);
2046 my ($dir, $file) = split_path($rpath);
2047 $self->{rm}->{$dir} = 1;
2048 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2049 }
2051 sub R {
2052 my ($self, $m) = @_;
2053 my ($dir, $file) = split_path($m->{file_b});
2054 my $pbat = $self->ensure_path($dir);
2055 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2056 $self->url_path($m->{file_a}), $self->{r});
2057 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2058 $self->chg_file($fbat, $m);
2059 $self->close_file($fbat,undef,$self->{pool});
2061 ($dir, $file) = split_path($m->{file_a});
2062 $pbat = $self->ensure_path($dir);
2063 $self->delete_entry($m->{file_a}, $pbat);
2064 }
2066 sub M {
2067 my ($self, $m) = @_;
2068 my ($dir, $file) = split_path($m->{file_b});
2069 my $pbat = $self->ensure_path($dir);
2070 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2071 $pbat,$self->{r},$self->{pool});
2072 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2073 $self->chg_file($fbat, $m);
2074 $self->close_file($fbat,undef,$self->{pool});
2075 }
2077 sub T { shift->M(@_) }
2079 sub change_file_prop {
2080 my ($self, $fbat, $pname, $pval) = @_;
2081 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2082 }
2084 sub chg_file {
2085 my ($self, $fbat, $m) = @_;
2086 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2087 $self->change_file_prop($fbat,'svn:executable','*');
2088 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2089 $self->change_file_prop($fbat,'svn:executable',undef);
2090 }
2091 my $fh = IO::File->new_tmpfile or croak $!;
2092 if ($m->{mode_b} =~ /^120/) {
2093 print $fh 'link ' or croak $!;
2094 $self->change_file_prop($fbat,'svn:special','*');
2095 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2096 $self->change_file_prop($fbat,'svn:special',undef);
2097 }
2098 defined(my $pid = fork) or croak $!;
2099 if (!$pid) {
2100 open STDOUT, '>&', $fh or croak $!;
2101 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2102 }
2103 waitpid $pid, 0;
2104 croak $? if $?;
2105 $fh->flush == 0 or croak $!;
2106 seek $fh, 0, 0 or croak $!;
2108 my $md5 = Digest::MD5->new;
2109 $md5->addfile($fh) or croak $!;
2110 seek $fh, 0, 0 or croak $!;
2112 my $exp = $md5->hexdigest;
2113 my $pool = SVN::Pool->new;
2114 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2115 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2116 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2117 $pool->clear;
2119 close $fh or croak $!;
2120 }
2122 sub D {
2123 my ($self, $m) = @_;
2124 my ($dir, $file) = split_path($m->{file_b});
2125 my $pbat = $self->ensure_path($dir);
2126 print "\tD\t$m->{file_b}\n" unless $::_q;
2127 $self->delete_entry($m->{file_b}, $pbat);
2128 }
2130 sub close_edit {
2131 my ($self) = @_;
2132 my ($p,$bat) = ($self->{pool}, $self->{bat});
2133 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2134 $self->close_directory($bat->{$_}, $p);
2135 }
2136 $self->SUPER::close_edit($p);
2137 $p->clear;
2138 }
2140 sub abort_edit {
2141 my ($self) = @_;
2142 $self->SUPER::abort_edit($self->{pool});
2143 }
2145 sub DESTROY {
2146 my $self = shift;
2147 $self->SUPER::DESTROY(@_);
2148 $self->{pool}->clear;
2149 }
2151 # this drives the editor
2152 sub apply_diff {
2153 my ($self) = @_;
2154 my $mods = $self->{mods};
2155 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2156 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2157 my $f = $m->{chg};
2158 if (defined $o{$f}) {
2159 $self->$f($m);
2160 } else {
2161 fatal("Invalid change type: $f\n");
2162 }
2163 }
2164 $self->rmdirs if $::_rmdir;
2165 if (@$mods == 0) {
2166 $self->abort_edit;
2167 } else {
2168 $self->close_edit;
2169 }
2170 return scalar @$mods;
2171 }
2173 package Git::SVN::Ra;
2174 use vars qw/@ISA $config_dir/;
2175 use strict;
2176 use warnings;
2177 my ($can_do_switch);
2178 my %RA;
2180 BEGIN {
2181 # enforce temporary pool usage for some simple functions
2182 my $e;
2183 foreach (qw/get_latest_revnum rev_proplist get_file
2184 check_path get_dir get_uuid get_repos_root/) {
2185 $e .= "sub $_ {
2186 my \$self = shift;
2187 my \$pool = SVN::Pool->new;
2188 my \@ret = \$self->SUPER::$_(\@_,\$pool);
2189 \$pool->clear;
2190 wantarray ? \@ret : \$ret[0]; }\n";
2191 }
2192 eval $e;
2193 }
2195 sub new {
2196 my ($class, $url) = @_;
2197 $url =~ s!/+$!!;
2198 return $RA{$url} if $RA{$url};
2200 SVN::_Core::svn_config_ensure($config_dir, undef);
2201 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2202 SVN::Client::get_simple_provider(),
2203 SVN::Client::get_ssl_server_trust_file_provider(),
2204 SVN::Client::get_simple_prompt_provider(
2205 \&Git::SVN::Prompt::simple, 2),
2206 SVN::Client::get_ssl_client_cert_prompt_provider(
2207 \&Git::SVN::Prompt::ssl_client_cert, 2),
2208 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2209 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2210 SVN::Client::get_username_provider(),
2211 SVN::Client::get_ssl_server_trust_prompt_provider(
2212 \&Git::SVN::Prompt::ssl_server_trust),
2213 SVN::Client::get_username_prompt_provider(
2214 \&Git::SVN::Prompt::username, 2),
2215 ]);
2216 my $config = SVN::Core::config_get_config($config_dir);
2217 my $self = SVN::Ra->new(url => $url, auth => $baton,
2218 config => $config,
2219 pool => SVN::Pool->new,
2220 auth_provider_callbacks => $callbacks);
2221 $self->{svn_path} = $url;
2222 $self->{repos_root} = $self->get_repos_root;
2223 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2224 $RA{$url} = bless $self, $class;
2225 }
2227 sub DESTROY {
2228 # do not call the real DESTROY since we store ourselves in %RA
2229 }
2231 sub get_log {
2232 my ($self, @args) = @_;
2233 my $pool = SVN::Pool->new;
2234 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2235 my $ret = $self->SUPER::get_log(@args, $pool);
2236 $pool->clear;
2237 $ret;
2238 }
2240 sub get_commit_editor {
2241 my ($self, $log, $cb, $pool) = @_;
2242 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2243 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2244 }
2246 sub uuid {
2247 my ($self) = @_;
2248 $self->{uuid} ||= $self->get_uuid;
2249 }
2251 sub gs_do_update {
2252 my ($self, $rev_a, $rev_b, $path, $recurse, $editor) = @_;
2253 my $pool = SVN::Pool->new;
2254 $editor->set_path_strip($path);
2255 my (@pc) = split m#/#, $path;
2256 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2257 $recurse, $editor, $pool);
2258 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2260 # Since we can't rely on svn_ra_reparent being available, we'll
2261 # just have to do some magic with set_path to make it so
2262 # we only want a partial path.
2263 my $sp = '';
2264 my $final = join('/', @pc);
2265 while (@pc) {
2266 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2267 $sp .= '/' if length $sp;
2268 $sp .= shift @pc;
2269 }
2270 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2272 my $new = ($rev_a == $rev_b);
2273 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2275 $reporter->finish_report($pool);
2276 $pool->clear;
2277 $editor->{git_commit_ok};
2278 }
2280 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2281 # svn_ra_reparent didn't work before 1.4)
2282 sub gs_do_switch {
2283 my ($self, $rev_a, $rev_b, $path, $recurse, $url_b, $editor) = @_;
2284 my $pool = SVN::Pool->new;
2286 my $full_url = $self->{url};
2287 my $old_url = $full_url;
2288 $full_url .= "/$path" if length $path;
2289 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
2290 $self->{url} = $full_url;
2292 my $reporter = $self->do_switch($rev_b, '',
2293 $recurse, $url_b, $editor, $pool);
2294 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2295 $reporter->set_path('', $rev_a, 0, @lock, $pool);
2296 $reporter->finish_report($pool);
2298 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
2299 $self->{url} = $old_url;
2301 $pool->clear;
2302 $editor->{git_commit_ok};
2303 }
2305 sub gs_fetch_loop_common {
2306 my ($self, $base, $head, @gs) = @_;
2307 my $inc = 1000;
2308 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
2309 my $err_handler = $SVN::Error::handler;
2310 my $err;
2311 $SVN::Error::handler = sub { ($err) = @_; skip_unknown_revs($err); };
2312 my @paths = @gs == 1 ? ($gs[0]->{path}) : ('');
2313 foreach my $gs (@gs) {
2314 if (my $last_commit = $gs->last_commit) {
2315 $gs->assert_index_clean($last_commit);
2316 }
2317 $gs->{path_regex} = qr/^\/\Q$gs->{path}\E\/?/;
2318 }
2319 while (1) {
2320 my @revs;
2321 $self->get_log(\@paths, $min, $max, 0, 1, 1,
2322 sub { push @revs, [ dup_changed_paths($_[0]), $_[1] ]; });
2323 if (! @revs && $err && $max >= $head) {
2324 print STDERR "Branch probably deleted:\n ",
2325 $err->expanded_message,
2326 "\nWill attempt to follow revisions ",
2327 "r$min .. r$max ",
2328 "committed before the deletion\n";
2329 @revs = map { [ undef, $_ ] } ($min .. $max);
2330 }
2331 foreach (@revs) {
2332 my ($paths, $r) = @$_;
2333 foreach my $gs (@gs) {
2334 if ($paths) {
2335 grep /$gs->{path_regex}/, keys %$paths
2336 or next;
2337 }
2338 next if defined $gs->rev_db_get($r);
2339 if (my $log_entry = $gs->do_fetch($paths, $r)) {
2340 $gs->do_git_commit($log_entry);
2341 }
2342 }
2343 }
2344 last if $max >= $head;
2345 $min = $max + 1;
2346 $max += $inc;
2347 $max = $head if ($max > $head);
2348 }
2349 $SVN::Error::handler = $err_handler;
2350 }
2352 sub minimize_url {
2353 my ($self) = @_;
2354 return $self->{url} if ($self->{url} eq $self->{repos_root});
2355 my $url = $self->{repos_root};
2356 my @components = split(m!/!, $self->{svn_path});
2357 my $c = '';
2358 do {
2359 $url .= "/$c" if length $c;
2360 eval { (ref $self)->new($url)->get_latest_revnum };
2361 } while ($@ && ($c = shift @components));
2362 $url;
2363 }
2365 sub can_do_switch {
2366 my $self = shift;
2367 unless (defined $can_do_switch) {
2368 my $pool = SVN::Pool->new;
2369 my $rep = eval {
2370 $self->do_switch(1, '', 0, $self->{url},
2371 SVN::Delta::Editor->new, $pool);
2372 };
2373 if ($@) {
2374 $can_do_switch = 0;
2375 } else {
2376 $rep->abort_report($pool);
2377 $can_do_switch = 1;
2378 }
2379 $pool->clear;
2380 }
2381 $can_do_switch;
2382 }
2384 sub skip_unknown_revs {
2385 my ($err) = @_;
2386 my $errno = $err->apr_err();
2387 # Maybe the branch we're tracking didn't
2388 # exist when the repo started, so it's
2389 # not an error if it doesn't, just continue
2390 #
2391 # Wonderfully consistent library, eh?
2392 # 160013 - svn:// and file://
2393 # 175002 - http(s)://
2394 # 175007 - http(s):// (this repo required authorization, too...)
2395 # More codes may be discovered later...
2396 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2397 return;
2398 }
2399 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2400 }
2402 # svn_log_changed_path_t objects passed to get_log are likely to be
2403 # overwritten even if only the refs are copied to an external variable,
2404 # so we should dup the structures in their entirety. Using an externally
2405 # passed pool (instead of our temporary and quickly cleared pool in
2406 # Git::SVN::Ra) does not help matters at all...
2407 sub dup_changed_paths {
2408 my ($paths) = @_;
2409 return undef unless $paths;
2410 my %ret;
2411 foreach my $p (keys %$paths) {
2412 my $i = $paths->{$p};
2413 my %s = map { $_ => $i->$_ }
2414 qw/copyfrom_path copyfrom_rev action/;
2415 $ret{$p} = \%s;
2416 }
2417 \%ret;
2418 }
2420 package Git::SVN::Log;
2421 use strict;
2422 use warnings;
2423 use POSIX qw/strftime/;
2424 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2425 %rusers $show_commit $incremental/;
2426 my $l_fmt;
2428 sub cmt_showable {
2429 my ($c) = @_;
2430 return 1 if defined $c->{r};
2431 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2432 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2433 my @log = command(qw/cat-file commit/, $c->{c});
2434 shift @log while ($log[0] ne "\n");
2435 shift @log;
2436 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2438 (undef, $c->{r}, undef) = ::extract_metadata(
2439 (grep(/^git-svn-id: /, @log))[-1]);
2440 }
2441 return defined $c->{r};
2442 }
2444 sub log_use_color {
2445 return 1 if $color;
2446 my ($dc, $dcvar);
2447 $dcvar = 'color.diff';
2448 $dc = `git-config --get $dcvar`;
2449 if ($dc eq '') {
2450 # nothing at all; fallback to "diff.color"
2451 $dcvar = 'diff.color';
2452 $dc = `git-config --get $dcvar`;
2453 }
2454 chomp($dc);
2455 if ($dc eq 'auto') {
2456 my $pc;
2457 $pc = `git-config --get color.pager`;
2458 if ($pc eq '') {
2459 # does not have it -- fallback to pager.color
2460 $pc = `git-config --bool --get pager.color`;
2461 }
2462 else {
2463 $pc = `git-config --bool --get color.pager`;
2464 if ($?) {
2465 $pc = 'false';
2466 }
2467 }
2468 chomp($pc);
2469 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2470 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2471 }
2472 return 0;
2473 }
2474 return 0 if $dc eq 'never';
2475 return 1 if $dc eq 'always';
2476 chomp($dc = `git-config --bool --get $dcvar`);
2477 return ($dc eq 'true');
2478 }
2480 sub git_svn_log_cmd {
2481 my ($r_min, $r_max) = @_;
2482 my $gs = Git::SVN->_new;
2483 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2484 $gs->refname);
2485 push @cmd, '-r' unless $non_recursive;
2486 push @cmd, qw/--raw --name-status/ if $verbose;
2487 push @cmd, '--color' if log_use_color();
2488 return @cmd unless defined $r_max;
2489 if ($r_max == $r_min) {
2490 push @cmd, '--max-count=1';
2491 if (my $c = $gs->rev_db_get($r_max)) {
2492 push @cmd, $c;
2493 }
2494 } else {
2495 my ($c_min, $c_max);
2496 $c_max = $gs->rev_db_get($r_max);
2497 $c_min = $gs->rev_db_get($r_min);
2498 if (defined $c_min && defined $c_max) {
2499 if ($r_max > $r_max) {
2500 push @cmd, "$c_min..$c_max";
2501 } else {
2502 push @cmd, "$c_max..$c_min";
2503 }
2504 } elsif ($r_max > $r_min) {
2505 push @cmd, $c_max;
2506 } else {
2507 push @cmd, $c_min;
2508 }
2509 }
2510 return @cmd;
2511 }
2513 # adapted from pager.c
2514 sub config_pager {
2515 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2516 if (!defined $pager) {
2517 $pager = 'less';
2518 } elsif (length $pager == 0 || $pager eq 'cat') {
2519 $pager = undef;
2520 }
2521 }
2523 sub run_pager {
2524 return unless -t *STDOUT;
2525 pipe my $rfd, my $wfd or return;
2526 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2527 if (!$pid) {
2528 open STDOUT, '>&', $wfd or
2529 ::fatal "Can't redirect to stdout: $!\n";
2530 return;
2531 }
2532 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2533 $ENV{LESS} ||= 'FRSX';
2534 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2535 }
2537 sub tz_to_s_offset {
2538 my ($tz) = @_;
2539 $tz =~ s/(\d\d)$//;
2540 return ($1 * 60) + ($tz * 3600);
2541 }
2543 sub get_author_info {
2544 my ($dest, $author, $t, $tz) = @_;
2545 $author =~ s/(?:^\s*|\s*$)//g;
2546 $dest->{a_raw} = $author;
2547 my $au;
2548 if ($::_authors) {
2549 $au = $rusers{$author} || undef;
2550 }
2551 if (!$au) {
2552 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2553 }
2554 $dest->{t} = $t;
2555 $dest->{tz} = $tz;
2556 $dest->{a} = $au;
2557 # Date::Parse isn't in the standard Perl distro :(
2558 if ($tz =~ s/^\+//) {
2559 $t += tz_to_s_offset($tz);
2560 } elsif ($tz =~ s/^\-//) {
2561 $t -= tz_to_s_offset($tz);
2562 }
2563 $dest->{t_utc} = $t;
2564 }
2566 sub process_commit {
2567 my ($c, $r_min, $r_max, $defer) = @_;
2568 if (defined $r_min && defined $r_max) {
2569 if ($r_min == $c->{r} && $r_min == $r_max) {
2570 show_commit($c);
2571 return 0;
2572 }
2573 return 1 if $r_min == $r_max;
2574 if ($r_min < $r_max) {
2575 # we need to reverse the print order
2576 return 0 if (defined $limit && --$limit < 0);
2577 push @$defer, $c;
2578 return 1;
2579 }
2580 if ($r_min != $r_max) {
2581 return 1 if ($r_min < $c->{r});
2582 return 1 if ($r_max > $c->{r});
2583 }
2584 }
2585 return 0 if (defined $limit && --$limit < 0);
2586 show_commit($c);
2587 return 1;
2588 }
2590 sub show_commit {
2591 my $c = shift;
2592 if ($oneline) {
2593 my $x = "\n";
2594 if (my $l = $c->{l}) {
2595 while ($l->[0] =~ /^\s*$/) { shift @$l }
2596 $x = $l->[0];
2597 }
2598 $l_fmt ||= 'A' . length($c->{r});
2599 print 'r',pack($l_fmt, $c->{r}),' | ';
2600 print "$c->{c} | " if $show_commit;
2601 print $x;
2602 } else {
2603 show_commit_normal($c);
2604 }
2605 }
2607 sub show_commit_changed_paths {
2608 my ($c) = @_;
2609 return unless $c->{changed};
2610 print "Changed paths:\n", @{$c->{changed}};
2611 }
2613 sub show_commit_normal {
2614 my ($c) = @_;
2615 print '-' x72, "\nr$c->{r} | ";
2616 print "$c->{c} | " if $show_commit;
2617 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2618 localtime($c->{t_utc})), ' | ';
2619 my $nr_line = 0;
2621 if (my $l = $c->{l}) {
2622 while ($l->[$#$l] eq "\n" && $#$l > 0
2623 && $l->[($#$l - 1)] eq "\n") {
2624 pop @$l;
2625 }
2626 $nr_line = scalar @$l;
2627 if (!$nr_line) {
2628 print "1 line\n\n\n";
2629 } else {
2630 if ($nr_line == 1) {
2631 $nr_line = '1 line';
2632 } else {
2633 $nr_line .= ' lines';
2634 }
2635 print $nr_line, "\n";
2636 show_commit_changed_paths($c);
2637 print "\n";
2638 print $_ foreach @$l;
2639 }
2640 } else {
2641 print "1 line\n";
2642 show_commit_changed_paths($c);
2643 print "\n";
2645 }
2646 foreach my $x (qw/raw diff/) {
2647 if ($c->{$x}) {
2648 print "\n";
2649 print $_ foreach @{$c->{$x}}
2650 }
2651 }
2652 }
2654 sub cmd_show_log {
2655 my (@args) = @_;
2656 my ($r_min, $r_max);
2657 my $r_last = -1; # prevent dupes
2658 if (defined $TZ) {
2659 $ENV{TZ} = $TZ;
2660 } else {
2661 delete $ENV{TZ};
2662 }
2663 if (defined $::_revision) {
2664 if ($::_revision =~ /^(\d+):(\d+)$/) {
2665 ($r_min, $r_max) = ($1, $2);
2666 } elsif ($::_revision =~ /^\d+$/) {
2667 $r_min = $r_max = $::_revision;
2668 } else {
2669 ::fatal "-r$::_revision is not supported, use ",
2670 "standard \'git log\' arguments instead\n";
2671 }
2672 }
2674 config_pager();
2675 @args = (git_svn_log_cmd($r_min, $r_max), @args);
2676 my $log = command_output_pipe(@args);
2677 run_pager();
2678 my (@k, $c, $d);
2679 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2680 while (<$log>) {
2681 if (/^${esc_color}commit ($::sha1_short)/o) {
2682 my $cmt = $1;
2683 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2684 $r_last = $c->{r};
2685 process_commit($c, $r_min, $r_max, \@k) or
2686 goto out;
2687 }
2688 $d = undef;
2689 $c = { c => $cmt };
2690 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2691 get_author_info($c, $1, $2, $3);
2692 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2693 # ignore
2694 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2695 push @{$c->{raw}}, $_;
2696 } elsif (/^${esc_color}[ACRMDT]\t/) {
2697 # we could add $SVN->{svn_path} here, but that requires
2698 # remote access at the moment (repo_path_split)...
2699 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
2700 push @{$c->{changed}}, $_;
2701 } elsif (/^${esc_color}diff /o) {
2702 $d = 1;
2703 push @{$c->{diff}}, $_;
2704 } elsif ($d) {
2705 push @{$c->{diff}}, $_;
2706 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
2707 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2708 } elsif (s/^${esc_color} //o) {
2709 push @{$c->{l}}, $_;
2710 }
2711 }
2712 if ($c && defined $c->{r} && $c->{r} != $r_last) {
2713 $r_last = $c->{r};
2714 process_commit($c, $r_min, $r_max, \@k);
2715 }
2716 if (@k) {
2717 my $swap = $r_max;
2718 $r_max = $r_min;
2719 $r_min = $swap;
2720 process_commit($_, $r_min, $r_max) foreach reverse @k;
2721 }
2722 out:
2723 close $log;
2724 print '-' x72,"\n" unless $incremental || $oneline;
2725 }
2727 package Git::SVN::Migration;
2728 # these version numbers do NOT correspond to actual version numbers
2729 # of git nor git-svn. They are just relative.
2730 #
2731 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2732 #
2733 # v1 layout: .git/$id/info/url, refs/remotes/$id
2734 #
2735 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2736 #
2737 # v3 layout: .git/svn/$id, refs/remotes/$id
2738 # - info/url may remain for backwards compatibility
2739 # - this is what we migrate up to this layout automatically,
2740 # - this will be used by git svn init on single branches
2741 #
2742 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2743 # - this is only created for newly multi-init-ed
2744 # repositories. Similar in spirit to the
2745 # --use-separate-remotes option in git-clone (now default)
2746 # - we do not automatically migrate to this (following
2747 # the example set by core git)
2748 use strict;
2749 use warnings;
2750 use Carp qw/croak/;
2751 use File::Path qw/mkpath/;
2752 use File::Basename qw/dirname basename/;
2753 use vars qw/$_minimize/;
2755 sub migrate_from_v0 {
2756 my $git_dir = $ENV{GIT_DIR};
2757 return undef unless -d $git_dir;
2758 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2759 my $migrated = 0;
2760 while (<$fh>) {
2761 chomp;
2762 my ($id, $orig_ref) = ($_, $_);
2763 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2764 next unless -f "$git_dir/$id/info/url";
2765 my $new_ref = "refs/remotes/$id";
2766 if (::verify_ref("$new_ref^0")) {
2767 print STDERR "W: $orig_ref is probably an old ",
2768 "branch used by an ancient version of ",
2769 "git-svn.\n",
2770 "However, $new_ref also exists.\n",
2771 "We will not be able ",
2772 "to use this branch until this ",
2773 "ambiguity is resolved.\n";
2774 next;
2775 }
2776 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2777 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2778 command_noisy('update-ref', $new_ref, $orig_ref);
2779 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2780 $migrated++;
2781 }
2782 command_close_pipe($fh, $ctx);
2783 print STDERR "Done migrating from v0 layout...\n" if $migrated;
2784 $migrated;
2785 }
2787 sub migrate_from_v1 {
2788 my $git_dir = $ENV{GIT_DIR};
2789 my $migrated = 0;
2790 return $migrated unless -d $git_dir;
2791 my $svn_dir = "$git_dir/svn";
2793 # just in case somebody used 'svn' as their $id at some point...
2794 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2796 print STDERR "Migrating from a git-svn v1 layout...\n";
2797 mkpath([$svn_dir]);
2798 print STDERR "Data from a previous version of git-svn exists, but\n\t",
2799 "$svn_dir\n\t(required for this version ",
2800 "($::VERSION) of git-svn) does not. exist\n";
2801 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2802 while (<$fh>) {
2803 my $x = $_;
2804 next unless $x =~ s#^refs/remotes/##;
2805 chomp $x;
2806 next unless -f "$git_dir/$x/info/url";
2807 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2808 next unless $u;
2809 my $dn = dirname("$git_dir/svn/$x");
2810 mkpath([$dn]) unless -d $dn;
2811 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2812 mkpath(["$git_dir/svn/svn"]);
2813 print STDERR " - $git_dir/$x/info => ",
2814 "$git_dir/svn/$x/info\n";
2815 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2816 croak "$!: $x";
2817 # don't worry too much about these, they probably
2818 # don't exist with repos this old (save for index,
2819 # and we can easily regenerate that)
2820 foreach my $f (qw/unhandled.log index .rev_db/) {
2821 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2822 }
2823 } else {
2824 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2825 rename "$git_dir/$x", "$git_dir/svn/$x" or
2826 croak "$!: $x";
2827 }
2828 $migrated++;
2829 }
2830 command_close_pipe($fh, $ctx);
2831 print STDERR "Done migrating from a git-svn v1 layout\n";
2832 $migrated;
2833 }
2835 sub read_old_urls {
2836 my ($l_map, $pfx, $path) = @_;
2837 my @dir;
2838 foreach (<$path/*>) {
2839 if (-r "$_/info/url") {
2840 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2841 my $ref_id = $pfx . basename $_;
2842 my $url = ::file_to_s("$_/info/url");
2843 $l_map->{$ref_id} = $url;
2844 } elsif (-d $_) {
2845 push @dir, $_;
2846 }
2847 }
2848 foreach (@dir) {
2849 my $x = $_;
2850 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2851 read_old_urls($l_map, $x, $_);
2852 }
2853 }
2855 sub migrate_from_v2 {
2856 my @cfg = command(qw/config -l/);
2857 return if grep /^svn-remote\..+\.url=/, @cfg;
2858 my %l_map;
2859 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2860 my $migrated = 0;
2862 foreach my $ref_id (sort keys %l_map) {
2863 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2864 $migrated++;
2865 }
2866 $migrated;
2867 }
2869 sub minimize_connections {
2870 my $r = Git::SVN::read_all_remotes();
2871 my $new_urls = {};
2872 my $root_repos = {};
2873 foreach my $repo_id (keys %$r) {
2874 my $url = $r->{$repo_id}->{url} or next;
2875 my $fetch = $r->{$repo_id}->{fetch} or next;
2876 my $ra = Git::SVN::Ra->new($url);
2878 # skip existing cases where we already connect to the root
2879 if (($ra->{url} eq $ra->{repos_root}) ||
2880 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2881 $repo_id)) {
2882 $root_repos->{$ra->{url}} = $repo_id;
2883 next;
2884 }
2886 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2887 my $root_path = $ra->{url};
2888 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2889 foreach my $path (keys %$fetch) {
2890 my $ref_id = $fetch->{$path};
2891 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2893 # make sure we can read when connecting to
2894 # a higher level of a repository
2895 my ($last_rev, undef) = $gs->last_rev_commit;
2896 if (!defined $last_rev) {
2897 $last_rev = eval {
2898 $root_ra->get_latest_revnum;
2899 };
2900 next if $@;
2901 }
2902 my $new = $root_path;
2903 $new .= length $path ? "/$path" : '';
2904 eval {
2905 $root_ra->get_log([$new], $last_rev, $last_rev,
2906 0, 0, 1, sub { });
2907 };
2908 next if $@;
2909 $new_urls->{$ra->{repos_root}}->{$new} =
2910 { ref_id => $ref_id,
2911 old_repo_id => $repo_id,
2912 old_path => $path };
2913 }
2914 }
2916 my @emptied;
2917 foreach my $url (keys %$new_urls) {
2918 # see if we can re-use an existing [svn-remote "repo_id"]
2919 # instead of creating a(n ugly) new section:
2920 my $repo_id = $root_repos->{$url} ||
2921 Git::SVN::sanitize_remote_name($url);
2923 my $fetch = $new_urls->{$url};
2924 foreach my $path (keys %$fetch) {
2925 my $x = $fetch->{$path};
2926 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2927 my $pfx = "svn-remote.$x->{old_repo_id}";
2929 my $old_fetch = quotemeta("$x->{old_path}:".
2930 "refs/remotes/$x->{ref_id}");
2931 command_noisy(qw/config --unset/,
2932 "$pfx.fetch", '^'. $old_fetch . '$');
2933 delete $r->{$x->{old_repo_id}}->
2934 {fetch}->{$x->{old_path}};
2935 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2936 command_noisy(qw/config --unset/,
2937 "$pfx.url");
2938 push @emptied, $x->{old_repo_id}
2939 }
2940 }
2941 }
2942 if (@emptied) {
2943 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2944 "$ENV{GIT_DIR}/config";
2945 print STDERR <<EOF;
2946 The following [svn-remote] sections in your config file ($file) are empty
2947 and can be safely removed:
2948 EOF
2949 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2950 }
2951 }
2953 sub migration_check {
2954 migrate_from_v0();
2955 migrate_from_v1();
2956 migrate_from_v2();
2957 minimize_connections() if $_minimize;
2958 }
2960 package Git::IndexInfo;
2961 use strict;
2962 use warnings;
2963 use Git qw/command_input_pipe command_close_pipe/;
2965 sub new {
2966 my ($class) = @_;
2967 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2968 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2969 }
2971 sub remove {
2972 my ($self, $path) = @_;
2973 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2974 return ++$self->{nr};
2975 }
2976 undef;
2977 }
2979 sub update {
2980 my ($self, $mode, $hash, $path) = @_;
2981 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2982 return ++$self->{nr};
2983 }
2984 undef;
2985 }
2987 sub DESTROY {
2988 my ($self) = @_;
2989 command_close_pipe($self->{gui}, $self->{ctx});
2990 }
2992 __END__
2994 Data structures:
2996 $log_entry hashref as returned by libsvn_log_entry()
2997 {
2998 log => 'whitespace-formatted log entry
2999 ', # trailing newline is preserved
3000 revision => '8', # integer
3001 date => '2004-02-24T17:01:44.108345Z', # commit date
3002 author => 'committer name'
3003 };
3006 # this is generated by generate_diff();
3007 @mods = array of diff-index line hashes, each element represents one line
3008 of diff-index output
3010 diff-index line ($m hash)
3011 {
3012 mode_a => first column of diff-index output, no leading ':',
3013 mode_b => second column of diff-index output,
3014 sha1_b => sha1sum of the final blob,
3015 chg => change type [MCRADT],
3016 file_a => original file name of a file (iff chg is 'C' or 'R')
3017 file_b => new/current file name of a file (any chg)
3018 }
3019 ;
3021 # retval of read_url_paths{,_all}();
3022 $l_map = {
3023 # repository root url
3024 'https://svn.musicpd.org' => {
3025 # repository path # GIT_SVN_ID
3026 'mpd/trunk' => 'trunk',
3027 'mpd/tags/0.11.5' => 'tags/0.11.5',
3028 },
3029 }
3031 Notes:
3032 I don't trust the each() function on unless I created %hash myself
3033 because the internal iterator may not have started at base.