git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git-send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-ssl     If set, connects to the SMTP server using SSL.
  88
  89    --suppress-cc  Suppress the specified category of auto-CC.  The category
  90                   can be one of 'author' for the patch author, 'self' to
  91                   avoid copying yourself, 'sob' for Signed-off-by lines,
  92                   'cccmd' for the output of the cccmd, or 'all' to suppress
  93                   all of these.
  94
  95    --suppress-from Suppress sending emails to yourself. Defaults to off.
  96
  97    --thread       Specify that the "In-Reply-To:" header should be set on all
  98                   emails. Defaults to on.
  99
 100    --quiet        Make git-send-email less verbose.  One line per email
 101                   should be all that is output.
 102
 103    --dry-run      Do everything except actually send the emails.
 104
 105    --envelope-sender    Specify the envelope sender used to send the emails.
 106
 107    --no-validate        Don't perform any sanity checks on patches.
 108
 109 EOT
 110         exit(1);
 111 }
 112
 113 # most mail servers generate the Date: header, but not all...
 114 sub format_2822_time {
 115         my ($time) = @_;
 116         my @localtm = localtime($time);
 117         my @gmttm = gmtime($time);
 118         my $localmin = $localtm[1] + $localtm[2] * 60;
 119         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 120         if ($localtm[0] != $gmttm[0]) {
 121                 die "local zone differs from GMT by a non-minute interval\n";
 122         }
 123         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 124                 $localmin += 1440;
 125         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 126                 $localmin -= 1440;
 127         } elsif ($gmttm[6] != $localtm[6]) {
 128                 die "local time offset greater than or equal to 24 hours\n";
 129         }
 130         my $offset = $localmin - $gmtmin;
 131         my $offhour = $offset / 60;
 132         my $offmin = abs($offset % 60);
 133         if (abs($offhour) >= 24) {
 134                 die ("local time offset greater than or equal to 24 hours\n");
 135         }
 136
 137         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 138                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 139                        $localtm[3],
 140                        qw(Jan Feb Mar Apr May Jun
 141                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 142                        $localtm[5]+1900,
 143                        $localtm[2],
 144                        $localtm[1],
 145                        $localtm[0],
 146                        ($offset >= 0) ? '+' : '-',
 147                        abs($offhour),
 148                        $offmin,
 149                        );
 150 }
 151
 152 my $have_email_valid = eval { require Email::Valid; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 sub unique_email_list(@);
 157 sub cleanup_compose_files();
 158
 159 # Constants (essentially)
 160 my $compose_filename = ".msg.$$";
 161
 162 # Variables we fill in automatically, or via prompting:
 163 my (@to,@cc,@initial_cc,@bcclist,@xh,
 164         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184
 185 # Variables with corresponding config settings
 186 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 187 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
 188 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 189 my ($no_validate);
 190 my (@suppress_cc);
 191
 192 my %config_bool_settings = (
 193     "thread" => [\$thread, 1],
 194     "chainreplyto" => [\$chain_reply_to, 1],
 195     "suppressfrom" => [\$suppress_from, undef],
 196     "signedoffcc" => [\$signed_off_cc, undef],
 197     "smtpssl" => [\$smtp_ssl, 0],
 198 );
 199
 200 my %config_settings = (
 201     "smtpserver" => \$smtp_server,
 202     "smtpserverport" => \$smtp_server_port,
 203     "smtpuser" => \$smtp_authuser,
 204     "smtppass" => \$smtp_authpass,
 205     "to" => \@to,
 206     "cccmd" => \$cc_cmd,
 207     "aliasfiletype" => \$aliasfiletype,
 208     "bcc" => \@bcclist,
 209     "aliasesfile" => \@alias_files,
 210     "suppresscc" => \@suppress_cc,
 211 );
 212
 213 # Handle Uncouth Termination
 214 sub signal_handler {
 215
 216         # Make text normal
 217         print color("reset"), "\n";
 218
 219         # SMTP password masked
 220         system "stty echo";
 221
 222         # tmp files from --compose
 223         if (-e $compose_filename) {
 224                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 225         }
 226         if (-e ($compose_filename . ".final")) {
 227                 print "'$compose_filename.final' contains the composed email.\n"
 228         }
 229
 230         exit;
 231 };
 232
 233 $SIG{TERM} = \&signal_handler;
 234 $SIG{INT}  = \&signal_handler;
 235
 236 # Begin by accumulating all the variables (defined above), that we will end up
 237 # needing, first, from the command line:
 238
 239 my $rc = GetOptions("sender|from=s" => \$sender,
 240                     "in-reply-to=s" => \$initial_reply_to,
 241                     "subject=s" => \$initial_subject,
 242                     "to=s" => \@to,
 243                     "cc=s" => \@initial_cc,
 244                     "bcc=s" => \@bcclist,
 245                     "chain-reply-to!" => \$chain_reply_to,
 246                     "smtp-server=s" => \$smtp_server,
 247                     "smtp-server-port=s" => \$smtp_server_port,
 248                     "smtp-user=s" => \$smtp_authuser,
 249                     "smtp-pass:s" => \$smtp_authpass,
 250                     "smtp-ssl!" => \$smtp_ssl,
 251                     "identity=s" => \$identity,
 252                     "compose" => \$compose,
 253                     "quiet" => \$quiet,
 254                     "cc-cmd=s" => \$cc_cmd,
 255                     "suppress-from!" => \$suppress_from,
 256                     "suppress-cc=s" => \@suppress_cc,
 257                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 258                     "dry-run" => \$dry_run,
 259                     "envelope-sender=s" => \$envelope_sender,
 260                     "thread!" => \$thread,
 261                     "no-validate" => \$no_validate,
 262          );
 263
 264 unless ($rc) {
 265     usage();
 266 }
 267
 268 # Now, let's fill any that aren't set in with defaults:
 269
 270 sub read_config {
 271         my ($prefix) = @_;
 272
 273         foreach my $setting (keys %config_bool_settings) {
 274                 my $target = $config_bool_settings{$setting}->[0];
 275                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 276         }
 277
 278         foreach my $setting (keys %config_settings) {
 279                 my $target = $config_settings{$setting};
 280                 if (ref($target) eq "ARRAY") {
 281                         unless (@$target) {
 282                                 my @values = Git::config(@repo, "$prefix.$setting");
 283                                 @$target = @values if (@values && defined $values[0]);
 284                         }
 285                 }
 286                 else {
 287                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 288                 }
 289         }
 290 }
 291
 292 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 293 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 294 read_config("sendemail.$identity") if (defined $identity);
 295 read_config("sendemail");
 296
 297 # fall back on builtin bool defaults
 298 foreach my $setting (values %config_bool_settings) {
 299         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 300 }
 301
 302 # Set CC suppressions
 303 my(%suppress_cc);
 304 if (@suppress_cc) {
 305         foreach my $entry (@suppress_cc) {
 306                 die "Unknown --suppress-cc field: '$entry'\n"
 307                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 308                 $suppress_cc{$entry} = 1;
 309         }
 310 }
 311
 312 if ($suppress_cc{'all'}) {
 313         foreach my $entry (qw (ccmd cc author self sob)) {
 314                 $suppress_cc{$entry} = 1;
 315         }
 316         delete $suppress_cc{'all'};
 317 }
 318
 319 # If explicit old-style ones are specified, they trump --suppress-cc.
 320 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 321 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 322
 323 # Debugging, print out the suppressions.
 324 if (0) {
 325         print "suppressions:\n";
 326         foreach my $entry (keys %suppress_cc) {
 327                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 328         }
 329 }
 330
 331 my ($repoauthor, $repocommitter);
 332 ($repoauthor) = Git::ident_person(@repo, 'author');
 333 ($repocommitter) = Git::ident_person(@repo, 'committer');
 334
 335 # Verify the user input
 336
 337 foreach my $entry (@to) {
 338         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 339 }
 340
 341 foreach my $entry (@initial_cc) {
 342         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 343 }
 344
 345 foreach my $entry (@bcclist) {
 346         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 347 }
 348
 349 my %aliases;
 350 my %parse_alias = (
 351         # multiline formats can be supported in the future
 352         mutt => sub { my $fh = shift; while (<$fh>) {
 353                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 354                         my ($alias, $addr) = ($1, $2);
 355                         $addr =~ s/#.*$//; # mutt allows # comments
 356                          # commas delimit multiple addresses
 357                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 358                 }}},
 359         mailrc => sub { my $fh = shift; while (<$fh>) {
 360                 if (/^alias\s+(\S+)\s+(.*)$/) {
 361                         # spaces delimit multiple addresses
 362                         $aliases{$1} = [ split(/\s+/, $2) ];
 363                 }}},
 364         pine => sub { my $fh = shift; while (<$fh>) {
 365                 if (/^(\S+)\t.*\t(.*)$/) {
 366                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 367                 }}},
 368         gnus => sub { my $fh = shift; while (<$fh>) {
 369                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 370                         $aliases{$1} = [ $2 ];
 371                 }}}
 372 );
 373
 374 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 375         foreach my $file (@alias_files) {
 376                 open my $fh, '<', $file or die "opening $file: $!\n";
 377                 $parse_alias{$aliasfiletype}->($fh);
 378                 close $fh;
 379         }
 380 }
 381
 382 ($sender) = expand_aliases($sender) if defined $sender;
 383
 384 # Now that all the defaults are set, process the rest of the command line
 385 # arguments and collect up the files that need to be processed.
 386 for my $f (@ARGV) {
 387         if (-d $f) {
 388                 opendir(DH,$f)
 389                         or die "Failed to opendir $f: $!";
 390
 391                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 392                                 sort readdir(DH);
 393
 394         } elsif (-f $f) {
 395                 push @files, $f;
 396
 397         } else {
 398                 print STDERR "Skipping $f - not found.\n";
 399         }
 400 }
 401
 402 if (!$no_validate) {
 403         foreach my $f (@files) {
 404                 my $error = validate_patch($f);
 405                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 406         }
 407 }
 408
 409 if (@files) {
 410         unless ($quiet) {
 411                 print $_,"\n" for (@files);
 412         }
 413 } else {
 414         print STDERR "\nNo patch files specified!\n\n";
 415         usage();
 416 }
 417
 418 my $prompting = 0;
 419 if (!defined $sender) {
 420         $sender = $repoauthor || $repocommitter || '';
 421
 422         while (1) {
 423                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 424                 last if defined $_;
 425                 print "\n";
 426         }
 427
 428         $sender = $_ if ($_);
 429         print "Emails will be sent from: ", $sender, "\n";
 430         $prompting++;
 431 }
 432
 433 if (!@to) {
 434
 435
 436         while (1) {
 437                 $_ = $term->readline("Who should the emails be sent to? ", "");
 438                 last if defined $_;
 439                 print "\n";
 440         }
 441
 442         my $to = $_;
 443         push @to, split /,/, $to;
 444         $prompting++;
 445 }
 446
 447 sub expand_aliases {
 448         my @cur = @_;
 449         my @last;
 450         do {
 451                 @last = @cur;
 452                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 453         } while (join(',',@cur) ne join(',',@last));
 454         return @cur;
 455 }
 456
 457 @to = expand_aliases(@to);
 458 @to = (map { sanitize_address($_) } @to);
 459 @initial_cc = expand_aliases(@initial_cc);
 460 @bcclist = expand_aliases(@bcclist);
 461
 462 if (!defined $initial_subject && $compose) {
 463         while (1) {
 464                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 465                 last if defined $_;
 466                 print "\n";
 467         }
 468
 469         $initial_subject = $_;
 470         $prompting++;
 471 }
 472
 473 if ($thread && !defined $initial_reply_to && $prompting) {
 474         while (1) {
 475                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 476                 last if defined $_;
 477                 print "\n";
 478         }
 479
 480         $initial_reply_to = $_;
 481 }
 482 if (defined $initial_reply_to) {
 483         $initial_reply_to =~ s/^\s*<?//;
 484         $initial_reply_to =~ s/>?\s*$//;
 485         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 486 }
 487
 488 if (!defined $smtp_server) {
 489         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 490                 if (-x $_) {
 491                         $smtp_server = $_;
 492                         last;
 493                 }
 494         }
 495         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 496 }
 497
 498 if ($compose) {
 499         # Note that this does not need to be secure, but we will make a small
 500         # effort to have it be unique
 501         open(C,">",$compose_filename)
 502                 or die "Failed to open for writing $compose_filename: $!";
 503         print C "From $sender # This line is ignored.\n";
 504         printf C "Subject: %s\n\n", $initial_subject;
 505         printf C <<EOT;
 506 GIT: Please enter your email below.
 507 GIT: Lines beginning in "GIT: " will be removed.
 508 GIT: Consider including an overall diffstat or table of contents
 509 GIT: for the patch you are writing.
 510
 511 EOT
 512         close(C);
 513
 514         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 515         system('sh', '-c', '$0 $@', $editor, $compose_filename);
 516
 517         open(C2,">",$compose_filename . ".final")
 518                 or die "Failed to open $compose_filename.final : " . $!;
 519
 520         open(C,"<",$compose_filename)
 521                 or die "Failed to open $compose_filename : " . $!;
 522
 523         while(<C>) {
 524                 next if m/^GIT: /;
 525                 print C2 $_;
 526         }
 527         close(C);
 528         close(C2);
 529
 530         while (1) {
 531                 $_ = $term->readline("Send this email? (y|n) ");
 532                 last if defined $_;
 533                 print "\n";
 534         }
 535
 536         if (uc substr($_,0,1) ne 'Y') {
 537                 cleanup_compose_files();
 538                 exit(0);
 539         }
 540
 541         @files = ($compose_filename . ".final", @files);
 542 }
 543
 544 # Variables we set as part of the loop over files
 545 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 546
 547 sub extract_valid_address {
 548         my $address = shift;
 549         my $local_part_regexp = '[^<>"\s@]+';
 550         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 551
 552         # check for a local address:
 553         return $address if ($address =~ /^($local_part_regexp)$/);
 554
 555         $address =~ s/^\s*<(.*)>\s*$/$1/;
 556         if ($have_email_valid) {
 557                 return scalar Email::Valid->address($address);
 558         } else {
 559                 # less robust/correct than the monster regexp in Email::Valid,
 560                 # but still does a 99% job, and one less dependency
 561                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 562                 return $1;
 563         }
 564 }
 565
 566 # Usually don't need to change anything below here.
 567
 568 # we make a "fake" message id by taking the current number
 569 # of seconds since the beginning of Unix time and tacking on
 570 # a random number to the end, in case we are called quicker than
 571 # 1 second since the last time we were called.
 572
 573 # We'll setup a template for the message id, using the "from" address:
 574
 575 my ($message_id_stamp, $message_id_serial);
 576 sub make_message_id
 577 {
 578         my $uniq;
 579         if (!defined $message_id_stamp) {
 580                 $message_id_stamp = sprintf("%s-%s", time, $$);
 581                 $message_id_serial = 0;
 582         }
 583         $message_id_serial++;
 584         $uniq = "$message_id_stamp-$message_id_serial";
 585
 586         my $du_part;
 587         for ($sender, $repocommitter, $repoauthor) {
 588                 $du_part = extract_valid_address(sanitize_address($_));
 589                 last if (defined $du_part and $du_part ne '');
 590         }
 591         if (not defined $du_part or $du_part eq '') {
 592                 use Sys::Hostname qw();
 593                 $du_part = 'user@' . Sys::Hostname::hostname();
 594         }
 595         my $message_id_template = "<%s-git-send-email-%s>";
 596         $message_id = sprintf($message_id_template, $uniq, $du_part);
 597         #print "new message id = $message_id\n"; # Was useful for debugging
 598 }
 599
 600
 601
 602 $time = time - scalar $#files;
 603
 604 sub unquote_rfc2047 {
 605         local ($_) = @_;
 606         my $encoding;
 607         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 608                 $encoding = $1;
 609                 s/_/ /g;
 610                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 611         }
 612         return wantarray ? ($_, $encoding) : $_;
 613 }
 614
 615 # use the simplest quoting being able to handle the recipient
 616 sub sanitize_address
 617 {
 618         my ($recipient) = @_;
 619         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 620
 621         if (not $recipient_name) {
 622                 return "$recipient";
 623         }
 624
 625         # if recipient_name is already quoted, do nothing
 626         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 627                 return $recipient;
 628         }
 629
 630         # rfc2047 is needed if a non-ascii char is included
 631         if ($recipient_name =~ /[^[:ascii:]]/) {
 632                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 633                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 634         }
 635
 636         # double quotes are needed if specials or CTLs are included
 637         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 638                 $recipient_name =~ s/(["\\\r])/\\$1/;
 639                 $recipient_name = "\"$recipient_name\"";
 640         }
 641
 642         return "$recipient_name $recipient_addr";
 643
 644 }
 645
 646 sub send_message
 647 {
 648         my @recipients = unique_email_list(@to);
 649         @cc = (grep { my $cc = extract_valid_address($_);
 650                       not grep { $cc eq $_ } @recipients
 651                     }
 652                map { sanitize_address($_) }
 653                @cc);
 654         my $to = join (",\n\t", @recipients);
 655         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 656         @recipients = (map { extract_valid_address($_) } @recipients);
 657         my $date = format_2822_time($time++);
 658         my $gitversion = '@@GIT_VERSION@@';
 659         if ($gitversion =~ m/..GIT_VERSION../) {
 660             $gitversion = Git::version();
 661         }
 662
 663         my $cc = join(", ", unique_email_list(@cc));
 664         my $ccline = "";
 665         if ($cc ne '') {
 666                 $ccline = "\nCc: $cc";
 667         }
 668         my $sanitized_sender = sanitize_address($sender);
 669         make_message_id() unless defined($message_id);
 670
 671         my $header = "From: $sanitized_sender
 672 To: $to${ccline}
 673 Subject: $subject
 674 Date: $date
 675 Message-Id: $message_id
 676 X-Mailer: git-send-email $gitversion
 677 ";
 678         if ($thread && $reply_to) {
 679
 680                 $header .= "In-Reply-To: $reply_to\n";
 681                 $header .= "References: $references\n";
 682         }
 683         if (@xh) {
 684                 $header .= join("\n", @xh) . "\n";
 685         }
 686
 687         my @sendmail_parameters = ('-i', @recipients);
 688         my $raw_from = $sanitized_sender;
 689         $raw_from = $envelope_sender if (defined $envelope_sender);
 690         $raw_from = extract_valid_address($raw_from);
 691         unshift (@sendmail_parameters,
 692                         '-f', $raw_from) if(defined $envelope_sender);
 693
 694         if ($dry_run) {
 695                 # We don't want to send the email.
 696         } elsif ($smtp_server =~ m#^/#) {
 697                 my $pid = open my $sm, '|-';
 698                 defined $pid or die $!;
 699                 if (!$pid) {
 700                         exec($smtp_server, @sendmail_parameters) or die $!;
 701                 }
 702                 print $sm "$header\n$message";
 703                 close $sm or die $?;
 704         } else {
 705
 706                 if (!defined $smtp_server) {
 707                         die "The required SMTP server is not properly defined."
 708                 }
 709
 710                 if ($smtp_ssl) {
 711                         $smtp_server_port ||= 465; # ssmtp
 712                         require Net::SMTP::SSL;
 713                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 714                 }
 715                 else {
 716                         require Net::SMTP;
 717                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 718                                                  ? "$smtp_server:$smtp_server_port"
 719                                                  : $smtp_server);
 720                 }
 721
 722                 if (!$smtp) {
 723                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 724                 }
 725
 726                 if (defined $smtp_authuser) {
 727
 728                         if (!defined $smtp_authpass) {
 729
 730                                 system "stty -echo";
 731
 732                                 do {
 733                                         print "Password: ";
 734                                         $_ = <STDIN>;
 735                                         print "\n";
 736                                 } while (!defined $_);
 737
 738                                 chomp($smtp_authpass = $_);
 739
 740                                 system "stty echo";
 741                         }
 742
 743                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 744                 }
 745
 746                 $smtp->mail( $raw_from ) or die $smtp->message;
 747                 $smtp->to( @recipients ) or die $smtp->message;
 748                 $smtp->data or die $smtp->message;
 749                 $smtp->datasend("$header\n$message") or die $smtp->message;
 750                 $smtp->dataend() or die $smtp->message;
 751                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 752         }
 753         if ($quiet) {
 754                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 755         } else {
 756                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 757                 if ($smtp_server !~ m#^/#) {
 758                         print "Server: $smtp_server\n";
 759                         print "MAIL FROM:<$raw_from>\n";
 760                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 761                 } else {
 762                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 763                 }
 764                 print $header, "\n";
 765                 if ($smtp) {
 766                         print "Result: ", $smtp->code, ' ',
 767                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 768                 } else {
 769                         print "Result: OK\n";
 770                 }
 771         }
 772 }
 773
 774 $reply_to = $initial_reply_to;
 775 $references = $initial_reply_to || '';
 776 $subject = $initial_subject;
 777
 778 foreach my $t (@files) {
 779         open(F,"<",$t) or die "can't open file $t";
 780
 781         my $author = undef;
 782         my $author_encoding;
 783         my $has_content_type;
 784         my $body_encoding;
 785         @cc = @initial_cc;
 786         @xh = ();
 787         my $input_format = undef;
 788         my $header_done = 0;
 789         $message = "";
 790         while(<F>) {
 791                 if (!$header_done) {
 792                         if (/^From /) {
 793                                 $input_format = 'mbox';
 794                                 next;
 795                         }
 796                         chomp;
 797                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 798                                 $input_format = 'mbox';
 799                         }
 800
 801                         if (defined $input_format && $input_format eq 'mbox') {
 802                                 if (/^Subject:\s+(.*)$/) {
 803                                         $subject = $1;
 804
 805                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 806                                         if (unquote_rfc2047($2) eq $sender) {
 807                                                 next if ($suppress_cc{'self'});
 808                                         }
 809                                         elsif ($1 eq 'From') {
 810                                                 ($author, $author_encoding)
 811                                                   = unquote_rfc2047($2);
 812                                                 next if ($suppress_cc{'author'});
 813                                         } else {
 814                                                 next if ($suppress_cc{'cc'});
 815                                         }
 816                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 817                                                 $2, $_) unless $quiet;
 818                                         push @cc, $2;
 819                                 }
 820                                 elsif (/^Content-type:/i) {
 821                                         $has_content_type = 1;
 822                                         if (/charset="?[^ "]+/) {
 823                                                 $body_encoding = $1;
 824                                         }
 825                                         push @xh, $_;
 826                                 }
 827                                 elsif (/^Message-Id: (.*)/i) {
 828                                         $message_id = $1;
 829                                 }
 830                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 831                                         push @xh, $_;
 832                                 }
 833
 834                         } else {
 835                                 # In the traditional
 836                                 # "send lots of email" format,
 837                                 # line 1 = cc
 838                                 # line 2 = subject
 839                                 # So let's support that, too.
 840                                 $input_format = 'lots';
 841                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 842                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 843                                                 $_, $_) unless $quiet;
 844
 845                                         push @cc, $_;
 846
 847                                 } elsif (!defined $subject) {
 848                                         $subject = $_;
 849                                 }
 850                         }
 851
 852                         # A whitespace line will terminate the headers
 853                         if (m/^\s*$/) {
 854                                 $header_done = 1;
 855                         }
 856                 } else {
 857                         $message .=  $_;
 858                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 859                                 next if ($suppress_cc{'sob'});
 860                                 chomp;
 861                                 my $c = $2;
 862                                 chomp $c;
 863                                 next if ($c eq $sender and $suppress_cc{'self'});
 864                                 push @cc, $c;
 865                                 printf("(sob) Adding cc: %s from line '%s'\n",
 866                                         $c, $_) unless $quiet;
 867                         }
 868                 }
 869         }
 870         close F;
 871
 872         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 873                 open(F, "$cc_cmd $t |")
 874                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 875                 while(<F>) {
 876                         my $c = $_;
 877                         $c =~ s/^\s*//g;
 878                         $c =~ s/\n$//g;
 879                         next if ($c eq $sender and $suppress_from);
 880                         push @cc, $c;
 881                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 882                                 $c, $cc_cmd) unless $quiet;
 883                 }
 884                 close F
 885                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 886         }
 887
 888         if (defined $author) {
 889                 $message = "From: $author\n\n$message";
 890                 if (defined $author_encoding) {
 891                         if ($has_content_type) {
 892                                 if ($body_encoding eq $author_encoding) {
 893                                         # ok, we already have the right encoding
 894                                 }
 895                                 else {
 896                                         # uh oh, we should re-encode
 897                                 }
 898                         }
 899                         else {
 900                                 push @xh,
 901                                   'MIME-Version: 1.0',
 902                                   "Content-Type: text/plain; charset=$author_encoding",
 903                                   'Content-Transfer-Encoding: 8bit';
 904                         }
 905                 }
 906         }
 907
 908         send_message();
 909
 910         # set up for the next message
 911         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 912                 $reply_to = $message_id;
 913                 if (length $references > 0) {
 914                         $references .= "\n $message_id";
 915                 } else {
 916                         $references = "$message_id";
 917                 }
 918         }
 919         $message_id = undef;
 920 }
 921
 922 if ($compose) {
 923         cleanup_compose_files();
 924 }
 925
 926 sub cleanup_compose_files() {
 927         unlink($compose_filename, $compose_filename . ".final");
 928
 929 }
 930
 931 $smtp->quit if $smtp;
 932
 933 sub unique_email_list(@) {
 934         my %seen;
 935         my @emails;
 936
 937         foreach my $entry (@_) {
 938                 if (my $clean = extract_valid_address($entry)) {
 939                         $seen{$clean} ||= 0;
 940                         next if $seen{$clean}++;
 941                         push @emails, $entry;
 942                 } else {
 943                         print STDERR "W: unable to extract a valid address",
 944                                         " from: $entry\n";
 945                 }
 946         }
 947         return @emails;
 948 }
 949
 950 sub validate_patch {
 951         my $fn = shift;
 952         open(my $fh, '<', $fn)
 953                 or die "unable to open $fn: $!\n";
 954         while (my $line = <$fh>) {
 955                 if (length($line) > 998) {
 956                         return "$.: patch contains a line longer than 998 characters";
 957                 }
 958         }
 959         return undef;
 960 }