git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 DD {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD -
1118                 DM {
1119                         set file_states($path) [list \
1120                                 _[string index $m 1] \
1121                                 [lindex $s 1] \
1122                                 [lindex $s 3] \
1123                                 {}]
1124                 }
1125                 }
1126         }
1127
1128         display_all_files
1129         unlock_index
1130         reshow_diff
1131         set ui_status_value \
1132                 "Changes committed as [string range $cmt_id 0 7]."
1133 }
1134
1135 ######################################################################
1136 ##
1137 ## fetch pull push
1138
1139 proc fetch_from {remote} {
1140         set w [new_console "fetch $remote" \
1141                 "Fetching new changes from $remote"]
1142         set cmd [list git fetch]
1143         lappend cmd $remote
1144         console_exec $w $cmd
1145 }
1146
1147 proc pull_remote {remote branch} {
1148         global HEAD commit_type file_states repo_config
1149
1150         if {![lock_index update]} return
1151
1152         # -- Our in memory state should match the repository.
1153         #
1154         repository_state curType curHEAD curMERGE_HEAD
1155         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1156                 info_popup {Last scanned state does not match repository state.
1157
1158 Another Git program has modified this repository
1159 since the last scan.  A rescan must be performed
1160 before a pull operation can be started.
1161
1162 The rescan will be automatically started now.
1163 }
1164                 unlock_index
1165                 rescan {set ui_status_value {Ready.}}
1166                 return
1167         }
1168
1169         # -- No differences should exist before a pull.
1170         #
1171         if {[array size file_states] != 0} {
1172                 error_popup {Uncommitted but modified files are present.
1173
1174 You should not perform a pull with unmodified
1175 files in your working directory as Git will be
1176 unable to recover from an incorrect merge.
1177
1178 You should commit or revert all changes before
1179 starting a pull operation.
1180 }
1181                 unlock_index
1182                 return
1183         }
1184
1185         set w [new_console "pull $remote $branch" \
1186                 "Pulling new changes from branch $branch in $remote"]
1187         set cmd [list git pull]
1188         if {$repo_config(gui.pullsummary) eq {false}} {
1189                 lappend cmd --no-summary
1190         }
1191         lappend cmd $remote
1192         lappend cmd $branch
1193         console_exec $w $cmd [list post_pull_remote $remote $branch]
1194 }
1195
1196 proc post_pull_remote {remote branch success} {
1197         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1198         global ui_status_value
1199
1200         unlock_index
1201         if {$success} {
1202                 repository_state commit_type HEAD MERGE_HEAD
1203                 set PARENT $HEAD
1204                 set selected_commit_type new
1205                 set ui_status_value "Pulling $branch from $remote complete."
1206         } else {
1207                 rescan [list set ui_status_value \
1208                         "Conflicts detected while pulling $branch from $remote."]
1209         }
1210 }
1211
1212 proc push_to {remote} {
1213         set w [new_console "push $remote" \
1214                 "Pushing changes to $remote"]
1215         set cmd [list git push]
1216         lappend cmd $remote
1217         console_exec $w $cmd
1218 }
1219
1220 ######################################################################
1221 ##
1222 ## ui helpers
1223
1224 proc mapicon {w state path} {
1225         global all_icons
1226
1227         if {[catch {set r $all_icons($state$w)}]} {
1228                 puts "error: no icon for $w state={$state} $path"
1229                 return file_plain
1230         }
1231         return $r
1232 }
1233
1234 proc mapdesc {state path} {
1235         global all_descs
1236
1237         if {[catch {set r $all_descs($state)}]} {
1238                 puts "error: no desc for state={$state} $path"
1239                 return $state
1240         }
1241         return $r
1242 }
1243
1244 proc escape_path {path} {
1245         regsub -all "\n" $path "\\n" path
1246         return $path
1247 }
1248
1249 proc short_path {path} {
1250         return [escape_path [lindex [file split $path] end]]
1251 }
1252
1253 set next_icon_id 0
1254 set null_sha1 [string repeat 0 40]
1255
1256 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1257         global file_states next_icon_id null_sha1
1258
1259         set s0 [string index $new_state 0]
1260         set s1 [string index $new_state 1]
1261
1262         if {[catch {set info $file_states($path)}]} {
1263                 set state __
1264                 set icon n[incr next_icon_id]
1265         } else {
1266                 set state [lindex $info 0]
1267                 set icon [lindex $info 1]
1268                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1269                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1270         }
1271
1272         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1273         elseif {$s0 eq {_}} {set s0 _}
1274
1275         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1276         elseif {$s1 eq {_}} {set s1 _}
1277
1278         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1279                 set head_info [list 0 $null_sha1]
1280         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1281                 && $head_info eq {}} {
1282                 set head_info $index_info
1283         }
1284
1285         set file_states($path) [list $s0$s1 $icon \
1286                 $head_info $index_info \
1287                 ]
1288         return $state
1289 }
1290
1291 proc display_file_helper {w path icon_name old_m new_m} {
1292         global file_lists
1293
1294         if {$new_m eq {_}} {
1295                 set lno [lsearch -sorted $file_lists($w) $path]
1296                 if {$lno >= 0} {
1297                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1298                         incr lno
1299                         $w conf -state normal
1300                         $w delete $lno.0 [expr {$lno + 1}].0
1301                         $w conf -state disabled
1302                 }
1303         } elseif {$old_m eq {_} && $new_m ne {_}} {
1304                 lappend file_lists($w) $path
1305                 set file_lists($w) [lsort -unique $file_lists($w)]
1306                 set lno [lsearch -sorted $file_lists($w) $path]
1307                 incr lno
1308                 $w conf -state normal
1309                 $w image create $lno.0 \
1310                         -align center -padx 5 -pady 1 \
1311                         -name $icon_name \
1312                         -image [mapicon $w $new_m $path]
1313                 $w insert $lno.1 "[escape_path $path]\n"
1314                 $w conf -state disabled
1315         } elseif {$old_m ne $new_m} {
1316                 $w conf -state normal
1317                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1318                 $w conf -state disabled
1319         }
1320 }
1321
1322 proc display_file {path state} {
1323         global file_states selected_paths
1324         global ui_index ui_workdir
1325
1326         set old_m [merge_state $path $state]
1327         set s $file_states($path)
1328         set new_m [lindex $s 0]
1329         set icon_name [lindex $s 1]
1330
1331         display_file_helper     $ui_index $path $icon_name \
1332                 [string index $old_m 0] \
1333                 [string index $new_m 0]
1334         display_file_helper     $ui_workdir $path $icon_name \
1335                 [string index $old_m 1] \
1336                 [string index $new_m 1]
1337
1338         if {$new_m eq {__}} {
1339                 unset file_states($path)
1340                 catch {unset selected_paths($path)}
1341         }
1342 }
1343
1344 proc display_all_files_helper {w path icon_name m} {
1345         global file_lists
1346
1347         lappend file_lists($w) $path
1348         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1349         $w image create end \
1350                 -align center -padx 5 -pady 1 \
1351                 -name $icon_name \
1352                 -image [mapicon $w $m $path]
1353         $w insert end "[escape_path $path]\n"
1354 }
1355
1356 proc display_all_files {} {
1357         global ui_index ui_workdir
1358         global file_states file_lists
1359         global last_clicked selected_paths
1360
1361         $ui_index conf -state normal
1362         $ui_workdir conf -state normal
1363
1364         $ui_index delete 0.0 end
1365         $ui_workdir delete 0.0 end
1366         set last_clicked {}
1367
1368         set file_lists($ui_index) [list]
1369         set file_lists($ui_workdir) [list]
1370
1371         foreach path [lsort [array names file_states]] {
1372                 set s $file_states($path)
1373                 set m [lindex $s 0]
1374                 set icon_name [lindex $s 1]
1375
1376                 if {[string index $m 0] ne {_}} {
1377                         display_all_files_helper $ui_index $path \
1378                                 $icon_name [string index $m 0]
1379                 }
1380                 if {[string index $m 1] ne {_}} {
1381                         display_all_files_helper $ui_workdir $path \
1382                                 $icon_name [string index $m 1]
1383                 }
1384         }
1385
1386         $ui_index conf -state disabled
1387         $ui_workdir conf -state disabled
1388 }
1389
1390 proc update_indexinfo {msg pathList after} {
1391         global update_index_cp ui_status_value
1392
1393         if {![lock_index update]} return
1394
1395         set update_index_cp 0
1396         set pathList [lsort $pathList]
1397         set totalCnt [llength $pathList]
1398         set batch [expr {int($totalCnt * .01) + 1}]
1399         if {$batch > 25} {set batch 25}
1400
1401         set ui_status_value [format \
1402                 "$msg... %i/%i files (%.2f%%)" \
1403                 $update_index_cp \
1404                 $totalCnt \
1405                 0.0]
1406         set fd [open "| git update-index -z --index-info" w]
1407         fconfigure $fd \
1408                 -blocking 0 \
1409                 -buffering full \
1410                 -buffersize 512 \
1411                 -translation binary
1412         fileevent $fd writable [list \
1413                 write_update_indexinfo \
1414                 $fd \
1415                 $pathList \
1416                 $totalCnt \
1417                 $batch \
1418                 $msg \
1419                 $after \
1420                 ]
1421 }
1422
1423 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1424         global update_index_cp ui_status_value
1425         global file_states current_diff
1426
1427         if {$update_index_cp >= $totalCnt} {
1428                 close $fd
1429                 unlock_index
1430                 uplevel #0 $after
1431                 return
1432         }
1433
1434         for {set i $batch} \
1435                 {$update_index_cp < $totalCnt && $i > 0} \
1436                 {incr i -1} {
1437                 set path [lindex $pathList $update_index_cp]
1438                 incr update_index_cp
1439
1440                 set s $file_states($path)
1441                 switch -glob -- [lindex $s 0] {
1442                 A? {set new _O}
1443                 M? {set new _M}
1444                 D_ {set new _D}
1445                 D? {set new _?}
1446                 ?? {continue}
1447                 }
1448                 set info [lindex $s 2]
1449                 if {$info eq {}} continue
1450
1451                 puts -nonewline $fd $info
1452                 puts -nonewline $fd "\t"
1453                 puts -nonewline $fd $path
1454                 puts -nonewline $fd "\0"
1455                 display_file $path $new
1456         }
1457
1458         set ui_status_value [format \
1459                 "$msg... %i/%i files (%.2f%%)" \
1460                 $update_index_cp \
1461                 $totalCnt \
1462                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1463 }
1464
1465 proc update_index {msg pathList after} {
1466         global update_index_cp ui_status_value
1467
1468         if {![lock_index update]} return
1469
1470         set update_index_cp 0
1471         set pathList [lsort $pathList]
1472         set totalCnt [llength $pathList]
1473         set batch [expr {int($totalCnt * .01) + 1}]
1474         if {$batch > 25} {set batch 25}
1475
1476         set ui_status_value [format \
1477                 "$msg... %i/%i files (%.2f%%)" \
1478                 $update_index_cp \
1479                 $totalCnt \
1480                 0.0]
1481         set fd [open "| git update-index --add --remove -z --stdin" w]
1482         fconfigure $fd \
1483                 -blocking 0 \
1484                 -buffering full \
1485                 -buffersize 512 \
1486                 -translation binary
1487         fileevent $fd writable [list \
1488                 write_update_index \
1489                 $fd \
1490                 $pathList \
1491                 $totalCnt \
1492                 $batch \
1493                 $msg \
1494                 $after \
1495                 ]
1496 }
1497
1498 proc write_update_index {fd pathList totalCnt batch msg after} {
1499         global update_index_cp ui_status_value
1500         global file_states current_diff
1501
1502         if {$update_index_cp >= $totalCnt} {
1503                 close $fd
1504                 unlock_index
1505                 uplevel #0 $after
1506                 return
1507         }
1508
1509         for {set i $batch} \
1510                 {$update_index_cp < $totalCnt && $i > 0} \
1511                 {incr i -1} {
1512                 set path [lindex $pathList $update_index_cp]
1513                 incr update_index_cp
1514
1515                 switch -glob -- [lindex $file_states($path) 0] {
1516                 AD -
1517                 MD -
1518                 UD -
1519                 _D {set new DD}
1520
1521                 _M -
1522                 MM -
1523                 UM -
1524                 U_ -
1525                 M_ {set new M_}
1526
1527                 _O -
1528                 AM -
1529                 A_ {set new A_}
1530
1531                 ?? {continue}
1532                 }
1533
1534                 puts -nonewline $fd $path
1535                 puts -nonewline $fd "\0"
1536                 display_file $path $new
1537         }
1538
1539         set ui_status_value [format \
1540                 "$msg... %i/%i files (%.2f%%)" \
1541                 $update_index_cp \
1542                 $totalCnt \
1543                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1544 }
1545
1546 proc checkout_index {msg pathList after} {
1547         global update_index_cp ui_status_value
1548
1549         if {![lock_index update]} return
1550
1551         set update_index_cp 0
1552         set pathList [lsort $pathList]
1553         set totalCnt [llength $pathList]
1554         set batch [expr {int($totalCnt * .01) + 1}]
1555         if {$batch > 25} {set batch 25}
1556
1557         set ui_status_value [format \
1558                 "$msg... %i/%i files (%.2f%%)" \
1559                 $update_index_cp \
1560                 $totalCnt \
1561                 0.0]
1562         set cmd [list git checkout-index]
1563         lappend cmd --index
1564         lappend cmd --quiet
1565         lappend cmd --force
1566         lappend cmd -z
1567         lappend cmd --stdin
1568         set fd [open "| $cmd " w]
1569         fconfigure $fd \
1570                 -blocking 0 \
1571                 -buffering full \
1572                 -buffersize 512 \
1573                 -translation binary
1574         fileevent $fd writable [list \
1575                 write_checkout_index \
1576                 $fd \
1577                 $pathList \
1578                 $totalCnt \
1579                 $batch \
1580                 $msg \
1581                 $after \
1582                 ]
1583 }
1584
1585 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1586         global update_index_cp ui_status_value
1587         global file_states current_diff
1588
1589         if {$update_index_cp >= $totalCnt} {
1590                 close $fd
1591                 unlock_index
1592                 uplevel #0 $after
1593                 return
1594         }
1595
1596         for {set i $batch} \
1597                 {$update_index_cp < $totalCnt && $i > 0} \
1598                 {incr i -1} {
1599                 set path [lindex $pathList $update_index_cp]
1600                 incr update_index_cp
1601
1602                 switch -glob -- [lindex $file_states($path) 0] {
1603                 AM -
1604                 AD {set new A_}
1605                 MM -
1606                 MD {set new M_}
1607                 _M -
1608                 _D {set new __}
1609                 ?? {continue}
1610                 }
1611
1612                 puts -nonewline $fd $path
1613                 puts -nonewline $fd "\0"
1614                 display_file $path $new
1615         }
1616
1617         set ui_status_value [format \
1618                 "$msg... %i/%i files (%.2f%%)" \
1619                 $update_index_cp \
1620                 $totalCnt \
1621                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1622 }
1623
1624 ######################################################################
1625 ##
1626 ## branch management
1627
1628 proc load_all_heads {} {
1629         global all_heads tracking_branches
1630
1631         set all_heads [list]
1632         set cmd [list git for-each-ref]
1633         lappend cmd --format=%(refname)
1634         lappend cmd refs/heads
1635         set fd [open "| $cmd" r]
1636         while {[gets $fd line] > 0} {
1637                 if {![catch {set info $tracking_branches($line)}]} continue
1638                 if {![regsub ^refs/heads/ $line {} name]} continue
1639                 lappend all_heads $name
1640         }
1641         close $fd
1642
1643         set all_heads [lsort $all_heads]
1644 }
1645
1646 proc populate_branch_menu {m} {
1647         global all_heads disable_on_lock
1648
1649         $m add separator
1650         foreach b $all_heads {
1651                 $m add radiobutton \
1652                         -label $b \
1653                         -command [list switch_branch $b] \
1654                         -variable current_branch \
1655                         -value $b \
1656                         -font font_ui
1657                 lappend disable_on_lock \
1658                         [list $m entryconf [$m index last] -state]
1659         }
1660 }
1661
1662 proc do_create_branch {} {
1663         error "NOT IMPLEMENTED"
1664 }
1665
1666 proc do_delete_branch {} {
1667         error "NOT IMPLEMENTED"
1668 }
1669
1670 proc switch_branch {b} {
1671         global HEAD commit_type file_states current_branch
1672         global selected_commit_type ui_comm
1673
1674         if {![lock_index switch]} return
1675
1676         # -- Backup the selected branch (repository_state resets it)
1677         #
1678         set new_branch $current_branch
1679
1680         # -- Our in memory state should match the repository.
1681         #
1682         repository_state curType curHEAD curMERGE_HEAD
1683         if {[string match amend* $commit_type]
1684                 && $curType eq {normal}
1685                 && $curHEAD eq $HEAD} {
1686         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1687                 info_popup {Last scanned state does not match repository state.
1688
1689 Another Git program has modified this repository
1690 since the last scan.  A rescan must be performed
1691 before the current branch can be changed.
1692
1693 The rescan will be automatically started now.
1694 }
1695                 unlock_index
1696                 rescan {set ui_status_value {Ready.}}
1697                 return
1698         }
1699
1700         # -- Toss the message buffer if we are in amend mode.
1701         #
1702         if {[string match amend* $curType]} {
1703                 $ui_comm delete 0.0 end
1704                 $ui_comm edit reset
1705                 $ui_comm edit modified false
1706         }
1707
1708         set selected_commit_type new
1709         set current_branch $new_branch
1710
1711         unlock_index
1712         error "NOT FINISHED"
1713 }
1714
1715 ######################################################################
1716 ##
1717 ## remote management
1718
1719 proc load_all_remotes {} {
1720         global repo_config
1721         global all_remotes tracking_branches
1722
1723         set all_remotes [list]
1724         array unset tracking_branches
1725
1726         set rm_dir [gitdir remotes]
1727         if {[file isdirectory $rm_dir]} {
1728                 set all_remotes [glob \
1729                         -types f \
1730                         -tails \
1731                         -nocomplain \
1732                         -directory $rm_dir *]
1733
1734                 foreach name $all_remotes {
1735                         catch {
1736                                 set fd [open [file join $rm_dir $name] r]
1737                                 while {[gets $fd line] >= 0} {
1738                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
1739                                                 $line line src dst]} continue
1740                                         if {![regexp ^refs/ $dst]} {
1741                                                 set dst "refs/heads/$dst"
1742                                         }
1743                                         set tracking_branches($dst) [list $name $src]
1744                                 }
1745                                 close $fd
1746                         }
1747                 }
1748         }
1749
1750         foreach line [array names repo_config remote.*.url] {
1751                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
1752                 lappend all_remotes $name
1753
1754                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
1755                         set fl {}
1756                 }
1757                 foreach line $fl {
1758                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
1759                         if {![regexp ^refs/ $dst]} {
1760                                 set dst "refs/heads/$dst"
1761                         }
1762                         set tracking_branches($dst) [list $name $src]
1763                 }
1764         }
1765
1766         set all_remotes [lsort -unique $all_remotes]
1767 }
1768
1769 proc populate_fetch_menu {m} {
1770         global all_remotes repo_config
1771
1772         foreach r $all_remotes {
1773                 set enable 0
1774                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1775                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
1776                                 set enable 1
1777                         }
1778                 } else {
1779                         catch {
1780                                 set fd [open [gitdir remotes $r] r]
1781                                 while {[gets $fd n] >= 0} {
1782                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
1783                                                 set enable 1
1784                                                 break
1785                                         }
1786                                 }
1787                                 close $fd
1788                         }
1789                 }
1790
1791                 if {$enable} {
1792                         $m add command \
1793                                 -label "Fetch from $r..." \
1794                                 -command [list fetch_from $r] \
1795                                 -font font_ui
1796                 }
1797         }
1798 }
1799
1800 proc populate_push_menu {m} {
1801         global all_remotes repo_config
1802
1803         foreach r $all_remotes {
1804                 set enable 0
1805                 if {![catch {set a $repo_config(remote.$r.url)}]} {
1806                         if {![catch {set a $repo_config(remote.$r.push)}]} {
1807                                 set enable 1
1808                         }
1809                 } else {
1810                         catch {
1811                                 set fd [open [gitdir remotes $r] r]
1812                                 while {[gets $fd n] >= 0} {
1813                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
1814                                                 set enable 1
1815                                                 break
1816                                         }
1817                                 }
1818                                 close $fd
1819                         }
1820                 }
1821
1822                 if {$enable} {
1823                         $m add command \
1824                                 -label "Push to $r..." \
1825                                 -command [list push_to $r] \
1826                                 -font font_ui
1827                 }
1828         }
1829 }
1830
1831 proc populate_pull_menu {m} {
1832         global repo_config all_remotes disable_on_lock
1833
1834         foreach remote $all_remotes {
1835                 set rb_list [list]
1836                 if {[array get repo_config remote.$remote.url] ne {}} {
1837                         if {[array get repo_config remote.$remote.fetch] ne {}} {
1838                                 foreach line $repo_config(remote.$remote.fetch) {
1839                                         if {[regexp {^([^:]+):} $line line rb]} {
1840                                                 lappend rb_list $rb
1841                                         }
1842                                 }
1843                         }
1844                 } else {
1845                         catch {
1846                                 set fd [open [gitdir remotes $remote] r]
1847                                 while {[gets $fd line] >= 0} {
1848                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
1849                                                 lappend rb_list $rb
1850                                         }
1851                                 }
1852                                 close $fd
1853                         }
1854                 }
1855
1856                 foreach rb $rb_list {
1857                         regsub ^refs/heads/ $rb {} rb_short
1858                         $m add command \
1859                                 -label "Branch $rb_short from $remote..." \
1860                                 -command [list pull_remote $remote $rb] \
1861                                 -font font_ui
1862                         lappend disable_on_lock \
1863                                 [list $m entryconf [$m index last] -state]
1864                 }
1865         }
1866 }
1867
1868 ######################################################################
1869 ##
1870 ## icons
1871
1872 set filemask {
1873 #define mask_width 14
1874 #define mask_height 15
1875 static unsigned char mask_bits[] = {
1876    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1877    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1878    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1879 }
1880
1881 image create bitmap file_plain -background white -foreground black -data {
1882 #define plain_width 14
1883 #define plain_height 15
1884 static unsigned char plain_bits[] = {
1885    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1886    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1887    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1888 } -maskdata $filemask
1889
1890 image create bitmap file_mod -background white -foreground blue -data {
1891 #define mod_width 14
1892 #define mod_height 15
1893 static unsigned char mod_bits[] = {
1894    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1895    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1896    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1897 } -maskdata $filemask
1898
1899 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1900 #define file_fulltick_width 14
1901 #define file_fulltick_height 15
1902 static unsigned char file_fulltick_bits[] = {
1903    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1904    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1905    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1906 } -maskdata $filemask
1907
1908 image create bitmap file_parttick -background white -foreground "#005050" -data {
1909 #define parttick_width 14
1910 #define parttick_height 15
1911 static unsigned char parttick_bits[] = {
1912    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1913    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1914    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1915 } -maskdata $filemask
1916
1917 image create bitmap file_question -background white -foreground black -data {
1918 #define file_question_width 14
1919 #define file_question_height 15
1920 static unsigned char file_question_bits[] = {
1921    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1922    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1923    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1924 } -maskdata $filemask
1925
1926 image create bitmap file_removed -background white -foreground red -data {
1927 #define file_removed_width 14
1928 #define file_removed_height 15
1929 static unsigned char file_removed_bits[] = {
1930    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1931    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1932    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1933 } -maskdata $filemask
1934
1935 image create bitmap file_merge -background white -foreground blue -data {
1936 #define file_merge_width 14
1937 #define file_merge_height 15
1938 static unsigned char file_merge_bits[] = {
1939    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1940    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1941    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1942 } -maskdata $filemask
1943
1944 set ui_index .vpane.files.index.list
1945 set ui_workdir .vpane.files.workdir.list
1946
1947 set all_icons(_$ui_index)   file_plain
1948 set all_icons(A$ui_index)   file_fulltick
1949 set all_icons(M$ui_index)   file_fulltick
1950 set all_icons(D$ui_index)   file_removed
1951 set all_icons(U$ui_index)   file_merge
1952
1953 set all_icons(_$ui_workdir) file_plain
1954 set all_icons(M$ui_workdir) file_mod
1955 set all_icons(D$ui_workdir) file_question
1956 set all_icons(O$ui_workdir) file_plain
1957
1958 set max_status_desc 0
1959 foreach i {
1960                 {__ "Unmodified"}
1961                 {_M "Modified"}
1962                 {M_ "Added to commit"}
1963                 {MM "Partially added"}
1964                 {MD "Added (but gone)"}
1965
1966                 {_O "Untracked"}
1967                 {A_ "Added by commit"}
1968                 {AM "Partially added"}
1969                 {AD "Added (but gone)"}
1970
1971                 {_D "Missing"}
1972                 {DD "Removed by commit"}
1973                 {D_ "Removed by commit"}
1974                 {DO "Removed (still exists)"}
1975                 {DM "Removed (but modified)"}
1976
1977                 {UD "Merge conflicts"}
1978                 {UM "Merge conflicts"}
1979                 {U_ "Merge conflicts"}
1980         } {
1981         if {$max_status_desc < [string length [lindex $i 1]]} {
1982                 set max_status_desc [string length [lindex $i 1]]
1983         }
1984         set all_descs([lindex $i 0]) [lindex $i 1]
1985 }
1986 unset i
1987
1988 ######################################################################
1989 ##
1990 ## util
1991
1992 proc is_MacOSX {} {
1993         global tcl_platform tk_library
1994         if {[tk windowingsystem] eq {aqua}} {
1995                 return 1
1996         }
1997         return 0
1998 }
1999
2000 proc is_Windows {} {
2001         global tcl_platform
2002         if {$tcl_platform(platform) eq {windows}} {
2003                 return 1
2004         }
2005         return 0
2006 }
2007
2008 proc bind_button3 {w cmd} {
2009         bind $w <Any-Button-3> $cmd
2010         if {[is_MacOSX]} {
2011                 bind $w <Control-Button-1> $cmd
2012         }
2013 }
2014
2015 proc incr_font_size {font {amt 1}} {
2016         set sz [font configure $font -size]
2017         incr sz $amt
2018         font configure $font -size $sz
2019         font configure ${font}bold -size $sz
2020 }
2021
2022 proc hook_failed_popup {hook msg} {
2023         set w .hookfail
2024         toplevel $w
2025
2026         frame $w.m
2027         label $w.m.l1 -text "$hook hook failed:" \
2028                 -anchor w \
2029                 -justify left \
2030                 -font font_uibold
2031         text $w.m.t \
2032                 -background white -borderwidth 1 \
2033                 -relief sunken \
2034                 -width 80 -height 10 \
2035                 -font font_diff \
2036                 -yscrollcommand [list $w.m.sby set]
2037         label $w.m.l2 \
2038                 -text {You must correct the above errors before committing.} \
2039                 -anchor w \
2040                 -justify left \
2041                 -font font_uibold
2042         scrollbar $w.m.sby -command [list $w.m.t yview]
2043         pack $w.m.l1 -side top -fill x
2044         pack $w.m.l2 -side bottom -fill x
2045         pack $w.m.sby -side right -fill y
2046         pack $w.m.t -side left -fill both -expand 1
2047         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2048
2049         $w.m.t insert 1.0 $msg
2050         $w.m.t conf -state disabled
2051
2052         button $w.ok -text OK \
2053                 -width 15 \
2054                 -font font_ui \
2055                 -command "destroy $w"
2056         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2057
2058         bind $w <Visibility> "grab $w; focus $w"
2059         bind $w <Key-Return> "destroy $w"
2060         wm title $w "[appname] ([reponame]): error"
2061         tkwait window $w
2062 }
2063
2064 set next_console_id 0
2065
2066 proc new_console {short_title long_title} {
2067         global next_console_id console_data
2068         set w .console[incr next_console_id]
2069         set console_data($w) [list $short_title $long_title]
2070         return [console_init $w]
2071 }
2072
2073 proc console_init {w} {
2074         global console_cr console_data M1B
2075
2076         set console_cr($w) 1.0
2077         toplevel $w
2078         frame $w.m
2079         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2080                 -anchor w \
2081                 -justify left \
2082                 -font font_uibold
2083         text $w.m.t \
2084                 -background white -borderwidth 1 \
2085                 -relief sunken \
2086                 -width 80 -height 10 \
2087                 -font font_diff \
2088                 -state disabled \
2089                 -yscrollcommand [list $w.m.sby set]
2090         label $w.m.s -text {Working... please wait...} \
2091                 -anchor w \
2092                 -justify left \
2093                 -font font_uibold
2094         scrollbar $w.m.sby -command [list $w.m.t yview]
2095         pack $w.m.l1 -side top -fill x
2096         pack $w.m.s -side bottom -fill x
2097         pack $w.m.sby -side right -fill y
2098         pack $w.m.t -side left -fill both -expand 1
2099         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2100
2101         menu $w.ctxm -tearoff 0
2102         $w.ctxm add command -label "Copy" \
2103                 -font font_ui \
2104                 -command "tk_textCopy $w.m.t"
2105         $w.ctxm add command -label "Select All" \
2106                 -font font_ui \
2107                 -command "$w.m.t tag add sel 0.0 end"
2108         $w.ctxm add command -label "Copy All" \
2109                 -font font_ui \
2110                 -command "
2111                         $w.m.t tag add sel 0.0 end
2112                         tk_textCopy $w.m.t
2113                         $w.m.t tag remove sel 0.0 end
2114                 "
2115
2116         button $w.ok -text {Close} \
2117                 -font font_ui \
2118                 -state disabled \
2119                 -command "destroy $w"
2120         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2121
2122         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2123         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2124         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2125         bind $w <Visibility> "focus $w"
2126         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2127         return $w
2128 }
2129
2130 proc console_exec {w cmd {after {}}} {
2131         # -- Windows tosses the enviroment when we exec our child.
2132         #    But most users need that so we have to relogin. :-(
2133         #
2134         if {[is_Windows]} {
2135                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2136         }
2137
2138         # -- Tcl won't let us redirect both stdout and stderr to
2139         #    the same pipe.  So pass it through cat...
2140         #
2141         set cmd [concat | $cmd |& cat]
2142
2143         set fd_f [open $cmd r]
2144         fconfigure $fd_f -blocking 0 -translation binary
2145         fileevent $fd_f readable [list console_read $w $fd_f $after]
2146 }
2147
2148 proc console_read {w fd after} {
2149         global console_cr console_data
2150
2151         set buf [read $fd]
2152         if {$buf ne {}} {
2153                 if {![winfo exists $w]} {console_init $w}
2154                 $w.m.t conf -state normal
2155                 set c 0
2156                 set n [string length $buf]
2157                 while {$c < $n} {
2158                         set cr [string first "\r" $buf $c]
2159                         set lf [string first "\n" $buf $c]
2160                         if {$cr < 0} {set cr [expr {$n + 1}]}
2161                         if {$lf < 0} {set lf [expr {$n + 1}]}
2162
2163                         if {$lf < $cr} {
2164                                 $w.m.t insert end [string range $buf $c $lf]
2165                                 set console_cr($w) [$w.m.t index {end -1c}]
2166                                 set c $lf
2167                                 incr c
2168                         } else {
2169                                 $w.m.t delete $console_cr($w) end
2170                                 $w.m.t insert end "\n"
2171                                 $w.m.t insert end [string range $buf $c $cr]
2172                                 set c $cr
2173                                 incr c
2174                         }
2175                 }
2176                 $w.m.t conf -state disabled
2177                 $w.m.t see end
2178         }
2179
2180         fconfigure $fd -blocking 1
2181         if {[eof $fd]} {
2182                 if {[catch {close $fd}]} {
2183                         if {![winfo exists $w]} {console_init $w}
2184                         $w.m.s conf -background red -text {Error: Command Failed}
2185                         $w.ok conf -state normal
2186                         set ok 0
2187                 } elseif {[winfo exists $w]} {
2188                         $w.m.s conf -background green -text {Success}
2189                         $w.ok conf -state normal
2190                         set ok 1
2191                 }
2192                 array unset console_cr $w
2193                 array unset console_data $w
2194                 if {$after ne {}} {
2195                         uplevel #0 $after $ok
2196                 }
2197                 return
2198         }
2199         fconfigure $fd -blocking 0
2200 }
2201
2202 ######################################################################
2203 ##
2204 ## ui commands
2205
2206 set starting_gitk_msg {Starting gitk... please wait...}
2207
2208 proc do_gitk {revs} {
2209         global ui_status_value starting_gitk_msg
2210
2211         set cmd gitk
2212         if {$revs ne {}} {
2213                 append cmd { }
2214                 append cmd $revs
2215         }
2216         if {[is_Windows]} {
2217                 set cmd "sh -c \"exec $cmd\""
2218         }
2219         append cmd { &}
2220
2221         if {[catch {eval exec $cmd} err]} {
2222                 error_popup "Failed to start gitk:\n\n$err"
2223         } else {
2224                 set ui_status_value $starting_gitk_msg
2225                 after 10000 {
2226                         if {$ui_status_value eq $starting_gitk_msg} {
2227                                 set ui_status_value {Ready.}
2228                         }
2229                 }
2230         }
2231 }
2232
2233 proc do_gc {} {
2234         set w [new_console {gc} {Compressing the object database}]
2235         console_exec $w {git gc}
2236 }
2237
2238 proc do_fsck_objects {} {
2239         set w [new_console {fsck-objects} \
2240                 {Verifying the object database with fsck-objects}]
2241         set cmd [list git fsck-objects]
2242         lappend cmd --full
2243         lappend cmd --cache
2244         lappend cmd --strict
2245         console_exec $w $cmd
2246 }
2247
2248 set is_quitting 0
2249
2250 proc do_quit {} {
2251         global ui_comm is_quitting repo_config commit_type
2252
2253         if {$is_quitting} return
2254         set is_quitting 1
2255
2256         # -- Stash our current commit buffer.
2257         #
2258         set save [gitdir GITGUI_MSG]
2259         set msg [string trim [$ui_comm get 0.0 end]]
2260         if {![string match amend* $commit_type]
2261                 && [$ui_comm edit modified]
2262                 && $msg ne {}} {
2263                 catch {
2264                         set fd [open $save w]
2265                         puts $fd [string trim [$ui_comm get 0.0 end]]
2266                         close $fd
2267                 }
2268         } else {
2269                 catch {file delete $save}
2270         }
2271
2272         # -- Stash our current window geometry into this repository.
2273         #
2274         set cfg_geometry [list]
2275         lappend cfg_geometry [wm geometry .]
2276         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2277         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2278         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2279                 set rc_geometry {}
2280         }
2281         if {$cfg_geometry ne $rc_geometry} {
2282                 catch {exec git repo-config gui.geometry $cfg_geometry}
2283         }
2284
2285         destroy .
2286 }
2287
2288 proc do_rescan {} {
2289         rescan {set ui_status_value {Ready.}}
2290 }
2291
2292 proc remove_helper {txt paths} {
2293         global file_states current_diff
2294
2295         if {![lock_index begin-update]} return
2296
2297         set pathList [list]
2298         set after {}
2299         foreach path $paths {
2300                 switch -glob -- [lindex $file_states($path) 0] {
2301                 A? -
2302                 M? -
2303                 D? {
2304                         lappend pathList $path
2305                         if {$path eq $current_diff} {
2306                                 set after {reshow_diff;}
2307                         }
2308                 }
2309                 }
2310         }
2311         if {$pathList eq {}} {
2312                 unlock_index
2313         } else {
2314                 update_indexinfo \
2315                         $txt \
2316                         $pathList \
2317                         [concat $after {set ui_status_value {Ready.}}]
2318         }
2319 }
2320
2321 proc do_remove_selection {} {
2322         global current_diff selected_paths
2323
2324         if {[array size selected_paths] > 0} {
2325                 remove_helper \
2326                         {Removing selected files from commit} \
2327                         [array names selected_paths]
2328         } elseif {$current_diff ne {}} {
2329                 remove_helper \
2330                         "Removing [short_path $current_diff] from commit" \
2331                         [list $current_diff]
2332         }
2333 }
2334
2335 proc include_helper {txt paths} {
2336         global file_states current_diff
2337
2338         if {![lock_index begin-update]} return
2339
2340         set pathList [list]
2341         set after {}
2342         foreach path $paths {
2343                 switch -glob -- [lindex $file_states($path) 0] {
2344                 AM -
2345                 AD -
2346                 MM -
2347                 MD -
2348                 U? -
2349                 _M -
2350                 _D -
2351                 _O {
2352                         lappend pathList $path
2353                         if {$path eq $current_diff} {
2354                                 set after {reshow_diff;}
2355                         }
2356                 }
2357                 }
2358         }
2359         if {$pathList eq {}} {
2360                 unlock_index
2361         } else {
2362                 update_index \
2363                         $txt \
2364                         $pathList \
2365                         [concat $after {set ui_status_value {Ready to commit.}}]
2366         }
2367 }
2368
2369 proc do_include_selection {} {
2370         global current_diff selected_paths
2371
2372         if {[array size selected_paths] > 0} {
2373                 include_helper \
2374                         {Adding selected files} \
2375                         [array names selected_paths]
2376         } elseif {$current_diff ne {}} {
2377                 include_helper \
2378                         "Adding [short_path $current_diff]" \
2379                         [list $current_diff]
2380         }
2381 }
2382
2383 proc do_include_all {} {
2384         global file_states
2385
2386         set paths [list]
2387         foreach path [array names file_states] {
2388                 switch -- [lindex $file_states($path) 0] {
2389                 AM -
2390                 AD -
2391                 MM -
2392                 MD -
2393                 _M -
2394                 _D {lappend paths $path}
2395                 }
2396         }
2397         include_helper \
2398                 {Adding all modified files} \
2399                 $paths
2400 }
2401
2402 proc revert_helper {txt paths} {
2403         global file_states current_diff
2404
2405         if {![lock_index begin-update]} return
2406
2407         set pathList [list]
2408         set after {}
2409         foreach path $paths {
2410                 switch -glob -- [lindex $file_states($path) 0] {
2411                 AM -
2412                 AD -
2413                 MM -
2414                 MD -
2415                 _M -
2416                 _D {
2417                         lappend pathList $path
2418                         if {$path eq $current_diff} {
2419                                 set after {reshow_diff;}
2420                         }
2421                 }
2422                 }
2423         }
2424
2425         set n [llength $pathList]
2426         if {$n == 0} {
2427                 unlock_index
2428                 return
2429         } elseif {$n == 1} {
2430                 set s "[short_path [lindex $pathList]]"
2431         } else {
2432                 set s "these $n files"
2433         }
2434
2435         set reply [tk_dialog \
2436                 .confirm_revert \
2437                 "[appname] ([reponame])" \
2438                 "Revert changes in $s?
2439
2440 Any unadded changes will be permanently lost by the revert." \
2441                 question \
2442                 1 \
2443                 {Do Nothing} \
2444                 {Revert Changes} \
2445                 ]
2446         if {$reply == 1} {
2447                 checkout_index \
2448                         $txt \
2449                         $pathList \
2450                         [concat $after {set ui_status_value {Ready.}}]
2451         } else {
2452                 unlock_index
2453         }
2454 }
2455
2456 proc do_revert_selection {} {
2457         global current_diff selected_paths
2458
2459         if {[array size selected_paths] > 0} {
2460                 revert_helper \
2461                         {Reverting selected files} \
2462                         [array names selected_paths]
2463         } elseif {$current_diff ne {}} {
2464                 revert_helper \
2465                         "Reverting [short_path $current_diff]" \
2466                         [list $current_diff]
2467         }
2468 }
2469
2470 proc do_signoff {} {
2471         global ui_comm
2472
2473         set me [committer_ident]
2474         if {$me eq {}} return
2475
2476         set sob "Signed-off-by: $me"
2477         set last [$ui_comm get {end -1c linestart} {end -1c}]
2478         if {$last ne $sob} {
2479                 $ui_comm edit separator
2480                 if {$last ne {}
2481                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2482                         $ui_comm insert end "\n"
2483                 }
2484                 $ui_comm insert end "\n$sob"
2485                 $ui_comm edit separator
2486                 $ui_comm see end
2487         }
2488 }
2489
2490 proc do_select_commit_type {} {
2491         global commit_type selected_commit_type
2492
2493         if {$selected_commit_type eq {new}
2494                 && [string match amend* $commit_type]} {
2495                 create_new_commit
2496         } elseif {$selected_commit_type eq {amend}
2497                 && ![string match amend* $commit_type]} {
2498                 load_last_commit
2499
2500                 # The amend request was rejected...
2501                 #
2502                 if {![string match amend* $commit_type]} {
2503                         set selected_commit_type new
2504                 }
2505         }
2506 }
2507
2508 proc do_commit {} {
2509         commit_tree
2510 }
2511
2512 proc do_about {} {
2513         global appvers copyright
2514         global tcl_patchLevel tk_patchLevel
2515
2516         set w .about_dialog
2517         toplevel $w
2518         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2519
2520         label $w.header -text "About [appname]" \
2521                 -font font_uibold
2522         pack $w.header -side top -fill x
2523
2524         frame $w.buttons
2525         button $w.buttons.close -text {Close} \
2526                 -font font_ui \
2527                 -command [list destroy $w]
2528         pack $w.buttons.close -side right
2529         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2530
2531         label $w.desc \
2532                 -text "[appname] - a commit creation tool for Git.
2533 $copyright" \
2534                 -padx 5 -pady 5 \
2535                 -justify left \
2536                 -anchor w \
2537                 -borderwidth 1 \
2538                 -relief solid \
2539                 -font font_ui
2540         pack $w.desc -side top -fill x -padx 5 -pady 5
2541
2542         set v {}
2543         append v "[appname] version $appvers\n"
2544         append v "[exec git version]\n"
2545         append v "\n"
2546         if {$tcl_patchLevel eq $tk_patchLevel} {
2547                 append v "Tcl/Tk version $tcl_patchLevel"
2548         } else {
2549                 append v "Tcl version $tcl_patchLevel"
2550                 append v ", Tk version $tk_patchLevel"
2551         }
2552
2553         label $w.vers \
2554                 -text $v \
2555                 -padx 5 -pady 5 \
2556                 -justify left \
2557                 -anchor w \
2558                 -borderwidth 1 \
2559                 -relief solid \
2560                 -font font_ui
2561         pack $w.vers -side top -fill x -padx 5 -pady 5
2562
2563         menu $w.ctxm -tearoff 0
2564         $w.ctxm add command \
2565                 -label {Copy} \
2566                 -font font_ui \
2567                 -command "
2568                 clipboard clear
2569                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2570         "
2571
2572         bind $w <Visibility> "grab $w; focus $w"
2573         bind $w <Key-Escape> "destroy $w"
2574         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2575         wm title $w "About [appname]"
2576         tkwait window $w
2577 }
2578
2579 proc do_options {} {
2580         global repo_config global_config font_descs
2581         global repo_config_new global_config_new
2582
2583         array unset repo_config_new
2584         array unset global_config_new
2585         foreach name [array names repo_config] {
2586                 set repo_config_new($name) $repo_config($name)
2587         }
2588         load_config 1
2589         foreach name [array names repo_config] {
2590                 switch -- $name {
2591                 gui.diffcontext {continue}
2592                 }
2593                 set repo_config_new($name) $repo_config($name)
2594         }
2595         foreach name [array names global_config] {
2596                 set global_config_new($name) $global_config($name)
2597         }
2598
2599         set w .options_editor
2600         toplevel $w
2601         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2602
2603         label $w.header -text "[appname] Options" \
2604                 -font font_uibold
2605         pack $w.header -side top -fill x
2606
2607         frame $w.buttons
2608         button $w.buttons.restore -text {Restore Defaults} \
2609                 -font font_ui \
2610                 -command do_restore_defaults
2611         pack $w.buttons.restore -side left
2612         button $w.buttons.save -text Save \
2613                 -font font_ui \
2614                 -command [list do_save_config $w]
2615         pack $w.buttons.save -side right
2616         button $w.buttons.cancel -text {Cancel} \
2617                 -font font_ui \
2618                 -command [list destroy $w]
2619         pack $w.buttons.cancel -side right
2620         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2621
2622         labelframe $w.repo -text "[reponame] Repository" \
2623                 -font font_ui \
2624                 -relief raised -borderwidth 2
2625         labelframe $w.global -text {Global (All Repositories)} \
2626                 -font font_ui \
2627                 -relief raised -borderwidth 2
2628         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2629         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2630
2631         foreach option {
2632                 {b partialinclude {Allow Partially Added Files}}
2633                 {b pullsummary {Show Pull Summary}}
2634                 {b trustmtime  {Trust File Modification Timestamps}}
2635                 {i diffcontext {Number of Diff Context Lines}}
2636                 } {
2637                 set type [lindex $option 0]
2638                 set name [lindex $option 1]
2639                 set text [lindex $option 2]
2640                 foreach f {repo global} {
2641                         switch $type {
2642                         b {
2643                                 checkbutton $w.$f.$name -text $text \
2644                                         -variable ${f}_config_new(gui.$name) \
2645                                         -onvalue true \
2646                                         -offvalue false \
2647                                         -font font_ui
2648                                 pack $w.$f.$name -side top -anchor w
2649                         }
2650                         i {
2651                                 frame $w.$f.$name
2652                                 label $w.$f.$name.l -text "$text:" -font font_ui
2653                                 pack $w.$f.$name.l -side left -anchor w -fill x
2654                                 spinbox $w.$f.$name.v \
2655                                         -textvariable ${f}_config_new(gui.$name) \
2656                                         -from 1 -to 99 -increment 1 \
2657                                         -width 3 \
2658                                         -font font_ui
2659                                 pack $w.$f.$name.v -side right -anchor e
2660                                 pack $w.$f.$name -side top -anchor w -fill x
2661                         }
2662                         }
2663                 }
2664         }
2665
2666         set all_fonts [lsort [font families]]
2667         foreach option $font_descs {
2668                 set name [lindex $option 0]
2669                 set font [lindex $option 1]
2670                 set text [lindex $option 2]
2671
2672                 set global_config_new(gui.$font^^family) \
2673                         [font configure $font -family]
2674                 set global_config_new(gui.$font^^size) \
2675                         [font configure $font -size]
2676
2677                 frame $w.global.$name
2678                 label $w.global.$name.l -text "$text:" -font font_ui
2679                 pack $w.global.$name.l -side left -anchor w -fill x
2680                 eval tk_optionMenu $w.global.$name.family \
2681                         global_config_new(gui.$font^^family) \
2682                         $all_fonts
2683                 spinbox $w.global.$name.size \
2684                         -textvariable global_config_new(gui.$font^^size) \
2685                         -from 2 -to 80 -increment 1 \
2686                         -width 3 \
2687                         -font font_ui
2688                 pack $w.global.$name.size -side right -anchor e
2689                 pack $w.global.$name.family -side right -anchor e
2690                 pack $w.global.$name -side top -anchor w -fill x
2691         }
2692
2693         bind $w <Visibility> "grab $w; focus $w"
2694         bind $w <Key-Escape> "destroy $w"
2695         wm title $w "[appname] ([reponame]): Options"
2696         tkwait window $w
2697 }
2698
2699 proc do_restore_defaults {} {
2700         global font_descs default_config repo_config
2701         global repo_config_new global_config_new
2702
2703         foreach name [array names default_config] {
2704                 set repo_config_new($name) $default_config($name)
2705                 set global_config_new($name) $default_config($name)
2706         }
2707
2708         foreach option $font_descs {
2709                 set name [lindex $option 0]
2710                 set repo_config(gui.$name) $default_config(gui.$name)
2711         }
2712         apply_config
2713
2714         foreach option $font_descs {
2715                 set name [lindex $option 0]
2716                 set font [lindex $option 1]
2717                 set global_config_new(gui.$font^^family) \
2718                         [font configure $font -family]
2719                 set global_config_new(gui.$font^^size) \
2720                         [font configure $font -size]
2721         }
2722 }
2723
2724 proc do_save_config {w} {
2725         if {[catch {save_config} err]} {
2726                 error_popup "Failed to completely save options:\n\n$err"
2727         }
2728         reshow_diff
2729         destroy $w
2730 }
2731
2732 proc do_windows_shortcut {} {
2733         global argv0
2734
2735         if {[catch {
2736                 set desktop [exec cygpath \
2737                         --windows \
2738                         --absolute \
2739                         --long-name \
2740                         --desktop]
2741                 }]} {
2742                         set desktop .
2743         }
2744         set fn [tk_getSaveFile \
2745                 -parent . \
2746                 -title "[appname] ([reponame]): Create Desktop Icon" \
2747                 -initialdir $desktop \
2748                 -initialfile "Git [reponame].bat"]
2749         if {$fn != {}} {
2750                 if {[catch {
2751                                 set fd [open $fn w]
2752                                 set sh [exec cygpath \
2753                                         --windows \
2754                                         --absolute \
2755                                         /bin/sh]
2756                                 set me [exec cygpath \
2757                                         --unix \
2758                                         --absolute \
2759                                         $argv0]
2760                                 set gd [exec cygpath \
2761                                         --unix \
2762                                         --absolute \
2763                                         [gitdir]]
2764                                 set gw [exec cygpath \
2765                                         --windows \
2766                                         --absolute \
2767                                         [file dirname [gitdir]]]
2768                                 regsub -all ' $me "'\\''" me
2769                                 regsub -all ' $gd "'\\''" gd
2770                                 puts $fd "@ECHO Entering $gw"
2771                                 puts $fd "@ECHO Starting git-gui... please wait..."
2772                                 puts -nonewline $fd "@\"$sh\" --login -c \""
2773                                 puts -nonewline $fd "GIT_DIR='$gd'"
2774                                 puts -nonewline $fd " '$me'"
2775                                 puts $fd "&\""
2776                                 close $fd
2777                         } err]} {
2778                         error_popup "Cannot write script:\n\n$err"
2779                 }
2780         }
2781 }
2782
2783 proc do_macosx_app {} {
2784         global argv0 env
2785
2786         set fn [tk_getSaveFile \
2787                 -parent . \
2788                 -title "[appname] ([reponame]): Create Desktop Icon" \
2789                 -initialdir [file join $env(HOME) Desktop] \
2790                 -initialfile "Git [reponame].app"]
2791         if {$fn != {}} {
2792                 if {[catch {
2793                                 set Contents [file join $fn Contents]
2794                                 set MacOS [file join $Contents MacOS]
2795                                 set exe [file join $MacOS git-gui]
2796
2797                                 file mkdir $MacOS
2798
2799                                 set fd [open [file join $Contents Info.plist] w]
2800                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
2801 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
2802 <plist version="1.0">
2803 <dict>
2804         <key>CFBundleDevelopmentRegion</key>
2805         <string>English</string>
2806         <key>CFBundleExecutable</key>
2807         <string>git-gui</string>
2808         <key>CFBundleIdentifier</key>
2809         <string>org.spearce.git-gui</string>
2810         <key>CFBundleInfoDictionaryVersion</key>
2811         <string>6.0</string>
2812         <key>CFBundlePackageType</key>
2813         <string>APPL</string>
2814         <key>CFBundleSignature</key>
2815         <string>????</string>
2816         <key>CFBundleVersion</key>
2817         <string>1.0</string>
2818         <key>NSPrincipalClass</key>
2819         <string>NSApplication</string>
2820 </dict>
2821 </plist>}
2822                                 close $fd
2823
2824                                 set fd [open $exe w]
2825                                 set gd [file normalize [gitdir]]
2826                                 set ep [file normalize [exec git --exec-path]]
2827                                 regsub -all ' $gd "'\\''" gd
2828                                 regsub -all ' $ep "'\\''" ep
2829                                 puts $fd "#!/bin/sh"
2830                                 foreach name [array names env] {
2831                                         if {[string match GIT_* $name]} {
2832                                                 regsub -all ' $env($name) "'\\''" v
2833                                                 puts $fd "export $name='$v'"
2834                                         }
2835                                 }
2836                                 puts $fd "export PATH='$ep':\$PATH"
2837                                 puts $fd "export GIT_DIR='$gd'"
2838                                 puts $fd "exec [file normalize $argv0]"
2839                                 close $fd
2840
2841                                 file attributes $exe -permissions u+x,g+x,o+x
2842                         } err]} {
2843                         error_popup "Cannot write icon:\n\n$err"
2844                 }
2845         }
2846 }
2847
2848 proc toggle_or_diff {w x y} {
2849         global file_states file_lists current_diff ui_index ui_workdir
2850         global last_clicked selected_paths
2851
2852         set pos [split [$w index @$x,$y] .]
2853         set lno [lindex $pos 0]
2854         set col [lindex $pos 1]
2855         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2856         if {$path eq {}} {
2857                 set last_clicked {}
2858                 return
2859         }
2860
2861         set last_clicked [list $w $lno]
2862         array unset selected_paths
2863         $ui_index tag remove in_sel 0.0 end
2864         $ui_workdir tag remove in_sel 0.0 end
2865
2866         if {$col == 0} {
2867                 if {$current_diff eq $path} {
2868                         set after {reshow_diff;}
2869                 } else {
2870                         set after {}
2871                 }
2872                 switch -glob -- [lindex $file_states($path) 0] {
2873                 A_ -
2874                 M_ -
2875                 DD -
2876                 DO -
2877                 DM {
2878                         update_indexinfo \
2879                                 "Removing [short_path $path] from commit" \
2880                                 [list $path] \
2881                                 [concat $after {set ui_status_value {Ready.}}]
2882                 }
2883                 ?? {
2884                         update_index \
2885                                 "Adding [short_path $path]" \
2886                                 [list $path] \
2887                                 [concat $after {set ui_status_value {Ready.}}]
2888                 }
2889                 }
2890         } else {
2891                 show_diff $path $w $lno
2892         }
2893 }
2894
2895 proc add_one_to_selection {w x y} {
2896         global file_lists
2897         global last_clicked selected_paths
2898
2899         set pos [split [$w index @$x,$y] .]
2900         set lno [lindex $pos 0]
2901         set col [lindex $pos 1]
2902         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2903         if {$path eq {}} {
2904                 set last_clicked {}
2905                 return
2906         }
2907
2908         set last_clicked [list $w $lno]
2909         if {[catch {set in_sel $selected_paths($path)}]} {
2910                 set in_sel 0
2911         }
2912         if {$in_sel} {
2913                 unset selected_paths($path)
2914                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2915         } else {
2916                 set selected_paths($path) 1
2917                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2918         }
2919 }
2920
2921 proc add_range_to_selection {w x y} {
2922         global file_lists
2923         global last_clicked selected_paths
2924
2925         if {[lindex $last_clicked 0] ne $w} {
2926                 toggle_or_diff $w $x $y
2927                 return
2928         }
2929
2930         set pos [split [$w index @$x,$y] .]
2931         set lno [lindex $pos 0]
2932         set lc [lindex $last_clicked 1]
2933         if {$lc < $lno} {
2934                 set begin $lc
2935                 set end $lno
2936         } else {
2937                 set begin $lno
2938                 set end $lc
2939         }
2940
2941         foreach path [lrange $file_lists($w) \
2942                 [expr {$begin - 1}] \
2943                 [expr {$end - 1}]] {
2944                 set selected_paths($path) 1
2945         }
2946         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2947 }
2948
2949 ######################################################################
2950 ##
2951 ## config defaults
2952
2953 set cursor_ptr arrow
2954 font create font_diff -family Courier -size 10
2955 font create font_ui
2956 catch {
2957         label .dummy
2958         eval font configure font_ui [font actual [.dummy cget -font]]
2959         destroy .dummy
2960 }
2961
2962 font create font_uibold
2963 font create font_diffbold
2964
2965 if {[is_Windows]} {
2966         set M1B Control
2967         set M1T Ctrl
2968 } elseif {[is_MacOSX]} {
2969         set M1B M1
2970         set M1T Cmd
2971 } else {
2972         set M1B M1
2973         set M1T M1
2974 }
2975
2976 proc apply_config {} {
2977         global repo_config font_descs
2978
2979         foreach option $font_descs {
2980                 set name [lindex $option 0]
2981                 set font [lindex $option 1]
2982                 if {[catch {
2983                         foreach {cn cv} $repo_config(gui.$name) {
2984                                 font configure $font $cn $cv
2985                         }
2986                         } err]} {
2987                         error_popup "Invalid font specified in gui.$name:\n\n$err"
2988                 }
2989                 foreach {cn cv} [font configure $font] {
2990                         font configure ${font}bold $cn $cv
2991                 }
2992                 font configure ${font}bold -weight bold
2993         }
2994 }
2995
2996 set default_config(gui.trustmtime) false
2997 set default_config(gui.pullsummary) true
2998 set default_config(gui.partialinclude) false
2999 set default_config(gui.diffcontext) 5
3000 set default_config(gui.fontui) [font configure font_ui]
3001 set default_config(gui.fontdiff) [font configure font_diff]
3002 set font_descs {
3003         {fontui   font_ui   {Main Font}}
3004         {fontdiff font_diff {Diff/Console Font}}
3005 }
3006 load_config 0
3007 apply_config
3008
3009 ######################################################################
3010 ##
3011 ## ui construction
3012
3013 # -- Menu Bar
3014 #
3015 menu .mbar -tearoff 0
3016 .mbar add cascade -label Repository -menu .mbar.repository
3017 .mbar add cascade -label Edit -menu .mbar.edit
3018 if {!$single_commit} {
3019         .mbar add cascade -label Branch -menu .mbar.branch
3020 }
3021 .mbar add cascade -label Commit -menu .mbar.commit
3022 if {!$single_commit} {
3023         .mbar add cascade -label Fetch -menu .mbar.fetch
3024         .mbar add cascade -label Pull -menu .mbar.pull
3025         .mbar add cascade -label Push -menu .mbar.push
3026 }
3027 . configure -menu .mbar
3028
3029 # -- Repository Menu
3030 #
3031 menu .mbar.repository
3032 .mbar.repository add command \
3033         -label {Visualize Current Branch} \
3034         -command {do_gitk {}} \
3035         -font font_ui
3036 if {![is_MacOSX]} {
3037         .mbar.repository add command \
3038                 -label {Visualize All Branches} \
3039                 -command {do_gitk {--all}} \
3040                 -font font_ui
3041 }
3042 .mbar.repository add separator
3043
3044 if {!$single_commit} {
3045         .mbar.repository add command -label {Compress Database} \
3046                 -command do_gc \
3047                 -font font_ui
3048
3049         .mbar.repository add command -label {Verify Database} \
3050                 -command do_fsck_objects \
3051                 -font font_ui
3052
3053         .mbar.repository add separator
3054
3055         if {[is_Windows]} {
3056                 .mbar.repository add command \
3057                         -label {Create Desktop Icon} \
3058                         -command do_windows_shortcut \
3059                         -font font_ui
3060         } elseif {[is_MacOSX]} {
3061                 .mbar.repository add command \
3062                         -label {Create Desktop Icon} \
3063                         -command do_macosx_app \
3064                         -font font_ui
3065         }
3066 }
3067
3068 .mbar.repository add command -label Quit \
3069         -command do_quit \
3070         -accelerator $M1T-Q \
3071         -font font_ui
3072
3073 # -- Edit Menu
3074 #
3075 menu .mbar.edit
3076 .mbar.edit add command -label Undo \
3077         -command {catch {[focus] edit undo}} \
3078         -accelerator $M1T-Z \
3079         -font font_ui
3080 .mbar.edit add command -label Redo \
3081         -command {catch {[focus] edit redo}} \
3082         -accelerator $M1T-Y \
3083         -font font_ui
3084 .mbar.edit add separator
3085 .mbar.edit add command -label Cut \
3086         -command {catch {tk_textCut [focus]}} \
3087         -accelerator $M1T-X \
3088         -font font_ui
3089 .mbar.edit add command -label Copy \
3090         -command {catch {tk_textCopy [focus]}} \
3091         -accelerator $M1T-C \
3092         -font font_ui
3093 .mbar.edit add command -label Paste \
3094         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3095         -accelerator $M1T-V \
3096         -font font_ui
3097 .mbar.edit add command -label Delete \
3098         -command {catch {[focus] delete sel.first sel.last}} \
3099         -accelerator Del \
3100         -font font_ui
3101 .mbar.edit add separator
3102 .mbar.edit add command -label {Select All} \
3103         -command {catch {[focus] tag add sel 0.0 end}} \
3104         -accelerator $M1T-A \
3105         -font font_ui
3106
3107 # -- Branch Menu
3108 #
3109 if {!$single_commit} {
3110         menu .mbar.branch
3111
3112         .mbar.branch add command -label {Create...} \
3113                 -command do_create_branch \
3114                 -font font_ui
3115         lappend disable_on_lock [list .mbar.branch entryconf \
3116                 [.mbar.branch index last] -state]
3117
3118         .mbar.branch add command -label {Delete...} \
3119                 -command do_delete_branch \
3120                 -font font_ui
3121         lappend disable_on_lock [list .mbar.branch entryconf \
3122                 [.mbar.branch index last] -state]
3123 }
3124
3125 # -- Commit Menu
3126 #
3127 menu .mbar.commit
3128
3129 .mbar.commit add radiobutton \
3130         -label {New Commit} \
3131         -command do_select_commit_type \
3132         -variable selected_commit_type \
3133         -value new \
3134         -font font_ui
3135 lappend disable_on_lock \
3136         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3137
3138 .mbar.commit add radiobutton \
3139         -label {Amend Last Commit} \
3140         -command do_select_commit_type \
3141         -variable selected_commit_type \
3142         -value amend \
3143         -font font_ui
3144 lappend disable_on_lock \
3145         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3146
3147 .mbar.commit add separator
3148
3149 .mbar.commit add command -label Rescan \
3150         -command do_rescan \
3151         -accelerator F5 \
3152         -font font_ui
3153 lappend disable_on_lock \
3154         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3155
3156 .mbar.commit add command -label {Add To Commit} \
3157         -command do_include_selection \
3158         -font font_ui
3159 lappend disable_on_lock \
3160         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3161
3162 .mbar.commit add command -label {Add All To Commit} \
3163         -command do_include_all \
3164         -accelerator $M1T-I \
3165         -font font_ui
3166 lappend disable_on_lock \
3167         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3168
3169 .mbar.commit add command -label {Remove From Commit} \
3170         -command do_remove_selection \
3171         -font font_ui
3172 lappend disable_on_lock \
3173         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3174
3175 .mbar.commit add command -label {Revert Changes} \
3176         -command do_revert_selection \
3177         -font font_ui
3178 lappend disable_on_lock \
3179         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3180
3181 .mbar.commit add separator
3182
3183 .mbar.commit add command -label {Sign Off} \
3184         -command do_signoff \
3185         -accelerator $M1T-S \
3186         -font font_ui
3187
3188 .mbar.commit add command -label Commit \
3189         -command do_commit \
3190         -accelerator $M1T-Return \
3191         -font font_ui
3192 lappend disable_on_lock \
3193         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3194
3195 # -- Transport menus
3196 #
3197 if {!$single_commit} {
3198         menu .mbar.fetch
3199         menu .mbar.pull
3200         menu .mbar.push
3201 }
3202
3203 if {[is_MacOSX]} {
3204         # -- Apple Menu (Mac OS X only)
3205         #
3206         .mbar add cascade -label Apple -menu .mbar.apple
3207         menu .mbar.apple
3208
3209         .mbar.apple add command -label "About [appname]" \
3210                 -command do_about \
3211                 -font font_ui
3212         .mbar.apple add command -label "[appname] Options..." \
3213                 -command do_options \
3214                 -font font_ui
3215 } else {
3216         # -- Edit Menu
3217         #
3218         .mbar.edit add separator
3219         .mbar.edit add command -label {Options...} \
3220                 -command do_options \
3221                 -font font_ui
3222
3223         # -- Tools Menu
3224         #
3225         if {[file exists /usr/local/miga/lib/gui-miga]
3226                 && [file exists .pvcsrc]} {
3227         proc do_miga {} {
3228                 global ui_status_value
3229                 if {![lock_index update]} return
3230                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3231                 set miga_fd [open "|$cmd" r]
3232                 fconfigure $miga_fd -blocking 0
3233                 fileevent $miga_fd readable [list miga_done $miga_fd]
3234                 set ui_status_value {Running miga...}
3235         }
3236         proc miga_done {fd} {
3237                 read $fd 512
3238                 if {[eof $fd]} {
3239                         close $fd
3240                         unlock_index
3241                         rescan [list set ui_status_value {Ready.}]
3242                 }
3243         }
3244         .mbar add cascade -label Tools -menu .mbar.tools
3245         menu .mbar.tools
3246         .mbar.tools add command -label "Migrate" \
3247                 -command do_miga \
3248                 -font font_ui
3249         lappend disable_on_lock \
3250                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3251         }
3252
3253         # -- Help Menu
3254         #
3255         .mbar add cascade -label Help -menu .mbar.help
3256         menu .mbar.help
3257
3258         .mbar.help add command -label "About [appname]" \
3259                 -command do_about \
3260                 -font font_ui
3261 }
3262
3263
3264 # -- Branch Control
3265 #
3266 frame .branch \
3267         -borderwidth 1 \
3268         -relief sunken
3269 label .branch.l1 \
3270         -text {Current Branch:} \
3271         -anchor w \
3272         -justify left \
3273         -font font_ui
3274 label .branch.cb \
3275         -textvariable current_branch \
3276         -anchor w \
3277         -justify left \
3278         -font font_ui
3279 pack .branch.l1 -side left
3280 pack .branch.cb -side left -fill x
3281 pack .branch -side top -fill x
3282
3283 # -- Main Window Layout
3284 #
3285 panedwindow .vpane -orient vertical
3286 panedwindow .vpane.files -orient horizontal
3287 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3288 pack .vpane -anchor n -side top -fill both -expand 1
3289
3290 # -- Index File List
3291 #
3292 frame .vpane.files.index -height 100 -width 400
3293 label .vpane.files.index.title -text {Changes To Be Committed} \
3294         -background green \
3295         -font font_ui
3296 text $ui_index -background white -borderwidth 0 \
3297         -width 40 -height 10 \
3298         -font font_ui \
3299         -cursor $cursor_ptr \
3300         -yscrollcommand {.vpane.files.index.sb set} \
3301         -state disabled
3302 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3303 pack .vpane.files.index.title -side top -fill x
3304 pack .vpane.files.index.sb -side right -fill y
3305 pack $ui_index -side left -fill both -expand 1
3306 .vpane.files add .vpane.files.index -sticky nsew
3307
3308 # -- Working Directory File List
3309 #
3310 frame .vpane.files.workdir -height 100 -width 100
3311 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3312         -background red \
3313         -font font_ui
3314 text $ui_workdir -background white -borderwidth 0 \
3315         -width 40 -height 10 \
3316         -font font_ui \
3317         -cursor $cursor_ptr \
3318         -yscrollcommand {.vpane.files.workdir.sb set} \
3319         -state disabled
3320 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3321 pack .vpane.files.workdir.title -side top -fill x
3322 pack .vpane.files.workdir.sb -side right -fill y
3323 pack $ui_workdir -side left -fill both -expand 1
3324 .vpane.files add .vpane.files.workdir -sticky nsew
3325
3326 foreach i [list $ui_index $ui_workdir] {
3327         $i tag conf in_diff -font font_uibold
3328         $i tag conf in_sel \
3329                 -background [$i cget -foreground] \
3330                 -foreground [$i cget -background]
3331 }
3332 unset i
3333
3334 # -- Diff and Commit Area
3335 #
3336 frame .vpane.lower -height 300 -width 400
3337 frame .vpane.lower.commarea
3338 frame .vpane.lower.diff -relief sunken -borderwidth 1
3339 pack .vpane.lower.commarea -side top -fill x
3340 pack .vpane.lower.diff -side bottom -fill both -expand 1
3341 .vpane add .vpane.lower -stick nsew
3342
3343 # -- Commit Area Buttons
3344 #
3345 frame .vpane.lower.commarea.buttons
3346 label .vpane.lower.commarea.buttons.l -text {} \
3347         -anchor w \
3348         -justify left \
3349         -font font_ui
3350 pack .vpane.lower.commarea.buttons.l -side top -fill x
3351 pack .vpane.lower.commarea.buttons -side left -fill y
3352
3353 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3354         -command do_rescan \
3355         -font font_ui
3356 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3357 lappend disable_on_lock \
3358         {.vpane.lower.commarea.buttons.rescan conf -state}
3359
3360 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3361         -command do_include_all \
3362         -font font_ui
3363 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3364 lappend disable_on_lock \
3365         {.vpane.lower.commarea.buttons.incall conf -state}
3366
3367 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3368         -command do_signoff \
3369         -font font_ui
3370 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3371
3372 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3373         -command do_commit \
3374         -font font_ui
3375 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3376 lappend disable_on_lock \
3377         {.vpane.lower.commarea.buttons.commit conf -state}
3378
3379 # -- Commit Message Buffer
3380 #
3381 frame .vpane.lower.commarea.buffer
3382 frame .vpane.lower.commarea.buffer.header
3383 set ui_comm .vpane.lower.commarea.buffer.t
3384 set ui_coml .vpane.lower.commarea.buffer.header.l
3385 radiobutton .vpane.lower.commarea.buffer.header.new \
3386         -text {New Commit} \
3387         -command do_select_commit_type \
3388         -variable selected_commit_type \
3389         -value new \
3390         -font font_ui
3391 lappend disable_on_lock \
3392         [list .vpane.lower.commarea.buffer.header.new conf -state]
3393 radiobutton .vpane.lower.commarea.buffer.header.amend \
3394         -text {Amend Last Commit} \
3395         -command do_select_commit_type \
3396         -variable selected_commit_type \
3397         -value amend \
3398         -font font_ui
3399 lappend disable_on_lock \
3400         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3401 label $ui_coml \
3402         -anchor w \
3403         -justify left \
3404         -font font_ui
3405 proc trace_commit_type {varname args} {
3406         global ui_coml commit_type
3407         switch -glob -- $commit_type {
3408         initial       {set txt {Initial Commit Message:}}
3409         amend         {set txt {Amended Commit Message:}}
3410         amend-initial {set txt {Amended Initial Commit Message:}}
3411         amend-merge   {set txt {Amended Merge Commit Message:}}
3412         merge         {set txt {Merge Commit Message:}}
3413         *             {set txt {Commit Message:}}
3414         }
3415         $ui_coml conf -text $txt
3416 }
3417 trace add variable commit_type write trace_commit_type
3418 pack $ui_coml -side left -fill x
3419 pack .vpane.lower.commarea.buffer.header.amend -side right
3420 pack .vpane.lower.commarea.buffer.header.new -side right
3421
3422 text $ui_comm -background white -borderwidth 1 \
3423         -undo true \
3424         -maxundo 20 \
3425         -autoseparators true \
3426         -relief sunken \
3427         -width 75 -height 9 -wrap none \
3428         -font font_diff \
3429         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3430 scrollbar .vpane.lower.commarea.buffer.sby \
3431         -command [list $ui_comm yview]
3432 pack .vpane.lower.commarea.buffer.header -side top -fill x
3433 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3434 pack $ui_comm -side left -fill y
3435 pack .vpane.lower.commarea.buffer -side left -fill y
3436
3437 # -- Commit Message Buffer Context Menu
3438 #
3439 set ctxm .vpane.lower.commarea.buffer.ctxm
3440 menu $ctxm -tearoff 0
3441 $ctxm add command \
3442         -label {Cut} \
3443         -font font_ui \
3444         -command {tk_textCut $ui_comm}
3445 $ctxm add command \
3446         -label {Copy} \
3447         -font font_ui \
3448         -command {tk_textCopy $ui_comm}
3449 $ctxm add command \
3450         -label {Paste} \
3451         -font font_ui \
3452         -command {tk_textPaste $ui_comm}
3453 $ctxm add command \
3454         -label {Delete} \
3455         -font font_ui \
3456         -command {$ui_comm delete sel.first sel.last}
3457 $ctxm add separator
3458 $ctxm add command \
3459         -label {Select All} \
3460         -font font_ui \
3461         -command {$ui_comm tag add sel 0.0 end}
3462 $ctxm add command \
3463         -label {Copy All} \
3464         -font font_ui \
3465         -command {
3466                 $ui_comm tag add sel 0.0 end
3467                 tk_textCopy $ui_comm
3468                 $ui_comm tag remove sel 0.0 end
3469         }
3470 $ctxm add separator
3471 $ctxm add command \
3472         -label {Sign Off} \
3473         -font font_ui \
3474         -command do_signoff
3475 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3476
3477 # -- Diff Header
3478 #
3479 set current_diff {}
3480 set diff_actions [list]
3481 proc trace_current_diff {varname args} {
3482         global current_diff diff_actions file_states
3483         if {$current_diff eq {}} {
3484                 set s {}
3485                 set f {}
3486                 set p {}
3487                 set o disabled
3488         } else {
3489                 set p $current_diff
3490                 set s [mapdesc [lindex $file_states($p) 0] $p]
3491                 set f {File:}
3492                 set p [escape_path $p]
3493                 set o normal
3494         }
3495
3496         .vpane.lower.diff.header.status configure -text $s
3497         .vpane.lower.diff.header.file configure -text $f
3498         .vpane.lower.diff.header.path configure -text $p
3499         foreach w $diff_actions {
3500                 uplevel #0 $w $o
3501         }
3502 }
3503 trace add variable current_diff write trace_current_diff
3504
3505 frame .vpane.lower.diff.header -background orange
3506 label .vpane.lower.diff.header.status \
3507         -background orange \
3508         -width $max_status_desc \
3509         -anchor w \
3510         -justify left \
3511         -font font_ui
3512 label .vpane.lower.diff.header.file \
3513         -background orange \
3514         -anchor w \
3515         -justify left \
3516         -font font_ui
3517 label .vpane.lower.diff.header.path \
3518         -background orange \
3519         -anchor w \
3520         -justify left \
3521         -font font_ui
3522 pack .vpane.lower.diff.header.status -side left
3523 pack .vpane.lower.diff.header.file -side left
3524 pack .vpane.lower.diff.header.path -fill x
3525 set ctxm .vpane.lower.diff.header.ctxm
3526 menu $ctxm -tearoff 0
3527 $ctxm add command \
3528         -label {Copy} \
3529         -font font_ui \
3530         -command {
3531                 clipboard clear
3532                 clipboard append \
3533                         -format STRING \
3534                         -type STRING \
3535                         -- $current_diff
3536         }
3537 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3538 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3539
3540 # -- Diff Body
3541 #
3542 frame .vpane.lower.diff.body
3543 set ui_diff .vpane.lower.diff.body.t
3544 text $ui_diff -background white -borderwidth 0 \
3545         -width 80 -height 15 -wrap none \
3546         -font font_diff \
3547         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3548         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3549         -state disabled
3550 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3551         -command [list $ui_diff xview]
3552 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3553         -command [list $ui_diff yview]
3554 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3555 pack .vpane.lower.diff.body.sby -side right -fill y
3556 pack $ui_diff -side left -fill both -expand 1
3557 pack .vpane.lower.diff.header -side top -fill x
3558 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3559
3560 $ui_diff tag conf d_@ -font font_diffbold
3561 $ui_diff tag conf d_+  -foreground blue
3562 $ui_diff tag conf d_-  -foreground red
3563 $ui_diff tag conf d_++ -foreground {#00a000}
3564 $ui_diff tag conf d_-- -foreground {#a000a0}
3565 $ui_diff tag conf d_+- \
3566         -foreground red \
3567         -background {light goldenrod yellow}
3568 $ui_diff tag conf d_-+ \
3569         -foreground blue \
3570         -background azure2
3571
3572 # -- Diff Body Context Menu
3573 #
3574 set ctxm .vpane.lower.diff.body.ctxm
3575 menu $ctxm -tearoff 0
3576 $ctxm add command \
3577         -label {Copy} \
3578         -font font_ui \
3579         -command {tk_textCopy $ui_diff}
3580 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3581 $ctxm add command \
3582         -label {Select All} \
3583         -font font_ui \
3584         -command {$ui_diff tag add sel 0.0 end}
3585 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3586 $ctxm add command \
3587         -label {Copy All} \
3588         -font font_ui \
3589         -command {
3590                 $ui_diff tag add sel 0.0 end
3591                 tk_textCopy $ui_diff
3592                 $ui_diff tag remove sel 0.0 end
3593         }
3594 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3595 $ctxm add separator
3596 $ctxm add command \
3597         -label {Decrease Font Size} \
3598         -font font_ui \
3599         -command {incr_font_size font_diff -1}
3600 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3601 $ctxm add command \
3602         -label {Increase Font Size} \
3603         -font font_ui \
3604         -command {incr_font_size font_diff 1}
3605 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3606 $ctxm add separator
3607 $ctxm add command \
3608         -label {Show Less Context} \
3609         -font font_ui \
3610         -command {if {$repo_config(gui.diffcontext) >= 2} {
3611                 incr repo_config(gui.diffcontext) -1
3612                 reshow_diff
3613         }}
3614 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3615 $ctxm add command \
3616         -label {Show More Context} \
3617         -font font_ui \
3618         -command {
3619                 incr repo_config(gui.diffcontext)
3620                 reshow_diff
3621         }
3622 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3623 $ctxm add separator
3624 $ctxm add command -label {Options...} \
3625         -font font_ui \
3626         -command do_options
3627 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3628
3629 # -- Status Bar
3630 #
3631 set ui_status_value {Initializing...}
3632 label .status -textvariable ui_status_value \
3633         -anchor w \
3634         -justify left \
3635         -borderwidth 1 \
3636         -relief sunken \
3637         -font font_ui
3638 pack .status -anchor w -side bottom -fill x
3639
3640 # -- Load geometry
3641 #
3642 catch {
3643 set gm $repo_config(gui.geometry)
3644 wm geometry . [lindex $gm 0]
3645 .vpane sash place 0 \
3646         [lindex [.vpane sash coord 0] 0] \
3647         [lindex $gm 1]
3648 .vpane.files sash place 0 \
3649         [lindex $gm 2] \
3650         [lindex [.vpane.files sash coord 0] 1]
3651 unset gm
3652 }
3653
3654 # -- Key Bindings
3655 #
3656 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3657 bind $ui_comm <$M1B-Key-i> {do_include_all;break}
3658 bind $ui_comm <$M1B-Key-I> {do_include_all;break}
3659 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3660 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3661 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3662 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3663 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3664 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3665 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3666 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3667
3668 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3669 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3670 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3671 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3672 bind $ui_diff <$M1B-Key-v> {break}
3673 bind $ui_diff <$M1B-Key-V> {break}
3674 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3675 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3676 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3677 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3678 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3679 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3680
3681 bind .   <Destroy> do_quit
3682 bind all <Key-F5> do_rescan
3683 bind all <$M1B-Key-r> do_rescan
3684 bind all <$M1B-Key-R> do_rescan
3685 bind .   <$M1B-Key-s> do_signoff
3686 bind .   <$M1B-Key-S> do_signoff
3687 bind .   <$M1B-Key-i> do_include_all
3688 bind .   <$M1B-Key-I> do_include_all
3689 bind .   <$M1B-Key-Return> do_commit
3690 bind all <$M1B-Key-q> do_quit
3691 bind all <$M1B-Key-Q> do_quit
3692 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3693 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3694 foreach i [list $ui_index $ui_workdir] {
3695         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3696         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3697         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3698 }
3699 unset i
3700
3701 set file_lists($ui_index) [list]
3702 set file_lists($ui_workdir) [list]
3703
3704 set HEAD {}
3705 set PARENT {}
3706 set MERGE_HEAD [list]
3707 set commit_type {}
3708 set empty_tree {}
3709 set current_branch {}
3710 set current_diff {}
3711 set selected_commit_type new
3712
3713 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3714 focus -force $ui_comm
3715
3716 # -- Warn the user about environmental problems.  Cygwin's Tcl
3717 #    does *not* pass its env array onto any processes it spawns.
3718 #    This means that git processes get none of our environment.
3719 #
3720 if {[is_Windows]} {
3721         set ignored_env 0
3722         set suggest_user {}
3723         set msg "Possible environment issues exist.
3724
3725 The following environment variables are probably
3726 going to be ignored by any Git subprocess run
3727 by [appname]:
3728
3729 "
3730         foreach name [array names env] {
3731                 switch -regexp -- $name {
3732                 {^GIT_INDEX_FILE$} -
3733                 {^GIT_OBJECT_DIRECTORY$} -
3734                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3735                 {^GIT_DIFF_OPTS$} -
3736                 {^GIT_EXTERNAL_DIFF$} -
3737                 {^GIT_PAGER$} -
3738                 {^GIT_TRACE$} -
3739                 {^GIT_CONFIG$} -
3740                 {^GIT_CONFIG_LOCAL$} -
3741                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3742                         append msg " - $name\n"
3743                         incr ignored_env
3744                 }
3745                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3746                         append msg " - $name\n"
3747                         incr ignored_env
3748                         set suggest_user $name
3749                 }
3750                 }
3751         }
3752         if {$ignored_env > 0} {
3753                 append msg "
3754 This is due to a known issue with the
3755 Tcl binary distributed by Cygwin."
3756
3757                 if {$suggest_user ne {}} {
3758                         append msg "
3759
3760 A good replacement for $suggest_user
3761 is placing values for the user.name and
3762 user.email settings into your personal
3763 ~/.gitconfig file.
3764 "
3765                 }
3766                 warn_popup $msg
3767         }
3768         unset ignored_env msg suggest_user name
3769 }
3770
3771 # -- Only initialize complex UI if we are going to stay running.
3772 #
3773 if {!$single_commit} {
3774         load_all_remotes
3775         load_all_heads
3776
3777         populate_branch_menu .mbar.branch
3778         populate_fetch_menu .mbar.fetch
3779         populate_pull_menu .mbar.pull
3780         populate_push_menu .mbar.push
3781 }
3782
3783 # -- Only suggest a gc run if we are going to stay running.
3784 #
3785 if {!$single_commit} {
3786         set object_limit 2000
3787         if {[is_Windows]} {set object_limit 200}
3788         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
3789         if {$objects_current >= $object_limit} {
3790                 if {[ask_popup \
3791                         "This repository currently has $objects_current loose objects.
3792
3793 To maintain optimal performance it is strongly
3794 recommended that you compress the database
3795 when more than $object_limit loose objects exist.
3796
3797 Compress the database now?"] eq yes} {
3798                         do_gc
3799                 }
3800         }
3801         unset object_limit _junk objects_current
3802 }
3803
3804 lock_index begin-read
3805 after 1 do_rescan