git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 D_ {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD {
1118                         set file_states($path) [list \
1119                                 _[string index $m 1] \
1120                                 [lindex $s 1] \
1121                                 [lindex $s 3] \
1122                                 {}]
1123                 }
1124                 }
1125         }
1126
1127         display_all_files
1128         unlock_index
1129         reshow_diff
1130         set ui_status_value \
1131                 "Changes committed as [string range $cmt_id 0 7]."
1132 }
1133
1134 ######################################################################
1135 ##
1136 ## fetch pull push
1137
1138 proc fetch_from {remote} {
1139         set w [new_console "fetch $remote" \
1140                 "Fetching new changes from $remote"]
1141         set cmd [list git fetch]
1142         lappend cmd $remote
1143         console_exec $w $cmd
1144 }
1145
1146 proc pull_remote {remote branch} {
1147         global HEAD commit_type file_states repo_config
1148
1149         if {![lock_index update]} return
1150
1151         # -- Our in memory state should match the repository.
1152         #
1153         repository_state curType curHEAD curMERGE_HEAD
1154         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1155                 info_popup {Last scanned state does not match repository state.
1156
1157 Another Git program has modified this repository
1158 since the last scan.  A rescan must be performed
1159 before a pull operation can be started.
1160
1161 The rescan will be automatically started now.
1162 }
1163                 unlock_index
1164                 rescan {set ui_status_value {Ready.}}
1165                 return
1166         }
1167
1168         # -- No differences should exist before a pull.
1169         #
1170         if {[array size file_states] != 0} {
1171                 error_popup {Uncommitted but modified files are present.
1172
1173 You should not perform a pull with unmodified
1174 files in your working directory as Git will be
1175 unable to recover from an incorrect merge.
1176
1177 You should commit or revert all changes before
1178 starting a pull operation.
1179 }
1180                 unlock_index
1181                 return
1182         }
1183
1184         set w [new_console "pull $remote $branch" \
1185                 "Pulling new changes from branch $branch in $remote"]
1186         set cmd [list git pull]
1187         if {$repo_config(gui.pullsummary) eq {false}} {
1188                 lappend cmd --no-summary
1189         }
1190         lappend cmd $remote
1191         lappend cmd $branch
1192         console_exec $w $cmd [list post_pull_remote $remote $branch]
1193 }
1194
1195 proc post_pull_remote {remote branch success} {
1196         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1197         global ui_status_value
1198
1199         unlock_index
1200         if {$success} {
1201                 repository_state commit_type HEAD MERGE_HEAD
1202                 set PARENT $HEAD
1203                 set selected_commit_type new
1204                 set ui_status_value "Pulling $branch from $remote complete."
1205         } else {
1206                 rescan [list set ui_status_value \
1207                         "Conflicts detected while pulling $branch from $remote."]
1208         }
1209 }
1210
1211 proc push_to {remote} {
1212         set w [new_console "push $remote" \
1213                 "Pushing changes to $remote"]
1214         set cmd [list git push]
1215         lappend cmd $remote
1216         console_exec $w $cmd
1217 }
1218
1219 ######################################################################
1220 ##
1221 ## ui helpers
1222
1223 proc mapicon {w state path} {
1224         global all_icons
1225
1226         if {[catch {set r $all_icons($state$w)}]} {
1227                 puts "error: no icon for $w state={$state} $path"
1228                 return file_plain
1229         }
1230         return $r
1231 }
1232
1233 proc mapdesc {state path} {
1234         global all_descs
1235
1236         if {[catch {set r $all_descs($state)}]} {
1237                 puts "error: no desc for state={$state} $path"
1238                 return $state
1239         }
1240         return $r
1241 }
1242
1243 proc escape_path {path} {
1244         regsub -all "\n" $path "\\n" path
1245         return $path
1246 }
1247
1248 proc short_path {path} {
1249         return [escape_path [lindex [file split $path] end]]
1250 }
1251
1252 set next_icon_id 0
1253 set null_sha1 [string repeat 0 40]
1254
1255 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1256         global file_states next_icon_id null_sha1
1257
1258         set s0 [string index $new_state 0]
1259         set s1 [string index $new_state 1]
1260
1261         if {[catch {set info $file_states($path)}]} {
1262                 set state __
1263                 set icon n[incr next_icon_id]
1264         } else {
1265                 set state [lindex $info 0]
1266                 set icon [lindex $info 1]
1267                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1268                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1269         }
1270
1271         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1272         elseif {$s0 eq {_}} {set s0 _}
1273
1274         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1275         elseif {$s1 eq {_}} {set s1 _}
1276
1277         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1278                 set head_info [list 0 $null_sha1]
1279         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1280                 && $head_info eq {}} {
1281                 set head_info $index_info
1282         }
1283
1284         set file_states($path) [list $s0$s1 $icon \
1285                 $head_info $index_info \
1286                 ]
1287         return $state
1288 }
1289
1290 proc display_file_helper {w path icon_name old_m new_m} {
1291         global file_lists
1292
1293         if {$new_m eq {_}} {
1294                 set lno [lsearch -sorted $file_lists($w) $path]
1295                 if {$lno >= 0} {
1296                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1297                         incr lno
1298                         $w conf -state normal
1299                         $w delete $lno.0 [expr {$lno + 1}].0
1300                         $w conf -state disabled
1301                 }
1302         } elseif {$old_m eq {_} && $new_m ne {_}} {
1303                 lappend file_lists($w) $path
1304                 set file_lists($w) [lsort -unique $file_lists($w)]
1305                 set lno [lsearch -sorted $file_lists($w) $path]
1306                 incr lno
1307                 $w conf -state normal
1308                 $w image create $lno.0 \
1309                         -align center -padx 5 -pady 1 \
1310                         -name $icon_name \
1311                         -image [mapicon $w $new_m $path]
1312                 $w insert $lno.1 "[escape_path $path]\n"
1313                 $w conf -state disabled
1314         } elseif {$old_m ne $new_m} {
1315                 $w conf -state normal
1316                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1317                 $w conf -state disabled
1318         }
1319 }
1320
1321 proc display_file {path state} {
1322         global file_states selected_paths
1323         global ui_index ui_workdir
1324
1325         set old_m [merge_state $path $state]
1326         set s $file_states($path)
1327         set new_m [lindex $s 0]
1328         set icon_name [lindex $s 1]
1329
1330         display_file_helper     $ui_index $path $icon_name \
1331                 [string index $old_m 0] \
1332                 [string index $new_m 0]
1333         display_file_helper     $ui_workdir $path $icon_name \
1334                 [string index $old_m 1] \
1335                 [string index $new_m 1]
1336
1337         if {$new_m eq {__}} {
1338                 unset file_states($path)
1339                 catch {unset selected_paths($path)}
1340         }
1341 }
1342
1343 proc display_all_files_helper {w path icon_name m} {
1344         global file_lists
1345
1346         lappend file_lists($w) $path
1347         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1348         $w image create end \
1349                 -align center -padx 5 -pady 1 \
1350                 -name $icon_name \
1351                 -image [mapicon $w $m $path]
1352         $w insert end "[escape_path $path]\n"
1353 }
1354
1355 proc display_all_files {} {
1356         global ui_index ui_workdir
1357         global file_states file_lists
1358         global last_clicked selected_paths
1359
1360         $ui_index conf -state normal
1361         $ui_workdir conf -state normal
1362
1363         $ui_index delete 0.0 end
1364         $ui_workdir delete 0.0 end
1365         set last_clicked {}
1366
1367         set file_lists($ui_index) [list]
1368         set file_lists($ui_workdir) [list]
1369
1370         foreach path [lsort [array names file_states]] {
1371                 set s $file_states($path)
1372                 set m [lindex $s 0]
1373                 set icon_name [lindex $s 1]
1374
1375                 if {[string index $m 0] ne {_}} {
1376                         display_all_files_helper $ui_index $path \
1377                                 $icon_name [string index $m 0]
1378                 }
1379                 if {[string index $m 1] ne {_}} {
1380                         display_all_files_helper $ui_workdir $path \
1381                                 $icon_name [string index $m 1]
1382                 }
1383         }
1384
1385         $ui_index conf -state disabled
1386         $ui_workdir conf -state disabled
1387 }
1388
1389 proc update_indexinfo {msg pathList after} {
1390         global update_index_cp ui_status_value
1391
1392         if {![lock_index update]} return
1393
1394         set update_index_cp 0
1395         set pathList [lsort $pathList]
1396         set totalCnt [llength $pathList]
1397         set batch [expr {int($totalCnt * .01) + 1}]
1398         if {$batch > 25} {set batch 25}
1399
1400         set ui_status_value [format \
1401                 "$msg... %i/%i files (%.2f%%)" \
1402                 $update_index_cp \
1403                 $totalCnt \
1404                 0.0]
1405         set fd [open "| git update-index -z --index-info" w]
1406         fconfigure $fd \
1407                 -blocking 0 \
1408                 -buffering full \
1409                 -buffersize 512 \
1410                 -translation binary
1411         fileevent $fd writable [list \
1412                 write_update_indexinfo \
1413                 $fd \
1414                 $pathList \
1415                 $totalCnt \
1416                 $batch \
1417                 $msg \
1418                 $after \
1419                 ]
1420 }
1421
1422 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1423         global update_index_cp ui_status_value
1424         global file_states current_diff
1425
1426         if {$update_index_cp >= $totalCnt} {
1427                 close $fd
1428                 unlock_index
1429                 uplevel #0 $after
1430                 return
1431         }
1432
1433         for {set i $batch} \
1434                 {$update_index_cp < $totalCnt && $i > 0} \
1435                 {incr i -1} {
1436                 set path [lindex $pathList $update_index_cp]
1437                 incr update_index_cp
1438
1439                 set s $file_states($path)
1440                 switch -glob -- [lindex $s 0] {
1441                 A? {set new _O}
1442                 M? {set new _M}
1443                 D_ {set new _D}
1444                 D? {set new _?}
1445                 ?? {continue}
1446                 }
1447                 set info [lindex $s 2]
1448                 if {$info eq {}} continue
1449
1450                 puts -nonewline $fd $info
1451                 puts -nonewline $fd "\t"
1452                 puts -nonewline $fd $path
1453                 puts -nonewline $fd "\0"
1454                 display_file $path $new
1455         }
1456
1457         set ui_status_value [format \
1458                 "$msg... %i/%i files (%.2f%%)" \
1459                 $update_index_cp \
1460                 $totalCnt \
1461                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1462 }
1463
1464 proc update_index {msg pathList after} {
1465         global update_index_cp ui_status_value
1466
1467         if {![lock_index update]} return
1468
1469         set update_index_cp 0
1470         set pathList [lsort $pathList]
1471         set totalCnt [llength $pathList]
1472         set batch [expr {int($totalCnt * .01) + 1}]
1473         if {$batch > 25} {set batch 25}
1474
1475         set ui_status_value [format \
1476                 "$msg... %i/%i files (%.2f%%)" \
1477                 $update_index_cp \
1478                 $totalCnt \
1479                 0.0]
1480         set fd [open "| git update-index --add --remove -z --stdin" w]
1481         fconfigure $fd \
1482                 -blocking 0 \
1483                 -buffering full \
1484                 -buffersize 512 \
1485                 -translation binary
1486         fileevent $fd writable [list \
1487                 write_update_index \
1488                 $fd \
1489                 $pathList \
1490                 $totalCnt \
1491                 $batch \
1492                 $msg \
1493                 $after \
1494                 ]
1495 }
1496
1497 proc write_update_index {fd pathList totalCnt batch msg after} {
1498         global update_index_cp ui_status_value
1499         global file_states current_diff
1500
1501         if {$update_index_cp >= $totalCnt} {
1502                 close $fd
1503                 unlock_index
1504                 uplevel #0 $after
1505                 return
1506         }
1507
1508         for {set i $batch} \
1509                 {$update_index_cp < $totalCnt && $i > 0} \
1510                 {incr i -1} {
1511                 set path [lindex $pathList $update_index_cp]
1512                 incr update_index_cp
1513
1514                 switch -glob -- [lindex $file_states($path) 0] {
1515                 AD {set new __}
1516                 ?D {set new D_}
1517                 _O -
1518                 AM {set new A_}
1519                 U_ -
1520                 ?M {set new M_}
1521                 ?? {continue}
1522                 }
1523                 puts -nonewline $fd "$path\0"
1524                 display_file $path $new
1525         }
1526
1527         set ui_status_value [format \
1528                 "$msg... %i/%i files (%.2f%%)" \
1529                 $update_index_cp \
1530                 $totalCnt \
1531                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1532 }
1533
1534 proc checkout_index {msg pathList after} {
1535         global update_index_cp ui_status_value
1536
1537         if {![lock_index update]} return
1538
1539         set update_index_cp 0
1540         set pathList [lsort $pathList]
1541         set totalCnt [llength $pathList]
1542         set batch [expr {int($totalCnt * .01) + 1}]
1543         if {$batch > 25} {set batch 25}
1544
1545         set ui_status_value [format \
1546                 "$msg... %i/%i files (%.2f%%)" \
1547                 $update_index_cp \
1548                 $totalCnt \
1549                 0.0]
1550         set cmd [list git checkout-index]
1551         lappend cmd --index
1552         lappend cmd --quiet
1553         lappend cmd --force
1554         lappend cmd -z
1555         lappend cmd --stdin
1556         set fd [open "| $cmd " w]
1557         fconfigure $fd \
1558                 -blocking 0 \
1559                 -buffering full \
1560                 -buffersize 512 \
1561                 -translation binary
1562         fileevent $fd writable [list \
1563                 write_checkout_index \
1564                 $fd \
1565                 $pathList \
1566                 $totalCnt \
1567                 $batch \
1568                 $msg \
1569                 $after \
1570                 ]
1571 }
1572
1573 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1574         global update_index_cp ui_status_value
1575         global file_states current_diff
1576
1577         if {$update_index_cp >= $totalCnt} {
1578                 close $fd
1579                 unlock_index
1580                 uplevel #0 $after
1581                 return
1582         }
1583
1584         for {set i $batch} \
1585                 {$update_index_cp < $totalCnt && $i > 0} \
1586                 {incr i -1} {
1587                 set path [lindex $pathList $update_index_cp]
1588                 incr update_index_cp
1589                 switch -glob -- [lindex $file_states($path) 0] {
1590                 U? {continue}
1591                 ?M -
1592                 ?D {
1593                         puts -nonewline $fd "$path\0"
1594                         display_file $path ?_
1595                 }
1596                 }
1597         }
1598
1599         set ui_status_value [format \
1600                 "$msg... %i/%i files (%.2f%%)" \
1601                 $update_index_cp \
1602                 $totalCnt \
1603                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1604 }
1605
1606 ######################################################################
1607 ##
1608 ## branch management
1609
1610 proc load_all_heads {} {
1611         global all_heads tracking_branches
1612
1613         set all_heads [list]
1614         set cmd [list git for-each-ref]
1615         lappend cmd --format=%(refname)
1616         lappend cmd refs/heads
1617         set fd [open "| $cmd" r]
1618         while {[gets $fd line] > 0} {
1619                 if {![catch {set info $tracking_branches($line)}]} continue
1620                 if {![regsub ^refs/heads/ $line {} name]} continue
1621                 lappend all_heads $name
1622         }
1623         close $fd
1624
1625         set all_heads [lsort $all_heads]
1626 }
1627
1628 proc populate_branch_menu {m} {
1629         global all_heads disable_on_lock
1630
1631         $m add separator
1632         foreach b $all_heads {
1633                 $m add radiobutton \
1634                         -label $b \
1635                         -command [list switch_branch $b] \
1636                         -variable current_branch \
1637                         -value $b \
1638                         -font font_ui
1639                 lappend disable_on_lock \
1640                         [list $m entryconf [$m index last] -state]
1641         }
1642 }
1643
1644 proc do_create_branch {} {
1645         error "NOT IMPLEMENTED"
1646 }
1647
1648 proc do_delete_branch {} {
1649         error "NOT IMPLEMENTED"
1650 }
1651
1652 proc switch_branch {b} {
1653         global HEAD commit_type file_states current_branch
1654         global selected_commit_type ui_comm
1655
1656         if {![lock_index switch]} return
1657
1658         # -- Backup the selected branch (repository_state resets it)
1659         #
1660         set new_branch $current_branch
1661
1662         # -- Our in memory state should match the repository.
1663         #
1664         repository_state curType curHEAD curMERGE_HEAD
1665         if {[string match amend* $commit_type]
1666                 && $curType eq {normal}
1667                 && $curHEAD eq $HEAD} {
1668         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1669                 info_popup {Last scanned state does not match repository state.
1670
1671 Another Git program has modified this repository
1672 since the last scan.  A rescan must be performed
1673 before the current branch can be changed.
1674
1675 The rescan will be automatically started now.
1676 }
1677                 unlock_index
1678                 rescan {set ui_status_value {Ready.}}
1679                 return
1680         }
1681
1682         # -- Toss the message buffer if we are in amend mode.
1683         #
1684         if {[string match amend* $curType]} {
1685                 $ui_comm delete 0.0 end
1686                 $ui_comm edit reset
1687                 $ui_comm edit modified false
1688         }
1689
1690         set selected_commit_type new
1691         set current_branch $new_branch
1692
1693         unlock_index
1694         error "NOT FINISHED"
1695 }
1696
1697 ######################################################################
1698 ##
1699 ## remote management
1700
1701 proc load_all_remotes {} {
1702         global repo_config
1703         global all_remotes tracking_branches
1704
1705         set all_remotes [list]
1706         array unset tracking_branches
1707
1708         set rm_dir [gitdir remotes]
1709         if {[file isdirectory $rm_dir]} {
1710                 set all_remotes [glob \
1711                         -types f \
1712                         -tails \
1713                         -nocomplain \
1714                         -directory $rm_dir *]
1715
1716                 foreach name $all_remotes {
1717                         catch {
1718                                 set fd [open [file join $rm_dir $name] r]
1719                                 while {[gets $fd line] >= 0} {
1720                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
1721                                                 $line line src dst]} continue
1722                                         if {![regexp ^refs/ $dst]} {
1723                                                 set dst "refs/heads/$dst"
1724                                         }
1725                                         set tracking_branches($dst) [list $name $src]
1726                                 }
1727                                 close $fd
1728                         }
1729                 }
1730         }
1731
1732         foreach line [array names repo_config remote.*.url] {
1733                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
1734                 lappend all_remotes $name
1735
1736                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
1737                         set fl {}
1738                 }
1739                 foreach line $fl {
1740                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
1741                         if {![regexp ^refs/ $dst]} {
1742                                 set dst "refs/heads/$dst"
1743                         }
1744                         set tracking_branches($dst) [list $name $src]
1745                 }
1746         }
1747
1748         set all_remotes [lsort -unique $all_remotes]
1749 }
1750
1751 proc populate_fetch_menu {m} {
1752         global all_remotes repo_config
1753
1754         foreach r $all_remotes {
1755                 set enable 0
1756                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1757                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1758                                 set enable 1
1759                         }
1760                 } else {
1761                         catch {
1762                                 set fd [open [gitdir remotes $r] r]
1763                                 while {[gets $fd n] >= 0} {
1764                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1765                                                 set enable 1
1766                                                 break
1767                                         }
1768                                 }
1769                                 close $fd
1770                         }
1771                 }
1772
1773                 if {$enable} {
1774                         $m add command \
1775                                 -label "Fetch from $r..." \
1776                                 -command [list fetch_from $r] \
1777                                 -font font_ui
1778                 }
1779         }
1780 }
1781
1782 proc populate_push_menu {m} {
1783         global all_remotes repo_config
1784
1785         foreach r $all_remotes {
1786                 set enable 0
1787                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1788                         if {![catch {set a $repo_config(remote.$r.push)}]} {
1789                                 set enable 1
1790                         }
1791                 } else {
1792                         catch {
1793                                 set fd [open [gitdir remotes $r] r]
1794                                 while {[gets $fd n] >= 0} {
1795                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1796                                                 set enable 1
1797                                                 break
1798                                         }
1799                                 }
1800                                 close $fd
1801                         }
1802                 }
1803
1804                 if {$enable} {
1805                         $m add command \
1806                                 -label "Push to $r..." \
1807                                 -command [list push_to $r] \
1808                                 -font font_ui
1809                 }
1810         }
1811 }
1812
1813 proc populate_pull_menu {m} {
1814         global repo_config all_remotes disable_on_lock
1815
1816         foreach remote $all_remotes {
1817                 set rb_list [list]
1818                 if {[array get repo_config remote.$remote.url] ne {}} {
1819                         if {[array get repo_config remote.$remote.fetch] ne {}} {
1820                                 foreach line $repo_config(remote.$remote.fetch) {
1821                                         if {[regexp {^([^:]+):} $line line rb]} {
1822                                                 lappend rb_list $rb
1823                                         }
1824                                 }
1825                         }
1826                 } else {
1827                         catch {
1828                                 set fd [open [gitdir remotes $remote] r]
1829                                 while {[gets $fd line] >= 0} {
1830                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1831                                                 lappend rb_list $rb
1832                                         }
1833                                 }
1834                                 close $fd
1835                         }
1836                 }
1837
1838                 foreach rb $rb_list {
1839                         regsub ^refs/heads/ $rb {} rb_short
1840                         $m add command \
1841                                 -label "Branch $rb_short from $remote..." \
1842                                 -command [list pull_remote $remote $rb] \
1843                                 -font font_ui
1844                         lappend disable_on_lock \
1845                                 [list $m entryconf [$m index last] -state]
1846                 }
1847         }
1848 }
1849
1850 ######################################################################
1851 ##
1852 ## icons
1853
1854 set filemask {
1855 #define mask_width 14
1856 #define mask_height 15
1857 static unsigned char mask_bits[] = {
1858    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1859    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1860    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1861 }
1862
1863 image create bitmap file_plain -background white -foreground black -data {
1864 #define plain_width 14
1865 #define plain_height 15
1866 static unsigned char plain_bits[] = {
1867    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1868    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1869    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1870 } -maskdata $filemask
1871
1872 image create bitmap file_mod -background white -foreground blue -data {
1873 #define mod_width 14
1874 #define mod_height 15
1875 static unsigned char mod_bits[] = {
1876    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1877    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1878    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1879 } -maskdata $filemask
1880
1881 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1882 #define file_fulltick_width 14
1883 #define file_fulltick_height 15
1884 static unsigned char file_fulltick_bits[] = {
1885    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1886    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1887    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1888 } -maskdata $filemask
1889
1890 image create bitmap file_parttick -background white -foreground "#005050" -data {
1891 #define parttick_width 14
1892 #define parttick_height 15
1893 static unsigned char parttick_bits[] = {
1894    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1895    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1896    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1897 } -maskdata $filemask
1898
1899 image create bitmap file_question -background white -foreground black -data {
1900 #define file_question_width 14
1901 #define file_question_height 15
1902 static unsigned char file_question_bits[] = {
1903    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1904    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1905    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1906 } -maskdata $filemask
1907
1908 image create bitmap file_removed -background white -foreground red -data {
1909 #define file_removed_width 14
1910 #define file_removed_height 15
1911 static unsigned char file_removed_bits[] = {
1912    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1913    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1914    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1915 } -maskdata $filemask
1916
1917 image create bitmap file_merge -background white -foreground blue -data {
1918 #define file_merge_width 14
1919 #define file_merge_height 15
1920 static unsigned char file_merge_bits[] = {
1921    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1922    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1923    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1924 } -maskdata $filemask
1925
1926 set ui_index .vpane.files.index.list
1927 set ui_workdir .vpane.files.workdir.list
1928
1929 set all_icons(_$ui_index)   file_plain
1930 set all_icons(A$ui_index)   file_fulltick
1931 set all_icons(M$ui_index)   file_fulltick
1932 set all_icons(D$ui_index)   file_removed
1933 set all_icons(U$ui_index)   file_merge
1934
1935 set all_icons(_$ui_workdir) file_plain
1936 set all_icons(M$ui_workdir) file_mod
1937 set all_icons(D$ui_workdir) file_question
1938 set all_icons(O$ui_workdir) file_plain
1939
1940 set max_status_desc 0
1941 foreach i {
1942                 {__ "Unmodified"}
1943
1944                 {_M "Modified, not staged"}
1945                 {M_ "Staged for commit"}
1946                 {MM "Portions staged for commit"}
1947                 {MD "Staged for commit, missing"}
1948
1949                 {_O "Untracked, not staged"}
1950                 {A_ "Staged for commit"}
1951                 {AM "Portions staged for commit"}
1952                 {AD "Staged for commit, missing"}
1953
1954                 {_D "Missing"}
1955                 {D_ "Staged for removal"}
1956                 {DO "Staged for removal, still present"}
1957
1958                 {U_ "Requires merge resolution"}
1959                 {UM "Requires merge resolution"}
1960                 {UD "Requires merge resolution"}
1961         } {
1962         if {$max_status_desc < [string length [lindex $i 1]]} {
1963                 set max_status_desc [string length [lindex $i 1]]
1964         }
1965         set all_descs([lindex $i 0]) [lindex $i 1]
1966 }
1967 unset i
1968
1969 ######################################################################
1970 ##
1971 ## util
1972
1973 proc is_MacOSX {} {
1974         global tcl_platform tk_library
1975         if {[tk windowingsystem] eq {aqua}} {
1976                 return 1
1977         }
1978         return 0
1979 }
1980
1981 proc is_Windows {} {
1982         global tcl_platform
1983         if {$tcl_platform(platform) eq {windows}} {
1984                 return 1
1985         }
1986         return 0
1987 }
1988
1989 proc bind_button3 {w cmd} {
1990         bind $w <Any-Button-3> $cmd
1991         if {[is_MacOSX]} {
1992                 bind $w <Control-Button-1> $cmd
1993         }
1994 }
1995
1996 proc incr_font_size {font {amt 1}} {
1997         set sz [font configure $font -size]
1998         incr sz $amt
1999         font configure $font -size $sz
2000         font configure ${font}bold -size $sz
2001 }
2002
2003 proc hook_failed_popup {hook msg} {
2004         set w .hookfail
2005         toplevel $w
2006
2007         frame $w.m
2008         label $w.m.l1 -text "$hook hook failed:" \
2009                 -anchor w \
2010                 -justify left \
2011                 -font font_uibold
2012         text $w.m.t \
2013                 -background white -borderwidth 1 \
2014                 -relief sunken \
2015                 -width 80 -height 10 \
2016                 -font font_diff \
2017                 -yscrollcommand [list $w.m.sby set]
2018         label $w.m.l2 \
2019                 -text {You must correct the above errors before committing.} \
2020                 -anchor w \
2021                 -justify left \
2022                 -font font_uibold
2023         scrollbar $w.m.sby -command [list $w.m.t yview]
2024         pack $w.m.l1 -side top -fill x
2025         pack $w.m.l2 -side bottom -fill x
2026         pack $w.m.sby -side right -fill y
2027         pack $w.m.t -side left -fill both -expand 1
2028         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2029
2030         $w.m.t insert 1.0 $msg
2031         $w.m.t conf -state disabled
2032
2033         button $w.ok -text OK \
2034                 -width 15 \
2035                 -font font_ui \
2036                 -command "destroy $w"
2037         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2038
2039         bind $w <Visibility> "grab $w; focus $w"
2040         bind $w <Key-Return> "destroy $w"
2041         wm title $w "[appname] ([reponame]): error"
2042         tkwait window $w
2043 }
2044
2045 set next_console_id 0
2046
2047 proc new_console {short_title long_title} {
2048         global next_console_id console_data
2049         set w .console[incr next_console_id]
2050         set console_data($w) [list $short_title $long_title]
2051         return [console_init $w]
2052 }
2053
2054 proc console_init {w} {
2055         global console_cr console_data M1B
2056
2057         set console_cr($w) 1.0
2058         toplevel $w
2059         frame $w.m
2060         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2061                 -anchor w \
2062                 -justify left \
2063                 -font font_uibold
2064         text $w.m.t \
2065                 -background white -borderwidth 1 \
2066                 -relief sunken \
2067                 -width 80 -height 10 \
2068                 -font font_diff \
2069                 -state disabled \
2070                 -yscrollcommand [list $w.m.sby set]
2071         label $w.m.s -text {Working... please wait...} \
2072                 -anchor w \
2073                 -justify left \
2074                 -font font_uibold
2075         scrollbar $w.m.sby -command [list $w.m.t yview]
2076         pack $w.m.l1 -side top -fill x
2077         pack $w.m.s -side bottom -fill x
2078         pack $w.m.sby -side right -fill y
2079         pack $w.m.t -side left -fill both -expand 1
2080         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2081
2082         menu $w.ctxm -tearoff 0
2083         $w.ctxm add command -label "Copy" \
2084                 -font font_ui \
2085                 -command "tk_textCopy $w.m.t"
2086         $w.ctxm add command -label "Select All" \
2087                 -font font_ui \
2088                 -command "$w.m.t tag add sel 0.0 end"
2089         $w.ctxm add command -label "Copy All" \
2090                 -font font_ui \
2091                 -command "
2092                         $w.m.t tag add sel 0.0 end
2093                         tk_textCopy $w.m.t
2094                         $w.m.t tag remove sel 0.0 end
2095                 "
2096
2097         button $w.ok -text {Close} \
2098                 -font font_ui \
2099                 -state disabled \
2100                 -command "destroy $w"
2101         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2102
2103         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2104         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2105         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2106         bind $w <Visibility> "focus $w"
2107         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2108         return $w
2109 }
2110
2111 proc console_exec {w cmd {after {}}} {
2112         # -- Windows tosses the enviroment when we exec our child.
2113         #    But most users need that so we have to relogin. :-(
2114         #
2115         if {[is_Windows]} {
2116                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2117         }
2118
2119         # -- Tcl won't let us redirect both stdout and stderr to
2120         #    the same pipe.  So pass it through cat...
2121         #
2122         set cmd [concat | $cmd |& cat]
2123
2124         set fd_f [open $cmd r]
2125         fconfigure $fd_f -blocking 0 -translation binary
2126         fileevent $fd_f readable [list console_read $w $fd_f $after]
2127 }
2128
2129 proc console_read {w fd after} {
2130         global console_cr console_data
2131
2132         set buf [read $fd]
2133         if {$buf ne {}} {
2134                 if {![winfo exists $w]} {console_init $w}
2135                 $w.m.t conf -state normal
2136                 set c 0
2137                 set n [string length $buf]
2138                 while {$c < $n} {
2139                         set cr [string first "\r" $buf $c]
2140                         set lf [string first "\n" $buf $c]
2141                         if {$cr < 0} {set cr [expr {$n + 1}]}
2142                         if {$lf < 0} {set lf [expr {$n + 1}]}
2143
2144                         if {$lf < $cr} {
2145                                 $w.m.t insert end [string range $buf $c $lf]
2146                                 set console_cr($w) [$w.m.t index {end -1c}]
2147                                 set c $lf
2148                                 incr c
2149                         } else {
2150                                 $w.m.t delete $console_cr($w) end
2151                                 $w.m.t insert end "\n"
2152                                 $w.m.t insert end [string range $buf $c $cr]
2153                                 set c $cr
2154                                 incr c
2155                         }
2156                 }
2157                 $w.m.t conf -state disabled
2158                 $w.m.t see end
2159         }
2160
2161         fconfigure $fd -blocking 1
2162         if {[eof $fd]} {
2163                 if {[catch {close $fd}]} {
2164                         if {![winfo exists $w]} {console_init $w}
2165                         $w.m.s conf -background red -text {Error: Command Failed}
2166                         $w.ok conf -state normal
2167                         set ok 0
2168                 } elseif {[winfo exists $w]} {
2169                         $w.m.s conf -background green -text {Success}
2170                         $w.ok conf -state normal
2171                         set ok 1
2172                 }
2173                 array unset console_cr $w
2174                 array unset console_data $w
2175                 if {$after ne {}} {
2176                         uplevel #0 $after $ok
2177                 }
2178                 return
2179         }
2180         fconfigure $fd -blocking 0
2181 }
2182
2183 ######################################################################
2184 ##
2185 ## ui commands
2186
2187 set starting_gitk_msg {Starting gitk... please wait...}
2188
2189 proc do_gitk {revs} {
2190         global ui_status_value starting_gitk_msg
2191
2192         set cmd gitk
2193         if {$revs ne {}} {
2194                 append cmd { }
2195                 append cmd $revs
2196         }
2197         if {[is_Windows]} {
2198                 set cmd "sh -c \"exec $cmd\""
2199         }
2200         append cmd { &}
2201
2202         if {[catch {eval exec $cmd} err]} {
2203                 error_popup "Failed to start gitk:\n\n$err"
2204         } else {
2205                 set ui_status_value $starting_gitk_msg
2206                 after 10000 {
2207                         if {$ui_status_value eq $starting_gitk_msg} {
2208                                 set ui_status_value {Ready.}
2209                         }
2210                 }
2211         }
2212 }
2213
2214 proc do_gc {} {
2215         set w [new_console {gc} {Compressing the object database}]
2216         console_exec $w {git gc}
2217 }
2218
2219 proc do_fsck_objects {} {
2220         set w [new_console {fsck-objects} \
2221                 {Verifying the object database with fsck-objects}]
2222         set cmd [list git fsck-objects]
2223         lappend cmd --full
2224         lappend cmd --cache
2225         lappend cmd --strict
2226         console_exec $w $cmd
2227 }
2228
2229 set is_quitting 0
2230
2231 proc do_quit {} {
2232         global ui_comm is_quitting repo_config commit_type
2233
2234         if {$is_quitting} return
2235         set is_quitting 1
2236
2237         # -- Stash our current commit buffer.
2238         #
2239         set save [gitdir GITGUI_MSG]
2240         set msg [string trim [$ui_comm get 0.0 end]]
2241         if {![string match amend* $commit_type]
2242                 && [$ui_comm edit modified]
2243                 && $msg ne {}} {
2244                 catch {
2245                         set fd [open $save w]
2246                         puts $fd [string trim [$ui_comm get 0.0 end]]
2247                         close $fd
2248                 }
2249         } else {
2250                 catch {file delete $save}
2251         }
2252
2253         # -- Stash our current window geometry into this repository.
2254         #
2255         set cfg_geometry [list]
2256         lappend cfg_geometry [wm geometry .]
2257         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2258         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2259         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2260                 set rc_geometry {}
2261         }
2262         if {$cfg_geometry ne $rc_geometry} {
2263                 catch {exec git repo-config gui.geometry $cfg_geometry}
2264         }
2265
2266         destroy .
2267 }
2268
2269 proc do_rescan {} {
2270         rescan {set ui_status_value {Ready.}}
2271 }
2272
2273 proc unstage_helper {txt paths} {
2274         global file_states current_diff
2275
2276         if {![lock_index begin-update]} return
2277
2278         set pathList [list]
2279         set after {}
2280         foreach path $paths {
2281                 switch -glob -- [lindex $file_states($path) 0] {
2282                 A? -
2283                 M? -
2284                 D? {
2285                         lappend pathList $path
2286                         if {$path eq $current_diff} {
2287                                 set after {reshow_diff;}
2288                         }
2289                 }
2290                 }
2291         }
2292         if {$pathList eq {}} {
2293                 unlock_index
2294         } else {
2295                 update_indexinfo \
2296                         $txt \
2297                         $pathList \
2298                         [concat $after {set ui_status_value {Ready.}}]
2299         }
2300 }
2301
2302 proc do_unstage_selection {} {
2303         global current_diff selected_paths
2304
2305         if {[array size selected_paths] > 0} {
2306                 unstage_helper \
2307                         {Unstaging selected files from commit} \
2308                         [array names selected_paths]
2309         } elseif {$current_diff ne {}} {
2310                 unstage_helper \
2311                         "Unstaging [short_path $current_diff] from commit" \
2312                         [list $current_diff]
2313         }
2314 }
2315
2316 proc add_helper {txt paths} {
2317         global file_states current_diff
2318
2319         if {![lock_index begin-update]} return
2320
2321         set pathList [list]
2322         set after {}
2323         foreach path $paths {
2324                 switch -glob -- [lindex $file_states($path) 0] {
2325                 _O -
2326                 ?M -
2327                 ?D -
2328                 U? {
2329                         lappend pathList $path
2330                         if {$path eq $current_diff} {
2331                                 set after {reshow_diff;}
2332                         }
2333                 }
2334                 }
2335         }
2336         if {$pathList eq {}} {
2337                 unlock_index
2338         } else {
2339                 update_index \
2340                         $txt \
2341                         $pathList \
2342                         [concat $after {set ui_status_value {Ready to commit.}}]
2343         }
2344 }
2345
2346 proc do_add_selection {} {
2347         global current_diff selected_paths
2348
2349         if {[array size selected_paths] > 0} {
2350                 add_helper \
2351                         {Adding selected files} \
2352                         [array names selected_paths]
2353         } elseif {$current_diff ne {}} {
2354                 add_helper \
2355                         "Adding [short_path $current_diff]" \
2356                         [list $current_diff]
2357         }
2358 }
2359
2360 proc do_add_all {} {
2361         global file_states
2362
2363         set paths [list]
2364         foreach path [array names file_states] {
2365                 switch -glob -- [lindex $file_states($path) 0] {
2366                 U? {continue}
2367                 ?M -
2368                 ?D {lappend paths $path}
2369                 }
2370         }
2371         add_helper {Adding all changed files} $paths
2372 }
2373
2374 proc revert_helper {txt paths} {
2375         global file_states current_diff
2376
2377         if {![lock_index begin-update]} return
2378
2379         set pathList [list]
2380         set after {}
2381         foreach path $paths {
2382                 switch -glob -- [lindex $file_states($path) 0] {
2383                 U? {continue}
2384                 ?M -
2385                 ?D {
2386                         lappend pathList $path
2387                         if {$path eq $current_diff} {
2388                                 set after {reshow_diff;}
2389                         }
2390                 }
2391                 }
2392         }
2393
2394         set n [llength $pathList]
2395         if {$n == 0} {
2396                 unlock_index
2397                 return
2398         } elseif {$n == 1} {
2399                 set s "[short_path [lindex $pathList]]"
2400         } else {
2401                 set s "these $n files"
2402         }
2403
2404         set reply [tk_dialog \
2405                 .confirm_revert \
2406                 "[appname] ([reponame])" \
2407                 "Revert changes in $s?
2408
2409 Any unadded changes will be permanently lost by the revert." \
2410                 question \
2411                 1 \
2412                 {Do Nothing} \
2413                 {Revert Changes} \
2414                 ]
2415         if {$reply == 1} {
2416                 checkout_index \
2417                         $txt \
2418                         $pathList \
2419                         [concat $after {set ui_status_value {Ready.}}]
2420         } else {
2421                 unlock_index
2422         }
2423 }
2424
2425 proc do_revert_selection {} {
2426         global current_diff selected_paths
2427
2428         if {[array size selected_paths] > 0} {
2429                 revert_helper \
2430                         {Reverting selected files} \
2431                         [array names selected_paths]
2432         } elseif {$current_diff ne {}} {
2433                 revert_helper \
2434                         "Reverting [short_path $current_diff]" \
2435                         [list $current_diff]
2436         }
2437 }
2438
2439 proc do_signoff {} {
2440         global ui_comm
2441
2442         set me [committer_ident]
2443         if {$me eq {}} return
2444
2445         set sob "Signed-off-by: $me"
2446         set last [$ui_comm get {end -1c linestart} {end -1c}]
2447         if {$last ne $sob} {
2448                 $ui_comm edit separator
2449                 if {$last ne {}
2450                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2451                         $ui_comm insert end "\n"
2452                 }
2453                 $ui_comm insert end "\n$sob"
2454                 $ui_comm edit separator
2455                 $ui_comm see end
2456         }
2457 }
2458
2459 proc do_select_commit_type {} {
2460         global commit_type selected_commit_type
2461
2462         if {$selected_commit_type eq {new}
2463                 && [string match amend* $commit_type]} {
2464                 create_new_commit
2465         } elseif {$selected_commit_type eq {amend}
2466                 && ![string match amend* $commit_type]} {
2467                 load_last_commit
2468
2469                 # The amend request was rejected...
2470                 #
2471                 if {![string match amend* $commit_type]} {
2472                         set selected_commit_type new
2473                 }
2474         }
2475 }
2476
2477 proc do_commit {} {
2478         commit_tree
2479 }
2480
2481 proc do_about {} {
2482         global appvers copyright
2483         global tcl_patchLevel tk_patchLevel
2484
2485         set w .about_dialog
2486         toplevel $w
2487         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2488
2489         label $w.header -text "About [appname]" \
2490                 -font font_uibold
2491         pack $w.header -side top -fill x
2492
2493         frame $w.buttons
2494         button $w.buttons.close -text {Close} \
2495                 -font font_ui \
2496                 -command [list destroy $w]
2497         pack $w.buttons.close -side right
2498         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2499
2500         label $w.desc \
2501                 -text "[appname] - a commit creation tool for Git.
2502 $copyright" \
2503                 -padx 5 -pady 5 \
2504                 -justify left \
2505                 -anchor w \
2506                 -borderwidth 1 \
2507                 -relief solid \
2508                 -font font_ui
2509         pack $w.desc -side top -fill x -padx 5 -pady 5
2510
2511         set v {}
2512         append v "[appname] version $appvers\n"
2513         append v "[exec git version]\n"
2514         append v "\n"
2515         if {$tcl_patchLevel eq $tk_patchLevel} {
2516                 append v "Tcl/Tk version $tcl_patchLevel"
2517         } else {
2518                 append v "Tcl version $tcl_patchLevel"
2519                 append v ", Tk version $tk_patchLevel"
2520         }
2521
2522         label $w.vers \
2523                 -text $v \
2524                 -padx 5 -pady 5 \
2525                 -justify left \
2526                 -anchor w \
2527                 -borderwidth 1 \
2528                 -relief solid \
2529                 -font font_ui
2530         pack $w.vers -side top -fill x -padx 5 -pady 5
2531
2532         menu $w.ctxm -tearoff 0
2533         $w.ctxm add command \
2534                 -label {Copy} \
2535                 -font font_ui \
2536                 -command "
2537                 clipboard clear
2538                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2539         "
2540
2541         bind $w <Visibility> "grab $w; focus $w"
2542         bind $w <Key-Escape> "destroy $w"
2543         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2544         wm title $w "About [appname]"
2545         tkwait window $w
2546 }
2547
2548 proc do_options {} {
2549         global repo_config global_config font_descs
2550         global repo_config_new global_config_new
2551
2552         array unset repo_config_new
2553         array unset global_config_new
2554         foreach name [array names repo_config] {
2555                 set repo_config_new($name) $repo_config($name)
2556         }
2557         load_config 1
2558         foreach name [array names repo_config] {
2559                 switch -- $name {
2560                 gui.diffcontext {continue}
2561                 }
2562                 set repo_config_new($name) $repo_config($name)
2563         }
2564         foreach name [array names global_config] {
2565                 set global_config_new($name) $global_config($name)
2566         }
2567
2568         set w .options_editor
2569         toplevel $w
2570         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2571
2572         label $w.header -text "[appname] Options" \
2573                 -font font_uibold
2574         pack $w.header -side top -fill x
2575
2576         frame $w.buttons
2577         button $w.buttons.restore -text {Restore Defaults} \
2578                 -font font_ui \
2579                 -command do_restore_defaults
2580         pack $w.buttons.restore -side left
2581         button $w.buttons.save -text Save \
2582                 -font font_ui \
2583                 -command [list do_save_config $w]
2584         pack $w.buttons.save -side right
2585         button $w.buttons.cancel -text {Cancel} \
2586                 -font font_ui \
2587                 -command [list destroy $w]
2588         pack $w.buttons.cancel -side right
2589         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2590
2591         labelframe $w.repo -text "[reponame] Repository" \
2592                 -font font_ui \
2593                 -relief raised -borderwidth 2
2594         labelframe $w.global -text {Global (All Repositories)} \
2595                 -font font_ui \
2596                 -relief raised -borderwidth 2
2597         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2598         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2599
2600         foreach option {
2601                 {b partialinclude {Allow Partially Added Files}}
2602                 {b pullsummary {Show Pull Summary}}
2603                 {b trustmtime  {Trust File Modification Timestamps}}
2604                 {i diffcontext {Number of Diff Context Lines}}
2605                 } {
2606                 set type [lindex $option 0]
2607                 set name [lindex $option 1]
2608                 set text [lindex $option 2]
2609                 foreach f {repo global} {
2610                         switch $type {
2611                         b {
2612                                 checkbutton $w.$f.$name -text $text \
2613                                         -variable ${f}_config_new(gui.$name) \
2614                                         -onvalue true \
2615                                         -offvalue false \
2616                                         -font font_ui
2617                                 pack $w.$f.$name -side top -anchor w
2618                         }
2619                         i {
2620                                 frame $w.$f.$name
2621                                 label $w.$f.$name.l -text "$text:" -font font_ui
2622                                 pack $w.$f.$name.l -side left -anchor w -fill x
2623                                 spinbox $w.$f.$name.v \
2624                                         -textvariable ${f}_config_new(gui.$name) \
2625                                         -from 1 -to 99 -increment 1 \
2626                                         -width 3 \
2627                                         -font font_ui
2628                                 pack $w.$f.$name.v -side right -anchor e
2629                                 pack $w.$f.$name -side top -anchor w -fill x
2630                         }
2631                         }
2632                 }
2633         }
2634
2635         set all_fonts [lsort [font families]]
2636         foreach option $font_descs {
2637                 set name [lindex $option 0]
2638                 set font [lindex $option 1]
2639                 set text [lindex $option 2]
2640
2641                 set global_config_new(gui.$font^^family) \
2642                         [font configure $font -family]
2643                 set global_config_new(gui.$font^^size) \
2644                         [font configure $font -size]
2645
2646                 frame $w.global.$name
2647                 label $w.global.$name.l -text "$text:" -font font_ui
2648                 pack $w.global.$name.l -side left -anchor w -fill x
2649                 eval tk_optionMenu $w.global.$name.family \
2650                         global_config_new(gui.$font^^family) \
2651                         $all_fonts
2652                 spinbox $w.global.$name.size \
2653                         -textvariable global_config_new(gui.$font^^size) \
2654                         -from 2 -to 80 -increment 1 \
2655                         -width 3 \
2656                         -font font_ui
2657                 pack $w.global.$name.size -side right -anchor e
2658                 pack $w.global.$name.family -side right -anchor e
2659                 pack $w.global.$name -side top -anchor w -fill x
2660         }
2661
2662         bind $w <Visibility> "grab $w; focus $w"
2663         bind $w <Key-Escape> "destroy $w"
2664         wm title $w "[appname] ([reponame]): Options"
2665         tkwait window $w
2666 }
2667
2668 proc do_restore_defaults {} {
2669         global font_descs default_config repo_config
2670         global repo_config_new global_config_new
2671
2672         foreach name [array names default_config] {
2673                 set repo_config_new($name) $default_config($name)
2674                 set global_config_new($name) $default_config($name)
2675         }
2676
2677         foreach option $font_descs {
2678                 set name [lindex $option 0]
2679                 set repo_config(gui.$name) $default_config(gui.$name)
2680         }
2681         apply_config
2682
2683         foreach option $font_descs {
2684                 set name [lindex $option 0]
2685                 set font [lindex $option 1]
2686                 set global_config_new(gui.$font^^family) \
2687                         [font configure $font -family]
2688                 set global_config_new(gui.$font^^size) \
2689                         [font configure $font -size]
2690         }
2691 }
2692
2693 proc do_save_config {w} {
2694         if {[catch {save_config} err]} {
2695                 error_popup "Failed to completely save options:\n\n$err"
2696         }
2697         reshow_diff
2698         destroy $w
2699 }
2700
2701 proc do_windows_shortcut {} {
2702         global argv0
2703
2704         if {[catch {
2705                 set desktop [exec cygpath \
2706                         --windows \
2707                         --absolute \
2708                         --long-name \
2709                         --desktop]
2710                 }]} {
2711                         set desktop .
2712         }
2713         set fn [tk_getSaveFile \
2714                 -parent . \
2715                 -title "[appname] ([reponame]): Create Desktop Icon" \
2716                 -initialdir $desktop \
2717                 -initialfile "Git [reponame].bat"]
2718         if {$fn != {}} {
2719                 if {[catch {
2720                                 set fd [open $fn w]
2721                                 set sh [exec cygpath \
2722                                         --windows \
2723                                         --absolute \
2724                                         /bin/sh]
2725                                 set me [exec cygpath \
2726                                         --unix \
2727                                         --absolute \
2728                                         $argv0]
2729                                 set gd [exec cygpath \
2730                                         --unix \
2731                                         --absolute \
2732                                         [gitdir]]
2733                                 set gw [exec cygpath \
2734                                         --windows \
2735                                         --absolute \
2736                                         [file dirname [gitdir]]]
2737                                 regsub -all ' $me "'\\''" me
2738                                 regsub -all ' $gd "'\\''" gd
2739                                 puts $fd "@ECHO Entering $gw"
2740                                 puts $fd "@ECHO Starting git-gui... please wait..."
2741                                 puts -nonewline $fd "@\"$sh\" --login -c \""
2742                                 puts -nonewline $fd "GIT_DIR='$gd'"
2743                                 puts -nonewline $fd " '$me'"
2744                                 puts $fd "&\""
2745                                 close $fd
2746                         } err]} {
2747                         error_popup "Cannot write script:\n\n$err"
2748                 }
2749         }
2750 }
2751
2752 proc do_macosx_app {} {
2753         global argv0 env
2754
2755         set fn [tk_getSaveFile \
2756                 -parent . \
2757                 -title "[appname] ([reponame]): Create Desktop Icon" \
2758                 -initialdir [file join $env(HOME) Desktop] \
2759                 -initialfile "Git [reponame].app"]
2760         if {$fn != {}} {
2761                 if {[catch {
2762                                 set Contents [file join $fn Contents]
2763                                 set MacOS [file join $Contents MacOS]
2764                                 set exe [file join $MacOS git-gui]
2765
2766                                 file mkdir $MacOS
2767
2768                                 set fd [open [file join $Contents Info.plist] w]
2769                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2770 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2771 <plist version="1.0">
2772 <dict>
2773         <key>CFBundleDevelopmentRegion</key>
2774         <string>English</string>
2775         <key>CFBundleExecutable</key>
2776         <string>git-gui</string>
2777         <key>CFBundleIdentifier</key>
2778         <string>org.spearce.git-gui</string>
2779         <key>CFBundleInfoDictionaryVersion</key>
2780         <string>6.0</string>
2781         <key>CFBundlePackageType</key>
2782         <string>APPL</string>
2783         <key>CFBundleSignature</key>
2784         <string>????</string>
2785         <key>CFBundleVersion</key>
2786         <string>1.0</string>
2787         <key>NSPrincipalClass</key>
2788         <string>NSApplication</string>
2789 </dict>
2790 </plist>}
2791                                 close $fd
2792
2793                                 set fd [open $exe w]
2794                                 set gd [file normalize [gitdir]]
2795                                 set ep [file normalize [exec git --exec-path]]
2796                                 regsub -all ' $gd "'\\''" gd
2797                                 regsub -all ' $ep "'\\''" ep
2798                                 puts $fd "#!/bin/sh"
2799                                 foreach name [array names env] {
2800                                         if {[string match GIT_* $name]} {
2801                                                 regsub -all ' $env($name) "'\\''" v
2802                                                 puts $fd "export $name='$v'"
2803                                         }
2804                                 }
2805                                 puts $fd "export PATH='$ep':\$PATH"
2806                                 puts $fd "export GIT_DIR='$gd'"
2807                                 puts $fd "exec [file normalize $argv0]"
2808                                 close $fd
2809
2810                                 file attributes $exe -permissions u+x,g+x,o+x
2811                         } err]} {
2812                         error_popup "Cannot write icon:\n\n$err"
2813                 }
2814         }
2815 }
2816
2817 proc toggle_or_diff {w x y} {
2818         global file_states file_lists current_diff ui_index ui_workdir
2819         global last_clicked selected_paths
2820
2821         set pos [split [$w index @$x,$y] .]
2822         set lno [lindex $pos 0]
2823         set col [lindex $pos 1]
2824         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2825         if {$path eq {}} {
2826                 set last_clicked {}
2827                 return
2828         }
2829
2830         set last_clicked [list $w $lno]
2831         array unset selected_paths
2832         $ui_index tag remove in_sel 0.0 end
2833         $ui_workdir tag remove in_sel 0.0 end
2834
2835         if {$col == 0} {
2836                 if {$current_diff eq $path} {
2837                         set after {reshow_diff;}
2838                 } else {
2839                         set after {}
2840                 }
2841                 if {$w eq $ui_index} {
2842                         update_indexinfo \
2843                                 "Unstaging [short_path $path] from commit" \
2844                                 [list $path] \
2845                                 [concat $after {set ui_status_value {Ready.}}]
2846                 } elseif {$w eq $ui_workdir} {
2847                         update_index \
2848                                 "Adding [short_path $path]" \
2849                                 [list $path] \
2850                                 [concat $after {set ui_status_value {Ready.}}]
2851                 }
2852         } else {
2853                 show_diff $path $w $lno
2854         }
2855 }
2856
2857 proc add_one_to_selection {w x y} {
2858         global file_lists
2859         global last_clicked selected_paths
2860
2861         set pos [split [$w index @$x,$y] .]
2862         set lno [lindex $pos 0]
2863         set col [lindex $pos 1]
2864         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2865         if {$path eq {}} {
2866                 set last_clicked {}
2867                 return
2868         }
2869
2870         set last_clicked [list $w $lno]
2871         if {[catch {set in_sel $selected_paths($path)}]} {
2872                 set in_sel 0
2873         }
2874         if {$in_sel} {
2875                 unset selected_paths($path)
2876                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2877         } else {
2878                 set selected_paths($path) 1
2879                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2880         }
2881 }
2882
2883 proc add_range_to_selection {w x y} {
2884         global file_lists
2885         global last_clicked selected_paths
2886
2887         if {[lindex $last_clicked 0] ne $w} {
2888                 toggle_or_diff $w $x $y
2889                 return
2890         }
2891
2892         set pos [split [$w index @$x,$y] .]
2893         set lno [lindex $pos 0]
2894         set lc [lindex $last_clicked 1]
2895         if {$lc < $lno} {
2896                 set begin $lc
2897                 set end $lno
2898         } else {
2899                 set begin $lno
2900                 set end $lc
2901         }
2902
2903         foreach path [lrange $file_lists($w) \
2904                 [expr {$begin - 1}] \
2905                 [expr {$end - 1}]] {
2906                 set selected_paths($path) 1
2907         }
2908         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2909 }
2910
2911 ######################################################################
2912 ##
2913 ## config defaults
2914
2915 set cursor_ptr arrow
2916 font create font_diff -family Courier -size 10
2917 font create font_ui
2918 catch {
2919         label .dummy
2920         eval font configure font_ui [font actual [.dummy cget -font]]
2921         destroy .dummy
2922 }
2923
2924 font create font_uibold
2925 font create font_diffbold
2926
2927 if {[is_Windows]} {
2928         set M1B Control
2929         set M1T Ctrl
2930 } elseif {[is_MacOSX]} {
2931         set M1B M1
2932         set M1T Cmd
2933 } else {
2934         set M1B M1
2935         set M1T M1
2936 }
2937
2938 proc apply_config {} {
2939         global repo_config font_descs
2940
2941         foreach option $font_descs {
2942                 set name [lindex $option 0]
2943                 set font [lindex $option 1]
2944                 if {[catch {
2945                         foreach {cn cv} $repo_config(gui.$name) {
2946                                 font configure $font $cn $cv
2947                         }
2948                         } err]} {
2949                         error_popup "Invalid font specified in gui.$name:\n\n$err"
2950                 }
2951                 foreach {cn cv} [font configure $font] {
2952                         font configure ${font}bold $cn $cv
2953                 }
2954                 font configure ${font}bold -weight bold
2955         }
2956 }
2957
2958 set default_config(gui.trustmtime) false
2959 set default_config(gui.pullsummary) true
2960 set default_config(gui.partialinclude) false
2961 set default_config(gui.diffcontext) 5
2962 set default_config(gui.fontui) [font configure font_ui]
2963 set default_config(gui.fontdiff) [font configure font_diff]
2964 set font_descs {
2965         {fontui   font_ui   {Main Font}}
2966         {fontdiff font_diff {Diff/Console Font}}
2967 }
2968 load_config 0
2969 apply_config
2970
2971 ######################################################################
2972 ##
2973 ## ui construction
2974
2975 # -- Menu Bar
2976 #
2977 menu .mbar -tearoff 0
2978 .mbar add cascade -label Repository -menu .mbar.repository
2979 .mbar add cascade -label Edit -menu .mbar.edit
2980 if {!$single_commit} {
2981         .mbar add cascade -label Branch -menu .mbar.branch
2982 }
2983 .mbar add cascade -label Commit -menu .mbar.commit
2984 if {!$single_commit} {
2985         .mbar add cascade -label Fetch -menu .mbar.fetch
2986         .mbar add cascade -label Pull -menu .mbar.pull
2987         .mbar add cascade -label Push -menu .mbar.push
2988 }
2989 . configure -menu .mbar
2990
2991 # -- Repository Menu
2992 #
2993 menu .mbar.repository
2994 .mbar.repository add command \
2995         -label {Visualize Current Branch} \
2996         -command {do_gitk {}} \
2997         -font font_ui
2998 if {![is_MacOSX]} {
2999         .mbar.repository add command \
3000                 -label {Visualize All Branches} \
3001                 -command {do_gitk {--all}} \
3002                 -font font_ui
3003 }
3004 .mbar.repository add separator
3005
3006 if {!$single_commit} {
3007         .mbar.repository add command -label {Compress Database} \
3008                 -command do_gc \
3009                 -font font_ui
3010
3011         .mbar.repository add command -label {Verify Database} \
3012                 -command do_fsck_objects \
3013                 -font font_ui
3014
3015         .mbar.repository add separator
3016
3017         if {[is_Windows]} {
3018                 .mbar.repository add command \
3019                         -label {Create Desktop Icon} \
3020                         -command do_windows_shortcut \
3021                         -font font_ui
3022         } elseif {[is_MacOSX]} {
3023                 .mbar.repository add command \
3024                         -label {Create Desktop Icon} \
3025                         -command do_macosx_app \
3026                         -font font_ui
3027         }
3028 }
3029
3030 .mbar.repository add command -label Quit \
3031         -command do_quit \
3032         -accelerator $M1T-Q \
3033         -font font_ui
3034
3035 # -- Edit Menu
3036 #
3037 menu .mbar.edit
3038 .mbar.edit add command -label Undo \
3039         -command {catch {[focus] edit undo}} \
3040         -accelerator $M1T-Z \
3041         -font font_ui
3042 .mbar.edit add command -label Redo \
3043         -command {catch {[focus] edit redo}} \
3044         -accelerator $M1T-Y \
3045         -font font_ui
3046 .mbar.edit add separator
3047 .mbar.edit add command -label Cut \
3048         -command {catch {tk_textCut [focus]}} \
3049         -accelerator $M1T-X \
3050         -font font_ui
3051 .mbar.edit add command -label Copy \
3052         -command {catch {tk_textCopy [focus]}} \
3053         -accelerator $M1T-C \
3054         -font font_ui
3055 .mbar.edit add command -label Paste \
3056         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3057         -accelerator $M1T-V \
3058         -font font_ui
3059 .mbar.edit add command -label Delete \
3060         -command {catch {[focus] delete sel.first sel.last}} \
3061         -accelerator Del \
3062         -font font_ui
3063 .mbar.edit add separator
3064 .mbar.edit add command -label {Select All} \
3065         -command {catch {[focus] tag add sel 0.0 end}} \
3066         -accelerator $M1T-A \
3067         -font font_ui
3068
3069 # -- Branch Menu
3070 #
3071 if {!$single_commit} {
3072         menu .mbar.branch
3073
3074         .mbar.branch add command -label {Create...} \
3075                 -command do_create_branch \
3076                 -font font_ui
3077         lappend disable_on_lock [list .mbar.branch entryconf \
3078                 [.mbar.branch index last] -state]
3079
3080         .mbar.branch add command -label {Delete...} \
3081                 -command do_delete_branch \
3082                 -font font_ui
3083         lappend disable_on_lock [list .mbar.branch entryconf \
3084                 [.mbar.branch index last] -state]
3085 }
3086
3087 # -- Commit Menu
3088 #
3089 menu .mbar.commit
3090
3091 .mbar.commit add radiobutton \
3092         -label {New Commit} \
3093         -command do_select_commit_type \
3094         -variable selected_commit_type \
3095         -value new \
3096         -font font_ui
3097 lappend disable_on_lock \
3098         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3099
3100 .mbar.commit add radiobutton \
3101         -label {Amend Last Commit} \
3102         -command do_select_commit_type \
3103         -variable selected_commit_type \
3104         -value amend \
3105         -font font_ui
3106 lappend disable_on_lock \
3107         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3108
3109 .mbar.commit add separator
3110
3111 .mbar.commit add command -label Rescan \
3112         -command do_rescan \
3113         -accelerator F5 \
3114         -font font_ui
3115 lappend disable_on_lock \
3116         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3117
3118 .mbar.commit add command -label {Add To Commit} \
3119         -command do_add_selection \
3120         -font font_ui
3121 lappend disable_on_lock \
3122         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3123
3124 .mbar.commit add command -label {Add All To Commit} \
3125         -command do_add_all \
3126         -accelerator $M1T-I \
3127         -font font_ui
3128 lappend disable_on_lock \
3129         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3130
3131 .mbar.commit add command -label {Unstage From Commit} \
3132         -command do_unstage_selection \
3133         -font font_ui
3134 lappend disable_on_lock \
3135         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3136
3137 .mbar.commit add command -label {Revert Changes} \
3138         -command do_revert_selection \
3139         -font font_ui
3140 lappend disable_on_lock \
3141         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3142
3143 .mbar.commit add separator
3144
3145 .mbar.commit add command -label {Sign Off} \
3146         -command do_signoff \
3147         -accelerator $M1T-S \
3148         -font font_ui
3149
3150 .mbar.commit add command -label Commit \
3151         -command do_commit \
3152         -accelerator $M1T-Return \
3153         -font font_ui
3154 lappend disable_on_lock \
3155         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3156
3157 # -- Transport menus
3158 #
3159 if {!$single_commit} {
3160         menu .mbar.fetch
3161         menu .mbar.pull
3162         menu .mbar.push
3163 }
3164
3165 if {[is_MacOSX]} {
3166         # -- Apple Menu (Mac OS X only)
3167         #
3168         .mbar add cascade -label Apple -menu .mbar.apple
3169         menu .mbar.apple
3170
3171         .mbar.apple add command -label "About [appname]" \
3172                 -command do_about \
3173                 -font font_ui
3174         .mbar.apple add command -label "[appname] Options..." \
3175                 -command do_options \
3176                 -font font_ui
3177 } else {
3178         # -- Edit Menu
3179         #
3180         .mbar.edit add separator
3181         .mbar.edit add command -label {Options...} \
3182                 -command do_options \
3183                 -font font_ui
3184
3185         # -- Tools Menu
3186         #
3187         if {[file exists /usr/local/miga/lib/gui-miga]
3188                 && [file exists .pvcsrc]} {
3189         proc do_miga {} {
3190                 global ui_status_value
3191                 if {![lock_index update]} return
3192                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3193                 set miga_fd [open "|$cmd" r]
3194                 fconfigure $miga_fd -blocking 0
3195                 fileevent $miga_fd readable [list miga_done $miga_fd]
3196                 set ui_status_value {Running miga...}
3197         }
3198         proc miga_done {fd} {
3199                 read $fd 512
3200                 if {[eof $fd]} {
3201                         close $fd
3202                         unlock_index
3203                         rescan [list set ui_status_value {Ready.}]
3204                 }
3205         }
3206         .mbar add cascade -label Tools -menu .mbar.tools
3207         menu .mbar.tools
3208         .mbar.tools add command -label "Migrate" \
3209                 -command do_miga \
3210                 -font font_ui
3211         lappend disable_on_lock \
3212                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3213         }
3214
3215         # -- Help Menu
3216         #
3217         .mbar add cascade -label Help -menu .mbar.help
3218         menu .mbar.help
3219
3220         .mbar.help add command -label "About [appname]" \
3221                 -command do_about \
3222                 -font font_ui
3223 }
3224
3225
3226 # -- Branch Control
3227 #
3228 frame .branch \
3229         -borderwidth 1 \
3230         -relief sunken
3231 label .branch.l1 \
3232         -text {Current Branch:} \
3233         -anchor w \
3234         -justify left \
3235         -font font_ui
3236 label .branch.cb \
3237         -textvariable current_branch \
3238         -anchor w \
3239         -justify left \
3240         -font font_ui
3241 pack .branch.l1 -side left
3242 pack .branch.cb -side left -fill x
3243 pack .branch -side top -fill x
3244
3245 # -- Main Window Layout
3246 #
3247 panedwindow .vpane -orient vertical
3248 panedwindow .vpane.files -orient horizontal
3249 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3250 pack .vpane -anchor n -side top -fill both -expand 1
3251
3252 # -- Index File List
3253 #
3254 frame .vpane.files.index -height 100 -width 400
3255 label .vpane.files.index.title -text {Changes To Be Committed} \
3256         -background green \
3257         -font font_ui
3258 text $ui_index -background white -borderwidth 0 \
3259         -width 40 -height 10 \
3260         -font font_ui \
3261         -cursor $cursor_ptr \
3262         -yscrollcommand {.vpane.files.index.sb set} \
3263         -state disabled
3264 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3265 pack .vpane.files.index.title -side top -fill x
3266 pack .vpane.files.index.sb -side right -fill y
3267 pack $ui_index -side left -fill both -expand 1
3268 .vpane.files add .vpane.files.index -sticky nsew
3269
3270 # -- Working Directory File List
3271 #
3272 frame .vpane.files.workdir -height 100 -width 100
3273 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3274         -background red \
3275         -font font_ui
3276 text $ui_workdir -background white -borderwidth 0 \
3277         -width 40 -height 10 \
3278         -font font_ui \
3279         -cursor $cursor_ptr \
3280         -yscrollcommand {.vpane.files.workdir.sb set} \
3281         -state disabled
3282 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3283 pack .vpane.files.workdir.title -side top -fill x
3284 pack .vpane.files.workdir.sb -side right -fill y
3285 pack $ui_workdir -side left -fill both -expand 1
3286 .vpane.files add .vpane.files.workdir -sticky nsew
3287
3288 foreach i [list $ui_index $ui_workdir] {
3289         $i tag conf in_diff -font font_uibold
3290         $i tag conf in_sel \
3291                 -background [$i cget -foreground] \
3292                 -foreground [$i cget -background]
3293 }
3294 unset i
3295
3296 # -- Diff and Commit Area
3297 #
3298 frame .vpane.lower -height 300 -width 400
3299 frame .vpane.lower.commarea
3300 frame .vpane.lower.diff -relief sunken -borderwidth 1
3301 pack .vpane.lower.commarea -side top -fill x
3302 pack .vpane.lower.diff -side bottom -fill both -expand 1
3303 .vpane add .vpane.lower -stick nsew
3304
3305 # -- Commit Area Buttons
3306 #
3307 frame .vpane.lower.commarea.buttons
3308 label .vpane.lower.commarea.buttons.l -text {} \
3309         -anchor w \
3310         -justify left \
3311         -font font_ui
3312 pack .vpane.lower.commarea.buttons.l -side top -fill x
3313 pack .vpane.lower.commarea.buttons -side left -fill y
3314
3315 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3316         -command do_rescan \
3317         -font font_ui
3318 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3319 lappend disable_on_lock \
3320         {.vpane.lower.commarea.buttons.rescan conf -state}
3321
3322 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3323         -command do_add_all \
3324         -font font_ui
3325 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3326 lappend disable_on_lock \
3327         {.vpane.lower.commarea.buttons.incall conf -state}
3328
3329 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3330         -command do_signoff \
3331         -font font_ui
3332 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3333
3334 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3335         -command do_commit \
3336         -font font_ui
3337 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3338 lappend disable_on_lock \
3339         {.vpane.lower.commarea.buttons.commit conf -state}
3340
3341 # -- Commit Message Buffer
3342 #
3343 frame .vpane.lower.commarea.buffer
3344 frame .vpane.lower.commarea.buffer.header
3345 set ui_comm .vpane.lower.commarea.buffer.t
3346 set ui_coml .vpane.lower.commarea.buffer.header.l
3347 radiobutton .vpane.lower.commarea.buffer.header.new \
3348         -text {New Commit} \
3349         -command do_select_commit_type \
3350         -variable selected_commit_type \
3351         -value new \
3352         -font font_ui
3353 lappend disable_on_lock \
3354         [list .vpane.lower.commarea.buffer.header.new conf -state]
3355 radiobutton .vpane.lower.commarea.buffer.header.amend \
3356         -text {Amend Last Commit} \
3357         -command do_select_commit_type \
3358         -variable selected_commit_type \
3359         -value amend \
3360         -font font_ui
3361 lappend disable_on_lock \
3362         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3363 label $ui_coml \
3364         -anchor w \
3365         -justify left \
3366         -font font_ui
3367 proc trace_commit_type {varname args} {
3368         global ui_coml commit_type
3369         switch -glob -- $commit_type {
3370         initial       {set txt {Initial Commit Message:}}
3371         amend         {set txt {Amended Commit Message:}}
3372         amend-initial {set txt {Amended Initial Commit Message:}}
3373         amend-merge   {set txt {Amended Merge Commit Message:}}
3374         merge         {set txt {Merge Commit Message:}}
3375         *             {set txt {Commit Message:}}
3376         }
3377         $ui_coml conf -text $txt
3378 }
3379 trace add variable commit_type write trace_commit_type
3380 pack $ui_coml -side left -fill x
3381 pack .vpane.lower.commarea.buffer.header.amend -side right
3382 pack .vpane.lower.commarea.buffer.header.new -side right
3383
3384 text $ui_comm -background white -borderwidth 1 \
3385         -undo true \
3386         -maxundo 20 \
3387         -autoseparators true \
3388         -relief sunken \
3389         -width 75 -height 9 -wrap none \
3390         -font font_diff \
3391         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3392 scrollbar .vpane.lower.commarea.buffer.sby \
3393         -command [list $ui_comm yview]
3394 pack .vpane.lower.commarea.buffer.header -side top -fill x
3395 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3396 pack $ui_comm -side left -fill y
3397 pack .vpane.lower.commarea.buffer -side left -fill y
3398
3399 # -- Commit Message Buffer Context Menu
3400 #
3401 set ctxm .vpane.lower.commarea.buffer.ctxm
3402 menu $ctxm -tearoff 0
3403 $ctxm add command \
3404         -label {Cut} \
3405         -font font_ui \
3406         -command {tk_textCut $ui_comm}
3407 $ctxm add command \
3408         -label {Copy} \
3409         -font font_ui \
3410         -command {tk_textCopy $ui_comm}
3411 $ctxm add command \
3412         -label {Paste} \
3413         -font font_ui \
3414         -command {tk_textPaste $ui_comm}
3415 $ctxm add command \
3416         -label {Delete} \
3417         -font font_ui \
3418         -command {$ui_comm delete sel.first sel.last}
3419 $ctxm add separator
3420 $ctxm add command \
3421         -label {Select All} \
3422         -font font_ui \
3423         -command {$ui_comm tag add sel 0.0 end}
3424 $ctxm add command \
3425         -label {Copy All} \
3426         -font font_ui \
3427         -command {
3428                 $ui_comm tag add sel 0.0 end
3429                 tk_textCopy $ui_comm
3430                 $ui_comm tag remove sel 0.0 end
3431         }
3432 $ctxm add separator
3433 $ctxm add command \
3434         -label {Sign Off} \
3435         -font font_ui \
3436         -command do_signoff
3437 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3438
3439 # -- Diff Header
3440 #
3441 set current_diff {}
3442 set diff_actions [list]
3443 proc trace_current_diff {varname args} {
3444         global current_diff diff_actions file_states
3445         if {$current_diff eq {}} {
3446                 set s {}
3447                 set f {}
3448                 set p {}
3449                 set o disabled
3450         } else {
3451                 set p $current_diff
3452                 set s [mapdesc [lindex $file_states($p) 0] $p]
3453                 set f {File:}
3454                 set p [escape_path $p]
3455                 set o normal
3456         }
3457
3458         .vpane.lower.diff.header.status configure -text $s
3459         .vpane.lower.diff.header.file configure -text $f
3460         .vpane.lower.diff.header.path configure -text $p
3461         foreach w $diff_actions {
3462                 uplevel #0 $w $o
3463         }
3464 }
3465 trace add variable current_diff write trace_current_diff
3466
3467 frame .vpane.lower.diff.header -background orange
3468 label .vpane.lower.diff.header.status \
3469         -background orange \
3470         -width $max_status_desc \
3471         -anchor w \
3472         -justify left \
3473         -font font_ui
3474 label .vpane.lower.diff.header.file \
3475         -background orange \
3476         -anchor w \
3477         -justify left \
3478         -font font_ui
3479 label .vpane.lower.diff.header.path \
3480         -background orange \
3481         -anchor w \
3482         -justify left \
3483         -font font_ui
3484 pack .vpane.lower.diff.header.status -side left
3485 pack .vpane.lower.diff.header.file -side left
3486 pack .vpane.lower.diff.header.path -fill x
3487 set ctxm .vpane.lower.diff.header.ctxm
3488 menu $ctxm -tearoff 0
3489 $ctxm add command \
3490         -label {Copy} \
3491         -font font_ui \
3492         -command {
3493                 clipboard clear
3494                 clipboard append \
3495                         -format STRING \
3496                         -type STRING \
3497                         -- $current_diff
3498         }
3499 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3500 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3501
3502 # -- Diff Body
3503 #
3504 frame .vpane.lower.diff.body
3505 set ui_diff .vpane.lower.diff.body.t
3506 text $ui_diff -background white -borderwidth 0 \
3507         -width 80 -height 15 -wrap none \
3508         -font font_diff \
3509         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3510         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3511         -state disabled
3512 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3513         -command [list $ui_diff xview]
3514 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3515         -command [list $ui_diff yview]
3516 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3517 pack .vpane.lower.diff.body.sby -side right -fill y
3518 pack $ui_diff -side left -fill both -expand 1
3519 pack .vpane.lower.diff.header -side top -fill x
3520 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3521
3522 $ui_diff tag conf d_@ -font font_diffbold
3523 $ui_diff tag conf d_+  -foreground blue
3524 $ui_diff tag conf d_-  -foreground red
3525 $ui_diff tag conf d_++ -foreground {#00a000}
3526 $ui_diff tag conf d_-- -foreground {#a000a0}
3527 $ui_diff tag conf d_+- \
3528         -foreground red \
3529         -background {light goldenrod yellow}
3530 $ui_diff tag conf d_-+ \
3531         -foreground blue \
3532         -background azure2
3533
3534 # -- Diff Body Context Menu
3535 #
3536 set ctxm .vpane.lower.diff.body.ctxm
3537 menu $ctxm -tearoff 0
3538 $ctxm add command \
3539         -label {Copy} \
3540         -font font_ui \
3541         -command {tk_textCopy $ui_diff}
3542 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543 $ctxm add command \
3544         -label {Select All} \
3545         -font font_ui \
3546         -command {$ui_diff tag add sel 0.0 end}
3547 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3548 $ctxm add command \
3549         -label {Copy All} \
3550         -font font_ui \
3551         -command {
3552                 $ui_diff tag add sel 0.0 end
3553                 tk_textCopy $ui_diff
3554                 $ui_diff tag remove sel 0.0 end
3555         }
3556 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3557 $ctxm add separator
3558 $ctxm add command \
3559         -label {Decrease Font Size} \
3560         -font font_ui \
3561         -command {incr_font_size font_diff -1}
3562 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3563 $ctxm add command \
3564         -label {Increase Font Size} \
3565         -font font_ui \
3566         -command {incr_font_size font_diff 1}
3567 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3568 $ctxm add separator
3569 $ctxm add command \
3570         -label {Show Less Context} \
3571         -font font_ui \
3572         -command {if {$repo_config(gui.diffcontext) >= 2} {
3573                 incr repo_config(gui.diffcontext) -1
3574                 reshow_diff
3575         }}
3576 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3577 $ctxm add command \
3578         -label {Show More Context} \
3579         -font font_ui \
3580         -command {
3581                 incr repo_config(gui.diffcontext)
3582                 reshow_diff
3583         }
3584 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3585 $ctxm add separator
3586 $ctxm add command -label {Options...} \
3587         -font font_ui \
3588         -command do_options
3589 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3590
3591 # -- Status Bar
3592 #
3593 set ui_status_value {Initializing...}
3594 label .status -textvariable ui_status_value \
3595         -anchor w \
3596         -justify left \
3597         -borderwidth 1 \
3598         -relief sunken \
3599         -font font_ui
3600 pack .status -anchor w -side bottom -fill x
3601
3602 # -- Load geometry
3603 #
3604 catch {
3605 set gm $repo_config(gui.geometry)
3606 wm geometry . [lindex $gm 0]
3607 .vpane sash place 0 \
3608         [lindex [.vpane sash coord 0] 0] \
3609         [lindex $gm 1]
3610 .vpane.files sash place 0 \
3611         [lindex $gm 2] \
3612         [lindex [.vpane.files sash coord 0] 1]
3613 unset gm
3614 }
3615
3616 # -- Key Bindings
3617 #
3618 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3619 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3620 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3621 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3622 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3623 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3624 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3625 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3626 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3627 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3628 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3629
3630 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3631 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3632 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3633 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3634 bind $ui_diff <$M1B-Key-v> {break}
3635 bind $ui_diff <$M1B-Key-V> {break}
3636 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3637 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3638 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3639 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3640 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3641 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3642
3643 bind .   <Destroy> do_quit
3644 bind all <Key-F5> do_rescan
3645 bind all <$M1B-Key-r> do_rescan
3646 bind all <$M1B-Key-R> do_rescan
3647 bind .   <$M1B-Key-s> do_signoff
3648 bind .   <$M1B-Key-S> do_signoff
3649 bind .   <$M1B-Key-i> do_add_all
3650 bind .   <$M1B-Key-I> do_add_all
3651 bind .   <$M1B-Key-Return> do_commit
3652 bind all <$M1B-Key-q> do_quit
3653 bind all <$M1B-Key-Q> do_quit
3654 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3655 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3656 foreach i [list $ui_index $ui_workdir] {
3657         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3658         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3659         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3660 }
3661 unset i
3662
3663 set file_lists($ui_index) [list]
3664 set file_lists($ui_workdir) [list]
3665
3666 set HEAD {}
3667 set PARENT {}
3668 set MERGE_HEAD [list]
3669 set commit_type {}
3670 set empty_tree {}
3671 set current_branch {}
3672 set current_diff {}
3673 set selected_commit_type new
3674
3675 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3676 focus -force $ui_comm
3677
3678 # -- Warn the user about environmental problems.  Cygwin's Tcl
3679 #    does *not* pass its env array onto any processes it spawns.
3680 #    This means that git processes get none of our environment.
3681 #
3682 if {[is_Windows]} {
3683         set ignored_env 0
3684         set suggest_user {}
3685         set msg "Possible environment issues exist.
3686
3687 The following environment variables are probably
3688 going to be ignored by any Git subprocess run
3689 by [appname]:
3690
3691 "
3692         foreach name [array names env] {
3693                 switch -regexp -- $name {
3694                 {^GIT_INDEX_FILE$} -
3695                 {^GIT_OBJECT_DIRECTORY$} -
3696                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3697                 {^GIT_DIFF_OPTS$} -
3698                 {^GIT_EXTERNAL_DIFF$} -
3699                 {^GIT_PAGER$} -
3700                 {^GIT_TRACE$} -
3701                 {^GIT_CONFIG$} -
3702                 {^GIT_CONFIG_LOCAL$} -
3703                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3704                         append msg " - $name\n"
3705                         incr ignored_env
3706                 }
3707                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3708                         append msg " - $name\n"
3709                         incr ignored_env
3710                         set suggest_user $name
3711                 }
3712                 }
3713         }
3714         if {$ignored_env > 0} {
3715                 append msg "
3716 This is due to a known issue with the
3717 Tcl binary distributed by Cygwin."
3718
3719                 if {$suggest_user ne {}} {
3720                         append msg "
3721
3722 A good replacement for $suggest_user
3723 is placing values for the user.name and
3724 user.email settings into your personal
3725 ~/.gitconfig file.
3726 "
3727                 }
3728                 warn_popup $msg
3729         }
3730         unset ignored_env msg suggest_user name
3731 }
3732
3733 # -- Only initialize complex UI if we are going to stay running.
3734 #
3735 if {!$single_commit} {
3736         load_all_remotes
3737         load_all_heads
3738
3739         populate_branch_menu .mbar.branch
3740         populate_fetch_menu .mbar.fetch
3741         populate_pull_menu .mbar.pull
3742         populate_push_menu .mbar.push
3743 }
3744
3745 # -- Only suggest a gc run if we are going to stay running.
3746 #
3747 if {!$single_commit} {
3748         set object_limit 2000
3749         if {[is_Windows]} {set object_limit 200}
3750         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
3751         if {$objects_current >= $object_limit} {
3752                 if {[ask_popup \
3753                         "This repository currently has $objects_current loose objects.
3754
3755 To maintain optimal performance it is strongly
3756 recommended that you compress the database
3757 when more than $object_limit loose objects exist.
3758
3759 Compress the database now?"] eq yes} {
3760                         do_gc
3761                 }
3762         }
3763         unset object_limit _junk objects_current
3764 }
3765
3766 lock_index begin-read
3767 after 1 do_rescan