git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-encryption Specify 'tls' for STARTTLS encryption, or 'ssl' for SSL.
  88                   Any other value disables the feature.
  89
  90    --smtp-ssl     Synonym for '--smtp-encryption=ssl'.  Deprecated.
  91
  92    --suppress-cc  Suppress the specified category of auto-CC.  The category
  93                   can be one of 'author' for the patch author, 'self' to
  94                   avoid copying yourself, 'sob' for Signed-off-by lines,
  95                   'cccmd' for the output of the cccmd, or 'all' to suppress
  96                   all of these.
  97
  98    --suppress-from Suppress sending emails to yourself. Defaults to off.
  99
 100    --thread       Specify that the "In-Reply-To:" header should be set on all
 101                   emails. Defaults to on.
 102
 103    --quiet        Make git-send-email less verbose.  One line per email
 104                   should be all that is output.
 105
 106    --dry-run      Do everything except actually send the emails.
 107
 108    --envelope-sender    Specify the envelope sender used to send the emails.
 109
 110    --no-validate        Don't perform any sanity checks on patches.
 111
 112 EOT
 113         exit(1);
 114 }
 115
 116 # most mail servers generate the Date: header, but not all...
 117 sub format_2822_time {
 118         my ($time) = @_;
 119         my @localtm = localtime($time);
 120         my @gmttm = gmtime($time);
 121         my $localmin = $localtm[1] + $localtm[2] * 60;
 122         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 123         if ($localtm[0] != $gmttm[0]) {
 124                 die "local zone differs from GMT by a non-minute interval\n";
 125         }
 126         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 127                 $localmin += 1440;
 128         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 129                 $localmin -= 1440;
 130         } elsif ($gmttm[6] != $localtm[6]) {
 131                 die "local time offset greater than or equal to 24 hours\n";
 132         }
 133         my $offset = $localmin - $gmtmin;
 134         my $offhour = $offset / 60;
 135         my $offmin = abs($offset % 60);
 136         if (abs($offhour) >= 24) {
 137                 die ("local time offset greater than or equal to 24 hours\n");
 138         }
 139
 140         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 141                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 142                        $localtm[3],
 143                        qw(Jan Feb Mar Apr May Jun
 144                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 145                        $localtm[5]+1900,
 146                        $localtm[2],
 147                        $localtm[1],
 148                        $localtm[0],
 149                        ($offset >= 0) ? '+' : '-',
 150                        abs($offhour),
 151                        $offmin,
 152                        );
 153 }
 154
 155 my $have_email_valid = eval { require Email::Valid; 1 };
 156 my $smtp;
 157 my $auth;
 158
 159 sub unique_email_list(@);
 160 sub cleanup_compose_files();
 161
 162 # Constants (essentially)
 163 my $compose_filename = ".msg.$$";
 164
 165 # Variables we fill in automatically, or via prompting:
 166 my (@to,@cc,@initial_cc,@bcclist,@xh,
 167         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 168
 169 my $envelope_sender;
 170
 171 # Example reply to:
 172 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 173
 174 my $repo = eval { Git->repository() };
 175 my @repo = $repo ? ($repo) : ();
 176 my $term = eval {
 177         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 178                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 179                 : new Term::ReadLine 'git-send-email';
 180 };
 181 if ($@) {
 182         $term = new FakeTerm "$@: going non-interactive";
 183 }
 184
 185 # Behavior modification variables
 186 my ($quiet, $dry_run) = (0, 0);
 187
 188 # Variables with corresponding config settings
 189 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 190 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 191 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 192 my ($no_validate);
 193 my (@suppress_cc);
 194
 195 my %config_bool_settings = (
 196     "thread" => [\$thread, 1],
 197     "chainreplyto" => [\$chain_reply_to, 1],
 198     "suppressfrom" => [\$suppress_from, undef],
 199     "signedoffcc" => [\$signed_off_cc, undef],
 200 );
 201
 202 my %config_settings = (
 203     "smtpserver" => \$smtp_server,
 204     "smtpserverport" => \$smtp_server_port,
 205     "smtpuser" => \$smtp_authuser,
 206     "smtppass" => \$smtp_authpass,
 207     "to" => \@to,
 208     "cc" => \@initial_cc,
 209     "cccmd" => \$cc_cmd,
 210     "aliasfiletype" => \$aliasfiletype,
 211     "bcc" => \@bcclist,
 212     "aliasesfile" => \@alias_files,
 213     "suppresscc" => \@suppress_cc,
 214     "envelopesender" => \$envelope_sender,
 215 );
 216
 217 # Handle Uncouth Termination
 218 sub signal_handler {
 219
 220         # Make text normal
 221         print color("reset"), "\n";
 222
 223         # SMTP password masked
 224         system "stty echo";
 225
 226         # tmp files from --compose
 227         if (-e $compose_filename) {
 228                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229         }
 230         if (-e ($compose_filename . ".final")) {
 231                 print "'$compose_filename.final' contains the composed email.\n"
 232         }
 233
 234         exit;
 235 };
 236
 237 $SIG{TERM} = \&signal_handler;
 238 $SIG{INT}  = \&signal_handler;
 239
 240 # Begin by accumulating all the variables (defined above), that we will end up
 241 # needing, first, from the command line:
 242
 243 my $rc = GetOptions("sender|from=s" => \$sender,
 244                     "in-reply-to=s" => \$initial_reply_to,
 245                     "subject=s" => \$initial_subject,
 246                     "to=s" => \@to,
 247                     "cc=s" => \@initial_cc,
 248                     "bcc=s" => \@bcclist,
 249                     "chain-reply-to!" => \$chain_reply_to,
 250                     "smtp-server=s" => \$smtp_server,
 251                     "smtp-server-port=s" => \$smtp_server_port,
 252                     "smtp-user=s" => \$smtp_authuser,
 253                     "smtp-pass:s" => \$smtp_authpass,
 254                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 255                     "smtp-encryption=s" => \$smtp_encryption,
 256                     "identity=s" => \$identity,
 257                     "compose" => \$compose,
 258                     "quiet" => \$quiet,
 259                     "cc-cmd=s" => \$cc_cmd,
 260                     "suppress-from!" => \$suppress_from,
 261                     "suppress-cc=s" => \@suppress_cc,
 262                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 263                     "dry-run" => \$dry_run,
 264                     "envelope-sender=s" => \$envelope_sender,
 265                     "thread!" => \$thread,
 266                     "no-validate" => \$no_validate,
 267          );
 268
 269 unless ($rc) {
 270     usage();
 271 }
 272
 273 # Now, let's fill any that aren't set in with defaults:
 274
 275 sub read_config {
 276         my ($prefix) = @_;
 277
 278         foreach my $setting (keys %config_bool_settings) {
 279                 my $target = $config_bool_settings{$setting}->[0];
 280                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 281         }
 282
 283         foreach my $setting (keys %config_settings) {
 284                 my $target = $config_settings{$setting};
 285                 if (ref($target) eq "ARRAY") {
 286                         unless (@$target) {
 287                                 my @values = Git::config(@repo, "$prefix.$setting");
 288                                 @$target = @values if (@values && defined $values[0]);
 289                         }
 290                 }
 291                 else {
 292                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 293                 }
 294         }
 295
 296         if (!defined $smtp_encryption) {
 297                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 298                 if (defined $enc) {
 299                         $smtp_encryption = $enc;
 300                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 301                         $smtp_encryption = 'ssl';
 302                 }
 303         }
 304 }
 305
 306 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 307 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 308 read_config("sendemail.$identity") if (defined $identity);
 309 read_config("sendemail");
 310
 311 # fall back on builtin bool defaults
 312 foreach my $setting (values %config_bool_settings) {
 313         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 314 }
 315
 316 # 'default' encryption is none -- this only prevents a warning
 317 $smtp_encryption = '' unless (defined $smtp_encryption);
 318
 319 # Set CC suppressions
 320 my(%suppress_cc);
 321 if (@suppress_cc) {
 322         foreach my $entry (@suppress_cc) {
 323                 die "Unknown --suppress-cc field: '$entry'\n"
 324                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 325                 $suppress_cc{$entry} = 1;
 326         }
 327 }
 328
 329 if ($suppress_cc{'all'}) {
 330         foreach my $entry (qw (ccmd cc author self sob)) {
 331                 $suppress_cc{$entry} = 1;
 332         }
 333         delete $suppress_cc{'all'};
 334 }
 335
 336 # If explicit old-style ones are specified, they trump --suppress-cc.
 337 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 338 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 339
 340 # Debugging, print out the suppressions.
 341 if (0) {
 342         print "suppressions:\n";
 343         foreach my $entry (keys %suppress_cc) {
 344                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 345         }
 346 }
 347
 348 my ($repoauthor, $repocommitter);
 349 ($repoauthor) = Git::ident_person(@repo, 'author');
 350 ($repocommitter) = Git::ident_person(@repo, 'committer');
 351
 352 # Verify the user input
 353
 354 foreach my $entry (@to) {
 355         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 356 }
 357
 358 foreach my $entry (@initial_cc) {
 359         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 360 }
 361
 362 foreach my $entry (@bcclist) {
 363         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 364 }
 365
 366 my %aliases;
 367 my %parse_alias = (
 368         # multiline formats can be supported in the future
 369         mutt => sub { my $fh = shift; while (<$fh>) {
 370                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 371                         my ($alias, $addr) = ($1, $2);
 372                         $addr =~ s/#.*$//; # mutt allows # comments
 373                          # commas delimit multiple addresses
 374                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 375                 }}},
 376         mailrc => sub { my $fh = shift; while (<$fh>) {
 377                 if (/^alias\s+(\S+)\s+(.*)$/) {
 378                         # spaces delimit multiple addresses
 379                         $aliases{$1} = [ split(/\s+/, $2) ];
 380                 }}},
 381         pine => sub { my $fh = shift; while (<$fh>) {
 382                 if (/^(\S+)\t.*\t(.*)$/) {
 383                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 384                 }}},
 385         gnus => sub { my $fh = shift; while (<$fh>) {
 386                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 387                         $aliases{$1} = [ $2 ];
 388                 }}}
 389 );
 390
 391 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 392         foreach my $file (@alias_files) {
 393                 open my $fh, '<', $file or die "opening $file: $!\n";
 394                 $parse_alias{$aliasfiletype}->($fh);
 395                 close $fh;
 396         }
 397 }
 398
 399 ($sender) = expand_aliases($sender) if defined $sender;
 400
 401 # Now that all the defaults are set, process the rest of the command line
 402 # arguments and collect up the files that need to be processed.
 403 for my $f (@ARGV) {
 404         if (-d $f) {
 405                 opendir(DH,$f)
 406                         or die "Failed to opendir $f: $!";
 407
 408                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 409                                 sort readdir(DH);
 410                 closedir(DH);
 411         } elsif (-f $f or -p $f) {
 412                 push @files, $f;
 413         } else {
 414                 print STDERR "Skipping $f - not found.\n";
 415         }
 416 }
 417
 418 if (!$no_validate) {
 419         foreach my $f (@files) {
 420                 unless (-p $f) {
 421                         my $error = validate_patch($f);
 422                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 423                 }
 424         }
 425 }
 426
 427 if (@files) {
 428         unless ($quiet) {
 429                 print $_,"\n" for (@files);
 430         }
 431 } else {
 432         print STDERR "\nNo patch files specified!\n\n";
 433         usage();
 434 }
 435
 436 my $prompting = 0;
 437 if (!defined $sender) {
 438         $sender = $repoauthor || $repocommitter || '';
 439
 440         while (1) {
 441                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 442                 last if defined $_;
 443                 print "\n";
 444         }
 445
 446         $sender = $_ if ($_);
 447         print "Emails will be sent from: ", $sender, "\n";
 448         $prompting++;
 449 }
 450
 451 if (!@to) {
 452
 453
 454         while (1) {
 455                 $_ = $term->readline("Who should the emails be sent to? ", "");
 456                 last if defined $_;
 457                 print "\n";
 458         }
 459
 460         my $to = $_;
 461         push @to, split /,\s*/, $to;
 462         $prompting++;
 463 }
 464
 465 sub expand_aliases {
 466         my @cur = @_;
 467         my @last;
 468         do {
 469                 @last = @cur;
 470                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 471         } while (join(',',@cur) ne join(',',@last));
 472         return @cur;
 473 }
 474
 475 @to = expand_aliases(@to);
 476 @to = (map { sanitize_address($_) } @to);
 477 @initial_cc = expand_aliases(@initial_cc);
 478 @bcclist = expand_aliases(@bcclist);
 479
 480 if (!defined $initial_subject && $compose) {
 481         while (1) {
 482                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 483                 last if defined $_;
 484                 print "\n";
 485         }
 486
 487         $initial_subject = $_;
 488         $prompting++;
 489 }
 490
 491 if ($thread && !defined $initial_reply_to && $prompting) {
 492         while (1) {
 493                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 494                 last if defined $_;
 495                 print "\n";
 496         }
 497
 498         $initial_reply_to = $_;
 499 }
 500 if (defined $initial_reply_to) {
 501         $initial_reply_to =~ s/^\s*<?//;
 502         $initial_reply_to =~ s/>?\s*$//;
 503         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 504 }
 505
 506 if (!defined $smtp_server) {
 507         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 508                 if (-x $_) {
 509                         $smtp_server = $_;
 510                         last;
 511                 }
 512         }
 513         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 514 }
 515
 516 if ($compose) {
 517         # Note that this does not need to be secure, but we will make a small
 518         # effort to have it be unique
 519         open(C,">",$compose_filename)
 520                 or die "Failed to open for writing $compose_filename: $!";
 521         print C "From $sender # This line is ignored.\n";
 522         printf C "Subject: %s\n\n", $initial_subject;
 523         printf C <<EOT;
 524 GIT: Please enter your email below.
 525 GIT: Lines beginning in "GIT: " will be removed.
 526 GIT: Consider including an overall diffstat or table of contents
 527 GIT: for the patch you are writing.
 528
 529 EOT
 530         close(C);
 531
 532         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 533         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 534
 535         open(C2,">",$compose_filename . ".final")
 536                 or die "Failed to open $compose_filename.final : " . $!;
 537
 538         open(C,"<",$compose_filename)
 539                 or die "Failed to open $compose_filename : " . $!;
 540
 541         my $need_8bit_cte = file_has_nonascii($compose_filename);
 542         my $in_body = 0;
 543         while(<C>) {
 544                 next if m/^GIT: /;
 545                 if (!$in_body && /^\n$/) {
 546                         $in_body = 1;
 547                         if ($need_8bit_cte) {
 548                                 print C2 "MIME-Version: 1.0\n",
 549                                          "Content-Type: text/plain; ",
 550                                            "charset=utf-8\n",
 551                                          "Content-Transfer-Encoding: 8bit\n";
 552                         }
 553                 }
 554                 if (!$in_body && /^MIME-Version:/i) {
 555                         $need_8bit_cte = 0;
 556                 }
 557                 if (!$in_body && /^Subject: ?(.*)/i) {
 558                         my $subject = $1;
 559                         $_ = "Subject: " .
 560                                 ($subject =~ /[^[:ascii:]]/ ?
 561                                  quote_rfc2047($subject) :
 562                                  $subject) .
 563                                 "\n";
 564                 }
 565                 print C2 $_;
 566         }
 567         close(C);
 568         close(C2);
 569
 570         while (1) {
 571                 $_ = $term->readline("Send this email? (y|n) ");
 572                 last if defined $_;
 573                 print "\n";
 574         }
 575
 576         if (uc substr($_,0,1) ne 'Y') {
 577                 cleanup_compose_files();
 578                 exit(0);
 579         }
 580
 581         @files = ($compose_filename . ".final", @files);
 582 }
 583
 584 # Variables we set as part of the loop over files
 585 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 586
 587 sub extract_valid_address {
 588         my $address = shift;
 589         my $local_part_regexp = '[^<>"\s@]+';
 590         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 591
 592         # check for a local address:
 593         return $address if ($address =~ /^($local_part_regexp)$/);
 594
 595         $address =~ s/^\s*<(.*)>\s*$/$1/;
 596         if ($have_email_valid) {
 597                 return scalar Email::Valid->address($address);
 598         } else {
 599                 # less robust/correct than the monster regexp in Email::Valid,
 600                 # but still does a 99% job, and one less dependency
 601                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 602                 return $1;
 603         }
 604 }
 605
 606 # Usually don't need to change anything below here.
 607
 608 # we make a "fake" message id by taking the current number
 609 # of seconds since the beginning of Unix time and tacking on
 610 # a random number to the end, in case we are called quicker than
 611 # 1 second since the last time we were called.
 612
 613 # We'll setup a template for the message id, using the "from" address:
 614
 615 my ($message_id_stamp, $message_id_serial);
 616 sub make_message_id
 617 {
 618         my $uniq;
 619         if (!defined $message_id_stamp) {
 620                 $message_id_stamp = sprintf("%s-%s", time, $$);
 621                 $message_id_serial = 0;
 622         }
 623         $message_id_serial++;
 624         $uniq = "$message_id_stamp-$message_id_serial";
 625
 626         my $du_part;
 627         for ($sender, $repocommitter, $repoauthor) {
 628                 $du_part = extract_valid_address(sanitize_address($_));
 629                 last if (defined $du_part and $du_part ne '');
 630         }
 631         if (not defined $du_part or $du_part eq '') {
 632                 use Sys::Hostname qw();
 633                 $du_part = 'user@' . Sys::Hostname::hostname();
 634         }
 635         my $message_id_template = "<%s-git-send-email-%s>";
 636         $message_id = sprintf($message_id_template, $uniq, $du_part);
 637         #print "new message id = $message_id\n"; # Was useful for debugging
 638 }
 639
 640
 641
 642 $time = time - scalar $#files;
 643
 644 sub unquote_rfc2047 {
 645         local ($_) = @_;
 646         my $encoding;
 647         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 648                 $encoding = $1;
 649                 s/_/ /g;
 650                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 651         }
 652         return wantarray ? ($_, $encoding) : $_;
 653 }
 654
 655 sub quote_rfc2047 {
 656         local $_ = shift;
 657         my $encoding = shift || 'utf-8';
 658         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 659         s/(.*)/=\?$encoding\?q\?$1\?=/;
 660         return $_;
 661 }
 662
 663 # use the simplest quoting being able to handle the recipient
 664 sub sanitize_address
 665 {
 666         my ($recipient) = @_;
 667         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 668
 669         if (not $recipient_name) {
 670                 return "$recipient";
 671         }
 672
 673         # if recipient_name is already quoted, do nothing
 674         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 675                 return $recipient;
 676         }
 677
 678         # rfc2047 is needed if a non-ascii char is included
 679         if ($recipient_name =~ /[^[:ascii:]]/) {
 680                 $recipient_name = quote_rfc2047($recipient_name);
 681         }
 682
 683         # double quotes are needed if specials or CTLs are included
 684         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 685                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 686                 $recipient_name = "\"$recipient_name\"";
 687         }
 688
 689         return "$recipient_name $recipient_addr";
 690
 691 }
 692
 693 sub send_message
 694 {
 695         my @recipients = unique_email_list(@to);
 696         @cc = (grep { my $cc = extract_valid_address($_);
 697                       not grep { $cc eq $_ } @recipients
 698                     }
 699                map { sanitize_address($_) }
 700                @cc);
 701         my $to = join (",\n\t", @recipients);
 702         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 703         @recipients = (map { extract_valid_address($_) } @recipients);
 704         my $date = format_2822_time($time++);
 705         my $gitversion = '@@GIT_VERSION@@';
 706         if ($gitversion =~ m/..GIT_VERSION../) {
 707             $gitversion = Git::version();
 708         }
 709
 710         my $cc = join(", ", unique_email_list(@cc));
 711         my $ccline = "";
 712         if ($cc ne '') {
 713                 $ccline = "\nCc: $cc";
 714         }
 715         my $sanitized_sender = sanitize_address($sender);
 716         make_message_id() unless defined($message_id);
 717
 718         my $header = "From: $sanitized_sender
 719 To: $to${ccline}
 720 Subject: $subject
 721 Date: $date
 722 Message-Id: $message_id
 723 X-Mailer: git-send-email $gitversion
 724 ";
 725         if ($thread && $reply_to) {
 726
 727                 $header .= "In-Reply-To: $reply_to\n";
 728                 $header .= "References: $references\n";
 729         }
 730         if (@xh) {
 731                 $header .= join("\n", @xh) . "\n";
 732         }
 733
 734         my @sendmail_parameters = ('-i', @recipients);
 735         my $raw_from = $sanitized_sender;
 736         $raw_from = $envelope_sender if (defined $envelope_sender);
 737         $raw_from = extract_valid_address($raw_from);
 738         unshift (@sendmail_parameters,
 739                         '-f', $raw_from) if(defined $envelope_sender);
 740
 741         if ($dry_run) {
 742                 # We don't want to send the email.
 743         } elsif ($smtp_server =~ m#^/#) {
 744                 my $pid = open my $sm, '|-';
 745                 defined $pid or die $!;
 746                 if (!$pid) {
 747                         exec($smtp_server, @sendmail_parameters) or die $!;
 748                 }
 749                 print $sm "$header\n$message";
 750                 close $sm or die $?;
 751         } else {
 752
 753                 if (!defined $smtp_server) {
 754                         die "The required SMTP server is not properly defined."
 755                 }
 756
 757                 if ($smtp_encryption eq 'ssl') {
 758                         $smtp_server_port ||= 465; # ssmtp
 759                         require Net::SMTP::SSL;
 760                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 761                 }
 762                 else {
 763                         require Net::SMTP;
 764                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 765                                                  ? "$smtp_server:$smtp_server_port"
 766                                                  : $smtp_server);
 767                         if ($smtp_encryption eq 'tls') {
 768                                 require Net::SMTP::SSL;
 769                                 $smtp->command('STARTTLS');
 770                                 $smtp->response();
 771                                 if ($smtp->code == 220) {
 772                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 773                                                 or die "STARTTLS failed! ".$smtp->message;
 774                                         $smtp_encryption = '';
 775                                         # Send EHLO again to receive fresh
 776                                         # supported commands
 777                                         $smtp->hello();
 778                                 } else {
 779                                         die "Server does not support STARTTLS! ".$smtp->message;
 780                                 }
 781                         }
 782                 }
 783
 784                 if (!$smtp) {
 785                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 786                 }
 787
 788                 if (defined $smtp_authuser) {
 789
 790                         if (!defined $smtp_authpass) {
 791
 792                                 system "stty -echo";
 793
 794                                 do {
 795                                         print "Password: ";
 796                                         $_ = <STDIN>;
 797                                         print "\n";
 798                                 } while (!defined $_);
 799
 800                                 chomp($smtp_authpass = $_);
 801
 802                                 system "stty echo";
 803                         }
 804
 805                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 806                 }
 807
 808                 $smtp->mail( $raw_from ) or die $smtp->message;
 809                 $smtp->to( @recipients ) or die $smtp->message;
 810                 $smtp->data or die $smtp->message;
 811                 $smtp->datasend("$header\n$message") or die $smtp->message;
 812                 $smtp->dataend() or die $smtp->message;
 813                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 814         }
 815         if ($quiet) {
 816                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 817         } else {
 818                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 819                 if ($smtp_server !~ m#^/#) {
 820                         print "Server: $smtp_server\n";
 821                         print "MAIL FROM:<$raw_from>\n";
 822                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 823                 } else {
 824                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 825                 }
 826                 print $header, "\n";
 827                 if ($smtp) {
 828                         print "Result: ", $smtp->code, ' ',
 829                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 830                 } else {
 831                         print "Result: OK\n";
 832                 }
 833         }
 834 }
 835
 836 $reply_to = $initial_reply_to;
 837 $references = $initial_reply_to || '';
 838 $subject = $initial_subject;
 839
 840 foreach my $t (@files) {
 841         open(F,"<",$t) or die "can't open file $t";
 842
 843         my $author = undef;
 844         my $author_encoding;
 845         my $has_content_type;
 846         my $body_encoding;
 847         @cc = @initial_cc;
 848         @xh = ();
 849         my $input_format = undef;
 850         my $header_done = 0;
 851         $message = "";
 852         while(<F>) {
 853                 if (!$header_done) {
 854                         if (/^From /) {
 855                                 $input_format = 'mbox';
 856                                 next;
 857                         }
 858                         chomp;
 859                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 860                                 $input_format = 'mbox';
 861                         }
 862
 863                         if (defined $input_format && $input_format eq 'mbox') {
 864                                 if (/^Subject:\s+(.*)$/) {
 865                                         $subject = $1;
 866
 867                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 868                                         if (unquote_rfc2047($2) eq $sender) {
 869                                                 next if ($suppress_cc{'self'});
 870                                         }
 871                                         elsif ($1 eq 'From') {
 872                                                 ($author, $author_encoding)
 873                                                   = unquote_rfc2047($2);
 874                                                 next if ($suppress_cc{'author'});
 875                                         } else {
 876                                                 next if ($suppress_cc{'cc'});
 877                                         }
 878                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 879                                                 $2, $_) unless $quiet;
 880                                         push @cc, $2;
 881                                 }
 882                                 elsif (/^Content-type:/i) {
 883                                         $has_content_type = 1;
 884                                         if (/charset="?([^ "]+)/) {
 885                                                 $body_encoding = $1;
 886                                         }
 887                                         push @xh, $_;
 888                                 }
 889                                 elsif (/^Message-Id: (.*)/i) {
 890                                         $message_id = $1;
 891                                 }
 892                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 893                                         push @xh, $_;
 894                                 }
 895
 896                         } else {
 897                                 # In the traditional
 898                                 # "send lots of email" format,
 899                                 # line 1 = cc
 900                                 # line 2 = subject
 901                                 # So let's support that, too.
 902                                 $input_format = 'lots';
 903                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 904                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 905                                                 $_, $_) unless $quiet;
 906
 907                                         push @cc, $_;
 908
 909                                 } elsif (!defined $subject) {
 910                                         $subject = $_;
 911                                 }
 912                         }
 913
 914                         # A whitespace line will terminate the headers
 915                         if (m/^\s*$/) {
 916                                 $header_done = 1;
 917                         }
 918                 } else {
 919                         $message .=  $_;
 920                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 921                                 next if ($suppress_cc{'sob'});
 922                                 chomp;
 923                                 my $c = $2;
 924                                 chomp $c;
 925                                 next if ($c eq $sender and $suppress_cc{'self'});
 926                                 push @cc, $c;
 927                                 printf("(sob) Adding cc: %s from line '%s'\n",
 928                                         $c, $_) unless $quiet;
 929                         }
 930                 }
 931         }
 932         close F;
 933
 934         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 935                 open(F, "$cc_cmd $t |")
 936                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 937                 while(<F>) {
 938                         my $c = $_;
 939                         $c =~ s/^\s*//g;
 940                         $c =~ s/\n$//g;
 941                         next if ($c eq $sender and $suppress_from);
 942                         push @cc, $c;
 943                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 944                                 $c, $cc_cmd) unless $quiet;
 945                 }
 946                 close F
 947                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 948         }
 949
 950         if (defined $author) {
 951                 $message = "From: $author\n\n$message";
 952                 if (defined $author_encoding) {
 953                         if ($has_content_type) {
 954                                 if ($body_encoding eq $author_encoding) {
 955                                         # ok, we already have the right encoding
 956                                 }
 957                                 else {
 958                                         # uh oh, we should re-encode
 959                                 }
 960                         }
 961                         else {
 962                                 push @xh,
 963                                   'MIME-Version: 1.0',
 964                                   "Content-Type: text/plain; charset=$author_encoding",
 965                                   'Content-Transfer-Encoding: 8bit';
 966                         }
 967                 }
 968         }
 969
 970         send_message();
 971
 972         # set up for the next message
 973         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 974                 $reply_to = $message_id;
 975                 if (length $references > 0) {
 976                         $references .= "\n $message_id";
 977                 } else {
 978                         $references = "$message_id";
 979                 }
 980         }
 981         $message_id = undef;
 982 }
 983
 984 if ($compose) {
 985         cleanup_compose_files();
 986 }
 987
 988 sub cleanup_compose_files() {
 989         unlink($compose_filename, $compose_filename . ".final");
 990
 991 }
 992
 993 $smtp->quit if $smtp;
 994
 995 sub unique_email_list(@) {
 996         my %seen;
 997         my @emails;
 998
 999         foreach my $entry (@_) {
1000                 if (my $clean = extract_valid_address($entry)) {
1001                         $seen{$clean} ||= 0;
1002                         next if $seen{$clean}++;
1003                         push @emails, $entry;
1004                 } else {
1005                         print STDERR "W: unable to extract a valid address",
1006                                         " from: $entry\n";
1007                 }
1008         }
1009         return @emails;
1010 }
1011
1012 sub validate_patch {
1013         my $fn = shift;
1014         open(my $fh, '<', $fn)
1015                 or die "unable to open $fn: $!\n";
1016         while (my $line = <$fh>) {
1017                 if (length($line) > 998) {
1018                         return "$.: patch contains a line longer than 998 characters";
1019                 }
1020         }
1021         return undef;
1022 }
1023
1024 sub file_has_nonascii {
1025         my $fn = shift;
1026         open(my $fh, '<', $fn)
1027                 or die "unable to open $fn: $!\n";
1028         while (my $line = <$fh>) {
1029                 return 1 if $line =~ /[^[:ascii:]]/;
1030         }
1031         return 0;
1032 }