git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cccmd, all.
  72     --[no-]signed-off-by-cc        * Send to Cc: and Signed-off-by:
  73                                      addresses. Default on.
  74     --[no-]suppress-from           * Send to self. Default off.
  75     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  76     --[no-]thread                  * Use In-Reply-To: field. Default on.
  77
  78   Administering:
  79     --quiet                        * Output one line of info per email.
  80     --dry-run                      * Don't actually send the emails.
  81     --[no-]validate                * Perform patch sanity checks. Default on.
  82     --[no-]format-patch            * understand any non optional arguments as
  83                                      `git format-patch` ones.
  84
  85 EOT
  86         exit(1);
  87 }
  88
  89 # most mail servers generate the Date: header, but not all...
  90 sub format_2822_time {
  91         my ($time) = @_;
  92         my @localtm = localtime($time);
  93         my @gmttm = gmtime($time);
  94         my $localmin = $localtm[1] + $localtm[2] * 60;
  95         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  96         if ($localtm[0] != $gmttm[0]) {
  97                 die "local zone differs from GMT by a non-minute interval\n";
  98         }
  99         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 100                 $localmin += 1440;
 101         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 102                 $localmin -= 1440;
 103         } elsif ($gmttm[6] != $localtm[6]) {
 104                 die "local time offset greater than or equal to 24 hours\n";
 105         }
 106         my $offset = $localmin - $gmtmin;
 107         my $offhour = $offset / 60;
 108         my $offmin = abs($offset % 60);
 109         if (abs($offhour) >= 24) {
 110                 die ("local time offset greater than or equal to 24 hours\n");
 111         }
 112
 113         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 114                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 115                        $localtm[3],
 116                        qw(Jan Feb Mar Apr May Jun
 117                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 118                        $localtm[5]+1900,
 119                        $localtm[2],
 120                        $localtm[1],
 121                        $localtm[0],
 122                        ($offset >= 0) ? '+' : '-',
 123                        abs($offhour),
 124                        $offmin,
 125                        );
 126 }
 127
 128 my $have_email_valid = eval { require Email::Valid; 1 };
 129 my $smtp;
 130 my $auth;
 131
 132 sub unique_email_list(@);
 133 sub cleanup_compose_files();
 134
 135 # Variables we fill in automatically, or via prompting:
 136 my (@to,@cc,@initial_cc,@bcclist,@xh,
 137         $initial_reply_to,$initial_subject,@files,
 138         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 139
 140 my $envelope_sender;
 141
 142 # Example reply to:
 143 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 144
 145 my $repo = eval { Git->repository() };
 146 my @repo = $repo ? ($repo) : ();
 147 my $term = eval {
 148         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 149                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 150                 : new Term::ReadLine 'git-send-email';
 151 };
 152 if ($@) {
 153         $term = new FakeTerm "$@: going non-interactive";
 154 }
 155
 156 # Behavior modification variables
 157 my ($quiet, $dry_run) = (0, 0);
 158 my $format_patch;
 159 my $compose_filename = ($repo ?
 160         tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 161         tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 162
 163
 164 # Handle interactive edition of files.
 165 my $multiedit;
 166 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 167 sub do_edit {
 168         if (defined($multiedit) && !$multiedit) {
 169                 map {
 170                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 171                         if (($? & 127) || ($? >> 8)) {
 172                                 die("the editor exited uncleanly, aborting everything");
 173                         }
 174                 } @_;
 175         } else {
 176                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 177                 if (($? & 127) || ($? >> 8)) {
 178                         die("the editor exited uncleanly, aborting everything");
 179                 }
 180         }
 181 }
 182
 183 # Variables with corresponding config settings
 184 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 185 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 186 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 187 my ($validate);
 188 my (@suppress_cc);
 189
 190 my %config_bool_settings = (
 191     "thread" => [\$thread, 1],
 192     "chainreplyto" => [\$chain_reply_to, 1],
 193     "suppressfrom" => [\$suppress_from, undef],
 194     "signedoffbycc" => [\$signed_off_by_cc, undef],
 195     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 196     "validate" => [\$validate, 1],
 197 );
 198
 199 my %config_settings = (
 200     "smtpserver" => \$smtp_server,
 201     "smtpserverport" => \$smtp_server_port,
 202     "smtpuser" => \$smtp_authuser,
 203     "smtppass" => \$smtp_authpass,
 204     "to" => \@to,
 205     "cc" => \@initial_cc,
 206     "cccmd" => \$cc_cmd,
 207     "aliasfiletype" => \$aliasfiletype,
 208     "bcc" => \@bcclist,
 209     "aliasesfile" => \@alias_files,
 210     "suppresscc" => \@suppress_cc,
 211     "envelopesender" => \$envelope_sender,
 212     "multiedit" => \$multiedit,
 213 );
 214
 215 # Handle Uncouth Termination
 216 sub signal_handler {
 217
 218         # Make text normal
 219         print color("reset"), "\n";
 220
 221         # SMTP password masked
 222         system "stty echo";
 223
 224         # tmp files from --compose
 225         if (-e $compose_filename) {
 226                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 227         }
 228         if (-e ($compose_filename . ".final")) {
 229                 print "'$compose_filename.final' contains the composed email.\n"
 230         }
 231
 232         exit;
 233 };
 234
 235 $SIG{TERM} = \&signal_handler;
 236 $SIG{INT}  = \&signal_handler;
 237
 238 # Begin by accumulating all the variables (defined above), that we will end up
 239 # needing, first, from the command line:
 240
 241 my $rc = GetOptions("sender|from=s" => \$sender,
 242                     "in-reply-to=s" => \$initial_reply_to,
 243                     "subject=s" => \$initial_subject,
 244                     "to=s" => \@to,
 245                     "cc=s" => \@initial_cc,
 246                     "bcc=s" => \@bcclist,
 247                     "chain-reply-to!" => \$chain_reply_to,
 248                     "smtp-server=s" => \$smtp_server,
 249                     "smtp-server-port=s" => \$smtp_server_port,
 250                     "smtp-user=s" => \$smtp_authuser,
 251                     "smtp-pass:s" => \$smtp_authpass,
 252                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 253                     "smtp-encryption=s" => \$smtp_encryption,
 254                     "identity=s" => \$identity,
 255                     "annotate" => \$annotate,
 256                     "compose" => \$compose,
 257                     "quiet" => \$quiet,
 258                     "cc-cmd=s" => \$cc_cmd,
 259                     "suppress-from!" => \$suppress_from,
 260                     "suppress-cc=s" => \@suppress_cc,
 261                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 262                     "dry-run" => \$dry_run,
 263                     "envelope-sender=s" => \$envelope_sender,
 264                     "thread!" => \$thread,
 265                     "validate!" => \$validate,
 266                     "format-patch!" => \$format_patch,
 267          );
 268
 269 unless ($rc) {
 270     usage();
 271 }
 272
 273 die "Cannot run git format-patch from outside a repository\n"
 274         if $format_patch and not $repo;
 275
 276 # Now, let's fill any that aren't set in with defaults:
 277
 278 sub read_config {
 279         my ($prefix) = @_;
 280
 281         foreach my $setting (keys %config_bool_settings) {
 282                 my $target = $config_bool_settings{$setting}->[0];
 283                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 284         }
 285
 286         foreach my $setting (keys %config_settings) {
 287                 my $target = $config_settings{$setting};
 288                 if (ref($target) eq "ARRAY") {
 289                         unless (@$target) {
 290                                 my @values = Git::config(@repo, "$prefix.$setting");
 291                                 @$target = @values if (@values && defined $values[0]);
 292                         }
 293                 }
 294                 else {
 295                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 296                 }
 297         }
 298
 299         if (!defined $smtp_encryption) {
 300                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 301                 if (defined $enc) {
 302                         $smtp_encryption = $enc;
 303                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 304                         $smtp_encryption = 'ssl';
 305                 }
 306         }
 307 }
 308
 309 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 310 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 311 read_config("sendemail.$identity") if (defined $identity);
 312 read_config("sendemail");
 313
 314 # fall back on builtin bool defaults
 315 foreach my $setting (values %config_bool_settings) {
 316         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 317 }
 318
 319 # 'default' encryption is none -- this only prevents a warning
 320 $smtp_encryption = '' unless (defined $smtp_encryption);
 321
 322 # Set CC suppressions
 323 my(%suppress_cc);
 324 if (@suppress_cc) {
 325         foreach my $entry (@suppress_cc) {
 326                 die "Unknown --suppress-cc field: '$entry'\n"
 327                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 328                 $suppress_cc{$entry} = 1;
 329         }
 330 }
 331
 332 if ($suppress_cc{'all'}) {
 333         foreach my $entry (qw (ccmd cc author self sob)) {
 334                 $suppress_cc{$entry} = 1;
 335         }
 336         delete $suppress_cc{'all'};
 337 }
 338
 339 # If explicit old-style ones are specified, they trump --suppress-cc.
 340 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 341 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 342
 343 # Debugging, print out the suppressions.
 344 if (0) {
 345         print "suppressions:\n";
 346         foreach my $entry (keys %suppress_cc) {
 347                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 348         }
 349 }
 350
 351 my ($repoauthor, $repocommitter);
 352 ($repoauthor) = Git::ident_person(@repo, 'author');
 353 ($repocommitter) = Git::ident_person(@repo, 'committer');
 354
 355 # Verify the user input
 356
 357 foreach my $entry (@to) {
 358         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 359 }
 360
 361 foreach my $entry (@initial_cc) {
 362         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 363 }
 364
 365 foreach my $entry (@bcclist) {
 366         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 367 }
 368
 369 sub split_addrs {
 370         return quotewords('\s*,\s*', 1, @_);
 371 }
 372
 373 my %aliases;
 374 my %parse_alias = (
 375         # multiline formats can be supported in the future
 376         mutt => sub { my $fh = shift; while (<$fh>) {
 377                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 378                         my ($alias, $addr) = ($1, $2);
 379                         $addr =~ s/#.*$//; # mutt allows # comments
 380                          # commas delimit multiple addresses
 381                         $aliases{$alias} = [ split_addrs($addr) ];
 382                 }}},
 383         mailrc => sub { my $fh = shift; while (<$fh>) {
 384                 if (/^alias\s+(\S+)\s+(.*)$/) {
 385                         # spaces delimit multiple addresses
 386                         $aliases{$1} = [ split(/\s+/, $2) ];
 387                 }}},
 388         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 389                 for (my $x = ''; defined($x); $x = $_) {
 390                         chomp $x;
 391                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 392                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 393                         $aliases{$1} = [ split_addrs($2) ];
 394                 }},
 395         gnus => sub { my $fh = shift; while (<$fh>) {
 396                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 397                         $aliases{$1} = [ $2 ];
 398                 }}}
 399 );
 400
 401 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 402         foreach my $file (@alias_files) {
 403                 open my $fh, '<', $file or die "opening $file: $!\n";
 404                 $parse_alias{$aliasfiletype}->($fh);
 405                 close $fh;
 406         }
 407 }
 408
 409 ($sender) = expand_aliases($sender) if defined $sender;
 410
 411 # returns 1 if the conflict must be solved using it as a format-patch argument
 412 sub check_file_rev_conflict($) {
 413         return unless $repo;
 414         my $f = shift;
 415         try {
 416                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 417                 if (defined($format_patch)) {
 418                         print "foo\n";
 419                         return $format_patch;
 420                 }
 421                 die(<<EOF);
 422 File '$f' exists but it could also be the range of commits
 423 to produce patches for.  Please disambiguate by...
 424
 425     * Saying "./$f" if you mean a file; or
 426     * Giving --format-patch option if you mean a range.
 427 EOF
 428         } catch Git::Error::Command with {
 429                 return 0;
 430         }
 431 }
 432
 433 # Now that all the defaults are set, process the rest of the command line
 434 # arguments and collect up the files that need to be processed.
 435 my @rev_list_opts;
 436 while (defined(my $f = shift @ARGV)) {
 437         if ($f eq "--") {
 438                 push @rev_list_opts, "--", @ARGV;
 439                 @ARGV = ();
 440         } elsif (-d $f and !check_file_rev_conflict($f)) {
 441                 opendir(DH,$f)
 442                         or die "Failed to opendir $f: $!";
 443
 444                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 445                                 sort readdir(DH);
 446                 closedir(DH);
 447         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 448                 push @files, $f;
 449         } else {
 450                 push @rev_list_opts, $f;
 451         }
 452 }
 453
 454 if (@rev_list_opts) {
 455         die "Cannot run git format-patch from outside a repository\n"
 456                 unless $repo;
 457         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 458 }
 459
 460 if ($validate) {
 461         foreach my $f (@files) {
 462                 unless (-p $f) {
 463                         my $error = validate_patch($f);
 464                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 465                 }
 466         }
 467 }
 468
 469 if (@files) {
 470         unless ($quiet) {
 471                 print $_,"\n" for (@files);
 472         }
 473 } else {
 474         print STDERR "\nNo patch files specified!\n\n";
 475         usage();
 476 }
 477
 478 sub get_patch_subject($) {
 479         my $fn = shift;
 480         open (my $fh, '<', $fn);
 481         while (my $line = <$fh>) {
 482                 next unless ($line =~ /^Subject: (.*)$/);
 483                 close $fh;
 484                 return "GIT: $1\n";
 485         }
 486         close $fh;
 487         die "No subject line in $fn ?";
 488 }
 489
 490 if ($compose) {
 491         # Note that this does not need to be secure, but we will make a small
 492         # effort to have it be unique
 493         open(C,">",$compose_filename)
 494                 or die "Failed to open for writing $compose_filename: $!";
 495
 496
 497         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 498         my $tpl_subject = $initial_subject || '';
 499         my $tpl_reply_to = $initial_reply_to || '';
 500
 501         print C <<EOT;
 502 From $tpl_sender # This line is ignored.
 503 GIT: Lines beginning in "GIT: " will be removed.
 504 GIT: Consider including an overall diffstat or table of contents
 505 GIT: for the patch you are writing.
 506 GIT:
 507 GIT: Clear the body content if you don't wish to send a summary.
 508 From: $tpl_sender
 509 Subject: $tpl_subject
 510 In-Reply-To: $tpl_reply_to
 511
 512 EOT
 513         for my $f (@files) {
 514                 print C get_patch_subject($f);
 515         }
 516         close(C);
 517
 518         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 519
 520         if ($annotate) {
 521                 do_edit($compose_filename, @files);
 522         } else {
 523                 do_edit($compose_filename);
 524         }
 525
 526         open(C2,">",$compose_filename . ".final")
 527                 or die "Failed to open $compose_filename.final : " . $!;
 528
 529         open(C,"<",$compose_filename)
 530                 or die "Failed to open $compose_filename : " . $!;
 531
 532         my $need_8bit_cte = file_has_nonascii($compose_filename);
 533         my $in_body = 0;
 534         my $summary_empty = 1;
 535         while(<C>) {
 536                 next if m/^GIT: /;
 537                 if ($in_body) {
 538                         $summary_empty = 0 unless (/^\n$/);
 539                 } elsif (/^\n$/) {
 540                         $in_body = 1;
 541                         if ($need_8bit_cte) {
 542                                 print C2 "MIME-Version: 1.0\n",
 543                                          "Content-Type: text/plain; ",
 544                                            "charset=utf-8\n",
 545                                          "Content-Transfer-Encoding: 8bit\n";
 546                         }
 547                 } elsif (/^MIME-Version:/i) {
 548                         $need_8bit_cte = 0;
 549                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 550                         $initial_subject = $1;
 551                         my $subject = $initial_subject;
 552                         $_ = "Subject: " .
 553                                 ($subject =~ /[^[:ascii:]]/ ?
 554                                  quote_rfc2047($subject) :
 555                                  $subject) .
 556                                 "\n";
 557                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 558                         $initial_reply_to = $1;
 559                         next;
 560                 } elsif (/^From:\s*(.+)\s*$/i) {
 561                         $sender = $1;
 562                         next;
 563                 } elsif (/^(?:To|Cc|Bcc):/i) {
 564                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 565                         next;
 566                 }
 567                 print C2 $_;
 568         }
 569         close(C);
 570         close(C2);
 571
 572         if ($summary_empty) {
 573                 print "Summary email is empty, skipping it\n";
 574                 $compose = -1;
 575         }
 576 } elsif ($annotate) {
 577         do_edit(@files);
 578 }
 579
 580 my $prompting = 0;
 581 if (!defined $sender) {
 582         $sender = $repoauthor || $repocommitter || '';
 583
 584         while (1) {
 585                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 586                 last if defined $_;
 587                 print "\n";
 588         }
 589
 590         $sender = $_ if ($_);
 591         print "Emails will be sent from: ", $sender, "\n";
 592         $prompting++;
 593 }
 594
 595 if (!@to) {
 596
 597
 598         while (1) {
 599                 $_ = $term->readline("Who should the emails be sent to? ", "");
 600                 last if defined $_;
 601                 print "\n";
 602         }
 603
 604         my $to = $_;
 605         push @to, split_addrs($to);
 606         $prompting++;
 607 }
 608
 609 sub expand_aliases {
 610         my @cur = @_;
 611         my @last;
 612         do {
 613                 @last = @cur;
 614                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 615         } while (join(',',@cur) ne join(',',@last));
 616         return @cur;
 617 }
 618
 619 @to = expand_aliases(@to);
 620 @to = (map { sanitize_address($_) } @to);
 621 @initial_cc = expand_aliases(@initial_cc);
 622 @bcclist = expand_aliases(@bcclist);
 623
 624 if ($thread && !defined $initial_reply_to && $prompting) {
 625         while (1) {
 626                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 627                 last if defined $_;
 628                 print "\n";
 629         }
 630
 631         $initial_reply_to = $_;
 632 }
 633 if (defined $initial_reply_to) {
 634         $initial_reply_to =~ s/^\s*<?//;
 635         $initial_reply_to =~ s/>?\s*$//;
 636         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 637 }
 638
 639 if (!defined $smtp_server) {
 640         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 641                 if (-x $_) {
 642                         $smtp_server = $_;
 643                         last;
 644                 }
 645         }
 646         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 647 }
 648
 649 if ($compose) {
 650         while (1) {
 651                 $_ = $term->readline("Send this email? (y|n) ");
 652                 last if defined $_;
 653                 print "\n";
 654         }
 655
 656         if (uc substr($_,0,1) ne 'Y') {
 657                 cleanup_compose_files();
 658                 exit(0);
 659         }
 660
 661         if ($compose > 0) {
 662                 @files = ($compose_filename . ".final", @files);
 663         }
 664 }
 665
 666 # Variables we set as part of the loop over files
 667 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 668
 669 sub extract_valid_address {
 670         my $address = shift;
 671         my $local_part_regexp = '[^<>"\s@]+';
 672         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 673
 674         # check for a local address:
 675         return $address if ($address =~ /^($local_part_regexp)$/);
 676
 677         $address =~ s/^\s*<(.*)>\s*$/$1/;
 678         if ($have_email_valid) {
 679                 return scalar Email::Valid->address($address);
 680         } else {
 681                 # less robust/correct than the monster regexp in Email::Valid,
 682                 # but still does a 99% job, and one less dependency
 683                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 684                 return $1;
 685         }
 686 }
 687
 688 # Usually don't need to change anything below here.
 689
 690 # we make a "fake" message id by taking the current number
 691 # of seconds since the beginning of Unix time and tacking on
 692 # a random number to the end, in case we are called quicker than
 693 # 1 second since the last time we were called.
 694
 695 # We'll setup a template for the message id, using the "from" address:
 696
 697 my ($message_id_stamp, $message_id_serial);
 698 sub make_message_id
 699 {
 700         my $uniq;
 701         if (!defined $message_id_stamp) {
 702                 $message_id_stamp = sprintf("%s-%s", time, $$);
 703                 $message_id_serial = 0;
 704         }
 705         $message_id_serial++;
 706         $uniq = "$message_id_stamp-$message_id_serial";
 707
 708         my $du_part;
 709         for ($sender, $repocommitter, $repoauthor) {
 710                 $du_part = extract_valid_address(sanitize_address($_));
 711                 last if (defined $du_part and $du_part ne '');
 712         }
 713         if (not defined $du_part or $du_part eq '') {
 714                 use Sys::Hostname qw();
 715                 $du_part = 'user@' . Sys::Hostname::hostname();
 716         }
 717         my $message_id_template = "<%s-git-send-email-%s>";
 718         $message_id = sprintf($message_id_template, $uniq, $du_part);
 719         #print "new message id = $message_id\n"; # Was useful for debugging
 720 }
 721
 722
 723
 724 $time = time - scalar $#files;
 725
 726 sub unquote_rfc2047 {
 727         local ($_) = @_;
 728         my $encoding;
 729         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 730                 $encoding = $1;
 731                 s/_/ /g;
 732                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 733         }
 734         return wantarray ? ($_, $encoding) : $_;
 735 }
 736
 737 sub quote_rfc2047 {
 738         local $_ = shift;
 739         my $encoding = shift || 'utf-8';
 740         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 741         s/(.*)/=\?$encoding\?q\?$1\?=/;
 742         return $_;
 743 }
 744
 745 # use the simplest quoting being able to handle the recipient
 746 sub sanitize_address
 747 {
 748         my ($recipient) = @_;
 749         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 750
 751         if (not $recipient_name) {
 752                 return "$recipient";
 753         }
 754
 755         # if recipient_name is already quoted, do nothing
 756         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 757                 return $recipient;
 758         }
 759
 760         # rfc2047 is needed if a non-ascii char is included
 761         if ($recipient_name =~ /[^[:ascii:]]/) {
 762                 $recipient_name = quote_rfc2047($recipient_name);
 763         }
 764
 765         # double quotes are needed if specials or CTLs are included
 766         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 767                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 768                 $recipient_name = "\"$recipient_name\"";
 769         }
 770
 771         return "$recipient_name $recipient_addr";
 772
 773 }
 774
 775 sub send_message
 776 {
 777         my @recipients = unique_email_list(@to);
 778         @cc = (grep { my $cc = extract_valid_address($_);
 779                       not grep { $cc eq $_ } @recipients
 780                     }
 781                map { sanitize_address($_) }
 782                @cc);
 783         my $to = join (",\n\t", @recipients);
 784         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 785         @recipients = (map { extract_valid_address($_) } @recipients);
 786         my $date = format_2822_time($time++);
 787         my $gitversion = '@@GIT_VERSION@@';
 788         if ($gitversion =~ m/..GIT_VERSION../) {
 789             $gitversion = Git::version();
 790         }
 791
 792         my $cc = join(", ", unique_email_list(@cc));
 793         my $ccline = "";
 794         if ($cc ne '') {
 795                 $ccline = "\nCc: $cc";
 796         }
 797         my $sanitized_sender = sanitize_address($sender);
 798         make_message_id() unless defined($message_id);
 799
 800         my $header = "From: $sanitized_sender
 801 To: $to${ccline}
 802 Subject: $subject
 803 Date: $date
 804 Message-Id: $message_id
 805 X-Mailer: git-send-email $gitversion
 806 ";
 807         if ($thread && $reply_to) {
 808
 809                 $header .= "In-Reply-To: $reply_to\n";
 810                 $header .= "References: $references\n";
 811         }
 812         if (@xh) {
 813                 $header .= join("\n", @xh) . "\n";
 814         }
 815
 816         my @sendmail_parameters = ('-i', @recipients);
 817         my $raw_from = $sanitized_sender;
 818         $raw_from = $envelope_sender if (defined $envelope_sender);
 819         $raw_from = extract_valid_address($raw_from);
 820         unshift (@sendmail_parameters,
 821                         '-f', $raw_from) if(defined $envelope_sender);
 822
 823         if ($dry_run) {
 824                 # We don't want to send the email.
 825         } elsif ($smtp_server =~ m#^/#) {
 826                 my $pid = open my $sm, '|-';
 827                 defined $pid or die $!;
 828                 if (!$pid) {
 829                         exec($smtp_server, @sendmail_parameters) or die $!;
 830                 }
 831                 print $sm "$header\n$message";
 832                 close $sm or die $?;
 833         } else {
 834
 835                 if (!defined $smtp_server) {
 836                         die "The required SMTP server is not properly defined."
 837                 }
 838
 839                 if ($smtp_encryption eq 'ssl') {
 840                         $smtp_server_port ||= 465; # ssmtp
 841                         require Net::SMTP::SSL;
 842                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 843                 }
 844                 else {
 845                         require Net::SMTP;
 846                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 847                                                  ? "$smtp_server:$smtp_server_port"
 848                                                  : $smtp_server);
 849                         if ($smtp_encryption eq 'tls') {
 850                                 require Net::SMTP::SSL;
 851                                 $smtp->command('STARTTLS');
 852                                 $smtp->response();
 853                                 if ($smtp->code == 220) {
 854                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 855                                                 or die "STARTTLS failed! ".$smtp->message;
 856                                         $smtp_encryption = '';
 857                                         # Send EHLO again to receive fresh
 858                                         # supported commands
 859                                         $smtp->hello();
 860                                 } else {
 861                                         die "Server does not support STARTTLS! ".$smtp->message;
 862                                 }
 863                         }
 864                 }
 865
 866                 if (!$smtp) {
 867                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 868                 }
 869
 870                 if (defined $smtp_authuser) {
 871
 872                         if (!defined $smtp_authpass) {
 873
 874                                 system "stty -echo";
 875
 876                                 do {
 877                                         print "Password: ";
 878                                         $_ = <STDIN>;
 879                                         print "\n";
 880                                 } while (!defined $_);
 881
 882                                 chomp($smtp_authpass = $_);
 883
 884                                 system "stty echo";
 885                         }
 886
 887                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 888                 }
 889
 890                 $smtp->mail( $raw_from ) or die $smtp->message;
 891                 $smtp->to( @recipients ) or die $smtp->message;
 892                 $smtp->data or die $smtp->message;
 893                 $smtp->datasend("$header\n$message") or die $smtp->message;
 894                 $smtp->dataend() or die $smtp->message;
 895                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 896         }
 897         if ($quiet) {
 898                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 899         } else {
 900                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 901                 if ($smtp_server !~ m#^/#) {
 902                         print "Server: $smtp_server\n";
 903                         print "MAIL FROM:<$raw_from>\n";
 904                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 905                 } else {
 906                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 907                 }
 908                 print $header, "\n";
 909                 if ($smtp) {
 910                         print "Result: ", $smtp->code, ' ',
 911                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 912                 } else {
 913                         print "Result: OK\n";
 914                 }
 915         }
 916 }
 917
 918 $reply_to = $initial_reply_to;
 919 $references = $initial_reply_to || '';
 920 $subject = $initial_subject;
 921
 922 foreach my $t (@files) {
 923         open(F,"<",$t) or die "can't open file $t";
 924
 925         my $author = undef;
 926         my $author_encoding;
 927         my $has_content_type;
 928         my $body_encoding;
 929         @cc = @initial_cc;
 930         @xh = ();
 931         my $input_format = undef;
 932         my $header_done = 0;
 933         $message = "";
 934         while(<F>) {
 935                 if (!$header_done) {
 936                         if (/^From /) {
 937                                 $input_format = 'mbox';
 938                                 next;
 939                         }
 940                         chomp;
 941                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 942                                 $input_format = 'mbox';
 943                         }
 944
 945                         if (defined $input_format && $input_format eq 'mbox') {
 946                                 if (/^Subject:\s+(.*)$/) {
 947                                         $subject = $1;
 948
 949                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 950                                         if (unquote_rfc2047($2) eq $sender) {
 951                                                 next if ($suppress_cc{'self'});
 952                                         }
 953                                         elsif ($1 eq 'From') {
 954                                                 ($author, $author_encoding)
 955                                                   = unquote_rfc2047($2);
 956                                                 next if ($suppress_cc{'author'});
 957                                         } else {
 958                                                 next if ($suppress_cc{'cc'});
 959                                         }
 960                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 961                                                 $2, $_) unless $quiet;
 962                                         push @cc, $2;
 963                                 }
 964                                 elsif (/^Content-type:/i) {
 965                                         $has_content_type = 1;
 966                                         if (/charset="?([^ "]+)/) {
 967                                                 $body_encoding = $1;
 968                                         }
 969                                         push @xh, $_;
 970                                 }
 971                                 elsif (/^Message-Id: (.*)/i) {
 972                                         $message_id = $1;
 973                                 }
 974                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 975                                         push @xh, $_;
 976                                 }
 977
 978                         } else {
 979                                 # In the traditional
 980                                 # "send lots of email" format,
 981                                 # line 1 = cc
 982                                 # line 2 = subject
 983                                 # So let's support that, too.
 984                                 $input_format = 'lots';
 985                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 986                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 987                                                 $_, $_) unless $quiet;
 988
 989                                         push @cc, $_;
 990
 991                                 } elsif (!defined $subject) {
 992                                         $subject = $_;
 993                                 }
 994                         }
 995
 996                         # A whitespace line will terminate the headers
 997                         if (m/^\s*$/) {
 998                                 $header_done = 1;
 999                         }
