git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 package FakeTerm;
  28 sub new {
  29         my ($class, $reason) = @_;
  30         return bless \$reason, shift;
  31 }
  32 sub readline {
  33         my $self = shift;
  34         die "Cannot use readline on FakeTerm: $$self";
  35 }
  36 package main;
  37
  38
  39 sub usage {
  40         print <<EOT;
  41 git-send-email [options] <file | directory>...
  42 Options:
  43    --from         Specify the "From:" line of the email to be sent.
  44
  45    --to           Specify the primary "To:" line of the email.
  46
  47    --cc           Specify an initial "Cc:" list for the entire series
  48                   of emails.
  49
  50    --cc-cmd       Specify a command to execute per file which adds
  51                   per file specific cc address entries
  52
  53    --bcc          Specify a list of email addresses that should be Bcc:
  54                   on all the emails.
  55
  56    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  57                   an introductory message for the patch series.
  58
  59    --subject      Specify the initial "Subject:" line.
  60                   Only necessary if --compose is also set.  If --compose
  61                   is not set, this will be prompted for.
  62
  63    --in-reply-to  Specify the first "In-Reply-To:" header line.
  64                   Only used if --compose is also set.  If --compose is not
  65                   set, this will be prompted for.
  66
  67    --chain-reply-to If set, the replies will all be to the previous
  68                   email sent, rather than to the first email sent.
  69                   Defaults to on.
  70
  71    --signed-off-cc Automatically add email addresses that appear in
  72                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  73
  74    --identity     The configuration identity, a subsection to prioritise over
  75                   the default section.
  76
  77    --smtp-server  If set, specifies the outgoing SMTP server to use.
  78                   Defaults to localhost.  Port number can be specified here with
  79                   hostname:port format or by using --smtp-server-port option.
  80
  81    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  82
  83    --smtp-user    The username for SMTP-AUTH.
  84
  85    --smtp-pass    The password for SMTP-AUTH.
  86
  87    --smtp-ssl     If set, connects to the SMTP server using SSL.
  88
  89    --suppress-cc  Suppress the specified category of auto-CC.  The category
  90                   can be one of 'author' for the patch author, 'self' to
  91                   avoid copying yourself, 'sob' for Signed-off-by lines,
  92                   'cccmd' for the output of the cccmd, or 'all' to suppress
  93                   all of these.
  94
  95    --suppress-from Suppress sending emails to yourself. Defaults to off.
  96
  97    --thread       Specify that the "In-Reply-To:" header should be set on all
  98                   emails. Defaults to on.
  99
 100    --quiet        Make git-send-email less verbose.  One line per email
 101                   should be all that is output.
 102
 103    --dry-run      Do everything except actually send the emails.
 104
 105    --envelope-sender    Specify the envelope sender used to send the emails.
 106
 107    --no-validate        Don't perform any sanity checks on patches.
 108
 109 EOT
 110         exit(1);
 111 }
 112
 113 # most mail servers generate the Date: header, but not all...
 114 sub format_2822_time {
 115         my ($time) = @_;
 116         my @localtm = localtime($time);
 117         my @gmttm = gmtime($time);
 118         my $localmin = $localtm[1] + $localtm[2] * 60;
 119         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 120         if ($localtm[0] != $gmttm[0]) {
 121                 die "local zone differs from GMT by a non-minute interval\n";
 122         }
 123         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 124                 $localmin += 1440;
 125         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 126                 $localmin -= 1440;
 127         } elsif ($gmttm[6] != $localtm[6]) {
 128                 die "local time offset greater than or equal to 24 hours\n";
 129         }
 130         my $offset = $localmin - $gmtmin;
 131         my $offhour = $offset / 60;
 132         my $offmin = abs($offset % 60);
 133         if (abs($offhour) >= 24) {
 134                 die ("local time offset greater than or equal to 24 hours\n");
 135         }
 136
 137         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 138                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 139                        $localtm[3],
 140                        qw(Jan Feb Mar Apr May Jun
 141                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 142                        $localtm[5]+1900,
 143                        $localtm[2],
 144                        $localtm[1],
 145                        $localtm[0],
 146                        ($offset >= 0) ? '+' : '-',
 147                        abs($offhour),
 148                        $offmin,
 149                        );
 150 }
 151
 152 my $have_email_valid = eval { require Email::Valid; 1 };
 153 my $smtp;
 154 my $auth;
 155
 156 sub unique_email_list(@);
 157 sub cleanup_compose_files();
 158
 159 # Constants (essentially)
 160 my $compose_filename = ".msg.$$";
 161
 162 # Variables we fill in automatically, or via prompting:
 163 my (@to,@cc,@initial_cc,@bcclist,@xh,
 164         $initial_reply_to,$initial_subject,@files,$author,$sender,$smtp_authpass,$compose,$time);
 165
 166 my $envelope_sender;
 167
 168 # Example reply to:
 169 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 170
 171 my $repo = eval { Git->repository() };
 172 my @repo = $repo ? ($repo) : ();
 173 my $term = eval {
 174         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 175                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 176                 : new Term::ReadLine 'git-send-email';
 177 };
 178 if ($@) {
 179         $term = new FakeTerm "$@: going non-interactive";
 180 }
 181
 182 # Behavior modification variables
 183 my ($quiet, $dry_run) = (0, 0);
 184
 185 # Variables with corresponding config settings
 186 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 187 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_ssl);
 188 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 189 my ($no_validate);
 190 my (@suppress_cc);
 191
 192 my %config_bool_settings = (
 193     "thread" => [\$thread, 1],
 194     "chainreplyto" => [\$chain_reply_to, 1],
 195     "suppressfrom" => [\$suppress_from, undef],
 196     "signedoffcc" => [\$signed_off_cc, undef],
 197     "smtpssl" => [\$smtp_ssl, 0],
 198 );
 199
 200 my %config_settings = (
 201     "smtpserver" => \$smtp_server,
 202     "smtpserverport" => \$smtp_server_port,
 203     "smtpuser" => \$smtp_authuser,
 204     "smtppass" => \$smtp_authpass,
 205     "to" => \@to,
 206     "cc" => \@initial_cc,
 207     "cccmd" => \$cc_cmd,
 208     "aliasfiletype" => \$aliasfiletype,
 209     "bcc" => \@bcclist,
 210     "aliasesfile" => \@alias_files,
 211     "suppresscc" => \@suppress_cc,
 212     "envelopesender" => \$envelope_sender,
 213 );
 214
 215 # Handle Uncouth Termination
 216 sub signal_handler {
 217
 218         # Make text normal
 219         print color("reset"), "\n";
 220
 221         # SMTP password masked
 222         system "stty echo";
 223
 224         # tmp files from --compose
 225         if (-e $compose_filename) {
 226                 print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 227         }
 228         if (-e ($compose_filename . ".final")) {
 229                 print "'$compose_filename.final' contains the composed email.\n"
 230         }
 231
 232         exit;
 233 };
 234
 235 $SIG{TERM} = \&signal_handler;
 236 $SIG{INT}  = \&signal_handler;
 237
 238 # Begin by accumulating all the variables (defined above), that we will end up
 239 # needing, first, from the command line:
 240
 241 my $rc = GetOptions("sender|from=s" => \$sender,
 242                     "in-reply-to=s" => \$initial_reply_to,
 243                     "subject=s" => \$initial_subject,
 244                     "to=s" => \@to,
 245                     "cc=s" => \@initial_cc,
 246                     "bcc=s" => \@bcclist,
 247                     "chain-reply-to!" => \$chain_reply_to,
 248                     "smtp-server=s" => \$smtp_server,
 249                     "smtp-server-port=s" => \$smtp_server_port,
 250                     "smtp-user=s" => \$smtp_authuser,
 251                     "smtp-pass:s" => \$smtp_authpass,
 252                     "smtp-ssl!" => \$smtp_ssl,
 253                     "identity=s" => \$identity,
 254                     "compose" => \$compose,
 255                     "quiet" => \$quiet,
 256                     "cc-cmd=s" => \$cc_cmd,
 257                     "suppress-from!" => \$suppress_from,
 258                     "suppress-cc=s" => \@suppress_cc,
 259                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 260                     "dry-run" => \$dry_run,
 261                     "envelope-sender=s" => \$envelope_sender,
 262                     "thread!" => \$thread,
 263                     "no-validate" => \$no_validate,
 264          );
 265
 266 unless ($rc) {
 267     usage();
 268 }
 269
 270 # Now, let's fill any that aren't set in with defaults:
 271
 272 sub read_config {
 273         my ($prefix) = @_;
 274
 275         foreach my $setting (keys %config_bool_settings) {
 276                 my $target = $config_bool_settings{$setting}->[0];
 277                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 278         }
 279
 280         foreach my $setting (keys %config_settings) {
 281                 my $target = $config_settings{$setting};
 282                 if (ref($target) eq "ARRAY") {
 283                         unless (@$target) {
 284                                 my @values = Git::config(@repo, "$prefix.$setting");
 285                                 @$target = @values if (@values && defined $values[0]);
 286                         }
 287                 }
 288                 else {
 289                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 290                 }
 291         }
 292 }
 293
 294 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 295 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 296 read_config("sendemail.$identity") if (defined $identity);
 297 read_config("sendemail");
 298
 299 # fall back on builtin bool defaults
 300 foreach my $setting (values %config_bool_settings) {
 301         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 302 }
 303
 304 # Set CC suppressions
 305 my(%suppress_cc);
 306 if (@suppress_cc) {
 307         foreach my $entry (@suppress_cc) {
 308                 die "Unknown --suppress-cc field: '$entry'\n"
 309                         unless $entry =~ /^(all|cccmd|cc|author|self|sob)$/;
 310                 $suppress_cc{$entry} = 1;
 311         }
 312 }
 313
 314 if ($suppress_cc{'all'}) {
 315         foreach my $entry (qw (ccmd cc author self sob)) {
 316                 $suppress_cc{$entry} = 1;
 317         }
 318         delete $suppress_cc{'all'};
 319 }
 320
 321 # If explicit old-style ones are specified, they trump --suppress-cc.
 322 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 323 $suppress_cc{'sob'} = !$signed_off_cc if defined $signed_off_cc;
 324
 325 # Debugging, print out the suppressions.
 326 if (0) {
 327         print "suppressions:\n";
 328         foreach my $entry (keys %suppress_cc) {
 329                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 330         }
 331 }
 332
 333 my ($repoauthor, $repocommitter);
 334 ($repoauthor) = Git::ident_person(@repo, 'author');
 335 ($repocommitter) = Git::ident_person(@repo, 'committer');
 336
 337 # Verify the user input
 338
 339 foreach my $entry (@to) {
 340         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 341 }
 342
 343 foreach my $entry (@initial_cc) {
 344         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 345 }
 346
 347 foreach my $entry (@bcclist) {
 348         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 349 }
 350
 351 my %aliases;
 352 my %parse_alias = (
 353         # multiline formats can be supported in the future
 354         mutt => sub { my $fh = shift; while (<$fh>) {
 355                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 356                         my ($alias, $addr) = ($1, $2);
 357                         $addr =~ s/#.*$//; # mutt allows # comments
 358                          # commas delimit multiple addresses
 359                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 360                 }}},
 361         mailrc => sub { my $fh = shift; while (<$fh>) {
 362                 if (/^alias\s+(\S+)\s+(.*)$/) {
 363                         # spaces delimit multiple addresses
 364                         $aliases{$1} = [ split(/\s+/, $2) ];
 365                 }}},
 366         pine => sub { my $fh = shift; while (<$fh>) {
 367                 if (/^(\S+)\t.*\t(.*)$/) {
 368                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 369                 }}},
 370         gnus => sub { my $fh = shift; while (<$fh>) {
 371                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 372                         $aliases{$1} = [ $2 ];
 373                 }}}
 374 );
 375
 376 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 377         foreach my $file (@alias_files) {
 378                 open my $fh, '<', $file or die "opening $file: $!\n";
 379                 $parse_alias{$aliasfiletype}->($fh);
 380                 close $fh;
 381         }
 382 }
 383
 384 ($sender) = expand_aliases($sender) if defined $sender;
 385
 386 # Now that all the defaults are set, process the rest of the command line
 387 # arguments and collect up the files that need to be processed.
 388 for my $f (@ARGV) {
 389         if (-d $f) {
 390                 opendir(DH,$f)
 391                         or die "Failed to opendir $f: $!";
 392
 393                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 394                                 sort readdir(DH);
 395
 396         } elsif (-f $f) {
 397                 push @files, $f;
 398
 399         } else {
 400                 print STDERR "Skipping $f - not found.\n";
 401         }
 402 }
 403
 404 if (!$no_validate) {
 405         foreach my $f (@files) {
 406                 my $error = validate_patch($f);
 407                 $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 408         }
 409 }
 410
 411 if (@files) {
 412         unless ($quiet) {
 413                 print $_,"\n" for (@files);
 414         }
 415 } else {
 416         print STDERR "\nNo patch files specified!\n\n";
 417         usage();
 418 }
 419
 420 my $prompting = 0;
 421 if (!defined $sender) {
 422         $sender = $repoauthor || $repocommitter || '';
 423
 424         while (1) {
 425                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 426                 last if defined $_;
 427                 print "\n";
 428         }
 429
 430         $sender = $_ if ($_);
 431         print "Emails will be sent from: ", $sender, "\n";
 432         $prompting++;
 433 }
 434
 435 if (!@to) {
 436
 437
 438         while (1) {
 439                 $_ = $term->readline("Who should the emails be sent to? ", "");
 440                 last if defined $_;
 441                 print "\n";
 442         }
 443
 444         my $to = $_;
 445         push @to, split /,\s*/, $to;
 446         $prompting++;
 447 }
 448
 449 sub expand_aliases {
 450         my @cur = @_;
 451         my @last;
 452         do {
 453                 @last = @cur;
 454                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 455         } while (join(',',@cur) ne join(',',@last));
 456         return @cur;
 457 }
 458
 459 @to = expand_aliases(@to);
 460 @to = (map { sanitize_address($_) } @to);
 461 @initial_cc = expand_aliases(@initial_cc);
 462 @bcclist = expand_aliases(@bcclist);
 463
 464 if (!defined $initial_subject && $compose) {
 465         while (1) {
 466                 $_ = $term->readline("What subject should the initial email start with? ", $initial_subject);
 467                 last if defined $_;
 468                 print "\n";
 469         }
 470
 471         $initial_subject = $_;
 472         $prompting++;
 473 }
 474
 475 if ($thread && !defined $initial_reply_to && $prompting) {
 476         while (1) {
 477                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ", $initial_reply_to);
 478                 last if defined $_;
 479                 print "\n";
 480         }
 481
 482         $initial_reply_to = $_;
 483 }
 484 if (defined $initial_reply_to) {
 485         $initial_reply_to =~ s/^\s*<?//;
 486         $initial_reply_to =~ s/>?\s*$//;
 487         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 488 }
 489
 490 if (!defined $smtp_server) {
 491         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 492                 if (-x $_) {
 493                         $smtp_server = $_;
 494                         last;
 495                 }
 496         }
 497         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 498 }
 499
 500 if ($compose) {
 501         # Note that this does not need to be secure, but we will make a small
 502         # effort to have it be unique
 503         open(C,">",$compose_filename)
 504                 or die "Failed to open for writing $compose_filename: $!";
 505         print C "From $sender # This line is ignored.\n";
 506         printf C "Subject: %s\n\n", $initial_subject;
 507         printf C <<EOT;
 508 GIT: Please enter your email below.
 509 GIT: Lines beginning in "GIT: " will be removed.
 510 GIT: Consider including an overall diffstat or table of contents
 511 GIT: for the patch you are writing.
 512
 513 EOT
 514         close(C);
 515
 516         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 517         system('sh', '-c', $editor.' "$@"', $editor, $compose_filename);
 518
 519         open(C2,">",$compose_filename . ".final")
 520                 or die "Failed to open $compose_filename.final : " . $!;
 521
 522         open(C,"<",$compose_filename)
 523                 or die "Failed to open $compose_filename : " . $!;
 524
 525         my $need_8bit_cte = file_has_nonascii($compose_filename);
 526         my $in_body = 0;
 527         while(<C>) {
 528                 next if m/^GIT: /;
 529                 if (!$in_body && /^\n$/) {
 530                         $in_body = 1;
 531                         if ($need_8bit_cte) {
 532                                 print C2 "MIME-Version: 1.0\n",
 533                                          "Content-Type: text/plain; ",
 534                                            "charset=utf-8\n",
 535                                          "Content-Transfer-Encoding: 8bit\n";
 536                         }
 537                 }
 538                 if (!$in_body && /^MIME-Version:/i) {
 539                         $need_8bit_cte = 0;
 540                 }
 541                 if (!$in_body && /^Subject: ?(.*)/i) {
 542                         my $subject = $1;
 543                         $_ = "Subject: " .
 544                                 ($subject =~ /[^[:ascii:]]/ ?
 545                                  quote_rfc2047($subject) :
 546                                  $subject) .
 547                                 "\n";
 548                 }
 549                 print C2 $_;
 550         }
 551         close(C);
 552         close(C2);
 553
 554         while (1) {
 555                 $_ = $term->readline("Send this email? (y|n) ");
 556                 last if defined $_;
 557                 print "\n";
 558         }
 559
 560         if (uc substr($_,0,1) ne 'Y') {
 561                 cleanup_compose_files();
 562                 exit(0);
 563         }
 564
 565         @files = ($compose_filename . ".final", @files);
 566 }
 567
 568 # Variables we set as part of the loop over files
 569 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 570
 571 sub extract_valid_address {
 572         my $address = shift;
 573         my $local_part_regexp = '[^<>"\s@]+';
 574         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 575
 576         # check for a local address:
 577         return $address if ($address =~ /^($local_part_regexp)$/);
 578
 579         $address =~ s/^\s*<(.*)>\s*$/$1/;
 580         if ($have_email_valid) {
 581                 return scalar Email::Valid->address($address);
 582         } else {
 583                 # less robust/correct than the monster regexp in Email::Valid,
 584                 # but still does a 99% job, and one less dependency
 585                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 586                 return $1;
 587         }
 588 }
 589
 590 # Usually don't need to change anything below here.
 591
 592 # we make a "fake" message id by taking the current number
 593 # of seconds since the beginning of Unix time and tacking on
 594 # a random number to the end, in case we are called quicker than
 595 # 1 second since the last time we were called.
 596
 597 # We'll setup a template for the message id, using the "from" address:
 598
 599 my ($message_id_stamp, $message_id_serial);
 600 sub make_message_id
 601 {
 602         my $uniq;
 603         if (!defined $message_id_stamp) {
 604                 $message_id_stamp = sprintf("%s-%s", time, $$);
 605                 $message_id_serial = 0;
 606         }
 607         $message_id_serial++;
 608         $uniq = "$message_id_stamp-$message_id_serial";
 609
 610         my $du_part;
 611         for ($sender, $repocommitter, $repoauthor) {
 612                 $du_part = extract_valid_address(sanitize_address($_));
 613                 last if (defined $du_part and $du_part ne '');
 614         }
 615         if (not defined $du_part or $du_part eq '') {
 616                 use Sys::Hostname qw();
 617                 $du_part = 'user@' . Sys::Hostname::hostname();
 618         }
 619         my $message_id_template = "<%s-git-send-email-%s>";
 620         $message_id = sprintf($message_id_template, $uniq, $du_part);
 621         #print "new message id = $message_id\n"; # Was useful for debugging
 622 }
 623
 624
 625
 626 $time = time - scalar $#files;
 627
 628 sub unquote_rfc2047 {
 629         local ($_) = @_;
 630         my $encoding;
 631         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 632                 $encoding = $1;
 633                 s/_/ /g;
 634                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 635         }
 636         return wantarray ? ($_, $encoding) : $_;
 637 }
 638
 639 sub quote_rfc2047 {
 640         local $_ = shift;
 641         my $encoding = shift || 'utf-8';
 642         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 643         s/(.*)/=\?$encoding\?q\?$1\?=/;
 644         return $_;
 645 }
 646
 647 # use the simplest quoting being able to handle the recipient
 648 sub sanitize_address
 649 {
 650         my ($recipient) = @_;
 651         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 652
 653         if (not $recipient_name) {
 654                 return "$recipient";
 655         }
 656
 657         # if recipient_name is already quoted, do nothing
 658         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 659                 return $recipient;
 660         }
 661
 662         # rfc2047 is needed if a non-ascii char is included
 663         if ($recipient_name =~ /[^[:ascii:]]/) {
 664                 $recipient_name = quote_rfc2047($recipient_name);
 665         }
 666
 667         # double quotes are needed if specials or CTLs are included
 668         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 669                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 670                 $recipient_name = "\"$recipient_name\"";
 671         }
 672
 673         return "$recipient_name $recipient_addr";
 674
 675 }
 676
 677 sub send_message
 678 {
 679         my @recipients = unique_email_list(@to);
 680         @cc = (grep { my $cc = extract_valid_address($_);
 681                       not grep { $cc eq $_ } @recipients
 682                     }
 683                map { sanitize_address($_) }
 684                @cc);
 685         my $to = join (",\n\t", @recipients);
 686         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 687         @recipients = (map { extract_valid_address($_) } @recipients);
 688         my $date = format_2822_time($time++);
 689         my $gitversion = '@@GIT_VERSION@@';
 690         if ($gitversion =~ m/..GIT_VERSION../) {
 691             $gitversion = Git::version();
 692         }
 693
 694         my $cc = join(", ", unique_email_list(@cc));
 695         my $ccline = "";
 696         if ($cc ne '') {
 697                 $ccline = "\nCc: $cc";
 698         }
 699         my $sanitized_sender = sanitize_address($sender);
 700         make_message_id() unless defined($message_id);
 701
 702         my $header = "From: $sanitized_sender
 703 To: $to${ccline}
 704 Subject: $subject
 705 Date: $date
 706 Message-Id: $message_id
 707 X-Mailer: git-send-email $gitversion
 708 ";
 709         if ($thread && $reply_to) {
 710
 711                 $header .= "In-Reply-To: $reply_to\n";
 712                 $header .= "References: $references\n";
 713         }
 714         if (@xh) {
 715                 $header .= join("\n", @xh) . "\n";
 716         }
 717
 718         my @sendmail_parameters = ('-i', @recipients);
 719         my $raw_from = $sanitized_sender;
 720         $raw_from = $envelope_sender if (defined $envelope_sender);
 721         $raw_from = extract_valid_address($raw_from);
 722         unshift (@sendmail_parameters,
 723                         '-f', $raw_from) if(defined $envelope_sender);
 724
 725         if ($dry_run) {
 726                 # We don't want to send the email.
 727         } elsif ($smtp_server =~ m#^/#) {
 728                 my $pid = open my $sm, '|-';
 729                 defined $pid or die $!;
 730                 if (!$pid) {
 731                         exec($smtp_server, @sendmail_parameters) or die $!;
 732                 }
 733                 print $sm "$header\n$message";
 734                 close $sm or die $?;
 735         } else {
 736
 737                 if (!defined $smtp_server) {
 738                         die "The required SMTP server is not properly defined."
 739                 }
 740
 741                 if ($smtp_ssl) {
 742                         $smtp_server_port ||= 465; # ssmtp
 743                         require Net::SMTP::SSL;
 744                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 745                 }
 746                 else {
 747                         require Net::SMTP;
 748                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 749                                                  ? "$smtp_server:$smtp_server_port"
 750                                                  : $smtp_server);
 751                 }
 752
 753                 if (!$smtp) {
 754                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 755                 }
 756
 757                 if (defined $smtp_authuser) {
 758
 759                         if (!defined $smtp_authpass) {
 760
 761                                 system "stty -echo";
 762
 763                                 do {
 764                                         print "Password: ";
 765                                         $_ = <STDIN>;
 766                                         print "\n";
 767                                 } while (!defined $_);
 768
 769                                 chomp($smtp_authpass = $_);
 770
 771                                 system "stty echo";
 772                         }
 773
 774                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 775                 }
 776
 777                 $smtp->mail( $raw_from ) or die $smtp->message;
 778                 $smtp->to( @recipients ) or die $smtp->message;
 779                 $smtp->data or die $smtp->message;
 780                 $smtp->datasend("$header\n$message") or die $smtp->message;
 781                 $smtp->dataend() or die $smtp->message;
 782                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 783         }
 784         if ($quiet) {
 785                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 786         } else {
 787                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 788                 if ($smtp_server !~ m#^/#) {
 789                         print "Server: $smtp_server\n";
 790                         print "MAIL FROM:<$raw_from>\n";
 791                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 792                 } else {
 793                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 794                 }
 795                 print $header, "\n";
 796                 if ($smtp) {
 797                         print "Result: ", $smtp->code, ' ',
 798                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 799                 } else {
 800                         print "Result: OK\n";
 801                 }
 802         }
 803 }
 804
 805 $reply_to = $initial_reply_to;
 806 $references = $initial_reply_to || '';
 807 $subject = $initial_subject;
 808
 809 foreach my $t (@files) {
 810         open(F,"<",$t) or die "can't open file $t";
 811
 812         my $author = undef;
 813         my $author_encoding;
 814         my $has_content_type;
 815         my $body_encoding;
 816         @cc = @initial_cc;
 817         @xh = ();
 818         my $input_format = undef;
 819         my $header_done = 0;
 820         $message = "";
 821         while(<F>) {
 822                 if (!$header_done) {
 823                         if (/^From /) {
 824                                 $input_format = 'mbox';
 825                                 next;
 826                         }
 827                         chomp;
 828                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 829                                 $input_format = 'mbox';
 830                         }
 831
 832                         if (defined $input_format && $input_format eq 'mbox') {
 833                                 if (/^Subject:\s+(.*)$/) {
 834                                         $subject = $1;
 835
 836                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 837                                         if (unquote_rfc2047($2) eq $sender) {
 838                                                 next if ($suppress_cc{'self'});
 839                                         }
 840                                         elsif ($1 eq 'From') {
 841                                                 ($author, $author_encoding)
 842                                                   = unquote_rfc2047($2);
 843                                                 next if ($suppress_cc{'author'});
 844                                         } else {
 845                                                 next if ($suppress_cc{'cc'});
 846                                         }
 847                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 848                                                 $2, $_) unless $quiet;
 849                                         push @cc, $2;
 850                                 }
 851                                 elsif (/^Content-type:/i) {
 852                                         $has_content_type = 1;
 853                                         if (/charset="?[^ "]+/) {
 854                                                 $body_encoding = $1;
 855                                         }
 856                                         push @xh, $_;
 857                                 }
 858                                 elsif (/^Message-Id: (.*)/i) {
 859                                         $message_id = $1;
 860                                 }
 861                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 862                                         push @xh, $_;
 863                                 }
 864
 865                         } else {
 866                                 # In the traditional
 867                                 # "send lots of email" format,
 868                                 # line 1 = cc
 869                                 # line 2 = subject
 870                                 # So let's support that, too.
 871                                 $input_format = 'lots';
 872                                 if (@cc == 0 && !$suppress_cc{'cc'}) {
 873                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 874                                                 $_, $_) unless $quiet;
 875
 876                                         push @cc, $_;
 877
 878                                 } elsif (!defined $subject) {
 879                                         $subject = $_;
 880                                 }
 881                         }
 882
 883                         # A whitespace line will terminate the headers
 884                         if (m/^\s*$/) {
 885                                 $header_done = 1;
 886                         }
 887                 } else {
 888                         $message .=  $_;
 889                         if (/^(Signed-off-by|Cc): (.*)$/i) {
 890                                 next if ($suppress_cc{'sob'});
 891                                 chomp;
 892                                 my $c = $2;
 893                                 chomp $c;
 894                                 next if ($c eq $sender and $suppress_cc{'self'});
 895                                 push @cc, $c;
 896                                 printf("(sob) Adding cc: %s from line '%s'\n",
 897                                         $c, $_) unless $quiet;
 898                         }
 899                 }
 900         }
 901         close F;
 902
 903         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
 904                 open(F, "$cc_cmd $t |")
 905                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 906                 while(<F>) {
 907                         my $c = $_;
 908                         $c =~ s/^\s*//g;
 909                         $c =~ s/\n$//g;
 910                         next if ($c eq $sender and $suppress_from);
 911                         push @cc, $c;
 912                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 913                                 $c, $cc_cmd) unless $quiet;
 914                 }
 915                 close F
 916                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 917         }
 918
 919         if (defined $author) {
 920                 $message = "From: $author\n\n$message";
 921                 if (defined $author_encoding) {
 922                         if ($has_content_type) {
 923                                 if ($body_encoding eq $author_encoding) {
 924                                         # ok, we already have the right encoding
 925                                 }
 926                                 else {
 927                                         # uh oh, we should re-encode
 928                                 }
 929                         }
 930                         else {
 931                                 push @xh,
 932                                   'MIME-Version: 1.0',
 933                                   "Content-Type: text/plain; charset=$author_encoding",
 934                                   'Content-Transfer-Encoding: 8bit';
 935                         }
 936                 }
 937         }
 938
 939         send_message();
 940
 941         # set up for the next message
 942         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 943                 $reply_to = $message_id;
 944                 if (length $references > 0) {
 945                         $references .= "\n $message_id";
 946                 } else {
 947                         $references = "$message_id";
 948                 }
 949         }
 950         $message_id = undef;
 951 }
 952
 953 if ($compose) {
 954         cleanup_compose_files();
 955 }
 956
 957 sub cleanup_compose_files() {
 958         unlink($compose_filename, $compose_filename . ".final");
 959
 960 }
 961
 962 $smtp->quit if $smtp;
 963
 964 sub unique_email_list(@) {
 965         my %seen;
 966         my @emails;
 967
 968         foreach my $entry (@_) {
 969                 if (my $clean = extract_valid_address($entry)) {
 970                         $seen{$clean} ||= 0;
 971                         next if $seen{$clean}++;
 972                         push @emails, $entry;
 973                 } else {
 974                         print STDERR "W: unable to extract a valid address",
 975                                         " from: $entry\n";
 976                 }
 977         }
 978         return @emails;
 979 }
 980
 981 sub validate_patch {
 982         my $fn = shift;
 983         open(my $fh, '<', $fn)
 984                 or die "unable to open $fn: $!\n";
 985         while (my $line = <$fh>) {
 986                 if (length($line) > 998) {
 987                         return "$.: patch contains a line longer than 998 characters";
 988                 }
 989         }
 990         return undef;
 991 }
 992
 993 sub file_has_nonascii {
 994         my $fn = shift;
 995         open(my $fh, '<', $fn)
 996                 or die "unable to open $fn: $!\n";
 997         while (my $line = <$fh>) {
 998                 return 1 if $line =~ /[^[:ascii:]]/;
 999         }
1000         return 0;
1001 }