git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc gitattr {path attr default} {
 525         if {[catch {set r [git check-attr $attr -- $path]}]} {
 526                 set r unspecified
 527         } else {
 528                 set r [join [lrange [split $r :] 2 end] :]
 529                 regsub {^ } $r {} r
 530         }
 531         if {$r eq {unspecified}} {
 532                 return $default
 533         }
 534         return $r
 535 }
 536
 537 proc sq {value} {
 538         regsub -all ' $value "'\\''" value
 539         return "'$value'"
 540 }
 541
 542 proc load_current_branch {} {
 543         global current_branch is_detached
 544
 545         set fd [open [gitdir HEAD] r]
 546         if {[gets $fd ref] < 1} {
 547                 set ref {}
 548         }
 549         close $fd
 550
 551         set pfx {ref: refs/heads/}
 552         set len [string length $pfx]
 553         if {[string equal -length $len $pfx $ref]} {
 554                 # We're on a branch.  It might not exist.  But
 555                 # HEAD looks good enough to be a branch.
 556                 #
 557                 set current_branch [string range $ref $len end]
 558                 set is_detached 0
 559         } else {
 560                 # Assume this is a detached head.
 561                 #
 562                 set current_branch HEAD
 563                 set is_detached 1
 564         }
 565 }
 566
 567 auto_load tk_optionMenu
 568 rename tk_optionMenu real__tkOptionMenu
 569 proc tk_optionMenu {w varName args} {
 570         set m [eval real__tkOptionMenu $w $varName $args]
 571         $m configure -font font_ui
 572         $w configure -font font_ui
 573         return $m
 574 }
 575
 576 proc rmsel_tag {text} {
 577         $text tag conf sel \
 578                 -background [$text cget -background] \
 579                 -foreground [$text cget -foreground] \
 580                 -borderwidth 0
 581         $text tag conf in_sel -background lightgray
 582         bind $text <Motion> break
 583         return $text
 584 }
 585
 586 set root_exists 0
 587 bind . <Visibility> {
 588         bind . <Visibility> {}
 589         set root_exists 1
 590 }
 591
 592 if {[is_Windows]} {
 593         wm iconbitmap . -default $oguilib/git-gui.ico
 594         set ::tk::AlwaysShowSelection 1
 595 }
 596
 597 ######################################################################
 598 ##
 599 ## config defaults
 600
 601 set cursor_ptr arrow
 602 font create font_diff -family Courier -size 10
 603 font create font_ui
 604 catch {
 605         label .dummy
 606         eval font configure font_ui [font actual [.dummy cget -font]]
 607         destroy .dummy
 608 }
 609
 610 font create font_uiitalic
 611 font create font_uibold
 612 font create font_diffbold
 613 font create font_diffitalic
 614
 615 foreach class {Button Checkbutton Entry Label
 616                 Labelframe Listbox Menu Message
 617                 Radiobutton Spinbox Text} {
 618         option add *$class.font font_ui
 619 }
 620 unset class
 621
 622 if {[is_Windows] || [is_MacOSX]} {
 623         option add *Menu.tearOff 0
 624 }
 625
 626 if {[is_MacOSX]} {
 627         set M1B M1
 628         set M1T Cmd
 629 } else {
 630         set M1B Control
 631         set M1T Ctrl
 632 }
 633
 634 proc bind_button3 {w cmd} {
 635         bind $w <Any-Button-3> $cmd
 636         if {[is_MacOSX]} {
 637                 # Mac OS X sends Button-2 on right click through three-button mouse,
 638                 # or through trackpad right-clicking (two-finger touch + click).
 639                 bind $w <Any-Button-2> $cmd
 640                 bind $w <Control-Button-1> $cmd
 641         }
 642 }
 643
 644 proc apply_config {} {
 645         global repo_config font_descs
 646
 647         foreach option $font_descs {
 648                 set name [lindex $option 0]
 649                 set font [lindex $option 1]
 650                 if {[catch {
 651                         set need_weight 1
 652                         foreach {cn cv} $repo_config(gui.$name) {
 653                                 if {$cn eq {-weight}} {
 654                                         set need_weight 0
 655                                 }
 656                                 font configure $font $cn $cv
 657                         }
 658                         if {$need_weight} {
 659                                 font configure $font -weight normal
 660                         }
 661                         } err]} {
 662                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 663                 }
 664                 foreach {cn cv} [font configure $font] {
 665                         font configure ${font}bold $cn $cv
 666                         font configure ${font}italic $cn $cv
 667                 }
 668                 font configure ${font}bold -weight bold
 669                 font configure ${font}italic -slant italic
 670         }
 671 }
 672
 673 set default_config(branch.autosetupmerge) true
 674 set default_config(merge.tool) {}
 675 set default_config(merge.keepbackup) true
 676 set default_config(merge.diffstat) true
 677 set default_config(merge.summary) false
 678 set default_config(merge.verbosity) 2
 679 set default_config(user.name) {}
 680 set default_config(user.email) {}
 681
 682 set default_config(gui.encoding) [encoding system]
 683 set default_config(gui.matchtrackingbranch) false
 684 set default_config(gui.pruneduringfetch) false
 685 set default_config(gui.trustmtime) false
 686 set default_config(gui.fastcopyblame) false
 687 set default_config(gui.copyblamethreshold) 40
 688 set default_config(gui.blamehistoryctx) 7
 689 set default_config(gui.diffcontext) 5
 690 set default_config(gui.commitmsgwidth) 75
 691 set default_config(gui.newbranchtemplate) {}
 692 set default_config(gui.spellingdictionary) {}
 693 set default_config(gui.fontui) [font configure font_ui]
 694 set default_config(gui.fontdiff) [font configure font_diff]
 695 set font_descs {
 696         {fontui   font_ui   {mc "Main Font"}}
 697         {fontdiff font_diff {mc "Diff/Console Font"}}
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## find git
 703
 704 set _git  [_which git]
 705 if {$_git eq {}} {
 706         catch {wm withdraw .}
 707         tk_messageBox \
 708                 -icon error \
 709                 -type ok \
 710                 -title [mc "git-gui: fatal error"] \
 711                 -message [mc "Cannot find git in PATH."]
 712         exit 1
 713 }
 714
 715 ######################################################################
 716 ##
 717 ## version check
 718
 719 if {[catch {set _git_version [git --version]} err]} {
 720         catch {wm withdraw .}
 721         tk_messageBox \
 722                 -icon error \
 723                 -type ok \
 724                 -title [mc "git-gui: fatal error"] \
 725                 -message "Cannot determine Git version:
 726
 727 $err
 728
 729 [appname] requires Git 1.5.0 or later."
 730         exit 1
 731 }
 732 if {![regsub {^git version } $_git_version {} _git_version]} {
 733         catch {wm withdraw .}
 734         tk_messageBox \
 735                 -icon error \
 736                 -type ok \
 737                 -title [mc "git-gui: fatal error"] \
 738                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 739         exit 1
 740 }
 741
 742 set _real_git_version $_git_version
 743 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 744 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 745 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 746 regsub {\.GIT$} $_git_version {} _git_version
 747 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 748
 749 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 750         catch {wm withdraw .}
 751         if {[tk_messageBox \
 752                 -icon warning \
 753                 -type yesno \
 754                 -default no \
 755                 -title "[appname]: warning" \
 756                  -message [mc "Git version cannot be determined.
 757
 758 %s claims it is version '%s'.
 759
 760 %s requires at least Git 1.5.0 or later.
 761
 762 Assume '%s' is version 1.5.0?
 763 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 764                 set _git_version 1.5.0
 765         } else {
 766                 exit 1
 767         }
 768 }
 769 unset _real_git_version
 770
 771 proc git-version {args} {
 772         global _git_version
 773
 774         switch [llength $args] {
 775         0 {
 776                 return $_git_version
 777         }
 778
 779         2 {
 780                 set op [lindex $args 0]
 781                 set vr [lindex $args 1]
 782                 set cm [package vcompare $_git_version $vr]
 783                 return [expr $cm $op 0]
 784         }
 785
 786         4 {
 787                 set type [lindex $args 0]
 788                 set name [lindex $args 1]
 789                 set parm [lindex $args 2]
 790                 set body [lindex $args 3]
 791
 792                 if {($type ne {proc} && $type ne {method})} {
 793                         error "Invalid arguments to git-version"
 794                 }
 795                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 796                         error "Last arm of $type $name must be default"
 797                 }
 798
 799                 foreach {op vr cb} [lrange $body 0 end-2] {
 800                         if {[git-version $op $vr]} {
 801                                 return [uplevel [list $type $name $parm $cb]]
 802                         }
 803                 }
 804
 805                 return [uplevel [list $type $name $parm [lindex $body end]]]
 806         }
 807
 808         default {
 809                 error "git-version >= x"
 810         }
 811
 812         }
 813 }
 814
 815 if {[git-version < 1.5]} {
 816         catch {wm withdraw .}
 817         tk_messageBox \
 818                 -icon error \
 819                 -type ok \
 820                 -title [mc "git-gui: fatal error"] \
 821                 -message "[appname] requires Git 1.5.0 or later.
 822
 823 You are using [git-version]:
 824
 825 [git --version]"
 826         exit 1
 827 }
 828
 829 ######################################################################
 830 ##
 831 ## configure our library
 832
 833 set idx [file join $oguilib tclIndex]
 834 if {[catch {set fd [open $idx r]} err]} {
 835         catch {wm withdraw .}
 836         tk_messageBox \
 837                 -icon error \
 838                 -type ok \
 839                 -title [mc "git-gui: fatal error"] \
 840                 -message $err
 841         exit 1
 842 }
 843 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 844         set idx [list]
 845         while {[gets $fd n] >= 0} {
 846                 if {$n ne {} && ![string match #* $n]} {
 847                         lappend idx $n
 848                 }
 849         }
 850 } else {
 851         set idx {}
 852 }
 853 close $fd
 854
 855 if {$idx ne {}} {
 856         set loaded [list]
 857         foreach p $idx {
 858                 if {[lsearch -exact $loaded $p] >= 0} continue
 859                 source [file join $oguilib $p]
 860                 lappend loaded $p
 861         }
 862         unset loaded p
 863 } else {
 864         set auto_path [concat [list $oguilib] $auto_path]
 865 }
 866 unset -nocomplain idx fd
 867
 868 ######################################################################
 869 ##
 870 ## config file parsing
 871
 872 git-version proc _parse_config {arr_name args} {
 873         >= 1.5.3 {
 874                 upvar $arr_name arr
 875                 array unset arr
 876                 set buf {}
 877                 catch {
 878                         set fd_rc [eval \
 879                                 [list git_read config] \
 880                                 $args \
 881                                 [list --null --list]]
 882                         fconfigure $fd_rc -translation binary
 883                         set buf [read $fd_rc]
 884                         close $fd_rc
 885                 }
 886                 foreach line [split $buf "\0"] {
 887                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 888                                 if {[is_many_config $name]} {
 889                                         lappend arr($name) $value
 890                                 } else {
 891                                         set arr($name) $value
 892                                 }
 893                         }
 894                 }
 895         }
 896         default {
 897                 upvar $arr_name arr
 898                 array unset arr
 899                 catch {
 900                         set fd_rc [eval [list git_read config --list] $args]
 901                         while {[gets $fd_rc line] >= 0} {
 902                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 903                                         if {[is_many_config $name]} {
 904                                                 lappend arr($name) $value
 905                                         } else {
 906                                                 set arr($name) $value
 907                                         }
 908                                 }
 909                         }
 910                         close $fd_rc
 911                 }
 912         }
 913 }
 914
 915 proc load_config {include_global} {
 916         global repo_config global_config default_config
 917
 918         if {$include_global} {
 919                 _parse_config global_config --global
 920         }
 921         _parse_config repo_config
 922
 923         foreach name [array names default_config] {
 924                 if {[catch {set v $global_config($name)}]} {
 925                         set global_config($name) $default_config($name)
 926                 }
 927                 if {[catch {set v $repo_config($name)}]} {
 928                         set repo_config($name) $default_config($name)
 929                 }
 930         }
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## feature option selection
 936
 937 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 938         unset _junk
 939 } else {
 940         set subcommand gui
 941 }
 942 if {$subcommand eq {gui.sh}} {
 943         set subcommand gui
 944 }
 945 if {$subcommand eq {gui} && [llength $argv] > 0} {
 946         set subcommand [lindex $argv 0]
 947         set argv [lrange $argv 1 end]
 948 }
 949
 950 enable_option multicommit
 951 enable_option branch
 952 enable_option transport
 953 disable_option bare
 954
 955 switch -- $subcommand {
 956 browser -
 957 blame {
 958         enable_option bare
 959
 960         disable_option multicommit
 961         disable_option branch
 962         disable_option transport
 963 }
 964 citool {
 965         enable_option singlecommit
 966         enable_option retcode
 967
 968         disable_option multicommit
 969         disable_option branch
 970         disable_option transport
 971
 972         while {[llength $argv] > 0} {
 973                 set a [lindex $argv 0]
 974                 switch -- $a {
 975                 --amend {
 976                         enable_option initialamend
 977                 }
 978                 --nocommit {
 979                         enable_option nocommit
 980                         enable_option nocommitmsg
 981                 }
 982                 --commitmsg {
 983                         disable_option nocommitmsg
 984                 }
 985                 default {
 986                         break
 987                 }
 988                 }
 989
 990                 set argv [lrange $argv 1 end]
 991         }
 992 }
 993 }
 994
 995 ######################################################################
 996 ##
 997 ## repository setup
 998
 999 set picked 0
