git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213 );
 214
 215 # Handle Uncouth Termination
 216 sub signal_handler {
 217
 218         # Make text normal
 219         print color("reset"), "\n";
 220
 221         # SMTP password masked
 222         system "stty echo";
 223
 224         # tmp files from --compose
 225         if (defined $compose_filename) {
 226                 if (-e $compose_filename) {
 227                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 228                 }
 229                 if (-e ($compose_filename . ".final")) {
 230                         print "'$compose_filename.final' contains the composed email.\n"
 231                 }
 232         }
 233
 234         exit;
 235 };
 236
 237 $SIG{TERM} = \&signal_handler;
 238 $SIG{INT}  = \&signal_handler;
 239
 240 # Begin by accumulating all the variables (defined above), that we will end up
 241 # needing, first, from the command line:
 242
 243 my $rc = GetOptions("sender|from=s" => \$sender,
 244                     "in-reply-to=s" => \$initial_reply_to,
 245                     "subject=s" => \$initial_subject,
 246                     "to=s" => \@to,
 247                     "cc=s" => \@initial_cc,
 248                     "bcc=s" => \@bcclist,
 249                     "chain-reply-to!" => \$chain_reply_to,
 250                     "smtp-server=s" => \$smtp_server,
 251                     "smtp-server-port=s" => \$smtp_server_port,
 252                     "smtp-user=s" => \$smtp_authuser,
 253                     "smtp-pass:s" => \$smtp_authpass,
 254                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 255                     "smtp-encryption=s" => \$smtp_encryption,
 256                     "identity=s" => \$identity,
 257                     "annotate" => \$annotate,
 258                     "compose" => \$compose,
 259                     "quiet" => \$quiet,
 260                     "cc-cmd=s" => \$cc_cmd,
 261                     "suppress-from!" => \$suppress_from,
 262                     "suppress-cc=s" => \@suppress_cc,
 263                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 264                     "confirm=s" => \$confirm,
 265                     "dry-run" => \$dry_run,
 266                     "envelope-sender=s" => \$envelope_sender,
 267                     "thread!" => \$thread,
 268                     "validate!" => \$validate,
 269                     "format-patch!" => \$format_patch,
 270          );
 271
 272 unless ($rc) {
 273     usage();
 274 }
 275
 276 die "Cannot run git format-patch from outside a repository\n"
 277         if $format_patch and not $repo;
 278
 279 # Now, let's fill any that aren't set in with defaults:
 280
 281 sub read_config {
 282         my ($prefix) = @_;
 283
 284         foreach my $setting (keys %config_bool_settings) {
 285                 my $target = $config_bool_settings{$setting}->[0];
 286                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 287         }
 288
 289         foreach my $setting (keys %config_settings) {
 290                 my $target = $config_settings{$setting};
 291                 if (ref($target) eq "ARRAY") {
 292                         unless (@$target) {
 293                                 my @values = Git::config(@repo, "$prefix.$setting");
 294                                 @$target = @values if (@values && defined $values[0]);
 295                         }
 296                 }
 297                 else {
 298                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 299                 }
 300         }
 301
 302         if (!defined $smtp_encryption) {
 303                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 304                 if (defined $enc) {
 305                         $smtp_encryption = $enc;
 306                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 307                         $smtp_encryption = 'ssl';
 308                 }
 309         }
 310 }
 311
 312 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 313 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 314 read_config("sendemail.$identity") if (defined $identity);
 315 read_config("sendemail");
 316
 317 # fall back on builtin bool defaults
 318 foreach my $setting (values %config_bool_settings) {
 319         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 320 }
 321
 322 # 'default' encryption is none -- this only prevents a warning
 323 $smtp_encryption = '' unless (defined $smtp_encryption);
 324
 325 # Set CC suppressions
 326 my(%suppress_cc);
 327 if (@suppress_cc) {
 328         foreach my $entry (@suppress_cc) {
 329                 die "Unknown --suppress-cc field: '$entry'\n"
 330                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 331                 $suppress_cc{$entry} = 1;
 332         }
 333 }
 334
 335 if ($suppress_cc{'all'}) {
 336         foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
 337                 $suppress_cc{$entry} = 1;
 338         }
 339         delete $suppress_cc{'all'};
 340 }
 341
 342 # If explicit old-style ones are specified, they trump --suppress-cc.
 343 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 344 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 345
 346 if ($suppress_cc{'body'}) {
 347         foreach my $entry (qw (sob bodycc)) {
 348                 $suppress_cc{$entry} = 1;
 349         }
 350         delete $suppress_cc{'body'};
 351 }
 352
 353 # Set confirm's default value
 354 my $confirm_unconfigured = !defined $confirm;
 355 if ($confirm_unconfigured) {
 356         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 357 };
 358 die "Unknown --confirm setting: '$confirm'\n"
 359         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 360
 361 # Debugging, print out the suppressions.
 362 if (0) {
 363         print "suppressions:\n";
 364         foreach my $entry (keys %suppress_cc) {
 365                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 366         }
 367 }
 368
 369 my ($repoauthor, $repocommitter);
 370 ($repoauthor) = Git::ident_person(@repo, 'author');
 371 ($repocommitter) = Git::ident_person(@repo, 'committer');
 372
 373 # Verify the user input
 374
 375 foreach my $entry (@to) {
 376         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 377 }
 378
 379 foreach my $entry (@initial_cc) {
 380         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 381 }
 382
 383 foreach my $entry (@bcclist) {
 384         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 385 }
 386
 387 sub parse_address_line {
 388         if ($have_mail_address) {
 389                 return map { $_->format } Mail::Address->parse($_[0]);
 390         } else {
 391                 return split_addrs($_[0]);
 392         }
 393 }
 394
 395 sub split_addrs {
 396         return quotewords('\s*,\s*', 1, @_);
 397 }
 398
 399 my %aliases;
 400 my %parse_alias = (
 401         # multiline formats can be supported in the future
 402         mutt => sub { my $fh = shift; while (<$fh>) {
 403                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 404                         my ($alias, $addr) = ($1, $2);
 405                         $addr =~ s/#.*$//; # mutt allows # comments
 406                          # commas delimit multiple addresses
 407                         $aliases{$alias} = [ split_addrs($addr) ];
 408                 }}},
 409         mailrc => sub { my $fh = shift; while (<$fh>) {
 410                 if (/^alias\s+(\S+)\s+(.*)$/) {
 411                         # spaces delimit multiple addresses
 412                         $aliases{$1} = [ split(/\s+/, $2) ];
 413                 }}},
 414         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 415                 for (my $x = ''; defined($x); $x = $_) {
 416                         chomp $x;
 417                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 418                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 419                         $aliases{$1} = [ split_addrs($2) ];
 420                 }},
 421         elm => sub  { my $fh = shift;
 422                       while (<$fh>) {
 423                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 424                               my ($alias, $addr) = ($1, $2);
 425                                $aliases{$alias} = [ split_addrs($addr) ];
 426                           }
 427                       } },
 428
 429         gnus => sub { my $fh = shift; while (<$fh>) {
 430                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 431                         $aliases{$1} = [ $2 ];
 432                 }}}
 433 );
 434
 435 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 436         foreach my $file (@alias_files) {
 437                 open my $fh, '<', $file or die "opening $file: $!\n";
 438                 $parse_alias{$aliasfiletype}->($fh);
 439                 close $fh;
 440         }
 441 }
 442
 443 ($sender) = expand_aliases($sender) if defined $sender;
 444
 445 # returns 1 if the conflict must be solved using it as a format-patch argument
 446 sub check_file_rev_conflict($) {
 447         return unless $repo;
 448         my $f = shift;
 449         try {
 450                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 451                 if (defined($format_patch)) {
 452                         print "foo\n";
 453                         return $format_patch;
 454                 }
 455                 die(<<EOF);
 456 File '$f' exists but it could also be the range of commits
 457 to produce patches for.  Please disambiguate by...
 458
 459     * Saying "./$f" if you mean a file; or
 460     * Giving --format-patch option if you mean a range.
 461 EOF
 462         } catch Git::Error::Command with {
 463                 return 0;
 464         }
 465 }
 466
 467 # Now that all the defaults are set, process the rest of the command line
 468 # arguments and collect up the files that need to be processed.
 469 my @rev_list_opts;
 470 while (defined(my $f = shift @ARGV)) {
 471         if ($f eq "--") {
 472                 push @rev_list_opts, "--", @ARGV;
 473                 @ARGV = ();
 474         } elsif (-d $f and !check_file_rev_conflict($f)) {
 475                 opendir(DH,$f)
 476                         or die "Failed to opendir $f: $!";
 477
 478                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 479                                 sort readdir(DH);
 480                 closedir(DH);
 481         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 482                 push @files, $f;
 483         } else {
 484                 push @rev_list_opts, $f;
 485         }
 486 }
 487
 488 if (@rev_list_opts) {
 489         die "Cannot run git format-patch from outside a repository\n"
 490                 unless $repo;
 491         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 492 }
 493
 494 if ($validate) {
 495         foreach my $f (@files) {
 496                 unless (-p $f) {
 497                         my $error = validate_patch($f);
 498                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 499                 }
 500         }
 501 }
 502
 503 if (@files) {
 504         unless ($quiet) {
 505                 print $_,"\n" for (@files);
 506         }
 507 } else {
 508         print STDERR "\nNo patch files specified!\n\n";
 509         usage();
 510 }
 511
 512 sub get_patch_subject($) {
 513         my $fn = shift;
 514         open (my $fh, '<', $fn);
 515         while (my $line = <$fh>) {
 516                 next unless ($line =~ /^Subject: (.*)$/);
 517                 close $fh;
 518                 return "GIT: $1\n";
 519         }
 520         close $fh;
 521         die "No subject line in $fn ?";
 522 }
 523
 524 if ($compose) {
 525         # Note that this does not need to be secure, but we will make a small
 526         # effort to have it be unique
 527         $compose_filename = ($repo ?
 528                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 530         open(C,">",$compose_filename)
 531                 or die "Failed to open for writing $compose_filename: $!";
 532
 533
 534         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 535         my $tpl_subject = $initial_subject || '';
 536         my $tpl_reply_to = $initial_reply_to || '';
 537
 538         print C <<EOT;
 539 From $tpl_sender # This line is ignored.
 540 GIT: Lines beginning in "GIT: " will be removed.
 541 GIT: Consider including an overall diffstat or table of contents
 542 GIT: for the patch you are writing.
 543 GIT:
 544 GIT: Clear the body content if you don't wish to send a summary.
 545 From: $tpl_sender
 546 Subject: $tpl_subject
 547 In-Reply-To: $tpl_reply_to
 548
 549 EOT
 550         for my $f (@files) {
 551                 print C get_patch_subject($f);
 552         }
 553         close(C);
 554
 555         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 556
 557         if ($annotate) {
 558                 do_edit($compose_filename, @files);
 559         } else {
 560                 do_edit($compose_filename);
 561         }
 562
 563         open(C2,">",$compose_filename . ".final")
 564                 or die "Failed to open $compose_filename.final : " . $!;
 565
 566         open(C,"<",$compose_filename)
 567                 or die "Failed to open $compose_filename : " . $!;
 568
 569         my $need_8bit_cte = file_has_nonascii($compose_filename);
 570         my $in_body = 0;
 571         my $summary_empty = 1;
 572         while(<C>) {
 573                 next if m/^GIT: /;
 574                 if ($in_body) {
 575                         $summary_empty = 0 unless (/^\n$/);
 576                 } elsif (/^\n$/) {
 577                         $in_body = 1;
 578                         if ($need_8bit_cte) {
 579                                 print C2 "MIME-Version: 1.0\n",
 580                                          "Content-Type: text/plain; ",
 581                                            "charset=utf-8\n",
 582                                          "Content-Transfer-Encoding: 8bit\n";
 583                         }
 584                 } elsif (/^MIME-Version:/i) {
 585                         $need_8bit_cte = 0;
 586                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 587                         $initial_subject = $1;
 588                         my $subject = $initial_subject;
 589                         $_ = "Subject: " .
 590                                 ($subject =~ /[^[:ascii:]]/ ?
 591                                  quote_rfc2047($subject) :
 592                                  $subject) .
 593                                 "\n";
 594                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 595                         $initial_reply_to = $1;
 596                         next;
 597                 } elsif (/^From:\s*(.+)\s*$/i) {
 598                         $sender = $1;
 599                         next;
 600                 } elsif (/^(?:To|Cc|Bcc):/i) {
 601                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 602                         next;
 603                 }
 604                 print C2 $_;
 605         }
 606         close(C);
 607         close(C2);
 608
 609         if ($summary_empty) {
 610                 print "Summary email is empty, skipping it\n";
 611                 $compose = -1;
 612         }
 613 } elsif ($annotate) {
 614         do_edit(@files);
 615 }
 616
 617 sub ask {
 618         my ($prompt, %arg) = @_;
 619         my $valid_re = $arg{valid_re};
 620         my $default = $arg{default};
 621         my $resp;
 622         my $i = 0;
 623         return defined $default ? $default : undef
 624                 unless defined $term->IN and defined fileno($term->IN) and
 625                        defined $term->OUT and defined fileno($term->OUT);
 626         while ($i++ < 10) {
 627                 $resp = $term->readline($prompt);
 628                 if (!defined $resp) { # EOF
 629                         print "\n";
 630                         return defined $default ? $default : undef;
 631                 }
 632                 if ($resp eq '' and defined $default) {
 633                         return $default;
 634                 }
 635                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 636                         return $resp;
 637                 }
 638         }
 639         return undef;
 640 }
 641
 642 my $prompting = 0;
 643 if (!defined $sender) {
 644         $sender = $repoauthor || $repocommitter || '';
 645         $sender = ask("Who should the emails appear to be from? [$sender] ",
 646                       default => $sender);
 647         print "Emails will be sent from: ", $sender, "\n";
 648         $prompting++;
 649 }
 650
 651 if (!@to) {
 652         my $to = ask("Who should the emails be sent to? ");
 653         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 654         $prompting++;
 655 }
 656
 657 sub expand_aliases {
 658         my @cur = @_;
 659         my @last;
 660         do {
 661                 @last = @cur;
 662                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 663         } while (join(',',@cur) ne join(',',@last));
 664         return @cur;
 665 }
 666
 667 @to = expand_aliases(@to);
 668 @to = (map { sanitize_address($_) } @to);
 669 @initial_cc = expand_aliases(@initial_cc);
 670 @bcclist = expand_aliases(@bcclist);
 671
 672 if ($thread && !defined $initial_reply_to && $prompting) {
 673         $initial_reply_to = ask(
 674                 "Message-ID to be used as In-Reply-To for the first email? ");
 675 }
 676 if (defined $initial_reply_to) {
 677         $initial_reply_to =~ s/^\s*<?//;
 678         $initial_reply_to =~ s/>?\s*$//;
 679         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 680 }
 681
 682 if (!defined $smtp_server) {
 683         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 684                 if (-x $_) {
 685                         $smtp_server = $_;
 686                         last;
 687                 }
 688         }
 689         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 690 }
 691
 692 if ($compose && $compose > 0) {
 693         @files = ($compose_filename . ".final", @files);
 694 }
 695
 696 # Variables we set as part of the loop over files
 697 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 698         $needs_confirm, $message_num, $ask_default);
 699
 700 sub extract_valid_address {
 701         my $address = shift;
 702         my $local_part_regexp = '[^<>"\s@]+';
 703         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 704
 705         # check for a local address:
 706         return $address if ($address =~ /^($local_part_regexp)$/);
 707
 708         $address =~ s/^\s*<(.*)>\s*$/$1/;
 709         if ($have_email_valid) {
 710                 return scalar Email::Valid->address($address);
 711         } else {
 712                 # less robust/correct than the monster regexp in Email::Valid,
 713                 # but still does a 99% job, and one less dependency
 714                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 715                 return $1;
 716         }
 717 }
 718
 719 # Usually don't need to change anything below here.
 720
 721 # we make a "fake" message id by taking the current number
 722 # of seconds since the beginning of Unix time and tacking on
 723 # a random number to the end, in case we are called quicker than
 724 # 1 second since the last time we were called.
 725
 726 # We'll setup a template for the message id, using the "from" address:
 727
 728 my ($message_id_stamp, $message_id_serial);
 729 sub make_message_id
 730 {
 731         my $uniq;
 732         if (!defined $message_id_stamp) {
 733                 $message_id_stamp = sprintf("%s-%s", time, $$);
 734                 $message_id_serial = 0;
 735         }
 736         $message_id_serial++;
 737         $uniq = "$message_id_stamp-$message_id_serial";
 738
 739         my $du_part;
 740         for ($sender, $repocommitter, $repoauthor) {
 741                 $du_part = extract_valid_address(sanitize_address($_));
 742                 last if (defined $du_part and $du_part ne '');
 743         }
 744         if (not defined $du_part or $du_part eq '') {
 745                 use Sys::Hostname qw();
 746                 $du_part = 'user@' . Sys::Hostname::hostname();
 747         }
 748         my $message_id_template = "<%s-git-send-email-%s>";
 749         $message_id = sprintf($message_id_template, $uniq, $du_part);
 750         #print "new message id = $message_id\n"; # Was useful for debugging
 751 }
 752
 753
 754
 755 $time = time - scalar $#files;
 756
 757 sub unquote_rfc2047 {
 758         local ($_) = @_;
 759         my $encoding;
 760         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 761                 $encoding = $1;
 762                 s/_/ /g;
 763                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 764         }
 765         return wantarray ? ($_, $encoding) : $_;
 766 }
 767
 768 sub quote_rfc2047 {
 769         local $_ = shift;
 770         my $encoding = shift || 'utf-8';
 771         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 772         s/(.*)/=\?$encoding\?q\?$1\?=/;
 773         return $_;
 774 }
 775
 776 # use the simplest quoting being able to handle the recipient
 777 sub sanitize_address
 778 {
 779         my ($recipient) = @_;
 780         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 781
 782         if (not $recipient_name) {
 783                 return "$recipient";
 784         }
 785
 786         # if recipient_name is already quoted, do nothing
 787         if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
 788                 return $recipient;
 789         }
 790
 791         # rfc2047 is needed if a non-ascii char is included
 792         if ($recipient_name =~ /[^[:ascii:]]/) {
 793                 $recipient_name =~ s/^"(.*)"$/$1/;
 794                 $recipient_name = quote_rfc2047($recipient_name);
 795         }
 796
 797         # double quotes are needed if specials or CTLs are included
 798         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 799                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 800                 $recipient_name = "\"$recipient_name\"";
 801         }
 802
 803         return "$recipient_name $recipient_addr";
 804
 805 }
 806
 807 sub send_message
 808 {
 809         my @recipients = unique_email_list(@to);
 810         @cc = (grep { my $cc = extract_valid_address($_);
 811                       not grep { $cc eq $_ } @recipients
 812                     }
 813                map { sanitize_address($_) }
 814                @cc);
 815         my $to = join (",\n\t", @recipients);
 816         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 817         @recipients = (map { extract_valid_address($_) } @recipients);
 818         my $date = format_2822_time($time++);
 819         my $gitversion = '@@GIT_VERSION@@';
 820         if ($gitversion =~ m/..GIT_VERSION../) {
 821             $gitversion = Git::version();
 822         }
 823
 824         my $cc = join(", ", unique_email_list(@cc));
 825         my $ccline = "";
 826         if ($cc ne '') {
 827                 $ccline = "\nCc: $cc";
 828         }
 829         my $sanitized_sender = sanitize_address($sender);
 830         make_message_id() unless defined($message_id);
 831
 832         my $header = "From: $sanitized_sender
 833 To: $to${ccline}
 834 Subject: $subject
 835 Date: $date
 836 Message-Id: $message_id
 837 X-Mailer: git-send-email $gitversion
 838 ";
 839         if ($reply_to) {
 840
 841                 $header .= "In-Reply-To: $reply_to\n";
 842                 $header .= "References: $references\n";
 843         }
 844         if (@xh) {
 845                 $header .= join("\n", @xh) . "\n";
 846         }
 847
 848         my @sendmail_parameters = ('-i', @recipients);
 849         my $raw_from = $sanitized_sender;
 850         $raw_from = $envelope_sender if (defined $envelope_sender);
 851         $raw_from = extract_valid_address($raw_from);
 852         unshift (@sendmail_parameters,
 853                         '-f', $raw_from) if(defined $envelope_sender);
 854
 855         if ($needs_confirm && !$dry_run) {
 856                 print "\n$header\n";
 857                 if ($needs_confirm eq "inform") {
 858                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 859                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 860                         print "    The Cc list above has been expanded by additional\n";
 861                         print "    addresses found in the patch commit message. By default\n";
 862                         print "    send-email prompts before sending whenever this occurs.\n";
 863                         print "    This behavior is controlled by the sendemail.confirm\n";
 864                         print "    configuration setting.\n";
 865                         print "\n";
 866                         print "    For additional information, run 'git send-email --help'.\n";
 867                         print "    To retain the current behavior, but squelch this message,\n";
 868                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 869                 }
 870                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 871                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 872                          default => $ask_default);
 873                 die "Send this email reply required" unless defined $_;
 874                 if (/^n/i) {
 875                         return;
 876                 } elsif (/^q/i) {
 877                         cleanup_compose_files();
 878                         exit(0);
 879                 } elsif (/^a/i) {
 880                         $confirm = 'never';
 881                 }
 882         }
 883
 884         if ($dry_run) {
 885                 # We don't want to send the email.
 886         } elsif ($smtp_server =~ m#^/#) {
 887                 my $pid = open my $sm, '|-';
 888                 defined $pid or die $!;
 889                 if (!$pid) {
 890                         exec($smtp_server, @sendmail_parameters) or die $!;
 891                 }
 892                 print $sm "$header\n$message";
 893                 close $sm or die $?;
 894         } else {
 895
 896                 if (!defined $smtp_server) {
 897                         die "The required SMTP server is not properly defined."
 898                 }
 899
 900                 if ($smtp_encryption eq 'ssl') {
 901                         $smtp_server_port ||= 465; # ssmtp
 902                         require Net::SMTP::SSL;
 903                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 904                 }
 905                 else {
 906                         require Net::SMTP;
 907                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 908                                                  ? "$smtp_server:$smtp_server_port"
 909                                                  : $smtp_server);
 910                         if ($smtp_encryption eq 'tls') {
 911                                 require Net::SMTP::SSL;
 912                                 $smtp->command('STARTTLS');
 913                                 $smtp->response();
 914                                 if ($smtp->code == 220) {
 915                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 916                                                 or die "STARTTLS failed! ".$smtp->message;
 917                                         $smtp_encryption = '';
 918                                         # Send EHLO again to receive fresh
 919                                         # supported commands
 920                                         $smtp->hello();
 921                                 } else {
 922                                         die "Server does not support STARTTLS! ".$smtp->message;
 923                                 }
 924                         }
 925                 }
 926
 927                 if (!$smtp) {
 928                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 929                 }
 930
 931                 if (defined $smtp_authuser) {
 932
 933                         if (!defined $smtp_authpass) {
 934
 935                                 system "stty -echo";
 936
 937                                 do {
 938                                         print "Password: ";
 939                                         $_ = <STDIN>;
 940                                         print "\n";
 941                                 } while (!defined $_);
 942
 943                                 chomp($smtp_authpass = $_);
 944
 945                                 system "stty echo";
 946                         }
 947
 948                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 949                 }
 950
 951                 $smtp->mail( $raw_from ) or die $smtp->message;
 952                 $smtp->to( @recipients ) or die $smtp->message;
 953                 $smtp->data or die $smtp->message;
 954                 $smtp->datasend("$header\n$message") or die $smtp->message;
 955                 $smtp->dataend() or die $smtp->message;
 956                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 957         }
 958         if ($quiet) {
 959                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 960         } else {
 961                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 962                 if ($smtp_server !~ m#^/#) {
 963                         print "Server: $smtp_server\n";
 964                         print "MAIL FROM:<$raw_from>\n";
 965                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 966                 } else {
 967                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 968                 }
 969                 print $header, "\n";
 970                 if ($smtp) {
 971                         print "Result: ", $smtp->code, ' ',
 972                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 973                 } else {
 974                         print "Result: OK\n";
 975                 }
 976         }
 977 }
 978
 979 $reply_to = $initial_reply_to;
 980 $references = $initial_reply_to || '';
 981 $subject = $initial_subject;
 982 $message_num = 0;
 983
 984 foreach my $t (@files) {
 985         open(F,"<",$t) or die "can't open file $t";
 986
 987         my $author = undef;
 988         my $author_encoding;
 989         my $has_content_type;
 990         my $body_encoding;
 991         @cc = ();
 992         @xh = ();
 993         my $input_format = undef;
 994         my @header = ();
 995         $message = "";
 996         $message_num++;
 997         # First unfold multiline header fields
 998         while(<F>) {
 999                 last if /^\s*$/;
1000                 if (/^\s+\S/ and @header) {
1001                         chomp($header[$#header]);
1002                         s/^\s+/ /;
1003                         $header[$#header] .= $_;
1004             } else {
1005                         push(@header, $_);
1006                 }
1007         }
1008         # Now parse the header
1009         foreach(@header) {
1010                 if (/^From /) {
1011                         $input_format = 'mbox';
1012                         next;
1013                 }
1014                 chomp;
1015                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1016                         $input_format = 'mbox';
1017                 }
1018
1019                 if (defined $input_format && $input_format eq 'mbox') {
1020                         if (/^Subject:\s+(.*)$/) {
1021                                 $subject = $1;
1022                         }
1023                         elsif (/^From:\s+(.*)$/) {
1024                                 ($author, $author_encoding) = unquote_rfc2047($1);
1025                                 next if $suppress_cc{'author'};
1026                                 next if $suppress_cc{'self'} and $author eq $sender;
1027                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1028                                         $1, $_) unless $quiet;
1029                                 push @cc, $1;
1030                         }
1031                         elsif (/^Cc:\s+(.*)$/) {
1032                                 foreach my $addr (parse_address_line($1)) {
1033                                         if (unquote_rfc2047($addr) eq $sender) {
1034                                                 next if ($suppress_cc{'self'});
1035                                         } else {
1036                                                 next if ($suppress_cc{'cc'});
1037                                         }
1038                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1039                                                 $addr, $_) unless $quiet;
1040                                         push @cc, $addr;
1041                                 }
1042                         }
1043                         elsif (/^Content-type:/i) {
1044                                 $has_content_type = 1;
1045                                 if (/charset="?([^ "]+)/) {
1046                                         $body_encoding = $1;
1047                                 }
1048                                 push @xh, $_;
1049                         }
1050                         elsif (/^Message-Id: (.*)/i) {
1051                                 $message_id = $1;
1052                         }
1053                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1054                                 push @xh, $_;
1055                         }
1056
1057                 } else {
1058                         # In the traditional
1059                         # "send lots of email" format,
1060                         # line 1 = cc
1061                         # line 2 = subject
1062                         # So let's support that, too.
1063                         $input_format = 'lots';
1064                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1065                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1066                                         $_, $_) unless $quiet;
1067                                 push @cc, $_;
1068                         } elsif (!defined $subject) {
1069                                 $subject = $_;
1070                         }
1071                 }
1072         }
1073         # Now parse the message body
1074         while(<F>) {
1075                 $message .=  $_;
1076                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1077                         chomp;
1078                         my ($what, $c) = ($1, $2);
1079                         chomp $c;
1080                         if ($c eq $sender) {
1081                                 next if ($suppress_cc{'self'});
1082                         } else {
1083                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1084                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1085                         }
1086                         push @cc, $c;
1087                         printf("(body) Adding cc: %s from line '%s'\n",
1088                                 $c, $_) unless $quiet;
1089                 }
1090         }
1091         close F;
1092
1093         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1094                 open(F, "$cc_cmd $t |")
1095                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1096                 while(<F>) {
1097                         my $c = $_;
1098                         $c =~ s/^\s*//g;
1099                         $c =~ s/\n$//g;
1100                         next if ($c eq $sender and $suppress_from);
1101                         push @cc, $c;
1102                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1103                                 $c, $cc_cmd) unless $quiet;
1104                 }
1105                 close F
1106                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1107         }
1108
1109         if (defined $author and $author ne $sender) {
1110                 $message = "From: $author\n\n$message";
1111                 if (defined $author_encoding) {
1112                         if ($has_content_type) {
1113                                 if ($body_encoding eq $author_encoding) {
1114                                         # ok, we already have the right encoding
1115                                 }
1116                                 else {
1117                                         # uh oh, we should re-encode
1118                                 }
1119                         }
1120                         else {
1121                                 push @xh,
1122                                   'MIME-Version: 1.0',
1123                                   "Content-Type: text/plain; charset=$author_encoding",
1124                                   'Content-Transfer-Encoding: 8bit';
1125                         }
1126                 }
1127         }
1128
1129         $needs_confirm = (
1130                 $confirm eq "always" or
1131                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1132                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1133         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1134
1135         @cc = (@initial_cc, @cc);
1136
1137         send_message();
1138
1139         # set up for the next message
1140         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1141                 $reply_to = $message_id;
1142                 if (length $references > 0) {
1143                         $references .= "\n $message_id";
1144                 } else {
1145                         $references = "$message_id";
1146                 }
1147         }
1148         $message_id = undef;
1149 }
1150
1151 cleanup_compose_files();
1152
1153 sub cleanup_compose_files() {
1154         unlink($compose_filename, $compose_filename . ".final") if $compose;
1155 }
1156
1157 $smtp->quit if $smtp;
1158
1159 sub unique_email_list(@) {
1160         my %seen;
1161         my @emails;
1162
1163         foreach my $entry (@_) {
1164                 if (my $clean = extract_valid_address($entry)) {
1165                         $seen{$clean} ||= 0;
1166                         next if $seen{$clean}++;
1167                         push @emails, $entry;
1168                 } else {
1169                         print STDERR "W: unable to extract a valid address",
1170                                         " from: $entry\n";
1171                 }
1172         }
1173         return @emails;
1174 }
1175
1176 sub validate_patch {
1177         my $fn = shift;
1178         open(my $fh, '<', $fn)
1179                 or die "unable to open $fn: $!\n";
1180         while (my $line = <$fh>) {
1181                 if (length($line) > 998) {
1182                         return "$.: patch contains a line longer than 998 characters";
1183                 }
1184         }
1185         return undef;
1186 }
1187
1188 sub file_has_nonascii {
1189         my $fn = shift;
1190         open(my $fh, '<', $fn)
1191                 or die "unable to open $fn: $!\n";
1192         while (my $line = <$fh>) {
1193                 return 1 if $line =~ /[^[:ascii:]]/;
1194         }
1195         return 0;
1196 }