git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor;
 166
 167 sub do_edit {
 168         if (!defined($editor)) {
 169                 $editor = Git::command_oneline('var', 'GIT_EDITOR');
 170         }
 171         if (defined($multiedit) && !$multiedit) {
 172                 map {
 173                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 174                         if (($? & 127) || ($? >> 8)) {
 175                                 die("the editor exited uncleanly, aborting everything");
 176                         }
 177                 } @_;
 178         } else {
 179                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 180                 if (($? & 127) || ($? >> 8)) {
 181                         die("the editor exited uncleanly, aborting everything");
 182                 }
 183         }
 184 }
 185
 186 # Variables with corresponding config settings
 187 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 188 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 189 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 190 my ($validate, $confirm);
 191 my (@suppress_cc);
 192
 193 my $not_set_by_user = "true but not set by the user";
 194
 195 my %config_bool_settings = (
 196     "thread" => [\$thread, 1],
 197     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 198     "suppressfrom" => [\$suppress_from, undef],
 199     "signedoffbycc" => [\$signed_off_by_cc, undef],
 200     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 201     "validate" => [\$validate, 1],
 202 );
 203
 204 my %config_settings = (
 205     "smtpserver" => \$smtp_server,
 206     "smtpserverport" => \$smtp_server_port,
 207     "smtpuser" => \$smtp_authuser,
 208     "smtppass" => \$smtp_authpass,
 209     "to" => \@to,
 210     "cc" => \@initial_cc,
 211     "cccmd" => \$cc_cmd,
 212     "aliasfiletype" => \$aliasfiletype,
 213     "bcc" => \@bcclist,
 214     "aliasesfile" => \@alias_files,
 215     "suppresscc" => \@suppress_cc,
 216     "envelopesender" => \$envelope_sender,
 217     "multiedit" => \$multiedit,
 218     "confirm"   => \$confirm,
 219     "from" => \$sender,
 220 );
 221
 222 # Help users prepare for 1.7.0
 223 sub chain_reply_to {
 224         if (defined $chain_reply_to &&
 225             $chain_reply_to eq $not_set_by_user) {
 226                 print STDERR
 227                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 228                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 229                     "you want to keep --chain-reply-to as your default.\n";
 230                 $chain_reply_to = 0;
 231         }
 232         return $chain_reply_to;
 233 }
 234
 235 # Handle Uncouth Termination
 236 sub signal_handler {
 237
 238         # Make text normal
 239         print color("reset"), "\n";
 240
 241         # SMTP password masked
 242         system "stty echo";
 243
 244         # tmp files from --compose
 245         if (defined $compose_filename) {
 246                 if (-e $compose_filename) {
 247                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 248                 }
 249                 if (-e ($compose_filename . ".final")) {
 250                         print "'$compose_filename.final' contains the composed email.\n"
 251                 }
 252         }
 253
 254         exit;
 255 };
 256
 257 $SIG{TERM} = \&signal_handler;
 258 $SIG{INT}  = \&signal_handler;
 259
 260 # Begin by accumulating all the variables (defined above), that we will end up
 261 # needing, first, from the command line:
 262
 263 my $rc = GetOptions("sender|from=s" => \$sender,
 264                     "in-reply-to=s" => \$initial_reply_to,
 265                     "subject=s" => \$initial_subject,
 266                     "to=s" => \@to,
 267                     "cc=s" => \@initial_cc,
 268                     "bcc=s" => \@bcclist,
 269                     "chain-reply-to!" => \$chain_reply_to,
 270                     "smtp-server=s" => \$smtp_server,
 271                     "smtp-server-port=s" => \$smtp_server_port,
 272                     "smtp-user=s" => \$smtp_authuser,
 273                     "smtp-pass:s" => \$smtp_authpass,
 274                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 275                     "smtp-encryption=s" => \$smtp_encryption,
 276                     "identity=s" => \$identity,
 277                     "annotate" => \$annotate,
 278                     "compose" => \$compose,
 279                     "quiet" => \$quiet,
 280                     "cc-cmd=s" => \$cc_cmd,
 281                     "suppress-from!" => \$suppress_from,
 282                     "suppress-cc=s" => \@suppress_cc,
 283                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 284                     "confirm=s" => \$confirm,
 285                     "dry-run" => \$dry_run,
 286                     "envelope-sender=s" => \$envelope_sender,
 287                     "thread!" => \$thread,
 288                     "validate!" => \$validate,
 289                     "format-patch!" => \$format_patch,
 290          );
 291
 292 unless ($rc) {
 293     usage();
 294 }
 295
 296 die "Cannot run git format-patch from outside a repository\n"
 297         if $format_patch and not $repo;
 298
 299 # Now, let's fill any that aren't set in with defaults:
 300
 301 sub read_config {
 302         my ($prefix) = @_;
 303
 304         foreach my $setting (keys %config_bool_settings) {
 305                 my $target = $config_bool_settings{$setting}->[0];
 306                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 307         }
 308
 309         foreach my $setting (keys %config_settings) {
 310                 my $target = $config_settings{$setting};
 311                 if (ref($target) eq "ARRAY") {
 312                         unless (@$target) {
 313                                 my @values = Git::config(@repo, "$prefix.$setting");
 314                                 @$target = @values if (@values && defined $values[0]);
 315                         }
 316                 }
 317                 else {
 318                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 319                 }
 320         }
 321
 322         if (!defined $smtp_encryption) {
 323                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 324                 if (defined $enc) {
 325                         $smtp_encryption = $enc;
 326                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 327                         $smtp_encryption = 'ssl';
 328                 }
 329         }
 330 }
 331
 332 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 333 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 334 read_config("sendemail.$identity") if (defined $identity);
 335 read_config("sendemail");
 336
 337 # fall back on builtin bool defaults
 338 foreach my $setting (values %config_bool_settings) {
 339         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 340 }
 341
 342 # 'default' encryption is none -- this only prevents a warning
 343 $smtp_encryption = '' unless (defined $smtp_encryption);
 344
 345 # Set CC suppressions
 346 my(%suppress_cc);
 347 if (@suppress_cc) {
 348         foreach my $entry (@suppress_cc) {
 349                 die "Unknown --suppress-cc field: '$entry'\n"
 350                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 351                 $suppress_cc{$entry} = 1;
 352         }
 353 }
 354
 355 if ($suppress_cc{'all'}) {
 356         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 357                 $suppress_cc{$entry} = 1;
 358         }
 359         delete $suppress_cc{'all'};
 360 }
 361
 362 # If explicit old-style ones are specified, they trump --suppress-cc.
 363 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 364 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 365
 366 if ($suppress_cc{'body'}) {
 367         foreach my $entry (qw (sob bodycc)) {
 368                 $suppress_cc{$entry} = 1;
 369         }
 370         delete $suppress_cc{'body'};
 371 }
 372
 373 # Set confirm's default value
 374 my $confirm_unconfigured = !defined $confirm;
 375 if ($confirm_unconfigured) {
 376         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 377 };
 378 die "Unknown --confirm setting: '$confirm'\n"
 379         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 380
 381 # Debugging, print out the suppressions.
 382 if (0) {
 383         print "suppressions:\n";
 384         foreach my $entry (keys %suppress_cc) {
 385                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 386         }
 387 }
 388
 389 my ($repoauthor, $repocommitter);
 390 ($repoauthor) = Git::ident_person(@repo, 'author');
 391 ($repocommitter) = Git::ident_person(@repo, 'committer');
 392
 393 # Verify the user input
 394
 395 foreach my $entry (@to) {
 396         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 397 }
 398
 399 foreach my $entry (@initial_cc) {
 400         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 401 }
 402
 403 foreach my $entry (@bcclist) {
 404         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 405 }
 406
 407 sub parse_address_line {
 408         if ($have_mail_address) {
 409                 return map { $_->format } Mail::Address->parse($_[0]);
 410         } else {
 411                 return split_addrs($_[0]);
 412         }
 413 }
 414
 415 sub split_addrs {
 416         return quotewords('\s*,\s*', 1, @_);
 417 }
 418
 419 my %aliases;
 420 my %parse_alias = (
 421         # multiline formats can be supported in the future
 422         mutt => sub { my $fh = shift; while (<$fh>) {
 423                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 424                         my ($alias, $addr) = ($1, $2);
 425                         $addr =~ s/#.*$//; # mutt allows # comments
 426                          # commas delimit multiple addresses
 427                         $aliases{$alias} = [ split_addrs($addr) ];
 428                 }}},
 429         mailrc => sub { my $fh = shift; while (<$fh>) {
 430                 if (/^alias\s+(\S+)\s+(.*)$/) {
 431                         # spaces delimit multiple addresses
 432                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 433                 }}},
 434         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 435                 for (my $x = ''; defined($x); $x = $_) {
 436                         chomp $x;
 437                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 438                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 439                         $aliases{$1} = [ split_addrs($2) ];
 440                 }},
 441         elm => sub  { my $fh = shift;
 442                       while (<$fh>) {
 443                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 444                               my ($alias, $addr) = ($1, $2);
 445                                $aliases{$alias} = [ split_addrs($addr) ];
 446                           }
 447                       } },
 448
 449         gnus => sub { my $fh = shift; while (<$fh>) {
 450                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 451                         $aliases{$1} = [ $2 ];
 452                 }}}
 453 );
 454
 455 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 456         foreach my $file (@alias_files) {
 457                 open my $fh, '<', $file or die "opening $file: $!\n";
 458                 $parse_alias{$aliasfiletype}->($fh);
 459                 close $fh;
 460         }
 461 }
 462
 463 ($sender) = expand_aliases($sender) if defined $sender;
 464
 465 # returns 1 if the conflict must be solved using it as a format-patch argument
 466 sub check_file_rev_conflict($) {
 467         return unless $repo;
 468         my $f = shift;
 469         try {
 470                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 471                 if (defined($format_patch)) {
 472                         return $format_patch;
 473                 }
 474                 die(<<EOF);
 475 File '$f' exists but it could also be the range of commits
 476 to produce patches for.  Please disambiguate by...
 477
 478     * Saying "./$f" if you mean a file; or
 479     * Giving --format-patch option if you mean a range.
 480 EOF
 481         } catch Git::Error::Command with {
 482                 return 0;
 483         }
 484 }
 485
 486 # Now that all the defaults are set, process the rest of the command line
 487 # arguments and collect up the files that need to be processed.
 488 my @rev_list_opts;
 489 while (defined(my $f = shift @ARGV)) {
 490         if ($f eq "--") {
 491                 push @rev_list_opts, "--", @ARGV;
 492                 @ARGV = ();
 493         } elsif (-d $f and !check_file_rev_conflict($f)) {
 494                 opendir(DH,$f)
 495                         or die "Failed to opendir $f: $!";
 496
 497                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 498                                 sort readdir(DH);
 499                 closedir(DH);
 500         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 501                 push @files, $f;
 502         } else {
 503                 push @rev_list_opts, $f;
 504         }
 505 }
 506
 507 if (@rev_list_opts) {
 508         die "Cannot run git format-patch from outside a repository\n"
 509                 unless $repo;
 510         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 511 }
 512
 513 if ($validate) {
 514         foreach my $f (@files) {
 515                 unless (-p $f) {
 516                         my $error = validate_patch($f);
 517                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 518                 }
 519         }
 520 }
 521
 522 if (@files) {
 523         unless ($quiet) {
 524                 print $_,"\n" for (@files);
 525         }
 526 } else {
 527         print STDERR "\nNo patch files specified!\n\n";
 528         usage();
 529 }
 530
 531 sub get_patch_subject($) {
 532         my $fn = shift;
 533         open (my $fh, '<', $fn);
 534         while (my $line = <$fh>) {
 535                 next unless ($line =~ /^Subject: (.*)$/);
 536                 close $fh;
 537                 return "GIT: $1\n";
 538         }
 539         close $fh;
 540         die "No subject line in $fn ?";
 541 }
 542
 543 if ($compose) {
 544         # Note that this does not need to be secure, but we will make a small
 545         # effort to have it be unique
 546         $compose_filename = ($repo ?
 547                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 548                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 549         open(C,">",$compose_filename)
 550                 or die "Failed to open for writing $compose_filename: $!";
 551
 552
 553         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 554         my $tpl_subject = $initial_subject || '';
 555         my $tpl_reply_to = $initial_reply_to || '';
 556
 557         print C <<EOT;
 558 From $tpl_sender # This line is ignored.
 559 GIT: Lines beginning in "GIT:" will be removed.
 560 GIT: Consider including an overall diffstat or table of contents
 561 GIT: for the patch you are writing.
 562 GIT:
 563 GIT: Clear the body content if you don't wish to send a summary.
 564 From: $tpl_sender
 565 Subject: $tpl_subject
 566 In-Reply-To: $tpl_reply_to
 567
 568 EOT
 569         for my $f (@files) {
 570                 print C get_patch_subject($f);
 571         }
 572         close(C);
 573
 574         if ($annotate) {
 575                 do_edit($compose_filename, @files);
 576         } else {
 577                 do_edit($compose_filename);
 578         }
 579
 580         open(C2,">",$compose_filename . ".final")
 581                 or die "Failed to open $compose_filename.final : " . $!;
 582
 583         open(C,"<",$compose_filename)
 584                 or die "Failed to open $compose_filename : " . $!;
 585
 586         my $need_8bit_cte = file_has_nonascii($compose_filename);
 587         my $in_body = 0;
 588         my $summary_empty = 1;
 589         while(<C>) {
 590                 next if m/^GIT:/;
 591                 if ($in_body) {
 592                         $summary_empty = 0 unless (/^\n$/);
 593                 } elsif (/^\n$/) {
 594                         $in_body = 1;
 595                         if ($need_8bit_cte) {
 596                                 print C2 "MIME-Version: 1.0\n",
 597                                          "Content-Type: text/plain; ",
 598                                            "charset=UTF-8\n",
 599                                          "Content-Transfer-Encoding: 8bit\n";
 600                         }
 601                 } elsif (/^MIME-Version:/i) {
 602                         $need_8bit_cte = 0;
 603                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 604                         $initial_subject = $1;
 605                         my $subject = $initial_subject;
 606                         $_ = "Subject: " .
 607                                 ($subject =~ /[^[:ascii:]]/ ?
 608                                  quote_rfc2047($subject) :
 609                                  $subject) .
 610                                 "\n";
 611                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 612                         $initial_reply_to = $1;
 613                         next;
 614                 } elsif (/^From:\s*(.+)\s*$/i) {
 615                         $sender = $1;
 616                         next;
 617                 } elsif (/^(?:To|Cc|Bcc):/i) {
 618                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 619                         next;
 620                 }
 621                 print C2 $_;
 622         }
 623         close(C);
 624         close(C2);
 625
 626         if ($summary_empty) {
 627                 print "Summary email is empty, skipping it\n";
 628                 $compose = -1;
 629         }
 630 } elsif ($annotate) {
 631         do_edit(@files);
 632 }
 633
 634 sub ask {
 635         my ($prompt, %arg) = @_;
 636         my $valid_re = $arg{valid_re};
 637         my $default = $arg{default};
 638         my $resp;
 639         my $i = 0;
 640         return defined $default ? $default : undef
 641                 unless defined $term->IN and defined fileno($term->IN) and
 642                        defined $term->OUT and defined fileno($term->OUT);
 643         while ($i++ < 10) {
 644                 $resp = $term->readline($prompt);
 645                 if (!defined $resp) { # EOF
 646                         print "\n";
 647                         return defined $default ? $default : undef;
 648                 }
 649                 if ($resp eq '' and defined $default) {
 650                         return $default;
 651                 }
 652                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 653                         return $resp;
 654                 }
 655         }
 656         return undef;
 657 }
 658
 659 my $prompting = 0;
 660 if (!defined $sender) {
 661         $sender = $repoauthor || $repocommitter || '';
 662         $sender = ask("Who should the emails appear to be from? [$sender] ",
 663                       default => $sender);
 664         print "Emails will be sent from: ", $sender, "\n";
 665         $prompting++;
 666 }
 667
 668 if (!@to) {
 669         my $to = ask("Who should the emails be sent to? ");
 670         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 671         $prompting++;
 672 }
 673
 674 sub expand_aliases {
 675         return map { expand_one_alias($_) } @_;
 676 }
 677
 678 my %EXPANDED_ALIASES;
 679 sub expand_one_alias {
 680         my $alias = shift;
 681         if ($EXPANDED_ALIASES{$alias}) {
 682                 die "fatal: alias '$alias' expands to itself\n";
 683         }
 684         local $EXPANDED_ALIASES{$alias} = 1;
 685         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 686 }
 687
 688 @to = expand_aliases(@to);
 689 @to = (map { sanitize_address($_) } @to);
 690 @initial_cc = expand_aliases(@initial_cc);
 691 @bcclist = expand_aliases(@bcclist);
 692
 693 if ($thread && !defined $initial_reply_to && $prompting) {
 694         $initial_reply_to = ask(
 695                 "Message-ID to be used as In-Reply-To for the first email? ");
 696 }
 697 if (defined $initial_reply_to) {
 698         $initial_reply_to =~ s/^\s*<?//;
 699         $initial_reply_to =~ s/>?\s*$//;
 700         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 701 }
 702
 703 if (!defined $smtp_server) {
 704         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 705                 if (-x $_) {
 706                         $smtp_server = $_;
 707                         last;
 708                 }
 709         }
 710         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 711 }
 712
 713 if ($compose && $compose > 0) {
 714         @files = ($compose_filename . ".final", @files);
 715 }
 716
 717 # Variables we set as part of the loop over files
 718 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 719         $needs_confirm, $message_num, $ask_default);
 720
 721 sub extract_valid_address {
 722         my $address = shift;
 723         my $local_part_regexp = '[^<>"\s@]+';
 724         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 725
 726         # check for a local address:
 727         return $address if ($address =~ /^($local_part_regexp)$/);
 728
 729         $address =~ s/^\s*<(.*)>\s*$/$1/;
 730         if ($have_email_valid) {
 731                 return scalar Email::Valid->address($address);
 732         } else {
 733                 # less robust/correct than the monster regexp in Email::Valid,
 734                 # but still does a 99% job, and one less dependency
 735                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 736                 return $1;
 737         }
 738 }
 739
 740 # Usually don't need to change anything below here.
 741
 742 # we make a "fake" message id by taking the current number
 743 # of seconds since the beginning of Unix time and tacking on
 744 # a random number to the end, in case we are called quicker than
 745 # 1 second since the last time we were called.
 746
 747 # We'll setup a template for the message id, using the "from" address:
 748
 749 my ($message_id_stamp, $message_id_serial);
 750 sub make_message_id
 751 {
 752         my $uniq;
 753         if (!defined $message_id_stamp) {
 754                 $message_id_stamp = sprintf("%s-%s", time, $$);
 755                 $message_id_serial = 0;
 756         }
 757         $message_id_serial++;
 758         $uniq = "$message_id_stamp-$message_id_serial";
 759
 760         my $du_part;
 761         for ($sender, $repocommitter, $repoauthor) {
 762                 $du_part = extract_valid_address(sanitize_address($_));
 763                 last if (defined $du_part and $du_part ne '');
 764         }
 765         if (not defined $du_part or $du_part eq '') {
 766                 use Sys::Hostname qw();
 767                 $du_part = 'user@' . Sys::Hostname::hostname();
 768         }
 769         my $message_id_template = "<%s-git-send-email-%s>";
 770         $message_id = sprintf($message_id_template, $uniq, $du_part);
 771         #print "new message id = $message_id\n"; # Was useful for debugging
 772 }
 773
 774
 775
 776 $time = time - scalar $#files;
 777
 778 sub unquote_rfc2047 {
 779         local ($_) = @_;
 780         my $encoding;
 781         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 782                 $encoding = $1;
 783                 s/_/ /g;
 784                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 785         }
 786         return wantarray ? ($_, $encoding) : $_;
 787 }
 788
 789 sub quote_rfc2047 {
 790         local $_ = shift;
 791         my $encoding = shift || 'UTF-8';
 792         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 793         s/(.*)/=\?$encoding\?q\?$1\?=/;
 794         return $_;
 795 }
 796
 797 sub is_rfc2047_quoted {
 798         my $s = shift;
 799         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 800         my $encoded_text = '[!->@-~]+';
 801         length($s) <= 75 &&
 802         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 803 }
 804
 805 # use the simplest quoting being able to handle the recipient
 806 sub sanitize_address
 807 {
 808         my ($recipient) = @_;
 809         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 810
 811         if (not $recipient_name) {
 812                 return "$recipient";
 813         }
 814
 815         # if recipient_name is already quoted, do nothing
 816         if (is_rfc2047_quoted($recipient_name)) {
 817                 return $recipient;
 818         }
 819
 820         # rfc2047 is needed if a non-ascii char is included
 821         if ($recipient_name =~ /[^[:ascii:]]/) {
 822                 $recipient_name =~ s/^"(.*)"$/$1/;
 823                 $recipient_name = quote_rfc2047($recipient_name);
 824         }
 825
 826         # double quotes are needed if specials or CTLs are included
 827         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 828                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 829                 $recipient_name = "\"$recipient_name\"";
 830         }
 831
 832         return "$recipient_name $recipient_addr";
 833
 834 }
 835
 836 # Returns 1 if the message was sent, and 0 otherwise.
 837 # In actuality, the whole program dies when there
 838 # is an error sending a message.
 839
 840 sub send_message
 841 {
 842         my @recipients = unique_email_list(@to);
 843         @cc = (grep { my $cc = extract_valid_address($_);
 844                       not grep { $cc eq $_ } @recipients
 845                     }
 846                map { sanitize_address($_) }
 847                @cc);
 848         my $to = join (",\n\t", @recipients);
 849         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 850         @recipients = (map { extract_valid_address($_) } @recipients);
 851         my $date = format_2822_time($time++);
 852         my $gitversion = '@@GIT_VERSION@@';
 853         if ($gitversion =~ m/..GIT_VERSION../) {
 854             $gitversion = Git::version();
 855         }
 856
 857         my $cc = join(",\n\t", unique_email_list(@cc));
 858         my $ccline = "";
 859         if ($cc ne '') {
 860                 $ccline = "\nCc: $cc";
 861         }
 862         my $sanitized_sender = sanitize_address($sender);
 863         make_message_id() unless defined($message_id);
 864
 865         my $header = "From: $sanitized_sender
 866 To: $to${ccline}
 867 Subject: $subject
 868 Date: $date
 869 Message-Id: $message_id
 870 X-Mailer: git-send-email $gitversion
 871 ";
 872         if ($reply_to) {
 873
 874                 $header .= "In-Reply-To: $reply_to\n";
 875                 $header .= "References: $references\n";
 876         }
 877         if (@xh) {
 878                 $header .= join("\n", @xh) . "\n";
 879         }
 880
 881         my @sendmail_parameters = ('-i', @recipients);
 882         my $raw_from = $sanitized_sender;
 883         if (defined $envelope_sender && $envelope_sender ne "auto") {
 884                 $raw_from = $envelope_sender;
 885         }
 886         $raw_from = extract_valid_address($raw_from);
 887         unshift (@sendmail_parameters,
 888                         '-f', $raw_from) if(defined $envelope_sender);
 889
 890         if ($needs_confirm && !$dry_run) {
 891                 print "\n$header\n";
 892                 if ($needs_confirm eq "inform") {
 893                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 894                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 895                         print "    The Cc list above has been expanded by additional\n";
 896                         print "    addresses found in the patch commit message. By default\n";
 897                         print "    send-email prompts before sending whenever this occurs.\n";
 898                         print "    This behavior is controlled by the sendemail.confirm\n";
 899                         print "    configuration setting.\n";
 900                         print "\n";
 901                         print "    For additional information, run 'git send-email --help'.\n";
 902                         print "    To retain the current behavior, but squelch this message,\n";
 903                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 904                 }
 905                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 906                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 907                          default => $ask_default);
 908                 die "Send this email reply required" unless defined $_;
 909                 if (/^n/i) {
 910                         return 0;
 911                 } elsif (/^q/i) {
 912                         cleanup_compose_files();
 913                         exit(0);
 914                 } elsif (/^a/i) {
 915                         $confirm = 'never';
 916                 }
 917         }
 918
 919         if ($dry_run) {
 920                 # We don't want to send the email.
 921         } elsif ($smtp_server =~ m#^/#) {
 922                 my $pid = open my $sm, '|-';
 923                 defined $pid or die $!;
 924                 if (!$pid) {
 925                         exec($smtp_server, @sendmail_parameters) or die $!;
 926                 }
 927                 print $sm "$header\n$message";
 928                 close $sm or die $?;
 929         } else {
 930
 931                 if (!defined $smtp_server) {
 932                         die "The required SMTP server is not properly defined."
 933                 }
 934
 935                 if ($smtp_encryption eq 'ssl') {
 936                         $smtp_server_port ||= 465; # ssmtp
 937                         require Net::SMTP::SSL;
 938                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 939                 }
 940                 else {
 941                         require Net::SMTP;
 942                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 943                                                  ? "$smtp_server:$smtp_server_port"
 944                                                  : $smtp_server);
 945                         if ($smtp_encryption eq 'tls' && $smtp) {
 946                                 require Net::SMTP::SSL;
 947                                 $smtp->command('STARTTLS');
 948                                 $smtp->response();
 949                                 if ($smtp->code == 220) {
 950                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 951                                                 or die "STARTTLS failed! ".$smtp->message;
 952                                         $smtp_encryption = '';
 953                                         # Send EHLO again to receive fresh
 954                                         # supported commands
 955                                         $smtp->hello();
 956                                 } else {
 957                                         die "Server does not support STARTTLS! ".$smtp->message;
 958                                 }
 959                         }
 960                 }
 961
 962                 if (!$smtp) {
 963                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 964                 }
 965
 966                 if (defined $smtp_authuser) {
 967
 968                         if (!defined $smtp_authpass) {
 969
 970                                 system "stty -echo";
 971
 972                                 do {
 973                                         print "Password: ";
 974                                         $_ = <STDIN>;
 975                                         print "\n";
 976                                 } while (!defined $_);
 977
 978                                 chomp($smtp_authpass = $_);
 979
 980                                 system "stty echo";
 981                         }
 982
 983                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 984                 }
 985
 986                 $smtp->mail( $raw_from ) or die $smtp->message;
 987                 $smtp->to( @recipients ) or die $smtp->message;
 988                 $smtp->data or die $smtp->message;
 989                 $smtp->datasend("$header\n$message") or die $smtp->message;
 990                 $smtp->dataend() or die $smtp->message;
 991                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 992         }
 993         if ($quiet) {
 994                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 995         } else {
 996                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 997                 if ($smtp_server !~ m#^/#) {
 998                         print "Server: $smtp_server\n";
 999                         print "MAIL FROM:<$raw_from>\n";
1000                         foreach my $entry (@recipients) {
1001                             print "RCPT TO:<$entry>\n";
1002                         }
1003                 } else {
1004                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1005                 }
1006                 print $header, "\n";
1007                 if ($smtp) {
1008                         print "Result: ", $smtp->code, ' ',
1009                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1010                 } else {
1011                         print "Result: OK\n";
1012                 }
1013         }
1014
1015         return 1;
1016 }
1017
1018 $reply_to = $initial_reply_to;
1019 $references = $initial_reply_to || '';
1020 $subject = $initial_subject;
1021 $message_num = 0;
1022
1023 foreach my $t (@files) {
1024         open(F,"<",$t) or die "can't open file $t";
1025
1026         my $author = undef;
1027         my $author_encoding;
1028         my $has_content_type;
1029         my $body_encoding;
1030         @cc = ();
1031         @xh = ();
1032         my $input_format = undef;
1033         my @header = ();
1034         $message = "";
1035         $message_num++;
1036         # First unfold multiline header fields
1037         while(<F>) {
1038                 last if /^\s*$/;
1039                 if (/^\s+\S/ and @header) {
1040                         chomp($header[$#header]);
1041                         s/^\s+/ /;
1042                         $header[$#header] .= $_;
1043             } else {
1044                         push(@header, $_);
1045                 }
1046         }
1047         # Now parse the header
1048         foreach(@header) {
1049                 if (/^From /) {
1050                         $input_format = 'mbox';
1051                         next;
1052                 }
1053                 chomp;
1054                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1055                         $input_format = 'mbox';
1056                 }
1057
1058                 if (defined $input_format && $input_format eq 'mbox') {
1059                         if (/^Subject:\s+(.*)$/) {
1060                                 $subject = $1;
1061                         }
1062                         elsif (/^From:\s+(.*)$/) {
1063                                 ($author, $author_encoding) = unquote_rfc2047($1);
1064                                 next if $suppress_cc{'author'};
1065                                 next if $suppress_cc{'self'} and $author eq $sender;
1066                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1067                                         $1, $_) unless $quiet;
1068                                 push @cc, $1;
1069                         }
1070                         elsif (/^Cc:\s+(.*)$/) {
1071                                 foreach my $addr (parse_address_line($1)) {
1072                                         if (unquote_rfc2047($addr) eq $sender) {
1073                                                 next if ($suppress_cc{'self'});
1074                                         } else {
1075                                                 next if ($suppress_cc{'cc'});
1076                                         }
1077                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1078                                                 $addr, $_) unless $quiet;
1079                                         push @cc, $addr;
1080                                 }
1081                         }
1082                         elsif (/^Content-type:/i) {
1083                                 $has_content_type = 1;
1084                                 if (/charset="?([^ "]+)/) {
1085                                         $body_encoding = $1;
1086                                 }
1087                                 push @xh, $_;
1088                         }
1089                         elsif (/^Message-Id: (.*)/i) {
1090                                 $message_id = $1;
1091                         }
1092                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1093                                 push @xh, $_;
1094                         }
1095
1096                 } else {
1097                         # In the traditional
1098                         # "send lots of email" format,
1099                         # line 1 = cc
1100                         # line 2 = subject
1101                         # So let's support that, too.
1102                         $input_format = 'lots';
1103                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1104                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1105                                         $_, $_) unless $quiet;
1106                                 push @cc, $_;
1107                         } elsif (!defined $subject) {
1108                                 $subject = $_;
1109                         }
1110                 }
1111         }
1112         # Now parse the message body
1113         while(<F>) {
1114                 $message .=  $_;
1115                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1116                         chomp;
1117                         my ($what, $c) = ($1, $2);
1118                         chomp $c;
1119                         if ($c eq $sender) {
1120                                 next if ($suppress_cc{'self'});
1121                         } else {
1122                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1123                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1124                         }
1125                         push @cc, $c;
1126                         printf("(body) Adding cc: %s from line '%s'\n",
1127                                 $c, $_) unless $quiet;
1128                 }
1129         }
1130         close F;
1131
1132         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1133                 open(F, "$cc_cmd \Q$t\E |")
1134                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1135                 while(<F>) {
1136                         my $c = $_;
1137                         $c =~ s/^\s*//g;
1138                         $c =~ s/\n$//g;
1139                         next if ($c eq $sender and $suppress_from);
1140                         push @cc, $c;
1141                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1142                                 $c, $cc_cmd) unless $quiet;
1143                 }
1144                 close F
1145                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1146         }
1147
1148         if (defined $author and $author ne $sender) {
1149                 $message = "From: $author\n\n$message";
1150                 if (defined $author_encoding) {
1151                         if ($has_content_type) {
1152                                 if ($body_encoding eq $author_encoding) {
1153                                         # ok, we already have the right encoding
1154                                 }
1155                                 else {
1156                                         # uh oh, we should re-encode
1157                                 }
1158                         }
1159                         else {
1160                                 push @xh,
1161                                   'MIME-Version: 1.0',
1162                                   "Content-Type: text/plain; charset=$author_encoding",
1163                                   'Content-Transfer-Encoding: 8bit';
1164                         }
1165                 }
1166         }
1167
1168         $needs_confirm = (
1169                 $confirm eq "always" or
1170                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1171                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1172         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1173
1174         @cc = (@initial_cc, @cc);
1175
1176         my $message_was_sent = send_message();
1177
1178         # set up for the next message
1179         if ($thread && $message_was_sent &&
1180                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1181                 $reply_to = $message_id;
1182                 if (length $references > 0) {
1183                         $references .= "\n $message_id";
1184                 } else {
1185                         $references = "$message_id";
1186                 }
1187         }
1188         $message_id = undef;
1189 }
1190
1191 cleanup_compose_files();
1192
1193 sub cleanup_compose_files() {
1194         unlink($compose_filename, $compose_filename . ".final") if $compose;
1195 }
1196
1197 $smtp->quit if $smtp;
1198
1199 sub unique_email_list(@) {
1200         my %seen;
1201         my @emails;
1202
1203         foreach my $entry (@_) {
1204                 if (my $clean = extract_valid_address($entry)) {
1205                         $seen{$clean} ||= 0;
1206                         next if $seen{$clean}++;
1207                         push @emails, $entry;
1208                 } else {
1209                         print STDERR "W: unable to extract a valid address",
1210                                         " from: $entry\n";
1211                 }
1212         }
1213         return @emails;
1214 }
1215
1216 sub validate_patch {
1217         my $fn = shift;
1218         open(my $fh, '<', $fn)
1219                 or die "unable to open $fn: $!\n";
1220         while (my $line = <$fh>) {
1221                 if (length($line) > 998) {
1222                         return "$.: patch contains a line longer than 998 characters";
1223                 }
1224         }
1225         return undef;
1226 }
1227
1228 sub file_has_nonascii {
1229         my $fn = shift;
1230         open(my $fh, '<', $fn)
1231                 or die "unable to open $fn: $!\n";
1232         while (my $line = <$fh>) {
1233                 return 1 if $line =~ /[^[:ascii:]]/;
1234         }
1235         return 0;
1236 }