git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git-send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-ssl     If set, connects to the SMTP server using SSL.
  88
  89    --suppress-from Suppress sending emails to yourself. Defaults to off.
  90
  91    --thread       Specify that the "In-Reply-To:" header should be set on all
  92                   emails. Defaults to on.
  93
  94    --quiet        Make git-send-email less verbose.  One line per email
  95                   should be all that is output.
  96
  97    --dry-run      Do everything except actually send the emails.
  98
  99    --envelope-sender    Specify the envelope sender used to send the emails.
 100
 101    --no-validate        Don't perform any sanity checks on patches.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180 my ($no_validate);
 181
 182 my %config_bool_settings = (
 183     "thread" => [\$thread, 1],
 184     "chainreplyto" => [\$chain_reply_to, 1],
 185     "suppressfrom" => [\$suppress_from, 0],
 186     "signedoffcc" => [\$signed_off_cc, 1],
 187     "smtpssl" => [\$smtp_ssl, 0],
 188 );
 189
 190 my %config_settings = (
 191     "smtpserver" => \$smtp_server,
 192     "smtpserverport" => \$smtp_server_port,
 193     "smtpuser" => \$smtp_authuser,
 194     "smtppass" => \$smtp_authpass,
 195     "to" => \@to,
 196     "cccmd" => \$cc_cmd,
 197     "aliasfiletype" => \$aliasfiletype,
 198     "bcc" => \@bcclist,
 199     "aliasesfile" => \@alias_files,
 200 );
 201
 202 # Handle Uncouth Termination
 203 sub signal_handler {
 204
 205         # Make text normal
 206         print color("reset"), "\n";
 207
 208         # SMTP password masked
 209         system "stty echo";
 210
 211         # tmp files from --compose
 212         if (-e $compose_filename) {
 213                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 214         }
 215         if (-e ($compose_filename . ".final")) {
 216                 print "'$compose_filename.final' contains the composed email.\n"
 217         }
 218
 219         exit;
 220 };
 221
 222 $SIG{TERM} = \&signal_handler;
 223 $SIG{INT}  = \&signal_handler;
 224
 225 # Begin by accumulating all the variables (defined above), that we will end up
 226 # needing, first, from the command line:
 227
 228 my $rc = GetOptions("sender|from=s" => \$sender,
 229                     "in-reply-to=s" => \$initial_reply_to,
 230                     "subject=s" => \$initial_subject,
 231                     "to=s" => \@to,
 232                     "cc=s" => \@initial_cc,
 233                     "bcc=s" => \@bcclist,
 234                     "chain-reply-to!" => \$chain_reply_to,
 235                     "smtp-server=s" => \$smtp_server,
 236                     "smtp-server-port=s" => \$smtp_server_port,
 237                     "smtp-user=s" => \$smtp_authuser,
 238                     "smtp-pass:s" => \$smtp_authpass,
 239                     "smtp-ssl!" => \$smtp_ssl,
 240                     "identity=s" => \$identity,
 241                     "compose" => \$compose,
 242                     "quiet" => \$quiet,
 243                     "cc-cmd=s" => \$cc_cmd,
 244                     "suppress-from!" => \$suppress_from,
 245                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 246                     "dry-run" => \$dry_run,
 247                     "envelope-sender=s" => \$envelope_sender,
 248                     "thread!" => \$thread,
 249                     "no-validate" => \$no_validate,
 250          );
 251
 252 unless ($rc) {
 253     usage();
 254 }
 255
 256 # Now, let's fill any that aren't set in with defaults:
 257
 258 sub read_config {
 259         my ($prefix) = @_;
 260
 261         foreach my $setting (keys %config_bool_settings) {
 262                 my $target = $config_bool_settings{$setting}->[0];
 263                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 264         }
 265
 266         foreach my $setting (keys %config_settings) {
 267                 my $target = $config_settings{$setting};
 268                 if (ref($target) eq "ARRAY") {
 269                         unless (@$target) {
 270                                 my @values = $repo->config("$prefix.$setting");
 271                                 @$target = @values if (@values && defined $values[0]);
 272                         }
 273                 }
 274                 else {
 275                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 276                 }
 277         }
 278 }
 279
 280 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 281 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 282 read_config("sendemail.$identity") if (defined $identity);
 283 read_config("sendemail");
 284
 285 # fall back on builtin bool defaults
 286 foreach my $setting (values %config_bool_settings) {
 287         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 288 }
 289
 290 my ($repoauthor) = $repo->ident_person('author');
 291 my ($repocommitter) = $repo->ident_person('committer');
 292
 293 # Verify the user input
 294
 295 foreach my $entry (@to) {
 296         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 297 }
 298
 299 foreach my $entry (@initial_cc) {
 300         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 301 }
 302
 303 foreach my $entry (@bcclist) {
 304         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 305 }
 306
 307 my %aliases;
 308 my %parse_alias = (
 309         # multiline formats can be supported in the future
 310         mutt => sub { my $fh = shift; while (<$fh>) {
 311                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 312                         my ($alias, $addr) = ($1, $2);
 313                         $addr =~ s/#.*$//; # mutt allows # comments
 314                          # commas delimit multiple addresses
 315                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 316                 }}},
 317         mailrc => sub { my $fh = shift; while (<$fh>) {
 318                 if (/^alias\s+(\S+)\s+(.*)$/) {
 319                         # spaces delimit multiple addresses
 320                         $aliases{$1} = [ split(/\s+/, $2) ];
 321                 }}},
 322         pine => sub { my $fh = shift; while (<$fh>) {
 323                 if (/^(\S+)\t.*\t(.*)$/) {
 324                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 325                 }}},
 326         gnus => sub { my $fh = shift; while (<$fh>) {
 327                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 328                         $aliases{$1} = [ $2 ];
 329                 }}}
 330 );
 331
 332 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 333         foreach my $file (@alias_files) {
 334                 open my $fh, '<', $file or die "opening $file: $!\n";
 335                 $parse_alias{$aliasfiletype}->($fh);
 336                 close $fh;
 337         }
 338 }
 339
 340 ($sender) = expand_aliases($sender) if defined $sender;
 341
 342 # Now that all the defaults are set, process the rest of the command line
 343 # arguments and collect up the files that need to be processed.
 344 for my $f (@ARGV) {
 345         if (-d $f) {
 346                 opendir(DH,$f)
 347                         or die "Failed to opendir $f: $!";
 348
 349                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 350                                 sort readdir(DH);
 351
 352         } elsif (-f $f) {
 353                 push @files, $f;
 354
 355         } else {
 356                 print STDERR "Skipping $f - not found.\n";
 357         }
 358 }
 359
 360 if (!$no_validate) {
 361         foreach my $f (@files) {
 362                 my $error = validate_patch($f);
 363                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 364         }
 365 }
 366
 367 if (@files) {
 368         unless ($quiet) {
 369                 print $_,"\n" for (@files);
 370         }
 371 } else {
 372         print STDERR "\nNo patch files specified!\n\n";
 373         usage();
 374 }
 375
 376 my $prompting = 0;
 377 if (!defined $sender) {
 378         $sender = $repoauthor || $repocommitter;
 379
 380         while (1) {
 381                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 382                 last if defined $_;
 383                 print "\n";
 384         }
 385
 386         $sender = $_ if ($_);
 387         print "Emails will be sent from: ", $sender, "\n";
 388         $prompting++;
 389 }
 390
 391 if (!@to) {
 392
 393
 394         while (1) {
 395                 $_ = $term->readline("Who should the emails be sent to? ", "");
 396                 last if defined $_;
 397                 print "\n";
 398         }
 399
 400         my $to = $_;
 401         push @to, split /,/, $to;
 402         $prompting++;
 403 }
 404
 405 sub expand_aliases {
 406         my @cur = @_;
 407         my @last;
 408         do {
 409                 @last = @cur;
 410                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 411         } while (join(',',@cur) ne join(',',@last));
 412         return @cur;
 413 }
 414
 415 @to = expand_aliases(@to);
 416 @to = (map { sanitize_address($_) } @to);
 417 @initial_cc = expand_aliases(@initial_cc);
 418 @bcclist = expand_aliases(@bcclist);
 419
 420 if (!defined $initial_subject && $compose) {
 421         while (1) {
 422                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 423                 last if defined $_;
 424                 print "\n";
 425         }
 426
 427         $initial_subject = $_;
 428         $prompting++;
 429 }
 430
 431 if ($thread && !defined $initial_reply_to && $prompting) {
 432         while (1) {
 433                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 434                 last if defined $_;
 435                 print "\n";
 436         }
 437
 438         $initial_reply_to = $_;
 439 }
 440 if (defined $initial_reply_to && $_ ne "") {
 441         $initial_reply_to =~ s/^\s*<?/</;
 442         $initial_reply_to =~ s/>?\s*$/>/;
 443 }
 444
 445 if (!defined $smtp_server) {
 446         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 447                 if (-x $_) {
 448                         $smtp_server = $_;
 449                         last;
 450                 }
 451         }
 452         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 453 }
 454
 455 if ($compose) {
 456         # Note that this does not need to be secure, but we will make a small
 457         # effort to have it be unique
 458         open(C,">",$compose_filename)
 459                 or die "Failed to open for writing $compose_filename: $!";
 460         print C "From $sender # This line is ignored.\n";
 461         printf C "Subject: %s\n\n", $initial_subject;
 462         printf C <<EOT;
 463 GIT: Please enter your email below.
 464 GIT: Lines beginning in "GIT: " will be removed.
 465 GIT: Consider including an overall diffstat or table of contents
 466 GIT: for the patch you are writing.
 467
 468 EOT
 469         close(C);
 470
 471         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 472         system('sh', '-c', '$0 $@', $editor, $compose_filename);
 473
 474         open(C2,">",$compose_filename . ".final")
 475                 or die "Failed to open $compose_filename.final : " . $!;
 476
 477         open(C,"<",$compose_filename)
 478                 or die "Failed to open $compose_filename : " . $!;
 479
 480         while(<C>) {
 481                 next if m/^GIT: /;
 482                 print C2 $_;
 483         }
 484         close(C);
 485         close(C2);
 486
 487         while (1) {
 488                 $_ = $term->readline("Send this email? (y|n) ");
 489                 last if defined $_;
 490                 print "\n";
 491         }
 492
 493         if (uc substr($_,0,1) ne 'Y') {
 494                 cleanup_compose_files();
 495                 exit(0);
 496         }
 497
 498         @files = ($compose_filename . ".final", @files);
 499 }
 500
 501 # Variables we set as part of the loop over files
 502 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 503
 504 sub extract_valid_address {
 505         my $address = shift;
 506         my $local_part_regexp = '[^<>"\s@]+';
 507         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 508
 509         # check for a local address:
 510         return $address if ($address =~ /^($local_part_regexp)$/);
 511
 512         $address =~ s/^\s*<(.*)>\s*$/$1/;
 513         if ($have_email_valid) {
 514                 return scalar Email::Valid->address($address);
 515         } else {
 516                 # less robust/correct than the monster regexp in Email::Valid,
 517                 # but still does a 99% job, and one less dependency
 518                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 519                 return $1;
 520         }
 521 }
 522
 523 # Usually don't need to change anything below here.
 524
 525 # we make a "fake" message id by taking the current number
 526 # of seconds since the beginning of Unix time and tacking on
 527 # a random number to the end, in case we are called quicker than
 528 # 1 second since the last time we were called.
 529
 530 # We'll setup a template for the message id, using the "from" address:
 531
 532 my ($message_id_stamp, $message_id_serial);
 533 sub make_message_id
 534 {
 535         my $uniq;
 536         if (!defined $message_id_stamp) {
 537                 $message_id_stamp = sprintf("%s-%s", time, $$);
 538                 $message_id_serial = 0;
 539         }
 540         $message_id_serial++;
 541         $uniq = "$message_id_stamp-$message_id_serial";
 542
 543         my $du_part;
 544         for ($sender, $repocommitter, $repoauthor) {
 545                 $du_part = extract_valid_address(sanitize_address($_));
 546                 last if (defined $du_part and $du_part ne '');
 547         }
 548         if (not defined $du_part or $du_part eq '') {
 549                 use Sys::Hostname qw();
 550                 $du_part = 'user@' . Sys::Hostname::hostname();
 551         }
 552         my $message_id_template = "<%s-git-send-email-%s>";
 553         $message_id = sprintf($message_id_template, $uniq, $du_part);
 554         #print "new message id = $message_id\n"; # Was useful for debugging
 555 }
 556
 557
 558
 559 $time = time - scalar $#files;
 560
 561 sub unquote_rfc2047 {
 562         local ($_) = @_;
 563         my $encoding;
 564         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 565                 $encoding = $1;
 566                 s/_/ /g;
 567                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 568         }
 569         return wantarray ? ($_, $encoding) : $_;
 570 }
 571
 572 # use the simplest quoting being able to handle the recipient
 573 sub sanitize_address
 574 {
 575         my ($recipient) = @_;
 576         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 577
 578         if (not $recipient_name) {
 579                 return "$recipient";
 580         }
 581
 582         # if recipient_name is already quoted, do nothing
 583         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 584                 return $recipient;
 585         }
 586
 587         # rfc2047 is needed if a non-ascii char is included
 588         if ($recipient_name =~ /[^[:ascii:]]/) {
 589                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 590                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 591         }
 592
 593         # double quotes are needed if specials or CTLs are included
 594         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 595                 $recipient_name =~ s/(["\\\r])/\\$1/;
 596                 $recipient_name = "\"$recipient_name\"";
 597         }
 598
 599         return "$recipient_name $recipient_addr";
 600
 601 }
 602
 603 sub send_message
 604 {
 605         my @recipients = unique_email_list(@to);
 606         @cc = (grep { my $cc = extract_valid_address($_);
 607                       not grep { $cc eq $_ } @recipients
 608                     }
 609                map { sanitize_address($_) }
 610                @cc);
 611         my $to = join (",\n\t", @recipients);
 612         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 613         @recipients = (map { extract_valid_address($_) } @recipients);
 614         my $date = format_2822_time($time++);
 615         my $gitversion = '@@GIT_VERSION@@';
 616         if ($gitversion =~ m/..GIT_VERSION../) {
 617             $gitversion = Git::version();
 618         }
 619
 620         my $cc = join(", ", unique_email_list(@cc));
 621         my $ccline = "";
 622         if ($cc ne '') {
 623                 $ccline = "\nCc: $cc";
 624         }
 625         my $sanitized_sender = sanitize_address($sender);
 626         make_message_id() unless defined($message_id);
 627
 628         my $header = "From: $sanitized_sender
 629 To: $to${ccline}
 630 Subject: $subject
 631 Date: $date
 632 Message-Id: $message_id
 633 X-Mailer: git-send-email $gitversion
 634 ";
 635         if ($thread && $reply_to) {
 636
 637                 $header .= "In-Reply-To: $reply_to\n";
 638                 $header .= "References: $references\n";
 639         }
 640         if (@xh) {
 641                 $header .= join("\n", @xh) . "\n";
 642         }
 643
 644         my @sendmail_parameters = ('-i', @recipients);
 645         my $raw_from = $sanitized_sender;
 646         $raw_from = $envelope_sender if (defined $envelope_sender);
 647         $raw_from = extract_valid_address($raw_from);
 648         unshift (@sendmail_parameters,
 649                         '-f', $raw_from) if(defined $envelope_sender);
 650
 651         if ($dry_run) {
 652                 # We don't want to send the email.
 653         } elsif ($smtp_server =~ m#^/#) {
 654                 my $pid = open my $sm, '|-';
 655                 defined $pid or die $!;
 656                 if (!$pid) {
 657                         exec($smtp_server, @sendmail_parameters) or die $!;
 658                 }
 659                 print $sm "$header\n$message";
 660                 close $sm or die $?;
 661         } else {
 662
 663                 if (!defined $smtp_server) {
 664                         die "The required SMTP server is not properly defined."
 665                 }
 666
 667                 if ($smtp_ssl) {
 668                         $smtp_server_port ||= 465; # ssmtp
 669                         require Net::SMTP::SSL;
 670                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 671                 }
 672                 else {
 673                         require Net::SMTP;
 674                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 675                                                  ? "$smtp_server:$smtp_server_port"
 676                                                  : $smtp_server);
 677                 }
 678
 679                 if (!$smtp) {
 680                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 681                 }
 682
 683                 if (defined $smtp_authuser) {
 684
 685                         if (!defined $smtp_authpass) {
 686
 687                                 system "stty -echo";
 688
 689                                 do {
 690                                         print "Password: ";
 691                                         $_ = <STDIN>;
 692                                         print "\n";
 693                                 } while (!defined $_);
 694
 695                                 chomp($smtp_authpass = $_);
 696
 697                                 system "stty echo";
 698                         }
 699
 700                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 701                 }
 702
 703                 $smtp->mail( $raw_from ) or die $smtp->message;
 704                 $smtp->to( @recipients ) or die $smtp->message;
 705                 $smtp->data or die $smtp->message;
 706                 $smtp->datasend("$header\n$message") or die $smtp->message;
 707                 $smtp->dataend() or die $smtp->message;
 708                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 709         }
 710         if ($quiet) {
 711                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 712         } else {
 713                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 714                 if ($smtp_server !~ m#^/#) {
 715                         print "Server: $smtp_server\n";
 716                         print "MAIL FROM:<$raw_from>\n";
 717                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 718                 } else {
 719                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 720                 }
 721                 print $header, "\n";
 722                 if ($smtp) {
 723                         print "Result: ", $smtp->code, ' ',
 724                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 725                 } else {
 726                         print "Result: OK\n";
 727                 }
 728         }
 729 }
 730
 731 $reply_to = $initial_reply_to;
 732 $references = $initial_reply_to || '';
 733 $subject = $initial_subject;
 734
 735 foreach my $t (@files) {
 736         open(F,"<",$t) or die "can't open file $t";
 737
 738         my $author = undef;
 739         my $author_encoding;
 740         my $has_content_type;
 741         my $body_encoding;
 742         @cc = @initial_cc;
 743         @xh = ();
 744         my $input_format = undef;
 745         my $header_done = 0;
 746         $message = "";
 747         while(<F>) {
 748                 if (!$header_done) {
 749                         if (/^From /) {
 750                                 $input_format = 'mbox';
 751                                 next;
 752                         }
 753                         chomp;
 754                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 755                                 $input_format = 'mbox';
 756                         }
 757
 758                         if (defined $input_format && $input_format eq 'mbox') {
 759                                 if (/^Subject:\s+(.*)$/) {
 760                                         $subject = $1;
 761
 762                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 763                                         if (unquote_rfc2047($2) eq $sender) {
 764                                                 next if ($suppress_from);
 765                                         }
 766                                         elsif ($1 eq 'From') {
 767                                                 ($author, $author_encoding)
 768                                                   = unquote_rfc2047($2);
 769                                         }
 770                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 771                                                 $2, $_) unless $quiet;
 772                                         push @cc, $2;
 773                                 }
 774                                 elsif (/^Content-type:/i) {
 775                                         $has_content_type = 1;
 776                                         if (/charset="?[^ "]+/) {
 777                                                 $body_encoding = $1;
 778                                         }
 779                                         push @xh, $_;
 780                                 }
 781                                 elsif (/^Message-Id: (.*)/i) {
 782                                         $message_id = $1;
 783                                 }
 784                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 785                                         push @xh, $_;
 786                                 }
 787
 788                         } else {
 789                                 # In the traditional
 790                                 # "send lots of email" format,
 791                                 # line 1 = cc
 792                                 # line 2 = subject
 793                                 # So let's support that, too.
 794                                 $input_format = 'lots';
 795                                 if (@cc == 0) {
 796                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 797                                                 $_, $_) unless $quiet;
 798
 799                                         push @cc, $_;
 800
 801                                 } elsif (!defined $subject) {
 802                                         $subject = $_;
 803                                 }
 804                         }
 805
 806                         # A whitespace line will terminate the headers
 807                         if (m/^\s*$/) {
 808                                 $header_done = 1;
 809                         }
 810                 } else {
 811                         $message .=  $_;
 812                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 813                                 my $c = $2;
 814                                 chomp $c;
 815                                 next if ($c eq $sender and $suppress_from);
 816                                 push @cc, $c;
 817                                 printf("(sob) Adding cc: %s from line '%s'\n",
 818                                         $c, $_) unless $quiet;
 819                         }
 820                 }
 821         }
 822         close F;
 823
 824         if (defined $cc_cmd) {
 825                 open(F, "$cc_cmd $t |")
 826                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 827                 while(<F>) {
 828                         my $c = $_;
 829                         $c =~ s/^\s*//g;
 830                         $c =~ s/\n$//g;
 831                         next if ($c eq $sender and $suppress_from);
 832                         push @cc, $c;
 833                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 834                                 $c, $cc_cmd) unless $quiet;
 835                 }
 836                 close F
 837                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 838         }
 839
 840         if (defined $author) {
 841                 $message = "From: $author\n\n$message";
 842                 if (defined $author_encoding) {
 843                         if ($has_content_type) {
 844                                 if ($body_encoding eq $author_encoding) {
 845                                         # ok, we already have the right encoding
 846                                 }
 847                                 else {
 848                                         # uh oh, we should re-encode
 849                                 }
 850                         }
 851                         else {
 852                                 push @xh,
 853                                   'MIME-Version: 1.0',
 854                                   "Content-Type: text/plain; charset=$author_encoding",
 855                                   'Content-Transfer-Encoding: 8bit';
 856                         }
 857                 }
 858         }
 859
 860         send_message();
 861
 862         # set up for the next message
 863         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 864                 $reply_to = $message_id;
 865                 if (length $references > 0) {
 866                         $references .= "\n $message_id";
 867                 } else {
 868                         $references = "$message_id";
 869                 }
 870         }
 871         $message_id = undef;
 872 }
 873
 874 if ($compose) {
 875         cleanup_compose_files();
 876 }
 877
 878 sub cleanup_compose_files() {
 879         unlink($compose_filename, $compose_filename . ".final");
 880
 881 }
 882
 883 $smtp->quit if $smtp;
 884
 885 sub unique_email_list(@) {
 886         my %seen;
 887         my @emails;
 888
 889         foreach my $entry (@_) {
 890                 if (my $clean = extract_valid_address($entry)) {
 891                         $seen{$clean} ||= 0;
 892                         next if $seen{$clean}++;
 893                         push @emails, $entry;
 894                 } else {
 895                         print STDERR "W: unable to extract a valid address",
 896                                         " from: $entry\n";
 897                 }
 898         }
 899         return @emails;
 900 }
 901
 902 sub validate_patch {
 903         my $fn = shift;
 904         open(my $fh, '<', $fn)
 905                 or die "unable to open $fn: $!\n";
 906         while (my $line = <$fh>) {
 907                 if (length($line) > 998) {
 908                         return "$.: patch contains a line longer than 998 characters";
 909                 }
 910         }
 911         return undef;
 912 }