git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103    --no-validate        Don't perform any sanity checks on patches.
 104
 105 EOT
 106         exit(1);
 107 }
 108
 109 # most mail servers generate the Date: header, but not all...
 110 sub format_2822_time {
 111         my ($time) = @_;
 112         my @localtm = localtime($time);
 113         my @gmttm = gmtime($time);
 114         my $localmin = $localtm[1] + $localtm[2] * 60;
 115         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 116         if ($localtm[0] != $gmttm[0]) {
 117                 die "local zone differs from GMT by a non-minute interval\n";
 118         }
 119         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 120                 $localmin += 1440;
 121         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 122                 $localmin -= 1440;
 123         } elsif ($gmttm[6] != $localtm[6]) {
 124                 die "local time offset greater than or equal to 24 hours\n";
 125         }
 126         my $offset = $localmin - $gmtmin;
 127         my $offhour = $offset / 60;
 128         my $offmin = abs($offset % 60);
 129         if (abs($offhour) >= 24) {
 130                 die ("local time offset greater than or equal to 24 hours\n");
 131         }
 132
 133         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 134                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 135                        $localtm[3],
 136                        qw(Jan Feb Mar Apr May Jun
 137                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 138                        $localtm[5]+1900,
 139                        $localtm[2],
 140                        $localtm[1],
 141                        $localtm[0],
 142                        ($offset >= 0) ? '+' : '-',
 143                        abs($offhour),
 144                        $offmin,
 145                        );
 146 }
 147
 148 my $have_email_valid = eval { require Email::Valid; 1 };
 149 my $smtp;
 150 my $auth;
 151
 152 sub unique_email_list(@);
 153 sub cleanup_compose_files();
 154
 155 # Constants (essentially)
 156 my $compose_filename = ".msg.$$";
 157
 158 # Variables we fill in automatically, or via prompting:
 159 my (@to,@cc,@initial_cc,@bcclist,@xh,
 160         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 161
 162 my $envelope_sender;
 163
 164 # Example reply to:
 165 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 166
 167 my $repo = Git->repository();
 168 my $term = eval {
 169         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 170                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 171                 : new Term::ReadLine 'git-send-email';
 172 };
 173 if ($@) {
 174         $term = new FakeTerm "$@: going non-interactive";
 175 }
 176
 177 # Behavior modification variables
 178 my ($quiet, $dry_run) = (0, 0);
 179
 180 # Variables with corresponding config settings
 181 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 182 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 183 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 184 my ($no_validate);
 185
 186 my %config_bool_settings = (
 187     "thread" => [\$thread, 1],
 188     "chainreplyto" => [\$chain_reply_to, 1],
 189     "suppressfrom" => [\$suppress_from, 0],
 190     "signedoffcc" => [\$signed_off_cc, 1],
 191     "smtpssl" => [\$smtp_ssl, 0],
 192 );
 193
 194 my %config_settings = (
 195     "smtpserver" => \$smtp_server,
 196     "smtpserverport" => \$smtp_server_port,
 197     "smtpuser" => \$smtp_authuser,
 198     "smtppass" => \$smtp_authpass,
 199     "to" => \@to,
 200     "cccmd" => \$cc_cmd,
 201     "aliasfiletype" => \$aliasfiletype,
 202     "bcc" => \@bcclist,
 203     "aliasesfile" => \@alias_files,
 204 );
 205
 206 # Begin by accumulating all the variables (defined above), that we will end up
 207 # needing, first, from the command line:
 208
 209 my $rc = GetOptions("sender|from=s" => \$sender,
 210                     "in-reply-to=s" => \$initial_reply_to,
 211                     "subject=s" => \$initial_subject,
 212                     "to=s" => \@to,
 213                     "cc=s" => \@initial_cc,
 214                     "bcc=s" => \@bcclist,
 215                     "chain-reply-to!" => \$chain_reply_to,
 216                     "smtp-server=s" => \$smtp_server,
 217                     "smtp-server-port=s" => \$smtp_server_port,
 218                     "smtp-user=s" => \$smtp_authuser,
 219                     "smtp-pass=s" => \$smtp_authpass,
 220                     "smtp-ssl!" => \$smtp_ssl,
 221                     "identity=s" => \$identity,
 222                     "compose" => \$compose,
 223                     "quiet" => \$quiet,
 224                     "cc-cmd=s" => \$cc_cmd,
 225                     "suppress-from!" => \$suppress_from,
 226                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 227                     "dry-run" => \$dry_run,
 228                     "envelope-sender=s" => \$envelope_sender,
 229                     "thread!" => \$thread,
 230                     "no-validate" => \$no_validate,
 231          );
 232
 233 unless ($rc) {
 234     usage();
 235 }
 236
 237 # Now, let's fill any that aren't set in with defaults:
 238
 239 sub read_config {
 240         my ($prefix) = @_;
 241
 242         foreach my $setting (keys %config_bool_settings) {
 243                 my $target = $config_bool_settings{$setting}->[0];
 244                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 245         }
 246
 247         foreach my $setting (keys %config_settings) {
 248                 my $target = $config_settings{$setting};
 249                 if (ref($target) eq "ARRAY") {
 250                         unless (@$target) {
 251                                 my @values = $repo->config("$prefix.$setting");
 252                                 @$target = @values if (@values && defined $values[0]);
 253                         }
 254                 }
 255                 else {
 256                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 257                 }
 258         }
 259 }
 260
 261 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 262 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 263 read_config("sendemail.$identity") if (defined $identity);
 264 read_config("sendemail");
 265
 266 # fall back on builtin bool defaults
 267 foreach my $setting (values %config_bool_settings) {
 268         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 269 }
 270
 271 my ($repoauthor) = $repo->ident_person('author');
 272 my ($repocommitter) = $repo->ident_person('committer');
 273
 274 # Verify the user input
 275
 276 foreach my $entry (@to) {
 277         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 278 }
 279
 280 foreach my $entry (@initial_cc) {
 281         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 282 }
 283
 284 foreach my $entry (@bcclist) {
 285         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 286 }
 287
 288 my %aliases;
 289 my %parse_alias = (
 290         # multiline formats can be supported in the future
 291         mutt => sub { my $fh = shift; while (<$fh>) {
 292                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 293                         my ($alias, $addr) = ($1, $2);
 294                         $addr =~ s/#.*$//; # mutt allows # comments
 295                          # commas delimit multiple addresses
 296                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 297                 }}},
 298         mailrc => sub { my $fh = shift; while (<$fh>) {
 299                 if (/^alias\s+(\S+)\s+(.*)$/) {
 300                         # spaces delimit multiple addresses
 301                         $aliases{$1} = [ split(/\s+/, $2) ];
 302                 }}},
 303         pine => sub { my $fh = shift; while (<$fh>) {
 304                 if (/^(\S+)\t.*\t(.*)$/) {
 305                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 306                 }}},
 307         gnus => sub { my $fh = shift; while (<$fh>) {
 308                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 309                         $aliases{$1} = [ $2 ];
 310                 }}}
 311 );
 312
 313 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 314         foreach my $file (@alias_files) {
 315                 open my $fh, '<', $file or die "opening $file: $!\n";
 316                 $parse_alias{$aliasfiletype}->($fh);
 317                 close $fh;
 318         }
 319 }
 320
 321 ($sender) = expand_aliases($sender) if defined $sender;
 322
 323 # Now that all the defaults are set, process the rest of the command line
 324 # arguments and collect up the files that need to be processed.
 325 for my $f (@ARGV) {
 326         if (-d $f) {
 327                 opendir(DH,$f)
 328                         or die "Failed to opendir $f: $!";
 329
 330                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 331                                 sort readdir(DH);
 332
 333         } elsif (-f $f) {
 334                 push @files, $f;
 335
 336         } else {
 337                 print STDERR "Skipping $f - not found.\n";
 338         }
 339 }
 340
 341 if (!$no_validate) {
 342         foreach my $f (@files) {
 343                 my $error = validate_patch($f);
 344                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 345         }
 346 }
 347
 348 if (@files) {
 349         unless ($quiet) {
 350                 print $_,"\n" for (@files);
 351         }
 352 } else {
 353         print STDERR "\nNo patch files specified!\n\n";
 354         usage();
 355 }
 356
 357 my $prompting = 0;
 358 if (!defined $sender) {
 359         $sender = $repoauthor || $repocommitter;
 360         do {
 361                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 362         } while (!defined $_);
 363
 364         $sender = $_ if ($_);
 365         print "Emails will be sent from: ", $sender, "\n";
 366         $prompting++;
 367 }
 368
 369 if (!@to) {
 370         do {
 371                 $_ = $term->readline("Who should the emails be sent to? ",
 372                                 "");
 373         } while (!defined $_);
 374         my $to = $_;
 375         push @to, split /,/, $to;
 376         $prompting++;
 377 }
 378
 379 sub expand_aliases {
 380         my @cur = @_;
 381         my @last;
 382         do {
 383                 @last = @cur;
 384                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 385         } while (join(',',@cur) ne join(',',@last));
 386         return @cur;
 387 }
 388
 389 @to = expand_aliases(@to);
 390 @to = (map { sanitize_address($_) } @to);
 391 @initial_cc = expand_aliases(@initial_cc);
 392 @bcclist = expand_aliases(@bcclist);
 393
 394 if (!defined $initial_subject && $compose) {
 395         do {
 396                 $_ = $term->readline("What subject should the initial email start with? ",
 397                         $initial_subject);
 398         } while (!defined $_);
 399         $initial_subject = $_;
 400         $prompting++;
 401 }
 402
 403 if ($thread && !defined $initial_reply_to && $prompting) {
 404         do {
 405                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 406                         $initial_reply_to);
 407         } while (!defined $_);
 408
 409         $initial_reply_to = $_;
 410 }
 411 if (defined $initial_reply_to) {
 412         $initial_reply_to =~ s/^\s*<?//;
 413         $initial_reply_to =~ s/>?\s*$//;
 414         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 415 }
 416
 417 if (!defined $smtp_server) {
 418         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 419                 if (-x $_) {
 420                         $smtp_server = $_;
 421                         last;
 422                 }
 423         }
 424         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 425 }
 426
 427 if ($compose) {
 428         # Note that this does not need to be secure, but we will make a small
 429         # effort to have it be unique
 430         open(C,">",$compose_filename)
 431                 or die "Failed to open for writing $compose_filename: $!";
 432         print C "From $sender # This line is ignored.\n";
 433         printf C "Subject: %s\n\n", $initial_subject;
 434         printf C <<EOT;
 435 GIT: Please enter your email below.
 436 GIT: Lines beginning in "GIT: " will be removed.
 437 GIT: Consider including an overall diffstat or table of contents
 438 GIT: for the patch you are writing.
 439
 440 EOT
 441         close(C);
 442
 443         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 444         system('sh', '-c', '$0 $@', $editor, $compose_filename);
 445
 446         open(C2,">",$compose_filename . ".final")
 447                 or die "Failed to open $compose_filename.final : " . $!;
 448
 449         open(C,"<",$compose_filename)
 450                 or die "Failed to open $compose_filename : " . $!;
 451
 452         while(<C>) {
 453                 next if m/^GIT: /;
 454                 print C2 $_;
 455         }
 456         close(C);
 457         close(C2);
 458
 459         do {
 460                 $_ = $term->readline("Send this email? (y|n) ");
 461         } while (!defined $_);
 462
 463         if (uc substr($_,0,1) ne 'Y') {
 464                 cleanup_compose_files();
 465                 exit(0);
 466         }
 467
 468         @files = ($compose_filename . ".final", @files);
 469 }
 470
 471 # Variables we set as part of the loop over files
 472 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 473
 474 sub extract_valid_address {
 475         my $address = shift;
 476         my $local_part_regexp = '[^<>"\s@]+';
 477         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 478
 479         # check for a local address:
 480         return $address if ($address =~ /^($local_part_regexp)$/);
 481
 482         $address =~ s/^\s*<(.*)>\s*$/$1/;
 483         if ($have_email_valid) {
 484                 return scalar Email::Valid->address($address);
 485         } else {
 486                 # less robust/correct than the monster regexp in Email::Valid,
 487                 # but still does a 99% job, and one less dependency
 488                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 489                 return $1;
 490         }
 491 }
 492
 493 # Usually don't need to change anything below here.
 494
 495 # we make a "fake" message id by taking the current number
 496 # of seconds since the beginning of Unix time and tacking on
 497 # a random number to the end, in case we are called quicker than
 498 # 1 second since the last time we were called.
 499
 500 # We'll setup a template for the message id, using the "from" address:
 501
 502 my ($message_id_stamp, $message_id_serial);
 503 sub make_message_id
 504 {
 505         my $uniq;
 506         if (!defined $message_id_stamp) {
 507                 $message_id_stamp = sprintf("%s-%s", time, $$);
 508                 $message_id_serial = 0;
 509         }
 510         $message_id_serial++;
 511         $uniq = "$message_id_stamp-$message_id_serial";
 512
 513         my $du_part;
 514         for ($sender, $repocommitter, $repoauthor) {
 515                 $du_part = extract_valid_address(sanitize_address($_));
 516                 last if (defined $du_part and $du_part ne '');
 517         }
 518         if (not defined $du_part or $du_part eq '') {
 519                 use Sys::Hostname qw();
 520                 $du_part = 'user@' . Sys::Hostname::hostname();
 521         }
 522         my $message_id_template = "<%s-git-send-email-%s>";
 523         $message_id = sprintf($message_id_template, $uniq, $du_part);
 524         #print "new message id = $message_id\n"; # Was useful for debugging
 525 }
 526
 527
 528
 529 $time = time - scalar $#files;
 530
 531 sub unquote_rfc2047 {
 532         local ($_) = @_;
 533         my $encoding;
 534         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 535                 $encoding = $1;
 536                 s/_/ /g;
 537                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 538         }
 539         return wantarray ? ($_, $encoding) : $_;
 540 }
 541
 542 # use the simplest quoting being able to handle the recipient
 543 sub sanitize_address
 544 {
 545         my ($recipient) = @_;
 546         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 547
 548         if (not $recipient_name) {
 549                 return "$recipient";
 550         }
 551
 552         # if recipient_name is already quoted, do nothing
 553         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 554                 return $recipient;
 555         }
 556
 557         # rfc2047 is needed if a non-ascii char is included
 558         if ($recipient_name =~ /[^[:ascii:]]/) {
 559                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 560                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 561         }
 562
 563         # double quotes are needed if specials or CTLs are included
 564         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 565                 $recipient_name =~ s/(["\\\r])/\\$1/;
 566                 $recipient_name = "\"$recipient_name\"";
 567         }
 568
 569         return "$recipient_name $recipient_addr";
 570
 571 }
 572
 573 sub send_message
 574 {
 575         my @recipients = unique_email_list(@to);
 576         @cc = (grep { my $cc = extract_valid_address($_);
 577                       not grep { $cc eq $_ } @recipients
 578                     }
 579                map { sanitize_address($_) }
 580                @cc);
 581         my $to = join (",\n\t", @recipients);
 582         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 583         @recipients = (map { extract_valid_address($_) } @recipients);
 584         my $date = format_2822_time($time++);
 585         my $gitversion = '@@GIT_VERSION@@';
 586         if ($gitversion =~ m/..GIT_VERSION../) {
 587             $gitversion = Git::version();
 588         }
 589
 590         my $cc = join(", ", unique_email_list(@cc));
 591         my $ccline = "";
 592         if ($cc ne '') {
 593                 $ccline = "\nCc: $cc";
 594         }
 595         my $sanitized_sender = sanitize_address($sender);
 596         make_message_id() unless defined($message_id);
 597
 598         my $header = "From: $sanitized_sender
 599 To: $to${ccline}
 600 Subject: $subject
 601 Date: $date
 602 Message-Id: $message_id
 603 X-Mailer: git-send-email $gitversion
 604 ";
 605         if ($thread && $reply_to) {
 606
 607                 $header .= "In-Reply-To: $reply_to\n";
 608                 $header .= "References: $references\n";
 609         }
 610         if (@xh) {
 611                 $header .= join("\n", @xh) . "\n";
 612         }
 613
 614         my @sendmail_parameters = ('-i', @recipients);
 615         my $raw_from = $sanitized_sender;
 616         $raw_from = $envelope_sender if (defined $envelope_sender);
 617         $raw_from = extract_valid_address($raw_from);
 618         unshift (@sendmail_parameters,
 619                         '-f', $raw_from) if(defined $envelope_sender);
 620
 621         if ($dry_run) {
 622                 # We don't want to send the email.
 623         } elsif ($smtp_server =~ m#^/#) {
 624                 my $pid = open my $sm, '|-';
 625                 defined $pid or die $!;
 626                 if (!$pid) {
 627                         exec($smtp_server, @sendmail_parameters) or die $!;
 628                 }
 629                 print $sm "$header\n$message";
 630                 close $sm or die $?;
 631         } else {
 632
 633                 if (!defined $smtp_server) {
 634                         die "The required SMTP server is not properly defined."
 635                 }
 636
 637                 if ($smtp_ssl) {
 638                         $smtp_server_port ||= 465; # ssmtp
 639                         require Net::SMTP::SSL;
 640                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 641                 }
 642                 else {
 643                         require Net::SMTP;
 644                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 645                                                  ? "$smtp_server:$smtp_server_port"
 646                                                  : $smtp_server);
 647                 }
 648
 649                 if (!$smtp) {
 650                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 651                 }
 652
 653                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 654                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 655                 }
 656                 $smtp->mail( $raw_from ) or die $smtp->message;
 657                 $smtp->to( @recipients ) or die $smtp->message;
 658                 $smtp->data or die $smtp->message;
 659                 $smtp->datasend("$header\n$message") or die $smtp->message;
 660                 $smtp->dataend() or die $smtp->message;
 661                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 662         }
 663         if ($quiet) {
 664                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 665         } else {
 666                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 667                 if ($smtp_server !~ m#^/#) {
 668                         print "Server: $smtp_server\n";
 669                         print "MAIL FROM:<$raw_from>\n";
 670                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 671                 } else {
 672                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 673                 }
 674                 print $header, "\n";
 675                 if ($smtp) {
 676                         print "Result: ", $smtp->code, ' ',
 677                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 678                 } else {
 679                         print "Result: OK\n";
 680                 }
 681         }
 682 }
 683
 684 $reply_to = $initial_reply_to;
 685 $references = $initial_reply_to || '';
 686 $subject = $initial_subject;
 687
 688 foreach my $t (@files) {
 689         open(F,"<",$t) or die "can't open file $t";
 690
 691         my $author = undef;
 692         my $author_encoding;
 693         my $has_content_type;
 694         my $body_encoding;
 695         @cc = @initial_cc;
 696         @xh = ();
 697         my $input_format = undef;
 698         my $header_done = 0;
 699         $message = "";
 700         while(<F>) {
 701                 if (!$header_done) {
 702                         if (/^From /) {
 703                                 $input_format = 'mbox';
 704                                 next;
 705                         }
 706                         chomp;
 707                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 708                                 $input_format = 'mbox';
 709                         }
 710
 711                         if (defined $input_format && $input_format eq 'mbox') {
 712                                 if (/^Subject:\s+(.*)$/) {
 713                                         $subject = $1;
 714
 715                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 716                                         if (unquote_rfc2047($2) eq $sender) {
 717                                                 next if ($suppress_from);
 718                                         }
 719                                         elsif ($1 eq 'From') {
 720                                                 ($author, $author_encoding)
 721                                                   = unquote_rfc2047($2);
 722                                         }
 723                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 724                                                 $2, $_) unless $quiet;
 725                                         push @cc, $2;
 726                                 }
 727                                 elsif (/^Content-type:/i) {
 728                                         $has_content_type = 1;
 729                                         if (/charset="?[^ "]+/) {
 730                                                 $body_encoding = $1;
 731                                         }
 732                                         push @xh, $_;
 733                                 }
 734                                 elsif (/^Message-Id: (.*)/i) {
 735                                         $message_id = $1;
 736                                 }
 737                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 738                                         push @xh, $_;
 739                                 }
 740
 741                         } else {
 742                                 # In the traditional
 743                                 # "send lots of email" format,
 744                                 # line 1 = cc
 745                                 # line 2 = subject
 746                                 # So let's support that, too.
 747                                 $input_format = 'lots';
 748                                 if (@cc == 0) {
 749                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 750                                                 $_, $_) unless $quiet;
 751
 752                                         push @cc, $_;
 753
 754                                 } elsif (!defined $subject) {
 755                                         $subject = $_;
 756                                 }
 757                         }
 758
 759                         # A whitespace line will terminate the headers
 760                         if (m/^\s*$/) {
 761                                 $header_done = 1;
 762                         }
 763                 } else {
 764                         $message .=  $_;
 765                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 766                                 my $c = $2;
 767                                 chomp $c;
 768                                 next if ($c eq $sender and $suppress_from);
 769                                 push @cc, $c;
 770                                 printf("(sob) Adding cc: %s from line '%s'\n",
 771                                         $c, $_) unless $quiet;
 772                         }
 773                 }
 774         }
 775         close F;
 776
 777         if (defined $cc_cmd) {
 778                 open(F, "$cc_cmd $t |")
 779                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 780                 while(<F>) {
 781                         my $c = $_;
 782                         $c =~ s/^\s*//g;
 783                         $c =~ s/\n$//g;
 784                         next if ($c eq $sender and $suppress_from);
 785                         push @cc, $c;
 786                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 787                                 $c, $cc_cmd) unless $quiet;
 788                 }
 789                 close F
 790                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 791         }
 792
 793         if (defined $author) {
 794                 $message = "From: $author\n\n$message";
 795                 if (defined $author_encoding) {
 796                         if ($has_content_type) {
 797                                 if ($body_encoding eq $author_encoding) {
 798                                         # ok, we already have the right encoding
 799                                 }
 800                                 else {
 801                                         # uh oh, we should re-encode
 802                                 }
 803                         }
 804                         else {
 805                                 push @xh,
 806                                   'MIME-Version: 1.0',
 807                                   "Content-Type: text/plain; charset=$author_encoding",
 808                                   'Content-Transfer-Encoding: 8bit';
 809                         }
 810                 }
 811         }
 812
 813         send_message();
 814
 815         # set up for the next message
 816         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 817                 $reply_to = $message_id;
 818                 if (length $references > 0) {
 819                         $references .= "\n $message_id";
 820                 } else {
 821                         $references = "$message_id";
 822                 }
 823         }
 824         $message_id = undef;
 825 }
 826
 827 if ($compose) {
 828         cleanup_compose_files();
 829 }
 830
 831 sub cleanup_compose_files() {
 832         unlink($compose_filename, $compose_filename . ".final");
 833
 834 }
 835
 836 $smtp->quit if $smtp;
 837
 838 sub unique_email_list(@) {
 839         my %seen;
 840         my @emails;
 841
 842         foreach my $entry (@_) {
 843                 if (my $clean = extract_valid_address($entry)) {
 844                         $seen{$clean} ||= 0;
 845                         next if $seen{$clean}++;
 846                         push @emails, $entry;
 847                 } else {
 848                         print STDERR "W: unable to extract a valid address",
 849                                         " from: $entry\n";
 850                 }
 851         }
 852         return @emails;
 853 }
 854
 855 sub validate_patch {
 856         my $fn = shift;
 857         open(my $fh, '<', $fn)
 858                 or die "unable to open $fn: $!\n";
 859         while (my $line = <$fh>) {
 860                 if (length($line) > 998) {
 861                         return "$.: patch contains a line longer than 998 characters";
 862                 }
 863         }
 864         return undef;
 865 }