git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527         reshow_diff
 528         uplevel #0 $after
 529 }
 530
 531 proc prune_selection {} {
 532         global file_states selected_paths
 533
 534         foreach path [array names selected_paths] {
 535                 if {[catch {set still_here $file_states($path)}]} {
 536                         unset selected_paths($path)
 537                 }
 538         }
 539 }
 540
 541 ######################################################################
 542 ##
 543 ## diff
 544
 545 proc clear_diff {} {
 546         global ui_diff current_diff ui_index ui_workdir
 547
 548         $ui_diff conf -state normal
 549         $ui_diff delete 0.0 end
 550         $ui_diff conf -state disabled
 551
 552         set current_diff {}
 553
 554         $ui_index tag remove in_diff 0.0 end
 555         $ui_workdir tag remove in_diff 0.0 end
 556 }
 557
 558 proc reshow_diff {} {
 559         global current_diff ui_status_value file_states
 560
 561         if {$current_diff eq {}
 562                 || [catch {set s $file_states($current_diff)}]} {
 563                 clear_diff
 564         } else {
 565                 show_diff $current_diff
 566         }
 567 }
 568
 569 proc handle_empty_diff {} {
 570         global current_diff file_states file_lists
 571
 572         set path $current_diff
 573         set s $file_states($path)
 574         if {[lindex $s 0] ne {_M}} return
 575
 576         info_popup "No differences detected.
 577
 578 [short_path $path] has no changes.
 579
 580 The modification date of this file was updated
 581 by another application and you currently have
 582 the Trust File Modification Timestamps option
 583 enabled, so Git did not automatically detect
 584 that there are no content differences in this
 585 file.
 586
 587 This file will now be removed from the modified
 588 files list, to prevent possible confusion.
 589 "
 590         if {[catch {exec git update-index -- $path} err]} {
 591                 error_popup "Failed to refresh index:\n\n$err"
 592         }
 593
 594         clear_diff
 595         display_file $path __
 596 }
 597
 598 proc show_diff {path {w {}} {lno {}}} {
 599         global file_states file_lists
 600         global is_3way_diff diff_active repo_config
 601         global ui_diff current_diff ui_status_value
 602
 603         if {$diff_active || ![lock_index read]} return
 604
 605         clear_diff
 606         if {$w eq {} || $lno == {}} {
 607                 foreach w [array names file_lists] {
 608                         set lno [lsearch -sorted $file_lists($w) $path]
 609                         if {$lno >= 0} {
 610                                 incr lno
 611                                 break
 612                         }
 613                 }
 614         }
 615         if {$w ne {} && $lno >= 1} {
 616                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 617         }
 618
 619         set s $file_states($path)
 620         set m [lindex $s 0]
 621         set is_3way_diff 0
 622         set diff_active 1
 623         set current_diff $path
 624         set ui_status_value "Loading diff of [escape_path $path]..."
 625
 626         set cmd [list | git diff-index]
 627         lappend cmd --no-color
 628         if {$repo_config(gui.diffcontext) > 0} {
 629                 lappend cmd "-U$repo_config(gui.diffcontext)"
 630         }
 631         lappend cmd -p
 632
 633         switch $m {
 634         MM {
 635                 lappend cmd -c
 636         }
 637         _O {
 638                 if {[catch {
 639                                 set fd [open $path r]
 640                                 set content [read $fd]
 641                                 close $fd
 642                         } err ]} {
 643                         set diff_active 0
 644                         unlock_index
 645                         set ui_status_value "Unable to display [escape_path $path]"
 646                         error_popup "Error loading file:\n\n$err"
 647                         return
 648                 }
 649                 $ui_diff conf -state normal
 650                 $ui_diff insert end $content
 651                 $ui_diff conf -state disabled
 652                 set diff_active 0
 653                 unlock_index
 654                 set ui_status_value {Ready.}
 655                 return
 656         }
 657         }
 658
 659         lappend cmd [PARENT]
 660         lappend cmd --
 661         lappend cmd $path
 662
 663         if {[catch {set fd [open $cmd r]} err]} {
 664                 set diff_active 0
 665                 unlock_index
 666                 set ui_status_value "Unable to display [escape_path $path]"
 667                 error_popup "Error loading diff:\n\n$err"
 668                 return
 669         }
 670
 671         fconfigure $fd -blocking 0 -translation auto
 672         fileevent $fd readable [list read_diff $fd]
 673 }
 674
 675 proc read_diff {fd} {
 676         global ui_diff ui_status_value is_3way_diff diff_active
 677         global repo_config
 678
 679         $ui_diff conf -state normal
 680         while {[gets $fd line] >= 0} {
 681                 # -- Cleanup uninteresting diff header lines.
 682                 #
 683                 if {[string match {diff --git *}      $line]} continue
 684                 if {[string match {diff --combined *} $line]} continue
 685                 if {[string match {--- *}             $line]} continue
 686                 if {[string match {+++ *}             $line]} continue
 687                 if {$line eq {deleted file mode 120000}} {
 688                         set line "deleted symlink"
 689                 }
 690
 691                 # -- Automatically detect if this is a 3 way diff.
 692                 #
 693                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 694
 695                 # -- Reformat a 3 way diff, 'cause its too weird.
 696                 #
 697                 if {$is_3way_diff} {
 698                         set op [string range $line 0 1]
 699                         switch -- $op {
 700                         {@@} {set tags d_@}
 701                         {++} {set tags d_+ ; set op { +}}
 702                         {--} {set tags d_- ; set op { -}}
 703                         { +} {set tags d_++; set op {++}}
 704                         { -} {set tags d_--; set op {--}}
 705                         {+ } {set tags d_-+; set op {-+}}
 706                         {- } {set tags d_+-; set op {+-}}
 707                         default {set tags {}}
 708                         }
 709                         set line [string replace $line 0 1 $op]
 710                 } else {
 711                         switch -- [string index $line 0] {
 712                         @ {set tags d_@}
 713                         + {set tags d_+}
 714                         - {set tags d_-}
 715                         default {set tags {}}
 716                         }
 717                 }
 718                 $ui_diff insert end $line $tags
 719                 $ui_diff insert end "\n" $tags
 720         }
 721         $ui_diff conf -state disabled
 722
 723         if {[eof $fd]} {
 724                 close $fd
 725                 set diff_active 0
 726                 unlock_index
 727                 set ui_status_value {Ready.}
 728
 729                 if {$repo_config(gui.trustmtime) eq {true}
 730                         && [$ui_diff index end] eq {2.0}} {
 731                         handle_empty_diff
 732                 }
 733         }
 734 }
 735
 736 ######################################################################
 737 ##
 738 ## commit
 739
 740 proc load_last_commit {} {
 741         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 742
 743         if {[llength $PARENT] == 0} {
 744                 error_popup {There is nothing to amend.
 745
 746 You are about to create the initial commit.
 747 There is no commit before this to amend.
 748 }
 749                 return
 750         }
 751
 752         repository_state curType curHEAD curMERGE_HEAD
 753         if {$curType eq {merge}} {
 754                 error_popup {Cannot amend while merging.
 755
 756 You are currently in the middle of a merge that
 757 has not been fully completed.  You cannot amend
 758 the prior commit unless you first abort the
 759 current merge activity.
 760 }
 761                 return
 762         }
 763
 764         set msg {}
 765         set parents [list]
 766         if {[catch {
 767                         set fd [open "| git cat-file commit $curHEAD" r]
 768                         while {[gets $fd line] > 0} {
 769                                 if {[string match {parent *} $line]} {
 770                                         lappend parents [string range $line 7 end]
 771                                 }
 772                         }
 773                         set msg [string trim [read $fd]]
 774                         close $fd
 775                 } err]} {
 776                 error_popup "Error loading commit data for amend:\n\n$err"
 777                 return
 778         }
 779
 780         set HEAD $curHEAD
 781         set PARENT $parents
 782         set MERGE_HEAD [list]
 783         switch -- [llength $parents] {
 784         0       {set commit_type amend-initial}
 785         1       {set commit_type amend}
 786         default {set commit_type amend-merge}
 787         }
 788
 789         $ui_comm delete 0.0 end
 790         $ui_comm insert end $msg
 791         $ui_comm edit reset
 792         $ui_comm edit modified false
 793         rescan {set ui_status_value {Ready.}}
 794 }
 795
 796 proc create_new_commit {} {
 797         global commit_type ui_comm
 798
 799         set commit_type normal
 800         $ui_comm delete 0.0 end
 801         $ui_comm edit reset
 802         $ui_comm edit modified false
 803         rescan {set ui_status_value {Ready.}}
 804 }
 805
 806 set GIT_COMMITTER_IDENT {}
 807
 808 proc committer_ident {} {
 809         global GIT_COMMITTER_IDENT
 810
 811         if {$GIT_COMMITTER_IDENT eq {}} {
 812                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 813                         error_popup "Unable to obtain your identity:\n\n$err"
 814                         return {}
 815                 }
 816                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 817                         $me me GIT_COMMITTER_IDENT]} {
 818                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 819                         return {}
 820                 }
 821         }
 822
 823         return $GIT_COMMITTER_IDENT
 824 }
 825
 826 proc commit_tree {} {
 827         global HEAD commit_type file_states ui_comm repo_config
 828         global ui_status_value pch_error
 829
 830         if {![lock_index update]} return
 831         if {[committer_ident] eq {}} return
 832
 833         # -- Our in memory state should match the repository.
 834         #
 835         repository_state curType curHEAD curMERGE_HEAD
 836         if {[string match amend* $commit_type]
 837                 && $curType eq {normal}
 838                 && $curHEAD eq $HEAD} {
 839         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 840                 info_popup {Last scanned state does not match repository state.
 841
 842 Another Git program has modified this repository
 843 since the last scan.  A rescan must be performed
 844 before another commit can be created.
 845
 846 The rescan will be automatically started now.
 847 }
 848                 unlock_index
 849                 rescan {set ui_status_value {Ready.}}
 850                 return
 851         }
 852
 853         # -- At least one file should differ in the index.
 854         #
 855         set files_ready 0
 856         foreach path [array names file_states] {
 857                 switch -glob -- [lindex $file_states($path) 0] {
 858                 _? {continue}
 859                 A? -
 860                 D? -
 861                 M? {set files_ready 1; break}
 862                 U? {
 863                         error_popup "Unmerged files cannot be committed.
 864
 865 File [short_path $path] has merge conflicts.
 866 You must resolve them and include the file before committing.
 867 "
 868                         unlock_index
 869                         return
 870                 }
 871                 default {
 872                         error_popup "Unknown file state [lindex $s 0] detected.
 873
 874 File [short_path $path] cannot be committed by this program.
 875 "
 876                 }
 877                 }
 878         }
 879         if {!$files_ready} {
 880                 error_popup {No included files to commit.
 881
 882 You must include at least 1 file before you can commit.
 883 }
 884                 unlock_index
 885                 return
 886         }
 887
 888         # -- A message is required.
 889         #
 890         set msg [string trim [$ui_comm get 1.0 end]]
 891         if {$msg eq {}} {
 892                 error_popup {Please supply a commit message.
 893
 894 A good commit message has the following format:
 895
 896 - First line: Describe in one sentance what you did.
 897 - Second line: Blank
 898 - Remaining lines: Describe why this change is good.
 899 }
 900                 unlock_index
 901                 return
 902         }
 903
 904         # -- Run the pre-commit hook.
 905         #
 906         set pchook [gitdir hooks pre-commit]
 907
 908         # On Cygwin [file executable] might lie so we need to ask
 909         # the shell if the hook is executable.  Yes that's annoying.
 910         #
 911         if {[is_Windows] && [file isfile $pchook]} {
 912                 set pchook [list sh -c [concat \
 913                         "if test -x \"$pchook\";" \
 914                         "then exec \"$pchook\" 2>&1;" \
 915                         "fi"]]
 916         } elseif {[file executable $pchook]} {
 917                 set pchook [list $pchook |& cat]
 918         } else {
 919                 commit_writetree $curHEAD $msg
 920                 return
 921         }
 922
 923         set ui_status_value {Calling pre-commit hook...}
 924         set pch_error {}
 925         set fd_ph [open "| $pchook" r]
 926         fconfigure $fd_ph -blocking 0 -translation binary
 927         fileevent $fd_ph readable \
 928                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 929 }
 930
 931 proc commit_prehook_wait {fd_ph curHEAD msg} {
 932         global pch_error ui_status_value
 933
 934         append pch_error [read $fd_ph]
 935         fconfigure $fd_ph -blocking 1
 936         if {[eof $fd_ph]} {
 937                 if {[catch {close $fd_ph}]} {
 938                         set ui_status_value {Commit declined by pre-commit hook.}
 939                         hook_failed_popup pre-commit $pch_error
 940                         unlock_index
 941                 } else {
 942                         commit_writetree $curHEAD $msg
 943                 }
 944                 set pch_error {}
 945                 return
 946         }
 947         fconfigure $fd_ph -blocking 0
 948 }
 949
 950 proc commit_writetree {curHEAD msg} {
 951         global ui_status_value
 952
 953         set ui_status_value {Committing changes...}
 954         set fd_wt [open "| git write-tree" r]
 955         fileevent $fd_wt readable \
 956                 [list commit_committree $fd_wt $curHEAD $msg]
 957 }
 958
 959 proc commit_committree {fd_wt curHEAD msg} {
 960         global HEAD PARENT MERGE_HEAD commit_type
 961         global single_commit
 962         global ui_status_value ui_comm selected_commit_type
 963         global file_states selected_paths rescan_active
 964
 965         gets $fd_wt tree_id
 966         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 967                 error_popup "write-tree failed:\n\n$err"
 968                 set ui_status_value {Commit failed.}
 969                 unlock_index
 970                 return
 971         }
 972
 973         # -- Create the commit.
 974         #
 975         set cmd [list git commit-tree $tree_id]
 976         set parents [concat $PARENT $MERGE_HEAD]
 977         if {[llength $parents] > 0} {
 978                 foreach p $parents {
 979                         lappend cmd -p $p
 980                 }
 981         } else {
 982                 # git commit-tree writes to stderr during initial commit.
 983                 lappend cmd 2>/dev/null
 984         }
 985         lappend cmd << $msg
 986         if {[catch {set cmt_id [eval exec $cmd]} err]} {
 987                 error_popup "commit-tree failed:\n\n$err"
 988                 set ui_status_value {Commit failed.}
 989                 unlock_index
 990                 return
 991         }
 992
 993         # -- Update the HEAD ref.
 994         #
 995         set reflogm commit
 996         if {$commit_type ne {normal}} {
 997                 append reflogm " ($commit_type)"
 998         }
 999         set i [string first "\n" $msg]
