git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180
 181 my %config_bool_settings = (
 182     "thread" => [\$thread, 1],
 183     "chainreplyto" => [\$chain_reply_to, 1],
 184     "suppressfrom" => [\$suppress_from, 0],
 185     "signedoffcc" => [\$signed_off_cc, 1],
 186     "smtpssl" => [\$smtp_ssl, 0],
 187 );
 188
 189 my %config_settings = (
 190     "smtpserver" => \$smtp_server,
 191     "smtpserverport" => \$smtp_server_port,
 192     "smtpuser" => \$smtp_authuser,
 193     "smtppass" => \$smtp_authpass,
 194     "to" => \@to,
 195     "cccmd" => \$cc_cmd,
 196     "aliasfiletype" => \$aliasfiletype,
 197     "bcc" => \@bcclist,
 198     "aliasesfile" => \@alias_files,
 199 );
 200
 201 # Begin by accumulating all the variables (defined above), that we will end up
 202 # needing, first, from the command line:
 203
 204 my $rc = GetOptions("sender|from=s" => \$sender,
 205                     "in-reply-to=s" => \$initial_reply_to,
 206                     "subject=s" => \$initial_subject,
 207                     "to=s" => \@to,
 208                     "cc=s" => \@initial_cc,
 209                     "bcc=s" => \@bcclist,
 210                     "chain-reply-to!" => \$chain_reply_to,
 211                     "smtp-server=s" => \$smtp_server,
 212                     "smtp-server-port=s" => \$smtp_server_port,
 213                     "smtp-user=s" => \$smtp_authuser,
 214                     "smtp-pass=s" => \$smtp_authpass,
 215                     "smtp-ssl!" => \$smtp_ssl,
 216                     "identity=s" => \$identity,
 217                     "compose" => \$compose,
 218                     "quiet" => \$quiet,
 219                     "cc-cmd=s" => \$cc_cmd,
 220                     "suppress-from!" => \$suppress_from,
 221                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 222                     "dry-run" => \$dry_run,
 223                     "envelope-sender=s" => \$envelope_sender,
 224                     "thread!" => \$thread,
 225          );
 226
 227 unless ($rc) {
 228     usage();
 229 }
 230
 231 # Now, let's fill any that aren't set in with defaults:
 232
 233 sub read_config {
 234         my ($prefix) = @_;
 235
 236         foreach my $setting (keys %config_bool_settings) {
 237                 my $target = $config_bool_settings{$setting}->[0];
 238                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 239         }
 240
 241         foreach my $setting (keys %config_settings) {
 242                 my $target = $config_settings{$setting};
 243                 if (ref($target) eq "ARRAY") {
 244                         unless (@$target) {
 245                                 my @values = $repo->config("$prefix.$setting");
 246                                 @$target = @values if (@values && defined $values[0]);
 247                         }
 248                 }
 249                 else {
 250                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 251                 }
 252         }
 253 }
 254
 255 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 256 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 257 read_config("sendemail.$identity") if (defined $identity);
 258 read_config("sendemail");
 259
 260 # fall back on builtin bool defaults
 261 foreach my $setting (values %config_bool_settings) {
 262         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 263 }
 264
 265 my ($repoauthor) = $repo->ident_person('author');
 266 my ($repocommitter) = $repo->ident_person('committer');
 267
 268 # Verify the user input
 269
 270 foreach my $entry (@to) {
 271         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 272 }
 273
 274 foreach my $entry (@initial_cc) {
 275         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 276 }
 277
 278 foreach my $entry (@bcclist) {
 279         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 280 }
 281
 282 my %aliases;
 283 my %parse_alias = (
 284         # multiline formats can be supported in the future
 285         mutt => sub { my $fh = shift; while (<$fh>) {
 286                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 287                         my ($alias, $addr) = ($1, $2);
 288                         $addr =~ s/#.*$//; # mutt allows # comments
 289                          # commas delimit multiple addresses
 290                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 291                 }}},
 292         mailrc => sub { my $fh = shift; while (<$fh>) {
 293                 if (/^alias\s+(\S+)\s+(.*)$/) {
 294                         # spaces delimit multiple addresses
 295                         $aliases{$1} = [ split(/\s+/, $2) ];
 296                 }}},
 297         pine => sub { my $fh = shift; while (<$fh>) {
 298                 if (/^(\S+)\t.*\t(.*)$/) {
 299                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 300                 }}},
 301         gnus => sub { my $fh = shift; while (<$fh>) {
 302                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 303                         $aliases{$1} = [ $2 ];
 304                 }}}
 305 );
 306
 307 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 308         foreach my $file (@alias_files) {
 309                 open my $fh, '<', $file or die "opening $file: $!\n";
 310                 $parse_alias{$aliasfiletype}->($fh);
 311                 close $fh;
 312         }
 313 }
 314
 315 ($sender) = expand_aliases($sender) if defined $sender;
 316
 317 my $prompting = 0;
 318 if (!defined $sender) {
 319         $sender = $repoauthor || $repocommitter;
 320         do {
 321                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 322         } while (!defined $_);
 323
 324         $sender = $_ if ($_);
 325         print "Emails will be sent from: ", $sender, "\n";
 326         $prompting++;
 327 }
 328
 329 if (!@to) {
 330         do {
 331                 $_ = $term->readline("Who should the emails be sent to? ",
 332                                 "");
 333         } while (!defined $_);
 334         my $to = $_;
 335         push @to, split /,/, $to;
 336         $prompting++;
 337 }
 338
 339 sub expand_aliases {
 340         my @cur = @_;
 341         my @last;
 342         do {
 343                 @last = @cur;
 344                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 345         } while (join(',',@cur) ne join(',',@last));
 346         return @cur;
 347 }
 348
 349 @to = expand_aliases(@to);
 350 @to = (map { sanitize_address($_) } @to);
 351 @initial_cc = expand_aliases(@initial_cc);
 352 @bcclist = expand_aliases(@bcclist);
 353
 354 if (!defined $initial_subject && $compose) {
 355         do {
 356                 $_ = $term->readline("What subject should the initial email start with? ",
 357                         $initial_subject);
 358         } while (!defined $_);
 359         $initial_subject = $_;
 360         $prompting++;
 361 }
 362
 363 if ($thread && !defined $initial_reply_to && $prompting) {
 364         do {
 365                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 366                         $initial_reply_to);
 367         } while (!defined $_);
 368
 369         $initial_reply_to = $_;
 370         $initial_reply_to =~ s/^\s+<?/</;
 371         $initial_reply_to =~ s/>?\s+$/>/;
 372 }
 373
 374 if (!defined $smtp_server) {
 375         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 376                 if (-x $_) {
 377                         $smtp_server = $_;
 378                         last;
 379                 }
 380         }
 381         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 382 }
 383
 384 if ($compose) {
 385         # Note that this does not need to be secure, but we will make a small
 386         # effort to have it be unique
 387         open(C,">",$compose_filename)
 388                 or die "Failed to open for writing $compose_filename: $!";
 389         print C "From $sender # This line is ignored.\n";
 390         printf C "Subject: %s\n\n", $initial_subject;
 391         printf C <<EOT;
 392 GIT: Please enter your email below.
 393 GIT: Lines beginning in "GIT: " will be removed.
 394 GIT: Consider including an overall diffstat or table of contents
 395 GIT: for the patch you are writing.
 396
 397 EOT
 398         close(C);
 399
 400         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 401         system($editor, $compose_filename);
 402
 403         open(C2,">",$compose_filename . ".final")
 404                 or die "Failed to open $compose_filename.final : " . $!;
 405
 406         open(C,"<",$compose_filename)
 407                 or die "Failed to open $compose_filename : " . $!;
 408
 409         while(<C>) {
 410                 next if m/^GIT: /;
 411                 print C2 $_;
 412         }
 413         close(C);
 414         close(C2);
 415
 416         do {
 417                 $_ = $term->readline("Send this email? (y|n) ");
 418         } while (!defined $_);
 419
 420         if (uc substr($_,0,1) ne 'Y') {
 421                 cleanup_compose_files();
 422                 exit(0);
 423         }
 424
 425         @files = ($compose_filename . ".final");
 426 }
 427
 428
 429 # Now that all the defaults are set, process the rest of the command line
 430 # arguments and collect up the files that need to be processed.
 431 for my $f (@ARGV) {
 432         if (-d $f) {
 433                 opendir(DH,$f)
 434                         or die "Failed to opendir $f: $!";
 435
 436                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 437                                 sort readdir(DH);
 438
 439         } elsif (-f $f) {
 440                 push @files, $f;
 441
 442         } else {
 443                 print STDERR "Skipping $f - not found.\n";
 444         }
 445 }
 446
 447 if (@files) {
 448         unless ($quiet) {
 449                 print $_,"\n" for (@files);
 450         }
 451 } else {
 452         print STDERR "\nNo patch files specified!\n\n";
 453         usage();
 454 }
 455
 456 # Variables we set as part of the loop over files
 457 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 458
 459 sub extract_valid_address {
 460         my $address = shift;
 461         my $local_part_regexp = '[^<>"\s@]+';
 462         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 463
 464         # check for a local address:
 465         return $address if ($address =~ /^($local_part_regexp)$/);
 466
 467         $address =~ s/^\s*<(.*)>\s*$/$1/;
 468         if ($have_email_valid) {
 469                 return scalar Email::Valid->address($address);
 470         } else {
 471                 # less robust/correct than the monster regexp in Email::Valid,
 472                 # but still does a 99% job, and one less dependency
 473                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 474                 return $1;
 475         }
 476 }
 477
 478 # Usually don't need to change anything below here.
 479
 480 # we make a "fake" message id by taking the current number
 481 # of seconds since the beginning of Unix time and tacking on
 482 # a random number to the end, in case we are called quicker than
 483 # 1 second since the last time we were called.
 484
 485 # We'll setup a template for the message id, using the "from" address:
 486
 487 my ($message_id_stamp, $message_id_serial);
 488 sub make_message_id
 489 {
 490         my $uniq;
 491         if (!defined $message_id_stamp) {
 492                 $message_id_stamp = sprintf("%s-%s", time, $$);
 493                 $message_id_serial = 0;
 494         }
 495         $message_id_serial++;
 496         $uniq = "$message_id_stamp-$message_id_serial";
 497
 498         my $du_part;
 499         for ($sender, $repocommitter, $repoauthor) {
 500                 $du_part = extract_valid_address(sanitize_address($_));
 501                 last if (defined $du_part and $du_part ne '');
 502         }
 503         if (not defined $du_part or $du_part eq '') {
 504                 use Sys::Hostname qw();
 505                 $du_part = 'user@' . Sys::Hostname::hostname();
 506         }
 507         my $message_id_template = "<%s-git-send-email-%s>";
 508         $message_id = sprintf($message_id_template, $uniq, $du_part);
 509         #print "new message id = $message_id\n"; # Was useful for debugging
 510 }
 511
 512
 513
 514 $time = time - scalar $#files;
 515
 516 sub unquote_rfc2047 {
 517         local ($_) = @_;
 518         my $encoding;
 519         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 520                 $encoding = $1;
 521                 s/_/ /g;
 522                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 523         }
 524         return wantarray ? ($_, $encoding) : $_;
 525 }
 526
 527 # use the simplest quoting being able to handle the recipient
 528 sub sanitize_address
 529 {
 530         my ($recipient) = @_;
 531         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 532
 533         if (not $recipient_name) {
 534                 return "$recipient";
 535         }
 536
 537         # if recipient_name is already quoted, do nothing
 538         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 539                 return $recipient;
 540         }
 541
 542         # rfc2047 is needed if a non-ascii char is included
 543         if ($recipient_name =~ /[^[:ascii:]]/) {
 544                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 545                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 546         }
 547
 548         # double quotes are needed if specials or CTLs are included
 549         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 550                 $recipient_name =~ s/(["\\\r])/\\$1/;
 551                 $recipient_name = "\"$recipient_name\"";
 552         }
 553
 554         return "$recipient_name $recipient_addr";
 555
 556 }
 557
 558 sub send_message
 559 {
 560         my @recipients = unique_email_list(@to);
 561         @cc = (grep { my $cc = extract_valid_address($_);
 562                       not grep { $cc eq $_ } @recipients
 563                     }
 564                map { sanitize_address($_) }
 565                @cc);
 566         my $to = join (",\n\t", @recipients);
 567         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 568         @recipients = (map { extract_valid_address($_) } @recipients);
 569         my $date = format_2822_time($time++);
 570         my $gitversion = '@@GIT_VERSION@@';
 571         if ($gitversion =~ m/..GIT_VERSION../) {
 572             $gitversion = Git::version();
 573         }
 574
 575         my $cc = join(", ", unique_email_list(@cc));
 576         my $ccline = "";
 577         if ($cc ne '') {
 578                 $ccline = "\nCc: $cc";
 579         }
 580         my $sanitized_sender = sanitize_address($sender);
 581         make_message_id();
 582
 583         my $header = "From: $sanitized_sender
 584 To: $to${ccline}
 585 Subject: $subject
 586 Date: $date
 587 Message-Id: $message_id
 588 X-Mailer: git-send-email $gitversion
 589 ";
 590         if ($thread && $reply_to) {
 591
 592                 $header .= "In-Reply-To: $reply_to\n";
 593                 $header .= "References: $references\n";
 594         }
 595         if (@xh) {
 596                 $header .= join("\n", @xh) . "\n";
 597         }
 598
 599         my @sendmail_parameters = ('-i', @recipients);
 600         my $raw_from = $sanitized_sender;
 601         $raw_from = $envelope_sender if (defined $envelope_sender);
 602         $raw_from = extract_valid_address($raw_from);
 603         unshift (@sendmail_parameters,
 604                         '-f', $raw_from) if(defined $envelope_sender);
 605
 606         if ($dry_run) {
 607                 # We don't want to send the email.
 608         } elsif ($smtp_server =~ m#^/#) {
 609                 my $pid = open my $sm, '|-';
 610                 defined $pid or die $!;
 611                 if (!$pid) {
 612                         exec($smtp_server, @sendmail_parameters) or die $!;
 613                 }
 614                 print $sm "$header\n$message";
 615                 close $sm or die $?;
 616         } else {
 617
 618                 if (!defined $smtp_server) {
 619                         die "The required SMTP server is not properly defined."
 620                 }
 621
 622                 if ($smtp_ssl) {
 623                         $smtp_server_port ||= 465; # ssmtp
 624                         require Net::SMTP::SSL;
 625                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 626                 }
 627                 else {
 628                         require Net::SMTP;
 629                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 630                                                  ? "$smtp_server:$smtp_server_port"
 631                                                  : $smtp_server);
 632                 }
 633
 634                 if (!$smtp) {
 635                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 636                 }
 637
 638                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 639                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 640                 }
 641                 $smtp->mail( $raw_from ) or die $smtp->message;
 642                 $smtp->to( @recipients ) or die $smtp->message;
 643                 $smtp->data or die $smtp->message;
 644                 $smtp->datasend("$header\n$message") or die $smtp->message;
 645                 $smtp->dataend() or die $smtp->message;
 646                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 647         }
 648         if ($quiet) {
 649                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 650         } else {
 651                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 652                 if ($smtp_server !~ m#^/#) {
 653                         print "Server: $smtp_server\n";
 654                         print "MAIL FROM:<$raw_from>\n";
 655                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 656                 } else {
 657                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 658                 }
 659                 print $header, "\n";
 660                 if ($smtp) {
 661                         print "Result: ", $smtp->code, ' ',
 662                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 663                 } else {
 664                         print "Result: OK\n";
 665                 }
 666         }
 667 }
 668
 669 $reply_to = $initial_reply_to;
 670 $references = $initial_reply_to || '';
 671 $subject = $initial_subject;
 672
 673 foreach my $t (@files) {
 674         open(F,"<",$t) or die "can't open file $t";
 675
 676         my $author = undef;
 677         my $author_encoding;
 678         my $has_content_type;
 679         my $body_encoding;
 680         @cc = @initial_cc;
 681         @xh = ();
 682         my $input_format = undef;
 683         my $header_done = 0;
 684         $message = "";
 685         while(<F>) {
 686                 if (!$header_done) {
 687                         if (/^From /) {
 688                                 $input_format = 'mbox';
 689                                 next;
 690                         }
 691                         chomp;
 692                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 693                                 $input_format = 'mbox';
 694                         }
 695
 696                         if (defined $input_format && $input_format eq 'mbox') {
 697                                 if (/^Subject:\s+(.*)$/) {
 698                                         $subject = $1;
 699
 700                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 701                                         if (unquote_rfc2047($2) eq $sender) {
 702                                                 next if ($suppress_from);
 703                                         }
 704                                         elsif ($1 eq 'From') {
 705                                                 ($author, $author_encoding)
 706                                                   = unquote_rfc2047($2);
 707                                         }
 708                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 709                                                 $2, $_) unless $quiet;
 710                                         push @cc, $2;
 711                                 }
 712                                 elsif (/^Content-type:/i) {
 713                                         $has_content_type = 1;
 714                                         if (/charset="?[^ "]+/) {
 715                                                 $body_encoding = $1;
 716                                         }
 717                                         push @xh, $_;
 718                                 }
 719                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 720                                         push @xh, $_;
 721                                 }
 722
 723                         } else {
 724                                 # In the traditional
 725                                 # "send lots of email" format,
 726                                 # line 1 = cc
 727                                 # line 2 = subject
 728                                 # So let's support that, too.
 729                                 $input_format = 'lots';
 730                                 if (@cc == 0) {
 731                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 732                                                 $_, $_) unless $quiet;
 733
 734                                         push @cc, $_;
 735
 736                                 } elsif (!defined $subject) {
 737                                         $subject = $_;
 738                                 }
 739                         }
 740
 741                         # A whitespace line will terminate the headers
 742                         if (m/^\s*$/) {
 743                                 $header_done = 1;
 744                         }
 745                 } else {
 746                         $message .=  $_;
 747                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 748                                 my $c = $2;
 749                                 chomp $c;
 750                                 next if ($c eq $sender and $suppress_from);
 751                                 push @cc, $c;
 752                                 printf("(sob) Adding cc: %s from line '%s'\n",
 753                                         $c, $_) unless $quiet;
 754                         }
 755                 }
 756         }
 757         close F;
 758
 759         if (defined $cc_cmd) {
 760                 open(F, "$cc_cmd $t |")
 761                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 762                 while(<F>) {
 763                         my $c = $_;
 764                         $c =~ s/^\s*//g;
 765                         $c =~ s/\n$//g;
 766                         next if ($c eq $sender and $suppress_from);
 767                         push @cc, $c;
 768                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 769                                 $c, $cc_cmd) unless $quiet;
 770                 }
 771                 close F
 772                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 773         }
 774
 775         if (defined $author) {
 776                 $message = "From: $author\n\n$message";
 777                 if (defined $author_encoding) {
 778                         if ($has_content_type) {
 779                                 if ($body_encoding eq $author_encoding) {
 780                                         # ok, we already have the right encoding
 781                                 }
 782                                 else {
 783                                         # uh oh, we should re-encode
 784                                 }
 785                         }
 786                         else {
 787                                 push @xh,
 788                                   'MIME-Version: 1.0',
 789                                   "Content-Type: text/plain; charset=$author_encoding",
 790                                   'Content-Transfer-Encoding: 8bit';
 791                         }
 792                 }
 793         }
 794
 795         send_message();
 796
 797         # set up for the next message
 798         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 799                 $reply_to = $message_id;
 800                 if (length $references > 0) {
 801                         $references .= "\n $message_id";
 802                 } else {
 803                         $references = "$message_id";
 804                 }
 805         }
 806 }
 807
 808 if ($compose) {
 809         cleanup_compose_files();
 810 }
 811
 812 sub cleanup_compose_files() {
 813         unlink($compose_filename, $compose_filename . ".final");
 814
 815 }
 816
 817 $smtp->quit if $smtp;
 818
 819 sub unique_email_list(@) {
 820         my %seen;
 821         my @emails;
 822
 823         foreach my $entry (@_) {
 824                 if (my $clean = extract_valid_address($entry)) {
 825                         $seen{$clean} ||= 0;
 826                         next if $seen{$clean}++;
 827                         push @emails, $entry;
 828                 } else {
 829                         print STDERR "W: unable to extract a valid address",
 830                                         " from: $entry\n";
 831                 }
 832         }
 833         return @emails;
 834 }