git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-encryption Specify 'tls' for STARTTLS encryption, or 'ssl' for SSL.
  88                   Any other value disables the feature.
  89
  90    --smtp-ssl     Synonym for '--smtp-encryption=ssl'.  Deprecated.
  91
  92    --suppress-cc  Suppress the specified category of auto-CC.  The category
  93                   can be one of 'author' for the patch author, 'self' to
  94                   avoid copying yourself, 'sob' for Signed-off-by lines,
  95                   'cccmd' for the output of the cccmd, or 'all' to suppress
  96                   all of these.
  97
  98    --suppress-from Suppress sending emails to yourself. Defaults to off.
  99
 100    --thread       Specify that the "In-Reply-To:" header should be set on all
 101                   emails. Defaults to on.
 102
 103    --quiet        Make git-send-email less verbose.  One line per email
 104                   should be all that is output.
 105
 106    --dry-run      Do everything except actually send the emails.
 107
 108    --envelope-sender    Specify the envelope sender used to send the emails.
 109
 110    --no-validate        Don't perform any sanity checks on patches.
 111
 112 EOT
 113         exit(1);
 114 }
 115
 116 # most mail servers generate the Date: header, but not all...
 117 sub format_2822_time {
 118         my ($time) = @_;
 119         my @localtm = localtime($time);
 120         my @gmttm = gmtime($time);
 121         my $localmin = $localtm[1] + $localtm[2] * 60;
 122         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 123         if ($localtm[0] != $gmttm[0]) {
 124                 die "local zone differs from GMT by a non-minute interval\n";
 125         }
 126         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 127                 $localmin += 1440;
 128         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 129                 $localmin -= 1440;
 130         } elsif ($gmttm[6] != $localtm[6]) {
 131                 die "local time offset greater than or equal to 24 hours\n";
 132         }
 133         my $offset = $localmin - $gmtmin;
 134         my $offhour = $offset / 60;
 135         my $offmin = abs($offset % 60);
 136         if (abs($offhour) >= 24) {
 137                 die ("local time offset greater than or equal to 24 hours\n");
 138         }
 139
 140         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 141                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 142                        $localtm[3],
 143                        qw(Jan Feb Mar Apr May Jun
 144                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 145                        $localtm[5]+1900,
 146                        $localtm[2],
 147                        $localtm[1],
 148                        $localtm[0],
 149                        ($offset >= 0) ? '+' : '-',
 150                        abs($offhour),
 151                        $offmin,
 152                        );
 153 }
 154
 155 my $have_email_valid = eval { require Email::Valid; 1 };
 156 my $smtp;
 157 my $auth;
 158
 159 sub unique_email_list(@);
 160 sub cleanup_compose_files();
 161
 162 # Constants (essentially)
 163 my $compose_filename = ".msg.$$";
 164
 165 # Variables we fill in automatically, or via prompting:
 166 my (@to,@cc,@initial_cc,@bcclist,@xh,
 167         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 168
 169 my $envelope_sender;
 170
 171 # Example reply to:
 172 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 173
 174 my $repo = eval { Git->repository() };
 175 my @repo = $repo ? ($repo) : ();
 176 my $term = eval {
 177         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 178                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 179                 : new Term::ReadLine 'git-send-email';
 180 };
 181 if ($@) {
 182         $term = new FakeTerm "$@: going non-interactive";
 183 }
 184
 185 # Behavior modification variables
 186 my ($quiet, $dry_run) = (0, 0);
 187
 188 # Variables with corresponding config settings
 189 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 190 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 191 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 192 my ($no_validate);
 193 my (@suppress_cc);
 194
 195 my %config_bool_settings = (
 196     "thread" => [\$thread, 1],
 197     "chainreplyto" => [\$chain_reply_to, 1],
 198     "suppressfrom" => [\$suppress_from, undef],
 199     "signedoffcc" => [\$signed_off_cc, undef],
 200 );
 201
 202 my %config_settings = (
 203     "smtpserver" => \$smtp_server,
 204     "smtpserverport" => \$smtp_server_port,
 205     "smtpuser" => \$smtp_authuser,
 206     "smtppass" => \$smtp_authpass,
 207     "to" => \@to,
 208     "cc" => \@initial_cc,
 209     "cccmd" => \$cc_cmd,
 210     "aliasfiletype" => \$aliasfiletype,
 211     "bcc" => \@bcclist,
 212     "aliasesfile" => \@alias_files,
 213     "suppresscc" => \@suppress_cc,
 214     "envelopesender" => \$envelope_sender,
 215 );
 216
 217 # Handle Uncouth Termination
 218 sub signal_handler {
 219
 220         # Make text normal
 221         print color("reset"), "\n";
 222
 223         # SMTP password masked
 224         system "stty echo";
 225
 226         # tmp files from --compose
 227         if (-e $compose_filename) {
 228                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229         }
 230         if (-e ($compose_filename . ".final")) {
 231                 print "'$compose_filename.final' contains the composed email.\n"
 232         }
 233
 234         exit;
 235 };
 236
 237 $SIG{TERM} = \&signal_handler;
 238 $SIG{INT}  = \&signal_handler;
 239
 240 # Begin by accumulating all the variables (defined above), that we will end up
 241 # needing, first, from the command line:
 242
 243 my $rc = GetOptions("sender|from=s" => \$sender,
 244                     "in-reply-to=s" => \$initial_reply_to,
 245                     "subject=s" => \$initial_subject,
 246                     "to=s" => \@to,
 247                     "cc=s" => \@initial_cc,
 248                     "bcc=s" => \@bcclist,
 249                     "chain-reply-to!" => \$chain_reply_to,
 250                     "smtp-server=s" => \$smtp_server,
 251                     "smtp-server-port=s" => \$smtp_server_port,
 252                     "smtp-user=s" => \$smtp_authuser,
 253                     "smtp-pass:s" => \$smtp_authpass,
 254                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 255                     "smtp-encryption=s" => \$smtp_encryption,
 256                     "identity=s" => \$identity,
 257                     "compose" => \$compose,
 258                     "quiet" => \$quiet,
 259                     "cc-cmd=s" => \$cc_cmd,
 260                     "suppress-from!" => \$suppress_from,
 261                     "suppress-cc=s" => \@suppress_cc,
 262                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 263                     "dry-run" => \$dry_run,
 264                     "envelope-sender=s" => \$envelope_sender,
 265                     "thread!" => \$thread,
 266                     "no-validate" => \$no_validate,
 267          );
 268
 269 unless ($rc) {
 270     usage();
 271 }
 272
 273 # Now, let's fill any that aren't set in with defaults:
 274
 275 sub read_config {
 276         my ($prefix) = @_;
 277
 278         foreach my $setting (keys %config_bool_settings) {
 279                 my $target = $config_bool_settings{$setting}->[0];
 280                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 281         }
 282
 283         foreach my $setting (keys %config_settings) {
 284                 my $target = $config_settings{$setting};
 285                 if (ref($target) eq "ARRAY") {
 286                         unless (@$target) {
 287                                 my @values = Git::config(@repo, "$prefix.$setting");
 288                                 @$target = @values if (@values && defined $values[0]);
 289                         }
 290                 }
 291                 else {
 292                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 293                 }
 294         }
 295
 296         if (!defined $smtp_encryption) {
 297                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 298                 if (defined $enc) {
 299                         $smtp_encryption = $enc;
 300                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 301                         $smtp_encryption = 'ssl';
 302                 }
 303         }
 304 }
 305
 306 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 307 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 308 read_config("sendemail.$identity") if (defined $identity);
 309 read_config("sendemail");
 310
 311 # fall back on builtin bool defaults
 312 foreach my $setting (values %config_bool_settings) {
 313         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 314 }
 315
 316 # 'default' encryption is none -- this only prevents a warning
 317 $smtp_encryption = '' unless (defined $smtp_encryption);
 318
 319 # Set CC suppressions
 320 my(%suppress_cc);
 321 if (@suppress_cc) {
 322         foreach my $entry (@suppress_cc) {
 323                 die "Unknown --suppress-cc field: '$entry'\n"
 324                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 325                 $suppress_cc{$entry} = 1;
 326         }
 327 }
 328
 329 if ($suppress_cc{'all'}) {
 330         foreach my $entry (qw (ccmd cc author self sob)) {
 331                 $suppress_cc{$entry} = 1;
 332         }
 333         delete $suppress_cc{'all'};
 334 }
 335
 336 # If explicit old-style ones are specified, they trump --suppress-cc.
 337 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 338 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 339
 340 # Debugging, print out the suppressions.
 341 if (0) {
 342         print "suppressions:\n";
 343         foreach my $entry (keys %suppress_cc) {
 344                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 345         }
 346 }
 347
 348 my ($repoauthor, $repocommitter);
 349 ($repoauthor) = Git::ident_person(@repo, 'author');
 350 ($repocommitter) = Git::ident_person(@repo, 'committer');
 351
 352 # Verify the user input
 353
 354 foreach my $entry (@to) {
 355         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 356 }
 357
 358 foreach my $entry (@initial_cc) {
 359         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 360 }
 361
 362 foreach my $entry (@bcclist) {
 363         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 364 }
 365
 366 my %aliases;
 367 my %parse_alias = (
 368         # multiline formats can be supported in the future
 369         mutt => sub { my $fh = shift; while (<$fh>) {
 370                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 371                         my ($alias, $addr) = ($1, $2);
 372                         $addr =~ s/#.*$//; # mutt allows # comments
 373                          # commas delimit multiple addresses
 374                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 375                 }}},
 376         mailrc => sub { my $fh = shift; while (<$fh>) {
 377                 if (/^alias\s+(\S+)\s+(.*)$/) {
 378                         # spaces delimit multiple addresses
 379                         $aliases{$1} = [ split(/\s+/, $2) ];
 380                 }}},
 381         pine => sub { my $fh = shift; while (<$fh>) {
 382                 if (/^(\S+)\t.*\t(.*)$/) {
 383                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 384                 }}},
 385         gnus => sub { my $fh = shift; while (<$fh>) {
 386                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 387                         $aliases{$1} = [ $2 ];
 388                 }}}
 389 );
 390
 391 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 392         foreach my $file (@alias_files) {
 393                 open my $fh, '<', $file or die "opening $file: $!\n";
 394                 $parse_alias{$aliasfiletype}->($fh);
 395                 close $fh;
 396         }
 397 }
 398
 399 ($sender) = expand_aliases($sender) if defined $sender;
 400
 401 # Now that all the defaults are set, process the rest of the command line
 402 # arguments and collect up the files that need to be processed.
 403 for my $f (@ARGV) {
 404         if (-d $f) {
 405                 opendir(DH,$f)
 406                         or die "Failed to opendir $f: $!";
 407
 408                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 409                                 sort readdir(DH);
 410
 411         } elsif (-f $f or -p $f) {
 412                 push @files, $f;
 413
 414         } else {
 415                 print STDERR "Skipping $f - not found.\n";
 416         }
 417 }
 418
 419 if (!$no_validate) {
 420         foreach my $f (@files) {
 421                 unless (-p $f) {
 422                         my $error = validate_patch($f);
 423                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 424                 }
 425         }
 426 }
 427
 428 if (@files) {
 429         unless ($quiet) {
 430                 print $_,"\n" for (@files);
 431         }
 432 } else {
 433         print STDERR "\nNo patch files specified!\n\n";
 434         usage();
 435 }
 436
 437 my $prompting = 0;
 438 if (!defined $sender) {
 439         $sender = $repoauthor || $repocommitter || '';
 440
 441         while (1) {
 442                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 443                 last if defined $_;
 444                 print "\n";
 445         }
 446
 447         $sender = $_ if ($_);
 448         print "Emails will be sent from: ", $sender, "\n";
 449         $prompting++;
 450 }
 451
 452 if (!@to) {
 453
 454
 455         while (1) {
 456                 $_ = $term->readline("Who should the emails be sent to? ", "");
 457                 last if defined $_;
 458                 print "\n";
 459         }
 460
 461         my $to = $_;
 462         push @to, split /,\s*/, $to;
 463         $prompting++;
 464 }
 465
 466 sub expand_aliases {
 467         my @cur = @_;
 468         my @last;
 469         do {
 470                 @last = @cur;
 471                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 472         } while (join(',',@cur) ne join(',',@last));
 473         return @cur;
 474 }
 475
 476 @to = expand_aliases(@to);
 477 @to = (map { sanitize_address($_) } @to);
 478 @initial_cc = expand_aliases(@initial_cc);
 479 @bcclist = expand_aliases(@bcclist);
 480
 481 if (!defined $initial_subject && $compose) {
 482         while (1) {
 483                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 484                 last if defined $_;
 485                 print "\n";
 486         }
 487
 488         $initial_subject = $_;
 489         $prompting++;
 490 }
 491
 492 if ($thread && !defined $initial_reply_to && $prompting) {
 493         while (1) {
 494                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 495                 last if defined $_;
 496                 print "\n";
 497         }
 498
 499         $initial_reply_to = $_;
 500 }
 501 if (defined $initial_reply_to) {
 502         $initial_reply_to =~ s/^\s*<?//;
 503         $initial_reply_to =~ s/>?\s*$//;
 504         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 505 }
 506
 507 if (!defined $smtp_server) {
 508         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 509                 if (-x $_) {
 510                         $smtp_server = $_;
 511                         last;
 512                 }
 513         }
 514         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 515 }
 516
 517 if ($compose) {
 518         # Note that this does not need to be secure, but we will make a small
 519         # effort to have it be unique
 520         open(C,">",$compose_filename)
 521                 or die "Failed to open for writing $compose_filename: $!";
 522         print C "From $sender # This line is ignored.\n";
 523         printf C "Subject: %s\n\n", $initial_subject;
 524         printf C <<EOT;
 525 GIT: Please enter your email below.
 526 GIT: Lines beginning in "GIT: " will be removed.
 527 GIT: Consider including an overall diffstat or table of contents
 528 GIT: for the patch you are writing.
 529
 530 EOT
 531         close(C);
 532
 533         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 534         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 535
 536         open(C2,">",$compose_filename . ".final")
 537                 or die "Failed to open $compose_filename.final : " . $!;
 538
 539         open(C,"<",$compose_filename)
 540                 or die "Failed to open $compose_filename : " . $!;
 541
 542         my $need_8bit_cte = file_has_nonascii($compose_filename);
 543         my $in_body = 0;
 544         while(<C>) {
 545                 next if m/^GIT: /;
 546                 if (!$in_body && /^\n$/) {
 547                         $in_body = 1;
 548                         if ($need_8bit_cte) {
 549                                 print C2 "MIME-Version: 1.0\n",
 550                                          "Content-Type: text/plain; ",
 551                                            "charset=utf-8\n",
 552                                          "Content-Transfer-Encoding: 8bit\n";
 553                         }
 554                 }
 555                 if (!$in_body && /^MIME-Version:/i) {
 556                         $need_8bit_cte = 0;
 557                 }
 558                 if (!$in_body && /^Subject: ?(.*)/i) {
 559                         my $subject = $1;
 560                         $_ = "Subject: " .
 561                                 ($subject =~ /[^[:ascii:]]/ ?
 562                                  quote_rfc2047($subject) :
 563                                  $subject) .
 564                                 "\n";
 565                 }
 566                 print C2 $_;
 567         }
 568         close(C);
 569         close(C2);
 570
 571         while (1) {
 572                 $_ = $term->readline("Send this email? (y|n) ");
 573                 last if defined $_;
 574                 print "\n";
 575         }
 576
 577         if (uc substr($_,0,1) ne 'Y') {
 578                 cleanup_compose_files();
 579                 exit(0);
 580         }
 581
 582         @files = ($compose_filename . ".final", @files);
 583 }
 584
 585 # Variables we set as part of the loop over files
 586 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 587
 588 sub extract_valid_address {
 589         my $address = shift;
 590         my $local_part_regexp = '[^<>"\s@]+';
 591         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 592
 593         # check for a local address:
 594         return $address if ($address =~ /^($local_part_regexp)$/);
 595
 596         $address =~ s/^\s*<(.*)>\s*$/$1/;
 597         if ($have_email_valid) {
 598                 return scalar Email::Valid->address($address);
 599         } else {
 600                 # less robust/correct than the monster regexp in Email::Valid,
 601                 # but still does a 99% job, and one less dependency
 602                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 603                 return $1;
 604         }
 605 }
 606
 607 # Usually don't need to change anything below here.
 608
 609 # we make a "fake" message id by taking the current number
 610 # of seconds since the beginning of Unix time and tacking on
 611 # a random number to the end, in case we are called quicker than
 612 # 1 second since the last time we were called.
 613
 614 # We'll setup a template for the message id, using the "from" address:
 615
 616 my ($message_id_stamp, $message_id_serial);
 617 sub make_message_id
 618 {
 619         my $uniq;
 620         if (!defined $message_id_stamp) {
 621                 $message_id_stamp = sprintf("%s-%s", time, $$);
 622                 $message_id_serial = 0;
 623         }
 624         $message_id_serial++;
 625         $uniq = "$message_id_stamp-$message_id_serial";
 626
 627         my $du_part;
 628         for ($sender, $repocommitter, $repoauthor) {
 629                 $du_part = extract_valid_address(sanitize_address($_));
 630                 last if (defined $du_part and $du_part ne '');
 631         }
 632         if (not defined $du_part or $du_part eq '') {
 633                 use Sys::Hostname qw();
 634                 $du_part = 'user@' . Sys::Hostname::hostname();
 635         }
 636         my $message_id_template = "<%s-git-send-email-%s>";
 637         $message_id = sprintf($message_id_template, $uniq, $du_part);
 638         #print "new message id = $message_id\n"; # Was useful for debugging
 639 }
 640
 641
 642
 643 $time = time - scalar $#files;
 644
 645 sub unquote_rfc2047 {
 646         local ($_) = @_;
 647         my $encoding;
 648         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 649                 $encoding = $1;
 650                 s/_/ /g;
 651                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 652         }
 653         return wantarray ? ($_, $encoding) : $_;
 654 }
 655
 656 sub quote_rfc2047 {
 657         local $_ = shift;
 658         my $encoding = shift || 'utf-8';
 659         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 660         s/(.*)/=\?$encoding\?q\?$1\?=/;
 661         return $_;
 662 }
 663
 664 # use the simplest quoting being able to handle the recipient
 665 sub sanitize_address
 666 {
 667         my ($recipient) = @_;
 668         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 669
 670         if (not $recipient_name) {
 671                 return "$recipient";
 672         }
 673
 674         # if recipient_name is already quoted, do nothing
 675         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 676                 return $recipient;
 677         }
 678
 679         # rfc2047 is needed if a non-ascii char is included
 680         if ($recipient_name =~ /[^[:ascii:]]/) {
 681                 $recipient_name = quote_rfc2047($recipient_name);
 682         }
 683
 684         # double quotes are needed if specials or CTLs are included
 685         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 686                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 687                 $recipient_name = "\"$recipient_name\"";
 688         }
 689
 690         return "$recipient_name $recipient_addr";
 691
 692 }
 693
 694 sub send_message
 695 {
 696         my @recipients = unique_email_list(@to);
 697         @cc = (grep { my $cc = extract_valid_address($_);
 698                       not grep { $cc eq $_ } @recipients
 699                     }
 700                map { sanitize_address($_) }
 701                @cc);
 702         my $to = join (",\n\t", @recipients);
 703         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 704         @recipients = (map { extract_valid_address($_) } @recipients);
 705         my $date = format_2822_time($time++);
 706         my $gitversion = '@@GIT_VERSION@@';
 707         if ($gitversion =~ m/..GIT_VERSION../) {
 708             $gitversion = Git::version();
 709         }
 710
 711         my $cc = join(", ", unique_email_list(@cc));
 712         my $ccline = "";
 713         if ($cc ne '') {
 714                 $ccline = "\nCc: $cc";
 715         }
 716         my $sanitized_sender = sanitize_address($sender);
 717         make_message_id() unless defined($message_id);
 718
 719         my $header = "From: $sanitized_sender
 720 To: $to${ccline}
 721 Subject: $subject
 722 Date: $date
 723 Message-Id: $message_id
 724 X-Mailer: git-send-email $gitversion
 725 ";
 726         if ($thread && $reply_to) {
 727
 728                 $header .= "In-Reply-To: $reply_to\n";
 729                 $header .= "References: $references\n";
 730         }
 731         if (@xh) {
 732                 $header .= join("\n", @xh) . "\n";
 733         }
 734
 735         my @sendmail_parameters = ('-i', @recipients);
 736         my $raw_from = $sanitized_sender;
 737         $raw_from = $envelope_sender if (defined $envelope_sender);
 738         $raw_from = extract_valid_address($raw_from);
 739         unshift (@sendmail_parameters,
 740                         '-f', $raw_from) if(defined $envelope_sender);
 741
 742         if ($dry_run) {
 743                 # We don't want to send the email.
 744         } elsif ($smtp_server =~ m#^/#) {
 745                 my $pid = open my $sm, '|-';
 746                 defined $pid or die $!;
 747                 if (!$pid) {
 748                         exec($smtp_server, @sendmail_parameters) or die $!;
 749                 }
 750                 print $sm "$header\n$message";
 751                 close $sm or die $?;
 752         } else {
 753
 754                 if (!defined $smtp_server) {
 755                         die "The required SMTP server is not properly defined."
 756                 }
 757
 758                 if ($smtp_encryption eq 'ssl') {
 759                         $smtp_server_port ||= 465; # ssmtp
 760                         require Net::SMTP::SSL;
 761                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 762                 }
 763                 else {
 764                         require Net::SMTP;
 765                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 766                                                  ? "$smtp_server:$smtp_server_port"
 767                                                  : $smtp_server);
 768                         if ($smtp_encryption eq 'tls') {
 769                                 require Net::SMTP::SSL;
 770                                 $smtp->command('STARTTLS');
 771                                 $smtp->response();
 772                                 if ($smtp->code == 220) {
 773                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 774                                                 or die "STARTTLS failed! ".$smtp->message;
 775                                         $smtp_encryption = '';
 776                                         # Send EHLO again to receive fresh
 777                                         # supported commands
 778                                         $smtp->hello();
 779                                 } else {
 780                                         die "Server does not support STARTTLS! ".$smtp->message;
 781                                 }
 782                         }
 783                 }
 784
 785                 if (!$smtp) {
 786                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 787                 }
 788
 789                 if (defined $smtp_authuser) {
 790
 791                         if (!defined $smtp_authpass) {
 792
 793                                 system "stty -echo";
 794
 795                                 do {
 796                                         print "Password: ";
 797                                         $_ = <STDIN>;
 798                                         print "\n";
 799                                 } while (!defined $_);
 800
 801                                 chomp($smtp_authpass = $_);
 802
 803                                 system "stty echo";
 804                         }
 805
 806                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 807                 }
 808
 809                 $smtp->mail( $raw_from ) or die $smtp->message;
 810                 $smtp->to( @recipients ) or die $smtp->message;
 811                 $smtp->data or die $smtp->message;
 812                 $smtp->datasend("$header\n$message") or die $smtp->message;
 813                 $smtp->dataend() or die $smtp->message;
 814                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 815         }
 816         if ($quiet) {
 817                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 818         } else {
 819                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 820                 if ($smtp_server !~ m#^/#) {
 821                         print "Server: $smtp_server\n";
 822                         print "MAIL FROM:<$raw_from>\n";
 823                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 824                 } else {
 825                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 826                 }
 827                 print $header, "\n";
 828                 if ($smtp) {
 829                         print "Result: ", $smtp->code, ' ',
 830                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 831                 } else {
 832                         print "Result: OK\n";
 833                 }
 834         }
 835 }
 836
 837 $reply_to = $initial_reply_to;
 838 $references = $initial_reply_to || '';
 839 $subject = $initial_subject;
 840
 841 foreach my $t (@files) {
 842         open(F,"<",$t) or die "can't open file $t";
 843
 844         my $author = undef;
 845         my $author_encoding;
 846         my $has_content_type;
 847         my $body_encoding;
 848         @cc = @initial_cc;
 849         @xh = ();
 850         my $input_format = undef;
 851         my $header_done = 0;
 852         $message = "";
 853         while(<F>) {
 854                 if (!$header_done) {
 855                         if (/^From /) {
 856                                 $input_format = 'mbox';
 857                                 next;
 858                         }
 859                         chomp;
 860                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 861                                 $input_format = 'mbox';
 862                         }
 863
 864                         if (defined $input_format && $input_format eq 'mbox') {
 865                                 if (/^Subject:\s+(.*)$/) {
 866                                         $subject = $1;
 867
 868                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 869                                         if (unquote_rfc2047($2) eq $sender) {
 870                                                 next if ($suppress_cc{'self'});
 871                                         }
 872                                         elsif ($1 eq 'From') {
 873                                                 ($author, $author_encoding)
 874                                                   = unquote_rfc2047($2);
 875                                                 next if ($suppress_cc{'author'});
 876                                         } else {
 877                                                 next if ($suppress_cc{'cc'});
 878                                         }
 879                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 880                                                 $2, $_) unless $quiet;
 881                                         push @cc, $2;
 882                                 }
 883                                 elsif (/^Content-type:/i) {
 884                                         $has_content_type = 1;
 885                                         if (/charset="?[^ "]+/) {
 886                                                 $body_encoding = $1;
 887                                         }
 888                                         push @xh, $_;
 889                                 }
 890                                 elsif (/^Message-Id: (.*)/i) {
 891                                         $message_id = $1;
 892                                 }
 893                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 894                                         push @xh, $_;
 895                                 }
 896
 897                         } else {
 898                                 # In the traditional
 899                                 # "send lots of email" format,
 900                                 # line 1 = cc
 901                                 # line 2 = subject
 902                                 # So let's support that, too.
 903                                 $input_format = 'lots';
 904                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 905                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 906                                                 $_, $_) unless $quiet;
 907
 908                                         push @cc, $_;
 909
 910                                 } elsif (!defined $subject) {
 911                                         $subject = $_;
 912                                 }
 913                         }
 914
 915                         # A whitespace line will terminate the headers
 916                         if (m/^\s*$/) {
 917                                 $header_done = 1;
 918                         }
 919                 } else {
 920                         $message .=  $_;
 921                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 922                                 next if ($suppress_cc{'sob'});
 923                                 chomp;
 924                                 my $c = $2;
 925                                 chomp $c;
 926                                 next if ($c eq $sender and $suppress_cc{'self'});
 927                                 push @cc, $c;
 928                                 printf("(sob) Adding cc: %s from line '%s'\n",
 929                                         $c, $_) unless $quiet;
 930                         }
 931                 }
 932         }
 933         close F;
 934
 935         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 936                 open(F, "$cc_cmd $t |")
 937                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 938                 while(<F>) {
 939                         my $c = $_;
 940                         $c =~ s/^\s*//g;
 941                         $c =~ s/\n$//g;
 942                         next if ($c eq $sender and $suppress_from);
 943                         push @cc, $c;
 944                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 945                                 $c, $cc_cmd) unless $quiet;
 946                 }
 947                 close F
 948                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 949         }
 950
 951         if (defined $author) {
 952                 $message = "From: $author\n\n$message";
 953                 if (defined $author_encoding) {
 954                         if ($has_content_type) {
 955                                 if ($body_encoding eq $author_encoding) {
 956                                         # ok, we already have the right encoding
 957                                 }
 958                                 else {
 959                                         # uh oh, we should re-encode
 960                                 }
 961                         }
 962                         else {
 963                                 push @xh,
 964                                   'MIME-Version: 1.0',
 965                                   "Content-Type: text/plain; charset=$author_encoding",
 966                                   'Content-Transfer-Encoding: 8bit';
 967                         }
 968                 }
 969         }
 970
 971         send_message();
 972
 973         # set up for the next message
 974         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 975                 $reply_to = $message_id;
 976                 if (length $references > 0) {
 977                         $references .= "\n $message_id";
 978                 } else {
 979                         $references = "$message_id";
 980                 }
 981         }
 982         $message_id = undef;
 983 }
 984
 985 if ($compose) {
 986         cleanup_compose_files();
 987 }
 988
 989 sub cleanup_compose_files() {
 990         unlink($compose_filename, $compose_filename . ".final");
 991
 992 }
 993
 994 $smtp->quit if $smtp;
 995
 996 sub unique_email_list(@) {
 997         my %seen;
 998         my @emails;
 999
1000         foreach my $entry (@_) {
1001                 if (my $clean = extract_valid_address($entry)) {
1002                         $seen{$clean} ||= 0;
1003                         next if $seen{$clean}++;
1004                         push @emails, $entry;
1005                 } else {
1006                         print STDERR "W: unable to extract a valid address",
1007                                         " from: $entry\n";
1008                 }
1009         }
1010         return @emails;
1011 }
1012
1013 sub validate_patch {
1014         my $fn = shift;
1015         open(my $fh, '<', $fn)
1016                 or die "unable to open $fn: $!\n";
1017         while (my $line = <$fh>) {
1018                 if (length($line) > 998) {
1019                         return "$.: patch contains a line longer than 998 characters";
1020                 }
1021         }
1022         return undef;
1023 }
1024
1025 sub file_has_nonascii {
1026         my $fn = shift;
1027         open(my $fh, '<', $fn)
1028                 or die "unable to open $fn: $!\n";
1029         while (my $line = <$fh>) {
1030                 return 1 if $line =~ /[^[:ascii:]]/;
1031         }
1032         return 0;
1033 }