git-svn.perl

   1 #!/usr/bin/env perl
   2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
   3 # License: GPL v2 or later
   4 use warnings;
   5 use strict;
   6 use vars qw/    $AUTHOR $VERSION
   7                 $sha1 $sha1_short $_revision
   8                 $_q $_authors %users/;
   9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
  10 $VERSION = '@@GIT_VERSION@@';
  11
  12 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
  13 $ENV{GIT_DIR} ||= '.git';
  14 $Git::SVN::default_repo_id = 'svn';
  15 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
  16 $Git::SVN::Ra::_log_window_size = 100;
  17
  18 $Git::SVN::Log::TZ = $ENV{TZ};
  19 $ENV{TZ} = 'UTC';
  20 $| = 1; # unbuffer STDOUT
  21
  22 sub fatal (@) { print STDERR @_; exit 1 }
  23 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
  24 require SVN::Ra;
  25 require SVN::Delta;
  26 if ($SVN::Core::VERSION lt '1.1.0') {
  27         fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
  28 }
  29 push @Git::SVN::Ra::ISA, 'SVN::Ra';
  30 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
  31 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
  32 use Carp qw/croak/;
  33 use IO::File qw//;
  34 use File::Basename qw/dirname basename/;
  35 use File::Path qw/mkpath/;
  36 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
  37 use IPC::Open3;
  38 use Git;
  39
  40 BEGIN {
  41         my $s;
  42         foreach (qw/command command_oneline command_noisy command_output_pipe
  43                     command_input_pipe command_close_pipe/) {
  44                 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
  45                       "*Git::SVN::Migration::$_ = ".
  46                       "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
  47         }
  48         eval $s;
  49 }
  50
  51 my ($SVN);
  52
  53 $sha1 = qr/[a-f\d]{40}/;
  54 $sha1_short = qr/[a-f\d]{4,40}/;
  55 my ($_stdin, $_help, $_edit,
  56         $_message, $_file,
  57         $_template, $_shared,
  58         $_version, $_fetch_all,
  59         $_merge, $_strategy, $_dry_run, $_local,
  60         $_prefix, $_no_checkout, $_verbose);
  61 $Git::SVN::_follow_parent = 1;
  62 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
  63                     'config-dir=s' => \$Git::SVN::Ra::config_dir,
  64                     'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
  65 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
  66                 'authors-file|A=s' => \$_authors,
  67                 'repack:i' => \$Git::SVN::_repack,
  68                 'noMetadata' => \$Git::SVN::_no_metadata,
  69                 'useSvmProps' => \$Git::SVN::_use_svm_props,
  70                 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
  71                 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
  72                 'no-checkout' => \$_no_checkout,
  73                 'quiet|q' => \$_q,
  74                 'repack-flags|repack-args|repack-opts=s' =>
  75                    \$Git::SVN::_repack_flags,
  76                 %remote_opts );
  77
  78 my ($_trunk, $_tags, $_branches);
  79 my %icv;
  80 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
  81                   'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
  82                   'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
  83                   'no-metadata' => sub { $icv{noMetadata} = 1 },
  84                   'use-svm-props' => sub { $icv{useSvmProps} = 1 },
  85                   'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
  86                   'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
  87                   %remote_opts );
  88 my %cmt_opts = ( 'edit|e' => \$_edit,
  89                 'rmdir' => \$SVN::Git::Editor::_rmdir,
  90                 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
  91                 'l=i' => \$SVN::Git::Editor::_rename_limit,
  92                 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
  93 );
  94
  95 my %cmd = (
  96         fetch => [ \&cmd_fetch, "Download new revisions from SVN",
  97                         { 'revision|r=s' => \$_revision,
  98                           'fetch-all|all' => \$_fetch_all,
  99                            %fc_opts } ],
 100         clone => [ \&cmd_clone, "Initialize and fetch revisions",
 101                         { 'revision|r=s' => \$_revision,
 102                            %fc_opts, %init_opts } ],
 103         init => [ \&cmd_init, "Initialize a repo for tracking" .
 104                           " (requires URL argument)",
 105                           \%init_opts ],
 106         'multi-init' => [ \&cmd_multi_init,
 107                           "Deprecated alias for ".
 108                           "'$0 init -T<trunk> -b<branches> -t<tags>'",
 109                           \%init_opts ],
 110         dcommit => [ \&cmd_dcommit,
 111                      'Commit several diffs to merge with upstream',
 112                         { 'merge|m|M' => \$_merge,
 113                           'strategy|s=s' => \$_strategy,
 114                           'verbose|v' => \$_verbose,
 115                           'dry-run|n' => \$_dry_run,
 116                           'fetch-all|all' => \$_fetch_all,
 117                         %cmt_opts, %fc_opts } ],
 118         'set-tree' => [ \&cmd_set_tree,
 119                         "Set an SVN repository to a git tree-ish",
 120                         { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
 121         'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
 122                         { 'revision|r=i' => \$_revision } ],
 123         'multi-fetch' => [ \&cmd_multi_fetch,
 124                            "Deprecated alias for $0 fetch --all",
 125                            { 'revision|r=s' => \$_revision, %fc_opts } ],
 126         'migrate' => [ sub { },
 127                        # no-op, we automatically run this anyways,
 128                        'Migrate configuration/metadata/layout from
 129                         previous versions of git-svn',
 130                        { 'minimize' => \$Git::SVN::Migration::_minimize,
 131                          %remote_opts } ],
 132         'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
 133                         { 'limit=i' => \$Git::SVN::Log::limit,
 134                           'revision|r=s' => \$_revision,
 135                           'verbose|v' => \$Git::SVN::Log::verbose,
 136                           'incremental' => \$Git::SVN::Log::incremental,
 137                           'oneline' => \$Git::SVN::Log::oneline,
 138                           'show-commit' => \$Git::SVN::Log::show_commit,
 139                           'non-recursive' => \$Git::SVN::Log::non_recursive,
 140                           'authors-file|A=s' => \$_authors,
 141                           'color' => \$Git::SVN::Log::color,
 142                           'pager=s' => \$Git::SVN::Log::pager,
 143                         } ],
 144         'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
 145                         { 'merge|m|M' => \$_merge,
 146                           'verbose|v' => \$_verbose,
 147                           'strategy|s=s' => \$_strategy,
 148                           'local|l' => \$_local,
 149                           'fetch-all|all' => \$_fetch_all,
 150                           %fc_opts } ],
 151         'commit-diff' => [ \&cmd_commit_diff,
 152                            'Commit a diff between two trees',
 153                         { 'message|m=s' => \$_message,
 154                           'file|F=s' => \$_file,
 155                           'revision|r=s' => \$_revision,
 156                         %cmt_opts } ],
 157 );
 158
 159 my $cmd;
 160 for (my $i = 0; $i < @ARGV; $i++) {
 161         if (defined $cmd{$ARGV[$i]}) {
 162                 $cmd = $ARGV[$i];
 163                 splice @ARGV, $i, 1;
 164                 last;
 165         }
 166 };
 167
 168 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
 169
 170 read_repo_config(\%opts);
 171 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
 172 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
 173                     'minimize-connections' => \$Git::SVN::Migration::_minimize,
 174                     'id|i=s' => \$Git::SVN::default_ref_id,
 175                     'svn-remote|remote|R=s' => sub {
 176                        $Git::SVN::no_reuse_existing = 1;
 177                        $Git::SVN::default_repo_id = $_[1] });
 178 exit 1 if (!$rv && $cmd && $cmd ne 'log');
 179
 180 usage(0) if $_help;
 181 version() if $_version;
 182 usage(1) unless defined $cmd;
 183 load_authors() if $_authors;
 184
 185 # make sure we're always running
 186 unless ($cmd =~ /(?:clone|init|multi-init)$/) {
 187         unless (-d $ENV{GIT_DIR}) {
 188                 if ($git_dir_user_set) {
 189                         die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
 190                             "but it is not a directory\n";
 191                 }
 192                 my $git_dir = delete $ENV{GIT_DIR};
 193                 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
 194                 unless (length $cdup) {
 195                         die "Already at toplevel, but $git_dir ",
 196                             "not found '$cdup'\n";
 197                 }
 198                 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
 199                 unless (-d $git_dir) {
 200                         die "$git_dir still not found after going to ",
 201                             "'$cdup'\n";
 202                 }
 203                 $ENV{GIT_DIR} = $git_dir;
 204         }
 205 }
 206 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
 207         Git::SVN::Migration::migration_check();
 208 }
 209 Git::SVN::init_vars();
 210 eval {
 211         Git::SVN::verify_remotes_sanity();
 212         $cmd{$cmd}->[0]->(@ARGV);
 213 };
 214 fatal $@ if $@;
 215 post_fetch_checkout();
 216 exit 0;
 217
 218 ####################### primary functions ######################
 219 sub usage {
 220         my $exit = shift || 0;
 221         my $fd = $exit ? \*STDERR : \*STDOUT;
 222         print $fd <<"";
 223 git-svn - bidirectional operations between a single Subversion tree and git
 224 Usage: $0 <command> [options] [arguments]\n
 225
 226         print $fd "Available commands:\n" unless $cmd;
 227
 228         foreach (sort keys %cmd) {
 229                 next if $cmd && $cmd ne $_;
 230                 next if /^multi-/; # don't show deprecated commands
 231                 print $fd '  ',pack('A17',$_),$cmd{$_}->[1],"\n";
 232                 foreach (keys %{$cmd{$_}->[2]}) {
 233                         # mixed-case options are for .git/config only
 234                         next if /[A-Z]/ && /^[a-z]+$/i;
 235                         # prints out arguments as they should be passed:
 236                         my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
 237                         print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
 238                                                         "--$_" : "-$_" }
 239                                                 split /\|/,$_)," $x\n";
 240                 }
 241         }
 242         print $fd <<"";
 243 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
 244 arbitrary identifier if you're tracking multiple SVN branches/repositories in
 245 one git repository and want to keep them separate.  See git-svn(1) for more
 246 information.
 247
 248         exit $exit;
 249 }
 250
 251 sub version {
 252         print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
 253         exit 0;
 254 }
 255
 256 sub do_git_init_db {
 257         unless (-d $ENV{GIT_DIR}) {
 258                 my @init_db = ('init');
 259                 push @init_db, "--template=$_template" if defined $_template;
 260                 if (defined $_shared) {
 261                         if ($_shared =~ /[a-z]/) {
 262                                 push @init_db, "--shared=$_shared";
 263                         } else {
 264                                 push @init_db, "--shared";
 265                         }
 266                 }
 267                 command_noisy(@init_db);
 268         }
 269         my $set;
 270         my $pfx = "svn-remote.$Git::SVN::default_repo_id";
 271         foreach my $i (keys %icv) {
 272                 die "'$set' and '$i' cannot both be set\n" if $set;
 273                 next unless defined $icv{$i};
 274                 command_noisy('config', "$pfx.$i", $icv{$i});
 275                 $set = $i;
 276         }
 277 }
 278
 279 sub init_subdir {
 280         my $repo_path = shift or return;
 281         mkpath([$repo_path]) unless -d $repo_path;
 282         chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
 283         $ENV{GIT_DIR} = '.git';
 284 }
 285
 286 sub cmd_clone {
 287         my ($url, $path) = @_;
 288         if (!defined $path &&
 289             (defined $_trunk || defined $_branches || defined $_tags) &&
 290             $url !~ m#^[a-z\+]+://#) {
 291                 $path = $url;
 292         }
 293         $path = basename($url) if !defined $path || !length $path;
 294         cmd_init($url, $path);
 295         Git::SVN::fetch_all($Git::SVN::default_repo_id);
 296 }
 297
 298 sub cmd_init {
 299         if (defined $_trunk || defined $_branches || defined $_tags) {
 300                 return cmd_multi_init(@_);
 301         }
 302         my $url = shift or die "SVN repository location required ",
 303                                "as a command-line argument\n";
 304         init_subdir(@_);
 305         do_git_init_db();
 306
 307         Git::SVN->init($url);
 308 }
 309
 310 sub cmd_fetch {
 311         if (grep /^\d+=./, @_) {
 312                 die "'<rev>=<commit>' fetch arguments are ",
 313                     "no longer supported.\n";
 314         }
 315         my ($remote) = @_;
 316         if (@_ > 1) {
 317                 die "Usage: $0 fetch [--all] [svn-remote]\n";
 318         }
 319         $remote ||= $Git::SVN::default_repo_id;
 320         if ($_fetch_all) {
 321                 cmd_multi_fetch();
 322         } else {
 323                 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
 324         }
 325 }
 326
 327 sub cmd_set_tree {
 328         my (@commits) = @_;
 329         if ($_stdin || !@commits) {
 330                 print "Reading from stdin...\n";
 331                 @commits = ();
 332                 while (<STDIN>) {
 333                         if (/\b($sha1_short)\b/o) {
 334                                 unshift @commits, $1;
 335                         }
 336                 }
 337         }
 338         my @revs;
 339         foreach my $c (@commits) {
 340                 my @tmp = command('rev-parse',$c);
 341                 if (scalar @tmp == 1) {
 342                         push @revs, $tmp[0];
 343                 } elsif (scalar @tmp > 1) {
 344                         push @revs, reverse(command('rev-list',@tmp));
 345                 } else {
 346                         fatal "Failed to rev-parse $c\n";
 347                 }
 348         }
 349         my $gs = Git::SVN->new;
 350         my ($r_last, $cmt_last) = $gs->last_rev_commit;
 351         $gs->fetch;
 352         if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
 353                 fatal "There are new revisions that were fetched ",
 354                       "and need to be merged (or acknowledged) ",
 355                       "before committing.\nlast rev: $r_last\n",
 356                       " current: $gs->{last_rev}\n";
 357         }
 358         $gs->set_tree($_) foreach @revs;
 359         print "Done committing ",scalar @revs," revisions to SVN\n";
 360 }
 361
 362 sub cmd_dcommit {
 363         my $head = shift;
 364         $head ||= 'HEAD';
 365         my @refs;
 366         my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
 367         unless ($gs) {
 368                 die "Unable to determine upstream SVN information from ",
 369                     "$head history\n";
 370         }
 371         my $c = $refs[-1];
 372         my $last_rev;
 373         foreach my $d (@refs) {
 374                 if (!verify_ref("$d~1")) {
 375                         fatal "Commit $d\n",
 376                               "has no parent commit, and therefore ",
 377                               "nothing to diff against.\n",
 378                               "You should be working from a repository ",
 379                               "originally created by git-svn\n";
 380                 }
 381                 unless (defined $last_rev) {
 382                         (undef, $last_rev, undef) = cmt_metadata("$d~1");
 383                         unless (defined $last_rev) {
 384                                 fatal "Unable to extract revision information ",
 385                                       "from commit $d~1\n";
 386                         }
 387                 }
 388                 if ($_dry_run) {
 389                         print "diff-tree $d~1 $d\n";
 390                 } else {
 391                         my %ed_opts = ( r => $last_rev,
 392                                         log => get_commit_entry($d)->{log},
 393                                         ra => Git::SVN::Ra->new($url),
 394                                         tree_a => "$d~1",
 395                                         tree_b => $d,
 396                                         editor_cb => sub {
 397                                                print "Committed r$_[0]\n";
 398                                                $last_rev = $_[0]; },
 399                                         svn_path => '');
 400                         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 401                                 print "No changes\n$d~1 == $d\n";
 402                         }
 403                 }
 404         }
 405         return if $_dry_run;
 406         unless ($gs) {
 407                 warn "Could not determine fetch information for $url\n",
 408                      "Will not attempt to fetch and rebase commits.\n",
 409                      "This probably means you have useSvmProps and should\n",
 410                      "now resync your SVN::Mirror repository.\n";
 411                 return;
 412         }
 413         $_fetch_all ? $gs->fetch_all : $gs->fetch;
 414         # we always want to rebase against the current HEAD, not any
 415         # head that was passed to us
 416         my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
 417         my @finish;
 418         if (@diff) {
 419                 @finish = rebase_cmd();
 420                 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
 421                              "using @finish:\n", "@diff";
 422         } else {
 423                 print "No changes between current HEAD and ",
 424                       $gs->refname, "\nResetting to the latest ",
 425                       $gs->refname, "\n";
 426                 @finish = qw/reset --mixed/;
 427         }
 428         command_noisy(@finish, $gs->refname);
 429 }
 430
 431 sub cmd_rebase {
 432         command_noisy(qw/update-index --refresh/);
 433         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 434         unless ($gs) {
 435                 die "Unable to determine upstream SVN information from ",
 436                     "working tree history\n";
 437         }
 438         if (command(qw/diff-index HEAD --/)) {
 439                 print STDERR "Cannot rebase with uncommited changes:\n";
 440                 command_noisy('status');
 441                 exit 1;
 442         }
 443         unless ($_local) {
 444                 $_fetch_all ? $gs->fetch_all : $gs->fetch;
 445         }
 446         command_noisy(rebase_cmd(), $gs->refname);
 447 }
 448
 449 sub cmd_show_ignore {
 450         my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
 451         $gs ||= Git::SVN->new;
 452         my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
 453         $gs->traverse_ignore(\*STDOUT, $gs->{path}, $r);
 454 }
 455
 456 sub cmd_multi_init {
 457         my $url = shift;
 458         unless (defined $_trunk || defined $_branches || defined $_tags) {
 459                 usage(1);
 460         }
 461         $_prefix = '' unless defined $_prefix;
 462         if (defined $url) {
 463                 $url =~ s#/+$##;
 464                 init_subdir(@_);
 465         }
 466         do_git_init_db();
 467         if (defined $_trunk) {
 468                 my $trunk_ref = $_prefix . 'trunk';
 469                 # try both old-style and new-style lookups:
 470                 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
 471                 unless ($gs_trunk) {
 472                         my ($trunk_url, $trunk_path) =
 473                                               complete_svn_url($url, $_trunk);
 474                         $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
 475                                                    undef, $trunk_ref);
 476                 }
 477         }
 478         return unless defined $_branches || defined $_tags;
 479         my $ra = $url ? Git::SVN::Ra->new($url) : undef;
 480         complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
 481         complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
 482 }
 483
 484 sub cmd_multi_fetch {
 485         my $remotes = Git::SVN::read_all_remotes();
 486         foreach my $repo_id (sort keys %$remotes) {
 487                 if ($remotes->{$repo_id}->{url}) {
 488                         Git::SVN::fetch_all($repo_id, $remotes);
 489                 }
 490         }
 491 }
 492
 493 # this command is special because it requires no metadata
 494 sub cmd_commit_diff {
 495         my ($ta, $tb, $url) = @_;
 496         my $usage = "Usage: $0 commit-diff -r<revision> ".
 497                     "<tree-ish> <tree-ish> [<URL>]\n";
 498         fatal($usage) if (!defined $ta || !defined $tb);
 499         my $svn_path;
 500         if (!defined $url) {
 501                 my $gs = eval { Git::SVN->new };
 502                 if (!$gs) {
 503                         fatal("Needed URL or usable git-svn --id in ",
 504                               "the command-line\n", $usage);
 505                 }
 506                 $url = $gs->{url};
 507                 $svn_path = $gs->{path};
 508         }
 509         unless (defined $_revision) {
 510                 fatal("-r|--revision is a required argument\n", $usage);
 511         }
 512         if (defined $_message && defined $_file) {
 513                 fatal("Both --message/-m and --file/-F specified ",
 514                       "for the commit message.\n",
 515                       "I have no idea what you mean\n");
 516         }
 517         if (defined $_file) {
 518                 $_message = file_to_s($_file);
 519         } else {
 520                 $_message ||= get_commit_entry($tb)->{log};
 521         }
 522         my $ra ||= Git::SVN::Ra->new($url);
 523         $svn_path ||= $ra->{svn_path};
 524         my $r = $_revision;
 525         if ($r eq 'HEAD') {
 526                 $r = $ra->get_latest_revnum;
 527         } elsif ($r !~ /^\d+$/) {
 528                 die "revision argument: $r not understood by git-svn\n";
 529         }
 530         my %ed_opts = ( r => $r,
 531                         log => $_message,
 532                         ra => $ra,
 533                         tree_a => $ta,
 534                         tree_b => $tb,
 535                         editor_cb => sub { print "Committed r$_[0]\n" },
 536                         svn_path => $svn_path );
 537         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
 538                 print "No changes\n$ta == $tb\n";
 539         }
 540 }
 541
 542 ########################### utility functions #########################
 543
 544 sub rebase_cmd {
 545         my @cmd = qw/rebase/;
 546         push @cmd, '-v' if $_verbose;
 547         push @cmd, qw/--merge/ if $_merge;
 548         push @cmd, "--strategy=$_strategy" if $_strategy;
 549         @cmd;
 550 }
 551
 552 sub post_fetch_checkout {
 553         return if $_no_checkout;
 554         my $gs = $Git::SVN::_head or return;
 555         return if verify_ref('refs/heads/master^0');
 556
 557         my $valid_head = verify_ref('HEAD^0');
 558         command_noisy(qw(update-ref refs/heads/master), $gs->refname);
 559         return if ($valid_head || !verify_ref('HEAD^0'));
 560
 561         return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
 562         my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
 563         return if -f $index;
 564
 565         chomp(my $bare = `git config --bool --get core.bare`);
 566         return if $bare eq 'true';
 567         return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
 568         command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
 569         print STDERR "Checked out HEAD:\n  ",
 570                      $gs->full_url, " r", $gs->last_rev, "\n";
 571 }
 572
 573 sub complete_svn_url {
 574         my ($url, $path) = @_;
 575         $path =~ s#/+$##;
 576         if ($path !~ m#^[a-z\+]+://#) {
 577                 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
 578                         fatal("E: '$path' is not a complete URL ",
 579                               "and a separate URL is not specified\n");
 580                 }
 581                 return ($url, $path);
 582         }
 583         return ($path, '');
 584 }
 585
 586 sub complete_url_ls_init {
 587         my ($ra, $repo_path, $switch, $pfx) = @_;
 588         unless ($repo_path) {
 589                 print STDERR "W: $switch not specified\n";
 590                 return;
 591         }
 592         $repo_path =~ s#/+$##;
 593         if ($repo_path =~ m#^[a-z\+]+://#) {
 594                 $ra = Git::SVN::Ra->new($repo_path);
 595                 $repo_path = '';
 596         } else {
 597                 $repo_path =~ s#^/+##;
 598                 unless ($ra) {
 599                         fatal("E: '$repo_path' is not a complete URL ",
 600                               "and a separate URL is not specified\n");
 601                 }
 602         }
 603         my $url = $ra->{url};
 604         my $gs = Git::SVN->init($url, undef, undef, undef, 1);
 605         my $k = "svn-remote.$gs->{repo_id}.url";
 606         my $orig_url = eval { command_oneline(qw/config --get/, $k) };
 607         if ($orig_url && ($orig_url ne $gs->{url})) {
 608                 die "$k already set: $orig_url\n",
 609                     "wanted to set to: $gs->{url}\n";
 610         }
 611         command_oneline('config', $k, $gs->{url}) unless $orig_url;
 612         my $remote_path = "$ra->{svn_path}/$repo_path/*";
 613         $remote_path =~ s#/+#/#g;
 614         $remote_path =~ s#^/##g;
 615         my ($n) = ($switch =~ /^--(\w+)/);
 616         if (length $pfx && $pfx !~ m#/$#) {
 617                 die "--prefix='$pfx' must have a trailing slash '/'\n";
 618         }
 619         command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
 620                                 "$remote_path:refs/remotes/$pfx*");
 621 }
 622
 623 sub verify_ref {
 624         my ($ref) = @_;
 625         eval { command_oneline([ 'rev-parse', '--verify', $ref ],
 626                                { STDERR => 0 }); };
 627 }
 628
 629 sub get_tree_from_treeish {
 630         my ($treeish) = @_;
 631         # $treeish can be a symbolic ref, too:
 632         my $type = command_oneline(qw/cat-file -t/, $treeish);
 633         my $expected;
 634         while ($type eq 'tag') {
 635                 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
 636         }
 637         if ($type eq 'commit') {
 638                 $expected = (grep /^tree /, command(qw/cat-file commit/,
 639                                                     $treeish))[0];
 640                 ($expected) = ($expected =~ /^tree ($sha1)$/o);
 641                 die "Unable to get tree from $treeish\n" unless $expected;
 642         } elsif ($type eq 'tree') {
 643                 $expected = $treeish;
 644         } else {
 645                 die "$treeish is a $type, expected tree, tag or commit\n";
 646         }
 647         return $expected;
 648 }
 649
 650 sub get_commit_entry {
 651         my ($treeish) = shift;
 652         my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
 653         my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
 654         my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
 655         open my $log_fh, '>', $commit_editmsg or croak $!;
 656
 657         my $type = command_oneline(qw/cat-file -t/, $treeish);
 658         if ($type eq 'commit' || $type eq 'tag') {
 659                 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
 660                                                          $type, $treeish);
 661                 my $in_msg = 0;
 662                 while (<$msg_fh>) {
 663                         if (!$in_msg) {
 664                                 $in_msg = 1 if (/^\s*$/);
 665                         } elsif (/^git-svn-id: /) {
 666                                 # skip this for now, we regenerate the
 667                                 # correct one on re-fetch anyways
 668                                 # TODO: set *:merge properties or like...
 669                         } else {
 670                                 print $log_fh $_ or croak $!;
 671                         }
 672                 }
 673                 command_close_pipe($msg_fh, $ctx);
 674         }
 675         close $log_fh or croak $!;
 676
 677         if ($_edit || ($type eq 'tree')) {
 678                 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
 679                 # TODO: strip out spaces, comments, like git-commit.sh
 680                 system($editor, $commit_editmsg);
 681         }
 682         rename $commit_editmsg, $commit_msg or croak $!;
 683         open $log_fh, '<', $commit_msg or croak $!;
 684         { local $/; chomp($log_entry{log} = <$log_fh>); }
 685         close $log_fh or croak $!;
 686         unlink $commit_msg;
 687         \%log_entry;
 688 }
 689
 690 sub s_to_file {
 691         my ($str, $file, $mode) = @_;
 692         open my $fd,'>',$file or croak $!;
 693         print $fd $str,"\n" or croak $!;
 694         close $fd or croak $!;
 695         chmod ($mode &~ umask, $file) if (defined $mode);
 696 }
 697
 698 sub file_to_s {
 699         my $file = shift;
 700         open my $fd,'<',$file or croak "$!: file: $file\n";
 701         local $/;
 702         my $ret = <$fd>;
 703         close $fd or croak $!;
 704         $ret =~ s/\s*$//s;
 705         return $ret;
 706 }
 707
 708 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
 709 sub load_authors {
 710         open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
 711         my $log = $cmd eq 'log';
 712         while (<$authors>) {
 713                 chomp;
 714                 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
 715                 my ($user, $name, $email) = ($1, $2, $3);
 716                 if ($log) {
 717                         $Git::SVN::Log::rusers{"$name <$email>"} = $user;
 718                 } else {
 719                         $users{$user} = [$name, $email];
 720                 }
 721         }
 722         close $authors or croak $!;
 723 }
 724
 725 # convert GetOpt::Long specs for use by git-config
 726 sub read_repo_config {
 727         return unless -d $ENV{GIT_DIR};
 728         my $opts = shift;
 729         my @config_only;
 730         foreach my $o (keys %$opts) {
 731                 # if we have mixedCase and a long option-only, then
 732                 # it's a config-only variable that we don't need for
 733                 # the command-line.
 734                 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
 735                 my $v = $opts->{$o};
 736                 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
 737                 $key =~ s/-//g;
 738                 my $arg = 'git-config';
 739                 $arg .= ' --int' if ($o =~ /[:=]i$/);
 740                 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
 741                 if (ref $v eq 'ARRAY') {
 742                         chomp(my @tmp = `$arg --get-all svn.$key`);
 743                         @$v = @tmp if @tmp;
 744                 } else {
 745                         chomp(my $tmp = `$arg --get svn.$key`);
 746                         if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
 747                                 $$v = $tmp;
 748                         }
 749                 }
 750         }
 751         delete @$opts{@config_only} if @config_only;
 752 }
 753
 754 sub extract_metadata {
 755         my $id = shift or return (undef, undef, undef);
 756         my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
 757                                                         \s([a-f\d\-]+)$/x);
 758         if (!defined $rev || !$uuid || !$url) {
 759                 # some of the original repositories I made had
 760                 # identifiers like this:
 761                 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
 762         }
 763         return ($url, $rev, $uuid);
 764 }
 765
 766 sub cmt_metadata {
 767         return extract_metadata((grep(/^git-svn-id: /,
 768                 command(qw/cat-file commit/, shift)))[-1]);
 769 }
 770
 771 sub working_head_info {
 772         my ($head, $refs) = @_;
 773         my ($fh, $ctx) = command_output_pipe('rev-list', $head);
 774         while (<$fh>) {
 775                 chomp;
 776                 my ($url, $rev, $uuid) = cmt_metadata($_);
 777                 if (defined $url && defined $rev) {
 778                         if (my $gs = Git::SVN->find_by_url($url)) {
 779                                 my $c = $gs->rev_db_get($rev);
 780                                 if ($c && $c eq $_) {
 781                                         close $fh; # break the pipe
 782                                         return ($url, $rev, $uuid, $gs);
 783                                 }
 784                         }
 785                 }
 786                 unshift @$refs, $_ if $refs;
 787         }
 788         command_close_pipe($fh, $ctx);
 789         (undef, undef, undef, undef);
 790 }
 791
 792 package Git::SVN;
 793 use strict;
 794 use warnings;
 795 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
 796             $_repack $_repack_flags $_use_svm_props $_head
 797             $_use_svnsync_props $no_reuse_existing/;
 798 use Carp qw/croak/;
 799 use File::Path qw/mkpath/;
 800 use File::Copy qw/copy/;
 801 use IPC::Open3;
 802
 803 my $_repack_nr;
 804 # properties that we do not log:
 805 my %SKIP_PROP;
 806 BEGIN {
 807         %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
 808                                         svn:special svn:executable
 809                                         svn:entry:committed-rev
 810                                         svn:entry:last-author
 811                                         svn:entry:uuid
 812                                         svn:entry:committed-date/;
 813
 814         # some options are read globally, but can be overridden locally
 815         # per [svn-remote "..."] section.  Command-line options will *NOT*
 816         # override options set in an [svn-remote "..."] section
 817         my $e;
 818         foreach (qw/follow_parent no_metadata use_svm_props
 819                     use_svnsync_props/) {
 820                 my $key = $_;
 821                 $key =~ tr/_//d;
 822                 $e .= "sub $_ {
 823                         my (\$self) = \@_;
 824                         return \$self->{-$_} if exists \$self->{-$_};
 825                         my \$k = \"svn-remote.\$self->{repo_id}\.$key\";
 826                         eval { command_oneline(qw/config --get/, \$k) };
 827                         if (\$@) {
 828                                 \$self->{-$_} = \$Git::SVN::_$_;
 829                         } else {
 830                                 my \$v = command_oneline(qw/config --bool/,\$k);
 831                                 \$self->{-$_} = \$v eq 'false' ? 0 : 1;
 832                         }
 833                         return \$self->{-$_} }\n";
 834         }
 835         $e .= "1;\n";
 836         eval $e or die $@;
 837 }
 838
 839 my %LOCKFILES;
 840 END { unlink keys %LOCKFILES if %LOCKFILES }
 841
 842 sub resolve_local_globs {
 843         my ($url, $fetch, $glob_spec) = @_;
 844         return unless defined $glob_spec;
 845         my $ref = $glob_spec->{ref};
 846         my $path = $glob_spec->{path};
 847         foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
 848                 next unless m#^refs/remotes/$ref->{regex}$#;
 849                 my $p = $1;
 850                 my $pathname = $path->full_path($p);
 851                 my $refname = $ref->full_path($p);
 852                 if (my $existing = $fetch->{$pathname}) {
 853                         if ($existing ne $refname) {
 854                                 die "Refspec conflict:\n",
 855                                     "existing: refs/remotes/$existing\n",
 856                                     " globbed: refs/remotes/$refname\n";
 857                         }
 858                         my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
 859                         $u =~ s!^\Q$url\E(/|$)!! or die
 860                           "refs/remotes/$refname: '$url' not found in '$u'\n";
 861                         if ($pathname ne $u) {
 862                                 warn "W: Refspec glob conflict ",
 863                                      "(ref: refs/remotes/$refname):\n",
 864                                      "expected path: $pathname\n",
 865                                      "    real path: $u\n",
 866                                      "Continuing ahead with $u\n";
 867                                 next;
 868                         }
 869                 } else {
 870                         $fetch->{$pathname} = $refname;
 871                 }
 872         }
 873 }
 874
 875 sub parse_revision_argument {
 876         my ($base, $head) = @_;
 877         if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
 878                 return ($base, $head);
 879         }
 880         return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
 881         return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
 882         return ($head, $head) if ($::_revision eq 'HEAD');
 883         return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
 884         return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
 885         die "revision argument: $::_revision not understood by git-svn\n";
 886 }
 887
 888 sub fetch_all {
 889         my ($repo_id, $remotes) = @_;
 890         if (ref $repo_id) {
 891                 my $gs = $repo_id;
 892                 $repo_id = undef;
 893                 $repo_id = $gs->{repo_id};
 894         }
 895         $remotes ||= read_all_remotes();
 896         my $remote = $remotes->{$repo_id} or
 897                      die "[svn-remote \"$repo_id\"] unknown\n";
 898         my $fetch = $remote->{fetch};
 899         my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
 900         my (@gs, @globs);
 901         my $ra = Git::SVN::Ra->new($url);
 902         my $uuid = $ra->get_uuid;
 903         my $head = $ra->get_latest_revnum;
 904         my $base = defined $fetch ? $head : 0;
 905
 906         # read the max revs for wildcard expansion (branches/*, tags/*)
 907         foreach my $t (qw/branches tags/) {
 908                 defined $remote->{$t} or next;
 909                 push @globs, $remote->{$t};
 910                 my $max_rev = eval { tmp_config(qw/--int --get/,
 911                                          "svn-remote.$repo_id.${t}-maxRev") };
 912                 if (defined $max_rev && ($max_rev < $base)) {
 913                         $base = $max_rev;
 914                 } elsif (!defined $max_rev) {
 915                         $base = 0;
 916                 }
 917         }
 918
 919         if ($fetch) {
 920                 foreach my $p (sort keys %$fetch) {
 921                         my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
 922                         my $lr = $gs->rev_db_max;
 923                         if (defined $lr) {
 924                                 $base = $lr if ($lr < $base);
 925                         }
 926                         push @gs, $gs;
 927                 }
 928         }
 929
 930         ($base, $head) = parse_revision_argument($base, $head);
 931         $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
 932 }
 933
 934 sub read_all_remotes {
 935         my $r = {};
 936         foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
 937                 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
 938                         $r->{$1}->{fetch}->{$2} = $3;
 939                 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
 940                         $r->{$1}->{url} = $2;
 941                 } elsif (m!^(.+)\.(branches|tags)=
 942                            (.*):refs/remotes/(.+)\s*$/!x) {
 943                         my ($p, $g) = ($3, $4);
 944                         my $rs = $r->{$1}->{$2} = {
 945                                           t => $2,
 946                                           remote => $1,
 947                                           path => Git::SVN::GlobSpec->new($p),
 948                                           ref => Git::SVN::GlobSpec->new($g) };
 949                         if (length($rs->{ref}->{right}) != 0) {
 950                                 die "The '*' glob character must be the last ",
 951                                     "character of '$g'\n";
 952                         }
 953                 }
 954         }
 955         $r;
 956 }
 957
 958 sub init_vars {
 959         if (defined $_repack) {
 960                 $_repack = 1000 if ($_repack <= 0);
 961                 $_repack_nr = $_repack;
 962                 $_repack_flags ||= '-d';
 963         }
 964 }
 965
 966 sub verify_remotes_sanity {
 967         return unless -d $ENV{GIT_DIR};
 968         my %seen;
 969         foreach (command(qw/config -l/)) {
 970                 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
 971                         if ($seen{$1}) {
 972                                 die "Remote ref refs/remote/$1 is tracked by",
 973                                     "\n  \"$_\"\nand\n  \"$seen{$1}\"\n",
 974                                     "Please resolve this ambiguity in ",
 975                                     "your git configuration file before ",
 976                                     "continuing\n";
 977                         }
 978                         $seen{$1} = $_;
 979                 }
 980         }
 981 }
 982
 983 # we allow more chars than remotes2config.sh...
 984 sub sanitize_remote_name {
 985         my ($name) = @_;
 986         $name =~ tr{A-Za-z0-9:,/+-}{.}c;
 987         $name;
 988 }
 989
 990 sub find_existing_remote {
 991         my ($url, $remotes) = @_;
 992         return undef if $no_reuse_existing;
 993         my $existing;
 994         foreach my $repo_id (keys %$remotes) {
 995                 my $u = $remotes->{$repo_id}->{url} or next;
 996                 next if $u ne $url;
 997                 $existing = $repo_id;
 998                 last;
 999         }
1000         $existing;
1001 }
1002
1003 sub init_remote_config {
1004         my ($self, $url, $no_write) = @_;
1005         $url =~ s!/+$!!; # strip trailing slash
1006         my $r = read_all_remotes();
1007         my $existing = find_existing_remote($url, $r);
1008         if ($existing) {
1009                 unless ($no_write) {
1010                         print STDERR "Using existing ",
1011                                      "[svn-remote \"$existing\"]\n";
1012                 }
1013                 $self->{repo_id} = $existing;
1014         } else {
1015                 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1016                 $existing = find_existing_remote($min_url, $r);
1017                 if ($existing) {
1018                         unless ($no_write) {
1019                                 print STDERR "Using existing ",
1020                                              "[svn-remote \"$existing\"]\n";
1021                         }
1022                         $self->{repo_id} = $existing;
1023                 }
1024                 if ($min_url ne $url) {
1025                         unless ($no_write) {
1026                                 print STDERR "Using higher level of URL: ",
1027                                              "$url => $min_url\n";
1028                         }
1029                         my $old_path = $self->{path};
1030                         $self->{path} = $url;
1031                         $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1032                         if (length $old_path) {
1033                                 $self->{path} .= "/$old_path";
1034                         }
1035                         $url = $min_url;
1036                 }
1037         }
1038         my $orig_url;
1039         if (!$existing) {
1040                 # verify that we aren't overwriting anything:
1041                 $orig_url = eval {
1042                         command_oneline('config', '--get',
1043                                         "svn-remote.$self->{repo_id}.url")
1044                 };
1045                 if ($orig_url && ($orig_url ne $url)) {
1046                         die "svn-remote.$self->{repo_id}.url already set: ",
1047                             "$orig_url\nwanted to set to: $url\n";
1048                 }
1049         }
1050         my ($xrepo_id, $xpath) = find_ref($self->refname);
1051         if (defined $xpath) {
1052                 die "svn-remote.$xrepo_id.fetch already set to track ",
1053                     "$xpath:refs/remotes/", $self->refname, "\n";
1054         }
1055         unless ($no_write) {
1056                 command_noisy('config',
1057                               "svn-remote.$self->{repo_id}.url", $url);
1058                 command_noisy('config', '--add',
1059                               "svn-remote.$self->{repo_id}.fetch",
1060                               "$self->{path}:".$self->refname);
1061         }
1062         $self->{url} = $url;
1063 }
1064
1065 sub find_by_url { # repos_root and, path are optional
1066         my ($class, $full_url, $repos_root, $path) = @_;
1067         return undef unless defined $full_url;
1068         my $remotes = read_all_remotes();
1069         if (defined $full_url && defined $repos_root && !defined $path) {
1070                 $path = $full_url;
1071                 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1072         }
1073         foreach my $repo_id (keys %$remotes) {
1074                 my $u = $remotes->{$repo_id}->{url} or next;
1075                 next if defined $repos_root && $repos_root ne $u;
1076
1077                 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1078                 foreach (qw/branches tags/) {
1079                         resolve_local_globs($u, $fetch,
1080                                             $remotes->{$repo_id}->{$_});
1081                 }
1082                 my $p = $path;
1083                 unless (defined $p) {
1084                         $p = $full_url;
1085                         $p =~ s#^\Q$u\E(?:/|$)## or next;
1086                 }
1087                 foreach my $f (keys %$fetch) {
1088                         next if $f ne $p;
1089                         return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1090                 }
1091         }
1092         undef;
1093 }
1094
1095 sub init {
1096         my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1097         my $self = _new($class, $repo_id, $ref_id, $path);
1098         if (defined $url) {
1099                 $self->init_remote_config($url, $no_write);
1100         }
1101         $self;
1102 }
1103
1104 sub find_ref {
1105         my ($ref_id) = @_;
1106         foreach (command(qw/config -l/)) {
1107                 next unless m!^svn-remote\.(.+)\.fetch=
1108                               \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1109                 my ($repo_id, $path, $ref) = ($1, $2, $3);
1110                 if ($ref eq $ref_id) {
1111                         $path = '' if ($path =~ m#^\./?#);
1112                         return ($repo_id, $path);
1113                 }
1114         }
1115         (undef, undef, undef);
1116 }
1117
1118 sub new {
1119         my ($class, $ref_id, $repo_id, $path) = @_;
1120         if (defined $ref_id && !defined $repo_id && !defined $path) {
1121                 ($repo_id, $path) = find_ref($ref_id);
1122                 if (!defined $repo_id) {
1123                         die "Could not find a \"svn-remote.*.fetch\" key ",
1124                             "in the repository configuration matching: ",
1125                             "refs/remotes/$ref_id\n";
1126                 }
1127         }
1128         my $self = _new($class, $repo_id, $ref_id, $path);
1129         if (!defined $self->{path} || !length $self->{path}) {
1130                 my $fetch = command_oneline('config', '--get',
1131                                             "svn-remote.$repo_id.fetch",
1132                                             ":refs/remotes/$ref_id\$") or
1133                      die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1134                          "\":refs/remotes/$ref_id\$\" in config\n";
1135                 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1136         }
1137         $self->{url} = command_oneline('config', '--get',
1138                                        "svn-remote.$repo_id.url") or
1139                   die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1140         $self->rebuild;
1141         $self;
1142 }
1143
1144 sub refname { "refs/remotes/$_[0]->{ref_id}" }
1145
1146 sub svm_uuid {
1147         my ($self) = @_;
1148         return $self->{svm}->{uuid} if $self->svm;
1149         $self->ra;
1150         unless ($self->{svm}) {
1151                 die "SVM UUID not cached, and reading remotely failed\n";
1152         }
1153         $self->{svm}->{uuid};
1154 }
1155
1156 sub svm {
1157         my ($self) = @_;
1158         return $self->{svm} if $self->{svm};
1159         my $svm;
1160         # see if we have it in our config, first:
1161         eval {
1162                 my $section = "svn-remote.$self->{repo_id}";
1163                 $svm = {
1164                   source => tmp_config('--get', "$section.svm-source"),
1165                   uuid => tmp_config('--get', "$section.svm-uuid"),
1166                   replace => tmp_config('--get', "$section.svm-replace"),
1167                 }
1168         };
1169         if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1170                 $self->{svm} = $svm;
1171         }
1172         $self->{svm};
1173 }
1174
1175 sub _set_svm_vars {
1176         my ($self, $ra) = @_;
1177         return $ra if $self->svm;
1178
1179         my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1180                     "(svm:source, svm:uuid) ",
1181                     "from the following URLs:\n" );
1182         sub read_svm_props {
1183                 my ($self, $ra, $path, $r) = @_;
1184                 my $props = ($ra->get_dir($path, $r))[2];
1185                 my $src = $props->{'svm:source'};
1186                 my $uuid = $props->{'svm:uuid'};
1187                 return undef if (!$src || !$uuid);
1188
1189                 chomp($src, $uuid);
1190
1191                 $uuid =~ m{^[0-9a-f\-]{30,}$}
1192                     or die "doesn't look right - svm:uuid is '$uuid'\n";
1193
1194                 # the '!' is used to mark the repos_root!/relative/path
1195                 $src =~ s{/?!/?}{/};
1196                 $src =~ s{/+$}{}; # no trailing slashes please
1197                 # username is of no interest
1198                 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1199
1200                 my $replace = $ra->{url};
1201                 $replace .= "/$path" if length $path;
1202
1203                 my $section = "svn-remote.$self->{repo_id}";
1204                 tmp_config("$section.svm-source", $src);
1205                 tmp_config("$section.svm-replace", $replace);
1206                 tmp_config("$section.svm-uuid", $uuid);
1207                 $self->{svm} = {
1208                         source => $src,
1209                         uuid => $uuid,
1210                         replace => $replace
1211                 };
1212         }
1213
1214         my $r = $ra->get_latest_revnum;
1215         my $path = $self->{path};
1216         my %tried;
1217         while (length $path) {
1218                 unless ($tried{"$self->{url}/$path"}) {
1219                         return $ra if $self->read_svm_props($ra, $path, $r);
1220                         $tried{"$self->{url}/$path"} = 1;
1221                 }
1222                 $path =~ s#/?[^/]+$##;
1223         }
1224         die "Path: '$path' should be ''\n" if $path ne '';
1225         return $ra if $self->read_svm_props($ra, $path, $r);
1226         $tried{"$self->{url}/$path"} = 1;
1227
1228         if ($ra->{repos_root} eq $self->{url}) {
1229                 die @err, (map { "  $_\n" } keys %tried), "\n";
1230         }
1231
1232         # nope, make sure we're connected to the repository root:
1233         my $ok;
1234         my @tried_b;
1235         $path = $ra->{svn_path};
1236         $ra = Git::SVN::Ra->new($ra->{repos_root});
1237         while (length $path) {
1238                 unless ($tried{"$ra->{url}/$path"}) {
1239                         $ok = $self->read_svm_props($ra, $path, $r);
1240                         last if $ok;
1241                         $tried{"$ra->{url}/$path"} = 1;
1242                 }
1243                 $path =~ s#/?[^/]+$##;
1244         }
1245         die "Path: '$path' should be ''\n" if $path ne '';
1246         $ok ||= $self->read_svm_props($ra, $path, $r);
1247         $tried{"$ra->{url}/$path"} = 1;
1248         if (!$ok) {
1249                 die @err, (map { "  $_\n" } keys %tried), "\n";
1250         }
1251         Git::SVN::Ra->new($self->{url});
1252 }
1253
1254 sub svnsync {
1255         my ($self) = @_;
1256         return $self->{svnsync} if $self->{svnsync};
1257
1258         if ($self->no_metadata) {
1259                 die "Can't have both 'noMetadata' and ",
1260                     "'useSvnsyncProps' options set!\n";
1261         }
1262         if ($self->rewrite_root) {
1263                 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1264                     "options set!\n";
1265         }
1266
1267         my $svnsync;
1268         # see if we have it in our config, first:
1269         eval {
1270                 my $section = "svn-remote.$self->{repo_id}";
1271                 $svnsync = {
1272                   url => tmp_config('--get', "$section.svnsync-url"),
1273                   uuid => tmp_config('--get', "$section.svnsync-uuid"),
1274                 }
1275         };
1276         if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1277                 return $self->{svnsync} = $svnsync;
1278         }
1279
1280         my $err = "useSvnsyncProps set, but failed to read " .
1281                   "svnsync property: svn:sync-from-";
1282         my $rp = $self->ra->rev_proplist(0);
1283
1284         my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1285         $url =~ m{^[a-z\+]+://} or
1286                    die "doesn't look right - svn:sync-from-url is '$url'\n";
1287
1288         my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1289         $uuid =~ m{^[0-9a-f\-]{30,}$} or
1290                    die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1291
1292         my $section = "svn-remote.$self->{repo_id}";
1293         tmp_config('--add', "$section.svnsync-uuid", $uuid);
1294         tmp_config('--add', "$section.svnsync-url", $url);
1295         return $self->{svnsync} = { url => $url, uuid => $uuid };
1296 }
1297
1298 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1299 # remote lookup (useful for 'git svn log').
1300 sub ra_uuid {
1301         my ($self) = @_;
1302         unless ($self->{ra_uuid}) {
1303                 my $key = "svn-remote.$self->{repo_id}.uuid";
1304                 my $uuid = eval { tmp_config('--get', $key) };
1305                 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1306                         $self->{ra_uuid} = $uuid;
1307                 } else {
1308                         die "ra_uuid called without URL\n" unless $self->{url};
1309                         $self->{ra_uuid} = $self->ra->get_uuid;
1310                         tmp_config('--add', $key, $self->{ra_uuid});
1311                 }
1312         }
1313         $self->{ra_uuid};
1314 }
1315
1316 sub ra {
1317         my ($self) = shift;
1318         my $ra = Git::SVN::Ra->new($self->{url});
1319         if ($self->use_svm_props && !$self->{svm}) {
1320                 if ($self->no_metadata) {
1321                         die "Can't have both 'noMetadata' and ",
1322                             "'useSvmProps' options set!\n";
1323                 } elsif ($self->use_svnsync_props) {
1324                         die "Can't have both 'useSvnsyncProps' and ",
1325                             "'useSvmProps' options set!\n";
1326                 }
1327                 $ra = $self->_set_svm_vars($ra);
1328                 $self->{-want_revprops} = 1;
1329         }
1330         $ra;
1331 }
1332
1333 sub rel_path {
1334         my ($self) = @_;
1335         my $repos_root = $self->ra->{repos_root};
1336         return $self->{path} if ($self->{url} eq $repos_root);
1337         my $url = $self->{url} .
1338                   (length $self->{path} ? "/$self->{path}" : $self->{path});
1339         $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1340         $url;
1341 }
1342
1343 sub traverse_ignore {
1344         my ($self, $fh, $path, $r) = @_;
1345         $path =~ s#^/+##g;
1346         my $ra = $self->ra;
1347         my ($dirent, undef, $props) = $ra->get_dir($path, $r);
1348         my $p = $path;
1349         $p =~ s#^\Q$self->{path}\E(/|$)##;
1350         print $fh length $p ? "\n# $p\n" : "\n# /\n";
1351         if (my $s = $props->{'svn:ignore'}) {
1352                 $s =~ s/[\r\n]+/\n/g;
1353                 chomp $s;
1354                 if (length $p == 0) {
1355                         $s =~ s#\n#\n/$p#g;
1356                         print $fh "/$s\n";
1357                 } else {
1358                         $s =~ s#\n#\n/$p/#g;
1359                         print $fh "/$p/$s\n";
1360                 }
1361         }
1362         foreach (sort keys %$dirent) {
1363                 next if $dirent->{$_}->kind != $SVN::Node::dir;
1364                 $self->traverse_ignore($fh, "$path/$_", $r);
1365         }
1366 }
1367
1368 sub last_rev { ($_[0]->last_rev_commit)[0] }
1369 sub last_commit { ($_[0]->last_rev_commit)[1] }
1370
1371 # returns the newest SVN revision number and newest commit SHA1
1372 sub last_rev_commit {
1373         my ($self) = @_;
1374         if (defined $self->{last_rev} && defined $self->{last_commit}) {
1375                 return ($self->{last_rev}, $self->{last_commit});
1376         }
1377         my $c = ::verify_ref($self->refname.'^0');
1378         if ($c && !$self->use_svm_props && !$self->no_metadata) {
1379                 my $rev = (::cmt_metadata($c))[1];
1380                 if (defined $rev) {
1381                         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1382                         return ($rev, $c);
1383                 }
1384         }
1385         my $db_path = $self->db_path;
1386         unless (-e $db_path) {
1387                 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1388                 return (undef, undef);
1389         }
1390         my $offset = -41; # from tail
1391         my $rl;
1392         open my $fh, '<', $db_path or croak "$db_path not readable: $!\n";
1393         sysseek($fh, $offset, 2); # don't care for errors
1394         sysread($fh, $rl, 41) == 41 or return (undef, undef);
1395         chomp $rl;
1396         while (('0' x40) eq $rl && sysseek($fh, 0, 1) != 0) {
1397                 $offset -= 41;
1398                 sysseek($fh, $offset, 2); # don't care for errors
1399                 sysread($fh, $rl, 41) == 41 or return (undef, undef);
1400                 chomp $rl;
1401         }
1402         if ($c && $c ne $rl) {
1403                 die "$db_path and ", $self->refname,
1404                     " inconsistent!:\n$c != $rl\n";
1405         }
1406         my $rev = sysseek($fh, 0, 1) or croak $!;
1407         $rev =  ($rev - 41) / 41;
1408         close $fh or croak $!;
1409         ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1410         return ($rev, $c);
1411 }
1412
1413 sub get_fetch_range {
1414         my ($self, $min, $max) = @_;
1415         $max ||= $self->ra->get_latest_revnum;
1416         $min ||= $self->rev_db_max;
1417         (++$min, $max);
1418 }
1419
1420 sub tmp_config {
1421         my (@args) = @_;
1422         my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1423         my $config = "$ENV{GIT_DIR}/svn/.metadata";
1424         if (-e $old_def_config && ! -e $config) {
1425                 rename $old_def_config, $config or
1426                        die "Failed rename $old_def_config => $config: $!\n";
1427         }
1428         my $old_config = $ENV{GIT_CONFIG};
1429         $ENV{GIT_CONFIG} = $config;
1430         $@ = undef;
1431         my @ret = eval {
1432                 unless (-f $config) {
1433                         mkfile($config);
1434                         open my $fh, '>', $config or
1435                             die "Can't open $config: $!\n";
1436                         print $fh "; This file is used internally by ",
1437                                   "git-svn\n" or die
1438                                   "Couldn't write to $config: $!\n";
1439                         print $fh "; You should not have to edit it\n" or
1440                               die "Couldn't write to $config: $!\n";
1441                         close $fh or die "Couldn't close $config: $!\n";
1442                 }
1443                 command('config', @args);
1444         };
1445         my $err = $@;
1446         if (defined $old_config) {
1447                 $ENV{GIT_CONFIG} = $old_config;
1448         } else {
1449                 delete $ENV{GIT_CONFIG};
1450         }
1451         die $err if $err;
1452         wantarray ? @ret : $ret[0];
1453 }
1454
1455 sub tmp_index_do {
1456         my ($self, $sub) = @_;
1457         my $old_index = $ENV{GIT_INDEX_FILE};
1458         $ENV{GIT_INDEX_FILE} = $self->{index};
1459         $@ = undef;
1460         my @ret = eval {
1461                 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1462                 mkpath([$dir]) unless -d $dir;
1463                 &$sub;
1464         };
1465         my $err = $@;
1466         if (defined $old_index) {
1467                 $ENV{GIT_INDEX_FILE} = $old_index;
1468         } else {
1469                 delete $ENV{GIT_INDEX_FILE};
1470         }
1471         die $err if $err;
1472         wantarray ? @ret : $ret[0];
1473 }
1474
1475 sub assert_index_clean {
1476         my ($self, $treeish) = @_;
1477
1478         $self->tmp_index_do(sub {
1479                 command_noisy('read-tree', $treeish) unless -e $self->{index};
1480                 my $x = command_oneline('write-tree');
1481                 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1482                            /^tree ($::sha1)/mo);
1483                 return if $y eq $x;
1484
1485                 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1486                 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1487                 command_noisy('read-tree', $treeish);
1488                 $x = command_oneline('write-tree');
1489                 if ($y ne $x) {
1490                         ::fatal "trees ($treeish) $y != $x\n",
1491                                 "Something is seriously wrong...\n";
1492                 }
1493         });
1494 }
1495
1496 sub get_commit_parents {
1497         my ($self, $log_entry) = @_;
1498         my (%seen, @ret, @tmp);
1499         # legacy support for 'set-tree'; this is only used by set_tree_cb:
1500         if (my $ip = $self->{inject_parents}) {
1501                 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1502                         push @tmp, $commit;
1503                 }
1504         }
1505         if (my $cur = ::verify_ref($self->refname.'^0')) {
1506                 push @tmp, $cur;
1507         }
1508         push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1509         while (my $p = shift @tmp) {
1510                 next if $seen{$p};
1511                 $seen{$p} = 1;
1512                 push @ret, $p;
1513                 # MAXPARENT is defined to 16 in commit-tree.c:
1514                 last if @ret >= 16;
1515         }
1516         if (@tmp) {
1517                 die "r$log_entry->{revision}: No room for parents:\n\t",
1518                     join("\n\t", @tmp), "\n";
1519         }
1520         @ret;
1521 }
1522
1523 sub rewrite_root {
1524         my ($self) = @_;
1525         return $self->{-rewrite_root} if exists $self->{-rewrite_root};
1526         my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
1527         my $rwr = eval { command_oneline(qw/config --get/, $k) };
1528         if ($rwr) {
1529                 $rwr =~ s#/+$##;
1530                 if ($rwr !~ m#^[a-z\+]+://#) {
1531                         die "$rwr is not a valid URL (key: $k)\n";
1532                 }
1533         }
1534         $self->{-rewrite_root} = $rwr;
1535 }
1536
1537 sub metadata_url {
1538         my ($self) = @_;
1539         ($self->rewrite_root || $self->{url}) .
1540            (length $self->{path} ? '/' . $self->{path} : '');
1541 }
1542
1543 sub full_url {
1544         my ($self) = @_;
1545         $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1546 }
1547
1548 sub do_git_commit {
1549         my ($self, $log_entry) = @_;
1550         my $lr = $self->last_rev;
1551         if (defined $lr && $lr >= $log_entry->{revision}) {
1552                 die "Last fetched revision of ", $self->refname,
1553                     " was r$lr, but we are about to fetch: ",
1554                     "r$log_entry->{revision}!\n";
1555         }
1556         if (my $c = $self->rev_db_get($log_entry->{revision})) {
1557                 croak "$log_entry->{revision} = $c already exists! ",
1558                       "Why are we refetching it?\n";
1559         }
1560         $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $log_entry->{name};
1561         $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} =
1562                                                           $log_entry->{email};
1563         $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1564
1565         my $tree = $log_entry->{tree};
1566         if (!defined $tree) {
1567                 $tree = $self->tmp_index_do(sub {
1568                                             command_oneline('write-tree') });
1569         }
1570         die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1571
1572         my @exec = ('git-commit-tree', $tree);
1573         foreach ($self->get_commit_parents($log_entry)) {
1574                 push @exec, '-p', $_;
1575         }
1576         defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1577                                                                    or croak $!;
1578         print $msg_fh $log_entry->{log} or croak $!;
1579         unless ($self->no_metadata) {
1580                 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
1581                               or croak $!;
1582         }
1583         $msg_fh->flush == 0 or croak $!;
1584         close $msg_fh or croak $!;
1585         chomp(my $commit = do { local $/; <$out_fh> });
1586         close $out_fh or croak $!;
1587         waitpid $pid, 0;
1588         croak $? if $?;
1589         if ($commit !~ /^$::sha1$/o) {
1590                 die "Failed to commit, invalid sha1: $commit\n";
1591         }
1592
1593         $self->rev_db_set($log_entry->{revision}, $commit, 1);
1594
1595         $self->{last_rev} = $log_entry->{revision};
1596         $self->{last_commit} = $commit;
1597         print "r$log_entry->{revision}";
1598         if (defined $log_entry->{svm_revision}) {
1599                  print " (\@$log_entry->{svm_revision})";
1600                  $self->rev_db_set($log_entry->{svm_revision}, $commit,
1601                                    0, $self->svm_uuid);
1602         }
1603         print " = $commit ($self->{ref_id})\n";
1604         if (defined $_repack && (--$_repack_nr == 0)) {
1605                 $_repack_nr = $_repack;
1606                 # repack doesn't use any arguments with spaces in them, does it?
1607                 print "Running git repack $_repack_flags ...\n";
1608                 command_noisy('repack', split(/\s+/, $_repack_flags));
1609                 print "Done repacking\n";
1610         }
1611         return $commit;
1612 }
1613
1614 sub match_paths {
1615         my ($self, $paths, $r) = @_;
1616         return 1 if $self->{path} eq '';
1617         if (my $path = $paths->{"/$self->{path}"}) {
1618                 return ($path->{action} eq 'D') ? 0 : 1;
1619         }
1620         $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
1621         if (grep /$self->{path_regex}/, keys %$paths) {
1622                 return 1;
1623         }
1624         my $c = '';
1625         foreach (split m#/#, $self->{path}) {
1626                 $c .= "/$_";
1627                 next unless ($paths->{$c} &&
1628                              ($paths->{$c}->{action} =~ /^[AR]$/));
1629                 if ($self->ra->check_path($self->{path}, $r) ==
1630                     $SVN::Node::dir) {
1631                         return 1;
1632                 }
1633         }
1634         return 0;
1635 }
1636
1637 sub find_parent_branch {
1638         my ($self, $paths, $rev) = @_;
1639         return undef unless $self->follow_parent;
1640         unless (defined $paths) {
1641                 my $err_handler = $SVN::Error::handler;
1642                 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
1643                 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
1644                                    $paths =
1645                                       Git::SVN::Ra::dup_changed_paths($_[0]) });
1646                 $SVN::Error::handler = $err_handler;
1647         }
1648         return undef unless defined $paths;
1649
1650         # look for a parent from another branch:
1651         my @b_path_components = split m#/#, $self->rel_path;
1652         my @a_path_components;
1653         my $i;
1654         while (@b_path_components) {
1655                 $i = $paths->{'/'.join('/', @b_path_components)};
1656                 last if $i && defined $i->{copyfrom_path};
1657                 unshift(@a_path_components, pop(@b_path_components));
1658         }
1659         return undef unless defined $i && defined $i->{copyfrom_path};
1660         my $branch_from = $i->{copyfrom_path};
1661         if (@a_path_components) {
1662                 print STDERR "branch_from: $branch_from => ";
1663                 $branch_from .= '/'.join('/', @a_path_components);
1664                 print STDERR $branch_from, "\n";
1665         }
1666         my $r = $i->{copyfrom_rev};
1667         my $repos_root = $self->ra->{repos_root};
1668         my $url = $self->ra->{url};
1669         my $new_url = $repos_root . $branch_from;
1670         print STDERR  "Found possible branch point: ",
1671                       "$new_url => ", $self->full_url, ", $r\n";
1672         $branch_from =~ s#^/##;
1673         my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
1674         unless ($gs) {
1675                 my $ref_id = $self->{ref_id};
1676                 $ref_id =~ s/\@\d+$//;
1677                 $ref_id .= "\@$r";
1678                 # just grow a tail if we're not unique enough :x
1679                 $ref_id .= '-' while find_ref($ref_id);
1680                 print STDERR "Initializing parent: $ref_id\n";
1681                 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
1682         }
1683         my ($r0, $parent) = $gs->find_rev_before($r, 1);
1684         if (!defined $r0 || !defined $parent) {
1685                 my ($base, $head) = parse_revision_argument(0, $r);
1686                 if ($base <= $r) {
1687                         $gs->fetch($base, $r);
1688                 }
1689                 ($r0, $parent) = $gs->last_rev_commit;
1690         }
1691         if (defined $r0 && defined $parent) {
1692                 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1693                 my $ed;
1694                 if ($self->ra->can_do_switch) {
1695                         $self->assert_index_clean($parent);
1696                         print STDERR "Following parent with do_switch\n";
1697                         # do_switch works with svn/trunk >= r22312, but that
1698                         # is not included with SVN 1.4.3 (the latest version
1699                         # at the moment), so we can't rely on it
1700                         $self->{last_commit} = $parent;
1701                         $ed = SVN::Git::Fetcher->new($self);
1702                         $gs->ra->gs_do_switch($r0, $rev, $gs,
1703                                               $self->full_url, $ed)
1704                           or die "SVN connection failed somewhere...\n";
1705                 } else {
1706                         print STDERR "Following parent with do_update\n";
1707                         $ed = SVN::Git::Fetcher->new($self);
1708                         $self->ra->gs_do_update($rev, $rev, $self, $ed)
1709                           or die "SVN connection failed somewhere...\n";
1710                 }
1711                 print STDERR "Successfully followed parent\n";
1712                 return $self->make_log_entry($rev, [$parent], $ed);
1713         }
1714         return undef;
1715 }
1716
1717 sub do_fetch {
1718         my ($self, $paths, $rev) = @_;
1719         my $ed;
1720         my ($last_rev, @parents);
1721         if (my $lc = $self->last_commit) {
1722                 # we can have a branch that was deleted, then re-added
1723                 # under the same name but copied from another path, in
1724                 # which case we'll have multiple parents (we don't
1725                 # want to break the original ref, nor lose copypath info):
1726                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1727                         push @{$log_entry->{parents}}, $lc;
1728                         return $log_entry;
1729                 }
1730                 $ed = SVN::Git::Fetcher->new($self);
1731                 $last_rev = $self->{last_rev};
1732                 $ed->{c} = $lc;
1733                 @parents = ($lc);
1734         } else {
1735                 $last_rev = $rev;
1736                 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1737                         return $log_entry;
1738                 }
1739                 $ed = SVN::Git::Fetcher->new($self);
1740         }
1741         unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
1742                 die "SVN connection failed somewhere...\n";
1743         }
1744         $self->make_log_entry($rev, \@parents, $ed);
1745 }
1746
1747 sub get_untracked {
1748         my ($self, $ed) = @_;
1749         my @out;
1750         my $h = $ed->{empty};
1751         foreach (sort keys %$h) {
1752                 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1753                 push @out, "  $act: " . uri_encode($_);
1754                 warn "W: $act: $_\n";
1755         }
1756         foreach my $t (qw/dir_prop file_prop/) {
1757                 $h = $ed->{$t} or next;
1758                 foreach my $path (sort keys %$h) {
1759                         my $ppath = $path eq '' ? '.' : $path;
1760                         foreach my $prop (sort keys %{$h->{$path}}) {
1761                                 next if $SKIP_PROP{$prop};
1762                                 my $v = $h->{$path}->{$prop};
1763                                 my $t_ppath_prop = "$t: " .
1764                                                     uri_encode($ppath) . ' ' .
1765                                                     uri_encode($prop);
1766                                 if (defined $v) {
1767                                         push @out, "  +$t_ppath_prop " .
1768                                                    uri_encode($v);
1769                                 } else {
1770                                         push @out, "  -$t_ppath_prop";
1771                                 }
1772                         }
1773                 }
1774         }
1775         foreach my $t (qw/absent_file absent_directory/) {
1776                 $h = $ed->{$t} or next;
1777                 foreach my $parent (sort keys %$h) {
1778                         foreach my $path (sort @{$h->{$parent}}) {
1779                                 push @out, "  $t: " .
1780                                            uri_encode("$parent/$path");
1781                                 warn "W: $t: $parent/$path ",
1782                                      "Insufficient permissions?\n";
1783                         }
1784                 }
1785         }
1786         \@out;
1787 }
1788
1789 sub parse_svn_date {
1790         my $date = shift || return '+0000 1970-01-01 00:00:00';
1791         my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1792                                             (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1793                                          croak "Unable to parse date: $date\n";
1794         "+0000 $Y-$m-$d $H:$M:$S";
1795 }
1796
1797 sub check_author {
1798         my ($author) = @_;
1799         if (!defined $author || length $author == 0) {
1800                 $author = '(no author)';
1801         }
1802         if (defined $::_authors && ! defined $::users{$author}) {
1803                 die "Author: $author not defined in $::_authors file\n";
1804         }
1805         $author;
1806 }
1807
1808 sub make_log_entry {
1809         my ($self, $rev, $parents, $ed) = @_;
1810         my $untracked = $self->get_untracked($ed);
1811
1812         open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1813         print $un "r$rev\n" or croak $!;
1814         print $un $_, "\n" foreach @$untracked;
1815         my %log_entry = ( parents => $parents || [], revision => $rev,
1816                           log => '');
1817
1818         my $headrev;
1819         my $logged = delete $self->{logged_rev_props};
1820         if (!$logged || $self->{-want_revprops}) {
1821                 my $rp = $self->ra->rev_proplist($rev);
1822                 foreach (sort keys %$rp) {
1823                         my $v = $rp->{$_};
1824                         if (/^svn:(author|date|log)$/) {
1825                                 $log_entry{$1} = $v;
1826                         } elsif ($_ eq 'svm:headrev') {
1827                                 $headrev = $v;
1828                         } else {
1829                                 print $un "  rev_prop: ", uri_encode($_), ' ',
1830                                           uri_encode($v), "\n";
1831                         }
1832                 }
1833         } else {
1834                 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
1835         }
1836         close $un or croak $!;
1837
1838         $log_entry{date} = parse_svn_date($log_entry{date});
1839         $log_entry{log} .= "\n";
1840         my $author = $log_entry{author} = check_author($log_entry{author});
1841         my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
1842                                                        : ($author, undef);
1843         if (defined $headrev && $self->use_svm_props) {
1844                 if ($self->rewrite_root) {
1845                         die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
1846                             "options set!\n";
1847                 }
1848                 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
1849                 # we don't want "SVM: initializing mirror for junk" ...
1850                 return undef if $r == 0;
1851                 my $svm = $self->svm;
1852                 if ($uuid ne $svm->{uuid}) {
1853                         die "UUID mismatch on SVM path:\n",
1854                             "expected: $svm->{uuid}\n",
1855                             "     got: $uuid\n";
1856                 }
1857                 my $full_url = $self->full_url;
1858                 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
1859                              die "Failed to replace '$svm->{replace}' with ",
1860                                  "'$svm->{source}' in $full_url\n";
1861                 # throw away username for storing in records
1862                 remove_username($full_url);
1863                 $log_entry{metadata} = "$full_url\@$r $uuid";
1864                 $log_entry{svm_revision} = $r;
1865                 $email ||= "$author\@$uuid"
1866         } elsif ($self->use_svnsync_props) {
1867                 my $full_url = $self->svnsync->{url};
1868                 $full_url .= "/$self->{path}" if length $self->{path};
1869                 my $uuid = $self->svnsync->{uuid};
1870                 $log_entry{metadata} = "$full_url\@$rev $uuid";
1871                 $email ||= "$author\@$uuid"
1872         } else {
1873                 $log_entry{metadata} = $self->metadata_url. "\@$rev " .
1874                                        $self->ra->get_uuid;
1875                 $email ||= "$author\@" . $self->ra->get_uuid;
1876         }
1877         $log_entry{name} = $name;
1878         $log_entry{email} = $email;
1879         \%log_entry;
1880 }
1881
1882 sub fetch {
1883         my ($self, $min_rev, $max_rev, @parents) = @_;
1884         my ($last_rev, $last_commit) = $self->last_rev_commit;
1885         my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1886         $self->ra->gs_fetch_loop_common($base, $head, [$self]);
1887 }
1888
1889 sub set_tree_cb {
1890         my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1891         $self->{inject_parents} = { $rev => $tree };
1892         $self->fetch(undef, undef);
1893 }
1894
1895 sub set_tree {
1896         my ($self, $tree) = (shift, shift);
1897         my $log_entry = ::get_commit_entry($tree);
1898         unless ($self->{last_rev}) {
1899                 fatal("Must have an existing revision to commit\n");
1900         }
1901         my %ed_opts = ( r => $self->{last_rev},
1902                         log => $log_entry->{log},
1903                         ra => $self->ra,
1904                         tree_a => $self->{last_commit},
1905                         tree_b => $tree,
1906                         editor_cb => sub {
1907                                $self->set_tree_cb($log_entry, $tree, @_) },
1908                         svn_path => $self->{path} );
1909         if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1910                 print "No changes\nr$self->{last_rev} = $tree\n";
1911         }
1912 }
1913
1914 sub rebuild {
1915         my ($self) = @_;
1916         my $db_path = $self->db_path;
1917         return if (-e $db_path && ! -z $db_path);
1918         return unless ::verify_ref($self->refname.'^0');
1919         if (-f $self->{db_root}) {
1920                 rename $self->{db_root}, $db_path or die
1921                      "rename $self->{db_root} => $db_path failed: $!\n";
1922                 my ($dir, $base) = ($db_path =~ m#^(.*?)/?([^/]+)$#);
1923                 symlink $base, $self->{db_root} or die
1924                      "symlink $base => $self->{db_root} failed: $!\n";
1925                 return;
1926         }
1927         print "Rebuilding $db_path ...\n";
1928         my ($rev_list, $ctx) = command_output_pipe("rev-list", $self->refname);
1929         my $latest;
1930         my $full_url = $self->full_url;
1931         remove_username($full_url);
1932         my $svn_uuid;
1933         while (<$rev_list>) {
1934                 chomp;
1935                 my $c = $_;
1936                 die "Non-SHA1: $c\n" unless $c =~ /^$::sha1$/o;
1937                 my ($url, $rev, $uuid) = ::cmt_metadata($c);
1938                 remove_username($url);
1939
1940                 # ignore merges (from set-tree)
1941                 next if (!defined $rev || !$uuid);
1942
1943                 # if we merged or otherwise started elsewhere, this is
1944                 # how we break out of it
1945                 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
1946                     ($full_url && $url && ($url ne $full_url))) {
1947                         next;
1948                 }
1949                 $latest ||= $rev;
1950                 $svn_uuid ||= $uuid;
1951
1952                 $self->rev_db_set($rev, $c);
1953                 print "r$rev = $c\n";
1954         }
1955         command_close_pipe($rev_list, $ctx);
1956         print "Done rebuilding $db_path\n";
1957 }
1958
1959 # rev_db:
1960 # Tie::File seems to be prone to offset errors if revisions get sparse,
1961 # it's not that fast, either.  Tie::File is also not in Perl 5.6.  So
1962 # one of my favorite modules is out :<  Next up would be one of the DBM
1963 # modules, but I'm not sure which is most portable...  So I'll just
1964 # go with something that's plain-text, but still capable of
1965 # being randomly accessed.  So here's my ultra-simple fixed-width
1966 # database.  All records are 40 characters + "\n", so it's easy to seek
1967 # to a revision: (41 * rev) is the byte offset.
1968 # A record of 40 0s denotes an empty revision.
1969 # And yes, it's still pretty fast (faster than Tie::File).
1970 # These files are disposable unless noMetadata or useSvmProps is set
1971
1972 sub _rev_db_set {
1973         my ($fh, $rev, $commit) = @_;
1974         my $offset = $rev * 41;
1975         # assume that append is the common case:
1976         seek $fh, 0, 2 or croak $!;
1977         my $pos = tell $fh;
1978         if ($pos < $offset) {
1979                 for (1 .. (($offset - $pos) / 41)) {
1980                         print $fh (('0' x 40),"\n") or croak $!;
1981                 }
1982         }
1983         seek $fh, $offset, 0 or croak $!;
1984         print $fh $commit,"\n" or croak $!;
1985 }
1986
1987 sub mkfile {
1988         my ($path) = @_;
1989         unless (-e $path) {
1990                 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
1991                 mkpath([$dir]) unless -d $dir;
1992                 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
1993                 close $fh or die "Couldn't close (create) $path: $!\n";
1994         }
1995 }
1996
1997 sub rev_db_set {
1998         my ($self, $rev, $commit, $update_ref, $uuid) = @_;
1999         length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2000         my $db = $self->db_path($uuid);
2001         my $db_lock = "$db.lock";
2002         my $sig;
2003         if ($update_ref) {
2004                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2005                             $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2006         }
2007         mkfile($db);
2008
2009         $LOCKFILES{$db_lock} = 1;
2010         my $sync;
2011         # both of these options make our .rev_db file very, very important
2012         # and we can't afford to lose it because rebuild() won't work
2013         if ($self->use_svm_props || $self->no_metadata) {
2014                 $sync = 1;
2015                 copy($db, $db_lock) or die "rev_db_set(@_): ",
2016                                            "Failed to copy: ",
2017                                            "$db => $db_lock ($!)\n";
2018         } else {
2019                 rename $db, $db_lock or die "rev_db_set(@_): ",
2020                                             "Failed to rename: ",
2021                                             "$db => $db_lock ($!)\n";
2022         }
2023         open my $fh, '+<', $db_lock or die "Couldn't open $db_lock: $!\n";
2024         _rev_db_set($fh, $rev, $commit);
2025         if ($sync) {
2026                 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2027                 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2028         }
2029         close $fh or croak $!;
2030         if ($update_ref) {
2031                 $_head = $self;
2032                 command_noisy('update-ref', '-m', "r$rev",
2033                               $self->refname, $commit);
2034         }
2035         rename $db_lock, $db or die "rev_db_set(@_): ", "Failed to rename: ",
2036                                     "$db_lock => $db ($!)\n";
2037         delete $LOCKFILES{$db_lock};
2038         if ($update_ref) {
2039                 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2040                             $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2041                 kill $sig, $$ if defined $sig;
2042         }
2043 }
2044
2045 sub rev_db_max {
2046         my ($self) = @_;
2047         $self->rebuild;
2048         my $db_path = $self->db_path;
2049         my @stat = stat $db_path or return 0;
2050         ($stat[7] % 41) == 0 or die "$db_path inconsistent size: $stat[7]\n";
2051         my $max = $stat[7] / 41;
2052         (($max > 0) ? $max - 1 : 0);
2053 }
2054
2055 sub rev_db_get {
2056         my ($self, $rev, $uuid) = @_;
2057         my $ret;
2058         my $offset = $rev * 41;
2059         my $db_path = $self->db_path($uuid);
2060         return undef unless -e $db_path;
2061         open my $fh, '<', $db_path or croak $!;
2062         if (sysseek($fh, $offset, 0) == $offset) {
2063                 my $read = sysread($fh, $ret, 40);
2064                 $ret = undef if ($read != 40 || $ret eq ('0'x40));
2065         }
2066         close $fh or croak $!;
2067         $ret;
2068 }
2069
2070 sub find_rev_before {
2071         my ($self, $rev, $eq_ok) = @_;
2072         --$rev unless $eq_ok;
2073         while ($rev > 0) {
2074                 if (my $c = $self->rev_db_get($rev)) {
2075                         return ($rev, $c);
2076                 }
2077                 --$rev;
2078         }
2079         return (undef, undef);
2080 }
2081
2082 sub _new {
2083         my ($class, $repo_id, $ref_id, $path) = @_;
2084         unless (defined $repo_id && length $repo_id) {
2085                 $repo_id = $Git::SVN::default_repo_id;
2086         }
2087         unless (defined $ref_id && length $ref_id) {
2088                 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2089         }
2090         $_[1] = $repo_id = sanitize_remote_name($repo_id);
2091         my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2092         $_[3] = $path = '' unless (defined $path);
2093         mkpath(["$ENV{GIT_DIR}/svn"]);
2094         bless {
2095                 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2096                 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2097                 db_root => "$dir/.rev_db", repo_id => $repo_id }, $class;
2098 }
2099
2100 sub db_path {
2101         my ($self, $uuid) = @_;
2102         $uuid ||= $self->ra_uuid;
2103         "$self->{db_root}.$uuid";
2104 }
2105
2106 sub uri_encode {
2107         my ($f) = @_;
2108         $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2109         $f
2110 }
2111
2112 sub remove_username {
2113         $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2114 }
2115
2116 package Git::SVN::Prompt;
2117 use strict;
2118 use warnings;
2119 require SVN::Core;
2120 use vars qw/$_no_auth_cache $_username/;
2121
2122 sub simple {
2123         my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2124         $may_save = undef if $_no_auth_cache;
2125         $default_username = $_username if defined $_username;
2126         if (defined $default_username && length $default_username) {
2127                 if (defined $realm && length $realm) {
2128                         print STDERR "Authentication realm: $realm\n";
2129                         STDERR->flush;
2130                 }
2131                 $cred->username($default_username);
2132         } else {
2133                 username($cred, $realm, $may_save, $pool);
2134         }
2135         $cred->password(_read_password("Password for '" .
2136                                        $cred->username . "': ", $realm));
2137         $cred->may_save($may_save);
2138         $SVN::_Core::SVN_NO_ERROR;
2139 }
2140
2141 sub ssl_server_trust {
2142         my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2143         $may_save = undef if $_no_auth_cache;
2144         print STDERR "Error validating server certificate for '$realm':\n";
2145         if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2146                 print STDERR " - The certificate is not issued by a trusted ",
2147                       "authority. Use the\n",
2148                       "   fingerprint to validate the certificate manually!\n";
2149         }
2150         if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2151                 print STDERR " - The certificate hostname does not match.\n";
2152         }
2153         if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2154                 print STDERR " - The certificate is not yet valid.\n";
2155         }
2156         if ($failures & $SVN::Auth::SSL::EXPIRED) {
2157                 print STDERR " - The certificate has expired.\n";
2158         }
2159         if ($failures & $SVN::Auth::SSL::OTHER) {
2160                 print STDERR " - The certificate has an unknown error.\n";
2161         }
2162         printf STDERR
2163                 "Certificate information:\n".
2164                 " - Hostname: %s\n".
2165                 " - Valid: from %s until %s\n".
2166                 " - Issuer: %s\n".
2167                 " - Fingerprint: %s\n",
2168                 map $cert_info->$_, qw(hostname valid_from valid_until
2169                                        issuer_dname fingerprint);
2170         my $choice;
2171 prompt:
2172         print STDERR $may_save ?
2173               "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2174               "(R)eject or accept (t)emporarily? ";
2175         STDERR->flush;
2176         $choice = lc(substr(<STDIN> || 'R', 0, 1));
2177         if ($choice =~ /^t$/i) {
2178                 $cred->may_save(undef);
2179         } elsif ($choice =~ /^r$/i) {
2180                 return -1;
2181         } elsif ($may_save && $choice =~ /^p$/i) {
2182                 $cred->may_save($may_save);
2183         } else {
2184                 goto prompt;
2185         }
2186         $cred->accepted_failures($failures);
2187         $SVN::_Core::SVN_NO_ERROR;
2188 }
2189
2190 sub ssl_client_cert {
2191         my ($cred, $realm, $may_save, $pool) = @_;
2192         $may_save = undef if $_no_auth_cache;
2193         print STDERR "Client certificate filename: ";
2194         STDERR->flush;
2195         chomp(my $filename = <STDIN>);
2196         $cred->cert_file($filename);
2197         $cred->may_save($may_save);
2198         $SVN::_Core::SVN_NO_ERROR;
2199 }
2200
2201 sub ssl_client_cert_pw {
2202         my ($cred, $realm, $may_save, $pool) = @_;
2203         $may_save = undef if $_no_auth_cache;
2204         $cred->password(_read_password("Password: ", $realm));
2205         $cred->may_save($may_save);
2206         $SVN::_Core::SVN_NO_ERROR;
2207 }
2208
2209 sub username {
2210         my ($cred, $realm, $may_save, $pool) = @_;
2211         $may_save = undef if $_no_auth_cache;
2212         if (defined $realm && length $realm) {
2213                 print STDERR "Authentication realm: $realm\n";
2214         }
2215         my $username;
2216         if (defined $_username) {
2217                 $username = $_username;
2218         } else {
2219                 print STDERR "Username: ";
2220                 STDERR->flush;
2221                 chomp($username = <STDIN>);
2222         }
2223         $cred->username($username);
2224         $cred->may_save($may_save);
2225         $SVN::_Core::SVN_NO_ERROR;
2226 }
2227
2228 sub _read_password {
2229         my ($prompt, $realm) = @_;
2230         print STDERR $prompt;
2231         STDERR->flush;
2232         require Term::ReadKey;
2233         Term::ReadKey::ReadMode('noecho');
2234         my $password = '';
2235         while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2236                 last if $key =~ /[\012\015]/; # \n\r
2237                 $password .= $key;
2238         }
2239         Term::ReadKey::ReadMode('restore');
2240         print STDERR "\n";
2241         STDERR->flush;
2242         $password;
2243 }
2244
2245 package main;
2246
2247 {
2248         my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2249                                 $SVN::Node::dir.$SVN::Node::unknown.
2250                                 $SVN::Node::none.$SVN::Node::file.
2251                                 $SVN::Node::dir.$SVN::Node::unknown.
2252                                 $SVN::Auth::SSL::CNMISMATCH.
2253                                 $SVN::Auth::SSL::NOTYETVALID.
2254                                 $SVN::Auth::SSL::EXPIRED.
2255                                 $SVN::Auth::SSL::UNKNOWNCA.
2256                                 $SVN::Auth::SSL::OTHER;
2257 }
2258
2259 package SVN::Git::Fetcher;
2260 use vars qw/@ISA/;
2261 use strict;
2262 use warnings;
2263 use Carp qw/croak/;
2264 use IO::File qw//;
2265 use Digest::MD5;
2266
2267 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2268 sub new {
2269         my ($class, $git_svn) = @_;
2270         my $self = SVN::Delta::Editor->new;
2271         bless $self, $class;
2272         $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2273         $self->{empty} = {};
2274         $self->{dir_prop} = {};
2275         $self->{file_prop} = {};
2276         $self->{absent_dir} = {};
2277         $self->{absent_file} = {};
2278         $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
2279         $self;
2280 }
2281
2282 sub set_path_strip {
2283         my ($self, $path) = @_;
2284         $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
2285 }
2286
2287 sub open_root {
2288         { path => '' };
2289 }
2290
2291 sub open_directory {
2292         my ($self, $path, $pb, $rev) = @_;
2293         { path => $path };
2294 }
2295
2296 sub git_path {
2297         my ($self, $path) = @_;
2298         if ($self->{path_strip}) {
2299                 $path =~ s!$self->{path_strip}!! or
2300                   die "Failed to strip path '$path' ($self->{path_strip})\n";
2301         }
2302         $path;
2303 }
2304
2305 sub delete_entry {
2306         my ($self, $path, $rev, $pb) = @_;
2307
2308         my $gpath = $self->git_path($path);
2309         return undef if ($gpath eq '');
2310
2311         # remove entire directories.
2312         if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
2313                 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
2314                                                      -r --name-only -z/,
2315                                                      $self->{c}, '--', $gpath);
2316                 local $/ = "\0";
2317                 while (<$ls>) {
2318                         chomp;
2319                         $self->{gii}->remove($_);
2320                         print "\tD\t$_\n" unless $::_q;
2321                 }
2322                 print "\tD\t$gpath/\n" unless $::_q;
2323                 command_close_pipe($ls, $ctx);
2324                 $self->{empty}->{$path} = 0
2325         } else {
2326                 $self->{gii}->remove($gpath);
2327                 print "\tD\t$gpath\n" unless $::_q;
2328         }
2329         undef;
2330 }
2331
2332 sub open_file {
2333         my ($self, $path, $pb, $rev) = @_;
2334         my $gpath = $self->git_path($path);
2335         my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
2336                              =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
2337         unless (defined $mode && defined $blob) {
2338                 die "$path was not found in commit $self->{c} (r$rev)\n";
2339         }
2340         { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
2341           pool => SVN::Pool->new, action => 'M' };
2342 }
2343
2344 sub add_file {
2345         my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
2346         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2347         delete $self->{empty}->{$dir};
2348         { path => $path, mode_a => 100644, mode_b => 100644,
2349           pool => SVN::Pool->new, action => 'A' };
2350 }
2351
2352 sub add_directory {
2353         my ($self, $path, $cp_path, $cp_rev) = @_;
2354         my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
2355         delete $self->{empty}->{$dir};
2356         $self->{empty}->{$path} = 1;
2357         { path => $path };
2358 }
2359
2360 sub change_dir_prop {
2361         my ($self, $db, $prop, $value) = @_;
2362         $self->{dir_prop}->{$db->{path}} ||= {};
2363         $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
2364         undef;
2365 }
2366
2367 sub absent_directory {
2368         my ($self, $path, $pb) = @_;
2369         $self->{absent_dir}->{$pb->{path}} ||= [];
2370         push @{$self->{absent_dir}->{$pb->{path}}}, $path;
2371         undef;
2372 }
2373
2374 sub absent_file {
2375         my ($self, $path, $pb) = @_;
2376         $self->{absent_file}->{$pb->{path}} ||= [];
2377         push @{$self->{absent_file}->{$pb->{path}}}, $path;
2378         undef;
2379 }
2380
2381 sub change_file_prop {
2382         my ($self, $fb, $prop, $value) = @_;
2383         if ($prop eq 'svn:executable') {
2384                 if ($fb->{mode_b} != 120000) {
2385                         $fb->{mode_b} = defined $value ? 100755 : 100644;
2386                 }
2387         } elsif ($prop eq 'svn:special') {
2388                 $fb->{mode_b} = defined $value ? 120000 : 100644;
2389         } else {
2390                 $self->{file_prop}->{$fb->{path}} ||= {};
2391                 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
2392         }
2393         undef;
2394 }
2395
2396 sub apply_textdelta {
2397         my ($self, $fb, $exp) = @_;
2398         my $fh = IO::File->new_tmpfile;
2399         $fh->autoflush(1);
2400         # $fh gets auto-closed() by SVN::TxDelta::apply(),
2401         # (but $base does not,) so dup() it for reading in close_file
2402         open my $dup, '<&', $fh or croak $!;
2403         my $base = IO::File->new_tmpfile;
2404         $base->autoflush(1);
2405         if ($fb->{blob}) {
2406                 defined (my $pid = fork) or croak $!;
2407                 if (!$pid) {
2408                         open STDOUT, '>&', $base or croak $!;
2409                         print STDOUT 'link ' if ($fb->{mode_a} == 120000);
2410                         exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
2411                 }
2412                 waitpid $pid, 0;
2413                 croak $? if $?;
2414
2415                 if (defined $exp) {
2416                         seek $base, 0, 0 or croak $!;
2417                         my $md5 = Digest::MD5->new;
2418                         $md5->addfile($base);
2419                         my $got = $md5->hexdigest;
2420                         die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
2421                             "expected: $exp\n",
2422                             "     got: $got\n" if ($got ne $exp);
2423                 }
2424         }
2425         seek $base, 0, 0 or croak $!;
2426         $fb->{fh} = $dup;
2427         $fb->{base} = $base;
2428         [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
2429 }
2430
2431 sub close_file {
2432         my ($self, $fb, $exp) = @_;
2433         my $hash;
2434         my $path = $self->git_path($fb->{path});
2435         if (my $fh = $fb->{fh}) {
2436                 seek($fh, 0, 0) or croak $!;
2437                 my $md5 = Digest::MD5->new;
2438                 $md5->addfile($fh);
2439                 my $got = $md5->hexdigest;
2440                 die "Checksum mismatch: $path\n",
2441                     "expected: $exp\n    got: $got\n" if ($got ne $exp);
2442                 seek($fh, 0, 0) or croak $!;
2443                 if ($fb->{mode_b} == 120000) {
2444                         read($fh, my $buf, 5) == 5 or croak $!;
2445                         $buf eq 'link ' or die "$path has mode 120000",
2446                                                "but is not a link\n";
2447                 }
2448                 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
2449                 if (!$pid) {
2450                         open STDIN, '<&', $fh or croak $!;
2451                         exec qw/git-hash-object -w --stdin/ or croak $!;
2452                 }
2453                 chomp($hash = do { local $/; <$out> });
2454                 close $out or croak $!;
2455                 close $fh or croak $!;
2456                 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
2457                 close $fb->{base} or croak $!;
2458         } else {
2459                 $hash = $fb->{blob} or die "no blob information\n";
2460         }
2461         $fb->{pool}->clear;
2462         $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
2463         print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
2464         undef;
2465 }
2466
2467 sub abort_edit {
2468         my $self = shift;
2469         $self->{nr} = $self->{gii}->{nr};
2470         delete $self->{gii};
2471         $self->SUPER::abort_edit(@_);
2472 }
2473
2474 sub close_edit {
2475         my $self = shift;
2476         $self->{git_commit_ok} = 1;
2477         $self->{nr} = $self->{gii}->{nr};
2478         delete $self->{gii};
2479         $self->SUPER::close_edit(@_);
2480 }
2481
2482 package SVN::Git::Editor;
2483 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
2484 use strict;
2485 use warnings;
2486 use Carp qw/croak/;
2487 use IO::File;
2488 use Digest::MD5;
2489
2490 sub new {
2491         my ($class, $opts) = @_;
2492         foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
2493                 die "$_ required!\n" unless (defined $opts->{$_});
2494         }
2495
2496         my $pool = SVN::Pool->new;
2497         my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
2498         my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
2499                                      $opts->{r}, $mods);
2500
2501         # $opts->{ra} functions should not be used after this:
2502         my @ce  = $opts->{ra}->get_commit_editor($opts->{log},
2503                                                 $opts->{editor_cb}, $pool);
2504         my $self = SVN::Delta::Editor->new(@ce, $pool);
2505         bless $self, $class;
2506         foreach (qw/svn_path r tree_a tree_b/) {
2507                 $self->{$_} = $opts->{$_};
2508         }
2509         $self->{url} = $opts->{ra}->{url};
2510         $self->{mods} = $mods;
2511         $self->{types} = $types;
2512         $self->{pool} = $pool;
2513         $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
2514         $self->{rm} = { };
2515         $self->{path_prefix} = length $self->{svn_path} ?
2516                                "$self->{svn_path}/" : '';
2517         return $self;
2518 }
2519
2520 sub generate_diff {
2521         my ($tree_a, $tree_b) = @_;
2522         my @diff_tree = qw(diff-tree -z -r);
2523         if ($_cp_similarity) {
2524                 push @diff_tree, "-C$_cp_similarity";
2525         } else {
2526                 push @diff_tree, '-C';
2527         }
2528         push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
2529         push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
2530         push @diff_tree, $tree_a, $tree_b;
2531         my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
2532         local $/ = "\0";
2533         my $state = 'meta';
2534         my @mods;
2535         while (<$diff_fh>) {
2536                 chomp $_; # this gets rid of the trailing "\0"
2537                 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
2538                                         $::sha1\s($::sha1)\s
2539                                         ([MTCRAD])\d*$/xo) {
2540                         push @mods, {   mode_a => $1, mode_b => $2,
2541                                         sha1_b => $3, chg => $4 };
2542                         if ($4 =~ /^(?:C|R)$/) {
2543                                 $state = 'file_a';
2544                         } else {
2545                                 $state = 'file_b';
2546                         }
2547                 } elsif ($state eq 'file_a') {
2548                         my $x = $mods[$#mods] or croak "Empty array\n";
2549                         if ($x->{chg} !~ /^(?:C|R)$/) {
2550                                 croak "Error parsing $_, $x->{chg}\n";
2551                         }
2552                         $x->{file_a} = $_;
2553                         $state = 'file_b';
2554                 } elsif ($state eq 'file_b') {
2555                         my $x = $mods[$#mods] or croak "Empty array\n";
2556                         if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
2557                                 croak "Error parsing $_, $x->{chg}\n";
2558                         }
2559                         if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
2560                                 croak "Error parsing $_, $x->{chg}\n";
2561                         }
2562                         $x->{file_b} = $_;
2563                         $state = 'meta';
2564                 } else {
2565                         croak "Error parsing $_\n";
2566                 }
2567         }
2568         command_close_pipe($diff_fh, $ctx);
2569         \@mods;
2570 }
2571
2572 sub check_diff_paths {
2573         my ($ra, $pfx, $rev, $mods) = @_;
2574         my %types;
2575         $pfx .= '/' if length $pfx;
2576
2577         sub type_diff_paths {
2578                 my ($ra, $types, $path, $rev) = @_;
2579                 my @p = split m#/+#, $path;
2580                 my $c = shift @p;
2581                 unless (defined $types->{$c}) {
2582                         $types->{$c} = $ra->check_path($c, $rev);
2583                 }
2584                 while (@p) {
2585                         $c .= '/' . shift @p;
2586                         next if defined $types->{$c};
2587                         $types->{$c} = $ra->check_path($c, $rev);
2588                 }
2589         }
2590
2591         foreach my $m (@$mods) {
2592                 foreach my $f (qw/file_a file_b/) {
2593                         next unless defined $m->{$f};
2594                         my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
2595                         if (length $pfx.$dir && ! defined $types{$dir}) {
2596                                 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
2597                         }
2598                 }
2599         }
2600         \%types;
2601 }
2602
2603 sub split_path {
2604         return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
2605 }
2606
2607 sub repo_path {
2608         my ($self, $path) = @_;
2609         $self->{path_prefix}.(defined $path ? $path : '');
2610 }
2611
2612 sub url_path {
2613         my ($self, $path) = @_;
2614         $self->{url} . '/' . $self->repo_path($path);
2615 }
2616
2617 sub rmdirs {
2618         my ($self) = @_;
2619         my $rm = $self->{rm};
2620         delete $rm->{''}; # we never delete the url we're tracking
2621         return unless %$rm;
2622
2623         foreach (keys %$rm) {
2624                 my @d = split m#/#, $_;
2625                 my $c = shift @d;
2626                 $rm->{$c} = 1;
2627                 while (@d) {
2628                         $c .= '/' . shift @d;
2629                         $rm->{$c} = 1;
2630                 }
2631         }
2632         delete $rm->{$self->{svn_path}};
2633         delete $rm->{''}; # we never delete the url we're tracking
2634         return unless %$rm;
2635
2636         my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
2637                                              $self->{tree_b});
2638         local $/ = "\0";
2639         while (<$fh>) {
2640                 chomp;
2641                 my @dn = split m#/#, $_;
2642                 while (pop @dn) {
2643                         delete $rm->{join '/', @dn};
2644                 }
2645                 unless (%$rm) {
2646                         close $fh;
2647                         return;
2648                 }
2649         }
2650         command_close_pipe($fh, $ctx);
2651
2652         my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
2653         foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
2654                 $self->close_directory($bat->{$d}, $p);
2655                 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
2656                 print "\tD+\t$d/\n" unless $::_q;
2657                 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
2658                 delete $bat->{$d};
2659         }
2660 }
2661
2662 sub open_or_add_dir {
2663         my ($self, $full_path, $baton) = @_;
2664         my $t = $self->{types}->{$full_path};
2665         if (!defined $t) {
2666                 die "$full_path not known in r$self->{r} or we have a bug!\n";
2667         }
2668         if ($t == $SVN::Node::none) {
2669                 return $self->add_directory($full_path, $baton,
2670                                                 undef, -1, $self->{pool});
2671         } elsif ($t == $SVN::Node::dir) {
2672                 return $self->open_directory($full_path, $baton,
2673                                                 $self->{r}, $self->{pool});
2674         }
2675         print STDERR "$full_path already exists in repository at ",
2676                 "r$self->{r} and it is not a directory (",
2677                 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2678         exit 1;
2679 }
2680
2681 sub ensure_path {
2682         my ($self, $path) = @_;
2683         my $bat = $self->{bat};
2684         my $repo_path = $self->repo_path($path);
2685         return $bat->{''} unless (length $repo_path);
2686         my @p = split m#/+#, $repo_path;
2687         my $c = shift @p;
2688         $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2689         while (@p) {
2690                 my $c0 = $c;
2691                 $c .= '/' . shift @p;
2692                 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2693         }
2694         return $bat->{$c};
2695 }
2696
2697 sub A {
2698         my ($self, $m) = @_;
2699         my ($dir, $file) = split_path($m->{file_b});
2700         my $pbat = $self->ensure_path($dir);
2701         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2702                                         undef, -1);
2703         print "\tA\t$m->{file_b}\n" unless $::_q;
2704         $self->chg_file($fbat, $m);
2705         $self->close_file($fbat,undef,$self->{pool});
2706 }
2707
2708 sub C {
2709         my ($self, $m) = @_;
2710         my ($dir, $file) = split_path($m->{file_b});
2711         my $pbat = $self->ensure_path($dir);
2712         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2713                                 $self->url_path($m->{file_a}), $self->{r});
2714         print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2715         $self->chg_file($fbat, $m);
2716         $self->close_file($fbat,undef,$self->{pool});
2717 }
2718
2719 sub delete_entry {
2720         my ($self, $path, $pbat) = @_;
2721         my $rpath = $self->repo_path($path);
2722         my ($dir, $file) = split_path($rpath);
2723         $self->{rm}->{$dir} = 1;
2724         $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2725 }
2726
2727 sub R {
2728         my ($self, $m) = @_;
2729         my ($dir, $file) = split_path($m->{file_b});
2730         my $pbat = $self->ensure_path($dir);
2731         my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2732                                 $self->url_path($m->{file_a}), $self->{r});
2733         print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2734         $self->chg_file($fbat, $m);
2735         $self->close_file($fbat,undef,$self->{pool});
2736
2737         ($dir, $file) = split_path($m->{file_a});
2738         $pbat = $self->ensure_path($dir);
2739         $self->delete_entry($m->{file_a}, $pbat);
2740 }
2741
2742 sub M {
2743         my ($self, $m) = @_;
2744         my ($dir, $file) = split_path($m->{file_b});
2745         my $pbat = $self->ensure_path($dir);
2746         my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2747                                 $pbat,$self->{r},$self->{pool});
2748         print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2749         $self->chg_file($fbat, $m);
2750         $self->close_file($fbat,undef,$self->{pool});
2751 }
2752
2753 sub T { shift->M(@_) }
2754
2755 sub change_file_prop {
2756         my ($self, $fbat, $pname, $pval) = @_;
2757         $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2758 }
2759
2760 sub chg_file {
2761         my ($self, $fbat, $m) = @_;
2762         if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2763                 $self->change_file_prop($fbat,'svn:executable','*');
2764         } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2765                 $self->change_file_prop($fbat,'svn:executable',undef);
2766         }
2767         my $fh = IO::File->new_tmpfile or croak $!;
2768         if ($m->{mode_b} =~ /^120/) {
2769                 print $fh 'link ' or croak $!;
2770                 $self->change_file_prop($fbat,'svn:special','*');
2771         } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2772                 $self->change_file_prop($fbat,'svn:special',undef);
2773         }
2774         defined(my $pid = fork) or croak $!;
2775         if (!$pid) {
2776                 open STDOUT, '>&', $fh or croak $!;
2777                 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2778         }
2779         waitpid $pid, 0;
2780         croak $? if $?;
2781         $fh->flush == 0 or croak $!;
2782         seek $fh, 0, 0 or croak $!;
2783
2784         my $md5 = Digest::MD5->new;
2785         $md5->addfile($fh) or croak $!;
2786         seek $fh, 0, 0 or croak $!;
2787
2788         my $exp = $md5->hexdigest;
2789         my $pool = SVN::Pool->new;
2790         my $atd = $self->apply_textdelta($fbat, undef, $pool);
2791         my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2792         die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2793         $pool->clear;
2794
2795         close $fh or croak $!;
2796 }
2797
2798 sub D {
2799         my ($self, $m) = @_;
2800         my ($dir, $file) = split_path($m->{file_b});
2801         my $pbat = $self->ensure_path($dir);
2802         print "\tD\t$m->{file_b}\n" unless $::_q;
2803         $self->delete_entry($m->{file_b}, $pbat);
2804 }
2805
2806 sub close_edit {
2807         my ($self) = @_;
2808         my ($p,$bat) = ($self->{pool}, $self->{bat});
2809         foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2810                 $self->close_directory($bat->{$_}, $p);
2811         }
2812         $self->SUPER::close_edit($p);
2813         $p->clear;
2814 }
2815
2816 sub abort_edit {
2817         my ($self) = @_;
2818         $self->SUPER::abort_edit($self->{pool});
2819 }
2820
2821 sub DESTROY {
2822         my $self = shift;
2823         $self->SUPER::DESTROY(@_);
2824         $self->{pool}->clear;
2825 }
2826
2827 # this drives the editor
2828 sub apply_diff {
2829         my ($self) = @_;
2830         my $mods = $self->{mods};
2831         my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2832         foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2833                 my $f = $m->{chg};
2834                 if (defined $o{$f}) {
2835                         $self->$f($m);
2836                 } else {
2837                         fatal("Invalid change type: $f\n");
2838                 }
2839         }
2840         $self->rmdirs if $_rmdir;
2841         if (@$mods == 0) {
2842                 $self->abort_edit;
2843         } else {
2844                 $self->close_edit;
2845         }
2846         return scalar @$mods;
2847 }
2848
2849 package Git::SVN::Ra;
2850 use vars qw/@ISA $config_dir $_log_window_size/;
2851 use strict;
2852 use warnings;
2853 my ($can_do_switch, %ignored_err, $RA);
2854
2855 BEGIN {
2856         # enforce temporary pool usage for some simple functions
2857         my $e;
2858         foreach (qw/get_latest_revnum get_uuid get_repos_root/) {
2859                 $e .= "sub $_ {
2860                         my \$self = shift;
2861                         my \$pool = SVN::Pool->new;
2862                         my \@ret = \$self->SUPER::$_(\@_,\$pool);
2863                         \$pool->clear;
2864                         wantarray ? \@ret : \$ret[0]; }\n";
2865         }
2866
2867         # get_dir needs $pool held in cache for dirents to work,
2868         # check_path is cacheable and rev_proplist is close enough
2869         # for our purposes.
2870         foreach (qw/check_path get_dir rev_proplist/) {
2871                 $e .= "my \%${_}_cache; my \$${_}_rev = 0; sub $_ {
2872                         my \$self = shift;
2873                         my \$r = pop;
2874                         my \$k = join(\"\\0\", \@_);
2875                         if (my \$x = \$${_}_cache{\$r}->{\$k}) {
2876                                 return wantarray ? \@\$x : \$x->[0];
2877                         }
2878                         my \$pool = SVN::Pool->new;
2879                         my \@ret = \$self->SUPER::$_(\@_, \$r, \$pool);
2880                         if (\$r != \$${_}_rev) {
2881                                 \%${_}_cache = ( pool => [] );
2882                                 \$${_}_rev = \$r;
2883                         }
2884                         \$${_}_cache{\$r}->{\$k} = \\\@ret;
2885                         push \@{\$${_}_cache{pool}}, \$pool;
2886                         wantarray ? \@ret : \$ret[0]; }\n";
2887         }
2888         $e .= "\n1;";
2889         eval $e or die $@;
2890 }
2891
2892 sub new {
2893         my ($class, $url) = @_;
2894         $url =~ s!/+$!!;
2895         return $RA if ($RA && $RA->{url} eq $url);
2896         $RA->{pool}->clear if $RA;
2897
2898         SVN::_Core::svn_config_ensure($config_dir, undef);
2899         my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2900             SVN::Client::get_simple_provider(),
2901             SVN::Client::get_ssl_server_trust_file_provider(),
2902             SVN::Client::get_simple_prompt_provider(
2903               \&Git::SVN::Prompt::simple, 2),
2904             SVN::Client::get_ssl_client_cert_prompt_provider(
2905               \&Git::SVN::Prompt::ssl_client_cert, 2),
2906             SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2907               \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2908             SVN::Client::get_username_provider(),
2909             SVN::Client::get_ssl_server_trust_prompt_provider(
2910               \&Git::SVN::Prompt::ssl_server_trust),
2911             SVN::Client::get_username_prompt_provider(
2912               \&Git::SVN::Prompt::username, 2),
2913           ]);
2914         my $config = SVN::Core::config_get_config($config_dir);
2915         my $self = SVN::Ra->new(url => $url, auth => $baton,
2916                               config => $config,
2917                               pool => SVN::Pool->new,
2918                               auth_provider_callbacks => $callbacks);
2919         $self->{svn_path} = $url;
2920         $self->{repos_root} = $self->get_repos_root;
2921         $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
2922         $RA = bless $self, $class;
2923 }
2924
2925 sub DESTROY {
2926         # do not call the real DESTROY since we store ourselves in $RA
2927 }
2928
2929 sub get_log {
2930         my ($self, @args) = @_;
2931         my $pool = SVN::Pool->new;
2932         splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2933         my $ret = $self->SUPER::get_log(@args, $pool);
2934         $pool->clear;
2935         $ret;
2936 }
2937
2938 sub get_commit_editor {
2939         my ($self, $log, $cb, $pool) = @_;
2940         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2941         $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2942 }
2943
2944 sub gs_do_update {
2945         my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
2946         my $new = ($rev_a == $rev_b);
2947         my $path = $gs->{path};
2948
2949         if ($new && -e $gs->{index}) {
2950                 unlink $gs->{index} or die
2951                   "Couldn't unlink index: $gs->{index}: $!\n";
2952         }
2953         my $pool = SVN::Pool->new;
2954         $editor->set_path_strip($path);
2955         my (@pc) = split m#/#, $path;
2956         my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2957                                         1, $editor, $pool);
2958         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2959
2960         # Since we can't rely on svn_ra_reparent being available, we'll
2961         # just have to do some magic with set_path to make it so
2962         # we only want a partial path.
2963         my $sp = '';
2964         my $final = join('/', @pc);
2965         while (@pc) {
2966                 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2967                 $sp .= '/' if length $sp;
2968                 $sp .= shift @pc;
2969         }
2970         die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2971
2972         $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2973
2974         $reporter->finish_report($pool);
2975         $pool->clear;
2976         $editor->{git_commit_ok};
2977 }
2978
2979 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2980 # svn_ra_reparent didn't work before 1.4)
2981 sub gs_do_switch {
2982         my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
2983         my $path = $gs->{path};
2984         my $pool = SVN::Pool->new;
2985
2986         my $full_url = $self->{url};
2987         my $old_url = $full_url;
2988         $full_url .= "/$path" if length $path;
2989         my ($ra, $reparented);
2990         if ($old_url ne $full_url) {
2991                 if ($old_url !~ m#^svn(\+ssh)?://#) {
2992                         SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
2993                                                   $pool);
2994                         $self->{url} = $full_url;
2995                         $reparented = 1;
2996                 } else {
2997                         $ra = Git::SVN::Ra->new($full_url);
2998                 }
2999         }
3000         $ra ||= $self;
3001         my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3002         my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3003         $reporter->set_path('', $rev_a, 0, @lock, $pool);
3004         $reporter->finish_report($pool);
3005
3006         if ($reparented) {
3007                 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3008                 $self->{url} = $old_url;
3009         }
3010
3011         $pool->clear;
3012         $editor->{git_commit_ok};
3013 }
3014
3015 sub gs_fetch_loop_common {
3016         my ($self, $base, $head, $gsv, $globs) = @_;
3017         return if ($base > $head);
3018         my $inc = $_log_window_size;
3019         my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3020         my %common;
3021         my $common_max = scalar @$gsv;
3022
3023         foreach my $gs (@$gsv) {
3024                 my @tmp = split m#/#, $gs->{path};
3025                 my $p = '';
3026                 foreach (@tmp) {
3027                         $p .= length($p) ? "/$_" : $_;
3028                         $common{$p} ||= 0;
3029                         $common{$p}++;
3030                 }
3031         }
3032         $globs ||= [];
3033         $common_max += scalar @$globs;
3034         foreach my $glob (@$globs) {
3035                 my @tmp = split m#/#, $glob->{path}->{left};
3036                 my $p = '';
3037                 foreach (@tmp) {
3038                         $p .= length($p) ? "/$_" : $_;
3039                         $common{$p} ||= 0;
3040                         $common{$p}++;
3041                 }
3042         }
3043
3044         my $longest_path = '';
3045         foreach (sort {length $b <=> length $a} keys %common) {
3046                 if ($common{$_} == $common_max) {
3047                         $longest_path = $_;
3048                         last;
3049                 }
3050         }
3051         while (1) {
3052                 my %revs;
3053                 my $err;
3054                 my $err_handler = $SVN::Error::handler;
3055                 $SVN::Error::handler = sub {
3056                         ($err) = @_;
3057                         skip_unknown_revs($err);
3058                 };
3059                 sub _cb {
3060                         my ($paths, $r, $author, $date, $log) = @_;
3061                         [ dup_changed_paths($paths),
3062                           { author => $author, date => $date, log => $log } ];
3063                 }
3064                 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3065                                sub { $revs{$_[1]} = _cb(@_) });
3066                 if ($err && $max >= $head) {
3067                         print STDERR "Path '$longest_path' ",
3068                                      "was probably deleted:\n",
3069                                      $err->expanded_message,
3070                                      "\nWill attempt to follow ",
3071                                      "revisions r$min .. r$max ",
3072                                      "committed before the deletion\n";
3073                         my $hi = $max;
3074                         while (--$hi >= $min) {
3075                                 my $ok;
3076                                 $self->get_log([$longest_path], $min, $hi,
3077                                                0, 1, 1, sub {
3078                                                $ok ||= $_[1];
3079                                                $revs{$_[1]} = _cb(@_) });
3080                                 if ($ok) {
3081                                         print STDERR "r$min .. r$ok OK\n";
3082                                         last;
3083                                 }
3084                         }
3085                 }
3086                 $SVN::Error::handler = $err_handler;
3087
3088                 my %exists = map { $_->{path} => $_ } @$gsv;
3089                 foreach my $r (sort {$a <=> $b} keys %revs) {
3090                         my ($paths, $logged) = @{$revs{$r}};
3091
3092                         foreach my $gs ($self->match_globs(\%exists, $paths,
3093                                                            $globs, $r)) {
3094                                 if ($gs->rev_db_max >= $r) {
3095                                         next;
3096                                 }
3097                                 next unless $gs->match_paths($paths, $r);
3098                                 $gs->{logged_rev_props} = $logged;
3099                                 if (my $last_commit = $gs->last_commit) {
3100                                         $gs->assert_index_clean($last_commit);
3101                                 }
3102                                 my $log_entry = $gs->do_fetch($paths, $r);
3103                                 if ($log_entry) {
3104                                         $gs->do_git_commit($log_entry);
3105                                 }
3106                         }
3107                         foreach my $g (@$globs) {
3108                                 my $k = "svn-remote.$g->{remote}." .
3109                                         "$g->{t}-maxRev";
3110                                 Git::SVN::tmp_config($k, $r);
3111                         }
3112                 }
3113                 # pre-fill the .rev_db since it'll eventually get filled in
3114                 # with '0' x40 if something new gets committed
3115                 foreach my $gs (@$gsv) {
3116                         next if defined $gs->rev_db_get($max);
3117                         $gs->rev_db_set($max, 0 x40);
3118                 }
3119                 foreach my $g (@$globs) {
3120                         my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3121                         Git::SVN::tmp_config($k, $max);
3122                 }
3123                 last if $max >= $head;
3124                 $min = $max + 1;
3125                 $max += $inc;
3126                 $max = $head if ($max > $head);
3127         }
3128 }
3129
3130 sub match_globs {
3131         my ($self, $exists, $paths, $globs, $r) = @_;
3132
3133         sub get_dir_check {
3134                 my ($self, $exists, $g, $r) = @_;
3135                 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3136                 return unless scalar @x == 3;
3137                 my $dirents = $x[0];
3138                 foreach my $de (keys %$dirents) {
3139                         next if $dirents->{$de}->kind != $SVN::Node::dir;
3140                         my $p = $g->{path}->full_path($de);
3141                         next if $exists->{$p};
3142                         next if (length $g->{path}->{right} &&
3143                                  ($self->check_path($p, $r) !=
3144                                   $SVN::Node::dir));
3145                         $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
3146                                          $g->{ref}->full_path($de), 1);
3147                 }
3148         }
3149         foreach my $g (@$globs) {
3150                 if (my $path = $paths->{"/$g->{path}->{left}"}) {
3151                         if ($path->{action} =~ /^[AR]$/) {
3152                                 get_dir_check($self, $exists, $g, $r);
3153                         }
3154                 }
3155                 foreach (keys %$paths) {
3156                         if (/$g->{path}->{left_regex}/ &&
3157                             !/$g->{path}->{regex}/) {
3158                                 next if $paths->{$_}->{action} !~ /^[AR]$/;
3159                                 get_dir_check($self, $exists, $g, $r);
3160                         }
3161                         next unless /$g->{path}->{regex}/;
3162                         my $p = $1;
3163                         my $pathname = $g->{path}->full_path($p);
3164                         next if $exists->{$pathname};
3165                         next if ($self->check_path($pathname, $r) !=
3166                                  $SVN::Node::dir);
3167                         $exists->{$pathname} = Git::SVN->init(
3168                                               $self->{url}, $pathname, undef,
3169                                               $g->{ref}->full_path($p), 1);
3170                 }
3171                 my $c = '';
3172                 foreach (split m#/#, $g->{path}->{left}) {
3173                         $c .= "/$_";
3174                         next unless ($paths->{$c} &&
3175                                      ($paths->{$c}->{action} =~ /^[AR]$/));
3176                         get_dir_check($self, $exists, $g, $r);
3177                 }
3178         }
3179         values %$exists;
3180 }
3181
3182 sub minimize_url {
3183         my ($self) = @_;
3184         return $self->{url} if ($self->{url} eq $self->{repos_root});
3185         my $url = $self->{repos_root};
3186         my @components = split(m!/!, $self->{svn_path});
3187         my $c = '';
3188         do {
3189                 $url .= "/$c" if length $c;
3190                 eval { (ref $self)->new($url)->get_latest_revnum };
3191         } while ($@ && ($c = shift @components));
3192         $url;
3193 }
3194
3195 sub can_do_switch {
3196         my $self = shift;
3197         unless (defined $can_do_switch) {
3198                 my $pool = SVN::Pool->new;
3199                 my $rep = eval {
3200                         $self->do_switch(1, '', 0, $self->{url},
3201                                          SVN::Delta::Editor->new, $pool);
3202                 };
3203                 if ($@) {
3204                         $can_do_switch = 0;
3205                 } else {
3206                         $rep->abort_report($pool);
3207                         $can_do_switch = 1;
3208                 }
3209                 $pool->clear;
3210         }
3211         $can_do_switch;
3212 }
3213
3214 sub skip_unknown_revs {
3215         my ($err) = @_;
3216         my $errno = $err->apr_err();
3217         # Maybe the branch we're tracking didn't
3218         # exist when the repo started, so it's
3219         # not an error if it doesn't, just continue
3220         #
3221         # Wonderfully consistent library, eh?
3222         # 160013 - svn:// and file://
3223         # 175002 - http(s)://
3224         # 175007 - http(s):// (this repo required authorization, too...)
3225         #   More codes may be discovered later...
3226         if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3227                 my $err_key = $err->expanded_message;
3228                 # revision numbers change every time, filter them out
3229                 $err_key =~ s/\d+/\0/g;
3230                 $err_key = "$errno\0$err_key";
3231                 unless ($ignored_err{$err_key}) {
3232                         warn "W: Ignoring error from SVN, path probably ",
3233                              "does not exist: ($errno): ",
3234                              $err->expanded_message,"\n";
3235                         $ignored_err{$err_key} = 1;
3236                 }
3237                 return;
3238         }
3239         die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3240 }
3241
3242 # svn_log_changed_path_t objects passed to get_log are likely to be
3243 # overwritten even if only the refs are copied to an external variable,
3244 # so we should dup the structures in their entirety.  Using an externally
3245 # passed pool (instead of our temporary and quickly cleared pool in
3246 # Git::SVN::Ra) does not help matters at all...
3247 sub dup_changed_paths {
3248         my ($paths) = @_;
3249         return undef unless $paths;
3250         my %ret;
3251         foreach my $p (keys %$paths) {
3252                 my $i = $paths->{$p};
3253                 my %s = map { $_ => $i->$_ }
3254                               qw/copyfrom_path copyfrom_rev action/;
3255                 $ret{$p} = \%s;
3256         }
3257         \%ret;
3258 }
3259
3260 package Git::SVN::Log;
3261 use strict;
3262 use warnings;
3263 use POSIX qw/strftime/;
3264 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
3265             %rusers $show_commit $incremental/;
3266 my $l_fmt;
3267
3268 sub cmt_showable {
3269         my ($c) = @_;
3270         return 1 if defined $c->{r};
3271
3272         # big commit message got truncated by the 16k pretty buffer in rev-list
3273         if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
3274                                 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
3275                 @{$c->{l}} = ();
3276                 my @log = command(qw/cat-file commit/, $c->{c});
3277
3278                 # shift off the headers
3279                 shift @log while ($log[0] ne '');
3280                 shift @log;
3281
3282                 # TODO: make $c->{l} not have a trailing newline in the future
3283                 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
3284
3285                 (undef, $c->{r}, undef) = ::extract_metadata(
3286                                 (grep(/^git-svn-id: /, @log))[-1]);
3287         }
3288         return defined $c->{r};
3289 }
3290
3291 sub log_use_color {
3292         return 1 if $color;
3293         my ($dc, $dcvar);
3294         $dcvar = 'color.diff';
3295         $dc = `git-config --get $dcvar`;
3296         if ($dc eq '') {
3297                 # nothing at all; fallback to "diff.color"
3298                 $dcvar = 'diff.color';
3299                 $dc = `git-config --get $dcvar`;
3300         }
3301         chomp($dc);
3302         if ($dc eq 'auto') {
3303                 my $pc;
3304                 $pc = `git-config --get color.pager`;
3305                 if ($pc eq '') {
3306                         # does not have it -- fallback to pager.color
3307                         $pc = `git-config --bool --get pager.color`;
3308                 }
3309                 else {
3310                         $pc = `git-config --bool --get color.pager`;
3311                         if ($?) {
3312                                 $pc = 'false';
3313                         }
3314                 }
3315                 chomp($pc);
3316                 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
3317                         return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
3318                 }
3319                 return 0;
3320         }
3321         return 0 if $dc eq 'never';
3322         return 1 if $dc eq 'always';
3323         chomp($dc = `git-config --bool --get $dcvar`);
3324         return ($dc eq 'true');
3325 }
3326
3327 sub git_svn_log_cmd {
3328         my ($r_min, $r_max, @args) = @_;
3329         my $head = 'HEAD';
3330         foreach my $x (@args) {
3331                 last if $x eq '--';
3332                 next unless ::verify_ref("$x^0");
3333                 $head = $x;
3334                 last;
3335         }
3336
3337         my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
3338         $gs ||= Git::SVN->_new;
3339         my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
3340                    $gs->refname);
3341         push @cmd, '-r' unless $non_recursive;
3342         push @cmd, qw/--raw --name-status/ if $verbose;
3343         push @cmd, '--color' if log_use_color();
3344         return @cmd unless defined $r_max;
3345         if ($r_max == $r_min) {
3346                 push @cmd, '--max-count=1';
3347                 if (my $c = $gs->rev_db_get($r_max)) {
3348                         push @cmd, $c;
3349                 }
3350         } else {
3351                 my ($c_min, $c_max);
3352                 $c_max = $gs->rev_db_get($r_max);
3353                 $c_min = $gs->rev_db_get($r_min);
3354                 if (defined $c_min && defined $c_max) {
3355                         if ($r_max > $r_max) {
3356                                 push @cmd, "$c_min..$c_max";
3357                         } else {
3358                                 push @cmd, "$c_max..$c_min";
3359                         }
3360                 } elsif ($r_max > $r_min) {
3361                         push @cmd, $c_max;
3362                 } else {
3363                         push @cmd, $c_min;
3364                 }
3365         }
3366         return @cmd;
3367 }
3368
3369 # adapted from pager.c
3370 sub config_pager {
3371         $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
3372         if (!defined $pager) {
3373                 $pager = 'less';
3374         } elsif (length $pager == 0 || $pager eq 'cat') {
3375                 $pager = undef;
3376         }
3377 }
3378
3379 sub run_pager {
3380         return unless -t *STDOUT;
3381         pipe my $rfd, my $wfd or return;
3382         defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
3383         if (!$pid) {
3384                 open STDOUT, '>&', $wfd or
3385                                      ::fatal "Can't redirect to stdout: $!\n";
3386                 return;
3387         }
3388         open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
3389         $ENV{LESS} ||= 'FRSX';
3390         exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
3391 }
3392
3393 sub tz_to_s_offset {
3394         my ($tz) = @_;
3395         $tz =~ s/(\d\d)$//;
3396         return ($1 * 60) + ($tz * 3600);
3397 }
3398
3399 sub get_author_info {
3400         my ($dest, $author, $t, $tz) = @_;
3401         $author =~ s/(?:^\s*|\s*$)//g;
3402         $dest->{a_raw} = $author;
3403         my $au;
3404         if ($::_authors) {
3405                 $au = $rusers{$author} || undef;
3406         }
3407         if (!$au) {
3408                 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
3409         }
3410         $dest->{t} = $t;
3411         $dest->{tz} = $tz;
3412         $dest->{a} = $au;
3413         # Date::Parse isn't in the standard Perl distro :(
3414         if ($tz =~ s/^\+//) {
3415                 $t += tz_to_s_offset($tz);
3416         } elsif ($tz =~ s/^\-//) {
3417                 $t -= tz_to_s_offset($tz);
3418         }
3419         $dest->{t_utc} = $t;
3420 }
3421
3422 sub process_commit {
3423         my ($c, $r_min, $r_max, $defer) = @_;
3424         if (defined $r_min && defined $r_max) {
3425                 if ($r_min == $c->{r} && $r_min == $r_max) {
3426                         show_commit($c);
3427                         return 0;
3428                 }
3429                 return 1 if $r_min == $r_max;
3430                 if ($r_min < $r_max) {
3431                         # we need to reverse the print order
3432                         return 0 if (defined $limit && --$limit < 0);
3433                         push @$defer, $c;
3434                         return 1;
3435                 }
3436                 if ($r_min != $r_max) {
3437                         return 1 if ($r_min < $c->{r});
3438                         return 1 if ($r_max > $c->{r});
3439                 }
3440         }
3441         return 0 if (defined $limit && --$limit < 0);
3442         show_commit($c);
3443         return 1;
3444 }
3445
3446 sub show_commit {
3447         my $c = shift;
3448         if ($oneline) {
3449                 my $x = "\n";
3450                 if (my $l = $c->{l}) {
3451                         while ($l->[0] =~ /^\s*$/) { shift @$l }
3452                         $x = $l->[0];
3453                 }
3454                 $l_fmt ||= 'A' . length($c->{r});
3455                 print 'r',pack($l_fmt, $c->{r}),' | ';
3456                 print "$c->{c} | " if $show_commit;
3457                 print $x;
3458         } else {
3459                 show_commit_normal($c);
3460         }
3461 }
3462
3463 sub show_commit_changed_paths {
3464         my ($c) = @_;
3465         return unless $c->{changed};
3466         print "Changed paths:\n", @{$c->{changed}};
3467 }
3468
3469 sub show_commit_normal {
3470         my ($c) = @_;
3471         print '-' x72, "\nr$c->{r} | ";
3472         print "$c->{c} | " if $show_commit;
3473         print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
3474                                  localtime($c->{t_utc})), ' | ';
3475         my $nr_line = 0;
3476
3477         if (my $l = $c->{l}) {
3478                 while ($l->[$#$l] eq "\n" && $#$l > 0
3479                                           && $l->[($#$l - 1)] eq "\n") {
3480                         pop @$l;
3481                 }
3482                 $nr_line = scalar @$l;
3483                 if (!$nr_line) {
3484                         print "1 line\n\n\n";
3485                 } else {
3486                         if ($nr_line == 1) {
3487                                 $nr_line = '1 line';
3488                         } else {
3489                                 $nr_line .= ' lines';
3490                         }
3491                         print $nr_line, "\n";
3492                         show_commit_changed_paths($c);
3493                         print "\n";
3494                         print $_ foreach @$l;
3495                 }
3496         } else {
3497                 print "1 line\n";
3498                 show_commit_changed_paths($c);
3499                 print "\n";
3500
3501         }
3502         foreach my $x (qw/raw stat diff/) {
3503                 if ($c->{$x}) {
3504                         print "\n";
3505                         print $_ foreach @{$c->{$x}}
3506                 }
3507         }
3508 }
3509
3510 sub cmd_show_log {
3511         my (@args) = @_;
3512         my ($r_min, $r_max);
3513         my $r_last = -1; # prevent dupes
3514         if (defined $TZ) {
3515                 $ENV{TZ} = $TZ;
3516         } else {
3517                 delete $ENV{TZ};
3518         }
3519         if (defined $::_revision) {
3520                 if ($::_revision =~ /^(\d+):(\d+)$/) {
3521                         ($r_min, $r_max) = ($1, $2);
3522                 } elsif ($::_revision =~ /^\d+$/) {
3523                         $r_min = $r_max = $::_revision;
3524                 } else {
3525                         ::fatal "-r$::_revision is not supported, use ",
3526                                 "standard \'git log\' arguments instead\n";
3527                 }
3528         }
3529
3530         config_pager();
3531         @args = (git_svn_log_cmd($r_min, $r_max, @args), @args);
3532         my $log = command_output_pipe(@args);
3533         run_pager();
3534         my (@k, $c, $d, $stat);
3535         my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
3536         while (<$log>) {
3537                 if (/^${esc_color}commit ($::sha1_short)/o) {
3538                         my $cmt = $1;
3539                         if ($c && cmt_showable($c) && $c->{r} != $r_last) {
3540                                 $r_last = $c->{r};
3541                                 process_commit($c, $r_min, $r_max, \@k) or
3542                                                                 goto out;
3543                         }
3544                         $d = undef;
3545                         $c = { c => $cmt };
3546                 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
3547                         get_author_info($c, $1, $2, $3);
3548                 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
3549                         # ignore
3550                 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
3551                         push @{$c->{raw}}, $_;
3552                 } elsif (/^${esc_color}[ACRMDT]\t/) {
3553                         # we could add $SVN->{svn_path} here, but that requires
3554                         # remote access at the moment (repo_path_split)...
3555                         s#^(${esc_color})([ACRMDT])\t#$1   $2 #o;
3556                         push @{$c->{changed}}, $_;
3557                 } elsif (/^${esc_color}diff /o) {
3558                         $d = 1;
3559                         push @{$c->{diff}}, $_;
3560                 } elsif ($d) {
3561                         push @{$c->{diff}}, $_;
3562                 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
3563                           $esc_color*[\+\-]*$esc_color$/x) {
3564                         $stat = 1;
3565                         push @{$c->{stat}}, $_;
3566                 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
3567                         push @{$c->{stat}}, $_;
3568                         $stat = undef;
3569                 } elsif (/^${esc_color}    (git-svn-id:.+)$/o) {
3570                         ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
3571                 } elsif (s/^${esc_color}    //o) {
3572                         push @{$c->{l}}, $_;
3573                 }
3574         }
3575         if ($c && defined $c->{r} && $c->{r} != $r_last) {
3576                 $r_last = $c->{r};
3577                 process_commit($c, $r_min, $r_max, \@k);
3578         }
3579         if (@k) {
3580                 my $swap = $r_max;
3581                 $r_max = $r_min;
3582                 $r_min = $swap;
3583                 process_commit($_, $r_min, $r_max) foreach reverse @k;
3584         }
3585 out:
3586         close $log;
3587         print '-' x72,"\n" unless $incremental || $oneline;
3588 }
3589
3590 package Git::SVN::Migration;
3591 # these version numbers do NOT correspond to actual version numbers
3592 # of git nor git-svn.  They are just relative.
3593 #
3594 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
3595 #
3596 # v1 layout: .git/$id/info/url, refs/remotes/$id
3597 #
3598 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
3599 #
3600 # v3 layout: .git/svn/$id, refs/remotes/$id
3601 #            - info/url may remain for backwards compatibility
3602 #            - this is what we migrate up to this layout automatically,
3603 #            - this will be used by git svn init on single branches
3604 # v3.1 layout (auto migrated):
3605 #            - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
3606 #              for backwards compatibility
3607 #
3608 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
3609 #            - this is only created for newly multi-init-ed
3610 #              repositories.  Similar in spirit to the
3611 #              --use-separate-remotes option in git-clone (now default)
3612 #            - we do not automatically migrate to this (following
3613 #              the example set by core git)
3614 use strict;
3615 use warnings;
3616 use Carp qw/croak/;
3617 use File::Path qw/mkpath/;
3618 use File::Basename qw/dirname basename/;
3619 use vars qw/$_minimize/;
3620
3621 sub migrate_from_v0 {
3622         my $git_dir = $ENV{GIT_DIR};
3623         return undef unless -d $git_dir;
3624         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3625         my $migrated = 0;
3626         while (<$fh>) {
3627                 chomp;
3628                 my ($id, $orig_ref) = ($_, $_);
3629                 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
3630                 next unless -f "$git_dir/$id/info/url";
3631                 my $new_ref = "refs/remotes/$id";
3632                 if (::verify_ref("$new_ref^0")) {
3633                         print STDERR "W: $orig_ref is probably an old ",
3634                                      "branch used by an ancient version of ",
3635                                      "git-svn.\n",
3636                                      "However, $new_ref also exists.\n",
3637                                      "We will not be able ",
3638                                      "to use this branch until this ",
3639                                      "ambiguity is resolved.\n";
3640                         next;
3641                 }
3642                 print STDERR "Migrating from v0 layout...\n" if !$migrated;
3643                 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
3644                 command_noisy('update-ref', $new_ref, $orig_ref);
3645                 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
3646                 $migrated++;
3647         }
3648         command_close_pipe($fh, $ctx);
3649         print STDERR "Done migrating from v0 layout...\n" if $migrated;
3650         $migrated;
3651 }
3652
3653 sub migrate_from_v1 {
3654         my $git_dir = $ENV{GIT_DIR};
3655         my $migrated = 0;
3656         return $migrated unless -d $git_dir;
3657         my $svn_dir = "$git_dir/svn";
3658
3659         # just in case somebody used 'svn' as their $id at some point...
3660         return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
3661
3662         print STDERR "Migrating from a git-svn v1 layout...\n";
3663         mkpath([$svn_dir]);
3664         print STDERR "Data from a previous version of git-svn exists, but\n\t",
3665                      "$svn_dir\n\t(required for this version ",
3666                      "($::VERSION) of git-svn) does not. exist\n";
3667         my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
3668         while (<$fh>) {
3669                 my $x = $_;
3670                 next unless $x =~ s#^refs/remotes/##;
3671                 chomp $x;
3672                 next unless -f "$git_dir/$x/info/url";
3673                 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
3674                 next unless $u;
3675                 my $dn = dirname("$git_dir/svn/$x");
3676                 mkpath([$dn]) unless -d $dn;
3677                 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
3678                         mkpath(["$git_dir/svn/svn"]);
3679                         print STDERR " - $git_dir/$x/info => ",
3680                                         "$git_dir/svn/$x/info\n";
3681                         rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
3682                                croak "$!: $x";
3683                         # don't worry too much about these, they probably
3684                         # don't exist with repos this old (save for index,
3685                         # and we can easily regenerate that)
3686                         foreach my $f (qw/unhandled.log index .rev_db/) {
3687                                 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
3688                         }
3689                 } else {
3690                         print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
3691                         rename "$git_dir/$x", "$git_dir/svn/$x" or
3692                                croak "$!: $x";
3693                 }
3694                 $migrated++;
3695         }
3696         command_close_pipe($fh, $ctx);
3697         print STDERR "Done migrating from a git-svn v1 layout\n";
3698         $migrated;
3699 }
3700
3701 sub read_old_urls {
3702         my ($l_map, $pfx, $path) = @_;
3703         my @dir;
3704         foreach (<$path/*>) {
3705                 if (-r "$_/info/url") {
3706                         $pfx .= '/' if $pfx && $pfx !~ m!/$!;
3707                         my $ref_id = $pfx . basename $_;
3708                         my $url = ::file_to_s("$_/info/url");
3709                         $l_map->{$ref_id} = $url;
3710                 } elsif (-d $_) {
3711                         push @dir, $_;
3712                 }
3713         }
3714         foreach (@dir) {
3715                 my $x = $_;
3716                 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
3717                 read_old_urls($l_map, $x, $_);
3718         }
3719 }
3720
3721 sub migrate_from_v2 {
3722         my @cfg = command(qw/config -l/);
3723         return if grep /^svn-remote\..+\.url=/, @cfg;
3724         my %l_map;
3725         read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
3726         my $migrated = 0;
3727
3728         foreach my $ref_id (sort keys %l_map) {
3729                 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
3730                 if ($@) {
3731                         Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
3732                 }
3733                 $migrated++;
3734         }
3735         $migrated;
3736 }
3737
3738 sub minimize_connections {
3739         my $r = Git::SVN::read_all_remotes();
3740         my $new_urls = {};
3741         my $root_repos = {};
3742         foreach my $repo_id (keys %$r) {
3743                 my $url = $r->{$repo_id}->{url} or next;
3744                 my $fetch = $r->{$repo_id}->{fetch} or next;
3745                 my $ra = Git::SVN::Ra->new($url);
3746
3747                 # skip existing cases where we already connect to the root
3748                 if (($ra->{url} eq $ra->{repos_root}) ||
3749                     (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
3750                      $repo_id)) {
3751                         $root_repos->{$ra->{url}} = $repo_id;
3752                         next;
3753                 }
3754
3755                 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
3756                 my $root_path = $ra->{url};
3757                 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
3758                 foreach my $path (keys %$fetch) {
3759                         my $ref_id = $fetch->{$path};
3760                         my $gs = Git::SVN->new($ref_id, $repo_id, $path);
3761
3762                         # make sure we can read when connecting to
3763                         # a higher level of a repository
3764                         my ($last_rev, undef) = $gs->last_rev_commit;
3765                         if (!defined $last_rev) {
3766                                 $last_rev = eval {
3767                                         $root_ra->get_latest_revnum;
3768                                 };
3769                                 next if $@;
3770                         }
3771                         my $new = $root_path;
3772                         $new .= length $path ? "/$path" : '';
3773                         eval {
3774                                 $root_ra->get_log([$new], $last_rev, $last_rev,
3775                                                   0, 0, 1, sub { });
3776                         };
3777                         next if $@;
3778                         $new_urls->{$ra->{repos_root}}->{$new} =
3779                                 { ref_id => $ref_id,
3780                                   old_repo_id => $repo_id,
3781                                   old_path => $path };
3782                 }
3783         }
3784
3785         my @emptied;
3786         foreach my $url (keys %$new_urls) {
3787                 # see if we can re-use an existing [svn-remote "repo_id"]
3788                 # instead of creating a(n ugly) new section:
3789                 my $repo_id = $root_repos->{$url} ||
3790                               Git::SVN::sanitize_remote_name($url);
3791
3792                 my $fetch = $new_urls->{$url};
3793                 foreach my $path (keys %$fetch) {
3794                         my $x = $fetch->{$path};
3795                         Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
3796                         my $pfx = "svn-remote.$x->{old_repo_id}";
3797
3798                         my $old_fetch = quotemeta("$x->{old_path}:".
3799                                                   "refs/remotes/$x->{ref_id}");
3800                         command_noisy(qw/config --unset/,
3801                                       "$pfx.fetch", '^'. $old_fetch . '$');
3802                         delete $r->{$x->{old_repo_id}}->
3803                                {fetch}->{$x->{old_path}};
3804                         if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
3805                                 command_noisy(qw/config --unset/,
3806                                               "$pfx.url");
3807                                 push @emptied, $x->{old_repo_id}
3808                         }
3809                 }
3810         }
3811         if (@emptied) {
3812                 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
3813                            "$ENV{GIT_DIR}/config";
3814                 print STDERR <<EOF;
3815 The following [svn-remote] sections in your config file ($file) are empty
3816 and can be safely removed:
3817 EOF
3818                 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
3819         }
3820 }
3821
3822 sub migration_check {
3823         migrate_from_v0();
3824         migrate_from_v1();
3825         migrate_from_v2();
3826         minimize_connections() if $_minimize;
3827 }
3828
3829 package Git::IndexInfo;
3830 use strict;
3831 use warnings;
3832 use Git qw/command_input_pipe command_close_pipe/;
3833
3834 sub new {
3835         my ($class) = @_;
3836         my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
3837         bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
3838 }
3839
3840 sub remove {
3841         my ($self, $path) = @_;
3842         if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
3843                 return ++$self->{nr};
3844         }
3845         undef;
3846 }
3847
3848 sub update {
3849         my ($self, $mode, $hash, $path) = @_;
3850         if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
3851                 return ++$self->{nr};
3852         }
3853         undef;
3854 }
3855
3856 sub DESTROY {
3857         my ($self) = @_;
3858         command_close_pipe($self->{gui}, $self->{ctx});
3859 }
3860
3861 package Git::SVN::GlobSpec;
3862 use strict;
3863 use warnings;
3864
3865 sub new {
3866         my ($class, $glob) = @_;
3867         my $re = $glob;
3868         $re =~ s!/+$!!g; # no need for trailing slashes
3869         my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
3870         my ($left, $right) = ($1, $2);
3871         if ($nr > 1) {
3872                 die "Only one '*' wildcard expansion ",
3873                     "is supported (got $nr): '$glob'\n";
3874         } elsif ($nr == 0) {
3875                 die "One '*' is needed for glob: '$glob'\n";
3876         }
3877         $re = quotemeta($left) . $re . quotemeta($right);
3878         if (length $left && !($left =~ s!/+$!!g)) {
3879                 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
3880         }
3881         if (length $right && !($right =~ s!^/+!!g)) {
3882                 die "Missing leading '/' on right side of: '$glob' ($right)\n";
3883         }
3884         my $left_re = qr/^\/\Q$left\E(\/|$)/;
3885         bless { left => $left, right => $right, left_regex => $left_re,
3886                 regex => qr/$re/, glob => $glob }, $class;
3887 }
3888
3889 sub full_path {
3890         my ($self, $path) = @_;
3891         return (length $self->{left} ? "$self->{left}/" : '') .
3892                $path . (length $self->{right} ? "/$self->{right}" : '');
3893 }
3894
3895 __END__
3896
3897 Data structures:
3898
3899
3900 $remotes = { # returned by read_all_remotes()
3901         'svn' => {
3902                 # svn-remote.svn.url=https://svn.musicpd.org
3903                 url => 'https://svn.musicpd.org',
3904                 # svn-remote.svn.fetch=mpd/trunk:trunk
3905                 fetch => {
3906                         'mpd/trunk' => 'trunk',
3907                 },
3908                 # svn-remote.svn.tags=mpd/tags/*:tags/*
3909                 tags => {
3910                         path => {
3911                                 left => 'mpd/tags',
3912                                 right => '',
3913                                 regex => qr!mpd/tags/([^/]+)$!,
3914                                 glob => 'tags/*',
3915                         },
3916                         ref => {
3917                                 left => 'tags',
3918                                 right => '',
3919                                 regex => qr!tags/([^/]+)$!,
3920                                 glob => 'tags/*',
3921                         },
3922                 }
3923         }
3924 };
3925
3926 $log_entry hashref as returned by libsvn_log_entry()
3927 {
3928         log => 'whitespace-formatted log entry
3929 ',                                              # trailing newline is preserved
3930         revision => '8',                        # integer
3931         date => '2004-02-24T17:01:44.108345Z',  # commit date
3932         author => 'committer name'
3933 };
3934
3935
3936 # this is generated by generate_diff();
3937 @mods = array of diff-index line hashes, each element represents one line
3938         of diff-index output
3939
3940 diff-index line ($m hash)
3941 {
3942         mode_a => first column of diff-index output, no leading ':',
3943         mode_b => second column of diff-index output,
3944         sha1_b => sha1sum of the final blob,
3945         chg => change type [MCRADT],
3946         file_a => original file name of a file (iff chg is 'C' or 'R')
3947         file_b => new/current file name of a file (any chg)
3948 }
3949 ;
3950
3951 # retval of read_url_paths{,_all}();
3952 $l_map = {
3953         # repository root url
3954         'https://svn.musicpd.org' => {
3955                 # repository path               # GIT_SVN_ID
3956                 'mpd/trunk'             =>      'trunk',
3957                 'mpd/tags/0.11.5'       =>      'tags/0.11.5',
3958         },
3959 }
3960
3961 Notes:
3962         I don't trust the each() function on unless I created %hash myself
3963         because the internal iterator may not have started at base.