git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180
 181 my %config_bool_settings = (
 182     "thread" => [\$thread, 1],
 183     "chainreplyto" => [\$chain_reply_to, 1],
 184     "suppressfrom" => [\$suppress_from, 0],
 185     "signedoffcc" => [\$signed_off_cc, 1],
 186     "smtpssl" => [\$smtp_ssl, 0],
 187 );
 188
 189 my %config_settings = (
 190     "smtpserver" => \$smtp_server,
 191     "smtpserverport" => \$smtp_server_port,
 192     "smtpuser" => \$smtp_authuser,
 193     "smtppass" => \$smtp_authpass,
 194     "to" => \@to,
 195     "cccmd" => \$cc_cmd,
 196     "aliasfiletype" => \$aliasfiletype,
 197     "bcc" => \@bcclist,
 198     "aliasesfile" => \@alias_files,
 199 );
 200
 201 # Begin by accumulating all the variables (defined above), that we will end up
 202 # needing, first, from the command line:
 203
 204 my $rc = GetOptions("sender|from=s" => \$sender,
 205                     "in-reply-to=s" => \$initial_reply_to,
 206                     "subject=s" => \$initial_subject,
 207                     "to=s" => \@to,
 208                     "cc=s" => \@initial_cc,
 209                     "bcc=s" => \@bcclist,
 210                     "chain-reply-to!" => \$chain_reply_to,
 211                     "smtp-server=s" => \$smtp_server,
 212                     "smtp-server-port=s" => \$smtp_server_port,
 213                     "smtp-user=s" => \$smtp_authuser,
 214                     "smtp-pass=s" => \$smtp_authpass,
 215                     "smtp-ssl!" => \$smtp_ssl,
 216                     "identity=s" => \$identity,
 217                     "compose" => \$compose,
 218                     "quiet" => \$quiet,
 219                     "cc-cmd=s" => \$cc_cmd,
 220                     "suppress-from!" => \$suppress_from,
 221                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 222                     "dry-run" => \$dry_run,
 223                     "envelope-sender=s" => \$envelope_sender,
 224                     "thread!" => \$thread,
 225          );
 226
 227 unless ($rc) {
 228     usage();
 229 }
 230
 231 # Now, let's fill any that aren't set in with defaults:
 232
 233 sub read_config {
 234         my ($prefix) = @_;
 235
 236         foreach my $setting (keys %config_bool_settings) {
 237                 my $target = $config_bool_settings{$setting}->[0];
 238                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 239         }
 240
 241         foreach my $setting (keys %config_settings) {
 242                 my $target = $config_settings{$setting};
 243                 if (ref($target) eq "ARRAY") {
 244                         unless (@$target) {
 245                                 my @values = $repo->config("$prefix.$setting");
 246                                 @$target = @values if (@values && defined $values[0]);
 247                         }
 248                 }
 249                 else {
 250                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 251                 }
 252         }
 253 }
 254
 255 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 256 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 257 read_config("sendemail.$identity") if (defined $identity);
 258 read_config("sendemail");
 259
 260 # fall back on builtin bool defaults
 261 foreach my $setting (values %config_bool_settings) {
 262         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 263 }
 264
 265 my ($repoauthor) = $repo->ident_person('author');
 266 my ($repocommitter) = $repo->ident_person('committer');
 267
 268 # Verify the user input
 269
 270 foreach my $entry (@to) {
 271         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 272 }
 273
 274 foreach my $entry (@initial_cc) {
 275         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 276 }
 277
 278 foreach my $entry (@bcclist) {
 279         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 280 }
 281
 282 my %aliases;
 283 my %parse_alias = (
 284         # multiline formats can be supported in the future
 285         mutt => sub { my $fh = shift; while (<$fh>) {
 286                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 287                         my ($alias, $addr) = ($1, $2);
 288                         $addr =~ s/#.*$//; # mutt allows # comments
 289                          # commas delimit multiple addresses
 290                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 291                 }}},
 292         mailrc => sub { my $fh = shift; while (<$fh>) {
 293                 if (/^alias\s+(\S+)\s+(.*)$/) {
 294                         # spaces delimit multiple addresses
 295                         $aliases{$1} = [ split(/\s+/, $2) ];
 296                 }}},
 297         pine => sub { my $fh = shift; while (<$fh>) {
 298                 if (/^(\S+)\t.*\t(.*)$/) {
 299                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 300                 }}},
 301         gnus => sub { my $fh = shift; while (<$fh>) {
 302                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 303                         $aliases{$1} = [ $2 ];
 304                 }}}
 305 );
 306
 307 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 308         foreach my $file (@alias_files) {
 309                 open my $fh, '<', $file or die "opening $file: $!\n";
 310                 $parse_alias{$aliasfiletype}->($fh);
 311                 close $fh;
 312         }
 313 }
 314
 315 ($sender) = expand_aliases($sender) if defined $sender;
 316
 317 my $prompting = 0;
 318 if (!defined $sender) {
 319         $sender = $repoauthor || $repocommitter;
 320         do {
 321                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 322         } while (!defined $_);
 323
 324         $sender = $_ if ($_);
 325         print "Emails will be sent from: ", $sender, "\n";
 326         $prompting++;
 327 }
 328
 329 if (!@to) {
 330         do {
 331                 $_ = $term->readline("Who should the emails be sent to? ",
 332                                 "");
 333         } while (!defined $_);
 334         my $to = $_;
 335         push @to, split /,/, $to;
 336         $prompting++;
 337 }
 338
 339 sub expand_aliases {
 340         my @cur = @_;
 341         my @last;
 342         do {
 343                 @last = @cur;
 344                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 345         } while (join(',',@cur) ne join(',',@last));
 346         return @cur;
 347 }
 348
 349 @to = expand_aliases(@to);
 350 @to = (map { sanitize_address($_) } @to);
 351 @initial_cc = expand_aliases(@initial_cc);
 352 @bcclist = expand_aliases(@bcclist);
 353
 354 if (!defined $initial_subject && $compose) {
 355         do {
 356                 $_ = $term->readline("What subject should the initial email start with? ",
 357                         $initial_subject);
 358         } while (!defined $_);
 359         $initial_subject = $_;
 360         $prompting++;
 361 }
 362
 363 if ($thread && !defined $initial_reply_to && $prompting) {
 364         do {
 365                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 366                         $initial_reply_to);
 367         } while (!defined $_);
 368
 369         $initial_reply_to = $_;
 370 }
 371
 372 $initial_reply_to =~ s/^\s*<?/</;
 373 $initial_reply_to =~ s/>?\s*$/>/;
 374
 375 if (!defined $smtp_server) {
 376         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 377                 if (-x $_) {
 378                         $smtp_server = $_;
 379                         last;
 380                 }
 381         }
 382         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 383 }
 384
 385 if ($compose) {
 386         # Note that this does not need to be secure, but we will make a small
 387         # effort to have it be unique
 388         open(C,">",$compose_filename)
 389                 or die "Failed to open for writing $compose_filename: $!";
 390         print C "From $sender # This line is ignored.\n";
 391         printf C "Subject: %s\n\n", $initial_subject;
 392         printf C <<EOT;
 393 GIT: Please enter your email below.
 394 GIT: Lines beginning in "GIT: " will be removed.
 395 GIT: Consider including an overall diffstat or table of contents
 396 GIT: for the patch you are writing.
 397
 398 EOT
 399         close(C);
 400
 401         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 402         system($editor, $compose_filename);
 403
 404         open(C2,">",$compose_filename . ".final")
 405                 or die "Failed to open $compose_filename.final : " . $!;
 406
 407         open(C,"<",$compose_filename)
 408                 or die "Failed to open $compose_filename : " . $!;
 409
 410         while(<C>) {
 411                 next if m/^GIT: /;
 412                 print C2 $_;
 413         }
 414         close(C);
 415         close(C2);
 416
 417         do {
 418                 $_ = $term->readline("Send this email? (y|n) ");
 419         } while (!defined $_);
 420
 421         if (uc substr($_,0,1) ne 'Y') {
 422                 cleanup_compose_files();
 423                 exit(0);
 424         }
 425
 426         @files = ($compose_filename . ".final");
 427 }
 428
 429
 430 # Now that all the defaults are set, process the rest of the command line
 431 # arguments and collect up the files that need to be processed.
 432 for my $f (@ARGV) {
 433         if (-d $f) {
 434                 opendir(DH,$f)
 435                         or die "Failed to opendir $f: $!";
 436
 437                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 438                                 sort readdir(DH);
 439
 440         } elsif (-f $f) {
 441                 push @files, $f;
 442
 443         } else {
 444                 print STDERR "Skipping $f - not found.\n";
 445         }
 446 }
 447
 448 if (@files) {
 449         unless ($quiet) {
 450                 print $_,"\n" for (@files);
 451         }
 452 } else {
 453         print STDERR "\nNo patch files specified!\n\n";
 454         usage();
 455 }
 456
 457 # Variables we set as part of the loop over files
 458 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 459
 460 sub extract_valid_address {
 461         my $address = shift;
 462         my $local_part_regexp = '[^<>"\s@]+';
 463         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 464
 465         # check for a local address:
 466         return $address if ($address =~ /^($local_part_regexp)$/);
 467
 468         $address =~ s/^\s*<(.*)>\s*$/$1/;
 469         if ($have_email_valid) {
 470                 return scalar Email::Valid->address($address);
 471         } else {
 472                 # less robust/correct than the monster regexp in Email::Valid,
 473                 # but still does a 99% job, and one less dependency
 474                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 475                 return $1;
 476         }
 477 }
 478
 479 # Usually don't need to change anything below here.
 480
 481 # we make a "fake" message id by taking the current number
 482 # of seconds since the beginning of Unix time and tacking on
 483 # a random number to the end, in case we are called quicker than
 484 # 1 second since the last time we were called.
 485
 486 # We'll setup a template for the message id, using the "from" address:
 487
 488 my ($message_id_stamp, $message_id_serial);
 489 sub make_message_id
 490 {
 491         my $uniq;
 492         if (!defined $message_id_stamp) {
 493                 $message_id_stamp = sprintf("%s-%s", time, $$);
 494                 $message_id_serial = 0;
 495         }
 496         $message_id_serial++;
 497         $uniq = "$message_id_stamp-$message_id_serial";
 498
 499         my $du_part;
 500         for ($sender, $repocommitter, $repoauthor) {
 501                 $du_part = extract_valid_address(sanitize_address($_));
 502                 last if (defined $du_part and $du_part ne '');
 503         }
 504         if (not defined $du_part or $du_part eq '') {
 505                 use Sys::Hostname qw();
 506                 $du_part = 'user@' . Sys::Hostname::hostname();
 507         }
 508         my $message_id_template = "<%s-git-send-email-%s>";
 509         $message_id = sprintf($message_id_template, $uniq, $du_part);
 510         #print "new message id = $message_id\n"; # Was useful for debugging
 511 }
 512
 513
 514
 515 $time = time - scalar $#files;
 516
 517 sub unquote_rfc2047 {
 518         local ($_) = @_;
 519         my $encoding;
 520         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 521                 $encoding = $1;
 522                 s/_/ /g;
 523                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 524         }
 525         return wantarray ? ($_, $encoding) : $_;
 526 }
 527
 528 # use the simplest quoting being able to handle the recipient
 529 sub sanitize_address
 530 {
 531         my ($recipient) = @_;
 532         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 533
 534         if (not $recipient_name) {
 535                 return "$recipient";
 536         }
 537
 538         # if recipient_name is already quoted, do nothing
 539         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 540                 return $recipient;
 541         }
 542
 543         # rfc2047 is needed if a non-ascii char is included
 544         if ($recipient_name =~ /[^[:ascii:]]/) {
 545                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 546                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 547         }
 548
 549         # double quotes are needed if specials or CTLs are included
 550         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 551                 $recipient_name =~ s/(["\\\r])/\\$1/;
 552                 $recipient_name = "\"$recipient_name\"";
 553         }
 554
 555         return "$recipient_name $recipient_addr";
 556
 557 }
 558
 559 sub send_message
 560 {
 561         my @recipients = unique_email_list(@to);
 562         @cc = (grep { my $cc = extract_valid_address($_);
 563                       not grep { $cc eq $_ } @recipients
 564                     }
 565                map { sanitize_address($_) }
 566                @cc);
 567         my $to = join (",\n\t", @recipients);
 568         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 569         @recipients = (map { extract_valid_address($_) } @recipients);
 570         my $date = format_2822_time($time++);
 571         my $gitversion = '@@GIT_VERSION@@';
 572         if ($gitversion =~ m/..GIT_VERSION../) {
 573             $gitversion = Git::version();
 574         }
 575
 576         my $cc = join(", ", unique_email_list(@cc));
 577         my $ccline = "";
 578         if ($cc ne '') {
 579                 $ccline = "\nCc: $cc";
 580         }
 581         my $sanitized_sender = sanitize_address($sender);
 582         make_message_id();
 583
 584         my $header = "From: $sanitized_sender
 585 To: $to${ccline}
 586 Subject: $subject
 587 Date: $date
 588 Message-Id: $message_id
 589 X-Mailer: git-send-email $gitversion
 590 ";
 591         if ($thread && $reply_to) {
 592
 593                 $header .= "In-Reply-To: $reply_to\n";
 594                 $header .= "References: $references\n";
 595         }
 596         if (@xh) {
 597                 $header .= join("\n", @xh) . "\n";
 598         }
 599
 600         my @sendmail_parameters = ('-i', @recipients);
 601         my $raw_from = $sanitized_sender;
 602         $raw_from = $envelope_sender if (defined $envelope_sender);
 603         $raw_from = extract_valid_address($raw_from);
 604         unshift (@sendmail_parameters,
 605                         '-f', $raw_from) if(defined $envelope_sender);
 606
 607         if ($dry_run) {
 608                 # We don't want to send the email.
 609         } elsif ($smtp_server =~ m#^/#) {
 610                 my $pid = open my $sm, '|-';
 611                 defined $pid or die $!;
 612                 if (!$pid) {
 613                         exec($smtp_server, @sendmail_parameters) or die $!;
 614                 }
 615                 print $sm "$header\n$message";
 616                 close $sm or die $?;
 617         } else {
 618
 619                 if (!defined $smtp_server) {
 620                         die "The required SMTP server is not properly defined."
 621                 }
 622
 623                 if ($smtp_ssl) {
 624                         $smtp_server_port ||= 465; # ssmtp
 625                         require Net::SMTP::SSL;
 626                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 627                 }
 628                 else {
 629                         require Net::SMTP;
 630                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 631                                                  ? "$smtp_server:$smtp_server_port"
 632                                                  : $smtp_server);
 633                 }
 634
 635                 if (!$smtp) {
 636                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 637                 }
 638
 639                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 640                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 641                 }
 642                 $smtp->mail( $raw_from ) or die $smtp->message;
 643                 $smtp->to( @recipients ) or die $smtp->message;
 644                 $smtp->data or die $smtp->message;
 645                 $smtp->datasend("$header\n$message") or die $smtp->message;
 646                 $smtp->dataend() or die $smtp->message;
 647                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 648         }
 649         if ($quiet) {
 650                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 651         } else {
 652                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 653                 if ($smtp_server !~ m#^/#) {
 654                         print "Server: $smtp_server\n";
 655                         print "MAIL FROM:<$raw_from>\n";
 656                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 657                 } else {
 658                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 659                 }
 660                 print $header, "\n";
 661                 if ($smtp) {
 662                         print "Result: ", $smtp->code, ' ',
 663                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 664                 } else {
 665                         print "Result: OK\n";
 666                 }
 667         }
 668 }
 669
 670 $reply_to = $initial_reply_to;
 671 $references = $initial_reply_to || '';
 672 $subject = $initial_subject;
 673
 674 foreach my $t (@files) {
 675         open(F,"<",$t) or die "can't open file $t";
 676
 677         my $author = undef;
 678         my $author_encoding;
 679         my $has_content_type;
 680         my $body_encoding;
 681         @cc = @initial_cc;
 682         @xh = ();
 683         my $input_format = undef;
 684         my $header_done = 0;
 685         $message = "";
 686         while(<F>) {
 687                 if (!$header_done) {
 688                         if (/^From /) {
 689                                 $input_format = 'mbox';
 690                                 next;
 691                         }
 692                         chomp;
 693                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 694                                 $input_format = 'mbox';
 695                         }
 696
 697                         if (defined $input_format && $input_format eq 'mbox') {
 698                                 if (/^Subject:\s+(.*)$/) {
 699                                         $subject = $1;
 700
 701                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 702                                         if (unquote_rfc2047($2) eq $sender) {
 703                                                 next if ($suppress_from);
 704                                         }
 705                                         elsif ($1 eq 'From') {
 706                                                 ($author, $author_encoding)
 707                                                   = unquote_rfc2047($2);
 708                                         }
 709                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 710                                                 $2, $_) unless $quiet;
 711                                         push @cc, $2;
 712                                 }
 713                                 elsif (/^Content-type:/i) {
 714                                         $has_content_type = 1;
 715                                         if (/charset="?[^ "]+/) {
 716                                                 $body_encoding = $1;
 717                                         }
 718                                         push @xh, $_;
 719                                 }
 720                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 721                                         push @xh, $_;
 722                                 }
 723
 724                         } else {
 725                                 # In the traditional
 726                                 # "send lots of email" format,
 727                                 # line 1 = cc
 728                                 # line 2 = subject
 729                                 # So let's support that, too.
 730                                 $input_format = 'lots';
 731                                 if (@cc == 0) {
 732                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 733                                                 $_, $_) unless $quiet;
 734
 735                                         push @cc, $_;
 736
 737                                 } elsif (!defined $subject) {
 738                                         $subject = $_;
 739                                 }
 740                         }
 741
 742                         # A whitespace line will terminate the headers
 743                         if (m/^\s*$/) {
 744                                 $header_done = 1;
 745                         }
 746                 } else {
 747                         $message .=  $_;
 748                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 749                                 my $c = $2;
 750                                 chomp $c;
 751                                 next if ($c eq $sender and $suppress_from);
 752                                 push @cc, $c;
 753                                 printf("(sob) Adding cc: %s from line '%s'\n",
 754                                         $c, $_) unless $quiet;
 755                         }
 756                 }
 757         }
 758         close F;
 759
 760         if (defined $cc_cmd) {
 761                 open(F, "$cc_cmd $t |")
 762                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 763                 while(<F>) {
 764                         my $c = $_;
 765                         $c =~ s/^\s*//g;
 766                         $c =~ s/\n$//g;
 767                         next if ($c eq $sender and $suppress_from);
 768                         push @cc, $c;
 769                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 770                                 $c, $cc_cmd) unless $quiet;
 771                 }
 772                 close F
 773                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 774         }
 775
 776         if (defined $author) {
 777                 $message = "From: $author\n\n$message";
 778                 if (defined $author_encoding) {
 779                         if ($has_content_type) {
 780                                 if ($body_encoding eq $author_encoding) {
 781                                         # ok, we already have the right encoding
 782                                 }
 783                                 else {
 784                                         # uh oh, we should re-encode
 785                                 }
 786                         }
 787                         else {
 788                                 push @xh,
 789                                   'MIME-Version: 1.0',
 790                                   "Content-Type: text/plain; charset=$author_encoding",
 791                                   'Content-Transfer-Encoding: 8bit';
 792                         }
 793                 }
 794         }
 795
 796         send_message();
 797
 798         # set up for the next message
 799         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 800                 $reply_to = $message_id;
 801                 if (length $references > 0) {
 802                         $references .= "\n $message_id";
 803                 } else {
 804                         $references = "$message_id";
 805                 }
 806         }
 807 }
 808
 809 if ($compose) {
 810         cleanup_compose_files();
 811 }
 812
 813 sub cleanup_compose_files() {
 814         unlink($compose_filename, $compose_filename . ".final");
 815
 816 }
 817
 818 $smtp->quit if $smtp;
 819
 820 sub unique_email_list(@) {
 821         my %seen;
 822         my @emails;
 823
 824         foreach my $entry (@_) {
 825                 if (my $clean = extract_valid_address($entry)) {
 826                         $seen{$clean} ||= 0;
 827                         next if $seen{$clean}++;
 828                         push @emails, $entry;
 829                 } else {
 830                         print STDERR "W: unable to extract a valid address",
 831                                         " from: $entry\n";
 832                 }
 833         }
 834         return @emails;
 835 }