git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use File::Spec::Functions qw(catfile);
  28 use Error qw(:try);
  29 use Git;
  30
  31 Getopt::Long::Configure qw/ pass_through /;
  32
  33 package FakeTerm;
  34 sub new {
  35         my ($class, $reason) = @_;
  36         return bless \$reason, shift;
  37 }
  38 sub readline {
  39         my $self = shift;
  40         die "Cannot use readline on FakeTerm: $$self";
  41 }
  42 package main;
  43
  44
  45 sub usage {
  46         print <<EOT;
  47 git send-email [options] <file | directory | rev-list options >
  48
  49   Composing:
  50     --from                  <str>  * Email From:
  51     --[no-]to               <str>  * Email To:
  52     --[no-]cc               <str>  * Email Cc:
  53     --[no-]bcc              <str>  * Email Bcc:
  54     --subject               <str>  * Email "Subject:"
  55     --in-reply-to           <str>  * Email "In-Reply-To:"
  56     --annotate                     * Review each patch that will be sent in an editor.
  57     --compose                      * Open an editor for introduction.
  58     --8bit-encoding         <str>  * Encoding to assume 8bit mails if undeclared
  59
  60   Sending:
  61     --envelope-sender       <str>  * Email envelope sender.
  62     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  63                                      is optional. Default 'localhost'.
  64     --smtp-server-port      <int>  * Outgoing SMTP server port.
  65     --smtp-user             <str>  * Username for SMTP-AUTH.
  66     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  67     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  68     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  69     --smtp-domain           <str>  * The domain name sent to HELO/EHLO handshake
  70     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  71
  72   Automating:
  73     --identity              <str>  * Use the sendemail.<id> options.
  74     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  75     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  76     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  77     --[no-]suppress-from           * Send to self. Default off.
  78     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  79     --[no-]thread                  * Use In-Reply-To: field. Default on.
  80
  81   Administering:
  82     --confirm               <str>  * Confirm recipients before sending;
  83                                      auto, cc, compose, always, or never.
  84     --quiet                        * Output one line of info per email.
  85     --dry-run                      * Don't actually send the emails.
  86     --[no-]validate                * Perform patch sanity checks. Default on.
  87     --[no-]format-patch            * understand any non optional arguments as
  88                                      `git format-patch` ones.
  89
  90 EOT
  91         exit(1);
  92 }
  93
  94 # most mail servers generate the Date: header, but not all...
  95 sub format_2822_time {
  96         my ($time) = @_;
  97         my @localtm = localtime($time);
  98         my @gmttm = gmtime($time);
  99         my $localmin = $localtm[1] + $localtm[2] * 60;
 100         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 101         if ($localtm[0] != $gmttm[0]) {
 102                 die "local zone differs from GMT by a non-minute interval\n";
 103         }
 104         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 105                 $localmin += 1440;
 106         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 107                 $localmin -= 1440;
 108         } elsif ($gmttm[6] != $localtm[6]) {
 109                 die "local time offset greater than or equal to 24 hours\n";
 110         }
 111         my $offset = $localmin - $gmtmin;
 112         my $offhour = $offset / 60;
 113         my $offmin = abs($offset % 60);
 114         if (abs($offhour) >= 24) {
 115                 die ("local time offset greater than or equal to 24 hours\n");
 116         }
 117
 118         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 119                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 120                        $localtm[3],
 121                        qw(Jan Feb Mar Apr May Jun
 122                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 123                        $localtm[5]+1900,
 124                        $localtm[2],
 125                        $localtm[1],
 126                        $localtm[0],
 127                        ($offset >= 0) ? '+' : '-',
 128                        abs($offhour),
 129                        $offmin,
 130                        );
 131 }
 132
 133 my $have_email_valid = eval { require Email::Valid; 1 };
 134 my $have_mail_address = eval { require Mail::Address; 1 };
 135 my $smtp;
 136 my $auth;
 137
 138 sub unique_email_list(@);
 139 sub cleanup_compose_files();
 140
 141 # Variables we fill in automatically, or via prompting:
 142 my (@to,$no_to,@cc,$no_cc,@initial_cc,@bcclist,$no_bcc,@xh,
 143         $initial_reply_to,$initial_subject,@files,
 144         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 145
 146 my $envelope_sender;
 147
 148 # Example reply to:
 149 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 150
 151 my $repo = eval { Git->repository() };
 152 my @repo = $repo ? ($repo) : ();
 153 my $term = eval {
 154         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 155                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 156                 : new Term::ReadLine 'git-send-email';
 157 };
 158 if ($@) {
 159         $term = new FakeTerm "$@: going non-interactive";
 160 }
 161
 162 # Behavior modification variables
 163 my ($quiet, $dry_run) = (0, 0);
 164 my $format_patch;
 165 my $compose_filename;
 166
 167 # Handle interactive edition of files.
 168 my $multiedit;
 169 my $editor;
 170
 171 sub do_edit {
 172         if (!defined($editor)) {
 173                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 174         }
 175         if (defined($multiedit) && !$multiedit) {
 176                 map {
 177                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 178                         if (($? & 127) || ($? >> 8)) {
 179                                 die("the editor exited uncleanly, aborting everything");
 180                         }
 181                 } @_;
 182         } else {
 183                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 184                 if (($? & 127) || ($? >> 8)) {
 185                         die("the editor exited uncleanly, aborting everything");
 186                 }
 187         }
 188 }
 189
 190 # Variables with corresponding config settings
 191 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 192 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 193 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts, $smtp_domain);
 194 my ($validate, $confirm);
 195 my (@suppress_cc);
 196 my ($auto_8bit_encoding);
 197
 198 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 199
 200 my $not_set_by_user = "true but not set by the user";
 201
 202 my %config_bool_settings = (
 203     "thread" => [\$thread, 1],
 204     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 205     "suppressfrom" => [\$suppress_from, undef],
 206     "signedoffbycc" => [\$signed_off_by_cc, undef],
 207     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 208     "validate" => [\$validate, 1],
 209 );
 210
 211 my %config_settings = (
 212     "smtpserver" => \$smtp_server,
 213     "smtpserverport" => \$smtp_server_port,
 214     "smtpuser" => \$smtp_authuser,
 215     "smtppass" => \$smtp_authpass,
 216         "smtpdomain" => \$smtp_domain,
 217     "to" => \@to,
 218     "cc" => \@initial_cc,
 219     "cccmd" => \$cc_cmd,
 220     "aliasfiletype" => \$aliasfiletype,
 221     "bcc" => \@bcclist,
 222     "aliasesfile" => \@alias_files,
 223     "suppresscc" => \@suppress_cc,
 224     "envelopesender" => \$envelope_sender,
 225     "multiedit" => \$multiedit,
 226     "confirm"   => \$confirm,
 227     "from" => \$sender,
 228     "assume8bitencoding" => \$auto_8bit_encoding,
 229 );
 230
 231 # Help users prepare for 1.7.0
 232 sub chain_reply_to {
 233         if (defined $chain_reply_to &&
 234             $chain_reply_to eq $not_set_by_user) {
 235                 print STDERR
 236                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 237                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 238                     "you want to keep --chain-reply-to as your default.\n";
 239                 $chain_reply_to = 0;
 240         }
 241         return $chain_reply_to;
 242 }
 243
 244 # Handle Uncouth Termination
 245 sub signal_handler {
 246
 247         # Make text normal
 248         print color("reset"), "\n";
 249
 250         # SMTP password masked
 251         system "stty echo";
 252
 253         # tmp files from --compose
 254         if (defined $compose_filename) {
 255                 if (-e $compose_filename) {
 256                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 257                 }
 258                 if (-e ($compose_filename . ".final")) {
 259                         print "'$compose_filename.final' contains the composed email.\n"
 260                 }
 261         }
 262
 263         exit;
 264 };
 265
 266 $SIG{TERM} = \&signal_handler;
 267 $SIG{INT}  = \&signal_handler;
 268
 269 # Begin by accumulating all the variables (defined above), that we will end up
 270 # needing, first, from the command line:
 271
 272 my $rc = GetOptions("sender|from=s" => \$sender,
 273                     "in-reply-to=s" => \$initial_reply_to,
 274                     "subject=s" => \$initial_subject,
 275                     "to=s" => \@to,
 276                     "no-to" => \$no_to,
 277                     "cc=s" => \@initial_cc,
 278                     "no-cc" => \$no_cc,
 279                     "bcc=s" => \@bcclist,
 280                     "no-bcc" => \$no_bcc,
 281                     "chain-reply-to!" => \$chain_reply_to,
 282                     "smtp-server=s" => \$smtp_server,
 283                     "smtp-server-port=s" => \$smtp_server_port,
 284                     "smtp-user=s" => \$smtp_authuser,
 285                     "smtp-pass:s" => \$smtp_authpass,
 286                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 287                     "smtp-encryption=s" => \$smtp_encryption,
 288                     "smtp-debug:i" => \$debug_net_smtp,
 289                     "smtp-domain:s" => \$smtp_domain,
 290                     "identity=s" => \$identity,
 291                     "annotate" => \$annotate,
 292                     "compose" => \$compose,
 293                     "quiet" => \$quiet,
 294                     "cc-cmd=s" => \$cc_cmd,
 295                     "suppress-from!" => \$suppress_from,
 296                     "suppress-cc=s" => \@suppress_cc,
 297                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 298                     "confirm=s" => \$confirm,
 299                     "dry-run" => \$dry_run,
 300                     "envelope-sender=s" => \$envelope_sender,
 301                     "thread!" => \$thread,
 302                     "validate!" => \$validate,
 303                     "format-patch!" => \$format_patch,
 304                     "8bit-encoding=s" => \$auto_8bit_encoding,
 305          );
 306
 307 unless ($rc) {
 308     usage();
 309 }
 310
 311 die "Cannot run git format-patch from outside a repository\n"
 312         if $format_patch and not $repo;
 313
 314 # Now, let's fill any that aren't set in with defaults:
 315
 316 sub read_config {
 317         my ($prefix) = @_;
 318
 319         foreach my $setting (keys %config_bool_settings) {
 320                 my $target = $config_bool_settings{$setting}->[0];
 321                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 322         }
 323
 324         foreach my $setting (keys %config_settings) {
 325                 my $target = $config_settings{$setting};
 326                 next if $setting eq "to" and defined $no_to;
 327                 next if $setting eq "cc" and defined $no_cc;
 328                 next if $setting eq "bcc" and defined $no_bcc;
 329                 if (ref($target) eq "ARRAY") {
 330                         unless (@$target) {
 331                                 my @values = Git::config(@repo, "$prefix.$setting");
 332                                 @$target = @values if (@values && defined $values[0]);
 333                         }
 334                 }
 335                 else {
 336                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 337                 }
 338         }
 339
 340         if (!defined $smtp_encryption) {
 341                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 342                 if (defined $enc) {
 343                         $smtp_encryption = $enc;
 344                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 345                         $smtp_encryption = 'ssl';
 346                 }
 347         }
 348 }
 349
 350 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 351 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 352 read_config("sendemail.$identity") if (defined $identity);
 353 read_config("sendemail");
 354
 355 # fall back on builtin bool defaults
 356 foreach my $setting (values %config_bool_settings) {
 357         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 358 }
 359
 360 # 'default' encryption is none -- this only prevents a warning
 361 $smtp_encryption = '' unless (defined $smtp_encryption);
 362
 363 # Set CC suppressions
 364 my(%suppress_cc);
 365 if (@suppress_cc) {
 366         foreach my $entry (@suppress_cc) {
 367                 die "Unknown --suppress-cc field: '$entry'\n"
 368                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 369                 $suppress_cc{$entry} = 1;
 370         }
 371 }
 372
 373 if ($suppress_cc{'all'}) {
 374         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 375                 $suppress_cc{$entry} = 1;
 376         }
 377         delete $suppress_cc{'all'};
 378 }
 379
 380 # If explicit old-style ones are specified, they trump --suppress-cc.
 381 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 382 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 383
 384 if ($suppress_cc{'body'}) {
 385         foreach my $entry (qw (sob bodycc)) {
 386                 $suppress_cc{$entry} = 1;
 387         }
 388         delete $suppress_cc{'body'};
 389 }
 390
 391 # Set confirm's default value
 392 my $confirm_unconfigured = !defined $confirm;
 393 if ($confirm_unconfigured) {
 394         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 395 };
 396 die "Unknown --confirm setting: '$confirm'\n"
 397         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 398
 399 # Debugging, print out the suppressions.
 400 if (0) {
 401         print "suppressions:\n";
 402         foreach my $entry (keys %suppress_cc) {
 403                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 404         }
 405 }
 406
 407 my ($repoauthor, $repocommitter);
 408 ($repoauthor) = Git::ident_person(@repo, 'author');
 409 ($repocommitter) = Git::ident_person(@repo, 'committer');
 410
 411 # Verify the user input
 412
 413 foreach my $entry (@to) {
 414         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 415 }
 416
 417 foreach my $entry (@initial_cc) {
 418         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 419 }
 420
 421 foreach my $entry (@bcclist) {
 422         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 423 }
 424
 425 sub parse_address_line {
 426         if ($have_mail_address) {
 427                 return map { $_->format } Mail::Address->parse($_[0]);
 428         } else {
 429                 return split_addrs($_[0]);
 430         }
 431 }
 432
 433 sub split_addrs {
 434         return quotewords('\s*,\s*', 1, @_);
 435 }
 436
 437 my %aliases;
 438 my %parse_alias = (
 439         # multiline formats can be supported in the future
 440         mutt => sub { my $fh = shift; while (<$fh>) {
 441                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 442                         my ($alias, $addr) = ($1, $2);
 443                         $addr =~ s/#.*$//; # mutt allows # comments
 444                          # commas delimit multiple addresses
 445                         $aliases{$alias} = [ split_addrs($addr) ];
 446                 }}},
 447         mailrc => sub { my $fh = shift; while (<$fh>) {
 448                 if (/^alias\s+(\S+)\s+(.*)$/) {
 449                         # spaces delimit multiple addresses
 450                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 451                 }}},
 452         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 453                 for (my $x = ''; defined($x); $x = $_) {
 454                         chomp $x;
 455                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 456                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 457                         $aliases{$1} = [ split_addrs($2) ];
 458                 }},
 459         elm => sub  { my $fh = shift;
 460                       while (<$fh>) {
 461                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 462                               my ($alias, $addr) = ($1, $2);
 463                                $aliases{$alias} = [ split_addrs($addr) ];
 464                           }
 465                       } },
 466
 467         gnus => sub { my $fh = shift; while (<$fh>) {
 468                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 469                         $aliases{$1} = [ $2 ];
 470                 }}}
 471 );
 472
 473 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 474         foreach my $file (@alias_files) {
 475                 open my $fh, '<', $file or die "opening $file: $!\n";
 476                 $parse_alias{$aliasfiletype}->($fh);
 477                 close $fh;
 478         }
 479 }
 480
 481 ($sender) = expand_aliases($sender) if defined $sender;
 482
 483 # returns 1 if the conflict must be solved using it as a format-patch argument
 484 sub check_file_rev_conflict($) {
 485         return unless $repo;
 486         my $f = shift;
 487         try {
 488                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 489                 if (defined($format_patch)) {
 490                         return $format_patch;
 491                 }
 492                 die(<<EOF);
 493 File '$f' exists but it could also be the range of commits
 494 to produce patches for.  Please disambiguate by...
 495
 496     * Saying "./$f" if you mean a file; or
 497     * Giving --format-patch option if you mean a range.
 498 EOF
 499         } catch Git::Error::Command with {
 500                 return 0;
 501         }
 502 }
 503
 504 # Now that all the defaults are set, process the rest of the command line
 505 # arguments and collect up the files that need to be processed.
 506 my @rev_list_opts;
 507 while (defined(my $f = shift @ARGV)) {
 508         if ($f eq "--") {
 509                 push @rev_list_opts, "--", @ARGV;
 510                 @ARGV = ();
 511         } elsif (-d $f and !check_file_rev_conflict($f)) {
 512                 opendir(DH,$f)
 513                         or die "Failed to opendir $f: $!";
 514
 515                 push @files, grep { -f $_ } map { catfile($f, $_) }
 516                                 sort readdir(DH);
 517                 closedir(DH);
 518         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 519                 push @files, $f;
 520         } else {
 521                 push @rev_list_opts, $f;
 522         }
 523 }
 524
 525 if (@rev_list_opts) {
 526         die "Cannot run git format-patch from outside a repository\n"
 527                 unless $repo;
 528         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 529 }
 530
 531 if ($validate) {
 532         foreach my $f (@files) {
 533                 unless (-p $f) {
 534                         my $error = validate_patch($f);
 535                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 536                 }
 537         }
 538 }
 539
 540 if (@files) {
 541         unless ($quiet) {
 542                 print $_,"\n" for (@files);
 543         }
 544 } else {
 545         print STDERR "\nNo patch files specified!\n\n";
 546         usage();
 547 }
 548
 549 sub get_patch_subject($) {
 550         my $fn = shift;
 551         open (my $fh, '<', $fn);
 552         while (my $line = <$fh>) {
 553                 next unless ($line =~ /^Subject: (.*)$/);
 554                 close $fh;
 555                 return "GIT: $1\n";
 556         }
 557         close $fh;
 558         die "No subject line in $fn ?";
 559 }
 560
 561 if ($compose) {
 562         # Note that this does not need to be secure, but we will make a small
 563         # effort to have it be unique
 564         $compose_filename = ($repo ?
 565                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 566                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 567         open(C,">",$compose_filename)
 568                 or die "Failed to open for writing $compose_filename: $!";
 569
 570
 571         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 572         my $tpl_subject = $initial_subject || '';
 573         my $tpl_reply_to = $initial_reply_to || '';
 574
 575         print C <<EOT;
 576 From $tpl_sender # This line is ignored.
 577 GIT: Lines beginning in "GIT:" will be removed.
 578 GIT: Consider including an overall diffstat or table of contents
 579 GIT: for the patch you are writing.
 580 GIT:
 581 GIT: Clear the body content if you don't wish to send a summary.
 582 From: $tpl_sender
 583 Subject: $tpl_subject
 584 In-Reply-To: $tpl_reply_to
 585
 586 EOT
 587         for my $f (@files) {
 588                 print C get_patch_subject($f);
 589         }
 590         close(C);
 591
 592         if ($annotate) {
 593                 do_edit($compose_filename, @files);
 594         } else {
 595                 do_edit($compose_filename);
 596         }
 597
 598         open(C2,">",$compose_filename . ".final")
 599                 or die "Failed to open $compose_filename.final : " . $!;
 600
 601         open(C,"<",$compose_filename)
 602                 or die "Failed to open $compose_filename : " . $!;
 603
 604         my $need_8bit_cte = file_has_nonascii($compose_filename);
 605         my $in_body = 0;
 606         my $summary_empty = 1;
 607         while(<C>) {
 608                 next if m/^GIT:/;
 609                 if ($in_body) {
 610                         $summary_empty = 0 unless (/^\n$/);
 611                 } elsif (/^\n$/) {
 612                         $in_body = 1;
 613                         if ($need_8bit_cte) {
 614                                 print C2 "MIME-Version: 1.0\n",
 615                                          "Content-Type: text/plain; ",
 616                                            "charset=UTF-8\n",
 617                                          "Content-Transfer-Encoding: 8bit\n";
 618                         }
 619                 } elsif (/^MIME-Version:/i) {
 620                         $need_8bit_cte = 0;
 621                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 622                         $initial_subject = $1;
 623                         my $subject = $initial_subject;
 624                         $_ = "Subject: " .
 625                                 ($subject =~ /[^[:ascii:]]/ ?
 626                                  quote_rfc2047($subject) :
 627                                  $subject) .
 628                                 "\n";
 629                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 630                         $initial_reply_to = $1;
 631                         next;
 632                 } elsif (/^From:\s*(.+)\s*$/i) {
 633                         $sender = $1;
 634                         next;
 635                 } elsif (/^(?:To|Cc|Bcc):/i) {
 636                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 637                         next;
 638                 }
 639                 print C2 $_;
 640         }
 641         close(C);
 642         close(C2);
 643
 644         if ($summary_empty) {
 645                 print "Summary email is empty, skipping it\n";
 646                 $compose = -1;
 647         }
 648 } elsif ($annotate) {
 649         do_edit(@files);
 650 }
 651
 652 sub ask {
 653         my ($prompt, %arg) = @_;
 654         my $valid_re = $arg{valid_re};
 655         my $default = $arg{default};
 656         my $resp;
 657         my $i = 0;
 658         return defined $default ? $default : undef
 659                 unless defined $term->IN and defined fileno($term->IN) and
 660                        defined $term->OUT and defined fileno($term->OUT);
 661         while ($i++ < 10) {
 662                 $resp = $term->readline($prompt);
 663                 if (!defined $resp) { # EOF
 664                         print "\n";
 665                         return defined $default ? $default : undef;
 666                 }
 667                 if ($resp eq '' and defined $default) {
 668                         return $default;
 669                 }
 670                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 671                         return $resp;
 672                 }
 673         }
 674         return undef;
 675 }
 676
 677 my %broken_encoding;
 678
 679 sub file_declares_8bit_cte($) {
 680         my $fn = shift;
 681         open (my $fh, '<', $fn);
 682         while (my $line = <$fh>) {
 683                 last if ($line =~ /^$/);
 684                 return 1 if ($line =~ /^Content-Transfer-Encoding: .*8bit.*$/);
 685         }
 686         close $fh;
 687         return 0;
 688 }
 689
 690 foreach my $f (@files) {
 691         next unless (body_or_subject_has_nonascii($f)
 692                      && !file_declares_8bit_cte($f));
 693         $broken_encoding{$f} = 1;
 694 }
 695
 696 if (!defined $auto_8bit_encoding && scalar %broken_encoding) {
 697         print "The following files are 8bit, but do not declare " .
 698                 "a Content-Transfer-Encoding.\n";
 699         foreach my $f (sort keys %broken_encoding) {
 700                 print "    $f\n";
 701         }
 702         $auto_8bit_encoding = ask("Which 8bit encoding should I declare [UTF-8]? ",
 703                                   default => "UTF-8");
 704 }
 705
 706 my $prompting = 0;
 707 if (!defined $sender) {
 708         $sender = $repoauthor || $repocommitter || '';
 709         $sender = ask("Who should the emails appear to be from? [$sender] ",
 710                       default => $sender);
 711         print "Emails will be sent from: ", $sender, "\n";
 712         $prompting++;
 713 }
 714
 715 if (!@to) {
 716         my $to = ask("Who should the emails be sent to? ");
 717         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 718         $prompting++;
 719 }
 720
 721 sub expand_aliases {
 722         return map { expand_one_alias($_) } @_;
 723 }
 724
 725 my %EXPANDED_ALIASES;
 726 sub expand_one_alias {
 727         my $alias = shift;
 728         if ($EXPANDED_ALIASES{$alias}) {
 729                 die "fatal: alias '$alias' expands to itself\n";
 730         }
 731         local $EXPANDED_ALIASES{$alias} = 1;
 732         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 733 }
 734
 735 @to = expand_aliases(@to);
 736 @to = (map { sanitize_address($_) } @to);
 737 @initial_cc = expand_aliases(@initial_cc);
 738 @bcclist = expand_aliases(@bcclist);
 739
 740 if ($thread && !defined $initial_reply_to && $prompting) {
 741         $initial_reply_to = ask(
 742                 "Message-ID to be used as In-Reply-To for the first email? ");
 743 }
 744 if (defined $initial_reply_to) {
 745         $initial_reply_to =~ s/^\s*<?//;
 746         $initial_reply_to =~ s/>?\s*$//;
 747         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 748 }
 749
 750 if (!defined $smtp_server) {
 751         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 752                 if (-x $_) {
 753                         $smtp_server = $_;
 754                         last;
 755                 }
 756         }
 757         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 758 }
 759
 760 if ($compose && $compose > 0) {
 761         @files = ($compose_filename . ".final", @files);
 762 }
 763
 764 # Variables we set as part of the loop over files
 765 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 766         $needs_confirm, $message_num, $ask_default);
 767
 768 sub extract_valid_address {
 769         my $address = shift;
 770         my $local_part_regexp = '[^<>"\s@]+';
 771         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 772
 773         # check for a local address:
 774         return $address if ($address =~ /^($local_part_regexp)$/);
 775
 776         $address =~ s/^\s*<(.*)>\s*$/$1/;
 777         if ($have_email_valid) {
 778                 return scalar Email::Valid->address($address);
 779         } else {
 780                 # less robust/correct than the monster regexp in Email::Valid,
 781                 # but still does a 99% job, and one less dependency
 782                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 783                 return $1;
 784         }
 785 }
 786
 787 # Usually don't need to change anything below here.
 788
 789 # we make a "fake" message id by taking the current number
 790 # of seconds since the beginning of Unix time and tacking on
 791 # a random number to the end, in case we are called quicker than
 792 # 1 second since the last time we were called.
 793
 794 # We'll setup a template for the message id, using the "from" address:
 795
 796 my ($message_id_stamp, $message_id_serial);
 797 sub make_message_id {
 798         my $uniq;
 799         if (!defined $message_id_stamp) {
 800                 $message_id_stamp = sprintf("%s-%s", time, $$);
 801                 $message_id_serial = 0;
 802         }
 803         $message_id_serial++;
 804         $uniq = "$message_id_stamp-$message_id_serial";
 805
 806         my $du_part;
 807         for ($sender, $repocommitter, $repoauthor) {
 808                 $du_part = extract_valid_address(sanitize_address($_));
 809                 last if (defined $du_part and $du_part ne '');
 810         }
 811         if (not defined $du_part or $du_part eq '') {
 812                 use Sys::Hostname qw();
 813                 $du_part = 'user@' . Sys::Hostname::hostname();
 814         }
 815         my $message_id_template = "<%s-git-send-email-%s>";
 816         $message_id = sprintf($message_id_template, $uniq, $du_part);
 817         #print "new message id = $message_id\n"; # Was useful for debugging
 818 }
 819
 820
 821
 822 $time = time - scalar $#files;
 823
 824 sub unquote_rfc2047 {
 825         local ($_) = @_;
 826         my $encoding;
 827         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 828                 $encoding = $1;
 829                 s/_/ /g;
 830                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 831         }
 832         return wantarray ? ($_, $encoding) : $_;
 833 }
 834
 835 sub quote_rfc2047 {
 836         local $_ = shift;
 837         my $encoding = shift || 'UTF-8';
 838         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 839         s/(.*)/=\?$encoding\?q\?$1\?=/;
 840         return $_;
 841 }
 842
 843 sub is_rfc2047_quoted {
 844         my $s = shift;
 845         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 846         my $encoded_text = '[!->@-~]+';
 847         length($s) <= 75 &&
 848         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 849 }
 850
 851 # use the simplest quoting being able to handle the recipient
 852 sub sanitize_address {
 853         my ($recipient) = @_;
 854         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 855
 856         if (not $recipient_name) {
 857                 return "$recipient";
 858         }
 859
 860         # if recipient_name is already quoted, do nothing
 861         if (is_rfc2047_quoted($recipient_name)) {
 862                 return $recipient;
 863         }
 864
 865         # rfc2047 is needed if a non-ascii char is included
 866         if ($recipient_name =~ /[^[:ascii:]]/) {
 867                 $recipient_name =~ s/^"(.*)"$/$1/;
 868                 $recipient_name = quote_rfc2047($recipient_name);
 869         }
 870
 871         # double quotes are needed if specials or CTLs are included
 872         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 873                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 874                 $recipient_name = "\"$recipient_name\"";
 875         }
 876
 877         return "$recipient_name $recipient_addr";
 878
 879 }
 880
 881 # Returns the local Fully Qualified Domain Name (FQDN) if available.
 882 #
 883 # Tightly configured MTAa require that a caller sends a real DNS
 884 # domain name that corresponds the IP address in the HELO/EHLO
 885 # handshake. This is used to verify the connection and prevent
 886 # spammers from trying to hide their identity. If the DNS and IP don't
 887 # match, the receiveing MTA may deny the connection.
 888 #
 889 # Here is a deny example of Net::SMTP with the default "localhost.localdomain"
 890 #
 891 # Net::SMTP=GLOB(0x267ec28)>>> EHLO localhost.localdomain
 892 # Net::SMTP=GLOB(0x267ec28)<<< 550 EHLO argument does not match calling host
 893 #
 894 # This maildomain*() code is based on ideas in Perl library Test::Reporter
 895 # /usr/share/perl5/Test/Reporter/Mail/Util.pm ==> sub _maildomain ()
 896
 897 sub valid_fqdn {
 898         my $domain = shift;
 899         return !($^O eq 'darwin' && $domain =~ /\.local$/) && $domain =~ /\./;
 900 }
 901
 902 sub maildomain_net {
 903         my $maildomain;
 904
 905         if (eval { require Net::Domain; 1 }) {
 906                 my $domain = Net::Domain::domainname();
 907                 $maildomain = $domain if valid_fqdn($domain);
 908         }
 909
 910         return $maildomain;
 911 }
 912
 913 sub maildomain_mta {
 914         my $maildomain;
 915
 916         if (eval { require Net::SMTP; 1 }) {
 917                 for my $host (qw(mailhost localhost)) {
 918                         my $smtp = Net::SMTP->new($host);
 919                         if (defined $smtp) {
 920                                 my $domain = $smtp->domain;
 921                                 $smtp->quit;
 922
 923                                 $maildomain = $domain if valid_fqdn($domain);
 924
 925                                 last if $maildomain;
 926                         }
 927                 }
 928         }
 929
 930         return $maildomain;
 931 }
 932
 933 sub maildomain {
 934         return maildomain_net() || maildomain_mta() || 'localhost.localdomain';
 935 }
 936
 937 # Returns 1 if the message was sent, and 0 otherwise.
 938 # In actuality, the whole program dies when there
 939 # is an error sending a message.
 940
 941 sub send_message {
 942         my @recipients = unique_email_list(@to);
 943         @cc = (grep { my $cc = extract_valid_address($_);
 944                       not grep { $cc eq $_ } @recipients
 945                     }
 946                map { sanitize_address($_) }
 947                @cc);
 948         my $to = join (",\n\t", @recipients);
 949         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 950         @recipients = (map { extract_valid_address($_) } @recipients);
 951         my $date = format_2822_time($time++);
 952         my $gitversion = '@@GIT_VERSION@@';
 953         if ($gitversion =~ m/..GIT_VERSION../) {
 954             $gitversion = Git::version();
 955         }
 956
 957         my $cc = join(",\n\t", unique_email_list(@cc));
 958         my $ccline = "";
 959         if ($cc ne '') {
 960                 $ccline = "\nCc: $cc";
 961         }
 962         my $sanitized_sender = sanitize_address($sender);
 963         make_message_id() unless defined($message_id);
 964
 965         my $header = "From: $sanitized_sender
 966 To: $to${ccline}
 967 Subject: $subject
 968 Date: $date
 969 Message-Id: $message_id
 970 X-Mailer: git-send-email $gitversion
 971 ";
 972         if ($reply_to) {
 973
 974                 $header .= "In-Reply-To: $reply_to\n";
 975                 $header .= "References: $references\n";
 976         }
 977         if (@xh) {
 978                 $header .= join("\n", @xh) . "\n";
 979         }
 980
 981         my @sendmail_parameters = ('-i', @recipients);
 982         my $raw_from = $sanitized_sender;
 983         if (defined $envelope_sender && $envelope_sender ne "auto") {
 984                 $raw_from = $envelope_sender;
 985         }
 986         $raw_from = extract_valid_address($raw_from);
 987         unshift (@sendmail_parameters,
 988                         '-f', $raw_from) if(defined $envelope_sender);
 989
 990         if ($needs_confirm && !$dry_run) {
 991                 print "\n$header\n";
 992                 if ($needs_confirm eq "inform") {
 993                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 994                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 995                         print "    The Cc list above has been expanded by additional\n";
 996                         print "    addresses found in the patch commit message. By default\n";
 997                         print "    send-email prompts before sending whenever this occurs.\n";
 998                         print "    This behavior is controlled by the sendemail.confirm\n";
 999                         print "    configuration setting.\n";
1000                         print "\n";
1001                         print "    For additional information, run 'git send-email --help'.\n";
1002                         print "    To retain the current behavior, but squelch this message,\n";
1003                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
1004                 }
1005                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
1006                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
1007                          default => $ask_default);
1008                 die "Send this email reply required" unless defined $_;
1009                 if (/^n/i) {
1010                         return 0;
1011                 } elsif (/^q/i) {
1012                         cleanup_compose_files();
1013                         exit(0);
1014                 } elsif (/^a/i) {
1015                         $confirm = 'never';
1016                 }
1017         }
1018
1019         if ($dry_run) {
1020                 # We don't want to send the email.
1021         } elsif ($smtp_server =~ m#^/#) {
1022                 my $pid = open my $sm, '|-';
1023                 defined $pid or die $!;
1024                 if (!$pid) {
1025                         exec($smtp_server, @sendmail_parameters) or die $!;
1026                 }
1027                 print $sm "$header\n$message";
1028                 close $sm or die $?;
1029         } else {
1030
1031                 if (!defined $smtp_server) {
1032                         die "The required SMTP server is not properly defined."
1033                 }
1034
1035                 if ($smtp_encryption eq 'ssl') {
1036                         $smtp_server_port ||= 465; # ssmtp
1037                         require Net::SMTP::SSL;
1038                         $smtp_domain ||= maildomain();
1039                         $smtp ||= Net::SMTP::SSL->new($smtp_server,
1040                                                       Hello => $smtp_domain,
1041                                                       Port => $smtp_server_port);
1042                 }
1043                 else {
1044                         require Net::SMTP;
1045                         $smtp_domain ||= maildomain();
1046                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
1047                                                  ? "$smtp_server:$smtp_server_port"
1048                                                  : $smtp_server,
1049                                                  Hello => $smtp_domain,
1050                                                  Debug => $debug_net_smtp);
1051                         if ($smtp_encryption eq 'tls' && $smtp) {
1052                                 require Net::SMTP::SSL;
1053                                 $smtp->command('STARTTLS');
1054                                 $smtp->response();
1055                                 if ($smtp->code == 220) {
1056                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
1057                                                 or die "STARTTLS failed! ".$smtp->message;
1058                                         $smtp_encryption = '';
1059                                         # Send EHLO again to receive fresh
1060                                         # supported commands
1061                                         $smtp->hello();
1062                                 } else {
1063                                         die "Server does not support STARTTLS! ".$smtp->message;
1064                                 }
1065                         }
1066                 }
1067
1068                 if (!$smtp) {
1069                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
1070                             "VALUES: server=$smtp_server ",
1071                             "encryption=$smtp_encryption ",
1072                             "hello=$smtp_domain",
1073                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
1074                 }
1075
1076                 if (defined $smtp_authuser) {
1077
1078                         if (!defined $smtp_authpass) {
1079
1080                                 system "stty -echo";
1081
1082                                 do {
1083                                         print "Password: ";
1084                                         $_ = <STDIN>;
1085                                         print "\n";
1086                                 } while (!defined $_);
1087
1088                                 chomp($smtp_authpass = $_);
1089
1090                                 system "stty echo";
1091                         }
1092
1093                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
1094                 }
1095
1096                 $smtp->mail( $raw_from ) or die $smtp->message;
1097                 $smtp->to( @recipients ) or die $smtp->message;
1098                 $smtp->data or die $smtp->message;
1099                 $smtp->datasend("$header\n$message") or die $smtp->message;
1100                 $smtp->dataend() or die $smtp->message;
1101                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
1102         }
1103         if ($quiet) {
1104                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1105         } else {
1106                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1107                 if ($smtp_server !~ m#^/#) {
1108                         print "Server: $smtp_server\n";
1109                         print "MAIL FROM:<$raw_from>\n";
1110                         foreach my $entry (@recipients) {
1111                             print "RCPT TO:<$entry>\n";
1112                         }
1113                 } else {
1114                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1115                 }
1116                 print $header, "\n";
1117                 if ($smtp) {
1118                         print "Result: ", $smtp->code, ' ',
1119                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1120                 } else {
1121                         print "Result: OK\n";
1122                 }
1123         }
1124
1125         return 1;
1126 }
1127
1128 $reply_to = $initial_reply_to;
1129 $references = $initial_reply_to || '';
1130 $subject = $initial_subject;
1131 $message_num = 0;
1132
1133 foreach my $t (@files) {
1134         open(F,"<",$t) or die "can't open file $t";
1135
1136         my $author = undef;
1137         my $author_encoding;
1138         my $has_content_type;
1139         my $body_encoding;
1140         @cc = ();
1141         @xh = ();
1142         my $input_format = undef;
1143         my @header = ();
1144         $message = "";
1145         $message_num++;
1146         # First unfold multiline header fields
1147         while(<F>) {
1148                 last if /^\s*$/;
1149                 if (/^\s+\S/ and @header) {
1150                         chomp($header[$#header]);
1151                         s/^\s+/ /;
1152                         $header[$#header] .= $_;
1153             } else {
1154                         push(@header, $_);
1155                 }
1156         }
1157         # Now parse the header
1158         foreach(@header) {
1159                 if (/^From /) {
1160                         $input_format = 'mbox';
1161                         next;
1162                 }
1163                 chomp;
1164                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1165                         $input_format = 'mbox';
1166                 }
1167
1168                 if (defined $input_format && $input_format eq 'mbox') {
1169                         if (/^Subject:\s+(.*)$/) {
1170                                 $subject = $1;
1171                         }
1172                         elsif (/^From:\s+(.*)$/) {
1173                                 ($author, $author_encoding) = unquote_rfc2047($1);
1174                                 next if $suppress_cc{'author'};
1175                                 next if $suppress_cc{'self'} and $author eq $sender;
1176                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1177                                         $1, $_) unless $quiet;
1178                                 push @cc, $1;
1179                         }
1180                         elsif (/^Cc:\s+(.*)$/) {
1181                                 foreach my $addr (parse_address_line($1)) {
1182                                         if (unquote_rfc2047($addr) eq $sender) {
1183                                                 next if ($suppress_cc{'self'});
1184                                         } else {
1185                                                 next if ($suppress_cc{'cc'});
1186                                         }
1187                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1188                                                 $addr, $_) unless $quiet;
1189                                         push @cc, $addr;
1190                                 }
1191                         }
1192                         elsif (/^Content-type:/i) {
1193                                 $has_content_type = 1;
1194                                 if (/charset="?([^ "]+)/) {
1195                                         $body_encoding = $1;
1196                                 }
1197                                 push @xh, $_;
1198                         }
1199                         elsif (/^Message-Id: (.*)/i) {
1200                                 $message_id = $1;
1201                         }
1202                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1203                                 push @xh, $_;
1204                         }
1205
1206                 } else {
1207                         # In the traditional
1208                         # "send lots of email" format,
1209                         # line 1 = cc
1210                         # line 2 = subject
1211                         # So let's support that, too.
1212                         $input_format = 'lots';
1213                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1214                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1215                                         $_, $_) unless $quiet;
1216                                 push @cc, $_;
1217                         } elsif (!defined $subject) {
1218                                 $subject = $_;
1219                         }
1220                 }
1221         }
1222         # Now parse the message body
1223         while(<F>) {
1224                 $message .=  $_;
1225                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1226                         chomp;
1227                         my ($what, $c) = ($1, $2);
1228                         chomp $c;
1229                         if ($c eq $sender) {
1230                                 next if ($suppress_cc{'self'});
1231                         } else {
1232                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1233                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1234                         }
1235                         push @cc, $c;
1236                         printf("(body) Adding cc: %s from line '%s'\n",
1237                                 $c, $_) unless $quiet;
1238                 }
1239         }
1240         close F;
1241
1242         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1243                 open(F, "$cc_cmd \Q$t\E |")
1244                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1245                 while(<F>) {
1246                         my $c = $_;
1247                         $c =~ s/^\s*//g;
1248                         $c =~ s/\n$//g;
1249                         next if ($c eq $sender and $suppress_from);
1250                         push @cc, $c;
1251                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1252                                 $c, $cc_cmd) unless $quiet;
1253                 }
1254                 close F
1255                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1256         }
1257
1258         if ($broken_encoding{$t} && !$has_content_type) {
1259                 $has_content_type = 1;
1260                 push @xh, "MIME-Version: 1.0",
1261                         "Content-Type: text/plain; charset=$auto_8bit_encoding",
1262                         "Content-Transfer-Encoding: 8bit";
1263                 $body_encoding = $auto_8bit_encoding;
1264         }
1265
1266         if ($broken_encoding{$t} && !is_rfc2047_quoted($subject)) {
1267                 $subject = quote_rfc2047($subject, $auto_8bit_encoding);
1268         }
1269
1270         if (defined $author and $author ne $sender) {
1271                 $message = "From: $author\n\n$message";
1272                 if (defined $author_encoding) {
1273                         if ($has_content_type) {
1274                                 if ($body_encoding eq $author_encoding) {
1275                                         # ok, we already have the right encoding
1276                                 }
1277                                 else {
1278                                         # uh oh, we should re-encode
1279                                 }
1280                         }
1281                         else {
1282                                 $has_content_type = 1;
1283                                 push @xh,
1284                                   'MIME-Version: 1.0',
1285                                   "Content-Type: text/plain; charset=$author_encoding",
1286                                   'Content-Transfer-Encoding: 8bit';
1287                         }
1288                 }
1289         }
1290
1291         $needs_confirm = (
1292                 $confirm eq "always" or
1293                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1294                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1295         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1296
1297         @cc = (@initial_cc, @cc);
1298
1299         my $message_was_sent = send_message();
1300
1301         # set up for the next message
1302         if ($thread && $message_was_sent &&
1303                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1304                 $reply_to = $message_id;
1305                 if (length $references > 0) {
1306                         $references .= "\n $message_id";
1307                 } else {
1308                         $references = "$message_id";
1309                 }
1310         }
1311         $message_id = undef;
1312 }
1313
1314 cleanup_compose_files();
1315
1316 sub cleanup_compose_files() {
1317         unlink($compose_filename, $compose_filename . ".final") if $compose;
1318 }
1319
1320 $smtp->quit if $smtp;
1321
1322 sub unique_email_list(@) {
1323         my %seen;
1324         my @emails;
1325
1326         foreach my $entry (@_) {
1327                 if (my $clean = extract_valid_address($entry)) {
1328                         $seen{$clean} ||= 0;
1329                         next if $seen{$clean}++;
1330                         push @emails, $entry;
1331                 } else {
1332                         print STDERR "W: unable to extract a valid address",
1333                                         " from: $entry\n";
1334                 }
1335         }
1336         return @emails;
1337 }
1338
1339 sub validate_patch {
1340         my $fn = shift;
1341         open(my $fh, '<', $fn)
1342                 or die "unable to open $fn: $!\n";
1343         while (my $line = <$fh>) {
1344                 if (length($line) > 998) {
1345                         return "$.: patch contains a line longer than 998 characters";
1346                 }
1347         }
1348         return undef;
1349 }
1350
1351 sub file_has_nonascii {
1352         my $fn = shift;
1353         open(my $fh, '<', $fn)
1354                 or die "unable to open $fn: $!\n";
1355         while (my $line = <$fh>) {
1356                 return 1 if $line =~ /[^[:ascii:]]/;
1357         }
1358         return 0;
1359 }
1360
1361 sub body_or_subject_has_nonascii {
1362         my $fn = shift;
1363         open(my $fh, '<', $fn)
1364                 or die "unable to open $fn: $!\n";
1365         while (my $line = <$fh>) {
1366                 last if $line =~ /^$/;
1367                 return 1 if $line =~ /^Subject.*[^[:ascii:]]/;
1368         }
1369         while (my $line = <$fh>) {
1370                 return 1 if $line =~ /[^[:ascii:]]/;
1371         }
1372         return 0;
1373 }