1000                 } else {
1001                         $message .=  $_;
1002                         if (/^(Signed-off-by|Cc): (.*)$/i) {
1003                                 next if ($suppress_cc{'sob'});
1004                                 chomp;
1005                                 my $c = $2;
1006                                 chomp $c;
1007                                 next if ($c eq $sender and $suppress_cc{'self'});
1008                                 push @cc, $c;
1009                                 printf("(sob) Adding cc: %s from line '%s'\n",
1010                                         $c, $_) unless $quiet;
1011                         }
1012                 }
1013         }
1014         close F;
1015
1016         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1017                 open(F, "$cc_cmd $t |")
1018                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1019                 while(<F>) {
1020                         my $c = $_;
1021                         $c =~ s/^\s*//g;
1022                         $c =~ s/\n$//g;
1023                         next if ($c eq $sender and $suppress_from);
1024                         push @cc, $c;
1025                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1026                                 $c, $cc_cmd) unless $quiet;
1027                 }
1028                 close F
1029                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1030         }
1031
1032         if (defined $author) {
1033                 $message = "From: $author\n\n$message";
1034                 if (defined $author_encoding) {
1035                         if ($has_content_type) {
1036                                 if ($body_encoding eq $author_encoding) {
1037                                         # ok, we already have the right encoding
1038                                 }
1039                                 else {
1040                                         # uh oh, we should re-encode
1041                                 }
1042                         }
1043                         else {
1044                                 push @xh,
1045                                   'MIME-Version: 1.0',
1046                                   "Content-Type: text/plain; charset=$author_encoding",
1047                                   'Content-Transfer-Encoding: 8bit';
1048                         }
1049                 }
1050         }
1051
1052         send_message();
1053
1054         # set up for the next message
1055         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1056                 $reply_to = $message_id;
1057                 if (length $references > 0) {
1058                         $references .= "\n $message_id";
1059                 } else {
1060                         $references = "$message_id";
1061                 }
1062         }
1063         $message_id = undef;
1064 }
1065
1066 if ($compose) {
1067         cleanup_compose_files();
1068 }
1069
1070 sub cleanup_compose_files() {
1071         unlink($compose_filename, $compose_filename . ".final");
1072
1073 }
1074
1075 $smtp->quit if $smtp;
1076
1077 sub unique_email_list(@) {
1078         my %seen;
1079         my @emails;
1080
1081         foreach my $entry (@_) {
1082                 if (my $clean = extract_valid_address($entry)) {
1083                         $seen{$clean} ||= 0;
1084                         next if $seen{$clean}++;
1085                         push @emails, $entry;
1086                 } else {
1087                         print STDERR "W: unable to extract a valid address",
1088                                         " from: $entry\n";
1089                 }
1090         }
1091         return @emails;
1092 }
1093
1094 sub validate_patch {
1095         my $fn = shift;
1096         open(my $fh, '<', $fn)
1097                 or die "unable to open $fn: $!\n";
1098         while (my $line = <$fh>) {
1099                 if (length($line) > 998) {
1100                         return "$.: patch contains a line longer than 998 characters";
1101                 }
1102         }
1103         return undef;
1104 }
1105
1106 sub file_has_nonascii {
1107         my $fn = shift;
1108         open(my $fh, '<', $fn)
1109                 or die "unable to open $fn: $!\n";
1110         while (my $line = <$fh>) {
1111                 return 1 if $line =~ /[^[:ascii:]]/;
1112         }
1113         return 0;
1114 }