git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git-send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-ssl     If set, connects to the SMTP server using SSL.
  88
  89    --suppress-cc  Suppress the specified category of auto-CC.  The category
  90                   can be one of 'author' for the patch author, 'self' to
  91                   avoid copying yourself, 'sob' for Signed-off-by lines,
  92                   'cccmd' for the output of the cccmd, or 'all' to suppress
  93                   all of these.
  94
  95    --suppress-from Suppress sending emails to yourself. Defaults to off.
  96
  97    --thread       Specify that the "In-Reply-To:" header should be set on all
  98                   emails. Defaults to on.
  99
 100    --quiet        Make git-send-email less verbose.  One line per email
 101                   should be all that is output.
 102
 103    --dry-run      Do everything except actually send the emails.
 104
 105    --envelope-sender    Specify the envelope sender used to send the emails.
 106
 107    --no-validate        Don't perform any sanity checks on patches.
 108
 109 EOT
 110         exit(1);
 111 }
 112
 113 # most mail servers generate the Date: header, but not all...
 114 sub format_2822_time {
 115         my ($time) = @_;
 116         my @localtm = localtime($time);
 117         my @gmttm = gmtime($time);
 118         my $localmin = $localtm[1] + $localtm[2] * 60;
 119         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 120         if ($localtm[0] != $gmttm[0]) {
 121                 die "local zone differs from GMT by a non-minute interval\n";
 122         }
 123         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 124                 $localmin += 1440;
 125         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 126                 $localmin -= 1440;
 127         } elsif ($gmttm[6] != $localtm[6]) {
 128                 die "local time offset greater than or equal to 24 hours\n";
 129         }
 130         my $offset = $localmin - $gmtmin;
 131         my $offhour = $offset / 60;
 132         my $offmin = abs($offset % 60);
 133         if (abs($offhour) >= 24) {
 134                 die ("local time offset greater than or equal to 24 hours\n");
 135         }
 136
 137         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 138                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 139                        $localtm[3],
 140                        qw(Jan Feb Mar Apr May Jun
 141                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 142                        $localtm[5]+1900,
 143                        $localtm[2],
 144                        $localtm[1],
 145                        $localtm[0],
 146                        ($offset >= 0) ? '+' : '-',
 147                        abs($offhour),
 148                        $offmin,
 149                        );
 150 }
 151
 152 my $have_email_valid = eval { require Email::Valid; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 sub unique_email_list(@);
 157 sub cleanup_compose_files();
 158
 159 # Constants (essentially)
 160 my $compose_filename = ".msg.$$";
 161
 162 # Variables we fill in automatically, or via prompting:
 163 my (@to,@cc,@initial_cc,@bcclist,@xh,
 164         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = Git->repository();
 172 my $term = eval {
 173         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 174                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 175                 : new Term::ReadLine 'git-send-email';
 176 };
 177 if ($@) {
 178         $term = new FakeTerm "$@: going non-interactive";
 179 }
 180
 181 # Behavior modification variables
 182 my ($quiet, $dry_run) = (0, 0);
 183
 184 # Variables with corresponding config settings
 185 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 186 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
 187 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 188 my ($no_validate);
 189 my (@suppress_cc);
 190
 191 my %config_bool_settings = (
 192     "thread" => [\$thread, 1],
 193     "chainreplyto" => [\$chain_reply_to, 1],
 194     "suppressfrom" => [\$suppress_from, undef],
 195     "signedoffcc" => [\$signed_off_cc, undef],
 196     "smtpssl" => [\$smtp_ssl, 0],
 197 );
 198
 199 my %config_settings = (
 200     "smtpserver" => \$smtp_server,
 201     "smtpserverport" => \$smtp_server_port,
 202     "smtpuser" => \$smtp_authuser,
 203     "smtppass" => \$smtp_authpass,
 204     "to" => \@to,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210 );
 211
 212 # Handle Uncouth Termination
 213 sub signal_handler {
 214
 215         # Make text normal
 216         print color("reset"), "\n";
 217
 218         # SMTP password masked
 219         system "stty echo";
 220
 221         # tmp files from --compose
 222         if (-e $compose_filename) {
 223                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 224         }
 225         if (-e ($compose_filename . ".final")) {
 226                 print "'$compose_filename.final' contains the composed email.\n"
 227         }
 228
 229         exit;
 230 };
 231
 232 $SIG{TERM} = \&signal_handler;
 233 $SIG{INT}  = \&signal_handler;
 234
 235 # Begin by accumulating all the variables (defined above), that we will end up
 236 # needing, first, from the command line:
 237
 238 my $rc = GetOptions("sender|from=s" => \$sender,
 239                     "in-reply-to=s" => \$initial_reply_to,
 240                     "subject=s" => \$initial_subject,
 241                     "to=s" => \@to,
 242                     "cc=s" => \@initial_cc,
 243                     "bcc=s" => \@bcclist,
 244                     "chain-reply-to!" => \$chain_reply_to,
 245                     "smtp-server=s" => \$smtp_server,
 246                     "smtp-server-port=s" => \$smtp_server_port,
 247                     "smtp-user=s" => \$smtp_authuser,
 248                     "smtp-pass:s" => \$smtp_authpass,
 249                     "smtp-ssl!" => \$smtp_ssl,
 250                     "identity=s" => \$identity,
 251                     "compose" => \$compose,
 252                     "quiet" => \$quiet,
 253                     "cc-cmd=s" => \$cc_cmd,
 254                     "suppress-from!" => \$suppress_from,
 255                     "suppress-cc=s" => \@suppress_cc,
 256                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 257                     "dry-run" => \$dry_run,
 258                     "envelope-sender=s" => \$envelope_sender,
 259                     "thread!" => \$thread,
 260                     "no-validate" => \$no_validate,
 261          );
 262
 263 unless ($rc) {
 264     usage();
 265 }
 266
 267 # Now, let's fill any that aren't set in with defaults:
 268
 269 sub read_config {
 270         my ($prefix) = @_;
 271
 272         foreach my $setting (keys %config_bool_settings) {
 273                 my $target = $config_bool_settings{$setting}->[0];
 274                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 275         }
 276
 277         foreach my $setting (keys %config_settings) {
 278                 my $target = $config_settings{$setting};
 279                 if (ref($target) eq "ARRAY") {
 280                         unless (@$target) {
 281                                 my @values = $repo->config("$prefix.$setting");
 282                                 @$target = @values if (@values && defined $values[0]);
 283                         }
 284                 }
 285                 else {
 286                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 287                 }
 288         }
 289 }
 290
 291 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 292 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 293 read_config("sendemail.$identity") if (defined $identity);
 294 read_config("sendemail");
 295
 296 # fall back on builtin bool defaults
 297 foreach my $setting (values %config_bool_settings) {
 298         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 299 }
 300
 301 # Set CC suppressions
 302 my(%suppress_cc);
 303 if (@suppress_cc) {
 304         foreach my $entry (@suppress_cc) {
 305                 die "Unknown --suppress-cc field: '$entry'\n"
 306                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 307                 $suppress_cc{$entry} = 1;
 308         }
 309 }
 310
 311 if ($suppress_cc{'all'}) {
 312         foreach my $entry (qw (ccmd cc author self sob)) {
 313                 $suppress_cc{$entry} = 1;
 314         }
 315         delete $suppress_cc{'all'};
 316 }
 317
 318 # If explicit old-style ones are specified, they trump --suppress-cc.
 319 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 320 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 321
 322 # Debugging, print out the suppressions.
 323 if (0) {
 324         print "suppressions:\n";
 325         foreach my $entry (keys %suppress_cc) {
 326                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 327         }
 328 }
 329
 330 my ($repoauthor) = $repo->ident_person('author');
 331 my ($repocommitter) = $repo->ident_person('committer');
 332
 333 # Verify the user input
 334
 335 foreach my $entry (@to) {
 336         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 337 }
 338
 339 foreach my $entry (@initial_cc) {
 340         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 341 }
 342
 343 foreach my $entry (@bcclist) {
 344         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 345 }
 346
 347 my %aliases;
 348 my %parse_alias = (
 349         # multiline formats can be supported in the future
 350         mutt => sub { my $fh = shift; while (<$fh>) {
 351                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 352                         my ($alias, $addr) = ($1, $2);
 353                         $addr =~ s/#.*$//; # mutt allows # comments
 354                          # commas delimit multiple addresses
 355                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 356                 }}},
 357         mailrc => sub { my $fh = shift; while (<$fh>) {
 358                 if (/^alias\s+(\S+)\s+(.*)$/) {
 359                         # spaces delimit multiple addresses
 360                         $aliases{$1} = [ split(/\s+/, $2) ];
 361                 }}},
 362         pine => sub { my $fh = shift; while (<$fh>) {
 363                 if (/^(\S+)\t.*\t(.*)$/) {
 364                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 365                 }}},
 366         gnus => sub { my $fh = shift; while (<$fh>) {
 367                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 368                         $aliases{$1} = [ $2 ];
 369                 }}}
 370 );
 371
 372 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 373         foreach my $file (@alias_files) {
 374                 open my $fh, '<', $file or die "opening $file: $!\n";
 375                 $parse_alias{$aliasfiletype}->($fh);
 376                 close $fh;
 377         }
 378 }
 379
 380 ($sender) = expand_aliases($sender) if defined $sender;
 381
 382 # Now that all the defaults are set, process the rest of the command line
 383 # arguments and collect up the files that need to be processed.
 384 for my $f (@ARGV) {
 385         if (-d $f) {
 386                 opendir(DH,$f)
 387                         or die "Failed to opendir $f: $!";
 388
 389                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 390                                 sort readdir(DH);
 391
 392         } elsif (-f $f) {
 393                 push @files, $f;
 394
 395         } else {
 396                 print STDERR "Skipping $f - not found.\n";
 397         }
 398 }
 399
 400 if (!$no_validate) {
 401         foreach my $f (@files) {
 402                 my $error = validate_patch($f);
 403                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 404         }
 405 }
 406
 407 if (@files) {
 408         unless ($quiet) {
 409                 print $_,"\n" for (@files);
 410         }
 411 } else {
 412         print STDERR "\nNo patch files specified!\n\n";
 413         usage();
 414 }
 415
 416 my $prompting = 0;
 417 if (!defined $sender) {
 418         $sender = $repoauthor || $repocommitter;
 419
 420         while (1) {
 421                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 422                 last if defined $_;
 423                 print "\n";
 424         }
 425
 426         $sender = $_ if ($_);
 427         print "Emails will be sent from: ", $sender, "\n";
 428         $prompting++;
 429 }
 430
 431 if (!@to) {
 432
 433
 434         while (1) {
 435                 $_ = $term->readline("Who should the emails be sent to? ", "");
 436                 last if defined $_;
 437                 print "\n";
 438         }
 439
 440         my $to = $_;
 441         push @to, split /,/, $to;
 442         $prompting++;
 443 }
 444
 445 sub expand_aliases {
 446         my @cur = @_;
 447         my @last;
 448         do {
 449                 @last = @cur;
 450                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 451         } while (join(',',@cur) ne join(',',@last));
 452         return @cur;
 453 }
 454
 455 @to = expand_aliases(@to);
 456 @to = (map { sanitize_address($_) } @to);
 457 @initial_cc = expand_aliases(@initial_cc);
 458 @bcclist = expand_aliases(@bcclist);
 459
 460 if (!defined $initial_subject && $compose) {
 461         while (1) {
 462                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 463                 last if defined $_;
 464                 print "\n";
 465         }
 466
 467         $initial_subject = $_;
 468         $prompting++;
 469 }
 470
 471 if ($thread && !defined $initial_reply_to && $prompting) {
 472         while (1) {
 473                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 474                 last if defined $_;
 475                 print "\n";
 476         }
 477
 478         $initial_reply_to = $_;
 479 }
 480 if (defined $initial_reply_to) {
 481         $initial_reply_to =~ s/^\s*<?//;
 482         $initial_reply_to =~ s/>?\s*$//;
 483         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 484 }
 485
 486 if (!defined $smtp_server) {
 487         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 488                 if (-x $_) {
 489                         $smtp_server = $_;
 490                         last;
 491                 }
 492         }
 493         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 494 }
 495
 496 if ($compose) {
 497         # Note that this does not need to be secure, but we will make a small
 498         # effort to have it be unique
 499         open(C,">",$compose_filename)
 500                 or die "Failed to open for writing $compose_filename: $!";
 501         print C "From $sender # This line is ignored.\n";
 502         printf C "Subject: %s\n\n", $initial_subject;
 503         printf C <<EOT;
 504 GIT: Please enter your email below.
 505 GIT: Lines beginning in "GIT: " will be removed.
 506 GIT: Consider including an overall diffstat or table of contents
 507 GIT: for the patch you are writing.
 508
 509 EOT
 510         close(C);
 511
 512         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 513         system('sh', '-c', '$0 $@', $editor, $compose_filename);
 514
 515         open(C2,">",$compose_filename . ".final")
 516                 or die "Failed to open $compose_filename.final : " . $!;
 517
 518         open(C,"<",$compose_filename)
 519                 or die "Failed to open $compose_filename : " . $!;
 520
 521         my $need_8bit_cte = file_has_nonascii($compose_filename);
 522         my $in_body = 0;
 523         while(<C>) {
 524                 next if m/^GIT: /;
 525                 if (!$in_body && /^\n$/) {
 526                         $in_body = 1;
 527                         if ($need_8bit_cte) {
 528                                 print C2 "MIME-Version: 1.0\n",
 529                                          "Content-Type: text/plain; ",
 530                                            "charset=utf-8\n",
 531                                          "Content-Transfer-Encoding: 8bit\n";
 532                         }
 533                 }
 534                 if (!$in_body && /^MIME-Version:/i) {
 535                         $need_8bit_cte = 0;
 536                 }
 537                 if (!$in_body && /^Subject: ?(.*)/i) {
 538                         my $subject = $1;
 539                         $_ = "Subject: " .
 540                                 ($subject =~ /[^[:ascii:]]/ ?
 541                                  quote_rfc2047($subject) :
 542                                  $subject) .
 543                                 "\n";
 544                 }
 545                 print C2 $_;
 546         }
 547         close(C);
 548         close(C2);
 549
 550         while (1) {
 551                 $_ = $term->readline("Send this email? (y|n) ");
 552                 last if defined $_;
 553                 print "\n";
 554         }
 555
 556         if (uc substr($_,0,1) ne 'Y') {
 557                 cleanup_compose_files();
 558                 exit(0);
 559         }
 560
 561         @files = ($compose_filename . ".final", @files);
 562 }
 563
 564 # Variables we set as part of the loop over files
 565 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 566
 567 sub extract_valid_address {
 568         my $address = shift;
 569         my $local_part_regexp = '[^<>"\s@]+';
 570         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 571
 572         # check for a local address:
 573         return $address if ($address =~ /^($local_part_regexp)$/);
 574
 575         $address =~ s/^\s*<(.*)>\s*$/$1/;
 576         if ($have_email_valid) {
 577                 return scalar Email::Valid->address($address);
 578         } else {
 579                 # less robust/correct than the monster regexp in Email::Valid,
 580                 # but still does a 99% job, and one less dependency
 581                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 582                 return $1;
 583         }
 584 }
 585
 586 # Usually don't need to change anything below here.
 587
 588 # we make a "fake" message id by taking the current number
 589 # of seconds since the beginning of Unix time and tacking on
 590 # a random number to the end, in case we are called quicker than
 591 # 1 second since the last time we were called.
 592
 593 # We'll setup a template for the message id, using the "from" address:
 594
 595 my ($message_id_stamp, $message_id_serial);
 596 sub make_message_id
 597 {
 598         my $uniq;
 599         if (!defined $message_id_stamp) {
 600                 $message_id_stamp = sprintf("%s-%s", time, $$);
 601                 $message_id_serial = 0;
 602         }
 603         $message_id_serial++;
 604         $uniq = "$message_id_stamp-$message_id_serial";
 605
 606         my $du_part;
 607         for ($sender, $repocommitter, $repoauthor) {
 608                 $du_part = extract_valid_address(sanitize_address($_));
 609                 last if (defined $du_part and $du_part ne '');
 610         }
 611         if (not defined $du_part or $du_part eq '') {
 612                 use Sys::Hostname qw();
 613                 $du_part = 'user@' . Sys::Hostname::hostname();
 614         }
 615         my $message_id_template = "<%s-git-send-email-%s>";
 616         $message_id = sprintf($message_id_template, $uniq, $du_part);
 617         #print "new message id = $message_id\n"; # Was useful for debugging
 618 }
 619
 620
 621
 622 $time = time - scalar $#files;
 623
 624 sub unquote_rfc2047 {
 625         local ($_) = @_;
 626         my $encoding;
 627         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 628                 $encoding = $1;
 629                 s/_/ /g;
 630                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 631         }
 632         return wantarray ? ($_, $encoding) : $_;
 633 }
 634
 635 sub quote_rfc2047 {
 636         local $_ = shift;
 637         my $encoding = shift || 'utf-8';
 638         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 639         s/(.*)/=\?$encoding\?q\?$1\?=/;
 640         return $_;
 641 }
 642
 643 # use the simplest quoting being able to handle the recipient
 644 sub sanitize_address
 645 {
 646         my ($recipient) = @_;
 647         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 648
 649         if (not $recipient_name) {
 650                 return "$recipient";
 651         }
 652
 653         # if recipient_name is already quoted, do nothing
 654         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 655                 return $recipient;
 656         }
 657
 658         # rfc2047 is needed if a non-ascii char is included
 659         if ($recipient_name =~ /[^[:ascii:]]/) {
 660                 $recipient_name = quote_rfc2047($recipient_name);
 661         }
 662
 663         # double quotes are needed if specials or CTLs are included
 664         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 665                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 666                 $recipient_name = "\"$recipient_name\"";
 667         }
 668
 669         return "$recipient_name $recipient_addr";
 670
 671 }
 672
 673 sub send_message
 674 {
 675         my @recipients = unique_email_list(@to);
 676         @cc = (grep { my $cc = extract_valid_address($_);
 677                       not grep { $cc eq $_ } @recipients
 678                     }
 679                map { sanitize_address($_) }
 680                @cc);
 681         my $to = join (",\n\t", @recipients);
 682         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 683         @recipients = (map { extract_valid_address($_) } @recipients);
 684         my $date = format_2822_time($time++);
 685         my $gitversion = '@@GIT_VERSION@@';
 686         if ($gitversion =~ m/..GIT_VERSION../) {
 687             $gitversion = Git::version();
 688         }
 689
 690         my $cc = join(", ", unique_email_list(@cc));
 691         my $ccline = "";
 692         if ($cc ne '') {
 693                 $ccline = "\nCc: $cc";
 694         }
 695         my $sanitized_sender = sanitize_address($sender);
 696         make_message_id() unless defined($message_id);
 697
 698         my $header = "From: $sanitized_sender
 699 To: $to${ccline}
 700 Subject: $subject
 701 Date: $date
 702 Message-Id: $message_id
 703 X-Mailer: git-send-email $gitversion
 704 ";
 705         if ($thread && $reply_to) {
 706
 707                 $header .= "In-Reply-To: $reply_to\n";
 708                 $header .= "References: $references\n";
 709         }
 710         if (@xh) {
 711                 $header .= join("\n", @xh) . "\n";
 712         }
 713
 714         my @sendmail_parameters = ('-i', @recipients);
 715         my $raw_from = $sanitized_sender;
 716         $raw_from = $envelope_sender if (defined $envelope_sender);
 717         $raw_from = extract_valid_address($raw_from);
 718         unshift (@sendmail_parameters,
 719                         '-f', $raw_from) if(defined $envelope_sender);
 720
 721         if ($dry_run) {
 722                 # We don't want to send the email.
 723         } elsif ($smtp_server =~ m#^/#) {
 724                 my $pid = open my $sm, '|-';
 725                 defined $pid or die $!;
 726                 if (!$pid) {
 727                         exec($smtp_server, @sendmail_parameters) or die $!;
 728                 }
 729                 print $sm "$header\n$message";
 730                 close $sm or die $?;
 731         } else {
 732
 733                 if (!defined $smtp_server) {
 734                         die "The required SMTP server is not properly defined."
 735                 }
 736
 737                 if ($smtp_ssl) {
 738                         $smtp_server_port ||= 465; # ssmtp
 739                         require Net::SMTP::SSL;
 740                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 741                 }
 742                 else {
 743                         require Net::SMTP;
 744                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 745                                                  ? "$smtp_server:$smtp_server_port"
 746                                                  : $smtp_server);
 747                 }
 748
 749                 if (!$smtp) {
 750                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 751                 }
 752
 753                 if (defined $smtp_authuser) {
 754
 755                         if (!defined $smtp_authpass) {
 756
 757                                 system "stty -echo";
 758
 759                                 do {
 760                                         print "Password: ";
 761                                         $_ = <STDIN>;
 762                                         print "\n";
 763                                 } while (!defined $_);
 764
 765                                 chomp($smtp_authpass = $_);
 766
 767                                 system "stty echo";
 768                         }
 769
 770                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 771                 }
 772
 773                 $smtp->mail( $raw_from ) or die $smtp->message;
 774                 $smtp->to( @recipients ) or die $smtp->message;
 775                 $smtp->data or die $smtp->message;
 776                 $smtp->datasend("$header\n$message") or die $smtp->message;
 777                 $smtp->dataend() or die $smtp->message;
 778                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 779         }
 780         if ($quiet) {
 781                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 782         } else {
 783                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 784                 if ($smtp_server !~ m#^/#) {
 785                         print "Server: $smtp_server\n";
 786                         print "MAIL FROM:<$raw_from>\n";
 787                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 788                 } else {
 789                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 790                 }
 791                 print $header, "\n";
 792                 if ($smtp) {
 793                         print "Result: ", $smtp->code, ' ',
 794                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 795                 } else {
 796                         print "Result: OK\n";
 797                 }
 798         }
 799 }
 800
 801 $reply_to = $initial_reply_to;
 802 $references = $initial_reply_to || '';
 803 $subject = $initial_subject;
 804
 805 foreach my $t (@files) {
 806         open(F,"<",$t) or die "can't open file $t";
 807
 808         my $author = undef;
 809         my $author_encoding;
 810         my $has_content_type;
 811         my $body_encoding;
 812         @cc = @initial_cc;
 813         @xh = ();
 814         my $input_format = undef;
 815         my $header_done = 0;
 816         $message = "";
 817         while(<F>) {
 818                 if (!$header_done) {
 819                         if (/^From /) {
 820                                 $input_format = 'mbox';
 821                                 next;
 822                         }
 823                         chomp;
 824                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 825                                 $input_format = 'mbox';
 826                         }
 827
 828                         if (defined $input_format && $input_format eq 'mbox') {
 829                                 if (/^Subject:\s+(.*)$/) {
 830                                         $subject = $1;
 831
 832                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 833                                         if (unquote_rfc2047($2) eq $sender) {
 834                                                 next if ($suppress_cc{'self'});
 835                                         }
 836                                         elsif ($1 eq 'From') {
 837                                                 ($author, $author_encoding)
 838                                                   = unquote_rfc2047($2);
 839                                                 next if ($suppress_cc{'author'});
 840                                         } else {
 841                                                 next if ($suppress_cc{'cc'});
 842                                         }
 843                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 844                                                 $2, $_) unless $quiet;
 845                                         push @cc, $2;
 846                                 }
 847                                 elsif (/^Content-type:/i) {
 848                                         $has_content_type = 1;
 849                                         if (/charset="?[^ "]+/) {
 850                                                 $body_encoding = $1;
 851                                         }
 852                                         push @xh, $_;
 853                                 }
 854                                 elsif (/^Message-Id: (.*)/i) {
 855                                         $message_id = $1;
 856                                 }
 857                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 858                                         push @xh, $_;
 859                                 }
 860
 861                         } else {
 862                                 # In the traditional
 863                                 # "send lots of email" format,
 864                                 # line 1 = cc
 865                                 # line 2 = subject
 866                                 # So let's support that, too.
 867                                 $input_format = 'lots';
 868                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 869                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 870                                                 $_, $_) unless $quiet;
 871
 872                                         push @cc, $_;
 873
 874                                 } elsif (!defined $subject) {
 875                                         $subject = $_;
 876                                 }
 877                         }
 878
 879                         # A whitespace line will terminate the headers
 880                         if (m/^\s*$/) {
 881                                 $header_done = 1;
 882                         }
 883                 } else {
 884                         $message .=  $_;
 885                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 886                                 next if ($suppress_cc{'sob'});
 887                                 chomp;
 888                                 my $c = $2;
 889                                 chomp $c;
 890                                 next if ($c eq $sender and $suppress_cc{'self'});
 891                                 push @cc, $c;
 892                                 printf("(sob) Adding cc: %s from line '%s'\n",
 893                                         $c, $_) unless $quiet;
 894                         }
 895                 }
 896         }
 897         close F;
 898
 899         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 900                 open(F, "$cc_cmd $t |")
 901                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 902                 while(<F>) {
 903                         my $c = $_;
 904                         $c =~ s/^\s*//g;
 905                         $c =~ s/\n$//g;
 906                         next if ($c eq $sender and $suppress_from);
 907                         push @cc, $c;
 908                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 909                                 $c, $cc_cmd) unless $quiet;
 910                 }
 911                 close F
 912                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 913         }
 914
 915         if (defined $author) {
 916                 $message = "From: $author\n\n$message";
 917                 if (defined $author_encoding) {
 918                         if ($has_content_type) {
 919                                 if ($body_encoding eq $author_encoding) {
 920                                         # ok, we already have the right encoding
 921                                 }
 922                                 else {
 923                                         # uh oh, we should re-encode
 924                                 }
 925                         }
 926                         else {
 927                                 push @xh,
 928                                   'MIME-Version: 1.0',
 929                                   "Content-Type: text/plain; charset=$author_encoding",
 930                                   'Content-Transfer-Encoding: 8bit';
 931                         }
 932                 }
 933         }
 934
 935         send_message();
 936
 937         # set up for the next message
 938         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 939                 $reply_to = $message_id;
 940                 if (length $references > 0) {
 941                         $references .= "\n $message_id";
 942                 } else {
 943                         $references = "$message_id";
 944                 }
 945         }
 946         $message_id = undef;
 947 }
 948
 949 if ($compose) {
 950         cleanup_compose_files();
 951 }
 952
 953 sub cleanup_compose_files() {
 954         unlink($compose_filename, $compose_filename . ".final");
 955
 956 }
 957
 958 $smtp->quit if $smtp;
 959
 960 sub unique_email_list(@) {
 961         my %seen;
 962         my @emails;
 963
 964         foreach my $entry (@_) {
 965                 if (my $clean = extract_valid_address($entry)) {
 966                         $seen{$clean} ||= 0;
 967                         next if $seen{$clean}++;
 968                         push @emails, $entry;
 969                 } else {
 970                         print STDERR "W: unable to extract a valid address",
 971                                         " from: $entry\n";
 972                 }
 973         }
 974         return @emails;
 975 }
 976
 977 sub validate_patch {
 978         my $fn = shift;
 979         open(my $fh, '<', $fn)
 980                 or die "unable to open $fn: $!\n";
 981         while (my $line = <$fh>) {
 982                 if (length($line) > 998) {
 983                         return "$.: patch contains a line longer than 998 characters";
 984                 }
 985         }
 986         return undef;
 987 }
 988
 989 sub file_has_nonascii {
 990         my $fn = shift;
 991         open(my $fh, '<', $fn)
 992                 or die "unable to open $fn: $!\n";
 993         while (my $line = <$fh>) {
 994                 return 1 if $line =~ /[^[:ascii:]]/;
 995         }
 996         return 0;
 997 }