1000 if {[catch {
1001                 set _gitdir $env(GIT_DIR)
1002                 set _prefix {}
1003                 }]
1004         && [catch {
1005                 set _gitdir [git rev-parse --git-dir]
1006                 set _prefix [git rev-parse --show-prefix]
1007         } err]} {
1008         load_config 1
1009         apply_config
1010         choose_repository::pick
1011         set picked 1
1012 }
1013 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1014         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1015 }
1016 if {![file isdirectory $_gitdir]} {
1017         catch {wm withdraw .}
1018         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1019         exit 1
1020 }
1021 if {$_prefix ne {}} {
1022         regsub -all {[^/]+/} $_prefix ../ cdup
1023         if {[catch {cd $cdup} err]} {
1024                 catch {wm withdraw .}
1025                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1026                 exit 1
1027         }
1028         unset cdup
1029 } elseif {![is_enabled bare]} {
1030         if {[lindex [file split $_gitdir] end] ne {.git}} {
1031                 catch {wm withdraw .}
1032                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
1033                 exit 1
1034         }
1035         if {[catch {cd [file dirname $_gitdir]} err]} {
1036                 catch {wm withdraw .}
1037                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
1038                 exit 1
1039         }
1040 }
1041 set _reponame [file split [file normalize $_gitdir]]
1042 if {[lindex $_reponame end] eq {.git}} {
1043         set _reponame [lindex $_reponame end-1]
1044 } else {
1045         set _reponame [lindex $_reponame end]
1046 }
1047
1048 ######################################################################
1049 ##
1050 ## global init
1051
1052 set current_diff_path {}
1053 set current_diff_side {}
1054 set diff_actions [list]
1055
1056 set HEAD {}
1057 set PARENT {}
1058 set MERGE_HEAD [list]
1059 set commit_type {}
1060 set empty_tree {}
1061 set current_branch {}
1062 set is_detached 0
1063 set current_diff_path {}
1064 set is_3way_diff 0
1065 set is_conflict_diff 0
1066 set selected_commit_type new
1067
1068 set nullid "0000000000000000000000000000000000000000"
1069 set nullid2 "0000000000000000000000000000000000000001"
1070
1071 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1072
1073 ######################################################################
1074 ##
1075 ## task management
1076
1077 set rescan_active 0
1078 set diff_active 0
1079 set last_clicked {}
1080
1081 set disable_on_lock [list]
1082 set index_lock_type none
1083
1084 proc lock_index {type} {
1085         global index_lock_type disable_on_lock
1086
1087         if {$index_lock_type eq {none}} {
1088                 set index_lock_type $type
1089                 foreach w $disable_on_lock {
1090                         uplevel #0 $w disabled
1091                 }
1092                 return 1
1093         } elseif {$index_lock_type eq "begin-$type"} {
1094                 set index_lock_type $type
1095                 return 1
1096         }
1097         return 0
1098 }
1099
1100 proc unlock_index {} {
1101         global index_lock_type disable_on_lock
1102
1103         set index_lock_type none
1104         foreach w $disable_on_lock {
1105                 uplevel #0 $w normal
1106         }
1107 }
1108
1109 ######################################################################
1110 ##
1111 ## status
1112
1113 proc repository_state {ctvar hdvar mhvar} {
1114         global current_branch
1115         upvar $ctvar ct $hdvar hd $mhvar mh
1116
1117         set mh [list]
1118
1119         load_current_branch
1120         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1121                 set hd {}
1122                 set ct initial
1123                 return
1124         }
1125
1126         set merge_head [gitdir MERGE_HEAD]
1127         if {[file exists $merge_head]} {
1128                 set ct merge
1129                 set fd_mh [open $merge_head r]
1130                 while {[gets $fd_mh line] >= 0} {
1131                         lappend mh $line
1132                 }
1133                 close $fd_mh
1134                 return
1135         }
1136
1137         set ct normal
1138 }
1139
1140 proc PARENT {} {
1141         global PARENT empty_tree
1142
1143         set p [lindex $PARENT 0]
1144         if {$p ne {}} {
1145                 return $p
1146         }
1147         if {$empty_tree eq {}} {
1148                 set empty_tree [git mktree << {}]
1149         }
1150         return $empty_tree
1151 }
1152
1153 proc force_amend {} {
1154         global selected_commit_type
1155         global HEAD PARENT MERGE_HEAD commit_type
1156
1157         repository_state newType newHEAD newMERGE_HEAD
1158         set HEAD $newHEAD
1159         set PARENT $newHEAD
1160         set MERGE_HEAD $newMERGE_HEAD
1161         set commit_type $newType
1162
1163         set selected_commit_type amend
1164         do_select_commit_type
1165 }
1166
1167 proc rescan {after {honor_trustmtime 1}} {
1168         global HEAD PARENT MERGE_HEAD commit_type
1169         global ui_index ui_workdir ui_comm
1170         global rescan_active file_states
1171         global repo_config
1172
1173         if {$rescan_active > 0 || ![lock_index read]} return
1174
1175         repository_state newType newHEAD newMERGE_HEAD
1176         if {[string match amend* $commit_type]
1177                 && $newType eq {normal}
1178                 && $newHEAD eq $HEAD} {
1179         } else {
1180                 set HEAD $newHEAD
1181                 set PARENT $newHEAD
1182                 set MERGE_HEAD $newMERGE_HEAD
1183                 set commit_type $newType
1184         }
1185
1186         array unset file_states
1187
1188         if {!$::GITGUI_BCK_exists &&
1189                 (![$ui_comm edit modified]
1190                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1191                 if {[string match amend* $commit_type]} {
1192                 } elseif {[load_message GITGUI_MSG]} {
1193                 } elseif {[run_prepare_commit_msg_hook]} {
1194                 } elseif {[load_message MERGE_MSG]} {
1195                 } elseif {[load_message SQUASH_MSG]} {
1196                 }
1197                 $ui_comm edit reset
1198                 $ui_comm edit modified false
1199         }
1200
1201         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1202                 rescan_stage2 {} $after
1203         } else {
1204                 set rescan_active 1
1205                 ui_status [mc "Refreshing file status..."]
1206                 set fd_rf [git_read update-index \
1207                         -q \
1208                         --unmerged \
1209                         --ignore-missing \
1210                         --refresh \
1211                         ]
1212                 fconfigure $fd_rf -blocking 0 -translation binary
1213                 fileevent $fd_rf readable \
1214                         [list rescan_stage2 $fd_rf $after]
1215         }
1216 }
1217
1218 if {[is_Cygwin]} {
1219         set is_git_info_exclude {}
1220         proc have_info_exclude {} {
1221                 global is_git_info_exclude
1222
1223                 if {$is_git_info_exclude eq {}} {
1224                         if {[catch {exec test -f [gitdir info exclude]}]} {
1225                                 set is_git_info_exclude 0
1226                         } else {
1227                                 set is_git_info_exclude 1
1228                         }
1229                 }
1230                 return $is_git_info_exclude
1231         }
1232 } else {
1233         proc have_info_exclude {} {
1234                 return [file readable [gitdir info exclude]]
1235         }
1236 }
1237
1238 proc rescan_stage2 {fd after} {
1239         global rescan_active buf_rdi buf_rdf buf_rlo
1240
1241         if {$fd ne {}} {
1242                 read $fd
1243                 if {![eof $fd]} return
1244                 close $fd
1245         }
1246
1247         set ls_others [list --exclude-per-directory=.gitignore]
1248         if {[have_info_exclude]} {
1249                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1250         }
1251         set user_exclude [get_config core.excludesfile]
1252         if {$user_exclude ne {} && [file readable $user_exclude]} {
1253                 lappend ls_others "--exclude-from=$user_exclude"
1254         }
1255
1256         set buf_rdi {}
1257         set buf_rdf {}
1258         set buf_rlo {}
1259
1260         set rescan_active 3
1261         ui_status [mc "Scanning for modified files ..."]
1262         set fd_di [git_read diff-index --cached -z [PARENT]]
1263         set fd_df [git_read diff-files -z]
1264         set fd_lo [eval git_read ls-files --others -z $ls_others]
1265
1266         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1267         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1268         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1269         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1270         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1271         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1272 }
1273
1274 proc load_message {file} {
1275         global ui_comm
1276
1277         set f [gitdir $file]
1278         if {[file isfile $f]} {
1279                 if {[catch {set fd [open $f r]}]} {
1280                         return 0
1281                 }
1282                 fconfigure $fd -eofchar {}
1283                 set content [string trim [read $fd]]
1284                 close $fd
1285                 regsub -all -line {[ \r\t]+$} $content {} content
1286                 $ui_comm delete 0.0 end
1287                 $ui_comm insert end $content
1288                 return 1
1289         }
1290         return 0
1291 }
1292
1293 proc run_prepare_commit_msg_hook {} {
1294         global pch_error
1295
1296         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1297         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1298         # empty file but existant file.
1299
1300         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1301
1302         if {[file isfile [gitdir MERGE_MSG]]} {
1303                 set pcm_source "merge"
1304                 set fd_mm [open [gitdir MERGE_MSG] r]
1305                 puts -nonewline $fd_pcm [read $fd_mm]
1306                 close $fd_mm
1307         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1308                 set pcm_source "squash"
1309                 set fd_sm [open [gitdir SQUASH_MSG] r]
1310                 puts -nonewline $fd_pcm [read $fd_sm]
1311                 close $fd_sm
1312         } else {
1313                 set pcm_source ""
1314         }
1315
1316         close $fd_pcm
1317
1318         set fd_ph [githook_read prepare-commit-msg \
1319                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1320         if {$fd_ph eq {}} {
1321                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1322                 return 0;
1323         }
1324
1325         ui_status [mc "Calling prepare-commit-msg hook..."]
1326         set pch_error {}
1327
1328         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1329         fileevent $fd_ph readable \
1330                 [list prepare_commit_msg_hook_wait $fd_ph]
1331
1332         return 1;
1333 }
1334
1335 proc prepare_commit_msg_hook_wait {fd_ph} {
1336         global pch_error
1337
1338         append pch_error [read $fd_ph]
1339         fconfigure $fd_ph -blocking 1
1340         if {[eof $fd_ph]} {
1341                 if {[catch {close $fd_ph}]} {
1342                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1343                         hook_failed_popup prepare-commit-msg $pch_error
1344                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1345                         exit 1
1346                 } else {
1347                         load_message PREPARE_COMMIT_MSG
1348                 }
1349                 set pch_error {}
1350                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1351                 return
1352         }
1353         fconfigure $fd_ph -blocking 0
1354         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1355 }
1356
1357 proc read_diff_index {fd after} {
1358         global buf_rdi
1359
1360         append buf_rdi [read $fd]
1361         set c 0
1362         set n [string length $buf_rdi]
1363         while {$c < $n} {
1364                 set z1 [string first "\0" $buf_rdi $c]
1365                 if {$z1 == -1} break
1366                 incr z1
1367                 set z2 [string first "\0" $buf_rdi $z1]
1368                 if {$z2 == -1} break
1369
1370                 incr c
1371                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1372                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1373                 merge_state \
1374                         [encoding convertfrom $p] \
1375                         [lindex $i 4]? \
1376                         [list [lindex $i 0] [lindex $i 2]] \
1377                         [list]
1378                 set c $z2
1379                 incr c
1380         }
1381         if {$c < $n} {
1382                 set buf_rdi [string range $buf_rdi $c end]
1383         } else {
1384                 set buf_rdi {}
1385         }
1386
1387         rescan_done $fd buf_rdi $after
1388 }
1389
1390 proc read_diff_files {fd after} {
1391         global buf_rdf
1392
1393         append buf_rdf [read $fd]
1394         set c 0
1395         set n [string length $buf_rdf]
1396         while {$c < $n} {
1397                 set z1 [string first "\0" $buf_rdf $c]
1398                 if {$z1 == -1} break
1399                 incr z1
1400                 set z2 [string first "\0" $buf_rdf $z1]
1401                 if {$z2 == -1} break
1402
1403                 incr c
1404                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1405                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1406                 merge_state \
1407                         [encoding convertfrom $p] \
1408                         ?[lindex $i 4] \
1409                         [list] \
1410                         [list [lindex $i 0] [lindex $i 2]]
1411                 set c $z2
1412                 incr c
1413         }
1414         if {$c < $n} {
1415                 set buf_rdf [string range $buf_rdf $c end]
1416         } else {
1417                 set buf_rdf {}
1418         }
1419
1420         rescan_done $fd buf_rdf $after
1421 }
1422
1423 proc read_ls_others {fd after} {
1424         global buf_rlo
1425
1426         append buf_rlo [read $fd]
1427         set pck [split $buf_rlo "\0"]
1428         set buf_rlo [lindex $pck end]
1429         foreach p [lrange $pck 0 end-1] {
1430                 set p [encoding convertfrom $p]
1431                 if {[string index $p end] eq {/}} {
1432                         set p [string range $p 0 end-1]
1433                 }
1434                 merge_state $p ?O
1435         }
1436         rescan_done $fd buf_rlo $after
1437 }
1438
1439 proc rescan_done {fd buf after} {
1440         global rescan_active current_diff_path
1441         global file_states repo_config
1442         upvar $buf to_clear
1443
1444         if {![eof $fd]} return
1445         set to_clear {}
1446         close $fd
1447         if {[incr rescan_active -1] > 0} return
1448
1449         prune_selection
1450         unlock_index
1451         display_all_files
1452         if {$current_diff_path ne {}} reshow_diff
1453         if {$current_diff_path eq {}} select_first_diff
1454
1455         uplevel #0 $after
1456 }
1457
1458 proc prune_selection {} {
1459         global file_states selected_paths
1460
1461         foreach path [array names selected_paths] {
1462                 if {[catch {set still_here $file_states($path)}]} {
1463                         unset selected_paths($path)
1464                 }
1465         }
1466 }
1467
1468 ######################################################################
1469 ##
1470 ## ui helpers
1471
1472 proc mapicon {w state path} {
1473         global all_icons
1474
1475         if {[catch {set r $all_icons($state$w)}]} {
1476                 puts "error: no icon for $w state={$state} $path"
1477                 return file_plain
1478         }
1479         return $r
1480 }
1481
1482 proc mapdesc {state path} {
1483         global all_descs
1484
1485         if {[catch {set r $all_descs($state)}]} {
1486                 puts "error: no desc for state={$state} $path"
1487                 return $state
1488         }
1489         return $r
1490 }
1491
1492 proc ui_status {msg} {
1493         global main_status
1494         if {[info exists main_status]} {
1495                 $main_status show $msg
1496         }
1497 }
1498
1499 proc ui_ready {{test {}}} {
1500         global main_status
1501         if {[info exists main_status]} {
1502                 $main_status show [mc "Ready."] $test
1503         }
1504 }
1505
1506 proc escape_path {path} {
1507         regsub -all {\\} $path "\\\\" path
1508         regsub -all "\n" $path "\\n" path
1509         return $path
1510 }
1511
1512 proc short_path {path} {
1513         return [escape_path [lindex [file split $path] end]]
1514 }
1515
1516 set next_icon_id 0
1517 set null_sha1 [string repeat 0 40]
1518
1519 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1520         global file_states next_icon_id null_sha1
1521
1522         set s0 [string index $new_state 0]
1523         set s1 [string index $new_state 1]
1524
1525         if {[catch {set info $file_states($path)}]} {
1526                 set state __
1527                 set icon n[incr next_icon_id]
1528         } else {
1529                 set state [lindex $info 0]
1530                 set icon [lindex $info 1]
1531                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1532                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1533         }
1534
1535         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1536         elseif {$s0 eq {_}} {set s0 _}
1537
1538         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1539         elseif {$s1 eq {_}} {set s1 _}
1540
1541         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1542                 set head_info [list 0 $null_sha1]
1543         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1544                 && $head_info eq {}} {
1545                 set head_info $index_info
1546         }
1547
1548         set file_states($path) [list $s0$s1 $icon \
1549                 $head_info $index_info \
1550                 ]
1551         return $state
1552 }
1553
1554 proc display_file_helper {w path icon_name old_m new_m} {
1555         global file_lists
1556
1557         if {$new_m eq {_}} {
1558                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1559                 if {$lno >= 0} {
1560                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1561                         incr lno
1562                         $w conf -state normal
1563                         $w delete $lno.0 [expr {$lno + 1}].0
1564                         $w conf -state disabled
1565                 }
1566         } elseif {$old_m eq {_} && $new_m ne {_}} {
1567                 lappend file_lists($w) $path
1568                 set file_lists($w) [lsort -unique $file_lists($w)]
1569                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1570                 incr lno
1571                 $w conf -state normal
1572                 $w image create $lno.0 \
1573                         -align center -padx 5 -pady 1 \
1574                         -name $icon_name \
1575                         -image [mapicon $w $new_m $path]
1576                 $w insert $lno.1 "[escape_path $path]\n"
1577                 $w conf -state disabled
1578         } elseif {$old_m ne $new_m} {
1579                 $w conf -state normal
1580                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1581                 $w conf -state disabled
1582         }
1583 }
1584
1585 proc display_file {path state} {
1586         global file_states selected_paths
1587         global ui_index ui_workdir
1588
1589         set old_m [merge_state $path $state]
1590         set s $file_states($path)
1591         set new_m [lindex $s 0]
1592         set icon_name [lindex $s 1]
1593
1594         set o [string index $old_m 0]
1595         set n [string index $new_m 0]
1596         if {$o eq {U}} {
1597                 set o _
1598         }
1599         if {$n eq {U}} {
1600                 set n _
1601         }
1602         display_file_helper     $ui_index $path $icon_name $o $n
1603
1604         if {[string index $old_m 0] eq {U}} {
1605                 set o U
1606         } else {
1607                 set o [string index $old_m 1]
1608         }
1609         if {[string index $new_m 0] eq {U}} {
1610                 set n U
1611         } else {
1612                 set n [string index $new_m 1]
1613         }
1614         display_file_helper     $ui_workdir $path $icon_name $o $n
1615
1616         if {$new_m eq {__}} {
1617                 unset file_states($path)
1618                 catch {unset selected_paths($path)}
1619         }
1620 }
1621
1622 proc display_all_files_helper {w path icon_name m} {
1623         global file_lists
1624
1625         lappend file_lists($w) $path
1626         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1627         $w image create end \
1628                 -align center -padx 5 -pady 1 \
1629                 -name $icon_name \
1630                 -image [mapicon $w $m $path]
1631         $w insert end "[escape_path $path]\n"
1632 }
1633
1634 proc display_all_files {} {
1635         global ui_index ui_workdir
1636         global file_states file_lists
1637         global last_clicked
1638
1639         $ui_index conf -state normal
1640         $ui_workdir conf -state normal
1641
1642         $ui_index delete 0.0 end
1643         $ui_workdir delete 0.0 end
1644         set last_clicked {}
1645
1646         set file_lists($ui_index) [list]
1647         set file_lists($ui_workdir) [list]
1648
1649         foreach path [lsort [array names file_states]] {
1650                 set s $file_states($path)
1651                 set m [lindex $s 0]
1652                 set icon_name [lindex $s 1]
1653
1654                 set s [string index $m 0]
1655                 if {$s ne {U} && $s ne {_}} {
1656                         display_all_files_helper $ui_index $path \
1657                                 $icon_name $s
1658                 }
1659
1660                 if {[string index $m 0] eq {U}} {
1661                         set s U
1662                 } else {
1663                         set s [string index $m 1]
1664                 }
1665                 if {$s ne {_}} {
1666                         display_all_files_helper $ui_workdir $path \
1667                                 $icon_name $s
1668                 }
1669         }
1670
1671         $ui_index conf -state disabled
1672         $ui_workdir conf -state disabled
1673 }
1674
1675 ######################################################################
1676 ##
1677 ## icons
1678
1679 set filemask {
1680 #define mask_width 14
1681 #define mask_height 15
1682 static unsigned char mask_bits[] = {
1683    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1684    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1685    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1686 }
1687
1688 image create bitmap file_plain -background white -foreground black -data {
1689 #define plain_width 14
1690 #define plain_height 15
1691 static unsigned char plain_bits[] = {
1692    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1693    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1694    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1695 } -maskdata $filemask
1696
1697 image create bitmap file_mod -background white -foreground blue -data {
1698 #define mod_width 14
1699 #define mod_height 15
1700 static unsigned char mod_bits[] = {
1701    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1702    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1703    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1704 } -maskdata $filemask
1705
1706 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1707 #define file_fulltick_width 14
1708 #define file_fulltick_height 15
1709 static unsigned char file_fulltick_bits[] = {
1710    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1711    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1712    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1713 } -maskdata $filemask
1714
1715 image create bitmap file_parttick -background white -foreground "#005050" -data {
1716 #define parttick_width 14
1717 #define parttick_height 15
1718 static unsigned char parttick_bits[] = {
1719    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1720    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1721    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1722 } -maskdata $filemask
1723
1724 image create bitmap file_question -background white -foreground black -data {
1725 #define file_question_width 14
1726 #define file_question_height 15
1727 static unsigned char file_question_bits[] = {
1728    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1729    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1730    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1731 } -maskdata $filemask
1732
1733 image create bitmap file_removed -background white -foreground red -data {
1734 #define file_removed_width 14
1735 #define file_removed_height 15
1736 static unsigned char file_removed_bits[] = {
1737    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1738    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1739    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1740 } -maskdata $filemask
1741
1742 image create bitmap file_merge -background white -foreground blue -data {
1743 #define file_merge_width 14
1744 #define file_merge_height 15
1745 static unsigned char file_merge_bits[] = {
1746    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1747    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1748    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1749 } -maskdata $filemask
1750
1751 image create bitmap file_statechange -background white -foreground green -data {
1752 #define file_merge_width 14
1753 #define file_merge_height 15
1754 static unsigned char file_statechange_bits[] = {
1755    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1756    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1757    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1758 } -maskdata $filemask
1759
1760 set ui_index .vpane.files.index.list
1761 set ui_workdir .vpane.files.workdir.list
1762
1763 set all_icons(_$ui_index)   file_plain
1764 set all_icons(A$ui_index)   file_fulltick
1765 set all_icons(M$ui_index)   file_fulltick
1766 set all_icons(D$ui_index)   file_removed
1767 set all_icons(U$ui_index)   file_merge
1768 set all_icons(T$ui_index)   file_statechange
1769
1770 set all_icons(_$ui_workdir) file_plain
1771 set all_icons(M$ui_workdir) file_mod
1772 set all_icons(D$ui_workdir) file_question
1773 set all_icons(U$ui_workdir) file_merge
1774 set all_icons(O$ui_workdir) file_plain
1775 set all_icons(T$ui_workdir) file_statechange
1776
1777 set max_status_desc 0
1778 foreach i {
1779                 {__ {mc "Unmodified"}}
1780
1781                 {_M {mc "Modified, not staged"}}
1782                 {M_ {mc "Staged for commit"}}
1783                 {MM {mc "Portions staged for commit"}}
1784                 {MD {mc "Staged for commit, missing"}}
1785
1786                 {_T {mc "File type changed, not staged"}}
1787                 {T_ {mc "File type changed, staged"}}
1788
1789                 {_O {mc "Untracked, not staged"}}
1790                 {A_ {mc "Staged for commit"}}
1791                 {AM {mc "Portions staged for commit"}}
1792                 {AD {mc "Staged for commit, missing"}}
1793
1794                 {_D {mc "Missing"}}
1795                 {D_ {mc "Staged for removal"}}
1796                 {DO {mc "Staged for removal, still present"}}
1797
1798                 {_U {mc "Requires merge resolution"}}
1799                 {U_ {mc "Requires merge resolution"}}
1800                 {UU {mc "Requires merge resolution"}}
1801                 {UM {mc "Requires merge resolution"}}
1802                 {UD {mc "Requires merge resolution"}}
1803                 {UT {mc "Requires merge resolution"}}
1804         } {
1805         set text [eval [lindex $i 1]]
1806         if {$max_status_desc < [string length $text]} {
1807                 set max_status_desc [string length $text]
1808         }
1809         set all_descs([lindex $i 0]) $text
1810 }
1811 unset i
1812
1813 ######################################################################
1814 ##
1815 ## util
1816
1817 proc scrollbar2many {list mode args} {
1818         foreach w $list {eval $w $mode $args}
1819 }
1820
1821 proc many2scrollbar {list mode sb top bottom} {
1822         $sb set $top $bottom
1823         foreach w $list {$w $mode moveto $top}
1824 }
1825
1826 proc incr_font_size {font {amt 1}} {
1827         set sz [font configure $font -size]
1828         incr sz $amt
1829         font configure $font -size $sz
1830         font configure ${font}bold -size $sz
1831         font configure ${font}italic -size $sz
1832 }
1833
1834 ######################################################################
1835 ##
1836 ## ui commands
1837
1838 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1839
1840 proc do_gitk {revs} {
1841         # -- Always start gitk through whatever we were loaded with.  This
1842         #    lets us bypass using shell process on Windows systems.
1843         #
1844         set exe [_which gitk -script]
1845         set cmd [list [info nameofexecutable] $exe]
1846         if {$exe eq {}} {
1847                 error_popup [mc "Couldn't find gitk in PATH"]
1848         } else {
1849                 global env
1850
1851                 if {[info exists env(GIT_DIR)]} {
1852                         set old_GIT_DIR $env(GIT_DIR)
1853                 } else {
1854                         set old_GIT_DIR {}
1855                 }
1856
1857                 set pwd [pwd]
1858                 cd [file dirname [gitdir]]
1859                 set env(GIT_DIR) [file tail [gitdir]]
1860
1861                 eval exec $cmd $revs &
1862
1863                 if {$old_GIT_DIR eq {}} {
1864                         unset env(GIT_DIR)
1865                 } else {
1866                         set env(GIT_DIR) $old_GIT_DIR
1867                 }
1868                 cd $pwd
1869
1870                 ui_status $::starting_gitk_msg
1871                 after 10000 {
1872                         ui_ready $starting_gitk_msg
1873                 }
1874         }
1875 }
1876
1877 proc do_explore {} {
1878         set explorer {}
1879         if {[is_Cygwin] || [is_Windows]} {
1880                 set explorer "explorer.exe"
1881         } elseif {[is_MacOSX]} {
1882                 set explorer "open"
1883         } else {
1884                 # freedesktop.org-conforming system is our best shot
1885                 set explorer "xdg-open"
1886         }
1887         eval exec $explorer [file dirname [gitdir]] &
1888 }
1889
1890 set is_quitting 0
1891 set ret_code    1
1892
1893 proc terminate_me {win} {
1894         global ret_code
1895         if {$win ne {.}} return
1896         exit $ret_code
1897 }
1898
1899 proc do_quit {{rc {1}}} {
1900         global ui_comm is_quitting repo_config commit_type
1901         global GITGUI_BCK_exists GITGUI_BCK_i
1902         global ui_comm_spell
1903         global ret_code
1904
1905         if {$is_quitting} return
1906         set is_quitting 1
1907
1908         if {[winfo exists $ui_comm]} {
1909                 # -- Stash our current commit buffer.
1910                 #
1911                 set save [gitdir GITGUI_MSG]
1912                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1913                         file rename -force [gitdir GITGUI_BCK] $save
1914                         set GITGUI_BCK_exists 0
1915                 } else {
1916                         set msg [string trim [$ui_comm get 0.0 end]]
1917                         regsub -all -line {[ \r\t]+$} $msg {} msg
1918                         if {(![string match amend* $commit_type]
1919                                 || [$ui_comm edit modified])
1920                                 && $msg ne {}} {
1921                                 catch {
1922                                         set fd [open $save w]
1923                                         puts -nonewline $fd $msg
1924                                         close $fd
1925                                 }
1926                         } else {
1927                                 catch {file delete $save}
1928                         }
1929                 }
1930
1931                 # -- Cancel our spellchecker if its running.
1932                 #
1933                 if {[info exists ui_comm_spell]} {
1934                         $ui_comm_spell stop
1935                 }
1936
1937                 # -- Remove our editor backup, its not needed.
1938                 #
1939                 after cancel $GITGUI_BCK_i
1940                 if {$GITGUI_BCK_exists} {
1941                         catch {file delete [gitdir GITGUI_BCK]}
1942                 }
1943
1944                 # -- Stash our current window geometry into this repository.
1945                 #
1946                 set cfg_geometry [list]
1947                 lappend cfg_geometry [wm geometry .]
1948                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1949                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1950                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1951                         set rc_geometry {}
1952                 }
1953                 if {$cfg_geometry ne $rc_geometry} {
1954                         catch {git config gui.geometry $cfg_geometry}
1955                 }
1956         }
1957
1958         set ret_code $rc
1959         destroy .
1960 }
1961
1962 proc do_rescan {} {
1963         rescan ui_ready
1964 }
1965
1966 proc ui_do_rescan {} {
1967         rescan {force_first_diff; ui_ready}
1968 }
1969
1970 proc do_commit {} {
1971         commit_tree
1972 }
1973
1974 proc next_diff {} {
1975         global next_diff_p next_diff_w next_diff_i
1976         show_diff $next_diff_p $next_diff_w {}
1977 }
1978
1979 proc find_anchor_pos {lst name} {
1980         set lid [lsearch -sorted -exact $lst $name]
1981
1982         if {$lid == -1} {
1983                 set lid 0
1984                 foreach lname $lst {
1985                         if {$lname >= $name} break
1986                         incr lid
1987                 }
1988         }
1989
1990         return $lid
1991 }
1992
1993 proc find_file_from {flist idx delta path mmask} {
1994         global file_states
1995
1996         set len [llength $flist]
1997         while {$idx >= 0 && $idx < $len} {
1998                 set name [lindex $flist $idx]
1999
2000                 if {$name ne $path && [info exists file_states($name)]} {
2001                         set state [lindex $file_states($name) 0]
2002
2003                         if {$mmask eq {} || [regexp $mmask $state]} {
2004                                 return $idx
2005                         }
2006                 }
2007
2008                 incr idx $delta
2009         }
2010
2011         return {}
2012 }
2013
2014 proc find_next_diff {w path {lno {}} {mmask {}}} {
2015         global next_diff_p next_diff_w next_diff_i
2016         global file_lists ui_index ui_workdir
2017
2018         set flist $file_lists($w)
2019         if {$lno eq {}} {
2020                 set lno [find_anchor_pos $flist $path]
2021         } else {
2022                 incr lno -1
2023         }
2024
2025         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2026                 if {$w eq $ui_index} {
2027                         set mmask "^$mmask"
2028                 } else {
2029                         set mmask "$mmask\$"
2030                 }
2031         }
2032
2033         set idx [find_file_from $flist $lno 1 $path $mmask]
2034         if {$idx eq {}} {
2035                 incr lno -1
2036                 set idx [find_file_from $flist $lno -1 $path $mmask]
2037         }
2038
2039         if {$idx ne {}} {
2040                 set next_diff_w $w
2041                 set next_diff_p [lindex $flist $idx]
2042                 set next_diff_i [expr {$idx+1}]
2043                 return 1
2044         } else {
2045                 return 0
2046         }
2047 }
2048
2049 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2050         global current_diff_path
2051
2052         if {$path ne $current_diff_path} {
2053                 return {}
2054         } elseif {[find_next_diff $w $path $lno $mmask]} {
2055                 return {next_diff;}
2056         } else {
2057                 return {reshow_diff;}
2058         }
2059 }
2060
2061 proc select_first_diff {} {
2062         global ui_workdir
2063
2064         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2065             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2066                 next_diff
2067         }
2068 }
2069
2070 proc force_first_diff {} {
2071         global current_diff_path
2072
2073         if {[info exists file_states($current_diff_path)]} {
2074                 set state [lindex $file_states($current_diff_path) 0]
2075
2076                 if {[string index $state 1] ne {O}} return
2077         }
2078
2079         select_first_diff
2080 }
2081
2082 proc toggle_or_diff {w x y} {
2083         global file_states file_lists current_diff_path ui_index ui_workdir
2084         global last_clicked selected_paths
2085
2086         set pos [split [$w index @$x,$y] .]
2087         set lno [lindex $pos 0]
2088         set col [lindex $pos 1]
2089         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2090         if {$path eq {}} {
2091                 set last_clicked {}
2092                 return
2093         }
2094
2095         set last_clicked [list $w $lno]
2096         array unset selected_paths
2097         $ui_index tag remove in_sel 0.0 end
2098         $ui_workdir tag remove in_sel 0.0 end
2099
2100         # Determine the state of the file
2101         if {[info exists file_states($path)]} {
2102                 set state [lindex $file_states($path) 0]
2103         } else {
2104                 set state {__}
2105         }
2106
2107         # Restage the file, or simply show the diff
2108         if {$col == 0 && $y > 1} {
2109                 # Conflicts need special handling
2110                 if {[string first {U} $state] >= 0} {
2111                         # $w must always be $ui_workdir, but...
2112                         if {$w ne $ui_workdir} { set lno {} }
2113                         merge_stage_workdir $path $lno
2114                         return
2115                 }
2116
2117                 if {[string index $state 1] eq {O}} {
2118                         set mmask {}
2119                 } else {
2120                         set mmask {[^O]}
2121                 }
2122
2123                 set after [next_diff_after_action $w $path $lno $mmask]
2124
2125                 if {$w eq $ui_index} {
2126                         update_indexinfo \
2127                                 "Unstaging [short_path $path] from commit" \
2128                                 [list $path] \
2129                                 [concat $after [list ui_ready]]
2130                 } elseif {$w eq $ui_workdir} {
2131                         update_index \
2132                                 "Adding [short_path $path]" \
2133                                 [list $path] \
2134                                 [concat $after [list ui_ready]]
2135                 }
2136         } else {
2137                 show_diff $path $w $lno
2138         }
2139 }
2140
2141 proc add_one_to_selection {w x y} {
2142         global file_lists last_clicked selected_paths
2143
2144         set lno [lindex [split [$w index @$x,$y] .] 0]
2145         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2146         if {$path eq {}} {
2147                 set last_clicked {}
2148                 return
2149         }
2150
2151         if {$last_clicked ne {}
2152                 && [lindex $last_clicked 0] ne $w} {
2153                 array unset selected_paths
2154                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2155         }
2156
2157         set last_clicked [list $w $lno]
2158         if {[catch {set in_sel $selected_paths($path)}]} {
2159                 set in_sel 0
2160         }
2161         if {$in_sel} {
2162                 unset selected_paths($path)
2163                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2164         } else {
2165                 set selected_paths($path) 1
2166                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2167         }
2168 }
2169
2170 proc add_range_to_selection {w x y} {
2171         global file_lists last_clicked selected_paths
2172
2173         if {[lindex $last_clicked 0] ne $w} {
2174                 toggle_or_diff $w $x $y
2175                 return
2176         }
2177
2178         set lno [lindex [split [$w index @$x,$y] .] 0]
2179         set lc [lindex $last_clicked 1]
2180         if {$lc < $lno} {
2181                 set begin $lc
2182                 set end $lno
2183         } else {
2184                 set begin $lno
2185                 set end $lc
2186         }
2187
2188         foreach path [lrange $file_lists($w) \
2189                 [expr {$begin - 1}] \
2190                 [expr {$end - 1}]] {
2191                 set selected_paths($path) 1
2192         }
2193         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2194 }
2195
2196 proc show_more_context {} {
2197         global repo_config
2198         if {$repo_config(gui.diffcontext) < 99} {
2199                 incr repo_config(gui.diffcontext)
2200                 reshow_diff
2201         }
2202 }
2203
2204 proc show_less_context {} {
2205         global repo_config
2206         if {$repo_config(gui.diffcontext) > 1} {
2207                 incr repo_config(gui.diffcontext) -1
2208                 reshow_diff
2209         }
2210 }
2211
2212 ######################################################################
2213 ##
2214 ## ui construction
2215
2216 load_config 0
2217 apply_config
2218 set ui_comm {}
2219
2220 # -- Menu Bar
2221 #
2222 menu .mbar -tearoff 0
2223 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2224 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2225 if {[is_enabled branch]} {
2226         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2227 }
2228 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2229         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2230 }
2231 if {[is_enabled transport]} {
2232         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2233         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2234 }
2235 . configure -menu .mbar
2236
2237 # -- Repository Menu
2238 #
2239 menu .mbar.repository
2240
2241 .mbar.repository add command \
2242         -label [mc "Explore Working Copy"] \
2243         -command {do_explore}
2244 .mbar.repository add separator
2245
2246 .mbar.repository add command \
2247         -label [mc "Browse Current Branch's Files"] \
2248         -command {browser::new $current_branch}
2249 set ui_browse_current [.mbar.repository index last]
2250 .mbar.repository add command \
2251         -label [mc "Browse Branch Files..."] \
2252         -command browser_open::dialog
2253 .mbar.repository add separator
2254
2255 .mbar.repository add command \
2256         -label [mc "Visualize Current Branch's History"] \
2257         -command {do_gitk $current_branch}
2258 set ui_visualize_current [.mbar.repository index last]
2259 .mbar.repository add command \
2260         -label [mc "Visualize All Branch History"] \
2261         -command {do_gitk --all}
2262 .mbar.repository add separator
2263
2264 proc current_branch_write {args} {
2265         global current_branch
2266         .mbar.repository entryconf $::ui_browse_current \
2267                 -label [mc "Browse %s's Files" $current_branch]
2268         .mbar.repository entryconf $::ui_visualize_current \
2269                 -label [mc "Visualize %s's History" $current_branch]
2270 }
2271 trace add variable current_branch write current_branch_write
2272
2273 if {[is_enabled multicommit]} {
2274         .mbar.repository add command -label [mc "Database Statistics"] \
2275                 -command do_stats
2276
2277         .mbar.repository add command -label [mc "Compress Database"] \
2278                 -command do_gc
2279
2280         .mbar.repository add command -label [mc "Verify Database"] \
2281                 -command do_fsck_objects
2282
2283         .mbar.repository add separator
2284
2285         if {[is_Cygwin]} {
2286                 .mbar.repository add command \
2287                         -label [mc "Create Desktop Icon"] \
2288                         -command do_cygwin_shortcut
2289         } elseif {[is_Windows]} {
2290                 .mbar.repository add command \
2291                         -label [mc "Create Desktop Icon"] \
2292                         -command do_windows_shortcut
2293         } elseif {[is_MacOSX]} {
2294                 .mbar.repository add command \
2295                         -label [mc "Create Desktop Icon"] \
2296                         -command do_macosx_app
2297         }
2298 }
2299
2300 if {[is_MacOSX]} {
2301         proc ::tk::mac::Quit {args} { do_quit }
2302 } else {
2303         .mbar.repository add command -label [mc Quit] \
2304                 -command do_quit \
2305                 -accelerator $M1T-Q
2306 }
2307
2308 # -- Edit Menu
2309 #
2310 menu .mbar.edit
2311 .mbar.edit add command -label [mc Undo] \
2312         -command {catch {[focus] edit undo}} \
2313         -accelerator $M1T-Z
2314 .mbar.edit add command -label [mc Redo] \
2315         -command {catch {[focus] edit redo}} \
2316         -accelerator $M1T-Y
2317 .mbar.edit add separator
2318 .mbar.edit add command -label [mc Cut] \
2319         -command {catch {tk_textCut [focus]}} \
2320         -accelerator $M1T-X
2321 .mbar.edit add command -label [mc Copy] \
2322         -command {catch {tk_textCopy [focus]}} \
2323         -accelerator $M1T-C
2324 .mbar.edit add command -label [mc Paste] \
2325         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2326         -accelerator $M1T-V
2327 .mbar.edit add command -label [mc Delete] \
2328         -command {catch {[focus] delete sel.first sel.last}} \
2329         -accelerator Del
2330 .mbar.edit add separator
2331 .mbar.edit add command -label [mc "Select All"] \
2332         -command {catch {[focus] tag add sel 0.0 end}} \
2333         -accelerator $M1T-A
2334
2335 # -- Branch Menu
2336 #
2337 if {[is_enabled branch]} {
2338         menu .mbar.branch
2339
2340         .mbar.branch add command -label [mc "Create..."] \
2341                 -command branch_create::dialog \
2342                 -accelerator $M1T-N
2343         lappend disable_on_lock [list .mbar.branch entryconf \
2344                 [.mbar.branch index last] -state]
2345
2346         .mbar.branch add command -label [mc "Checkout..."] \
2347                 -command branch_checkout::dialog \
2348                 -accelerator $M1T-O
2349         lappend disable_on_lock [list .mbar.branch entryconf \
2350                 [.mbar.branch index last] -state]
2351
2352         .mbar.branch add command -label [mc "Rename..."] \
2353                 -command branch_rename::dialog
2354         lappend disable_on_lock [list .mbar.branch entryconf \
2355                 [.mbar.branch index last] -state]
2356
2357         .mbar.branch add command -label [mc "Delete..."] \
2358                 -command branch_delete::dialog
2359         lappend disable_on_lock [list .mbar.branch entryconf \
2360                 [.mbar.branch index last] -state]
2361
2362         .mbar.branch add command -label [mc "Reset..."] \
2363                 -command merge::reset_hard
2364         lappend disable_on_lock [list .mbar.branch entryconf \
2365                 [.mbar.branch index last] -state]
2366 }
2367
2368 # -- Commit Menu
2369 #
2370 proc commit_btn_caption {} {
2371         if {[is_enabled nocommit]} {
2372                 return [mc "Done"]
2373         } else {
2374                 return [mc Commit@@verb]
2375         }
2376 }
2377
2378 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2379         menu .mbar.commit
2380
2381         if {![is_enabled nocommit]} {
2382                 .mbar.commit add radiobutton \
2383                         -label [mc "New Commit"] \
2384                         -command do_select_commit_type \
2385                         -variable selected_commit_type \
2386                         -value new
2387                 lappend disable_on_lock \
2388                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2389
2390                 .mbar.commit add radiobutton \
2391                         -label [mc "Amend Last Commit"] \
2392                         -command do_select_commit_type \
2393                         -variable selected_commit_type \
2394                         -value amend
2395                 lappend disable_on_lock \
2396                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2397
2398                 .mbar.commit add separator
2399         }
2400
2401         .mbar.commit add command -label [mc Rescan] \
2402                 -command ui_do_rescan \
2403                 -accelerator F5
2404         lappend disable_on_lock \
2405                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2406
2407         .mbar.commit add command -label [mc "Stage To Commit"] \
2408                 -command do_add_selection \
2409                 -accelerator $M1T-T
2410         lappend disable_on_lock \
2411                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2412
2413         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2414                 -command do_add_all \
2415                 -accelerator $M1T-I
2416         lappend disable_on_lock \
2417                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2418
2419         .mbar.commit add command -label [mc "Unstage From Commit"] \
2420                 -command do_unstage_selection
2421         lappend disable_on_lock \
2422                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2423
2424         .mbar.commit add command -label [mc "Revert Changes"] \
2425                 -command do_revert_selection
2426         lappend disable_on_lock \
2427                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2428
2429         .mbar.commit add separator
2430
2431         .mbar.commit add command -label [mc "Show Less Context"] \
2432                 -command show_less_context \
2433                 -accelerator $M1T-\-
2434
2435         .mbar.commit add command -label [mc "Show More Context"] \
2436                 -command show_more_context \
2437                 -accelerator $M1T-=
2438
2439         .mbar.commit add separator
2440
2441         if {![is_enabled nocommitmsg]} {
2442                 .mbar.commit add command -label [mc "Sign Off"] \
2443                         -command do_signoff \
2444                         -accelerator $M1T-S
2445         }
2446
2447         .mbar.commit add command -label [commit_btn_caption] \
2448                 -command do_commit \
2449                 -accelerator $M1T-Return
2450         lappend disable_on_lock \
2451                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2452 }
2453
2454 # -- Merge Menu
2455 #
2456 if {[is_enabled branch]} {
2457         menu .mbar.merge
2458         .mbar.merge add command -label [mc "Local Merge..."] \
2459                 -command merge::dialog \
2460                 -accelerator $M1T-M
2461         lappend disable_on_lock \
2462                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2463         .mbar.merge add command -label [mc "Abort Merge..."] \
2464                 -command merge::reset_hard
2465         lappend disable_on_lock \
2466                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2467 }
2468
2469 # -- Transport Menu
2470 #
2471 if {[is_enabled transport]} {
2472         menu .mbar.remote
2473
2474         .mbar.remote add command \
2475                 -label [mc "Add..."] \
2476                 -command remote_add::dialog \
2477                 -accelerator $M1T-A
2478         .mbar.remote add command \
2479                 -label [mc "Push..."] \
2480                 -command do_push_anywhere \
2481                 -accelerator $M1T-P
2482         .mbar.remote add command \
2483                 -label [mc "Delete Branch..."] \
2484                 -command remote_branch_delete::dialog
2485 }
2486
2487 if {[is_MacOSX]} {
2488         # -- Apple Menu (Mac OS X only)
2489         #
2490         .mbar add cascade -label Apple -menu .mbar.apple
2491         menu .mbar.apple
2492
2493         .mbar.apple add command -label [mc "About %s" [appname]] \
2494                 -command do_about
2495         .mbar.apple add separator
2496         .mbar.apple add command \
2497                 -label [mc "Preferences..."] \
2498                 -command do_options \
2499                 -accelerator $M1T-,
2500         bind . <$M1B-,> do_options
2501 } else {
2502         # -- Edit Menu
2503         #
2504         .mbar.edit add separator
2505         .mbar.edit add command -label [mc "Options..."] \
2506                 -command do_options
2507 }
2508
2509 # -- Help Menu
2510 #
2511 .mbar add cascade -label [mc Help] -menu .mbar.help
2512 menu .mbar.help
2513
2514 if {![is_MacOSX]} {
2515         .mbar.help add command -label [mc "About %s" [appname]] \
2516                 -command do_about
2517 }
2518
2519
2520 set doc_path [file dirname [gitexec]]
2521 set doc_path [file join $doc_path Documentation index.html]
2522
2523 if {[is_Cygwin]} {
2524         set doc_path [exec cygpath --mixed $doc_path]
2525 }
2526
2527 if {[file isfile $doc_path]} {
2528         set doc_url "file:$doc_path"
2529 } else {
2530         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2531 }
2532
2533 proc start_browser {url} {
2534         git "web--browse" $url
2535 }
2536
2537 .mbar.help add command -label [mc "Online Documentation"] \
2538         -command [list start_browser $doc_url]
2539
2540 .mbar.help add command -label [mc "Show SSH Key"] \
2541         -command do_ssh_key
2542
2543 unset doc_path doc_url
2544
2545 # -- Standard bindings
2546 #
2547 wm protocol . WM_DELETE_WINDOW do_quit
2548 bind all <$M1B-Key-q> do_quit
2549 bind all <$M1B-Key-Q> do_quit
2550 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2551 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2552
2553 set subcommand_args {}
2554 proc usage {} {
2555         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2556         exit 1
2557 }
2558
2559 # -- Not a normal commit type invocation?  Do that instead!
2560 #
2561 switch -- $subcommand {
2562 browser -
2563 blame {
2564         if {$subcommand eq "blame"} {
2565                 set subcommand_args {[--line=<num>] rev? path}
2566         } else {
2567                 set subcommand_args {rev? path}
2568         }
2569         if {$argv eq {}} usage
2570         set head {}
2571         set path {}
2572         set jump_spec {}
2573         set is_path 0
2574         foreach a $argv {
2575                 if {$is_path || [file exists $_prefix$a]} {
2576                         if {$path ne {}} usage
2577                         set path $_prefix$a
2578                         break
2579                 } elseif {$a eq {--}} {
2580                         if {$path ne {}} {
2581                                 if {$head ne {}} usage
2582                                 set head $path
2583                                 set path {}
2584                         }
2585                         set is_path 1
2586                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2587                         if {$jump_spec ne {} || $head ne {}} usage
2588                         set jump_spec [list $lnum]
2589                 } elseif {$head eq {}} {
2590                         if {$head ne {}} usage
2591                         set head $a
2592                         set is_path 1
2593                 } else {
2594                         usage
2595                 }
2596         }
2597         unset is_path
2598
2599         if {$head ne {} && $path eq {}} {
2600                 set path $_prefix$head
2601                 set head {}
2602         }
2603
2604         if {$head eq {}} {
2605                 load_current_branch
2606         } else {
2607                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2608                         if {[catch {
2609                                         set head [git rev-parse --verify $head]
2610                                 } err]} {
2611                                 puts stderr $err
2612                                 exit 1
2613                         }
2614                 }
2615                 set current_branch $head
2616         }
2617
2618         switch -- $subcommand {
2619         browser {
2620                 if {$jump_spec ne {}} usage
2621                 if {$head eq {}} {
2622                         if {$path ne {} && [file isdirectory $path]} {
2623                                 set head $current_branch
2624                         } else {
2625                                 set head $path
2626                                 set path {}
2627                         }
2628                 }
2629                 browser::new $head $path
2630         }
2631         blame   {
2632                 if {$head eq {} && ![file exists $path]} {
2633                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2634                         exit 1
2635                 }
2636                 blame::new $head $path $jump_spec
2637         }
2638         }
2639         return
2640 }
2641 citool -
2642 gui {
2643         if {[llength $argv] != 0} {
2644                 puts -nonewline stderr "usage: $argv0"
2645                 if {$subcommand ne {gui}
2646                         && [file tail $argv0] ne "git-$subcommand"} {
2647                         puts -nonewline stderr " $subcommand"
2648                 }
2649                 puts stderr {}
2650                 exit 1
2651         }
2652         # fall through to setup UI for commits
2653 }
2654 default {
2655         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2656         exit 1
2657 }
2658 }
2659
2660 # -- Branch Control
2661 #
2662 frame .branch \
2663         -borderwidth 1 \
2664         -relief sunken
2665 label .branch.l1 \
2666         -text [mc "Current Branch:"] \
2667         -anchor w \
2668         -justify left
2669 label .branch.cb \
2670         -textvariable current_branch \
2671         -anchor w \
2672         -justify left
2673 pack .branch.l1 -side left
2674 pack .branch.cb -side left -fill x
2675 pack .branch -side top -fill x
2676
2677 # -- Main Window Layout
2678 #
2679 panedwindow .vpane -orient horizontal
2680 panedwindow .vpane.files -orient vertical
2681 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2682 pack .vpane -anchor n -side top -fill both -expand 1
2683
2684 # -- Index File List
2685 #
2686 frame .vpane.files.index -height 100 -width 200
2687 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2688         -background lightgreen -foreground black
2689 text $ui_index -background white -foreground black \
2690         -borderwidth 0 \
2691         -width 20 -height 10 \
2692         -wrap none \
2693         -cursor $cursor_ptr \
2694         -xscrollcommand {.vpane.files.index.sx set} \
2695         -yscrollcommand {.vpane.files.index.sy set} \
2696         -state disabled
2697 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2698 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2699 pack .vpane.files.index.title -side top -fill x
2700 pack .vpane.files.index.sx -side bottom -fill x
2701 pack .vpane.files.index.sy -side right -fill y
2702 pack $ui_index -side left -fill both -expand 1
2703
2704 # -- Working Directory File List
2705 #
2706 frame .vpane.files.workdir -height 100 -width 200
2707 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2708         -background lightsalmon -foreground black
2709 text $ui_workdir -background white -foreground black \
2710         -borderwidth 0 \
2711         -width 20 -height 10 \
2712         -wrap none \
2713         -cursor $cursor_ptr \
2714         -xscrollcommand {.vpane.files.workdir.sx set} \
2715         -yscrollcommand {.vpane.files.workdir.sy set} \
2716         -state disabled
2717 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2718 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2719 pack .vpane.files.workdir.title -side top -fill x
2720 pack .vpane.files.workdir.sx -side bottom -fill x
2721 pack .vpane.files.workdir.sy -side right -fill y
2722 pack $ui_workdir -side left -fill both -expand 1
2723
2724 .vpane.files add .vpane.files.workdir -sticky nsew
2725 .vpane.files add .vpane.files.index -sticky nsew
2726
2727 foreach i [list $ui_index $ui_workdir] {
2728         rmsel_tag $i
2729         $i tag conf in_diff -background [$i tag cget in_sel -background]
2730 }
2731 unset i
2732
2733 # -- Diff and Commit Area
2734 #
2735 frame .vpane.lower -height 300 -width 400
2736 frame .vpane.lower.commarea
2737 frame .vpane.lower.diff -relief sunken -borderwidth 1
2738 pack .vpane.lower.diff -fill both -expand 1
2739 pack .vpane.lower.commarea -side bottom -fill x
2740 .vpane add .vpane.lower -sticky nsew
2741
2742 # -- Commit Area Buttons
2743 #
2744 frame .vpane.lower.commarea.buttons
2745 label .vpane.lower.commarea.buttons.l -text {} \
2746         -anchor w \
2747         -justify left
2748 pack .vpane.lower.commarea.buttons.l -side top -fill x
2749 pack .vpane.lower.commarea.buttons -side left -fill y
2750
2751 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2752         -command ui_do_rescan
2753 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2754 lappend disable_on_lock \
2755         {.vpane.lower.commarea.buttons.rescan conf -state}
2756
2757 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2758         -command do_add_all
2759 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2760 lappend disable_on_lock \
2761         {.vpane.lower.commarea.buttons.incall conf -state}
2762
2763 if {![is_enabled nocommitmsg]} {
2764         button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2765                 -command do_signoff
2766         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2767 }
2768
2769 button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
2770         -command do_commit
2771 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2772 lappend disable_on_lock \
2773         {.vpane.lower.commarea.buttons.commit conf -state}
2774
2775 if {![is_enabled nocommit]} {
2776         button .vpane.lower.commarea.buttons.push -text [mc Push] \
2777                 -command do_push_anywhere
2778         pack .vpane.lower.commarea.buttons.push -side top -fill x
2779 }
2780
2781 # -- Commit Message Buffer
2782 #
2783 frame .vpane.lower.commarea.buffer
2784 frame .vpane.lower.commarea.buffer.header
2785 set ui_comm .vpane.lower.commarea.buffer.t
2786 set ui_coml .vpane.lower.commarea.buffer.header.l
2787
2788 if {![is_enabled nocommit]} {
2789         radiobutton .vpane.lower.commarea.buffer.header.new \
2790                 -text [mc "New Commit"] \
2791                 -command do_select_commit_type \
2792                 -variable selected_commit_type \
2793                 -value new
2794         lappend disable_on_lock \
2795                 [list .vpane.lower.commarea.buffer.header.new conf -state]
2796         radiobutton .vpane.lower.commarea.buffer.header.amend \
2797                 -text [mc "Amend Last Commit"] \
2798                 -command do_select_commit_type \
2799                 -variable selected_commit_type \
2800                 -value amend
2801         lappend disable_on_lock \
2802                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
2803 }
2804
2805 label $ui_coml \
2806         -anchor w \
2807         -justify left
2808 proc trace_commit_type {varname args} {
2809         global ui_coml commit_type
2810         switch -glob -- $commit_type {
2811         initial       {set txt [mc "Initial Commit Message:"]}
2812         amend         {set txt [mc "Amended Commit Message:"]}
2813         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2814         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2815         merge         {set txt [mc "Merge Commit Message:"]}
2816         *             {set txt [mc "Commit Message:"]}
2817         }
2818         $ui_coml conf -text $txt
2819 }
2820 trace add variable commit_type write trace_commit_type
2821 pack $ui_coml -side left -fill x
2822
2823 if {![is_enabled nocommit]} {
2824         pack .vpane.lower.commarea.buffer.header.amend -side right
2825         pack .vpane.lower.commarea.buffer.header.new -side right
2826 }
2827
2828 text $ui_comm -background white -foreground black \
2829         -borderwidth 1 \
2830         -undo true \
2831         -maxundo 20 \
2832         -autoseparators true \
2833         -relief sunken \
2834         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2835         -font font_diff \
2836         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2837 scrollbar .vpane.lower.commarea.buffer.sby \
2838         -command [list $ui_comm yview]
2839 pack .vpane.lower.commarea.buffer.header -side top -fill x
2840 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2841 pack $ui_comm -side left -fill y
2842 pack .vpane.lower.commarea.buffer -side left -fill y
2843
2844 # -- Commit Message Buffer Context Menu
2845 #
2846 set ctxm .vpane.lower.commarea.buffer.ctxm
2847 menu $ctxm -tearoff 0
2848 $ctxm add command \
2849         -label [mc Cut] \
2850         -command {tk_textCut $ui_comm}
2851 $ctxm add command \
2852         -label [mc Copy] \
2853         -command {tk_textCopy $ui_comm}
2854 $ctxm add command \
2855         -label [mc Paste] \
2856         -command {tk_textPaste $ui_comm}
2857 $ctxm add command \
2858         -label [mc Delete] \
2859         -command {$ui_comm delete sel.first sel.last}
2860 $ctxm add separator
2861 $ctxm add command \
2862         -label [mc "Select All"] \
2863         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2864 $ctxm add command \
2865         -label [mc "Copy All"] \
2866         -command {
2867                 $ui_comm tag add sel 0.0 end
2868                 tk_textCopy $ui_comm
2869                 $ui_comm tag remove sel 0.0 end
2870         }
2871 $ctxm add separator
2872 $ctxm add command \
2873         -label [mc "Sign Off"] \
2874         -command do_signoff
2875 set ui_comm_ctxm $ctxm
2876
2877 # -- Diff Header
2878 #
2879 proc trace_current_diff_path {varname args} {
2880         global current_diff_path diff_actions file_states
2881         if {$current_diff_path eq {}} {
2882                 set s {}
2883                 set f {}
2884                 set p {}
2885                 set o disabled
2886         } else {
2887                 set p $current_diff_path
2888                 set s [mapdesc [lindex $file_states($p) 0] $p]
2889                 set f [mc "File:"]
2890                 set p [escape_path $p]
2891                 set o normal
2892         }
2893
2894         .vpane.lower.diff.header.status configure -text $s
2895         .vpane.lower.diff.header.file configure -text $f
2896         .vpane.lower.diff.header.path configure -text $p
2897         foreach w $diff_actions {
2898                 uplevel #0 $w $o
2899         }
2900 }
2901 trace add variable current_diff_path write trace_current_diff_path
2902
2903 frame .vpane.lower.diff.header -background gold
2904 label .vpane.lower.diff.header.status \
2905         -background gold \
2906         -foreground black \
2907         -width $max_status_desc \
2908         -anchor w \
2909         -justify left
2910 label .vpane.lower.diff.header.file \
2911         -background gold \
2912         -foreground black \
2913         -anchor w \
2914         -justify left
2915 label .vpane.lower.diff.header.path \
2916         -background gold \
2917         -foreground black \
2918         -anchor w \
2919         -justify left
2920 pack .vpane.lower.diff.header.status -side left
2921 pack .vpane.lower.diff.header.file -side left
2922 pack .vpane.lower.diff.header.path -fill x
2923 set ctxm .vpane.lower.diff.header.ctxm
2924 menu $ctxm -tearoff 0
2925 $ctxm add command \
2926         -label [mc Copy] \
2927         -command {
2928                 clipboard clear
2929                 clipboard append \
2930                         -format STRING \
2931                         -type STRING \
2932                         -- $current_diff_path
2933         }
2934 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2935 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2936
2937 # -- Diff Body
2938 #
2939 frame .vpane.lower.diff.body
2940 set ui_diff .vpane.lower.diff.body.t
2941 text $ui_diff -background white -foreground black \
2942         -borderwidth 0 \
2943         -width 80 -height 15 -wrap none \
2944         -font font_diff \
2945         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2946         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2947         -state disabled
2948 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2949         -command [list $ui_diff xview]
2950 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2951         -command [list $ui_diff yview]
2952 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2953 pack .vpane.lower.diff.body.sby -side right -fill y
2954 pack $ui_diff -side left -fill both -expand 1
2955 pack .vpane.lower.diff.header -side top -fill x
2956 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2957
2958 $ui_diff tag conf d_cr -elide true
2959 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2960 $ui_diff tag conf d_+ -foreground {#00a000}
2961 $ui_diff tag conf d_- -foreground red
2962
2963 $ui_diff tag conf d_++ -foreground {#00a000}
2964 $ui_diff tag conf d_-- -foreground red
2965 $ui_diff tag conf d_+s \
2966         -foreground {#00a000} \
2967         -background {#e2effa}
2968 $ui_diff tag conf d_-s \
2969         -foreground red \
2970         -background {#e2effa}
2971 $ui_diff tag conf d_s+ \
2972         -foreground {#00a000} \
2973         -background ivory1
2974 $ui_diff tag conf d_s- \
2975         -foreground red \
2976         -background ivory1
2977
2978 $ui_diff tag conf d<<<<<<< \
2979         -foreground orange \
2980         -font font_diffbold
2981 $ui_diff tag conf d======= \
2982         -foreground orange \
2983         -font font_diffbold
2984 $ui_diff tag conf d>>>>>>> \
2985         -foreground orange \
2986         -font font_diffbold
2987
2988 $ui_diff tag raise sel
2989
2990 # -- Diff Body Context Menu
2991 #
2992
2993 proc create_common_diff_popup {ctxm} {
2994         $ctxm add command \
2995                 -label [mc "Show Less Context"] \
2996                 -command show_less_context
2997         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2998         $ctxm add command \
2999                 -label [mc "Show More Context"] \
3000                 -command show_more_context
3001         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3002         $ctxm add separator
3003         $ctxm add command \
3004                 -label [mc Refresh] \
3005                 -command reshow_diff
3006         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3007         $ctxm add command \
3008                 -label [mc Copy] \
3009                 -command {tk_textCopy $ui_diff}
3010         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3011         $ctxm add command \
3012                 -label [mc "Select All"] \
3013                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3014         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3015         $ctxm add command \
3016                 -label [mc "Copy All"] \
3017                 -command {
3018                         $ui_diff tag add sel 0.0 end
3019                         tk_textCopy $ui_diff
3020                         $ui_diff tag remove sel 0.0 end
3021                 }
3022         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3023         $ctxm add separator
3024         $ctxm add command \
3025                 -label [mc "Decrease Font Size"] \
3026                 -command {incr_font_size font_diff -1}
3027         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3028         $ctxm add command \
3029                 -label [mc "Increase Font Size"] \
3030                 -command {incr_font_size font_diff 1}
3031         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3032         $ctxm add separator
3033         set emenu $ctxm.enc
3034         menu $emenu
3035         build_encoding_menu $emenu [list force_diff_encoding]
3036         $ctxm add cascade \
3037                 -label [mc "Encoding"] \
3038                 -menu $emenu
3039         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3040         $ctxm add separator
3041         $ctxm add command -label [mc "Options..."] \
3042                 -command do_options
3043 }
3044
3045 set ctxm .vpane.lower.diff.body.ctxm
3046 menu $ctxm -tearoff 0
3047 $ctxm add command \
3048         -label [mc "Apply/Reverse Hunk"] \
3049         -command {apply_hunk $cursorX $cursorY}
3050 set ui_diff_applyhunk [$ctxm index last]
3051 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3052 $ctxm add command \
3053         -label [mc "Apply/Reverse Line"] \
3054         -command {apply_line $cursorX $cursorY; do_rescan}
3055 set ui_diff_applyline [$ctxm index last]
3056 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3057 $ctxm add separator
3058 create_common_diff_popup $ctxm
3059
3060 set ctxmmg .vpane.lower.diff.body.ctxmmg
3061 menu $ctxmmg -tearoff 0
3062 $ctxmmg add command \
3063         -label [mc "Run Merge Tool"] \
3064         -command {merge_resolve_tool}
3065 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3066 $ctxmmg add separator
3067 $ctxmmg add command \
3068         -label [mc "Use Remote Version"] \
3069         -command {merge_resolve_one 3}
3070 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3071 $ctxmmg add command \
3072         -label [mc "Use Local Version"] \
3073         -command {merge_resolve_one 2}
3074 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3075 $ctxmmg add command \
3076         -label [mc "Revert To Base"] \
3077         -command {merge_resolve_one 1}
3078 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3079 $ctxmmg add separator
3080 create_common_diff_popup $ctxmmg
3081
3082 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
3083         global current_diff_path file_states
3084         set ::cursorX $x
3085         set ::cursorY $y
3086         if {[info exists file_states($current_diff_path)]} {
3087                 set state [lindex $file_states($current_diff_path) 0]
3088         } else {
3089                 set state {__}
3090         }
3091         if {[string first {U} $state] >= 0} {
3092                 tk_popup $ctxmmg $X $Y
3093         } else {
3094                 if {$::ui_index eq $::current_diff_side} {
3095                         set l [mc "Unstage Hunk From Commit"]
3096                         set t [mc "Unstage Line From Commit"]
3097                 } else {
3098                         set l [mc "Stage Hunk For Commit"]
3099                         set t [mc "Stage Line For Commit"]
3100                 }
3101                 if {$::is_3way_diff
3102                         || $current_diff_path eq {}
3103                         || {__} eq $state
3104                         || {_O} eq $state
3105                         || {_T} eq $state
3106                         || {T_} eq $state} {
3107                         set s disabled
3108                 } else {
3109                         set s normal
3110                 }
3111                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3112                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3113                 tk_popup $ctxm $X $Y
3114         }
3115 }
3116 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
3117
3118 # -- Status Bar
3119 #
3120 set main_status [::status_bar::new .status]
3121 pack .status -anchor w -side bottom -fill x
3122 $main_status show [mc "Initializing..."]
3123
3124 # -- Load geometry
3125 #
3126 catch {
3127 set gm $repo_config(gui.geometry)
3128 wm geometry . [lindex $gm 0]
3129 .vpane sash place 0 \
3130         [lindex $gm 1] \
3131         [lindex [.vpane sash coord 0] 1]
3132 .vpane.files sash place 0 \
3133         [lindex [.vpane.files sash coord 0] 0] \
3134         [lindex $gm 2]
3135 unset gm
3136 }
3137
3138 # -- Key Bindings
3139 #
3140 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3141 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3142 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3143 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3144 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3145 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3146 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3147 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3148 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3149 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3150 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3151 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3152 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3153 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3154 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3155 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3156 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3157 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3158
3159 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3160 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3161 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3162 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3163 bind $ui_diff <$M1B-Key-v> {break}
3164 bind $ui_diff <$M1B-Key-V> {break}
3165 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3166 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3167 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3168 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3169 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3170 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3171 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3172 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3173 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3174 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3175 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3176 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3177 bind $ui_diff <Button-1>   {focus %W}
3178
3179 if {[is_enabled branch]} {
3180         bind . <$M1B-Key-n> branch_create::dialog
3181         bind . <$M1B-Key-N> branch_create::dialog
3182         bind . <$M1B-Key-o> branch_checkout::dialog
3183         bind . <$M1B-Key-O> branch_checkout::dialog
3184         bind . <$M1B-Key-m> merge::dialog
3185         bind . <$M1B-Key-M> merge::dialog
3186 }
3187 if {[is_enabled transport]} {
3188         bind . <$M1B-Key-p> do_push_anywhere
3189         bind . <$M1B-Key-P> do_push_anywhere
3190 }
3191
3192 bind .   <Key-F5>     ui_do_rescan
3193 bind .   <$M1B-Key-r> ui_do_rescan
3194 bind .   <$M1B-Key-R> ui_do_rescan
3195 bind .   <$M1B-Key-s> do_signoff
3196 bind .   <$M1B-Key-S> do_signoff
3197 bind .   <$M1B-Key-t> do_add_selection
3198 bind .   <$M1B-Key-T> do_add_selection
3199 bind .   <$M1B-Key-i> do_add_all
3200 bind .   <$M1B-Key-I> do_add_all
3201 bind .   <$M1B-Key-minus> {show_less_context;break}
3202 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3203 bind .   <$M1B-Key-equal> {show_more_context;break}
3204 bind .   <$M1B-Key-plus> {show_more_context;break}
3205 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3206 bind .   <$M1B-Key-Return> do_commit
3207 foreach i [list $ui_index $ui_workdir] {
3208         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3209         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3210         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3211 }
3212 unset i
3213
3214 set file_lists($ui_index) [list]
3215 set file_lists($ui_workdir) [list]
3216
3217 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3218 focus -force $ui_comm
3219
3220 # -- Warn the user about environmental problems.  Cygwin's Tcl
3221 #    does *not* pass its env array onto any processes it spawns.
3222 #    This means that git processes get none of our environment.
3223 #
3224 if {[is_Cygwin]} {
3225         set ignored_env 0
3226         set suggest_user {}
3227         set msg [mc "Possible environment issues exist.
3228
3229 The following environment variables are probably
3230 going to be ignored by any Git subprocess run
3231 by %s:
3232
3233 " [appname]]
3234         foreach name [array names env] {
3235                 switch -regexp -- $name {
3236                 {^GIT_INDEX_FILE$} -
3237                 {^GIT_OBJECT_DIRECTORY$} -
3238                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3239                 {^GIT_DIFF_OPTS$} -
3240                 {^GIT_EXTERNAL_DIFF$} -
3241                 {^GIT_PAGER$} -
3242                 {^GIT_TRACE$} -
3243                 {^GIT_CONFIG$} -
3244                 {^GIT_CONFIG_LOCAL$} -
3245                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3246                         append msg " - $name\n"
3247                         incr ignored_env
3248                 }
3249                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3250                         append msg " - $name\n"
3251                         incr ignored_env
3252                         set suggest_user $name
3253                 }
3254                 }
3255         }
3256         if {$ignored_env > 0} {
3257                 append msg [mc "
3258 This is due to a known issue with the
3259 Tcl binary distributed by Cygwin."]
3260
3261                 if {$suggest_user ne {}} {
3262                         append msg [mc "
3263
3264 A good replacement for %s
3265 is placing values for the user.name and
3266 user.email settings into your personal
3267 ~/.gitconfig file.
3268 " $suggest_user]
3269                 }
3270                 warn_popup $msg
3271         }
3272         unset ignored_env msg suggest_user name
3273 }
3274
3275 # -- Only initialize complex UI if we are going to stay running.
3276 #
3277 if {[is_enabled transport]} {
3278         load_all_remotes
3279
3280         set n [.mbar.remote index end]
3281         populate_remotes_menu
3282         set n [expr {[.mbar.remote index end] - $n}]
3283         if {$n > 0} {
3284                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3285                 .mbar.remote insert $n separator
3286         }
3287         unset n
3288 }
3289
3290 if {[winfo exists $ui_comm]} {
3291         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3292
3293         # -- If both our backup and message files exist use the
3294         #    newer of the two files to initialize the buffer.
3295         #
3296         if {$GITGUI_BCK_exists} {
3297                 set m [gitdir GITGUI_MSG]
3298                 if {[file isfile $m]} {
3299                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3300                                 catch {file delete [gitdir GITGUI_MSG]}
3301                         } else {
3302                                 $ui_comm delete 0.0 end
3303                                 $ui_comm edit reset
3304                                 $ui_comm edit modified false
3305                                 catch {file delete [gitdir GITGUI_BCK]}
3306                                 set GITGUI_BCK_exists 0
3307                         }
3308                 }
3309                 unset m
3310         }
3311
3312         proc backup_commit_buffer {} {
3313                 global ui_comm GITGUI_BCK_exists
3314
3315                 set m [$ui_comm edit modified]
3316                 if {$m || $GITGUI_BCK_exists} {
3317                         set msg [string trim [$ui_comm get 0.0 end]]
3318                         regsub -all -line {[ \r\t]+$} $msg {} msg
3319
3320                         if {$msg eq {}} {
3321                                 if {$GITGUI_BCK_exists} {
3322                                         catch {file delete [gitdir GITGUI_BCK]}
3323                                         set GITGUI_BCK_exists 0
3324                                 }
3325                         } elseif {$m} {
3326                                 catch {
3327                                         set fd [open [gitdir GITGUI_BCK] w]
3328                                         puts -nonewline $fd $msg
3329                                         close $fd
3330                                         set GITGUI_BCK_exists 1
3331                                 }
3332                         }
3333
3334                         $ui_comm edit modified false
3335                 }
3336
3337                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3338         }
3339
3340         backup_commit_buffer
3341
3342         # -- If the user has aspell available we can drive it
3343         #    in pipe mode to spellcheck the commit message.
3344         #
3345         set spell_cmd [list |]
3346         set spell_dict [get_config gui.spellingdictionary]
3347         lappend spell_cmd aspell
3348         if {$spell_dict ne {}} {
3349                 lappend spell_cmd --master=$spell_dict
3350         }
3351         lappend spell_cmd --mode=none
3352         lappend spell_cmd --encoding=utf-8
3353         lappend spell_cmd pipe
3354         if {$spell_dict eq {none}
3355          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3356                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3357         } else {
3358                 set ui_comm_spell [spellcheck::init \
3359                         $spell_fd \
3360                         $ui_comm \
3361                         $ui_comm_ctxm \
3362                 ]
3363         }
3364         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3365 }
3366
3367 lock_index begin-read
3368 if {![winfo ismapped .]} {
3369         wm deiconify .
3370 }
3371 after 1 {
3372         if {[is_enabled initialamend]} {
3373                 force_amend
3374         } else {
3375                 do_rescan
3376         }
3377
3378         if {[is_enabled nocommitmsg]} {
3379                 $ui_comm configure -state disabled -background gray
3380         }
3381 }
3382 if {[is_enabled multicommit]} {
3383         after 1000 hint_gc
3384 }
3385 if {[is_enabled retcode]} {
3386         bind . <Destroy> {+terminate_me %W}
3387 }
3388 if {$picked && [is_config_true gui.autoexplore]} {
3389         do_explore
3390 }