git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  13 $ENV{GIT_DIR} ||= '.git';
  14 $Git::SVN::default_repo_id = 'svn';
  15 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  16 $Git::SVN::Ra::_log_window_size = 100;
  17
  18 $Git::SVN::Log::TZ = $ENV{TZ};
  19 $ENV{TZ} = 'UTC';
  20 $| = 1; # unbuffer STDOUT
  21
  22 sub fatal (@) { print STDERR @_; exit 1 }
  23 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  24 require SVN::Ra;
  25 require SVN::Delta;
  26 if ($SVN::Core::VERSION lt '1.1.0') {
  27         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  28 }
  29 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  30 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  31 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  32 use Carp qw/croak/;
  33 use IO::File qw//;
  34 use File::Basename qw/dirname basename/;
  35 use File::Path qw/mkpath/;
  36 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  37 use IPC::Open3;
  38 use Git;
  39
  40 BEGIN {
  41         my $s;
  42         foreach (qw/command command_oneline command_noisy command_output_pipe
  43                     command_input_pipe command_close_pipe/) {
  44                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  45                       "*Git::SVN::Migration::$_ = ".
  46                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  47         }
  48         eval $s;
  49 }
  50
  51 my ($SVN);
  52
  53 $sha1 = qr/[a-f\d]{40}/;
  54 $sha1_short = qr/[a-f\d]{4,40}/;
  55 my ($_stdin, $_help, $_edit,
  56         $_message, $_file,
  57         $_template, $_shared,
  58         $_version, $_fetch_all, $_no_rebase,
  59         $_merge, $_strategy, $_dry_run, $_local,
  60         $_prefix, $_no_checkout, $_verbose);
  61 $Git::SVN::_follow_parent = 1;
  62 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  63                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  64                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  65 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  66                 'authors-file|A=s' => \$_authors,
  67                 'repack:i' => \$Git::SVN::_repack,
  68                 'noMetadata' => \$Git::SVN::_no_metadata,
  69                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  70                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  71                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  72                 'no-checkout' => \$_no_checkout,
  73                 'quiet|q' => \$_q,
  74                 'repack-flags|repack-args|repack-opts=s' =>
  75                    \$Git::SVN::_repack_flags,
  76                 %remote_opts );
  77
  78 my ($_trunk, $_tags, $_branches);
  79 my %icv;
  80 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  81                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  82                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  83                   'minimize-url|m' => \$Git::SVN::_minimize_url,
  84                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  85                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  86                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  87                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  88                   %remote_opts );
  89 my %cmt_opts = ( 'edit|e' => \$_edit,
  90                 'rmdir' => \$SVN::Git::Editor::_rmdir,
  91                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
  92                 'l=i' => \$SVN::Git::Editor::_rename_limit,
  93                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
  94 );
  95
  96 my %cmd = (
  97         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  98                         { 'revision|r=s' => \$_revision,
  99                           'fetch-all|all' => \$_fetch_all,
 100                            %fc_opts } ],
 101         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 102                         { 'revision|r=s' => \$_revision,
 103                            %fc_opts, %init_opts } ],
 104         init => [ \&cmd_init, "Initialize a repo for tracking" .
 105                           " (requires URL argument)",
 106                           \%init_opts ],
 107         'multi-init' => [ \&cmd_multi_init,
 108                           "Deprecated alias for ".
 109                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 110                           \%init_opts ],
 111         dcommit => [ \&cmd_dcommit,
 112                      'Commit several diffs to merge with upstream',
 113                         { 'merge|m|M' => \$_merge,
 114                           'strategy|s=s' => \$_strategy,
 115                           'verbose|v' => \$_verbose,
 116                           'dry-run|n' => \$_dry_run,
 117                           'fetch-all|all' => \$_fetch_all,
 118                           'no-rebase' => \$_no_rebase,
 119                         %cmt_opts, %fc_opts } ],
 120         'set-tree' => [ \&cmd_set_tree,
 121                         "Set an SVN repository to a git tree-ish",
 122                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 123         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 124                         { 'revision|r=i' => \$_revision } ],
 125         'multi-fetch' => [ \&cmd_multi_fetch,
 126                            "Deprecated alias for $0 fetch --all",
 127                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 128         'migrate' => [ sub { },
 129                        # no-op, we automatically run this anyways,
 130                        'Migrate configuration/metadata/layout from
 131                         previous versions of git-svn',
 132                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 133                          %remote_opts } ],
 134         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 135                         { 'limit=i' => \$Git::SVN::Log::limit,
 136                           'revision|r=s' => \$_revision,
 137                           'verbose|v' => \$Git::SVN::Log::verbose,
 138                           'incremental' => \$Git::SVN::Log::incremental,
 139                           'oneline' => \$Git::SVN::Log::oneline,
 140                           'show-commit' => \$Git::SVN::Log::show_commit,
 141                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 142                           'authors-file|A=s' => \$_authors,
 143                           'color' => \$Git::SVN::Log::color,
 144                           'pager=s' => \$Git::SVN::Log::pager,
 145                         } ],
 146         'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
 147                         { } ],
 148         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 149                         { 'merge|m|M' => \$_merge,
 150                           'verbose|v' => \$_verbose,
 151                           'strategy|s=s' => \$_strategy,
 152                           'local|l' => \$_local,
 153                           'fetch-all|all' => \$_fetch_all,
 154                           %fc_opts } ],
 155         'commit-diff' => [ \&cmd_commit_diff,
 156                            'Commit a diff between two trees',
 157                         { 'message|m=s' => \$_message,
 158                           'file|F=s' => \$_file,
 159                           'revision|r=s' => \$_revision,
 160                         %cmt_opts } ],
 161 );
 162
 163 my $cmd;
 164 for (my $i = 0; $i < @ARGV; $i++) {
 165         if (defined $cmd{$ARGV[$i]}) {
 166                 $cmd = $ARGV[$i];
 167                 splice @ARGV, $i, 1;
 168                 last;
 169         }
 170 };
 171
 172 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 173
 174 read_repo_config(\%opts);
 175 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 176 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 177                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 178                     'id|i=s' => \$Git::SVN::default_ref_id,
 179                     'svn-remote|remote|R=s' => sub {
 180                        $Git::SVN::no_reuse_existing = 1;
 181                        $Git::SVN::default_repo_id = $_[1] });
 182 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 183
 184 usage(0) if $_help;
 185 version() if $_version;
 186 usage(1) unless defined $cmd;
 187 load_authors() if $_authors;
 188
 189 # make sure we're always running
 190 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
 191         unless (-d $ENV{GIT_DIR}) {
 192                 if ($git_dir_user_set) {
 193                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 194                             "but it is not a directory\n";
 195                 }
 196                 my $git_dir = delete $ENV{GIT_DIR};
 197                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 198                 unless (length $cdup) {
 199                         die "Already at toplevel, but $git_dir ",
 200                             "not found '$cdup'\n";
 201                 }
 202                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 203                 unless (-d $git_dir) {
 204                         die "$git_dir still not found after going to ",
 205                             "'$cdup'\n";
 206                 }
 207                 $ENV{GIT_DIR} = $git_dir;
 208         }
 209 }
 210 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 211         Git::SVN::Migration::migration_check();
 212 }
 213 Git::SVN::init_vars();
 214 eval {
 215         Git::SVN::verify_remotes_sanity();
 216         $cmd{$cmd}->[0]->(@ARGV);
 217 };
 218 fatal $@ if $@;
 219 post_fetch_checkout();
 220 exit 0;
 221
 222 ####################### primary functions ######################
 223 sub usage {
 224         my $exit = shift || 0;
 225         my $fd = $exit ? \*STDERR : \*STDOUT;
 226         print $fd <<"";
 227 git-svn - bidirectional operations between a single Subversion tree and git
 228 Usage: $0 <command> [options] [arguments]\n
 229
 230         print $fd "Available commands:\n" unless $cmd;
 231
 232         foreach (sort keys %cmd) {
 233                 next if $cmd && $cmd ne $_;
 234                 next if /^multi-/; # don't show deprecated commands
 235                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 236                 foreach (keys %{$cmd{$_}->[2]}) {
 237                         # mixed-case options are for .git/config only
 238                         next if /[A-Z]/ && /^[a-z]+$/i;
 239                         # prints out arguments as they should be passed:
 240                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 241                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 242                                                         "--$_" : "-$_" }
 243                                                 split /\|/,$_)," $x\n";
 244                 }
 245         }
 246         print $fd <<"";
 247 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 248 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 249 one git repository and want to keep them separate.  See git-svn(1) for more
 250 information.
 251
 252         exit $exit;
 253 }
 254
 255 sub version {
 256         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 257         exit 0;
 258 }
 259
 260 sub do_git_init_db {
 261         unless (-d $ENV{GIT_DIR}) {
 262                 my @init_db = ('init');
 263                 push @init_db, "--template=$_template" if defined $_template;
 264                 if (defined $_shared) {
 265                         if ($_shared =~ /[a-z]/) {
 266                                 push @init_db, "--shared=$_shared";
 267                         } else {
 268                                 push @init_db, "--shared";
 269                         }
 270                 }
 271                 command_noisy(@init_db);
 272         }
 273         my $set;
 274         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 275         foreach my $i (keys %icv) {
 276                 die "'$set' and '$i' cannot both be set\n" if $set;
 277                 next unless defined $icv{$i};
 278                 command_noisy('config', "$pfx.$i", $icv{$i});
 279                 $set = $i;
 280         }
 281 }
 282
 283 sub init_subdir {
 284         my $repo_path = shift or return;
 285         mkpath([$repo_path]) unless -d $repo_path;
 286         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 287         $ENV{GIT_DIR} = '.git';
 288 }
 289
 290 sub cmd_clone {
 291         my ($url, $path) = @_;
 292         if (!defined $path &&
 293             (defined $_trunk || defined $_branches || defined $_tags) &&
 294             $url !~ m#^[a-z\+]+://#) {
 295                 $path = $url;
 296         }
 297         $path = basename($url) if !defined $path || !length $path;
 298         cmd_init($url, $path);
 299         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 300 }
 301
 302 sub cmd_init {
 303         if (defined $_trunk || defined $_branches || defined $_tags) {
 304                 return cmd_multi_init(@_);
 305         }
 306         my $url = shift or die "SVN repository location required ",
 307                                "as a command-line argument\n";
 308         init_subdir(@_);
 309         do_git_init_db();
 310
 311         Git::SVN->init($url);
 312 }
 313
 314 sub cmd_fetch {
 315         if (grep /^\d+=./, @_) {
 316                 die "'<rev>=<commit>' fetch arguments are ",
 317                     "no longer supported.\n";
 318         }
 319         my ($remote) = @_;
 320         if (@_ > 1) {
 321                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 322         }
 323         $remote ||= $Git::SVN::default_repo_id;
 324         if ($_fetch_all) {
 325                 cmd_multi_fetch();
 326         } else {
 327                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 328         }
 329 }
 330
 331 sub cmd_set_tree {
 332         my (@commits) = @_;
 333         if ($_stdin || !@commits) {
 334                 print "Reading from stdin...\n";
 335                 @commits = ();
 336                 while (<STDIN>) {
 337                         if (/\b($sha1_short)\b/o) {
 338                                 unshift @commits, $1;
 339                         }
 340                 }
 341         }
 342         my @revs;
 343         foreach my $c (@commits) {
 344                 my @tmp = command('rev-parse',$c);
 345                 if (scalar @tmp == 1) {
 346                         push @revs, $tmp[0];
 347                 } elsif (scalar @tmp > 1) {
 348                         push @revs, reverse(command('rev-list',@tmp));
 349                 } else {
 350                         fatal "Failed to rev-parse $c\n";
 351                 }
 352         }
 353         my $gs = Git::SVN->new;
 354         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 355         $gs->fetch;
 356         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 357                 fatal "There are new revisions that were fetched ",
 358                       "and need to be merged (or acknowledged) ",
 359                       "before committing.\nlast rev: $r_last\n",
 360                       " current: $gs->{last_rev}\n";
 361         }
 362         $gs->set_tree($_) foreach @revs;
 363         print "Done committing ",scalar @revs," revisions to SVN\n";
 364 }
 365
 366 sub cmd_dcommit {
 367         my $head = shift;
 368         $head ||= 'HEAD';
 369         my @refs;
 370         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 371         unless ($gs) {
 372                 die "Unable to determine upstream SVN information from ",
 373                     "$head history\n";
 374         }
 375         my $c = $refs[-1];
 376         my $last_rev;
 377         foreach my $d (@refs) {
 378                 if (!verify_ref("$d~1")) {
 379                         fatal "Commit $d\n",
 380                               "has no parent commit, and therefore ",
 381                               "nothing to diff against.\n",
 382                               "You should be working from a repository ",
 383                               "originally created by git-svn\n";
 384                 }
 385                 unless (defined $last_rev) {
 386                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 387                         unless (defined $last_rev) {
 388                                 fatal "Unable to extract revision information ",
 389                                       "from commit $d~1\n";
 390                         }
 391                 }
 392                 if ($_dry_run) {
 393                         print "diff-tree $d~1 $d\n";
 394                 } else {
 395                         my %ed_opts = ( r => $last_rev,
 396                                         log => get_commit_entry($d)->{log},
 397                                         ra => Git::SVN::Ra->new($gs->full_url),
 398                                         tree_a => "$d~1",
 399                                         tree_b => $d,
 400                                         editor_cb => sub {
 401                                                print "Committed r$_[0]\n";
 402                                                $last_rev = $_[0]; },
 403                                         svn_path => '');
 404                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 405                                 print "No changes\n$d~1 == $d\n";
 406                         }
 407                 }
 408         }
 409         return if $_dry_run;
 410         unless ($gs) {
 411                 warn "Could not determine fetch information for $url\n",
 412                      "Will not attempt to fetch and rebase commits.\n",
 413                      "This probably means you have useSvmProps and should\n",
 414                      "now resync your SVN::Mirror repository.\n";
 415                 return;
 416         }
 417         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 418         unless ($_no_rebase) {
 419                 # we always want to rebase against the current HEAD, not any
 420                 # head that was passed to us
 421                 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 422                 my @finish;
 423                 if (@diff) {
 424                         @finish = rebase_cmd();
 425                         print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 426                                      "using @finish:\n", "@diff";
 427                 } else {
 428                         print "No changes between current HEAD and ",
 429                               $gs->refname, "\nResetting to the latest ",
 430                               $gs->refname, "\n";
 431                         @finish = qw/reset --mixed/;
 432                 }
 433                 command_noisy(@finish, $gs->refname);
 434         }
 435 }
 436
 437 sub cmd_find_rev {
 438         my $revision_or_hash = shift;
 439         my $result;
 440         if ($revision_or_hash =~ /^r\d+$/) {
 441                 my $head = shift;
 442                 $head ||= 'HEAD';
 443                 my @refs;
 444                 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
 445                 unless ($gs) {
 446                         die "Unable to determine upstream SVN information from ",
 447                             "$head history\n";
 448                 }
 449                 my $desired_revision = substr($revision_or_hash, 1);
 450                 $result = $gs->rev_db_get($desired_revision);
 451         } else {
 452                 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
 453                 $result = $rev;
 454         }
 455         print "$result\n" if $result;
 456 }
 457
 458 sub cmd_rebase {
 459         command_noisy(qw/update-index --refresh/);
 460         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 461         unless ($gs) {
 462                 die "Unable to determine upstream SVN information from ",
 463                     "working tree history\n";
 464         }
 465         if (command(qw/diff-index HEAD --/)) {
 466                 print STDERR "Cannot rebase with uncommited changes:\n";
 467                 command_noisy('status');
 468                 exit 1;
 469         }
 470         unless ($_local) {
 471                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 472         }
 473         command_noisy(rebase_cmd(), $gs->refname);
 474 }
 475
 476 sub cmd_show_ignore {
 477         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 478         $gs ||= Git::SVN->new;
 479         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 480         $gs->traverse_ignore(\*STDOUT, $gs->{path}, $r);
 481 }
 482
 483 sub cmd_multi_init {
 484         my $url = shift;
 485         unless (defined $_trunk || defined $_branches || defined $_tags) {
 486                 usage(1);
 487         }
 488         $_prefix = '' unless defined $_prefix;
 489         if (defined $url) {
 490                 $url =~ s#/+$##;
 491                 init_subdir(@_);
 492         }
 493         do_git_init_db();
 494         if (defined $_trunk) {
 495                 my $trunk_ref = $_prefix . 'trunk';
 496                 # try both old-style and new-style lookups:
 497                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 498                 unless ($gs_trunk) {
 499                         my ($trunk_url, $trunk_path) =
 500                                               complete_svn_url($url, $_trunk);
 501                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 502                                                    undef, $trunk_ref);
 503                 }
 504         }
 505         return unless defined $_branches || defined $_tags;
 506         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 507         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 508         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 509 }
 510
 511 sub cmd_multi_fetch {
 512         my $remotes = Git::SVN::read_all_remotes();
 513         foreach my $repo_id (sort keys %$remotes) {
 514                 if ($remotes->{$repo_id}->{url}) {
 515                         Git::SVN::fetch_all($repo_id, $remotes);
 516                 }
 517         }
 518 }
 519
 520 # this command is special because it requires no metadata
 521 sub cmd_commit_diff {
 522         my ($ta, $tb, $url) = @_;
 523         my $usage = "Usage: $0 commit-diff -r<revision> ".
 524                     "<tree-ish> <tree-ish> [<URL>]\n";
 525         fatal($usage) if (!defined $ta || !defined $tb);
 526         my $svn_path;
 527         if (!defined $url) {
 528                 my $gs = eval { Git::SVN->new };
 529                 if (!$gs) {
 530                         fatal("Needed URL or usable git-svn --id in ",
 531                               "the command-line\n", $usage);
 532                 }
 533                 $url = $gs->{url};
 534                 $svn_path = $gs->{path};
 535         }
 536         unless (defined $_revision) {
 537                 fatal("-r|--revision is a required argument\n", $usage);
 538         }
 539         if (defined $_message && defined $_file) {
 540                 fatal("Both --message/-m and --file/-F specified ",
 541                       "for the commit message.\n",
 542                       "I have no idea what you mean\n");
 543         }
 544         if (defined $_file) {
 545                 $_message = file_to_s($_file);
 546         } else {
 547                 $_message ||= get_commit_entry($tb)->{log};
 548         }
 549         my $ra ||= Git::SVN::Ra->new($url);
 550         $svn_path ||= $ra->{svn_path};
 551         my $r = $_revision;
 552         if ($r eq 'HEAD') {
 553                 $r = $ra->get_latest_revnum;
 554         } elsif ($r !~ /^\d+$/) {
 555                 die "revision argument: $r not understood by git-svn\n";
 556         }
 557         my %ed_opts = ( r => $r,
 558                         log => $_message,
 559                         ra => $ra,
 560                         tree_a => $ta,
 561                         tree_b => $tb,
 562                         editor_cb => sub { print "Committed r$_[0]\n" },
 563                         svn_path => $svn_path );
 564         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 565                 print "No changes\n$ta == $tb\n";
 566         }
 567 }
 568
 569 ########################### utility functions #########################
 570
 571 sub rebase_cmd {
 572         my @cmd = qw/rebase/;
 573         push @cmd, '-v' if $_verbose;
 574         push @cmd, qw/--merge/ if $_merge;
 575         push @cmd, "--strategy=$_strategy" if $_strategy;
 576         @cmd;
 577 }
 578
 579 sub post_fetch_checkout {
 580         return if $_no_checkout;
 581         my $gs = $Git::SVN::_head or return;
 582         return if verify_ref('refs/heads/master^0');
 583
 584         my $valid_head = verify_ref('HEAD^0');
 585         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 586         return if ($valid_head || !verify_ref('HEAD^0'));
 587
 588         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 589         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 590         return if -f $index;
 591
 592         chomp(my $bare = `git config --bool --get core.bare`);
 593         return if $bare eq 'true';
 594         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 595         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 596         print STDERR "Checked out HEAD:\n  ",
 597                      $gs->full_url, " r", $gs->last_rev, "\n";
 598 }
 599
 600 sub complete_svn_url {
 601         my ($url, $path) = @_;
 602         $path =~ s#/+$##;
 603         if ($path !~ m#^[a-z\+]+://#) {
 604                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 605                         fatal("E: '$path' is not a complete URL ",
 606                               "and a separate URL is not specified\n");
 607                 }
 608                 return ($url, $path);
 609         }
 610         return ($path, '');
 611 }
 612
 613 sub complete_url_ls_init {
 614         my ($ra, $repo_path, $switch, $pfx) = @_;
 615         unless ($repo_path) {
 616                 print STDERR "W: $switch not specified\n";
 617                 return;
 618         }
 619         $repo_path =~ s#/+$##;
 620         if ($repo_path =~ m#^[a-z\+]+://#) {
 621                 $ra = Git::SVN::Ra->new($repo_path);
 622                 $repo_path = '';
 623         } else {
 624                 $repo_path =~ s#^/+##;
 625                 unless ($ra) {
 626                         fatal("E: '$repo_path' is not a complete URL ",
 627                               "and a separate URL is not specified\n");
 628                 }
 629         }
 630         my $url = $ra->{url};
 631         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 632         my $k = "svn-remote.$gs->{repo_id}.url";
 633         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 634         if ($orig_url && ($orig_url ne $gs->{url})) {
 635                 die "$k already set: $orig_url\n",
 636                     "wanted to set to: $gs->{url}\n";
 637         }
 638         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 639         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 640         $remote_path =~ s#/+#/#g;
 641         $remote_path =~ s#^/##g;
 642         my ($n) = ($switch =~ /^--(\w+)/);
 643         if (length $pfx && $pfx !~ m#/$#) {
 644                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 645         }
 646         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 647                                 "$remote_path:refs/remotes/$pfx*");
 648 }
 649
 650 sub verify_ref {
 651         my ($ref) = @_;
 652         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 653                                { STDERR => 0 }); };
 654 }
 655
 656 sub get_tree_from_treeish {
 657         my ($treeish) = @_;
 658         # $treeish can be a symbolic ref, too:
 659         my $type = command_oneline(qw/cat-file -t/, $treeish);
 660         my $expected;
 661         while ($type eq 'tag') {
 662                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 663         }
 664         if ($type eq 'commit') {
 665                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 666                                                     $treeish))[0];
 667                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 668                 die "Unable to get tree from $treeish\n" unless $expected;
 669         } elsif ($type eq 'tree') {
 670                 $expected = $treeish;
 671         } else {
 672                 die "$treeish is a $type, expected tree, tag or commit\n";
 673         }
 674         return $expected;
 675 }
 676
 677 sub get_commit_entry {
 678         my ($treeish) = shift;
 679         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 680         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 681         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 682         open my $log_fh, '>', $commit_editmsg or croak $!;
 683
 684         my $type = command_oneline(qw/cat-file -t/, $treeish);
 685         if ($type eq 'commit' || $type eq 'tag') {
 686                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 687                                                          $type, $treeish);
 688                 my $in_msg = 0;
 689                 while (<$msg_fh>) {
 690                         if (!$in_msg) {
 691                                 $in_msg = 1 if (/^\s*$/);
 692                         } elsif (/^git-svn-id: /) {
 693                                 # skip this for now, we regenerate the
 694                                 # correct one on re-fetch anyways
 695                                 # TODO: set *:merge properties or like...
 696                         } else {
 697                                 print $log_fh $_ or croak $!;
 698                         }
 699                 }
 700                 command_close_pipe($msg_fh, $ctx);
 701         }
 702         close $log_fh or croak $!;
 703
 704         if ($_edit || ($type eq 'tree')) {
 705                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 706                 # TODO: strip out spaces, comments, like git-commit.sh
 707                 system($editor, $commit_editmsg);
 708         }
 709         rename $commit_editmsg, $commit_msg or croak $!;
 710         open $log_fh, '<', $commit_msg or croak $!;
 711         { local $/; chomp($log_entry{log} = <$log_fh>); }
 712         close $log_fh or croak $!;
 713         unlink $commit_msg;
 714         \%log_entry;
 715 }
 716
 717 sub s_to_file {
 718         my ($str, $file, $mode) = @_;
 719         open my $fd,'>',$file or croak $!;
 720         print $fd $str,"\n" or croak $!;
 721         close $fd or croak $!;
 722         chmod ($mode &~ umask, $file) if (defined $mode);
 723 }
 724
 725 sub file_to_s {
 726         my $file = shift;
 727         open my $fd,'<',$file or croak "$!: file: $file\n";
 728         local $/;
 729         my $ret = <$fd>;
 730         close $fd or croak $!;
 731         $ret =~ s/\s*$//s;
 732         return $ret;
 733 }
 734
 735 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 736 sub load_authors {
 737         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 738         my $log = $cmd eq 'log';
 739         while (<$authors>) {
 740                 chomp;
 741                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 742                 my ($user, $name, $email) = ($1, $2, $3);
 743                 if ($log) {
 744                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 745                 } else {
 746                         $users{$user} = [$name, $email];
 747                 }
 748         }
 749         close $authors or croak $!;
 750 }
 751
 752 # convert GetOpt::Long specs for use by git-config
 753 sub read_repo_config {
 754         return unless -d $ENV{GIT_DIR};
 755         my $opts = shift;
 756         my @config_only;
 757         foreach my $o (keys %$opts) {
 758                 # if we have mixedCase and a long option-only, then
 759                 # it's a config-only variable that we don't need for
 760                 # the command-line.
 761                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
 762                 my $v = $opts->{$o};
 763                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
 764                 $key =~ s/-//g;
 765                 my $arg = 'git-config';
 766                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 767                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 768                 if (ref $v eq 'ARRAY') {
 769                         chomp(my @tmp = `$arg --get-all svn.$key`);
 770                         @$v = @tmp if @tmp;
 771                 } else {
 772                         chomp(my $tmp = `$arg --get svn.$key`);
 773                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 774                                 $$v = $tmp;
 775                         }
 776                 }
 777         }
 778         delete @$opts{@config_only} if @config_only;
 779 }
 780
 781 sub extract_metadata {
 782         my $id = shift or return (undef, undef, undef);
 783         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 784                                                         \s([a-f\d\-]+)$/x);
 785         if (!defined $rev || !$uuid || !$url) {
 786                 # some of the original repositories I made had
 787                 # identifiers like this:
 788                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 789         }
 790         return ($url, $rev, $uuid);
 791 }
 792
 793 sub cmt_metadata {
 794         return extract_metadata((grep(/^git-svn-id: /,
 795                 command(qw/cat-file commit/, shift)))[-1]);
 796 }
 797
 798 sub working_head_info {
 799         my ($head, $refs) = @_;
 800         my ($fh, $ctx) = command_output_pipe('rev-list', $head);
 801         while (my $hash = <$fh>) {
 802                 chomp($hash);
 803                 my ($url, $rev, $uuid) = cmt_metadata($hash);
 804                 if (defined $url && defined $rev) {
 805                         if (my $gs = Git::SVN->find_by_url($url)) {
 806                                 my $c = $gs->rev_db_get($rev);
 807                                 if ($c && $c eq $hash) {
 808                                         close $fh; # break the pipe
 809                                         return ($url, $rev, $uuid, $gs);
 810                                 }
 811                         }
 812                 }
 813                 unshift @$refs, $hash if $refs;
 814         }
 815         command_close_pipe($fh, $ctx);
 816         (undef, undef, undef, undef);
 817 }
 818
 819 package Git::SVN;
 820 use strict;
 821 use warnings;
 822 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
 823             $_repack $_repack_flags $_use_svm_props $_head
 824             $_use_svnsync_props $no_reuse_existing $_minimize_url/;
 825 use Carp qw/croak/;
 826 use File::Path qw/mkpath/;
 827 use File::Copy qw/copy/;
 828 use IPC::Open3;
 829
 830 my $_repack_nr;
 831 # properties that we do not log:
 832 my %SKIP_PROP;
 833 BEGIN {
 834         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 835                                         svn:special svn:executable
 836                                         svn:entry:committed-rev
 837                                         svn:entry:last-author
 838                                         svn:entry:uuid
 839                                         svn:entry:committed-date/;
 840
 841         # some options are read globally, but can be overridden locally
 842         # per [svn-remote "..."] section.  Command-line options will *NOT*
 843         # override options set in an [svn-remote "..."] section
 844         my $e;
 845         foreach (qw/follow_parent no_metadata use_svm_props
 846                     use_svnsync_props/) {
 847                 my $key = $_;
 848                 $key =~ tr/_//d;
 849                 $e .= "sub $_ {
 850                         my (\$self) = \@_;
 851                         return \$self->{-$_} if exists \$self->{-$_};
 852                         my \$k = \"svn-remote.\$self->{repo_id}\.$key\";
 853                         eval { command_oneline(qw/config --get/, \$k) };
 854                         if (\$@) {
 855                                 \$self->{-$_} = \$Git::SVN::_$_;
 856                         } else {
 857                                 my \$v = command_oneline(qw/config --bool/,\$k);
 858                                 \$self->{-$_} = \$v eq 'false' ? 0 : 1;
 859                         }
 860                         return \$self->{-$_} }\n";
 861         }
 862         $e .= "1;\n";
 863         eval $e or die $@;
 864 }
 865
 866 my %LOCKFILES;
 867 END { unlink keys %LOCKFILES if %LOCKFILES }
 868
 869 sub resolve_local_globs {
 870         my ($url, $fetch, $glob_spec) = @_;
 871         return unless defined $glob_spec;
 872         my $ref = $glob_spec->{ref};
 873         my $path = $glob_spec->{path};
 874         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
 875                 next unless m#^refs/remotes/$ref->{regex}$#;
 876                 my $p = $1;
 877                 my $pathname = $path->full_path($p);
 878                 my $refname = $ref->full_path($p);
 879                 if (my $existing = $fetch->{$pathname}) {
 880                         if ($existing ne $refname) {
 881                                 die "Refspec conflict:\n",
 882                                     "existing: refs/remotes/$existing\n",
 883                                     " globbed: refs/remotes/$refname\n";
 884                         }
 885                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
 886                         $u =~ s!^\Q$url\E(/|$)!! or die
 887                           "refs/remotes/$refname: '$url' not found in '$u'\n";
 888                         if ($pathname ne $u) {
 889                                 warn "W: Refspec glob conflict ",
 890                                      "(ref: refs/remotes/$refname):\n",
 891                                      "expected path: $pathname\n",
 892                                      "    real path: $u\n",
 893                                      "Continuing ahead with $u\n";
 894                                 next;
 895                         }
 896                 } else {
 897                         $fetch->{$pathname} = $refname;
 898                 }
 899         }
 900 }
 901
 902 sub parse_revision_argument {
 903         my ($base, $head) = @_;
 904         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 905                 return ($base, $head);
 906         }
 907         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 908         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 909         return ($head, $head) if ($::_revision eq 'HEAD');
 910         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
 911         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 912         die "revision argument: $::_revision not understood by git-svn\n";
 913 }
 914
 915 sub fetch_all {
 916         my ($repo_id, $remotes) = @_;
 917         if (ref $repo_id) {
 918                 my $gs = $repo_id;
 919                 $repo_id = undef;
 920                 $repo_id = $gs->{repo_id};
 921         }
 922         $remotes ||= read_all_remotes();
 923         my $remote = $remotes->{$repo_id} or
 924                      die "[svn-remote \"$repo_id\"] unknown\n";
 925         my $fetch = $remote->{fetch};
 926         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
 927         my (@gs, @globs);
 928         my $ra = Git::SVN::Ra->new($url);
 929         my $uuid = $ra->get_uuid;
 930         my $head = $ra->get_latest_revnum;
 931         my $base = defined $fetch ? $head : 0;
 932
 933         # read the max revs for wildcard expansion (branches/*, tags/*)
 934         foreach my $t (qw/branches tags/) {
 935                 defined $remote->{$t} or next;
 936                 push @globs, $remote->{$t};
 937                 my $max_rev = eval { tmp_config(qw/--int --get/,
 938                                          "svn-remote.$repo_id.${t}-maxRev") };
 939                 if (defined $max_rev && ($max_rev < $base)) {
 940                         $base = $max_rev;
 941                 } elsif (!defined $max_rev) {
 942                         $base = 0;
 943                 }
 944         }
 945
 946         if ($fetch) {
 947                 foreach my $p (sort keys %$fetch) {
 948                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 949                         my $lr = $gs->rev_db_max;
 950                         if (defined $lr) {
 951                                 $base = $lr if ($lr < $base);
 952                         }
 953                         push @gs, $gs;
 954                 }
 955         }
 956
 957         ($base, $head) = parse_revision_argument($base, $head);
 958         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
 959 }
 960
 961 sub read_all_remotes {
 962         my $r = {};
 963         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 964                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 965                         $r->{$1}->{fetch}->{$2} = $3;
 966                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 967                         $r->{$1}->{url} = $2;
 968                 } elsif (m!^(.+)\.(branches|tags)=
 969                            (.*):refs/remotes/(.+)\s*$/!x) {
 970                         my ($p, $g) = ($3, $4);
 971                         my $rs = $r->{$1}->{$2} = {
 972                                           t => $2,
 973                                           remote => $1,
 974                                           path => Git::SVN::GlobSpec->new($p),
 975                                           ref => Git::SVN::GlobSpec->new($g) };
 976                         if (length($rs->{ref}->{right}) != 0) {
 977                                 die "The '*' glob character must be the last ",
 978                                     "character of '$g'\n";
 979                         }
 980                 }
 981         }
 982         $r;
 983 }
 984
 985 sub init_vars {
 986         if (defined $_repack) {
 987                 $_repack = 1000 if ($_repack <= 0);
 988                 $_repack_nr = $_repack;
 989                 $_repack_flags ||= '-d';
 990         }
 991 }
 992
 993 sub verify_remotes_sanity {
 994         return unless -d $ENV{GIT_DIR};
 995         my %seen;
 996         foreach (command(qw/config -l/)) {
 997                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 998                         if ($seen{$1}) {
 999                                 die "Remote ref refs/remote/$1 is tracked by",
1000                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
1001                                     "Please resolve this ambiguity in ",
1002                                     "your git configuration file before ",
1003                                     "continuing\n";
1004                         }
1005                         $seen{$1} = $_;
1006                 }
1007         }
1008 }
1009
1010 # we allow more chars than remotes2config.sh...
1011 sub sanitize_remote_name {
1012         my ($name) = @_;
1013         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1014         $name;
1015 }
1016
1017 sub find_existing_remote {
1018         my ($url, $remotes) = @_;
1019         return undef if $no_reuse_existing;
1020         my $existing;
1021         foreach my $repo_id (keys %$remotes) {
1022                 my $u = $remotes->{$repo_id}->{url} or next;
1023                 next if $u ne $url;
1024                 $existing = $repo_id;
1025                 last;
1026         }
1027         $existing;
1028 }
1029
1030 sub init_remote_config {
1031         my ($self, $url, $no_write) = @_;
1032         $url =~ s!/+$!!; # strip trailing slash
1033         my $r = read_all_remotes();
1034         my $existing = find_existing_remote($url, $r);
1035         if ($existing) {
1036                 unless ($no_write) {
1037                         print STDERR "Using existing ",
1038                                      "[svn-remote \"$existing\"]\n";
1039                 }
1040                 $self->{repo_id} = $existing;
1041         } elsif ($_minimize_url) {
1042                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1043                 $existing = find_existing_remote($min_url, $r);
1044                 if ($existing) {
1045                         unless ($no_write) {
1046                                 print STDERR "Using existing ",
1047                                              "[svn-remote \"$existing\"]\n";
1048                         }
1049                         $self->{repo_id} = $existing;
1050                 }
1051                 if ($min_url ne $url) {
1052                         unless ($no_write) {
1053                                 print STDERR "Using higher level of URL: ",
1054                                              "$url => $min_url\n";
1055                         }
1056                         my $old_path = $self->{path};
1057                         $self->{path} = $url;
1058                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1059                         if (length $old_path) {
1060                                 $self->{path} .= "/$old_path";
1061                         }
1062                         $url = $min_url;
1063                 }
1064         }
1065         my $orig_url;
1066         if (!$existing) {
1067                 # verify that we aren't overwriting anything:
1068                 $orig_url = eval {
1069                         command_oneline('config', '--get',
1070                                         "svn-remote.$self->{repo_id}.url")
1071                 };
1072                 if ($orig_url && ($orig_url ne $url)) {
1073                         die "svn-remote.$self->{repo_id}.url already set: ",
1074                             "$orig_url\nwanted to set to: $url\n";
1075                 }
1076         }
1077         my ($xrepo_id, $xpath) = find_ref($self->refname);
1078         if (defined $xpath) {
1079                 die "svn-remote.$xrepo_id.fetch already set to track ",
1080                     "$xpath:refs/remotes/", $self->refname, "\n";
1081         }
1082         unless ($no_write) {
1083                 command_noisy('config',
1084                               "svn-remote.$self->{repo_id}.url", $url);
1085                 command_noisy('config', '--add',
1086                               "svn-remote.$self->{repo_id}.fetch",
1087                               "$self->{path}:".$self->refname);
1088         }
1089         $self->{url} = $url;
1090 }
1091
1092 sub find_by_url { # repos_root and, path are optional
1093         my ($class, $full_url, $repos_root, $path) = @_;
1094
1095         return undef unless defined $full_url;
1096         remove_username($full_url);
1097         remove_username($repos_root) if defined $repos_root;
1098         my $remotes = read_all_remotes();
1099         if (defined $full_url && defined $repos_root && !defined $path) {
1100                 $path = $full_url;
1101                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1102         }
1103         foreach my $repo_id (keys %$remotes) {
1104                 my $u = $remotes->{$repo_id}->{url} or next;
1105                 remove_username($u);
1106                 next if defined $repos_root && $repos_root ne $u;
1107
1108                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1109                 foreach (qw/branches tags/) {
1110                         resolve_local_globs($u, $fetch,
1111                                             $remotes->{$repo_id}->{$_});
1112                 }
1113                 my $p = $path;
1114                 unless (defined $p) {
1115                         $p = $full_url;
1116                         $p =~ s#^\Q$u\E(?:/|$)## or next;
1117                 }
1118                 foreach my $f (keys %$fetch) {
1119                         next if $f ne $p;
1120                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1121                 }
1122         }
1123         undef;
1124 }
1125
1126 sub init {
1127         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1128         my $self = _new($class, $repo_id, $ref_id, $path);
1129         if (defined $url) {
1130                 $self->init_remote_config($url, $no_write);
1131         }
1132         $self;
1133 }
1134
1135 sub find_ref {
1136         my ($ref_id) = @_;
1137         foreach (command(qw/config -l/)) {
1138                 next unless m!^svn-remote\.(.+)\.fetch=
1139                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1140                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1141                 if ($ref eq $ref_id) {
1142                         $path = '' if ($path =~ m#^\./?#);
1143                         return ($repo_id, $path);
1144                 }
1145         }
1146         (undef, undef, undef);
1147 }
1148
1149 sub new {
1150         my ($class, $ref_id, $repo_id, $path) = @_;
1151         if (defined $ref_id && !defined $repo_id && !defined $path) {
1152                 ($repo_id, $path) = find_ref($ref_id);
1153                 if (!defined $repo_id) {
1154                         die "Could not find a \"svn-remote.*.fetch\" key ",
1155                             "in the repository configuration matching: ",
1156                             "refs/remotes/$ref_id\n";
1157                 }
1158         }
1159         my $self = _new($class, $repo_id, $ref_id, $path);
1160         if (!defined $self->{path} || !length $self->{path}) {
1161                 my $fetch = command_oneline('config', '--get',
1162                                             "svn-remote.$repo_id.fetch",
1163                                             ":refs/remotes/$ref_id\$") or
1164                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1165                          "\":refs/remotes/$ref_id\$\" in config\n";
1166                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1167         }
1168         $self->{url} = command_oneline('config', '--get',
1169                                        "svn-remote.$repo_id.url") or
1170                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1171         $self->rebuild;
1172         $self;
1173 }
1174
1175 sub refname { "refs/remotes/$_[0]->{ref_id}" }
1176
1177 sub svm_uuid {
1178         my ($self) = @_;
1179         return $self->{svm}->{uuid} if $self->svm;
1180         $self->ra;
1181         unless ($self->{svm}) {
1182                 die "SVM UUID not cached, and reading remotely failed\n";
1183         }
1184         $self->{svm}->{uuid};
1185 }
1186
1187 sub svm {
1188         my ($self) = @_;
1189         return $self->{svm} if $self->{svm};
1190         my $svm;
1191         # see if we have it in our config, first:
1192         eval {
1193                 my $section = "svn-remote.$self->{repo_id}";
1194                 $svm = {
1195                   source => tmp_config('--get', "$section.svm-source"),
1196                   uuid => tmp_config('--get', "$section.svm-uuid"),
1197                   replace => tmp_config('--get', "$section.svm-replace"),
1198                 }
1199         };
1200         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1201                 $self->{svm} = $svm;
1202         }
1203         $self->{svm};
1204 }
1205
1206 sub _set_svm_vars {
1207         my ($self, $ra) = @_;
1208         return $ra if $self->svm;
1209
1210         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1211                     "(svm:source, svm:uuid) ",
1212                     "from the following URLs:\n" );
1213         sub read_svm_props {
1214                 my ($self, $ra, $path, $r) = @_;
1215                 my $props = ($ra->get_dir($path, $r))[2];
1216                 my $src = $props->{'svm:source'};
1217                 my $uuid = $props->{'svm:uuid'};
1218                 return undef if (!$src || !$uuid);
1219
1220                 chomp($src, $uuid);
1221
1222                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1223                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1224
1225                 # the '!' is used to mark the repos_root!/relative/path
1226                 $src =~ s{/?!/?}{/};
1227                 $src =~ s{/+$}{}; # no trailing slashes please
1228                 # username is of no interest
1229                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1230
1231                 my $replace = $ra->{url};
1232                 $replace .= "/$path" if length $path;
1233
1234                 my $section = "svn-remote.$self->{repo_id}";
1235                 tmp_config("$section.svm-source", $src);
1236                 tmp_config("$section.svm-replace", $replace);
1237                 tmp_config("$section.svm-uuid", $uuid);
1238                 $self->{svm} = {
1239                         source => $src,
1240                         uuid => $uuid,
1241                         replace => $replace
1242                 };
1243         }
1244
1245         my $r = $ra->get_latest_revnum;
1246         my $path = $self->{path};
1247         my %tried;
1248         while (length $path) {
1249                 unless ($tried{"$self->{url}/$path"}) {
1250                         return $ra if $self->read_svm_props($ra, $path, $r);
1251                         $tried{"$self->{url}/$path"} = 1;
1252                 }
1253                 $path =~ s#/?[^/]+$##;
1254         }
1255         die "Path: '$path' should be ''\n" if $path ne '';
1256         return $ra if $self->read_svm_props($ra, $path, $r);
1257         $tried{"$self->{url}/$path"} = 1;
1258
1259         if ($ra->{repos_root} eq $self->{url}) {
1260                 die @err, (map { "  $_\n" } keys %tried), "\n";
1261         }
1262
1263         # nope, make sure we're connected to the repository root:
1264         my $ok;
1265         my @tried_b;
1266         $path = $ra->{svn_path};
1267         $ra = Git::SVN::Ra->new($ra->{repos_root});
1268         while (length $path) {
1269                 unless ($tried{"$ra->{url}/$path"}) {
1270                         $ok = $self->read_svm_props($ra, $path, $r);
1271                         last if $ok;
1272                         $tried{"$ra->{url}/$path"} = 1;
1273                 }
1274                 $path =~ s#/?[^/]+$##;
1275         }
1276         die "Path: '$path' should be ''\n" if $path ne '';
1277         $ok ||= $self->read_svm_props($ra, $path, $r);
1278         $tried{"$ra->{url}/$path"} = 1;
1279         if (!$ok) {
1280                 die @err, (map { "  $_\n" } keys %tried), "\n";
1281         }
1282         Git::SVN::Ra->new($self->{url});
1283 }
1284
1285 sub svnsync {
1286         my ($self) = @_;
1287         return $self->{svnsync} if $self->{svnsync};
1288
1289         if ($self->no_metadata) {
1290                 die "Can't have both 'noMetadata' and ",
1291                     "'useSvnsyncProps' options set!\n";
1292         }
1293         if ($self->rewrite_root) {
1294                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1295                     "options set!\n";
1296         }
1297
1298         my $svnsync;
1299         # see if we have it in our config, first:
1300         eval {
1301                 my $section = "svn-remote.$self->{repo_id}";
1302                 $svnsync = {
1303                   url => tmp_config('--get', "$section.svnsync-url"),
1304                   uuid => tmp_config('--get', "$section.svnsync-uuid"),
1305                 }
1306         };
1307         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1308                 return $self->{svnsync} = $svnsync;
1309         }
1310
1311         my $err = "useSvnsyncProps set, but failed to read " .
1312                   "svnsync property: svn:sync-from-";
1313         my $rp = $self->ra->rev_proplist(0);
1314
1315         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1316         $url =~ m{^[a-z\+]+://} or
1317                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1318
1319         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1320         $uuid =~ m{^[0-9a-f\-]{30,}$} or
1321                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1322
1323         my $section = "svn-remote.$self->{repo_id}";
1324         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1325         tmp_config('--add', "$section.svnsync-url", $url);
1326         return $self->{svnsync} = { url => $url, uuid => $uuid };
1327 }
1328
1329 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1330 # remote lookup (useful for 'git svn log').
1331 sub ra_uuid {
1332         my ($self) = @_;
1333         unless ($self->{ra_uuid}) {
1334                 my $key = "svn-remote.$self->{repo_id}.uuid";
1335                 my $uuid = eval { tmp_config('--get', $key) };
1336                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1337                         $self->{ra_uuid} = $uuid;
1338                 } else {
1339                         die "ra_uuid called without URL\n" unless $self->{url};
1340                         $self->{ra_uuid} = $self->ra->get_uuid;
1341                         tmp_config('--add', $key, $self->{ra_uuid});
1342                 }
1343         }
1344         $self->{ra_uuid};
1345 }
1346
1347 sub ra {
1348         my ($self) = shift;
1349         my $ra = Git::SVN::Ra->new($self->{url});
1350         if ($self->use_svm_props && !$self->{svm}) {
1351                 if ($self->no_metadata) {
1352                         die "Can't have both 'noMetadata' and ",
1353                             "'useSvmProps' options set!\n";
1354                 } elsif ($self->use_svnsync_props) {
1355                         die "Can't have both 'useSvnsyncProps' and ",
1356                             "'useSvmProps' options set!\n";
1357                 }
1358                 $ra = $self->_set_svm_vars($ra);
1359                 $self->{-want_revprops} = 1;
1360         }
1361         $ra;
1362 }
1363
1364 sub rel_path {
1365         my ($self) = @_;
1366         my $repos_root = $self->ra->{repos_root};
1367         return $self->{path} if ($self->{url} eq $repos_root);
1368         my $url = $self->{url} .
1369                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1370         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1371         $url;
1372 }
1373
1374 sub traverse_ignore {
1375         my ($self, $fh, $path, $r) = @_;
1376         $path =~ s#^/+##g;
1377         my $ra = $self->ra;
1378         my ($dirent, undef, $props) = $ra->get_dir($path, $r);
1379         my $p = $path;
1380         $p =~ s#^\Q$self->{path}\E(/|$)##;
1381         print $fh length $p ? "\n# $p\n" : "\n# /\n";
1382         if (my $s = $props->{'svn:ignore'}) {
1383                 $s =~ s/[\r\n]+/\n/g;
1384                 chomp $s;
1385                 if (length $p == 0) {
1386                         $s =~ s#\n#\n/$p#g;
1387                         print $fh "/$s\n";
1388                 } else {
1389                         $s =~ s#\n#\n/$p/#g;
1390                         print $fh "/$p/$s\n";
1391                 }
1392         }
1393         foreach (sort keys %$dirent) {
1394                 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1395                 $self->traverse_ignore($fh, "$path/$_", $r);
1396         }
1397 }
1398
1399 sub last_rev { ($_[0]->last_rev_commit)[0] }
1400 sub last_commit { ($_[0]->last_rev_commit)[1] }
1401
1402 # returns the newest SVN revision number and newest commit SHA1
1403 sub last_rev_commit {
1404         my ($self) = @_;
1405         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1406                 return ($self->{last_rev}, $self->{last_commit});
1407         }
1408         my $c = ::verify_ref($self->refname.'^0');
1409         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1410                 my $rev = (::cmt_metadata($c))[1];
1411                 if (defined $rev) {
1412                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1413                         return ($rev, $c);
1414                 }
1415         }
1416         my $db_path = $self->db_path;
1417         unless (-e $db_path) {
1418                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1419                 return (undef, undef);
1420         }
1421         my $offset = -41; # from tail
1422         my $rl;
1423         open my $fh, '<', $db_path or croak "$db_path not readable: $!\n";
1424         sysseek($fh, $offset, 2); # don't care for errors
1425         sysread($fh, $rl, 41) == 41 or return (undef, undef);
1426         chomp $rl;
1427         while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
1428                 $offset -= 41;
1429                 sysseek($fh, $offset, 2); # don't care for errors
1430                 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1431                 chomp $rl;
1432         }
1433         if ($c && $c ne $rl) {
1434                 die "$db_path and ", $self->refname,
1435                     " inconsistent!:\n$c != $rl\n";
1436         }
1437         my $rev = sysseek($fh, 0, 1) or croak $!;
1438         $rev =  ($rev - 41) / 41;
1439         close $fh or croak $!;
1440         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1441         return ($rev, $c);
1442 }
1443
1444 sub get_fetch_range {
1445         my ($self, $min, $max) = @_;
1446         $max ||= $self->ra->get_latest_revnum;
1447         $min ||= $self->rev_db_max;
1448         (++$min, $max);
1449 }
1450
1451 sub tmp_config {
1452         my (@args) = @_;
1453         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1454         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1455         if (-e $old_def_config && ! -e $config) {
1456                 rename $old_def_config, $config or
1457                        die "Failed rename $old_def_config => $config: $!\n";
1458         }
1459         my $old_config = $ENV{GIT_CONFIG};
1460         $ENV{GIT_CONFIG} = $config;
1461         $@ = undef;
1462         my @ret = eval {
1463                 unless (-f $config) {
1464                         mkfile($config);
1465                         open my $fh, '>', $config or
1466                             die "Can't open $config: $!\n";
1467                         print $fh "; This file is used internally by ",
1468                                   "git-svn\n" or die
1469                                   "Couldn't write to $config: $!\n";
1470                         print $fh "; You should not have to edit it\n" or
1471                               die "Couldn't write to $config: $!\n";
1472                         close $fh or die "Couldn't close $config: $!\n";
1473                 }
1474                 command('config', @args);
1475         };
1476         my $err = $@;
1477         if (defined $old_config) {
1478                 $ENV{GIT_CONFIG} = $old_config;
1479         } else {
1480                 delete $ENV{GIT_CONFIG};
1481         }
1482         die $err if $err;
1483         wantarray ? @ret : $ret[0];
1484 }
1485
1486 sub tmp_index_do {
1487         my ($self, $sub) = @_;
1488         my $old_index = $ENV{GIT_INDEX_FILE};
1489         $ENV{GIT_INDEX_FILE} = $self->{index};
1490         $@ = undef;
1491         my @ret = eval {
1492                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1493                 mkpath([$dir]) unless -d $dir;
1494                 &$sub;
1495         };
1496         my $err = $@;
1497         if (defined $old_index) {
1498                 $ENV{GIT_INDEX_FILE} = $old_index;
1499         } else {
1500                 delete $ENV{GIT_INDEX_FILE};
1501         }
1502         die $err if $err;
1503         wantarray ? @ret : $ret[0];
1504 }
1505
1506 sub assert_index_clean {
1507         my ($self, $treeish) = @_;
1508
1509         $self->tmp_index_do(sub {
1510                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1511                 my $x = command_oneline('write-tree');
1512                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1513                            /^tree ($::sha1)/mo);
1514                 return if $y eq $x;
1515
1516                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1517                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1518                 command_noisy('read-tree', $treeish);
1519                 $x = command_oneline('write-tree');
1520                 if ($y ne $x) {
1521                         ::fatal "trees ($treeish) $y != $x\n",
1522                                 "Something is seriously wrong...\n";
1523                 }
1524         });
1525 }
1526
1527 sub get_commit_parents {
1528         my ($self, $log_entry) = @_;
1529         my (%seen, @ret, @tmp);
1530         # legacy support for 'set-tree'; this is only used by set_tree_cb:
1531         if (my $ip = $self->{inject_parents}) {
1532                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1533                         push @tmp, $commit;
1534                 }
1535         }
1536         if (my $cur = ::verify_ref($self->refname.'^0')) {
1537                 push @tmp, $cur;
1538         }
1539         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1540         while (my $p = shift @tmp) {
1541                 next if $seen{$p};
1542                 $seen{$p} = 1;
1543                 push @ret, $p;
1544                 # MAXPARENT is defined to 16 in commit-tree.c:
1545                 last if @ret >= 16;
1546         }
1547         if (@tmp) {
1548                 die "r$log_entry->{revision}: No room for parents:\n\t",
1549                     join("\n\t", @tmp), "\n";
1550         }
1551         @ret;
1552 }
1553
1554 sub rewrite_root {
1555         my ($self) = @_;
1556         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
1557         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
1558         my $rwr = eval { command_oneline(qw/config --get/, $k) };
1559         if ($rwr) {
1560                 $rwr =~ s#/+$##;
1561                 if ($rwr !~ m#^[a-z\+]+://#) {
1562                         die "$rwr is not a valid URL (key: $k)\n";
1563                 }
1564         }
1565         $self->{-rewrite_root} = $rwr;
1566 }
1567
1568 sub metadata_url {
1569         my ($self) = @_;
1570         ($self->rewrite_root || $self->{url}) .
1571            (length $self->{path} ? '/' . $self->{path} : '');
1572 }
1573
1574 sub full_url {
1575         my ($self) = @_;
1576         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1577 }
1578
1579 sub do_git_commit {
1580         my ($self, $log_entry) = @_;
1581         my $lr = $self->last_rev;
1582         if (defined $lr && $lr >= $log_entry->{revision}) {
1583                 die "Last fetched revision of ", $self->refname,
1584                     " was r$lr, but we are about to fetch: ",
1585                     "r$log_entry->{revision}!\n";
1586         }
1587         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1588                 croak "$log_entry->{revision} = $c already exists! ",
1589                       "Why are we refetching it?\n";
1590         }
1591         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $log_entry->{name};
1592         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} =
1593                                                           $log_entry->{email};
1594         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1595
1596         my $tree = $log_entry->{tree};
1597         if (!defined $tree) {
1598                 $tree = $self->tmp_index_do(sub {
1599                                             command_oneline('write-tree') });
1600         }
1601         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1602
1603         my @exec = ('git-commit-tree', $tree);
1604         foreach ($self->get_commit_parents($log_entry)) {
1605                 push @exec, '-p', $_;
1606         }
1607         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1608                                                                    or croak $!;
1609         print $msg_fh $log_entry->{log} or croak $!;
1610         unless ($self->no_metadata) {
1611                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1612                               or croak $!;
1613         }
1614         $msg_fh->flush == 0 or croak $!;
1615         close $msg_fh or croak $!;
1616         chomp(my $commit = do { local $/; <$out_fh> });
1617         close $out_fh or croak $!;
1618         waitpid $pid, 0;
1619         croak $? if $?;
1620         if ($commit !~ /^$::sha1$/o) {
1621                 die "Failed to commit, invalid sha1: $commit\n";
1622         }
1623
1624         $self->rev_db_set($log_entry->{revision}, $commit, 1);
1625
1626         $self->{last_rev} = $log_entry->{revision};
1627         $self->{last_commit} = $commit;
1628         print "r$log_entry->{revision}";
1629         if (defined $log_entry->{svm_revision}) {
1630                  print " (\@$log_entry->{svm_revision})";
1631                  $self->rev_db_set($log_entry->{svm_revision}, $commit,
1632                                    0, $self->svm_uuid);
1633         }
1634         print " = $commit ($self->{ref_id})\n";
1635         if (defined $_repack && (--$_repack_nr == 0)) {
1636                 $_repack_nr = $_repack;
1637                 # repack doesn't use any arguments with spaces in them, does it?
1638                 print "Running git repack $_repack_flags ...\n";
1639                 command_noisy('repack', split(/\s+/, $_repack_flags));
1640                 print "Done repacking\n";
1641         }
1642         return $commit;
1643 }
1644
1645 sub match_paths {
1646         my ($self, $paths, $r) = @_;
1647         return 1 if $self->{path} eq '';
1648         if (my $path = $paths->{"/$self->{path}"}) {
1649                 return ($path->{action} eq 'D') ? 0 : 1;
1650         }
1651         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
1652         if (grep /$self->{path_regex}/, keys %$paths) {
1653                 return 1;
1654         }
1655         my $c = '';
1656         foreach (split m#/#, $self->{path}) {
1657                 $c .= "/$_";
1658                 next unless ($paths->{$c} &&
1659                              ($paths->{$c}->{action} =~ /^[AR]$/));
1660                 if ($self->ra->check_path($self->{path}, $r) ==
1661                     $SVN::Node::dir) {
1662                         return 1;
1663                 }
1664         }
1665         return 0;
1666 }
1667
1668 sub find_parent_branch {
1669         my ($self, $paths, $rev) = @_;
1670         return undef unless $self->follow_parent;
1671         unless (defined $paths) {
1672                 my $err_handler = $SVN::Error::handler;
1673                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1674                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1675                                    $paths =
1676                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
1677                 $SVN::Error::handler = $err_handler;
1678         }
1679         return undef unless defined $paths;
1680
1681         # look for a parent from another branch:
1682         my @b_path_components = split m#/#, $self->rel_path;
1683         my @a_path_components;
1684         my $i;
1685         while (@b_path_components) {
1686                 $i = $paths->{'/'.join('/', @b_path_components)};
1687                 last if $i && defined $i->{copyfrom_path};
1688                 unshift(@a_path_components, pop(@b_path_components));
1689         }
1690         return undef unless defined $i && defined $i->{copyfrom_path};
1691         my $branch_from = $i->{copyfrom_path};
1692         if (@a_path_components) {
1693                 print STDERR "branch_from: $branch_from => ";
1694                 $branch_from .= '/'.join('/', @a_path_components);
1695                 print STDERR $branch_from, "\n";
1696         }
1697         my $r = $i->{copyfrom_rev};
1698         my $repos_root = $self->ra->{repos_root};
1699         my $url = $self->ra->{url};
1700         my $new_url = $repos_root . $branch_from;
1701         print STDERR  "Found possible branch point: ",
1702                       "$new_url => ", $self->full_url, ", $r\n";
1703         $branch_from =~ s#^/##;
1704         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
1705         unless ($gs) {
1706                 my $ref_id = $self->{ref_id};
1707                 $ref_id =~ s/\@\d+$//;
1708                 $ref_id .= "\@$r";
1709                 # just grow a tail if we're not unique enough :x
1710                 $ref_id .= '-' while find_ref($ref_id);
1711                 print STDERR "Initializing parent: $ref_id\n";
1712                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1713         }
1714         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1715         if (!defined $r0 || !defined $parent) {
1716                 my ($base, $head) = parse_revision_argument(0, $r);
1717                 if ($base <= $r) {
1718                         $gs->fetch($base, $r);
1719                 }
1720                 ($r0, $parent) = $gs->last_rev_commit;
1721         }
1722         if (defined $r0 && defined $parent) {
1723                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1724                 my $ed;
1725                 if ($self->ra->can_do_switch) {
1726                         $self->assert_index_clean($parent);
1727                         print STDERR "Following parent with do_switch\n";
1728                         # do_switch works with svn/trunk >= r22312, but that
1729                         # is not included with SVN 1.4.3 (the latest version
1730                         # at the moment), so we can't rely on it
1731                         $self->{last_commit} = $parent;
1732                         $ed = SVN::Git::Fetcher->new($self);
1733                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1734                                               $self->full_url, $ed)
1735                           or die "SVN connection failed somewhere...\n";
1736                 } else {
1737                         print STDERR "Following parent with do_update\n";
1738                         $ed = SVN::Git::Fetcher->new($self);
1739                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1740                           or die "SVN connection failed somewhere...\n";
1741                 }
1742                 print STDERR "Successfully followed parent\n";
1743                 return $self->make_log_entry($rev, [$parent], $ed);
1744         }
1745         return undef;
1746 }
1747
1748 sub do_fetch {
1749         my ($self, $paths, $rev) = @_;
1750         my $ed;
1751         my ($last_rev, @parents);
1752         if (my $lc = $self->last_commit) {
1753                 # we can have a branch that was deleted, then re-added
1754                 # under the same name but copied from another path, in
1755                 # which case we'll have multiple parents (we don't
1756                 # want to break the original ref, nor lose copypath info):
1757                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1758                         push @{$log_entry->{parents}}, $lc;
1759                         return $log_entry;
1760                 }
1761                 $ed = SVN::Git::Fetcher->new($self);
1762                 $last_rev = $self->{last_rev};
1763                 $ed->{c} = $lc;
1764                 @parents = ($lc);
1765         } else {
1766                 $last_rev = $rev;
1767                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1768                         return $log_entry;
1769                 }
1770                 $ed = SVN::Git::Fetcher->new($self);
1771         }
1772         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1773                 die "SVN connection failed somewhere...\n";
1774         }
1775         $self->make_log_entry($rev, \@parents, $ed);
1776 }
1777
1778 sub get_untracked {
1779         my ($self, $ed) = @_;
1780         my @out;
1781         my $h = $ed->{empty};
1782         foreach (sort keys %$h) {
1783                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1784                 push @out, "  $act: " . uri_encode($_);
1785                 warn "W: $act: $_\n";
1786         }
1787         foreach my $t (qw/dir_prop file_prop/) {
1788                 $h = $ed->{$t} or next;
1789                 foreach my $path (sort keys %$h) {
1790                         my $ppath = $path eq '' ? '.' : $path;
1791                         foreach my $prop (sort keys %{$h->{$path}}) {
1792                                 next if $SKIP_PROP{$prop};
1793                                 my $v = $h->{$path}->{$prop};
1794                                 my $t_ppath_prop = "$t: " .
1795                                                     uri_encode($ppath) . ' ' .
1796                                                     uri_encode($prop);
1797                                 if (defined $v) {
1798                                         push @out, "  +$t_ppath_prop " .
1799                                                    uri_encode($v);
1800                                 } else {
1801                                         push @out, "  -$t_ppath_prop";
1802                                 }
1803                         }
1804                 }
1805         }
1806         foreach my $t (qw/absent_file absent_directory/) {
1807                 $h = $ed->{$t} or next;
1808                 foreach my $parent (sort keys %$h) {
1809                         foreach my $path (sort @{$h->{$parent}}) {
1810                                 push @out, "  $t: " .
1811                                            uri_encode("$parent/$path");
1812                                 warn "W: $t: $parent/$path ",
1813                                      "Insufficient permissions?\n";
1814                         }
1815                 }
1816         }
1817         \@out;
1818 }
1819
1820 sub parse_svn_date {
1821         my $date = shift || return '+0000 1970-01-01 00:00:00';
1822         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1823                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1824                                          croak "Unable to parse date: $date\n";
1825         "+0000 $Y-$m-$d $H:$M:$S";
1826 }
1827
1828 sub check_author {
1829         my ($author) = @_;
1830         if (!defined $author || length $author == 0) {
1831                 $author = '(no author)';
1832         }
1833         if (defined $::_authors && ! defined $::users{$author}) {
1834                 die "Author: $author not defined in $::_authors file\n";
1835         }
1836         $author;
1837 }
1838
1839 sub make_log_entry {
1840         my ($self, $rev, $parents, $ed) = @_;
1841         my $untracked = $self->get_untracked($ed);
1842
1843         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1844         print $un "r$rev\n" or croak $!;
1845         print $un $_, "\n" foreach @$untracked;
1846         my %log_entry = ( parents => $parents || [], revision => $rev,
1847                           log => '');
1848
1849         my $headrev;
1850         my $logged = delete $self->{logged_rev_props};
1851         if (!$logged || $self->{-want_revprops}) {
1852                 my $rp = $self->ra->rev_proplist($rev);
1853                 foreach (sort keys %$rp) {
1854                         my $v = $rp->{$_};
1855                         if (/^svn:(author|date|log)$/) {
1856                                 $log_entry{$1} = $v;
1857                         } elsif ($_ eq 'svm:headrev') {
1858                                 $headrev = $v;
1859                         } else {
1860                                 print $un "  rev_prop: ", uri_encode($_), ' ',
1861                                           uri_encode($v), "\n";
1862                         }
1863                 }
1864         } else {
1865                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1866         }
1867         close $un or croak $!;
1868
1869         $log_entry{date} = parse_svn_date($log_entry{date});
1870         $log_entry{log} .= "\n";
1871         my $author = $log_entry{author} = check_author($log_entry{author});
1872         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1873                                                        : ($author, undef);
1874         if (defined $headrev && $self->use_svm_props) {
1875                 if ($self->rewrite_root) {
1876                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1877                             "options set!\n";
1878                 }
1879                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
1880                 # we don't want "SVM: initializing mirror for junk" ...
1881                 return undef if $r == 0;
1882                 my $svm = $self->svm;
1883                 if ($uuid ne $svm->{uuid}) {
1884                         die "UUID mismatch on SVM path:\n",
1885                             "expected: $svm->{uuid}\n",
1886                             "     got: $uuid\n";
1887                 }
1888                 my $full_url = $self->full_url;
1889                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1890                              die "Failed to replace '$svm->{replace}' with ",
1891                                  "'$svm->{source}' in $full_url\n";
1892                 # throw away username for storing in records
1893                 remove_username($full_url);
1894                 $log_entry{metadata} = "$full_url\@$r $uuid";
1895                 $log_entry{svm_revision} = $r;
1896                 $email ||= "$author\@$uuid"
1897         } elsif ($self->use_svnsync_props) {
1898                 my $full_url = $self->svnsync->{url};
1899                 $full_url .= "/$self->{path}" if length $self->{path};
1900                 remove_username($full_url);
1901                 my $uuid = $self->svnsync->{uuid};
1902                 $log_entry{metadata} = "$full_url\@$rev $uuid";
1903                 $email ||= "$author\@$uuid"
1904         } else {
1905                 my $url = $self->metadata_url;
1906                 remove_username($url);
1907                 $log_entry{metadata} = "$url\@$rev " .
1908                                        $self->ra->get_uuid;
1909                 $email ||= "$author\@" . $self->ra->get_uuid;
1910         }
1911         $log_entry{name} = $name;
1912         $log_entry{email} = $email;
1913         \%log_entry;
1914 }
1915
1916 sub fetch {
1917         my ($self, $min_rev, $max_rev, @parents) = @_;
1918         my ($last_rev, $last_commit) = $self->last_rev_commit;
1919         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1920         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1921 }
1922
1923 sub set_tree_cb {
1924         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1925         $self->{inject_parents} = { $rev => $tree };
1926         $self->fetch(undef, undef);
1927 }
1928
1929 sub set_tree {
1930         my ($self, $tree) = (shift, shift);
1931         my $log_entry = ::get_commit_entry($tree);
1932         unless ($self->{last_rev}) {
1933                 fatal("Must have an existing revision to commit\n");
1934         }
1935         my %ed_opts = ( r => $self->{last_rev},
1936                         log => $log_entry->{log},
1937                         ra => $self->ra,
1938                         tree_a => $self->{last_commit},
1939                         tree_b => $tree,
1940                         editor_cb => sub {
1941                                $self->set_tree_cb($log_entry, $tree, @_) },
1942                         svn_path => $self->{path} );
1943         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1944                 print "No changes\nr$self->{last_rev} = $tree\n";
1945         }
1946 }
1947
1948 sub rebuild {
1949         my ($self) = @_;
1950         my $db_path = $self->db_path;
1951         return if (-e $db_path && ! -z $db_path);
1952         return unless ::verify_ref($self->refname.'^0');
1953         if (-f $self->{db_root}) {
1954                 rename $self->{db_root}, $db_path or die
1955                      "rename $self->{db_root} => $db_path failed: $!\n";
1956                 my ($dir, $base) = ($db_path =~ m#^(.*?)/?([^/]+)$#);
1957                 symlink $base, $self->{db_root} or die
1958                      "symlink $base => $self->{db_root} failed: $!\n";
1959                 return;
1960         }
1961         print "Rebuilding $db_path ...\n";
1962         my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1963         my $latest;
1964         my $full_url = $self->full_url;
1965         remove_username($full_url);
1966         my $svn_uuid;
1967         while (<$rev_list>) {
1968                 chomp;
1969                 my $c = $_;
1970                 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1971                 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1972                 remove_username($url);
1973
1974                 # ignore merges (from set-tree)
1975                 next if (!defined $rev || !$uuid);
1976
1977                 # if we merged or otherwise started elsewhere, this is
1978                 # how we break out of it
1979                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1980                     ($full_url && $url && ($url ne $full_url))) {
1981                         next;
1982                 }
1983                 $latest ||= $rev;
1984                 $svn_uuid ||= $uuid;
1985
1986                 $self->rev_db_set($rev, $c);
1987                 print "r$rev = $c\n";
1988         }
1989         command_close_pipe($rev_list, $ctx);
1990         print "Done rebuilding $db_path\n";
1991 }
1992
1993 # rev_db:
1994 # Tie::File seems to be prone to offset errors if revisions get sparse,
1995 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1996 # one of my favorite modules is out :<  Next up would be one of the DBM
1997 # modules, but I'm not sure which is most portable...  So I'll just
1998 # go with something that's plain-text, but still capable of
1999 # being randomly accessed.  So here's my ultra-simple fixed-width
2000 # database.  All records are 40 characters + "\n", so it's easy to seek
2001 # to a revision: (41 * rev) is the byte offset.
2002 # A record of 40 0s denotes an empty revision.
2003 # And yes, it's still pretty fast (faster than Tie::File).
2004 # These files are disposable unless noMetadata or useSvmProps is set
2005
2006 sub _rev_db_set {
2007         my ($fh, $rev, $commit) = @_;
2008         my $offset = $rev * 41;
2009         # assume that append is the common case:
2010         seek $fh, 0, 2 or croak $!;
2011         my $pos = tell $fh;
2012         if ($pos < $offset) {
2013                 for (1 .. (($offset - $pos) / 41)) {
2014                         print $fh (('0' x 40),"\n") or croak $!;
2015                 }
2016         }
2017         seek $fh, $offset, 0 or croak $!;
2018         print $fh $commit,"\n" or croak $!;
2019 }
2020
2021 sub mkfile {
2022         my ($path) = @_;
2023         unless (-e $path) {
2024                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2025                 mkpath([$dir]) unless -d $dir;
2026                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2027                 close $fh or die "Couldn't close (create) $path: $!\n";
2028         }
2029 }
2030
2031 sub rev_db_set {
2032         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2033         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2034         my $db = $self->db_path($uuid);
2035         my $db_lock = "$db.lock";
2036         my $sig;
2037         if ($update_ref) {
2038                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2039                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2040         }
2041         mkfile($db);
2042
2043         $LOCKFILES{$db_lock} = 1;
2044         my $sync;
2045         # both of these options make our .rev_db file very, very important
2046         # and we can't afford to lose it because rebuild() won't work
2047         if ($self->use_svm_props || $self->no_metadata) {
2048                 $sync = 1;
2049                 copy($db, $db_lock) or die "rev_db_set(@_): ",
2050                                            "Failed to copy: ",
2051                                            "$db => $db_lock ($!)\n";
2052         } else {
2053                 rename $db, $db_lock or die "rev_db_set(@_): ",
2054                                             "Failed to rename: ",
2055                                             "$db => $db_lock ($!)\n";
2056         }
2057         open my $fh, '+<', $db_lock or die "Couldn't open $db_lock: $!\n";
2058         _rev_db_set($fh, $rev, $commit);
2059         if ($sync) {
2060                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2061                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2062         }
2063         close $fh or croak $!;
2064         if ($update_ref) {
2065                 $_head = $self;
2066                 command_noisy('update-ref', '-m', "r$rev",
2067                               $self->refname, $commit);
2068         }
2069         rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
2070                                     "$db_lock => $db ($!)\n";
2071         delete $LOCKFILES{$db_lock};
2072         if ($update_ref) {
2073                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2074                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2075                 kill $sig, $$ if defined $sig;
2076         }
2077 }
2078
2079 sub rev_db_max {
2080         my ($self) = @_;
2081         $self->rebuild;
2082         my $db_path = $self->db_path;
2083         my @stat = stat $db_path or return 0;
2084         ($stat[7] % 41) == 0 or die "$db_path inconsistent size: $stat[7]\n";
2085         my $max = $stat[7] / 41;
2086         (($max > 0) ? $max - 1 : 0);
2087 }
2088
2089 sub rev_db_get {
2090         my ($self, $rev, $uuid) = @_;
2091         my $ret;
2092         my $offset = $rev * 41;
2093         my $db_path = $self->db_path($uuid);
2094         return undef unless -e $db_path;
2095         open my $fh, '<', $db_path or croak $!;
2096         if (sysseek($fh, $offset, 0) == $offset) {
2097                 my $read = sysread($fh, $ret, 40);
2098                 $ret = undef if ($read != 40 || $ret eq ('0'x40));
2099         }
2100         close $fh or croak $!;
2101         $ret;
2102 }
2103
2104 sub find_rev_before {
2105         my ($self, $rev, $eq_ok) = @_;
2106         --$rev unless $eq_ok;
2107         while ($rev > 0) {
2108                 if (my $c = $self->rev_db_get($rev)) {
2109                         return ($rev, $c);
2110                 }
2111                 --$rev;
2112         }
2113         return (undef, undef);
2114 }
2115
2116 sub _new {
2117         my ($class, $repo_id, $ref_id, $path) = @_;
2118         unless (defined $repo_id && length $repo_id) {
2119                 $repo_id = $Git::SVN::default_repo_id;
2120         }
2121         unless (defined $ref_id && length $ref_id) {
2122                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2123         }
2124         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2125         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2126         $_[3] = $path = '' unless (defined $path);
2127         mkpath(["$ENV{GIT_DIR}/svn"]);
2128         bless {
2129                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2130                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2131                 db_root => "$dir/.rev_db", repo_id => $repo_id }, $class;
2132 }
2133
2134 sub db_path {
2135         my ($self, $uuid) = @_;
2136         $uuid ||= $self->ra_uuid;
2137         "$self->{db_root}.$uuid";
2138 }
2139
2140 sub uri_encode {
2141         my ($f) = @_;
2142         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2143         $f
2144 }
2145
2146 sub remove_username {
2147         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2148 }
2149
2150 package Git::SVN::Prompt;
2151 use strict;
2152 use warnings;
2153 require SVN::Core;
2154 use vars qw/$_no_auth_cache $_username/;
2155
2156 sub simple {
2157         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2158         $may_save = undef if $_no_auth_cache;
2159         $default_username = $_username if defined $_username;
2160         if (defined $default_username && length $default_username) {
2161                 if (defined $realm && length $realm) {
2162                         print STDERR "Authentication realm: $realm\n";
2163                         STDERR->flush;
2164                 }
2165                 $cred->username($default_username);
2166         } else {
2167                 username($cred, $realm, $may_save, $pool);
2168         }
2169         $cred->password(_read_password("Password for '" .
2170                                        $cred->username . "': ", $realm));
2171         $cred->may_save($may_save);
2172         $SVN::_Core::SVN_NO_ERROR;
2173 }
2174
2175 sub ssl_server_trust {
2176         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2177         $may_save = undef if $_no_auth_cache;
2178         print STDERR "Error validating server certificate for '$realm':\n";
2179         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2180                 print STDERR " - The certificate is not issued by a trusted ",
2181                       "authority. Use the\n",
2182                       "   fingerprint to validate the certificate manually!\n";
2183         }
2184         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2185                 print STDERR " - The certificate hostname does not match.\n";
2186         }
2187         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2188                 print STDERR " - The certificate is not yet valid.\n";
2189         }
2190         if ($failures & $SVN::Auth::SSL::EXPIRED) {
2191                 print STDERR " - The certificate has expired.\n";
2192         }
2193         if ($failures & $SVN::Auth::SSL::OTHER) {
2194                 print STDERR " - The certificate has an unknown error.\n";
2195         }
2196         printf STDERR
2197                 "Certificate information:\n".
2198                 " - Hostname: %s\n".
2199                 " - Valid: from %s until %s\n".
2200                 " - Issuer: %s\n".
2201                 " - Fingerprint: %s\n",
2202                 map $cert_info->$_, qw(hostname valid_from valid_until
2203                                        issuer_dname fingerprint);
2204         my $choice;
2205 prompt:
2206         print STDERR $may_save ?
2207               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2208               "(R)eject or accept (t)emporarily? ";
2209         STDERR->flush;
2210         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2211         if ($choice =~ /^t$/i) {
2212                 $cred->may_save(undef);
2213         } elsif ($choice =~ /^r$/i) {
2214                 return -1;
2215         } elsif ($may_save && $choice =~ /^p$/i) {
2216                 $cred->may_save($may_save);
2217         } else {
2218                 goto prompt;
2219         }
2220         $cred->accepted_failures($failures);
2221         $SVN::_Core::SVN_NO_ERROR;
2222 }
2223
2224 sub ssl_client_cert {
2225         my ($cred, $realm, $may_save, $pool) = @_;
2226         $may_save = undef if $_no_auth_cache;
2227         print STDERR "Client certificate filename: ";
2228         STDERR->flush;
2229         chomp(my $filename = <STDIN>);
2230         $cred->cert_file($filename);
2231         $cred->may_save($may_save);
2232         $SVN::_Core::SVN_NO_ERROR;
2233 }
2234
2235 sub ssl_client_cert_pw {
2236         my ($cred, $realm, $may_save, $pool) = @_;
2237         $may_save = undef if $_no_auth_cache;
2238         $cred->password(_read_password("Password: ", $realm));
2239         $cred->may_save($may_save);
2240         $SVN::_Core::SVN_NO_ERROR;
2241 }
2242
2243 sub username {
2244         my ($cred, $realm, $may_save, $pool) = @_;
2245         $may_save = undef if $_no_auth_cache;
2246         if (defined $realm && length $realm) {
2247                 print STDERR "Authentication realm: $realm\n";
2248         }
2249         my $username;
2250         if (defined $_username) {
2251                 $username = $_username;
2252         } else {
2253                 print STDERR "Username: ";
2254                 STDERR->flush;
2255                 chomp($username = <STDIN>);
2256         }
2257         $cred->username($username);
2258         $cred->may_save($may_save);
2259         $SVN::_Core::SVN_NO_ERROR;
2260 }
2261
2262 sub _read_password {
2263         my ($prompt, $realm) = @_;
2264         print STDERR $prompt;
2265         STDERR->flush;
2266         require Term::ReadKey;
2267         Term::ReadKey::ReadMode('noecho');
2268         my $password = '';
2269         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2270                 last if $key =~ /[\012\015]/; # \n\r
2271                 $password .= $key;
2272         }
2273         Term::ReadKey::ReadMode('restore');
2274         print STDERR "\n";
2275         STDERR->flush;
2276         $password;
2277 }
2278
2279 package main;
2280
2281 {
2282         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2283                                 $SVN::Node::dir.$SVN::Node::unknown.
2284                                 $SVN::Node::none.$SVN::Node::file.
2285                                 $SVN::Node::dir.$SVN::Node::unknown.
2286                                 $SVN::Auth::SSL::CNMISMATCH.
2287                                 $SVN::Auth::SSL::NOTYETVALID.
2288                                 $SVN::Auth::SSL::EXPIRED.
2289                                 $SVN::Auth::SSL::UNKNOWNCA.
2290                                 $SVN::Auth::SSL::OTHER;
2291 }
2292
2293 package SVN::Git::Fetcher;
2294 use vars qw/@ISA/;
2295 use strict;
2296 use warnings;
2297 use Carp qw/croak/;
2298 use IO::File qw//;
2299 use Digest::MD5;
2300
2301 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2302 sub new {
2303         my ($class, $git_svn) = @_;
2304         my $self = SVN::Delta::Editor->new;
2305         bless $self, $class;
2306         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2307         $self->{empty} = {};
2308         $self->{dir_prop} = {};
2309         $self->{file_prop} = {};
2310         $self->{absent_dir} = {};
2311         $self->{absent_file} = {};
2312         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2313         $self;
2314 }
2315
2316 sub set_path_strip {
2317         my ($self, $path) = @_;
2318         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2319 }
2320
2321 sub open_root {
2322         { path => '' };
2323 }
2324
2325 sub open_directory {
2326         my ($self, $path, $pb, $rev) = @_;
2327         { path => $path };
2328 }
2329
2330 sub git_path {
2331         my ($self, $path) = @_;
2332         if ($self->{path_strip}) {
2333                 $path =~ s!$self->{path_strip}!! or
2334                   die "Failed to strip path '$path' ($self->{path_strip})\n";
2335         }
2336         $path;
2337 }
2338
2339 sub delete_entry {
2340         my ($self, $path, $rev, $pb) = @_;
2341
2342         my $gpath = $self->git_path($path);
2343         return undef if ($gpath eq '');
2344
2345         # remove entire directories.
2346         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2347                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2348                                                      -r --name-only -z/,
2349                                                      $self->{c}, '--', $gpath);
2350                 local $/ = "\0";
2351                 while (<$ls>) {
2352                         chomp;
2353                         $self->{gii}->remove($_);
2354                         print "\tD\t$_\n" unless $::_q;
2355                 }
2356                 print "\tD\t$gpath/\n" unless $::_q;
2357                 command_close_pipe($ls, $ctx);
2358                 $self->{empty}->{$path} = 0
2359         } else {
2360                 $self->{gii}->remove($gpath);
2361                 print "\tD\t$gpath\n" unless $::_q;
2362         }
2363         undef;
2364 }
2365
2366 sub open_file {
2367         my ($self, $path, $pb, $rev) = @_;
2368         my $gpath = $self->git_path($path);
2369         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
2370                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2371         unless (defined $mode && defined $blob) {
2372                 die "$path was not found in commit $self->{c} (r$rev)\n";
2373         }
2374         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2375           pool => SVN::Pool->new, action => 'M' };
2376 }
2377
2378 sub add_file {
2379         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2380         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2381         delete $self->{empty}->{$dir};
2382         { path => $path, mode_a => 100644, mode_b => 100644,
2383           pool => SVN::Pool->new, action => 'A' };
2384 }
2385
2386 sub add_directory {
2387         my ($self, $path, $cp_path, $cp_rev) = @_;
2388         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2389         delete $self->{empty}->{$dir};
2390         $self->{empty}->{$path} = 1;
2391         { path => $path };
2392 }
2393
2394 sub change_dir_prop {
2395         my ($self, $db, $prop, $value) = @_;
2396         $self->{dir_prop}->{$db->{path}} ||= {};
2397         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2398         undef;
2399 }
2400
2401 sub absent_directory {
2402         my ($self, $path, $pb) = @_;
2403         $self->{absent_dir}->{$pb->{path}} ||= [];
2404         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2405         undef;
2406 }
2407
2408 sub absent_file {
2409         my ($self, $path, $pb) = @_;
2410         $self->{absent_file}->{$pb->{path}} ||= [];
2411         push @{$self->{absent_file}->{$pb->{path}}}, $path;
2412         undef;
2413 }
2414
2415 sub change_file_prop {
2416         my ($self, $fb, $prop, $value) = @_;
2417         if ($prop eq 'svn:executable') {
2418                 if ($fb->{mode_b} != 120000) {
2419                         $fb->{mode_b} = defined $value ? 100755 : 100644;
2420                 }
2421         } elsif ($prop eq 'svn:special') {
2422                 $fb->{mode_b} = defined $value ? 120000 : 100644;
2423         } else {
2424                 $self->{file_prop}->{$fb->{path}} ||= {};
2425                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2426         }
2427         undef;
2428 }
2429
2430 sub apply_textdelta {
2431         my ($self, $fb, $exp) = @_;
2432         my $fh = IO::File->new_tmpfile;
2433         $fh->autoflush(1);
2434         # $fh gets auto-closed() by SVN::TxDelta::apply(),
2435         # (but $base does not,) so dup() it for reading in close_file
2436         open my $dup, '<&', $fh or croak $!;
2437         my $base = IO::File->new_tmpfile;
2438         $base->autoflush(1);
2439         if ($fb->{blob}) {
2440                 defined (my $pid = fork) or croak $!;
2441                 if (!$pid) {
2442                         open STDOUT, '>&', $base or croak $!;
2443                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2444                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2445                 }
2446                 waitpid $pid, 0;
2447                 croak $? if $?;
2448
2449                 if (defined $exp) {
2450                         seek $base, 0, 0 or croak $!;
2451                         my $md5 = Digest::MD5->new;
2452                         $md5->addfile($base);
2453                         my $got = $md5->hexdigest;
2454                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2455                             "expected: $exp\n",
2456                             "     got: $got\n" if ($got ne $exp);
2457                 }
2458         }
2459         seek $base, 0, 0 or croak $!;
2460         $fb->{fh} = $dup;
2461         $fb->{base} = $base;
2462         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2463 }
2464
2465 sub close_file {
2466         my ($self, $fb, $exp) = @_;
2467         my $hash;
2468         my $path = $self->git_path($fb->{path});
2469         if (my $fh = $fb->{fh}) {
2470                 seek($fh, 0, 0) or croak $!;
2471                 my $md5 = Digest::MD5->new;
2472                 $md5->addfile($fh);
2473                 my $got = $md5->hexdigest;
2474                 die "Checksum mismatch: $path\n",
2475                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
2476                 sysseek($fh, 0, 0) or croak $!;
2477                 if ($fb->{mode_b} == 120000) {
2478                         sysread($fh, my $buf, 5) == 5 or croak $!;
2479                         $buf eq 'link ' or die "$path has mode 120000",
2480                                                "but is not a link\n";
2481                 }
2482                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2483                 if (!$pid) {
2484                         open STDIN, '<&', $fh or croak $!;
2485                         exec qw/git-hash-object -w --stdin/ or croak $!;
2486                 }
2487                 chomp($hash = do { local $/; <$out> });
2488                 close $out or croak $!;
2489                 close $fh or croak $!;
2490                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2491                 close $fb->{base} or croak $!;
2492         } else {
2493                 $hash = $fb->{blob} or die "no blob information\n";
2494         }
2495         $fb->{pool}->clear;
2496         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
2497         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
2498         undef;
2499 }
2500
2501 sub abort_edit {
2502         my $self = shift;
2503         $self->{nr} = $self->{gii}->{nr};
2504         delete $self->{gii};
2505         $self->SUPER::abort_edit(@_);
2506 }
2507
2508 sub close_edit {
2509         my $self = shift;
2510         $self->{git_commit_ok} = 1;
2511         $self->{nr} = $self->{gii}->{nr};
2512         delete $self->{gii};
2513         $self->SUPER::close_edit(@_);
2514 }
2515
2516 package SVN::Git::Editor;
2517 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
2518 use strict;
2519 use warnings;
2520 use Carp qw/croak/;
2521 use IO::File;
2522 use Digest::MD5;
2523
2524 sub new {
2525         my ($class, $opts) = @_;
2526         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
2527                 die "$_ required!\n" unless (defined $opts->{$_});
2528         }
2529
2530         my $pool = SVN::Pool->new;
2531         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
2532         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
2533                                      $opts->{r}, $mods);
2534
2535         # $opts->{ra} functions should not be used after this:
2536         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
2537                                                 $opts->{editor_cb}, $pool);
2538         my $self = SVN::Delta::Editor->new(@ce, $pool);
2539         bless $self, $class;
2540         foreach (qw/svn_path r tree_a tree_b/) {
2541                 $self->{$_} = $opts->{$_};
2542         }
2543         $self->{url} = $opts->{ra}->{url};
2544         $self->{mods} = $mods;
2545         $self->{types} = $types;
2546         $self->{pool} = $pool;
2547         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2548         $self->{rm} = { };
2549         $self->{path_prefix} = length $self->{svn_path} ?
2550                                "$self->{svn_path}/" : '';
2551         return $self;
2552 }
2553
2554 sub generate_diff {
2555         my ($tree_a, $tree_b) = @_;
2556         my @diff_tree = qw(diff-tree -z -r);
2557         if ($_cp_similarity) {
2558                 push @diff_tree, "-C$_cp_similarity";
2559         } else {
2560                 push @diff_tree, '-C';
2561         }
2562         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
2563         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
2564         push @diff_tree, $tree_a, $tree_b;
2565         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2566         local $/ = "\0";
2567         my $state = 'meta';
2568         my @mods;
2569         while (<$diff_fh>) {
2570                 chomp $_; # this gets rid of the trailing "\0"
2571                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2572                                         $::sha1\s($::sha1)\s
2573                                         ([MTCRAD])\d*$/xo) {
2574                         push @mods, {   mode_a => $1, mode_b => $2,
2575                                         sha1_b => $3, chg => $4 };
2576                         if ($4 =~ /^(?:C|R)$/) {
2577                                 $state = 'file_a';
2578                         } else {
2579                                 $state = 'file_b';
2580                         }
2581                 } elsif ($state eq 'file_a') {
2582                         my $x = $mods[$#mods] or croak "Empty array\n";
2583                         if ($x->{chg} !~ /^(?:C|R)$/) {
2584                                 croak "Error parsing $_, $x->{chg}\n";
2585                         }
2586                         $x->{file_a} = $_;
2587                         $state = 'file_b';
2588                 } elsif ($state eq 'file_b') {
2589                         my $x = $mods[$#mods] or croak "Empty array\n";
2590                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2591                                 croak "Error parsing $_, $x->{chg}\n";
2592                         }
2593                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2594                                 croak "Error parsing $_, $x->{chg}\n";
2595                         }
2596                         $x->{file_b} = $_;
2597                         $state = 'meta';
2598                 } else {
2599                         croak "Error parsing $_\n";
2600                 }
2601         }
2602         command_close_pipe($diff_fh, $ctx);
2603         \@mods;
2604 }
2605
2606 sub check_diff_paths {
2607         my ($ra, $pfx, $rev, $mods) = @_;
2608         my %types;
2609         $pfx .= '/' if length $pfx;
2610
2611         sub type_diff_paths {
2612                 my ($ra, $types, $path, $rev) = @_;
2613                 my @p = split m#/+#, $path;
2614                 my $c = shift @p;
2615                 unless (defined $types->{$c}) {
2616                         $types->{$c} = $ra->check_path($c, $rev);
2617                 }
2618                 while (@p) {
2619                         $c .= '/' . shift @p;
2620                         next if defined $types->{$c};
2621                         $types->{$c} = $ra->check_path($c, $rev);
2622                 }
2623         }
2624
2625         foreach my $m (@$mods) {
2626                 foreach my $f (qw/file_a file_b/) {
2627                         next unless defined $m->{$f};
2628                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
2629                         if (length $pfx.$dir && ! defined $types{$dir}) {
2630                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
2631                         }
2632                 }
2633         }
2634         \%types;
2635 }
2636
2637 sub split_path {
2638         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2639 }
2640
2641 sub repo_path {
2642         my ($self, $path) = @_;
2643         $self->{path_prefix}.(defined $path ? $path : '');
2644 }
2645
2646 sub url_path {
2647         my ($self, $path) = @_;
2648         $self->{url} . '/' . $self->repo_path($path);
2649 }
2650
2651 sub rmdirs {
2652         my ($self) = @_;
2653         my $rm = $self->{rm};
2654         delete $rm->{''}; # we never delete the url we're tracking
2655         return unless %$rm;
2656
2657         foreach (keys %$rm) {
2658                 my @d = split m#/#, $_;
2659                 my $c = shift @d;
2660                 $rm->{$c} = 1;
2661                 while (@d) {
2662                         $c .= '/' . shift @d;
2663                         $rm->{$c} = 1;
2664                 }
2665         }
2666         delete $rm->{$self->{svn_path}};
2667         delete $rm->{''}; # we never delete the url we're tracking
2668         return unless %$rm;
2669
2670         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2671                                              $self->{tree_b});
2672         local $/ = "\0";
2673         while (<$fh>) {
2674                 chomp;
2675                 my @dn = split m#/#, $_;
2676                 while (pop @dn) {
2677                         delete $rm->{join '/', @dn};
2678                 }
2679                 unless (%$rm) {
2680                         close $fh;
2681                         return;
2682                 }
2683         }
2684         command_close_pipe($fh, $ctx);
2685
2686         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2687         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2688                 $self->close_directory($bat->{$d}, $p);
2689                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2690                 print "\tD+\t$d/\n" unless $::_q;
2691                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2692                 delete $bat->{$d};
2693         }
2694 }
2695
2696 sub open_or_add_dir {
2697         my ($self, $full_path, $baton) = @_;
2698         my $t = $self->{types}->{$full_path};
2699         if (!defined $t) {
2700                 die "$full_path not known in r$self->{r} or we have a bug!\n";
2701         }
2702         if ($t == $SVN::Node::none) {
2703                 return $self->add_directory($full_path, $baton,
2704                                                 undef, -1, $self->{pool});
2705         } elsif ($t == $SVN::Node::dir) {
2706                 return $self->open_directory($full_path, $baton,
2707                                                 $self->{r}, $self->{pool});
2708         }
2709         print STDERR "$full_path already exists in repository at ",
2710                 "r$self->{r} and it is not a directory (",
2711                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2712         exit 1;
2713 }
2714
2715 sub ensure_path {
2716         my ($self, $path) = @_;
2717         my $bat = $self->{bat};
2718         my $repo_path = $self->repo_path($path);
2719         return $bat->{''} unless (length $repo_path);
2720         my @p = split m#/+#, $repo_path;
2721         my $c = shift @p;
2722         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2723         while (@p) {
2724                 my $c0 = $c;
2725                 $c .= '/' . shift @p;
2726                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2727         }
2728         return $bat->{$c};
2729 }
2730
2731 sub A {
2732         my ($self, $m) = @_;
2733         my ($dir, $file) = split_path($m->{file_b});
2734         my $pbat = $self->ensure_path($dir);
2735         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2736                                         undef, -1);
2737         print "\tA\t$m->{file_b}\n" unless $::_q;
2738         $self->chg_file($fbat, $m);
2739         $self->close_file($fbat,undef,$self->{pool});
2740 }
2741
2742 sub C {
2743         my ($self, $m) = @_;
2744         my ($dir, $file) = split_path($m->{file_b});
2745         my $pbat = $self->ensure_path($dir);
2746         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2747                                 $self->url_path($m->{file_a}), $self->{r});
2748         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2749         $self->chg_file($fbat, $m);
2750         $self->close_file($fbat,undef,$self->{pool});
2751 }
2752
2753 sub delete_entry {
2754         my ($self, $path, $pbat) = @_;
2755         my $rpath = $self->repo_path($path);
2756         my ($dir, $file) = split_path($rpath);
2757         $self->{rm}->{$dir} = 1;
2758         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2759 }
2760
2761 sub R {
2762         my ($self, $m) = @_;
2763         my ($dir, $file) = split_path($m->{file_b});
2764         my $pbat = $self->ensure_path($dir);
2765         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2766                                 $self->url_path($m->{file_a}), $self->{r});
2767         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2768         $self->chg_file($fbat, $m);
2769         $self->close_file($fbat,undef,$self->{pool});
2770
2771         ($dir, $file) = split_path($m->{file_a});
2772         $pbat = $self->ensure_path($dir);
2773         $self->delete_entry($m->{file_a}, $pbat);
2774 }
2775
2776 sub M {
2777         my ($self, $m) = @_;
2778         my ($dir, $file) = split_path($m->{file_b});
2779         my $pbat = $self->ensure_path($dir);
2780         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2781                                 $pbat,$self->{r},$self->{pool});
2782         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2783         $self->chg_file($fbat, $m);
2784         $self->close_file($fbat,undef,$self->{pool});
2785 }
2786
2787 sub T { shift->M(@_) }
2788
2789 sub change_file_prop {
2790         my ($self, $fbat, $pname, $pval) = @_;
2791         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2792 }
2793
2794 sub chg_file {
2795         my ($self, $fbat, $m) = @_;
2796         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2797                 $self->change_file_prop($fbat,'svn:executable','*');
2798         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2799                 $self->change_file_prop($fbat,'svn:executable',undef);
2800         }
2801         my $fh = IO::File->new_tmpfile or croak $!;
2802         if ($m->{mode_b} =~ /^120/) {
2803                 print $fh 'link ' or croak $!;
2804                 $self->change_file_prop($fbat,'svn:special','*');
2805         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2806                 $self->change_file_prop($fbat,'svn:special',undef);
2807         }
2808         defined(my $pid = fork) or croak $!;
2809         if (!$pid) {
2810                 open STDOUT, '>&', $fh or croak $!;
2811                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2812         }
2813         waitpid $pid, 0;
2814         croak $? if $?;
2815         $fh->flush == 0 or croak $!;
2816         seek $fh, 0, 0 or croak $!;
2817
2818         my $md5 = Digest::MD5->new;
2819         $md5->addfile($fh) or croak $!;
2820         seek $fh, 0, 0 or croak $!;
2821
2822         my $exp = $md5->hexdigest;
2823         my $pool = SVN::Pool->new;
2824         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2825         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2826         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2827         $pool->clear;
2828
2829         close $fh or croak $!;
2830 }
2831
2832 sub D {
2833         my ($self, $m) = @_;
2834         my ($dir, $file) = split_path($m->{file_b});
2835         my $pbat = $self->ensure_path($dir);
2836         print "\tD\t$m->{file_b}\n" unless $::_q;
2837         $self->delete_entry($m->{file_b}, $pbat);
2838 }
2839
2840 sub close_edit {
2841         my ($self) = @_;
2842         my ($p,$bat) = ($self->{pool}, $self->{bat});
2843         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2844                 $self->close_directory($bat->{$_}, $p);
2845         }
2846         $self->SUPER::close_edit($p);
2847         $p->clear;
2848 }
2849
2850 sub abort_edit {
2851         my ($self) = @_;
2852         $self->SUPER::abort_edit($self->{pool});
2853 }
2854
2855 sub DESTROY {
2856         my $self = shift;
2857         $self->SUPER::DESTROY(@_);
2858         $self->{pool}->clear;
2859 }
2860
2861 # this drives the editor
2862 sub apply_diff {
2863         my ($self) = @_;
2864         my $mods = $self->{mods};
2865         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2866         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2867                 my $f = $m->{chg};
2868                 if (defined $o{$f}) {
2869                         $self->$f($m);
2870                 } else {
2871                         fatal("Invalid change type: $f\n");
2872                 }
2873         }
2874         $self->rmdirs if $_rmdir;
2875         if (@$mods == 0) {
2876                 $self->abort_edit;
2877         } else {
2878                 $self->close_edit;
2879         }
2880         return scalar @$mods;
2881 }
2882
2883 package Git::SVN::Ra;
2884 use vars qw/@ISA $config_dir $_log_window_size/;
2885 use strict;
2886 use warnings;
2887 my ($can_do_switch, %ignored_err, $RA);
2888
2889 BEGIN {
2890         # enforce temporary pool usage for some simple functions
2891         my $e;
2892         foreach (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
2893                 $e .= "sub $_ {
2894                         my \$self = shift;
2895                         my \$pool = SVN::Pool->new;
2896                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2897                         \$pool->clear;
2898                         wantarray ? \@ret : \$ret[0]; }\n";
2899         }
2900
2901         eval "$e; 1;" or die $@;
2902 }
2903
2904 sub new {
2905         my ($class, $url) = @_;
2906         $url =~ s!/+$!!;
2907         return $RA if ($RA && $RA->{url} eq $url);
2908
2909         SVN::_Core::svn_config_ensure($config_dir, undef);
2910         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2911             SVN::Client::get_simple_provider(),
2912             SVN::Client::get_ssl_server_trust_file_provider(),
2913             SVN::Client::get_simple_prompt_provider(
2914               \&Git::SVN::Prompt::simple, 2),
2915             SVN::Client::get_ssl_client_cert_prompt_provider(
2916               \&Git::SVN::Prompt::ssl_client_cert, 2),
2917             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2918               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2919             SVN::Client::get_username_provider(),
2920             SVN::Client::get_ssl_server_trust_prompt_provider(
2921               \&Git::SVN::Prompt::ssl_server_trust),
2922             SVN::Client::get_username_prompt_provider(
2923               \&Git::SVN::Prompt::username, 2),
2924           ]);
2925         my $config = SVN::Core::config_get_config($config_dir);
2926         my $self = SVN::Ra->new(url => $url, auth => $baton,
2927                               config => $config,
2928                               pool => SVN::Pool->new,
2929                               auth_provider_callbacks => $callbacks);
2930         $self->{svn_path} = $url;
2931         $self->{repos_root} = $self->get_repos_root;
2932         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
2933         $self->{cache} = { check_path => { r => 0, data => {} },
2934                            get_dir => { r => 0, data => {} } };
2935         $RA = bless $self, $class;
2936 }
2937
2938 sub check_path {
2939         my ($self, $path, $r) = @_;
2940         my $cache = $self->{cache}->{check_path};
2941         if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
2942                 return $cache->{data}->{$path};
2943         }
2944         my $pool = SVN::Pool->new;
2945         my $t = $self->SUPER::check_path($path, $r, $pool);
2946         $pool->clear;
2947         if ($r != $cache->{r}) {
2948                 %{$cache->{data}} = ();
2949                 $cache->{r} = $r;
2950         }
2951         $cache->{data}->{$path} = $t;
2952 }
2953
2954 sub get_dir {
2955         my ($self, $dir, $r) = @_;
2956         my $cache = $self->{cache}->{get_dir};
2957         if ($r == $cache->{r}) {
2958                 if (my $x = $cache->{data}->{$dir}) {
2959                         return wantarray ? @$x : $x->[0];
2960                 }
2961         }
2962         my $pool = SVN::Pool->new;
2963         my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
2964         my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
2965         $pool->clear;
2966         if ($r != $cache->{r}) {
2967                 %{$cache->{data}} = ();
2968                 $cache->{r} = $r;
2969         }
2970         $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
2971         wantarray ? (\%dirents, $r, $props) : \%dirents;
2972 }
2973
2974 sub DESTROY {
2975         # do not call the real DESTROY since we store ourselves in $RA
2976 }
2977
2978 sub get_log {
2979         my ($self, @args) = @_;
2980         my $pool = SVN::Pool->new;
2981         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2982         my $ret = $self->SUPER::get_log(@args, $pool);
2983         $pool->clear;
2984         $ret;
2985 }
2986
2987 sub get_commit_editor {
2988         my ($self, $log, $cb, $pool) = @_;
2989         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2990         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2991 }
2992
2993 sub gs_do_update {
2994         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
2995         my $new = ($rev_a == $rev_b);
2996         my $path = $gs->{path};
2997
2998         if ($new && -e $gs->{index}) {
2999                 unlink $gs->{index} or die
3000                   "Couldn't unlink index: $gs->{index}: $!\n";
3001         }
3002         my $pool = SVN::Pool->new;
3003         $editor->set_path_strip($path);
3004         my (@pc) = split m#/#, $path;
3005         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3006                                         1, $editor, $pool);
3007         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3008
3009         # Since we can't rely on svn_ra_reparent being available, we'll
3010         # just have to do some magic with set_path to make it so
3011         # we only want a partial path.
3012         my $sp = '';
3013         my $final = join('/', @pc);
3014         while (@pc) {
3015                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3016                 $sp .= '/' if length $sp;
3017                 $sp .= shift @pc;
3018         }
3019         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3020
3021         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3022
3023         $reporter->finish_report($pool);
3024         $pool->clear;
3025         $editor->{git_commit_ok};
3026 }
3027
3028 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3029 # svn_ra_reparent didn't work before 1.4)
3030 sub gs_do_switch {
3031         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3032         my $path = $gs->{path};
3033         my $pool = SVN::Pool->new;
3034
3035         my $full_url = $self->{url};
3036         my $old_url = $full_url;
3037         $full_url .= "/$path" if length $path;
3038         my ($ra, $reparented);
3039         if ($old_url ne $full_url) {
3040                 if ($old_url !~ m#^svn(\+ssh)?://#) {
3041                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3042                                                   $pool);
3043                         $self->{url} = $full_url;
3044                         $reparented = 1;
3045                 } else {
3046                         $ra = Git::SVN::Ra->new($full_url);
3047                 }
3048         }
3049         $ra ||= $self;
3050         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3051         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3052         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3053         $reporter->finish_report($pool);
3054
3055         if ($reparented) {
3056                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3057                 $self->{url} = $old_url;
3058         }
3059
3060         $pool->clear;
3061         $editor->{git_commit_ok};
3062 }
3063
3064 sub gs_fetch_loop_common {
3065         my ($self, $base, $head, $gsv, $globs) = @_;
3066         return if ($base > $head);
3067         my $inc = $_log_window_size;
3068         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3069         my %common;
3070         my $common_max = scalar @$gsv;
3071
3072         foreach my $gs (@$gsv) {
3073                 my @tmp = split m#/#, $gs->{path};
3074                 my $p = '';
3075                 foreach (@tmp) {
3076                         $p .= length($p) ? "/$_" : $_;
3077                         $common{$p} ||= 0;
3078                         $common{$p}++;
3079                 }
3080         }
3081         $globs ||= [];
3082         $common_max += scalar @$globs;
3083         foreach my $glob (@$globs) {
3084                 my @tmp = split m#/#, $glob->{path}->{left};
3085                 my $p = '';
3086                 foreach (@tmp) {
3087                         $p .= length($p) ? "/$_" : $_;
3088                         $common{$p} ||= 0;
3089                         $common{$p}++;
3090                 }
3091         }
3092
3093         my $longest_path = '';
3094         foreach (sort {length $b <=> length $a} keys %common) {
3095                 if ($common{$_} == $common_max) {
3096                         $longest_path = $_;
3097                         last;
3098                 }
3099         }
3100         while (1) {
3101                 my %revs;
3102                 my $err;
3103                 my $err_handler = $SVN::Error::handler;
3104                 $SVN::Error::handler = sub {
3105                         ($err) = @_;
3106                         skip_unknown_revs($err);
3107                 };
3108                 sub _cb {
3109                         my ($paths, $r, $author, $date, $log) = @_;
3110                         [ dup_changed_paths($paths),
3111                           { author => $author, date => $date, log => $log } ];
3112                 }
3113                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3114                                sub { $revs{$_[1]} = _cb(@_) });
3115                 if ($err && $max >= $head) {
3116                         print STDERR "Path '$longest_path' ",
3117                                      "was probably deleted:\n",
3118                                      $err->expanded_message,
3119                                      "\nWill attempt to follow ",
3120                                      "revisions r$min .. r$max ",
3121                                      "committed before the deletion\n";
3122                         my $hi = $max;
3123                         while (--$hi >= $min) {
3124                                 my $ok;
3125                                 $self->get_log([$longest_path], $min, $hi,
3126                                                0, 1, 1, sub {
3127                                                $ok ||= $_[1];
3128                                                $revs{$_[1]} = _cb(@_) });
3129                                 if ($ok) {
3130                                         print STDERR "r$min .. r$ok OK\n";
3131                                         last;
3132                                 }
3133                         }
3134                 }
3135                 $SVN::Error::handler = $err_handler;
3136
3137                 my %exists = map { $_->{path} => $_ } @$gsv;
3138                 foreach my $r (sort {$a <=> $b} keys %revs) {
3139                         my ($paths, $logged) = @{$revs{$r}};
3140
3141                         foreach my $gs ($self->match_globs(\%exists, $paths,
3142                                                            $globs, $r)) {
3143                                 if ($gs->rev_db_max >= $r) {
3144                                         next;
3145                                 }
3146                                 next unless $gs->match_paths($paths, $r);
3147                                 $gs->{logged_rev_props} = $logged;
3148                                 if (my $last_commit = $gs->last_commit) {
3149                                         $gs->assert_index_clean($last_commit);
3150                                 }
3151                                 my $log_entry = $gs->do_fetch($paths, $r);
3152                                 if ($log_entry) {
3153                                         $gs->do_git_commit($log_entry);
3154                                 }
3155                         }
3156                         foreach my $g (@$globs) {
3157                                 my $k = "svn-remote.$g->{remote}." .
3158                                         "$g->{t}-maxRev";
3159                                 Git::SVN::tmp_config($k, $r);
3160                         }
3161                 }
3162                 # pre-fill the .rev_db since it'll eventually get filled in
3163                 # with '0' x40 if something new gets committed
3164                 foreach my $gs (@$gsv) {
3165                         next if defined $gs->rev_db_get($max);
3166                         $gs->rev_db_set($max, 0 x40);
3167                 }
3168                 foreach my $g (@$globs) {
3169                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3170                         Git::SVN::tmp_config($k, $max);
3171                 }
3172                 last if $max >= $head;
3173                 $min = $max + 1;
3174                 $max += $inc;
3175                 $max = $head if ($max > $head);
3176         }
3177 }
3178
3179 sub match_globs {
3180         my ($self, $exists, $paths, $globs, $r) = @_;
3181
3182         sub get_dir_check {
3183                 my ($self, $exists, $g, $r) = @_;
3184                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3185                 return unless scalar @x == 3;
3186                 my $dirents = $x[0];
3187                 foreach my $de (keys %$dirents) {
3188                         next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3189                         my $p = $g->{path}->full_path($de);
3190                         next if $exists->{$p};
3191                         next if (length $g->{path}->{right} &&
3192                                  ($self->check_path($p, $r) !=
3193                                   $SVN::Node::dir));
3194                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3195                                          $g->{ref}->full_path($de), 1);
3196                 }
3197         }
3198         foreach my $g (@$globs) {
3199                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3200                         if ($path->{action} =~ /^[AR]$/) {
3201                                 get_dir_check($self, $exists, $g, $r);
3202                         }
3203                 }
3204                 foreach (keys %$paths) {
3205                         if (/$g->{path}->{left_regex}/ &&
3206                             !/$g->{path}->{regex}/) {
3207                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
3208                                 get_dir_check($self, $exists, $g, $r);
3209                         }
3210                         next unless /$g->{path}->{regex}/;
3211                         my $p = $1;
3212                         my $pathname = $g->{path}->full_path($p);
3213                         next if $exists->{$pathname};
3214                         next if ($self->check_path($pathname, $r) !=
3215                                  $SVN::Node::dir);
3216                         $exists->{$pathname} = Git::SVN->init(
3217                                               $self->{url}, $pathname, undef,
3218                                               $g->{ref}->full_path($p), 1);
3219                 }
3220                 my $c = '';
3221                 foreach (split m#/#, $g->{path}->{left}) {
3222                         $c .= "/$_";
3223                         next unless ($paths->{$c} &&
3224                                      ($paths->{$c}->{action} =~ /^[AR]$/));
3225                         get_dir_check($self, $exists, $g, $r);
3226                 }
3227         }
3228         values %$exists;
3229 }
3230
3231 sub minimize_url {
3232         my ($self) = @_;
3233         return $self->{url} if ($self->{url} eq $self->{repos_root});
3234         my $url = $self->{repos_root};
3235         my @components = split(m!/!, $self->{svn_path});
3236         my $c = '';
3237         do {
3238                 $url .= "/$c" if length $c;
3239                 eval { (ref $self)->new($url)->get_latest_revnum };
3240         } while ($@ && ($c = shift @components));
3241         $url;
3242 }
3243
3244 sub can_do_switch {
3245         my $self = shift;
3246         unless (defined $can_do_switch) {
3247                 my $pool = SVN::Pool->new;
3248                 my $rep = eval {
3249                         $self->do_switch(1, '', 0, $self->{url},
3250                                          SVN::Delta::Editor->new, $pool);
3251                 };
3252                 if ($@) {
3253                         $can_do_switch = 0;
3254                 } else {
3255                         $rep->abort_report($pool);
3256                         $can_do_switch = 1;
3257                 }
3258                 $pool->clear;
3259         }
3260         $can_do_switch;
3261 }
3262
3263 sub skip_unknown_revs {
3264         my ($err) = @_;
3265         my $errno = $err->apr_err();
3266         # Maybe the branch we're tracking didn't
3267         # exist when the repo started, so it's
3268         # not an error if it doesn't, just continue
3269         #
3270         # Wonderfully consistent library, eh?
3271         # 160013 - svn:// and file://
3272         # 175002 - http(s)://
3273         # 175007 - http(s):// (this repo required authorization, too...)
3274         #   More codes may be discovered later...
3275         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3276                 my $err_key = $err->expanded_message;
3277                 # revision numbers change every time, filter them out
3278                 $err_key =~ s/\d+/\0/g;
3279                 $err_key = "$errno\0$err_key";
3280                 unless ($ignored_err{$err_key}) {
3281                         warn "W: Ignoring error from SVN, path probably ",
3282                              "does not exist: ($errno): ",
3283                              $err->expanded_message,"\n";
3284                         $ignored_err{$err_key} = 1;
3285                 }
3286                 return;
3287         }
3288         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3289 }
3290
3291 # svn_log_changed_path_t objects passed to get_log are likely to be
3292 # overwritten even if only the refs are copied to an external variable,
3293 # so we should dup the structures in their entirety.  Using an externally
3294 # passed pool (instead of our temporary and quickly cleared pool in
3295 # Git::SVN::Ra) does not help matters at all...
3296 sub dup_changed_paths {
3297         my ($paths) = @_;
3298         return undef unless $paths;
3299         my %ret;
3300         foreach my $p (keys %$paths) {
3301                 my $i = $paths->{$p};
3302                 my %s = map { $_ => $i->$_ }
3303                               qw/copyfrom_path copyfrom_rev action/;
3304                 $ret{$p} = \%s;
3305         }
3306         \%ret;
3307 }
3308
3309 package Git::SVN::Log;
3310 use strict;
3311 use warnings;
3312 use POSIX qw/strftime/;
3313 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
3314             %rusers $show_commit $incremental/;
3315 my $l_fmt;
3316
3317 sub cmt_showable {
3318         my ($c) = @_;
3319         return 1 if defined $c->{r};
3320
3321         # big commit message got truncated by the 16k pretty buffer in rev-list
3322         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
3323                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
3324                 @{$c->{l}} = ();
3325                 my @log = command(qw/cat-file commit/, $c->{c});
3326
3327                 # shift off the headers
3328                 shift @log while ($log[0] ne '');
3329                 shift @log;
3330
3331                 # TODO: make $c->{l} not have a trailing newline in the future
3332                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
3333
3334                 (undef, $c->{r}, undef) = ::extract_metadata(
3335                                 (grep(/^git-svn-id: /, @log))[-1]);
3336         }
3337         return defined $c->{r};
3338 }
3339
3340 sub log_use_color {
3341         return 1 if $color;
3342         my ($dc, $dcvar);
3343         $dcvar = 'color.diff';
3344         $dc = `git-config --get $dcvar`;
3345         if ($dc eq '') {
3346                 # nothing at all; fallback to "diff.color"
3347                 $dcvar = 'diff.color';
3348                 $dc = `git-config --get $dcvar`;
3349         }
3350         chomp($dc);
3351         if ($dc eq 'auto') {
3352                 my $pc;
3353                 $pc = `git-config --get color.pager`;
3354                 if ($pc eq '') {
3355                         # does not have it -- fallback to pager.color
3356                         $pc = `git-config --bool --get pager.color`;
3357                 }
3358                 else {
3359                         $pc = `git-config --bool --get color.pager`;
3360                         if ($?) {
3361                                 $pc = 'false';
3362                         }
3363                 }
3364                 chomp($pc);
3365                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
3366                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
3367                 }
3368                 return 0;
3369         }
3370         return 0 if $dc eq 'never';
3371         return 1 if $dc eq 'always';
3372         chomp($dc = `git-config --bool --get $dcvar`);
3373         return ($dc eq 'true');
3374 }
3375
3376 sub git_svn_log_cmd {
3377         my ($r_min, $r_max, @args) = @_;
3378         my $head = 'HEAD';
3379         foreach my $x (@args) {
3380                 last if $x eq '--';
3381                 next unless ::verify_ref("$x^0");
3382                 $head = $x;
3383                 last;
3384         }
3385
3386         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
3387         $gs ||= Git::SVN->_new;
3388         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
3389                    $gs->refname);
3390         push @cmd, '-r' unless $non_recursive;
3391         push @cmd, qw/--raw --name-status/ if $verbose;
3392         push @cmd, '--color' if log_use_color();
3393         return @cmd unless defined $r_max;
3394         if ($r_max == $r_min) {
3395                 push @cmd, '--max-count=1';
3396                 if (my $c = $gs->rev_db_get($r_max)) {
3397                         push @cmd, $c;
3398                 }
3399         } else {
3400                 my ($c_min, $c_max);
3401                 $c_max = $gs->rev_db_get($r_max);
3402                 $c_min = $gs->rev_db_get($r_min);
3403                 if (defined $c_min && defined $c_max) {
3404                         if ($r_max > $r_max) {
3405                                 push @cmd, "$c_min..$c_max";
3406                         } else {
3407                                 push @cmd, "$c_max..$c_min";
3408                         }
3409                 } elsif ($r_max > $r_min) {
3410                         push @cmd, $c_max;
3411                 } else {
3412                         push @cmd, $c_min;
3413                 }
3414         }
3415         return @cmd;
3416 }
3417
3418 # adapted from pager.c
3419 sub config_pager {
3420         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
3421         if (!defined $pager) {
3422                 $pager = 'less';
3423         } elsif (length $pager == 0 || $pager eq 'cat') {
3424                 $pager = undef;
3425         }
3426 }
3427
3428 sub run_pager {
3429         return unless -t *STDOUT;
3430         pipe my $rfd, my $wfd or return;
3431         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
3432         if (!$pid) {
3433                 open STDOUT, '>&', $wfd or
3434                                      ::fatal "Can't redirect to stdout: $!\n";
3435                 return;
3436         }
3437         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
3438         $ENV{LESS} ||= 'FRSX';
3439         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
3440 }
3441
3442 sub tz_to_s_offset {
3443         my ($tz) = @_;
3444         $tz =~ s/(\d\d)$//;
3445         return ($1 * 60) + ($tz * 3600);
3446 }
3447
3448 sub get_author_info {
3449         my ($dest, $author, $t, $tz) = @_;
3450         $author =~ s/(?:^\s*|\s*$)//g;
3451         $dest->{a_raw} = $author;
3452         my $au;
3453         if ($::_authors) {
3454                 $au = $rusers{$author} || undef;
3455         }
3456         if (!$au) {
3457                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
3458         }
3459         $dest->{t} = $t;
3460         $dest->{tz} = $tz;
3461         $dest->{a} = $au;
3462         # Date::Parse isn't in the standard Perl distro :(
3463         if ($tz =~ s/^\+//) {
3464                 $t += tz_to_s_offset($tz);
3465         } elsif ($tz =~ s/^\-//) {
3466                 $t -= tz_to_s_offset($tz);
3467         }
3468         $dest->{t_utc} = $t;
3469 }
3470
3471 sub process_commit {
3472         my ($c, $r_min, $r_max, $defer) = @_;
3473         if (defined $r_min && defined $r_max) {
3474                 if ($r_min == $c->{r} && $r_min == $r_max) {
3475                         show_commit($c);
3476                         return 0;
3477                 }
3478                 return 1 if $r_min == $r_max;
3479                 if ($r_min < $r_max) {
3480                         # we need to reverse the print order
3481                         return 0 if (defined $limit && --$limit < 0);
3482                         push @$defer, $c;
3483                         return 1;
3484                 }
3485                 if ($r_min != $r_max) {
3486                         return 1 if ($r_min < $c->{r});
3487                         return 1 if ($r_max > $c->{r});
3488                 }
3489         }
3490         return 0 if (defined $limit && --$limit < 0);
3491         show_commit($c);
3492         return 1;
3493 }
3494
3495 sub show_commit {
3496         my $c = shift;
3497         if ($oneline) {
3498                 my $x = "\n";
3499                 if (my $l = $c->{l}) {
3500                         while ($l->[0] =~ /^\s*$/) { shift @$l }
3501                         $x = $l->[0];
3502                 }
3503                 $l_fmt ||= 'A' . length($c->{r});
3504                 print 'r',pack($l_fmt, $c->{r}),' | ';
3505                 print "$c->{c} | " if $show_commit;
3506                 print $x;
3507         } else {
3508                 show_commit_normal($c);
3509         }
3510 }
3511
3512 sub show_commit_changed_paths {
3513         my ($c) = @_;
3514         return unless $c->{changed};
3515         print "Changed paths:\n", @{$c->{changed}};
3516 }
3517
3518 sub show_commit_normal {
3519         my ($c) = @_;
3520         print '-' x72, "\nr$c->{r} | ";
3521         print "$c->{c} | " if $show_commit;
3522         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
3523                                  localtime($c->{t_utc})), ' | ';
3524         my $nr_line = 0;
3525
3526         if (my $l = $c->{l}) {
3527                 while ($l->[$#$l] eq "\n" && $#$l > 0
3528                                           && $l->[($#$l - 1)] eq "\n") {
3529                         pop @$l;
3530                 }
3531                 $nr_line = scalar @$l;
3532                 if (!$nr_line) {
3533                         print "1 line\n\n\n";
3534                 } else {
3535                         if ($nr_line == 1) {
3536                                 $nr_line = '1 line';
3537                         } else {
3538                                 $nr_line .= ' lines';
3539                         }
3540                         print $nr_line, "\n";
3541                         show_commit_changed_paths($c);
3542                         print "\n";
3543                         print $_ foreach @$l;
3544                 }
3545         } else {
3546                 print "1 line\n";
3547                 show_commit_changed_paths($c);
3548                 print "\n";
3549
3550         }
3551         foreach my $x (qw/raw stat diff/) {
3552                 if ($c->{$x}) {
3553                         print "\n";
3554                         print $_ foreach @{$c->{$x}}
3555                 }
3556         }
3557 }
3558
3559 sub cmd_show_log {
3560         my (@args) = @_;
3561         my ($r_min, $r_max);
3562         my $r_last = -1; # prevent dupes
3563         if (defined $TZ) {
3564                 $ENV{TZ} = $TZ;
3565         } else {
3566                 delete $ENV{TZ};
3567         }
3568         if (defined $::_revision) {
3569                 if ($::_revision =~ /^(\d+):(\d+)$/) {
3570                         ($r_min, $r_max) = ($1, $2);
3571                 } elsif ($::_revision =~ /^\d+$/) {
3572                         $r_min = $r_max = $::_revision;
3573                 } else {
3574                         ::fatal "-r$::_revision is not supported, use ",
3575                                 "standard \'git log\' arguments instead\n";
3576                 }
3577         }
3578
3579         config_pager();
3580         @args = (git_svn_log_cmd($r_min, $r_max, @args), @args);
3581         my $log = command_output_pipe(@args);
3582         run_pager();
3583         my (@k, $c, $d, $stat);
3584         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
3585         while (<$log>) {
3586                 if (/^${esc_color}commit ($::sha1_short)/o) {
3587                         my $cmt = $1;
3588                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
3589                                 $r_last = $c->{r};
3590                                 process_commit($c, $r_min, $r_max, \@k) or
3591                                                                 goto out;
3592                         }
3593                         $d = undef;
3594                         $c = { c => $cmt };
3595                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
3596                         get_author_info($c, $1, $2, $3);
3597                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
3598                         # ignore
3599                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
3600                         push @{$c->{raw}}, $_;
3601                 } elsif (/^${esc_color}[ACRMDT]\t/) {
3602                         # we could add $SVN->{svn_path} here, but that requires
3603                         # remote access at the moment (repo_path_split)...
3604                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
3605                         push @{$c->{changed}}, $_;
3606                 } elsif (/^${esc_color}diff /o) {
3607                         $d = 1;
3608                         push @{$c->{diff}}, $_;
3609                 } elsif ($d) {
3610                         push @{$c->{diff}}, $_;
3611                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
3612                           $esc_color*[\+\-]*$esc_color$/x) {
3613                         $stat = 1;
3614                         push @{$c->{stat}}, $_;
3615                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
3616                         push @{$c->{stat}}, $_;
3617                         $stat = undef;
3618                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
3619                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
3620                 } elsif (s/^${esc_color}    //o) {
3621                         push @{$c->{l}}, $_;
3622                 }
3623         }
3624         if ($c && defined $c->{r} && $c->{r} != $r_last) {
3625                 $r_last = $c->{r};
3626                 process_commit($c, $r_min, $r_max, \@k);
3627         }
3628         if (@k) {
3629                 my $swap = $r_max;
3630                 $r_max = $r_min;
3631                 $r_min = $swap;
3632                 process_commit($_, $r_min, $r_max) foreach reverse @k;
3633         }
3634 out:
3635         close $log;
3636         print '-' x72,"\n" unless $incremental || $oneline;
3637 }
3638
3639 package Git::SVN::Migration;
3640 # these version numbers do NOT correspond to actual version numbers
3641 # of git nor git-svn.  They are just relative.
3642 #
3643 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
3644 #
3645 # v1 layout: .git/$id/info/url, refs/remotes/$id
3646 #
3647 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
3648 #
3649 # v3 layout: .git/svn/$id, refs/remotes/$id
3650 #            - info/url may remain for backwards compatibility
3651 #            - this is what we migrate up to this layout automatically,
3652 #            - this will be used by git svn init on single branches
3653 # v3.1 layout (auto migrated):
3654 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
3655 #              for backwards compatibility
3656 #
3657 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
3658 #            - this is only created for newly multi-init-ed
3659 #              repositories.  Similar in spirit to the
3660 #              --use-separate-remotes option in git-clone (now default)
3661 #            - we do not automatically migrate to this (following
3662 #              the example set by core git)
3663 use strict;
3664 use warnings;
3665 use Carp qw/croak/;
3666 use File::Path qw/mkpath/;
3667 use File::Basename qw/dirname basename/;
3668 use vars qw/$_minimize/;
3669
3670 sub migrate_from_v0 {
3671         my $git_dir = $ENV{GIT_DIR};
3672         return undef unless -d $git_dir;
3673         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3674         my $migrated = 0;
3675         while (<$fh>) {
3676                 chomp;
3677                 my ($id, $orig_ref) = ($_, $_);
3678                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
3679                 next unless -f "$git_dir/$id/info/url";
3680                 my $new_ref = "refs/remotes/$id";
3681                 if (::verify_ref("$new_ref^0")) {
3682                         print STDERR "W: $orig_ref is probably an old ",
3683                                      "branch used by an ancient version of ",
3684                                      "git-svn.\n",
3685                                      "However, $new_ref also exists.\n",
3686                                      "We will not be able ",
3687                                      "to use this branch until this ",
3688                                      "ambiguity is resolved.\n";
3689                         next;
3690                 }
3691                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
3692                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
3693                 command_noisy('update-ref', $new_ref, $orig_ref);
3694                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
3695                 $migrated++;
3696         }
3697         command_close_pipe($fh, $ctx);
3698         print STDERR "Done migrating from v0 layout...\n" if $migrated;
3699         $migrated;
3700 }
3701
3702 sub migrate_from_v1 {
3703         my $git_dir = $ENV{GIT_DIR};
3704         my $migrated = 0;
3705         return $migrated unless -d $git_dir;
3706         my $svn_dir = "$git_dir/svn";
3707
3708         # just in case somebody used 'svn' as their $id at some point...
3709         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
3710
3711         print STDERR "Migrating from a git-svn v1 layout...\n";
3712         mkpath([$svn_dir]);
3713         print STDERR "Data from a previous version of git-svn exists, but\n\t",
3714                      "$svn_dir\n\t(required for this version ",
3715                      "($::VERSION) of git-svn) does not. exist\n";
3716         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3717         while (<$fh>) {
3718                 my $x = $_;
3719                 next unless $x =~ s#^refs/remotes/##;
3720                 chomp $x;
3721                 next unless -f "$git_dir/$x/info/url";
3722                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
3723                 next unless $u;
3724                 my $dn = dirname("$git_dir/svn/$x");
3725                 mkpath([$dn]) unless -d $dn;
3726                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
3727                         mkpath(["$git_dir/svn/svn"]);
3728                         print STDERR " - $git_dir/$x/info => ",
3729                                         "$git_dir/svn/$x/info\n";
3730                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
3731                                croak "$!: $x";
3732                         # don't worry too much about these, they probably
3733                         # don't exist with repos this old (save for index,
3734                         # and we can easily regenerate that)
3735                         foreach my $f (qw/unhandled.log index .rev_db/) {
3736                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
3737                         }
3738                 } else {
3739                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
3740                         rename "$git_dir/$x", "$git_dir/svn/$x" or
3741                                croak "$!: $x";
3742                 }
3743                 $migrated++;
3744         }
3745         command_close_pipe($fh, $ctx);
3746         print STDERR "Done migrating from a git-svn v1 layout\n";
3747         $migrated;
3748 }
3749
3750 sub read_old_urls {
3751         my ($l_map, $pfx, $path) = @_;
3752         my @dir;
3753         foreach (<$path/*>) {
3754                 if (-r "$_/info/url") {
3755                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
3756                         my $ref_id = $pfx . basename $_;
3757                         my $url = ::file_to_s("$_/info/url");
3758                         $l_map->{$ref_id} = $url;
3759                 } elsif (-d $_) {
3760                         push @dir, $_;
3761                 }
3762         }
3763         foreach (@dir) {
3764                 my $x = $_;
3765                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
3766                 read_old_urls($l_map, $x, $_);
3767         }
3768 }
3769
3770 sub migrate_from_v2 {
3771         my @cfg = command(qw/config -l/);
3772         return if grep /^svn-remote\..+\.url=/, @cfg;
3773         my %l_map;
3774         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
3775         my $migrated = 0;
3776
3777         foreach my $ref_id (sort keys %l_map) {
3778                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
3779                 if ($@) {
3780                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
3781                 }
3782                 $migrated++;
3783         }
3784         $migrated;
3785 }
3786
3787 sub minimize_connections {
3788         my $r = Git::SVN::read_all_remotes();
3789         my $new_urls = {};
3790         my $root_repos = {};
3791         foreach my $repo_id (keys %$r) {
3792                 my $url = $r->{$repo_id}->{url} or next;
3793                 my $fetch = $r->{$repo_id}->{fetch} or next;
3794                 my $ra = Git::SVN::Ra->new($url);
3795
3796                 # skip existing cases where we already connect to the root
3797                 if (($ra->{url} eq $ra->{repos_root}) ||
3798                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
3799                      $repo_id)) {
3800                         $root_repos->{$ra->{url}} = $repo_id;
3801                         next;
3802                 }
3803
3804                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
3805                 my $root_path = $ra->{url};
3806                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
3807                 foreach my $path (keys %$fetch) {
3808                         my $ref_id = $fetch->{$path};
3809                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
3810
3811                         # make sure we can read when connecting to
3812                         # a higher level of a repository
3813                         my ($last_rev, undef) = $gs->last_rev_commit;
3814                         if (!defined $last_rev) {
3815                                 $last_rev = eval {
3816                                         $root_ra->get_latest_revnum;
3817                                 };
3818                                 next if $@;
3819                         }
3820                         my $new = $root_path;
3821                         $new .= length $path ? "/$path" : '';
3822                         eval {
3823                                 $root_ra->get_log([$new], $last_rev, $last_rev,
3824                                                   0, 0, 1, sub { });
3825                         };
3826                         next if $@;
3827                         $new_urls->{$ra->{repos_root}}->{$new} =
3828                                 { ref_id => $ref_id,
3829                                   old_repo_id => $repo_id,
3830                                   old_path => $path };
3831                 }
3832         }
3833
3834         my @emptied;
3835         foreach my $url (keys %$new_urls) {
3836                 # see if we can re-use an existing [svn-remote "repo_id"]
3837                 # instead of creating a(n ugly) new section:
3838                 my $repo_id = $root_repos->{$url} ||
3839                               Git::SVN::sanitize_remote_name($url);
3840
3841                 my $fetch = $new_urls->{$url};
3842                 foreach my $path (keys %$fetch) {
3843                         my $x = $fetch->{$path};
3844                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
3845                         my $pfx = "svn-remote.$x->{old_repo_id}";
3846
3847                         my $old_fetch = quotemeta("$x->{old_path}:".
3848                                                   "refs/remotes/$x->{ref_id}");
3849                         command_noisy(qw/config --unset/,
3850                                       "$pfx.fetch", '^'. $old_fetch . '$');
3851                         delete $r->{$x->{old_repo_id}}->
3852                                {fetch}->{$x->{old_path}};
3853                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3854                                 command_noisy(qw/config --unset/,
3855                                               "$pfx.url");
3856                                 push @emptied, $x->{old_repo_id}
3857                         }
3858                 }
3859         }
3860         if (@emptied) {
3861                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3862                            "$ENV{GIT_DIR}/config";
3863                 print STDERR <<EOF;
3864 The following [svn-remote] sections in your config file ($file) are empty
3865 and can be safely removed:
3866 EOF
3867                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3868         }
3869 }
3870
3871 sub migration_check {
3872         migrate_from_v0();
3873         migrate_from_v1();
3874         migrate_from_v2();
3875         minimize_connections() if $_minimize;
3876 }
3877
3878 package Git::IndexInfo;
3879 use strict;
3880 use warnings;
3881 use Git qw/command_input_pipe command_close_pipe/;
3882
3883 sub new {
3884         my ($class) = @_;
3885         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
3886         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
3887 }
3888
3889 sub remove {
3890         my ($self, $path) = @_;
3891         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
3892                 return ++$self->{nr};
3893         }
3894         undef;
3895 }
3896
3897 sub update {
3898         my ($self, $mode, $hash, $path) = @_;
3899         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
3900                 return ++$self->{nr};
3901         }
3902         undef;
3903 }
3904
3905 sub DESTROY {
3906         my ($self) = @_;
3907         command_close_pipe($self->{gui}, $self->{ctx});
3908 }
3909
3910 package Git::SVN::GlobSpec;
3911 use strict;
3912 use warnings;
3913
3914 sub new {
3915         my ($class, $glob) = @_;
3916         my $re = $glob;
3917         $re =~ s!/+$!!g; # no need for trailing slashes
3918         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
3919         my ($left, $right) = ($1, $2);
3920         if ($nr > 1) {
3921                 die "Only one '*' wildcard expansion ",
3922                     "is supported (got $nr): '$glob'\n";
3923         } elsif ($nr == 0) {
3924                 die "One '*' is needed for glob: '$glob'\n";
3925         }
3926         $re = quotemeta($left) . $re . quotemeta($right);
3927         if (length $left && !($left =~ s!/+$!!g)) {
3928                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
3929         }
3930         if (length $right && !($right =~ s!^/+!!g)) {
3931                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
3932         }
3933         my $left_re = qr/^\/\Q$left\E(\/|$)/;
3934         bless { left => $left, right => $right, left_regex => $left_re,
3935                 regex => qr/$re/, glob => $glob }, $class;
3936 }
3937
3938 sub full_path {
3939         my ($self, $path) = @_;
3940         return (length $self->{left} ? "$self->{left}/" : '') .
3941                $path . (length $self->{right} ? "/$self->{right}" : '');
3942 }
3943
3944 __END__
3945
3946 Data structures:
3947
3948
3949 $remotes = { # returned by read_all_remotes()
3950         'svn' => {
3951                 # svn-remote.svn.url=https://svn.musicpd.org
3952                 url => 'https://svn.musicpd.org',
3953                 # svn-remote.svn.fetch=mpd/trunk:trunk
3954                 fetch => {
3955                         'mpd/trunk' => 'trunk',
3956                 },
3957                 # svn-remote.svn.tags=mpd/tags/*:tags/*
3958                 tags => {
3959                         path => {
3960                                 left => 'mpd/tags',
3961                                 right => '',
3962                                 regex => qr!mpd/tags/([^/]+)$!,
3963                                 glob => 'tags/*',
3964                         },
3965                         ref => {
3966                                 left => 'tags',
3967                                 right => '',
3968                                 regex => qr!tags/([^/]+)$!,
3969                                 glob => 'tags/*',
3970                         },
3971                 }
3972         }
3973 };
3974
3975 $log_entry hashref as returned by libsvn_log_entry()
3976 {
3977         log => 'whitespace-formatted log entry
3978 ',                                              # trailing newline is preserved
3979         revision => '8',                        # integer
3980         date => '2004-02-24T17:01:44.108345Z',  # commit date
3981         author => 'committer name'
3982 };
3983
3984
3985 # this is generated by generate_diff();
3986 @mods = array of diff-index line hashes, each element represents one line
3987         of diff-index output
3988
3989 diff-index line ($m hash)
3990 {
3991         mode_a => first column of diff-index output, no leading ':',
3992         mode_b => second column of diff-index output,
3993         sha1_b => sha1sum of the final blob,
3994         chg => change type [MCRADT],
3995         file_a => original file name of a file (iff chg is 'C' or 'R')
3996         file_b => new/current file name of a file (any chg)
3997 }
3998 ;
3999
4000 # retval of read_url_paths{,_all}();
4001 $l_map = {
4002         # repository root url
4003         'https://svn.musicpd.org' => {
4004                 # repository path               # GIT_SVN_ID
4005                 'mpd/trunk'             =>      'trunk',
4006                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
4007         },
4008 }
4009
4010 Notes:
4011         I don't trust the each() function on unless I created %hash myself
4012         because the internal iterator may not have started at base.