1000         if {$i >= 0} {
1001                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1002         } else {
1003                 append reflogm {: } $msg
1004         }
1005         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1006         if {[catch {eval exec $cmd} err]} {
1007                 error_popup "update-ref failed:\n\n$err"
1008                 set ui_status_value {Commit failed.}
1009                 unlock_index
1010                 return
1011         }
1012
1013         # -- Cleanup after ourselves.
1014         #
1015         catch {file delete [gitdir MERGE_HEAD]}
1016         catch {file delete [gitdir MERGE_MSG]}
1017         catch {file delete [gitdir SQUASH_MSG]}
1018         catch {file delete [gitdir GITGUI_MSG]}
1019
1020         # -- Let rerere do its thing.
1021         #
1022         if {[file isdirectory [gitdir rr-cache]]} {
1023                 catch {exec git rerere}
1024         }
1025
1026         # -- Run the post-commit hook.
1027         #
1028         set pchook [gitdir hooks post-commit]
1029         if {[is_Windows] && [file isfile $pchook]} {
1030                 set pchook [list sh -c [concat \
1031                         "if test -x \"$pchook\";" \
1032                         "then exec \"$pchook\";" \
1033                         "fi"]]
1034         } elseif {![file executable $pchook]} {
1035                 set pchook {}
1036         }
1037         if {$pchook ne {}} {
1038                 catch {exec $pchook &}
1039         }
1040
1041         $ui_comm delete 0.0 end
1042         $ui_comm edit reset
1043         $ui_comm edit modified false
1044
1045         if {$single_commit} do_quit
1046
1047         # -- Update in memory status
1048         #
1049         set selected_commit_type new
1050         set commit_type normal
1051         set HEAD $cmt_id
1052         set PARENT $cmt_id
1053         set MERGE_HEAD [list]
1054
1055         foreach path [array names file_states] {
1056                 set s $file_states($path)
1057                 set m [lindex $s 0]
1058                 switch -glob -- $m {
1059                 _O -
1060                 _M -
1061                 _D {continue}
1062                 __ -
1063                 A_ -
1064                 M_ -
1065                 D_ {
1066                         unset file_states($path)
1067                         catch {unset selected_paths($path)}
1068                 }
1069                 DO {
1070                         set file_states($path) [list _O [lindex $s 1] {} {}]
1071                 }
1072                 AM -
1073                 AD -
1074                 MM -
1075                 MD {
1076                         set file_states($path) [list \
1077                                 _[string index $m 1] \
1078                                 [lindex $s 1] \
1079                                 [lindex $s 3] \
1080                                 {}]
1081                 }
1082                 }
1083         }
1084
1085         display_all_files
1086         unlock_index
1087         reshow_diff
1088         set ui_status_value \
1089                 "Changes committed as [string range $cmt_id 0 7]."
1090 }
1091
1092 ######################################################################
1093 ##
1094 ## fetch pull push
1095
1096 proc fetch_from {remote} {
1097         set w [new_console "fetch $remote" \
1098                 "Fetching new changes from $remote"]
1099         set cmd [list git fetch]
1100         lappend cmd $remote
1101         console_exec $w $cmd
1102 }
1103
1104 proc pull_remote {remote branch} {
1105         global HEAD commit_type file_states repo_config
1106
1107         if {![lock_index update]} return
1108
1109         # -- Our in memory state should match the repository.
1110         #
1111         repository_state curType curHEAD curMERGE_HEAD
1112         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1113                 info_popup {Last scanned state does not match repository state.
1114
1115 Another Git program has modified this repository
1116 since the last scan.  A rescan must be performed
1117 before a pull operation can be started.
1118
1119 The rescan will be automatically started now.
1120 }
1121                 unlock_index
1122                 rescan {set ui_status_value {Ready.}}
1123                 return
1124         }
1125
1126         # -- No differences should exist before a pull.
1127         #
1128         if {[array size file_states] != 0} {
1129                 error_popup {Uncommitted but modified files are present.
1130
1131 You should not perform a pull with unmodified
1132 files in your working directory as Git will be
1133 unable to recover from an incorrect merge.
1134
1135 You should commit or revert all changes before
1136 starting a pull operation.
1137 }
1138                 unlock_index
1139                 return
1140         }
1141
1142         set w [new_console "pull $remote $branch" \
1143                 "Pulling new changes from branch $branch in $remote"]
1144         set cmd [list git pull]
1145         if {$repo_config(gui.pullsummary) eq {false}} {
1146                 lappend cmd --no-summary
1147         }
1148         lappend cmd $remote
1149         lappend cmd $branch
1150         console_exec $w $cmd [list post_pull_remote $remote $branch]
1151 }
1152
1153 proc post_pull_remote {remote branch success} {
1154         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1155         global ui_status_value
1156
1157         unlock_index
1158         if {$success} {
1159                 repository_state commit_type HEAD MERGE_HEAD
1160                 set PARENT $HEAD
1161                 set selected_commit_type new
1162                 set ui_status_value "Pulling $branch from $remote complete."
1163         } else {
1164                 rescan [list set ui_status_value \
1165                         "Conflicts detected while pulling $branch from $remote."]
1166         }
1167 }
1168
1169 proc push_to {remote} {
1170         set w [new_console "push $remote" \
1171                 "Pushing changes to $remote"]
1172         set cmd [list git push]
1173         lappend cmd $remote
1174         console_exec $w $cmd
1175 }
1176
1177 ######################################################################
1178 ##
1179 ## ui helpers
1180
1181 proc mapicon {w state path} {
1182         global all_icons
1183
1184         if {[catch {set r $all_icons($state$w)}]} {
1185                 puts "error: no icon for $w state={$state} $path"
1186                 return file_plain
1187         }
1188         return $r
1189 }
1190
1191 proc mapdesc {state path} {
1192         global all_descs
1193
1194         if {[catch {set r $all_descs($state)}]} {
1195                 puts "error: no desc for state={$state} $path"
1196                 return $state
1197         }
1198         return $r
1199 }
1200
1201 proc escape_path {path} {
1202         regsub -all "\n" $path "\\n" path
1203         return $path
1204 }
1205
1206 proc short_path {path} {
1207         return [escape_path [lindex [file split $path] end]]
1208 }
1209
1210 set next_icon_id 0
1211 set null_sha1 [string repeat 0 40]
1212
1213 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1214         global file_states next_icon_id null_sha1
1215
1216         set s0 [string index $new_state 0]
1217         set s1 [string index $new_state 1]
1218
1219         if {[catch {set info $file_states($path)}]} {
1220                 set state __
1221                 set icon n[incr next_icon_id]
1222         } else {
1223                 set state [lindex $info 0]
1224                 set icon [lindex $info 1]
1225                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1226                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1227         }
1228
1229         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1230         elseif {$s0 eq {_}} {set s0 _}
1231
1232         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1233         elseif {$s1 eq {_}} {set s1 _}
1234
1235         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1236                 set head_info [list 0 $null_sha1]
1237         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1238                 && $head_info eq {}} {
1239                 set head_info $index_info
1240         }
1241
1242         set file_states($path) [list $s0$s1 $icon \
1243                 $head_info $index_info \
1244                 ]
1245         return $state
1246 }
1247
1248 proc display_file_helper {w path icon_name old_m new_m} {
1249         global file_lists
1250
1251         if {$new_m eq {_}} {
1252                 set lno [lsearch -sorted $file_lists($w) $path]
1253                 if {$lno >= 0} {
1254                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1255                         incr lno
1256                         $w conf -state normal
1257                         $w delete $lno.0 [expr {$lno + 1}].0
1258                         $w conf -state disabled
1259                 }
1260         } elseif {$old_m eq {_} && $new_m ne {_}} {
1261                 lappend file_lists($w) $path
1262                 set file_lists($w) [lsort -unique $file_lists($w)]
1263                 set lno [lsearch -sorted $file_lists($w) $path]
1264                 incr lno
1265                 $w conf -state normal
1266                 $w image create $lno.0 \
1267                         -align center -padx 5 -pady 1 \
1268                         -name $icon_name \
1269                         -image [mapicon $w $new_m $path]
1270                 $w insert $lno.1 "[escape_path $path]\n"
1271                 $w conf -state disabled
1272         } elseif {$old_m ne $new_m} {
1273                 $w conf -state normal
1274                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1275                 $w conf -state disabled
1276         }
1277 }
1278
1279 proc display_file {path state} {
1280         global file_states selected_paths
1281         global ui_index ui_workdir
1282
1283         set old_m [merge_state $path $state]
1284         set s $file_states($path)
1285         set new_m [lindex $s 0]
1286         set icon_name [lindex $s 1]
1287
1288         display_file_helper     $ui_index $path $icon_name \
1289                 [string index $old_m 0] \
1290                 [string index $new_m 0]
1291         display_file_helper     $ui_workdir $path $icon_name \
1292                 [string index $old_m 1] \
1293                 [string index $new_m 1]
1294
1295         if {$new_m eq {__}} {
1296                 unset file_states($path)
1297                 catch {unset selected_paths($path)}
1298         }
1299 }
1300
1301 proc display_all_files_helper {w path icon_name m} {
1302         global file_lists
1303
1304         lappend file_lists($w) $path
1305         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1306         $w image create end \
1307                 -align center -padx 5 -pady 1 \
1308                 -name $icon_name \
1309                 -image [mapicon $w $m $path]
1310         $w insert end "[escape_path $path]\n"
1311 }
1312
1313 proc display_all_files {} {
1314         global ui_index ui_workdir
1315         global file_states file_lists
1316         global last_clicked
1317
1318         $ui_index conf -state normal
1319         $ui_workdir conf -state normal
1320
1321         $ui_index delete 0.0 end
1322         $ui_workdir delete 0.0 end
1323         set last_clicked {}
1324
1325         set file_lists($ui_index) [list]
1326         set file_lists($ui_workdir) [list]
1327
1328         foreach path [lsort [array names file_states]] {
1329                 set s $file_states($path)
1330                 set m [lindex $s 0]
1331                 set icon_name [lindex $s 1]
1332
1333                 if {[string index $m 0] ne {_}} {
1334                         display_all_files_helper $ui_index $path \
1335                                 $icon_name [string index $m 0]
1336                 }
1337                 if {[string index $m 1] ne {_}} {
1338                         display_all_files_helper $ui_workdir $path \
1339                                 $icon_name [string index $m 1]
1340                 }
1341         }
1342
1343         $ui_index conf -state disabled
1344         $ui_workdir conf -state disabled
1345 }
1346
1347 proc update_indexinfo {msg pathList after} {
1348         global update_index_cp ui_status_value
1349
1350         if {![lock_index update]} return
1351
1352         set update_index_cp 0
1353         set pathList [lsort $pathList]
1354         set totalCnt [llength $pathList]
1355         set batch [expr {int($totalCnt * .01) + 1}]
1356         if {$batch > 25} {set batch 25}
1357
1358         set ui_status_value [format \
1359                 "$msg... %i/%i files (%.2f%%)" \
1360                 $update_index_cp \
1361                 $totalCnt \
1362                 0.0]
1363         set fd [open "| git update-index -z --index-info" w]
1364         fconfigure $fd \
1365                 -blocking 0 \
1366                 -buffering full \
1367                 -buffersize 512 \
1368                 -translation binary
1369         fileevent $fd writable [list \
1370                 write_update_indexinfo \
1371                 $fd \
1372                 $pathList \
1373                 $totalCnt \
1374                 $batch \
1375                 $msg \
1376                 $after \
1377                 ]
1378 }
1379
1380 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1381         global update_index_cp ui_status_value
1382         global file_states current_diff
1383
1384         if {$update_index_cp >= $totalCnt} {
1385                 close $fd
1386                 unlock_index
1387                 uplevel #0 $after
1388                 return
1389         }
1390
1391         for {set i $batch} \
1392                 {$update_index_cp < $totalCnt && $i > 0} \
1393                 {incr i -1} {
1394                 set path [lindex $pathList $update_index_cp]
1395                 incr update_index_cp
1396
1397                 set s $file_states($path)
1398                 switch -glob -- [lindex $s 0] {
1399                 A? {set new _O}
1400                 M? {set new _M}
1401                 D_ {set new _D}
1402                 D? {set new _?}
1403                 ?? {continue}
1404                 }
1405                 set info [lindex $s 2]
1406                 if {$info eq {}} continue
1407
1408                 puts -nonewline $fd "$info\t$path\0"
1409                 display_file $path $new
1410         }
1411
1412         set ui_status_value [format \
1413                 "$msg... %i/%i files (%.2f%%)" \
1414                 $update_index_cp \
1415                 $totalCnt \
1416                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1417 }
1418
1419 proc update_index {msg pathList after} {
1420         global update_index_cp ui_status_value
1421
1422         if {![lock_index update]} return
1423
1424         set update_index_cp 0
1425         set pathList [lsort $pathList]
1426         set totalCnt [llength $pathList]
1427         set batch [expr {int($totalCnt * .01) + 1}]
1428         if {$batch > 25} {set batch 25}
1429
1430         set ui_status_value [format \
1431                 "$msg... %i/%i files (%.2f%%)" \
1432                 $update_index_cp \
1433                 $totalCnt \
1434                 0.0]
1435         set fd [open "| git update-index --add --remove -z --stdin" w]
1436         fconfigure $fd \
1437                 -blocking 0 \
1438                 -buffering full \
1439                 -buffersize 512 \
1440                 -translation binary
1441         fileevent $fd writable [list \
1442                 write_update_index \
1443                 $fd \
1444                 $pathList \
1445                 $totalCnt \
1446                 $batch \
1447                 $msg \
1448                 $after \
1449                 ]
1450 }
1451
1452 proc write_update_index {fd pathList totalCnt batch msg after} {
1453         global update_index_cp ui_status_value
1454         global file_states current_diff
1455
1456         if {$update_index_cp >= $totalCnt} {
1457                 close $fd
1458                 unlock_index
1459                 uplevel #0 $after
1460                 return
1461         }
1462
1463         for {set i $batch} \
1464                 {$update_index_cp < $totalCnt && $i > 0} \
1465                 {incr i -1} {
1466                 set path [lindex $pathList $update_index_cp]
1467                 incr update_index_cp
1468
1469                 switch -glob -- [lindex $file_states($path) 0] {
1470                 AD {set new __}
1471                 ?D {set new D_}
1472                 _O -
1473                 AM {set new A_}
1474                 U_ -
1475                 ?M {set new M_}
1476                 ?? {continue}
1477                 }
1478                 puts -nonewline $fd "$path\0"
1479                 display_file $path $new
1480         }
1481
1482         set ui_status_value [format \
1483                 "$msg... %i/%i files (%.2f%%)" \
1484                 $update_index_cp \
1485                 $totalCnt \
1486                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1487 }
1488
1489 proc checkout_index {msg pathList after} {
1490         global update_index_cp ui_status_value
1491
1492         if {![lock_index update]} return
1493
1494         set update_index_cp 0
1495         set pathList [lsort $pathList]
1496         set totalCnt [llength $pathList]
1497         set batch [expr {int($totalCnt * .01) + 1}]
1498         if {$batch > 25} {set batch 25}
1499
1500         set ui_status_value [format \
1501                 "$msg... %i/%i files (%.2f%%)" \
1502                 $update_index_cp \
1503                 $totalCnt \
1504                 0.0]
1505         set cmd [list git checkout-index]
1506         lappend cmd --index
1507         lappend cmd --quiet
1508         lappend cmd --force
1509         lappend cmd -z
1510         lappend cmd --stdin
1511         set fd [open "| $cmd " w]
1512         fconfigure $fd \
1513                 -blocking 0 \
1514                 -buffering full \
1515                 -buffersize 512 \
1516                 -translation binary
1517         fileevent $fd writable [list \
1518                 write_checkout_index \
1519                 $fd \
1520                 $pathList \
1521                 $totalCnt \
1522                 $batch \
1523                 $msg \
1524                 $after \
1525                 ]
1526 }
1527
1528 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1529         global update_index_cp ui_status_value
1530         global file_states current_diff
1531
1532         if {$update_index_cp >= $totalCnt} {
1533                 close $fd
1534                 unlock_index
1535                 uplevel #0 $after
1536                 return
1537         }
1538
1539         for {set i $batch} \
1540                 {$update_index_cp < $totalCnt && $i > 0} \
1541                 {incr i -1} {
1542                 set path [lindex $pathList $update_index_cp]
1543                 incr update_index_cp
1544                 switch -glob -- [lindex $file_states($path) 0] {
1545                 U? {continue}
1546                 ?M -
1547                 ?D {
1548                         puts -nonewline $fd "$path\0"
1549                         display_file $path ?_
1550                 }
1551                 }
1552         }
1553
1554         set ui_status_value [format \
1555                 "$msg... %i/%i files (%.2f%%)" \
1556                 $update_index_cp \
1557                 $totalCnt \
1558                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1559 }
1560
1561 ######################################################################
1562 ##
1563 ## branch management
1564
1565 proc load_all_heads {} {
1566         global all_heads tracking_branches
1567
1568         set all_heads [list]
1569         set cmd [list git for-each-ref]
1570         lappend cmd --format=%(refname)
1571         lappend cmd refs/heads
1572         set fd [open "| $cmd" r]
1573         while {[gets $fd line] > 0} {
1574                 if {![catch {set info $tracking_branches($line)}]} continue
1575                 if {![regsub ^refs/heads/ $line {} name]} continue
1576                 lappend all_heads $name
1577         }
1578         close $fd
1579
1580         set all_heads [lsort $all_heads]
1581 }
1582
1583 proc populate_branch_menu {} {
1584         global all_heads disable_on_lock
1585
1586         set m .mbar.branch
1587         set last [$m index last]
1588         for {set i 0} {$i <= $last} {incr i} {
1589                 if {[$m type $i] eq {separator}} {
1590                         $m delete $i last
1591                         set new_dol [list]
1592                         foreach a $disable_on_lock {
1593                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1594                                         lappend new_dol $a
1595                                 }
1596                         }
1597                         set disable_on_lock $new_dol
1598                         break
1599                 }
1600         }
1601
1602         $m add separator
1603         foreach b $all_heads {
1604                 $m add radiobutton \
1605                         -label $b \
1606                         -command [list switch_branch $b] \
1607                         -variable current_branch \
1608                         -value $b \
1609                         -font font_ui
1610                 lappend disable_on_lock \
1611                         [list $m entryconf [$m index last] -state]
1612         }
1613 }
1614
1615 proc do_create_branch_action {w} {
1616         global all_heads null_sha1
1617         global create_branch_checkout create_branch_revtype
1618         global create_branch_head create_branch_trackinghead
1619
1620         set newbranch [string trim [$w.name.t get 0.0 end]]
1621         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1622                 tk_messageBox \
1623                         -icon error \
1624                         -type ok \
1625                         -title [wm title $w] \
1626                         -parent $w \
1627                         -message "Branch '$newbranch' already exists."
1628                 focus $w.name.t
1629                 return
1630         }
1631         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1632                 tk_messageBox \
1633                         -icon error \
1634                         -type ok \
1635                         -title [wm title $w] \
1636                         -parent $w \
1637                         -message "We do not like '$newbranch' as a branch name."
1638                 focus $w.name.t
1639                 return
1640         }
1641
1642         set rev {}
1643         switch -- $create_branch_revtype {
1644         head {set rev $create_branch_head}
1645         tracking {set rev $create_branch_trackinghead}
1646         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1647         }
1648         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1649                 tk_messageBox \
1650                         -icon error \
1651                         -type ok \
1652                         -title [wm title $w] \
1653                         -parent $w \
1654                         -message "Invalid starting revision: $rev"
1655                 return
1656         }
1657         set cmd [list git update-ref]
1658         lappend cmd -m
1659         lappend cmd "branch: Created from $rev"
1660         lappend cmd "refs/heads/$newbranch"
1661         lappend cmd $cmt
1662         lappend cmd $null_sha1
1663         if {[catch {eval exec $cmd} err]} {
1664                 tk_messageBox \
1665                         -icon error \
1666                         -type ok \
1667                         -title [wm title $w] \
1668                         -parent $w \
1669                         -message "Failed to create '$newbranch'.\n\n$err"
1670                 return
1671         }
1672
1673         lappend all_heads $newbranch
1674         set all_heads [lsort $all_heads]
1675         populate_branch_menu
1676         destroy $w
1677 }
1678
1679 proc do_create_branch {} {
1680         global all_heads current_branch tracking_branches
1681         global create_branch_checkout create_branch_revtype
1682         global create_branch_head create_branch_trackinghead
1683
1684         set create_branch_checkout true
1685         set create_branch_revtype head
1686         set create_branch_head $current_branch
1687         set create_branch_trackinghead {}
1688
1689         set w .branch_editor
1690         toplevel $w
1691         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1692
1693         label $w.header -text {Create New Branch} \
1694                 -font font_uibold
1695         pack $w.header -side top -fill x
1696
1697         frame $w.buttons
1698         button $w.buttons.create -text Create \
1699                 -font font_ui \
1700                 -default active \
1701                 -command [list do_create_branch_action $w]
1702         pack $w.buttons.create -side right
1703         button $w.buttons.cancel -text {Cancel} \
1704                 -font font_ui \
1705                 -command [list destroy $w]
1706         pack $w.buttons.cancel -side right -padx 5
1707         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1708
1709         labelframe $w.name \
1710                 -text {Branch Description} \
1711                 -font font_ui
1712         label $w.name.l -text {Name:} -font font_ui
1713         text $w.name.t \
1714                 -borderwidth 1 \
1715                 -relief sunken \
1716                 -height 1 \
1717                 -width 40 \
1718                 -font font_ui
1719         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1720         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1721         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1722         bind $w.name.t <Key> {
1723                 if {{%K} ne {BackSpace}
1724                         && {%K} ne {Tab}
1725                         && {%K} ne {Escape}
1726                         && {%K} ne {Return}} {
1727                         if {%k <= 32} break
1728                         if {[string first %A {~^:?*[}] >= 0} break
1729                 }
1730         }
1731         pack $w.name.l -side left -padx 5
1732         pack $w.name.t -side left -fill x -expand 1
1733         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1734
1735         set all_trackings [list]
1736         foreach b [array names tracking_branches] {
1737                 regsub ^refs/(heads|remotes)/ $b {} b
1738                 lappend all_trackings $b
1739         }
1740         set all_trackings [lsort -unique $all_trackings]
1741         if {$all_trackings ne {}} {
1742                 set create_branch_trackinghead [lindex $all_trackings 0]
1743         }
1744
1745         labelframe $w.from \
1746                 -text {Starting Revision} \
1747                 -font font_ui
1748         frame $w.from.head
1749         radiobutton $w.from.head.r \
1750                 -text {Local Branch:} \
1751                 -value head \
1752                 -variable create_branch_revtype \
1753                 -font font_ui
1754         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1755         pack $w.from.head.r -side left
1756         pack $w.from.head.m -side left
1757         frame $w.from.tracking
1758         radiobutton $w.from.tracking.r \
1759                 -text {Tracking Branch:} \
1760                 -value tracking \
1761                 -variable create_branch_revtype \
1762                 -font font_ui
1763         eval tk_optionMenu $w.from.tracking.m \
1764                 create_branch_trackinghead \
1765                 $all_trackings
1766         pack $w.from.tracking.r -side left
1767         pack $w.from.tracking.m -side left
1768         frame $w.from.exp
1769         radiobutton $w.from.exp.r \
1770                 -text {Revision Expression:} \
1771                 -value expression \
1772                 -variable create_branch_revtype \
1773                 -font font_ui
1774         text $w.from.exp.t \
1775                 -borderwidth 1 \
1776                 -relief sunken \
1777                 -height 1 \
1778                 -width 50 \
1779                 -font font_ui
1780         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1781         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1782         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1783         pack $w.from.exp.r -side left
1784         pack $w.from.exp.t -side left -fill x -expand 1
1785         pack $w.from.head -padx 5 -fill x -expand 1
1786         pack $w.from.tracking -padx 5 -fill x -expand 1
1787         pack $w.from.exp -padx 5 -fill x -expand 1
1788         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1789
1790         labelframe $w.postActions \
1791                 -text {Post Creation Actions} \
1792                 -font font_ui
1793         checkbutton $w.postActions.checkout \
1794                 -text {Checkout after creation} \
1795                 -offvalue false \
1796                 -onvalue true \
1797                 -variable create_branch_checkout \
1798                 -font font_ui
1799         pack $w.postActions.checkout -anchor nw
1800         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1801
1802         bind $w <Visibility> "grab $w; focus $w.name.t"
1803         bind $w <Key-Escape> "destroy $w"
1804         bind $w <Key-Return> "do_create_branch_action $w;break"
1805         wm title $w "[appname] ([reponame]): Create Branch"
1806         tkwait window $w
1807 }
1808
1809 proc do_delete_branch_action {w} {
1810         global all_heads
1811         global delete_branch_checkhead delete_branch_head
1812
1813         set to_delete [list]
1814         set not_merged [list]
1815         foreach i [$w.list.l curselection] {
1816                 set b [$w.list.l get $i]
1817                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1818                 if {$delete_branch_checkhead} {
1819                         if {$b eq $delete_branch_head} continue
1820                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1821                         if {$o ne $m} {
1822                                 lappend not_merged $b
1823                                 continue
1824                         }
1825                 }
1826                 lappend to_delete [list $b $o]
1827         }
1828         if {$not_merged ne {}} {
1829                 set msg "The following branches are not completely merged into $delete_branch_head:
1830
1831  - [join $not_merged "\n - "]"
1832                 tk_messageBox \
1833                         -icon info \
1834                         -type ok \
1835                         -title [wm title $w] \
1836                         -parent $w \
1837                         -message $msg
1838         }
1839         if {$to_delete eq {}} return
1840         if {!$delete_branch_checkhead} {
1841                 set msg {Recovering deleted branches is difficult.
1842
1843 Delete the selected branches?}
1844                 if {[tk_messageBox \
1845                         -icon warning \
1846                         -type yesno \
1847                         -title [wm title $w] \
1848                         -parent $w \
1849                         -message $msg] ne yes} {
1850                         return
1851                 }
1852         }
1853
1854         set failed {}
1855         foreach i $to_delete {
1856                 set b [lindex $i 0]
1857                 set o [lindex $i 1]
1858                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1859                         append failed " - $b: $err\n"
1860                 } else {
1861                         set x [lsearch -sorted $all_heads $b]
1862                         if {$x >= 0} {
1863                                 set all_heads [lreplace $all_heads $x $x]
1864                         }
1865                 }
1866         }
1867
1868         if {$failed ne {}} {
1869                 tk_messageBox \
1870                         -icon error \
1871                         -type ok \
1872                         -title [wm title $w] \
1873                         -parent $w \
1874                         -message "Failed to delete branches:\n$failed"
1875         }
1876
1877         set all_heads [lsort $all_heads]
1878         populate_branch_menu
1879         destroy $w
1880 }
1881
1882 proc do_delete_branch {} {
1883         global all_heads tracking_branches current_branch
1884         global delete_branch_checkhead delete_branch_head
1885
1886         set delete_branch_checkhead 1
1887         set delete_branch_head $current_branch
1888
1889         set w .branch_editor
1890         toplevel $w
1891         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1892
1893         label $w.header -text {Delete Local Branch} \
1894                 -font font_uibold
1895         pack $w.header -side top -fill x
1896
1897         frame $w.buttons
1898         button $w.buttons.create -text Delete \
1899                 -font font_ui \
1900                 -command [list do_delete_branch_action $w]
1901         pack $w.buttons.create -side right
1902         button $w.buttons.cancel -text {Cancel} \
1903                 -font font_ui \
1904                 -command [list destroy $w]
1905         pack $w.buttons.cancel -side right -padx 5
1906         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1907
1908         labelframe $w.list \
1909                 -text {Local Branches} \
1910                 -font font_ui
1911         listbox $w.list.l \
1912                 -height 10 \
1913                 -width 50 \
1914                 -selectmode extended \
1915                 -font font_ui
1916         foreach h $all_heads {
1917                 if {$h ne $current_branch} {
1918                         $w.list.l insert end $h
1919                 }
1920         }
1921         pack $w.list.l -fill both -pady 5 -padx 5
1922         pack $w.list -fill both -pady 5 -padx 5
1923
1924         set all_trackings [list]
1925         foreach b [array names tracking_branches] {
1926                 regsub ^refs/(heads|remotes)/ $b {} b
1927                 lappend all_trackings $b
1928         }
1929
1930         labelframe $w.validate \
1931                 -text {Only Delete If} \
1932                 -font font_ui
1933         frame $w.validate.head
1934         checkbutton $w.validate.head.r \
1935                 -text {Already Merged Into:} \
1936                 -variable delete_branch_checkhead \
1937                 -font font_ui
1938         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1939                 $all_heads \
1940                 [lsort -unique $all_trackings]
1941         pack $w.validate.head.r -side left
1942         pack $w.validate.head.m -side left
1943         pack $w.validate.head -padx 5 -fill x -expand 1
1944         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1945
1946         bind $w <Visibility> "grab $w; focus $w"
1947         bind $w <Key-Escape> "destroy $w"
1948         wm title $w "[appname] ([reponame]): Delete Branch"
1949         tkwait window $w
1950 }
1951
1952 proc switch_branch {b} {
1953         global HEAD commit_type file_states current_branch
1954         global selected_commit_type ui_comm
1955
1956         if {![lock_index switch]} return
1957
1958         # -- Backup the selected branch (repository_state resets it)
1959         #
1960         set new_branch $current_branch
1961
1962         # -- Our in memory state should match the repository.
1963         #
1964         repository_state curType curHEAD curMERGE_HEAD
1965         if {[string match amend* $commit_type]
1966                 && $curType eq {normal}
1967                 && $curHEAD eq $HEAD} {
1968         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1969                 info_popup {Last scanned state does not match repository state.
1970
1971 Another Git program has modified this repository
1972 since the last scan.  A rescan must be performed
1973 before the current branch can be changed.
1974
1975 The rescan will be automatically started now.
1976 }
1977                 unlock_index
1978                 rescan {set ui_status_value {Ready.}}
1979                 return
1980         }
1981
1982         # -- Toss the message buffer if we are in amend mode.
1983         #
1984         if {[string match amend* $curType]} {
1985                 $ui_comm delete 0.0 end
1986                 $ui_comm edit reset
1987                 $ui_comm edit modified false
1988         }
1989
1990         set selected_commit_type new
1991         set current_branch $new_branch
1992
1993         unlock_index
1994         error "NOT FINISHED"
1995 }
1996
1997 ######################################################################
1998 ##
1999 ## remote management
2000
2001 proc load_all_remotes {} {
2002         global repo_config
2003         global all_remotes tracking_branches
2004
2005         set all_remotes [list]
2006         array unset tracking_branches
2007
2008         set rm_dir [gitdir remotes]
2009         if {[file isdirectory $rm_dir]} {
2010                 set all_remotes [glob \
2011                         -types f \
2012                         -tails \
2013                         -nocomplain \
2014                         -directory $rm_dir *]
2015
2016                 foreach name $all_remotes {
2017                         catch {
2018                                 set fd [open [file join $rm_dir $name] r]
2019                                 while {[gets $fd line] >= 0} {
2020                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2021                                                 $line line src dst]} continue
2022                                         if {![regexp ^refs/ $dst]} {
2023                                                 set dst "refs/heads/$dst"
2024                                         }
2025                                         set tracking_branches($dst) [list $name $src]
2026                                 }
2027                                 close $fd
2028                         }
2029                 }
2030         }
2031
2032         foreach line [array names repo_config remote.*.url] {
2033                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2034                 lappend all_remotes $name
2035
2036                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2037                         set fl {}
2038                 }
2039                 foreach line $fl {
2040                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2041                         if {![regexp ^refs/ $dst]} {
2042                                 set dst "refs/heads/$dst"
2043                         }
2044                         set tracking_branches($dst) [list $name $src]
2045                 }
2046         }
2047
2048         set all_remotes [lsort -unique $all_remotes]
2049 }
2050
2051 proc populate_fetch_menu {m} {
2052         global all_remotes repo_config
2053
2054         foreach r $all_remotes {
2055                 set enable 0
2056                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2057                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2058                                 set enable 1
2059                         }
2060                 } else {
2061                         catch {
2062                                 set fd [open [gitdir remotes $r] r]
2063                                 while {[gets $fd n] >= 0} {
2064                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2065                                                 set enable 1
2066                                                 break
2067                                         }
2068                                 }
2069                                 close $fd
2070                         }
2071                 }
2072
2073                 if {$enable} {
2074                         $m add command \
2075                                 -label "Fetch from $r..." \
2076                                 -command [list fetch_from $r] \
2077                                 -font font_ui
2078                 }
2079         }
2080 }
2081
2082 proc populate_push_menu {m} {
2083         global all_remotes repo_config
2084
2085         foreach r $all_remotes {
2086                 set enable 0
2087                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2088                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2089                                 set enable 1
2090                         }
2091                 } else {
2092                         catch {
2093                                 set fd [open [gitdir remotes $r] r]
2094                                 while {[gets $fd n] >= 0} {
2095                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2096                                                 set enable 1
2097                                                 break
2098                                         }
2099                                 }
2100                                 close $fd
2101                         }
2102                 }
2103
2104                 if {$enable} {
2105                         $m add command \
2106                                 -label "Push to $r..." \
2107                                 -command [list push_to $r] \
2108                                 -font font_ui
2109                 }
2110         }
2111 }
2112
2113 proc populate_pull_menu {m} {
2114         global repo_config all_remotes disable_on_lock
2115
2116         foreach remote $all_remotes {
2117                 set rb_list [list]
2118                 if {[array get repo_config remote.$remote.url] ne {}} {
2119                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2120                                 foreach line $repo_config(remote.$remote.fetch) {
2121                                         if {[regexp {^([^:]+):} $line line rb]} {
2122                                                 lappend rb_list $rb
2123                                         }
2124                                 }
2125                         }
2126                 } else {
2127                         catch {
2128                                 set fd [open [gitdir remotes $remote] r]
2129                                 while {[gets $fd line] >= 0} {
2130                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2131                                                 lappend rb_list $rb
2132                                         }
2133                                 }
2134                                 close $fd
2135                         }
2136                 }
2137
2138                 foreach rb $rb_list {
2139                         regsub ^refs/heads/ $rb {} rb_short
2140                         $m add command \
2141                                 -label "Branch $rb_short from $remote..." \
2142                                 -command [list pull_remote $remote $rb] \
2143                                 -font font_ui
2144                         lappend disable_on_lock \
2145                                 [list $m entryconf [$m index last] -state]
2146                 }
2147         }
2148 }
2149
2150 ######################################################################
2151 ##
2152 ## icons
2153
2154 set filemask {
2155 #define mask_width 14
2156 #define mask_height 15
2157 static unsigned char mask_bits[] = {
2158    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2159    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2160    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2161 }
2162
2163 image create bitmap file_plain -background white -foreground black -data {
2164 #define plain_width 14
2165 #define plain_height 15
2166 static unsigned char plain_bits[] = {
2167    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2168    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2169    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2170 } -maskdata $filemask
2171
2172 image create bitmap file_mod -background white -foreground blue -data {
2173 #define mod_width 14
2174 #define mod_height 15
2175 static unsigned char mod_bits[] = {
2176    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2177    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2178    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2179 } -maskdata $filemask
2180
2181 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2182 #define file_fulltick_width 14
2183 #define file_fulltick_height 15
2184 static unsigned char file_fulltick_bits[] = {
2185    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2186    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2187    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2188 } -maskdata $filemask
2189
2190 image create bitmap file_parttick -background white -foreground "#005050" -data {
2191 #define parttick_width 14
2192 #define parttick_height 15
2193 static unsigned char parttick_bits[] = {
2194    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2195    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2196    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2197 } -maskdata $filemask
2198
2199 image create bitmap file_question -background white -foreground black -data {
2200 #define file_question_width 14
2201 #define file_question_height 15
2202 static unsigned char file_question_bits[] = {
2203    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2204    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2205    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2206 } -maskdata $filemask
2207
2208 image create bitmap file_removed -background white -foreground red -data {
2209 #define file_removed_width 14
2210 #define file_removed_height 15
2211 static unsigned char file_removed_bits[] = {
2212    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2213    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2214    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2215 } -maskdata $filemask
2216
2217 image create bitmap file_merge -background white -foreground blue -data {
2218 #define file_merge_width 14
2219 #define file_merge_height 15
2220 static unsigned char file_merge_bits[] = {
2221    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2222    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2223    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2224 } -maskdata $filemask
2225
2226 set ui_index .vpane.files.index.list
2227 set ui_workdir .vpane.files.workdir.list
2228
2229 set all_icons(_$ui_index)   file_plain
2230 set all_icons(A$ui_index)   file_fulltick
2231 set all_icons(M$ui_index)   file_fulltick
2232 set all_icons(D$ui_index)   file_removed
2233 set all_icons(U$ui_index)   file_merge
2234
2235 set all_icons(_$ui_workdir) file_plain
2236 set all_icons(M$ui_workdir) file_mod
2237 set all_icons(D$ui_workdir) file_question
2238 set all_icons(O$ui_workdir) file_plain
2239
2240 set max_status_desc 0
2241 foreach i {
2242                 {__ "Unmodified"}
2243
2244                 {_M "Modified, not staged"}
2245                 {M_ "Staged for commit"}
2246                 {MM "Portions staged for commit"}
2247                 {MD "Staged for commit, missing"}
2248
2249                 {_O "Untracked, not staged"}
2250                 {A_ "Staged for commit"}
2251                 {AM "Portions staged for commit"}
2252                 {AD "Staged for commit, missing"}
2253
2254                 {_D "Missing"}
2255                 {D_ "Staged for removal"}
2256                 {DO "Staged for removal, still present"}
2257
2258                 {U_ "Requires merge resolution"}
2259                 {UM "Requires merge resolution"}
2260                 {UD "Requires merge resolution"}
2261         } {
2262         if {$max_status_desc < [string length [lindex $i 1]]} {
2263                 set max_status_desc [string length [lindex $i 1]]
2264         }
2265         set all_descs([lindex $i 0]) [lindex $i 1]
2266 }
2267 unset i
2268
2269 ######################################################################
2270 ##
2271 ## util
2272
2273 proc is_MacOSX {} {
2274         global tcl_platform tk_library
2275         if {[tk windowingsystem] eq {aqua}} {
2276                 return 1
2277         }
2278         return 0
2279 }
2280
2281 proc is_Windows {} {
2282         global tcl_platform
2283         if {$tcl_platform(platform) eq {windows}} {
2284                 return 1
2285         }
2286         return 0
2287 }
2288
2289 proc bind_button3 {w cmd} {
2290         bind $w <Any-Button-3> $cmd
2291         if {[is_MacOSX]} {
2292                 bind $w <Control-Button-1> $cmd
2293         }
2294 }
2295
2296 proc incr_font_size {font {amt 1}} {
2297         set sz [font configure $font -size]
2298         incr sz $amt
2299         font configure $font -size $sz
2300         font configure ${font}bold -size $sz
2301 }
2302
2303 proc hook_failed_popup {hook msg} {
2304         set w .hookfail
2305         toplevel $w
2306
2307         frame $w.m
2308         label $w.m.l1 -text "$hook hook failed:" \
2309                 -anchor w \
2310                 -justify left \
2311                 -font font_uibold
2312         text $w.m.t \
2313                 -background white -borderwidth 1 \
2314                 -relief sunken \
2315                 -width 80 -height 10 \
2316                 -font font_diff \
2317                 -yscrollcommand [list $w.m.sby set]
2318         label $w.m.l2 \
2319                 -text {You must correct the above errors before committing.} \
2320                 -anchor w \
2321                 -justify left \
2322                 -font font_uibold
2323         scrollbar $w.m.sby -command [list $w.m.t yview]
2324         pack $w.m.l1 -side top -fill x
2325         pack $w.m.l2 -side bottom -fill x
2326         pack $w.m.sby -side right -fill y
2327         pack $w.m.t -side left -fill both -expand 1
2328         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2329
2330         $w.m.t insert 1.0 $msg
2331         $w.m.t conf -state disabled
2332
2333         button $w.ok -text OK \
2334                 -width 15 \
2335                 -font font_ui \
2336                 -command "destroy $w"
2337         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2338
2339         bind $w <Visibility> "grab $w; focus $w"
2340         bind $w <Key-Return> "destroy $w"
2341         wm title $w "[appname] ([reponame]): error"
2342         tkwait window $w
2343 }
2344
2345 set next_console_id 0
2346
2347 proc new_console {short_title long_title} {
2348         global next_console_id console_data
2349         set w .console[incr next_console_id]
2350         set console_data($w) [list $short_title $long_title]
2351         return [console_init $w]
2352 }
2353
2354 proc console_init {w} {
2355         global console_cr console_data M1B
2356
2357         set console_cr($w) 1.0
2358         toplevel $w
2359         frame $w.m
2360         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2361                 -anchor w \
2362                 -justify left \
2363                 -font font_uibold
2364         text $w.m.t \
2365                 -background white -borderwidth 1 \
2366                 -relief sunken \
2367                 -width 80 -height 10 \
2368                 -font font_diff \
2369                 -state disabled \
2370                 -yscrollcommand [list $w.m.sby set]
2371         label $w.m.s -text {Working... please wait...} \
2372                 -anchor w \
2373                 -justify left \
2374                 -font font_uibold
2375         scrollbar $w.m.sby -command [list $w.m.t yview]
2376         pack $w.m.l1 -side top -fill x
2377         pack $w.m.s -side bottom -fill x
2378         pack $w.m.sby -side right -fill y
2379         pack $w.m.t -side left -fill both -expand 1
2380         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2381
2382         menu $w.ctxm -tearoff 0
2383         $w.ctxm add command -label "Copy" \
2384                 -font font_ui \
2385                 -command "tk_textCopy $w.m.t"
2386         $w.ctxm add command -label "Select All" \
2387                 -font font_ui \
2388                 -command "$w.m.t tag add sel 0.0 end"
2389         $w.ctxm add command -label "Copy All" \
2390                 -font font_ui \
2391                 -command "
2392                         $w.m.t tag add sel 0.0 end
2393                         tk_textCopy $w.m.t
2394                         $w.m.t tag remove sel 0.0 end
2395                 "
2396
2397         button $w.ok -text {Close} \
2398                 -font font_ui \
2399                 -state disabled \
2400                 -command "destroy $w"
2401         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2402
2403         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2404         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2405         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2406         bind $w <Visibility> "focus $w"
2407         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2408         return $w
2409 }
2410
2411 proc console_exec {w cmd {after {}}} {
2412         # -- Windows tosses the enviroment when we exec our child.
2413         #    But most users need that so we have to relogin. :-(
2414         #
2415         if {[is_Windows]} {
2416                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2417         }
2418
2419         # -- Tcl won't let us redirect both stdout and stderr to
2420         #    the same pipe.  So pass it through cat...
2421         #
2422         set cmd [concat | $cmd |& cat]
2423
2424         set fd_f [open $cmd r]
2425         fconfigure $fd_f -blocking 0 -translation binary
2426         fileevent $fd_f readable [list console_read $w $fd_f $after]
2427 }
2428
2429 proc console_read {w fd after} {
2430         global console_cr console_data
2431
2432         set buf [read $fd]
2433         if {$buf ne {}} {
2434                 if {![winfo exists $w]} {console_init $w}
2435                 $w.m.t conf -state normal
2436                 set c 0
2437                 set n [string length $buf]
2438                 while {$c < $n} {
2439                         set cr [string first "\r" $buf $c]
2440                         set lf [string first "\n" $buf $c]
2441                         if {$cr < 0} {set cr [expr {$n + 1}]}
2442                         if {$lf < 0} {set lf [expr {$n + 1}]}
2443
2444                         if {$lf < $cr} {
2445                                 $w.m.t insert end [string range $buf $c $lf]
2446                                 set console_cr($w) [$w.m.t index {end -1c}]
2447                                 set c $lf
2448                                 incr c
2449                         } else {
2450                                 $w.m.t delete $console_cr($w) end
2451                                 $w.m.t insert end "\n"
2452                                 $w.m.t insert end [string range $buf $c $cr]
2453                                 set c $cr
2454                                 incr c
2455                         }
2456                 }
2457                 $w.m.t conf -state disabled
2458                 $w.m.t see end
2459         }
2460
2461         fconfigure $fd -blocking 1
2462         if {[eof $fd]} {
2463                 if {[catch {close $fd}]} {
2464                         if {![winfo exists $w]} {console_init $w}
2465                         $w.m.s conf -background red -text {Error: Command Failed}
2466                         $w.ok conf -state normal
2467                         set ok 0
2468                 } elseif {[winfo exists $w]} {
2469                         $w.m.s conf -background green -text {Success}
2470                         $w.ok conf -state normal
2471                         set ok 1
2472                 }
2473                 array unset console_cr $w
2474                 array unset console_data $w
2475                 if {$after ne {}} {
2476                         uplevel #0 $after $ok
2477                 }
2478                 return
2479         }
2480         fconfigure $fd -blocking 0
2481 }
2482
2483 ######################################################################
2484 ##
2485 ## ui commands
2486
2487 set starting_gitk_msg {Starting gitk... please wait...}
2488
2489 proc do_gitk {revs} {
2490         global ui_status_value starting_gitk_msg
2491
2492         set cmd gitk
2493         if {$revs ne {}} {
2494                 append cmd { }
2495                 append cmd $revs
2496         }
2497         if {[is_Windows]} {
2498                 set cmd "sh -c \"exec $cmd\""
2499         }
2500         append cmd { &}
2501
2502         if {[catch {eval exec $cmd} err]} {
2503                 error_popup "Failed to start gitk:\n\n$err"
2504         } else {
2505                 set ui_status_value $starting_gitk_msg
2506                 after 10000 {
2507                         if {$ui_status_value eq $starting_gitk_msg} {
2508                                 set ui_status_value {Ready.}
2509                         }
2510                 }
2511         }
2512 }
2513
2514 proc do_gc {} {
2515         set w [new_console {gc} {Compressing the object database}]
2516         console_exec $w {git gc}
2517 }
2518
2519 proc do_fsck_objects {} {
2520         set w [new_console {fsck-objects} \
2521                 {Verifying the object database with fsck-objects}]
2522         set cmd [list git fsck-objects]
2523         lappend cmd --full
2524         lappend cmd --cache
2525         lappend cmd --strict
2526         console_exec $w $cmd
2527 }
2528
2529 set is_quitting 0
2530
2531 proc do_quit {} {
2532         global ui_comm is_quitting repo_config commit_type
2533
2534         if {$is_quitting} return
2535         set is_quitting 1
2536
2537         # -- Stash our current commit buffer.
2538         #
2539         set save [gitdir GITGUI_MSG]
2540         set msg [string trim [$ui_comm get 0.0 end]]
2541         if {![string match amend* $commit_type]
2542                 && [$ui_comm edit modified]
2543                 && $msg ne {}} {
2544                 catch {
2545                         set fd [open $save w]
2546                         puts $fd [string trim [$ui_comm get 0.0 end]]
2547                         close $fd
2548                 }
2549         } else {
2550                 catch {file delete $save}
2551         }
2552
2553         # -- Stash our current window geometry into this repository.
2554         #
2555         set cfg_geometry [list]
2556         lappend cfg_geometry [wm geometry .]
2557         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2558         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2559         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2560                 set rc_geometry {}
2561         }
2562         if {$cfg_geometry ne $rc_geometry} {
2563                 catch {exec git repo-config gui.geometry $cfg_geometry}
2564         }
2565
2566         destroy .
2567 }
2568
2569 proc do_rescan {} {
2570         rescan {set ui_status_value {Ready.}}
2571 }
2572
2573 proc unstage_helper {txt paths} {
2574         global file_states current_diff
2575
2576         if {![lock_index begin-update]} return
2577
2578         set pathList [list]
2579         set after {}
2580         foreach path $paths {
2581                 switch -glob -- [lindex $file_states($path) 0] {
2582                 A? -
2583                 M? -
2584                 D? {
2585                         lappend pathList $path
2586                         if {$path eq $current_diff} {
2587                                 set after {reshow_diff;}
2588                         }
2589                 }
2590                 }
2591         }
2592         if {$pathList eq {}} {
2593                 unlock_index
2594         } else {
2595                 update_indexinfo \
2596                         $txt \
2597                         $pathList \
2598                         [concat $after {set ui_status_value {Ready.}}]
2599         }
2600 }
2601
2602 proc do_unstage_selection {} {
2603         global current_diff selected_paths
2604
2605         if {[array size selected_paths] > 0} {
2606                 unstage_helper \
2607                         {Unstaging selected files from commit} \
2608                         [array names selected_paths]
2609         } elseif {$current_diff ne {}} {
2610                 unstage_helper \
2611                         "Unstaging [short_path $current_diff] from commit" \
2612                         [list $current_diff]
2613         }
2614 }
2615
2616 proc add_helper {txt paths} {
2617         global file_states current_diff
2618
2619         if {![lock_index begin-update]} return
2620
2621         set pathList [list]
2622         set after {}
2623         foreach path $paths {
2624                 switch -glob -- [lindex $file_states($path) 0] {
2625                 _O -
2626                 ?M -
2627                 ?D -
2628                 U? {
2629                         lappend pathList $path
2630                         if {$path eq $current_diff} {
2631                                 set after {reshow_diff;}
2632                         }
2633                 }
2634                 }
2635         }
2636         if {$pathList eq {}} {
2637                 unlock_index
2638         } else {
2639                 update_index \
2640                         $txt \
2641                         $pathList \
2642                         [concat $after {set ui_status_value {Ready to commit.}}]
2643         }
2644 }
2645
2646 proc do_add_selection {} {
2647         global current_diff selected_paths
2648
2649         if {[array size selected_paths] > 0} {
2650                 add_helper \
2651                         {Adding selected files} \
2652                         [array names selected_paths]
2653         } elseif {$current_diff ne {}} {
2654                 add_helper \
2655                         "Adding [short_path $current_diff]" \
2656                         [list $current_diff]
2657         }
2658 }
2659
2660 proc do_add_all {} {
2661         global file_states
2662
2663         set paths [list]
2664         foreach path [array names file_states] {
2665                 switch -glob -- [lindex $file_states($path) 0] {
2666                 U? {continue}
2667                 ?M -
2668                 ?D {lappend paths $path}
2669                 }
2670         }
2671         add_helper {Adding all changed files} $paths
2672 }
2673
2674 proc revert_helper {txt paths} {
2675         global file_states current_diff
2676
2677         if {![lock_index begin-update]} return
2678
2679         set pathList [list]
2680         set after {}
2681         foreach path $paths {
2682                 switch -glob -- [lindex $file_states($path) 0] {
2683                 U? {continue}
2684                 ?M -
2685                 ?D {
2686                         lappend pathList $path
2687                         if {$path eq $current_diff} {
2688                                 set after {reshow_diff;}
2689                         }
2690                 }
2691                 }
2692         }
2693
2694         set n [llength $pathList]
2695         if {$n == 0} {
2696                 unlock_index
2697                 return
2698         } elseif {$n == 1} {
2699                 set s "[short_path [lindex $pathList]]"
2700         } else {
2701                 set s "these $n files"
2702         }
2703
2704         set reply [tk_dialog \
2705                 .confirm_revert \
2706                 "[appname] ([reponame])" \
2707                 "Revert changes in $s?
2708
2709 Any unadded changes will be permanently lost by the revert." \
2710                 question \
2711                 1 \
2712                 {Do Nothing} \
2713                 {Revert Changes} \
2714                 ]
2715         if {$reply == 1} {
2716                 checkout_index \
2717                         $txt \
2718                         $pathList \
2719                         [concat $after {set ui_status_value {Ready.}}]
2720         } else {
2721                 unlock_index
2722         }
2723 }
2724
2725 proc do_revert_selection {} {
2726         global current_diff selected_paths
2727
2728         if {[array size selected_paths] > 0} {
2729                 revert_helper \
2730                         {Reverting selected files} \
2731                         [array names selected_paths]
2732         } elseif {$current_diff ne {}} {
2733                 revert_helper \
2734                         "Reverting [short_path $current_diff]" \
2735                         [list $current_diff]
2736         }
2737 }
2738
2739 proc do_signoff {} {
2740         global ui_comm
2741
2742         set me [committer_ident]
2743         if {$me eq {}} return
2744
2745         set sob "Signed-off-by: $me"
2746         set last [$ui_comm get {end -1c linestart} {end -1c}]
2747         if {$last ne $sob} {
2748                 $ui_comm edit separator
2749                 if {$last ne {}
2750                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2751                         $ui_comm insert end "\n"
2752                 }
2753                 $ui_comm insert end "\n$sob"
2754                 $ui_comm edit separator
2755                 $ui_comm see end
2756         }
2757 }
2758
2759 proc do_select_commit_type {} {
2760         global commit_type selected_commit_type
2761
2762         if {$selected_commit_type eq {new}
2763                 && [string match amend* $commit_type]} {
2764                 create_new_commit
2765         } elseif {$selected_commit_type eq {amend}
2766                 && ![string match amend* $commit_type]} {
2767                 load_last_commit
2768
2769                 # The amend request was rejected...
2770                 #
2771                 if {![string match amend* $commit_type]} {
2772                         set selected_commit_type new
2773                 }
2774         }
2775 }
2776
2777 proc do_commit {} {
2778         commit_tree
2779 }
2780
2781 proc do_about {} {
2782         global appvers copyright
2783         global tcl_patchLevel tk_patchLevel
2784
2785         set w .about_dialog
2786         toplevel $w
2787         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2788
2789         label $w.header -text "About [appname]" \
2790                 -font font_uibold
2791         pack $w.header -side top -fill x
2792
2793         frame $w.buttons
2794         button $w.buttons.close -text {Close} \
2795                 -font font_ui \
2796                 -command [list destroy $w]
2797         pack $w.buttons.close -side right
2798         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2799
2800         label $w.desc \
2801                 -text "[appname] - a commit creation tool for Git.
2802 $copyright" \
2803                 -padx 5 -pady 5 \
2804                 -justify left \
2805                 -anchor w \
2806                 -borderwidth 1 \
2807                 -relief solid \
2808                 -font font_ui
2809         pack $w.desc -side top -fill x -padx 5 -pady 5
2810
2811         set v {}
2812         append v "[appname] version $appvers\n"
2813         append v "[exec git version]\n"
2814         append v "\n"
2815         if {$tcl_patchLevel eq $tk_patchLevel} {
2816                 append v "Tcl/Tk version $tcl_patchLevel"
2817         } else {
2818                 append v "Tcl version $tcl_patchLevel"
2819                 append v ", Tk version $tk_patchLevel"
2820         }
2821
2822         label $w.vers \
2823                 -text $v \
2824                 -padx 5 -pady 5 \
2825                 -justify left \
2826                 -anchor w \
2827                 -borderwidth 1 \
2828                 -relief solid \
2829                 -font font_ui
2830         pack $w.vers -side top -fill x -padx 5 -pady 5
2831
2832         menu $w.ctxm -tearoff 0
2833         $w.ctxm add command \
2834                 -label {Copy} \
2835                 -font font_ui \
2836                 -command "
2837                 clipboard clear
2838                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2839         "
2840
2841         bind $w <Visibility> "grab $w; focus $w"
2842         bind $w <Key-Escape> "destroy $w"
2843         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2844         wm title $w "About [appname]"
2845         tkwait window $w
2846 }
2847
2848 proc do_options {} {
2849         global repo_config global_config font_descs
2850         global repo_config_new global_config_new
2851
2852         array unset repo_config_new
2853         array unset global_config_new
2854         foreach name [array names repo_config] {
2855                 set repo_config_new($name) $repo_config($name)
2856         }
2857         load_config 1
2858         foreach name [array names repo_config] {
2859                 switch -- $name {
2860                 gui.diffcontext {continue}
2861                 }
2862                 set repo_config_new($name) $repo_config($name)
2863         }
2864         foreach name [array names global_config] {
2865                 set global_config_new($name) $global_config($name)
2866         }
2867
2868         set w .options_editor
2869         toplevel $w
2870         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2871
2872         label $w.header -text "[appname] Options" \
2873                 -font font_uibold
2874         pack $w.header -side top -fill x
2875
2876         frame $w.buttons
2877         button $w.buttons.restore -text {Restore Defaults} \
2878                 -font font_ui \
2879                 -command do_restore_defaults
2880         pack $w.buttons.restore -side left
2881         button $w.buttons.save -text Save \
2882                 -font font_ui \
2883                 -command [list do_save_config $w]
2884         pack $w.buttons.save -side right
2885         button $w.buttons.cancel -text {Cancel} \
2886                 -font font_ui \
2887                 -command [list destroy $w]
2888         pack $w.buttons.cancel -side right -padx 5
2889         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2890
2891         labelframe $w.repo -text "[reponame] Repository" \
2892                 -font font_ui \
2893                 -relief raised -borderwidth 2
2894         labelframe $w.global -text {Global (All Repositories)} \
2895                 -font font_ui \
2896                 -relief raised -borderwidth 2
2897         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2898         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2899
2900         foreach option {
2901                 {b pullsummary {Show Pull Summary}}
2902                 {b trustmtime  {Trust File Modification Timestamps}}
2903                 {i diffcontext {Number of Diff Context Lines}}
2904                 } {
2905                 set type [lindex $option 0]
2906                 set name [lindex $option 1]
2907                 set text [lindex $option 2]
2908                 foreach f {repo global} {
2909                         switch $type {
2910                         b {
2911                                 checkbutton $w.$f.$name -text $text \
2912                                         -variable ${f}_config_new(gui.$name) \
2913                                         -onvalue true \
2914                                         -offvalue false \
2915                                         -font font_ui
2916                                 pack $w.$f.$name -side top -anchor w
2917                         }
2918                         i {
2919                                 frame $w.$f.$name
2920                                 label $w.$f.$name.l -text "$text:" -font font_ui
2921                                 pack $w.$f.$name.l -side left -anchor w -fill x
2922                                 spinbox $w.$f.$name.v \
2923                                         -textvariable ${f}_config_new(gui.$name) \
2924                                         -from 1 -to 99 -increment 1 \
2925                                         -width 3 \
2926                                         -font font_ui
2927                                 pack $w.$f.$name.v -side right -anchor e
2928                                 pack $w.$f.$name -side top -anchor w -fill x
2929                         }
2930                         }
2931                 }
2932         }
2933
2934         set all_fonts [lsort [font families]]
2935         foreach option $font_descs {
2936                 set name [lindex $option 0]
2937                 set font [lindex $option 1]
2938                 set text [lindex $option 2]
2939
2940                 set global_config_new(gui.$font^^family) \
2941                         [font configure $font -family]
2942                 set global_config_new(gui.$font^^size) \
2943                         [font configure $font -size]
2944
2945                 frame $w.global.$name
2946                 label $w.global.$name.l -text "$text:" -font font_ui
2947                 pack $w.global.$name.l -side left -anchor w -fill x
2948                 eval tk_optionMenu $w.global.$name.family \
2949                         global_config_new(gui.$font^^family) \
2950                         $all_fonts
2951                 spinbox $w.global.$name.size \
2952                         -textvariable global_config_new(gui.$font^^size) \
2953                         -from 2 -to 80 -increment 1 \
2954                         -width 3 \
2955                         -font font_ui
2956                 pack $w.global.$name.size -side right -anchor e
2957                 pack $w.global.$name.family -side right -anchor e
2958                 pack $w.global.$name -side top -anchor w -fill x
2959         }
2960
2961         bind $w <Visibility> "grab $w; focus $w"
2962         bind $w <Key-Escape> "destroy $w"
2963         wm title $w "[appname] ([reponame]): Options"
2964         tkwait window $w
2965 }
2966
2967 proc do_restore_defaults {} {
2968         global font_descs default_config repo_config
2969         global repo_config_new global_config_new
2970
2971         foreach name [array names default_config] {
2972                 set repo_config_new($name) $default_config($name)
2973                 set global_config_new($name) $default_config($name)
2974         }
2975
2976         foreach option $font_descs {
2977                 set name [lindex $option 0]
2978                 set repo_config(gui.$name) $default_config(gui.$name)
2979         }
2980         apply_config
2981
2982         foreach option $font_descs {
2983                 set name [lindex $option 0]
2984                 set font [lindex $option 1]
2985                 set global_config_new(gui.$font^^family) \
2986                         [font configure $font -family]
2987                 set global_config_new(gui.$font^^size) \
2988                         [font configure $font -size]
2989         }
2990 }
2991
2992 proc do_save_config {w} {
2993         if {[catch {save_config} err]} {
2994                 error_popup "Failed to completely save options:\n\n$err"
2995         }
2996         reshow_diff
2997         destroy $w
2998 }
2999
3000 proc do_windows_shortcut {} {
3001         global argv0
3002
3003         if {[catch {
3004                 set desktop [exec cygpath \
3005                         --windows \
3006                         --absolute \
3007                         --long-name \
3008                         --desktop]
3009                 }]} {
3010                         set desktop .
3011         }
3012         set fn [tk_getSaveFile \
3013                 -parent . \
3014                 -title "[appname] ([reponame]): Create Desktop Icon" \
3015                 -initialdir $desktop \
3016                 -initialfile "Git [reponame].bat"]
3017         if {$fn != {}} {
3018                 if {[catch {
3019                                 set fd [open $fn w]
3020                                 set sh [exec cygpath \
3021                                         --windows \
3022                                         --absolute \
3023                                         /bin/sh]
3024                                 set me [exec cygpath \
3025                                         --unix \
3026                                         --absolute \
3027                                         $argv0]
3028                                 set gd [exec cygpath \
3029                                         --unix \
3030                                         --absolute \
3031                                         [gitdir]]
3032                                 set gw [exec cygpath \
3033                                         --windows \
3034                                         --absolute \
3035                                         [file dirname [gitdir]]]
3036                                 regsub -all ' $me "'\\''" me
3037                                 regsub -all ' $gd "'\\''" gd
3038                                 puts $fd "@ECHO Entering $gw"
3039                                 puts $fd "@ECHO Starting git-gui... please wait..."
3040                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3041                                 puts -nonewline $fd "GIT_DIR='$gd'"
3042                                 puts -nonewline $fd " '$me'"
3043                                 puts $fd "&\""
3044                                 close $fd
3045                         } err]} {
3046                         error_popup "Cannot write script:\n\n$err"
3047                 }
3048         }
3049 }
3050
3051 proc do_macosx_app {} {
3052         global argv0 env
3053
3054         set fn [tk_getSaveFile \
3055                 -parent . \
3056                 -title "[appname] ([reponame]): Create Desktop Icon" \
3057                 -initialdir [file join $env(HOME) Desktop] \
3058                 -initialfile "Git [reponame].app"]
3059         if {$fn != {}} {
3060                 if {[catch {
3061                                 set Contents [file join $fn Contents]
3062                                 set MacOS [file join $Contents MacOS]
3063                                 set exe [file join $MacOS git-gui]
3064
3065                                 file mkdir $MacOS
3066
3067                                 set fd [open [file join $Contents Info.plist] w]
3068                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3069 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3070 <plist version="1.0">
3071 <dict>
3072         <key>CFBundleDevelopmentRegion</key>
3073         <string>English</string>
3074         <key>CFBundleExecutable</key>
3075         <string>git-gui</string>
3076         <key>CFBundleIdentifier</key>
3077         <string>org.spearce.git-gui</string>
3078         <key>CFBundleInfoDictionaryVersion</key>
3079         <string>6.0</string>
3080         <key>CFBundlePackageType</key>
3081         <string>APPL</string>
3082         <key>CFBundleSignature</key>
3083         <string>????</string>
3084         <key>CFBundleVersion</key>
3085         <string>1.0</string>
3086         <key>NSPrincipalClass</key>
3087         <string>NSApplication</string>
3088 </dict>
3089 </plist>}
3090                                 close $fd
3091
3092                                 set fd [open $exe w]
3093                                 set gd [file normalize [gitdir]]
3094                                 set ep [file normalize [exec git --exec-path]]
3095                                 regsub -all ' $gd "'\\''" gd
3096                                 regsub -all ' $ep "'\\''" ep
3097                                 puts $fd "#!/bin/sh"
3098                                 foreach name [array names env] {
3099                                         if {[string match GIT_* $name]} {
3100                                                 regsub -all ' $env($name) "'\\''" v
3101                                                 puts $fd "export $name='$v'"
3102                                         }
3103                                 }
3104                                 puts $fd "export PATH='$ep':\$PATH"
3105                                 puts $fd "export GIT_DIR='$gd'"
3106                                 puts $fd "exec [file normalize $argv0]"
3107                                 close $fd
3108
3109                                 file attributes $exe -permissions u+x,g+x,o+x
3110                         } err]} {
3111                         error_popup "Cannot write icon:\n\n$err"
3112                 }
3113         }
3114 }
3115
3116 proc toggle_or_diff {w x y} {
3117         global file_states file_lists current_diff ui_index ui_workdir
3118         global last_clicked selected_paths
3119
3120         set pos [split [$w index @$x,$y] .]
3121         set lno [lindex $pos 0]
3122         set col [lindex $pos 1]
3123         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3124         if {$path eq {}} {
3125                 set last_clicked {}
3126                 return
3127         }
3128
3129         set last_clicked [list $w $lno]
3130         array unset selected_paths
3131         $ui_index tag remove in_sel 0.0 end
3132         $ui_workdir tag remove in_sel 0.0 end
3133
3134         if {$col == 0} {
3135                 if {$current_diff eq $path} {
3136                         set after {reshow_diff;}
3137                 } else {
3138                         set after {}
3139                 }
3140                 if {$w eq $ui_index} {
3141                         update_indexinfo \
3142                                 "Unstaging [short_path $path] from commit" \
3143                                 [list $path] \
3144                                 [concat $after {set ui_status_value {Ready.}}]
3145                 } elseif {$w eq $ui_workdir} {
3146                         update_index \
3147                                 "Adding [short_path $path]" \
3148                                 [list $path] \
3149                                 [concat $after {set ui_status_value {Ready.}}]
3150                 }
3151         } else {
3152                 show_diff $path $w $lno
3153         }
3154 }
3155
3156 proc add_one_to_selection {w x y} {
3157         global file_lists last_clicked selected_paths
3158
3159         set lno [lindex [split [$w index @$x,$y] .] 0]
3160         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3161         if {$path eq {}} {
3162                 set last_clicked {}
3163                 return
3164         }
3165
3166         if {$last_clicked ne {}
3167                 && [lindex $last_clicked 0] ne $w} {
3168                 array unset selected_paths
3169                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3170         }
3171
3172         set last_clicked [list $w $lno]
3173         if {[catch {set in_sel $selected_paths($path)}]} {
3174                 set in_sel 0
3175         }
3176         if {$in_sel} {
3177                 unset selected_paths($path)
3178                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3179         } else {
3180                 set selected_paths($path) 1
3181                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3182         }
3183 }
3184
3185 proc add_range_to_selection {w x y} {
3186         global file_lists last_clicked selected_paths
3187
3188         if {[lindex $last_clicked 0] ne $w} {
3189                 toggle_or_diff $w $x $y
3190                 return
3191         }
3192
3193         set lno [lindex [split [$w index @$x,$y] .] 0]
3194         set lc [lindex $last_clicked 1]
3195         if {$lc < $lno} {
3196                 set begin $lc
3197                 set end $lno
3198         } else {
3199                 set begin $lno
3200                 set end $lc
3201         }
3202
3203         foreach path [lrange $file_lists($w) \
3204                 [expr {$begin - 1}] \
3205                 [expr {$end - 1}]] {
3206                 set selected_paths($path) 1
3207         }
3208         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3209 }
3210
3211 ######################################################################
3212 ##
3213 ## config defaults
3214
3215 set cursor_ptr arrow
3216 font create font_diff -family Courier -size 10
3217 font create font_ui
3218 catch {
3219         label .dummy
3220         eval font configure font_ui [font actual [.dummy cget -font]]
3221         destroy .dummy
3222 }
3223
3224 font create font_uibold
3225 font create font_diffbold
3226
3227 if {[is_Windows]} {
3228         set M1B Control
3229         set M1T Ctrl
3230 } elseif {[is_MacOSX]} {
3231         set M1B M1
3232         set M1T Cmd
3233 } else {
3234         set M1B M1
3235         set M1T M1
3236 }
3237
3238 proc apply_config {} {
3239         global repo_config font_descs
3240
3241         foreach option $font_descs {
3242                 set name [lindex $option 0]
3243                 set font [lindex $option 1]
3244                 if {[catch {
3245                         foreach {cn cv} $repo_config(gui.$name) {
3246                                 font configure $font $cn $cv
3247                         }
3248                         } err]} {
3249                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3250                 }
3251                 foreach {cn cv} [font configure $font] {
3252                         font configure ${font}bold $cn $cv
3253                 }
3254                 font configure ${font}bold -weight bold
3255         }
3256 }
3257
3258 set default_config(gui.trustmtime) false
3259 set default_config(gui.pullsummary) true
3260 set default_config(gui.diffcontext) 5
3261 set default_config(gui.fontui) [font configure font_ui]
3262 set default_config(gui.fontdiff) [font configure font_diff]
3263 set font_descs {
3264         {fontui   font_ui   {Main Font}}
3265         {fontdiff font_diff {Diff/Console Font}}
3266 }
3267 load_config 0
3268 apply_config
3269
3270 ######################################################################
3271 ##
3272 ## ui construction
3273
3274 # -- Menu Bar
3275 #
3276 menu .mbar -tearoff 0
3277 .mbar add cascade -label Repository -menu .mbar.repository
3278 .mbar add cascade -label Edit -menu .mbar.edit
3279 if {!$single_commit} {
3280         .mbar add cascade -label Branch -menu .mbar.branch
3281 }
3282 .mbar add cascade -label Commit -menu .mbar.commit
3283 if {!$single_commit} {
3284         .mbar add cascade -label Fetch -menu .mbar.fetch
3285         .mbar add cascade -label Pull -menu .mbar.pull
3286         .mbar add cascade -label Push -menu .mbar.push
3287 }
3288 . configure -menu .mbar
3289
3290 # -- Repository Menu
3291 #
3292 menu .mbar.repository
3293 .mbar.repository add command \
3294         -label {Visualize Current Branch} \
3295         -command {do_gitk {}} \
3296         -font font_ui
3297 if {![is_MacOSX]} {
3298         .mbar.repository add command \
3299                 -label {Visualize All Branches} \
3300                 -command {do_gitk {--all}} \
3301                 -font font_ui
3302 }
3303 .mbar.repository add separator
3304
3305 if {!$single_commit} {
3306         .mbar.repository add command -label {Compress Database} \
3307                 -command do_gc \
3308                 -font font_ui
3309
3310         .mbar.repository add command -label {Verify Database} \
3311                 -command do_fsck_objects \
3312                 -font font_ui
3313
3314         .mbar.repository add separator
3315
3316         if {[is_Windows]} {
3317                 .mbar.repository add command \
3318                         -label {Create Desktop Icon} \
3319                         -command do_windows_shortcut \
3320                         -font font_ui
3321         } elseif {[is_MacOSX]} {
3322                 .mbar.repository add command \
3323                         -label {Create Desktop Icon} \
3324                         -command do_macosx_app \
3325                         -font font_ui
3326         }
3327 }
3328
3329 .mbar.repository add command -label Quit \
3330         -command do_quit \
3331         -accelerator $M1T-Q \
3332         -font font_ui
3333
3334 # -- Edit Menu
3335 #
3336 menu .mbar.edit
3337 .mbar.edit add command -label Undo \
3338         -command {catch {[focus] edit undo}} \
3339         -accelerator $M1T-Z \
3340         -font font_ui
3341 .mbar.edit add command -label Redo \
3342         -command {catch {[focus] edit redo}} \
3343         -accelerator $M1T-Y \
3344         -font font_ui
3345 .mbar.edit add separator
3346 .mbar.edit add command -label Cut \
3347         -command {catch {tk_textCut [focus]}} \
3348         -accelerator $M1T-X \
3349         -font font_ui
3350 .mbar.edit add command -label Copy \
3351         -command {catch {tk_textCopy [focus]}} \
3352         -accelerator $M1T-C \
3353         -font font_ui
3354 .mbar.edit add command -label Paste \
3355         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3356         -accelerator $M1T-V \
3357         -font font_ui
3358 .mbar.edit add command -label Delete \
3359         -command {catch {[focus] delete sel.first sel.last}} \
3360         -accelerator Del \
3361         -font font_ui
3362 .mbar.edit add separator
3363 .mbar.edit add command -label {Select All} \
3364         -command {catch {[focus] tag add sel 0.0 end}} \
3365         -accelerator $M1T-A \
3366         -font font_ui
3367
3368 # -- Branch Menu
3369 #
3370 if {!$single_commit} {
3371         menu .mbar.branch
3372
3373         .mbar.branch add command -label {Create...} \
3374                 -command do_create_branch \
3375                 -accelerator $M1T-N \
3376                 -font font_ui
3377         lappend disable_on_lock [list .mbar.branch entryconf \
3378                 [.mbar.branch index last] -state]
3379
3380         .mbar.branch add command -label {Delete...} \
3381                 -command do_delete_branch \
3382                 -font font_ui
3383         lappend disable_on_lock [list .mbar.branch entryconf \
3384                 [.mbar.branch index last] -state]
3385 }
3386
3387 # -- Commit Menu
3388 #
3389 menu .mbar.commit
3390
3391 .mbar.commit add radiobutton \
3392         -label {New Commit} \
3393         -command do_select_commit_type \
3394         -variable selected_commit_type \
3395         -value new \
3396         -font font_ui
3397 lappend disable_on_lock \
3398         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3399
3400 .mbar.commit add radiobutton \
3401         -label {Amend Last Commit} \
3402         -command do_select_commit_type \
3403         -variable selected_commit_type \
3404         -value amend \
3405         -font font_ui
3406 lappend disable_on_lock \
3407         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3408
3409 .mbar.commit add separator
3410
3411 .mbar.commit add command -label Rescan \
3412         -command do_rescan \
3413         -accelerator F5 \
3414         -font font_ui
3415 lappend disable_on_lock \
3416         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3417
3418 .mbar.commit add command -label {Add To Commit} \
3419         -command do_add_selection \
3420         -font font_ui
3421 lappend disable_on_lock \
3422         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3423
3424 .mbar.commit add command -label {Add All To Commit} \
3425         -command do_add_all \
3426         -accelerator $M1T-I \
3427         -font font_ui
3428 lappend disable_on_lock \
3429         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3430
3431 .mbar.commit add command -label {Unstage From Commit} \
3432         -command do_unstage_selection \
3433         -font font_ui
3434 lappend disable_on_lock \
3435         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3436
3437 .mbar.commit add command -label {Revert Changes} \
3438         -command do_revert_selection \
3439         -font font_ui
3440 lappend disable_on_lock \
3441         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3442
3443 .mbar.commit add separator
3444
3445 .mbar.commit add command -label {Sign Off} \
3446         -command do_signoff \
3447         -accelerator $M1T-S \
3448         -font font_ui
3449
3450 .mbar.commit add command -label Commit \
3451         -command do_commit \
3452         -accelerator $M1T-Return \
3453         -font font_ui
3454 lappend disable_on_lock \
3455         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3456
3457 # -- Transport menus
3458 #
3459 if {!$single_commit} {
3460         menu .mbar.fetch
3461         menu .mbar.pull
3462         menu .mbar.push
3463 }
3464
3465 if {[is_MacOSX]} {
3466         # -- Apple Menu (Mac OS X only)
3467         #
3468         .mbar add cascade -label Apple -menu .mbar.apple
3469         menu .mbar.apple
3470
3471         .mbar.apple add command -label "About [appname]" \
3472                 -command do_about \
3473                 -font font_ui
3474         .mbar.apple add command -label "[appname] Options..." \
3475                 -command do_options \
3476                 -font font_ui
3477 } else {
3478         # -- Edit Menu
3479         #
3480         .mbar.edit add separator
3481         .mbar.edit add command -label {Options...} \
3482                 -command do_options \
3483                 -font font_ui
3484
3485         # -- Tools Menu
3486         #
3487         if {[file exists /usr/local/miga/lib/gui-miga]
3488                 && [file exists .pvcsrc]} {
3489         proc do_miga {} {
3490                 global ui_status_value
3491                 if {![lock_index update]} return
3492                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3493                 set miga_fd [open "|$cmd" r]
3494                 fconfigure $miga_fd -blocking 0
3495                 fileevent $miga_fd readable [list miga_done $miga_fd]
3496                 set ui_status_value {Running miga...}
3497         }
3498         proc miga_done {fd} {
3499                 read $fd 512
3500                 if {[eof $fd]} {
3501                         close $fd
3502                         unlock_index
3503                         rescan [list set ui_status_value {Ready.}]
3504                 }
3505         }
3506         .mbar add cascade -label Tools -menu .mbar.tools
3507         menu .mbar.tools
3508         .mbar.tools add command -label "Migrate" \
3509                 -command do_miga \
3510                 -font font_ui
3511         lappend disable_on_lock \
3512                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3513         }
3514
3515         # -- Help Menu
3516         #
3517         .mbar add cascade -label Help -menu .mbar.help
3518         menu .mbar.help
3519
3520         .mbar.help add command -label "About [appname]" \
3521                 -command do_about \
3522                 -font font_ui
3523 }
3524
3525
3526 # -- Branch Control
3527 #
3528 frame .branch \
3529         -borderwidth 1 \
3530         -relief sunken
3531 label .branch.l1 \
3532         -text {Current Branch:} \
3533         -anchor w \
3534         -justify left \
3535         -font font_ui
3536 label .branch.cb \
3537         -textvariable current_branch \
3538         -anchor w \
3539         -justify left \
3540         -font font_ui
3541 pack .branch.l1 -side left
3542 pack .branch.cb -side left -fill x
3543 pack .branch -side top -fill x
3544
3545 # -- Main Window Layout
3546 #
3547 panedwindow .vpane -orient vertical
3548 panedwindow .vpane.files -orient horizontal
3549 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3550 pack .vpane -anchor n -side top -fill both -expand 1
3551
3552 # -- Index File List
3553 #
3554 frame .vpane.files.index -height 100 -width 400
3555 label .vpane.files.index.title -text {Changes To Be Committed} \
3556         -background green \
3557         -font font_ui
3558 text $ui_index -background white -borderwidth 0 \
3559         -width 40 -height 10 \
3560         -font font_ui \
3561         -cursor $cursor_ptr \
3562         -yscrollcommand {.vpane.files.index.sb set} \
3563         -state disabled
3564 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3565 pack .vpane.files.index.title -side top -fill x
3566 pack .vpane.files.index.sb -side right -fill y
3567 pack $ui_index -side left -fill both -expand 1
3568 .vpane.files add .vpane.files.index -sticky nsew
3569
3570 # -- Working Directory File List
3571 #
3572 frame .vpane.files.workdir -height 100 -width 100
3573 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3574         -background red \
3575         -font font_ui
3576 text $ui_workdir -background white -borderwidth 0 \
3577         -width 40 -height 10 \
3578         -font font_ui \
3579         -cursor $cursor_ptr \
3580         -yscrollcommand {.vpane.files.workdir.sb set} \
3581         -state disabled
3582 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3583 pack .vpane.files.workdir.title -side top -fill x
3584 pack .vpane.files.workdir.sb -side right -fill y
3585 pack $ui_workdir -side left -fill both -expand 1
3586 .vpane.files add .vpane.files.workdir -sticky nsew
3587
3588 foreach i [list $ui_index $ui_workdir] {
3589         $i tag conf in_diff -font font_uibold
3590         $i tag conf in_sel \
3591                 -background [$i cget -foreground] \
3592                 -foreground [$i cget -background]
3593 }
3594 unset i
3595
3596 # -- Diff and Commit Area
3597 #
3598 frame .vpane.lower -height 300 -width 400
3599 frame .vpane.lower.commarea
3600 frame .vpane.lower.diff -relief sunken -borderwidth 1
3601 pack .vpane.lower.commarea -side top -fill x
3602 pack .vpane.lower.diff -side bottom -fill both -expand 1
3603 .vpane add .vpane.lower -stick nsew
3604
3605 # -- Commit Area Buttons
3606 #
3607 frame .vpane.lower.commarea.buttons
3608 label .vpane.lower.commarea.buttons.l -text {} \
3609         -anchor w \
3610         -justify left \
3611         -font font_ui
3612 pack .vpane.lower.commarea.buttons.l -side top -fill x
3613 pack .vpane.lower.commarea.buttons -side left -fill y
3614
3615 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3616         -command do_rescan \
3617         -font font_ui
3618 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3619 lappend disable_on_lock \
3620         {.vpane.lower.commarea.buttons.rescan conf -state}
3621
3622 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3623         -command do_add_all \
3624         -font font_ui
3625 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3626 lappend disable_on_lock \
3627         {.vpane.lower.commarea.buttons.incall conf -state}
3628
3629 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3630         -command do_signoff \
3631         -font font_ui
3632 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3633
3634 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3635         -command do_commit \
3636         -font font_ui
3637 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3638 lappend disable_on_lock \
3639         {.vpane.lower.commarea.buttons.commit conf -state}
3640
3641 # -- Commit Message Buffer
3642 #
3643 frame .vpane.lower.commarea.buffer
3644 frame .vpane.lower.commarea.buffer.header
3645 set ui_comm .vpane.lower.commarea.buffer.t
3646 set ui_coml .vpane.lower.commarea.buffer.header.l
3647 radiobutton .vpane.lower.commarea.buffer.header.new \
3648         -text {New Commit} \
3649         -command do_select_commit_type \
3650         -variable selected_commit_type \
3651         -value new \
3652         -font font_ui
3653 lappend disable_on_lock \
3654         [list .vpane.lower.commarea.buffer.header.new conf -state]
3655 radiobutton .vpane.lower.commarea.buffer.header.amend \
3656         -text {Amend Last Commit} \
3657         -command do_select_commit_type \
3658         -variable selected_commit_type \
3659         -value amend \
3660         -font font_ui
3661 lappend disable_on_lock \
3662         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3663 label $ui_coml \
3664         -anchor w \
3665         -justify left \
3666         -font font_ui
3667 proc trace_commit_type {varname args} {
3668         global ui_coml commit_type
3669         switch -glob -- $commit_type {
3670         initial       {set txt {Initial Commit Message:}}
3671         amend         {set txt {Amended Commit Message:}}
3672         amend-initial {set txt {Amended Initial Commit Message:}}
3673         amend-merge   {set txt {Amended Merge Commit Message:}}
3674         merge         {set txt {Merge Commit Message:}}
3675         *             {set txt {Commit Message:}}
3676         }
3677         $ui_coml conf -text $txt
3678 }
3679 trace add variable commit_type write trace_commit_type
3680 pack $ui_coml -side left -fill x
3681 pack .vpane.lower.commarea.buffer.header.amend -side right
3682 pack .vpane.lower.commarea.buffer.header.new -side right
3683
3684 text $ui_comm -background white -borderwidth 1 \
3685         -undo true \
3686         -maxundo 20 \
3687         -autoseparators true \
3688         -relief sunken \
3689         -width 75 -height 9 -wrap none \
3690         -font font_diff \
3691         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3692 scrollbar .vpane.lower.commarea.buffer.sby \
3693         -command [list $ui_comm yview]
3694 pack .vpane.lower.commarea.buffer.header -side top -fill x
3695 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3696 pack $ui_comm -side left -fill y
3697 pack .vpane.lower.commarea.buffer -side left -fill y
3698
3699 # -- Commit Message Buffer Context Menu
3700 #
3701 set ctxm .vpane.lower.commarea.buffer.ctxm
3702 menu $ctxm -tearoff 0
3703 $ctxm add command \
3704         -label {Cut} \
3705         -font font_ui \
3706         -command {tk_textCut $ui_comm}
3707 $ctxm add command \
3708         -label {Copy} \
3709         -font font_ui \
3710         -command {tk_textCopy $ui_comm}
3711 $ctxm add command \
3712         -label {Paste} \
3713         -font font_ui \
3714         -command {tk_textPaste $ui_comm}
3715 $ctxm add command \
3716         -label {Delete} \
3717         -font font_ui \
3718         -command {$ui_comm delete sel.first sel.last}
3719 $ctxm add separator
3720 $ctxm add command \
3721         -label {Select All} \
3722         -font font_ui \
3723         -command {$ui_comm tag add sel 0.0 end}
3724 $ctxm add command \
3725         -label {Copy All} \
3726         -font font_ui \
3727         -command {
3728                 $ui_comm tag add sel 0.0 end
3729                 tk_textCopy $ui_comm
3730                 $ui_comm tag remove sel 0.0 end
3731         }
3732 $ctxm add separator
3733 $ctxm add command \
3734         -label {Sign Off} \
3735         -font font_ui \
3736         -command do_signoff
3737 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3738
3739 # -- Diff Header
3740 #
3741 set current_diff {}
3742 set diff_actions [list]
3743 proc trace_current_diff {varname args} {
3744         global current_diff diff_actions file_states
3745         if {$current_diff eq {}} {
3746                 set s {}
3747                 set f {}
3748                 set p {}
3749                 set o disabled
3750         } else {
3751                 set p $current_diff
3752                 set s [mapdesc [lindex $file_states($p) 0] $p]
3753                 set f {File:}
3754                 set p [escape_path $p]
3755                 set o normal
3756         }
3757
3758         .vpane.lower.diff.header.status configure -text $s
3759         .vpane.lower.diff.header.file configure -text $f
3760         .vpane.lower.diff.header.path configure -text $p
3761         foreach w $diff_actions {
3762                 uplevel #0 $w $o
3763         }
3764 }
3765 trace add variable current_diff write trace_current_diff
3766
3767 frame .vpane.lower.diff.header -background orange
3768 label .vpane.lower.diff.header.status \
3769         -background orange \
3770         -width $max_status_desc \
3771         -anchor w \
3772         -justify left \
3773         -font font_ui
3774 label .vpane.lower.diff.header.file \
3775         -background orange \
3776         -anchor w \
3777         -justify left \
3778         -font font_ui
3779 label .vpane.lower.diff.header.path \
3780         -background orange \
3781         -anchor w \
3782         -justify left \
3783         -font font_ui
3784 pack .vpane.lower.diff.header.status -side left
3785 pack .vpane.lower.diff.header.file -side left
3786 pack .vpane.lower.diff.header.path -fill x
3787 set ctxm .vpane.lower.diff.header.ctxm
3788 menu $ctxm -tearoff 0
3789 $ctxm add command \
3790         -label {Copy} \
3791         -font font_ui \
3792         -command {
3793                 clipboard clear
3794                 clipboard append \
3795                         -format STRING \
3796                         -type STRING \
3797                         -- $current_diff
3798         }
3799 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3800 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3801
3802 # -- Diff Body
3803 #
3804 frame .vpane.lower.diff.body
3805 set ui_diff .vpane.lower.diff.body.t
3806 text $ui_diff -background white -borderwidth 0 \
3807         -width 80 -height 15 -wrap none \
3808         -font font_diff \
3809         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3810         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3811         -state disabled
3812 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3813         -command [list $ui_diff xview]
3814 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3815         -command [list $ui_diff yview]
3816 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3817 pack .vpane.lower.diff.body.sby -side right -fill y
3818 pack $ui_diff -side left -fill both -expand 1
3819 pack .vpane.lower.diff.header -side top -fill x
3820 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3821
3822 $ui_diff tag conf d_@ -font font_diffbold
3823 $ui_diff tag conf d_+  -foreground blue
3824 $ui_diff tag conf d_-  -foreground red
3825 $ui_diff tag conf d_++ -foreground {#00a000}
3826 $ui_diff tag conf d_-- -foreground {#a000a0}
3827 $ui_diff tag conf d_+- \
3828         -foreground red \
3829         -background {light goldenrod yellow}
3830 $ui_diff tag conf d_-+ \
3831         -foreground blue \
3832         -background azure2
3833
3834 # -- Diff Body Context Menu
3835 #
3836 set ctxm .vpane.lower.diff.body.ctxm
3837 menu $ctxm -tearoff 0
3838 $ctxm add command \
3839         -label {Copy} \
3840         -font font_ui \
3841         -command {tk_textCopy $ui_diff}
3842 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3843 $ctxm add command \
3844         -label {Select All} \
3845         -font font_ui \
3846         -command {$ui_diff tag add sel 0.0 end}
3847 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3848 $ctxm add command \
3849         -label {Copy All} \
3850         -font font_ui \
3851         -command {
3852                 $ui_diff tag add sel 0.0 end
3853                 tk_textCopy $ui_diff
3854                 $ui_diff tag remove sel 0.0 end
3855         }
3856 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3857 $ctxm add separator
3858 $ctxm add command \
3859         -label {Decrease Font Size} \
3860         -font font_ui \
3861         -command {incr_font_size font_diff -1}
3862 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3863 $ctxm add command \
3864         -label {Increase Font Size} \
3865         -font font_ui \
3866         -command {incr_font_size font_diff 1}
3867 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3868 $ctxm add separator
3869 $ctxm add command \
3870         -label {Show Less Context} \
3871         -font font_ui \
3872         -command {if {$repo_config(gui.diffcontext) >= 2} {
3873                 incr repo_config(gui.diffcontext) -1
3874                 reshow_diff
3875         }}
3876 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3877 $ctxm add command \
3878         -label {Show More Context} \
3879         -font font_ui \
3880         -command {
3881                 incr repo_config(gui.diffcontext)
3882                 reshow_diff
3883         }
3884 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3885 $ctxm add separator
3886 $ctxm add command -label {Options...} \
3887         -font font_ui \
3888         -command do_options
3889 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3890
3891 # -- Status Bar
3892 #
3893 set ui_status_value {Initializing...}
3894 label .status -textvariable ui_status_value \
3895         -anchor w \
3896         -justify left \
3897         -borderwidth 1 \
3898         -relief sunken \
3899         -font font_ui
3900 pack .status -anchor w -side bottom -fill x
3901
3902 # -- Load geometry
3903 #
3904 catch {
3905 set gm $repo_config(gui.geometry)
3906 wm geometry . [lindex $gm 0]
3907 .vpane sash place 0 \
3908         [lindex [.vpane sash coord 0] 0] \
3909         [lindex $gm 1]
3910 .vpane.files sash place 0 \
3911         [lindex $gm 2] \
3912         [lindex [.vpane.files sash coord 0] 1]
3913 unset gm
3914 }
3915
3916 # -- Key Bindings
3917 #
3918 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3919 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3920 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3921 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3922 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3923 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3924 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3925 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3926 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3927 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3928 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3929
3930 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3931 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3932 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3933 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3934 bind $ui_diff <$M1B-Key-v> {break}
3935 bind $ui_diff <$M1B-Key-V> {break}
3936 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3937 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3938 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3939 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3940 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3941 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3942
3943 if {!$single_commit} {
3944         bind . <$M1B-Key-n> do_create_branch
3945         bind . <$M1B-Key-N> do_create_branch
3946 }
3947
3948 bind .   <Destroy> do_quit
3949 bind all <Key-F5> do_rescan
3950 bind all <$M1B-Key-r> do_rescan
3951 bind all <$M1B-Key-R> do_rescan
3952 bind .   <$M1B-Key-s> do_signoff
3953 bind .   <$M1B-Key-S> do_signoff
3954 bind .   <$M1B-Key-i> do_add_all
3955 bind .   <$M1B-Key-I> do_add_all
3956 bind .   <$M1B-Key-Return> do_commit
3957 bind all <$M1B-Key-q> do_quit
3958 bind all <$M1B-Key-Q> do_quit
3959 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3960 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3961 foreach i [list $ui_index $ui_workdir] {
3962         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3963         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3964         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3965 }
3966 unset i
3967
3968 set file_lists($ui_index) [list]
3969 set file_lists($ui_workdir) [list]
3970
3971 set HEAD {}
3972 set PARENT {}
3973 set MERGE_HEAD [list]
3974 set commit_type {}
3975 set empty_tree {}
3976 set current_branch {}
3977 set current_diff {}
3978 set selected_commit_type new
3979
3980 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3981 focus -force $ui_comm
3982
3983 # -- Warn the user about environmental problems.  Cygwin's Tcl
3984 #    does *not* pass its env array onto any processes it spawns.
3985 #    This means that git processes get none of our environment.
3986 #
3987 if {[is_Windows]} {
3988         set ignored_env 0
3989         set suggest_user {}
3990         set msg "Possible environment issues exist.
3991
3992 The following environment variables are probably
3993 going to be ignored by any Git subprocess run
3994 by [appname]:
3995
3996 "
3997         foreach name [array names env] {
3998                 switch -regexp -- $name {
3999                 {^GIT_INDEX_FILE$} -
4000                 {^GIT_OBJECT_DIRECTORY$} -
4001                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4002                 {^GIT_DIFF_OPTS$} -
4003                 {^GIT_EXTERNAL_DIFF$} -
4004                 {^GIT_PAGER$} -
4005                 {^GIT_TRACE$} -
4006                 {^GIT_CONFIG$} -
4007                 {^GIT_CONFIG_LOCAL$} -
4008                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4009                         append msg " - $name\n"
4010                         incr ignored_env
4011                 }
4012                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4013                         append msg " - $name\n"
4014                         incr ignored_env
4015                         set suggest_user $name
4016                 }
4017                 }
4018         }
4019         if {$ignored_env > 0} {
4020                 append msg "
4021 This is due to a known issue with the
4022 Tcl binary distributed by Cygwin."
4023
4024                 if {$suggest_user ne {}} {
4025                         append msg "
4026
4027 A good replacement for $suggest_user
4028 is placing values for the user.name and
4029 user.email settings into your personal
4030 ~/.gitconfig file.
4031 "
4032                 }
4033                 warn_popup $msg
4034         }
4035         unset ignored_env msg suggest_user name
4036 }
4037
4038 # -- Only initialize complex UI if we are going to stay running.
4039 #
4040 if {!$single_commit} {
4041         load_all_remotes
4042         load_all_heads
4043
4044         populate_branch_menu
4045         populate_fetch_menu .mbar.fetch
4046         populate_pull_menu .mbar.pull
4047         populate_push_menu .mbar.push
4048 }
4049
4050 # -- Only suggest a gc run if we are going to stay running.
4051 #
4052 if {!$single_commit} {
4053         set object_limit 2000
4054         if {[is_Windows]} {set object_limit 200}
4055         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4056         if {$objects_current >= $object_limit} {
4057                 if {[ask_popup \
4058                         "This repository currently has $objects_current loose objects.
4059
4060 To maintain optimal performance it is strongly
4061 recommended that you compress the database
4062 when more than $object_limit loose objects exist.
4063
4064 Compress the database now?"] eq yes} {
4065                         do_gc
4066                 }
4067         }
4068         unset object_limit _junk objects_current
4069 }
4070
4071 lock_index begin-read
4072 after 1 do_rescan