git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitexec {}
 125 set _reponame {}
 126 set _iscygwin {}
 127 set _search_path {}
 128
 129 set _trace [lsearch -exact $argv --trace]
 130 if {$_trace >= 0} {
 131         set argv [lreplace $argv $_trace $_trace]
 132         set _trace 1
 133 } else {
 134         set _trace 0
 135 }
 136
 137 proc appname {} {
 138         global _appname
 139         return $_appname
 140 }
 141
 142 proc gitdir {args} {
 143         global _gitdir
 144         if {$args eq {}} {
 145                 return $_gitdir
 146         }
 147         return [eval [list file join $_gitdir] $args]
 148 }
 149
 150 proc gitexec {args} {
 151         global _gitexec
 152         if {$_gitexec eq {}} {
 153                 if {[catch {set _gitexec [git --exec-path]} err]} {
 154                         error "Git not installed?\n\n$err"
 155                 }
 156                 if {[is_Cygwin]} {
 157                         set _gitexec [exec cygpath \
 158                                 --windows \
 159                                 --absolute \
 160                                 $_gitexec]
 161                 } else {
 162                         set _gitexec [file normalize $_gitexec]
 163                 }
 164         }
 165         if {$args eq {}} {
 166                 return $_gitexec
 167         }
 168         return [eval [list file join $_gitexec] $args]
 169 }
 170
 171 proc reponame {} {
 172         return $::_reponame
 173 }
 174
 175 proc is_MacOSX {} {
 176         if {[tk windowingsystem] eq {aqua}} {
 177                 return 1
 178         }
 179         return 0
 180 }
 181
 182 proc is_Windows {} {
 183         if {$::tcl_platform(platform) eq {windows}} {
 184                 return 1
 185         }
 186         return 0
 187 }
 188
 189 proc is_Cygwin {} {
 190         global _iscygwin
 191         if {$_iscygwin eq {}} {
 192                 if {$::tcl_platform(platform) eq {windows}} {
 193                         if {[catch {set p [exec cygpath --windir]} err]} {
 194                                 set _iscygwin 0
 195                         } else {
 196                                 set _iscygwin 1
 197                         }
 198                 } else {
 199                         set _iscygwin 0
 200                 }
 201         }
 202         return $_iscygwin
 203 }
 204
 205 proc is_enabled {option} {
 206         global enabled_options
 207         if {[catch {set on $enabled_options($option)}]} {return 0}
 208         return $on
 209 }
 210
 211 proc enable_option {option} {
 212         global enabled_options
 213         set enabled_options($option) 1
 214 }
 215
 216 proc disable_option {option} {
 217         global enabled_options
 218         set enabled_options($option) 0
 219 }
 220
 221 ######################################################################
 222 ##
 223 ## config
 224
 225 proc is_many_config {name} {
 226         switch -glob -- $name {
 227         gui.recentrepo -
 228         remote.*.fetch -
 229         remote.*.push
 230                 {return 1}
 231         *
 232                 {return 0}
 233         }
 234 }
 235
 236 proc is_config_true {name} {
 237         global repo_config
 238         if {[catch {set v $repo_config($name)}]} {
 239                 return 0
 240         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 241                 return 1
 242         } else {
 243                 return 0
 244         }
 245 }
 246
 247 proc get_config {name} {
 248         global repo_config
 249         if {[catch {set v $repo_config($name)}]} {
 250                 return {}
 251         } else {
 252                 return $v
 253         }
 254 }
 255
 256 ######################################################################
 257 ##
 258 ## handy utils
 259
 260 proc _trace_exec {cmd} {
 261         if {!$::_trace} return
 262         set d {}
 263         foreach v $cmd {
 264                 if {$d ne {}} {
 265                         append d { }
 266                 }
 267                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 268                         set v [sq $v]
 269                 }
 270                 append d $v
 271         }
 272         puts stderr $d
 273 }
 274
 275 proc _git_cmd {name} {
 276         global _git_cmd_path
 277
 278         if {[catch {set v $_git_cmd_path($name)}]} {
 279                 switch -- $name {
 280                   version   -
 281                 --version   -
 282                 --exec-path { return [list $::_git $name] }
 283                 }
 284
 285                 set p [gitexec git-$name$::_search_exe]
 286                 if {[file exists $p]} {
 287                         set v [list $p]
 288                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 289                         # Try to determine what sort of magic will make
 290                         # git-$name go and do its thing, because native
 291                         # Tcl on Windows doesn't know it.
 292                         #
 293                         set p [gitexec git-$name]
 294                         set f [open $p r]
 295                         set s [gets $f]
 296                         close $f
 297
 298                         switch -glob -- [lindex $s 0] {
 299                         #!*sh     { set i sh     }
 300                         #!*perl   { set i perl   }
 301                         #!*python { set i python }
 302                         default   { error "git-$name is not supported: $s" }
 303                         }
 304
 305                         upvar #0 _$i interp
 306                         if {![info exists interp]} {
 307                                 set interp [_which $i]
 308                         }
 309                         if {$interp eq {}} {
 310                                 error "git-$name requires $i (not in PATH)"
 311                         }
 312                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 313                 } else {
 314                         # Assume it is builtin to git somehow and we
 315                         # aren't actually able to see a file for it.
 316                         #
 317                         set v [list $::_git $name]
 318                 }
 319                 set _git_cmd_path($name) $v
 320         }
 321         return $v
 322 }
 323
 324 proc _which {what args} {
 325         global env _search_exe _search_path
 326
 327         if {$_search_path eq {}} {
 328                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 329                         set _search_path [split [exec cygpath \
 330                                 --windows \
 331                                 --path \
 332                                 --absolute \
 333                                 $env(PATH)] {;}]
 334                         set _search_exe .exe
 335                 } elseif {[is_Windows]} {
 336                         set gitguidir [file dirname [info script]]
 337                         regsub -all ";" $gitguidir "\\;" gitguidir
 338                         set env(PATH) "$gitguidir;$env(PATH)"
 339                         set _search_path [split $env(PATH) {;}]
 340                         set _search_exe .exe
 341                 } else {
 342                         set _search_path [split $env(PATH) :]
 343                         set _search_exe {}
 344                 }
 345         }
 346
 347         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 348                 set suffix {}
 349         } else {
 350                 set suffix $_search_exe
 351         }
 352
 353         foreach p $_search_path {
 354                 set p [file join $p $what$suffix]
 355                 if {[file exists $p]} {
 356                         return [file normalize $p]
 357                 }
 358         }
 359         return {}
 360 }
 361
 362 proc _lappend_nice {cmd_var} {
 363         global _nice
 364         upvar $cmd_var cmd
 365
 366         if {![info exists _nice]} {
 367                 set _nice [_which nice]
 368         }
 369         if {$_nice ne {}} {
 370                 lappend cmd $_nice
 371         }
 372 }
 373
 374 proc git {args} {
 375         set opt [list]
 376
 377         while {1} {
 378                 switch -- [lindex $args 0] {
 379                 --nice {
 380                         _lappend_nice opt
 381                 }
 382
 383                 default {
 384                         break
 385                 }
 386
 387                 }
 388
 389                 set args [lrange $args 1 end]
 390         }
 391
 392         set cmdp [_git_cmd [lindex $args 0]]
 393         set args [lrange $args 1 end]
 394
 395         _trace_exec [concat $opt $cmdp $args]
 396         set result [eval exec $opt $cmdp $args]
 397         if {$::_trace} {
 398                 puts stderr "< $result"
 399         }
 400         return $result
 401 }
 402
 403 proc _open_stdout_stderr {cmd} {
 404         _trace_exec $cmd
 405         if {[catch {
 406                         set fd [open [concat [list | ] $cmd] r]
 407                 } err]} {
 408                 if {   [lindex $cmd end] eq {2>@1}
 409                     && $err eq {can not find channel named "1"}
 410                         } {
 411                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 412                         # redirect operator.  Fallback to |& cat for those.
 413                         # The command was not actually started, so its safe
 414                         # to try to start it a second time.
 415                         #
 416                         set fd [open [concat \
 417                                 [list | ] \
 418                                 [lrange $cmd 0 end-1] \
 419                                 [list |& cat] \
 420                                 ] r]
 421                 } else {
 422                         error $err
 423                 }
 424         }
 425         fconfigure $fd -eofchar {}
 426         return $fd
 427 }
 428
 429 proc git_read {args} {
 430         set opt [list]
 431
 432         while {1} {
 433                 switch -- [lindex $args 0] {
 434                 --nice {
 435                         _lappend_nice opt
 436                 }
 437
 438                 --stderr {
 439                         lappend args 2>@1
 440                 }
 441
 442                 default {
 443                         break
 444                 }
 445
 446                 }
 447
 448                 set args [lrange $args 1 end]
 449         }
 450
 451         set cmdp [_git_cmd [lindex $args 0]]
 452         set args [lrange $args 1 end]
 453
 454         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 455 }
 456
 457 proc git_write {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         return [open [concat [list | ] $opt $cmdp $args] w]
 480 }
 481
 482 proc githook_read {hook_name args} {
 483         set pchook [gitdir hooks $hook_name]
 484         lappend args 2>@1
 485
 486         # On Windows [file executable] might lie so we need to ask
 487         # the shell if the hook is executable.  Yes that's annoying.
 488         #
 489         if {[is_Windows]} {
 490                 upvar #0 _sh interp
 491                 if {![info exists interp]} {
 492                         set interp [_which sh]
 493                 }
 494                 if {$interp eq {}} {
 495                         error "hook execution requires sh (not in PATH)"
 496                 }
 497
 498                 set scr {if test -x "$1";then exec "$@";fi}
 499                 set sh_c [list $interp -c $scr $interp $pchook]
 500                 return [_open_stdout_stderr [concat $sh_c $args]]
 501         }
 502
 503         if {[file executable $pchook]} {
 504                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 505         }
 506
 507         return {}
 508 }
 509
 510 proc kill_file_process {fd} {
 511         set process [pid $fd]
 512
 513         catch {
 514                 if {[is_Windows]} {
 515                         # Use a Cygwin-specific flag to allow killing
 516                         # native Windows processes
 517                         exec kill -f $process
 518                 } else {
 519                         exec kill $process
 520                 }
 521         }
 522 }
 523
 524 proc sq {value} {
 525         regsub -all ' $value "'\\''" value
 526         return "'$value'"
 527 }
 528
 529 proc load_current_branch {} {
 530         global current_branch is_detached
 531
 532         set fd [open [gitdir HEAD] r]
 533         if {[gets $fd ref] < 1} {
 534                 set ref {}
 535         }
 536         close $fd
 537
 538         set pfx {ref: refs/heads/}
 539         set len [string length $pfx]
 540         if {[string equal -length $len $pfx $ref]} {
 541                 # We're on a branch.  It might not exist.  But
 542                 # HEAD looks good enough to be a branch.
 543                 #
 544                 set current_branch [string range $ref $len end]
 545                 set is_detached 0
 546         } else {
 547                 # Assume this is a detached head.
 548                 #
 549                 set current_branch HEAD
 550                 set is_detached 1
 551         }
 552 }
 553
 554 auto_load tk_optionMenu
 555 rename tk_optionMenu real__tkOptionMenu
 556 proc tk_optionMenu {w varName args} {
 557         set m [eval real__tkOptionMenu $w $varName $args]
 558         $m configure -font font_ui
 559         $w configure -font font_ui
 560         return $m
 561 }
 562
 563 proc rmsel_tag {text} {
 564         $text tag conf sel \
 565                 -background [$text cget -background] \
 566                 -foreground [$text cget -foreground] \
 567                 -borderwidth 0
 568         $text tag conf in_sel -background lightgray
 569         bind $text <Motion> break
 570         return $text
 571 }
 572
 573 set root_exists 0
 574 bind . <Visibility> {
 575         bind . <Visibility> {}
 576         set root_exists 1
 577 }
 578
 579 if {[is_Windows]} {
 580         wm iconbitmap . -default $oguilib/git-gui.ico
 581 }
 582
 583 ######################################################################
 584 ##
 585 ## config defaults
 586
 587 set cursor_ptr arrow
 588 font create font_diff -family Courier -size 10
 589 font create font_ui
 590 catch {
 591         label .dummy
 592         eval font configure font_ui [font actual [.dummy cget -font]]
 593         destroy .dummy
 594 }
 595
 596 font create font_uiitalic
 597 font create font_uibold
 598 font create font_diffbold
 599 font create font_diffitalic
 600
 601 foreach class {Button Checkbutton Entry Label
 602                 Labelframe Listbox Menu Message
 603                 Radiobutton Spinbox Text} {
 604         option add *$class.font font_ui
 605 }
 606 unset class
 607
 608 if {[is_Windows] || [is_MacOSX]} {
 609         option add *Menu.tearOff 0
 610 }
 611
 612 if {[is_MacOSX]} {
 613         set M1B M1
 614         set M1T Cmd
 615 } else {
 616         set M1B Control
 617         set M1T Ctrl
 618 }
 619
 620 proc bind_button3 {w cmd} {
 621         bind $w <Any-Button-3> $cmd
 622         if {[is_MacOSX]} {
 623                 # Mac OS X sends Button-2 on right click through three-button mouse,
 624                 # or through trackpad right-clicking (two-finger touch + click).
 625                 bind $w <Any-Button-2> $cmd
 626                 bind $w <Control-Button-1> $cmd
 627         }
 628 }
 629
 630 proc apply_config {} {
 631         global repo_config font_descs
 632
 633         foreach option $font_descs {
 634                 set name [lindex $option 0]
 635                 set font [lindex $option 1]
 636                 if {[catch {
 637                         set need_weight 1
 638                         foreach {cn cv} $repo_config(gui.$name) {
 639                                 if {$cn eq {-weight}} {
 640                                         set need_weight 0
 641                                 }
 642                                 font configure $font $cn $cv
 643                         }
 644                         if {$need_weight} {
 645                                 font configure $font -weight normal
 646                         }
 647                         } err]} {
 648                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 649                 }
 650                 foreach {cn cv} [font configure $font] {
 651                         font configure ${font}bold $cn $cv
 652                         font configure ${font}italic $cn $cv
 653                 }
 654                 font configure ${font}bold -weight bold
 655                 font configure ${font}italic -slant italic
 656         }
 657 }
 658
 659 set default_config(branch.autosetupmerge) true
 660 set default_config(merge.tool) {}
 661 set default_config(merge.keepbackup) true
 662 set default_config(merge.diffstat) true
 663 set default_config(merge.summary) false
 664 set default_config(merge.verbosity) 2
 665 set default_config(user.name) {}
 666 set default_config(user.email) {}
 667
 668 set default_config(gui.matchtrackingbranch) false
 669 set default_config(gui.pruneduringfetch) false
 670 set default_config(gui.trustmtime) false
 671 set default_config(gui.fastcopyblame) false
 672 set default_config(gui.copyblamethreshold) 40
 673 set default_config(gui.blamehistoryctx) 7
 674 set default_config(gui.diffcontext) 5
 675 set default_config(gui.commitmsgwidth) 75
 676 set default_config(gui.newbranchtemplate) {}
 677 set default_config(gui.spellingdictionary) {}
 678 set default_config(gui.fontui) [font configure font_ui]
 679 set default_config(gui.fontdiff) [font configure font_diff]
 680 set font_descs {
 681         {fontui   font_ui   {mc "Main Font"}}
 682         {fontdiff font_diff {mc "Diff/Console Font"}}
 683 }
 684
 685 ######################################################################
 686 ##
 687 ## find git
 688
 689 set _git  [_which git]
 690 if {$_git eq {}} {
 691         catch {wm withdraw .}
 692         tk_messageBox \
 693                 -icon error \
 694                 -type ok \
 695                 -title [mc "git-gui: fatal error"] \
 696                 -message [mc "Cannot find git in PATH."]
 697         exit 1
 698 }
 699
 700 ######################################################################
 701 ##
 702 ## version check
 703
 704 if {[catch {set _git_version [git --version]} err]} {
 705         catch {wm withdraw .}
 706         tk_messageBox \
 707                 -icon error \
 708                 -type ok \
 709                 -title [mc "git-gui: fatal error"] \
 710                 -message "Cannot determine Git version:
 711
 712 $err
 713
 714 [appname] requires Git 1.5.0 or later."
 715         exit 1
 716 }
 717 if {![regsub {^git version } $_git_version {} _git_version]} {
 718         catch {wm withdraw .}
 719         tk_messageBox \
 720                 -icon error \
 721                 -type ok \
 722                 -title [mc "git-gui: fatal error"] \
 723                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 724         exit 1
 725 }
 726
 727 set _real_git_version $_git_version
 728 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 729 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 730 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 731 regsub {\.GIT$} $_git_version {} _git_version
 732 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 733
 734 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 735         catch {wm withdraw .}
 736         if {[tk_messageBox \
 737                 -icon warning \
 738                 -type yesno \
 739                 -default no \
 740                 -title "[appname]: warning" \
 741                  -message [mc "Git version cannot be determined.
 742
 743 %s claims it is version '%s'.
 744
 745 %s requires at least Git 1.5.0 or later.
 746
 747 Assume '%s' is version 1.5.0?
 748 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 749                 set _git_version 1.5.0
 750         } else {
 751                 exit 1
 752         }
 753 }
 754 unset _real_git_version
 755
 756 proc git-version {args} {
 757         global _git_version
 758
 759         switch [llength $args] {
 760         0 {
 761                 return $_git_version
 762         }
 763
 764         2 {
 765                 set op [lindex $args 0]
 766                 set vr [lindex $args 1]
 767                 set cm [package vcompare $_git_version $vr]
 768                 return [expr $cm $op 0]
 769         }
 770
 771         4 {
 772                 set type [lindex $args 0]
 773                 set name [lindex $args 1]
 774                 set parm [lindex $args 2]
 775                 set body [lindex $args 3]
 776
 777                 if {($type ne {proc} && $type ne {method})} {
 778                         error "Invalid arguments to git-version"
 779                 }
 780                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 781                         error "Last arm of $type $name must be default"
 782                 }
 783
 784                 foreach {op vr cb} [lrange $body 0 end-2] {
 785                         if {[git-version $op $vr]} {
 786                                 return [uplevel [list $type $name $parm $cb]]
 787                         }
 788                 }
 789
 790                 return [uplevel [list $type $name $parm [lindex $body end]]]
 791         }
 792
 793         default {
 794                 error "git-version >= x"
 795         }
 796
 797         }
 798 }
 799
 800 if {[git-version < 1.5]} {
 801         catch {wm withdraw .}
 802         tk_messageBox \
 803                 -icon error \
 804                 -type ok \
 805                 -title [mc "git-gui: fatal error"] \
 806                 -message "[appname] requires Git 1.5.0 or later.
 807
 808 You are using [git-version]:
 809
 810 [git --version]"
 811         exit 1
 812 }
 813
 814 ######################################################################
 815 ##
 816 ## configure our library
 817
 818 set idx [file join $oguilib tclIndex]
 819 if {[catch {set fd [open $idx r]} err]} {
 820         catch {wm withdraw .}
 821         tk_messageBox \
 822                 -icon error \
 823                 -type ok \
 824                 -title [mc "git-gui: fatal error"] \
 825                 -message $err
 826         exit 1
 827 }
 828 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 829         set idx [list]
 830         while {[gets $fd n] >= 0} {
 831                 if {$n ne {} && ![string match #* $n]} {
 832                         lappend idx $n
 833                 }
 834         }
 835 } else {
 836         set idx {}
 837 }
 838 close $fd
 839
 840 if {$idx ne {}} {
 841         set loaded [list]
 842         foreach p $idx {
 843                 if {[lsearch -exact $loaded $p] >= 0} continue
 844                 source [file join $oguilib $p]
 845                 lappend loaded $p
 846         }
 847         unset loaded p
 848 } else {
 849         set auto_path [concat [list $oguilib] $auto_path]
 850 }
 851 unset -nocomplain idx fd
 852
 853 ######################################################################
 854 ##
 855 ## config file parsing
 856
 857 git-version proc _parse_config {arr_name args} {
 858         >= 1.5.3 {
 859                 upvar $arr_name arr
 860                 array unset arr
 861                 set buf {}
 862                 catch {
 863                         set fd_rc [eval \
 864                                 [list git_read config] \
 865                                 $args \
 866                                 [list --null --list]]
 867                         fconfigure $fd_rc -translation binary
 868                         set buf [read $fd_rc]
 869                         close $fd_rc
 870                 }
 871                 foreach line [split $buf "\0"] {
 872                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 873                                 if {[is_many_config $name]} {
 874                                         lappend arr($name) $value
 875                                 } else {
 876                                         set arr($name) $value
 877                                 }
 878                         }
 879                 }
 880         }
 881         default {
 882                 upvar $arr_name arr
 883                 array unset arr
 884                 catch {
 885                         set fd_rc [eval [list git_read config --list] $args]
 886                         while {[gets $fd_rc line] >= 0} {
 887                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 888                                         if {[is_many_config $name]} {
 889                                                 lappend arr($name) $value
 890                                         } else {
 891                                                 set arr($name) $value
 892                                         }
 893                                 }
 894                         }
 895                         close $fd_rc
 896                 }
 897         }
 898 }
 899
 900 proc load_config {include_global} {
 901         global repo_config global_config default_config
 902
 903         if {$include_global} {
 904                 _parse_config global_config --global
 905         }
 906         _parse_config repo_config
 907
 908         foreach name [array names default_config] {
 909                 if {[catch {set v $global_config($name)}]} {
 910                         set global_config($name) $default_config($name)
 911                 }
 912                 if {[catch {set v $repo_config($name)}]} {
 913                         set repo_config($name) $default_config($name)
 914                 }
 915         }
 916 }
 917
 918 ######################################################################
 919 ##
 920 ## feature option selection
 921
 922 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 923         unset _junk
 924 } else {
 925         set subcommand gui
 926 }
 927 if {$subcommand eq {gui.sh}} {
 928         set subcommand gui
 929 }
 930 if {$subcommand eq {gui} && [llength $argv] > 0} {
 931         set subcommand [lindex $argv 0]
 932         set argv [lrange $argv 1 end]
 933 }
 934
 935 enable_option multicommit
 936 enable_option branch
 937 enable_option transport
 938 disable_option bare
 939
 940 switch -- $subcommand {
 941 browser -
 942 blame {
 943         enable_option bare
 944
 945         disable_option multicommit
 946         disable_option branch
 947         disable_option transport
 948 }
 949 citool {
 950         enable_option singlecommit
 951
 952         disable_option multicommit
 953         disable_option branch
 954         disable_option transport
 955 }
 956 }
 957
 958 ######################################################################
 959 ##
 960 ## repository setup
 961
 962 if {[catch {
 963                 set _gitdir $env(GIT_DIR)
 964                 set _prefix {}
 965                 }]
 966         && [catch {
 967                 set _gitdir [git rev-parse --git-dir]
 968                 set _prefix [git rev-parse --show-prefix]
 969         } err]} {
 970         load_config 1
 971         apply_config
 972         choose_repository::pick
 973 }
 974 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 975         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 976 }
 977 if {![file isdirectory $_gitdir]} {
 978         catch {wm withdraw .}
 979         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 980         exit 1
 981 }
 982 if {$_prefix ne {}} {
 983         regsub -all {[^/]+/} $_prefix ../ cdup
 984         if {[catch {cd $cdup} err]} {
 985                 catch {wm withdraw .}
 986                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 987                 exit 1
 988         }
 989         unset cdup
 990 } elseif {![is_enabled bare]} {
 991         if {[lindex [file split $_gitdir] end] ne {.git}} {
 992                 catch {wm withdraw .}
 993                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 994                 exit 1
 995         }
 996         if {[catch {cd [file dirname $_gitdir]} err]} {
 997                 catch {wm withdraw .}
 998                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 999                 exit 1
1000         }
1001 }
1002 set _reponame [file split [file normalize $_gitdir]]
1003 if {[lindex $_reponame end] eq {.git}} {
1004         set _reponame [lindex $_reponame end-1]
1005 } else {
1006         set _reponame [lindex $_reponame end]
1007 }
1008
1009 ######################################################################
1010 ##
1011 ## global init
1012
1013 set current_diff_path {}
1014 set current_diff_side {}
1015 set diff_actions [list]
1016
1017 set HEAD {}
1018 set PARENT {}
1019 set MERGE_HEAD [list]
1020 set commit_type {}
1021 set empty_tree {}
1022 set current_branch {}
1023 set is_detached 0
1024 set current_diff_path {}
1025 set is_3way_diff 0
1026 set selected_commit_type new
1027
1028 ######################################################################
1029 ##
1030 ## task management
1031
1032 set rescan_active 0
1033 set diff_active 0
1034 set last_clicked {}
1035
1036 set disable_on_lock [list]
1037 set index_lock_type none
1038
1039 proc lock_index {type} {
1040         global index_lock_type disable_on_lock
1041
1042         if {$index_lock_type eq {none}} {
1043                 set index_lock_type $type
1044                 foreach w $disable_on_lock {
1045                         uplevel #0 $w disabled
1046                 }
1047                 return 1
1048         } elseif {$index_lock_type eq "begin-$type"} {
1049                 set index_lock_type $type
1050                 return 1
1051         }
1052         return 0
1053 }
1054
1055 proc unlock_index {} {
1056         global index_lock_type disable_on_lock
1057
1058         set index_lock_type none
1059         foreach w $disable_on_lock {
1060                 uplevel #0 $w normal
1061         }
1062 }
1063
1064 ######################################################################
1065 ##
1066 ## status
1067
1068 proc repository_state {ctvar hdvar mhvar} {
1069         global current_branch
1070         upvar $ctvar ct $hdvar hd $mhvar mh
1071
1072         set mh [list]
1073
1074         load_current_branch
1075         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1076                 set hd {}
1077                 set ct initial
1078                 return
1079         }
1080
1081         set merge_head [gitdir MERGE_HEAD]
1082         if {[file exists $merge_head]} {
1083                 set ct merge
1084                 set fd_mh [open $merge_head r]
1085                 while {[gets $fd_mh line] >= 0} {
1086                         lappend mh $line
1087                 }
1088                 close $fd_mh
1089                 return
1090         }
1091
1092         set ct normal
1093 }
1094
1095 proc PARENT {} {
1096         global PARENT empty_tree
1097
1098         set p [lindex $PARENT 0]
1099         if {$p ne {}} {
1100                 return $p
1101         }
1102         if {$empty_tree eq {}} {
1103                 set empty_tree [git mktree << {}]
1104         }
1105         return $empty_tree
1106 }
1107
1108 proc rescan {after {honor_trustmtime 1}} {
1109         global HEAD PARENT MERGE_HEAD commit_type
1110         global ui_index ui_workdir ui_comm
1111         global rescan_active file_states
1112         global repo_config
1113
1114         if {$rescan_active > 0 || ![lock_index read]} return
1115
1116         repository_state newType newHEAD newMERGE_HEAD
1117         if {[string match amend* $commit_type]
1118                 && $newType eq {normal}
1119                 && $newHEAD eq $HEAD} {
1120         } else {
1121                 set HEAD $newHEAD
1122                 set PARENT $newHEAD
1123                 set MERGE_HEAD $newMERGE_HEAD
1124                 set commit_type $newType
1125         }
1126
1127         array unset file_states
1128
1129         if {!$::GITGUI_BCK_exists &&
1130                 (![$ui_comm edit modified]
1131                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1132                 if {[string match amend* $commit_type]} {
1133                 } elseif {[load_message GITGUI_MSG]} {
1134                 } elseif {[load_message MERGE_MSG]} {
1135                 } elseif {[load_message SQUASH_MSG]} {
1136                 }
1137                 $ui_comm edit reset
1138                 $ui_comm edit modified false
1139         }
1140
1141         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1142                 rescan_stage2 {} $after
1143         } else {
1144                 set rescan_active 1
1145                 ui_status [mc "Refreshing file status..."]
1146                 set fd_rf [git_read update-index \
1147                         -q \
1148                         --unmerged \
1149                         --ignore-missing \
1150                         --refresh \
1151                         ]
1152                 fconfigure $fd_rf -blocking 0 -translation binary
1153                 fileevent $fd_rf readable \
1154                         [list rescan_stage2 $fd_rf $after]
1155         }
1156 }
1157
1158 if {[is_Cygwin]} {
1159         set is_git_info_exclude {}
1160         proc have_info_exclude {} {
1161                 global is_git_info_exclude
1162
1163                 if {$is_git_info_exclude eq {}} {
1164                         if {[catch {exec test -f [gitdir info exclude]}]} {
1165                                 set is_git_info_exclude 0
1166                         } else {
1167                                 set is_git_info_exclude 1
1168                         }
1169                 }
1170                 return $is_git_info_exclude
1171         }
1172 } else {
1173         proc have_info_exclude {} {
1174                 return [file readable [gitdir info exclude]]
1175         }
1176 }
1177
1178 proc rescan_stage2 {fd after} {
1179         global rescan_active buf_rdi buf_rdf buf_rlo
1180
1181         if {$fd ne {}} {
1182                 read $fd
1183                 if {![eof $fd]} return
1184                 close $fd
1185         }
1186
1187         set ls_others [list --exclude-per-directory=.gitignore]
1188         if {[have_info_exclude]} {
1189                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1190         }
1191         set user_exclude [get_config core.excludesfile]
1192         if {$user_exclude ne {} && [file readable $user_exclude]} {
1193                 lappend ls_others "--exclude-from=$user_exclude"
1194         }
1195
1196         set buf_rdi {}
1197         set buf_rdf {}
1198         set buf_rlo {}
1199
1200         set rescan_active 3
1201         ui_status [mc "Scanning for modified files ..."]
1202         set fd_di [git_read diff-index --cached -z [PARENT]]
1203         set fd_df [git_read diff-files -z]
1204         set fd_lo [eval git_read ls-files --others -z $ls_others]
1205
1206         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1207         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1208         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1209         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1210         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1211         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1212 }
1213
1214 proc load_message {file} {
1215         global ui_comm
1216
1217         set f [gitdir $file]
1218         if {[file isfile $f]} {
1219                 if {[catch {set fd [open $f r]}]} {
1220                         return 0
1221                 }
1222                 fconfigure $fd -eofchar {}
1223                 set content [string trim [read $fd]]
1224                 close $fd
1225                 regsub -all -line {[ \r\t]+$} $content {} content
1226                 $ui_comm delete 0.0 end
1227                 $ui_comm insert end $content
1228                 return 1
1229         }
1230         return 0
1231 }
1232
1233 proc read_diff_index {fd after} {
1234         global buf_rdi
1235
1236         append buf_rdi [read $fd]
1237         set c 0
1238         set n [string length $buf_rdi]
1239         while {$c < $n} {
1240                 set z1 [string first "\0" $buf_rdi $c]
1241                 if {$z1 == -1} break
1242                 incr z1
1243                 set z2 [string first "\0" $buf_rdi $z1]
1244                 if {$z2 == -1} break
1245
1246                 incr c
1247                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1248                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1249                 merge_state \
1250                         [encoding convertfrom $p] \
1251                         [lindex $i 4]? \
1252                         [list [lindex $i 0] [lindex $i 2]] \
1253                         [list]
1254                 set c $z2
1255                 incr c
1256         }
1257         if {$c < $n} {
1258                 set buf_rdi [string range $buf_rdi $c end]
1259         } else {
1260                 set buf_rdi {}
1261         }
1262
1263         rescan_done $fd buf_rdi $after
1264 }
1265
1266 proc read_diff_files {fd after} {
1267         global buf_rdf
1268
1269         append buf_rdf [read $fd]
1270         set c 0
1271         set n [string length $buf_rdf]
1272         while {$c < $n} {
1273                 set z1 [string first "\0" $buf_rdf $c]
1274                 if {$z1 == -1} break
1275                 incr z1
1276                 set z2 [string first "\0" $buf_rdf $z1]
1277                 if {$z2 == -1} break
1278
1279                 incr c
1280                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1281                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1282                 merge_state \
1283                         [encoding convertfrom $p] \
1284                         ?[lindex $i 4] \
1285                         [list] \
1286                         [list [lindex $i 0] [lindex $i 2]]
1287                 set c $z2
1288                 incr c
1289         }
1290         if {$c < $n} {
1291                 set buf_rdf [string range $buf_rdf $c end]
1292         } else {
1293                 set buf_rdf {}
1294         }
1295
1296         rescan_done $fd buf_rdf $after
1297 }
1298
1299 proc read_ls_others {fd after} {
1300         global buf_rlo
1301
1302         append buf_rlo [read $fd]
1303         set pck [split $buf_rlo "\0"]
1304         set buf_rlo [lindex $pck end]
1305         foreach p [lrange $pck 0 end-1] {
1306                 set p [encoding convertfrom $p]
1307                 if {[string index $p end] eq {/}} {
1308                         set p [string range $p 0 end-1]
1309                 }
1310                 merge_state $p ?O
1311         }
1312         rescan_done $fd buf_rlo $after
1313 }
1314
1315 proc rescan_done {fd buf after} {
1316         global rescan_active current_diff_path
1317         global file_states repo_config
1318         upvar $buf to_clear
1319
1320         if {![eof $fd]} return
1321         set to_clear {}
1322         close $fd
1323         if {[incr rescan_active -1] > 0} return
1324
1325         prune_selection
1326         unlock_index
1327         display_all_files
1328         if {$current_diff_path ne {}} reshow_diff
1329         if {$current_diff_path eq {}} select_first_diff
1330
1331         uplevel #0 $after
1332 }
1333
1334 proc prune_selection {} {
1335         global file_states selected_paths
1336
1337         foreach path [array names selected_paths] {
1338                 if {[catch {set still_here $file_states($path)}]} {
1339                         unset selected_paths($path)
1340                 }
1341         }
1342 }
1343
1344 ######################################################################
1345 ##
1346 ## ui helpers
1347
1348 proc mapicon {w state path} {
1349         global all_icons
1350
1351         if {[catch {set r $all_icons($state$w)}]} {
1352                 puts "error: no icon for $w state={$state} $path"
1353                 return file_plain
1354         }
1355         return $r
1356 }
1357
1358 proc mapdesc {state path} {
1359         global all_descs
1360
1361         if {[catch {set r $all_descs($state)}]} {
1362                 puts "error: no desc for state={$state} $path"
1363                 return $state
1364         }
1365         return $r
1366 }
1367
1368 proc ui_status {msg} {
1369         global main_status
1370         if {[info exists main_status]} {
1371                 $main_status show $msg
1372         }
1373 }
1374
1375 proc ui_ready {{test {}}} {
1376         global main_status
1377         if {[info exists main_status]} {
1378                 $main_status show [mc "Ready."] $test
1379         }
1380 }
1381
1382 proc escape_path {path} {
1383         regsub -all {\\} $path "\\\\" path
1384         regsub -all "\n" $path "\\n" path
1385         return $path
1386 }
1387
1388 proc short_path {path} {
1389         return [escape_path [lindex [file split $path] end]]
1390 }
1391
1392 set next_icon_id 0
1393 set null_sha1 [string repeat 0 40]
1394
1395 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1396         global file_states next_icon_id null_sha1
1397
1398         set s0 [string index $new_state 0]
1399         set s1 [string index $new_state 1]
1400
1401         if {[catch {set info $file_states($path)}]} {
1402                 set state __
1403                 set icon n[incr next_icon_id]
1404         } else {
1405                 set state [lindex $info 0]
1406                 set icon [lindex $info 1]
1407                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1408                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1409         }
1410
1411         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1412         elseif {$s0 eq {_}} {set s0 _}
1413
1414         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1415         elseif {$s1 eq {_}} {set s1 _}
1416
1417         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1418                 set head_info [list 0 $null_sha1]
1419         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1420                 && $head_info eq {}} {
1421                 set head_info $index_info
1422         }
1423
1424         set file_states($path) [list $s0$s1 $icon \
1425                 $head_info $index_info \
1426                 ]
1427         return $state
1428 }
1429
1430 proc display_file_helper {w path icon_name old_m new_m} {
1431         global file_lists
1432
1433         if {$new_m eq {_}} {
1434                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1435                 if {$lno >= 0} {
1436                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1437                         incr lno
1438                         $w conf -state normal
1439                         $w delete $lno.0 [expr {$lno + 1}].0
1440                         $w conf -state disabled
1441                 }
1442         } elseif {$old_m eq {_} && $new_m ne {_}} {
1443                 lappend file_lists($w) $path
1444                 set file_lists($w) [lsort -unique $file_lists($w)]
1445                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1446                 incr lno
1447                 $w conf -state normal
1448                 $w image create $lno.0 \
1449                         -align center -padx 5 -pady 1 \
1450                         -name $icon_name \
1451                         -image [mapicon $w $new_m $path]
1452                 $w insert $lno.1 "[escape_path $path]\n"
1453                 $w conf -state disabled
1454         } elseif {$old_m ne $new_m} {
1455                 $w conf -state normal
1456                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1457                 $w conf -state disabled
1458         }
1459 }
1460
1461 proc display_file {path state} {
1462         global file_states selected_paths
1463         global ui_index ui_workdir
1464
1465         set old_m [merge_state $path $state]
1466         set s $file_states($path)
1467         set new_m [lindex $s 0]
1468         set icon_name [lindex $s 1]
1469
1470         set o [string index $old_m 0]
1471         set n [string index $new_m 0]
1472         if {$o eq {U}} {
1473                 set o _
1474         }
1475         if {$n eq {U}} {
1476                 set n _
1477         }
1478         display_file_helper     $ui_index $path $icon_name $o $n
1479
1480         if {[string index $old_m 0] eq {U}} {
1481                 set o U
1482         } else {
1483                 set o [string index $old_m 1]
1484         }
1485         if {[string index $new_m 0] eq {U}} {
1486                 set n U
1487         } else {
1488                 set n [string index $new_m 1]
1489         }
1490         display_file_helper     $ui_workdir $path $icon_name $o $n
1491
1492         if {$new_m eq {__}} {
1493                 unset file_states($path)
1494                 catch {unset selected_paths($path)}
1495         }
1496 }
1497
1498 proc display_all_files_helper {w path icon_name m} {
1499         global file_lists
1500
1501         lappend file_lists($w) $path
1502         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1503         $w image create end \
1504                 -align center -padx 5 -pady 1 \
1505                 -name $icon_name \
1506                 -image [mapicon $w $m $path]
1507         $w insert end "[escape_path $path]\n"
1508 }
1509
1510 proc display_all_files {} {
1511         global ui_index ui_workdir
1512         global file_states file_lists
1513         global last_clicked
1514
1515         $ui_index conf -state normal
1516         $ui_workdir conf -state normal
1517
1518         $ui_index delete 0.0 end
1519         $ui_workdir delete 0.0 end
1520         set last_clicked {}
1521
1522         set file_lists($ui_index) [list]
1523         set file_lists($ui_workdir) [list]
1524
1525         foreach path [lsort [array names file_states]] {
1526                 set s $file_states($path)
1527                 set m [lindex $s 0]
1528                 set icon_name [lindex $s 1]
1529
1530                 set s [string index $m 0]
1531                 if {$s ne {U} && $s ne {_}} {
1532                         display_all_files_helper $ui_index $path \
1533                                 $icon_name $s
1534                 }
1535
1536                 if {[string index $m 0] eq {U}} {
1537                         set s U
1538                 } else {
1539                         set s [string index $m 1]
1540                 }
1541                 if {$s ne {_}} {
1542                         display_all_files_helper $ui_workdir $path \
1543                                 $icon_name $s
1544                 }
1545         }
1546
1547         $ui_index conf -state disabled
1548         $ui_workdir conf -state disabled
1549 }
1550
1551 ######################################################################
1552 ##
1553 ## icons
1554
1555 set filemask {
1556 #define mask_width 14
1557 #define mask_height 15
1558 static unsigned char mask_bits[] = {
1559    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1560    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1561    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1562 }
1563
1564 image create bitmap file_plain -background white -foreground black -data {
1565 #define plain_width 14
1566 #define plain_height 15
1567 static unsigned char plain_bits[] = {
1568    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1569    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1570    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1571 } -maskdata $filemask
1572
1573 image create bitmap file_mod -background white -foreground blue -data {
1574 #define mod_width 14
1575 #define mod_height 15
1576 static unsigned char mod_bits[] = {
1577    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1578    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1579    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1580 } -maskdata $filemask
1581
1582 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1583 #define file_fulltick_width 14
1584 #define file_fulltick_height 15
1585 static unsigned char file_fulltick_bits[] = {
1586    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1587    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1588    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1589 } -maskdata $filemask
1590
1591 image create bitmap file_parttick -background white -foreground "#005050" -data {
1592 #define parttick_width 14
1593 #define parttick_height 15
1594 static unsigned char parttick_bits[] = {
1595    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1596    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1597    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1598 } -maskdata $filemask
1599
1600 image create bitmap file_question -background white -foreground black -data {
1601 #define file_question_width 14
1602 #define file_question_height 15
1603 static unsigned char file_question_bits[] = {
1604    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1605    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1606    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1607 } -maskdata $filemask
1608
1609 image create bitmap file_removed -background white -foreground red -data {
1610 #define file_removed_width 14
1611 #define file_removed_height 15
1612 static unsigned char file_removed_bits[] = {
1613    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1614    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1615    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1616 } -maskdata $filemask
1617
1618 image create bitmap file_merge -background white -foreground blue -data {
1619 #define file_merge_width 14
1620 #define file_merge_height 15
1621 static unsigned char file_merge_bits[] = {
1622    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1623    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1624    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1625 } -maskdata $filemask
1626
1627 image create bitmap file_statechange -background white -foreground green -data {
1628 #define file_merge_width 14
1629 #define file_merge_height 15
1630 static unsigned char file_statechange_bits[] = {
1631    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1632    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1633    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1634 } -maskdata $filemask
1635
1636 set ui_index .vpane.files.index.list
1637 set ui_workdir .vpane.files.workdir.list
1638
1639 set all_icons(_$ui_index)   file_plain
1640 set all_icons(A$ui_index)   file_fulltick
1641 set all_icons(M$ui_index)   file_fulltick
1642 set all_icons(D$ui_index)   file_removed
1643 set all_icons(U$ui_index)   file_merge
1644 set all_icons(T$ui_index)   file_statechange
1645
1646 set all_icons(_$ui_workdir) file_plain
1647 set all_icons(M$ui_workdir) file_mod
1648 set all_icons(D$ui_workdir) file_question
1649 set all_icons(U$ui_workdir) file_merge
1650 set all_icons(O$ui_workdir) file_plain
1651 set all_icons(T$ui_workdir) file_statechange
1652
1653 set max_status_desc 0
1654 foreach i {
1655                 {__ {mc "Unmodified"}}
1656
1657                 {_M {mc "Modified, not staged"}}
1658                 {M_ {mc "Staged for commit"}}
1659                 {MM {mc "Portions staged for commit"}}
1660                 {MD {mc "Staged for commit, missing"}}
1661
1662                 {_T {mc "File type changed, not staged"}}
1663                 {T_ {mc "File type changed, staged"}}
1664
1665                 {_O {mc "Untracked, not staged"}}
1666                 {A_ {mc "Staged for commit"}}
1667                 {AM {mc "Portions staged for commit"}}
1668                 {AD {mc "Staged for commit, missing"}}
1669
1670                 {_D {mc "Missing"}}
1671                 {D_ {mc "Staged for removal"}}
1672                 {DO {mc "Staged for removal, still present"}}
1673
1674                 {_U {mc "Requires merge resolution"}}
1675                 {U_ {mc "Requires merge resolution"}}
1676                 {UU {mc "Requires merge resolution"}}
1677                 {UM {mc "Requires merge resolution"}}
1678                 {UD {mc "Requires merge resolution"}}
1679                 {UT {mc "Requires merge resolution"}}
1680         } {
1681         set text [eval [lindex $i 1]]
1682         if {$max_status_desc < [string length $text]} {
1683                 set max_status_desc [string length $text]
1684         }
1685         set all_descs([lindex $i 0]) $text
1686 }
1687 unset i
1688
1689 ######################################################################
1690 ##
1691 ## util
1692
1693 proc scrollbar2many {list mode args} {
1694         foreach w $list {eval $w $mode $args}
1695 }
1696
1697 proc many2scrollbar {list mode sb top bottom} {
1698         $sb set $top $bottom
1699         foreach w $list {$w $mode moveto $top}
1700 }
1701
1702 proc incr_font_size {font {amt 1}} {
1703         set sz [font configure $font -size]
1704         incr sz $amt
1705         font configure $font -size $sz
1706         font configure ${font}bold -size $sz
1707         font configure ${font}italic -size $sz
1708 }
1709
1710 ######################################################################
1711 ##
1712 ## ui commands
1713
1714 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1715
1716 proc do_gitk {revs} {
1717         # -- Always start gitk through whatever we were loaded with.  This
1718         #    lets us bypass using shell process on Windows systems.
1719         #
1720         set exe [_which gitk -script]
1721         set cmd [list [info nameofexecutable] $exe]
1722         if {$exe eq {}} {
1723                 error_popup [mc "Couldn't find gitk in PATH"]
1724         } else {
1725                 global env
1726
1727                 if {[info exists env(GIT_DIR)]} {
1728                         set old_GIT_DIR $env(GIT_DIR)
1729                 } else {
1730                         set old_GIT_DIR {}
1731                 }
1732
1733                 set pwd [pwd]
1734                 cd [file dirname [gitdir]]
1735                 set env(GIT_DIR) [file tail [gitdir]]
1736
1737                 eval exec $cmd $revs &
1738
1739                 if {$old_GIT_DIR eq {}} {
1740                         unset env(GIT_DIR)
1741                 } else {
1742                         set env(GIT_DIR) $old_GIT_DIR
1743                 }
1744                 cd $pwd
1745
1746                 ui_status $::starting_gitk_msg
1747                 after 10000 {
1748                         ui_ready $starting_gitk_msg
1749                 }
1750         }
1751 }
1752
1753 set is_quitting 0
1754
1755 proc do_quit {} {
1756         global ui_comm is_quitting repo_config commit_type
1757         global GITGUI_BCK_exists GITGUI_BCK_i
1758         global ui_comm_spell
1759
1760         if {$is_quitting} return
1761         set is_quitting 1
1762
1763         if {[winfo exists $ui_comm]} {
1764                 # -- Stash our current commit buffer.
1765                 #
1766                 set save [gitdir GITGUI_MSG]
1767                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1768                         file rename -force [gitdir GITGUI_BCK] $save
1769                         set GITGUI_BCK_exists 0
1770                 } else {
1771                         set msg [string trim [$ui_comm get 0.0 end]]
1772                         regsub -all -line {[ \r\t]+$} $msg {} msg
1773                         if {(![string match amend* $commit_type]
1774                                 || [$ui_comm edit modified])
1775                                 && $msg ne {}} {
1776                                 catch {
1777                                         set fd [open $save w]
1778                                         puts -nonewline $fd $msg
1779                                         close $fd
1780                                 }
1781                         } else {
1782                                 catch {file delete $save}
1783                         }
1784                 }
1785
1786                 # -- Cancel our spellchecker if its running.
1787                 #
1788                 if {[info exists ui_comm_spell]} {
1789                         $ui_comm_spell stop
1790                 }
1791
1792                 # -- Remove our editor backup, its not needed.
1793                 #
1794                 after cancel $GITGUI_BCK_i
1795                 if {$GITGUI_BCK_exists} {
1796                         catch {file delete [gitdir GITGUI_BCK]}
1797                 }
1798
1799                 # -- Stash our current window geometry into this repository.
1800                 #
1801                 set cfg_geometry [list]
1802                 lappend cfg_geometry [wm geometry .]
1803                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1804                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1805                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1806                         set rc_geometry {}
1807                 }
1808                 if {$cfg_geometry ne $rc_geometry} {
1809                         catch {git config gui.geometry $cfg_geometry}
1810                 }
1811         }
1812
1813         destroy .
1814 }
1815
1816 proc do_rescan {} {
1817         rescan ui_ready
1818 }
1819
1820 proc ui_do_rescan {} {
1821         rescan {force_first_diff; ui_ready}
1822 }
1823
1824 proc do_commit {} {
1825         commit_tree
1826 }
1827
1828 proc next_diff {} {
1829         global next_diff_p next_diff_w next_diff_i
1830         show_diff $next_diff_p $next_diff_w {}
1831 }
1832
1833 proc find_anchor_pos {lst name} {
1834         set lid [lsearch -sorted -exact $lst $name]
1835
1836         if {$lid == -1} {
1837                 set lid 0
1838                 foreach lname $lst {
1839                         if {$lname >= $name} break
1840                         incr lid
1841                 }
1842         }
1843
1844         return $lid
1845 }
1846
1847 proc find_file_from {flist idx delta path mmask} {
1848         global file_states
1849
1850         set len [llength $flist]
1851         while {$idx >= 0 && $idx < $len} {
1852                 set name [lindex $flist $idx]
1853
1854                 if {$name ne $path && [info exists file_states($name)]} {
1855                         set state [lindex $file_states($name) 0]
1856
1857                         if {$mmask eq {} || [regexp $mmask $state]} {
1858                                 return $idx
1859                         }
1860                 }
1861
1862                 incr idx $delta
1863         }
1864
1865         return {}
1866 }
1867
1868 proc find_next_diff {w path {lno {}} {mmask {}}} {
1869         global next_diff_p next_diff_w next_diff_i
1870         global file_lists ui_index ui_workdir
1871
1872         set flist $file_lists($w)
1873         if {$lno eq {}} {
1874                 set lno [find_anchor_pos $flist $path]
1875         } else {
1876                 incr lno -1
1877         }
1878
1879         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
1880                 if {$w eq $ui_index} {
1881                         set mmask "^$mmask"
1882                 } else {
1883                         set mmask "$mmask\$"
1884                 }
1885         }
1886
1887         set idx [find_file_from $flist $lno 1 $path $mmask]
1888         if {$idx eq {}} {
1889                 incr lno -1
1890                 set idx [find_file_from $flist $lno -1 $path $mmask]
1891         }
1892
1893         if {$idx ne {}} {
1894                 set next_diff_w $w
1895                 set next_diff_p [lindex $flist $idx]
1896                 set next_diff_i [expr {$idx+1}]
1897                 return 1
1898         } else {
1899                 return 0
1900         }
1901 }
1902
1903 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
1904         global current_diff_path
1905
1906         if {$path ne $current_diff_path} {
1907                 return {}
1908         } elseif {[find_next_diff $w $path $lno $mmask]} {
1909                 return {next_diff;}
1910         } else {
1911                 return {reshow_diff;}
1912         }
1913 }
1914
1915 proc select_first_diff {} {
1916         global ui_workdir
1917
1918         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
1919             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
1920                 next_diff
1921         }
1922 }
1923
1924 proc force_first_diff {} {
1925         global current_diff_path
1926
1927         if {[info exists file_states($current_diff_path)]} {
1928                 set state [lindex $file_states($current_diff_path) 0]
1929
1930                 if {[string index $state 1] ne {O}} return
1931         }
1932
1933         select_first_diff
1934 }
1935
1936 proc toggle_or_diff {w x y} {
1937         global file_states file_lists current_diff_path ui_index ui_workdir
1938         global last_clicked selected_paths
1939
1940         set pos [split [$w index @$x,$y] .]
1941         set lno [lindex $pos 0]
1942         set col [lindex $pos 1]
1943         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1944         if {$path eq {}} {
1945                 set last_clicked {}
1946                 return
1947         }
1948
1949         set last_clicked [list $w $lno]
1950         array unset selected_paths
1951         $ui_index tag remove in_sel 0.0 end
1952         $ui_workdir tag remove in_sel 0.0 end
1953
1954         # Do not stage files with conflicts
1955         if {[info exists file_states($path)]} {
1956                 set state [lindex $file_states($path) 0]
1957         } else {
1958                 set state {__}
1959         }
1960
1961         if {[string first {U} $state] >= 0} {
1962                 set col 1
1963         }
1964
1965         # Restage the file, or simply show the diff
1966         if {$col == 0 && $y > 1} {
1967                 if {[string index $state 1] eq {O}} {
1968                         set mmask {}
1969                 } else {
1970                         set mmask {[^O]}
1971                 }
1972
1973                 set after [next_diff_after_action $w $path $lno $mmask]
1974
1975                 if {$w eq $ui_index} {
1976                         update_indexinfo \
1977                                 "Unstaging [short_path $path] from commit" \
1978                                 [list $path] \
1979                                 [concat $after [list ui_ready]]
1980                 } elseif {$w eq $ui_workdir} {
1981                         update_index \
1982                                 "Adding [short_path $path]" \
1983                                 [list $path] \
1984                                 [concat $after [list ui_ready]]
1985                 }
1986         } else {
1987                 show_diff $path $w $lno
1988         }
1989 }
1990
1991 proc add_one_to_selection {w x y} {
1992         global file_lists last_clicked selected_paths
1993
1994         set lno [lindex [split [$w index @$x,$y] .] 0]
1995         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1996         if {$path eq {}} {
1997                 set last_clicked {}
1998                 return
1999         }
2000
2001         if {$last_clicked ne {}
2002                 && [lindex $last_clicked 0] ne $w} {
2003                 array unset selected_paths
2004                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2005         }
2006
2007         set last_clicked [list $w $lno]
2008         if {[catch {set in_sel $selected_paths($path)}]} {
2009                 set in_sel 0
2010         }
2011         if {$in_sel} {
2012                 unset selected_paths($path)
2013                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2014         } else {
2015                 set selected_paths($path) 1
2016                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2017         }
2018 }
2019
2020 proc add_range_to_selection {w x y} {
2021         global file_lists last_clicked selected_paths
2022
2023         if {[lindex $last_clicked 0] ne $w} {
2024                 toggle_or_diff $w $x $y
2025                 return
2026         }
2027
2028         set lno [lindex [split [$w index @$x,$y] .] 0]
2029         set lc [lindex $last_clicked 1]
2030         if {$lc < $lno} {
2031                 set begin $lc
2032                 set end $lno
2033         } else {
2034                 set begin $lno
2035                 set end $lc
2036         }
2037
2038         foreach path [lrange $file_lists($w) \
2039                 [expr {$begin - 1}] \
2040                 [expr {$end - 1}]] {
2041                 set selected_paths($path) 1
2042         }
2043         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2044 }
2045
2046 proc show_more_context {} {
2047         global repo_config
2048         if {$repo_config(gui.diffcontext) < 99} {
2049                 incr repo_config(gui.diffcontext)
2050                 reshow_diff
2051         }
2052 }
2053
2054 proc show_less_context {} {
2055         global repo_config
2056         if {$repo_config(gui.diffcontext) > 1} {
2057                 incr repo_config(gui.diffcontext) -1
2058                 reshow_diff
2059         }
2060 }
2061
2062 ######################################################################
2063 ##
2064 ## ui construction
2065
2066 load_config 0
2067 apply_config
2068 set ui_comm {}
2069
2070 # -- Menu Bar
2071 #
2072 menu .mbar -tearoff 0
2073 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2074 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2075 if {[is_enabled branch]} {
2076         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2077 }
2078 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2079         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2080 }
2081 if {[is_enabled transport]} {
2082         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2083         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2084 }
2085 . configure -menu .mbar
2086
2087 # -- Repository Menu
2088 #
2089 menu .mbar.repository
2090
2091 .mbar.repository add command \
2092         -label [mc "Browse Current Branch's Files"] \
2093         -command {browser::new $current_branch}
2094 set ui_browse_current [.mbar.repository index last]
2095 .mbar.repository add command \
2096         -label [mc "Browse Branch Files..."] \
2097         -command browser_open::dialog
2098 .mbar.repository add separator
2099
2100 .mbar.repository add command \
2101         -label [mc "Visualize Current Branch's History"] \
2102         -command {do_gitk $current_branch}
2103 set ui_visualize_current [.mbar.repository index last]
2104 .mbar.repository add command \
2105         -label [mc "Visualize All Branch History"] \
2106         -command {do_gitk --all}
2107 .mbar.repository add separator
2108
2109 proc current_branch_write {args} {
2110         global current_branch
2111         .mbar.repository entryconf $::ui_browse_current \
2112                 -label [mc "Browse %s's Files" $current_branch]
2113         .mbar.repository entryconf $::ui_visualize_current \
2114                 -label [mc "Visualize %s's History" $current_branch]
2115 }
2116 trace add variable current_branch write current_branch_write
2117
2118 if {[is_enabled multicommit]} {
2119         .mbar.repository add command -label [mc "Database Statistics"] \
2120                 -command do_stats
2121
2122         .mbar.repository add command -label [mc "Compress Database"] \
2123                 -command do_gc
2124
2125         .mbar.repository add command -label [mc "Verify Database"] \
2126                 -command do_fsck_objects
2127
2128         .mbar.repository add separator
2129
2130         if {[is_Cygwin]} {
2131                 .mbar.repository add command \
2132                         -label [mc "Create Desktop Icon"] \
2133                         -command do_cygwin_shortcut
2134         } elseif {[is_Windows]} {
2135                 .mbar.repository add command \
2136                         -label [mc "Create Desktop Icon"] \
2137                         -command do_windows_shortcut
2138         } elseif {[is_MacOSX]} {
2139                 .mbar.repository add command \
2140                         -label [mc "Create Desktop Icon"] \
2141                         -command do_macosx_app
2142         }
2143 }
2144
2145 if {[is_MacOSX]} {
2146         proc ::tk::mac::Quit {args} { do_quit }
2147 } else {
2148         .mbar.repository add command -label [mc Quit] \
2149                 -command do_quit \
2150                 -accelerator $M1T-Q
2151 }
2152
2153 # -- Edit Menu
2154 #
2155 menu .mbar.edit
2156 .mbar.edit add command -label [mc Undo] \
2157         -command {catch {[focus] edit undo}} \
2158         -accelerator $M1T-Z
2159 .mbar.edit add command -label [mc Redo] \
2160         -command {catch {[focus] edit redo}} \
2161         -accelerator $M1T-Y
2162 .mbar.edit add separator
2163 .mbar.edit add command -label [mc Cut] \
2164         -command {catch {tk_textCut [focus]}} \
2165         -accelerator $M1T-X
2166 .mbar.edit add command -label [mc Copy] \
2167         -command {catch {tk_textCopy [focus]}} \
2168         -accelerator $M1T-C
2169 .mbar.edit add command -label [mc Paste] \
2170         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2171         -accelerator $M1T-V
2172 .mbar.edit add command -label [mc Delete] \
2173         -command {catch {[focus] delete sel.first sel.last}} \
2174         -accelerator Del
2175 .mbar.edit add separator
2176 .mbar.edit add command -label [mc "Select All"] \
2177         -command {catch {[focus] tag add sel 0.0 end}} \
2178         -accelerator $M1T-A
2179
2180 # -- Branch Menu
2181 #
2182 if {[is_enabled branch]} {
2183         menu .mbar.branch
2184
2185         .mbar.branch add command -label [mc "Create..."] \
2186                 -command branch_create::dialog \
2187                 -accelerator $M1T-N
2188         lappend disable_on_lock [list .mbar.branch entryconf \
2189                 [.mbar.branch index last] -state]
2190
2191         .mbar.branch add command -label [mc "Checkout..."] \
2192                 -command branch_checkout::dialog \
2193                 -accelerator $M1T-O
2194         lappend disable_on_lock [list .mbar.branch entryconf \
2195                 [.mbar.branch index last] -state]
2196
2197         .mbar.branch add command -label [mc "Rename..."] \
2198                 -command branch_rename::dialog
2199         lappend disable_on_lock [list .mbar.branch entryconf \
2200                 [.mbar.branch index last] -state]
2201
2202         .mbar.branch add command -label [mc "Delete..."] \
2203                 -command branch_delete::dialog
2204         lappend disable_on_lock [list .mbar.branch entryconf \
2205                 [.mbar.branch index last] -state]
2206
2207         .mbar.branch add command -label [mc "Reset..."] \
2208                 -command merge::reset_hard
2209         lappend disable_on_lock [list .mbar.branch entryconf \
2210                 [.mbar.branch index last] -state]
2211 }
2212
2213 # -- Commit Menu
2214 #
2215 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2216         menu .mbar.commit
2217
2218         .mbar.commit add radiobutton \
2219                 -label [mc "New Commit"] \
2220                 -command do_select_commit_type \
2221                 -variable selected_commit_type \
2222                 -value new
2223         lappend disable_on_lock \
2224                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2225
2226         .mbar.commit add radiobutton \
2227                 -label [mc "Amend Last Commit"] \
2228                 -command do_select_commit_type \
2229                 -variable selected_commit_type \
2230                 -value amend
2231         lappend disable_on_lock \
2232                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2233
2234         .mbar.commit add separator
2235
2236         .mbar.commit add command -label [mc Rescan] \
2237                 -command ui_do_rescan \
2238                 -accelerator F5
2239         lappend disable_on_lock \
2240                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2241
2242         .mbar.commit add command -label [mc "Stage To Commit"] \
2243                 -command do_add_selection \
2244                 -accelerator $M1T-T
2245         lappend disable_on_lock \
2246                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2247
2248         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2249                 -command do_add_all \
2250                 -accelerator $M1T-I
2251         lappend disable_on_lock \
2252                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2253
2254         .mbar.commit add command -label [mc "Unstage From Commit"] \
2255                 -command do_unstage_selection
2256         lappend disable_on_lock \
2257                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2258
2259         .mbar.commit add command -label [mc "Revert Changes"] \
2260                 -command do_revert_selection
2261         lappend disable_on_lock \
2262                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2263
2264         .mbar.commit add separator
2265
2266         .mbar.commit add command -label [mc "Show Less Context"] \
2267                 -command show_less_context \
2268                 -accelerator $M1T-\-
2269
2270         .mbar.commit add command -label [mc "Show More Context"] \
2271                 -command show_more_context \
2272                 -accelerator $M1T-=
2273
2274         .mbar.commit add separator
2275
2276         .mbar.commit add command -label [mc "Sign Off"] \
2277                 -command do_signoff \
2278                 -accelerator $M1T-S
2279
2280         .mbar.commit add command -label [mc Commit@@verb] \
2281                 -command do_commit \
2282                 -accelerator $M1T-Return
2283         lappend disable_on_lock \
2284                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2285 }
2286
2287 # -- Merge Menu
2288 #
2289 if {[is_enabled branch]} {
2290         menu .mbar.merge
2291         .mbar.merge add command -label [mc "Local Merge..."] \
2292                 -command merge::dialog \
2293                 -accelerator $M1T-M
2294         lappend disable_on_lock \
2295                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2296         .mbar.merge add command -label [mc "Abort Merge..."] \
2297                 -command merge::reset_hard
2298         lappend disable_on_lock \
2299                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2300 }
2301
2302 # -- Transport Menu
2303 #
2304 if {[is_enabled transport]} {
2305         menu .mbar.remote
2306
2307         .mbar.remote add command \
2308                 -label [mc "Push..."] \
2309                 -command do_push_anywhere \
2310                 -accelerator $M1T-P
2311         .mbar.remote add command \
2312                 -label [mc "Delete..."] \
2313                 -command remote_branch_delete::dialog
2314 }
2315
2316 if {[is_MacOSX]} {
2317         # -- Apple Menu (Mac OS X only)
2318         #
2319         .mbar add cascade -label Apple -menu .mbar.apple
2320         menu .mbar.apple
2321
2322         .mbar.apple add command -label [mc "About %s" [appname]] \
2323                 -command do_about
2324         .mbar.apple add separator
2325         .mbar.apple add command \
2326                 -label [mc "Preferences..."] \
2327                 -command do_options \
2328                 -accelerator $M1T-,
2329         bind . <$M1B-,> do_options
2330 } else {
2331         # -- Edit Menu
2332         #
2333         .mbar.edit add separator
2334         .mbar.edit add command -label [mc "Options..."] \
2335                 -command do_options
2336 }
2337
2338 # -- Help Menu
2339 #
2340 .mbar add cascade -label [mc Help] -menu .mbar.help
2341 menu .mbar.help
2342
2343 if {![is_MacOSX]} {
2344         .mbar.help add command -label [mc "About %s" [appname]] \
2345                 -command do_about
2346 }
2347
2348 set browser {}
2349 catch {set browser $repo_config(instaweb.browser)}
2350 set doc_path [file dirname [gitexec]]
2351 set doc_path [file join $doc_path Documentation index.html]
2352
2353 if {[is_Cygwin]} {
2354         set doc_path [exec cygpath --mixed $doc_path]
2355 }
2356
2357 if {$browser eq {}} {
2358         if {[is_MacOSX]} {
2359                 set browser open
2360         } elseif {[is_Cygwin]} {
2361                 set program_files [file dirname [exec cygpath --windir]]
2362                 set program_files [file join $program_files {Program Files}]
2363                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2364                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2365                 if {[file exists $firefox]} {
2366                         set browser $firefox
2367                 } elseif {[file exists $ie]} {
2368                         set browser $ie
2369                 }
2370                 unset program_files firefox ie
2371         }
2372 }
2373
2374 if {[file isfile $doc_path]} {
2375         set doc_url "file:$doc_path"
2376 } else {
2377         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2378 }
2379
2380 if {$browser ne {}} {
2381         .mbar.help add command -label [mc "Online Documentation"] \
2382                 -command [list exec $browser $doc_url &]
2383 }
2384 unset browser doc_path doc_url
2385
2386 # -- Standard bindings
2387 #
2388 wm protocol . WM_DELETE_WINDOW do_quit
2389 bind all <$M1B-Key-q> do_quit
2390 bind all <$M1B-Key-Q> do_quit
2391 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2392 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2393
2394 set subcommand_args {}
2395 proc usage {} {
2396         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2397         exit 1
2398 }
2399
2400 # -- Not a normal commit type invocation?  Do that instead!
2401 #
2402 switch -- $subcommand {
2403 browser -
2404 blame {
2405         if {$subcommand eq "blame"} {
2406                 set subcommand_args {[--line=<num>] rev? path}
2407         } else {
2408                 set subcommand_args {rev? path}
2409         }
2410         if {$argv eq {}} usage
2411         set head {}
2412         set path {}
2413         set jump_spec {}
2414         set is_path 0
2415         foreach a $argv {
2416                 if {$is_path || [file exists $_prefix$a]} {
2417                         if {$path ne {}} usage
2418                         set path $_prefix$a
2419                         break
2420                 } elseif {$a eq {--}} {
2421                         if {$path ne {}} {
2422                                 if {$head ne {}} usage
2423                                 set head $path
2424                                 set path {}
2425                         }
2426                         set is_path 1
2427                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2428                         if {$jump_spec ne {} || $head ne {}} usage
2429                         set jump_spec [list $lnum]
2430                 } elseif {$head eq {}} {
2431                         if {$head ne {}} usage
2432                         set head $a
2433                         set is_path 1
2434                 } else {
2435                         usage
2436                 }
2437         }
2438         unset is_path
2439
2440         if {$head ne {} && $path eq {}} {
2441                 set path $_prefix$head
2442                 set head {}
2443         }
2444
2445         if {$head eq {}} {
2446                 load_current_branch
2447         } else {
2448                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2449                         if {[catch {
2450                                         set head [git rev-parse --verify $head]
2451                                 } err]} {
2452                                 puts stderr $err
2453                                 exit 1
2454                         }
2455                 }
2456                 set current_branch $head
2457         }
2458
2459         switch -- $subcommand {
2460         browser {
2461                 if {$jump_spec ne {}} usage
2462                 if {$head eq {}} {
2463                         if {$path ne {} && [file isdirectory $path]} {
2464                                 set head $current_branch
2465                         } else {
2466                                 set head $path
2467                                 set path {}
2468                         }
2469                 }
2470                 browser::new $head $path
2471         }
2472         blame   {
2473                 if {$head eq {} && ![file exists $path]} {
2474                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2475                         exit 1
2476                 }
2477                 blame::new $head $path $jump_spec
2478         }
2479         }
2480         return
2481 }
2482 citool -
2483 gui {
2484         if {[llength $argv] != 0} {
2485                 puts -nonewline stderr "usage: $argv0"
2486                 if {$subcommand ne {gui}
2487                         && [file tail $argv0] ne "git-$subcommand"} {
2488                         puts -nonewline stderr " $subcommand"
2489                 }
2490                 puts stderr {}
2491                 exit 1
2492         }
2493         # fall through to setup UI for commits
2494 }
2495 default {
2496         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2497         exit 1
2498 }
2499 }
2500
2501 # -- Branch Control
2502 #
2503 frame .branch \
2504         -borderwidth 1 \
2505         -relief sunken
2506 label .branch.l1 \
2507         -text [mc "Current Branch:"] \
2508         -anchor w \
2509         -justify left
2510 label .branch.cb \
2511         -textvariable current_branch \
2512         -anchor w \
2513         -justify left
2514 pack .branch.l1 -side left
2515 pack .branch.cb -side left -fill x
2516 pack .branch -side top -fill x
2517
2518 # -- Main Window Layout
2519 #
2520 panedwindow .vpane -orient horizontal
2521 panedwindow .vpane.files -orient vertical
2522 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2523 pack .vpane -anchor n -side top -fill both -expand 1
2524
2525 # -- Index File List
2526 #
2527 frame .vpane.files.index -height 100 -width 200
2528 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2529         -background lightgreen -foreground black
2530 text $ui_index -background white -foreground black \
2531         -borderwidth 0 \
2532         -width 20 -height 10 \
2533         -wrap none \
2534         -cursor $cursor_ptr \
2535         -xscrollcommand {.vpane.files.index.sx set} \
2536         -yscrollcommand {.vpane.files.index.sy set} \
2537         -state disabled
2538 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2539 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2540 pack .vpane.files.index.title -side top -fill x
2541 pack .vpane.files.index.sx -side bottom -fill x
2542 pack .vpane.files.index.sy -side right -fill y
2543 pack $ui_index -side left -fill both -expand 1
2544
2545 # -- Working Directory File List
2546 #
2547 frame .vpane.files.workdir -height 100 -width 200
2548 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2549         -background lightsalmon -foreground black
2550 text $ui_workdir -background white -foreground black \
2551         -borderwidth 0 \
2552         -width 20 -height 10 \
2553         -wrap none \
2554         -cursor $cursor_ptr \
2555         -xscrollcommand {.vpane.files.workdir.sx set} \
2556         -yscrollcommand {.vpane.files.workdir.sy set} \
2557         -state disabled
2558 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2559 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2560 pack .vpane.files.workdir.title -side top -fill x
2561 pack .vpane.files.workdir.sx -side bottom -fill x
2562 pack .vpane.files.workdir.sy -side right -fill y
2563 pack $ui_workdir -side left -fill both -expand 1
2564
2565 .vpane.files add .vpane.files.workdir -sticky nsew
2566 .vpane.files add .vpane.files.index -sticky nsew
2567
2568 foreach i [list $ui_index $ui_workdir] {
2569         rmsel_tag $i
2570         $i tag conf in_diff -background [$i tag cget in_sel -background]
2571 }
2572 unset i
2573
2574 # -- Diff and Commit Area
2575 #
2576 frame .vpane.lower -height 300 -width 400
2577 frame .vpane.lower.commarea
2578 frame .vpane.lower.diff -relief sunken -borderwidth 1
2579 pack .vpane.lower.diff -fill both -expand 1
2580 pack .vpane.lower.commarea -side bottom -fill x
2581 .vpane add .vpane.lower -sticky nsew
2582
2583 # -- Commit Area Buttons
2584 #
2585 frame .vpane.lower.commarea.buttons
2586 label .vpane.lower.commarea.buttons.l -text {} \
2587         -anchor w \
2588         -justify left
2589 pack .vpane.lower.commarea.buttons.l -side top -fill x
2590 pack .vpane.lower.commarea.buttons -side left -fill y
2591
2592 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2593         -command ui_do_rescan
2594 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2595 lappend disable_on_lock \
2596         {.vpane.lower.commarea.buttons.rescan conf -state}
2597
2598 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2599         -command do_add_all
2600 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2601 lappend disable_on_lock \
2602         {.vpane.lower.commarea.buttons.incall conf -state}
2603
2604 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2605         -command do_signoff
2606 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2607
2608 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2609         -command do_commit
2610 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2611 lappend disable_on_lock \
2612         {.vpane.lower.commarea.buttons.commit conf -state}
2613
2614 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2615         -command do_push_anywhere
2616 pack .vpane.lower.commarea.buttons.push -side top -fill x
2617
2618 # -- Commit Message Buffer
2619 #
2620 frame .vpane.lower.commarea.buffer
2621 frame .vpane.lower.commarea.buffer.header
2622 set ui_comm .vpane.lower.commarea.buffer.t
2623 set ui_coml .vpane.lower.commarea.buffer.header.l
2624 radiobutton .vpane.lower.commarea.buffer.header.new \
2625         -text [mc "New Commit"] \
2626         -command do_select_commit_type \
2627         -variable selected_commit_type \
2628         -value new
2629 lappend disable_on_lock \
2630         [list .vpane.lower.commarea.buffer.header.new conf -state]
2631 radiobutton .vpane.lower.commarea.buffer.header.amend \
2632         -text [mc "Amend Last Commit"] \
2633         -command do_select_commit_type \
2634         -variable selected_commit_type \
2635         -value amend
2636 lappend disable_on_lock \
2637         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2638 label $ui_coml \
2639         -anchor w \
2640         -justify left
2641 proc trace_commit_type {varname args} {
2642         global ui_coml commit_type
2643         switch -glob -- $commit_type {
2644         initial       {set txt [mc "Initial Commit Message:"]}
2645         amend         {set txt [mc "Amended Commit Message:"]}
2646         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2647         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2648         merge         {set txt [mc "Merge Commit Message:"]}
2649         *             {set txt [mc "Commit Message:"]}
2650         }
2651         $ui_coml conf -text $txt
2652 }
2653 trace add variable commit_type write trace_commit_type
2654 pack $ui_coml -side left -fill x
2655 pack .vpane.lower.commarea.buffer.header.amend -side right
2656 pack .vpane.lower.commarea.buffer.header.new -side right
2657
2658 text $ui_comm -background white -foreground black \
2659         -borderwidth 1 \
2660         -undo true \
2661         -maxundo 20 \
2662         -autoseparators true \
2663         -relief sunken \
2664         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2665         -font font_diff \
2666         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2667 scrollbar .vpane.lower.commarea.buffer.sby \
2668         -command [list $ui_comm yview]
2669 pack .vpane.lower.commarea.buffer.header -side top -fill x
2670 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2671 pack $ui_comm -side left -fill y
2672 pack .vpane.lower.commarea.buffer -side left -fill y
2673
2674 # -- Commit Message Buffer Context Menu
2675 #
2676 set ctxm .vpane.lower.commarea.buffer.ctxm
2677 menu $ctxm -tearoff 0
2678 $ctxm add command \
2679         -label [mc Cut] \
2680         -command {tk_textCut $ui_comm}
2681 $ctxm add command \
2682         -label [mc Copy] \
2683         -command {tk_textCopy $ui_comm}
2684 $ctxm add command \
2685         -label [mc Paste] \
2686         -command {tk_textPaste $ui_comm}
2687 $ctxm add command \
2688         -label [mc Delete] \
2689         -command {$ui_comm delete sel.first sel.last}
2690 $ctxm add separator
2691 $ctxm add command \
2692         -label [mc "Select All"] \
2693         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2694 $ctxm add command \
2695         -label [mc "Copy All"] \
2696         -command {
2697                 $ui_comm tag add sel 0.0 end
2698                 tk_textCopy $ui_comm
2699                 $ui_comm tag remove sel 0.0 end
2700         }
2701 $ctxm add separator
2702 $ctxm add command \
2703         -label [mc "Sign Off"] \
2704         -command do_signoff
2705 set ui_comm_ctxm $ctxm
2706
2707 # -- Diff Header
2708 #
2709 proc trace_current_diff_path {varname args} {
2710         global current_diff_path diff_actions file_states
2711         if {$current_diff_path eq {}} {
2712                 set s {}
2713                 set f {}
2714                 set p {}
2715                 set o disabled
2716         } else {
2717                 set p $current_diff_path
2718                 set s [mapdesc [lindex $file_states($p) 0] $p]
2719                 set f [mc "File:"]
2720                 set p [escape_path $p]
2721                 set o normal
2722         }
2723
2724         .vpane.lower.diff.header.status configure -text $s
2725         .vpane.lower.diff.header.file configure -text $f
2726         .vpane.lower.diff.header.path configure -text $p
2727         foreach w $diff_actions {
2728                 uplevel #0 $w $o
2729         }
2730 }
2731 trace add variable current_diff_path write trace_current_diff_path
2732
2733 frame .vpane.lower.diff.header -background gold
2734 label .vpane.lower.diff.header.status \
2735         -background gold \
2736         -foreground black \
2737         -width $max_status_desc \
2738         -anchor w \
2739         -justify left
2740 label .vpane.lower.diff.header.file \
2741         -background gold \
2742         -foreground black \
2743         -anchor w \
2744         -justify left
2745 label .vpane.lower.diff.header.path \
2746         -background gold \
2747         -foreground black \
2748         -anchor w \
2749         -justify left
2750 pack .vpane.lower.diff.header.status -side left
2751 pack .vpane.lower.diff.header.file -side left
2752 pack .vpane.lower.diff.header.path -fill x
2753 set ctxm .vpane.lower.diff.header.ctxm
2754 menu $ctxm -tearoff 0
2755 $ctxm add command \
2756         -label [mc Copy] \
2757         -command {
2758                 clipboard clear
2759                 clipboard append \
2760                         -format STRING \
2761                         -type STRING \
2762                         -- $current_diff_path
2763         }
2764 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2765 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2766
2767 # -- Diff Body
2768 #
2769 frame .vpane.lower.diff.body
2770 set ui_diff .vpane.lower.diff.body.t
2771 text $ui_diff -background white -foreground black \
2772         -borderwidth 0 \
2773         -width 80 -height 15 -wrap none \
2774         -font font_diff \
2775         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2776         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2777         -state disabled
2778 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2779         -command [list $ui_diff xview]
2780 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2781         -command [list $ui_diff yview]
2782 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2783 pack .vpane.lower.diff.body.sby -side right -fill y
2784 pack $ui_diff -side left -fill both -expand 1
2785 pack .vpane.lower.diff.header -side top -fill x
2786 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2787
2788 $ui_diff tag conf d_cr -elide true
2789 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2790 $ui_diff tag conf d_+ -foreground {#00a000}
2791 $ui_diff tag conf d_- -foreground red
2792
2793 $ui_diff tag conf d_++ -foreground {#00a000}
2794 $ui_diff tag conf d_-- -foreground red
2795 $ui_diff tag conf d_+s \
2796         -foreground {#00a000} \
2797         -background {#e2effa}
2798 $ui_diff tag conf d_-s \
2799         -foreground red \
2800         -background {#e2effa}
2801 $ui_diff tag conf d_s+ \
2802         -foreground {#00a000} \
2803         -background ivory1
2804 $ui_diff tag conf d_s- \
2805         -foreground red \
2806         -background ivory1
2807
2808 $ui_diff tag conf d<<<<<<< \
2809         -foreground orange \
2810         -font font_diffbold
2811 $ui_diff tag conf d======= \
2812         -foreground orange \
2813         -font font_diffbold
2814 $ui_diff tag conf d>>>>>>> \
2815         -foreground orange \
2816         -font font_diffbold
2817
2818 $ui_diff tag raise sel
2819
2820 # -- Diff Body Context Menu
2821 #
2822
2823 proc create_common_diff_popup {ctxm} {
2824         $ctxm add command \
2825                 -label [mc "Show Less Context"] \
2826                 -command show_less_context
2827         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2828         $ctxm add command \
2829                 -label [mc "Show More Context"] \
2830                 -command show_more_context
2831         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2832         $ctxm add separator
2833         $ctxm add command \
2834                 -label [mc Refresh] \
2835                 -command reshow_diff
2836         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2837         $ctxm add command \
2838                 -label [mc Copy] \
2839                 -command {tk_textCopy $ui_diff}
2840         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2841         $ctxm add command \
2842                 -label [mc "Select All"] \
2843                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2844         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2845         $ctxm add command \
2846                 -label [mc "Copy All"] \
2847                 -command {
2848                         $ui_diff tag add sel 0.0 end
2849                         tk_textCopy $ui_diff
2850                         $ui_diff tag remove sel 0.0 end
2851                 }
2852         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2853         $ctxm add separator
2854         $ctxm add command \
2855                 -label [mc "Decrease Font Size"] \
2856                 -command {incr_font_size font_diff -1}
2857         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2858         $ctxm add command \
2859                 -label [mc "Increase Font Size"] \
2860                 -command {incr_font_size font_diff 1}
2861         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2862         $ctxm add separator
2863         $ctxm add command -label [mc "Options..."] \
2864                 -command do_options
2865 }
2866
2867 set ctxm .vpane.lower.diff.body.ctxm
2868 menu $ctxm -tearoff 0
2869 $ctxm add command \
2870         -label [mc "Apply/Reverse Hunk"] \
2871         -command {apply_hunk $cursorX $cursorY}
2872 set ui_diff_applyhunk [$ctxm index last]
2873 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2874 $ctxm add command \
2875         -label [mc "Apply/Reverse Line"] \
2876         -command {apply_line $cursorX $cursorY; do_rescan}
2877 set ui_diff_applyline [$ctxm index last]
2878 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
2879 $ctxm add separator
2880 create_common_diff_popup $ctxm
2881
2882 set ctxmmg .vpane.lower.diff.body.ctxmmg
2883 menu $ctxmmg -tearoff 0
2884 $ctxmmg add command \
2885         -label [mc "Run Merge Tool"] \
2886         -command {merge_resolve_tool}
2887 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2888 $ctxmmg add separator
2889 $ctxmmg add command \
2890         -label [mc "Use Remote Version"] \
2891         -command {merge_resolve_one 3}
2892 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2893 $ctxmmg add command \
2894         -label [mc "Use Local Version"] \
2895         -command {merge_resolve_one 2}
2896 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2897 $ctxmmg add command \
2898         -label [mc "Revert To Base"] \
2899         -command {merge_resolve_one 1}
2900 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
2901 $ctxmmg add separator
2902 create_common_diff_popup $ctxmmg
2903
2904 proc popup_diff_menu {ctxm ctxmmg x y X Y} {
2905         global current_diff_path file_states
2906         set ::cursorX $x
2907         set ::cursorY $y
2908         if {[info exists file_states($current_diff_path)]} {
2909                 set state [lindex $file_states($current_diff_path) 0]
2910         } else {
2911                 set state {__}
2912         }
2913         if {[string first {U} $state] >= 0} {
2914                 tk_popup $ctxmmg $X $Y
2915         } else {
2916                 if {$::ui_index eq $::current_diff_side} {
2917                         set l [mc "Unstage Hunk From Commit"]
2918                         set t [mc "Unstage Line From Commit"]
2919                 } else {
2920                         set l [mc "Stage Hunk For Commit"]
2921                         set t [mc "Stage Line For Commit"]
2922                 }
2923                 if {$::is_3way_diff
2924                         || $current_diff_path eq {}
2925                         || {__} eq $state
2926                         || {_O} eq $state
2927                         || {_T} eq $state
2928                         || {T_} eq $state} {
2929                         set s disabled
2930                 } else {
2931                         set s normal
2932                 }
2933                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2934                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
2935                 tk_popup $ctxm $X $Y
2936         }
2937 }
2938 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg %x %y %X %Y]
2939
2940 # -- Status Bar
2941 #
2942 set main_status [::status_bar::new .status]
2943 pack .status -anchor w -side bottom -fill x
2944 $main_status show [mc "Initializing..."]
2945
2946 # -- Load geometry
2947 #
2948 catch {
2949 set gm $repo_config(gui.geometry)
2950 wm geometry . [lindex $gm 0]
2951 .vpane sash place 0 \
2952         [lindex $gm 1] \
2953         [lindex [.vpane sash coord 0] 1]
2954 .vpane.files sash place 0 \
2955         [lindex [.vpane.files sash coord 0] 0] \
2956         [lindex $gm 2]
2957 unset gm
2958 }
2959
2960 # -- Key Bindings
2961 #
2962 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2963 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2964 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2965 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2966 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2967 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2968 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2969 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2970 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2971 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2972 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2973 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2974 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2975 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
2976 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
2977 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
2978 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
2979 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
2980
2981 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2982 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2983 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2984 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2985 bind $ui_diff <$M1B-Key-v> {break}
2986 bind $ui_diff <$M1B-Key-V> {break}
2987 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2988 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2989 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2990 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2991 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2992 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2993 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2994 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2995 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2996 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2997 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2998 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2999 bind $ui_diff <Button-1>   {focus %W}
3000
3001 if {[is_enabled branch]} {
3002         bind . <$M1B-Key-n> branch_create::dialog
3003         bind . <$M1B-Key-N> branch_create::dialog
3004         bind . <$M1B-Key-o> branch_checkout::dialog
3005         bind . <$M1B-Key-O> branch_checkout::dialog
3006         bind . <$M1B-Key-m> merge::dialog
3007         bind . <$M1B-Key-M> merge::dialog
3008 }
3009 if {[is_enabled transport]} {
3010         bind . <$M1B-Key-p> do_push_anywhere
3011         bind . <$M1B-Key-P> do_push_anywhere
3012 }
3013
3014 bind .   <Key-F5>     ui_do_rescan
3015 bind .   <$M1B-Key-r> ui_do_rescan
3016 bind .   <$M1B-Key-R> ui_do_rescan
3017 bind .   <$M1B-Key-s> do_signoff
3018 bind .   <$M1B-Key-S> do_signoff
3019 bind .   <$M1B-Key-t> do_add_selection
3020 bind .   <$M1B-Key-T> do_add_selection
3021 bind .   <$M1B-Key-i> do_add_all
3022 bind .   <$M1B-Key-I> do_add_all
3023 bind .   <$M1B-Key-minus> {show_less_context;break}
3024 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3025 bind .   <$M1B-Key-equal> {show_more_context;break}
3026 bind .   <$M1B-Key-plus> {show_more_context;break}
3027 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3028 bind .   <$M1B-Key-Return> do_commit
3029 foreach i [list $ui_index $ui_workdir] {
3030         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3031         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3032         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3033 }
3034 unset i
3035
3036 set file_lists($ui_index) [list]
3037 set file_lists($ui_workdir) [list]
3038
3039 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
3040 focus -force $ui_comm
3041
3042 # -- Warn the user about environmental problems.  Cygwin's Tcl
3043 #    does *not* pass its env array onto any processes it spawns.
3044 #    This means that git processes get none of our environment.
3045 #
3046 if {[is_Cygwin]} {
3047         set ignored_env 0
3048         set suggest_user {}
3049         set msg [mc "Possible environment issues exist.
3050
3051 The following environment variables are probably
3052 going to be ignored by any Git subprocess run
3053 by %s:
3054
3055 " [appname]]
3056         foreach name [array names env] {
3057                 switch -regexp -- $name {
3058                 {^GIT_INDEX_FILE$} -
3059                 {^GIT_OBJECT_DIRECTORY$} -
3060                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3061                 {^GIT_DIFF_OPTS$} -
3062                 {^GIT_EXTERNAL_DIFF$} -
3063                 {^GIT_PAGER$} -
3064                 {^GIT_TRACE$} -
3065                 {^GIT_CONFIG$} -
3066                 {^GIT_CONFIG_LOCAL$} -
3067                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3068                         append msg " - $name\n"
3069                         incr ignored_env
3070                 }
3071                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3072                         append msg " - $name\n"
3073                         incr ignored_env
3074                         set suggest_user $name
3075                 }
3076                 }
3077         }
3078         if {$ignored_env > 0} {
3079                 append msg [mc "
3080 This is due to a known issue with the
3081 Tcl binary distributed by Cygwin."]
3082
3083                 if {$suggest_user ne {}} {
3084                         append msg [mc "
3085
3086 A good replacement for %s
3087 is placing values for the user.name and
3088 user.email settings into your personal
3089 ~/.gitconfig file.
3090 " $suggest_user]
3091                 }
3092                 warn_popup $msg
3093         }
3094         unset ignored_env msg suggest_user name
3095 }
3096
3097 # -- Only initialize complex UI if we are going to stay running.
3098 #
3099 if {[is_enabled transport]} {
3100         load_all_remotes
3101
3102         set n [.mbar.remote index end]
3103         populate_push_menu
3104         populate_fetch_menu
3105         set n [expr {[.mbar.remote index end] - $n}]
3106         if {$n > 0} {
3107                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3108                 .mbar.remote insert $n separator
3109         }
3110         unset n
3111 }
3112
3113 if {[winfo exists $ui_comm]} {
3114         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3115
3116         # -- If both our backup and message files exist use the
3117         #    newer of the two files to initialize the buffer.
3118         #
3119         if {$GITGUI_BCK_exists} {
3120                 set m [gitdir GITGUI_MSG]
3121                 if {[file isfile $m]} {
3122                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3123                                 catch {file delete [gitdir GITGUI_MSG]}
3124                         } else {
3125                                 $ui_comm delete 0.0 end
3126                                 $ui_comm edit reset
3127                                 $ui_comm edit modified false
3128                                 catch {file delete [gitdir GITGUI_BCK]}
3129                                 set GITGUI_BCK_exists 0
3130                         }
3131                 }
3132                 unset m
3133         }
3134
3135         proc backup_commit_buffer {} {
3136                 global ui_comm GITGUI_BCK_exists
3137
3138                 set m [$ui_comm edit modified]
3139                 if {$m || $GITGUI_BCK_exists} {
3140                         set msg [string trim [$ui_comm get 0.0 end]]
3141                         regsub -all -line {[ \r\t]+$} $msg {} msg
3142
3143                         if {$msg eq {}} {
3144                                 if {$GITGUI_BCK_exists} {
3145                                         catch {file delete [gitdir GITGUI_BCK]}
3146                                         set GITGUI_BCK_exists 0
3147                                 }
3148                         } elseif {$m} {
3149                                 catch {
3150                                         set fd [open [gitdir GITGUI_BCK] w]
3151                                         puts -nonewline $fd $msg
3152                                         close $fd
3153                                         set GITGUI_BCK_exists 1
3154                                 }
3155                         }
3156
3157                         $ui_comm edit modified false
3158                 }
3159
3160                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3161         }
3162
3163         backup_commit_buffer
3164
3165         # -- If the user has aspell available we can drive it
3166         #    in pipe mode to spellcheck the commit message.
3167         #
3168         set spell_cmd [list |]
3169         set spell_dict [get_config gui.spellingdictionary]
3170         lappend spell_cmd aspell
3171         if {$spell_dict ne {}} {
3172                 lappend spell_cmd --master=$spell_dict
3173         }
3174         lappend spell_cmd --mode=none
3175         lappend spell_cmd --encoding=utf-8
3176         lappend spell_cmd pipe
3177         if {$spell_dict eq {none}
3178          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3179                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3180         } else {
3181                 set ui_comm_spell [spellcheck::init \
3182                         $spell_fd \
3183                         $ui_comm \
3184                         $ui_comm_ctxm \
3185                 ]
3186         }
3187         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3188 }
3189
3190 lock_index begin-read
3191 if {![winfo ismapped .]} {
3192         wm deiconify .
3193 }
3194 after 1 do_rescan
3195 if {[is_enabled multicommit]} {
3196         after 1000 hint_gc
3197 }