![[tokkee]](http://tokkee.org/images/avatar.png){kind=avatar}
d5316eb6da3f94df82bdb8a73a81a1f63f117390
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision
8 $_q $_authors %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
23 $Git::SVN::Log::TZ = $ENV{TZ};
24 $ENV{TZ} = 'UTC';
25 $| = 1; # unbuffer STDOUT
27 sub fatal (@) { print STDERR "@_\n"; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use Digest::MD5;
39 use IO::File qw//;
40 use File::Basename qw/dirname basename/;
41 use File::Path qw/mkpath/;
42 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
43 use IPC::Open3;
44 use Git;
46 BEGIN {
47 # import functions from Git into our packages, en masse
48 no strict 'refs';
49 foreach (qw/command command_oneline command_noisy command_output_pipe
50 command_input_pipe command_close_pipe/) {
51 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
52 Git::SVN::Migration Git::SVN::Log Git::SVN),
53 __PACKAGE__) {
54 *{"${package}::$_"} = \&{"Git::$_"};
55 }
56 }
57 }
59 my ($SVN);
61 $sha1 = qr/[a-f\d]{40}/;
62 $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_stdin, $_help, $_edit,
64 $_message, $_file,
65 $_template, $_shared,
66 $_version, $_fetch_all, $_no_rebase,
67 $_merge, $_strategy, $_dry_run, $_local,
68 $_prefix, $_no_checkout, $_url, $_verbose);
69 $Git::SVN::_follow_parent = 1;
70 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
71 'config-dir=s' => \$Git::SVN::Ra::config_dir,
72 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
73 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
74 'authors-file|A=s' => \$_authors,
75 'repack:i' => \$Git::SVN::_repack,
76 'noMetadata' => \$Git::SVN::_no_metadata,
77 'useSvmProps' => \$Git::SVN::_use_svm_props,
78 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
79 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
80 'no-checkout' => \$_no_checkout,
81 'quiet|q' => \$_q,
82 'repack-flags|repack-args|repack-opts=s' =>
83 \$Git::SVN::_repack_flags,
84 'use-log-author' => \$Git::SVN::_use_log_author,
85 %remote_opts );
87 my ($_trunk, $_tags, $_branches, $_stdlayout);
88 my %icv;
89 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
90 'trunk|T=s' => \$_trunk, 'tags|t=s' => \$_tags,
91 'branches|b=s' => \$_branches, 'prefix=s' => \$_prefix,
92 'stdlayout|s' => \$_stdlayout,
93 'minimize-url|m' => \$Git::SVN::_minimize_url,
94 'no-metadata' => sub { $icv{noMetadata} = 1 },
95 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
96 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
97 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
98 %remote_opts );
99 my %cmt_opts = ( 'edit|e' => \$_edit,
100 'rmdir' => \$SVN::Git::Editor::_rmdir,
101 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
102 'l=i' => \$SVN::Git::Editor::_rename_limit,
103 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
104 );
106 my %cmd = (
107 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
108 { 'revision|r=s' => \$_revision,
109 'fetch-all|all' => \$_fetch_all,
110 %fc_opts } ],
111 clone => [ \&cmd_clone, "Initialize and fetch revisions",
112 { 'revision|r=s' => \$_revision,
113 %fc_opts, %init_opts } ],
114 init => [ \&cmd_init, "Initialize a repo for tracking" .
115 " (requires URL argument)",
116 \%init_opts ],
117 'multi-init' => [ \&cmd_multi_init,
118 "Deprecated alias for ".
119 "'$0 init -T<trunk> -b<branches> -t<tags>'",
120 \%init_opts ],
121 dcommit => [ \&cmd_dcommit,
122 'Commit several diffs to merge with upstream',
123 { 'merge|m|M' => \$_merge,
124 'strategy|s=s' => \$_strategy,
125 'verbose|v' => \$_verbose,
126 'dry-run|n' => \$_dry_run,
127 'fetch-all|all' => \$_fetch_all,
128 'no-rebase' => \$_no_rebase,
129 %cmt_opts, %fc_opts } ],
130 'set-tree' => [ \&cmd_set_tree,
131 "Set an SVN repository to a git tree-ish",
132 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
133 'create-ignore' => [ \&cmd_create_ignore,
134 'Create a .gitignore per svn:ignore',
135 { 'revision|r=i' => \$_revision
136 } ],
137 'propget' => [ \&cmd_propget,
138 'Print the value of a property on a file or directory',
139 { 'revision|r=i' => \$_revision } ],
140 'proplist' => [ \&cmd_proplist,
141 'List all properties of a file or directory',
142 { 'revision|r=i' => \$_revision } ],
143 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
144 { 'revision|r=i' => \$_revision
145 } ],
146 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
147 { 'revision|r=i' => \$_revision
148 } ],
149 'multi-fetch' => [ \&cmd_multi_fetch,
150 "Deprecated alias for $0 fetch --all",
151 { 'revision|r=s' => \$_revision, %fc_opts } ],
152 'migrate' => [ sub { },
153 # no-op, we automatically run this anyways,
154 'Migrate configuration/metadata/layout from
155 previous versions of git-svn',
156 { 'minimize' => \$Git::SVN::Migration::_minimize,
157 %remote_opts } ],
158 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
159 { 'limit=i' => \$Git::SVN::Log::limit,
160 'revision|r=s' => \$_revision,
161 'verbose|v' => \$Git::SVN::Log::verbose,
162 'incremental' => \$Git::SVN::Log::incremental,
163 'oneline' => \$Git::SVN::Log::oneline,
164 'show-commit' => \$Git::SVN::Log::show_commit,
165 'non-recursive' => \$Git::SVN::Log::non_recursive,
166 'authors-file|A=s' => \$_authors,
167 'color' => \$Git::SVN::Log::color,
168 'pager=s' => \$Git::SVN::Log::pager
169 } ],
170 'find-rev' => [ \&cmd_find_rev, "Translate between SVN revision numbers and tree-ish",
171 {} ],
172 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
173 { 'merge|m|M' => \$_merge,
174 'verbose|v' => \$_verbose,
175 'strategy|s=s' => \$_strategy,
176 'local|l' => \$_local,
177 'fetch-all|all' => \$_fetch_all,
178 %fc_opts } ],
179 'commit-diff' => [ \&cmd_commit_diff,
180 'Commit a diff between two trees',
181 { 'message|m=s' => \$_message,
182 'file|F=s' => \$_file,
183 'revision|r=s' => \$_revision,
184 %cmt_opts } ],
185 'info' => [ \&cmd_info,
186 "Show info about the latest SVN revision
187 on the current branch",
188 { 'url' => \$_url, } ],
189 );
191 my $cmd;
192 for (my $i = 0; $i < @ARGV; $i++) {
193 if (defined $cmd{$ARGV[$i]}) {
194 $cmd = $ARGV[$i];
195 splice @ARGV, $i, 1;
196 last;
197 }
198 };
200 # make sure we're always running at the top-level working directory
201 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
202 unless (-d $ENV{GIT_DIR}) {
203 if ($git_dir_user_set) {
204 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
205 "but it is not a directory\n";
206 }
207 my $git_dir = delete $ENV{GIT_DIR};
208 chomp(my $cdup = command_oneline(qw/rev-parse --show-cdup/));
209 unless (length $cdup) {
210 die "Already at toplevel, but $git_dir ",
211 "not found '$cdup'\n";
212 }
213 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
214 unless (-d $git_dir) {
215 die "$git_dir still not found after going to ",
216 "'$cdup'\n";
217 }
218 $ENV{GIT_DIR} = $git_dir;
219 }
220 }
222 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
224 read_repo_config(\%opts);
225 Getopt::Long::Configure('pass_through') if ($cmd && $cmd eq 'log');
226 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
227 'minimize-connections' => \$Git::SVN::Migration::_minimize,
228 'id|i=s' => \$Git::SVN::default_ref_id,
229 'svn-remote|remote|R=s' => sub {
230 $Git::SVN::no_reuse_existing = 1;
231 $Git::SVN::default_repo_id = $_[1] });
232 exit 1 if (!$rv && $cmd && $cmd ne 'log');
234 usage(0) if $_help;
235 version() if $_version;
236 usage(1) unless defined $cmd;
237 load_authors() if $_authors;
239 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
240 Git::SVN::Migration::migration_check();
241 }
242 Git::SVN::init_vars();
243 eval {
244 Git::SVN::verify_remotes_sanity();
245 $cmd{$cmd}->[0]->(@ARGV);
246 };
247 fatal $@ if $@;
248 post_fetch_checkout();
249 exit 0;
251 ####################### primary functions ######################
252 sub usage {
253 my $exit = shift || 0;
254 my $fd = $exit ? \*STDERR : \*STDOUT;
255 print $fd <<"";
256 git-svn - bidirectional operations between a single Subversion tree and git
257 Usage: $0 <command> [options] [arguments]\n
259 print $fd "Available commands:\n" unless $cmd;
261 foreach (sort keys %cmd) {
262 next if $cmd && $cmd ne $_;
263 next if /^multi-/; # don't show deprecated commands
264 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
265 foreach (sort keys %{$cmd{$_}->[2]}) {
266 # mixed-case options are for .git/config only
267 next if /[A-Z]/ && /^[a-z]+$/i;
268 # prints out arguments as they should be passed:
269 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
270 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
271 "--$_" : "-$_" }
272 split /\|/,$_)," $x\n";
273 }
274 }
275 print $fd <<"";
276 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
277 arbitrary identifier if you're tracking multiple SVN branches/repositories in
278 one git repository and want to keep them separate. See git-svn(1) for more
279 information.
281 exit $exit;
282 }
284 sub version {
285 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
286 exit 0;
287 }
289 sub do_git_init_db {
290 unless (-d $ENV{GIT_DIR}) {
291 my @init_db = ('init');
292 push @init_db, "--template=$_template" if defined $_template;
293 if (defined $_shared) {
294 if ($_shared =~ /[a-z]/) {
295 push @init_db, "--shared=$_shared";
296 } else {
297 push @init_db, "--shared";
298 }
299 }
300 command_noisy(@init_db);
301 }
302 my $set;
303 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
304 foreach my $i (keys %icv) {
305 die "'$set' and '$i' cannot both be set\n" if $set;
306 next unless defined $icv{$i};
307 command_noisy('config', "$pfx.$i", $icv{$i});
308 $set = $i;
309 }
310 }
312 sub init_subdir {
313 my $repo_path = shift or return;
314 mkpath([$repo_path]) unless -d $repo_path;
315 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
316 $ENV{GIT_DIR} = '.git';
317 }
319 sub cmd_clone {
320 my ($url, $path) = @_;
321 if (!defined $path &&
322 (defined $_trunk || defined $_branches || defined $_tags ||
323 defined $_stdlayout) &&
324 $url !~ m#^[a-z\+]+://#) {
325 $path = $url;
326 }
327 $path = basename($url) if !defined $path || !length $path;
328 cmd_init($url, $path);
329 Git::SVN::fetch_all($Git::SVN::default_repo_id);
330 }
332 sub cmd_init {
333 if (defined $_stdlayout) {
334 $_trunk = 'trunk' if (!defined $_trunk);
335 $_tags = 'tags' if (!defined $_tags);
336 $_branches = 'branches' if (!defined $_branches);
337 }
338 if (defined $_trunk || defined $_branches || defined $_tags) {
339 return cmd_multi_init(@_);
340 }
341 my $url = shift or die "SVN repository location required ",
342 "as a command-line argument\n";
343 init_subdir(@_);
344 do_git_init_db();
346 Git::SVN->init($url);
347 }
349 sub cmd_fetch {
350 if (grep /^\d+=./, @_) {
351 die "'<rev>=<commit>' fetch arguments are ",
352 "no longer supported.\n";
353 }
354 my ($remote) = @_;
355 if (@_ > 1) {
356 die "Usage: $0 fetch [--all] [svn-remote]\n";
357 }
358 $remote ||= $Git::SVN::default_repo_id;
359 if ($_fetch_all) {
360 cmd_multi_fetch();
361 } else {
362 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
363 }
364 }
366 sub cmd_set_tree {
367 my (@commits) = @_;
368 if ($_stdin || !@commits) {
369 print "Reading from stdin...\n";
370 @commits = ();
371 while (<STDIN>) {
372 if (/\b($sha1_short)\b/o) {
373 unshift @commits, $1;
374 }
375 }
376 }
377 my @revs;
378 foreach my $c (@commits) {
379 my @tmp = command('rev-parse',$c);
380 if (scalar @tmp == 1) {
381 push @revs, $tmp[0];
382 } elsif (scalar @tmp > 1) {
383 push @revs, reverse(command('rev-list',@tmp));
384 } else {
385 fatal "Failed to rev-parse $c";
386 }
387 }
388 my $gs = Git::SVN->new;
389 my ($r_last, $cmt_last) = $gs->last_rev_commit;
390 $gs->fetch;
391 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
392 fatal "There are new revisions that were fetched ",
393 "and need to be merged (or acknowledged) ",
394 "before committing.\nlast rev: $r_last\n",
395 " current: $gs->{last_rev}";
396 }
397 $gs->set_tree($_) foreach @revs;
398 print "Done committing ",scalar @revs," revisions to SVN\n";
399 unlink $gs->{index};
400 }
402 sub cmd_dcommit {
403 my $head = shift;
404 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
405 'Cannot dcommit with a dirty index. Commit your changes first, '
406 . "or stash them with `git stash'.\n";
407 $head ||= 'HEAD';
408 my @refs;
409 my ($url, $rev, $uuid, $gs) = working_head_info($head, \@refs);
410 print "Committing to $url ...\n";
411 unless ($gs) {
412 die "Unable to determine upstream SVN information from ",
413 "$head history\n";
414 }
415 my $last_rev;
416 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
417 if ($_no_rebase && scalar(@$linear_refs) > 1) {
418 warn "Attempting to commit more than one change while ",
419 "--no-rebase is enabled.\n",
420 "If these changes depend on each other, re-running ",
421 "without --no-rebase may be required."
422 }
423 while (1) {
424 my $d = shift @$linear_refs or last;
425 unless (defined $last_rev) {
426 (undef, $last_rev, undef) = cmt_metadata("$d~1");
427 unless (defined $last_rev) {
428 fatal "Unable to extract revision information ",
429 "from commit $d~1";
430 }
431 }
432 if ($_dry_run) {
433 print "diff-tree $d~1 $d\n";
434 } else {
435 my $cmt_rev;
436 my %ed_opts = ( r => $last_rev,
437 log => get_commit_entry($d)->{log},
438 ra => Git::SVN::Ra->new($gs->full_url),
439 config => SVN::Core::config_get_config(
440 $Git::SVN::Ra::config_dir
441 ),
442 tree_a => "$d~1",
443 tree_b => $d,
444 editor_cb => sub {
445 print "Committed r$_[0]\n";
446 $cmt_rev = $_[0];
447 },
448 svn_path => '');
449 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
450 print "No changes\n$d~1 == $d\n";
451 } elsif ($parents->{$d} && @{$parents->{$d}}) {
452 $gs->{inject_parents_dcommit}->{$cmt_rev} =
453 $parents->{$d};
454 }
455 $_fetch_all ? $gs->fetch_all : $gs->fetch;
456 $last_rev = $cmt_rev;
457 next if $_no_rebase;
459 # we always want to rebase against the current HEAD,
460 # not any head that was passed to us
461 my @diff = command('diff-tree', $d,
462 $gs->refname, '--');
463 my @finish;
464 if (@diff) {
465 @finish = rebase_cmd();
466 print STDERR "W: $d and ", $gs->refname,
467 " differ, using @finish:\n",
468 join("\n", @diff), "\n";
469 } else {
470 print "No changes between current HEAD and ",
471 $gs->refname,
472 "\nResetting to the latest ",
473 $gs->refname, "\n";
474 @finish = qw/reset --mixed/;
475 }
476 command_noisy(@finish, $gs->refname);
477 if (@diff) {
478 @refs = ();
479 my ($url_, $rev_, $uuid_, $gs_) =
480 working_head_info($head, \@refs);
481 my ($linear_refs_, $parents_) =
482 linearize_history($gs_, \@refs);
483 if (scalar(@$linear_refs) !=
484 scalar(@$linear_refs_)) {
485 fatal "# of revisions changed ",
486 "\nbefore:\n",
487 join("\n", @$linear_refs),
488 "\n\nafter:\n",
489 join("\n", @$linear_refs_), "\n",
490 'If you are attempting to commit ',
491 "merges, try running:\n\t",
492 'git rebase --interactive',
493 '--preserve-merges ',
494 $gs->refname,
495 "\nBefore dcommitting";
496 }
497 if ($url_ ne $url) {
498 fatal "URL mismatch after rebase: ",
499 "$url_ != $url";
500 }
501 if ($uuid_ ne $uuid) {
502 fatal "uuid mismatch after rebase: ",
503 "$uuid_ != $uuid";
504 }
505 # remap parents
506 my (%p, @l, $i);
507 for ($i = 0; $i < scalar @$linear_refs; $i++) {
508 my $new = $linear_refs_->[$i] or next;
509 $p{$new} =
510 $parents->{$linear_refs->[$i]};
511 push @l, $new;
512 }
513 $parents = \%p;
514 $linear_refs = \@l;
515 }
516 }
517 }
518 unlink $gs->{index};
519 }
521 sub cmd_find_rev {
522 my $revision_or_hash = shift;
523 my $result;
524 if ($revision_or_hash =~ /^r\d+$/) {
525 my $head = shift;
526 $head ||= 'HEAD';
527 my @refs;
528 my (undef, undef, undef, $gs) = working_head_info($head, \@refs);
529 unless ($gs) {
530 die "Unable to determine upstream SVN information from ",
531 "$head history\n";
532 }
533 my $desired_revision = substr($revision_or_hash, 1);
534 $result = $gs->rev_map_get($desired_revision);
535 } else {
536 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
537 $result = $rev;
538 }
539 print "$result\n" if $result;
540 }
542 sub cmd_rebase {
543 command_noisy(qw/update-index --refresh/);
544 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
545 unless ($gs) {
546 die "Unable to determine upstream SVN information from ",
547 "working tree history\n";
548 }
549 if (command(qw/diff-index HEAD --/)) {
550 print STDERR "Cannot rebase with uncommited changes:\n";
551 command_noisy('status');
552 exit 1;
553 }
554 unless ($_local) {
555 # rebase will checkout for us, so no need to do it explicitly
556 $_no_checkout = 'true';
557 $_fetch_all ? $gs->fetch_all : $gs->fetch;
558 }
559 command_noisy(rebase_cmd(), $gs->refname);
560 }
562 sub cmd_show_ignore {
563 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
564 $gs ||= Git::SVN->new;
565 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
566 $gs->prop_walk($gs->{path}, $r, sub {
567 my ($gs, $path, $props) = @_;
568 print STDOUT "\n# $path\n";
569 my $s = $props->{'svn:ignore'} or return;
570 $s =~ s/[\r\n]+/\n/g;
571 chomp $s;
572 $s =~ s#^#$path#gm;
573 print STDOUT "$s\n";
574 });
575 }
577 sub cmd_show_externals {
578 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
579 $gs ||= Git::SVN->new;
580 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
581 $gs->prop_walk($gs->{path}, $r, sub {
582 my ($gs, $path, $props) = @_;
583 print STDOUT "\n# $path\n";
584 my $s = $props->{'svn:externals'} or return;
585 $s =~ s/[\r\n]+/\n/g;
586 chomp $s;
587 $s =~ s#^#$path#gm;
588 print STDOUT "$s\n";
589 });
590 }
592 sub cmd_create_ignore {
593 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
594 $gs ||= Git::SVN->new;
595 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
596 $gs->prop_walk($gs->{path}, $r, sub {
597 my ($gs, $path, $props) = @_;
598 # $path is of the form /path/to/dir/
599 my $ignore = '.' . $path . '.gitignore';
600 my $s = $props->{'svn:ignore'} or return;
601 open(GITIGNORE, '>', $ignore)
602 or fatal("Failed to open `$ignore' for writing: $!");
603 $s =~ s/[\r\n]+/\n/g;
604 chomp $s;
605 # Prefix all patterns so that the ignore doesn't apply
606 # to sub-directories.
607 $s =~ s#^#/#gm;
608 print GITIGNORE "$s\n";
609 close(GITIGNORE)
610 or fatal("Failed to close `$ignore': $!");
611 command_noisy('add', $ignore);
612 });
613 }
615 sub canonicalize_path {
616 my ($path) = @_;
617 my $dot_slash_added = 0;
618 if (substr($path, 0, 1) ne "/") {
619 $path = "./" . $path;
620 $dot_slash_added = 1;
621 }
622 # File::Spec->canonpath doesn't collapse x/../y into y (for a
623 # good reason), so let's do this manually.
624 $path =~ s#/+#/#g;
625 $path =~ s#/\.(?:/|$)#/#g;
626 $path =~ s#/[^/]+/\.\.##g;
627 $path =~ s#/$##g;
628 $path =~ s#^\./## if $dot_slash_added;
629 return $path;
630 }
632 # get_svnprops(PATH)
633 # ------------------
634 # Helper for cmd_propget and cmd_proplist below.
635 sub get_svnprops {
636 my $path = shift;
637 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
638 $gs ||= Git::SVN->new;
640 # prefix THE PATH by the sub-directory from which the user
641 # invoked us.
642 $path = $cmd_dir_prefix . $path;
643 fatal("No such file or directory: $path") unless -e $path;
644 my $is_dir = -d $path ? 1 : 0;
645 $path = $gs->{path} . '/' . $path;
647 # canonicalize the path (otherwise libsvn will abort or fail to
648 # find the file)
649 $path = canonicalize_path($path);
651 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
652 my $props;
653 if ($is_dir) {
654 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
655 }
656 else {
657 (undef, $props) = $gs->ra->get_file($path, $r, undef);
658 }
659 return $props;
660 }
662 # cmd_propget (PROP, PATH)
663 # ------------------------
664 # Print the SVN property PROP for PATH.
665 sub cmd_propget {
666 my ($prop, $path) = @_;
667 $path = '.' if not defined $path;
668 usage(1) if not defined $prop;
669 my $props = get_svnprops($path);
670 if (not defined $props->{$prop}) {
671 fatal("`$path' does not have a `$prop' SVN property.");
672 }
673 print $props->{$prop} . "\n";
674 }
676 # cmd_proplist (PATH)
677 # -------------------
678 # Print the list of SVN properties for PATH.
679 sub cmd_proplist {
680 my $path = shift;
681 $path = '.' if not defined $path;
682 my $props = get_svnprops($path);
683 print "Properties on '$path':\n";
684 foreach (sort keys %{$props}) {
685 print " $_\n";
686 }
687 }
689 sub cmd_multi_init {
690 my $url = shift;
691 unless (defined $_trunk || defined $_branches || defined $_tags) {
692 usage(1);
693 }
695 # there are currently some bugs that prevent multi-init/multi-fetch
696 # setups from working well without this.
697 $Git::SVN::_minimize_url = 1;
699 $_prefix = '' unless defined $_prefix;
700 if (defined $url) {
701 $url =~ s#/+$##;
702 init_subdir(@_);
703 }
704 do_git_init_db();
705 if (defined $_trunk) {
706 my $trunk_ref = $_prefix . 'trunk';
707 # try both old-style and new-style lookups:
708 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
709 unless ($gs_trunk) {
710 my ($trunk_url, $trunk_path) =
711 complete_svn_url($url, $_trunk);
712 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
713 undef, $trunk_ref);
714 }
715 }
716 return unless defined $_branches || defined $_tags;
717 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
718 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
719 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
720 }
722 sub cmd_multi_fetch {
723 my $remotes = Git::SVN::read_all_remotes();
724 foreach my $repo_id (sort keys %$remotes) {
725 if ($remotes->{$repo_id}->{url}) {
726 Git::SVN::fetch_all($repo_id, $remotes);
727 }
728 }
729 }
731 # this command is special because it requires no metadata
732 sub cmd_commit_diff {
733 my ($ta, $tb, $url) = @_;
734 my $usage = "Usage: $0 commit-diff -r<revision> ".
735 "<tree-ish> <tree-ish> [<URL>]";
736 fatal($usage) if (!defined $ta || !defined $tb);
737 my $svn_path;
738 if (!defined $url) {
739 my $gs = eval { Git::SVN->new };
740 if (!$gs) {
741 fatal("Needed URL or usable git-svn --id in ",
742 "the command-line\n", $usage);
743 }
744 $url = $gs->{url};
745 $svn_path = $gs->{path};
746 }
747 unless (defined $_revision) {
748 fatal("-r|--revision is a required argument\n", $usage);
749 }
750 if (defined $_message && defined $_file) {
751 fatal("Both --message/-m and --file/-F specified ",
752 "for the commit message.\n",
753 "I have no idea what you mean");
754 }
755 if (defined $_file) {
756 $_message = file_to_s($_file);
757 } else {
758 $_message ||= get_commit_entry($tb)->{log};
759 }
760 my $ra ||= Git::SVN::Ra->new($url);
761 $svn_path ||= $ra->{svn_path};
762 my $r = $_revision;
763 if ($r eq 'HEAD') {
764 $r = $ra->get_latest_revnum;
765 } elsif ($r !~ /^\d+$/) {
766 die "revision argument: $r not understood by git-svn\n";
767 }
768 my %ed_opts = ( r => $r,
769 log => $_message,
770 ra => $ra,
771 tree_a => $ta,
772 tree_b => $tb,
773 editor_cb => sub { print "Committed r$_[0]\n" },
774 svn_path => $svn_path );
775 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
776 print "No changes\n$ta == $tb\n";
777 }
778 }
780 sub cmd_info {
781 my $path = canonicalize_path(shift or ".");
782 unless (scalar(@_) == 0) {
783 die "Too many arguments specified\n";
784 }
786 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
788 if (!$file_type && !$diff_status) {
789 print STDERR "$path: (Not a versioned resource)\n\n";
790 return;
791 }
793 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
794 unless ($gs) {
795 die "Unable to determine upstream SVN information from ",
796 "working tree history\n";
797 }
798 my $full_url = $url . ($path eq "." ? "" : "/$path");
800 if ($_url) {
801 print $full_url, "\n";
802 return;
803 }
805 my $result = "Path: $path\n";
806 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
807 $result .= "URL: " . $full_url . "\n";
809 eval {
810 my $repos_root = $gs->repos_root;
811 Git::SVN::remove_username($repos_root);
812 $result .= "Repository Root: $repos_root\n";
813 };
814 if ($@) {
815 $result .= "Repository Root: (offline)\n";
816 }
817 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A";
818 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
820 $result .= "Node Kind: " .
821 ($file_type eq "dir" ? "directory" : "file") . "\n";
823 my $schedule = $diff_status eq "A"
824 ? "add"
825 : ($diff_status eq "D" ? "delete" : "normal");
826 $result .= "Schedule: $schedule\n";
828 if ($diff_status eq "A") {
829 print $result, "\n";
830 return;
831 }
833 my ($lc_author, $lc_rev, $lc_date_utc);
834 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $path);
835 my $log = command_output_pipe(@args);
836 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
837 while (<$log>) {
838 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
839 $lc_author = $1;
840 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
841 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
842 (undef, $lc_rev, undef) = ::extract_metadata($1);
843 }
844 }
845 close $log;
847 Git::SVN::Log::set_local_timezone();
849 $result .= "Last Changed Author: $lc_author\n";
850 $result .= "Last Changed Rev: $lc_rev\n";
851 $result .= "Last Changed Date: " .
852 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
854 if ($file_type ne "dir") {
855 my $text_last_updated_date =
856 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
857 $result .=
858 "Text Last Updated: " .
859 Git::SVN::Log::format_svn_date($text_last_updated_date) .
860 "\n";
861 my $checksum;
862 if ($diff_status eq "D") {
863 my ($fh, $ctx) =
864 command_output_pipe(qw(cat-file blob), "HEAD:$path");
865 if ($file_type eq "link") {
866 my $file_name = <$fh>;
867 $checksum = md5sum("link $file_name");
868 } else {
869 $checksum = md5sum($fh);
870 }
871 command_close_pipe($fh, $ctx);
872 } elsif ($file_type eq "link") {
873 my $file_name =
874 command(qw(cat-file blob), "HEAD:$path");
875 $checksum =
876 md5sum("link " . $file_name);
877 } else {
878 open FILE, "<", $path or die $!;
879 $checksum = md5sum(\*FILE);
880 close FILE or die $!;
881 }
882 $result .= "Checksum: " . $checksum . "\n";
883 }
885 print $result, "\n";
886 }
888 ########################### utility functions #########################
890 sub rebase_cmd {
891 my @cmd = qw/rebase/;
892 push @cmd, '-v' if $_verbose;
893 push @cmd, qw/--merge/ if $_merge;
894 push @cmd, "--strategy=$_strategy" if $_strategy;
895 @cmd;
896 }
898 sub post_fetch_checkout {
899 return if $_no_checkout;
900 my $gs = $Git::SVN::_head or return;
901 return if verify_ref('refs/heads/master^0');
903 my $valid_head = verify_ref('HEAD^0');
904 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
905 return if ($valid_head || !verify_ref('HEAD^0'));
907 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
908 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
909 return if -f $index;
911 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
912 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
913 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
914 print STDERR "Checked out HEAD:\n ",
915 $gs->full_url, " r", $gs->last_rev, "\n";
916 }
918 sub complete_svn_url {
919 my ($url, $path) = @_;
920 $path =~ s#/+$##;
921 if ($path !~ m#^[a-z\+]+://#) {
922 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
923 fatal("E: '$path' is not a complete URL ",
924 "and a separate URL is not specified");
925 }
926 return ($url, $path);
927 }
928 return ($path, '');
929 }
931 sub complete_url_ls_init {
932 my ($ra, $repo_path, $switch, $pfx) = @_;
933 unless ($repo_path) {
934 print STDERR "W: $switch not specified\n";
935 return;
936 }
937 $repo_path =~ s#/+$##;
938 if ($repo_path =~ m#^[a-z\+]+://#) {
939 $ra = Git::SVN::Ra->new($repo_path);
940 $repo_path = '';
941 } else {
942 $repo_path =~ s#^/+##;
943 unless ($ra) {
944 fatal("E: '$repo_path' is not a complete URL ",
945 "and a separate URL is not specified");
946 }
947 }
948 my $url = $ra->{url};
949 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
950 my $k = "svn-remote.$gs->{repo_id}.url";
951 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
952 if ($orig_url && ($orig_url ne $gs->{url})) {
953 die "$k already set: $orig_url\n",
954 "wanted to set to: $gs->{url}\n";
955 }
956 command_oneline('config', $k, $gs->{url}) unless $orig_url;
957 my $remote_path = "$ra->{svn_path}/$repo_path/*";
958 $remote_path =~ s#/+#/#g;
959 $remote_path =~ s#^/##g;
960 my ($n) = ($switch =~ /^--(\w+)/);
961 if (length $pfx && $pfx !~ m#/$#) {
962 die "--prefix='$pfx' must have a trailing slash '/'\n";
963 }
964 command_noisy('config', "svn-remote.$gs->{repo_id}.$n",
965 "$remote_path:refs/remotes/$pfx*");
966 }
968 sub verify_ref {
969 my ($ref) = @_;
970 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
971 { STDERR => 0 }); };
972 }
974 sub get_tree_from_treeish {
975 my ($treeish) = @_;
976 # $treeish can be a symbolic ref, too:
977 my $type = command_oneline(qw/cat-file -t/, $treeish);
978 my $expected;
979 while ($type eq 'tag') {
980 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
981 }
982 if ($type eq 'commit') {
983 $expected = (grep /^tree /, command(qw/cat-file commit/,
984 $treeish))[0];
985 ($expected) = ($expected =~ /^tree ($sha1)$/o);
986 die "Unable to get tree from $treeish\n" unless $expected;
987 } elsif ($type eq 'tree') {
988 $expected = $treeish;
989 } else {
990 die "$treeish is a $type, expected tree, tag or commit\n";
991 }
992 return $expected;
993 }
995 sub get_commit_entry {
996 my ($treeish) = shift;
997 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
998 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
999 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1000 open my $log_fh, '>', $commit_editmsg or croak $!;
1002 my $type = command_oneline(qw/cat-file -t/, $treeish);
1003 if ($type eq 'commit' || $type eq 'tag') {
1004 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1005 $type, $treeish);
1006 my $in_msg = 0;
1007 while (<$msg_fh>) {
1008 if (!$in_msg) {
1009 $in_msg = 1 if (/^\s*$/);
1010 } elsif (/^git-svn-id: /) {
1011 # skip this for now, we regenerate the
1012 # correct one on re-fetch anyways
1013 # TODO: set *:merge properties or like...
1014 } else {
1015 print $log_fh $_ or croak $!;
1016 }
1017 }
1018 command_close_pipe($msg_fh, $ctx);
1019 }
1020 close $log_fh or croak $!;
1022 if ($_edit || ($type eq 'tree')) {
1023 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1024 # TODO: strip out spaces, comments, like git-commit.sh
1025 system($editor, $commit_editmsg);
1026 }
1027 rename $commit_editmsg, $commit_msg or croak $!;
1028 open $log_fh, '<', $commit_msg or croak $!;
1029 { local $/; chomp($log_entry{log} = <$log_fh>); }
1030 close $log_fh or croak $!;
1031 unlink $commit_msg;
1032 \%log_entry;
1033 }
1035 sub s_to_file {
1036 my ($str, $file, $mode) = @_;
1037 open my $fd,'>',$file or croak $!;
1038 print $fd $str,"\n" or croak $!;
1039 close $fd or croak $!;
1040 chmod ($mode &~ umask, $file) if (defined $mode);
1041 }
1043 sub file_to_s {
1044 my $file = shift;
1045 open my $fd,'<',$file or croak "$!: file: $file\n";
1046 local $/;
1047 my $ret = <$fd>;
1048 close $fd or croak $!;
1049 $ret =~ s/\s*$//s;
1050 return $ret;
1051 }
1053 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1054 sub load_authors {
1055 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1056 my $log = $cmd eq 'log';
1057 while (<$authors>) {
1058 chomp;
1059 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1060 my ($user, $name, $email) = ($1, $2, $3);
1061 if ($log) {
1062 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1063 } else {
1064 $users{$user} = [$name, $email];
1065 }
1066 }
1067 close $authors or croak $!;
1068 }
1070 # convert GetOpt::Long specs for use by git-config
1071 sub read_repo_config {
1072 return unless -d $ENV{GIT_DIR};
1073 my $opts = shift;
1074 my @config_only;
1075 foreach my $o (keys %$opts) {
1076 # if we have mixedCase and a long option-only, then
1077 # it's a config-only variable that we don't need for
1078 # the command-line.
1079 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1080 my $v = $opts->{$o};
1081 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1082 $key =~ s/-//g;
1083 my $arg = 'git-config';
1084 $arg .= ' --int' if ($o =~ /[:=]i$/);
1085 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1086 if (ref $v eq 'ARRAY') {
1087 chomp(my @tmp = `$arg --get-all svn.$key`);
1088 @$v = @tmp if @tmp;
1089 } else {
1090 chomp(my $tmp = `$arg --get svn.$key`);
1091 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1092 $$v = $tmp;
1093 }
1094 }
1095 }
1096 delete @$opts{@config_only} if @config_only;
1097 }
1099 sub extract_metadata {
1100 my $id = shift or return (undef, undef, undef);
1101 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1102 \s([a-f\d\-]+)$/x);
1103 if (!defined $rev || !$uuid || !$url) {
1104 # some of the original repositories I made had
1105 # identifiers like this:
1106 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
1107 }
1108 return ($url, $rev, $uuid);
1109 }
1111 sub cmt_metadata {
1112 return extract_metadata((grep(/^git-svn-id: /,
1113 command(qw/cat-file commit/, shift)))[-1]);
1114 }
1116 sub working_head_info {
1117 my ($head, $refs) = @_;
1118 my @args = ('log', '--no-color', '--first-parent');
1119 my ($fh, $ctx) = command_output_pipe(@args, $head);
1120 my $hash;
1121 my %max;
1122 while (<$fh>) {
1123 if ( m{^commit ($::sha1)$} ) {
1124 unshift @$refs, $hash if $hash and $refs;
1125 $hash = $1;
1126 next;
1127 }
1128 next unless s{^\s*(git-svn-id:)}{$1};
1129 my ($url, $rev, $uuid) = extract_metadata($_);
1130 if (defined $url && defined $rev) {
1131 next if $max{$url} and $max{$url} < $rev;
1132 if (my $gs = Git::SVN->find_by_url($url)) {
1133 my $c = $gs->rev_map_get($rev);
1134 if ($c && $c eq $hash) {
1135 close $fh; # break the pipe
1136 return ($url, $rev, $uuid, $gs);
1137 } else {
1138 $max{$url} ||= $gs->rev_map_max;
1139 }
1140 }
1141 }
1142 }
1143 command_close_pipe($fh, $ctx);
1144 (undef, undef, undef, undef);
1145 }
1147 sub read_commit_parents {
1148 my ($parents, $c) = @_;
1149 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1150 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1151 @{$parents->{$c}} = split(/ /, $p);
1152 }
1154 sub linearize_history {
1155 my ($gs, $refs) = @_;
1156 my %parents;
1157 foreach my $c (@$refs) {
1158 read_commit_parents(\%parents, $c);
1159 }
1161 my @linear_refs;
1162 my %skip = ();
1163 my $last_svn_commit = $gs->last_commit;
1164 foreach my $c (reverse @$refs) {
1165 next if $c eq $last_svn_commit;
1166 last if $skip{$c};
1168 unshift @linear_refs, $c;
1169 $skip{$c} = 1;
1171 # we only want the first parent to diff against for linear
1172 # history, we save the rest to inject when we finalize the
1173 # svn commit
1174 my $fp_a = verify_ref("$c~1");
1175 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1176 if (!$fp_a || !$fp_b) {
1177 die "Commit $c\n",
1178 "has no parent commit, and therefore ",
1179 "nothing to diff against.\n",
1180 "You should be working from a repository ",
1181 "originally created by git-svn\n";
1182 }
1183 if ($fp_a ne $fp_b) {
1184 die "$c~1 = $fp_a, however parsing commit $c ",
1185 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1186 }
1188 foreach my $p (@{$parents{$c}}) {
1189 $skip{$p} = 1;
1190 }
1191 }
1192 (\@linear_refs, \%parents);
1193 }
1195 sub find_file_type_and_diff_status {
1196 my ($path) = @_;
1197 return ('dir', '') if $path eq '.';
1199 my $diff_output =
1200 command_oneline(qw(diff --cached --name-status --), $path) || "";
1201 my $diff_status = (split(' ', $diff_output))[0] || "";
1203 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1205 return (undef, undef) if !$diff_status && !$ls_tree;
1207 if ($diff_status eq "A") {
1208 return ("link", $diff_status) if -l $path;
1209 return ("dir", $diff_status) if -d $path;
1210 return ("file", $diff_status);
1211 }
1213 my $mode = (split(' ', $ls_tree))[0] || "";
1215 return ("link", $diff_status) if $mode eq "120000";
1216 return ("dir", $diff_status) if $mode eq "040000";
1217 return ("file", $diff_status);
1218 }
1220 sub md5sum {
1221 my $arg = shift;
1222 my $ref = ref $arg;
1223 my $md5 = Digest::MD5->new();
1224 if ($ref eq 'GLOB' || $ref eq 'IO::File') {
1225 $md5->addfile($arg) or croak $!;
1226 } elsif ($ref eq 'SCALAR') {
1227 $md5->add($$arg) or croak $!;
1228 } elsif (!$ref) {
1229 $md5->add($arg) or croak $!;
1230 } else {
1231 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1232 }
1233 return $md5->hexdigest();
1234 }
1236 package Git::SVN;
1237 use strict;
1238 use warnings;
1239 use Fcntl qw/:DEFAULT :seek/;
1240 use constant rev_map_fmt => 'NH40';
1241 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1242 $_repack $_repack_flags $_use_svm_props $_head
1243 $_use_svnsync_props $no_reuse_existing $_minimize_url
1244 $_use_log_author/;
1245 use Carp qw/croak/;
1246 use File::Path qw/mkpath/;
1247 use File::Copy qw/copy/;
1248 use IPC::Open3;
1250 my $_repack_nr;
1251 # properties that we do not log:
1252 my %SKIP_PROP;
1253 BEGIN {
1254 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1255 svn:special svn:executable
1256 svn:entry:committed-rev
1257 svn:entry:last-author
1258 svn:entry:uuid
1259 svn:entry:committed-date/;
1261 # some options are read globally, but can be overridden locally
1262 # per [svn-remote "..."] section. Command-line options will *NOT*
1263 # override options set in an [svn-remote "..."] section
1264 no strict 'refs';
1265 for my $option (qw/follow_parent no_metadata use_svm_props
1266 use_svnsync_props/) {
1267 my $key = $option;
1268 $key =~ tr/_//d;
1269 my $prop = "-$option";
1270 *$option = sub {
1271 my ($self) = @_;
1272 return $self->{$prop} if exists $self->{$prop};
1273 my $k = "svn-remote.$self->{repo_id}.$key";
1274 eval { command_oneline(qw/config --get/, $k) };
1275 if ($@) {
1276 $self->{$prop} = ${"Git::SVN::_$option"};
1277 } else {
1278 my $v = command_oneline(qw/config --bool/,$k);
1279 $self->{$prop} = $v eq 'false' ? 0 : 1;
1280 }
1281 return $self->{$prop};
1282 }
1283 }
1284 }
1286 my (%LOCKFILES, %INDEX_FILES);
1287 END {
1288 unlink keys %LOCKFILES if %LOCKFILES;
1289 unlink keys %INDEX_FILES if %INDEX_FILES;
1290 }
1292 sub resolve_local_globs {
1293 my ($url, $fetch, $glob_spec) = @_;
1294 return unless defined $glob_spec;
1295 my $ref = $glob_spec->{ref};
1296 my $path = $glob_spec->{path};
1297 foreach (command(qw#for-each-ref --format=%(refname) refs/remotes#)) {
1298 next unless m#^refs/remotes/$ref->{regex}$#;
1299 my $p = $1;
1300 my $pathname = desanitize_refname($path->full_path($p));
1301 my $refname = desanitize_refname($ref->full_path($p));
1302 if (my $existing = $fetch->{$pathname}) {
1303 if ($existing ne $refname) {
1304 die "Refspec conflict:\n",
1305 "existing: refs/remotes/$existing\n",
1306 " globbed: refs/remotes/$refname\n";
1307 }
1308 my $u = (::cmt_metadata("refs/remotes/$refname"))[0];
1309 $u =~ s!^\Q$url\E(/|$)!! or die
1310 "refs/remotes/$refname: '$url' not found in '$u'\n";
1311 if ($pathname ne $u) {
1312 warn "W: Refspec glob conflict ",
1313 "(ref: refs/remotes/$refname):\n",
1314 "expected path: $pathname\n",
1315 " real path: $u\n",
1316 "Continuing ahead with $u\n";
1317 next;
1318 }
1319 } else {
1320 $fetch->{$pathname} = $refname;
1321 }
1322 }
1323 }
1325 sub parse_revision_argument {
1326 my ($base, $head) = @_;
1327 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1328 return ($base, $head);
1329 }
1330 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1331 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1332 return ($head, $head) if ($::_revision eq 'HEAD');
1333 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1334 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1335 die "revision argument: $::_revision not understood by git-svn\n";
1336 }
1338 sub fetch_all {
1339 my ($repo_id, $remotes) = @_;
1340 if (ref $repo_id) {
1341 my $gs = $repo_id;
1342 $repo_id = undef;
1343 $repo_id = $gs->{repo_id};
1344 }
1345 $remotes ||= read_all_remotes();
1346 my $remote = $remotes->{$repo_id} or
1347 die "[svn-remote \"$repo_id\"] unknown\n";
1348 my $fetch = $remote->{fetch};
1349 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1350 my (@gs, @globs);
1351 my $ra = Git::SVN::Ra->new($url);
1352 my $uuid = $ra->get_uuid;
1353 my $head = $ra->get_latest_revnum;
1354 my $base = defined $fetch ? $head : 0;
1356 # read the max revs for wildcard expansion (branches/*, tags/*)
1357 foreach my $t (qw/branches tags/) {
1358 defined $remote->{$t} or next;
1359 push @globs, $remote->{$t};
1360 my $max_rev = eval { tmp_config(qw/--int --get/,
1361 "svn-remote.$repo_id.${t}-maxRev") };
1362 if (defined $max_rev && ($max_rev < $base)) {
1363 $base = $max_rev;
1364 } elsif (!defined $max_rev) {
1365 $base = 0;
1366 }
1367 }
1369 if ($fetch) {
1370 foreach my $p (sort keys %$fetch) {
1371 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1372 my $lr = $gs->rev_map_max;
1373 if (defined $lr) {
1374 $base = $lr if ($lr < $base);
1375 }
1376 push @gs, $gs;
1377 }
1378 }
1380 ($base, $head) = parse_revision_argument($base, $head);
1381 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1382 }
1384 sub read_all_remotes {
1385 my $r = {};
1386 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1387 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
1388 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1389 $local_ref =~ s{^/}{};
1390 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1391 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1392 $r->{$1}->{url} = $2;
1393 } elsif (m!^(.+)\.(branches|tags)=
1394 (.*):refs/remotes/(.+)\s*$/!x) {
1395 my ($p, $g) = ($3, $4);
1396 my $rs = $r->{$1}->{$2} = {
1397 t => $2,
1398 remote => $1,
1399 path => Git::SVN::GlobSpec->new($p),
1400 ref => Git::SVN::GlobSpec->new($g) };
1401 if (length($rs->{ref}->{right}) != 0) {
1402 die "The '*' glob character must be the last ",
1403 "character of '$g'\n";
1404 }
1405 }
1406 }
1407 $r;
1408 }
1410 sub init_vars {
1411 if (defined $_repack) {
1412 $_repack = 1000 if ($_repack <= 0);
1413 $_repack_nr = $_repack;
1414 $_repack_flags ||= '-d';
1415 }
1416 }
1418 sub verify_remotes_sanity {
1419 return unless -d $ENV{GIT_DIR};
1420 my %seen;
1421 foreach (command(qw/config -l/)) {
1422 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1423 if ($seen{$1}) {
1424 die "Remote ref refs/remote/$1 is tracked by",
1425 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1426 "Please resolve this ambiguity in ",
1427 "your git configuration file before ",
1428 "continuing\n";
1429 }
1430 $seen{$1} = $_;
1431 }
1432 }
1433 }
1435 # we allow more chars than remotes2config.sh...
1436 sub sanitize_remote_name {
1437 my ($name) = @_;
1438 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
1439 $name;
1440 }
1442 sub find_existing_remote {
1443 my ($url, $remotes) = @_;
1444 return undef if $no_reuse_existing;
1445 my $existing;
1446 foreach my $repo_id (keys %$remotes) {
1447 my $u = $remotes->{$repo_id}->{url} or next;
1448 next if $u ne $url;
1449 $existing = $repo_id;
1450 last;
1451 }
1452 $existing;
1453 }
1455 sub init_remote_config {
1456 my ($self, $url, $no_write) = @_;
1457 $url =~ s!/+$!!; # strip trailing slash
1458 my $r = read_all_remotes();
1459 my $existing = find_existing_remote($url, $r);
1460 if ($existing) {
1461 unless ($no_write) {
1462 print STDERR "Using existing ",
1463 "[svn-remote \"$existing\"]\n";
1464 }
1465 $self->{repo_id} = $existing;
1466 } elsif ($_minimize_url) {
1467 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1468 $existing = find_existing_remote($min_url, $r);
1469 if ($existing) {
1470 unless ($no_write) {
1471 print STDERR "Using existing ",
1472 "[svn-remote \"$existing\"]\n";
1473 }
1474 $self->{repo_id} = $existing;
1475 }
1476 if ($min_url ne $url) {
1477 unless ($no_write) {
1478 print STDERR "Using higher level of URL: ",
1479 "$url => $min_url\n";
1480 }
1481 my $old_path = $self->{path};
1482 $self->{path} = $url;
1483 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1484 if (length $old_path) {
1485 $self->{path} .= "/$old_path";
1486 }
1487 $url = $min_url;
1488 }
1489 }
1490 my $orig_url;
1491 if (!$existing) {
1492 # verify that we aren't overwriting anything:
1493 $orig_url = eval {
1494 command_oneline('config', '--get',
1495 "svn-remote.$self->{repo_id}.url")
1496 };
1497 if ($orig_url && ($orig_url ne $url)) {
1498 die "svn-remote.$self->{repo_id}.url already set: ",
1499 "$orig_url\nwanted to set to: $url\n";
1500 }
1501 }
1502 my ($xrepo_id, $xpath) = find_ref($self->refname);
1503 if (defined $xpath) {
1504 die "svn-remote.$xrepo_id.fetch already set to track ",
1505 "$xpath:refs/remotes/", $self->refname, "\n";
1506 }
1507 unless ($no_write) {
1508 command_noisy('config',
1509 "svn-remote.$self->{repo_id}.url", $url);
1510 $self->{path} =~ s{^/}{};
1511 command_noisy('config', '--add',
1512 "svn-remote.$self->{repo_id}.fetch",
1513 "$self->{path}:".$self->refname);
1514 }
1515 $self->{url} = $url;
1516 }
1518 sub find_by_url { # repos_root and, path are optional
1519 my ($class, $full_url, $repos_root, $path) = @_;
1521 return undef unless defined $full_url;
1522 remove_username($full_url);
1523 remove_username($repos_root) if defined $repos_root;
1524 my $remotes = read_all_remotes();
1525 if (defined $full_url && defined $repos_root && !defined $path) {
1526 $path = $full_url;
1527 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1528 }
1529 foreach my $repo_id (keys %$remotes) {
1530 my $u = $remotes->{$repo_id}->{url} or next;
1531 remove_username($u);
1532 next if defined $repos_root && $repos_root ne $u;
1534 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1535 foreach (qw/branches tags/) {
1536 resolve_local_globs($u, $fetch,
1537 $remotes->{$repo_id}->{$_});
1538 }
1539 my $p = $path;
1540 unless (defined $p) {
1541 $p = $full_url;
1542 $p =~ s#^\Q$u\E(?:/|$)## or next;
1543 }
1544 foreach my $f (keys %$fetch) {
1545 next if $f ne $p;
1546 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1547 }
1548 }
1549 undef;
1550 }
1552 sub init {
1553 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1554 my $self = _new($class, $repo_id, $ref_id, $path);
1555 if (defined $url) {
1556 $self->init_remote_config($url, $no_write);
1557 }
1558 $self;
1559 }
1561 sub find_ref {
1562 my ($ref_id) = @_;
1563 foreach (command(qw/config -l/)) {
1564 next unless m!^svn-remote\.(.+)\.fetch=
1565 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
1566 my ($repo_id, $path, $ref) = ($1, $2, $3);
1567 if ($ref eq $ref_id) {
1568 $path = '' if ($path =~ m#^\./?#);
1569 return ($repo_id, $path);
1570 }
1571 }
1572 (undef, undef, undef);
1573 }
1575 sub new {
1576 my ($class, $ref_id, $repo_id, $path) = @_;
1577 if (defined $ref_id && !defined $repo_id && !defined $path) {
1578 ($repo_id, $path) = find_ref($ref_id);
1579 if (!defined $repo_id) {
1580 die "Could not find a \"svn-remote.*.fetch\" key ",
1581 "in the repository configuration matching: ",
1582 "refs/remotes/$ref_id\n";
1583 }
1584 }
1585 my $self = _new($class, $repo_id, $ref_id, $path);
1586 if (!defined $self->{path} || !length $self->{path}) {
1587 my $fetch = command_oneline('config', '--get',
1588 "svn-remote.$repo_id.fetch",
1589 ":refs/remotes/$ref_id\$") or
1590 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1591 "\":refs/remotes/$ref_id\$\" in config\n";
1592 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1593 }
1594 $self->{url} = command_oneline('config', '--get',
1595 "svn-remote.$repo_id.url") or
1596 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1597 $self->rebuild;
1598 $self;
1599 }
1601 sub refname {
1602 my ($refname) = "refs/remotes/$_[0]->{ref_id}" ;
1604 # It cannot end with a slash /, we'll throw up on this because
1605 # SVN can't have directories with a slash in their name, either:
1606 if ($refname =~ m{/$}) {
1607 die "ref: '$refname' ends with a trailing slash, this is ",
1608 "not permitted by git nor Subversion\n";
1609 }
1611 # It cannot have ASCII control character space, tilde ~, caret ^,
1612 # colon :, question-mark ?, asterisk *, space, or open bracket [
1613 # anywhere.
1614 #
1615 # Additionally, % must be escaped because it is used for escaping
1616 # and we want our escaped refname to be reversible
1617 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
1619 # no slash-separated component can begin with a dot .
1620 # /.* becomes /%2E*
1621 $refname =~ s{/\.}{/%2E}g;
1623 # It cannot have two consecutive dots .. anywhere
1624 # .. becomes %2E%2E
1625 $refname =~ s{\.\.}{%2E%2E}g;
1627 return $refname;
1628 }
1630 sub desanitize_refname {
1631 my ($refname) = @_;
1632 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
1633 return $refname;
1634 }
1636 sub svm_uuid {
1637 my ($self) = @_;
1638 return $self->{svm}->{uuid} if $self->svm;
1639 $self->ra;
1640 unless ($self->{svm}) {
1641 die "SVM UUID not cached, and reading remotely failed\n";
1642 }
1643 $self->{svm}->{uuid};
1644 }
1646 sub svm {
1647 my ($self) = @_;
1648 return $self->{svm} if $self->{svm};
1649 my $svm;
1650 # see if we have it in our config, first:
1651 eval {
1652 my $section = "svn-remote.$self->{repo_id}";
1653 $svm = {
1654 source => tmp_config('--get', "$section.svm-source"),
1655 uuid => tmp_config('--get', "$section.svm-uuid"),
1656 replace => tmp_config('--get', "$section.svm-replace"),
1657 }
1658 };
1659 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
1660 $self->{svm} = $svm;
1661 }
1662 $self->{svm};
1663 }
1665 sub _set_svm_vars {
1666 my ($self, $ra) = @_;
1667 return $ra if $self->svm;
1669 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
1670 "(svm:source, svm:uuid) ",
1671 "from the following URLs:\n" );
1672 sub read_svm_props {
1673 my ($self, $ra, $path, $r) = @_;
1674 my $props = ($ra->get_dir($path, $r))[2];
1675 my $src = $props->{'svm:source'};
1676 my $uuid = $props->{'svm:uuid'};
1677 return undef if (!$src || !$uuid);
1679 chomp($src, $uuid);
1681 $uuid =~ m{^[0-9a-f\-]{30,}$}
1682 or die "doesn't look right - svm:uuid is '$uuid'\n";
1684 # the '!' is used to mark the repos_root!/relative/path
1685 $src =~ s{/?!/?}{/};
1686 $src =~ s{/+$}{}; # no trailing slashes please
1687 # username is of no interest
1688 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
1690 my $replace = $ra->{url};
1691 $replace .= "/$path" if length $path;
1693 my $section = "svn-remote.$self->{repo_id}";
1694 tmp_config("$section.svm-source", $src);
1695 tmp_config("$section.svm-replace", $replace);
1696 tmp_config("$section.svm-uuid", $uuid);
1697 $self->{svm} = {
1698 source => $src,
1699 uuid => $uuid,
1700 replace => $replace
1701 };
1702 }
1704 my $r = $ra->get_latest_revnum;
1705 my $path = $self->{path};
1706 my %tried;
1707 while (length $path) {
1708 unless ($tried{"$self->{url}/$path"}) {
1709 return $ra if $self->read_svm_props($ra, $path, $r);
1710 $tried{"$self->{url}/$path"} = 1;
1711 }
1712 $path =~ s#/?[^/]+$##;
1713 }
1714 die "Path: '$path' should be ''\n" if $path ne '';
1715 return $ra if $self->read_svm_props($ra, $path, $r);
1716 $tried{"$self->{url}/$path"} = 1;
1718 if ($ra->{repos_root} eq $self->{url}) {
1719 die @err, (map { " $_\n" } keys %tried), "\n";
1720 }
1722 # nope, make sure we're connected to the repository root:
1723 my $ok;
1724 my @tried_b;
1725 $path = $ra->{svn_path};
1726 $ra = Git::SVN::Ra->new($ra->{repos_root});
1727 while (length $path) {
1728 unless ($tried{"$ra->{url}/$path"}) {
1729 $ok = $self->read_svm_props($ra, $path, $r);
1730 last if $ok;
1731 $tried{"$ra->{url}/$path"} = 1;
1732 }
1733 $path =~ s#/?[^/]+$##;
1734 }
1735 die "Path: '$path' should be ''\n" if $path ne '';
1736 $ok ||= $self->read_svm_props($ra, $path, $r);
1737 $tried{"$ra->{url}/$path"} = 1;
1738 if (!$ok) {
1739 die @err, (map { " $_\n" } keys %tried), "\n";
1740 }
1741 Git::SVN::Ra->new($self->{url});
1742 }
1744 sub svnsync {
1745 my ($self) = @_;
1746 return $self->{svnsync} if $self->{svnsync};
1748 if ($self->no_metadata) {
1749 die "Can't have both 'noMetadata' and ",
1750 "'useSvnsyncProps' options set!\n";
1751 }
1752 if ($self->rewrite_root) {
1753 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
1754 "options set!\n";
1755 }
1757 my $svnsync;
1758 # see if we have it in our config, first:
1759 eval {
1760 my $section = "svn-remote.$self->{repo_id}";
1761 $svnsync = {
1762 url => tmp_config('--get', "$section.svnsync-url"),
1763 uuid => tmp_config('--get', "$section.svnsync-uuid"),
1764 }
1765 };
1766 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
1767 return $self->{svnsync} = $svnsync;
1768 }
1770 my $err = "useSvnsyncProps set, but failed to read " .
1771 "svnsync property: svn:sync-from-";
1772 my $rp = $self->ra->rev_proplist(0);
1774 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
1775 $url =~ m{^[a-z\+]+://} or
1776 die "doesn't look right - svn:sync-from-url is '$url'\n";
1778 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
1779 $uuid =~ m{^[0-9a-f\-]{30,}$} or
1780 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
1782 my $section = "svn-remote.$self->{repo_id}";
1783 tmp_config('--add', "$section.svnsync-uuid", $uuid);
1784 tmp_config('--add', "$section.svnsync-url", $url);
1785 return $self->{svnsync} = { url => $url, uuid => $uuid };
1786 }
1788 # this allows us to memoize our SVN::Ra UUID locally and avoid a
1789 # remote lookup (useful for 'git svn log').
1790 sub ra_uuid {
1791 my ($self) = @_;
1792 unless ($self->{ra_uuid}) {
1793 my $key = "svn-remote.$self->{repo_id}.uuid";
1794 my $uuid = eval { tmp_config('--get', $key) };
1795 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/) {
1796 $self->{ra_uuid} = $uuid;
1797 } else {
1798 die "ra_uuid called without URL\n" unless $self->{url};
1799 $self->{ra_uuid} = $self->ra->get_uuid;
1800 tmp_config('--add', $key, $self->{ra_uuid});
1801 }
1802 }
1803 $self->{ra_uuid};
1804 }
1806 sub _set_repos_root {
1807 my ($self, $repos_root) = @_;
1808 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1809 $repos_root ||= $self->ra->{repos_root};
1810 tmp_config($k, $repos_root);
1811 $repos_root;
1812 }
1814 sub repos_root {
1815 my ($self) = @_;
1816 my $k = "svn-remote.$self->{repo_id}.reposRoot";
1817 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
1818 }
1820 sub ra {
1821 my ($self) = shift;
1822 my $ra = Git::SVN::Ra->new($self->{url});
1823 $self->_set_repos_root($ra->{repos_root});
1824 if ($self->use_svm_props && !$self->{svm}) {
1825 if ($self->no_metadata) {
1826 die "Can't have both 'noMetadata' and ",
1827 "'useSvmProps' options set!\n";
1828 } elsif ($self->use_svnsync_props) {
1829 die "Can't have both 'useSvnsyncProps' and ",
1830 "'useSvmProps' options set!\n";
1831 }
1832 $ra = $self->_set_svm_vars($ra);
1833 $self->{-want_revprops} = 1;
1834 }
1835 $ra;
1836 }
1838 sub rel_path {
1839 my ($self) = @_;
1840 my $repos_root = $self->ra->{repos_root};
1841 return $self->{path} if ($self->{url} eq $repos_root);
1842 my $url = $self->{url} .
1843 (length $self->{path} ? "/$self->{path}" : $self->{path});
1844 $url =~ s!^\Q$repos_root\E(?:/+|$)!!g;
1845 $url;
1846 }
1848 # prop_walk(PATH, REV, SUB)
1849 # -------------------------
1850 # Recursively traverse PATH at revision REV and invoke SUB for each
1851 # directory that contains a SVN property. SUB will be invoked as
1852 # follows: &SUB(gs, path, props); where `gs' is this instance of
1853 # Git::SVN, `path' the path to the directory where the properties
1854 # `props' were found. The `path' will be relative to point of checkout,
1855 # that is, if url://repo/trunk is the current Git branch, and that
1856 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
1857 # as `path' (note the trailing `/').
1858 sub prop_walk {
1859 my ($self, $path, $rev, $sub) = @_;
1861 $path =~ s#^/##;
1862 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
1863 $path =~ s#^/*#/#g;
1864 my $p = $path;
1865 # Strip the irrelevant part of the path.
1866 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
1867 # Ensure the path is terminated by a `/'.
1868 $p =~ s#/*$#/#;
1870 # The properties contain all the internal SVN stuff nobody
1871 # (usually) cares about.
1872 my $interesting_props = 0;
1873 foreach (keys %{$props}) {
1874 # If it doesn't start with `svn:', it must be a
1875 # user-defined property.
1876 ++$interesting_props and next if $_ !~ /^svn:/;
1877 # FIXME: Fragile, if SVN adds new public properties,
1878 # this needs to be updated.
1879 ++$interesting_props if /^svn:(?:ignore|keywords|executable
1880 |eol-style|mime-type
1881 |externals|needs-lock)$/x;
1882 }
1883 &$sub($self, $p, $props) if $interesting_props;
1885 foreach (sort keys %$dirent) {
1886 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
1887 $self->prop_walk($path . '/' . $_, $rev, $sub);
1888 }
1889 }
1891 sub last_rev { ($_[0]->last_rev_commit)[0] }
1892 sub last_commit { ($_[0]->last_rev_commit)[1] }
1894 # returns the newest SVN revision number and newest commit SHA1
1895 sub last_rev_commit {
1896 my ($self) = @_;
1897 if (defined $self->{last_rev} && defined $self->{last_commit}) {
1898 return ($self->{last_rev}, $self->{last_commit});
1899 }
1900 my $c = ::verify_ref($self->refname.'^0');
1901 if ($c && !$self->use_svm_props && !$self->no_metadata) {
1902 my $rev = (::cmt_metadata($c))[1];
1903 if (defined $rev) {
1904 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
1905 return ($rev, $c);
1906 }
1907 }
1908 my $map_path = $self->map_path;
1909 unless (-e $map_path) {
1910 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
1911 return (undef, undef);
1912 }
1913 my ($rev, $commit) = $self->rev_map_max(1);
1914 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
1915 return ($rev, $commit);
1916 }
1918 sub get_fetch_range {
1919 my ($self, $min, $max) = @_;
1920 $max ||= $self->ra->get_latest_revnum;
1921 $min ||= $self->rev_map_max;
1922 (++$min, $max);
1923 }
1925 sub tmp_config {
1926 my (@args) = @_;
1927 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
1928 my $config = "$ENV{GIT_DIR}/svn/.metadata";
1929 if (! -f $config && -f $old_def_config) {
1930 rename $old_def_config, $config or
1931 die "Failed rename $old_def_config => $config: $!\n";
1932 }
1933 my $old_config = $ENV{GIT_CONFIG};
1934 $ENV{GIT_CONFIG} = $config;
1935 $@ = undef;
1936 my @ret = eval {
1937 unless (-f $config) {
1938 mkfile($config);
1939 open my $fh, '>', $config or
1940 die "Can't open $config: $!\n";
1941 print $fh "; This file is used internally by ",
1942 "git-svn\n" or die
1943 "Couldn't write to $config: $!\n";
1944 print $fh "; You should not have to edit it\n" or
1945 die "Couldn't write to $config: $!\n";
1946 close $fh or die "Couldn't close $config: $!\n";
1947 }
1948 command('config', @args);
1949 };
1950 my $err = $@;
1951 if (defined $old_config) {
1952 $ENV{GIT_CONFIG} = $old_config;
1953 } else {
1954 delete $ENV{GIT_CONFIG};
1955 }
1956 die $err if $err;
1957 wantarray ? @ret : $ret[0];
1958 }
1960 sub tmp_index_do {
1961 my ($self, $sub) = @_;
1962 my $old_index = $ENV{GIT_INDEX_FILE};
1963 $ENV{GIT_INDEX_FILE} = $self->{index};
1964 $@ = undef;
1965 my @ret = eval {
1966 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
1967 mkpath([$dir]) unless -d $dir;
1968 &$sub;
1969 };
1970 my $err = $@;
1971 if (defined $old_index) {
1972 $ENV{GIT_INDEX_FILE} = $old_index;
1973 } else {
1974 delete $ENV{GIT_INDEX_FILE};
1975 }
1976 die $err if $err;
1977 wantarray ? @ret : $ret[0];
1978 }
1980 sub assert_index_clean {
1981 my ($self, $treeish) = @_;
1983 $self->tmp_index_do(sub {
1984 command_noisy('read-tree', $treeish) unless -e $self->{index};
1985 my $x = command_oneline('write-tree');
1986 my ($y) = (command(qw/cat-file commit/, $treeish) =~
1987 /^tree ($::sha1)/mo);
1988 return if $y eq $x;
1990 warn "Index mismatch: $y != $x\nrereading $treeish\n";
1991 unlink $self->{index} or die "unlink $self->{index}: $!\n";
1992 command_noisy('read-tree', $treeish);
1993 $x = command_oneline('write-tree');
1994 if ($y ne $x) {
1995 ::fatal "trees ($treeish) $y != $x\n",
1996 "Something is seriously wrong...";
1997 }
1998 });
1999 }
2001 sub get_commit_parents {
2002 my ($self, $log_entry) = @_;
2003 my (%seen, @ret, @tmp);
2004 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2005 if (my $ip = $self->{inject_parents}) {
2006 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2007 push @tmp, $commit;
2008 }
2009 }
2010 if (my $cur = ::verify_ref($self->refname.'^0')) {
2011 push @tmp, $cur;
2012 }
2013 if (my $ipd = $self->{inject_parents_dcommit}) {
2014 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2015 push @tmp, @$commit;
2016 }
2017 }
2018 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2019 while (my $p = shift @tmp) {
2020 next if $seen{$p};
2021 $seen{$p} = 1;
2022 push @ret, $p;
2023 # MAXPARENT is defined to 16 in commit-tree.c:
2024 last if @ret >= 16;
2025 }
2026 if (@tmp) {
2027 die "r$log_entry->{revision}: No room for parents:\n\t",
2028 join("\n\t", @tmp), "\n";
2029 }
2030 @ret;
2031 }
2033 sub rewrite_root {
2034 my ($self) = @_;
2035 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2036 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2037 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2038 if ($rwr) {
2039 $rwr =~ s#/+$##;
2040 if ($rwr !~ m#^[a-z\+]+://#) {
2041 die "$rwr is not a valid URL (key: $k)\n";
2042 }
2043 }
2044 $self->{-rewrite_root} = $rwr;
2045 }
2047 sub metadata_url {
2048 my ($self) = @_;
2049 ($self->rewrite_root || $self->{url}) .
2050 (length $self->{path} ? '/' . $self->{path} : '');
2051 }
2053 sub full_url {
2054 my ($self) = @_;
2055 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2056 }
2059 sub set_commit_header_env {
2060 my ($log_entry) = @_;
2061 my %env;
2062 foreach my $ned (qw/NAME EMAIL DATE/) {
2063 foreach my $ac (qw/AUTHOR COMMITTER/) {
2064 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2065 }
2066 }
2068 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2069 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2070 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2072 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2073 ? $log_entry->{commit_name}
2074 : $log_entry->{name};
2075 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2076 ? $log_entry->{commit_email}
2077 : $log_entry->{email};
2078 \%env;
2079 }
2081 sub restore_commit_header_env {
2082 my ($env) = @_;
2083 foreach my $ned (qw/NAME EMAIL DATE/) {
2084 foreach my $ac (qw/AUTHOR COMMITTER/) {
2085 my $k = "GIT_${ac}_${ned}";
2086 if (defined $env->{$k}) {
2087 $ENV{$k} = $env->{$k};
2088 } else {
2089 delete $ENV{$k};
2090 }
2091 }
2092 }
2093 }
2095 sub do_git_commit {
2096 my ($self, $log_entry) = @_;
2097 my $lr = $self->last_rev;
2098 if (defined $lr && $lr >= $log_entry->{revision}) {
2099 die "Last fetched revision of ", $self->refname,
2100 " was r$lr, but we are about to fetch: ",
2101 "r$log_entry->{revision}!\n";
2102 }
2103 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2104 croak "$log_entry->{revision} = $c already exists! ",
2105 "Why are we refetching it?\n";
2106 }
2107 my $old_env = set_commit_header_env($log_entry);
2108 my $tree = $log_entry->{tree};
2109 if (!defined $tree) {
2110 $tree = $self->tmp_index_do(sub {
2111 command_oneline('write-tree') });
2112 }
2113 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2115 my @exec = ('git-commit-tree', $tree);
2116 foreach ($self->get_commit_parents($log_entry)) {
2117 push @exec, '-p', $_;
2118 }
2119 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2120 or croak $!;
2121 print $msg_fh $log_entry->{log} or croak $!;
2122 restore_commit_header_env($old_env);
2123 unless ($self->no_metadata) {
2124 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2125 or croak $!;
2126 }
2127 $msg_fh->flush == 0 or croak $!;
2128 close $msg_fh or croak $!;
2129 chomp(my $commit = do { local $/; <$out_fh> });
2130 close $out_fh or croak $!;
2131 waitpid $pid, 0;
2132 croak $? if $?;
2133 if ($commit !~ /^$::sha1$/o) {
2134 die "Failed to commit, invalid sha1: $commit\n";
2135 }
2137 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2139 $self->{last_rev} = $log_entry->{revision};
2140 $self->{last_commit} = $commit;
2141 print "r$log_entry->{revision}";
2142 if (defined $log_entry->{svm_revision}) {
2143 print " (\@$log_entry->{svm_revision})";
2144 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2145 0, $self->svm_uuid);
2146 }
2147 print " = $commit ($self->{ref_id})\n";
2148 if (defined $_repack && (--$_repack_nr == 0)) {
2149 $_repack_nr = $_repack;
2150 # repack doesn't use any arguments with spaces in them, does it?
2151 print "Running git repack $_repack_flags ...\n";
2152 command_noisy('repack', split(/\s+/, $_repack_flags));
2153 print "Done repacking\n";
2154 }
2155 return $commit;
2156 }
2158 sub match_paths {
2159 my ($self, $paths, $r) = @_;
2160 return 1 if $self->{path} eq '';
2161 if (my $path = $paths->{"/$self->{path}"}) {
2162 return ($path->{action} eq 'D') ? 0 : 1;
2163 }
2164 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2165 if (grep /$self->{path_regex}/, keys %$paths) {
2166 return 1;
2167 }
2168 my $c = '';
2169 foreach (split m#/#, $self->{path}) {
2170 $c .= "/$_";
2171 next unless ($paths->{$c} &&
2172 ($paths->{$c}->{action} =~ /^[AR]$/));
2173 if ($self->ra->check_path($self->{path}, $r) ==
2174 $SVN::Node::dir) {
2175 return 1;
2176 }
2177 }
2178 return 0;
2179 }
2181 sub find_parent_branch {
2182 my ($self, $paths, $rev) = @_;
2183 return undef unless $self->follow_parent;
2184 unless (defined $paths) {
2185 my $err_handler = $SVN::Error::handler;
2186 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2187 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1, sub {
2188 $paths =
2189 Git::SVN::Ra::dup_changed_paths($_[0]) });
2190 $SVN::Error::handler = $err_handler;
2191 }
2192 return undef unless defined $paths;
2194 # look for a parent from another branch:
2195 my @b_path_components = split m#/#, $self->rel_path;
2196 my @a_path_components;
2197 my $i;
2198 while (@b_path_components) {
2199 $i = $paths->{'/'.join('/', @b_path_components)};
2200 last if $i && defined $i->{copyfrom_path};
2201 unshift(@a_path_components, pop(@b_path_components));
2202 }
2203 return undef unless defined $i && defined $i->{copyfrom_path};
2204 my $branch_from = $i->{copyfrom_path};
2205 if (@a_path_components) {
2206 print STDERR "branch_from: $branch_from => ";
2207 $branch_from .= '/'.join('/', @a_path_components);
2208 print STDERR $branch_from, "\n";
2209 }
2210 my $r = $i->{copyfrom_rev};
2211 my $repos_root = $self->ra->{repos_root};
2212 my $url = $self->ra->{url};
2213 my $new_url = $repos_root . $branch_from;
2214 print STDERR "Found possible branch point: ",
2215 "$new_url => ", $self->full_url, ", $r\n";
2216 $branch_from =~ s#^/##;
2217 my $gs = Git::SVN->find_by_url($new_url, $repos_root, $branch_from);
2218 unless ($gs) {
2219 my $ref_id = $self->{ref_id};
2220 $ref_id =~ s/\@\d+$//;
2221 $ref_id .= "\@$r";
2222 # just grow a tail if we're not unique enough :x
2223 $ref_id .= '-' while find_ref($ref_id);
2224 print STDERR "Initializing parent: $ref_id\n";
2225 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id, 1);
2226 }
2227 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2228 if (!defined $r0 || !defined $parent) {
2229 my ($base, $head) = parse_revision_argument(0, $r);
2230 if ($base <= $r) {
2231 $gs->fetch($base, $r);
2232 }
2233 ($r0, $parent) = $gs->last_rev_commit;
2234 }
2235 if (defined $r0 && defined $parent) {
2236 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2237 my $ed;
2238 if ($self->ra->can_do_switch) {
2239 $self->assert_index_clean($parent);
2240 print STDERR "Following parent with do_switch\n";
2241 # do_switch works with svn/trunk >= r22312, but that
2242 # is not included with SVN 1.4.3 (the latest version
2243 # at the moment), so we can't rely on it
2244 $self->{last_commit} = $parent;
2245 $ed = SVN::Git::Fetcher->new($self);
2246 $gs->ra->gs_do_switch($r0, $rev, $gs,
2247 $self->full_url, $ed)
2248 or die "SVN connection failed somewhere...\n";
2249 } elsif ($self->ra->trees_match($new_url, $r0,
2250 $self->full_url, $rev)) {
2251 print STDERR "Trees match:\n",
2252 " $new_url\@$r0\n",
2253 " ${\$self->full_url}\@$rev\n",
2254 "Following parent with no changes\n";
2255 $self->tmp_index_do(sub {
2256 command_noisy('read-tree', $parent);
2257 });
2258 $self->{last_commit} = $parent;
2259 } else {
2260 print STDERR "Following parent with do_update\n";
2261 $ed = SVN::Git::Fetcher->new($self);
2262 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2263 or die "SVN connection failed somewhere...\n";
2264 }
2265 print STDERR "Successfully followed parent\n";
2266 return $self->make_log_entry($rev, [$parent], $ed);
2267 }
2268 return undef;
2269 }
2271 sub do_fetch {
2272 my ($self, $paths, $rev) = @_;
2273 my $ed;
2274 my ($last_rev, @parents);
2275 if (my $lc = $self->last_commit) {
2276 # we can have a branch that was deleted, then re-added
2277 # under the same name but copied from another path, in
2278 # which case we'll have multiple parents (we don't
2279 # want to break the original ref, nor lose copypath info):
2280 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2281 push @{$log_entry->{parents}}, $lc;
2282 return $log_entry;
2283 }
2284 $ed = SVN::Git::Fetcher->new($self);
2285 $last_rev = $self->{last_rev};
2286 $ed->{c} = $lc;
2287 @parents = ($lc);
2288 } else {
2289 $last_rev = $rev;
2290 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2291 return $log_entry;
2292 }
2293 $ed = SVN::Git::Fetcher->new($self);
2294 }
2295 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2296 die "SVN connection failed somewhere...\n";
2297 }
2298 $self->make_log_entry($rev, \@parents, $ed);
2299 }
2301 sub get_untracked {
2302 my ($self, $ed) = @_;
2303 my @out;
2304 my $h = $ed->{empty};
2305 foreach (sort keys %$h) {
2306 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2307 push @out, " $act: " . uri_encode($_);
2308 warn "W: $act: $_\n";
2309 }
2310 foreach my $t (qw/dir_prop file_prop/) {
2311 $h = $ed->{$t} or next;
2312 foreach my $path (sort keys %$h) {
2313 my $ppath = $path eq '' ? '.' : $path;
2314 foreach my $prop (sort keys %{$h->{$path}}) {
2315 next if $SKIP_PROP{$prop};
2316 my $v = $h->{$path}->{$prop};
2317 my $t_ppath_prop = "$t: " .
2318 uri_encode($ppath) . ' ' .
2319 uri_encode($prop);
2320 if (defined $v) {
2321 push @out, " +$t_ppath_prop " .
2322 uri_encode($v);
2323 } else {
2324 push @out, " -$t_ppath_prop";
2325 }
2326 }
2327 }
2328 }
2329 foreach my $t (qw/absent_file absent_directory/) {
2330 $h = $ed->{$t} or next;
2331 foreach my $parent (sort keys %$h) {
2332 foreach my $path (sort @{$h->{$parent}}) {
2333 push @out, " $t: " .
2334 uri_encode("$parent/$path");
2335 warn "W: $t: $parent/$path ",
2336 "Insufficient permissions?\n";
2337 }
2338 }
2339 }
2340 \@out;
2341 }
2343 sub parse_svn_date {
2344 my $date = shift || return '+0000 1970-01-01 00:00:00';
2345 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2346 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
2347 croak "Unable to parse date: $date\n";
2348 "+0000 $Y-$m-$d $H:$M:$S";
2349 }
2351 sub check_author {
2352 my ($author) = @_;
2353 if (!defined $author || length $author == 0) {
2354 $author = '(no author)';
2355 }
2356 if (defined $::_authors && ! defined $::users{$author}) {
2357 die "Author: $author not defined in $::_authors file\n";
2358 }
2359 $author;
2360 }
2362 sub make_log_entry {
2363 my ($self, $rev, $parents, $ed) = @_;
2364 my $untracked = $self->get_untracked($ed);
2366 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2367 print $un "r$rev\n" or croak $!;
2368 print $un $_, "\n" foreach @$untracked;
2369 my %log_entry = ( parents => $parents || [], revision => $rev,
2370 log => '');
2372 my $headrev;
2373 my $logged = delete $self->{logged_rev_props};
2374 if (!$logged || $self->{-want_revprops}) {
2375 my $rp = $self->ra->rev_proplist($rev);
2376 foreach (sort keys %$rp) {
2377 my $v = $rp->{$_};
2378 if (/^svn:(author|date|log)$/) {
2379 $log_entry{$1} = $v;
2380 } elsif ($_ eq 'svm:headrev') {
2381 $headrev = $v;
2382 } else {
2383 print $un " rev_prop: ", uri_encode($_), ' ',
2384 uri_encode($v), "\n";
2385 }
2386 }
2387 } else {
2388 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2389 }
2390 close $un or croak $!;
2392 $log_entry{date} = parse_svn_date($log_entry{date});
2393 $log_entry{log} .= "\n";
2394 my $author = $log_entry{author} = check_author($log_entry{author});
2395 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2396 : ($author, undef);
2398 my ($commit_name, $commit_email) = ($name, $email);
2399 if ($_use_log_author) {
2400 my $name_field;
2401 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2402 $name_field = $1;
2403 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2404 $name_field = $1;
2405 }
2406 if (!defined $name_field) {
2407 #
2408 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2409 ($name, $email) = ($1, $2);
2410 } elsif ($name_field =~ /(.*)@/) {
2411 ($name, $email) = ($1, $name_field);
2412 } else {
2413 ($name, $email) = ($name_field, 'unknown');
2414 }
2415 }
2416 if (defined $headrev && $self->use_svm_props) {
2417 if ($self->rewrite_root) {
2418 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2419 "options set!\n";
2420 }
2421 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$};
2422 # we don't want "SVM: initializing mirror for junk" ...
2423 return undef if $r == 0;
2424 my $svm = $self->svm;
2425 if ($uuid ne $svm->{uuid}) {
2426 die "UUID mismatch on SVM path:\n",
2427 "expected: $svm->{uuid}\n",
2428 " got: $uuid\n";
2429 }
2430 my $full_url = $self->full_url;
2431 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2432 die "Failed to replace '$svm->{replace}' with ",
2433 "'$svm->{source}' in $full_url\n";
2434 # throw away username for storing in records
2435 remove_username($full_url);
2436 $log_entry{metadata} = "$full_url\@$r $uuid";
2437 $log_entry{svm_revision} = $r;
2438 $email ||= "$author\@$uuid";
2439 $commit_email ||= "$author\@$uuid";
2440 } elsif ($self->use_svnsync_props) {
2441 my $full_url = $self->svnsync->{url};
2442 $full_url .= "/$self->{path}" if length $self->{path};
2443 remove_username($full_url);
2444 my $uuid = $self->svnsync->{uuid};
2445 $log_entry{metadata} = "$full_url\@$rev $uuid";
2446 $email ||= "$author\@$uuid";
2447 $commit_email ||= "$author\@$uuid";
2448 } else {
2449 my $url = $self->metadata_url;
2450 remove_username($url);
2451 $log_entry{metadata} = "$url\@$rev " .
2452 $self->ra->get_uuid;
2453 $email ||= "$author\@" . $self->ra->get_uuid;
2454 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2455 }
2456 $log_entry{name} = $name;
2457 $log_entry{email} = $email;
2458 $log_entry{commit_name} = $commit_name;
2459 $log_entry{commit_email} = $commit_email;
2460 \%log_entry;
2461 }
2463 sub fetch {
2464 my ($self, $min_rev, $max_rev, @parents) = @_;
2465 my ($last_rev, $last_commit) = $self->last_rev_commit;
2466 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2467 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2468 }
2470 sub set_tree_cb {
2471 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2472 $self->{inject_parents} = { $rev => $tree };
2473 $self->fetch(undef, undef);
2474 }
2476 sub set_tree {
2477 my ($self, $tree) = (shift, shift);
2478 my $log_entry = ::get_commit_entry($tree);
2479 unless ($self->{last_rev}) {
2480 fatal("Must have an existing revision to commit");
2481 }
2482 my %ed_opts = ( r => $self->{last_rev},
2483 log => $log_entry->{log},
2484 ra => $self->ra,
2485 tree_a => $self->{last_commit},
2486 tree_b => $tree,
2487 editor_cb => sub {
2488 $self->set_tree_cb($log_entry, $tree, @_) },
2489 svn_path => $self->{path} );
2490 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2491 print "No changes\nr$self->{last_rev} = $tree\n";
2492 }
2493 }
2495 sub rebuild_from_rev_db {
2496 my ($self, $path) = @_;
2497 my $r = -1;
2498 open my $fh, '<', $path or croak "open: $!";
2499 while (<$fh>) {
2500 length($_) == 41 or croak "inconsistent size in ($_) != 41";
2501 chomp($_);
2502 ++$r;
2503 next if $_ eq ('0' x 40);
2504 $self->rev_map_set($r, $_);
2505 print "r$r = $_\n";
2506 }
2507 close $fh or croak "close: $!";
2508 unlink $path or croak "unlink: $!";
2509 }
2511 sub rebuild {
2512 my ($self) = @_;
2513 my $map_path = $self->map_path;
2514 return if (-e $map_path && ! -z $map_path);
2515 return unless ::verify_ref($self->refname.'^0');
2516 if ($self->use_svm_props || $self->no_metadata) {
2517 my $rev_db = $self->rev_db_path;
2518 $self->rebuild_from_rev_db($rev_db);
2519 if ($self->use_svm_props) {
2520 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
2521 $self->rebuild_from_rev_db($svm_rev_db);
2522 }
2523 $self->unlink_rev_db_symlink;
2524 return;
2525 }
2526 print "Rebuilding $map_path ...\n";
2527 my ($log, $ctx) =
2528 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
2529 $self->refname, '--');
2530 my $full_url = $self->full_url;
2531 remove_username($full_url);
2532 my $svn_uuid = $self->ra_uuid;
2533 my $c;
2534 while (<$log>) {
2535 if ( m{^commit ($::sha1)$} ) {
2536 $c = $1;
2537 next;
2538 }
2539 next unless s{^\s*(git-svn-id:)}{$1};
2540 my ($url, $rev, $uuid) = ::extract_metadata($_);
2541 remove_username($url);
2543 # ignore merges (from set-tree)
2544 next if (!defined $rev || !$uuid);
2546 # if we merged or otherwise started elsewhere, this is
2547 # how we break out of it
2548 if (($uuid ne $svn_uuid) ||
2549 ($full_url && $url && ($url ne $full_url))) {
2550 next;
2551 }
2553 $self->rev_map_set($rev, $c);
2554 print "r$rev = $c\n";
2555 }
2556 command_close_pipe($log, $ctx);
2557 print "Done rebuilding $map_path\n";
2558 my $rev_db_path = $self->rev_db_path;
2559 if (-f $self->rev_db_path) {
2560 unlink $self->rev_db_path or croak "unlink: $!";
2561 }
2562 $self->unlink_rev_db_symlink;
2563 }
2565 # rev_map:
2566 # Tie::File seems to be prone to offset errors if revisions get sparse,
2567 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
2568 # one of my favorite modules is out :< Next up would be one of the DBM
2569 # modules, but I'm not sure which is most portable...
2570 #
2571 # This is the replacement for the rev_db format, which was too big
2572 # and inefficient for large repositories with a lot of sparse history
2573 # (mainly tags)
2574 #
2575 # The format is this:
2576 # - 24 bytes for every record,
2577 # * 4 bytes for the integer representing an SVN revision number
2578 # * 20 bytes representing the sha1 of a git commit
2579 # - No empty padding records like the old format
2580 # (except the last record, which can be overwritten)
2581 # - new records are written append-only since SVN revision numbers
2582 # increase monotonically
2583 # - lookups on SVN revision number are done via a binary search
2584 # - Piping the file to xxd -c24 is a good way of dumping it for
2585 # viewing or editing (piped back through xxd -r), should the need
2586 # ever arise.
2587 # - The last record can be padding revision with an all-zero sha1
2588 # This is used to optimize fetch performance when using multiple
2589 # "fetch" directives in .git/config
2590 #
2591 # These files are disposable unless noMetadata or useSvmProps is set
2593 sub _rev_map_set {
2594 my ($fh, $rev, $commit) = @_;
2596 my $size = (stat($fh))[7];
2597 ($size % 24) == 0 or croak "inconsistent size: $size";
2599 my $wr_offset = 0;
2600 if ($size > 0) {
2601 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2602 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
2603 $read == 24 or croak "read only $read bytes (!= 24)";
2604 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
2605 if ($last_commit eq ('0' x40)) {
2606 if ($size >= 48) {
2607 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2608 $read = sysread($fh, $buf, 24) or
2609 croak "read: $!";
2610 $read == 24 or
2611 croak "read only $read bytes (!= 24)";
2612 ($last_rev, $last_commit) =
2613 unpack(rev_map_fmt, $buf);
2614 if ($last_commit eq ('0' x40)) {
2615 croak "inconsistent .rev_map\n";
2616 }
2617 }
2618 if ($last_rev >= $rev) {
2619 croak "last_rev is higher!: $last_rev >= $rev";
2620 }
2621 $wr_offset = -24;
2622 }
2623 }
2624 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
2625 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
2626 croak "write: $!";
2627 }
2629 sub mkfile {
2630 my ($path) = @_;
2631 unless (-e $path) {
2632 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
2633 mkpath([$dir]) unless -d $dir;
2634 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
2635 close $fh or die "Couldn't close (create) $path: $!\n";
2636 }
2637 }
2639 sub rev_map_set {
2640 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
2641 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
2642 my $db = $self->map_path($uuid);
2643 my $db_lock = "$db.lock";
2644 my $sig;
2645 if ($update_ref) {
2646 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2647 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
2648 }
2649 mkfile($db);
2651 $LOCKFILES{$db_lock} = 1;
2652 my $sync;
2653 # both of these options make our .rev_db file very, very important
2654 # and we can't afford to lose it because rebuild() won't work
2655 if ($self->use_svm_props || $self->no_metadata) {
2656 $sync = 1;
2657 copy($db, $db_lock) or die "rev_map_set(@_): ",
2658 "Failed to copy: ",
2659 "$db => $db_lock ($!)\n";
2660 } else {
2661 rename $db, $db_lock or die "rev_map_set(@_): ",
2662 "Failed to rename: ",
2663 "$db => $db_lock ($!)\n";
2664 }
2666 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
2667 or croak "Couldn't open $db_lock: $!\n";
2668 _rev_map_set($fh, $rev, $commit);
2669 if ($sync) {
2670 $fh->flush or die "Couldn't flush $db_lock: $!\n";
2671 $fh->sync or die "Couldn't sync $db_lock: $!\n";
2672 }
2673 close $fh or croak $!;
2674 if ($update_ref) {
2675 $_head = $self;
2676 command_noisy('update-ref', '-m', "r$rev",
2677 $self->refname, $commit);
2678 }
2679 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
2680 "$db_lock => $db ($!)\n";
2681 delete $LOCKFILES{$db_lock};
2682 if ($update_ref) {
2683 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
2684 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
2685 kill $sig, $$ if defined $sig;
2686 }
2687 }
2689 # If want_commit, this will return an array of (rev, commit) where
2690 # commit _must_ be a valid commit in the archive.
2691 # Otherwise, it'll return the max revision (whether or not the
2692 # commit is valid or just a 0x40 placeholder).
2693 sub rev_map_max {
2694 my ($self, $want_commit) = @_;
2695 $self->rebuild;
2696 my $map_path = $self->map_path;
2697 stat $map_path or return $want_commit ? (0, undef) : 0;
2698 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2699 my $size = (stat($fh))[7];
2700 ($size % 24) == 0 or croak "inconsistent size: $size";
2702 if ($size == 0) {
2703 close $fh or croak "close: $!";
2704 return $want_commit ? (0, undef) : 0;
2705 }
2707 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
2708 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2709 my ($r, $c) = unpack(rev_map_fmt, $buf);
2710 if ($want_commit && $c eq ('0' x40)) {
2711 if ($size < 48) {
2712 return $want_commit ? (0, undef) : 0;
2713 }
2714 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
2715 sysread($fh, $buf, 24) == 24 or croak "read: $!";
2716 ($r, $c) = unpack(rev_map_fmt, $buf);
2717 if ($c eq ('0'x40)) {
2718 croak "Penultimate record is all-zeroes in $map_path";
2719 }
2720 }
2721 close $fh or croak "close: $!";
2722 $want_commit ? ($r, $c) : $r;
2723 }
2725 sub rev_map_get {
2726 my ($self, $rev, $uuid) = @_;
2727 my $map_path = $self->map_path($uuid);
2728 return undef unless -e $map_path;
2730 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
2731 my $size = (stat($fh))[7];
2732 ($size % 24) == 0 or croak "inconsistent size: $size";
2734 if ($size == 0) {
2735 close $fh or croak "close: $fh";
2736 return undef;
2737 }
2739 my ($l, $u) = (0, $size - 24);
2740 my ($r, $c, $buf);
2742 while ($l <= $u) {
2743 my $i = int(($l/24 + $u/24) / 2) * 24;
2744 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
2745 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
2746 my ($r, $c) = unpack('NH40', $buf);
2748 if ($r < $rev) {
2749 $l = $i + 24;
2750 } elsif ($r > $rev) {
2751 $u = $i - 24;
2752 } else { # $r == $rev
2753 close($fh) or croak "close: $!";
2754 return $c eq ('0' x 40) ? undef : $c;
2755 }
2756 }
2757 close($fh) or croak "close: $!";
2758 undef;
2759 }
2761 # Finds the first svn revision that exists on (if $eq_ok is true) or
2762 # before $rev for the current branch. It will not search any lower
2763 # than $min_rev. Returns the git commit hash and svn revision number
2764 # if found, else (undef, undef).
2765 sub find_rev_before {
2766 my ($self, $rev, $eq_ok, $min_rev) = @_;
2767 --$rev unless $eq_ok;
2768 $min_rev ||= 1;
2769 while ($rev >= $min_rev) {
2770 if (my $c = $self->rev_map_get($rev)) {
2771 return ($rev, $c);
2772 }
2773 --$rev;
2774 }
2775 return (undef, undef);
2776 }
2778 # Finds the first svn revision that exists on (if $eq_ok is true) or
2779 # after $rev for the current branch. It will not search any higher
2780 # than $max_rev. Returns the git commit hash and svn revision number
2781 # if found, else (undef, undef).
2782 sub find_rev_after {
2783 my ($self, $rev, $eq_ok, $max_rev) = @_;
2784 ++$rev unless $eq_ok;
2785 $max_rev ||= $self->rev_map_max;
2786 while ($rev <= $max_rev) {
2787 if (my $c = $self->rev_map_get($rev)) {
2788 return ($rev, $c);
2789 }
2790 ++$rev;
2791 }
2792 return (undef, undef);
2793 }
2795 sub _new {
2796 my ($class, $repo_id, $ref_id, $path) = @_;
2797 unless (defined $repo_id && length $repo_id) {
2798 $repo_id = $Git::SVN::default_repo_id;
2799 }
2800 unless (defined $ref_id && length $ref_id) {
2801 $_[2] = $ref_id = $Git::SVN::default_ref_id;
2802 }
2803 $_[1] = $repo_id = sanitize_remote_name($repo_id);
2804 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
2805 $_[3] = $path = '' unless (defined $path);
2806 mkpath(["$ENV{GIT_DIR}/svn"]);
2807 bless {
2808 ref_id => $ref_id, dir => $dir, index => "$dir/index",
2809 path => $path, config => "$ENV{GIT_DIR}/svn/config",
2810 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
2811 }
2813 # for read-only access of old .rev_db formats
2814 sub unlink_rev_db_symlink {
2815 my ($self) = @_;
2816 my $link = $self->rev_db_path;
2817 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
2818 if (-l $link) {
2819 unlink $link or croak "unlink: $link failed!";
2820 }
2821 }
2823 sub rev_db_path {
2824 my ($self, $uuid) = @_;
2825 my $db_path = $self->map_path($uuid);
2826 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
2827 or croak "map_path: $db_path does not contain '/.rev_map.' !";
2828 $db_path;
2829 }
2831 # the new replacement for .rev_db
2832 sub map_path {
2833 my ($self, $uuid) = @_;
2834 $uuid ||= $self->ra_uuid;
2835 "$self->{map_root}.$uuid";
2836 }
2838 sub uri_encode {
2839 my ($f) = @_;
2840 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
2841 $f
2842 }
2844 sub remove_username {
2845 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
2846 }
2848 package Git::SVN::Prompt;
2849 use strict;
2850 use warnings;
2851 require SVN::Core;
2852 use vars qw/$_no_auth_cache $_username/;
2854 sub simple {
2855 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2856 $may_save = undef if $_no_auth_cache;
2857 $default_username = $_username if defined $_username;
2858 if (defined $default_username && length $default_username) {
2859 if (defined $realm && length $realm) {
2860 print STDERR "Authentication realm: $realm\n";
2861 STDERR->flush;
2862 }
2863 $cred->username($default_username);
2864 } else {
2865 username($cred, $realm, $may_save, $pool);
2866 }
2867 $cred->password(_read_password("Password for '" .
2868 $cred->username . "': ", $realm));
2869 $cred->may_save($may_save);
2870 $SVN::_Core::SVN_NO_ERROR;
2871 }
2873 sub ssl_server_trust {
2874 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2875 $may_save = undef if $_no_auth_cache;
2876 print STDERR "Error validating server certificate for '$realm':\n";
2877 {
2878 no warnings 'once';
2879 # All variables SVN::Auth::SSL::* are used only once,
2880 # so we're shutting up Perl warnings about this.
2881 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2882 print STDERR " - The certificate is not issued ",
2883 "by a trusted authority. Use the\n",
2884 " fingerprint to validate ",
2885 "the certificate manually!\n";
2886 }
2887 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2888 print STDERR " - The certificate hostname ",
2889 "does not match.\n";
2890 }
2891 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2892 print STDERR " - The certificate is not yet valid.\n";
2893 }
2894 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2895 print STDERR " - The certificate has expired.\n";
2896 }
2897 if ($failures & $SVN::Auth::SSL::OTHER) {
2898 print STDERR " - The certificate has ",
2899 "an unknown error.\n";
2900 }
2901 } # no warnings 'once'
2902 printf STDERR
2903 "Certificate information:\n".
2904 " - Hostname: %s\n".
2905 " - Valid: from %s until %s\n".
2906 " - Issuer: %s\n".
2907 " - Fingerprint: %s\n",
2908 map $cert_info->$_, qw(hostname valid_from valid_until
2909 issuer_dname fingerprint);
2910 my $choice;
2911 prompt:
2912 print STDERR $may_save ?
2913 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2914 "(R)eject or accept (t)emporarily? ";
2915 STDERR->flush;
2916 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2917 if ($choice =~ /^t$/i) {
2918 $cred->may_save(undef);
2919 } elsif ($choice =~ /^r$/i) {
2920 return -1;
2921 } elsif ($may_save && $choice =~ /^p$/i) {
2922 $cred->may_save($may_save);
2923 } else {
2924 goto prompt;
2925 }
2926 $cred->accepted_failures($failures);
2927 $SVN::_Core::SVN_NO_ERROR;
2928 }
2930 sub ssl_client_cert {
2931 my ($cred, $realm, $may_save, $pool) = @_;
2932 $may_save = undef if $_no_auth_cache;
2933 print STDERR "Client certificate filename: ";
2934 STDERR->flush;
2935 chomp(my $filename = <STDIN>);
2936 $cred->cert_file($filename);
2937 $cred->may_save($may_save);
2938 $SVN::_Core::SVN_NO_ERROR;
2939 }
2941 sub ssl_client_cert_pw {
2942 my ($cred, $realm, $may_save, $pool) = @_;
2943 $may_save = undef if $_no_auth_cache;
2944 $cred->password(_read_password("Password: ", $realm));
2945 $cred->may_save($may_save);
2946 $SVN::_Core::SVN_NO_ERROR;
2947 }
2949 sub username {
2950 my ($cred, $realm, $may_save, $pool) = @_;
2951 $may_save = undef if $_no_auth_cache;
2952 if (defined $realm && length $realm) {
2953 print STDERR "Authentication realm: $realm\n";
2954 }
2955 my $username;
2956 if (defined $_username) {
2957 $username = $_username;
2958 } else {
2959 print STDERR "Username: ";
2960 STDERR->flush;
2961 chomp($username = <STDIN>);
2962 }
2963 $cred->username($username);
2964 $cred->may_save($may_save);
2965 $SVN::_Core::SVN_NO_ERROR;
2966 }
2968 sub _read_password {
2969 my ($prompt, $realm) = @_;
2970 print STDERR $prompt;
2971 STDERR->flush;
2972 require Term::ReadKey;
2973 Term::ReadKey::ReadMode('noecho');
2974 my $password = '';
2975 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2976 last if $key =~ /[\012\015]/; # \n\r
2977 $password .= $key;
2978 }
2979 Term::ReadKey::ReadMode('restore');
2980 print STDERR "\n";
2981 STDERR->flush;
2982 $password;
2983 }
2985 package SVN::Git::Fetcher;
2986 use vars qw/@ISA/;
2987 use strict;
2988 use warnings;
2989 use Carp qw/croak/;
2990 use IO::File qw//;
2992 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
2993 sub new {
2994 my ($class, $git_svn) = @_;
2995 my $self = SVN::Delta::Editor->new;
2996 bless $self, $class;
2997 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
2998 $self->{empty} = {};
2999 $self->{dir_prop} = {};
3000 $self->{file_prop} = {};
3001 $self->{absent_dir} = {};
3002 $self->{absent_file} = {};
3003 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3004 $self;
3005 }
3007 sub set_path_strip {
3008 my ($self, $path) = @_;
3009 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3010 }
3012 sub open_root {
3013 { path => '' };
3014 }
3016 sub open_directory {
3017 my ($self, $path, $pb, $rev) = @_;
3018 { path => $path };
3019 }
3021 sub git_path {
3022 my ($self, $path) = @_;
3023 if ($self->{path_strip}) {
3024 $path =~ s!$self->{path_strip}!! or
3025 die "Failed to strip path '$path' ($self->{path_strip})\n";
3026 }
3027 $path;
3028 }
3030 sub delete_entry {
3031 my ($self, $path, $rev, $pb) = @_;
3033 my $gpath = $self->git_path($path);
3034 return undef if ($gpath eq '');
3036 # remove entire directories.
3037 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
3038 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3039 -r --name-only -z/,
3040 $self->{c}, '--', $gpath);
3041 local $/ = "\0";
3042 while (<$ls>) {
3043 chomp;
3044 $self->{gii}->remove($_);
3045 print "\tD\t$_\n" unless $::_q;
3046 }
3047 print "\tD\t$gpath/\n" unless $::_q;
3048 command_close_pipe($ls, $ctx);
3049 $self->{empty}->{$path} = 0
3050 } else {
3051 $self->{gii}->remove($gpath);
3052 print "\tD\t$gpath\n" unless $::_q;
3053 }
3054 undef;
3055 }
3057 sub open_file {
3058 my ($self, $path, $pb, $rev) = @_;
3059 my $gpath = $self->git_path($path);
3060 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
3061 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
3062 unless (defined $mode && defined $blob) {
3063 die "$path was not found in commit $self->{c} (r$rev)\n";
3064 }
3065 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3066 pool => SVN::Pool->new, action => 'M' };
3067 }
3069 sub add_file {
3070 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3071 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3072 delete $self->{empty}->{$dir};
3073 { path => $path, mode_a => 100644, mode_b => 100644,
3074 pool => SVN::Pool->new, action => 'A' };
3075 }
3077 sub add_directory {
3078 my ($self, $path, $cp_path, $cp_rev) = @_;
3079 my $gpath = $self->git_path($path);
3080 if ($gpath eq '') {
3081 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3082 -r --name-only -z/,
3083 $self->{c});
3084 local $/ = "\0";
3085 while (<$ls>) {
3086 chomp;
3087 $self->{gii}->remove($_);
3088 print "\tD\t$_\n" unless $::_q;
3089 }
3090 command_close_pipe($ls, $ctx);
3091 $self->{empty}->{$path} = 0;
3092 }
3093 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3094 delete $self->{empty}->{$dir};
3095 $self->{empty}->{$path} = 1;
3096 { path => $path };
3097 }
3099 sub change_dir_prop {
3100 my ($self, $db, $prop, $value) = @_;
3101 $self->{dir_prop}->{$db->{path}} ||= {};
3102 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3103 undef;
3104 }
3106 sub absent_directory {
3107 my ($self, $path, $pb) = @_;
3108 $self->{absent_dir}->{$pb->{path}} ||= [];
3109 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3110 undef;
3111 }
3113 sub absent_file {
3114 my ($self, $path, $pb) = @_;
3115 $self->{absent_file}->{$pb->{path}} ||= [];
3116 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3117 undef;
3118 }
3120 sub change_file_prop {
3121 my ($self, $fb, $prop, $value) = @_;
3122 if ($prop eq 'svn:executable') {
3123 if ($fb->{mode_b} != 120000) {
3124 $fb->{mode_b} = defined $value ? 100755 : 100644;
3125 }
3126 } elsif ($prop eq 'svn:special') {
3127 $fb->{mode_b} = defined $value ? 120000 : 100644;
3128 } else {
3129 $self->{file_prop}->{$fb->{path}} ||= {};
3130 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3131 }
3132 undef;
3133 }
3135 sub apply_textdelta {
3136 my ($self, $fb, $exp) = @_;
3137 my $fh = IO::File->new_tmpfile;
3138 $fh->autoflush(1);
3139 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3140 # (but $base does not,) so dup() it for reading in close_file
3141 open my $dup, '<&', $fh or croak $!;
3142 my $base = IO::File->new_tmpfile;
3143 $base->autoflush(1);
3144 if ($fb->{blob}) {
3145 defined (my $pid = fork) or croak $!;
3146 if (!$pid) {
3147 open STDOUT, '>&', $base or croak $!;
3148 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
3149 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
3150 }
3151 waitpid $pid, 0;
3152 croak $? if $?;
3154 if (defined $exp) {
3155 seek $base, 0, 0 or croak $!;
3156 my $got = ::md5sum($base);
3157 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
3158 "expected: $exp\n",
3159 " got: $got\n" if ($got ne $exp);
3160 }
3161 }
3162 seek $base, 0, 0 or croak $!;
3163 $fb->{fh} = $dup;
3164 $fb->{base} = $base;
3165 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
3166 }
3168 sub close_file {
3169 my ($self, $fb, $exp) = @_;
3170 my $hash;
3171 my $path = $self->git_path($fb->{path});
3172 if (my $fh = $fb->{fh}) {
3173 if (defined $exp) {
3174 seek($fh, 0, 0) or croak $!;
3175 my $got = ::md5sum($fh);
3176 if ($got ne $exp) {
3177 die "Checksum mismatch: $path\n",
3178 "expected: $exp\n got: $got\n";
3179 }
3180 }
3181 sysseek($fh, 0, 0) or croak $!;
3182 if ($fb->{mode_b} == 120000) {
3183 eval {
3184 sysread($fh, my $buf, 5) == 5 or croak $!;
3185 $buf eq 'link ' or die "$path has mode 120000",
3186 " but is not a link";
3187 };
3188 if ($@) {
3189 warn "$@\n";
3190 sysseek($fh, 0, 0) or croak $!;
3191 }
3192 }
3193 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
3194 if (!$pid) {
3195 open STDIN, '<&', $fh or croak $!;
3196 exec qw/git-hash-object -w --stdin/ or croak $!;
3197 }
3198 chomp($hash = do { local $/; <$out> });
3199 close $out or croak $!;
3200 close $fh or croak $!;
3201 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3202 close $fb->{base} or croak $!;
3203 } else {
3204 $hash = $fb->{blob} or die "no blob information\n";
3205 }
3206 $fb->{pool}->clear;
3207 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3208 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3209 undef;
3210 }
3212 sub abort_edit {
3213 my $self = shift;
3214 $self->{nr} = $self->{gii}->{nr};
3215 delete $self->{gii};
3216 $self->SUPER::abort_edit(@_);
3217 }
3219 sub close_edit {
3220 my $self = shift;
3221 $self->{git_commit_ok} = 1;
3222 $self->{nr} = $self->{gii}->{nr};
3223 delete $self->{gii};
3224 $self->SUPER::close_edit(@_);
3225 }
3227 package SVN::Git::Editor;
3228 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3229 use strict;
3230 use warnings;
3231 use Carp qw/croak/;
3232 use IO::File;
3234 sub new {
3235 my ($class, $opts) = @_;
3236 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3237 die "$_ required!\n" unless (defined $opts->{$_});
3238 }
3240 my $pool = SVN::Pool->new;
3241 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3242 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3243 $opts->{r}, $mods);
3245 # $opts->{ra} functions should not be used after this:
3246 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3247 $opts->{editor_cb}, $pool);
3248 my $self = SVN::Delta::Editor->new(@ce, $pool);
3249 bless $self, $class;
3250 foreach (qw/svn_path r tree_a tree_b/) {
3251 $self->{$_} = $opts->{$_};
3252 }
3253 $self->{url} = $opts->{ra}->{url};
3254 $self->{mods} = $mods;
3255 $self->{types} = $types;
3256 $self->{pool} = $pool;
3257 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3258 $self->{rm} = { };
3259 $self->{path_prefix} = length $self->{svn_path} ?
3260 "$self->{svn_path}/" : '';
3261 return $self;
3262 }
3264 sub generate_diff {
3265 my ($tree_a, $tree_b) = @_;
3266 my @diff_tree = qw(diff-tree -z -r);
3267 if ($_cp_similarity) {
3268 push @diff_tree, "-C$_cp_similarity";
3269 } else {
3270 push @diff_tree, '-C';
3271 }
3272 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3273 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3274 push @diff_tree, $tree_a, $tree_b;
3275 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3276 local $/ = "\0";
3277 my $state = 'meta';
3278 my @mods;
3279 while (<$diff_fh>) {
3280 chomp $_; # this gets rid of the trailing "\0"
3281 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3282 $::sha1\s($::sha1)\s
3283 ([MTCRAD])\d*$/xo) {
3284 push @mods, { mode_a => $1, mode_b => $2,
3285 sha1_b => $3, chg => $4 };
3286 if ($4 =~ /^(?:C|R)$/) {
3287 $state = 'file_a';
3288 } else {
3289 $state = 'file_b';
3290 }
3291 } elsif ($state eq 'file_a') {
3292 my $x = $mods[$#mods] or croak "Empty array\n";
3293 if ($x->{chg} !~ /^(?:C|R)$/) {
3294 croak "Error parsing $_, $x->{chg}\n";
3295 }
3296 $x->{file_a} = $_;
3297 $state = 'file_b';
3298 } elsif ($state eq 'file_b') {
3299 my $x = $mods[$#mods] or croak "Empty array\n";
3300 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3301 croak "Error parsing $_, $x->{chg}\n";
3302 }
3303 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3304 croak "Error parsing $_, $x->{chg}\n";
3305 }
3306 $x->{file_b} = $_;
3307 $state = 'meta';
3308 } else {
3309 croak "Error parsing $_\n";
3310 }
3311 }
3312 command_close_pipe($diff_fh, $ctx);
3313 \@mods;
3314 }
3316 sub check_diff_paths {
3317 my ($ra, $pfx, $rev, $mods) = @_;
3318 my %types;
3319 $pfx .= '/' if length $pfx;
3321 sub type_diff_paths {
3322 my ($ra, $types, $path, $rev) = @_;
3323 my @p = split m#/+#, $path;
3324 my $c = shift @p;
3325 unless (defined $types->{$c}) {
3326 $types->{$c} = $ra->check_path($c, $rev);
3327 }
3328 while (@p) {
3329 $c .= '/' . shift @p;
3330 next if defined $types->{$c};
3331 $types->{$c} = $ra->check_path($c, $rev);
3332 }
3333 }
3335 foreach my $m (@$mods) {
3336 foreach my $f (qw/file_a file_b/) {
3337 next unless defined $m->{$f};
3338 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
3339 if (length $pfx.$dir && ! defined $types{$dir}) {
3340 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
3341 }
3342 }
3343 }
3344 \%types;
3345 }
3347 sub split_path {
3348 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3349 }
3351 sub repo_path {
3352 my ($self, $path) = @_;
3353 $self->{path_prefix}.(defined $path ? $path : '');
3354 }
3356 sub url_path {
3357 my ($self, $path) = @_;
3358 if ($self->{url} =~ m#^https?://#) {
3359 $path =~ s/([^a-zA-Z0-9_.-])/uc sprintf("%%%02x",ord($1))/eg;
3360 }
3361 $self->{url} . '/' . $self->repo_path($path);
3362 }
3364 sub rmdirs {
3365 my ($self) = @_;
3366 my $rm = $self->{rm};
3367 delete $rm->{''}; # we never delete the url we're tracking
3368 return unless %$rm;
3370 foreach (keys %$rm) {
3371 my @d = split m#/#, $_;
3372 my $c = shift @d;
3373 $rm->{$c} = 1;
3374 while (@d) {
3375 $c .= '/' . shift @d;
3376 $rm->{$c} = 1;
3377 }
3378 }
3379 delete $rm->{$self->{svn_path}};
3380 delete $rm->{''}; # we never delete the url we're tracking
3381 return unless %$rm;
3383 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
3384 $self->{tree_b});
3385 local $/ = "\0";
3386 while (<$fh>) {
3387 chomp;
3388 my @dn = split m#/#, $_;
3389 while (pop @dn) {
3390 delete $rm->{join '/', @dn};
3391 }
3392 unless (%$rm) {
3393 close $fh;
3394 return;
3395 }
3396 }
3397 command_close_pipe($fh, $ctx);
3399 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3400 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3401 $self->close_directory($bat->{$d}, $p);
3402 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3403 print "\tD+\t$d/\n" unless $::_q;
3404 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3405 delete $bat->{$d};
3406 }
3407 }
3409 sub open_or_add_dir {
3410 my ($self, $full_path, $baton) = @_;
3411 my $t = $self->{types}->{$full_path};
3412 if (!defined $t) {
3413 die "$full_path not known in r$self->{r} or we have a bug!\n";
3414 }
3415 {
3416 no warnings 'once';
3417 # SVN::Node::none and SVN::Node::file are used only once,
3418 # so we're shutting up Perl's warnings about them.
3419 if ($t == $SVN::Node::none) {
3420 return $self->add_directory($full_path, $baton,
3421 undef, -1, $self->{pool});
3422 } elsif ($t == $SVN::Node::dir) {
3423 return $self->open_directory($full_path, $baton,
3424 $self->{r}, $self->{pool});
3425 } # no warnings 'once'
3426 print STDERR "$full_path already exists in repository at ",
3427 "r$self->{r} and it is not a directory (",
3428 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3429 } # no warnings 'once'
3430 exit 1;
3431 }
3433 sub ensure_path {
3434 my ($self, $path) = @_;
3435 my $bat = $self->{bat};
3436 my $repo_path = $self->repo_path($path);
3437 return $bat->{''} unless (length $repo_path);
3438 my @p = split m#/+#, $repo_path;
3439 my $c = shift @p;
3440 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3441 while (@p) {
3442 my $c0 = $c;
3443 $c .= '/' . shift @p;
3444 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3445 }
3446 return $bat->{$c};
3447 }
3449 sub A {
3450 my ($self, $m) = @_;
3451 my ($dir, $file) = split_path($m->{file_b});
3452 my $pbat = $self->ensure_path($dir);
3453 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3454 undef, -1);
3455 print "\tA\t$m->{file_b}\n" unless $::_q;
3456 $self->chg_file($fbat, $m);
3457 $self->close_file($fbat,undef,$self->{pool});
3458 }
3460 sub C {
3461 my ($self, $m) = @_;
3462 my ($dir, $file) = split_path($m->{file_b});
3463 my $pbat = $self->ensure_path($dir);
3464 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3465 $self->url_path($m->{file_a}), $self->{r});
3466 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3467 $self->chg_file($fbat, $m);
3468 $self->close_file($fbat,undef,$self->{pool});
3469 }
3471 sub delete_entry {
3472 my ($self, $path, $pbat) = @_;
3473 my $rpath = $self->repo_path($path);
3474 my ($dir, $file) = split_path($rpath);
3475 $self->{rm}->{$dir} = 1;
3476 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3477 }
3479 sub R {
3480 my ($self, $m) = @_;
3481 my ($dir, $file) = split_path($m->{file_b});
3482 my $pbat = $self->ensure_path($dir);
3483 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3484 $self->url_path($m->{file_a}), $self->{r});
3485 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
3486 $self->chg_file($fbat, $m);
3487 $self->close_file($fbat,undef,$self->{pool});
3489 ($dir, $file) = split_path($m->{file_a});
3490 $pbat = $self->ensure_path($dir);
3491 $self->delete_entry($m->{file_a}, $pbat);
3492 }
3494 sub M {
3495 my ($self, $m) = @_;
3496 my ($dir, $file) = split_path($m->{file_b});
3497 my $pbat = $self->ensure_path($dir);
3498 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3499 $pbat,$self->{r},$self->{pool});
3500 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
3501 $self->chg_file($fbat, $m);
3502 $self->close_file($fbat,undef,$self->{pool});
3503 }
3505 sub T { shift->M(@_) }
3507 sub change_file_prop {
3508 my ($self, $fbat, $pname, $pval) = @_;
3509 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3510 }
3512 sub chg_file {
3513 my ($self, $fbat, $m) = @_;
3514 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3515 $self->change_file_prop($fbat,'svn:executable','*');
3516 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3517 $self->change_file_prop($fbat,'svn:executable',undef);
3518 }
3519 my $fh = IO::File->new_tmpfile or croak $!;
3520 if ($m->{mode_b} =~ /^120/) {
3521 print $fh 'link ' or croak $!;
3522 $self->change_file_prop($fbat,'svn:special','*');
3523 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3524 $self->change_file_prop($fbat,'svn:special',undef);
3525 }
3526 defined(my $pid = fork) or croak $!;
3527 if (!$pid) {
3528 open STDOUT, '>&', $fh or croak $!;
3529 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3530 }
3531 waitpid $pid, 0;
3532 croak $? if $?;
3533 $fh->flush == 0 or croak $!;
3534 seek $fh, 0, 0 or croak $!;
3536 my $exp = ::md5sum($fh);
3537 seek $fh, 0, 0 or croak $!;
3539 my $pool = SVN::Pool->new;
3540 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3541 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3542 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3543 $pool->clear;
3545 close $fh or croak $!;
3546 }
3548 sub D {
3549 my ($self, $m) = @_;
3550 my ($dir, $file) = split_path($m->{file_b});
3551 my $pbat = $self->ensure_path($dir);
3552 print "\tD\t$m->{file_b}\n" unless $::_q;
3553 $self->delete_entry($m->{file_b}, $pbat);
3554 }
3556 sub close_edit {
3557 my ($self) = @_;
3558 my ($p,$bat) = ($self->{pool}, $self->{bat});
3559 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3560 next if $_ eq '';
3561 $self->close_directory($bat->{$_}, $p);
3562 }
3563 $self->close_directory($bat->{''}, $p);
3564 $self->SUPER::close_edit($p);
3565 $p->clear;
3566 }
3568 sub abort_edit {
3569 my ($self) = @_;
3570 $self->SUPER::abort_edit($self->{pool});
3571 }
3573 sub DESTROY {
3574 my $self = shift;
3575 $self->SUPER::DESTROY(@_);
3576 $self->{pool}->clear;
3577 }
3579 # this drives the editor
3580 sub apply_diff {
3581 my ($self) = @_;
3582 my $mods = $self->{mods};
3583 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
3584 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
3585 my $f = $m->{chg};
3586 if (defined $o{$f}) {
3587 $self->$f($m);
3588 } else {
3589 fatal("Invalid change type: $f");
3590 }
3591 }
3592 $self->rmdirs if $_rmdir;
3593 if (@$mods == 0) {
3594 $self->abort_edit;
3595 } else {
3596 $self->close_edit;
3597 }
3598 return scalar @$mods;
3599 }
3601 package Git::SVN::Ra;
3602 use vars qw/@ISA $config_dir $_log_window_size/;
3603 use strict;
3604 use warnings;
3605 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
3607 BEGIN {
3608 # enforce temporary pool usage for some simple functions
3609 no strict 'refs';
3610 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root/) {
3611 my $SUPER = "SUPER::$f";
3612 *$f = sub {
3613 my $self = shift;
3614 my $pool = SVN::Pool->new;
3615 my @ret = $self->$SUPER(@_,$pool);
3616 $pool->clear;
3617 wantarray ? @ret : $ret[0];
3618 };
3619 }
3620 }
3622 sub _auth_providers () {
3623 [
3624 SVN::Client::get_simple_provider(),
3625 SVN::Client::get_ssl_server_trust_file_provider(),
3626 SVN::Client::get_simple_prompt_provider(
3627 \&Git::SVN::Prompt::simple, 2),
3628 SVN::Client::get_ssl_client_cert_file_provider(),
3629 SVN::Client::get_ssl_client_cert_prompt_provider(
3630 \&Git::SVN::Prompt::ssl_client_cert, 2),
3631 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
3632 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
3633 SVN::Client::get_username_provider(),
3634 SVN::Client::get_ssl_server_trust_prompt_provider(
3635 \&Git::SVN::Prompt::ssl_server_trust),
3636 SVN::Client::get_username_prompt_provider(
3637 \&Git::SVN::Prompt::username, 2)
3638 ]
3639 }
3641 sub escape_uri_only {
3642 my ($uri) = @_;
3643 my @tmp;
3644 foreach (split m{/}, $uri) {
3645 s/([^\w.-])/sprintf("%%%02X",ord($1))/eg;
3646 push @tmp, $_;
3647 }
3648 join('/', @tmp);
3649 }
3651 sub escape_url {
3652 my ($url) = @_;
3653 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
3654 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
3655 $url = "$scheme://$domain$uri";
3656 }
3657 $url;
3658 }
3660 sub new {
3661 my ($class, $url) = @_;
3662 $url =~ s!/+$!!;
3663 return $RA if ($RA && $RA->{url} eq $url);
3665 SVN::_Core::svn_config_ensure($config_dir, undef);
3666 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
3667 my $config = SVN::Core::config_get_config($config_dir);
3668 $RA = undef;
3669 my $dont_store_passwords = 1;
3670 my $conf_t = ${$config}{'config'};
3671 {
3672 no warnings 'once';
3673 # The usage of $SVN::_Core::SVN_CONFIG_* variables
3674 # produces warnings that variables are used only once.
3675 # I had not found the better way to shut them up, so
3676 # the warnings of type 'once' are disabled in this block.
3677 if (SVN::_Core::svn_config_get_bool($conf_t,
3678 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3679 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
3680 1) == 0) {
3681 SVN::_Core::svn_auth_set_parameter($baton,
3682 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
3683 bless (\$dont_store_passwords, "_p_void"));
3684 }
3685 if (SVN::_Core::svn_config_get_bool($conf_t,
3686 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
3687 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
3688 1) == 0) {
3689 $Git::SVN::Prompt::_no_auth_cache = 1;
3690 }
3691 } # no warnings 'once'
3692 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
3693 config => $config,
3694 pool => SVN::Pool->new,
3695 auth_provider_callbacks => $callbacks);
3696 $self->{url} = $url;
3697 $self->{svn_path} = $url;
3698 $self->{repos_root} = $self->get_repos_root;
3699 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
3700 $self->{cache} = { check_path => { r => 0, data => {} },
3701 get_dir => { r => 0, data => {} } };
3702 $RA = bless $self, $class;
3703 }
3705 sub check_path {
3706 my ($self, $path, $r) = @_;
3707 my $cache = $self->{cache}->{check_path};
3708 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
3709 return $cache->{data}->{$path};
3710 }
3711 my $pool = SVN::Pool->new;
3712 my $t = $self->SUPER::check_path($path, $r, $pool);
3713 $pool->clear;
3714 if ($r != $cache->{r}) {
3715 %{$cache->{data}} = ();
3716 $cache->{r} = $r;
3717 }
3718 $cache->{data}->{$path} = $t;
3719 }
3721 sub get_dir {
3722 my ($self, $dir, $r) = @_;
3723 my $cache = $self->{cache}->{get_dir};
3724 if ($r == $cache->{r}) {
3725 if (my $x = $cache->{data}->{$dir}) {
3726 return wantarray ? @$x : $x->[0];
3727 }
3728 }
3729 my $pool = SVN::Pool->new;
3730 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
3731 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
3732 $pool->clear;
3733 if ($r != $cache->{r}) {
3734 %{$cache->{data}} = ();
3735 $cache->{r} = $r;
3736 }
3737 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
3738 wantarray ? (\%dirents, $r, $props) : \%dirents;
3739 }
3741 sub DESTROY {
3742 # do not call the real DESTROY since we store ourselves in $RA
3743 }
3745 sub get_log {
3746 my ($self, @args) = @_;
3747 my $pool = SVN::Pool->new;
3748 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
3749 my $ret = $self->SUPER::get_log(@args, $pool);
3750 $pool->clear;
3751 $ret;
3752 }
3754 sub trees_match {
3755 my ($self, $url1, $rev1, $url2, $rev2) = @_;
3756 my $ctx = SVN::Client->new(auth => _auth_providers);
3757 my $out = IO::File->new_tmpfile;
3759 # older SVN (1.1.x) doesn't take $pool as the last parameter for
3760 # $ctx->diff(), so we'll create a default one
3761 my $pool = SVN::Pool->new_default_sub;
3763 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
3764 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
3765 $out->flush;
3766 my $ret = (($out->stat)[7] == 0);
3767 close $out or croak $!;
3769 $ret;
3770 }
3772 sub get_commit_editor {
3773 my ($self, $log, $cb, $pool) = @_;
3774 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
3775 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
3776 }
3778 sub gs_do_update {
3779 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
3780 my $new = ($rev_a == $rev_b);
3781 my $path = $gs->{path};
3783 if ($new && -e $gs->{index}) {
3784 unlink $gs->{index} or die
3785 "Couldn't unlink index: $gs->{index}: $!\n";
3786 }
3787 my $pool = SVN::Pool->new;
3788 $editor->set_path_strip($path);
3789 my (@pc) = split m#/#, $path;
3790 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
3791 1, $editor, $pool);
3792 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3794 # Since we can't rely on svn_ra_reparent being available, we'll
3795 # just have to do some magic with set_path to make it so
3796 # we only want a partial path.
3797 my $sp = '';
3798 my $final = join('/', @pc);
3799 while (@pc) {
3800 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
3801 $sp .= '/' if length $sp;
3802 $sp .= shift @pc;
3803 }
3804 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
3806 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
3808 $reporter->finish_report($pool);
3809 $pool->clear;
3810 $editor->{git_commit_ok};
3811 }
3813 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
3814 # svn_ra_reparent didn't work before 1.4)
3815 sub gs_do_switch {
3816 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
3817 my $path = $gs->{path};
3818 my $pool = SVN::Pool->new;
3820 my $full_url = $self->{url};
3821 my $old_url = $full_url;
3822 $full_url .= '/' . escape_uri_only($path) if length $path;
3823 my ($ra, $reparented);
3824 if ($old_url ne $full_url) {
3825 if ($old_url !~ m#^svn(\+ssh)?://#) {
3826 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url,
3827 $pool);
3828 $self->{url} = $full_url;
3829 $reparented = 1;
3830 } else {
3831 $_[0] = undef;
3832 $self = undef;
3833 $RA = undef;
3834 $ra = Git::SVN::Ra->new($full_url);
3835 $ra_invalid = 1;
3836 }
3837 }
3838 $ra ||= $self;
3839 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
3840 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
3841 $reporter->set_path('', $rev_a, 0, @lock, $pool);
3842 $reporter->finish_report($pool);
3844 if ($reparented) {
3845 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
3846 $self->{url} = $old_url;
3847 }
3849 $pool->clear;
3850 $editor->{git_commit_ok};
3851 }
3853 sub longest_common_path {
3854 my ($gsv, $globs) = @_;
3855 my %common;
3856 my $common_max = scalar @$gsv;
3858 foreach my $gs (@$gsv) {
3859 my @tmp = split m#/#, $gs->{path};
3860 my $p = '';
3861 foreach (@tmp) {
3862 $p .= length($p) ? "/$_" : $_;
3863 $common{$p} ||= 0;
3864 $common{$p}++;
3865 }
3866 }
3867 $globs ||= [];
3868 $common_max += scalar @$globs;
3869 foreach my $glob (@$globs) {
3870 my @tmp = split m#/#, $glob->{path}->{left};
3871 my $p = '';
3872 foreach (@tmp) {
3873 $p .= length($p) ? "/$_" : $_;
3874 $common{$p} ||= 0;
3875 $common{$p}++;
3876 }
3877 }
3879 my $longest_path = '';
3880 foreach (sort {length $b <=> length $a} keys %common) {
3881 if ($common{$_} == $common_max) {
3882 $longest_path = $_;
3883 last;
3884 }
3885 }
3886 $longest_path;
3887 }
3889 sub gs_fetch_loop_common {
3890 my ($self, $base, $head, $gsv, $globs) = @_;
3891 return if ($base > $head);
3892 my $inc = $_log_window_size;
3893 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
3894 my $longest_path = longest_common_path($gsv, $globs);
3895 my $ra_url = $self->{url};
3896 while (1) {
3897 my %revs;
3898 my $err;
3899 my $err_handler = $SVN::Error::handler;
3900 $SVN::Error::handler = sub {
3901 ($err) = @_;
3902 skip_unknown_revs($err);
3903 };
3904 sub _cb {
3905 my ($paths, $r, $author, $date, $log) = @_;
3906 [ dup_changed_paths($paths),
3907 { author => $author, date => $date, log => $log } ];
3908 }
3909 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
3910 sub { $revs{$_[1]} = _cb(@_) });
3911 if ($err && $max >= $head) {
3912 print STDERR "Path '$longest_path' ",
3913 "was probably deleted:\n",
3914 $err->expanded_message,
3915 "\nWill attempt to follow ",
3916 "revisions r$min .. r$max ",
3917 "committed before the deletion\n";
3918 my $hi = $max;
3919 while (--$hi >= $min) {
3920 my $ok;
3921 $self->get_log([$longest_path], $min, $hi,
3922 0, 1, 1, sub {
3923 $ok ||= $_[1];
3924 $revs{$_[1]} = _cb(@_) });
3925 if ($ok) {
3926 print STDERR "r$min .. r$ok OK\n";
3927 last;
3928 }
3929 }
3930 }
3931 $SVN::Error::handler = $err_handler;
3933 my %exists = map { $_->{path} => $_ } @$gsv;
3934 foreach my $r (sort {$a <=> $b} keys %revs) {
3935 my ($paths, $logged) = @{$revs{$r}};
3937 foreach my $gs ($self->match_globs(\%exists, $paths,
3938 $globs, $r)) {
3939 if ($gs->rev_map_max >= $r) {
3940 next;
3941 }
3942 next unless $gs->match_paths($paths, $r);
3943 $gs->{logged_rev_props} = $logged;
3944 if (my $last_commit = $gs->last_commit) {
3945 $gs->assert_index_clean($last_commit);
3946 }
3947 my $log_entry = $gs->do_fetch($paths, $r);
3948 if ($log_entry) {
3949 $gs->do_git_commit($log_entry);
3950 }
3951 $INDEX_FILES{$gs->{index}} = 1;
3952 }
3953 foreach my $g (@$globs) {
3954 my $k = "svn-remote.$g->{remote}." .
3955 "$g->{t}-maxRev";
3956 Git::SVN::tmp_config($k, $r);
3957 }
3958 if ($ra_invalid) {
3959 $_[0] = undef;
3960 $self = undef;
3961 $RA = undef;
3962 $self = Git::SVN::Ra->new($ra_url);
3963 $ra_invalid = undef;
3964 }
3965 }
3966 # pre-fill the .rev_db since it'll eventually get filled in
3967 # with '0' x40 if something new gets committed
3968 foreach my $gs (@$gsv) {
3969 next if $gs->rev_map_max >= $max;
3970 next if defined $gs->rev_map_get($max);
3971 $gs->rev_map_set($max, 0 x40);
3972 }
3973 foreach my $g (@$globs) {
3974 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
3975 Git::SVN::tmp_config($k, $max);
3976 }
3977 last if $max >= $head;
3978 $min = $max + 1;
3979 $max += $inc;
3980 $max = $head if ($max > $head);
3981 }
3982 }
3984 sub match_globs {
3985 my ($self, $exists, $paths, $globs, $r) = @_;
3987 sub get_dir_check {
3988 my ($self, $exists, $g, $r) = @_;
3989 my @x = eval { $self->get_dir($g->{path}->{left}, $r) };
3990 return unless scalar @x == 3;
3991 my $dirents = $x[0];
3992 foreach my $de (keys %$dirents) {
3993 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
3994 my $p = $g->{path}->full_path($de);
3995 next if $exists->{$p};
3996 next if (length $g->{path}->{right} &&
3997 ($self->check_path($p, $r) !=
3998 $SVN::Node::dir));
3999 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4000 $g->{ref}->full_path($de), 1);
4001 }
4002 }
4003 foreach my $g (@$globs) {
4004 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4005 if ($path->{action} =~ /^[AR]$/) {
4006 get_dir_check($self, $exists, $g, $r);
4007 }
4008 }
4009 foreach (keys %$paths) {
4010 if (/$g->{path}->{left_regex}/ &&
4011 !/$g->{path}->{regex}/) {
4012 next if $paths->{$_}->{action} !~ /^[AR]$/;
4013 get_dir_check($self, $exists, $g, $r);
4014 }
4015 next unless /$g->{path}->{regex}/;
4016 my $p = $1;
4017 my $pathname = $g->{path}->full_path($p);
4018 next if $exists->{$pathname};
4019 next if ($self->check_path($pathname, $r) !=
4020 $SVN::Node::dir);
4021 $exists->{$pathname} = Git::SVN->init(
4022 $self->{url}, $pathname, undef,
4023 $g->{ref}->full_path($p), 1);
4024 }
4025 my $c = '';
4026 foreach (split m#/#, $g->{path}->{left}) {
4027 $c .= "/$_";
4028 next unless ($paths->{$c} &&
4029 ($paths->{$c}->{action} =~ /^[AR]$/));
4030 get_dir_check($self, $exists, $g, $r);
4031 }
4032 }
4033 values %$exists;
4034 }
4036 sub minimize_url {
4037 my ($self) = @_;
4038 return $self->{url} if ($self->{url} eq $self->{repos_root});
4039 my $url = $self->{repos_root};
4040 my @components = split(m!/!, $self->{svn_path});
4041 my $c = '';
4042 do {
4043 $url .= "/$c" if length $c;
4044 eval { (ref $self)->new($url)->get_latest_revnum };
4045 } while ($@ && ($c = shift @components));
4046 $url;
4047 }
4049 sub can_do_switch {
4050 my $self = shift;
4051 unless (defined $can_do_switch) {
4052 my $pool = SVN::Pool->new;
4053 my $rep = eval {
4054 $self->do_switch(1, '', 0, $self->{url},
4055 SVN::Delta::Editor->new, $pool);
4056 };
4057 if ($@) {
4058 $can_do_switch = 0;
4059 } else {
4060 $rep->abort_report($pool);
4061 $can_do_switch = 1;
4062 }
4063 $pool->clear;
4064 }
4065 $can_do_switch;
4066 }
4068 sub skip_unknown_revs {
4069 my ($err) = @_;
4070 my $errno = $err->apr_err();
4071 # Maybe the branch we're tracking didn't
4072 # exist when the repo started, so it's
4073 # not an error if it doesn't, just continue
4074 #
4075 # Wonderfully consistent library, eh?
4076 # 160013 - svn:// and file://
4077 # 175002 - http(s)://
4078 # 175007 - http(s):// (this repo required authorization, too...)
4079 # More codes may be discovered later...
4080 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4081 my $err_key = $err->expanded_message;
4082 # revision numbers change every time, filter them out
4083 $err_key =~ s/\d+/\0/g;
4084 $err_key = "$errno\0$err_key";
4085 unless ($ignored_err{$err_key}) {
4086 warn "W: Ignoring error from SVN, path probably ",
4087 "does not exist: ($errno): ",
4088 $err->expanded_message,"\n";
4089 warn "W: Do not be alarmed at the above message ",
4090 "git-svn is just searching aggressively for ",
4091 "old history.\n",
4092 "This may take a while on large repositories\n";
4093 $ignored_err{$err_key} = 1;
4094 }
4095 return;
4096 }
4097 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4098 }
4100 # svn_log_changed_path_t objects passed to get_log are likely to be
4101 # overwritten even if only the refs are copied to an external variable,
4102 # so we should dup the structures in their entirety. Using an externally
4103 # passed pool (instead of our temporary and quickly cleared pool in
4104 # Git::SVN::Ra) does not help matters at all...
4105 sub dup_changed_paths {
4106 my ($paths) = @_;
4107 return undef unless $paths;
4108 my %ret;
4109 foreach my $p (keys %$paths) {
4110 my $i = $paths->{$p};
4111 my %s = map { $_ => $i->$_ }
4112 qw/copyfrom_path copyfrom_rev action/;
4113 $ret{$p} = \%s;
4114 }
4115 \%ret;
4116 }
4118 package Git::SVN::Log;
4119 use strict;
4120 use warnings;
4121 use POSIX qw/strftime/;
4122 use constant commit_log_separator => ('-' x 72) . "\n";
4123 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4124 %rusers $show_commit $incremental/;
4125 my $l_fmt;
4127 sub cmt_showable {
4128 my ($c) = @_;
4129 return 1 if defined $c->{r};
4131 # big commit message got truncated by the 16k pretty buffer in rev-list
4132 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4133 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4134 @{$c->{l}} = ();
4135 my @log = command(qw/cat-file commit/, $c->{c});
4137 # shift off the headers
4138 shift @log while ($log[0] ne '');
4139 shift @log;
4141 # TODO: make $c->{l} not have a trailing newline in the future
4142 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4144 (undef, $c->{r}, undef) = ::extract_metadata(
4145 (grep(/^git-svn-id: /, @log))[-1]);
4146 }
4147 return defined $c->{r};
4148 }
4150 sub log_use_color {
4151 return $color || Git->repository->get_colorbool('color.diff');
4152 }
4154 sub git_svn_log_cmd {
4155 my ($r_min, $r_max, @args) = @_;
4156 my $head = 'HEAD';
4157 my (@files, @log_opts);
4158 foreach my $x (@args) {
4159 if ($x eq '--' || @files) {
4160 push @files, $x;
4161 } else {
4162 if (::verify_ref("$x^0")) {
4163 $head = $x;
4164 } else {
4165 push @log_opts, $x;
4166 }
4167 }
4168 }
4170 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4171 $gs ||= Git::SVN->_new;
4172 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4173 $gs->refname);
4174 push @cmd, '-r' unless $non_recursive;
4175 push @cmd, qw/--raw --name-status/ if $verbose;
4176 push @cmd, '--color' if log_use_color();
4177 push @cmd, @log_opts;
4178 if (defined $r_max && $r_max == $r_min) {
4179 push @cmd, '--max-count=1';
4180 if (my $c = $gs->rev_map_get($r_max)) {
4181 push @cmd, $c;
4182 }
4183 } elsif (defined $r_max) {
4184 if ($r_max < $r_min) {
4185 ($r_min, $r_max) = ($r_max, $r_min);
4186 }
4187 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4188 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4189 # If there are no commits in the range, both $c_max and $c_min
4190 # will be undefined. If there is at least 1 commit in the
4191 # range, both will be defined.
4192 return () if !defined $c_min || !defined $c_max;
4193 if ($c_min eq $c_max) {
4194 push @cmd, '--max-count=1', $c_min;
4195 } else {
4196 push @cmd, '--boundary', "$c_min..$c_max";
4197 }
4198 }
4199 return (@cmd, @files);
4200 }
4202 # adapted from pager.c
4203 sub config_pager {
4204 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
4205 if (!defined $pager) {
4206 $pager = 'less';
4207 } elsif (length $pager == 0 || $pager eq 'cat') {
4208 $pager = undef;
4209 }
4210 $ENV{GIT_PAGER_IN_USE} = defined($pager);
4211 }
4213 sub run_pager {
4214 return unless -t *STDOUT && defined $pager;
4215 pipe my $rfd, my $wfd or return;
4216 defined(my $pid = fork) or ::fatal "Can't fork: $!";
4217 if (!$pid) {
4218 open STDOUT, '>&', $wfd or
4219 ::fatal "Can't redirect to stdout: $!";
4220 return;
4221 }
4222 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
4223 $ENV{LESS} ||= 'FRSX';
4224 exec $pager or ::fatal "Can't run pager: $! ($pager)";
4225 }
4227 sub format_svn_date {
4228 return strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)", localtime(shift));
4229 }
4231 sub parse_git_date {
4232 my ($t, $tz) = @_;
4233 # Date::Parse isn't in the standard Perl distro :(
4234 if ($tz =~ s/^\+//) {
4235 $t += tz_to_s_offset($tz);
4236 } elsif ($tz =~ s/^\-//) {
4237 $t -= tz_to_s_offset($tz);
4238 }
4239 return $t;
4240 }
4242 sub set_local_timezone {
4243 if (defined $TZ) {
4244 $ENV{TZ} = $TZ;
4245 } else {
4246 delete $ENV{TZ};
4247 }
4248 }
4250 sub tz_to_s_offset {
4251 my ($tz) = @_;
4252 $tz =~ s/(\d\d)$//;
4253 return ($1 * 60) + ($tz * 3600);
4254 }
4256 sub get_author_info {
4257 my ($dest, $author, $t, $tz) = @_;
4258 $author =~ s/(?:^\s*|\s*$)//g;
4259 $dest->{a_raw} = $author;
4260 my $au;
4261 if ($::_authors) {
4262 $au = $rusers{$author} || undef;
4263 }
4264 if (!$au) {
4265 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
4266 }
4267 $dest->{t} = $t;
4268 $dest->{tz} = $tz;
4269 $dest->{a} = $au;
4270 $dest->{t_utc} = parse_git_date($t, $tz);
4271 }
4273 sub process_commit {
4274 my ($c, $r_min, $r_max, $defer) = @_;
4275 if (defined $r_min && defined $r_max) {
4276 if ($r_min == $c->{r} && $r_min == $r_max) {
4277 show_commit($c);
4278 return 0;
4279 }
4280 return 1 if $r_min == $r_max;
4281 if ($r_min < $r_max) {
4282 # we need to reverse the print order
4283 return 0 if (defined $limit && --$limit < 0);
4284 push @$defer, $c;
4285 return 1;
4286 }
4287 if ($r_min != $r_max) {
4288 return 1 if ($r_min < $c->{r});
4289 return 1 if ($r_max > $c->{r});
4290 }
4291 }
4292 return 0 if (defined $limit && --$limit < 0);
4293 show_commit($c);
4294 return 1;
4295 }
4297 sub show_commit {
4298 my $c = shift;
4299 if ($oneline) {
4300 my $x = "\n";
4301 if (my $l = $c->{l}) {
4302 while ($l->[0] =~ /^\s*$/) { shift @$l }
4303 $x = $l->[0];
4304 }
4305 $l_fmt ||= 'A' . length($c->{r});
4306 print 'r',pack($l_fmt, $c->{r}),' | ';
4307 print "$c->{c} | " if $show_commit;
4308 print $x;
4309 } else {
4310 show_commit_normal($c);
4311 }
4312 }
4314 sub show_commit_changed_paths {
4315 my ($c) = @_;
4316 return unless $c->{changed};
4317 print "Changed paths:\n", @{$c->{changed}};
4318 }
4320 sub show_commit_normal {
4321 my ($c) = @_;
4322 print commit_log_separator, "r$c->{r} | ";
4323 print "$c->{c} | " if $show_commit;
4324 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
4325 my $nr_line = 0;
4327 if (my $l = $c->{l}) {
4328 while ($l->[$#$l] eq "\n" && $#$l > 0
4329 && $l->[($#$l - 1)] eq "\n") {
4330 pop @$l;
4331 }
4332 $nr_line = scalar @$l;
4333 if (!$nr_line) {
4334 print "1 line\n\n\n";
4335 } else {
4336 if ($nr_line == 1) {
4337 $nr_line = '1 line';
4338 } else {
4339 $nr_line .= ' lines';
4340 }
4341 print $nr_line, "\n";
4342 show_commit_changed_paths($c);
4343 print "\n";
4344 print $_ foreach @$l;
4345 }
4346 } else {
4347 print "1 line\n";
4348 show_commit_changed_paths($c);
4349 print "\n";
4351 }
4352 foreach my $x (qw/raw stat diff/) {
4353 if ($c->{$x}) {
4354 print "\n";
4355 print $_ foreach @{$c->{$x}}
4356 }
4357 }
4358 }
4360 sub cmd_show_log {
4361 my (@args) = @_;
4362 my ($r_min, $r_max);
4363 my $r_last = -1; # prevent dupes
4364 set_local_timezone();
4365 if (defined $::_revision) {
4366 if ($::_revision =~ /^(\d+):(\d+)$/) {
4367 ($r_min, $r_max) = ($1, $2);
4368 } elsif ($::_revision =~ /^\d+$/) {
4369 $r_min = $r_max = $::_revision;
4370 } else {
4371 ::fatal "-r$::_revision is not supported, use ",
4372 "standard 'git log' arguments instead";
4373 }
4374 }
4376 config_pager();
4377 @args = git_svn_log_cmd($r_min, $r_max, @args);
4378 if (!@args) {
4379 print commit_log_separator unless $incremental || $oneline;
4380 return;
4381 }
4382 my $log = command_output_pipe(@args);
4383 run_pager();
4384 my (@k, $c, $d, $stat);
4385 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
4386 while (<$log>) {
4387 if (/^${esc_color}commit -?($::sha1_short)/o) {
4388 my $cmt = $1;
4389 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
4390 $r_last = $c->{r};
4391 process_commit($c, $r_min, $r_max, \@k) or
4392 goto out;
4393 }
4394 $d = undef;
4395 $c = { c => $cmt };
4396 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
4397 get_author_info($c, $1, $2, $3);
4398 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
4399 # ignore
4400 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
4401 push @{$c->{raw}}, $_;
4402 } elsif (/^${esc_color}[ACRMDT]\t/) {
4403 # we could add $SVN->{svn_path} here, but that requires
4404 # remote access at the moment (repo_path_split)...
4405 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
4406 push @{$c->{changed}}, $_;
4407 } elsif (/^${esc_color}diff /o) {
4408 $d = 1;
4409 push @{$c->{diff}}, $_;
4410 } elsif ($d) {
4411 push @{$c->{diff}}, $_;
4412 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
4413 $esc_color*[\+\-]*$esc_color$/x) {
4414 $stat = 1;
4415 push @{$c->{stat}}, $_;
4416 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
4417 push @{$c->{stat}}, $_;
4418 $stat = undef;
4419 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
4420 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
4421 } elsif (s/^${esc_color} //o) {
4422 push @{$c->{l}}, $_;
4423 }
4424 }
4425 if ($c && defined $c->{r} && $c->{r} != $r_last) {
4426 $r_last = $c->{r};
4427 process_commit($c, $r_min, $r_max, \@k);
4428 }
4429 if (@k) {
4430 ($r_min, $r_max) = ($r_max, $r_min);
4431 process_commit($_, $r_min, $r_max) foreach reverse @k;
4432 }
4433 out:
4434 close $log;
4435 print commit_log_separator unless $incremental || $oneline;
4436 }
4438 package Git::SVN::Migration;
4439 # these version numbers do NOT correspond to actual version numbers
4440 # of git nor git-svn. They are just relative.
4441 #
4442 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
4443 #
4444 # v1 layout: .git/$id/info/url, refs/remotes/$id
4445 #
4446 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
4447 #
4448 # v3 layout: .git/svn/$id, refs/remotes/$id
4449 # - info/url may remain for backwards compatibility
4450 # - this is what we migrate up to this layout automatically,
4451 # - this will be used by git svn init on single branches
4452 # v3.1 layout (auto migrated):
4453 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
4454 # for backwards compatibility
4455 #
4456 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
4457 # - this is only created for newly multi-init-ed
4458 # repositories. Similar in spirit to the
4459 # --use-separate-remotes option in git-clone (now default)
4460 # - we do not automatically migrate to this (following
4461 # the example set by core git)
4462 #
4463 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
4464 # - newer, more-efficient format that uses 24-bytes per record
4465 # with no filler space.
4466 # - use xxd -c24 < .rev_map.$UUID to view and debug
4467 # - This is a one-way migration, repositories updated to the
4468 # new format will not be able to use old git-svn without
4469 # rebuilding the .rev_db. Rebuilding the rev_db is not
4470 # possible if noMetadata or useSvmProps are set; but should
4471 # be no problem for users that use the (sensible) defaults.
4472 use strict;
4473 use warnings;
4474 use Carp qw/croak/;
4475 use File::Path qw/mkpath/;
4476 use File::Basename qw/dirname basename/;
4477 use vars qw/$_minimize/;
4479 sub migrate_from_v0 {
4480 my $git_dir = $ENV{GIT_DIR};
4481 return undef unless -d $git_dir;
4482 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4483 my $migrated = 0;
4484 while (<$fh>) {
4485 chomp;
4486 my ($id, $orig_ref) = ($_, $_);
4487 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
4488 next unless -f "$git_dir/$id/info/url";
4489 my $new_ref = "refs/remotes/$id";
4490 if (::verify_ref("$new_ref^0")) {
4491 print STDERR "W: $orig_ref is probably an old ",
4492 "branch used by an ancient version of ",
4493 "git-svn.\n",
4494 "However, $new_ref also exists.\n",
4495 "We will not be able ",
4496 "to use this branch until this ",
4497 "ambiguity is resolved.\n";
4498 next;
4499 }
4500 print STDERR "Migrating from v0 layout...\n" if !$migrated;
4501 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
4502 command_noisy('update-ref', $new_ref, $orig_ref);
4503 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
4504 $migrated++;
4505 }
4506 command_close_pipe($fh, $ctx);
4507 print STDERR "Done migrating from v0 layout...\n" if $migrated;
4508 $migrated;
4509 }
4511 sub migrate_from_v1 {
4512 my $git_dir = $ENV{GIT_DIR};
4513 my $migrated = 0;
4514 return $migrated unless -d $git_dir;
4515 my $svn_dir = "$git_dir/svn";
4517 # just in case somebody used 'svn' as their $id at some point...
4518 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
4520 print STDERR "Migrating from a git-svn v1 layout...\n";
4521 mkpath([$svn_dir]);
4522 print STDERR "Data from a previous version of git-svn exists, but\n\t",
4523 "$svn_dir\n\t(required for this version ",
4524 "($::VERSION) of git-svn) does not. exist\n";
4525 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
4526 while (<$fh>) {
4527 my $x = $_;
4528 next unless $x =~ s#^refs/remotes/##;
4529 chomp $x;
4530 next unless -f "$git_dir/$x/info/url";
4531 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
4532 next unless $u;
4533 my $dn = dirname("$git_dir/svn/$x");
4534 mkpath([$dn]) unless -d $dn;
4535 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
4536 mkpath(["$git_dir/svn/svn"]);
4537 print STDERR " - $git_dir/$x/info => ",
4538 "$git_dir/svn/$x/info\n";
4539 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
4540 croak "$!: $x";
4541 # don't worry too much about these, they probably
4542 # don't exist with repos this old (save for index,
4543 # and we can easily regenerate that)
4544 foreach my $f (qw/unhandled.log index .rev_db/) {
4545 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
4546 }
4547 } else {
4548 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
4549 rename "$git_dir/$x", "$git_dir/svn/$x" or
4550 croak "$!: $x";
4551 }
4552 $migrated++;
4553 }
4554 command_close_pipe($fh, $ctx);
4555 print STDERR "Done migrating from a git-svn v1 layout\n";
4556 $migrated;
4557 }
4559 sub read_old_urls {
4560 my ($l_map, $pfx, $path) = @_;
4561 my @dir;
4562 foreach (<$path/*>) {
4563 if (-r "$_/info/url") {
4564 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
4565 my $ref_id = $pfx . basename $_;
4566 my $url = ::file_to_s("$_/info/url");
4567 $l_map->{$ref_id} = $url;
4568 } elsif (-d $_) {
4569 push @dir, $_;
4570 }
4571 }
4572 foreach (@dir) {
4573 my $x = $_;
4574 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
4575 read_old_urls($l_map, $x, $_);
4576 }
4577 }
4579 sub migrate_from_v2 {
4580 my @cfg = command(qw/config -l/);
4581 return if grep /^svn-remote\..+\.url=/, @cfg;
4582 my %l_map;
4583 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
4584 my $migrated = 0;
4586 foreach my $ref_id (sort keys %l_map) {
4587 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
4588 if ($@) {
4589 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
4590 }
4591 $migrated++;
4592 }
4593 $migrated;
4594 }
4596 sub minimize_connections {
4597 my $r = Git::SVN::read_all_remotes();
4598 my $new_urls = {};
4599 my $root_repos = {};
4600 foreach my $repo_id (keys %$r) {
4601 my $url = $r->{$repo_id}->{url} or next;
4602 my $fetch = $r->{$repo_id}->{fetch} or next;
4603 my $ra = Git::SVN::Ra->new($url);
4605 # skip existing cases where we already connect to the root
4606 if (($ra->{url} eq $ra->{repos_root}) ||
4607 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
4608 $repo_id)) {
4609 $root_repos->{$ra->{url}} = $repo_id;
4610 next;
4611 }
4613 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
4614 my $root_path = $ra->{url};
4615 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
4616 foreach my $path (keys %$fetch) {
4617 my $ref_id = $fetch->{$path};
4618 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
4620 # make sure we can read when connecting to
4621 # a higher level of a repository
4622 my ($last_rev, undef) = $gs->last_rev_commit;
4623 if (!defined $last_rev) {
4624 $last_rev = eval {
4625 $root_ra->get_latest_revnum;
4626 };
4627 next if $@;
4628 }
4629 my $new = $root_path;
4630 $new .= length $path ? "/$path" : '';
4631 eval {
4632 $root_ra->get_log([$new], $last_rev, $last_rev,
4633 0, 0, 1, sub { });
4634 };
4635 next if $@;
4636 $new_urls->{$ra->{repos_root}}->{$new} =
4637 { ref_id => $ref_id,
4638 old_repo_id => $repo_id,
4639 old_path => $path };
4640 }
4641 }
4643 my @emptied;
4644 foreach my $url (keys %$new_urls) {
4645 # see if we can re-use an existing [svn-remote "repo_id"]
4646 # instead of creating a(n ugly) new section:
4647 my $repo_id = $root_repos->{$url} ||
4648 Git::SVN::sanitize_remote_name($url);
4650 my $fetch = $new_urls->{$url};
4651 foreach my $path (keys %$fetch) {
4652 my $x = $fetch->{$path};
4653 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
4654 my $pfx = "svn-remote.$x->{old_repo_id}";
4656 my $old_fetch = quotemeta("$x->{old_path}:".
4657 "refs/remotes/$x->{ref_id}");
4658 command_noisy(qw/config --unset/,
4659 "$pfx.fetch", '^'. $old_fetch . '$');
4660 delete $r->{$x->{old_repo_id}}->
4661 {fetch}->{$x->{old_path}};
4662 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
4663 command_noisy(qw/config --unset/,
4664 "$pfx.url");
4665 push @emptied, $x->{old_repo_id}
4666 }
4667 }
4668 }
4669 if (@emptied) {
4670 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
4671 "$ENV{GIT_DIR}/config";
4672 print STDERR <<EOF;
4673 The following [svn-remote] sections in your config file ($file) are empty
4674 and can be safely removed:
4675 EOF
4676 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
4677 }
4678 }
4680 sub migration_check {
4681 migrate_from_v0();
4682 migrate_from_v1();
4683 migrate_from_v2();
4684 minimize_connections() if $_minimize;
4685 }
4687 package Git::IndexInfo;
4688 use strict;
4689 use warnings;
4690 use Git qw/command_input_pipe command_close_pipe/;
4692 sub new {
4693 my ($class) = @_;
4694 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
4695 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
4696 }
4698 sub remove {
4699 my ($self, $path) = @_;
4700 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
4701 return ++$self->{nr};
4702 }
4703 undef;
4704 }
4706 sub update {
4707 my ($self, $mode, $hash, $path) = @_;
4708 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
4709 return ++$self->{nr};
4710 }
4711 undef;
4712 }
4714 sub DESTROY {
4715 my ($self) = @_;
4716 command_close_pipe($self->{gui}, $self->{ctx});
4717 }
4719 package Git::SVN::GlobSpec;
4720 use strict;
4721 use warnings;
4723 sub new {
4724 my ($class, $glob) = @_;
4725 my $re = $glob;
4726 $re =~ s!/+$!!g; # no need for trailing slashes
4727 my $nr = ($re =~ s!^(.*)\*(.*)$!\(\[^/\]+\)!g);
4728 my ($left, $right) = ($1, $2);
4729 if ($nr > 1) {
4730 die "Only one '*' wildcard expansion ",
4731 "is supported (got $nr): '$glob'\n";
4732 } elsif ($nr == 0) {
4733 die "One '*' is needed for glob: '$glob'\n";
4734 }
4735 $re = quotemeta($left) . $re . quotemeta($right);
4736 if (length $left && !($left =~ s!/+$!!g)) {
4737 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
4738 }
4739 if (length $right && !($right =~ s!^/+!!g)) {
4740 die "Missing leading '/' on right side of: '$glob' ($right)\n";
4741 }
4742 my $left_re = qr/^\/\Q$left\E(\/|$)/;
4743 bless { left => $left, right => $right, left_regex => $left_re,
4744 regex => qr/$re/, glob => $glob }, $class;
4745 }
4747 sub full_path {
4748 my ($self, $path) = @_;
4749 return (length $self->{left} ? "$self->{left}/" : '') .
4750 $path . (length $self->{right} ? "/$self->{right}" : '');
4751 }
4753 __END__
4755 Data structures:
4758 $remotes = { # returned by read_all_remotes()
4759 'svn' => {
4760 # svn-remote.svn.url=https://svn.musicpd.org
4761 url => 'https://svn.musicpd.org',
4762 # svn-remote.svn.fetch=mpd/trunk:trunk
4763 fetch => {
4764 'mpd/trunk' => 'trunk',
4765 },
4766 # svn-remote.svn.tags=mpd/tags/*:tags/*
4767 tags => {
4768 path => {
4769 left => 'mpd/tags',
4770 right => '',
4771 regex => qr!mpd/tags/([^/]+)$!,
4772 glob => 'tags/*',
4773 },
4774 ref => {
4775 left => 'tags',
4776 right => '',
4777 regex => qr!tags/([^/]+)$!,
4778 glob => 'tags/*',
4779 },
4780 }
4781 }
4782 };
4784 $log_entry hashref as returned by libsvn_log_entry()
4785 {
4786 log => 'whitespace-formatted log entry
4787 ', # trailing newline is preserved
4788 revision => '8', # integer
4789 date => '2004-02-24T17:01:44.108345Z', # commit date
4790 author => 'committer name'
4791 };
4794 # this is generated by generate_diff();
4795 @mods = array of diff-index line hashes, each element represents one line
4796 of diff-index output
4798 diff-index line ($m hash)
4799 {
4800 mode_a => first column of diff-index output, no leading ':',
4801 mode_b => second column of diff-index output,
4802 sha1_b => sha1sum of the final blob,
4803 chg => change type [MCRADT],
4804 file_a => original file name of a file (iff chg is 'C' or 'R')
4805 file_b => new/current file name of a file (any chg)
4806 }
4807 ;
4809 # retval of read_url_paths{,_all}();
4810 $l_map = {
4811 # repository root url
4812 'https://svn.musicpd.org' => {
4813 # repository path # GIT_SVN_ID
4814 'mpd/trunk' => 'trunk',
4815 'mpd/tags/0.11.5' => 'tags/0.11.5',
4816 },
4817 }
4819 Notes:
4820 I don't trust the each() function on unless I created %hash myself
4821 because the internal iterator may not have started at base.