git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = Git::command_oneline('var', 'GIT_EDITOR');
 166
 167 sub do_edit {
 168         if (defined($multiedit) && !$multiedit) {
 169                 map {
 170                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 171                         if (($? & 127) || ($? >> 8)) {
 172                                 die("the editor exited uncleanly, aborting everything");
 173                         }
 174                 } @_;
 175         } else {
 176                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 177                 if (($? & 127) || ($? >> 8)) {
 178                         die("the editor exited uncleanly, aborting everything");
 179                 }
 180         }
 181 }
 182
 183 # Variables with corresponding config settings
 184 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 185 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 186 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 187 my ($validate, $confirm);
 188 my (@suppress_cc);
 189
 190 my $not_set_by_user = "true but not set by the user";
 191
 192 my %config_bool_settings = (
 193     "thread" => [\$thread, 1],
 194     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 195     "suppressfrom" => [\$suppress_from, undef],
 196     "signedoffbycc" => [\$signed_off_by_cc, undef],
 197     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 198     "validate" => [\$validate, 1],
 199 );
 200
 201 my %config_settings = (
 202     "smtpserver" => \$smtp_server,
 203     "smtpserverport" => \$smtp_server_port,
 204     "smtpuser" => \$smtp_authuser,
 205     "smtppass" => \$smtp_authpass,
 206     "to" => \@to,
 207     "cc" => \@initial_cc,
 208     "cccmd" => \$cc_cmd,
 209     "aliasfiletype" => \$aliasfiletype,
 210     "bcc" => \@bcclist,
 211     "aliasesfile" => \@alias_files,
 212     "suppresscc" => \@suppress_cc,
 213     "envelopesender" => \$envelope_sender,
 214     "multiedit" => \$multiedit,
 215     "confirm"   => \$confirm,
 216     "from" => \$sender,
 217 );
 218
 219 # Help users prepare for 1.7.0
 220 sub chain_reply_to {
 221         if (defined $chain_reply_to &&
 222             $chain_reply_to eq $not_set_by_user) {
 223                 print STDERR
 224                     "In git 1.7.0, the default will be changed to --no-chain-reply-to\n" .
 225                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 226                     "you want to keep --chain-reply-to as your default.\n";
 227                 $chain_reply_to = 1;
 228         }
 229         return $chain_reply_to;
 230 }
 231
 232 # Handle Uncouth Termination
 233 sub signal_handler {
 234
 235         # Make text normal
 236         print color("reset"), "\n";
 237
 238         # SMTP password masked
 239         system "stty echo";
 240
 241         # tmp files from --compose
 242         if (defined $compose_filename) {
 243                 if (-e $compose_filename) {
 244                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 245                 }
 246                 if (-e ($compose_filename . ".final")) {
 247                         print "'$compose_filename.final' contains the composed email.\n"
 248                 }
 249         }
 250
 251         exit;
 252 };
 253
 254 $SIG{TERM} = \&signal_handler;
 255 $SIG{INT}  = \&signal_handler;
 256
 257 # Begin by accumulating all the variables (defined above), that we will end up
 258 # needing, first, from the command line:
 259
 260 my $rc = GetOptions("sender|from=s" => \$sender,
 261                     "in-reply-to=s" => \$initial_reply_to,
 262                     "subject=s" => \$initial_subject,
 263                     "to=s" => \@to,
 264                     "cc=s" => \@initial_cc,
 265                     "bcc=s" => \@bcclist,
 266                     "chain-reply-to!" => \$chain_reply_to,
 267                     "smtp-server=s" => \$smtp_server,
 268                     "smtp-server-port=s" => \$smtp_server_port,
 269                     "smtp-user=s" => \$smtp_authuser,
 270                     "smtp-pass:s" => \$smtp_authpass,
 271                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 272                     "smtp-encryption=s" => \$smtp_encryption,
 273                     "identity=s" => \$identity,
 274                     "annotate" => \$annotate,
 275                     "compose" => \$compose,
 276                     "quiet" => \$quiet,
 277                     "cc-cmd=s" => \$cc_cmd,
 278                     "suppress-from!" => \$suppress_from,
 279                     "suppress-cc=s" => \@suppress_cc,
 280                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 281                     "confirm=s" => \$confirm,
 282                     "dry-run" => \$dry_run,
 283                     "envelope-sender=s" => \$envelope_sender,
 284                     "thread!" => \$thread,
 285                     "validate!" => \$validate,
 286                     "format-patch!" => \$format_patch,
 287          );
 288
 289 unless ($rc) {
 290     usage();
 291 }
 292
 293 die "Cannot run git format-patch from outside a repository\n"
 294         if $format_patch and not $repo;
 295
 296 # Now, let's fill any that aren't set in with defaults:
 297
 298 sub read_config {
 299         my ($prefix) = @_;
 300
 301         foreach my $setting (keys %config_bool_settings) {
 302                 my $target = $config_bool_settings{$setting}->[0];
 303                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 304         }
 305
 306         foreach my $setting (keys %config_settings) {
 307                 my $target = $config_settings{$setting};
 308                 if (ref($target) eq "ARRAY") {
 309                         unless (@$target) {
 310                                 my @values = Git::config(@repo, "$prefix.$setting");
 311                                 @$target = @values if (@values && defined $values[0]);
 312                         }
 313                 }
 314                 else {
 315                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 316                 }
 317         }
 318
 319         if (!defined $smtp_encryption) {
 320                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 321                 if (defined $enc) {
 322                         $smtp_encryption = $enc;
 323                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 324                         $smtp_encryption = 'ssl';
 325                 }
 326         }
 327 }
 328
 329 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 330 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 331 read_config("sendemail.$identity") if (defined $identity);
 332 read_config("sendemail");
 333
 334 # fall back on builtin bool defaults
 335 foreach my $setting (values %config_bool_settings) {
 336         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 337 }
 338
 339 # 'default' encryption is none -- this only prevents a warning
 340 $smtp_encryption = '' unless (defined $smtp_encryption);
 341
 342 # Set CC suppressions
 343 my(%suppress_cc);
 344 if (@suppress_cc) {
 345         foreach my $entry (@suppress_cc) {
 346                 die "Unknown --suppress-cc field: '$entry'\n"
 347                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 348                 $suppress_cc{$entry} = 1;
 349         }
 350 }
 351
 352 if ($suppress_cc{'all'}) {
 353         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 354                 $suppress_cc{$entry} = 1;
 355         }
 356         delete $suppress_cc{'all'};
 357 }
 358
 359 # If explicit old-style ones are specified, they trump --suppress-cc.
 360 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 361 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 362
 363 if ($suppress_cc{'body'}) {
 364         foreach my $entry (qw (sob bodycc)) {
 365                 $suppress_cc{$entry} = 1;
 366         }
 367         delete $suppress_cc{'body'};
 368 }
 369
 370 # Set confirm's default value
 371 my $confirm_unconfigured = !defined $confirm;
 372 if ($confirm_unconfigured) {
 373         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 374 };
 375 die "Unknown --confirm setting: '$confirm'\n"
 376         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 377
 378 # Debugging, print out the suppressions.
 379 if (0) {
 380         print "suppressions:\n";
 381         foreach my $entry (keys %suppress_cc) {
 382                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 383         }
 384 }
 385
 386 my ($repoauthor, $repocommitter);
 387 ($repoauthor) = Git::ident_person(@repo, 'author');
 388 ($repocommitter) = Git::ident_person(@repo, 'committer');
 389
 390 # Verify the user input
 391
 392 foreach my $entry (@to) {
 393         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 394 }
 395
 396 foreach my $entry (@initial_cc) {
 397         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 398 }
 399
 400 foreach my $entry (@bcclist) {
 401         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 402 }
 403
 404 sub parse_address_line {
 405         if ($have_mail_address) {
 406                 return map { $_->format } Mail::Address->parse($_[0]);
 407         } else {
 408                 return split_addrs($_[0]);
 409         }
 410 }
 411
 412 sub split_addrs {
 413         return quotewords('\s*,\s*', 1, @_);
 414 }
 415
 416 my %aliases;
 417 my %parse_alias = (
 418         # multiline formats can be supported in the future
 419         mutt => sub { my $fh = shift; while (<$fh>) {
 420                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 421                         my ($alias, $addr) = ($1, $2);
 422                         $addr =~ s/#.*$//; # mutt allows # comments
 423                          # commas delimit multiple addresses
 424                         $aliases{$alias} = [ split_addrs($addr) ];
 425                 }}},
 426         mailrc => sub { my $fh = shift; while (<$fh>) {
 427                 if (/^alias\s+(\S+)\s+(.*)$/) {
 428                         # spaces delimit multiple addresses
 429                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 430                 }}},
 431         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 432                 for (my $x = ''; defined($x); $x = $_) {
 433                         chomp $x;
 434                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 435                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 436                         $aliases{$1} = [ split_addrs($2) ];
 437                 }},
 438         elm => sub  { my $fh = shift;
 439                       while (<$fh>) {
 440                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 441                               my ($alias, $addr) = ($1, $2);
 442                                $aliases{$alias} = [ split_addrs($addr) ];
 443                           }
 444                       } },
 445
 446         gnus => sub { my $fh = shift; while (<$fh>) {
 447                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 448                         $aliases{$1} = [ $2 ];
 449                 }}}
 450 );
 451
 452 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 453         foreach my $file (@alias_files) {
 454                 open my $fh, '<', $file or die "opening $file: $!\n";
 455                 $parse_alias{$aliasfiletype}->($fh);
 456                 close $fh;
 457         }
 458 }
 459
 460 ($sender) = expand_aliases($sender) if defined $sender;
 461
 462 # returns 1 if the conflict must be solved using it as a format-patch argument
 463 sub check_file_rev_conflict($) {
 464         return unless $repo;
 465         my $f = shift;
 466         try {
 467                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 468                 if (defined($format_patch)) {
 469                         return $format_patch;
 470                 }
 471                 die(<<EOF);
 472 File '$f' exists but it could also be the range of commits
 473 to produce patches for.  Please disambiguate by...
 474
 475     * Saying "./$f" if you mean a file; or
 476     * Giving --format-patch option if you mean a range.
 477 EOF
 478         } catch Git::Error::Command with {
 479                 return 0;
 480         }
 481 }
 482
 483 # Now that all the defaults are set, process the rest of the command line
 484 # arguments and collect up the files that need to be processed.
 485 my @rev_list_opts;
 486 while (defined(my $f = shift @ARGV)) {
 487         if ($f eq "--") {
 488                 push @rev_list_opts, "--", @ARGV;
 489                 @ARGV = ();
 490         } elsif (-d $f and !check_file_rev_conflict($f)) {
 491                 opendir(DH,$f)
 492                         or die "Failed to opendir $f: $!";
 493
 494                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 495                                 sort readdir(DH);
 496                 closedir(DH);
 497         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 498                 push @files, $f;
 499         } else {
 500                 push @rev_list_opts, $f;
 501         }
 502 }
 503
 504 if (@rev_list_opts) {
 505         die "Cannot run git format-patch from outside a repository\n"
 506                 unless $repo;
 507         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 508 }
 509
 510 if ($validate) {
 511         foreach my $f (@files) {
 512                 unless (-p $f) {
 513                         my $error = validate_patch($f);
 514                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 515                 }
 516         }
 517 }
 518
 519 if (@files) {
 520         unless ($quiet) {
 521                 print $_,"\n" for (@files);
 522         }
 523 } else {
 524         print STDERR "\nNo patch files specified!\n\n";
 525         usage();
 526 }
 527
 528 sub get_patch_subject($) {
 529         my $fn = shift;
 530         open (my $fh, '<', $fn);
 531         while (my $line = <$fh>) {
 532                 next unless ($line =~ /^Subject: (.*)$/);
 533                 close $fh;
 534                 return "GIT: $1\n";
 535         }
 536         close $fh;
 537         die "No subject line in $fn ?";
 538 }
 539
 540 if ($compose) {
 541         # Note that this does not need to be secure, but we will make a small
 542         # effort to have it be unique
 543         $compose_filename = ($repo ?
 544                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 545                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 546         open(C,">",$compose_filename)
 547                 or die "Failed to open for writing $compose_filename: $!";
 548
 549
 550         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 551         my $tpl_subject = $initial_subject || '';
 552         my $tpl_reply_to = $initial_reply_to || '';
 553
 554         print C <<EOT;
 555 From $tpl_sender # This line is ignored.
 556 GIT: Lines beginning in "GIT:" will be removed.
 557 GIT: Consider including an overall diffstat or table of contents
 558 GIT: for the patch you are writing.
 559 GIT:
 560 GIT: Clear the body content if you don't wish to send a summary.
 561 From: $tpl_sender
 562 Subject: $tpl_subject
 563 In-Reply-To: $tpl_reply_to
 564
 565 EOT
 566         for my $f (@files) {
 567                 print C get_patch_subject($f);
 568         }
 569         close(C);
 570
 571         if ($annotate) {
 572                 do_edit($compose_filename, @files);
 573         } else {
 574                 do_edit($compose_filename);
 575         }
 576
 577         open(C2,">",$compose_filename . ".final")
 578                 or die "Failed to open $compose_filename.final : " . $!;
 579
 580         open(C,"<",$compose_filename)
 581                 or die "Failed to open $compose_filename : " . $!;
 582
 583         my $need_8bit_cte = file_has_nonascii($compose_filename);
 584         my $in_body = 0;
 585         my $summary_empty = 1;
 586         while(<C>) {
 587                 next if m/^GIT:/;
 588                 if ($in_body) {
 589                         $summary_empty = 0 unless (/^\n$/);
 590                 } elsif (/^\n$/) {
 591                         $in_body = 1;
 592                         if ($need_8bit_cte) {
 593                                 print C2 "MIME-Version: 1.0\n",
 594                                          "Content-Type: text/plain; ",
 595                                            "charset=UTF-8\n",
 596                                          "Content-Transfer-Encoding: 8bit\n";
 597                         }
 598                 } elsif (/^MIME-Version:/i) {
 599                         $need_8bit_cte = 0;
 600                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 601                         $initial_subject = $1;
 602                         my $subject = $initial_subject;
 603                         $_ = "Subject: " .
 604                                 ($subject =~ /[^[:ascii:]]/ ?
 605                                  quote_rfc2047($subject) :
 606                                  $subject) .
 607                                 "\n";
 608                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 609                         $initial_reply_to = $1;
 610                         next;
 611                 } elsif (/^From:\s*(.+)\s*$/i) {
 612                         $sender = $1;
 613                         next;
 614                 } elsif (/^(?:To|Cc|Bcc):/i) {
 615                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 616                         next;
 617                 }
 618                 print C2 $_;
 619         }
 620         close(C);
 621         close(C2);
 622
 623         if ($summary_empty) {
 624                 print "Summary email is empty, skipping it\n";
 625                 $compose = -1;
 626         }
 627 } elsif ($annotate) {
 628         do_edit(@files);
 629 }
 630
 631 sub ask {
 632         my ($prompt, %arg) = @_;
 633         my $valid_re = $arg{valid_re};
 634         my $default = $arg{default};
 635         my $resp;
 636         my $i = 0;
 637         return defined $default ? $default : undef
 638                 unless defined $term->IN and defined fileno($term->IN) and
 639                        defined $term->OUT and defined fileno($term->OUT);
 640         while ($i++ < 10) {
 641                 $resp = $term->readline($prompt);
 642                 if (!defined $resp) { # EOF
 643                         print "\n";
 644                         return defined $default ? $default : undef;
 645                 }
 646                 if ($resp eq '' and defined $default) {
 647                         return $default;
 648                 }
 649                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 650                         return $resp;
 651                 }
 652         }
 653         return undef;
 654 }
 655
 656 my $prompting = 0;
 657 if (!defined $sender) {
 658         $sender = $repoauthor || $repocommitter || '';
 659         $sender = ask("Who should the emails appear to be from? [$sender] ",
 660                       default => $sender);
 661         print "Emails will be sent from: ", $sender, "\n";
 662         $prompting++;
 663 }
 664
 665 if (!@to) {
 666         my $to = ask("Who should the emails be sent to? ");
 667         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 668         $prompting++;
 669 }
 670
 671 sub expand_aliases {
 672         return map { expand_one_alias($_) } @_;
 673 }
 674
 675 my %EXPANDED_ALIASES;
 676 sub expand_one_alias {
 677         my $alias = shift;
 678         if ($EXPANDED_ALIASES{$alias}) {
 679                 die "fatal: alias '$alias' expands to itself\n";
 680         }
 681         local $EXPANDED_ALIASES{$alias} = 1;
 682         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 683 }
 684
 685 @to = expand_aliases(@to);
 686 @to = (map { sanitize_address($_) } @to);
 687 @initial_cc = expand_aliases(@initial_cc);
 688 @bcclist = expand_aliases(@bcclist);
 689
 690 if ($thread && !defined $initial_reply_to && $prompting) {
 691         $initial_reply_to = ask(
 692                 "Message-ID to be used as In-Reply-To for the first email? ");
 693 }
 694 if (defined $initial_reply_to) {
 695         $initial_reply_to =~ s/^\s*<?//;
 696         $initial_reply_to =~ s/>?\s*$//;
 697         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 698 }
 699
 700 if (!defined $smtp_server) {
 701         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 702                 if (-x $_) {
 703                         $smtp_server = $_;
 704                         last;
 705                 }
 706         }
 707         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 708 }
 709
 710 if ($compose && $compose > 0) {
 711         @files = ($compose_filename . ".final", @files);
 712 }
 713
 714 # Variables we set as part of the loop over files
 715 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 716         $needs_confirm, $message_num, $ask_default);
 717
 718 sub extract_valid_address {
 719         my $address = shift;
 720         my $local_part_regexp = '[^<>"\s@]+';
 721         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 722
 723         # check for a local address:
 724         return $address if ($address =~ /^($local_part_regexp)$/);
 725
 726         $address =~ s/^\s*<(.*)>\s*$/$1/;
 727         if ($have_email_valid) {
 728                 return scalar Email::Valid->address($address);
 729         } else {
 730                 # less robust/correct than the monster regexp in Email::Valid,
 731                 # but still does a 99% job, and one less dependency
 732                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 733                 return $1;
 734         }
 735 }
 736
 737 # Usually don't need to change anything below here.
 738
 739 # we make a "fake" message id by taking the current number
 740 # of seconds since the beginning of Unix time and tacking on
 741 # a random number to the end, in case we are called quicker than
 742 # 1 second since the last time we were called.
 743
 744 # We'll setup a template for the message id, using the "from" address:
 745
 746 my ($message_id_stamp, $message_id_serial);
 747 sub make_message_id
 748 {
 749         my $uniq;
 750         if (!defined $message_id_stamp) {
 751                 $message_id_stamp = sprintf("%s-%s", time, $$);
 752                 $message_id_serial = 0;
 753         }
 754         $message_id_serial++;
 755         $uniq = "$message_id_stamp-$message_id_serial";
 756
 757         my $du_part;
 758         for ($sender, $repocommitter, $repoauthor) {
 759                 $du_part = extract_valid_address(sanitize_address($_));
 760                 last if (defined $du_part and $du_part ne '');
 761         }
 762         if (not defined $du_part or $du_part eq '') {
 763                 use Sys::Hostname qw();
 764                 $du_part = 'user@' . Sys::Hostname::hostname();
 765         }
 766         my $message_id_template = "<%s-git-send-email-%s>";
 767         $message_id = sprintf($message_id_template, $uniq, $du_part);
 768         #print "new message id = $message_id\n"; # Was useful for debugging
 769 }
 770
 771
 772
 773 $time = time - scalar $#files;
 774
 775 sub unquote_rfc2047 {
 776         local ($_) = @_;
 777         my $encoding;
 778         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 779                 $encoding = $1;
 780                 s/_/ /g;
 781                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 782         }
 783         return wantarray ? ($_, $encoding) : $_;
 784 }
 785
 786 sub quote_rfc2047 {
 787         local $_ = shift;
 788         my $encoding = shift || 'UTF-8';
 789         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 790         s/(.*)/=\?$encoding\?q\?$1\?=/;
 791         return $_;
 792 }
 793
 794 sub is_rfc2047_quoted {
 795         my $s = shift;
 796         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 797         my $encoded_text = '[!->@-~]+';
 798         length($s) <= 75 &&
 799         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 800 }
 801
 802 # use the simplest quoting being able to handle the recipient
 803 sub sanitize_address
 804 {
 805         my ($recipient) = @_;
 806         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 807
 808         if (not $recipient_name) {
 809                 return "$recipient";
 810         }
 811
 812         # if recipient_name is already quoted, do nothing
 813         if (is_rfc2047_quoted($recipient_name)) {
 814                 return $recipient;
 815         }
 816
 817         # rfc2047 is needed if a non-ascii char is included
 818         if ($recipient_name =~ /[^[:ascii:]]/) {
 819                 $recipient_name =~ s/^"(.*)"$/$1/;
 820                 $recipient_name = quote_rfc2047($recipient_name);
 821         }
 822
 823         # double quotes are needed if specials or CTLs are included
 824         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 825                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 826                 $recipient_name = "\"$recipient_name\"";
 827         }
 828
 829         return "$recipient_name $recipient_addr";
 830
 831 }
 832
 833 # Returns 1 if the message was sent, and 0 otherwise.
 834 # In actuality, the whole program dies when there
 835 # is an error sending a message.
 836
 837 sub send_message
 838 {
 839         my @recipients = unique_email_list(@to);
 840         @cc = (grep { my $cc = extract_valid_address($_);
 841                       not grep { $cc eq $_ } @recipients
 842                     }
 843                map { sanitize_address($_) }
 844                @cc);
 845         my $to = join (",\n\t", @recipients);
 846         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 847         @recipients = (map { extract_valid_address($_) } @recipients);
 848         my $date = format_2822_time($time++);
 849         my $gitversion = '@@GIT_VERSION@@';
 850         if ($gitversion =~ m/..GIT_VERSION../) {
 851             $gitversion = Git::version();
 852         }
 853
 854         my $cc = join(",\n\t", unique_email_list(@cc));
 855         my $ccline = "";
 856         if ($cc ne '') {
 857                 $ccline = "\nCc: $cc";
 858         }
 859         my $sanitized_sender = sanitize_address($sender);
 860         make_message_id() unless defined($message_id);
 861
 862         my $header = "From: $sanitized_sender
 863 To: $to${ccline}
 864 Subject: $subject
 865 Date: $date
 866 Message-Id: $message_id
 867 X-Mailer: git-send-email $gitversion
 868 ";
 869         if ($reply_to) {
 870
 871                 $header .= "In-Reply-To: $reply_to\n";
 872                 $header .= "References: $references\n";
 873         }
 874         if (@xh) {
 875                 $header .= join("\n", @xh) . "\n";
 876         }
 877
 878         my @sendmail_parameters = ('-i', @recipients);
 879         my $raw_from = $sanitized_sender;
 880         if (defined $envelope_sender && $envelope_sender ne "auto") {
 881                 $raw_from = $envelope_sender;
 882         }
 883         $raw_from = extract_valid_address($raw_from);
 884         unshift (@sendmail_parameters,
 885                         '-f', $raw_from) if(defined $envelope_sender);
 886
 887         if ($needs_confirm && !$dry_run) {
 888                 print "\n$header\n";
 889                 if ($needs_confirm eq "inform") {
 890                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 891                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 892                         print "    The Cc list above has been expanded by additional\n";
 893                         print "    addresses found in the patch commit message. By default\n";
 894                         print "    send-email prompts before sending whenever this occurs.\n";
 895                         print "    This behavior is controlled by the sendemail.confirm\n";
 896                         print "    configuration setting.\n";
 897                         print "\n";
 898                         print "    For additional information, run 'git send-email --help'.\n";
 899                         print "    To retain the current behavior, but squelch this message,\n";
 900                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 901                 }
 902                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 903                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 904                          default => $ask_default);
 905                 die "Send this email reply required" unless defined $_;
 906                 if (/^n/i) {
 907                         return 0;
 908                 } elsif (/^q/i) {
 909                         cleanup_compose_files();
 910                         exit(0);
 911                 } elsif (/^a/i) {
 912                         $confirm = 'never';
 913                 }
 914         }
 915
 916         if ($dry_run) {
 917                 # We don't want to send the email.
 918         } elsif ($smtp_server =~ m#^/#) {
 919                 my $pid = open my $sm, '|-';
 920                 defined $pid or die $!;
 921                 if (!$pid) {
 922                         exec($smtp_server, @sendmail_parameters) or die $!;
 923                 }
 924                 print $sm "$header\n$message";
 925                 close $sm or die $?;
 926         } else {
 927
 928                 if (!defined $smtp_server) {
 929                         die "The required SMTP server is not properly defined."
 930                 }
 931
 932                 if ($smtp_encryption eq 'ssl') {
 933                         $smtp_server_port ||= 465; # ssmtp
 934                         require Net::SMTP::SSL;
 935                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 936                 }
 937                 else {
 938                         require Net::SMTP;
 939                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 940                                                  ? "$smtp_server:$smtp_server_port"
 941                                                  : $smtp_server);
 942                         if ($smtp_encryption eq 'tls' && $smtp) {
 943                                 require Net::SMTP::SSL;
 944                                 $smtp->command('STARTTLS');
 945                                 $smtp->response();
 946                                 if ($smtp->code == 220) {
 947                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 948                                                 or die "STARTTLS failed! ".$smtp->message;
 949                                         $smtp_encryption = '';
 950                                         # Send EHLO again to receive fresh
 951                                         # supported commands
 952                                         $smtp->hello();
 953                                 } else {
 954                                         die "Server does not support STARTTLS! ".$smtp->message;
 955                                 }
 956                         }
 957                 }
 958
 959                 if (!$smtp) {
 960                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 961                 }
 962
 963                 if (defined $smtp_authuser) {
 964
 965                         if (!defined $smtp_authpass) {
 966
 967                                 system "stty -echo";
 968
 969                                 do {
 970                                         print "Password: ";
 971                                         $_ = <STDIN>;
 972                                         print "\n";
 973                                 } while (!defined $_);
 974
 975                                 chomp($smtp_authpass = $_);
 976
 977                                 system "stty echo";
 978                         }
 979
 980                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 981                 }
 982
 983                 $smtp->mail( $raw_from ) or die $smtp->message;
 984                 $smtp->to( @recipients ) or die $smtp->message;
 985                 $smtp->data or die $smtp->message;
 986                 $smtp->datasend("$header\n$message") or die $smtp->message;
 987                 $smtp->dataend() or die $smtp->message;
 988                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 989         }
 990         if ($quiet) {
 991                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 992         } else {
 993                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 994                 if ($smtp_server !~ m#^/#) {
 995                         print "Server: $smtp_server\n";
 996                         print "MAIL FROM:<$raw_from>\n";
 997                         foreach my $entry (@recipients) {
 998                             print "RCPT TO:<$entry>\n";
 999                         }
1000                 } else {
1001                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1002                 }
1003                 print $header, "\n";
1004                 if ($smtp) {
1005                         print "Result: ", $smtp->code, ' ',
1006                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1007                 } else {
1008                         print "Result: OK\n";
1009                 }
1010         }
1011
1012         return 1;
1013 }
1014
1015 $reply_to = $initial_reply_to;
1016 $references = $initial_reply_to || '';
1017 $subject = $initial_subject;
1018 $message_num = 0;
1019
1020 foreach my $t (@files) {
1021         open(F,"<",$t) or die "can't open file $t";
1022
1023         my $author = undef;
1024         my $author_encoding;
1025         my $has_content_type;
1026         my $body_encoding;
1027         @cc = ();
1028         @xh = ();
1029         my $input_format = undef;
1030         my @header = ();
1031         $message = "";
1032         $message_num++;
1033         # First unfold multiline header fields
1034         while(<F>) {
1035                 last if /^\s*$/;
1036                 if (/^\s+\S/ and @header) {
1037                         chomp($header[$#header]);
1038                         s/^\s+/ /;
1039                         $header[$#header] .= $_;
1040             } else {
1041                         push(@header, $_);
1042                 }
1043         }
1044         # Now parse the header
1045         foreach(@header) {
1046                 if (/^From /) {
1047                         $input_format = 'mbox';
1048                         next;
1049                 }
1050                 chomp;
1051                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1052                         $input_format = 'mbox';
1053                 }
1054
1055                 if (defined $input_format && $input_format eq 'mbox') {
1056                         if (/^Subject:\s+(.*)$/) {
1057                                 $subject = $1;
1058                         }
1059                         elsif (/^From:\s+(.*)$/) {
1060                                 ($author, $author_encoding) = unquote_rfc2047($1);
1061                                 next if $suppress_cc{'author'};
1062                                 next if $suppress_cc{'self'} and $author eq $sender;
1063                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1064                                         $1, $_) unless $quiet;
1065                                 push @cc, $1;
1066                         }
1067                         elsif (/^Cc:\s+(.*)$/) {
1068                                 foreach my $addr (parse_address_line($1)) {
1069                                         if (unquote_rfc2047($addr) eq $sender) {
1070                                                 next if ($suppress_cc{'self'});
1071                                         } else {
1072                                                 next if ($suppress_cc{'cc'});
1073                                         }
1074                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1075                                                 $addr, $_) unless $quiet;
1076                                         push @cc, $addr;
1077                                 }
1078                         }
1079                         elsif (/^Content-type:/i) {
1080                                 $has_content_type = 1;
1081                                 if (/charset="?([^ "]+)/) {
1082                                         $body_encoding = $1;
1083                                 }
1084                                 push @xh, $_;
1085                         }
1086                         elsif (/^Message-Id: (.*)/i) {
1087                                 $message_id = $1;
1088                         }
1089                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1090                                 push @xh, $_;
1091                         }
1092
1093                 } else {
1094                         # In the traditional
1095                         # "send lots of email" format,
1096                         # line 1 = cc
1097                         # line 2 = subject
1098                         # So let's support that, too.
1099                         $input_format = 'lots';
1100                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1101                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1102                                         $_, $_) unless $quiet;
1103                                 push @cc, $_;
1104                         } elsif (!defined $subject) {
1105                                 $subject = $_;
1106                         }
1107                 }
1108         }
1109         # Now parse the message body
1110         while(<F>) {
1111                 $message .=  $_;
1112                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1113                         chomp;
1114                         my ($what, $c) = ($1, $2);
1115                         chomp $c;
1116                         if ($c eq $sender) {
1117                                 next if ($suppress_cc{'self'});
1118                         } else {
1119                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1120                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1121                         }
1122                         push @cc, $c;
1123                         printf("(body) Adding cc: %s from line '%s'\n",
1124                                 $c, $_) unless $quiet;
1125                 }
1126         }
1127         close F;
1128
1129         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1130                 open(F, "$cc_cmd \Q$t\E |")
1131                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1132                 while(<F>) {
1133                         my $c = $_;
1134                         $c =~ s/^\s*//g;
1135                         $c =~ s/\n$//g;
1136                         next if ($c eq $sender and $suppress_from);
1137                         push @cc, $c;
1138                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1139                                 $c, $cc_cmd) unless $quiet;
1140                 }
1141                 close F
1142                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1143         }
1144
1145         if (defined $author and $author ne $sender) {
1146                 $message = "From: $author\n\n$message";
1147                 if (defined $author_encoding) {
1148                         if ($has_content_type) {
1149                                 if ($body_encoding eq $author_encoding) {
1150                                         # ok, we already have the right encoding
1151                                 }
1152                                 else {
1153                                         # uh oh, we should re-encode
1154                                 }
1155                         }
1156                         else {
1157                                 push @xh,
1158                                   'MIME-Version: 1.0',
1159                                   "Content-Type: text/plain; charset=$author_encoding",
1160                                   'Content-Transfer-Encoding: 8bit';
1161                         }
1162                 }
1163         }
1164
1165         $needs_confirm = (
1166                 $confirm eq "always" or
1167                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1168                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1169         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1170
1171         @cc = (@initial_cc, @cc);
1172
1173         my $message_was_sent = send_message();
1174
1175         # set up for the next message
1176         if ($thread && $message_was_sent &&
1177                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1178                 $reply_to = $message_id;
1179                 if (length $references > 0) {
1180                         $references .= "\n $message_id";
1181                 } else {
1182                         $references = "$message_id";
1183                 }
1184         }
1185         $message_id = undef;
1186 }
1187
1188 cleanup_compose_files();
1189
1190 sub cleanup_compose_files() {
1191         unlink($compose_filename, $compose_filename . ".final") if $compose;
1192 }
1193
1194 $smtp->quit if $smtp;
1195
1196 sub unique_email_list(@) {
1197         my %seen;
1198         my @emails;
1199
1200         foreach my $entry (@_) {
1201                 if (my $clean = extract_valid_address($entry)) {
1202                         $seen{$clean} ||= 0;
1203                         next if $seen{$clean}++;
1204                         push @emails, $entry;
1205                 } else {
1206                         print STDERR "W: unable to extract a valid address",
1207                                         " from: $entry\n";
1208                 }
1209         }
1210         return @emails;
1211 }
1212
1213 sub validate_patch {
1214         my $fn = shift;
1215         open(my $fh, '<', $fn)
1216                 or die "unable to open $fn: $!\n";
1217         while (my $line = <$fh>) {
1218                 if (length($line) > 998) {
1219                         return "$.: patch contains a line longer than 998 characters";
1220                 }
1221         }
1222         return undef;
1223 }
1224
1225 sub file_has_nonascii {
1226         my $fn = shift;
1227         open(my $fh, '<', $fn)
1228                 or die "unable to open $fn: $!\n";
1229         while (my $line = <$fh>) {
1230                 return 1 if $line =~ /[^[:ascii:]]/;
1231         }
1232         return 0;
1233 }