git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527         reshow_diff
 528         uplevel #0 $after
 529 }
 530
 531 proc prune_selection {} {
 532         global file_states selected_paths
 533
 534         foreach path [array names selected_paths] {
 535                 if {[catch {set still_here $file_states($path)}]} {
 536                         unset selected_paths($path)
 537                 }
 538         }
 539 }
 540
 541 ######################################################################
 542 ##
 543 ## diff
 544
 545 proc clear_diff {} {
 546         global ui_diff current_diff_path ui_index ui_workdir
 547
 548         $ui_diff conf -state normal
 549         $ui_diff delete 0.0 end
 550         $ui_diff conf -state disabled
 551
 552         set current_diff_path {}
 553
 554         $ui_index tag remove in_diff 0.0 end
 555         $ui_workdir tag remove in_diff 0.0 end
 556 }
 557
 558 proc reshow_diff {} {
 559         global ui_status_value file_states file_lists
 560         global current_diff_path current_diff_side
 561
 562         set p $current_diff_path
 563         if {$p eq {}
 564                 || $current_diff_side eq {}
 565                 || [catch {set s $file_states($p)}]
 566                 || [lsearch -sorted $file_lists($current_diff_side) $p] == -1} {
 567                 clear_diff
 568         } else {
 569                 show_diff $p $current_diff_side
 570         }
 571 }
 572
 573 proc handle_empty_diff {} {
 574         global current_diff_path file_states file_lists
 575
 576         set path $current_diff_path
 577         set s $file_states($path)
 578         if {[lindex $s 0] ne {_M}} return
 579
 580         info_popup "No differences detected.
 581
 582 [short_path $path] has no changes.
 583
 584 The modification date of this file was updated
 585 by another application and you currently have
 586 the Trust File Modification Timestamps option
 587 enabled, so Git did not automatically detect
 588 that there are no content differences in this
 589 file.
 590
 591 This file will now be removed from the modified
 592 files list, to prevent possible confusion.
 593 "
 594         if {[catch {exec git update-index -- $path} err]} {
 595                 error_popup "Failed to refresh index:\n\n$err"
 596         }
 597
 598         clear_diff
 599         display_file $path __
 600 }
 601
 602 proc show_diff {path w {lno {}}} {
 603         global file_states file_lists
 604         global is_3way_diff diff_active repo_config
 605         global ui_diff ui_status_value ui_index ui_workdir
 606         global current_diff_path current_diff_side
 607
 608         if {$diff_active || ![lock_index read]} return
 609
 610         clear_diff
 611         if {$w eq {} || $lno == {}} {
 612                 foreach w [array names file_lists] {
 613                         set lno [lsearch -sorted $file_lists($w) $path]
 614                         if {$lno >= 0} {
 615                                 incr lno
 616                                 break
 617                         }
 618                 }
 619         }
 620         if {$w ne {} && $lno >= 1} {
 621                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 622         }
 623
 624         set s $file_states($path)
 625         set m [lindex $s 0]
 626         set is_3way_diff 0
 627         set diff_active 1
 628         set current_diff_path $path
 629         set current_diff_side $w
 630         set ui_status_value "Loading diff of [escape_path $path]..."
 631
 632         # - Git won't give us the diff, there's nothing to compare to!
 633         #
 634         if {$m eq {_O}} {
 635                 if {[catch {
 636                                 set fd [open $path r]
 637                                 set content [read $fd]
 638                                 close $fd
 639                         } err ]} {
 640                         set diff_active 0
 641                         unlock_index
 642                         set ui_status_value "Unable to display [escape_path $path]"
 643                         error_popup "Error loading file:\n\n$err"
 644                         return
 645                 }
 646                 $ui_diff conf -state normal
 647                 $ui_diff insert end $content
 648                 $ui_diff conf -state disabled
 649                 set diff_active 0
 650                 unlock_index
 651                 set ui_status_value {Ready.}
 652                 return
 653         }
 654
 655         set cmd [list | git]
 656         if {$w eq $ui_index} {
 657                 lappend cmd diff-index
 658                 lappend cmd --cached
 659         } elseif {$w eq $ui_workdir} {
 660                 if {[string index $m 0] eq {U}} {
 661                         lappend cmd diff
 662                 } else {
 663                         lappend cmd diff-files
 664                 }
 665         }
 666
 667         lappend cmd -p
 668         lappend cmd --no-color
 669         if {$repo_config(gui.diffcontext) > 0} {
 670                 lappend cmd "-U$repo_config(gui.diffcontext)"
 671         }
 672         if {$w eq $ui_index} {
 673                 lappend cmd [PARENT]
 674         }
 675         lappend cmd --
 676         lappend cmd $path
 677
 678         if {[catch {set fd [open $cmd r]} err]} {
 679                 set diff_active 0
 680                 unlock_index
 681                 set ui_status_value "Unable to display [escape_path $path]"
 682                 error_popup "Error loading diff:\n\n$err"
 683                 return
 684         }
 685
 686         fconfigure $fd -blocking 0 -translation auto
 687         fileevent $fd readable [list read_diff $fd]
 688 }
 689
 690 proc read_diff {fd} {
 691         global ui_diff ui_status_value is_3way_diff diff_active
 692         global repo_config
 693
 694         $ui_diff conf -state normal
 695         while {[gets $fd line] >= 0} {
 696                 # -- Cleanup uninteresting diff header lines.
 697                 #
 698                 if {[string match {diff --git *}      $line]} continue
 699                 if {[string match {diff --cc *}       $line]} continue
 700                 if {[string match {diff --combined *} $line]} continue
 701                 if {[string match {--- *}             $line]} continue
 702                 if {[string match {+++ *}             $line]} continue
 703                 if {$line eq {deleted file mode 120000}} {
 704                         set line "deleted symlink"
 705                 }
 706
 707                 # -- Automatically detect if this is a 3 way diff.
 708                 #
 709                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 710
 711                 if {[string match {index *} $line]} {
 712                         set tags {}
 713                 } elseif {$is_3way_diff} {
 714                         set op [string range $line 0 1]
 715                         switch -- $op {
 716                         {  } {set tags {}}
 717                         {@@} {set tags d_@}
 718                         { +} {set tags d_s+}
 719                         { -} {set tags d_s-}
 720                         {+ } {set tags d_+s}
 721                         {- } {set tags d_-s}
 722                         {--} {set tags d_--}
 723                         {++} {
 724                                 if {[regexp {^\+\+([<>]{7} |={7})} $line _g op]} {
 725                                         set line [string replace $line 0 1 {  }]
 726                                         set tags d$op
 727                                 } else {
 728                                         set tags d_++
 729                                 }
 730                         }
 731                         default {
 732                                 puts "error: Unhandled 3 way diff marker: {$op}"
 733                                 set tags {}
 734                         }
 735                         }
 736                 } else {
 737                         set op [string index $line 0]
 738                         switch -- $op {
 739                         { } {set tags {}}
 740                         {@} {set tags d_@}
 741                         {-} {set tags d_-}
 742                         {+} {
 743                                 if {[regexp {^\+([<>]{7} |={7})} $line _g op]} {
 744                                         set line [string replace $line 0 0 { }]
 745                                         set tags d$op
 746                                 } else {
 747                                         set tags d_+
 748                                 }
 749                         }
 750                         default {
 751                                 puts "error: Unhandled 2 way diff marker: {$op}"
 752                                 set tags {}
 753                         }
 754                         }
 755                 }
 756                 $ui_diff insert end $line $tags
 757                 $ui_diff insert end "\n" $tags
 758         }
 759         $ui_diff conf -state disabled
 760
 761         if {[eof $fd]} {
 762                 close $fd
 763                 set diff_active 0
 764                 unlock_index
 765                 set ui_status_value {Ready.}
 766
 767                 if {$repo_config(gui.trustmtime) eq {true}
 768                         && [$ui_diff index end] eq {2.0}} {
 769                         handle_empty_diff
 770                 }
 771         }
 772 }
 773
 774 ######################################################################
 775 ##
 776 ## commit
 777
 778 proc load_last_commit {} {
 779         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 780
 781         if {[llength $PARENT] == 0} {
 782                 error_popup {There is nothing to amend.
 783
 784 You are about to create the initial commit.
 785 There is no commit before this to amend.
 786 }
 787                 return
 788         }
 789
 790         repository_state curType curHEAD curMERGE_HEAD
 791         if {$curType eq {merge}} {
 792                 error_popup {Cannot amend while merging.
 793
 794 You are currently in the middle of a merge that
 795 has not been fully completed.  You cannot amend
 796 the prior commit unless you first abort the
 797 current merge activity.
 798 }
 799                 return
 800         }
 801
 802         set msg {}
 803         set parents [list]
 804         if {[catch {
 805                         set fd [open "| git cat-file commit $curHEAD" r]
 806                         while {[gets $fd line] > 0} {
 807                                 if {[string match {parent *} $line]} {
 808                                         lappend parents [string range $line 7 end]
 809                                 }
 810                         }
 811                         set msg [string trim [read $fd]]
 812                         close $fd
 813                 } err]} {
 814                 error_popup "Error loading commit data for amend:\n\n$err"
 815                 return
 816         }
 817
 818         set HEAD $curHEAD
 819         set PARENT $parents
 820         set MERGE_HEAD [list]
 821         switch -- [llength $parents] {
 822         0       {set commit_type amend-initial}
 823         1       {set commit_type amend}
 824         default {set commit_type amend-merge}
 825         }
 826
 827         $ui_comm delete 0.0 end
 828         $ui_comm insert end $msg
 829         $ui_comm edit reset
 830         $ui_comm edit modified false
 831         rescan {set ui_status_value {Ready.}}
 832 }
 833
 834 proc create_new_commit {} {
 835         global commit_type ui_comm
 836
 837         set commit_type normal
 838         $ui_comm delete 0.0 end
 839         $ui_comm edit reset
 840         $ui_comm edit modified false
 841         rescan {set ui_status_value {Ready.}}
 842 }
 843
 844 set GIT_COMMITTER_IDENT {}
 845
 846 proc committer_ident {} {
 847         global GIT_COMMITTER_IDENT
 848
 849         if {$GIT_COMMITTER_IDENT eq {}} {
 850                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 851                         error_popup "Unable to obtain your identity:\n\n$err"
 852                         return {}
 853                 }
 854                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 855                         $me me GIT_COMMITTER_IDENT]} {
 856                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 857                         return {}
 858                 }
 859         }
 860
 861         return $GIT_COMMITTER_IDENT
 862 }
 863
 864 proc commit_tree {} {
 865         global HEAD commit_type file_states ui_comm repo_config
 866         global ui_status_value pch_error
 867
 868         if {![lock_index update]} return
 869         if {[committer_ident] eq {}} return
 870
 871         # -- Our in memory state should match the repository.
 872         #
 873         repository_state curType curHEAD curMERGE_HEAD
 874         if {[string match amend* $commit_type]
 875                 && $curType eq {normal}
 876                 && $curHEAD eq $HEAD} {
 877         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 878                 info_popup {Last scanned state does not match repository state.
 879
 880 Another Git program has modified this repository
 881 since the last scan.  A rescan must be performed
 882 before another commit can be created.
 883
 884 The rescan will be automatically started now.
 885 }
 886                 unlock_index
 887                 rescan {set ui_status_value {Ready.}}
 888                 return
 889         }
 890
 891         # -- At least one file should differ in the index.
 892         #
 893         set files_ready 0
 894         foreach path [array names file_states] {
 895                 switch -glob -- [lindex $file_states($path) 0] {
 896                 _? {continue}
 897                 A? -
 898                 D? -
 899                 M? {set files_ready 1}
 900                 U? {
 901                         error_popup "Unmerged files cannot be committed.
 902
 903 File [short_path $path] has merge conflicts.
 904 You must resolve them and add the file before committing.
 905 "
 906                         unlock_index
 907                         return
 908                 }
 909                 default {
 910                         error_popup "Unknown file state [lindex $s 0] detected.
 911
 912 File [short_path $path] cannot be committed by this program.
 913 "
 914                 }
 915                 }
 916         }
 917         if {!$files_ready} {
 918                 error_popup {No changes to commit.
 919
 920 You must add at least 1 file before you can commit.
 921 }
 922                 unlock_index
 923                 return
 924         }
 925
 926         # -- A message is required.
 927         #
 928         set msg [string trim [$ui_comm get 1.0 end]]
 929         if {$msg eq {}} {
 930                 error_popup {Please supply a commit message.
 931
 932 A good commit message has the following format:
 933
 934 - First line: Describe in one sentance what you did.
 935 - Second line: Blank
 936 - Remaining lines: Describe why this change is good.
 937 }
 938                 unlock_index
 939                 return
 940         }
 941
 942         # -- Run the pre-commit hook.
 943         #
 944         set pchook [gitdir hooks pre-commit]
 945
 946         # On Cygwin [file executable] might lie so we need to ask
 947         # the shell if the hook is executable.  Yes that's annoying.
 948         #
 949         if {[is_Windows] && [file isfile $pchook]} {
 950                 set pchook [list sh -c [concat \
 951                         "if test -x \"$pchook\";" \
 952                         "then exec \"$pchook\" 2>&1;" \
 953                         "fi"]]
 954         } elseif {[file executable $pchook]} {
 955                 set pchook [list $pchook |& cat]
 956         } else {
 957                 commit_writetree $curHEAD $msg
 958                 return
 959         }
 960
 961         set ui_status_value {Calling pre-commit hook...}
 962         set pch_error {}
 963         set fd_ph [open "| $pchook" r]
 964         fconfigure $fd_ph -blocking 0 -translation binary
 965         fileevent $fd_ph readable \
 966                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 967 }
 968
 969 proc commit_prehook_wait {fd_ph curHEAD msg} {
 970         global pch_error ui_status_value
 971
 972         append pch_error [read $fd_ph]
 973         fconfigure $fd_ph -blocking 1
 974         if {[eof $fd_ph]} {
 975                 if {[catch {close $fd_ph}]} {
 976                         set ui_status_value {Commit declined by pre-commit hook.}
 977                         hook_failed_popup pre-commit $pch_error
 978                         unlock_index
 979                 } else {
 980                         commit_writetree $curHEAD $msg
 981                 }
 982                 set pch_error {}
 983                 return
 984         }
 985         fconfigure $fd_ph -blocking 0
 986 }
 987
 988 proc commit_writetree {curHEAD msg} {
 989         global ui_status_value
 990
 991         set ui_status_value {Committing changes...}
 992         set fd_wt [open "| git write-tree" r]
 993         fileevent $fd_wt readable \
 994                 [list commit_committree $fd_wt $curHEAD $msg]
 995 }
 996
 997 proc commit_committree {fd_wt curHEAD msg} {
 998         global HEAD PARENT MERGE_HEAD commit_type
 999         global single_commit
1000         global ui_status_value ui_comm selected_commit_type
1001         global file_states selected_paths rescan_active
1002
1003         gets $fd_wt tree_id
1004         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1005                 error_popup "write-tree failed:\n\n$err"
1006                 set ui_status_value {Commit failed.}
1007                 unlock_index
1008                 return
1009         }
1010
1011         # -- Create the commit.
1012         #
1013         set cmd [list git commit-tree $tree_id]
1014         set parents [concat $PARENT $MERGE_HEAD]
1015         if {[llength $parents] > 0} {
1016                 foreach p $parents {
1017                         lappend cmd -p $p
1018                 }
1019         } else {
1020                 # git commit-tree writes to stderr during initial commit.
1021                 lappend cmd 2>/dev/null
1022         }
1023         lappend cmd << $msg
1024         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1025                 error_popup "commit-tree failed:\n\n$err"
1026                 set ui_status_value {Commit failed.}
1027                 unlock_index
1028                 return
1029         }
1030
1031         # -- Update the HEAD ref.
1032         #
1033         set reflogm commit
1034         if {$commit_type ne {normal}} {
1035                 append reflogm " ($commit_type)"
1036         }
1037         set i [string first "\n" $msg]
1038         if {$i >= 0} {
1039                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1040         } else {
1041                 append reflogm {: } $msg
1042         }
1043         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1044         if {[catch {eval exec $cmd} err]} {
1045                 error_popup "update-ref failed:\n\n$err"
1046                 set ui_status_value {Commit failed.}
1047                 unlock_index
1048                 return
1049         }
1050
1051         # -- Cleanup after ourselves.
1052         #
1053         catch {file delete [gitdir MERGE_HEAD]}
1054         catch {file delete [gitdir MERGE_MSG]}
1055         catch {file delete [gitdir SQUASH_MSG]}
1056         catch {file delete [gitdir GITGUI_MSG]}
1057
1058         # -- Let rerere do its thing.
1059         #
1060         if {[file isdirectory [gitdir rr-cache]]} {
1061                 catch {exec git rerere}
1062         }
1063
1064         # -- Run the post-commit hook.
1065         #
1066         set pchook [gitdir hooks post-commit]
1067         if {[is_Windows] && [file isfile $pchook]} {
1068                 set pchook [list sh -c [concat \
1069                         "if test -x \"$pchook\";" \
1070                         "then exec \"$pchook\";" \
1071                         "fi"]]
1072         } elseif {![file executable $pchook]} {
1073                 set pchook {}
1074         }
1075         if {$pchook ne {}} {
1076                 catch {exec $pchook &}
1077         }
1078
1079         $ui_comm delete 0.0 end
1080         $ui_comm edit reset
1081         $ui_comm edit modified false
1082
1083         if {$single_commit} do_quit
1084
1085         # -- Update in memory status
1086         #
1087         set selected_commit_type new
1088         set commit_type normal
1089         set HEAD $cmt_id
1090         set PARENT $cmt_id
1091         set MERGE_HEAD [list]
1092
1093         foreach path [array names file_states] {
1094                 set s $file_states($path)
1095                 set m [lindex $s 0]
1096                 switch -glob -- $m {
1097                 _O -
1098                 _M -
1099                 _D {continue}
1100                 __ -
1101                 A_ -
1102                 M_ -
1103                 D_ {
1104                         unset file_states($path)
1105                         catch {unset selected_paths($path)}
1106                 }
1107                 DO {
1108                         set file_states($path) [list _O [lindex $s 1] {} {}]
1109                 }
1110                 AM -
1111                 AD -
1112                 MM -
1113                 MD {
1114                         set file_states($path) [list \
1115                                 _[string index $m 1] \
1116                                 [lindex $s 1] \
1117                                 [lindex $s 3] \
1118                                 {}]
1119                 }
1120                 }
1121         }
1122
1123         display_all_files
1124         unlock_index
1125         reshow_diff
1126         set ui_status_value \
1127                 "Changes committed as [string range $cmt_id 0 7]."
1128 }
1129
1130 ######################################################################
1131 ##
1132 ## fetch pull push
1133
1134 proc fetch_from {remote} {
1135         set w [new_console "fetch $remote" \
1136                 "Fetching new changes from $remote"]
1137         set cmd [list git fetch]
1138         lappend cmd $remote
1139         console_exec $w $cmd
1140 }
1141
1142 proc pull_remote {remote branch} {
1143         global HEAD commit_type file_states repo_config
1144
1145         if {![lock_index update]} return
1146
1147         # -- Our in memory state should match the repository.
1148         #
1149         repository_state curType curHEAD curMERGE_HEAD
1150         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1151                 info_popup {Last scanned state does not match repository state.
1152
1153 Another Git program has modified this repository
1154 since the last scan.  A rescan must be performed
1155 before a pull operation can be started.
1156
1157 The rescan will be automatically started now.
1158 }
1159                 unlock_index
1160                 rescan {set ui_status_value {Ready.}}
1161                 return
1162         }
1163
1164         # -- No differences should exist before a pull.
1165         #
1166         if {[array size file_states] != 0} {
1167                 error_popup {Uncommitted but modified files are present.
1168
1169 You should not perform a pull with unmodified
1170 files in your working directory as Git will be
1171 unable to recover from an incorrect merge.
1172
1173 You should commit or revert all changes before
1174 starting a pull operation.
1175 }
1176                 unlock_index
1177                 return
1178         }
1179
1180         set w [new_console "pull $remote $branch" \
1181                 "Pulling new changes from branch $branch in $remote"]
1182         set cmd [list git pull]
1183         if {$repo_config(gui.pullsummary) eq {false}} {
1184                 lappend cmd --no-summary
1185         }
1186         lappend cmd $remote
1187         lappend cmd $branch
1188         console_exec $w $cmd [list post_pull_remote $remote $branch]
1189 }
1190
1191 proc post_pull_remote {remote branch success} {
1192         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1193         global ui_status_value
1194
1195         unlock_index
1196         if {$success} {
1197                 repository_state commit_type HEAD MERGE_HEAD
1198                 set PARENT $HEAD
1199                 set selected_commit_type new
1200                 set ui_status_value "Pulling $branch from $remote complete."
1201         } else {
1202                 rescan [list set ui_status_value \
1203                         "Conflicts detected while pulling $branch from $remote."]
1204         }
1205 }
1206
1207 proc push_to {remote} {
1208         set w [new_console "push $remote" \
1209                 "Pushing changes to $remote"]
1210         set cmd [list git push]
1211         lappend cmd $remote
1212         console_exec $w $cmd
1213 }
1214
1215 ######################################################################
1216 ##
1217 ## ui helpers
1218
1219 proc mapicon {w state path} {
1220         global all_icons
1221
1222         if {[catch {set r $all_icons($state$w)}]} {
1223                 puts "error: no icon for $w state={$state} $path"
1224                 return file_plain
1225         }
1226         return $r
1227 }
1228
1229 proc mapdesc {state path} {
1230         global all_descs
1231
1232         if {[catch {set r $all_descs($state)}]} {
1233                 puts "error: no desc for state={$state} $path"
1234                 return $state
1235         }
1236         return $r
1237 }
1238
1239 proc escape_path {path} {
1240         regsub -all "\n" $path "\\n" path
1241         return $path
1242 }
1243
1244 proc short_path {path} {
1245         return [escape_path [lindex [file split $path] end]]
1246 }
1247
1248 set next_icon_id 0
1249 set null_sha1 [string repeat 0 40]
1250
1251 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1252         global file_states next_icon_id null_sha1
1253
1254         set s0 [string index $new_state 0]
1255         set s1 [string index $new_state 1]
1256
1257         if {[catch {set info $file_states($path)}]} {
1258                 set state __
1259                 set icon n[incr next_icon_id]
1260         } else {
1261                 set state [lindex $info 0]
1262                 set icon [lindex $info 1]
1263                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1264                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1265         }
1266
1267         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1268         elseif {$s0 eq {_}} {set s0 _}
1269
1270         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1271         elseif {$s1 eq {_}} {set s1 _}
1272
1273         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1274                 set head_info [list 0 $null_sha1]
1275         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1276                 && $head_info eq {}} {
1277                 set head_info $index_info
1278         }
1279
1280         set file_states($path) [list $s0$s1 $icon \
1281                 $head_info $index_info \
1282                 ]
1283         return $state
1284 }
1285
1286 proc display_file_helper {w path icon_name old_m new_m} {
1287         global file_lists
1288
1289         if {$new_m eq {_}} {
1290                 set lno [lsearch -sorted $file_lists($w) $path]
1291                 if {$lno >= 0} {
1292                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1293                         incr lno
1294                         $w conf -state normal
1295                         $w delete $lno.0 [expr {$lno + 1}].0
1296                         $w conf -state disabled
1297                 }
1298         } elseif {$old_m eq {_} && $new_m ne {_}} {
1299                 lappend file_lists($w) $path
1300                 set file_lists($w) [lsort -unique $file_lists($w)]
1301                 set lno [lsearch -sorted $file_lists($w) $path]
1302                 incr lno
1303                 $w conf -state normal
1304                 $w image create $lno.0 \
1305                         -align center -padx 5 -pady 1 \
1306                         -name $icon_name \
1307                         -image [mapicon $w $new_m $path]
1308                 $w insert $lno.1 "[escape_path $path]\n"
1309                 $w conf -state disabled
1310         } elseif {$old_m ne $new_m} {
1311                 $w conf -state normal
1312                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1313                 $w conf -state disabled
1314         }
1315 }
1316
1317 proc display_file {path state} {
1318         global file_states selected_paths
1319         global ui_index ui_workdir
1320
1321         set old_m [merge_state $path $state]
1322         set s $file_states($path)
1323         set new_m [lindex $s 0]
1324         set icon_name [lindex $s 1]
1325
1326         set o [string index $old_m 0]
1327         set n [string index $new_m 0]
1328         if {$o eq {U}} {
1329                 set o _
1330         }
1331         if {$n eq {U}} {
1332                 set n _
1333         }
1334         display_file_helper     $ui_index $path $icon_name $o $n
1335
1336         if {[string index $old_m 0] eq {U}} {
1337                 set o U
1338         } else {
1339                 set o [string index $old_m 1]
1340         }
1341         if {[string index $new_m 0] eq {U}} {
1342                 set n U
1343         } else {
1344                 set n [string index $new_m 1]
1345         }
1346         display_file_helper     $ui_workdir $path $icon_name $o $n
1347
1348         if {$new_m eq {__}} {
1349                 unset file_states($path)
1350                 catch {unset selected_paths($path)}
1351         }
1352 }
1353
1354 proc display_all_files_helper {w path icon_name m} {
1355         global file_lists
1356
1357         lappend file_lists($w) $path
1358         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1359         $w image create end \
1360                 -align center -padx 5 -pady 1 \
1361                 -name $icon_name \
1362                 -image [mapicon $w $m $path]
1363         $w insert end "[escape_path $path]\n"
1364 }
1365
1366 proc display_all_files {} {
1367         global ui_index ui_workdir
1368         global file_states file_lists
1369         global last_clicked
1370
1371         $ui_index conf -state normal
1372         $ui_workdir conf -state normal
1373
1374         $ui_index delete 0.0 end
1375         $ui_workdir delete 0.0 end
1376         set last_clicked {}
1377
1378         set file_lists($ui_index) [list]
1379         set file_lists($ui_workdir) [list]
1380
1381         foreach path [lsort [array names file_states]] {
1382                 set s $file_states($path)
1383                 set m [lindex $s 0]
1384                 set icon_name [lindex $s 1]
1385
1386                 set s [string index $m 0]
1387                 if {$s ne {U} && $s ne {_}} {
1388                         display_all_files_helper $ui_index $path \
1389                                 $icon_name $s
1390                 }
1391
1392                 if {[string index $m 0] eq {U}} {
1393                         set s U
1394                 } else {
1395                         set s [string index $m 1]
1396                 }
1397                 if {$s ne {_}} {
1398                         display_all_files_helper $ui_workdir $path \
1399                                 $icon_name $s
1400                 }
1401         }
1402
1403         $ui_index conf -state disabled
1404         $ui_workdir conf -state disabled
1405 }
1406
1407 proc update_indexinfo {msg pathList after} {
1408         global update_index_cp ui_status_value
1409
1410         if {![lock_index update]} return
1411
1412         set update_index_cp 0
1413         set pathList [lsort $pathList]
1414         set totalCnt [llength $pathList]
1415         set batch [expr {int($totalCnt * .01) + 1}]
1416         if {$batch > 25} {set batch 25}
1417
1418         set ui_status_value [format \
1419                 "$msg... %i/%i files (%.2f%%)" \
1420                 $update_index_cp \
1421                 $totalCnt \
1422                 0.0]
1423         set fd [open "| git update-index -z --index-info" w]
1424         fconfigure $fd \
1425                 -blocking 0 \
1426                 -buffering full \
1427                 -buffersize 512 \
1428                 -translation binary
1429         fileevent $fd writable [list \
1430                 write_update_indexinfo \
1431                 $fd \
1432                 $pathList \
1433                 $totalCnt \
1434                 $batch \
1435                 $msg \
1436                 $after \
1437                 ]
1438 }
1439
1440 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1441         global update_index_cp ui_status_value
1442         global file_states current_diff_path
1443
1444         if {$update_index_cp >= $totalCnt} {
1445                 close $fd
1446                 unlock_index
1447                 uplevel #0 $after
1448                 return
1449         }
1450
1451         for {set i $batch} \
1452                 {$update_index_cp < $totalCnt && $i > 0} \
1453                 {incr i -1} {
1454                 set path [lindex $pathList $update_index_cp]
1455                 incr update_index_cp
1456
1457                 set s $file_states($path)
1458                 switch -glob -- [lindex $s 0] {
1459                 A? {set new _O}
1460                 M? {set new _M}
1461                 D_ {set new _D}
1462                 D? {set new _?}
1463                 ?? {continue}
1464                 }
1465                 set info [lindex $s 2]
1466                 if {$info eq {}} continue
1467
1468                 puts -nonewline $fd "$info\t$path\0"
1469                 display_file $path $new
1470         }
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1477 }
1478
1479 proc update_index {msg pathList after} {
1480         global update_index_cp ui_status_value
1481
1482         if {![lock_index update]} return
1483
1484         set update_index_cp 0
1485         set pathList [lsort $pathList]
1486         set totalCnt [llength $pathList]
1487         set batch [expr {int($totalCnt * .01) + 1}]
1488         if {$batch > 25} {set batch 25}
1489
1490         set ui_status_value [format \
1491                 "$msg... %i/%i files (%.2f%%)" \
1492                 $update_index_cp \
1493                 $totalCnt \
1494                 0.0]
1495         set fd [open "| git update-index --add --remove -z --stdin" w]
1496         fconfigure $fd \
1497                 -blocking 0 \
1498                 -buffering full \
1499                 -buffersize 512 \
1500                 -translation binary
1501         fileevent $fd writable [list \
1502                 write_update_index \
1503                 $fd \
1504                 $pathList \
1505                 $totalCnt \
1506                 $batch \
1507                 $msg \
1508                 $after \
1509                 ]
1510 }
1511
1512 proc write_update_index {fd pathList totalCnt batch msg after} {
1513         global update_index_cp ui_status_value
1514         global file_states current_diff_path
1515
1516         if {$update_index_cp >= $totalCnt} {
1517                 close $fd
1518                 unlock_index
1519                 uplevel #0 $after
1520                 return
1521         }
1522
1523         for {set i $batch} \
1524                 {$update_index_cp < $totalCnt && $i > 0} \
1525                 {incr i -1} {
1526                 set path [lindex $pathList $update_index_cp]
1527                 incr update_index_cp
1528
1529                 switch -glob -- [lindex $file_states($path) 0] {
1530                 AD {set new __}
1531                 ?D {set new D_}
1532                 _O -
1533                 AM {set new A_}
1534                 U? {
1535                         if {[file exists $path]} {
1536                                 set new M_
1537                         } else {
1538                                 set new D_
1539                         }
1540                 }
1541                 ?M {set new M_}
1542                 ?? {continue}
1543                 }
1544                 puts -nonewline $fd "$path\0"
1545                 display_file $path $new
1546         }
1547
1548         set ui_status_value [format \
1549                 "$msg... %i/%i files (%.2f%%)" \
1550                 $update_index_cp \
1551                 $totalCnt \
1552                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1553 }
1554
1555 proc checkout_index {msg pathList after} {
1556         global update_index_cp ui_status_value
1557
1558         if {![lock_index update]} return
1559
1560         set update_index_cp 0
1561         set pathList [lsort $pathList]
1562         set totalCnt [llength $pathList]
1563         set batch [expr {int($totalCnt * .01) + 1}]
1564         if {$batch > 25} {set batch 25}
1565
1566         set ui_status_value [format \
1567                 "$msg... %i/%i files (%.2f%%)" \
1568                 $update_index_cp \
1569                 $totalCnt \
1570                 0.0]
1571         set cmd [list git checkout-index]
1572         lappend cmd --index
1573         lappend cmd --quiet
1574         lappend cmd --force
1575         lappend cmd -z
1576         lappend cmd --stdin
1577         set fd [open "| $cmd " w]
1578         fconfigure $fd \
1579                 -blocking 0 \
1580                 -buffering full \
1581                 -buffersize 512 \
1582                 -translation binary
1583         fileevent $fd writable [list \
1584                 write_checkout_index \
1585                 $fd \
1586                 $pathList \
1587                 $totalCnt \
1588                 $batch \
1589                 $msg \
1590                 $after \
1591                 ]
1592 }
1593
1594 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1595         global update_index_cp ui_status_value
1596         global file_states current_diff_path
1597
1598         if {$update_index_cp >= $totalCnt} {
1599                 close $fd
1600                 unlock_index
1601                 uplevel #0 $after
1602                 return
1603         }
1604
1605         for {set i $batch} \
1606                 {$update_index_cp < $totalCnt && $i > 0} \
1607                 {incr i -1} {
1608                 set path [lindex $pathList $update_index_cp]
1609                 incr update_index_cp
1610                 switch -glob -- [lindex $file_states($path) 0] {
1611                 U? {continue}
1612                 ?M -
1613                 ?D {
1614                         puts -nonewline $fd "$path\0"
1615                         display_file $path ?_
1616                 }
1617                 }
1618         }
1619
1620         set ui_status_value [format \
1621                 "$msg... %i/%i files (%.2f%%)" \
1622                 $update_index_cp \
1623                 $totalCnt \
1624                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1625 }
1626
1627 ######################################################################
1628 ##
1629 ## branch management
1630
1631 proc load_all_heads {} {
1632         global all_heads tracking_branches
1633
1634         set all_heads [list]
1635         set cmd [list git for-each-ref]
1636         lappend cmd --format=%(refname)
1637         lappend cmd refs/heads
1638         set fd [open "| $cmd" r]
1639         while {[gets $fd line] > 0} {
1640                 if {![catch {set info $tracking_branches($line)}]} continue
1641                 if {![regsub ^refs/heads/ $line {} name]} continue
1642                 lappend all_heads $name
1643         }
1644         close $fd
1645
1646         set all_heads [lsort $all_heads]
1647 }
1648
1649 proc populate_branch_menu {} {
1650         global all_heads disable_on_lock
1651
1652         set m .mbar.branch
1653         set last [$m index last]
1654         for {set i 0} {$i <= $last} {incr i} {
1655                 if {[$m type $i] eq {separator}} {
1656                         $m delete $i last
1657                         set new_dol [list]
1658                         foreach a $disable_on_lock {
1659                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1660                                         lappend new_dol $a
1661                                 }
1662                         }
1663                         set disable_on_lock $new_dol
1664                         break
1665                 }
1666         }
1667
1668         $m add separator
1669         foreach b $all_heads {
1670                 $m add radiobutton \
1671                         -label $b \
1672                         -command [list switch_branch $b] \
1673                         -variable current_branch \
1674                         -value $b \
1675                         -font font_ui
1676                 lappend disable_on_lock \
1677                         [list $m entryconf [$m index last] -state]
1678         }
1679 }
1680
1681 proc do_create_branch_action {w} {
1682         global all_heads null_sha1
1683         global create_branch_checkout create_branch_revtype
1684         global create_branch_head create_branch_trackinghead
1685
1686         set newbranch [string trim [$w.desc.name_t get 0.0 end]]
1687         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1688                 tk_messageBox \
1689                         -icon error \
1690                         -type ok \
1691                         -title [wm title $w] \
1692                         -parent $w \
1693                         -message "Branch '$newbranch' already exists."
1694                 focus $w.desc.name_t
1695                 return
1696         }
1697         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1698                 tk_messageBox \
1699                         -icon error \
1700                         -type ok \
1701                         -title [wm title $w] \
1702                         -parent $w \
1703                         -message "We do not like '$newbranch' as a branch name."
1704                 focus $w.desc.name_t
1705                 return
1706         }
1707
1708         set rev {}
1709         switch -- $create_branch_revtype {
1710         head {set rev $create_branch_head}
1711         tracking {set rev $create_branch_trackinghead}
1712         expression {set rev [string trim [$w.from.exp_t get 0.0 end]]}
1713         }
1714         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1715                 tk_messageBox \
1716                         -icon error \
1717                         -type ok \
1718                         -title [wm title $w] \
1719                         -parent $w \
1720                         -message "Invalid starting revision: $rev"
1721                 return
1722         }
1723         set cmd [list git update-ref]
1724         lappend cmd -m
1725         lappend cmd "branch: Created from $rev"
1726         lappend cmd "refs/heads/$newbranch"
1727         lappend cmd $cmt
1728         lappend cmd $null_sha1
1729         if {[catch {eval exec $cmd} err]} {
1730                 tk_messageBox \
1731                         -icon error \
1732                         -type ok \
1733                         -title [wm title $w] \
1734                         -parent $w \
1735                         -message "Failed to create '$newbranch'.\n\n$err"
1736                 return
1737         }
1738
1739         lappend all_heads $newbranch
1740         set all_heads [lsort $all_heads]
1741         populate_branch_menu
1742         destroy $w
1743         if {$create_branch_checkout} {
1744                 switch_branch $newbranch
1745         }
1746 }
1747
1748 proc do_create_branch {} {
1749         global all_heads current_branch tracking_branches
1750         global create_branch_checkout create_branch_revtype
1751         global create_branch_head create_branch_trackinghead
1752
1753         set create_branch_checkout 1
1754         set create_branch_revtype head
1755         set create_branch_head $current_branch
1756         set create_branch_trackinghead {}
1757
1758         set w .branch_editor
1759         toplevel $w
1760         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1761
1762         label $w.header -text {Create New Branch} \
1763                 -font font_uibold
1764         pack $w.header -side top -fill x
1765
1766         frame $w.buttons
1767         button $w.buttons.create -text Create \
1768                 -font font_ui \
1769                 -default active \
1770                 -command [list do_create_branch_action $w]
1771         pack $w.buttons.create -side right
1772         button $w.buttons.cancel -text {Cancel} \
1773                 -font font_ui \
1774                 -command [list destroy $w]
1775         pack $w.buttons.cancel -side right -padx 5
1776         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1777
1778         labelframe $w.desc \
1779                 -text {Branch Description} \
1780                 -font font_ui
1781         label $w.desc.name_l -text {Name:} -font font_ui
1782         text $w.desc.name_t \
1783                 -borderwidth 1 \
1784                 -relief sunken \
1785                 -height 1 \
1786                 -width 40 \
1787                 -font font_ui
1788         grid $w.desc.name_l $w.desc.name_t -stick we -padx {0 5}
1789         bind $w.desc.name_t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1790         bind $w.desc.name_t <Key-Tab> "focus $w.from.exp_t;break"
1791         bind $w.desc.name_t <Key-Return> "do_create_branch_action $w;break"
1792         bind $w.desc.name_t <Key> {
1793                 if {{%K} ne {BackSpace}
1794                         && {%K} ne {Tab}
1795                         && {%K} ne {Escape}
1796                         && {%K} ne {Return}} {
1797                         if {%k <= 32} break
1798                         if {[string first %A {~^:?*[}] >= 0} break
1799                 }
1800         }
1801         grid columnconfigure $w.desc 1 -weight 1
1802         pack $w.desc -anchor nw -fill x -pady 5 -padx 5
1803
1804         set all_trackings [list]
1805         foreach b [array names tracking_branches] {
1806                 regsub ^refs/(heads|remotes)/ $b {} b
1807                 lappend all_trackings $b
1808         }
1809         set all_trackings [lsort -unique $all_trackings]
1810         if {$all_trackings ne {}} {
1811                 set create_branch_trackinghead [lindex $all_trackings 0]
1812         }
1813
1814         labelframe $w.from \
1815                 -text {Starting Revision} \
1816                 -font font_ui
1817         radiobutton $w.from.head_r \
1818                 -text {Local Branch:} \
1819                 -value head \
1820                 -variable create_branch_revtype \
1821                 -font font_ui
1822         eval tk_optionMenu $w.from.head_m create_branch_head $all_heads
1823         grid $w.from.head_r $w.from.head_m -sticky w
1824         radiobutton $w.from.tracking_r \
1825                 -text {Tracking Branch:} \
1826                 -value tracking \
1827                 -variable create_branch_revtype \
1828                 -font font_ui
1829         eval tk_optionMenu $w.from.tracking_m \
1830                 create_branch_trackinghead \
1831                 $all_trackings
1832         grid $w.from.tracking_r $w.from.tracking_m -sticky w
1833         radiobutton $w.from.exp_r \
1834                 -text {Revision Expression:} \
1835                 -value expression \
1836                 -variable create_branch_revtype \
1837                 -font font_ui
1838         text $w.from.exp_t \
1839                 -borderwidth 1 \
1840                 -relief sunken \
1841                 -height 1 \
1842                 -width 50 \
1843                 -font font_ui
1844         grid $w.from.exp_r $w.from.exp_t -stick we -padx {0 5}
1845         bind $w.from.exp_t <Shift-Key-Tab> "focus $w.desc.name_t;break"
1846         bind $w.from.exp_t <Key-Tab> "focus $w.postActions.checkout;break"
1847         bind $w.from.exp_t <Key-Return> "do_create_branch_action $w;break"
1848         grid columnconfigure $w.from 1 -weight 1
1849         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1850
1851         labelframe $w.postActions \
1852                 -text {Post Creation Actions} \
1853                 -font font_ui
1854         checkbutton $w.postActions.checkout \
1855                 -text {Checkout after creation} \
1856                 -variable create_branch_checkout \
1857                 -font font_ui
1858         pack $w.postActions.checkout -anchor nw
1859         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1860
1861         bind $w <Visibility> "grab $w; focus $w.desc.name_t"
1862         bind $w <Key-Escape> "destroy $w"
1863         bind $w <Key-Return> "do_create_branch_action $w;break"
1864         wm title $w "[appname] ([reponame]): Create Branch"
1865         tkwait window $w
1866 }
1867
1868 proc do_delete_branch_action {w} {
1869         global all_heads
1870         global delete_branch_checkhead delete_branch_head
1871
1872         set to_delete [list]
1873         set not_merged [list]
1874         foreach i [$w.list.l curselection] {
1875                 set b [$w.list.l get $i]
1876                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1877                 if {$delete_branch_checkhead} {
1878                         if {$b eq $delete_branch_head} continue
1879                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1880                         if {$o ne $m} {
1881                                 lappend not_merged $b
1882                                 continue
1883                         }
1884                 }
1885                 lappend to_delete [list $b $o]
1886         }
1887         if {$not_merged ne {}} {
1888                 set msg "The following branches are not completely merged into $delete_branch_head:
1889
1890  - [join $not_merged "\n - "]"
1891                 tk_messageBox \
1892                         -icon info \
1893                         -type ok \
1894                         -title [wm title $w] \
1895                         -parent $w \
1896                         -message $msg
1897         }
1898         if {$to_delete eq {}} return
1899         if {!$delete_branch_checkhead} {
1900                 set msg {Recovering deleted branches is difficult.
1901
1902 Delete the selected branches?}
1903                 if {[tk_messageBox \
1904                         -icon warning \
1905                         -type yesno \
1906                         -title [wm title $w] \
1907                         -parent $w \
1908                         -message $msg] ne yes} {
1909                         return
1910                 }
1911         }
1912
1913         set failed {}
1914         foreach i $to_delete {
1915                 set b [lindex $i 0]
1916                 set o [lindex $i 1]
1917                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1918                         append failed " - $b: $err\n"
1919                 } else {
1920                         set x [lsearch -sorted $all_heads $b]
1921                         if {$x >= 0} {
1922                                 set all_heads [lreplace $all_heads $x $x]
1923                         }
1924                 }
1925         }
1926
1927         if {$failed ne {}} {
1928                 tk_messageBox \
1929                         -icon error \
1930                         -type ok \
1931                         -title [wm title $w] \
1932                         -parent $w \
1933                         -message "Failed to delete branches:\n$failed"
1934         }
1935
1936         set all_heads [lsort $all_heads]
1937         populate_branch_menu
1938         destroy $w
1939 }
1940
1941 proc do_delete_branch {} {
1942         global all_heads tracking_branches current_branch
1943         global delete_branch_checkhead delete_branch_head
1944
1945         set delete_branch_checkhead 1
1946         set delete_branch_head $current_branch
1947
1948         set w .branch_editor
1949         toplevel $w
1950         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1951
1952         label $w.header -text {Delete Local Branch} \
1953                 -font font_uibold
1954         pack $w.header -side top -fill x
1955
1956         frame $w.buttons
1957         button $w.buttons.create -text Delete \
1958                 -font font_ui \
1959                 -command [list do_delete_branch_action $w]
1960         pack $w.buttons.create -side right
1961         button $w.buttons.cancel -text {Cancel} \
1962                 -font font_ui \
1963                 -command [list destroy $w]
1964         pack $w.buttons.cancel -side right -padx 5
1965         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1966
1967         labelframe $w.list \
1968                 -text {Local Branches} \
1969                 -font font_ui
1970         listbox $w.list.l \
1971                 -height 10 \
1972                 -width 50 \
1973                 -selectmode extended \
1974                 -font font_ui
1975         foreach h $all_heads {
1976                 if {$h ne $current_branch} {
1977                         $w.list.l insert end $h
1978                 }
1979         }
1980         pack $w.list.l -fill both -pady 5 -padx 5
1981         pack $w.list -fill both -pady 5 -padx 5
1982
1983         set all_trackings [list]
1984         foreach b [array names tracking_branches] {
1985                 regsub ^refs/(heads|remotes)/ $b {} b
1986                 lappend all_trackings $b
1987         }
1988
1989         labelframe $w.validate \
1990                 -text {Only Delete If} \
1991                 -font font_ui
1992         frame $w.validate.head
1993         checkbutton $w.validate.head.r \
1994                 -text {Already Merged Into:} \
1995                 -variable delete_branch_checkhead \
1996                 -font font_ui
1997         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1998                 $all_heads \
1999                 [lsort -unique $all_trackings]
2000         pack $w.validate.head.r -side left
2001         pack $w.validate.head.m -side left
2002         pack $w.validate.head -padx 5 -fill x -expand 1
2003         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
2004
2005         bind $w <Visibility> "grab $w; focus $w"
2006         bind $w <Key-Escape> "destroy $w"
2007         wm title $w "[appname] ([reponame]): Delete Branch"
2008         tkwait window $w
2009 }
2010
2011 proc switch_branch {b} {
2012         global HEAD commit_type file_states current_branch
2013         global selected_commit_type ui_comm
2014
2015         if {![lock_index switch]} return
2016
2017         # -- Backup the selected branch (repository_state resets it)
2018         #
2019         set new_branch $current_branch
2020
2021         # -- Our in memory state should match the repository.
2022         #
2023         repository_state curType curHEAD curMERGE_HEAD
2024         if {[string match amend* $commit_type]
2025                 && $curType eq {normal}
2026                 && $curHEAD eq $HEAD} {
2027         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2028                 info_popup {Last scanned state does not match repository state.
2029
2030 Another Git program has modified this repository
2031 since the last scan.  A rescan must be performed
2032 before the current branch can be changed.
2033
2034 The rescan will be automatically started now.
2035 }
2036                 unlock_index
2037                 rescan {set ui_status_value {Ready.}}
2038                 return
2039         }
2040
2041         # -- Toss the message buffer if we are in amend mode.
2042         #
2043         if {[string match amend* $curType]} {
2044                 $ui_comm delete 0.0 end
2045                 $ui_comm edit reset
2046                 $ui_comm edit modified false
2047         }
2048
2049         set selected_commit_type new
2050         set current_branch $new_branch
2051
2052         unlock_index
2053         error "NOT FINISHED"
2054 }
2055
2056 ######################################################################
2057 ##
2058 ## remote management
2059
2060 proc load_all_remotes {} {
2061         global repo_config
2062         global all_remotes tracking_branches
2063
2064         set all_remotes [list]
2065         array unset tracking_branches
2066
2067         set rm_dir [gitdir remotes]
2068         if {[file isdirectory $rm_dir]} {
2069                 set all_remotes [glob \
2070                         -types f \
2071                         -tails \
2072                         -nocomplain \
2073                         -directory $rm_dir *]
2074
2075                 foreach name $all_remotes {
2076                         catch {
2077                                 set fd [open [file join $rm_dir $name] r]
2078                                 while {[gets $fd line] >= 0} {
2079                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2080                                                 $line line src dst]} continue
2081                                         if {![regexp ^refs/ $dst]} {
2082                                                 set dst "refs/heads/$dst"
2083                                         }
2084                                         set tracking_branches($dst) [list $name $src]
2085                                 }
2086                                 close $fd
2087                         }
2088                 }
2089         }
2090
2091         foreach line [array names repo_config remote.*.url] {
2092                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2093                 lappend all_remotes $name
2094
2095                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2096                         set fl {}
2097                 }
2098                 foreach line $fl {
2099                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2100                         if {![regexp ^refs/ $dst]} {
2101                                 set dst "refs/heads/$dst"
2102                         }
2103                         set tracking_branches($dst) [list $name $src]
2104                 }
2105         }
2106
2107         set all_remotes [lsort -unique $all_remotes]
2108 }
2109
2110 proc populate_fetch_menu {m} {
2111         global all_remotes repo_config
2112
2113         foreach r $all_remotes {
2114                 set enable 0
2115                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2116                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2117                                 set enable 1
2118                         }
2119                 } else {
2120                         catch {
2121                                 set fd [open [gitdir remotes $r] r]
2122                                 while {[gets $fd n] >= 0} {
2123                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2124                                                 set enable 1
2125                                                 break
2126                                         }
2127                                 }
2128                                 close $fd
2129                         }
2130                 }
2131
2132                 if {$enable} {
2133                         $m add command \
2134                                 -label "Fetch from $r..." \
2135                                 -command [list fetch_from $r] \
2136                                 -font font_ui
2137                 }
2138         }
2139 }
2140
2141 proc populate_push_menu {m} {
2142         global all_remotes repo_config
2143
2144         foreach r $all_remotes {
2145                 set enable 0
2146                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2147                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2148                                 set enable 1
2149                         }
2150                 } else {
2151                         catch {
2152                                 set fd [open [gitdir remotes $r] r]
2153                                 while {[gets $fd n] >= 0} {
2154                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2155                                                 set enable 1
2156                                                 break
2157                                         }
2158                                 }
2159                                 close $fd
2160                         }
2161                 }
2162
2163                 if {$enable} {
2164                         $m add command \
2165                                 -label "Push to $r..." \
2166                                 -command [list push_to $r] \
2167                                 -font font_ui
2168                 }
2169         }
2170 }
2171
2172 proc populate_pull_menu {m} {
2173         global repo_config all_remotes disable_on_lock
2174
2175         foreach remote $all_remotes {
2176                 set rb_list [list]
2177                 if {[array get repo_config remote.$remote.url] ne {}} {
2178                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2179                                 foreach line $repo_config(remote.$remote.fetch) {
2180                                         if {[regexp {^([^:]+):} $line line rb]} {
2181                                                 lappend rb_list $rb
2182                                         }
2183                                 }
2184                         }
2185                 } else {
2186                         catch {
2187                                 set fd [open [gitdir remotes $remote] r]
2188                                 while {[gets $fd line] >= 0} {
2189                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2190                                                 lappend rb_list $rb
2191                                         }
2192                                 }
2193                                 close $fd
2194                         }
2195                 }
2196
2197                 foreach rb $rb_list {
2198                         regsub ^refs/heads/ $rb {} rb_short
2199                         $m add command \
2200                                 -label "Branch $rb_short from $remote..." \
2201                                 -command [list pull_remote $remote $rb] \
2202                                 -font font_ui
2203                         lappend disable_on_lock \
2204                                 [list $m entryconf [$m index last] -state]
2205                 }
2206         }
2207 }
2208
2209 ######################################################################
2210 ##
2211 ## icons
2212
2213 set filemask {
2214 #define mask_width 14
2215 #define mask_height 15
2216 static unsigned char mask_bits[] = {
2217    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2218    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2219    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2220 }
2221
2222 image create bitmap file_plain -background white -foreground black -data {
2223 #define plain_width 14
2224 #define plain_height 15
2225 static unsigned char plain_bits[] = {
2226    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2227    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2228    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2229 } -maskdata $filemask
2230
2231 image create bitmap file_mod -background white -foreground blue -data {
2232 #define mod_width 14
2233 #define mod_height 15
2234 static unsigned char mod_bits[] = {
2235    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2236    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2237    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2238 } -maskdata $filemask
2239
2240 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2241 #define file_fulltick_width 14
2242 #define file_fulltick_height 15
2243 static unsigned char file_fulltick_bits[] = {
2244    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2245    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2246    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2247 } -maskdata $filemask
2248
2249 image create bitmap file_parttick -background white -foreground "#005050" -data {
2250 #define parttick_width 14
2251 #define parttick_height 15
2252 static unsigned char parttick_bits[] = {
2253    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2254    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2255    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2256 } -maskdata $filemask
2257
2258 image create bitmap file_question -background white -foreground black -data {
2259 #define file_question_width 14
2260 #define file_question_height 15
2261 static unsigned char file_question_bits[] = {
2262    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2263    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2264    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2265 } -maskdata $filemask
2266
2267 image create bitmap file_removed -background white -foreground red -data {
2268 #define file_removed_width 14
2269 #define file_removed_height 15
2270 static unsigned char file_removed_bits[] = {
2271    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2272    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2273    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2274 } -maskdata $filemask
2275
2276 image create bitmap file_merge -background white -foreground blue -data {
2277 #define file_merge_width 14
2278 #define file_merge_height 15
2279 static unsigned char file_merge_bits[] = {
2280    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2281    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2282    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2283 } -maskdata $filemask
2284
2285 set ui_index .vpane.files.index.list
2286 set ui_workdir .vpane.files.workdir.list
2287
2288 set all_icons(_$ui_index)   file_plain
2289 set all_icons(A$ui_index)   file_fulltick
2290 set all_icons(M$ui_index)   file_fulltick
2291 set all_icons(D$ui_index)   file_removed
2292 set all_icons(U$ui_index)   file_merge
2293
2294 set all_icons(_$ui_workdir) file_plain
2295 set all_icons(M$ui_workdir) file_mod
2296 set all_icons(D$ui_workdir) file_question
2297 set all_icons(U$ui_workdir) file_merge
2298 set all_icons(O$ui_workdir) file_plain
2299
2300 set max_status_desc 0
2301 foreach i {
2302                 {__ "Unmodified"}
2303
2304                 {_M "Modified, not staged"}
2305                 {M_ "Staged for commit"}
2306                 {MM "Portions staged for commit"}
2307                 {MD "Staged for commit, missing"}
2308
2309                 {_O "Untracked, not staged"}
2310                 {A_ "Staged for commit"}
2311                 {AM "Portions staged for commit"}
2312                 {AD "Staged for commit, missing"}
2313
2314                 {_D "Missing"}
2315                 {D_ "Staged for removal"}
2316                 {DO "Staged for removal, still present"}
2317
2318                 {U_ "Requires merge resolution"}
2319                 {UU "Requires merge resolution"}
2320                 {UM "Requires merge resolution"}
2321                 {UD "Requires merge resolution"}
2322         } {
2323         if {$max_status_desc < [string length [lindex $i 1]]} {
2324                 set max_status_desc [string length [lindex $i 1]]
2325         }
2326         set all_descs([lindex $i 0]) [lindex $i 1]
2327 }
2328 unset i
2329
2330 ######################################################################
2331 ##
2332 ## util
2333
2334 proc is_MacOSX {} {
2335         global tcl_platform tk_library
2336         if {[tk windowingsystem] eq {aqua}} {
2337                 return 1
2338         }
2339         return 0
2340 }
2341
2342 proc is_Windows {} {
2343         global tcl_platform
2344         if {$tcl_platform(platform) eq {windows}} {
2345                 return 1
2346         }
2347         return 0
2348 }
2349
2350 proc bind_button3 {w cmd} {
2351         bind $w <Any-Button-3> $cmd
2352         if {[is_MacOSX]} {
2353                 bind $w <Control-Button-1> $cmd
2354         }
2355 }
2356
2357 proc incr_font_size {font {amt 1}} {
2358         set sz [font configure $font -size]
2359         incr sz $amt
2360         font configure $font -size $sz
2361         font configure ${font}bold -size $sz
2362 }
2363
2364 proc hook_failed_popup {hook msg} {
2365         set w .hookfail
2366         toplevel $w
2367
2368         frame $w.m
2369         label $w.m.l1 -text "$hook hook failed:" \
2370                 -anchor w \
2371                 -justify left \
2372                 -font font_uibold
2373         text $w.m.t \
2374                 -background white -borderwidth 1 \
2375                 -relief sunken \
2376                 -width 80 -height 10 \
2377                 -font font_diff \
2378                 -yscrollcommand [list $w.m.sby set]
2379         label $w.m.l2 \
2380                 -text {You must correct the above errors before committing.} \
2381                 -anchor w \
2382                 -justify left \
2383                 -font font_uibold
2384         scrollbar $w.m.sby -command [list $w.m.t yview]
2385         pack $w.m.l1 -side top -fill x
2386         pack $w.m.l2 -side bottom -fill x
2387         pack $w.m.sby -side right -fill y
2388         pack $w.m.t -side left -fill both -expand 1
2389         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2390
2391         $w.m.t insert 1.0 $msg
2392         $w.m.t conf -state disabled
2393
2394         button $w.ok -text OK \
2395                 -width 15 \
2396                 -font font_ui \
2397                 -command "destroy $w"
2398         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2399
2400         bind $w <Visibility> "grab $w; focus $w"
2401         bind $w <Key-Return> "destroy $w"
2402         wm title $w "[appname] ([reponame]): error"
2403         tkwait window $w
2404 }
2405
2406 set next_console_id 0
2407
2408 proc new_console {short_title long_title} {
2409         global next_console_id console_data
2410         set w .console[incr next_console_id]
2411         set console_data($w) [list $short_title $long_title]
2412         return [console_init $w]
2413 }
2414
2415 proc console_init {w} {
2416         global console_cr console_data M1B
2417
2418         set console_cr($w) 1.0
2419         toplevel $w
2420         frame $w.m
2421         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2422                 -anchor w \
2423                 -justify left \
2424                 -font font_uibold
2425         text $w.m.t \
2426                 -background white -borderwidth 1 \
2427                 -relief sunken \
2428                 -width 80 -height 10 \
2429                 -font font_diff \
2430                 -state disabled \
2431                 -yscrollcommand [list $w.m.sby set]
2432         label $w.m.s -text {Working... please wait...} \
2433                 -anchor w \
2434                 -justify left \
2435                 -font font_uibold
2436         scrollbar $w.m.sby -command [list $w.m.t yview]
2437         pack $w.m.l1 -side top -fill x
2438         pack $w.m.s -side bottom -fill x
2439         pack $w.m.sby -side right -fill y
2440         pack $w.m.t -side left -fill both -expand 1
2441         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2442
2443         menu $w.ctxm -tearoff 0
2444         $w.ctxm add command -label "Copy" \
2445                 -font font_ui \
2446                 -command "tk_textCopy $w.m.t"
2447         $w.ctxm add command -label "Select All" \
2448                 -font font_ui \
2449                 -command "$w.m.t tag add sel 0.0 end"
2450         $w.ctxm add command -label "Copy All" \
2451                 -font font_ui \
2452                 -command "
2453                         $w.m.t tag add sel 0.0 end
2454                         tk_textCopy $w.m.t
2455                         $w.m.t tag remove sel 0.0 end
2456                 "
2457
2458         button $w.ok -text {Close} \
2459                 -font font_ui \
2460                 -state disabled \
2461                 -command "destroy $w"
2462         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2463
2464         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2465         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2466         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2467         bind $w <Visibility> "focus $w"
2468         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2469         return $w
2470 }
2471
2472 proc console_exec {w cmd {after {}}} {
2473         # -- Windows tosses the enviroment when we exec our child.
2474         #    But most users need that so we have to relogin. :-(
2475         #
2476         if {[is_Windows]} {
2477                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2478         }
2479
2480         # -- Tcl won't let us redirect both stdout and stderr to
2481         #    the same pipe.  So pass it through cat...
2482         #
2483         set cmd [concat | $cmd |& cat]
2484
2485         set fd_f [open $cmd r]
2486         fconfigure $fd_f -blocking 0 -translation binary
2487         fileevent $fd_f readable [list console_read $w $fd_f $after]
2488 }
2489
2490 proc console_read {w fd after} {
2491         global console_cr console_data
2492
2493         set buf [read $fd]
2494         if {$buf ne {}} {
2495                 if {![winfo exists $w]} {console_init $w}
2496                 $w.m.t conf -state normal
2497                 set c 0
2498                 set n [string length $buf]
2499                 while {$c < $n} {
2500                         set cr [string first "\r" $buf $c]
2501                         set lf [string first "\n" $buf $c]
2502                         if {$cr < 0} {set cr [expr {$n + 1}]}
2503                         if {$lf < 0} {set lf [expr {$n + 1}]}
2504
2505                         if {$lf < $cr} {
2506                                 $w.m.t insert end [string range $buf $c $lf]
2507                                 set console_cr($w) [$w.m.t index {end -1c}]
2508                                 set c $lf
2509                                 incr c
2510                         } else {
2511                                 $w.m.t delete $console_cr($w) end
2512                                 $w.m.t insert end "\n"
2513                                 $w.m.t insert end [string range $buf $c $cr]
2514                                 set c $cr
2515                                 incr c
2516                         }
2517                 }
2518                 $w.m.t conf -state disabled
2519                 $w.m.t see end
2520         }
2521
2522         fconfigure $fd -blocking 1
2523         if {[eof $fd]} {
2524                 if {[catch {close $fd}]} {
2525                         if {![winfo exists $w]} {console_init $w}
2526                         $w.m.s conf -background red -text {Error: Command Failed}
2527                         $w.ok conf -state normal
2528                         set ok 0
2529                 } elseif {[winfo exists $w]} {
2530                         $w.m.s conf -background green -text {Success}
2531                         $w.ok conf -state normal
2532                         set ok 1
2533                 }
2534                 array unset console_cr $w
2535                 array unset console_data $w
2536                 if {$after ne {}} {
2537                         uplevel #0 $after $ok
2538                 }
2539                 return
2540         }
2541         fconfigure $fd -blocking 0
2542 }
2543
2544 ######################################################################
2545 ##
2546 ## ui commands
2547
2548 set starting_gitk_msg {Starting gitk... please wait...}
2549
2550 proc do_gitk {revs} {
2551         global ui_status_value starting_gitk_msg
2552
2553         set cmd gitk
2554         if {$revs ne {}} {
2555                 append cmd { }
2556                 append cmd $revs
2557         }
2558         if {[is_Windows]} {
2559                 set cmd "sh -c \"exec $cmd\""
2560         }
2561         append cmd { &}
2562
2563         if {[catch {eval exec $cmd} err]} {
2564                 error_popup "Failed to start gitk:\n\n$err"
2565         } else {
2566                 set ui_status_value $starting_gitk_msg
2567                 after 10000 {
2568                         if {$ui_status_value eq $starting_gitk_msg} {
2569                                 set ui_status_value {Ready.}
2570                         }
2571                 }
2572         }
2573 }
2574
2575 proc do_gc {} {
2576         set w [new_console {gc} {Compressing the object database}]
2577         console_exec $w {git gc}
2578 }
2579
2580 proc do_fsck_objects {} {
2581         set w [new_console {fsck-objects} \
2582                 {Verifying the object database with fsck-objects}]
2583         set cmd [list git fsck-objects]
2584         lappend cmd --full
2585         lappend cmd --cache
2586         lappend cmd --strict
2587         console_exec $w $cmd
2588 }
2589
2590 set is_quitting 0
2591
2592 proc do_quit {} {
2593         global ui_comm is_quitting repo_config commit_type
2594
2595         if {$is_quitting} return
2596         set is_quitting 1
2597
2598         # -- Stash our current commit buffer.
2599         #
2600         set save [gitdir GITGUI_MSG]
2601         set msg [string trim [$ui_comm get 0.0 end]]
2602         if {![string match amend* $commit_type]
2603                 && [$ui_comm edit modified]
2604                 && $msg ne {}} {
2605                 catch {
2606                         set fd [open $save w]
2607                         puts $fd [string trim [$ui_comm get 0.0 end]]
2608                         close $fd
2609                 }
2610         } else {
2611                 catch {file delete $save}
2612         }
2613
2614         # -- Stash our current window geometry into this repository.
2615         #
2616         set cfg_geometry [list]
2617         lappend cfg_geometry [wm geometry .]
2618         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2619         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2620         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2621                 set rc_geometry {}
2622         }
2623         if {$cfg_geometry ne $rc_geometry} {
2624                 catch {exec git repo-config gui.geometry $cfg_geometry}
2625         }
2626
2627         destroy .
2628 }
2629
2630 proc do_rescan {} {
2631         rescan {set ui_status_value {Ready.}}
2632 }
2633
2634 proc unstage_helper {txt paths} {
2635         global file_states current_diff_path
2636
2637         if {![lock_index begin-update]} return
2638
2639         set pathList [list]
2640         set after {}
2641         foreach path $paths {
2642                 switch -glob -- [lindex $file_states($path) 0] {
2643                 A? -
2644                 M? -
2645                 D? {
2646                         lappend pathList $path
2647                         if {$path eq $current_diff_path} {
2648                                 set after {reshow_diff;}
2649                         }
2650                 }
2651                 }
2652         }
2653         if {$pathList eq {}} {
2654                 unlock_index
2655         } else {
2656                 update_indexinfo \
2657                         $txt \
2658                         $pathList \
2659                         [concat $after {set ui_status_value {Ready.}}]
2660         }
2661 }
2662
2663 proc do_unstage_selection {} {
2664         global current_diff_path selected_paths
2665
2666         if {[array size selected_paths] > 0} {
2667                 unstage_helper \
2668                         {Unstaging selected files from commit} \
2669                         [array names selected_paths]
2670         } elseif {$current_diff_path ne {}} {
2671                 unstage_helper \
2672                         "Unstaging [short_path $current_diff_path] from commit" \
2673                         [list $current_diff_path]
2674         }
2675 }
2676
2677 proc add_helper {txt paths} {
2678         global file_states current_diff_path
2679
2680         if {![lock_index begin-update]} return
2681
2682         set pathList [list]
2683         set after {}
2684         foreach path $paths {
2685                 switch -glob -- [lindex $file_states($path) 0] {
2686                 _O -
2687                 ?M -
2688                 ?D -
2689                 U? {
2690                         lappend pathList $path
2691                         if {$path eq $current_diff_path} {
2692                                 set after {reshow_diff;}
2693                         }
2694                 }
2695                 }
2696         }
2697         if {$pathList eq {}} {
2698                 unlock_index
2699         } else {
2700                 update_index \
2701                         $txt \
2702                         $pathList \
2703                         [concat $after {set ui_status_value {Ready to commit.}}]
2704         }
2705 }
2706
2707 proc do_add_selection {} {
2708         global current_diff_path selected_paths
2709
2710         if {[array size selected_paths] > 0} {
2711                 add_helper \
2712                         {Adding selected files} \
2713                         [array names selected_paths]
2714         } elseif {$current_diff_path ne {}} {
2715                 add_helper \
2716                         "Adding [short_path $current_diff_path]" \
2717                         [list $current_diff_path]
2718         }
2719 }
2720
2721 proc do_add_all {} {
2722         global file_states
2723
2724         set paths [list]
2725         foreach path [array names file_states] {
2726                 switch -glob -- [lindex $file_states($path) 0] {
2727                 U? {continue}
2728                 ?M -
2729                 ?D {lappend paths $path}
2730                 }
2731         }
2732         add_helper {Adding all changed files} $paths
2733 }
2734
2735 proc revert_helper {txt paths} {
2736         global file_states current_diff_path
2737
2738         if {![lock_index begin-update]} return
2739
2740         set pathList [list]
2741         set after {}
2742         foreach path $paths {
2743                 switch -glob -- [lindex $file_states($path) 0] {
2744                 U? {continue}
2745                 ?M -
2746                 ?D {
2747                         lappend pathList $path
2748                         if {$path eq $current_diff_path} {
2749                                 set after {reshow_diff;}
2750                         }
2751                 }
2752                 }
2753         }
2754
2755         set n [llength $pathList]
2756         if {$n == 0} {
2757                 unlock_index
2758                 return
2759         } elseif {$n == 1} {
2760                 set s "[short_path [lindex $pathList]]"
2761         } else {
2762                 set s "these $n files"
2763         }
2764
2765         set reply [tk_dialog \
2766                 .confirm_revert \
2767                 "[appname] ([reponame])" \
2768                 "Revert changes in $s?
2769
2770 Any unadded changes will be permanently lost by the revert." \
2771                 question \
2772                 1 \
2773                 {Do Nothing} \
2774                 {Revert Changes} \
2775                 ]
2776         if {$reply == 1} {
2777                 checkout_index \
2778                         $txt \
2779                         $pathList \
2780                         [concat $after {set ui_status_value {Ready.}}]
2781         } else {
2782                 unlock_index
2783         }
2784 }
2785
2786 proc do_revert_selection {} {
2787         global current_diff_path selected_paths
2788
2789         if {[array size selected_paths] > 0} {
2790                 revert_helper \
2791                         {Reverting selected files} \
2792                         [array names selected_paths]
2793         } elseif {$current_diff_path ne {}} {
2794                 revert_helper \
2795                         "Reverting [short_path $current_diff_path]" \
2796                         [list $current_diff_path]
2797         }
2798 }
2799
2800 proc do_signoff {} {
2801         global ui_comm
2802
2803         set me [committer_ident]
2804         if {$me eq {}} return
2805
2806         set sob "Signed-off-by: $me"
2807         set last [$ui_comm get {end -1c linestart} {end -1c}]
2808         if {$last ne $sob} {
2809                 $ui_comm edit separator
2810                 if {$last ne {}
2811                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2812                         $ui_comm insert end "\n"
2813                 }
2814                 $ui_comm insert end "\n$sob"
2815                 $ui_comm edit separator
2816                 $ui_comm see end
2817         }
2818 }
2819
2820 proc do_select_commit_type {} {
2821         global commit_type selected_commit_type
2822
2823         if {$selected_commit_type eq {new}
2824                 && [string match amend* $commit_type]} {
2825                 create_new_commit
2826         } elseif {$selected_commit_type eq {amend}
2827                 && ![string match amend* $commit_type]} {
2828                 load_last_commit
2829
2830                 # The amend request was rejected...
2831                 #
2832                 if {![string match amend* $commit_type]} {
2833                         set selected_commit_type new
2834                 }
2835         }
2836 }
2837
2838 proc do_commit {} {
2839         commit_tree
2840 }
2841
2842 proc do_about {} {
2843         global appvers copyright
2844         global tcl_patchLevel tk_patchLevel
2845
2846         set w .about_dialog
2847         toplevel $w
2848         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2849
2850         label $w.header -text "About [appname]" \
2851                 -font font_uibold
2852         pack $w.header -side top -fill x
2853
2854         frame $w.buttons
2855         button $w.buttons.close -text {Close} \
2856                 -font font_ui \
2857                 -command [list destroy $w]
2858         pack $w.buttons.close -side right
2859         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2860
2861         label $w.desc \
2862                 -text "[appname] - a commit creation tool for Git.
2863 $copyright" \
2864                 -padx 5 -pady 5 \
2865                 -justify left \
2866                 -anchor w \
2867                 -borderwidth 1 \
2868                 -relief solid \
2869                 -font font_ui
2870         pack $w.desc -side top -fill x -padx 5 -pady 5
2871
2872         set v {}
2873         append v "[appname] version $appvers\n"
2874         append v "[exec git version]\n"
2875         append v "\n"
2876         if {$tcl_patchLevel eq $tk_patchLevel} {
2877                 append v "Tcl/Tk version $tcl_patchLevel"
2878         } else {
2879                 append v "Tcl version $tcl_patchLevel"
2880                 append v ", Tk version $tk_patchLevel"
2881         }
2882
2883         label $w.vers \
2884                 -text $v \
2885                 -padx 5 -pady 5 \
2886                 -justify left \
2887                 -anchor w \
2888                 -borderwidth 1 \
2889                 -relief solid \
2890                 -font font_ui
2891         pack $w.vers -side top -fill x -padx 5 -pady 5
2892
2893         menu $w.ctxm -tearoff 0
2894         $w.ctxm add command \
2895                 -label {Copy} \
2896                 -font font_ui \
2897                 -command "
2898                 clipboard clear
2899                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2900         "
2901
2902         bind $w <Visibility> "grab $w; focus $w"
2903         bind $w <Key-Escape> "destroy $w"
2904         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2905         wm title $w "About [appname]"
2906         tkwait window $w
2907 }
2908
2909 proc do_options {} {
2910         global repo_config global_config font_descs
2911         global repo_config_new global_config_new
2912
2913         array unset repo_config_new
2914         array unset global_config_new
2915         foreach name [array names repo_config] {
2916                 set repo_config_new($name) $repo_config($name)
2917         }
2918         load_config 1
2919         foreach name [array names repo_config] {
2920                 switch -- $name {
2921                 gui.diffcontext {continue}
2922                 }
2923                 set repo_config_new($name) $repo_config($name)
2924         }
2925         foreach name [array names global_config] {
2926                 set global_config_new($name) $global_config($name)
2927         }
2928
2929         set w .options_editor
2930         toplevel $w
2931         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2932
2933         label $w.header -text "[appname] Options" \
2934                 -font font_uibold
2935         pack $w.header -side top -fill x
2936
2937         frame $w.buttons
2938         button $w.buttons.restore -text {Restore Defaults} \
2939                 -font font_ui \
2940                 -command do_restore_defaults
2941         pack $w.buttons.restore -side left
2942         button $w.buttons.save -text Save \
2943                 -font font_ui \
2944                 -command [list do_save_config $w]
2945         pack $w.buttons.save -side right
2946         button $w.buttons.cancel -text {Cancel} \
2947                 -font font_ui \
2948                 -command [list destroy $w]
2949         pack $w.buttons.cancel -side right -padx 5
2950         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2951
2952         labelframe $w.repo -text "[reponame] Repository" \
2953                 -font font_ui \
2954                 -relief raised -borderwidth 2
2955         labelframe $w.global -text {Global (All Repositories)} \
2956                 -font font_ui \
2957                 -relief raised -borderwidth 2
2958         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2959         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2960
2961         foreach option {
2962                 {b pullsummary {Show Pull Summary}}
2963                 {b trustmtime  {Trust File Modification Timestamps}}
2964                 {i diffcontext {Number of Diff Context Lines}}
2965                 } {
2966                 set type [lindex $option 0]
2967                 set name [lindex $option 1]
2968                 set text [lindex $option 2]
2969                 foreach f {repo global} {
2970                         switch $type {
2971                         b {
2972                                 checkbutton $w.$f.$name -text $text \
2973                                         -variable ${f}_config_new(gui.$name) \
2974                                         -onvalue true \
2975                                         -offvalue false \
2976                                         -font font_ui
2977                                 pack $w.$f.$name -side top -anchor w
2978                         }
2979                         i {
2980                                 frame $w.$f.$name
2981                                 label $w.$f.$name.l -text "$text:" -font font_ui
2982                                 pack $w.$f.$name.l -side left -anchor w -fill x
2983                                 spinbox $w.$f.$name.v \
2984                                         -textvariable ${f}_config_new(gui.$name) \
2985                                         -from 1 -to 99 -increment 1 \
2986                                         -width 3 \
2987                                         -font font_ui
2988                                 pack $w.$f.$name.v -side right -anchor e
2989                                 pack $w.$f.$name -side top -anchor w -fill x
2990                         }
2991                         }
2992                 }
2993         }
2994
2995         set all_fonts [lsort [font families]]
2996         foreach option $font_descs {
2997                 set name [lindex $option 0]
2998                 set font [lindex $option 1]
2999                 set text [lindex $option 2]
3000
3001                 set global_config_new(gui.$font^^family) \
3002                         [font configure $font -family]
3003                 set global_config_new(gui.$font^^size) \
3004                         [font configure $font -size]
3005
3006                 frame $w.global.$name
3007                 label $w.global.$name.l -text "$text:" -font font_ui
3008                 pack $w.global.$name.l -side left -anchor w -fill x
3009                 eval tk_optionMenu $w.global.$name.family \
3010                         global_config_new(gui.$font^^family) \
3011                         $all_fonts
3012                 spinbox $w.global.$name.size \
3013                         -textvariable global_config_new(gui.$font^^size) \
3014                         -from 2 -to 80 -increment 1 \
3015                         -width 3 \
3016                         -font font_ui
3017                 pack $w.global.$name.size -side right -anchor e
3018                 pack $w.global.$name.family -side right -anchor e
3019                 pack $w.global.$name -side top -anchor w -fill x
3020         }
3021
3022         bind $w <Visibility> "grab $w; focus $w"
3023         bind $w <Key-Escape> "destroy $w"
3024         wm title $w "[appname] ([reponame]): Options"
3025         tkwait window $w
3026 }
3027
3028 proc do_restore_defaults {} {
3029         global font_descs default_config repo_config
3030         global repo_config_new global_config_new
3031
3032         foreach name [array names default_config] {
3033                 set repo_config_new($name) $default_config($name)
3034                 set global_config_new($name) $default_config($name)
3035         }
3036
3037         foreach option $font_descs {
3038                 set name [lindex $option 0]
3039                 set repo_config(gui.$name) $default_config(gui.$name)
3040         }
3041         apply_config
3042
3043         foreach option $font_descs {
3044                 set name [lindex $option 0]
3045                 set font [lindex $option 1]
3046                 set global_config_new(gui.$font^^family) \
3047                         [font configure $font -family]
3048                 set global_config_new(gui.$font^^size) \
3049                         [font configure $font -size]
3050         }
3051 }
3052
3053 proc do_save_config {w} {
3054         if {[catch {save_config} err]} {
3055                 error_popup "Failed to completely save options:\n\n$err"
3056         }
3057         reshow_diff
3058         destroy $w
3059 }
3060
3061 proc do_windows_shortcut {} {
3062         global argv0
3063
3064         if {[catch {
3065                 set desktop [exec cygpath \
3066                         --windows \
3067                         --absolute \
3068                         --long-name \
3069                         --desktop]
3070                 }]} {
3071                         set desktop .
3072         }
3073         set fn [tk_getSaveFile \
3074                 -parent . \
3075                 -title "[appname] ([reponame]): Create Desktop Icon" \
3076                 -initialdir $desktop \
3077                 -initialfile "Git [reponame].bat"]
3078         if {$fn != {}} {
3079                 if {[catch {
3080                                 set fd [open $fn w]
3081                                 set sh [exec cygpath \
3082                                         --windows \
3083                                         --absolute \
3084                                         /bin/sh]
3085                                 set me [exec cygpath \
3086                                         --unix \
3087                                         --absolute \
3088                                         $argv0]
3089                                 set gd [exec cygpath \
3090                                         --unix \
3091                                         --absolute \
3092                                         [gitdir]]
3093                                 set gw [exec cygpath \
3094                                         --windows \
3095                                         --absolute \
3096                                         [file dirname [gitdir]]]
3097                                 regsub -all ' $me "'\\''" me
3098                                 regsub -all ' $gd "'\\''" gd
3099                                 puts $fd "@ECHO Entering $gw"
3100                                 puts $fd "@ECHO Starting git-gui... please wait..."
3101                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3102                                 puts -nonewline $fd "GIT_DIR='$gd'"
3103                                 puts -nonewline $fd " '$me'"
3104                                 puts $fd "&\""
3105                                 close $fd
3106                         } err]} {
3107                         error_popup "Cannot write script:\n\n$err"
3108                 }
3109         }
3110 }
3111
3112 proc do_macosx_app {} {
3113         global argv0 env
3114
3115         set fn [tk_getSaveFile \
3116                 -parent . \
3117                 -title "[appname] ([reponame]): Create Desktop Icon" \
3118                 -initialdir [file join $env(HOME) Desktop] \
3119                 -initialfile "Git [reponame].app"]
3120         if {$fn != {}} {
3121                 if {[catch {
3122                                 set Contents [file join $fn Contents]
3123                                 set MacOS [file join $Contents MacOS]
3124                                 set exe [file join $MacOS git-gui]
3125
3126                                 file mkdir $MacOS
3127
3128                                 set fd [open [file join $Contents Info.plist] w]
3129                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3130 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3131 <plist version="1.0">
3132 <dict>
3133         <key>CFBundleDevelopmentRegion</key>
3134         <string>English</string>
3135         <key>CFBundleExecutable</key>
3136         <string>git-gui</string>
3137         <key>CFBundleIdentifier</key>
3138         <string>org.spearce.git-gui</string>
3139         <key>CFBundleInfoDictionaryVersion</key>
3140         <string>6.0</string>
3141         <key>CFBundlePackageType</key>
3142         <string>APPL</string>
3143         <key>CFBundleSignature</key>
3144         <string>????</string>
3145         <key>CFBundleVersion</key>
3146         <string>1.0</string>
3147         <key>NSPrincipalClass</key>
3148         <string>NSApplication</string>
3149 </dict>
3150 </plist>}
3151                                 close $fd
3152
3153                                 set fd [open $exe w]
3154                                 set gd [file normalize [gitdir]]
3155                                 set ep [file normalize [exec git --exec-path]]
3156                                 regsub -all ' $gd "'\\''" gd
3157                                 regsub -all ' $ep "'\\''" ep
3158                                 puts $fd "#!/bin/sh"
3159                                 foreach name [array names env] {
3160                                         if {[string match GIT_* $name]} {
3161                                                 regsub -all ' $env($name) "'\\''" v
3162                                                 puts $fd "export $name='$v'"
3163                                         }
3164                                 }
3165                                 puts $fd "export PATH='$ep':\$PATH"
3166                                 puts $fd "export GIT_DIR='$gd'"
3167                                 puts $fd "exec [file normalize $argv0]"
3168                                 close $fd
3169
3170                                 file attributes $exe -permissions u+x,g+x,o+x
3171                         } err]} {
3172                         error_popup "Cannot write icon:\n\n$err"
3173                 }
3174         }
3175 }
3176
3177 proc toggle_or_diff {w x y} {
3178         global file_states file_lists current_diff_path ui_index ui_workdir
3179         global last_clicked selected_paths
3180
3181         set pos [split [$w index @$x,$y] .]
3182         set lno [lindex $pos 0]
3183         set col [lindex $pos 1]
3184         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3185         if {$path eq {}} {
3186                 set last_clicked {}
3187                 return
3188         }
3189
3190         set last_clicked [list $w $lno]
3191         array unset selected_paths
3192         $ui_index tag remove in_sel 0.0 end
3193         $ui_workdir tag remove in_sel 0.0 end
3194
3195         if {$col == 0} {
3196                 if {$current_diff_path eq $path} {
3197                         set after {reshow_diff;}
3198                 } else {
3199                         set after {}
3200                 }
3201                 if {$w eq $ui_index} {
3202                         update_indexinfo \
3203                                 "Unstaging [short_path $path] from commit" \
3204                                 [list $path] \
3205                                 [concat $after {set ui_status_value {Ready.}}]
3206                 } elseif {$w eq $ui_workdir} {
3207                         update_index \
3208                                 "Adding [short_path $path]" \
3209                                 [list $path] \
3210                                 [concat $after {set ui_status_value {Ready.}}]
3211                 }
3212         } else {
3213                 show_diff $path $w $lno
3214         }
3215 }
3216
3217 proc add_one_to_selection {w x y} {
3218         global file_lists last_clicked selected_paths
3219
3220         set lno [lindex [split [$w index @$x,$y] .] 0]
3221         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3222         if {$path eq {}} {
3223                 set last_clicked {}
3224                 return
3225         }
3226
3227         if {$last_clicked ne {}
3228                 && [lindex $last_clicked 0] ne $w} {
3229                 array unset selected_paths
3230                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3231         }
3232
3233         set last_clicked [list $w $lno]
3234         if {[catch {set in_sel $selected_paths($path)}]} {
3235                 set in_sel 0
3236         }
3237         if {$in_sel} {
3238                 unset selected_paths($path)
3239                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3240         } else {
3241                 set selected_paths($path) 1
3242                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3243         }
3244 }
3245
3246 proc add_range_to_selection {w x y} {
3247         global file_lists last_clicked selected_paths
3248
3249         if {[lindex $last_clicked 0] ne $w} {
3250                 toggle_or_diff $w $x $y
3251                 return
3252         }
3253
3254         set lno [lindex [split [$w index @$x,$y] .] 0]
3255         set lc [lindex $last_clicked 1]
3256         if {$lc < $lno} {
3257                 set begin $lc
3258                 set end $lno
3259         } else {
3260                 set begin $lno
3261                 set end $lc
3262         }
3263
3264         foreach path [lrange $file_lists($w) \
3265                 [expr {$begin - 1}] \
3266                 [expr {$end - 1}]] {
3267                 set selected_paths($path) 1
3268         }
3269         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3270 }
3271
3272 ######################################################################
3273 ##
3274 ## config defaults
3275
3276 set cursor_ptr arrow
3277 font create font_diff -family Courier -size 10
3278 font create font_ui
3279 catch {
3280         label .dummy
3281         eval font configure font_ui [font actual [.dummy cget -font]]
3282         destroy .dummy
3283 }
3284
3285 font create font_uibold
3286 font create font_diffbold
3287
3288 if {[is_Windows]} {
3289         set M1B Control
3290         set M1T Ctrl
3291 } elseif {[is_MacOSX]} {
3292         set M1B M1
3293         set M1T Cmd
3294 } else {
3295         set M1B M1
3296         set M1T M1
3297 }
3298
3299 proc apply_config {} {
3300         global repo_config font_descs
3301
3302         foreach option $font_descs {
3303                 set name [lindex $option 0]
3304                 set font [lindex $option 1]
3305                 if {[catch {
3306                         foreach {cn cv} $repo_config(gui.$name) {
3307                                 font configure $font $cn $cv
3308                         }
3309                         } err]} {
3310                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3311                 }
3312                 foreach {cn cv} [font configure $font] {
3313                         font configure ${font}bold $cn $cv
3314                 }
3315                 font configure ${font}bold -weight bold
3316         }
3317 }
3318
3319 set default_config(gui.trustmtime) false
3320 set default_config(gui.pullsummary) true
3321 set default_config(gui.diffcontext) 5
3322 set default_config(gui.fontui) [font configure font_ui]
3323 set default_config(gui.fontdiff) [font configure font_diff]
3324 set font_descs {
3325         {fontui   font_ui   {Main Font}}
3326         {fontdiff font_diff {Diff/Console Font}}
3327 }
3328 load_config 0
3329 apply_config
3330
3331 ######################################################################
3332 ##
3333 ## ui construction
3334
3335 # -- Menu Bar
3336 #
3337 menu .mbar -tearoff 0
3338 .mbar add cascade -label Repository -menu .mbar.repository
3339 .mbar add cascade -label Edit -menu .mbar.edit
3340 if {!$single_commit} {
3341         .mbar add cascade -label Branch -menu .mbar.branch
3342 }
3343 .mbar add cascade -label Commit -menu .mbar.commit
3344 if {!$single_commit} {
3345         .mbar add cascade -label Fetch -menu .mbar.fetch
3346         .mbar add cascade -label Pull -menu .mbar.pull
3347         .mbar add cascade -label Push -menu .mbar.push
3348 }
3349 . configure -menu .mbar
3350
3351 # -- Repository Menu
3352 #
3353 menu .mbar.repository
3354 .mbar.repository add command \
3355         -label {Visualize Current Branch} \
3356         -command {do_gitk {}} \
3357         -font font_ui
3358 if {![is_MacOSX]} {
3359         .mbar.repository add command \
3360                 -label {Visualize All Branches} \
3361                 -command {do_gitk {--all}} \
3362                 -font font_ui
3363 }
3364 .mbar.repository add separator
3365
3366 if {!$single_commit} {
3367         .mbar.repository add command -label {Compress Database} \
3368                 -command do_gc \
3369                 -font font_ui
3370
3371         .mbar.repository add command -label {Verify Database} \
3372                 -command do_fsck_objects \
3373                 -font font_ui
3374
3375         .mbar.repository add separator
3376
3377         if {[is_Windows]} {
3378                 .mbar.repository add command \
3379                         -label {Create Desktop Icon} \
3380                         -command do_windows_shortcut \
3381                         -font font_ui
3382         } elseif {[is_MacOSX]} {
3383                 .mbar.repository add command \
3384                         -label {Create Desktop Icon} \
3385                         -command do_macosx_app \
3386                         -font font_ui
3387         }
3388 }
3389
3390 .mbar.repository add command -label Quit \
3391         -command do_quit \
3392         -accelerator $M1T-Q \
3393         -font font_ui
3394
3395 # -- Edit Menu
3396 #
3397 menu .mbar.edit
3398 .mbar.edit add command -label Undo \
3399         -command {catch {[focus] edit undo}} \
3400         -accelerator $M1T-Z \
3401         -font font_ui
3402 .mbar.edit add command -label Redo \
3403         -command {catch {[focus] edit redo}} \
3404         -accelerator $M1T-Y \
3405         -font font_ui
3406 .mbar.edit add separator
3407 .mbar.edit add command -label Cut \
3408         -command {catch {tk_textCut [focus]}} \
3409         -accelerator $M1T-X \
3410         -font font_ui
3411 .mbar.edit add command -label Copy \
3412         -command {catch {tk_textCopy [focus]}} \
3413         -accelerator $M1T-C \
3414         -font font_ui
3415 .mbar.edit add command -label Paste \
3416         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3417         -accelerator $M1T-V \
3418         -font font_ui
3419 .mbar.edit add command -label Delete \
3420         -command {catch {[focus] delete sel.first sel.last}} \
3421         -accelerator Del \
3422         -font font_ui
3423 .mbar.edit add separator
3424 .mbar.edit add command -label {Select All} \
3425         -command {catch {[focus] tag add sel 0.0 end}} \
3426         -accelerator $M1T-A \
3427         -font font_ui
3428
3429 # -- Branch Menu
3430 #
3431 if {!$single_commit} {
3432         menu .mbar.branch
3433
3434         .mbar.branch add command -label {Create...} \
3435                 -command do_create_branch \
3436                 -accelerator $M1T-N \
3437                 -font font_ui
3438         lappend disable_on_lock [list .mbar.branch entryconf \
3439                 [.mbar.branch index last] -state]
3440
3441         .mbar.branch add command -label {Delete...} \
3442                 -command do_delete_branch \
3443                 -font font_ui
3444         lappend disable_on_lock [list .mbar.branch entryconf \
3445                 [.mbar.branch index last] -state]
3446 }
3447
3448 # -- Commit Menu
3449 #
3450 menu .mbar.commit
3451
3452 .mbar.commit add radiobutton \
3453         -label {New Commit} \
3454         -command do_select_commit_type \
3455         -variable selected_commit_type \
3456         -value new \
3457         -font font_ui
3458 lappend disable_on_lock \
3459         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3460
3461 .mbar.commit add radiobutton \
3462         -label {Amend Last Commit} \
3463         -command do_select_commit_type \
3464         -variable selected_commit_type \
3465         -value amend \
3466         -font font_ui
3467 lappend disable_on_lock \
3468         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3469
3470 .mbar.commit add separator
3471
3472 .mbar.commit add command -label Rescan \
3473         -command do_rescan \
3474         -accelerator F5 \
3475         -font font_ui
3476 lappend disable_on_lock \
3477         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3478
3479 .mbar.commit add command -label {Add To Commit} \
3480         -command do_add_selection \
3481         -font font_ui
3482 lappend disable_on_lock \
3483         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3484
3485 .mbar.commit add command -label {Add All To Commit} \
3486         -command do_add_all \
3487         -accelerator $M1T-I \
3488         -font font_ui
3489 lappend disable_on_lock \
3490         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3491
3492 .mbar.commit add command -label {Unstage From Commit} \
3493         -command do_unstage_selection \
3494         -font font_ui
3495 lappend disable_on_lock \
3496         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3497
3498 .mbar.commit add command -label {Revert Changes} \
3499         -command do_revert_selection \
3500         -font font_ui
3501 lappend disable_on_lock \
3502         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3503
3504 .mbar.commit add separator
3505
3506 .mbar.commit add command -label {Sign Off} \
3507         -command do_signoff \
3508         -accelerator $M1T-S \
3509         -font font_ui
3510
3511 .mbar.commit add command -label Commit \
3512         -command do_commit \
3513         -accelerator $M1T-Return \
3514         -font font_ui
3515 lappend disable_on_lock \
3516         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3517
3518 # -- Transport menus
3519 #
3520 if {!$single_commit} {
3521         menu .mbar.fetch
3522         menu .mbar.pull
3523         menu .mbar.push
3524 }
3525
3526 if {[is_MacOSX]} {
3527         # -- Apple Menu (Mac OS X only)
3528         #
3529         .mbar add cascade -label Apple -menu .mbar.apple
3530         menu .mbar.apple
3531
3532         .mbar.apple add command -label "About [appname]" \
3533                 -command do_about \
3534                 -font font_ui
3535         .mbar.apple add command -label "[appname] Options..." \
3536                 -command do_options \
3537                 -font font_ui
3538 } else {
3539         # -- Edit Menu
3540         #
3541         .mbar.edit add separator
3542         .mbar.edit add command -label {Options...} \
3543                 -command do_options \
3544                 -font font_ui
3545
3546         # -- Tools Menu
3547         #
3548         if {[file exists /usr/local/miga/lib/gui-miga]
3549                 && [file exists .pvcsrc]} {
3550         proc do_miga {} {
3551                 global ui_status_value
3552                 if {![lock_index update]} return
3553                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3554                 set miga_fd [open "|$cmd" r]
3555                 fconfigure $miga_fd -blocking 0
3556                 fileevent $miga_fd readable [list miga_done $miga_fd]
3557                 set ui_status_value {Running miga...}
3558         }
3559         proc miga_done {fd} {
3560                 read $fd 512
3561                 if {[eof $fd]} {
3562                         close $fd
3563                         unlock_index
3564                         rescan [list set ui_status_value {Ready.}]
3565                 }
3566         }
3567         .mbar add cascade -label Tools -menu .mbar.tools
3568         menu .mbar.tools
3569         .mbar.tools add command -label "Migrate" \
3570                 -command do_miga \
3571                 -font font_ui
3572         lappend disable_on_lock \
3573                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3574         }
3575
3576         # -- Help Menu
3577         #
3578         .mbar add cascade -label Help -menu .mbar.help
3579         menu .mbar.help
3580
3581         .mbar.help add command -label "About [appname]" \
3582                 -command do_about \
3583                 -font font_ui
3584 }
3585
3586
3587 # -- Branch Control
3588 #
3589 frame .branch \
3590         -borderwidth 1 \
3591         -relief sunken
3592 label .branch.l1 \
3593         -text {Current Branch:} \
3594         -anchor w \
3595         -justify left \
3596         -font font_ui
3597 label .branch.cb \
3598         -textvariable current_branch \
3599         -anchor w \
3600         -justify left \
3601         -font font_ui
3602 pack .branch.l1 -side left
3603 pack .branch.cb -side left -fill x
3604 pack .branch -side top -fill x
3605
3606 # -- Main Window Layout
3607 #
3608 panedwindow .vpane -orient vertical
3609 panedwindow .vpane.files -orient horizontal
3610 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3611 pack .vpane -anchor n -side top -fill both -expand 1
3612
3613 # -- Index File List
3614 #
3615 frame .vpane.files.index -height 100 -width 400
3616 label .vpane.files.index.title -text {Changes To Be Committed} \
3617         -background green \
3618         -font font_ui
3619 text $ui_index -background white -borderwidth 0 \
3620         -width 40 -height 10 \
3621         -font font_ui \
3622         -cursor $cursor_ptr \
3623         -yscrollcommand {.vpane.files.index.sb set} \
3624         -state disabled
3625 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3626 pack .vpane.files.index.title -side top -fill x
3627 pack .vpane.files.index.sb -side right -fill y
3628 pack $ui_index -side left -fill both -expand 1
3629 .vpane.files add .vpane.files.index -sticky nsew
3630
3631 # -- Working Directory File List
3632 #
3633 frame .vpane.files.workdir -height 100 -width 100
3634 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3635         -background red \
3636         -font font_ui
3637 text $ui_workdir -background white -borderwidth 0 \
3638         -width 40 -height 10 \
3639         -font font_ui \
3640         -cursor $cursor_ptr \
3641         -yscrollcommand {.vpane.files.workdir.sb set} \
3642         -state disabled
3643 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3644 pack .vpane.files.workdir.title -side top -fill x
3645 pack .vpane.files.workdir.sb -side right -fill y
3646 pack $ui_workdir -side left -fill both -expand 1
3647 .vpane.files add .vpane.files.workdir -sticky nsew
3648
3649 foreach i [list $ui_index $ui_workdir] {
3650         $i tag conf in_diff -font font_uibold
3651         $i tag conf in_sel \
3652                 -background [$i cget -foreground] \
3653                 -foreground [$i cget -background]
3654 }
3655 unset i
3656
3657 # -- Diff and Commit Area
3658 #
3659 frame .vpane.lower -height 300 -width 400
3660 frame .vpane.lower.commarea
3661 frame .vpane.lower.diff -relief sunken -borderwidth 1
3662 pack .vpane.lower.commarea -side top -fill x
3663 pack .vpane.lower.diff -side bottom -fill both -expand 1
3664 .vpane add .vpane.lower -stick nsew
3665
3666 # -- Commit Area Buttons
3667 #
3668 frame .vpane.lower.commarea.buttons
3669 label .vpane.lower.commarea.buttons.l -text {} \
3670         -anchor w \
3671         -justify left \
3672         -font font_ui
3673 pack .vpane.lower.commarea.buttons.l -side top -fill x
3674 pack .vpane.lower.commarea.buttons -side left -fill y
3675
3676 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3677         -command do_rescan \
3678         -font font_ui
3679 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3680 lappend disable_on_lock \
3681         {.vpane.lower.commarea.buttons.rescan conf -state}
3682
3683 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3684         -command do_add_all \
3685         -font font_ui
3686 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3687 lappend disable_on_lock \
3688         {.vpane.lower.commarea.buttons.incall conf -state}
3689
3690 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3691         -command do_signoff \
3692         -font font_ui
3693 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3694
3695 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3696         -command do_commit \
3697         -font font_ui
3698 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3699 lappend disable_on_lock \
3700         {.vpane.lower.commarea.buttons.commit conf -state}
3701
3702 # -- Commit Message Buffer
3703 #
3704 frame .vpane.lower.commarea.buffer
3705 frame .vpane.lower.commarea.buffer.header
3706 set ui_comm .vpane.lower.commarea.buffer.t
3707 set ui_coml .vpane.lower.commarea.buffer.header.l
3708 radiobutton .vpane.lower.commarea.buffer.header.new \
3709         -text {New Commit} \
3710         -command do_select_commit_type \
3711         -variable selected_commit_type \
3712         -value new \
3713         -font font_ui
3714 lappend disable_on_lock \
3715         [list .vpane.lower.commarea.buffer.header.new conf -state]
3716 radiobutton .vpane.lower.commarea.buffer.header.amend \
3717         -text {Amend Last Commit} \
3718         -command do_select_commit_type \
3719         -variable selected_commit_type \
3720         -value amend \
3721         -font font_ui
3722 lappend disable_on_lock \
3723         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3724 label $ui_coml \
3725         -anchor w \
3726         -justify left \
3727         -font font_ui
3728 proc trace_commit_type {varname args} {
3729         global ui_coml commit_type
3730         switch -glob -- $commit_type {
3731         initial       {set txt {Initial Commit Message:}}
3732         amend         {set txt {Amended Commit Message:}}
3733         amend-initial {set txt {Amended Initial Commit Message:}}
3734         amend-merge   {set txt {Amended Merge Commit Message:}}
3735         merge         {set txt {Merge Commit Message:}}
3736         *             {set txt {Commit Message:}}
3737         }
3738         $ui_coml conf -text $txt
3739 }
3740 trace add variable commit_type write trace_commit_type
3741 pack $ui_coml -side left -fill x
3742 pack .vpane.lower.commarea.buffer.header.amend -side right
3743 pack .vpane.lower.commarea.buffer.header.new -side right
3744
3745 text $ui_comm -background white -borderwidth 1 \
3746         -undo true \
3747         -maxundo 20 \
3748         -autoseparators true \
3749         -relief sunken \
3750         -width 75 -height 9 -wrap none \
3751         -font font_diff \
3752         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3753 scrollbar .vpane.lower.commarea.buffer.sby \
3754         -command [list $ui_comm yview]
3755 pack .vpane.lower.commarea.buffer.header -side top -fill x
3756 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3757 pack $ui_comm -side left -fill y
3758 pack .vpane.lower.commarea.buffer -side left -fill y
3759
3760 # -- Commit Message Buffer Context Menu
3761 #
3762 set ctxm .vpane.lower.commarea.buffer.ctxm
3763 menu $ctxm -tearoff 0
3764 $ctxm add command \
3765         -label {Cut} \
3766         -font font_ui \
3767         -command {tk_textCut $ui_comm}
3768 $ctxm add command \
3769         -label {Copy} \
3770         -font font_ui \
3771         -command {tk_textCopy $ui_comm}
3772 $ctxm add command \
3773         -label {Paste} \
3774         -font font_ui \
3775         -command {tk_textPaste $ui_comm}
3776 $ctxm add command \
3777         -label {Delete} \
3778         -font font_ui \
3779         -command {$ui_comm delete sel.first sel.last}
3780 $ctxm add separator
3781 $ctxm add command \
3782         -label {Select All} \
3783         -font font_ui \
3784         -command {$ui_comm tag add sel 0.0 end}
3785 $ctxm add command \
3786         -label {Copy All} \
3787         -font font_ui \
3788         -command {
3789                 $ui_comm tag add sel 0.0 end
3790                 tk_textCopy $ui_comm
3791                 $ui_comm tag remove sel 0.0 end
3792         }
3793 $ctxm add separator
3794 $ctxm add command \
3795         -label {Sign Off} \
3796         -font font_ui \
3797         -command do_signoff
3798 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3799
3800 # -- Diff Header
3801 #
3802 set current_diff_path {}
3803 set diff_actions [list]
3804 proc trace_current_diff_path {varname args} {
3805         global current_diff_path diff_actions file_states
3806         if {$current_diff_path eq {}} {
3807                 set s {}
3808                 set f {}
3809                 set p {}
3810                 set o disabled
3811         } else {
3812                 set p $current_diff_path
3813                 set s [mapdesc [lindex $file_states($p) 0] $p]
3814                 set f {File:}
3815                 set p [escape_path $p]
3816                 set o normal
3817         }
3818
3819         .vpane.lower.diff.header.status configure -text $s
3820         .vpane.lower.diff.header.file configure -text $f
3821         .vpane.lower.diff.header.path configure -text $p
3822         foreach w $diff_actions {
3823                 uplevel #0 $w $o
3824         }
3825 }
3826 trace add variable current_diff_path write trace_current_diff_path
3827
3828 frame .vpane.lower.diff.header -background orange
3829 label .vpane.lower.diff.header.status \
3830         -background orange \
3831         -width $max_status_desc \
3832         -anchor w \
3833         -justify left \
3834         -font font_ui
3835 label .vpane.lower.diff.header.file \
3836         -background orange \
3837         -anchor w \
3838         -justify left \
3839         -font font_ui
3840 label .vpane.lower.diff.header.path \
3841         -background orange \
3842         -anchor w \
3843         -justify left \
3844         -font font_ui
3845 pack .vpane.lower.diff.header.status -side left
3846 pack .vpane.lower.diff.header.file -side left
3847 pack .vpane.lower.diff.header.path -fill x
3848 set ctxm .vpane.lower.diff.header.ctxm
3849 menu $ctxm -tearoff 0
3850 $ctxm add command \
3851         -label {Copy} \
3852         -font font_ui \
3853         -command {
3854                 clipboard clear
3855                 clipboard append \
3856                         -format STRING \
3857                         -type STRING \
3858                         -- $current_diff_path
3859         }
3860 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3861 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3862
3863 # -- Diff Body
3864 #
3865 frame .vpane.lower.diff.body
3866 set ui_diff .vpane.lower.diff.body.t
3867 text $ui_diff -background white -borderwidth 0 \
3868         -width 80 -height 15 -wrap none \
3869         -font font_diff \
3870         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3871         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3872         -state disabled
3873 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3874         -command [list $ui_diff xview]
3875 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3876         -command [list $ui_diff yview]
3877 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3878 pack .vpane.lower.diff.body.sby -side right -fill y
3879 pack $ui_diff -side left -fill both -expand 1
3880 pack .vpane.lower.diff.header -side top -fill x
3881 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3882
3883 $ui_diff tag conf d_@ -font font_diffbold
3884 $ui_diff tag conf d_+ -foreground blue
3885 $ui_diff tag conf d_- -foreground red
3886
3887 $ui_diff tag conf d_++ -foreground blue
3888 $ui_diff tag conf d_-- -foreground red
3889 $ui_diff tag conf d_+s \
3890         -foreground blue \
3891         -background azure2
3892 $ui_diff tag conf d_-s \
3893         -foreground red \
3894         -background azure2
3895 $ui_diff tag conf d_s+ \
3896         -foreground blue \
3897         -background {light goldenrod yellow}
3898 $ui_diff tag conf d_s- \
3899         -foreground red \
3900         -background {light goldenrod yellow}
3901
3902 $ui_diff tag conf d<<<<<<< \
3903         -foreground orange \
3904         -font font_diffbold
3905 $ui_diff tag conf d======= \
3906         -foreground orange \
3907         -font font_diffbold
3908 $ui_diff tag conf d>>>>>>> \
3909         -foreground orange \
3910         -font font_diffbold
3911
3912 # -- Diff Body Context Menu
3913 #
3914 set ctxm .vpane.lower.diff.body.ctxm
3915 menu $ctxm -tearoff 0
3916 $ctxm add command \
3917         -label {Refresh} \
3918         -font font_ui \
3919         -command reshow_diff
3920 $ctxm add command \
3921         -label {Copy} \
3922         -font font_ui \
3923         -command {tk_textCopy $ui_diff}
3924 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3925 $ctxm add command \
3926         -label {Select All} \
3927         -font font_ui \
3928         -command {$ui_diff tag add sel 0.0 end}
3929 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3930 $ctxm add command \
3931         -label {Copy All} \
3932         -font font_ui \
3933         -command {
3934                 $ui_diff tag add sel 0.0 end
3935                 tk_textCopy $ui_diff
3936                 $ui_diff tag remove sel 0.0 end
3937         }
3938 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3939 $ctxm add separator
3940 $ctxm add command \
3941         -label {Decrease Font Size} \
3942         -font font_ui \
3943         -command {incr_font_size font_diff -1}
3944 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3945 $ctxm add command \
3946         -label {Increase Font Size} \
3947         -font font_ui \
3948         -command {incr_font_size font_diff 1}
3949 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3950 $ctxm add separator
3951 $ctxm add command \
3952         -label {Show Less Context} \
3953         -font font_ui \
3954         -command {if {$repo_config(gui.diffcontext) >= 2} {
3955                 incr repo_config(gui.diffcontext) -1
3956                 reshow_diff
3957         }}
3958 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3959 $ctxm add command \
3960         -label {Show More Context} \
3961         -font font_ui \
3962         -command {
3963                 incr repo_config(gui.diffcontext)
3964                 reshow_diff
3965         }
3966 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3967 $ctxm add separator
3968 $ctxm add command -label {Options...} \
3969         -font font_ui \
3970         -command do_options
3971 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3972
3973 # -- Status Bar
3974 #
3975 set ui_status_value {Initializing...}
3976 label .status -textvariable ui_status_value \
3977         -anchor w \
3978         -justify left \
3979         -borderwidth 1 \
3980         -relief sunken \
3981         -font font_ui
3982 pack .status -anchor w -side bottom -fill x
3983
3984 # -- Load geometry
3985 #
3986 catch {
3987 set gm $repo_config(gui.geometry)
3988 wm geometry . [lindex $gm 0]
3989 .vpane sash place 0 \
3990         [lindex [.vpane sash coord 0] 0] \
3991         [lindex $gm 1]
3992 .vpane.files sash place 0 \
3993         [lindex $gm 2] \
3994         [lindex [.vpane.files sash coord 0] 1]
3995 unset gm
3996 }
3997
3998 # -- Key Bindings
3999 #
4000 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
4001 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
4002 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
4003 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
4004 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
4005 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
4006 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
4007 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
4008 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
4009 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4010 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4011
4012 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
4013 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
4014 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
4015 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
4016 bind $ui_diff <$M1B-Key-v> {break}
4017 bind $ui_diff <$M1B-Key-V> {break}
4018 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
4019 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
4020 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
4021 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
4022 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
4023 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
4024
4025 if {!$single_commit} {
4026         bind . <$M1B-Key-n> do_create_branch
4027         bind . <$M1B-Key-N> do_create_branch
4028 }
4029
4030 bind .   <Destroy> do_quit
4031 bind all <Key-F5> do_rescan
4032 bind all <$M1B-Key-r> do_rescan
4033 bind all <$M1B-Key-R> do_rescan
4034 bind .   <$M1B-Key-s> do_signoff
4035 bind .   <$M1B-Key-S> do_signoff
4036 bind .   <$M1B-Key-i> do_add_all
4037 bind .   <$M1B-Key-I> do_add_all
4038 bind .   <$M1B-Key-Return> do_commit
4039 bind all <$M1B-Key-q> do_quit
4040 bind all <$M1B-Key-Q> do_quit
4041 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
4042 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4043 foreach i [list $ui_index $ui_workdir] {
4044         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4045         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4046         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4047 }
4048 unset i
4049
4050 set file_lists($ui_index) [list]
4051 set file_lists($ui_workdir) [list]
4052
4053 set HEAD {}
4054 set PARENT {}
4055 set MERGE_HEAD [list]
4056 set commit_type {}
4057 set empty_tree {}
4058 set current_branch {}
4059 set current_diff_path {}
4060 set selected_commit_type new
4061
4062 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4063 focus -force $ui_comm
4064
4065 # -- Warn the user about environmental problems.  Cygwin's Tcl
4066 #    does *not* pass its env array onto any processes it spawns.
4067 #    This means that git processes get none of our environment.
4068 #
4069 if {[is_Windows]} {
4070         set ignored_env 0
4071         set suggest_user {}
4072         set msg "Possible environment issues exist.
4073
4074 The following environment variables are probably
4075 going to be ignored by any Git subprocess run
4076 by [appname]:
4077
4078 "
4079         foreach name [array names env] {
4080                 switch -regexp -- $name {
4081                 {^GIT_INDEX_FILE$} -
4082                 {^GIT_OBJECT_DIRECTORY$} -
4083                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4084                 {^GIT_DIFF_OPTS$} -
4085                 {^GIT_EXTERNAL_DIFF$} -
4086                 {^GIT_PAGER$} -
4087                 {^GIT_TRACE$} -
4088                 {^GIT_CONFIG$} -
4089                 {^GIT_CONFIG_LOCAL$} -
4090                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4091                         append msg " - $name\n"
4092                         incr ignored_env
4093                 }
4094                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4095                         append msg " - $name\n"
4096                         incr ignored_env
4097                         set suggest_user $name
4098                 }
4099                 }
4100         }
4101         if {$ignored_env > 0} {
4102                 append msg "
4103 This is due to a known issue with the
4104 Tcl binary distributed by Cygwin."
4105
4106                 if {$suggest_user ne {}} {
4107                         append msg "
4108
4109 A good replacement for $suggest_user
4110 is placing values for the user.name and
4111 user.email settings into your personal
4112 ~/.gitconfig file.
4113 "
4114                 }
4115                 warn_popup $msg
4116         }
4117         unset ignored_env msg suggest_user name
4118 }
4119
4120 # -- Only initialize complex UI if we are going to stay running.
4121 #
4122 if {!$single_commit} {
4123         load_all_remotes
4124         load_all_heads
4125
4126         populate_branch_menu
4127         populate_fetch_menu .mbar.fetch
4128         populate_pull_menu .mbar.pull
4129         populate_push_menu .mbar.push
4130 }
4131
4132 # -- Only suggest a gc run if we are going to stay running.
4133 #
4134 if {!$single_commit} {
4135         set object_limit 2000
4136         if {[is_Windows]} {set object_limit 200}
4137         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4138         if {$objects_current >= $object_limit} {
4139                 if {[ask_popup \
4140                         "This repository currently has $objects_current loose objects.
4141
4142 To maintain optimal performance it is strongly
4143 recommended that you compress the database
4144 when more than $object_limit loose objects exist.
4145
4146 Compress the database now?"] eq yes} {
4147                         do_gc
4148                 }
4149         }
4150         unset object_limit _junk objects_current
4151 }
4152
4153 lock_index begin-read
4154 after 1 do_rescan