![[tokkee]](http://tokkee.org/images/avatar.png){kind=avatar}
5515e3ea549fd16df5f851b8b3ffc1e7cc1e2c22
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $sha1 $sha1_short $_revision $_repository
8 $_q $_authors $_authors_prog %users/;
9 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
10 $VERSION = '@@GIT_VERSION@@';
12 # From which subdir have we been invoked?
13 my $cmd_dir_prefix = eval {
14 command_oneline([qw/rev-parse --show-prefix/], STDERR => 0)
15 } || '';
17 my $git_dir_user_set = 1 if defined $ENV{GIT_DIR};
18 $ENV{GIT_DIR} ||= '.git';
19 $Git::SVN::default_repo_id = 'svn';
20 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
21 $Git::SVN::Ra::_log_window_size = 100;
22 $Git::SVN::_minimize_url = 'unset';
24 $Git::SVN::Log::TZ = $ENV{TZ};
25 $ENV{TZ} = 'UTC';
26 $| = 1; # unbuffer STDOUT
28 sub fatal (@) { print STDERR "@_\n"; exit 1 }
29 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
30 require SVN::Ra;
31 require SVN::Delta;
32 if ($SVN::Core::VERSION lt '1.1.0') {
33 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)";
34 }
35 my $can_compress = eval { require Compress::Zlib; 1};
36 push @Git::SVN::Ra::ISA, 'SVN::Ra';
37 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
38 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
39 use Carp qw/croak/;
40 use Digest::MD5;
41 use IO::File qw//;
42 use File::Basename qw/dirname basename/;
43 use File::Path qw/mkpath/;
44 use File::Spec;
45 use File::Find;
46 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev/;
47 use IPC::Open3;
48 use Git;
50 BEGIN {
51 # import functions from Git into our packages, en masse
52 no strict 'refs';
53 foreach (qw/command command_oneline command_noisy command_output_pipe
54 command_input_pipe command_close_pipe
55 command_bidi_pipe command_close_bidi_pipe/) {
56 for my $package ( qw(SVN::Git::Editor SVN::Git::Fetcher
57 Git::SVN::Migration Git::SVN::Log Git::SVN),
58 __PACKAGE__) {
59 *{"${package}::$_"} = \&{"Git::$_"};
60 }
61 }
62 }
64 my ($SVN);
66 $sha1 = qr/[a-f\d]{40}/;
67 $sha1_short = qr/[a-f\d]{4,40}/;
68 my ($_stdin, $_help, $_edit,
69 $_message, $_file, $_branch_dest,
70 $_template, $_shared,
71 $_version, $_fetch_all, $_no_rebase, $_fetch_parent,
72 $_merge, $_strategy, $_dry_run, $_local,
73 $_prefix, $_no_checkout, $_url, $_verbose,
74 $_git_format, $_commit_url, $_tag);
75 $Git::SVN::_follow_parent = 1;
76 $_q ||= 0;
77 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
78 'config-dir=s' => \$Git::SVN::Ra::config_dir,
79 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache,
80 'ignore-paths=s' => \$SVN::Git::Fetcher::_ignore_regex );
81 my %fc_opts = ( 'follow-parent|follow!' => \$Git::SVN::_follow_parent,
82 'authors-file|A=s' => \$_authors,
83 'authors-prog=s' => \$_authors_prog,
84 'repack:i' => \$Git::SVN::_repack,
85 'noMetadata' => \$Git::SVN::_no_metadata,
86 'useSvmProps' => \$Git::SVN::_use_svm_props,
87 'useSvnsyncProps' => \$Git::SVN::_use_svnsync_props,
88 'log-window-size=i' => \$Git::SVN::Ra::_log_window_size,
89 'no-checkout' => \$_no_checkout,
90 'quiet|q+' => \$_q,
91 'repack-flags|repack-args|repack-opts=s' =>
92 \$Git::SVN::_repack_flags,
93 'use-log-author' => \$Git::SVN::_use_log_author,
94 'add-author-from' => \$Git::SVN::_add_author_from,
95 'localtime' => \$Git::SVN::_localtime,
96 %remote_opts );
98 my ($_trunk, @_tags, @_branches, $_stdlayout);
99 my %icv;
100 my %init_opts = ( 'template=s' => \$_template, 'shared:s' => \$_shared,
101 'trunk|T=s' => \$_trunk, 'tags|t=s@' => \@_tags,
102 'branches|b=s@' => \@_branches, 'prefix=s' => \$_prefix,
103 'stdlayout|s' => \$_stdlayout,
104 'minimize-url|m!' => \$Git::SVN::_minimize_url,
105 'no-metadata' => sub { $icv{noMetadata} = 1 },
106 'use-svm-props' => sub { $icv{useSvmProps} = 1 },
107 'use-svnsync-props' => sub { $icv{useSvnsyncProps} = 1 },
108 'rewrite-root=s' => sub { $icv{rewriteRoot} = $_[1] },
109 %remote_opts );
110 my %cmt_opts = ( 'edit|e' => \$_edit,
111 'rmdir' => \$SVN::Git::Editor::_rmdir,
112 'find-copies-harder' => \$SVN::Git::Editor::_find_copies_harder,
113 'l=i' => \$SVN::Git::Editor::_rename_limit,
114 'copy-similarity|C=i'=> \$SVN::Git::Editor::_cp_similarity
115 );
117 my %cmd = (
118 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
119 { 'revision|r=s' => \$_revision,
120 'fetch-all|all' => \$_fetch_all,
121 'parent|p' => \$_fetch_parent,
122 %fc_opts } ],
123 clone => [ \&cmd_clone, "Initialize and fetch revisions",
124 { 'revision|r=s' => \$_revision,
125 %fc_opts, %init_opts } ],
126 init => [ \&cmd_init, "Initialize a repo for tracking" .
127 " (requires URL argument)",
128 \%init_opts ],
129 'multi-init' => [ \&cmd_multi_init,
130 "Deprecated alias for ".
131 "'$0 init -T<trunk> -b<branches> -t<tags>'",
132 \%init_opts ],
133 dcommit => [ \&cmd_dcommit,
134 'Commit several diffs to merge with upstream',
135 { 'merge|m|M' => \$_merge,
136 'strategy|s=s' => \$_strategy,
137 'verbose|v' => \$_verbose,
138 'dry-run|n' => \$_dry_run,
139 'fetch-all|all' => \$_fetch_all,
140 'commit-url=s' => \$_commit_url,
141 'revision|r=i' => \$_revision,
142 'no-rebase' => \$_no_rebase,
143 %cmt_opts, %fc_opts } ],
144 branch => [ \&cmd_branch,
145 'Create a branch in the SVN repository',
146 { 'message|m=s' => \$_message,
147 'destination|d=s' => \$_branch_dest,
148 'dry-run|n' => \$_dry_run,
149 'tag|t' => \$_tag } ],
150 tag => [ sub { $_tag = 1; cmd_branch(@_) },
151 'Create a tag in the SVN repository',
152 { 'message|m=s' => \$_message,
153 'destination|d=s' => \$_branch_dest,
154 'dry-run|n' => \$_dry_run } ],
155 'set-tree' => [ \&cmd_set_tree,
156 "Set an SVN repository to a git tree-ish",
157 { 'stdin' => \$_stdin, %cmt_opts, %fc_opts, } ],
158 'create-ignore' => [ \&cmd_create_ignore,
159 'Create a .gitignore per svn:ignore',
160 { 'revision|r=i' => \$_revision
161 } ],
162 'propget' => [ \&cmd_propget,
163 'Print the value of a property on a file or directory',
164 { 'revision|r=i' => \$_revision } ],
165 'proplist' => [ \&cmd_proplist,
166 'List all properties of a file or directory',
167 { 'revision|r=i' => \$_revision } ],
168 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
169 { 'revision|r=i' => \$_revision
170 } ],
171 'show-externals' => [ \&cmd_show_externals, "Show svn:externals listings",
172 { 'revision|r=i' => \$_revision
173 } ],
174 'multi-fetch' => [ \&cmd_multi_fetch,
175 "Deprecated alias for $0 fetch --all",
176 { 'revision|r=s' => \$_revision, %fc_opts } ],
177 'migrate' => [ sub { },
178 # no-op, we automatically run this anyways,
179 'Migrate configuration/metadata/layout from
180 previous versions of git-svn',
181 { 'minimize' => \$Git::SVN::Migration::_minimize,
182 %remote_opts } ],
183 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
184 { 'limit=i' => \$Git::SVN::Log::limit,
185 'revision|r=s' => \$_revision,
186 'verbose|v' => \$Git::SVN::Log::verbose,
187 'incremental' => \$Git::SVN::Log::incremental,
188 'oneline' => \$Git::SVN::Log::oneline,
189 'show-commit' => \$Git::SVN::Log::show_commit,
190 'non-recursive' => \$Git::SVN::Log::non_recursive,
191 'authors-file|A=s' => \$_authors,
192 'color' => \$Git::SVN::Log::color,
193 'pager=s' => \$Git::SVN::Log::pager
194 } ],
195 'find-rev' => [ \&cmd_find_rev,
196 "Translate between SVN revision numbers and tree-ish",
197 {} ],
198 'rebase' => [ \&cmd_rebase, "Fetch and rebase your working directory",
199 { 'merge|m|M' => \$_merge,
200 'verbose|v' => \$_verbose,
201 'strategy|s=s' => \$_strategy,
202 'local|l' => \$_local,
203 'fetch-all|all' => \$_fetch_all,
204 'dry-run|n' => \$_dry_run,
205 %fc_opts } ],
206 'commit-diff' => [ \&cmd_commit_diff,
207 'Commit a diff between two trees',
208 { 'message|m=s' => \$_message,
209 'file|F=s' => \$_file,
210 'revision|r=s' => \$_revision,
211 %cmt_opts } ],
212 'info' => [ \&cmd_info,
213 "Show info about the latest SVN revision
214 on the current branch",
215 { 'url' => \$_url, } ],
216 'blame' => [ \&Git::SVN::Log::cmd_blame,
217 "Show what revision and author last modified each line of a file",
218 { 'git-format' => \$_git_format } ],
219 'reset' => [ \&cmd_reset,
220 "Undo fetches back to the specified SVN revision",
221 { 'revision|r=s' => \$_revision,
222 'parent|p' => \$_fetch_parent } ],
223 'gc' => [ \&cmd_gc,
224 "Compress unhandled.log files in .git/svn and remove " .
225 "index files in .git/svn",
226 {} ],
227 );
229 my $cmd;
230 for (my $i = 0; $i < @ARGV; $i++) {
231 if (defined $cmd{$ARGV[$i]}) {
232 $cmd = $ARGV[$i];
233 splice @ARGV, $i, 1;
234 last;
235 } elsif ($ARGV[$i] eq 'help') {
236 $cmd = $ARGV[$i+1];
237 usage(0);
238 }
239 };
241 # make sure we're always running at the top-level working directory
242 unless ($cmd && $cmd =~ /(?:clone|init|multi-init)$/) {
243 unless (-d $ENV{GIT_DIR}) {
244 if ($git_dir_user_set) {
245 die "GIT_DIR=$ENV{GIT_DIR} explicitly set, ",
246 "but it is not a directory\n";
247 }
248 my $git_dir = delete $ENV{GIT_DIR};
249 my $cdup = undef;
250 git_cmd_try {
251 $cdup = command_oneline(qw/rev-parse --show-cdup/);
252 $git_dir = '.' unless ($cdup);
253 chomp $cdup if ($cdup);
254 $cdup = "." unless ($cdup && length $cdup);
255 } "Already at toplevel, but $git_dir not found\n";
256 chdir $cdup or die "Unable to chdir up to '$cdup'\n";
257 unless (-d $git_dir) {
258 die "$git_dir still not found after going to ",
259 "'$cdup'\n";
260 }
261 $ENV{GIT_DIR} = $git_dir;
262 }
263 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
264 }
266 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
268 read_repo_config(\%opts);
269 if ($cmd && ($cmd eq 'log' || $cmd eq 'blame')) {
270 Getopt::Long::Configure('pass_through');
271 }
272 my $rv = GetOptions(%opts, 'help|H|h' => \$_help, 'version|V' => \$_version,
273 'minimize-connections' => \$Git::SVN::Migration::_minimize,
274 'id|i=s' => \$Git::SVN::default_ref_id,
275 'svn-remote|remote|R=s' => sub {
276 $Git::SVN::no_reuse_existing = 1;
277 $Git::SVN::default_repo_id = $_[1] });
278 exit 1 if (!$rv && $cmd && $cmd ne 'log');
280 usage(0) if $_help;
281 version() if $_version;
282 usage(1) unless defined $cmd;
283 load_authors() if $_authors;
284 if (defined $_authors_prog) {
285 $_authors_prog = "'" . File::Spec->rel2abs($_authors_prog) . "'";
286 }
288 unless ($cmd =~ /^(?:clone|init|multi-init|commit-diff)$/) {
289 Git::SVN::Migration::migration_check();
290 }
291 Git::SVN::init_vars();
292 eval {
293 Git::SVN::verify_remotes_sanity();
294 $cmd{$cmd}->[0]->(@ARGV);
295 };
296 fatal $@ if $@;
297 post_fetch_checkout();
298 exit 0;
300 ####################### primary functions ######################
301 sub usage {
302 my $exit = shift || 0;
303 my $fd = $exit ? \*STDERR : \*STDOUT;
304 print $fd <<"";
305 git-svn - bidirectional operations between a single Subversion tree and git
306 Usage: git svn <command> [options] [arguments]\n
308 print $fd "Available commands:\n" unless $cmd;
310 foreach (sort keys %cmd) {
311 next if $cmd && $cmd ne $_;
312 next if /^multi-/; # don't show deprecated commands
313 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
314 foreach (sort keys %{$cmd{$_}->[2]}) {
315 # mixed-case options are for .git/config only
316 next if /[A-Z]/ && /^[a-z]+$/i;
317 # prints out arguments as they should be passed:
318 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
319 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
320 "--$_" : "-$_" }
321 split /\|/,$_)," $x\n";
322 }
323 }
324 print $fd <<"";
325 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
326 arbitrary identifier if you're tracking multiple SVN branches/repositories in
327 one git repository and want to keep them separate. See git-svn(1) for more
328 information.
330 exit $exit;
331 }
333 sub version {
334 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
335 exit 0;
336 }
338 sub do_git_init_db {
339 unless (-d $ENV{GIT_DIR}) {
340 my @init_db = ('init');
341 push @init_db, "--template=$_template" if defined $_template;
342 if (defined $_shared) {
343 if ($_shared =~ /[a-z]/) {
344 push @init_db, "--shared=$_shared";
345 } else {
346 push @init_db, "--shared";
347 }
348 }
349 command_noisy(@init_db);
350 $_repository = Git->repository(Repository => ".git");
351 }
352 command_noisy('config', 'core.autocrlf', 'false');
353 my $set;
354 my $pfx = "svn-remote.$Git::SVN::default_repo_id";
355 foreach my $i (keys %icv) {
356 die "'$set' and '$i' cannot both be set\n" if $set;
357 next unless defined $icv{$i};
358 command_noisy('config', "$pfx.$i", $icv{$i});
359 $set = $i;
360 }
361 my $ignore_regex = \$SVN::Git::Fetcher::_ignore_regex;
362 command_noisy('config', "$pfx.ignore-paths", $$ignore_regex)
363 if defined $$ignore_regex;
364 }
366 sub init_subdir {
367 my $repo_path = shift or return;
368 mkpath([$repo_path]) unless -d $repo_path;
369 chdir $repo_path or die "Couldn't chdir to $repo_path: $!\n";
370 $ENV{GIT_DIR} = '.git';
371 $_repository = Git->repository(Repository => $ENV{GIT_DIR});
372 }
374 sub cmd_clone {
375 my ($url, $path) = @_;
376 if (!defined $path &&
377 (defined $_trunk || @_branches || @_tags ||
378 defined $_stdlayout) &&
379 $url !~ m#^[a-z\+]+://#) {
380 $path = $url;
381 }
382 $path = basename($url) if !defined $path || !length $path;
383 cmd_init($url, $path);
384 Git::SVN::fetch_all($Git::SVN::default_repo_id);
385 command_oneline('config', 'svn.authorsfile', $_authors) if $_authors;
386 }
388 sub cmd_init {
389 if (defined $_stdlayout) {
390 $_trunk = 'trunk' if (!defined $_trunk);
391 @_tags = 'tags' if (! @_tags);
392 @_branches = 'branches' if (! @_branches);
393 }
394 if (defined $_trunk || @_branches || @_tags) {
395 return cmd_multi_init(@_);
396 }
397 my $url = shift or die "SVN repository location required ",
398 "as a command-line argument\n";
399 $url = canonicalize_url($url);
400 init_subdir(@_);
401 do_git_init_db();
403 if ($Git::SVN::_minimize_url eq 'unset') {
404 $Git::SVN::_minimize_url = 0;
405 }
407 Git::SVN->init($url);
408 }
410 sub cmd_fetch {
411 if (grep /^\d+=./, @_) {
412 die "'<rev>=<commit>' fetch arguments are ",
413 "no longer supported.\n";
414 }
415 my ($remote) = @_;
416 if (@_ > 1) {
417 die "Usage: $0 fetch [--all] [--parent] [svn-remote]\n";
418 }
419 if ($_fetch_parent) {
420 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
421 unless ($gs) {
422 die "Unable to determine upstream SVN information from ",
423 "working tree history\n";
424 }
425 # just fetch, don't checkout.
426 $_no_checkout = 'true';
427 $_fetch_all ? $gs->fetch_all : $gs->fetch;
428 } elsif ($_fetch_all) {
429 cmd_multi_fetch();
430 } else {
431 $remote ||= $Git::SVN::default_repo_id;
432 Git::SVN::fetch_all($remote, Git::SVN::read_all_remotes());
433 }
434 }
436 sub cmd_set_tree {
437 my (@commits) = @_;
438 if ($_stdin || !@commits) {
439 print "Reading from stdin...\n";
440 @commits = ();
441 while (<STDIN>) {
442 if (/\b($sha1_short)\b/o) {
443 unshift @commits, $1;
444 }
445 }
446 }
447 my @revs;
448 foreach my $c (@commits) {
449 my @tmp = command('rev-parse',$c);
450 if (scalar @tmp == 1) {
451 push @revs, $tmp[0];
452 } elsif (scalar @tmp > 1) {
453 push @revs, reverse(command('rev-list',@tmp));
454 } else {
455 fatal "Failed to rev-parse $c";
456 }
457 }
458 my $gs = Git::SVN->new;
459 my ($r_last, $cmt_last) = $gs->last_rev_commit;
460 $gs->fetch;
461 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
462 fatal "There are new revisions that were fetched ",
463 "and need to be merged (or acknowledged) ",
464 "before committing.\nlast rev: $r_last\n",
465 " current: $gs->{last_rev}";
466 }
467 $gs->set_tree($_) foreach @revs;
468 print "Done committing ",scalar @revs," revisions to SVN\n";
469 unlink $gs->{index};
470 }
472 sub cmd_dcommit {
473 my $head = shift;
474 git_cmd_try { command_oneline(qw/diff-index --quiet HEAD/) }
475 'Cannot dcommit with a dirty index. Commit your changes first, '
476 . "or stash them with `git stash'.\n";
477 $head ||= 'HEAD';
479 my $old_head;
480 if ($head ne 'HEAD') {
481 $old_head = eval {
482 command_oneline([qw/symbolic-ref -q HEAD/])
483 };
484 if ($old_head) {
485 $old_head =~ s{^refs/heads/}{};
486 } else {
487 $old_head = eval { command_oneline(qw/rev-parse HEAD/) };
488 }
489 command(['checkout', $head], STDERR => 0);
490 }
492 my @refs;
493 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD', \@refs);
494 unless ($gs) {
495 die "Unable to determine upstream SVN information from ",
496 "$head history.\nPerhaps the repository is empty.";
497 }
499 if (defined $_commit_url) {
500 $url = $_commit_url;
501 } else {
502 $url = eval { command_oneline('config', '--get',
503 "svn-remote.$gs->{repo_id}.commiturl") };
504 if (!$url) {
505 $url = $gs->full_url
506 }
507 }
509 my $last_rev = $_revision if defined $_revision;
510 if ($url) {
511 print "Committing to $url ...\n";
512 }
513 my ($linear_refs, $parents) = linearize_history($gs, \@refs);
514 if ($_no_rebase && scalar(@$linear_refs) > 1) {
515 warn "Attempting to commit more than one change while ",
516 "--no-rebase is enabled.\n",
517 "If these changes depend on each other, re-running ",
518 "without --no-rebase may be required."
519 }
520 my $expect_url = $url;
521 Git::SVN::remove_username($expect_url);
522 while (1) {
523 my $d = shift @$linear_refs or last;
524 unless (defined $last_rev) {
525 (undef, $last_rev, undef) = cmt_metadata("$d~1");
526 unless (defined $last_rev) {
527 fatal "Unable to extract revision information ",
528 "from commit $d~1";
529 }
530 }
531 if ($_dry_run) {
532 print "diff-tree $d~1 $d\n";
533 } else {
534 my $cmt_rev;
535 my %ed_opts = ( r => $last_rev,
536 log => get_commit_entry($d)->{log},
537 ra => Git::SVN::Ra->new($url),
538 config => SVN::Core::config_get_config(
539 $Git::SVN::Ra::config_dir
540 ),
541 tree_a => "$d~1",
542 tree_b => $d,
543 editor_cb => sub {
544 print "Committed r$_[0]\n";
545 $cmt_rev = $_[0];
546 },
547 svn_path => '');
548 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
549 print "No changes\n$d~1 == $d\n";
550 } elsif ($parents->{$d} && @{$parents->{$d}}) {
551 $gs->{inject_parents_dcommit}->{$cmt_rev} =
552 $parents->{$d};
553 }
554 $_fetch_all ? $gs->fetch_all : $gs->fetch;
555 $last_rev = $cmt_rev;
556 next if $_no_rebase;
558 # we always want to rebase against the current HEAD,
559 # not any head that was passed to us
560 my @diff = command('diff-tree', $d,
561 $gs->refname, '--');
562 my @finish;
563 if (@diff) {
564 @finish = rebase_cmd();
565 print STDERR "W: $d and ", $gs->refname,
566 " differ, using @finish:\n",
567 join("\n", @diff), "\n";
568 } else {
569 print "No changes between current HEAD and ",
570 $gs->refname,
571 "\nResetting to the latest ",
572 $gs->refname, "\n";
573 @finish = qw/reset --mixed/;
574 }
575 command_noisy(@finish, $gs->refname);
576 if (@diff) {
577 @refs = ();
578 my ($url_, $rev_, $uuid_, $gs_) =
579 working_head_info('HEAD', \@refs);
580 my ($linear_refs_, $parents_) =
581 linearize_history($gs_, \@refs);
582 if (scalar(@$linear_refs) !=
583 scalar(@$linear_refs_)) {
584 fatal "# of revisions changed ",
585 "\nbefore:\n",
586 join("\n", @$linear_refs),
587 "\n\nafter:\n",
588 join("\n", @$linear_refs_), "\n",
589 'If you are attempting to commit ',
590 "merges, try running:\n\t",
591 'git rebase --interactive',
592 '--preserve-merges ',
593 $gs->refname,
594 "\nBefore dcommitting";
595 }
596 if ($url_ ne $expect_url) {
597 fatal "URL mismatch after rebase: ",
598 "$url_ != $expect_url";
599 }
600 if ($uuid_ ne $uuid) {
601 fatal "uuid mismatch after rebase: ",
602 "$uuid_ != $uuid";
603 }
604 # remap parents
605 my (%p, @l, $i);
606 for ($i = 0; $i < scalar @$linear_refs; $i++) {
607 my $new = $linear_refs_->[$i] or next;
608 $p{$new} =
609 $parents->{$linear_refs->[$i]};
610 push @l, $new;
611 }
612 $parents = \%p;
613 $linear_refs = \@l;
614 }
615 }
616 }
618 if ($old_head) {
619 my $new_head = command_oneline(qw/rev-parse HEAD/);
620 my $new_is_symbolic = eval {
621 command_oneline(qw/symbolic-ref -q HEAD/);
622 };
623 if ($new_is_symbolic) {
624 print "dcommitted the branch ", $head, "\n";
625 } else {
626 print "dcommitted on a detached HEAD because you gave ",
627 "a revision argument.\n",
628 "The rewritten commit is: ", $new_head, "\n";
629 }
630 command(['checkout', $old_head], STDERR => 0);
631 }
633 unlink $gs->{index};
634 }
636 sub cmd_branch {
637 my ($branch_name, $head) = @_;
639 unless (defined $branch_name && length $branch_name) {
640 die(($_tag ? "tag" : "branch") . " name required\n");
641 }
642 $head ||= 'HEAD';
644 my ($src, $rev, undef, $gs) = working_head_info($head);
646 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
647 my $allglobs = $remote->{ $_tag ? 'tags' : 'branches' };
648 my $glob;
649 if ($#{$allglobs} == 0) {
650 $glob = $allglobs->[0];
651 } else {
652 unless(defined $_branch_dest) {
653 die "Multiple ",
654 $_tag ? "tag" : "branch",
655 " paths defined for Subversion repository.\n",
656 "You must specify where you want to create the ",
657 $_tag ? "tag" : "branch",
658 " with the --destination argument.\n";
659 }
660 foreach my $g (@{$allglobs}) {
661 # SVN::Git::Editor could probably be moved to Git.pm..
662 my $re = SVN::Git::Editor::glob2pat($g->{path}->{left});
663 if ($_branch_dest =~ /$re/) {
664 $glob = $g;
665 last;
666 }
667 }
668 unless (defined $glob) {
669 my $dest_re = qr/\b\Q$_branch_dest\E\b/;
670 foreach my $g (@{$allglobs}) {
671 $g->{path}->{left} =~ /$dest_re/ or next;
672 if (defined $glob) {
673 die "Ambiguous destination: ",
674 $_branch_dest, "\nmatches both '",
675 $glob->{path}->{left}, "' and '",
676 $g->{path}->{left}, "'\n";
677 }
678 $glob = $g;
679 }
680 unless (defined $glob) {
681 die "Unknown ",
682 $_tag ? "tag" : "branch",
683 " destination $_branch_dest\n";
684 }
685 }
686 }
687 my ($lft, $rgt) = @{ $glob->{path} }{qw/left right/};
688 my $dst = join '/', $remote->{url}, $lft, $branch_name, ($rgt || ());
690 my $ctx = SVN::Client->new(
691 auth => Git::SVN::Ra::_auth_providers(),
692 log_msg => sub {
693 ${ $_[0] } = defined $_message
694 ? $_message
695 : 'Create ' . ($_tag ? 'tag ' : 'branch ' )
696 . $branch_name;
697 },
698 );
700 eval {
701 $ctx->ls($dst, 'HEAD', 0);
702 } and die "branch ${branch_name} already exists\n";
704 print "Copying ${src} at r${rev} to ${dst}...\n";
705 $ctx->copy($src, $rev, $dst)
706 unless $_dry_run;
708 $gs->fetch_all;
709 }
711 sub cmd_find_rev {
712 my $revision_or_hash = shift or die "SVN or git revision required ",
713 "as a command-line argument\n";
714 my $result;
715 if ($revision_or_hash =~ /^r\d+$/) {
716 my $head = shift;
717 $head ||= 'HEAD';
718 my @refs;
719 my (undef, undef, $uuid, $gs) = working_head_info($head, \@refs);
720 unless ($gs) {
721 die "Unable to determine upstream SVN information from ",
722 "$head history\n";
723 }
724 my $desired_revision = substr($revision_or_hash, 1);
725 $result = $gs->rev_map_get($desired_revision, $uuid);
726 } else {
727 my (undef, $rev, undef) = cmt_metadata($revision_or_hash);
728 $result = $rev;
729 }
730 print "$result\n" if $result;
731 }
733 sub cmd_rebase {
734 command_noisy(qw/update-index --refresh/);
735 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
736 unless ($gs) {
737 die "Unable to determine upstream SVN information from ",
738 "working tree history\n";
739 }
740 if ($_dry_run) {
741 print "Remote Branch: " . $gs->refname . "\n";
742 print "SVN URL: " . $url . "\n";
743 return;
744 }
745 if (command(qw/diff-index HEAD --/)) {
746 print STDERR "Cannot rebase with uncommited changes:\n";
747 command_noisy('status');
748 exit 1;
749 }
750 unless ($_local) {
751 # rebase will checkout for us, so no need to do it explicitly
752 $_no_checkout = 'true';
753 $_fetch_all ? $gs->fetch_all : $gs->fetch;
754 }
755 command_noisy(rebase_cmd(), $gs->refname);
756 }
758 sub cmd_show_ignore {
759 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
760 $gs ||= Git::SVN->new;
761 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
762 $gs->prop_walk($gs->{path}, $r, sub {
763 my ($gs, $path, $props) = @_;
764 print STDOUT "\n# $path\n";
765 my $s = $props->{'svn:ignore'} or return;
766 $s =~ s/[\r\n]+/\n/g;
767 $s =~ s/^\n+//;
768 chomp $s;
769 $s =~ s#^#$path#gm;
770 print STDOUT "$s\n";
771 });
772 }
774 sub cmd_show_externals {
775 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
776 $gs ||= Git::SVN->new;
777 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
778 $gs->prop_walk($gs->{path}, $r, sub {
779 my ($gs, $path, $props) = @_;
780 print STDOUT "\n# $path\n";
781 my $s = $props->{'svn:externals'} or return;
782 $s =~ s/[\r\n]+/\n/g;
783 chomp $s;
784 $s =~ s#^#$path#gm;
785 print STDOUT "$s\n";
786 });
787 }
789 sub cmd_create_ignore {
790 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
791 $gs ||= Git::SVN->new;
792 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
793 $gs->prop_walk($gs->{path}, $r, sub {
794 my ($gs, $path, $props) = @_;
795 # $path is of the form /path/to/dir/
796 $path = '.' . $path;
797 # SVN can have attributes on empty directories,
798 # which git won't track
799 mkpath([$path]) unless -d $path;
800 my $ignore = $path . '.gitignore';
801 my $s = $props->{'svn:ignore'} or return;
802 open(GITIGNORE, '>', $ignore)
803 or fatal("Failed to open `$ignore' for writing: $!");
804 $s =~ s/[\r\n]+/\n/g;
805 $s =~ s/^\n+//;
806 chomp $s;
807 # Prefix all patterns so that the ignore doesn't apply
808 # to sub-directories.
809 $s =~ s#^#/#gm;
810 print GITIGNORE "$s\n";
811 close(GITIGNORE)
812 or fatal("Failed to close `$ignore': $!");
813 command_noisy('add', '-f', $ignore);
814 });
815 }
817 sub canonicalize_path {
818 my ($path) = @_;
819 my $dot_slash_added = 0;
820 if (substr($path, 0, 1) ne "/") {
821 $path = "./" . $path;
822 $dot_slash_added = 1;
823 }
824 # File::Spec->canonpath doesn't collapse x/../y into y (for a
825 # good reason), so let's do this manually.
826 $path =~ s#/+#/#g;
827 $path =~ s#/\.(?:/|$)#/#g;
828 $path =~ s#/[^/]+/\.\.##g;
829 $path =~ s#/$##g;
830 $path =~ s#^\./## if $dot_slash_added;
831 $path =~ s#^/##;
832 $path =~ s#^\.$##;
833 return $path;
834 }
836 sub canonicalize_url {
837 my ($url) = @_;
838 $url =~ s#^([^:]+://[^/]*/)(.*)$#$1 . canonicalize_path($2)#e;
839 return $url;
840 }
842 # get_svnprops(PATH)
843 # ------------------
844 # Helper for cmd_propget and cmd_proplist below.
845 sub get_svnprops {
846 my $path = shift;
847 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
848 $gs ||= Git::SVN->new;
850 # prefix THE PATH by the sub-directory from which the user
851 # invoked us.
852 $path = $cmd_dir_prefix . $path;
853 fatal("No such file or directory: $path") unless -e $path;
854 my $is_dir = -d $path ? 1 : 0;
855 $path = $gs->{path} . '/' . $path;
857 # canonicalize the path (otherwise libsvn will abort or fail to
858 # find the file)
859 $path = canonicalize_path($path);
861 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
862 my $props;
863 if ($is_dir) {
864 (undef, undef, $props) = $gs->ra->get_dir($path, $r);
865 }
866 else {
867 (undef, $props) = $gs->ra->get_file($path, $r, undef);
868 }
869 return $props;
870 }
872 # cmd_propget (PROP, PATH)
873 # ------------------------
874 # Print the SVN property PROP for PATH.
875 sub cmd_propget {
876 my ($prop, $path) = @_;
877 $path = '.' if not defined $path;
878 usage(1) if not defined $prop;
879 my $props = get_svnprops($path);
880 if (not defined $props->{$prop}) {
881 fatal("`$path' does not have a `$prop' SVN property.");
882 }
883 print $props->{$prop} . "\n";
884 }
886 # cmd_proplist (PATH)
887 # -------------------
888 # Print the list of SVN properties for PATH.
889 sub cmd_proplist {
890 my $path = shift;
891 $path = '.' if not defined $path;
892 my $props = get_svnprops($path);
893 print "Properties on '$path':\n";
894 foreach (sort keys %{$props}) {
895 print " $_\n";
896 }
897 }
899 sub cmd_multi_init {
900 my $url = shift;
901 unless (defined $_trunk || @_branches || @_tags) {
902 usage(1);
903 }
905 $_prefix = '' unless defined $_prefix;
906 if (defined $url) {
907 $url = canonicalize_url($url);
908 init_subdir(@_);
909 }
910 do_git_init_db();
911 if (defined $_trunk) {
912 my $trunk_ref = 'refs/remotes/' . $_prefix . 'trunk';
913 # try both old-style and new-style lookups:
914 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
915 unless ($gs_trunk) {
916 my ($trunk_url, $trunk_path) =
917 complete_svn_url($url, $_trunk);
918 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
919 undef, $trunk_ref);
920 }
921 }
922 return unless @_branches || @_tags;
923 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
924 foreach my $path (@_branches) {
925 complete_url_ls_init($ra, $path, '--branches/-b', $_prefix);
926 }
927 foreach my $path (@_tags) {
928 complete_url_ls_init($ra, $path, '--tags/-t', $_prefix.'tags/');
929 }
930 }
932 sub cmd_multi_fetch {
933 my $remotes = Git::SVN::read_all_remotes();
934 foreach my $repo_id (sort keys %$remotes) {
935 if ($remotes->{$repo_id}->{url}) {
936 Git::SVN::fetch_all($repo_id, $remotes);
937 }
938 }
939 }
941 # this command is special because it requires no metadata
942 sub cmd_commit_diff {
943 my ($ta, $tb, $url) = @_;
944 my $usage = "Usage: $0 commit-diff -r<revision> ".
945 "<tree-ish> <tree-ish> [<URL>]";
946 fatal($usage) if (!defined $ta || !defined $tb);
947 my $svn_path = '';
948 if (!defined $url) {
949 my $gs = eval { Git::SVN->new };
950 if (!$gs) {
951 fatal("Needed URL or usable git-svn --id in ",
952 "the command-line\n", $usage);
953 }
954 $url = $gs->{url};
955 $svn_path = $gs->{path};
956 }
957 unless (defined $_revision) {
958 fatal("-r|--revision is a required argument\n", $usage);
959 }
960 if (defined $_message && defined $_file) {
961 fatal("Both --message/-m and --file/-F specified ",
962 "for the commit message.\n",
963 "I have no idea what you mean");
964 }
965 if (defined $_file) {
966 $_message = file_to_s($_file);
967 } else {
968 $_message ||= get_commit_entry($tb)->{log};
969 }
970 my $ra ||= Git::SVN::Ra->new($url);
971 my $r = $_revision;
972 if ($r eq 'HEAD') {
973 $r = $ra->get_latest_revnum;
974 } elsif ($r !~ /^\d+$/) {
975 die "revision argument: $r not understood by git-svn\n";
976 }
977 my %ed_opts = ( r => $r,
978 log => $_message,
979 ra => $ra,
980 tree_a => $ta,
981 tree_b => $tb,
982 editor_cb => sub { print "Committed r$_[0]\n" },
983 svn_path => $svn_path );
984 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
985 print "No changes\n$ta == $tb\n";
986 }
987 }
989 sub escape_uri_only {
990 my ($uri) = @_;
991 my @tmp;
992 foreach (split m{/}, $uri) {
993 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
994 push @tmp, $_;
995 }
996 join('/', @tmp);
997 }
999 sub escape_url {
1000 my ($url) = @_;
1001 if ($url =~ m#^([^:]+)://([^/]*)(.*)$#) {
1002 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
1003 $url = "$scheme://$domain$uri";
1004 }
1005 $url;
1006 }
1008 sub cmd_info {
1009 my $path = canonicalize_path(defined($_[0]) ? $_[0] : ".");
1010 my $fullpath = canonicalize_path($cmd_dir_prefix . $path);
1011 if (exists $_[1]) {
1012 die "Too many arguments specified\n";
1013 }
1015 my ($file_type, $diff_status) = find_file_type_and_diff_status($path);
1017 if (!$file_type && !$diff_status) {
1018 print STDERR "svn: '$path' is not under version control\n";
1019 exit 1;
1020 }
1022 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1023 unless ($gs) {
1024 die "Unable to determine upstream SVN information from ",
1025 "working tree history\n";
1026 }
1028 # canonicalize_path() will return "" to make libsvn 1.5.x happy,
1029 $path = "." if $path eq "";
1031 my $full_url = $url . ($fullpath eq "" ? "" : "/$fullpath");
1033 if ($_url) {
1034 print escape_url($full_url), "\n";
1035 return;
1036 }
1038 my $result = "Path: $path\n";
1039 $result .= "Name: " . basename($path) . "\n" if $file_type ne "dir";
1040 $result .= "URL: " . escape_url($full_url) . "\n";
1042 eval {
1043 my $repos_root = $gs->repos_root;
1044 Git::SVN::remove_username($repos_root);
1045 $result .= "Repository Root: " . escape_url($repos_root) . "\n";
1046 };
1047 if ($@) {
1048 $result .= "Repository Root: (offline)\n";
1049 }
1050 $result .= "Repository UUID: $uuid\n" unless $diff_status eq "A" &&
1051 ($SVN::Core::VERSION le '1.5.4' || $file_type ne "dir");
1052 $result .= "Revision: " . ($diff_status eq "A" ? 0 : $rev) . "\n";
1054 $result .= "Node Kind: " .
1055 ($file_type eq "dir" ? "directory" : "file") . "\n";
1057 my $schedule = $diff_status eq "A"
1058 ? "add"
1059 : ($diff_status eq "D" ? "delete" : "normal");
1060 $result .= "Schedule: $schedule\n";
1062 if ($diff_status eq "A") {
1063 print $result, "\n";
1064 return;
1065 }
1067 my ($lc_author, $lc_rev, $lc_date_utc);
1068 my @args = Git::SVN::Log::git_svn_log_cmd($rev, $rev, "--", $fullpath);
1069 my $log = command_output_pipe(@args);
1070 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
1071 while (<$log>) {
1072 if (/^${esc_color}author (.+) <[^>]+> (\d+) ([\-\+]?\d+)$/o) {
1073 $lc_author = $1;
1074 $lc_date_utc = Git::SVN::Log::parse_git_date($2, $3);
1075 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
1076 (undef, $lc_rev, undef) = ::extract_metadata($1);
1077 }
1078 }
1079 close $log;
1081 Git::SVN::Log::set_local_timezone();
1083 $result .= "Last Changed Author: $lc_author\n";
1084 $result .= "Last Changed Rev: $lc_rev\n";
1085 $result .= "Last Changed Date: " .
1086 Git::SVN::Log::format_svn_date($lc_date_utc) . "\n";
1088 if ($file_type ne "dir") {
1089 my $text_last_updated_date =
1090 ($diff_status eq "D" ? $lc_date_utc : (stat $path)[9]);
1091 $result .=
1092 "Text Last Updated: " .
1093 Git::SVN::Log::format_svn_date($text_last_updated_date) .
1094 "\n";
1095 my $checksum;
1096 if ($diff_status eq "D") {
1097 my ($fh, $ctx) =
1098 command_output_pipe(qw(cat-file blob), "HEAD:$path");
1099 if ($file_type eq "link") {
1100 my $file_name = <$fh>;
1101 $checksum = md5sum("link $file_name");
1102 } else {
1103 $checksum = md5sum($fh);
1104 }
1105 command_close_pipe($fh, $ctx);
1106 } elsif ($file_type eq "link") {
1107 my $file_name =
1108 command(qw(cat-file blob), "HEAD:$path");
1109 $checksum =
1110 md5sum("link " . $file_name);
1111 } else {
1112 open FILE, "<", $path or die $!;
1113 $checksum = md5sum(\*FILE);
1114 close FILE or die $!;
1115 }
1116 $result .= "Checksum: " . $checksum . "\n";
1117 }
1119 print $result, "\n";
1120 }
1122 sub cmd_reset {
1123 my $target = shift || $_revision or die "SVN revision required\n";
1124 $target = $1 if $target =~ /^r(\d+)$/;
1125 $target =~ /^\d+$/ or die "Numeric SVN revision expected\n";
1126 my ($url, $rev, $uuid, $gs) = working_head_info('HEAD');
1127 unless ($gs) {
1128 die "Unable to determine upstream SVN information from ".
1129 "history\n";
1130 }
1131 my ($r, $c) = $gs->find_rev_before($target, not $_fetch_parent);
1132 $gs->rev_map_set($r, $c, 'reset', $uuid);
1133 print "r$r = $c ($gs->{ref_id})\n";
1134 }
1136 sub cmd_gc {
1137 if (!$can_compress) {
1138 warn "Compress::Zlib could not be found; unhandled.log " .
1139 "files will not be compressed.\n";
1140 }
1141 find({ wanted => \&gc_directory, no_chdir => 1}, "$ENV{GIT_DIR}/svn");
1142 }
1144 ########################### utility functions #########################
1146 sub rebase_cmd {
1147 my @cmd = qw/rebase/;
1148 push @cmd, '-v' if $_verbose;
1149 push @cmd, qw/--merge/ if $_merge;
1150 push @cmd, "--strategy=$_strategy" if $_strategy;
1151 @cmd;
1152 }
1154 sub post_fetch_checkout {
1155 return if $_no_checkout;
1156 my $gs = $Git::SVN::_head or return;
1157 return if verify_ref('refs/heads/master^0');
1159 # look for "trunk" ref if it exists
1160 my $remote = Git::SVN::read_all_remotes()->{$gs->{repo_id}};
1161 my $fetch = $remote->{fetch};
1162 if ($fetch) {
1163 foreach my $p (keys %$fetch) {
1164 basename($fetch->{$p}) eq 'trunk' or next;
1165 $gs = Git::SVN->new($fetch->{$p}, $gs->{repo_id}, $p);
1166 last;
1167 }
1168 }
1170 my $valid_head = verify_ref('HEAD^0');
1171 command_noisy(qw(update-ref refs/heads/master), $gs->refname);
1172 return if ($valid_head || !verify_ref('HEAD^0'));
1174 return if $ENV{GIT_DIR} !~ m#^(?:.*/)?\.git$#;
1175 my $index = $ENV{GIT_INDEX_FILE} || "$ENV{GIT_DIR}/index";
1176 return if -f $index;
1178 return if command_oneline(qw/rev-parse --is-inside-work-tree/) eq 'false';
1179 return if command_oneline(qw/rev-parse --is-inside-git-dir/) eq 'true';
1180 command_noisy(qw/read-tree -m -u -v HEAD HEAD/);
1181 print STDERR "Checked out HEAD:\n ",
1182 $gs->full_url, " r", $gs->last_rev, "\n";
1183 }
1185 sub complete_svn_url {
1186 my ($url, $path) = @_;
1187 $path =~ s#/+$##;
1188 if ($path !~ m#^[a-z\+]+://#) {
1189 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
1190 fatal("E: '$path' is not a complete URL ",
1191 "and a separate URL is not specified");
1192 }
1193 return ($url, $path);
1194 }
1195 return ($path, '');
1196 }
1198 sub complete_url_ls_init {
1199 my ($ra, $repo_path, $switch, $pfx) = @_;
1200 unless ($repo_path) {
1201 print STDERR "W: $switch not specified\n";
1202 return;
1203 }
1204 $repo_path =~ s#/+$##;
1205 if ($repo_path =~ m#^[a-z\+]+://#) {
1206 $ra = Git::SVN::Ra->new($repo_path);
1207 $repo_path = '';
1208 } else {
1209 $repo_path =~ s#^/+##;
1210 unless ($ra) {
1211 fatal("E: '$repo_path' is not a complete URL ",
1212 "and a separate URL is not specified");
1213 }
1214 }
1215 my $url = $ra->{url};
1216 my $gs = Git::SVN->init($url, undef, undef, undef, 1);
1217 my $k = "svn-remote.$gs->{repo_id}.url";
1218 my $orig_url = eval { command_oneline(qw/config --get/, $k) };
1219 if ($orig_url && ($orig_url ne $gs->{url})) {
1220 die "$k already set: $orig_url\n",
1221 "wanted to set to: $gs->{url}\n";
1222 }
1223 command_oneline('config', $k, $gs->{url}) unless $orig_url;
1224 my $remote_path = "$gs->{path}/$repo_path";
1225 $remote_path =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1226 $remote_path =~ s#/+#/#g;
1227 $remote_path =~ s#^/##g;
1228 $remote_path .= "/*" if $remote_path !~ /\*/;
1229 my ($n) = ($switch =~ /^--(\w+)/);
1230 if (length $pfx && $pfx !~ m#/$#) {
1231 die "--prefix='$pfx' must have a trailing slash '/'\n";
1232 }
1233 command_noisy('config',
1234 '--add',
1235 "svn-remote.$gs->{repo_id}.$n",
1236 "$remote_path:refs/remotes/$pfx*" .
1237 ('/*' x (($remote_path =~ tr/*/*/) - 1)) );
1238 }
1240 sub verify_ref {
1241 my ($ref) = @_;
1242 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
1243 { STDERR => 0 }); };
1244 }
1246 sub get_tree_from_treeish {
1247 my ($treeish) = @_;
1248 # $treeish can be a symbolic ref, too:
1249 my $type = command_oneline(qw/cat-file -t/, $treeish);
1250 my $expected;
1251 while ($type eq 'tag') {
1252 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
1253 }
1254 if ($type eq 'commit') {
1255 $expected = (grep /^tree /, command(qw/cat-file commit/,
1256 $treeish))[0];
1257 ($expected) = ($expected =~ /^tree ($sha1)$/o);
1258 die "Unable to get tree from $treeish\n" unless $expected;
1259 } elsif ($type eq 'tree') {
1260 $expected = $treeish;
1261 } else {
1262 die "$treeish is a $type, expected tree, tag or commit\n";
1263 }
1264 return $expected;
1265 }
1267 sub get_commit_entry {
1268 my ($treeish) = shift;
1269 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
1270 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
1271 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
1272 open my $log_fh, '>', $commit_editmsg or croak $!;
1274 my $type = command_oneline(qw/cat-file -t/, $treeish);
1275 if ($type eq 'commit' || $type eq 'tag') {
1276 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
1277 $type, $treeish);
1278 my $in_msg = 0;
1279 my $author;
1280 my $saw_from = 0;
1281 my $msgbuf = "";
1282 while (<$msg_fh>) {
1283 if (!$in_msg) {
1284 $in_msg = 1 if (/^\s*$/);
1285 $author = $1 if (/^author (.*>)/);
1286 } elsif (/^git-svn-id: /) {
1287 # skip this for now, we regenerate the
1288 # correct one on re-fetch anyways
1289 # TODO: set *:merge properties or like...
1290 } else {
1291 if (/^From:/ || /^Signed-off-by:/) {
1292 $saw_from = 1;
1293 }
1294 $msgbuf .= $_;
1295 }
1296 }
1297 $msgbuf =~ s/\s+$//s;
1298 if ($Git::SVN::_add_author_from && defined($author)
1299 && !$saw_from) {
1300 $msgbuf .= "\n\nFrom: $author";
1301 }
1302 print $log_fh $msgbuf or croak $!;
1303 command_close_pipe($msg_fh, $ctx);
1304 }
1305 close $log_fh or croak $!;
1307 if ($_edit || ($type eq 'tree')) {
1308 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1309 # TODO: strip out spaces, comments, like git-commit.sh
1310 system($editor, $commit_editmsg);
1311 }
1312 rename $commit_editmsg, $commit_msg or croak $!;
1313 {
1314 require Encode;
1315 # SVN requires messages to be UTF-8 when entering the repo
1316 local $/;
1317 open $log_fh, '<', $commit_msg or croak $!;
1318 binmode $log_fh;
1319 chomp($log_entry{log} = <$log_fh>);
1321 my $enc = Git::config('i18n.commitencoding') || 'UTF-8';
1322 my $msg = $log_entry{log};
1324 eval { $msg = Encode::decode($enc, $msg, 1) };
1325 if ($@) {
1326 die "Could not decode as $enc:\n", $msg,
1327 "\nPerhaps you need to set i18n.commitencoding\n";
1328 }
1330 eval { $msg = Encode::encode('UTF-8', $msg, 1) };
1331 die "Could not encode as UTF-8:\n$msg\n" if $@;
1333 $log_entry{log} = $msg;
1335 close $log_fh or croak $!;
1336 }
1337 unlink $commit_msg;
1338 \%log_entry;
1339 }
1341 sub s_to_file {
1342 my ($str, $file, $mode) = @_;
1343 open my $fd,'>',$file or croak $!;
1344 print $fd $str,"\n" or croak $!;
1345 close $fd or croak $!;
1346 chmod ($mode &~ umask, $file) if (defined $mode);
1347 }
1349 sub file_to_s {
1350 my $file = shift;
1351 open my $fd,'<',$file or croak "$!: file: $file\n";
1352 local $/;
1353 my $ret = <$fd>;
1354 close $fd or croak $!;
1355 $ret =~ s/\s*$//s;
1356 return $ret;
1357 }
1359 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
1360 sub load_authors {
1361 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
1362 my $log = $cmd eq 'log';
1363 while (<$authors>) {
1364 chomp;
1365 next unless /^(.+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
1366 my ($user, $name, $email) = ($1, $2, $3);
1367 if ($log) {
1368 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
1369 } else {
1370 $users{$user} = [$name, $email];
1371 }
1372 }
1373 close $authors or croak $!;
1374 }
1376 # convert GetOpt::Long specs for use by git-config
1377 sub read_repo_config {
1378 return unless -d $ENV{GIT_DIR};
1379 my $opts = shift;
1380 my @config_only;
1381 foreach my $o (keys %$opts) {
1382 # if we have mixedCase and a long option-only, then
1383 # it's a config-only variable that we don't need for
1384 # the command-line.
1385 push @config_only, $o if ($o =~ /[A-Z]/ && $o =~ /^[a-z]+$/i);
1386 my $v = $opts->{$o};
1387 my ($key) = ($o =~ /^([a-zA-Z\-]+)/);
1388 $key =~ s/-//g;
1389 my $arg = 'git config';
1390 $arg .= ' --int' if ($o =~ /[:=]i$/);
1391 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
1392 if (ref $v eq 'ARRAY') {
1393 chomp(my @tmp = `$arg --get-all svn.$key`);
1394 @$v = @tmp if @tmp;
1395 } else {
1396 chomp(my $tmp = `$arg --get svn.$key`);
1397 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
1398 $$v = $tmp;
1399 }
1400 }
1401 }
1402 delete @$opts{@config_only} if @config_only;
1403 }
1405 sub extract_metadata {
1406 my $id = shift or return (undef, undef, undef);
1407 my ($url, $rev, $uuid) = ($id =~ /^\s*git-svn-id:\s+(.*)\@(\d+)
1408 \s([a-f\d\-]+)$/ix);
1409 if (!defined $rev || !$uuid || !$url) {
1410 # some of the original repositories I made had
1411 # identifiers like this:
1412 ($rev, $uuid) = ($id =~/^\s*git-svn-id:\s(\d+)\@([a-f\d\-]+)/i);
1413 }
1414 return ($url, $rev, $uuid);
1415 }
1417 sub cmt_metadata {
1418 return extract_metadata((grep(/^git-svn-id: /,
1419 command(qw/cat-file commit/, shift)))[-1]);
1420 }
1422 sub cmt_sha2rev_batch {
1423 my %s2r;
1424 my ($pid, $in, $out, $ctx) = command_bidi_pipe(qw/cat-file --batch/);
1425 my $list = shift;
1427 foreach my $sha (@{$list}) {
1428 my $first = 1;
1429 my $size = 0;
1430 print $out $sha, "\n";
1432 while (my $line = <$in>) {
1433 if ($first && $line =~ /^[[:xdigit:]]{40}\smissing$/) {
1434 last;
1435 } elsif ($first &&
1436 $line =~ /^[[:xdigit:]]{40}\scommit\s(\d+)$/) {
1437 $first = 0;
1438 $size = $1;
1439 next;
1440 } elsif ($line =~ /^(git-svn-id: )/) {
1441 my (undef, $rev, undef) =
1442 extract_metadata($line);
1443 $s2r{$sha} = $rev;
1444 }
1446 $size -= length($line);
1447 last if ($size == 0);
1448 }
1449 }
1451 command_close_bidi_pipe($pid, $in, $out, $ctx);
1453 return \%s2r;
1454 }
1456 sub working_head_info {
1457 my ($head, $refs) = @_;
1458 my @args = ('log', '--no-color', '--first-parent', '--pretty=medium');
1459 my ($fh, $ctx) = command_output_pipe(@args, $head);
1460 my $hash;
1461 my %max;
1462 while (<$fh>) {
1463 if ( m{^commit ($::sha1)$} ) {
1464 unshift @$refs, $hash if $hash and $refs;
1465 $hash = $1;
1466 next;
1467 }
1468 next unless s{^\s*(git-svn-id:)}{$1};
1469 my ($url, $rev, $uuid) = extract_metadata($_);
1470 if (defined $url && defined $rev) {
1471 next if $max{$url} and $max{$url} < $rev;
1472 if (my $gs = Git::SVN->find_by_url($url)) {
1473 my $c = $gs->rev_map_get($rev, $uuid);
1474 if ($c && $c eq $hash) {
1475 close $fh; # break the pipe
1476 return ($url, $rev, $uuid, $gs);
1477 } else {
1478 $max{$url} ||= $gs->rev_map_max;
1479 }
1480 }
1481 }
1482 }
1483 command_close_pipe($fh, $ctx);
1484 (undef, undef, undef, undef);
1485 }
1487 sub read_commit_parents {
1488 my ($parents, $c) = @_;
1489 chomp(my $p = command_oneline(qw/rev-list --parents -1/, $c));
1490 $p =~ s/^($c)\s*// or die "rev-list --parents -1 $c failed!\n";
1491 @{$parents->{$c}} = split(/ /, $p);
1492 }
1494 sub linearize_history {
1495 my ($gs, $refs) = @_;
1496 my %parents;
1497 foreach my $c (@$refs) {
1498 read_commit_parents(\%parents, $c);
1499 }
1501 my @linear_refs;
1502 my %skip = ();
1503 my $last_svn_commit = $gs->last_commit;
1504 foreach my $c (reverse @$refs) {
1505 next if $c eq $last_svn_commit;
1506 last if $skip{$c};
1508 unshift @linear_refs, $c;
1509 $skip{$c} = 1;
1511 # we only want the first parent to diff against for linear
1512 # history, we save the rest to inject when we finalize the
1513 # svn commit
1514 my $fp_a = verify_ref("$c~1");
1515 my $fp_b = shift @{$parents{$c}} if $parents{$c};
1516 if (!$fp_a || !$fp_b) {
1517 die "Commit $c\n",
1518 "has no parent commit, and therefore ",
1519 "nothing to diff against.\n",
1520 "You should be working from a repository ",
1521 "originally created by git-svn\n";
1522 }
1523 if ($fp_a ne $fp_b) {
1524 die "$c~1 = $fp_a, however parsing commit $c ",
1525 "revealed that:\n$c~1 = $fp_b\nBUG!\n";
1526 }
1528 foreach my $p (@{$parents{$c}}) {
1529 $skip{$p} = 1;
1530 }
1531 }
1532 (\@linear_refs, \%parents);
1533 }
1535 sub find_file_type_and_diff_status {
1536 my ($path) = @_;
1537 return ('dir', '') if $path eq '';
1539 my $diff_output =
1540 command_oneline(qw(diff --cached --name-status --), $path) || "";
1541 my $diff_status = (split(' ', $diff_output))[0] || "";
1543 my $ls_tree = command_oneline(qw(ls-tree HEAD), $path) || "";
1545 return (undef, undef) if !$diff_status && !$ls_tree;
1547 if ($diff_status eq "A") {
1548 return ("link", $diff_status) if -l $path;
1549 return ("dir", $diff_status) if -d $path;
1550 return ("file", $diff_status);
1551 }
1553 my $mode = (split(' ', $ls_tree))[0] || "";
1555 return ("link", $diff_status) if $mode eq "120000";
1556 return ("dir", $diff_status) if $mode eq "040000";
1557 return ("file", $diff_status);
1558 }
1560 sub md5sum {
1561 my $arg = shift;
1562 my $ref = ref $arg;
1563 my $md5 = Digest::MD5->new();
1564 if ($ref eq 'GLOB' || $ref eq 'IO::File' || $ref eq 'File::Temp') {
1565 $md5->addfile($arg) or croak $!;
1566 } elsif ($ref eq 'SCALAR') {
1567 $md5->add($$arg) or croak $!;
1568 } elsif (!$ref) {
1569 $md5->add($arg) or croak $!;
1570 } else {
1571 ::fatal "Can't provide MD5 hash for unknown ref type: '", $ref, "'";
1572 }
1573 return $md5->hexdigest();
1574 }
1576 sub gc_directory {
1577 if ($can_compress && -f $_ && basename($_) eq "unhandled.log") {
1578 my $out_filename = $_ . ".gz";
1579 open my $in_fh, "<", $_ or die "Unable to open $_: $!\n";
1580 binmode $in_fh;
1581 my $gz = Compress::Zlib::gzopen($out_filename, "ab") or
1582 die "Unable to open $out_filename: $!\n";
1584 my $res;
1585 while ($res = sysread($in_fh, my $str, 1024)) {
1586 $gz->gzwrite($str) or
1587 die "Unable to write: ".$gz->gzerror()."!\n";
1588 }
1589 unlink $_ or die "unlink $File::Find::name: $!\n";
1590 } elsif (-f $_ && basename($_) eq "index") {
1591 unlink $_ or die "unlink $_: $!\n";
1592 }
1593 }
1595 package Git::SVN;
1596 use strict;
1597 use warnings;
1598 use Fcntl qw/:DEFAULT :seek/;
1599 use constant rev_map_fmt => 'NH40';
1600 use vars qw/$default_repo_id $default_ref_id $_no_metadata $_follow_parent
1601 $_repack $_repack_flags $_use_svm_props $_head
1602 $_use_svnsync_props $no_reuse_existing $_minimize_url
1603 $_use_log_author $_add_author_from $_localtime/;
1604 use Carp qw/croak/;
1605 use File::Path qw/mkpath/;
1606 use File::Copy qw/copy/;
1607 use IPC::Open3;
1609 my ($_gc_nr, $_gc_period);
1611 # properties that we do not log:
1612 my %SKIP_PROP;
1613 BEGIN {
1614 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
1615 svn:special svn:executable
1616 svn:entry:committed-rev
1617 svn:entry:last-author
1618 svn:entry:uuid
1619 svn:entry:committed-date/;
1621 # some options are read globally, but can be overridden locally
1622 # per [svn-remote "..."] section. Command-line options will *NOT*
1623 # override options set in an [svn-remote "..."] section
1624 no strict 'refs';
1625 for my $option (qw/follow_parent no_metadata use_svm_props
1626 use_svnsync_props/) {
1627 my $key = $option;
1628 $key =~ tr/_//d;
1629 my $prop = "-$option";
1630 *$option = sub {
1631 my ($self) = @_;
1632 return $self->{$prop} if exists $self->{$prop};
1633 my $k = "svn-remote.$self->{repo_id}.$key";
1634 eval { command_oneline(qw/config --get/, $k) };
1635 if ($@) {
1636 $self->{$prop} = ${"Git::SVN::_$option"};
1637 } else {
1638 my $v = command_oneline(qw/config --bool/,$k);
1639 $self->{$prop} = $v eq 'false' ? 0 : 1;
1640 }
1641 return $self->{$prop};
1642 }
1643 }
1644 }
1647 my (%LOCKFILES, %INDEX_FILES);
1648 END {
1649 unlink keys %LOCKFILES if %LOCKFILES;
1650 unlink keys %INDEX_FILES if %INDEX_FILES;
1651 }
1653 sub resolve_local_globs {
1654 my ($url, $fetch, $glob_spec) = @_;
1655 return unless defined $glob_spec;
1656 my $ref = $glob_spec->{ref};
1657 my $path = $glob_spec->{path};
1658 foreach (command(qw#for-each-ref --format=%(refname) refs/#)) {
1659 next unless m#^$ref->{regex}$#;
1660 my $p = $1;
1661 my $pathname = desanitize_refname($path->full_path($p));
1662 my $refname = desanitize_refname($ref->full_path($p));
1663 if (my $existing = $fetch->{$pathname}) {
1664 if ($existing ne $refname) {
1665 die "Refspec conflict:\n",
1666 "existing: $existing\n",
1667 " globbed: $refname\n";
1668 }
1669 my $u = (::cmt_metadata("$refname"))[0];
1670 $u =~ s!^\Q$url\E(/|$)!! or die
1671 "$refname: '$url' not found in '$u'\n";
1672 if ($pathname ne $u) {
1673 warn "W: Refspec glob conflict ",
1674 "(ref: $refname):\n",
1675 "expected path: $pathname\n",
1676 " real path: $u\n",
1677 "Continuing ahead with $u\n";
1678 next;
1679 }
1680 } else {
1681 $fetch->{$pathname} = $refname;
1682 }
1683 }
1684 }
1686 sub parse_revision_argument {
1687 my ($base, $head) = @_;
1688 if (!defined $::_revision || $::_revision eq 'BASE:HEAD') {
1689 return ($base, $head);
1690 }
1691 return ($1, $2) if ($::_revision =~ /^(\d+):(\d+)$/);
1692 return ($::_revision, $::_revision) if ($::_revision =~ /^\d+$/);
1693 return ($head, $head) if ($::_revision eq 'HEAD');
1694 return ($base, $1) if ($::_revision =~ /^BASE:(\d+)$/);
1695 return ($1, $head) if ($::_revision =~ /^(\d+):HEAD$/);
1696 die "revision argument: $::_revision not understood by git-svn\n";
1697 }
1699 sub fetch_all {
1700 my ($repo_id, $remotes) = @_;
1701 if (ref $repo_id) {
1702 my $gs = $repo_id;
1703 $repo_id = undef;
1704 $repo_id = $gs->{repo_id};
1705 }
1706 $remotes ||= read_all_remotes();
1707 my $remote = $remotes->{$repo_id} or
1708 die "[svn-remote \"$repo_id\"] unknown\n";
1709 my $fetch = $remote->{fetch};
1710 my $url = $remote->{url} or die "svn-remote.$repo_id.url not defined\n";
1711 my (@gs, @globs);
1712 my $ra = Git::SVN::Ra->new($url);
1713 my $uuid = $ra->get_uuid;
1714 my $head = $ra->get_latest_revnum;
1715 $ra->get_log("", $head, 0, 1, 0, 1, sub { $head = $_[1] });
1716 my $base = defined $fetch ? $head : 0;
1718 # read the max revs for wildcard expansion (branches/*, tags/*)
1719 foreach my $t (qw/branches tags/) {
1720 defined $remote->{$t} or next;
1721 push @globs, @{$remote->{$t}};
1723 my $max_rev = eval { tmp_config(qw/--int --get/,
1724 "svn-remote.$repo_id.${t}-maxRev") };
1725 if (defined $max_rev && ($max_rev < $base)) {
1726 $base = $max_rev;
1727 } elsif (!defined $max_rev) {
1728 $base = 0;
1729 }
1730 }
1732 if ($fetch) {
1733 foreach my $p (sort keys %$fetch) {
1734 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
1735 my $lr = $gs->rev_map_max;
1736 if (defined $lr) {
1737 $base = $lr if ($lr < $base);
1738 }
1739 push @gs, $gs;
1740 }
1741 }
1743 ($base, $head) = parse_revision_argument($base, $head);
1744 $ra->gs_fetch_loop_common($base, $head, \@gs, \@globs);
1745 }
1747 sub read_all_remotes {
1748 my $r = {};
1749 my $use_svm_props = eval { command_oneline(qw/config --bool
1750 svn.useSvmProps/) };
1751 $use_svm_props = $use_svm_props eq 'true' if $use_svm_props;
1752 my $svn_refspec = qr{\s*/?(.*?)\s*:\s*(.+?)\s*};
1753 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
1754 if (m!^(.+)\.fetch=$svn_refspec$!) {
1755 my ($remote, $local_ref, $remote_ref) = ($1, $2, $3);
1756 die("svn-remote.$remote: remote ref '$remote_ref' "
1757 . "must start with 'refs/'\n")
1758 unless $remote_ref =~ m{^refs/};
1759 $r->{$remote}->{fetch}->{$local_ref} = $remote_ref;
1760 $r->{$remote}->{svm} = {} if $use_svm_props;
1761 } elsif (m!^(.+)\.usesvmprops=\s*(.*)\s*$!) {
1762 $r->{$1}->{svm} = {};
1763 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
1764 $r->{$1}->{url} = $2;
1765 } elsif (m!^(.+)\.(branches|tags)=$svn_refspec$!) {
1766 my ($remote, $t, $local_ref, $remote_ref) =
1767 ($1, $2, $3, $4);
1768 die("svn-remote.$remote: remote ref '$remote_ref' ($t) "
1769 . "must start with 'refs/'\n")
1770 unless $remote_ref =~ m{^refs/};
1771 my $rs = {
1772 t => $t,
1773 remote => $remote,
1774 path => Git::SVN::GlobSpec->new($local_ref),
1775 ref => Git::SVN::GlobSpec->new($remote_ref) };
1776 if (length($rs->{ref}->{right}) != 0) {
1777 die "The '*' glob character must be the last ",
1778 "character of '$remote_ref'\n";
1779 }
1780 push @{ $r->{$remote}->{$t} }, $rs;
1781 }
1782 }
1784 map {
1785 if (defined $r->{$_}->{svm}) {
1786 my $svm;
1787 eval {
1788 my $section = "svn-remote.$_";
1789 $svm = {
1790 source => tmp_config('--get',
1791 "$section.svm-source"),
1792 replace => tmp_config('--get',
1793 "$section.svm-replace"),
1794 }
1795 };
1796 $r->{$_}->{svm} = $svm;
1797 }
1798 } keys %$r;
1800 $r;
1801 }
1803 sub init_vars {
1804 $_gc_nr = $_gc_period = 1000;
1805 if (defined $_repack || defined $_repack_flags) {
1806 warn "Repack options are obsolete; they have no effect.\n";
1807 }
1808 }
1810 sub verify_remotes_sanity {
1811 return unless -d $ENV{GIT_DIR};
1812 my %seen;
1813 foreach (command(qw/config -l/)) {
1814 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
1815 if ($seen{$1}) {
1816 die "Remote ref refs/remote/$1 is tracked by",
1817 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
1818 "Please resolve this ambiguity in ",
1819 "your git configuration file before ",
1820 "continuing\n";
1821 }
1822 $seen{$1} = $_;
1823 }
1824 }
1825 }
1827 sub find_existing_remote {
1828 my ($url, $remotes) = @_;
1829 return undef if $no_reuse_existing;
1830 my $existing;
1831 foreach my $repo_id (keys %$remotes) {
1832 my $u = $remotes->{$repo_id}->{url} or next;
1833 next if $u ne $url;
1834 $existing = $repo_id;
1835 last;
1836 }
1837 $existing;
1838 }
1840 sub init_remote_config {
1841 my ($self, $url, $no_write) = @_;
1842 $url =~ s!/+$!!; # strip trailing slash
1843 my $r = read_all_remotes();
1844 my $existing = find_existing_remote($url, $r);
1845 if ($existing) {
1846 unless ($no_write) {
1847 print STDERR "Using existing ",
1848 "[svn-remote \"$existing\"]\n";
1849 }
1850 $self->{repo_id} = $existing;
1851 } elsif ($_minimize_url) {
1852 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
1853 $existing = find_existing_remote($min_url, $r);
1854 if ($existing) {
1855 unless ($no_write) {
1856 print STDERR "Using existing ",
1857 "[svn-remote \"$existing\"]\n";
1858 }
1859 $self->{repo_id} = $existing;
1860 }
1861 if ($min_url ne $url) {
1862 unless ($no_write) {
1863 print STDERR "Using higher level of URL: ",
1864 "$url => $min_url\n";
1865 }
1866 my $old_path = $self->{path};
1867 $self->{path} = $url;
1868 $self->{path} =~ s!^\Q$min_url\E(/|$)!!;
1869 if (length $old_path) {
1870 $self->{path} .= "/$old_path";
1871 }
1872 $url = $min_url;
1873 }
1874 }
1875 my $orig_url;
1876 if (!$existing) {
1877 # verify that we aren't overwriting anything:
1878 $orig_url = eval {
1879 command_oneline('config', '--get',
1880 "svn-remote.$self->{repo_id}.url")
1881 };
1882 if ($orig_url && ($orig_url ne $url)) {
1883 die "svn-remote.$self->{repo_id}.url already set: ",
1884 "$orig_url\nwanted to set to: $url\n";
1885 }
1886 }
1887 my ($xrepo_id, $xpath) = find_ref($self->refname);
1888 if (!$no_write && defined $xpath) {
1889 die "svn-remote.$xrepo_id.fetch already set to track ",
1890 "$xpath:", $self->refname, "\n";
1891 }
1892 unless ($no_write) {
1893 command_noisy('config',
1894 "svn-remote.$self->{repo_id}.url", $url);
1895 $self->{path} =~ s{^/}{};
1896 $self->{path} =~ s{%([0-9A-F]{2})}{chr hex($1)}ieg;
1897 command_noisy('config', '--add',
1898 "svn-remote.$self->{repo_id}.fetch",
1899 "$self->{path}:".$self->refname);
1900 }
1901 $self->{url} = $url;
1902 }
1904 sub find_by_url { # repos_root and, path are optional
1905 my ($class, $full_url, $repos_root, $path) = @_;
1907 return undef unless defined $full_url;
1908 remove_username($full_url);
1909 remove_username($repos_root) if defined $repos_root;
1910 my $remotes = read_all_remotes();
1911 if (defined $full_url && defined $repos_root && !defined $path) {
1912 $path = $full_url;
1913 $path =~ s#^\Q$repos_root\E(?:/|$)##;
1914 }
1915 foreach my $repo_id (keys %$remotes) {
1916 my $u = $remotes->{$repo_id}->{url} or next;
1917 remove_username($u);
1918 next if defined $repos_root && $repos_root ne $u;
1920 my $fetch = $remotes->{$repo_id}->{fetch} || {};
1921 foreach my $t (qw/branches tags/) {
1922 foreach my $globspec (@{$remotes->{$repo_id}->{$t}}) {
1923 resolve_local_globs($u, $fetch, $globspec);
1924 }
1925 }
1926 my $p = $path;
1927 my $rwr = rewrite_root({repo_id => $repo_id});
1928 my $svm = $remotes->{$repo_id}->{svm}
1929 if defined $remotes->{$repo_id}->{svm};
1930 unless (defined $p) {
1931 $p = $full_url;
1932 my $z = $u;
1933 my $prefix = '';
1934 if ($rwr) {
1935 $z = $rwr;
1936 remove_username($z);
1937 } elsif (defined $svm) {
1938 $z = $svm->{source};
1939 $prefix = $svm->{replace};
1940 $prefix =~ s#^\Q$u\E(?:/|$)##;
1941 $prefix =~ s#/$##;
1942 }
1943 $p =~ s#^\Q$z\E(?:/|$)#$prefix# or next;
1944 }
1945 foreach my $f (keys %$fetch) {
1946 next if $f ne $p;
1947 return Git::SVN->new($fetch->{$f}, $repo_id, $f);
1948 }
1949 }
1950 undef;
1951 }
1953 sub init {
1954 my ($class, $url, $path, $repo_id, $ref_id, $no_write) = @_;
1955 my $self = _new($class, $repo_id, $ref_id, $path);
1956 if (defined $url) {
1957 $self->init_remote_config($url, $no_write);
1958 }
1959 $self;
1960 }
1962 sub find_ref {
1963 my ($ref_id) = @_;
1964 foreach (command(qw/config -l/)) {
1965 next unless m!^svn-remote\.(.+)\.fetch=
1966 \s*/?(.*?)\s*:\s*(.+?)\s*$!x;
1967 my ($repo_id, $path, $ref) = ($1, $2, $3);
1968 if ($ref eq $ref_id) {
1969 $path = '' if ($path =~ m#^\./?#);
1970 return ($repo_id, $path);
1971 }
1972 }
1973 (undef, undef, undef);
1974 }
1976 sub new {
1977 my ($class, $ref_id, $repo_id, $path) = @_;
1978 if (defined $ref_id && !defined $repo_id && !defined $path) {
1979 ($repo_id, $path) = find_ref($ref_id);
1980 if (!defined $repo_id) {
1981 die "Could not find a \"svn-remote.*.fetch\" key ",
1982 "in the repository configuration matching: ",
1983 "$ref_id\n";
1984 }
1985 }
1986 my $self = _new($class, $repo_id, $ref_id, $path);
1987 if (!defined $self->{path} || !length $self->{path}) {
1988 my $fetch = command_oneline('config', '--get',
1989 "svn-remote.$repo_id.fetch",
1990 ":$ref_id\$") or
1991 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
1992 "\":$ref_id\$\" in config\n";
1993 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
1994 }
1995 $self->{url} = command_oneline('config', '--get',
1996 "svn-remote.$repo_id.url") or
1997 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
1998 $self->rebuild;
1999 $self;
2000 }
2002 sub refname {
2003 my ($refname) = $_[0]->{ref_id} ;
2005 # It cannot end with a slash /, we'll throw up on this because
2006 # SVN can't have directories with a slash in their name, either:
2007 if ($refname =~ m{/$}) {
2008 die "ref: '$refname' ends with a trailing slash, this is ",
2009 "not permitted by git nor Subversion\n";
2010 }
2012 # It cannot have ASCII control character space, tilde ~, caret ^,
2013 # colon :, question-mark ?, asterisk *, space, or open bracket [
2014 # anywhere.
2015 #
2016 # Additionally, % must be escaped because it is used for escaping
2017 # and we want our escaped refname to be reversible
2018 $refname =~ s{([ \%~\^:\?\*\[\t])}{uc sprintf('%%%02x',ord($1))}eg;
2020 # no slash-separated component can begin with a dot .
2021 # /.* becomes /%2E*
2022 $refname =~ s{/\.}{/%2E}g;
2024 # It cannot have two consecutive dots .. anywhere
2025 # .. becomes %2E%2E
2026 $refname =~ s{\.\.}{%2E%2E}g;
2028 return $refname;
2029 }
2031 sub desanitize_refname {
2032 my ($refname) = @_;
2033 $refname =~ s{%(?:([0-9A-F]{2}))}{chr hex($1)}eg;
2034 return $refname;
2035 }
2037 sub svm_uuid {
2038 my ($self) = @_;
2039 return $self->{svm}->{uuid} if $self->svm;
2040 $self->ra;
2041 unless ($self->{svm}) {
2042 die "SVM UUID not cached, and reading remotely failed\n";
2043 }
2044 $self->{svm}->{uuid};
2045 }
2047 sub svm {
2048 my ($self) = @_;
2049 return $self->{svm} if $self->{svm};
2050 my $svm;
2051 # see if we have it in our config, first:
2052 eval {
2053 my $section = "svn-remote.$self->{repo_id}";
2054 $svm = {
2055 source => tmp_config('--get', "$section.svm-source"),
2056 uuid => tmp_config('--get', "$section.svm-uuid"),
2057 replace => tmp_config('--get', "$section.svm-replace"),
2058 }
2059 };
2060 if ($svm && $svm->{source} && $svm->{uuid} && $svm->{replace}) {
2061 $self->{svm} = $svm;
2062 }
2063 $self->{svm};
2064 }
2066 sub _set_svm_vars {
2067 my ($self, $ra) = @_;
2068 return $ra if $self->svm;
2070 my @err = ( "useSvmProps set, but failed to read SVM properties\n",
2071 "(svm:source, svm:uuid) ",
2072 "from the following URLs:\n" );
2073 sub read_svm_props {
2074 my ($self, $ra, $path, $r) = @_;
2075 my $props = ($ra->get_dir($path, $r))[2];
2076 my $src = $props->{'svm:source'};
2077 my $uuid = $props->{'svm:uuid'};
2078 return undef if (!$src || !$uuid);
2080 chomp($src, $uuid);
2082 $uuid =~ m{^[0-9a-f\-]{30,}$}i
2083 or die "doesn't look right - svm:uuid is '$uuid'\n";
2085 # the '!' is used to mark the repos_root!/relative/path
2086 $src =~ s{/?!/?}{/};
2087 $src =~ s{/+$}{}; # no trailing slashes please
2088 # username is of no interest
2089 $src =~ s{(^[a-z\+]*://)[^/@]*@}{$1};
2091 my $replace = $ra->{url};
2092 $replace .= "/$path" if length $path;
2094 my $section = "svn-remote.$self->{repo_id}";
2095 tmp_config("$section.svm-source", $src);
2096 tmp_config("$section.svm-replace", $replace);
2097 tmp_config("$section.svm-uuid", $uuid);
2098 $self->{svm} = {
2099 source => $src,
2100 uuid => $uuid,
2101 replace => $replace
2102 };
2103 }
2105 my $r = $ra->get_latest_revnum;
2106 my $path = $self->{path};
2107 my %tried;
2108 while (length $path) {
2109 unless ($tried{"$self->{url}/$path"}) {
2110 return $ra if $self->read_svm_props($ra, $path, $r);
2111 $tried{"$self->{url}/$path"} = 1;
2112 }
2113 $path =~ s#/?[^/]+$##;
2114 }
2115 die "Path: '$path' should be ''\n" if $path ne '';
2116 return $ra if $self->read_svm_props($ra, $path, $r);
2117 $tried{"$self->{url}/$path"} = 1;
2119 if ($ra->{repos_root} eq $self->{url}) {
2120 die @err, (map { " $_\n" } keys %tried), "\n";
2121 }
2123 # nope, make sure we're connected to the repository root:
2124 my $ok;
2125 my @tried_b;
2126 $path = $ra->{svn_path};
2127 $ra = Git::SVN::Ra->new($ra->{repos_root});
2128 while (length $path) {
2129 unless ($tried{"$ra->{url}/$path"}) {
2130 $ok = $self->read_svm_props($ra, $path, $r);
2131 last if $ok;
2132 $tried{"$ra->{url}/$path"} = 1;
2133 }
2134 $path =~ s#/?[^/]+$##;
2135 }
2136 die "Path: '$path' should be ''\n" if $path ne '';
2137 $ok ||= $self->read_svm_props($ra, $path, $r);
2138 $tried{"$ra->{url}/$path"} = 1;
2139 if (!$ok) {
2140 die @err, (map { " $_\n" } keys %tried), "\n";
2141 }
2142 Git::SVN::Ra->new($self->{url});
2143 }
2145 sub svnsync {
2146 my ($self) = @_;
2147 return $self->{svnsync} if $self->{svnsync};
2149 if ($self->no_metadata) {
2150 die "Can't have both 'noMetadata' and ",
2151 "'useSvnsyncProps' options set!\n";
2152 }
2153 if ($self->rewrite_root) {
2154 die "Can't have both 'useSvnsyncProps' and 'rewriteRoot' ",
2155 "options set!\n";
2156 }
2158 my $svnsync;
2159 # see if we have it in our config, first:
2160 eval {
2161 my $section = "svn-remote.$self->{repo_id}";
2163 my $url = tmp_config('--get', "$section.svnsync-url");
2164 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2165 die "doesn't look right - svn:sync-from-url is '$url'\n";
2167 my $uuid = tmp_config('--get', "$section.svnsync-uuid");
2168 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2169 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2171 $svnsync = { url => $url, uuid => $uuid }
2172 };
2173 if ($svnsync && $svnsync->{url} && $svnsync->{uuid}) {
2174 return $self->{svnsync} = $svnsync;
2175 }
2177 my $err = "useSvnsyncProps set, but failed to read " .
2178 "svnsync property: svn:sync-from-";
2179 my $rp = $self->ra->rev_proplist(0);
2181 my $url = $rp->{'svn:sync-from-url'} or die $err . "url\n";
2182 ($url) = ($url =~ m{^([a-z\+]+://\S+)$}) or
2183 die "doesn't look right - svn:sync-from-url is '$url'\n";
2185 my $uuid = $rp->{'svn:sync-from-uuid'} or die $err . "uuid\n";
2186 ($uuid) = ($uuid =~ m{^([0-9a-f\-]{30,})$}i) or
2187 die "doesn't look right - svn:sync-from-uuid is '$uuid'\n";
2189 my $section = "svn-remote.$self->{repo_id}";
2190 tmp_config('--add', "$section.svnsync-uuid", $uuid);
2191 tmp_config('--add', "$section.svnsync-url", $url);
2192 return $self->{svnsync} = { url => $url, uuid => $uuid };
2193 }
2195 # this allows us to memoize our SVN::Ra UUID locally and avoid a
2196 # remote lookup (useful for 'git svn log').
2197 sub ra_uuid {
2198 my ($self) = @_;
2199 unless ($self->{ra_uuid}) {
2200 my $key = "svn-remote.$self->{repo_id}.uuid";
2201 my $uuid = eval { tmp_config('--get', $key) };
2202 if (!$@ && $uuid && $uuid =~ /^([a-f\d\-]{30,})$/i) {
2203 $self->{ra_uuid} = $uuid;
2204 } else {
2205 die "ra_uuid called without URL\n" unless $self->{url};
2206 $self->{ra_uuid} = $self->ra->get_uuid;
2207 tmp_config('--add', $key, $self->{ra_uuid});
2208 }
2209 }
2210 $self->{ra_uuid};
2211 }
2213 sub _set_repos_root {
2214 my ($self, $repos_root) = @_;
2215 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2216 $repos_root ||= $self->ra->{repos_root};
2217 tmp_config($k, $repos_root);
2218 $repos_root;
2219 }
2221 sub repos_root {
2222 my ($self) = @_;
2223 my $k = "svn-remote.$self->{repo_id}.reposRoot";
2224 eval { tmp_config('--get', $k) } || $self->_set_repos_root;
2225 }
2227 sub ra {
2228 my ($self) = shift;
2229 my $ra = Git::SVN::Ra->new($self->{url});
2230 $self->_set_repos_root($ra->{repos_root});
2231 if ($self->use_svm_props && !$self->{svm}) {
2232 if ($self->no_metadata) {
2233 die "Can't have both 'noMetadata' and ",
2234 "'useSvmProps' options set!\n";
2235 } elsif ($self->use_svnsync_props) {
2236 die "Can't have both 'useSvnsyncProps' and ",
2237 "'useSvmProps' options set!\n";
2238 }
2239 $ra = $self->_set_svm_vars($ra);
2240 $self->{-want_revprops} = 1;
2241 }
2242 $ra;
2243 }
2245 # prop_walk(PATH, REV, SUB)
2246 # -------------------------
2247 # Recursively traverse PATH at revision REV and invoke SUB for each
2248 # directory that contains a SVN property. SUB will be invoked as
2249 # follows: &SUB(gs, path, props); where `gs' is this instance of
2250 # Git::SVN, `path' the path to the directory where the properties
2251 # `props' were found. The `path' will be relative to point of checkout,
2252 # that is, if url://repo/trunk is the current Git branch, and that
2253 # directory contains a sub-directory `d', SUB will be invoked with `/d/'
2254 # as `path' (note the trailing `/').
2255 sub prop_walk {
2256 my ($self, $path, $rev, $sub) = @_;
2258 $path =~ s#^/##;
2259 my ($dirent, undef, $props) = $self->ra->get_dir($path, $rev);
2260 $path =~ s#^/*#/#g;
2261 my $p = $path;
2262 # Strip the irrelevant part of the path.
2263 $p =~ s#^/+\Q$self->{path}\E(/|$)#/#;
2264 # Ensure the path is terminated by a `/'.
2265 $p =~ s#/*$#/#;
2267 # The properties contain all the internal SVN stuff nobody
2268 # (usually) cares about.
2269 my $interesting_props = 0;
2270 foreach (keys %{$props}) {
2271 # If it doesn't start with `svn:', it must be a
2272 # user-defined property.
2273 ++$interesting_props and next if $_ !~ /^svn:/;
2274 # FIXME: Fragile, if SVN adds new public properties,
2275 # this needs to be updated.
2276 ++$interesting_props if /^svn:(?:ignore|keywords|executable
2277 |eol-style|mime-type
2278 |externals|needs-lock)$/x;
2279 }
2280 &$sub($self, $p, $props) if $interesting_props;
2282 foreach (sort keys %$dirent) {
2283 next if $dirent->{$_}->{kind} != $SVN::Node::dir;
2284 $self->prop_walk($self->{path} . $p . $_, $rev, $sub);
2285 }
2286 }
2288 sub last_rev { ($_[0]->last_rev_commit)[0] }
2289 sub last_commit { ($_[0]->last_rev_commit)[1] }
2291 # returns the newest SVN revision number and newest commit SHA1
2292 sub last_rev_commit {
2293 my ($self) = @_;
2294 if (defined $self->{last_rev} && defined $self->{last_commit}) {
2295 return ($self->{last_rev}, $self->{last_commit});
2296 }
2297 my $c = ::verify_ref($self->refname.'^0');
2298 if ($c && !$self->use_svm_props && !$self->no_metadata) {
2299 my $rev = (::cmt_metadata($c))[1];
2300 if (defined $rev) {
2301 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
2302 return ($rev, $c);
2303 }
2304 }
2305 my $map_path = $self->map_path;
2306 unless (-e $map_path) {
2307 ($self->{last_rev}, $self->{last_commit}) = (undef, undef);
2308 return (undef, undef);
2309 }
2310 my ($rev, $commit) = $self->rev_map_max(1);
2311 ($self->{last_rev}, $self->{last_commit}) = ($rev, $commit);
2312 return ($rev, $commit);
2313 }
2315 sub get_fetch_range {
2316 my ($self, $min, $max) = @_;
2317 $max ||= $self->ra->get_latest_revnum;
2318 $min ||= $self->rev_map_max;
2319 (++$min, $max);
2320 }
2322 sub tmp_config {
2323 my (@args) = @_;
2324 my $old_def_config = "$ENV{GIT_DIR}/svn/config";
2325 my $config = "$ENV{GIT_DIR}/svn/.metadata";
2326 if (! -f $config && -f $old_def_config) {
2327 rename $old_def_config, $config or
2328 die "Failed rename $old_def_config => $config: $!\n";
2329 }
2330 my $old_config = $ENV{GIT_CONFIG};
2331 $ENV{GIT_CONFIG} = $config;
2332 $@ = undef;
2333 my @ret = eval {
2334 unless (-f $config) {
2335 mkfile($config);
2336 open my $fh, '>', $config or
2337 die "Can't open $config: $!\n";
2338 print $fh "; This file is used internally by ",
2339 "git-svn\n" or die
2340 "Couldn't write to $config: $!\n";
2341 print $fh "; You should not have to edit it\n" or
2342 die "Couldn't write to $config: $!\n";
2343 close $fh or die "Couldn't close $config: $!\n";
2344 }
2345 command('config', @args);
2346 };
2347 my $err = $@;
2348 if (defined $old_config) {
2349 $ENV{GIT_CONFIG} = $old_config;
2350 } else {
2351 delete $ENV{GIT_CONFIG};
2352 }
2353 die $err if $err;
2354 wantarray ? @ret : $ret[0];
2355 }
2357 sub tmp_index_do {
2358 my ($self, $sub) = @_;
2359 my $old_index = $ENV{GIT_INDEX_FILE};
2360 $ENV{GIT_INDEX_FILE} = $self->{index};
2361 $@ = undef;
2362 my @ret = eval {
2363 my ($dir, $base) = ($self->{index} =~ m#^(.*?)/?([^/]+)$#);
2364 mkpath([$dir]) unless -d $dir;
2365 &$sub;
2366 };
2367 my $err = $@;
2368 if (defined $old_index) {
2369 $ENV{GIT_INDEX_FILE} = $old_index;
2370 } else {
2371 delete $ENV{GIT_INDEX_FILE};
2372 }
2373 die $err if $err;
2374 wantarray ? @ret : $ret[0];
2375 }
2377 sub assert_index_clean {
2378 my ($self, $treeish) = @_;
2380 $self->tmp_index_do(sub {
2381 command_noisy('read-tree', $treeish) unless -e $self->{index};
2382 my $x = command_oneline('write-tree');
2383 my ($y) = (command(qw/cat-file commit/, $treeish) =~
2384 /^tree ($::sha1)/mo);
2385 return if $y eq $x;
2387 warn "Index mismatch: $y != $x\nrereading $treeish\n";
2388 unlink $self->{index} or die "unlink $self->{index}: $!\n";
2389 command_noisy('read-tree', $treeish);
2390 $x = command_oneline('write-tree');
2391 if ($y ne $x) {
2392 ::fatal "trees ($treeish) $y != $x\n",
2393 "Something is seriously wrong...";
2394 }
2395 });
2396 }
2398 sub get_commit_parents {
2399 my ($self, $log_entry) = @_;
2400 my (%seen, @ret, @tmp);
2401 # legacy support for 'set-tree'; this is only used by set_tree_cb:
2402 if (my $ip = $self->{inject_parents}) {
2403 if (my $commit = delete $ip->{$log_entry->{revision}}) {
2404 push @tmp, $commit;
2405 }
2406 }
2407 if (my $cur = ::verify_ref($self->refname.'^0')) {
2408 push @tmp, $cur;
2409 }
2410 if (my $ipd = $self->{inject_parents_dcommit}) {
2411 if (my $commit = delete $ipd->{$log_entry->{revision}}) {
2412 push @tmp, @$commit;
2413 }
2414 }
2415 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
2416 while (my $p = shift @tmp) {
2417 next if $seen{$p};
2418 $seen{$p} = 1;
2419 push @ret, $p;
2420 # MAXPARENT is defined to 16 in commit-tree.c:
2421 last if @ret >= 16;
2422 }
2423 if (@tmp) {
2424 die "r$log_entry->{revision}: No room for parents:\n\t",
2425 join("\n\t", @tmp), "\n";
2426 }
2427 @ret;
2428 }
2430 sub rewrite_root {
2431 my ($self) = @_;
2432 return $self->{-rewrite_root} if exists $self->{-rewrite_root};
2433 my $k = "svn-remote.$self->{repo_id}.rewriteRoot";
2434 my $rwr = eval { command_oneline(qw/config --get/, $k) };
2435 if ($rwr) {
2436 $rwr =~ s#/+$##;
2437 if ($rwr !~ m#^[a-z\+]+://#) {
2438 die "$rwr is not a valid URL (key: $k)\n";
2439 }
2440 }
2441 $self->{-rewrite_root} = $rwr;
2442 }
2444 sub metadata_url {
2445 my ($self) = @_;
2446 ($self->rewrite_root || $self->{url}) .
2447 (length $self->{path} ? '/' . $self->{path} : '');
2448 }
2450 sub full_url {
2451 my ($self) = @_;
2452 $self->{url} . (length $self->{path} ? '/' . $self->{path} : '');
2453 }
2456 sub set_commit_header_env {
2457 my ($log_entry) = @_;
2458 my %env;
2459 foreach my $ned (qw/NAME EMAIL DATE/) {
2460 foreach my $ac (qw/AUTHOR COMMITTER/) {
2461 $env{"GIT_${ac}_${ned}"} = $ENV{"GIT_${ac}_${ned}"};
2462 }
2463 }
2465 $ENV{GIT_AUTHOR_NAME} = $log_entry->{name};
2466 $ENV{GIT_AUTHOR_EMAIL} = $log_entry->{email};
2467 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
2469 $ENV{GIT_COMMITTER_NAME} = (defined $log_entry->{commit_name})
2470 ? $log_entry->{commit_name}
2471 : $log_entry->{name};
2472 $ENV{GIT_COMMITTER_EMAIL} = (defined $log_entry->{commit_email})
2473 ? $log_entry->{commit_email}
2474 : $log_entry->{email};
2475 \%env;
2476 }
2478 sub restore_commit_header_env {
2479 my ($env) = @_;
2480 foreach my $ned (qw/NAME EMAIL DATE/) {
2481 foreach my $ac (qw/AUTHOR COMMITTER/) {
2482 my $k = "GIT_${ac}_${ned}";
2483 if (defined $env->{$k}) {
2484 $ENV{$k} = $env->{$k};
2485 } else {
2486 delete $ENV{$k};
2487 }
2488 }
2489 }
2490 }
2492 sub gc {
2493 command_noisy('gc', '--auto');
2494 };
2496 sub do_git_commit {
2497 my ($self, $log_entry) = @_;
2498 my $lr = $self->last_rev;
2499 if (defined $lr && $lr >= $log_entry->{revision}) {
2500 die "Last fetched revision of ", $self->refname,
2501 " was r$lr, but we are about to fetch: ",
2502 "r$log_entry->{revision}!\n";
2503 }
2504 if (my $c = $self->rev_map_get($log_entry->{revision})) {
2505 croak "$log_entry->{revision} = $c already exists! ",
2506 "Why are we refetching it?\n";
2507 }
2508 my $old_env = set_commit_header_env($log_entry);
2509 my $tree = $log_entry->{tree};
2510 if (!defined $tree) {
2511 $tree = $self->tmp_index_do(sub {
2512 command_oneline('write-tree') });
2513 }
2514 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
2516 my @exec = ('git', 'commit-tree', $tree);
2517 foreach ($self->get_commit_parents($log_entry)) {
2518 push @exec, '-p', $_;
2519 }
2520 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2521 or croak $!;
2522 binmode $msg_fh;
2524 # we always get UTF-8 from SVN, but we may want our commits in
2525 # a different encoding.
2526 if (my $enc = Git::config('i18n.commitencoding')) {
2527 require Encode;
2528 Encode::from_to($log_entry->{log}, 'UTF-8', $enc);
2529 }
2530 print $msg_fh $log_entry->{log} or croak $!;
2531 restore_commit_header_env($old_env);
2532 unless ($self->no_metadata) {
2533 print $msg_fh "\ngit-svn-id: $log_entry->{metadata}\n"
2534 or croak $!;
2535 }
2536 $msg_fh->flush == 0 or croak $!;
2537 close $msg_fh or croak $!;
2538 chomp(my $commit = do { local $/; <$out_fh> });
2539 close $out_fh or croak $!;
2540 waitpid $pid, 0;
2541 croak $? if $?;
2542 if ($commit !~ /^$::sha1$/o) {
2543 die "Failed to commit, invalid sha1: $commit\n";
2544 }
2546 $self->rev_map_set($log_entry->{revision}, $commit, 1);
2548 $self->{last_rev} = $log_entry->{revision};
2549 $self->{last_commit} = $commit;
2550 print "r$log_entry->{revision}" unless $::_q > 1;
2551 if (defined $log_entry->{svm_revision}) {
2552 print " (\@$log_entry->{svm_revision})" unless $::_q > 1;
2553 $self->rev_map_set($log_entry->{svm_revision}, $commit,
2554 0, $self->svm_uuid);
2555 }
2556 print " = $commit ($self->{ref_id})\n" unless $::_q > 1;
2557 if (--$_gc_nr == 0) {
2558 $_gc_nr = $_gc_period;
2559 gc();
2560 }
2561 return $commit;
2562 }
2564 sub match_paths {
2565 my ($self, $paths, $r) = @_;
2566 return 1 if $self->{path} eq '';
2567 if (my $path = $paths->{"/$self->{path}"}) {
2568 return ($path->{action} eq 'D') ? 0 : 1;
2569 }
2570 $self->{path_regex} ||= qr/^\/\Q$self->{path}\E\//;
2571 if (grep /$self->{path_regex}/, keys %$paths) {
2572 return 1;
2573 }
2574 my $c = '';
2575 foreach (split m#/#, $self->{path}) {
2576 $c .= "/$_";
2577 next unless ($paths->{$c} &&
2578 ($paths->{$c}->{action} =~ /^[AR]$/));
2579 if ($self->ra->check_path($self->{path}, $r) ==
2580 $SVN::Node::dir) {
2581 return 1;
2582 }
2583 }
2584 return 0;
2585 }
2587 sub find_parent_branch {
2588 my ($self, $paths, $rev) = @_;
2589 return undef unless $self->follow_parent;
2590 unless (defined $paths) {
2591 my $err_handler = $SVN::Error::handler;
2592 $SVN::Error::handler = \&Git::SVN::Ra::skip_unknown_revs;
2593 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
2594 sub { $paths = $_[0] });
2595 $SVN::Error::handler = $err_handler;
2596 }
2597 return undef unless defined $paths;
2599 # look for a parent from another branch:
2600 my @b_path_components = split m#/#, $self->{path};
2601 my @a_path_components;
2602 my $i;
2603 while (@b_path_components) {
2604 $i = $paths->{'/'.join('/', @b_path_components)};
2605 last if $i && defined $i->{copyfrom_path};
2606 unshift(@a_path_components, pop(@b_path_components));
2607 }
2608 return undef unless defined $i && defined $i->{copyfrom_path};
2609 my $branch_from = $i->{copyfrom_path};
2610 if (@a_path_components) {
2611 print STDERR "branch_from: $branch_from => ";
2612 $branch_from .= '/'.join('/', @a_path_components);
2613 print STDERR $branch_from, "\n";
2614 }
2615 my $r = $i->{copyfrom_rev};
2616 my $repos_root = $self->ra->{repos_root};
2617 my $url = $self->ra->{url};
2618 my $new_url = $url . $branch_from;
2619 print STDERR "Found possible branch point: ",
2620 "$new_url => ", $self->full_url, ", $r\n";
2621 $branch_from =~ s#^/##;
2622 my $gs = $self->other_gs($new_url, $url,
2623 $branch_from, $r, $self->{ref_id});
2624 my ($r0, $parent) = $gs->find_rev_before($r, 1);
2625 {
2626 my ($base, $head);
2627 if (!defined $r0 || !defined $parent) {
2628 ($base, $head) = parse_revision_argument(0, $r);
2629 } else {
2630 if ($r0 < $r) {
2631 $gs->ra->get_log([$gs->{path}], $r0 + 1, $r, 1,
2632 0, 1, sub { $base = $_[1] - 1 });
2633 }
2634 }
2635 if (defined $base && $base <= $r) {
2636 $gs->fetch($base, $r);
2637 }
2638 ($r0, $parent) = $gs->find_rev_before($r, 1);
2639 }
2640 if (defined $r0 && defined $parent) {
2641 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
2642 my $ed;
2643 if ($self->ra->can_do_switch) {
2644 $self->assert_index_clean($parent);
2645 print STDERR "Following parent with do_switch\n";
2646 # do_switch works with svn/trunk >= r22312, but that
2647 # is not included with SVN 1.4.3 (the latest version
2648 # at the moment), so we can't rely on it
2649 $self->{last_rev} = $r0;
2650 $self->{last_commit} = $parent;
2651 $ed = SVN::Git::Fetcher->new($self, $gs->{path});
2652 $gs->ra->gs_do_switch($r0, $rev, $gs,
2653 $self->full_url, $ed)
2654 or die "SVN connection failed somewhere...\n";
2655 } elsif ($self->ra->trees_match($new_url, $r0,
2656 $self->full_url, $rev)) {
2657 print STDERR "Trees match:\n",
2658 " $new_url\@$r0\n",
2659 " ${\$self->full_url}\@$rev\n",
2660 "Following parent with no changes\n";
2661 $self->tmp_index_do(sub {
2662 command_noisy('read-tree', $parent);
2663 });
2664 $self->{last_commit} = $parent;
2665 } else {
2666 print STDERR "Following parent with do_update\n";
2667 $ed = SVN::Git::Fetcher->new($self);
2668 $self->ra->gs_do_update($rev, $rev, $self, $ed)
2669 or die "SVN connection failed somewhere...\n";
2670 }
2671 print STDERR "Successfully followed parent\n";
2672 return $self->make_log_entry($rev, [$parent], $ed);
2673 }
2674 return undef;
2675 }
2677 sub do_fetch {
2678 my ($self, $paths, $rev) = @_;
2679 my $ed;
2680 my ($last_rev, @parents);
2681 if (my $lc = $self->last_commit) {
2682 # we can have a branch that was deleted, then re-added
2683 # under the same name but copied from another path, in
2684 # which case we'll have multiple parents (we don't
2685 # want to break the original ref, nor lose copypath info):
2686 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2687 push @{$log_entry->{parents}}, $lc;
2688 return $log_entry;
2689 }
2690 $ed = SVN::Git::Fetcher->new($self);
2691 $last_rev = $self->{last_rev};
2692 $ed->{c} = $lc;
2693 @parents = ($lc);
2694 } else {
2695 $last_rev = $rev;
2696 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
2697 return $log_entry;
2698 }
2699 $ed = SVN::Git::Fetcher->new($self);
2700 }
2701 unless ($self->ra->gs_do_update($last_rev, $rev, $self, $ed)) {
2702 die "SVN connection failed somewhere...\n";
2703 }
2704 $self->make_log_entry($rev, \@parents, $ed);
2705 }
2707 sub get_untracked {
2708 my ($self, $ed) = @_;
2709 my @out;
2710 my $h = $ed->{empty};
2711 foreach (sort keys %$h) {
2712 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
2713 push @out, " $act: " . uri_encode($_);
2714 warn "W: $act: $_\n";
2715 }
2716 foreach my $t (qw/dir_prop file_prop/) {
2717 $h = $ed->{$t} or next;
2718 foreach my $path (sort keys %$h) {
2719 my $ppath = $path eq '' ? '.' : $path;
2720 foreach my $prop (sort keys %{$h->{$path}}) {
2721 next if $SKIP_PROP{$prop};
2722 my $v = $h->{$path}->{$prop};
2723 my $t_ppath_prop = "$t: " .
2724 uri_encode($ppath) . ' ' .
2725 uri_encode($prop);
2726 if (defined $v) {
2727 push @out, " +$t_ppath_prop " .
2728 uri_encode($v);
2729 } else {
2730 push @out, " -$t_ppath_prop";
2731 }
2732 }
2733 }
2734 }
2735 foreach my $t (qw/absent_file absent_directory/) {
2736 $h = $ed->{$t} or next;
2737 foreach my $parent (sort keys %$h) {
2738 foreach my $path (sort @{$h->{$parent}}) {
2739 push @out, " $t: " .
2740 uri_encode("$parent/$path");
2741 warn "W: $t: $parent/$path ",
2742 "Insufficient permissions?\n";
2743 }
2744 }
2745 }
2746 \@out;
2747 }
2749 # parse_svn_date(DATE)
2750 # --------------------
2751 # Given a date (in UTC) from Subversion, return a string in the format
2752 # "<TZ Offset> <local date/time>" that Git will use.
2753 #
2754 # By default the parsed date will be in UTC; if $Git::SVN::_localtime
2755 # is true we'll convert it to the local timezone instead.
2756 sub parse_svn_date {
2757 my $date = shift || return '+0000 1970-01-01 00:00:00';
2758 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2759 (\d\d)\:(\d\d)\:(\d\d)\.\d*Z$/x) or
2760 croak "Unable to parse date: $date\n";
2761 my $parsed_date; # Set next.
2763 if ($Git::SVN::_localtime) {
2764 # Translate the Subversion datetime to an epoch time.
2765 # Begin by switching ourselves to $date's timezone, UTC.
2766 my $old_env_TZ = $ENV{TZ};
2767 $ENV{TZ} = 'UTC';
2769 my $epoch_in_UTC =
2770 POSIX::strftime('%s', $S, $M, $H, $d, $m - 1, $Y - 1900);
2772 # Determine our local timezone (including DST) at the
2773 # time of $epoch_in_UTC. $Git::SVN::Log::TZ stored the
2774 # value of TZ, if any, at the time we were run.
2775 if (defined $Git::SVN::Log::TZ) {
2776 $ENV{TZ} = $Git::SVN::Log::TZ;
2777 } else {
2778 delete $ENV{TZ};
2779 }
2781 my $our_TZ =
2782 POSIX::strftime('%Z', $S, $M, $H, $d, $m - 1, $Y - 1900);
2784 # This converts $epoch_in_UTC into our local timezone.
2785 my ($sec, $min, $hour, $mday, $mon, $year,
2786 $wday, $yday, $isdst) = localtime($epoch_in_UTC);
2788 $parsed_date = sprintf('%s %04d-%02d-%02d %02d:%02d:%02d',
2789 $our_TZ, $year + 1900, $mon + 1,
2790 $mday, $hour, $min, $sec);
2792 # Reset us to the timezone in effect when we entered
2793 # this routine.
2794 if (defined $old_env_TZ) {
2795 $ENV{TZ} = $old_env_TZ;
2796 } else {
2797 delete $ENV{TZ};
2798 }
2799 } else {
2800 $parsed_date = "+0000 $Y-$m-$d $H:$M:$S";
2801 }
2803 return $parsed_date;
2804 }
2806 sub other_gs {
2807 my ($self, $new_url, $url,
2808 $branch_from, $r, $old_ref_id) = @_;
2809 my $gs = Git::SVN->find_by_url($new_url, $url, $branch_from);
2810 unless ($gs) {
2811 my $ref_id = $old_ref_id;
2812 $ref_id =~ s/\@\d+$//;
2813 $ref_id .= "\@$r";
2814 # just grow a tail if we're not unique enough :x
2815 $ref_id .= '-' while find_ref($ref_id);
2816 print STDERR "Initializing parent: $ref_id\n";
2817 my ($u, $p, $repo_id) = ($new_url, '', $ref_id);
2818 if ($u =~ s#^\Q$url\E(/|$)##) {
2819 $p = $u;
2820 $u = $url;
2821 $repo_id = $self->{repo_id};
2822 }
2823 $gs = Git::SVN->init($u, $p, $repo_id, $ref_id, 1);
2824 }
2825 $gs
2826 }
2828 sub call_authors_prog {
2829 my ($orig_author) = @_;
2830 my $author = `$::_authors_prog $orig_author`;
2831 if ($? != 0) {
2832 die "$::_authors_prog failed with exit code $?\n"
2833 }
2834 if ($author =~ /^\s*(.+?)\s*<(.*)>\s*$/) {
2835 my ($name, $email) = ($1, $2);
2836 $email = undef if length $2 == 0;
2837 return [$name, $email];
2838 } else {
2839 die "Author: $orig_author: $::_authors_prog returned "
2840 . "invalid author format: $author\n";
2841 }
2842 }
2844 sub check_author {
2845 my ($author) = @_;
2846 if (!defined $author || length $author == 0) {
2847 $author = '(no author)';
2848 }
2849 if (!defined $::users{$author}) {
2850 if (defined $::_authors_prog) {
2851 $::users{$author} = call_authors_prog($author);
2852 } elsif (defined $::_authors) {
2853 die "Author: $author not defined in $::_authors file\n";
2854 }
2855 }
2856 $author;
2857 }
2859 sub make_log_entry {
2860 my ($self, $rev, $parents, $ed) = @_;
2861 my $untracked = $self->get_untracked($ed);
2863 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
2864 print $un "r$rev\n" or croak $!;
2865 print $un $_, "\n" foreach @$untracked;
2866 my %log_entry = ( parents => $parents || [], revision => $rev,
2867 log => '');
2869 my $headrev;
2870 my $logged = delete $self->{logged_rev_props};
2871 if (!$logged || $self->{-want_revprops}) {
2872 my $rp = $self->ra->rev_proplist($rev);
2873 foreach (sort keys %$rp) {
2874 my $v = $rp->{$_};
2875 if (/^svn:(author|date|log)$/) {
2876 $log_entry{$1} = $v;
2877 } elsif ($_ eq 'svm:headrev') {
2878 $headrev = $v;
2879 } else {
2880 print $un " rev_prop: ", uri_encode($_), ' ',
2881 uri_encode($v), "\n";
2882 }
2883 }
2884 } else {
2885 map { $log_entry{$_} = $logged->{$_} } keys %$logged;
2886 }
2887 close $un or croak $!;
2889 $log_entry{date} = parse_svn_date($log_entry{date});
2890 $log_entry{log} .= "\n";
2891 my $author = $log_entry{author} = check_author($log_entry{author});
2892 my ($name, $email) = defined $::users{$author} ? @{$::users{$author}}
2893 : ($author, undef);
2895 my ($commit_name, $commit_email) = ($name, $email);
2896 if ($_use_log_author) {
2897 my $name_field;
2898 if ($log_entry{log} =~ /From:\s+(.*\S)\s*\n/i) {
2899 $name_field = $1;
2900 } elsif ($log_entry{log} =~ /Signed-off-by:\s+(.*\S)\s*\n/i) {
2901 $name_field = $1;
2902 }
2903 if (!defined $name_field) {
2904 if (!defined $email) {
2905 $email = $name;
2906 }
2907 } elsif ($name_field =~ /(.*?)\s+<(.*)>/) {
2908 ($name, $email) = ($1, $2);
2909 } elsif ($name_field =~ /(.*)@/) {
2910 ($name, $email) = ($1, $name_field);
2911 } else {
2912 ($name, $email) = ($name_field, $name_field);
2913 }
2914 }
2915 if (defined $headrev && $self->use_svm_props) {
2916 if ($self->rewrite_root) {
2917 die "Can't have both 'useSvmProps' and 'rewriteRoot' ",
2918 "options set!\n";
2919 }
2920 my ($uuid, $r) = $headrev =~ m{^([a-f\d\-]{30,}):(\d+)$}i;
2921 # we don't want "SVM: initializing mirror for junk" ...
2922 return undef if $r == 0;
2923 my $svm = $self->svm;
2924 if ($uuid ne $svm->{uuid}) {
2925 die "UUID mismatch on SVM path:\n",
2926 "expected: $svm->{uuid}\n",
2927 " got: $uuid\n";
2928 }
2929 my $full_url = $self->full_url;
2930 $full_url =~ s#^\Q$svm->{replace}\E(/|$)#$svm->{source}$1# or
2931 die "Failed to replace '$svm->{replace}' with ",
2932 "'$svm->{source}' in $full_url\n";
2933 # throw away username for storing in records
2934 remove_username($full_url);
2935 $log_entry{metadata} = "$full_url\@$r $uuid";
2936 $log_entry{svm_revision} = $r;
2937 $email ||= "$author\@$uuid";
2938 $commit_email ||= "$author\@$uuid";
2939 } elsif ($self->use_svnsync_props) {
2940 my $full_url = $self->svnsync->{url};
2941 $full_url .= "/$self->{path}" if length $self->{path};
2942 remove_username($full_url);
2943 my $uuid = $self->svnsync->{uuid};
2944 $log_entry{metadata} = "$full_url\@$rev $uuid";
2945 $email ||= "$author\@$uuid";
2946 $commit_email ||= "$author\@$uuid";
2947 } else {
2948 my $url = $self->metadata_url;
2949 remove_username($url);
2950 $log_entry{metadata} = "$url\@$rev " .
2951 $self->ra->get_uuid;
2952 $email ||= "$author\@" . $self->ra->get_uuid;
2953 $commit_email ||= "$author\@" . $self->ra->get_uuid;
2954 }
2955 $log_entry{name} = $name;
2956 $log_entry{email} = $email;
2957 $log_entry{commit_name} = $commit_name;
2958 $log_entry{commit_email} = $commit_email;
2959 \%log_entry;
2960 }
2962 sub fetch {
2963 my ($self, $min_rev, $max_rev, @parents) = @_;
2964 my ($last_rev, $last_commit) = $self->last_rev_commit;
2965 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
2966 $self->ra->gs_fetch_loop_common($base, $head, [$self]);
2967 }
2969 sub set_tree_cb {
2970 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
2971 $self->{inject_parents} = { $rev => $tree };
2972 $self->fetch(undef, undef);
2973 }
2975 sub set_tree {
2976 my ($self, $tree) = (shift, shift);
2977 my $log_entry = ::get_commit_entry($tree);
2978 unless ($self->{last_rev}) {
2979 ::fatal("Must have an existing revision to commit");
2980 }
2981 my %ed_opts = ( r => $self->{last_rev},
2982 log => $log_entry->{log},
2983 ra => $self->ra,
2984 tree_a => $self->{last_commit},
2985 tree_b => $tree,
2986 editor_cb => sub {
2987 $self->set_tree_cb($log_entry, $tree, @_) },
2988 svn_path => $self->{path} );
2989 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
2990 print "No changes\nr$self->{last_rev} = $tree\n";
2991 }
2992 }
2994 sub rebuild_from_rev_db {
2995 my ($self, $path) = @_;
2996 my $r = -1;
2997 open my $fh, '<', $path or croak "open: $!";
2998 binmode $fh or croak "binmode: $!";
2999 while (<$fh>) {
3000 length($_) == 41 or croak "inconsistent size in ($_) != 41";
3001 chomp($_);
3002 ++$r;
3003 next if $_ eq ('0' x 40);
3004 $self->rev_map_set($r, $_);
3005 print "r$r = $_\n";
3006 }
3007 close $fh or croak "close: $!";
3008 unlink $path or croak "unlink: $!";
3009 }
3011 sub rebuild {
3012 my ($self) = @_;
3013 my $map_path = $self->map_path;
3014 my $partial = (-e $map_path && ! -z $map_path);
3015 return unless ::verify_ref($self->refname.'^0');
3016 if (!$partial && ($self->use_svm_props || $self->no_metadata)) {
3017 my $rev_db = $self->rev_db_path;
3018 $self->rebuild_from_rev_db($rev_db);
3019 if ($self->use_svm_props) {
3020 my $svm_rev_db = $self->rev_db_path($self->svm_uuid);
3021 $self->rebuild_from_rev_db($svm_rev_db);
3022 }
3023 $self->unlink_rev_db_symlink;
3024 return;
3025 }
3026 print "Rebuilding $map_path ...\n" if (!$partial);
3027 my ($base_rev, $head) = ($partial ? $self->rev_map_max_norebuild(1) :
3028 (undef, undef));
3029 my ($log, $ctx) =
3030 command_output_pipe(qw/rev-list --pretty=raw --no-color --reverse/,
3031 ($head ? "$head.." : "") . $self->refname,
3032 '--');
3033 my $metadata_url = $self->metadata_url;
3034 remove_username($metadata_url);
3035 my $svn_uuid = $self->ra_uuid;
3036 my $c;
3037 while (<$log>) {
3038 if ( m{^commit ($::sha1)$} ) {
3039 $c = $1;
3040 next;
3041 }
3042 next unless s{^\s*(git-svn-id:)}{$1};
3043 my ($url, $rev, $uuid) = ::extract_metadata($_);
3044 remove_username($url);
3046 # ignore merges (from set-tree)
3047 next if (!defined $rev || !$uuid);
3049 # if we merged or otherwise started elsewhere, this is
3050 # how we break out of it
3051 if (($uuid ne $svn_uuid) ||
3052 ($metadata_url && $url && ($url ne $metadata_url))) {
3053 next;
3054 }
3055 if ($partial && $head) {
3056 print "Partial-rebuilding $map_path ...\n";
3057 print "Currently at $base_rev = $head\n";
3058 $head = undef;
3059 }
3061 $self->rev_map_set($rev, $c);
3062 print "r$rev = $c\n";
3063 }
3064 command_close_pipe($log, $ctx);
3065 print "Done rebuilding $map_path\n" if (!$partial || !$head);
3066 my $rev_db_path = $self->rev_db_path;
3067 if (-f $self->rev_db_path) {
3068 unlink $self->rev_db_path or croak "unlink: $!";
3069 }
3070 $self->unlink_rev_db_symlink;
3071 }
3073 # rev_map:
3074 # Tie::File seems to be prone to offset errors if revisions get sparse,
3075 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3076 # one of my favorite modules is out :< Next up would be one of the DBM
3077 # modules, but I'm not sure which is most portable...
3078 #
3079 # This is the replacement for the rev_db format, which was too big
3080 # and inefficient for large repositories with a lot of sparse history
3081 # (mainly tags)
3082 #
3083 # The format is this:
3084 # - 24 bytes for every record,
3085 # * 4 bytes for the integer representing an SVN revision number
3086 # * 20 bytes representing the sha1 of a git commit
3087 # - No empty padding records like the old format
3088 # (except the last record, which can be overwritten)
3089 # - new records are written append-only since SVN revision numbers
3090 # increase monotonically
3091 # - lookups on SVN revision number are done via a binary search
3092 # - Piping the file to xxd -c24 is a good way of dumping it for
3093 # viewing or editing (piped back through xxd -r), should the need
3094 # ever arise.
3095 # - The last record can be padding revision with an all-zero sha1
3096 # This is used to optimize fetch performance when using multiple
3097 # "fetch" directives in .git/config
3098 #
3099 # These files are disposable unless noMetadata or useSvmProps is set
3101 sub _rev_map_set {
3102 my ($fh, $rev, $commit) = @_;
3104 binmode $fh or croak "binmode: $!";
3105 my $size = (stat($fh))[7];
3106 ($size % 24) == 0 or croak "inconsistent size: $size";
3108 my $wr_offset = 0;
3109 if ($size > 0) {
3110 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3111 my $read = sysread($fh, my $buf, 24) or croak "read: $!";
3112 $read == 24 or croak "read only $read bytes (!= 24)";
3113 my ($last_rev, $last_commit) = unpack(rev_map_fmt, $buf);
3114 if ($last_commit eq ('0' x40)) {
3115 if ($size >= 48) {
3116 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3117 $read = sysread($fh, $buf, 24) or
3118 croak "read: $!";
3119 $read == 24 or
3120 croak "read only $read bytes (!= 24)";
3121 ($last_rev, $last_commit) =
3122 unpack(rev_map_fmt, $buf);
3123 if ($last_commit eq ('0' x40)) {
3124 croak "inconsistent .rev_map\n";
3125 }
3126 }
3127 if ($last_rev >= $rev) {
3128 croak "last_rev is higher!: $last_rev >= $rev";
3129 }
3130 $wr_offset = -24;
3131 }
3132 }
3133 sysseek($fh, $wr_offset, SEEK_END) or croak "seek: $!";
3134 syswrite($fh, pack(rev_map_fmt, $rev, $commit), 24) == 24 or
3135 croak "write: $!";
3136 }
3138 sub _rev_map_reset {
3139 my ($fh, $rev, $commit) = @_;
3140 my $c = _rev_map_get($fh, $rev);
3141 $c eq $commit or die "_rev_map_reset(@_) commit $c does not match!\n";
3142 my $offset = sysseek($fh, 0, SEEK_CUR) or croak "seek: $!";
3143 truncate $fh, $offset or croak "truncate: $!";
3144 }
3146 sub mkfile {
3147 my ($path) = @_;
3148 unless (-e $path) {
3149 my ($dir, $base) = ($path =~ m#^(.*?)/?([^/]+)$#);
3150 mkpath([$dir]) unless -d $dir;
3151 open my $fh, '>>', $path or die "Couldn't create $path: $!\n";
3152 close $fh or die "Couldn't close (create) $path: $!\n";
3153 }
3154 }
3156 sub rev_map_set {
3157 my ($self, $rev, $commit, $update_ref, $uuid) = @_;
3158 length $commit == 40 or die "arg3 must be a full SHA1 hexsum\n";
3159 my $db = $self->map_path($uuid);
3160 my $db_lock = "$db.lock";
3161 my $sig;
3162 $update_ref ||= 0;
3163 if ($update_ref) {
3164 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3165 $SIG{USR1} = $SIG{USR2} = sub { $sig = $_[0] };
3166 }
3167 mkfile($db);
3169 $LOCKFILES{$db_lock} = 1;
3170 my $sync;
3171 # both of these options make our .rev_db file very, very important
3172 # and we can't afford to lose it because rebuild() won't work
3173 if ($self->use_svm_props || $self->no_metadata) {
3174 $sync = 1;
3175 copy($db, $db_lock) or die "rev_map_set(@_): ",
3176 "Failed to copy: ",
3177 "$db => $db_lock ($!)\n";
3178 } else {
3179 rename $db, $db_lock or die "rev_map_set(@_): ",
3180 "Failed to rename: ",
3181 "$db => $db_lock ($!)\n";
3182 }
3184 sysopen(my $fh, $db_lock, O_RDWR | O_CREAT)
3185 or croak "Couldn't open $db_lock: $!\n";
3186 $update_ref eq 'reset' ? _rev_map_reset($fh, $rev, $commit) :
3187 _rev_map_set($fh, $rev, $commit);
3188 if ($sync) {
3189 $fh->flush or die "Couldn't flush $db_lock: $!\n";
3190 $fh->sync or die "Couldn't sync $db_lock: $!\n";
3191 }
3192 close $fh or croak $!;
3193 if ($update_ref) {
3194 $_head = $self;
3195 my $note = "";
3196 $note = " ($update_ref)" if ($update_ref !~ /^\d*$/);
3197 command_noisy('update-ref', '-m', "r$rev$note",
3198 $self->refname, $commit);
3199 }
3200 rename $db_lock, $db or die "rev_map_set(@_): ", "Failed to rename: ",
3201 "$db_lock => $db ($!)\n";
3202 delete $LOCKFILES{$db_lock};
3203 if ($update_ref) {
3204 $SIG{INT} = $SIG{HUP} = $SIG{TERM} = $SIG{ALRM} = $SIG{PIPE} =
3205 $SIG{USR1} = $SIG{USR2} = 'DEFAULT';
3206 kill $sig, $$ if defined $sig;
3207 }
3208 }
3210 # If want_commit, this will return an array of (rev, commit) where
3211 # commit _must_ be a valid commit in the archive.
3212 # Otherwise, it'll return the max revision (whether or not the
3213 # commit is valid or just a 0x40 placeholder).
3214 sub rev_map_max {
3215 my ($self, $want_commit) = @_;
3216 $self->rebuild;
3217 my ($r, $c) = $self->rev_map_max_norebuild($want_commit);
3218 $want_commit ? ($r, $c) : $r;
3219 }
3221 sub rev_map_max_norebuild {
3222 my ($self, $want_commit) = @_;
3223 my $map_path = $self->map_path;
3224 stat $map_path or return $want_commit ? (0, undef) : 0;
3225 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3226 binmode $fh or croak "binmode: $!";
3227 my $size = (stat($fh))[7];
3228 ($size % 24) == 0 or croak "inconsistent size: $size";
3230 if ($size == 0) {
3231 close $fh or croak "close: $!";
3232 return $want_commit ? (0, undef) : 0;
3233 }
3235 sysseek($fh, -24, SEEK_END) or croak "seek: $!";
3236 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3237 my ($r, $c) = unpack(rev_map_fmt, $buf);
3238 if ($want_commit && $c eq ('0' x40)) {
3239 if ($size < 48) {
3240 return $want_commit ? (0, undef) : 0;
3241 }
3242 sysseek($fh, -48, SEEK_END) or croak "seek: $!";
3243 sysread($fh, $buf, 24) == 24 or croak "read: $!";
3244 ($r, $c) = unpack(rev_map_fmt, $buf);
3245 if ($c eq ('0'x40)) {
3246 croak "Penultimate record is all-zeroes in $map_path";
3247 }
3248 }
3249 close $fh or croak "close: $!";
3250 $want_commit ? ($r, $c) : $r;
3251 }
3253 sub rev_map_get {
3254 my ($self, $rev, $uuid) = @_;
3255 my $map_path = $self->map_path($uuid);
3256 return undef unless -e $map_path;
3258 sysopen(my $fh, $map_path, O_RDONLY) or croak "open: $!";
3259 my $c = _rev_map_get($fh, $rev);
3260 close($fh) or croak "close: $!";
3261 $c
3262 }
3264 sub _rev_map_get {
3265 my ($fh, $rev) = @_;
3267 binmode $fh or croak "binmode: $!";
3268 my $size = (stat($fh))[7];
3269 ($size % 24) == 0 or croak "inconsistent size: $size";
3271 if ($size == 0) {
3272 return undef;
3273 }
3275 my ($l, $u) = (0, $size - 24);
3276 my ($r, $c, $buf);
3278 while ($l <= $u) {
3279 my $i = int(($l/24 + $u/24) / 2) * 24;
3280 sysseek($fh, $i, SEEK_SET) or croak "seek: $!";
3281 sysread($fh, my $buf, 24) == 24 or croak "read: $!";
3282 my ($r, $c) = unpack(rev_map_fmt, $buf);
3284 if ($r < $rev) {
3285 $l = $i + 24;
3286 } elsif ($r > $rev) {
3287 $u = $i - 24;
3288 } else { # $r == $rev
3289 return $c eq ('0' x 40) ? undef : $c;
3290 }
3291 }
3292 undef;
3293 }
3295 # Finds the first svn revision that exists on (if $eq_ok is true) or
3296 # before $rev for the current branch. It will not search any lower
3297 # than $min_rev. Returns the git commit hash and svn revision number
3298 # if found, else (undef, undef).
3299 sub find_rev_before {
3300 my ($self, $rev, $eq_ok, $min_rev) = @_;
3301 --$rev unless $eq_ok;
3302 $min_rev ||= 1;
3303 my $max_rev = $self->rev_map_max;
3304 $rev = $max_rev if ($rev > $max_rev);
3305 while ($rev >= $min_rev) {
3306 if (my $c = $self->rev_map_get($rev)) {
3307 return ($rev, $c);
3308 }
3309 --$rev;
3310 }
3311 return (undef, undef);
3312 }
3314 # Finds the first svn revision that exists on (if $eq_ok is true) or
3315 # after $rev for the current branch. It will not search any higher
3316 # than $max_rev. Returns the git commit hash and svn revision number
3317 # if found, else (undef, undef).
3318 sub find_rev_after {
3319 my ($self, $rev, $eq_ok, $max_rev) = @_;
3320 ++$rev unless $eq_ok;
3321 $max_rev ||= $self->rev_map_max;
3322 while ($rev <= $max_rev) {
3323 if (my $c = $self->rev_map_get($rev)) {
3324 return ($rev, $c);
3325 }
3326 ++$rev;
3327 }
3328 return (undef, undef);
3329 }
3331 sub _new {
3332 my ($class, $repo_id, $ref_id, $path) = @_;
3333 unless (defined $repo_id && length $repo_id) {
3334 $repo_id = $Git::SVN::default_repo_id;
3335 }
3336 unless (defined $ref_id && length $ref_id) {
3337 $_prefix = '' unless defined($_prefix);
3338 $_[2] = $ref_id =
3339 "refs/remotes/$_prefix$Git::SVN::default_ref_id";
3340 }
3341 $_[1] = $repo_id;
3342 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
3344 # Older repos imported by us used $GIT_DIR/svn/foo instead of
3345 # $GIT_DIR/svn/refs/remotes/foo when tracking refs/remotes/foo
3346 if ($ref_id =~ m{^refs/remotes/(.*)}) {
3347 my $old_dir = "$ENV{GIT_DIR}/svn/$1";
3348 if (-d $old_dir && ! -d $dir) {
3349 $dir = $old_dir;
3350 }
3351 }
3353 $_[3] = $path = '' unless (defined $path);
3354 mkpath([$dir]);
3355 bless {
3356 ref_id => $ref_id, dir => $dir, index => "$dir/index",
3357 path => $path, config => "$ENV{GIT_DIR}/svn/config",
3358 map_root => "$dir/.rev_map", repo_id => $repo_id }, $class;
3359 }
3361 # for read-only access of old .rev_db formats
3362 sub unlink_rev_db_symlink {
3363 my ($self) = @_;
3364 my $link = $self->rev_db_path;
3365 $link =~ s/\.[\w-]+$// or croak "missing UUID at the end of $link";
3366 if (-l $link) {
3367 unlink $link or croak "unlink: $link failed!";
3368 }
3369 }
3371 sub rev_db_path {
3372 my ($self, $uuid) = @_;
3373 my $db_path = $self->map_path($uuid);
3374 $db_path =~ s{/\.rev_map\.}{/\.rev_db\.}
3375 or croak "map_path: $db_path does not contain '/.rev_map.' !";
3376 $db_path;
3377 }
3379 # the new replacement for .rev_db
3380 sub map_path {
3381 my ($self, $uuid) = @_;
3382 $uuid ||= $self->ra_uuid;
3383 "$self->{map_root}.$uuid";
3384 }
3386 sub uri_encode {
3387 my ($f) = @_;
3388 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
3389 $f
3390 }
3392 sub remove_username {
3393 $_[0] =~ s{^([^:]*://)[^@]+@}{$1};
3394 }
3396 package Git::SVN::Prompt;
3397 use strict;
3398 use warnings;
3399 require SVN::Core;
3400 use vars qw/$_no_auth_cache $_username/;
3402 sub simple {
3403 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
3404 $may_save = undef if $_no_auth_cache;
3405 $default_username = $_username if defined $_username;
3406 if (defined $default_username && length $default_username) {
3407 if (defined $realm && length $realm) {
3408 print STDERR "Authentication realm: $realm\n";
3409 STDERR->flush;
3410 }
3411 $cred->username($default_username);
3412 } else {
3413 username($cred, $realm, $may_save, $pool);
3414 }
3415 $cred->password(_read_password("Password for '" .
3416 $cred->username . "': ", $realm));
3417 $cred->may_save($may_save);
3418 $SVN::_Core::SVN_NO_ERROR;
3419 }
3421 sub ssl_server_trust {
3422 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
3423 $may_save = undef if $_no_auth_cache;
3424 print STDERR "Error validating server certificate for '$realm':\n";
3425 {
3426 no warnings 'once';
3427 # All variables SVN::Auth::SSL::* are used only once,
3428 # so we're shutting up Perl warnings about this.
3429 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
3430 print STDERR " - The certificate is not issued ",
3431 "by a trusted authority. Use the\n",
3432 " fingerprint to validate ",
3433 "the certificate manually!\n";
3434 }
3435 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
3436 print STDERR " - The certificate hostname ",
3437 "does not match.\n";
3438 }
3439 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
3440 print STDERR " - The certificate is not yet valid.\n";
3441 }
3442 if ($failures & $SVN::Auth::SSL::EXPIRED) {
3443 print STDERR " - The certificate has expired.\n";
3444 }
3445 if ($failures & $SVN::Auth::SSL::OTHER) {
3446 print STDERR " - The certificate has ",
3447 "an unknown error.\n";
3448 }
3449 } # no warnings 'once'
3450 printf STDERR
3451 "Certificate information:\n".
3452 " - Hostname: %s\n".
3453 " - Valid: from %s until %s\n".
3454 " - Issuer: %s\n".
3455 " - Fingerprint: %s\n",
3456 map $cert_info->$_, qw(hostname valid_from valid_until
3457 issuer_dname fingerprint);
3458 my $choice;
3459 prompt:
3460 print STDERR $may_save ?
3461 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
3462 "(R)eject or accept (t)emporarily? ";
3463 STDERR->flush;
3464 $choice = lc(substr(<STDIN> || 'R', 0, 1));
3465 if ($choice =~ /^t$/i) {
3466 $cred->may_save(undef);
3467 } elsif ($choice =~ /^r$/i) {
3468 return -1;
3469 } elsif ($may_save && $choice =~ /^p$/i) {
3470 $cred->may_save($may_save);
3471 } else {
3472 goto prompt;
3473 }
3474 $cred->accepted_failures($failures);
3475 $SVN::_Core::SVN_NO_ERROR;
3476 }
3478 sub ssl_client_cert {
3479 my ($cred, $realm, $may_save, $pool) = @_;
3480 $may_save = undef if $_no_auth_cache;
3481 print STDERR "Client certificate filename: ";
3482 STDERR->flush;
3483 chomp(my $filename = <STDIN>);
3484 $cred->cert_file($filename);
3485 $cred->may_save($may_save);
3486 $SVN::_Core::SVN_NO_ERROR;
3487 }
3489 sub ssl_client_cert_pw {
3490 my ($cred, $realm, $may_save, $pool) = @_;
3491 $may_save = undef if $_no_auth_cache;
3492 $cred->password(_read_password("Password: ", $realm));
3493 $cred->may_save($may_save);
3494 $SVN::_Core::SVN_NO_ERROR;
3495 }
3497 sub username {
3498 my ($cred, $realm, $may_save, $pool) = @_;
3499 $may_save = undef if $_no_auth_cache;
3500 if (defined $realm && length $realm) {
3501 print STDERR "Authentication realm: $realm\n";
3502 }
3503 my $username;
3504 if (defined $_username) {
3505 $username = $_username;
3506 } else {
3507 print STDERR "Username: ";
3508 STDERR->flush;
3509 chomp($username = <STDIN>);
3510 }
3511 $cred->username($username);
3512 $cred->may_save($may_save);
3513 $SVN::_Core::SVN_NO_ERROR;
3514 }
3516 sub _read_password {
3517 my ($prompt, $realm) = @_;
3518 print STDERR $prompt;
3519 STDERR->flush;
3520 require Term::ReadKey;
3521 Term::ReadKey::ReadMode('noecho');
3522 my $password = '';
3523 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
3524 last if $key =~ /[\012\015]/; # \n\r
3525 $password .= $key;
3526 }
3527 Term::ReadKey::ReadMode('restore');
3528 print STDERR "\n";
3529 STDERR->flush;
3530 $password;
3531 }
3533 package SVN::Git::Fetcher;
3534 use vars qw/@ISA/;
3535 use strict;
3536 use warnings;
3537 use Carp qw/croak/;
3538 use File::Temp qw/tempfile/;
3539 use IO::File qw//;
3540 use vars qw/$_ignore_regex/;
3542 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
3543 sub new {
3544 my ($class, $git_svn, $switch_path) = @_;
3545 my $self = SVN::Delta::Editor->new;
3546 bless $self, $class;
3547 if (exists $git_svn->{last_commit}) {
3548 $self->{c} = $git_svn->{last_commit};
3549 $self->{empty_symlinks} =
3550 _mark_empty_symlinks($git_svn, $switch_path);
3551 }
3552 $self->{ignore_regex} = eval { command_oneline('config', '--get',
3553 "svn-remote.$git_svn->{repo_id}.ignore-paths") };
3554 $self->{empty} = {};
3555 $self->{dir_prop} = {};
3556 $self->{file_prop} = {};
3557 $self->{absent_dir} = {};
3558 $self->{absent_file} = {};
3559 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
3560 $self;
3561 }
3563 # this uses the Ra object, so it must be called before do_{switch,update},
3564 # not inside them (when the Git::SVN::Fetcher object is passed) to
3565 # do_{switch,update}
3566 sub _mark_empty_symlinks {
3567 my ($git_svn, $switch_path) = @_;
3568 my $bool = Git::config_bool('svn.brokenSymlinkWorkaround');
3569 return {} if (!defined($bool)) || (defined($bool) && ! $bool);
3571 my %ret;
3572 my ($rev, $cmt) = $git_svn->last_rev_commit;
3573 return {} unless ($rev && $cmt);
3575 # allow the warning to be printed for each revision we fetch to
3576 # ensure the user sees it. The user can also disable the workaround
3577 # on the repository even while git svn is running and the next
3578 # revision fetched will skip this expensive function.
3579 my $printed_warning;
3580 chomp(my $empty_blob = `git hash-object -t blob --stdin < /dev/null`);
3581 my ($ls, $ctx) = command_output_pipe(qw/ls-tree -r -z/, $cmt);
3582 local $/ = "\0";
3583 my $pfx = defined($switch_path) ? $switch_path : $git_svn->{path};
3584 $pfx .= '/' if length($pfx);
3585 while (<$ls>) {
3586 chomp;
3587 s/\A100644 blob $empty_blob\t//o or next;
3588 unless ($printed_warning) {
3589 print STDERR "Scanning for empty symlinks, ",
3590 "this may take a while if you have ",
3591 "many empty files\n",
3592 "You may disable this with `",
3593 "git config svn.brokenSymlinkWorkaround ",
3594 "false'.\n",
3595 "This may be done in a different ",
3596 "terminal without restarting ",
3597 "git svn\n";
3598 $printed_warning = 1;
3599 }
3600 my $path = $_;
3601 my (undef, $props) =
3602 $git_svn->ra->get_file($pfx.$path, $rev, undef);
3603 if ($props->{'svn:special'}) {
3604 $ret{$path} = 1;
3605 }
3606 }
3607 command_close_pipe($ls, $ctx);
3608 \%ret;
3609 }
3611 # returns true if a given path is inside a ".git" directory
3612 sub in_dot_git {
3613 $_[0] =~ m{(?:^|/)\.git(?:/|$)};
3614 }
3616 # return value: 0 -- don't ignore, 1 -- ignore
3617 sub is_path_ignored {
3618 my ($self, $path) = @_;
3619 return 1 if in_dot_git($path);
3620 return 1 if defined($self->{ignore_regex}) &&
3621 $path =~ m!$self->{ignore_regex}!;
3622 return 0 unless defined($_ignore_regex);
3623 return 1 if $path =~ m!$_ignore_regex!o;
3624 return 0;
3625 }
3627 sub set_path_strip {
3628 my ($self, $path) = @_;
3629 $self->{path_strip} = qr/^\Q$path\E(\/|$)/ if length $path;
3630 }
3632 sub open_root {
3633 { path => '' };
3634 }
3636 sub open_directory {
3637 my ($self, $path, $pb, $rev) = @_;
3638 { path => $path };
3639 }
3641 sub git_path {
3642 my ($self, $path) = @_;
3643 if ($self->{path_strip}) {
3644 $path =~ s!$self->{path_strip}!! or
3645 die "Failed to strip path '$path' ($self->{path_strip})\n";
3646 }
3647 $path;
3648 }
3650 sub delete_entry {
3651 my ($self, $path, $rev, $pb) = @_;
3652 return undef if $self->is_path_ignored($path);
3654 my $gpath = $self->git_path($path);
3655 return undef if ($gpath eq '');
3657 # remove entire directories.
3658 my ($tree) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3659 =~ /\A040000 tree ([a-f\d]{40})\t\Q$gpath\E\0/);
3660 if ($tree) {
3661 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3662 -r --name-only -z/,
3663 $tree);
3664 local $/ = "\0";
3665 while (<$ls>) {
3666 chomp;
3667 my $rmpath = "$gpath/$_";
3668 $self->{gii}->remove($rmpath);
3669 print "\tD\t$rmpath\n" unless $::_q;
3670 }
3671 print "\tD\t$gpath/\n" unless $::_q;
3672 command_close_pipe($ls, $ctx);
3673 $self->{empty}->{$path} = 0
3674 } else {
3675 $self->{gii}->remove($gpath);
3676 print "\tD\t$gpath\n" unless $::_q;
3677 }
3678 undef;
3679 }
3681 sub open_file {
3682 my ($self, $path, $pb, $rev) = @_;
3683 my ($mode, $blob);
3685 goto out if $self->is_path_ignored($path);
3687 my $gpath = $self->git_path($path);
3688 ($mode, $blob) = (command('ls-tree', '-z', $self->{c}, "./$gpath")
3689 =~ /\A(\d{6}) blob ([a-f\d]{40})\t\Q$gpath\E\0/);
3690 unless (defined $mode && defined $blob) {
3691 die "$path was not found in commit $self->{c} (r$rev)\n";
3692 }
3693 if ($mode eq '100644' && $self->{empty_symlinks}->{$path}) {
3694 $mode = '120000';
3695 }
3696 out:
3697 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
3698 pool => SVN::Pool->new, action => 'M' };
3699 }
3701 sub add_file {
3702 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
3703 my $mode;
3705 if (!$self->is_path_ignored($path)) {
3706 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3707 delete $self->{empty}->{$dir};
3708 $mode = '100644';
3709 }
3710 { path => $path, mode_a => $mode, mode_b => $mode,
3711 pool => SVN::Pool->new, action => 'A' };
3712 }
3714 sub add_directory {
3715 my ($self, $path, $cp_path, $cp_rev) = @_;
3716 goto out if $self->is_path_ignored($path);
3717 my $gpath = $self->git_path($path);
3718 if ($gpath eq '') {
3719 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
3720 -r --name-only -z/,
3721 $self->{c});
3722 local $/ = "\0";
3723 while (<$ls>) {
3724 chomp;
3725 $self->{gii}->remove($_);
3726 print "\tD\t$_\n" unless $::_q;
3727 }
3728 command_close_pipe($ls, $ctx);
3729 $self->{empty}->{$path} = 0;
3730 }
3731 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
3732 delete $self->{empty}->{$dir};
3733 $self->{empty}->{$path} = 1;
3734 out:
3735 { path => $path };
3736 }
3738 sub change_dir_prop {
3739 my ($self, $db, $prop, $value) = @_;
3740 return undef if $self->is_path_ignored($db->{path});
3741 $self->{dir_prop}->{$db->{path}} ||= {};
3742 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
3743 undef;
3744 }
3746 sub absent_directory {
3747 my ($self, $path, $pb) = @_;
3748 return undef if $self->is_path_ignored($path);
3749 $self->{absent_dir}->{$pb->{path}} ||= [];
3750 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
3751 undef;
3752 }
3754 sub absent_file {
3755 my ($self, $path, $pb) = @_;
3756 return undef if $self->is_path_ignored($path);
3757 $self->{absent_file}->{$pb->{path}} ||= [];
3758 push @{$self->{absent_file}->{$pb->{path}}}, $path;
3759 undef;
3760 }
3762 sub change_file_prop {
3763 my ($self, $fb, $prop, $value) = @_;
3764 return undef if $self->is_path_ignored($fb->{path});
3765 if ($prop eq 'svn:executable') {
3766 if ($fb->{mode_b} != 120000) {
3767 $fb->{mode_b} = defined $value ? 100755 : 100644;
3768 }
3769 } elsif ($prop eq 'svn:special') {
3770 $fb->{mode_b} = defined $value ? 120000 : 100644;
3771 } else {
3772 $self->{file_prop}->{$fb->{path}} ||= {};
3773 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
3774 }
3775 undef;
3776 }
3778 sub apply_textdelta {
3779 my ($self, $fb, $exp) = @_;
3780 return undef if $self->is_path_ignored($fb->{path});
3781 my $fh = $::_repository->temp_acquire('svn_delta');
3782 # $fh gets auto-closed() by SVN::TxDelta::apply(),
3783 # (but $base does not,) so dup() it for reading in close_file
3784 open my $dup, '<&', $fh or croak $!;
3785 my $base = $::_repository->temp_acquire('git_blob');
3787 if ($fb->{blob}) {
3788 my ($base_is_link, $size);
3790 if ($fb->{mode_a} eq '120000' &&
3791 ! $self->{empty_symlinks}->{$fb->{path}}) {
3792 print $base 'link ' or die "print $!\n";
3793 $base_is_link = 1;
3794 }
3795 retry:
3796 $size = $::_repository->cat_blob($fb->{blob}, $base);
3797 die "Failed to read object $fb->{blob}" if ($size < 0);
3799 if (defined $exp) {
3800 seek $base, 0, 0 or croak $!;
3801 my $got = ::md5sum($base);
3802 if ($got ne $exp) {
3803 my $err = "Checksum mismatch: ".
3804 "$fb->{path} $fb->{blob}\n" .
3805 "expected: $exp\n" .
3806 " got: $got\n";
3807 if ($base_is_link) {
3808 warn $err,
3809 "Retrying... (possibly ",
3810 "a bad symlink from SVN)\n";
3811 $::_repository->temp_reset($base);
3812 $base_is_link = 0;
3813 goto retry;
3814 }
3815 die $err;
3816 }
3817 }
3818 }
3819 seek $base, 0, 0 or croak $!;
3820 $fb->{fh} = $fh;
3821 $fb->{base} = $base;
3822 [ SVN::TxDelta::apply($base, $dup, undef, $fb->{path}, $fb->{pool}) ];
3823 }
3825 sub close_file {
3826 my ($self, $fb, $exp) = @_;
3827 return undef if $self->is_path_ignored($fb->{path});
3829 my $hash;
3830 my $path = $self->git_path($fb->{path});
3831 if (my $fh = $fb->{fh}) {
3832 if (defined $exp) {
3833 seek($fh, 0, 0) or croak $!;
3834 my $got = ::md5sum($fh);
3835 if ($got ne $exp) {
3836 die "Checksum mismatch: $path\n",
3837 "expected: $exp\n got: $got\n";
3838 }
3839 }
3840 if ($fb->{mode_b} == 120000) {
3841 sysseek($fh, 0, 0) or croak $!;
3842 my $rd = sysread($fh, my $buf, 5);
3844 if (!defined $rd) {
3845 croak "sysread: $!\n";
3846 } elsif ($rd == 0) {
3847 warn "$path has mode 120000",
3848 " but it points to nothing\n",
3849 "converting to an empty file with mode",
3850 " 100644\n";
3851 $fb->{mode_b} = '100644';
3852 } elsif ($buf ne 'link ') {
3853 warn "$path has mode 120000",
3854 " but is not a link\n";
3855 } else {
3856 my $tmp_fh = $::_repository->temp_acquire(
3857 'svn_hash');
3858 my $res;
3859 while ($res = sysread($fh, my $str, 1024)) {
3860 my $out = syswrite($tmp_fh, $str, $res);
3861 defined($out) && $out == $res
3862 or croak("write ",
3863 Git::temp_path($tmp_fh),
3864 ": $!\n");
3865 }
3866 defined $res or croak $!;
3868 ($fh, $tmp_fh) = ($tmp_fh, $fh);
3869 Git::temp_release($tmp_fh, 1);
3870 }
3871 }
3873 $hash = $::_repository->hash_and_insert_object(
3874 Git::temp_path($fh));
3875 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
3877 Git::temp_release($fb->{base}, 1);
3878 Git::temp_release($fh, 1);
3879 } else {
3880 $hash = $fb->{blob} or die "no blob information\n";
3881 }
3882 $fb->{pool}->clear;
3883 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
3884 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $::_q;
3885 undef;
3886 }
3888 sub abort_edit {
3889 my $self = shift;
3890 $self->{nr} = $self->{gii}->{nr};
3891 delete $self->{gii};
3892 $self->SUPER::abort_edit(@_);
3893 }
3895 sub close_edit {
3896 my $self = shift;
3897 $self->{git_commit_ok} = 1;
3898 $self->{nr} = $self->{gii}->{nr};
3899 delete $self->{gii};
3900 $self->SUPER::close_edit(@_);
3901 }
3903 package SVN::Git::Editor;
3904 use vars qw/@ISA $_rmdir $_cp_similarity $_find_copies_harder $_rename_limit/;
3905 use strict;
3906 use warnings;
3907 use Carp qw/croak/;
3908 use IO::File;
3910 sub new {
3911 my ($class, $opts) = @_;
3912 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
3913 die "$_ required!\n" unless (defined $opts->{$_});
3914 }
3916 my $pool = SVN::Pool->new;
3917 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
3918 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
3919 $opts->{r}, $mods);
3921 # $opts->{ra} functions should not be used after this:
3922 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
3923 $opts->{editor_cb}, $pool);
3924 my $self = SVN::Delta::Editor->new(@ce, $pool);
3925 bless $self, $class;
3926 foreach (qw/svn_path r tree_a tree_b/) {
3927 $self->{$_} = $opts->{$_};
3928 }
3929 $self->{url} = $opts->{ra}->{url};
3930 $self->{mods} = $mods;
3931 $self->{types} = $types;
3932 $self->{pool} = $pool;
3933 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3934 $self->{rm} = { };
3935 $self->{path_prefix} = length $self->{svn_path} ?
3936 "$self->{svn_path}/" : '';
3937 $self->{config} = $opts->{config};
3938 return $self;
3939 }
3941 sub generate_diff {
3942 my ($tree_a, $tree_b) = @_;
3943 my @diff_tree = qw(diff-tree -z -r);
3944 if ($_cp_similarity) {
3945 push @diff_tree, "-C$_cp_similarity";
3946 } else {
3947 push @diff_tree, '-C';
3948 }
3949 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
3950 push @diff_tree, "-l$_rename_limit" if defined $_rename_limit;
3951 push @diff_tree, $tree_a, $tree_b;
3952 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
3953 local $/ = "\0";
3954 my $state = 'meta';
3955 my @mods;
3956 while (<$diff_fh>) {
3957 chomp $_; # this gets rid of the trailing "\0"
3958 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
3959 ($::sha1)\s($::sha1)\s
3960 ([MTCRAD])\d*$/xo) {
3961 push @mods, { mode_a => $1, mode_b => $2,
3962 sha1_a => $3, sha1_b => $4,
3963 chg => $5 };
3964 if ($5 =~ /^(?:C|R)$/) {
3965 $state = 'file_a';
3966 } else {
3967 $state = 'file_b';
3968 }
3969 } elsif ($state eq 'file_a') {
3970 my $x = $mods[$#mods] or croak "Empty array\n";
3971 if ($x->{chg} !~ /^(?:C|R)$/) {
3972 croak "Error parsing $_, $x->{chg}\n";
3973 }
3974 $x->{file_a} = $_;
3975 $state = 'file_b';
3976 } elsif ($state eq 'file_b') {
3977 my $x = $mods[$#mods] or croak "Empty array\n";
3978 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
3979 croak "Error parsing $_, $x->{chg}\n";
3980 }
3981 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
3982 croak "Error parsing $_, $x->{chg}\n";
3983 }
3984 $x->{file_b} = $_;
3985 $state = 'meta';
3986 } else {
3987 croak "Error parsing $_\n";
3988 }
3989 }
3990 command_close_pipe($diff_fh, $ctx);
3991 \@mods;
3992 }
3994 sub check_diff_paths {
3995 my ($ra, $pfx, $rev, $mods) = @_;
3996 my %types;
3997 $pfx .= '/' if length $pfx;
3999 sub type_diff_paths {
4000 my ($ra, $types, $path, $rev) = @_;
4001 my @p = split m#/+#, $path;
4002 my $c = shift @p;
4003 unless (defined $types->{$c}) {
4004 $types->{$c} = $ra->check_path($c, $rev);
4005 }
4006 while (@p) {
4007 $c .= '/' . shift @p;
4008 next if defined $types->{$c};
4009 $types->{$c} = $ra->check_path($c, $rev);
4010 }
4011 }
4013 foreach my $m (@$mods) {
4014 foreach my $f (qw/file_a file_b/) {
4015 next unless defined $m->{$f};
4016 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
4017 if (length $pfx.$dir && ! defined $types{$dir}) {
4018 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
4019 }
4020 }
4021 }
4022 \%types;
4023 }
4025 sub split_path {
4026 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
4027 }
4029 sub repo_path {
4030 my ($self, $path) = @_;
4031 $self->{path_prefix}.(defined $path ? $path : '');
4032 }
4034 sub url_path {
4035 my ($self, $path) = @_;
4036 if ($self->{url} =~ m#^https?://#) {
4037 $path =~ s!([^~a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;
4038 }
4039 $self->{url} . '/' . $self->repo_path($path);
4040 }
4042 sub rmdirs {
4043 my ($self) = @_;
4044 my $rm = $self->{rm};
4045 delete $rm->{''}; # we never delete the url we're tracking
4046 return unless %$rm;
4048 foreach (keys %$rm) {
4049 my @d = split m#/#, $_;
4050 my $c = shift @d;
4051 $rm->{$c} = 1;
4052 while (@d) {
4053 $c .= '/' . shift @d;
4054 $rm->{$c} = 1;
4055 }
4056 }
4057 delete $rm->{$self->{svn_path}};
4058 delete $rm->{''}; # we never delete the url we're tracking
4059 return unless %$rm;
4061 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
4062 $self->{tree_b});
4063 local $/ = "\0";
4064 while (<$fh>) {
4065 chomp;
4066 my @dn = split m#/#, $_;
4067 while (pop @dn) {
4068 delete $rm->{join '/', @dn};
4069 }
4070 unless (%$rm) {
4071 close $fh;
4072 return;
4073 }
4074 }
4075 command_close_pipe($fh, $ctx);
4077 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
4078 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
4079 $self->close_directory($bat->{$d}, $p);
4080 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
4081 print "\tD+\t$d/\n" unless $::_q;
4082 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
4083 delete $bat->{$d};
4084 }
4085 }
4087 sub open_or_add_dir {
4088 my ($self, $full_path, $baton) = @_;
4089 my $t = $self->{types}->{$full_path};
4090 if (!defined $t) {
4091 die "$full_path not known in r$self->{r} or we have a bug!\n";
4092 }
4093 {
4094 no warnings 'once';
4095 # SVN::Node::none and SVN::Node::file are used only once,
4096 # so we're shutting up Perl's warnings about them.
4097 if ($t == $SVN::Node::none) {
4098 return $self->add_directory($full_path, $baton,
4099 undef, -1, $self->{pool});
4100 } elsif ($t == $SVN::Node::dir) {
4101 return $self->open_directory($full_path, $baton,
4102 $self->{r}, $self->{pool});
4103 } # no warnings 'once'
4104 print STDERR "$full_path already exists in repository at ",
4105 "r$self->{r} and it is not a directory (",
4106 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
4107 } # no warnings 'once'
4108 exit 1;
4109 }
4111 sub ensure_path {
4112 my ($self, $path) = @_;
4113 my $bat = $self->{bat};
4114 my $repo_path = $self->repo_path($path);
4115 return $bat->{''} unless (length $repo_path);
4116 my @p = split m#/+#, $repo_path;
4117 my $c = shift @p;
4118 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
4119 while (@p) {
4120 my $c0 = $c;
4121 $c .= '/' . shift @p;
4122 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
4123 }
4124 return $bat->{$c};
4125 }
4127 # Subroutine to convert a globbing pattern to a regular expression.
4128 # From perl cookbook.
4129 sub glob2pat {
4130 my $globstr = shift;
4131 my %patmap = ('*' => '.*', '?' => '.', '[' => '[', ']' => ']');
4132 $globstr =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
4133 return '^' . $globstr . '$';
4134 }
4136 sub check_autoprop {
4137 my ($self, $pattern, $properties, $file, $fbat) = @_;
4138 # Convert the globbing pattern to a regular expression.
4139 my $regex = glob2pat($pattern);
4140 # Check if the pattern matches the file name.
4141 if($file =~ m/($regex)/) {
4142 # Parse the list of properties to set.
4143 my @props = split(/;/, $properties);
4144 foreach my $prop (@props) {
4145 # Parse 'name=value' syntax and set the property.
4146 if ($prop =~ /([^=]+)=(.*)/) {
4147 my ($n,$v) = ($1,$2);
4148 for ($n, $v) {
4149 s/^\s+//; s/\s+$//;
4150 }
4151 $self->change_file_prop($fbat, $n, $v);
4152 }
4153 }
4154 }
4155 }
4157 sub apply_autoprops {
4158 my ($self, $file, $fbat) = @_;
4159 my $conf_t = ${$self->{config}}{'config'};
4160 no warnings 'once';
4161 # Check [miscellany]/enable-auto-props in svn configuration.
4162 if (SVN::_Core::svn_config_get_bool(
4163 $conf_t,
4164 $SVN::_Core::SVN_CONFIG_SECTION_MISCELLANY,
4165 $SVN::_Core::SVN_CONFIG_OPTION_ENABLE_AUTO_PROPS,
4166 0)) {
4167 # Auto-props are enabled. Enumerate them to look for matches.
4168 my $callback = sub {
4169 $self->check_autoprop($_[0], $_[1], $file, $fbat);
4170 };
4171 SVN::_Core::svn_config_enumerate(
4172 $conf_t,
4173 $SVN::_Core::SVN_CONFIG_SECTION_AUTO_PROPS,
4174 $callback);
4175 }
4176 }
4178 sub A {
4179 my ($self, $m) = @_;
4180 my ($dir, $file) = split_path($m->{file_b});
4181 my $pbat = $self->ensure_path($dir);
4182 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4183 undef, -1);
4184 print "\tA\t$m->{file_b}\n" unless $::_q;
4185 $self->apply_autoprops($file, $fbat);
4186 $self->chg_file($fbat, $m);
4187 $self->close_file($fbat,undef,$self->{pool});
4188 }
4190 sub C {
4191 my ($self, $m) = @_;
4192 my ($dir, $file) = split_path($m->{file_b});
4193 my $pbat = $self->ensure_path($dir);
4194 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4195 $self->url_path($m->{file_a}), $self->{r});
4196 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4197 $self->chg_file($fbat, $m);
4198 $self->close_file($fbat,undef,$self->{pool});
4199 }
4201 sub delete_entry {
4202 my ($self, $path, $pbat) = @_;
4203 my $rpath = $self->repo_path($path);
4204 my ($dir, $file) = split_path($rpath);
4205 $self->{rm}->{$dir} = 1;
4206 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
4207 }
4209 sub R {
4210 my ($self, $m) = @_;
4211 my ($dir, $file) = split_path($m->{file_b});
4212 my $pbat = $self->ensure_path($dir);
4213 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
4214 $self->url_path($m->{file_a}), $self->{r});
4215 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
4216 $self->apply_autoprops($file, $fbat);
4217 $self->chg_file($fbat, $m);
4218 $self->close_file($fbat,undef,$self->{pool});
4220 ($dir, $file) = split_path($m->{file_a});
4221 $pbat = $self->ensure_path($dir);
4222 $self->delete_entry($m->{file_a}, $pbat);
4223 }
4225 sub M {
4226 my ($self, $m) = @_;
4227 my ($dir, $file) = split_path($m->{file_b});
4228 my $pbat = $self->ensure_path($dir);
4229 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
4230 $pbat,$self->{r},$self->{pool});
4231 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
4232 $self->chg_file($fbat, $m);
4233 $self->close_file($fbat,undef,$self->{pool});
4234 }
4236 sub T { shift->M(@_) }
4238 sub change_file_prop {
4239 my ($self, $fbat, $pname, $pval) = @_;
4240 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
4241 }
4243 sub _chg_file_get_blob ($$$$) {
4244 my ($self, $fbat, $m, $which) = @_;
4245 my $fh = $::_repository->temp_acquire("git_blob_$which");
4246 if ($m->{"mode_$which"} =~ /^120/) {
4247 print $fh 'link ' or croak $!;
4248 $self->change_file_prop($fbat,'svn:special','*');
4249 } elsif ($m->{mode_a} =~ /^120/ && $m->{"mode_$which"} !~ /^120/) {
4250 $self->change_file_prop($fbat,'svn:special',undef);
4251 }
4252 my $blob = $m->{"sha1_$which"};
4253 return ($fh,) if ($blob =~ /^0{40}$/);
4254 my $size = $::_repository->cat_blob($blob, $fh);
4255 croak "Failed to read object $blob" if ($size < 0);
4256 $fh->flush == 0 or croak $!;
4257 seek $fh, 0, 0 or croak $!;
4259 my $exp = ::md5sum($fh);
4260 seek $fh, 0, 0 or croak $!;
4261 return ($fh, $exp);
4262 }
4264 sub chg_file {
4265 my ($self, $fbat, $m) = @_;
4266 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
4267 $self->change_file_prop($fbat,'svn:executable','*');
4268 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
4269 $self->change_file_prop($fbat,'svn:executable',undef);
4270 }
4271 my ($fh_a, $exp_a) = _chg_file_get_blob $self, $fbat, $m, 'a';
4272 my ($fh_b, $exp_b) = _chg_file_get_blob $self, $fbat, $m, 'b';
4273 my $pool = SVN::Pool->new;
4274 my $atd = $self->apply_textdelta($fbat, $exp_a, $pool);
4275 if (-s $fh_a) {
4276 my $txstream = SVN::TxDelta::new ($fh_a, $fh_b, $pool);
4277 my $res = SVN::TxDelta::send_txstream($txstream, @$atd, $pool);
4278 if (defined $res) {
4279 die "Unexpected result from send_txstream: $res\n",
4280 "(SVN::Core::VERSION: $SVN::Core::VERSION)\n";
4281 }
4282 } else {
4283 my $got = SVN::TxDelta::send_stream($fh_b, @$atd, $pool);
4284 die "Checksum mismatch\nexpected: $exp_b\ngot: $got\n"
4285 if ($got ne $exp_b);
4286 }
4287 Git::temp_release($fh_b, 1);
4288 Git::temp_release($fh_a, 1);
4289 $pool->clear;
4290 }
4292 sub D {
4293 my ($self, $m) = @_;
4294 my ($dir, $file) = split_path($m->{file_b});
4295 my $pbat = $self->ensure_path($dir);
4296 print "\tD\t$m->{file_b}\n" unless $::_q;
4297 $self->delete_entry($m->{file_b}, $pbat);
4298 }
4300 sub close_edit {
4301 my ($self) = @_;
4302 my ($p,$bat) = ($self->{pool}, $self->{bat});
4303 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
4304 next if $_ eq '';
4305 $self->close_directory($bat->{$_}, $p);
4306 }
4307 $self->close_directory($bat->{''}, $p);
4308 $self->SUPER::close_edit($p);
4309 $p->clear;
4310 }
4312 sub abort_edit {
4313 my ($self) = @_;
4314 $self->SUPER::abort_edit($self->{pool});
4315 }
4317 sub DESTROY {
4318 my $self = shift;
4319 $self->SUPER::DESTROY(@_);
4320 $self->{pool}->clear;
4321 }
4323 # this drives the editor
4324 sub apply_diff {
4325 my ($self) = @_;
4326 my $mods = $self->{mods};
4327 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
4328 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
4329 my $f = $m->{chg};
4330 if (defined $o{$f}) {
4331 $self->$f($m);
4332 } else {
4333 fatal("Invalid change type: $f");
4334 }
4335 }
4336 $self->rmdirs if $_rmdir;
4337 if (@$mods == 0) {
4338 $self->abort_edit;
4339 } else {
4340 $self->close_edit;
4341 }
4342 return scalar @$mods;
4343 }
4345 package Git::SVN::Ra;
4346 use vars qw/@ISA $config_dir $_log_window_size/;
4347 use strict;
4348 use warnings;
4349 my ($ra_invalid, $can_do_switch, %ignored_err, $RA);
4351 BEGIN {
4352 # enforce temporary pool usage for some simple functions
4353 no strict 'refs';
4354 for my $f (qw/rev_proplist get_latest_revnum get_uuid get_repos_root
4355 get_file/) {
4356 my $SUPER = "SUPER::$f";
4357 *$f = sub {
4358 my $self = shift;
4359 my $pool = SVN::Pool->new;
4360 my @ret = $self->$SUPER(@_,$pool);
4361 $pool->clear;
4362 wantarray ? @ret : $ret[0];
4363 };
4364 }
4365 }
4367 sub _auth_providers () {
4368 [
4369 SVN::Client::get_simple_provider(),
4370 SVN::Client::get_ssl_server_trust_file_provider(),
4371 SVN::Client::get_simple_prompt_provider(
4372 \&Git::SVN::Prompt::simple, 2),
4373 SVN::Client::get_ssl_client_cert_file_provider(),
4374 SVN::Client::get_ssl_client_cert_prompt_provider(
4375 \&Git::SVN::Prompt::ssl_client_cert, 2),
4376 SVN::Client::get_ssl_client_cert_pw_file_provider(),
4377 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
4378 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
4379 SVN::Client::get_username_provider(),
4380 SVN::Client::get_ssl_server_trust_prompt_provider(
4381 \&Git::SVN::Prompt::ssl_server_trust),
4382 SVN::Client::get_username_prompt_provider(
4383 \&Git::SVN::Prompt::username, 2)
4384 ]
4385 }
4387 sub escape_uri_only {
4388 my ($uri) = @_;
4389 my @tmp;
4390 foreach (split m{/}, $uri) {
4391 s/([^~\w.%+-]|%(?![a-fA-F0-9]{2}))/sprintf("%%%02X",ord($1))/eg;
4392 push @tmp, $_;
4393 }
4394 join('/', @tmp);
4395 }
4397 sub escape_url {
4398 my ($url) = @_;
4399 if ($url =~ m#^(https?)://([^/]+)(.*)$#) {
4400 my ($scheme, $domain, $uri) = ($1, $2, escape_uri_only($3));
4401 $url = "$scheme://$domain$uri";
4402 }
4403 $url;
4404 }
4406 sub new {
4407 my ($class, $url) = @_;
4408 $url =~ s!/+$!!;
4409 return $RA if ($RA && $RA->{url} eq $url);
4411 SVN::_Core::svn_config_ensure($config_dir, undef);
4412 my ($baton, $callbacks) = SVN::Core::auth_open_helper(_auth_providers);
4413 my $config = SVN::Core::config_get_config($config_dir);
4414 $RA = undef;
4415 my $dont_store_passwords = 1;
4416 my $conf_t = ${$config}{'config'};
4417 {
4418 no warnings 'once';
4419 # The usage of $SVN::_Core::SVN_CONFIG_* variables
4420 # produces warnings that variables are used only once.
4421 # I had not found the better way to shut them up, so
4422 # the warnings of type 'once' are disabled in this block.
4423 if (SVN::_Core::svn_config_get_bool($conf_t,
4424 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4425 $SVN::_Core::SVN_CONFIG_OPTION_STORE_PASSWORDS,
4426 1) == 0) {
4427 SVN::_Core::svn_auth_set_parameter($baton,
4428 $SVN::_Core::SVN_AUTH_PARAM_DONT_STORE_PASSWORDS,
4429 bless (\$dont_store_passwords, "_p_void"));
4430 }
4431 if (SVN::_Core::svn_config_get_bool($conf_t,
4432 $SVN::_Core::SVN_CONFIG_SECTION_AUTH,
4433 $SVN::_Core::SVN_CONFIG_OPTION_STORE_AUTH_CREDS,
4434 1) == 0) {
4435 $Git::SVN::Prompt::_no_auth_cache = 1;
4436 }
4437 } # no warnings 'once'
4438 my $self = SVN::Ra->new(url => escape_url($url), auth => $baton,
4439 config => $config,
4440 pool => SVN::Pool->new,
4441 auth_provider_callbacks => $callbacks);
4442 $self->{url} = $url;
4443 $self->{svn_path} = $url;
4444 $self->{repos_root} = $self->get_repos_root;
4445 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E(/|$)##;
4446 $self->{cache} = { check_path => { r => 0, data => {} },
4447 get_dir => { r => 0, data => {} } };
4448 $RA = bless $self, $class;
4449 }
4451 sub check_path {
4452 my ($self, $path, $r) = @_;
4453 my $cache = $self->{cache}->{check_path};
4454 if ($r == $cache->{r} && exists $cache->{data}->{$path}) {
4455 return $cache->{data}->{$path};
4456 }
4457 my $pool = SVN::Pool->new;
4458 my $t = $self->SUPER::check_path($path, $r, $pool);
4459 $pool->clear;
4460 if ($r != $cache->{r}) {
4461 %{$cache->{data}} = ();
4462 $cache->{r} = $r;
4463 }
4464 $cache->{data}->{$path} = $t;
4465 }
4467 sub get_dir {
4468 my ($self, $dir, $r) = @_;
4469 my $cache = $self->{cache}->{get_dir};
4470 if ($r == $cache->{r}) {
4471 if (my $x = $cache->{data}->{$dir}) {
4472 return wantarray ? @$x : $x->[0];
4473 }
4474 }
4475 my $pool = SVN::Pool->new;
4476 my ($d, undef, $props) = $self->SUPER::get_dir($dir, $r, $pool);
4477 my %dirents = map { $_ => { kind => $d->{$_}->kind } } keys %$d;
4478 $pool->clear;
4479 if ($r != $cache->{r}) {
4480 %{$cache->{data}} = ();
4481 $cache->{r} = $r;
4482 }
4483 $cache->{data}->{$dir} = [ \%dirents, $r, $props ];
4484 wantarray ? (\%dirents, $r, $props) : \%dirents;
4485 }
4487 sub DESTROY {
4488 # do not call the real DESTROY since we store ourselves in $RA
4489 }
4491 # get_log(paths, start, end, limit,
4492 # discover_changed_paths, strict_node_history, receiver)
4493 sub get_log {
4494 my ($self, @args) = @_;
4495 my $pool = SVN::Pool->new;
4497 # svn_log_changed_path_t objects passed to get_log are likely to be
4498 # overwritten even if only the refs are copied to an external variable,
4499 # so we should dup the structures in their entirety. Using an
4500 # externally passed pool (instead of our temporary and quickly cleared
4501 # pool in Git::SVN::Ra) does not help matters at all...
4502 my $receiver = pop @args;
4503 my $prefix = "/".$self->{svn_path};
4504 $prefix =~ s#/+($)##;
4505 my $prefix_regex = qr#^\Q$prefix\E#;
4506 push(@args, sub {
4507 my ($paths) = $_[0];
4508 return &$receiver(@_) unless $paths;
4509 $_[0] = ();
4510 foreach my $p (keys %$paths) {
4511 my $i = $paths->{$p};
4512 # Make path relative to our url, not repos_root
4513 $p =~ s/$prefix_regex//;
4514 my %s = map { $_ => $i->$_; }
4515 qw/copyfrom_path copyfrom_rev action/;
4516 if ($s{'copyfrom_path'}) {
4517 $s{'copyfrom_path'} =~ s/$prefix_regex//;
4518 }
4519 $_[0]{$p} = \%s;
4520 }
4521 &$receiver(@_);
4522 });
4525 # the limit parameter was not supported in SVN 1.1.x, so we
4526 # drop it. Therefore, the receiver callback passed to it
4527 # is made aware of this limitation by being wrapped if
4528 # the limit passed to is being wrapped.
4529 if ($SVN::Core::VERSION le '1.2.0') {
4530 my $limit = splice(@args, 3, 1);
4531 if ($limit > 0) {
4532 my $receiver = pop @args;
4533 push(@args, sub { &$receiver(@_) if (--$limit >= 0) });
4534 }
4535 }
4536 my $ret = $self->SUPER::get_log(@args, $pool);
4537 $pool->clear;
4538 $ret;
4539 }
4541 sub trees_match {
4542 my ($self, $url1, $rev1, $url2, $rev2) = @_;
4543 my $ctx = SVN::Client->new(auth => _auth_providers);
4544 my $out = IO::File->new_tmpfile;
4546 # older SVN (1.1.x) doesn't take $pool as the last parameter for
4547 # $ctx->diff(), so we'll create a default one
4548 my $pool = SVN::Pool->new_default_sub;
4550 $ra_invalid = 1; # this will open a new SVN::Ra connection to $url1
4551 $ctx->diff([], $url1, $rev1, $url2, $rev2, 1, 1, 0, $out, $out);
4552 $out->flush;
4553 my $ret = (($out->stat)[7] == 0);
4554 close $out or croak $!;
4556 $ret;
4557 }
4559 sub get_commit_editor {
4560 my ($self, $log, $cb, $pool) = @_;
4561 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
4562 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
4563 }
4565 sub gs_do_update {
4566 my ($self, $rev_a, $rev_b, $gs, $editor) = @_;
4567 my $new = ($rev_a == $rev_b);
4568 my $path = $gs->{path};
4570 if ($new && -e $gs->{index}) {
4571 unlink $gs->{index} or die
4572 "Couldn't unlink index: $gs->{index}: $!\n";
4573 }
4574 my $pool = SVN::Pool->new;
4575 $editor->set_path_strip($path);
4576 my (@pc) = split m#/#, $path;
4577 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
4578 1, $editor, $pool);
4579 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4581 # Since we can't rely on svn_ra_reparent being available, we'll
4582 # just have to do some magic with set_path to make it so
4583 # we only want a partial path.
4584 my $sp = '';
4585 my $final = join('/', @pc);
4586 while (@pc) {
4587 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
4588 $sp .= '/' if length $sp;
4589 $sp .= shift @pc;
4590 }
4591 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
4593 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
4595 $reporter->finish_report($pool);
4596 $pool->clear;
4597 $editor->{git_commit_ok};
4598 }
4600 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
4601 # svn_ra_reparent didn't work before 1.4)
4602 sub gs_do_switch {
4603 my ($self, $rev_a, $rev_b, $gs, $url_b, $editor) = @_;
4604 my $path = $gs->{path};
4605 my $pool = SVN::Pool->new;
4607 my $full_url = $self->{url};
4608 my $old_url = $full_url;
4609 $full_url .= '/' . $path if length $path;
4610 my ($ra, $reparented);
4612 if ($old_url =~ m#^svn(\+ssh)?://# ||
4613 ($full_url =~ m#^https?://# &&
4614 escape_url($full_url) ne $full_url)) {
4615 $_[0] = undef;
4616 $self = undef;
4617 $RA = undef;
4618 $ra = Git::SVN::Ra->new($full_url);
4619 $ra_invalid = 1;
4620 } elsif ($old_url ne $full_url) {
4621 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
4622 $self->{url} = $full_url;
4623 $reparented = 1;
4624 }
4626 $ra ||= $self;
4627 $url_b = escape_url($url_b);
4628 my $reporter = $ra->do_switch($rev_b, '', 1, $url_b, $editor, $pool);
4629 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
4630 $reporter->set_path('', $rev_a, 0, @lock, $pool);
4631 $reporter->finish_report($pool);
4633 if ($reparented) {
4634 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
4635 $self->{url} = $old_url;
4636 }
4638 $pool->clear;
4639 $editor->{git_commit_ok};
4640 }
4642 sub longest_common_path {
4643 my ($gsv, $globs) = @_;
4644 my %common;
4645 my $common_max = scalar @$gsv;
4647 foreach my $gs (@$gsv) {
4648 my @tmp = split m#/#, $gs->{path};
4649 my $p = '';
4650 foreach (@tmp) {
4651 $p .= length($p) ? "/$_" : $_;
4652 $common{$p} ||= 0;
4653 $common{$p}++;
4654 }
4655 }
4656 $globs ||= [];
4657 $common_max += scalar @$globs;
4658 foreach my $glob (@$globs) {
4659 my @tmp = split m#/#, $glob->{path}->{left};
4660 my $p = '';
4661 foreach (@tmp) {
4662 $p .= length($p) ? "/$_" : $_;
4663 $common{$p} ||= 0;
4664 $common{$p}++;
4665 }
4666 }
4668 my $longest_path = '';
4669 foreach (sort {length $b <=> length $a} keys %common) {
4670 if ($common{$_} == $common_max) {
4671 $longest_path = $_;
4672 last;
4673 }
4674 }
4675 $longest_path;
4676 }
4678 sub gs_fetch_loop_common {
4679 my ($self, $base, $head, $gsv, $globs) = @_;
4680 return if ($base > $head);
4681 my $inc = $_log_window_size;
4682 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
4683 my $longest_path = longest_common_path($gsv, $globs);
4684 my $ra_url = $self->{url};
4685 my $find_trailing_edge;
4686 while (1) {
4687 my %revs;
4688 my $err;
4689 my $err_handler = $SVN::Error::handler;
4690 $SVN::Error::handler = sub {
4691 ($err) = @_;
4692 skip_unknown_revs($err);
4693 };
4694 sub _cb {
4695 my ($paths, $r, $author, $date, $log) = @_;
4696 [ $paths,
4697 { author => $author, date => $date, log => $log } ];
4698 }
4699 $self->get_log([$longest_path], $min, $max, 0, 1, 1,
4700 sub { $revs{$_[1]} = _cb(@_) });
4701 if ($err) {
4702 print "Checked through r$max\r";
4703 } else {
4704 $find_trailing_edge = 1;
4705 }
4706 if ($err and $find_trailing_edge) {
4707 print STDERR "Path '$longest_path' ",
4708 "was probably deleted:\n",
4709 $err->expanded_message,
4710 "\nWill attempt to follow ",
4711 "revisions r$min .. r$max ",
4712 "committed before the deletion\n";
4713 my $hi = $max;
4714 while (--$hi >= $min) {
4715 my $ok;
4716 $self->get_log([$longest_path], $min, $hi,
4717 0, 1, 1, sub {
4718 $ok = $_[1];
4719 $revs{$_[1]} = _cb(@_) });
4720 if ($ok) {
4721 print STDERR "r$min .. r$ok OK\n";
4722 last;
4723 }
4724 }
4725 $find_trailing_edge = 0;
4726 }
4727 $SVN::Error::handler = $err_handler;
4729 my %exists = map { $_->{path} => $_ } @$gsv;
4730 foreach my $r (sort {$a <=> $b} keys %revs) {
4731 my ($paths, $logged) = @{$revs{$r}};
4733 foreach my $gs ($self->match_globs(\%exists, $paths,
4734 $globs, $r)) {
4735 if ($gs->rev_map_max >= $r) {
4736 next;
4737 }
4738 next unless $gs->match_paths($paths, $r);
4739 $gs->{logged_rev_props} = $logged;
4740 if (my $last_commit = $gs->last_commit) {
4741 $gs->assert_index_clean($last_commit);
4742 }
4743 my $log_entry = $gs->do_fetch($paths, $r);
4744 if ($log_entry) {
4745 $gs->do_git_commit($log_entry);
4746 }
4747 $INDEX_FILES{$gs->{index}} = 1;
4748 }
4749 foreach my $g (@$globs) {
4750 my $k = "svn-remote.$g->{remote}." .
4751 "$g->{t}-maxRev";
4752 Git::SVN::tmp_config($k, $r);
4753 }
4754 if ($ra_invalid) {
4755 $_[0] = undef;
4756 $self = undef;
4757 $RA = undef;
4758 $self = Git::SVN::Ra->new($ra_url);
4759 $ra_invalid = undef;
4760 }
4761 }
4762 # pre-fill the .rev_db since it'll eventually get filled in
4763 # with '0' x40 if something new gets committed
4764 foreach my $gs (@$gsv) {
4765 next if $gs->rev_map_max >= $max;
4766 next if defined $gs->rev_map_get($max);
4767 $gs->rev_map_set($max, 0 x40);
4768 }
4769 foreach my $g (@$globs) {
4770 my $k = "svn-remote.$g->{remote}.$g->{t}-maxRev";
4771 Git::SVN::tmp_config($k, $max);
4772 }
4773 last if $max >= $head;
4774 $min = $max + 1;
4775 $max += $inc;
4776 $max = $head if ($max > $head);
4777 }
4778 Git::SVN::gc();
4779 }
4781 sub get_dir_globbed {
4782 my ($self, $left, $depth, $r) = @_;
4784 my @x = eval { $self->get_dir($left, $r) };
4785 return unless scalar @x == 3;
4786 my $dirents = $x[0];
4787 my @finalents;
4788 foreach my $de (keys %$dirents) {
4789 next if $dirents->{$de}->{kind} != $SVN::Node::dir;
4790 if ($depth > 1) {
4791 my @args = ("$left/$de", $depth - 1, $r);
4792 foreach my $dir ($self->get_dir_globbed(@args)) {
4793 push @finalents, "$de/$dir";
4794 }
4795 } else {
4796 push @finalents, $de;
4797 }
4798 }
4799 @finalents;
4800 }
4802 sub match_globs {
4803 my ($self, $exists, $paths, $globs, $r) = @_;
4805 sub get_dir_check {
4806 my ($self, $exists, $g, $r) = @_;
4808 my @dirs = $self->get_dir_globbed($g->{path}->{left},
4809 $g->{path}->{depth},
4810 $r);
4812 foreach my $de (@dirs) {
4813 my $p = $g->{path}->full_path($de);
4814 next if $exists->{$p};
4815 next if (length $g->{path}->{right} &&
4816 ($self->check_path($p, $r) !=
4817 $SVN::Node::dir));
4818 $exists->{$p} = Git::SVN->init($self->{url}, $p, undef,
4819 $g->{ref}->full_path($de), 1);
4820 }
4821 }
4822 foreach my $g (@$globs) {
4823 if (my $path = $paths->{"/$g->{path}->{left}"}) {
4824 if ($path->{action} =~ /^[AR]$/) {
4825 get_dir_check($self, $exists, $g, $r);
4826 }
4827 }
4828 foreach (keys %$paths) {
4829 if (/$g->{path}->{left_regex}/ &&
4830 !/$g->{path}->{regex}/) {
4831 next if $paths->{$_}->{action} !~ /^[AR]$/;
4832 get_dir_check($self, $exists, $g, $r);
4833 }
4834 next unless /$g->{path}->{regex}/;
4835 my $p = $1;
4836 my $pathname = $g->{path}->full_path($p);
4837 next if $exists->{$pathname};
4838 next if ($self->check_path($pathname, $r) !=
4839 $SVN::Node::dir);
4840 $exists->{$pathname} = Git::SVN->init(
4841 $self->{url}, $pathname, undef,
4842 $g->{ref}->full_path($p), 1);
4843 }
4844 my $c = '';
4845 foreach (split m#/#, $g->{path}->{left}) {
4846 $c .= "/$_";
4847 next unless ($paths->{$c} &&
4848 ($paths->{$c}->{action} =~ /^[AR]$/));
4849 get_dir_check($self, $exists, $g, $r);
4850 }
4851 }
4852 values %$exists;
4853 }
4855 sub minimize_url {
4856 my ($self) = @_;
4857 return $self->{url} if ($self->{url} eq $self->{repos_root});
4858 my $url = $self->{repos_root};
4859 my @components = split(m!/!, $self->{svn_path});
4860 my $c = '';
4861 do {
4862 $url .= "/$c" if length $c;
4863 eval {
4864 my $ra = (ref $self)->new($url);
4865 my $latest = $ra->get_latest_revnum;
4866 $ra->get_log("", $latest, 0, 1, 0, 1, sub {});
4867 };
4868 } while ($@ && ($c = shift @components));
4869 $url;
4870 }
4872 sub can_do_switch {
4873 my $self = shift;
4874 unless (defined $can_do_switch) {
4875 my $pool = SVN::Pool->new;
4876 my $rep = eval {
4877 $self->do_switch(1, '', 0, $self->{url},
4878 SVN::Delta::Editor->new, $pool);
4879 };
4880 if ($@) {
4881 $can_do_switch = 0;
4882 } else {
4883 $rep->abort_report($pool);
4884 $can_do_switch = 1;
4885 }
4886 $pool->clear;
4887 }
4888 $can_do_switch;
4889 }
4891 sub skip_unknown_revs {
4892 my ($err) = @_;
4893 my $errno = $err->apr_err();
4894 # Maybe the branch we're tracking didn't
4895 # exist when the repo started, so it's
4896 # not an error if it doesn't, just continue
4897 #
4898 # Wonderfully consistent library, eh?
4899 # 160013 - svn:// and file://
4900 # 175002 - http(s)://
4901 # 175007 - http(s):// (this repo required authorization, too...)
4902 # More codes may be discovered later...
4903 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
4904 my $err_key = $err->expanded_message;
4905 # revision numbers change every time, filter them out
4906 $err_key =~ s/\d+/\0/g;
4907 $err_key = "$errno\0$err_key";
4908 unless ($ignored_err{$err_key}) {
4909 warn "W: Ignoring error from SVN, path probably ",
4910 "does not exist: ($errno): ",
4911 $err->expanded_message,"\n";
4912 warn "W: Do not be alarmed at the above message ",
4913 "git-svn is just searching aggressively for ",
4914 "old history.\n",
4915 "This may take a while on large repositories\n";
4916 $ignored_err{$err_key} = 1;
4917 }
4918 return;
4919 }
4920 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
4921 }
4923 package Git::SVN::Log;
4924 use strict;
4925 use warnings;
4926 use POSIX qw/strftime/;
4927 use Time::Local;
4928 use constant commit_log_separator => ('-' x 72) . "\n";
4929 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
4930 %rusers $show_commit $incremental/;
4931 my $l_fmt;
4933 sub cmt_showable {
4934 my ($c) = @_;
4935 return 1 if defined $c->{r};
4937 # big commit message got truncated by the 16k pretty buffer in rev-list
4938 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
4939 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
4940 @{$c->{l}} = ();
4941 my @log = command(qw/cat-file commit/, $c->{c});
4943 # shift off the headers
4944 shift @log while ($log[0] ne '');
4945 shift @log;
4947 # TODO: make $c->{l} not have a trailing newline in the future
4948 @{$c->{l}} = map { "$_\n" } grep !/^git-svn-id: /, @log;
4950 (undef, $c->{r}, undef) = ::extract_metadata(
4951 (grep(/^git-svn-id: /, @log))[-1]);
4952 }
4953 return defined $c->{r};
4954 }
4956 sub log_use_color {
4957 return $color || Git->repository->get_colorbool('color.diff');
4958 }
4960 sub git_svn_log_cmd {
4961 my ($r_min, $r_max, @args) = @_;
4962 my $head = 'HEAD';
4963 my (@files, @log_opts);
4964 foreach my $x (@args) {
4965 if ($x eq '--' || @files) {
4966 push @files, $x;
4967 } else {
4968 if (::verify_ref("$x^0")) {
4969 $head = $x;
4970 } else {
4971 push @log_opts, $x;
4972 }
4973 }
4974 }
4976 my ($url, $rev, $uuid, $gs) = ::working_head_info($head);
4977 $gs ||= Git::SVN->_new;
4978 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
4979 $gs->refname);
4980 push @cmd, '-r' unless $non_recursive;
4981 push @cmd, qw/--raw --name-status/ if $verbose;
4982 push @cmd, '--color' if log_use_color();
4983 push @cmd, @log_opts;
4984 if (defined $r_max && $r_max == $r_min) {
4985 push @cmd, '--max-count=1';
4986 if (my $c = $gs->rev_map_get($r_max)) {
4987 push @cmd, $c;
4988 }
4989 } elsif (defined $r_max) {
4990 if ($r_max < $r_min) {
4991 ($r_min, $r_max) = ($r_max, $r_min);
4992 }
4993 my (undef, $c_max) = $gs->find_rev_before($r_max, 1, $r_min);
4994 my (undef, $c_min) = $gs->find_rev_after($r_min, 1, $r_max);
4995 # If there are no commits in the range, both $c_max and $c_min
4996 # will be undefined. If there is at least 1 commit in the
4997 # range, both will be defined.
4998 return () if !defined $c_min || !defined $c_max;
4999 if ($c_min eq $c_max) {
5000 push @cmd, '--max-count=1', $c_min;
5001 } else {
5002 push @cmd, '--boundary', "$c_min..$c_max";
5003 }
5004 }
5005 return (@cmd, @files);
5006 }
5008 # adapted from pager.c
5009 sub config_pager {
5010 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
5011 if (!defined $pager) {
5012 $pager = 'less';
5013 } elsif (length $pager == 0 || $pager eq 'cat') {
5014 $pager = undef;
5015 }
5016 $ENV{GIT_PAGER_IN_USE} = defined($pager);
5017 }
5019 sub run_pager {
5020 return unless -t *STDOUT && defined $pager;
5021 pipe my ($rfd, $wfd) or return;
5022 defined(my $pid = fork) or ::fatal "Can't fork: $!";
5023 if (!$pid) {
5024 open STDOUT, '>&', $wfd or
5025 ::fatal "Can't redirect to stdout: $!";
5026 return;
5027 }
5028 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!";
5029 $ENV{LESS} ||= 'FRSX';
5030 exec $pager or ::fatal "Can't run pager: $! ($pager)";
5031 }
5033 sub format_svn_date {
5034 # some systmes don't handle or mishandle %z, so be creative.
5035 my $t = shift || time;
5036 my $gm = timelocal(gmtime($t));
5037 my $sign = qw( + + - )[ $t <=> $gm ];
5038 my $gmoff = sprintf("%s%02d%02d", $sign, (gmtime(abs($t - $gm)))[2,1]);
5039 return strftime("%Y-%m-%d %H:%M:%S $gmoff (%a, %d %b %Y)", localtime($t));
5040 }
5042 sub parse_git_date {
5043 my ($t, $tz) = @_;
5044 # Date::Parse isn't in the standard Perl distro :(
5045 if ($tz =~ s/^\+//) {
5046 $t += tz_to_s_offset($tz);
5047 } elsif ($tz =~ s/^\-//) {
5048 $t -= tz_to_s_offset($tz);
5049 }
5050 return $t;
5051 }
5053 sub set_local_timezone {
5054 if (defined $TZ) {
5055 $ENV{TZ} = $TZ;
5056 } else {
5057 delete $ENV{TZ};
5058 }
5059 }
5061 sub tz_to_s_offset {
5062 my ($tz) = @_;
5063 $tz =~ s/(\d\d)$//;
5064 return ($1 * 60) + ($tz * 3600);
5065 }
5067 sub get_author_info {
5068 my ($dest, $author, $t, $tz) = @_;
5069 $author =~ s/(?:^\s*|\s*$)//g;
5070 $dest->{a_raw} = $author;
5071 my $au;
5072 if ($::_authors) {
5073 $au = $rusers{$author} || undef;
5074 }
5075 if (!$au) {
5076 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
5077 }
5078 $dest->{t} = $t;
5079 $dest->{tz} = $tz;
5080 $dest->{a} = $au;
5081 $dest->{t_utc} = parse_git_date($t, $tz);
5082 }
5084 sub process_commit {
5085 my ($c, $r_min, $r_max, $defer) = @_;
5086 if (defined $r_min && defined $r_max) {
5087 if ($r_min == $c->{r} && $r_min == $r_max) {
5088 show_commit($c);
5089 return 0;
5090 }
5091 return 1 if $r_min == $r_max;
5092 if ($r_min < $r_max) {
5093 # we need to reverse the print order
5094 return 0 if (defined $limit && --$limit < 0);
5095 push @$defer, $c;
5096 return 1;
5097 }
5098 if ($r_min != $r_max) {
5099 return 1 if ($r_min < $c->{r});
5100 return 1 if ($r_max > $c->{r});
5101 }
5102 }
5103 return 0 if (defined $limit && --$limit < 0);
5104 show_commit($c);
5105 return 1;
5106 }
5108 sub show_commit {
5109 my $c = shift;
5110 if ($oneline) {
5111 my $x = "\n";
5112 if (my $l = $c->{l}) {
5113 while ($l->[0] =~ /^\s*$/) { shift @$l }
5114 $x = $l->[0];
5115 }
5116 $l_fmt ||= 'A' . length($c->{r});
5117 print 'r',pack($l_fmt, $c->{r}),' | ';
5118 print "$c->{c} | " if $show_commit;
5119 print $x;
5120 } else {
5121 show_commit_normal($c);
5122 }
5123 }
5125 sub show_commit_changed_paths {
5126 my ($c) = @_;
5127 return unless $c->{changed};
5128 print "Changed paths:\n", @{$c->{changed}};
5129 }
5131 sub show_commit_normal {
5132 my ($c) = @_;
5133 print commit_log_separator, "r$c->{r} | ";
5134 print "$c->{c} | " if $show_commit;
5135 print "$c->{a} | ", format_svn_date($c->{t_utc}), ' | ';
5136 my $nr_line = 0;
5138 if (my $l = $c->{l}) {
5139 while ($l->[$#$l] eq "\n" && $#$l > 0
5140 && $l->[($#$l - 1)] eq "\n") {
5141 pop @$l;
5142 }
5143 $nr_line = scalar @$l;
5144 if (!$nr_line) {
5145 print "1 line\n\n\n";
5146 } else {
5147 if ($nr_line == 1) {
5148 $nr_line = '1 line';
5149 } else {
5150 $nr_line .= ' lines';
5151 }
5152 print $nr_line, "\n";
5153 show_commit_changed_paths($c);
5154 print "\n";
5155 print $_ foreach @$l;
5156 }
5157 } else {
5158 print "1 line\n";
5159 show_commit_changed_paths($c);
5160 print "\n";
5162 }
5163 foreach my $x (qw/raw stat diff/) {
5164 if ($c->{$x}) {
5165 print "\n";
5166 print $_ foreach @{$c->{$x}}
5167 }
5168 }
5169 }
5171 sub cmd_show_log {
5172 my (@args) = @_;
5173 my ($r_min, $r_max);
5174 my $r_last = -1; # prevent dupes
5175 set_local_timezone();
5176 if (defined $::_revision) {
5177 if ($::_revision =~ /^(\d+):(\d+)$/) {
5178 ($r_min, $r_max) = ($1, $2);
5179 } elsif ($::_revision =~ /^\d+$/) {
5180 $r_min = $r_max = $::_revision;
5181 } else {
5182 ::fatal "-r$::_revision is not supported, use ",
5183 "standard 'git log' arguments instead";
5184 }
5185 }
5187 config_pager();
5188 @args = git_svn_log_cmd($r_min, $r_max, @args);
5189 if (!@args) {
5190 print commit_log_separator unless $incremental || $oneline;
5191 return;
5192 }
5193 my $log = command_output_pipe(@args);
5194 run_pager();
5195 my (@k, $c, $d, $stat);
5196 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
5197 while (<$log>) {
5198 if (/^${esc_color}commit -?($::sha1_short)/o) {
5199 my $cmt = $1;
5200 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
5201 $r_last = $c->{r};
5202 process_commit($c, $r_min, $r_max, \@k) or
5203 goto out;
5204 }
5205 $d = undef;
5206 $c = { c => $cmt };
5207 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
5208 get_author_info($c, $1, $2, $3);
5209 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
5210 # ignore
5211 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
5212 push @{$c->{raw}}, $_;
5213 } elsif (/^${esc_color}[ACRMDT]\t/) {
5214 # we could add $SVN->{svn_path} here, but that requires
5215 # remote access at the moment (repo_path_split)...
5216 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
5217 push @{$c->{changed}}, $_;
5218 } elsif (/^${esc_color}diff /o) {
5219 $d = 1;
5220 push @{$c->{diff}}, $_;
5221 } elsif ($d) {
5222 push @{$c->{diff}}, $_;
5223 } elsif (/^\ .+\ \|\s*\d+\ $esc_color[\+\-]*
5224 $esc_color*[\+\-]*$esc_color$/x) {
5225 $stat = 1;
5226 push @{$c->{stat}}, $_;
5227 } elsif ($stat && /^ \d+ files changed, \d+ insertions/) {
5228 push @{$c->{stat}}, $_;
5229 $stat = undef;
5230 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
5231 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
5232 } elsif (s/^${esc_color} //o) {
5233 push @{$c->{l}}, $_;
5234 }
5235 }
5236 if ($c && defined $c->{r} && $c->{r} != $r_last) {
5237 $r_last = $c->{r};
5238 process_commit($c, $r_min, $r_max, \@k);
5239 }
5240 if (@k) {
5241 ($r_min, $r_max) = ($r_max, $r_min);
5242 process_commit($_, $r_min, $r_max) foreach reverse @k;
5243 }
5244 out:
5245 close $log;
5246 print commit_log_separator unless $incremental || $oneline;
5247 }
5249 sub cmd_blame {
5250 my $path = pop;
5252 config_pager();
5253 run_pager();
5255 my ($fh, $ctx, $rev);
5257 if ($_git_format) {
5258 ($fh, $ctx) = command_output_pipe('blame', @_, $path);
5259 while (my $line = <$fh>) {
5260 if ($line =~ /^\^?([[:xdigit:]]+)\s/) {
5261 # Uncommitted edits show up as a rev ID of
5262 # all zeros, which we can't look up with
5263 # cmt_metadata
5264 if ($1 !~ /^0+$/) {
5265 (undef, $rev, undef) =
5266 ::cmt_metadata($1);
5267 $rev = '0' if (!$rev);
5268 } else {
5269 $rev = '0';
5270 }
5271 $rev = sprintf('%-10s', $rev);
5272 $line =~ s/^\^?[[:xdigit:]]+(\s)/$rev$1/;
5273 }
5274 print $line;
5275 }
5276 } else {
5277 ($fh, $ctx) = command_output_pipe('blame', '-p', @_, 'HEAD',
5278 '--', $path);
5279 my ($sha1);
5280 my %authors;
5281 my @buffer;
5282 my %dsha; #distinct sha keys
5284 while (my $line = <$fh>) {
5285 push @buffer, $line;
5286 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5287 $dsha{$1} = 1;
5288 }
5289 }
5291 my $s2r = ::cmt_sha2rev_batch([keys %dsha]);
5293 foreach my $line (@buffer) {
5294 if ($line =~ /^([[:xdigit:]]{40})\s\d+\s\d+/) {
5295 $rev = $s2r->{$1};
5296 $rev = '0' if (!$rev)
5297 }
5298 elsif ($line =~ /^author (.*)/) {
5299 $authors{$rev} = $1;
5300 $authors{$rev} =~ s/\s/_/g;
5301 }
5302 elsif ($line =~ /^\t(.*)$/) {
5303 printf("%6s %10s %s\n", $rev, $authors{$rev}, $1);
5304 }
5305 }
5306 }
5307 command_close_pipe($fh, $ctx);
5308 }
5310 package Git::SVN::Migration;
5311 # these version numbers do NOT correspond to actual version numbers
5312 # of git nor git-svn. They are just relative.
5313 #
5314 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
5315 #
5316 # v1 layout: .git/$id/info/url, refs/remotes/$id
5317 #
5318 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
5319 #
5320 # v3 layout: .git/svn/$id, refs/remotes/$id
5321 # - info/url may remain for backwards compatibility
5322 # - this is what we migrate up to this layout automatically,
5323 # - this will be used by git svn init on single branches
5324 # v3.1 layout (auto migrated):
5325 # - .rev_db => .rev_db.$UUID, .rev_db will remain as a symlink
5326 # for backwards compatibility
5327 #
5328 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
5329 # - this is only created for newly multi-init-ed
5330 # repositories. Similar in spirit to the
5331 # --use-separate-remotes option in git-clone (now default)
5332 # - we do not automatically migrate to this (following
5333 # the example set by core git)
5334 #
5335 # v5 layout: .rev_db.$UUID => .rev_map.$UUID
5336 # - newer, more-efficient format that uses 24-bytes per record
5337 # with no filler space.
5338 # - use xxd -c24 < .rev_map.$UUID to view and debug
5339 # - This is a one-way migration, repositories updated to the
5340 # new format will not be able to use old git-svn without
5341 # rebuilding the .rev_db. Rebuilding the rev_db is not
5342 # possible if noMetadata or useSvmProps are set; but should
5343 # be no problem for users that use the (sensible) defaults.
5344 use strict;
5345 use warnings;
5346 use Carp qw/croak/;
5347 use File::Path qw/mkpath/;
5348 use File::Basename qw/dirname basename/;
5349 use vars qw/$_minimize/;
5351 sub migrate_from_v0 {
5352 my $git_dir = $ENV{GIT_DIR};
5353 return undef unless -d $git_dir;
5354 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5355 my $migrated = 0;
5356 while (<$fh>) {
5357 chomp;
5358 my ($id, $orig_ref) = ($_, $_);
5359 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
5360 next unless -f "$git_dir/$id/info/url";
5361 my $new_ref = "refs/remotes/$id";
5362 if (::verify_ref("$new_ref^0")) {
5363 print STDERR "W: $orig_ref is probably an old ",
5364 "branch used by an ancient version of ",
5365 "git-svn.\n",
5366 "However, $new_ref also exists.\n",
5367 "We will not be able ",
5368 "to use this branch until this ",
5369 "ambiguity is resolved.\n";
5370 next;
5371 }
5372 print STDERR "Migrating from v0 layout...\n" if !$migrated;
5373 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
5374 command_noisy('update-ref', $new_ref, $orig_ref);
5375 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
5376 $migrated++;
5377 }
5378 command_close_pipe($fh, $ctx);
5379 print STDERR "Done migrating from v0 layout...\n" if $migrated;
5380 $migrated;
5381 }
5383 sub migrate_from_v1 {
5384 my $git_dir = $ENV{GIT_DIR};
5385 my $migrated = 0;
5386 return $migrated unless -d $git_dir;
5387 my $svn_dir = "$git_dir/svn";
5389 # just in case somebody used 'svn' as their $id at some point...
5390 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
5392 print STDERR "Migrating from a git-svn v1 layout...\n";
5393 mkpath([$svn_dir]);
5394 print STDERR "Data from a previous version of git-svn exists, but\n\t",
5395 "$svn_dir\n\t(required for this version ",
5396 "($::VERSION) of git-svn) does not exist.\n";
5397 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
5398 while (<$fh>) {
5399 my $x = $_;
5400 next unless $x =~ s#^refs/remotes/##;
5401 chomp $x;
5402 next unless -f "$git_dir/$x/info/url";
5403 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
5404 next unless $u;
5405 my $dn = dirname("$git_dir/svn/$x");
5406 mkpath([$dn]) unless -d $dn;
5407 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
5408 mkpath(["$git_dir/svn/svn"]);
5409 print STDERR " - $git_dir/$x/info => ",
5410 "$git_dir/svn/$x/info\n";
5411 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
5412 croak "$!: $x";
5413 # don't worry too much about these, they probably
5414 # don't exist with repos this old (save for index,
5415 # and we can easily regenerate that)
5416 foreach my $f (qw/unhandled.log index .rev_db/) {
5417 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
5418 }
5419 } else {
5420 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
5421 rename "$git_dir/$x", "$git_dir/svn/$x" or
5422 croak "$!: $x";
5423 }
5424 $migrated++;
5425 }
5426 command_close_pipe($fh, $ctx);
5427 print STDERR "Done migrating from a git-svn v1 layout\n";
5428 $migrated;
5429 }
5431 sub read_old_urls {
5432 my ($l_map, $pfx, $path) = @_;
5433 my @dir;
5434 foreach (<$path/*>) {
5435 if (-r "$_/info/url") {
5436 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
5437 my $ref_id = $pfx . basename $_;
5438 my $url = ::file_to_s("$_/info/url");
5439 $l_map->{$ref_id} = $url;
5440 } elsif (-d $_) {
5441 push @dir, $_;
5442 }
5443 }
5444 foreach (@dir) {
5445 my $x = $_;
5446 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
5447 read_old_urls($l_map, $x, $_);
5448 }
5449 }
5451 sub migrate_from_v2 {
5452 my @cfg = command(qw/config -l/);
5453 return if grep /^svn-remote\..+\.url=/, @cfg;
5454 my %l_map;
5455 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
5456 my $migrated = 0;
5458 foreach my $ref_id (sort keys %l_map) {
5459 eval { Git::SVN->init($l_map{$ref_id}, '', undef, $ref_id) };
5460 if ($@) {
5461 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
5462 }
5463 $migrated++;
5464 }
5465 $migrated;
5466 }
5468 sub minimize_connections {
5469 my $r = Git::SVN::read_all_remotes();
5470 my $new_urls = {};
5471 my $root_repos = {};
5472 foreach my $repo_id (keys %$r) {
5473 my $url = $r->{$repo_id}->{url} or next;
5474 my $fetch = $r->{$repo_id}->{fetch} or next;
5475 my $ra = Git::SVN::Ra->new($url);
5477 # skip existing cases where we already connect to the root
5478 if (($ra->{url} eq $ra->{repos_root}) ||
5479 ($ra->{repos_root} eq $repo_id)) {
5480 $root_repos->{$ra->{url}} = $repo_id;
5481 next;
5482 }
5484 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
5485 my $root_path = $ra->{url};
5486 $root_path =~ s#^\Q$ra->{repos_root}\E(/|$)##;
5487 foreach my $path (keys %$fetch) {
5488 my $ref_id = $fetch->{$path};
5489 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
5491 # make sure we can read when connecting to
5492 # a higher level of a repository
5493 my ($last_rev, undef) = $gs->last_rev_commit;
5494 if (!defined $last_rev) {
5495 $last_rev = eval {
5496 $root_ra->get_latest_revnum;
5497 };
5498 next if $@;
5499 }
5500 my $new = $root_path;
5501 $new .= length $path ? "/$path" : '';
5502 eval {
5503 $root_ra->get_log([$new], $last_rev, $last_rev,
5504 0, 0, 1, sub { });
5505 };
5506 next if $@;
5507 $new_urls->{$ra->{repos_root}}->{$new} =
5508 { ref_id => $ref_id,
5509 old_repo_id => $repo_id,
5510 old_path => $path };
5511 }
5512 }
5514 my @emptied;
5515 foreach my $url (keys %$new_urls) {
5516 # see if we can re-use an existing [svn-remote "repo_id"]
5517 # instead of creating a(n ugly) new section:
5518 my $repo_id = $root_repos->{$url} || $url;
5520 my $fetch = $new_urls->{$url};
5521 foreach my $path (keys %$fetch) {
5522 my $x = $fetch->{$path};
5523 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
5524 my $pfx = "svn-remote.$x->{old_repo_id}";
5526 my $old_fetch = quotemeta("$x->{old_path}:".
5527 "$x->{ref_id}");
5528 command_noisy(qw/config --unset/,
5529 "$pfx.fetch", '^'. $old_fetch . '$');
5530 delete $r->{$x->{old_repo_id}}->
5531 {fetch}->{$x->{old_path}};
5532 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
5533 command_noisy(qw/config --unset/,
5534 "$pfx.url");
5535 push @emptied, $x->{old_repo_id}
5536 }
5537 }
5538 }
5539 if (@emptied) {
5540 my $file = $ENV{GIT_CONFIG} || "$ENV{GIT_DIR}/config";
5541 print STDERR <<EOF;
5542 The following [svn-remote] sections in your config file ($file) are empty
5543 and can be safely removed:
5544 EOF
5545 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
5546 }
5547 }
5549 sub migration_check {
5550 migrate_from_v0();
5551 migrate_from_v1();
5552 migrate_from_v2();
5553 minimize_connections() if $_minimize;
5554 }
5556 package Git::IndexInfo;
5557 use strict;
5558 use warnings;
5559 use Git qw/command_input_pipe command_close_pipe/;
5561 sub new {
5562 my ($class) = @_;
5563 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
5564 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
5565 }
5567 sub remove {
5568 my ($self, $path) = @_;
5569 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
5570 return ++$self->{nr};
5571 }
5572 undef;
5573 }
5575 sub update {
5576 my ($self, $mode, $hash, $path) = @_;
5577 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
5578 return ++$self->{nr};
5579 }
5580 undef;
5581 }
5583 sub DESTROY {
5584 my ($self) = @_;
5585 command_close_pipe($self->{gui}, $self->{ctx});
5586 }
5588 package Git::SVN::GlobSpec;
5589 use strict;
5590 use warnings;
5592 sub new {
5593 my ($class, $glob) = @_;
5594 my $re = $glob;
5595 $re =~ s!/+$!!g; # no need for trailing slashes
5596 $re =~ m!^([^*]*)(\*(?:/\*)*)(.*)$!;
5597 my $temp = $re;
5598 my ($left, $right) = ($1, $3);
5599 $re = $2;
5600 my $depth = $re =~ tr/*/*/;
5601 if ($depth != $temp =~ tr/*/*/) {
5602 die "Only one set of wildcard directories " .
5603 "(e.g. '*' or '*/*/*') is supported: '$glob'\n";
5604 }
5605 if ($depth == 0) {
5606 die "One '*' is needed for glob: '$glob'\n";
5607 }
5608 $re =~ s!\*!\[^/\]*!g;
5609 $re = quotemeta($left) . "($re)" . quotemeta($right);
5610 if (length $left && !($left =~ s!/+$!!g)) {
5611 die "Missing trailing '/' on left side of: '$glob' ($left)\n";
5612 }
5613 if (length $right && !($right =~ s!^/+!!g)) {
5614 die "Missing leading '/' on right side of: '$glob' ($right)\n";
5615 }
5616 my $left_re = qr/^\/\Q$left\E(\/|$)/;
5617 bless { left => $left, right => $right, left_regex => $left_re,
5618 regex => qr/$re/, glob => $glob, depth => $depth }, $class;
5619 }
5621 sub full_path {
5622 my ($self, $path) = @_;
5623 return (length $self->{left} ? "$self->{left}/" : '') .
5624 $path . (length $self->{right} ? "/$self->{right}" : '');
5625 }
5627 __END__
5629 Data structures:
5632 $remotes = { # returned by read_all_remotes()
5633 'svn' => {
5634 # svn-remote.svn.url=https://svn.musicpd.org
5635 url => 'https://svn.musicpd.org',
5636 # svn-remote.svn.fetch=mpd/trunk:trunk
5637 fetch => {
5638 'mpd/trunk' => 'trunk',
5639 },
5640 # svn-remote.svn.tags=mpd/tags/*:tags/*
5641 tags => {
5642 path => {
5643 left => 'mpd/tags',
5644 right => '',
5645 regex => qr!mpd/tags/([^/]+)$!,
5646 glob => 'tags/*',
5647 },
5648 ref => {
5649 left => 'tags',
5650 right => '',
5651 regex => qr!tags/([^/]+)$!,
5652 glob => 'tags/*',
5653 },
5654 }
5655 }
5656 };
5658 $log_entry hashref as returned by libsvn_log_entry()
5659 {
5660 log => 'whitespace-formatted log entry
5661 ', # trailing newline is preserved
5662 revision => '8', # integer
5663 date => '2004-02-24T17:01:44.108345Z', # commit date
5664 author => 'committer name'
5665 };
5668 # this is generated by generate_diff();
5669 @mods = array of diff-index line hashes, each element represents one line
5670 of diff-index output
5672 diff-index line ($m hash)
5673 {
5674 mode_a => first column of diff-index output, no leading ':',
5675 mode_b => second column of diff-index output,
5676 sha1_b => sha1sum of the final blob,
5677 chg => change type [MCRADT],
5678 file_a => original file name of a file (iff chg is 'C' or 'R')
5679 file_b => new/current file name of a file (any chg)
5680 }
5681 ;
5683 # retval of read_url_paths{,_all}();
5684 $l_map = {
5685 # repository root url
5686 'https://svn.musicpd.org' => {
5687 # repository path # GIT_SVN_ID
5688 'mpd/trunk' => 'trunk',
5689 'mpd/tags/0.11.5' => 'tags/0.11.5',
5690 },
5691 }
5693 Notes:
5694 I don't trust the each() function on unless I created %hash myself
5695 because the internal iterator may not have started at base.