git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 D_ {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD {
1118                         set file_states($path) [list \
1119                                 _[string index $m 1] \
1120                                 [lindex $s 1] \
1121                                 [lindex $s 3] \
1122                                 {}]
1123                 }
1124                 }
1125         }
1126
1127         display_all_files
1128         unlock_index
1129         reshow_diff
1130         set ui_status_value \
1131                 "Changes committed as [string range $cmt_id 0 7]."
1132 }
1133
1134 ######################################################################
1135 ##
1136 ## fetch pull push
1137
1138 proc fetch_from {remote} {
1139         set w [new_console "fetch $remote" \
1140                 "Fetching new changes from $remote"]
1141         set cmd [list git fetch]
1142         lappend cmd $remote
1143         console_exec $w $cmd
1144 }
1145
1146 proc pull_remote {remote branch} {
1147         global HEAD commit_type file_states repo_config
1148
1149         if {![lock_index update]} return
1150
1151         # -- Our in memory state should match the repository.
1152         #
1153         repository_state curType curHEAD curMERGE_HEAD
1154         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1155                 info_popup {Last scanned state does not match repository state.
1156
1157 Another Git program has modified this repository
1158 since the last scan.  A rescan must be performed
1159 before a pull operation can be started.
1160
1161 The rescan will be automatically started now.
1162 }
1163                 unlock_index
1164                 rescan {set ui_status_value {Ready.}}
1165                 return
1166         }
1167
1168         # -- No differences should exist before a pull.
1169         #
1170         if {[array size file_states] != 0} {
1171                 error_popup {Uncommitted but modified files are present.
1172
1173 You should not perform a pull with unmodified
1174 files in your working directory as Git will be
1175 unable to recover from an incorrect merge.
1176
1177 You should commit or revert all changes before
1178 starting a pull operation.
1179 }
1180                 unlock_index
1181                 return
1182         }
1183
1184         set w [new_console "pull $remote $branch" \
1185                 "Pulling new changes from branch $branch in $remote"]
1186         set cmd [list git pull]
1187         if {$repo_config(gui.pullsummary) eq {false}} {
1188                 lappend cmd --no-summary
1189         }
1190         lappend cmd $remote
1191         lappend cmd $branch
1192         console_exec $w $cmd [list post_pull_remote $remote $branch]
1193 }
1194
1195 proc post_pull_remote {remote branch success} {
1196         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1197         global ui_status_value
1198
1199         unlock_index
1200         if {$success} {
1201                 repository_state commit_type HEAD MERGE_HEAD
1202                 set PARENT $HEAD
1203                 set selected_commit_type new
1204                 set ui_status_value "Pulling $branch from $remote complete."
1205         } else {
1206                 rescan [list set ui_status_value \
1207                         "Conflicts detected while pulling $branch from $remote."]
1208         }
1209 }
1210
1211 proc push_to {remote} {
1212         set w [new_console "push $remote" \
1213                 "Pushing changes to $remote"]
1214         set cmd [list git push]
1215         lappend cmd $remote
1216         console_exec $w $cmd
1217 }
1218
1219 ######################################################################
1220 ##
1221 ## ui helpers
1222
1223 proc mapicon {w state path} {
1224         global all_icons
1225
1226         if {[catch {set r $all_icons($state$w)}]} {
1227                 puts "error: no icon for $w state={$state} $path"
1228                 return file_plain
1229         }
1230         return $r
1231 }
1232
1233 proc mapdesc {state path} {
1234         global all_descs
1235
1236         if {[catch {set r $all_descs($state)}]} {
1237                 puts "error: no desc for state={$state} $path"
1238                 return $state
1239         }
1240         return $r
1241 }
1242
1243 proc escape_path {path} {
1244         regsub -all "\n" $path "\\n" path
1245         return $path
1246 }
1247
1248 proc short_path {path} {
1249         return [escape_path [lindex [file split $path] end]]
1250 }
1251
1252 set next_icon_id 0
1253 set null_sha1 [string repeat 0 40]
1254
1255 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1256         global file_states next_icon_id null_sha1
1257
1258         set s0 [string index $new_state 0]
1259         set s1 [string index $new_state 1]
1260
1261         if {[catch {set info $file_states($path)}]} {
1262                 set state __
1263                 set icon n[incr next_icon_id]
1264         } else {
1265                 set state [lindex $info 0]
1266                 set icon [lindex $info 1]
1267                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1268                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1269         }
1270
1271         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1272         elseif {$s0 eq {_}} {set s0 _}
1273
1274         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1275         elseif {$s1 eq {_}} {set s1 _}
1276
1277         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1278                 set head_info [list 0 $null_sha1]
1279         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1280                 && $head_info eq {}} {
1281                 set head_info $index_info
1282         }
1283
1284         set file_states($path) [list $s0$s1 $icon \
1285                 $head_info $index_info \
1286                 ]
1287         return $state
1288 }
1289
1290 proc display_file_helper {w path icon_name old_m new_m} {
1291         global file_lists
1292
1293         if {$new_m eq {_}} {
1294                 set lno [lsearch -sorted $file_lists($w) $path]
1295                 if {$lno >= 0} {
1296                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1297                         incr lno
1298                         $w conf -state normal
1299                         $w delete $lno.0 [expr {$lno + 1}].0
1300                         $w conf -state disabled
1301                 }
1302         } elseif {$old_m eq {_} && $new_m ne {_}} {
1303                 lappend file_lists($w) $path
1304                 set file_lists($w) [lsort -unique $file_lists($w)]
1305                 set lno [lsearch -sorted $file_lists($w) $path]
1306                 incr lno
1307                 $w conf -state normal
1308                 $w image create $lno.0 \
1309                         -align center -padx 5 -pady 1 \
1310                         -name $icon_name \
1311                         -image [mapicon $w $new_m $path]
1312                 $w insert $lno.1 "[escape_path $path]\n"
1313                 $w conf -state disabled
1314         } elseif {$old_m ne $new_m} {
1315                 $w conf -state normal
1316                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1317                 $w conf -state disabled
1318         }
1319 }
1320
1321 proc display_file {path state} {
1322         global file_states selected_paths
1323         global ui_index ui_workdir
1324
1325         set old_m [merge_state $path $state]
1326         set s $file_states($path)
1327         set new_m [lindex $s 0]
1328         set icon_name [lindex $s 1]
1329
1330         display_file_helper     $ui_index $path $icon_name \
1331                 [string index $old_m 0] \
1332                 [string index $new_m 0]
1333         display_file_helper     $ui_workdir $path $icon_name \
1334                 [string index $old_m 1] \
1335                 [string index $new_m 1]
1336
1337         if {$new_m eq {__}} {
1338                 unset file_states($path)
1339                 catch {unset selected_paths($path)}
1340         }
1341 }
1342
1343 proc display_all_files_helper {w path icon_name m} {
1344         global file_lists
1345
1346         lappend file_lists($w) $path
1347         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1348         $w image create end \
1349                 -align center -padx 5 -pady 1 \
1350                 -name $icon_name \
1351                 -image [mapicon $w $m $path]
1352         $w insert end "[escape_path $path]\n"
1353 }
1354
1355 proc display_all_files {} {
1356         global ui_index ui_workdir
1357         global file_states file_lists
1358         global last_clicked
1359
1360         $ui_index conf -state normal
1361         $ui_workdir conf -state normal
1362
1363         $ui_index delete 0.0 end
1364         $ui_workdir delete 0.0 end
1365         set last_clicked {}
1366
1367         set file_lists($ui_index) [list]
1368         set file_lists($ui_workdir) [list]
1369
1370         foreach path [lsort [array names file_states]] {
1371                 set s $file_states($path)
1372                 set m [lindex $s 0]
1373                 set icon_name [lindex $s 1]
1374
1375                 if {[string index $m 0] ne {_}} {
1376                         display_all_files_helper $ui_index $path \
1377                                 $icon_name [string index $m 0]
1378                 }
1379                 if {[string index $m 1] ne {_}} {
1380                         display_all_files_helper $ui_workdir $path \
1381                                 $icon_name [string index $m 1]
1382                 }
1383         }
1384
1385         $ui_index conf -state disabled
1386         $ui_workdir conf -state disabled
1387 }
1388
1389 proc update_indexinfo {msg pathList after} {
1390         global update_index_cp ui_status_value
1391
1392         if {![lock_index update]} return
1393
1394         set update_index_cp 0
1395         set pathList [lsort $pathList]
1396         set totalCnt [llength $pathList]
1397         set batch [expr {int($totalCnt * .01) + 1}]
1398         if {$batch > 25} {set batch 25}
1399
1400         set ui_status_value [format \
1401                 "$msg... %i/%i files (%.2f%%)" \
1402                 $update_index_cp \
1403                 $totalCnt \
1404                 0.0]
1405         set fd [open "| git update-index -z --index-info" w]
1406         fconfigure $fd \
1407                 -blocking 0 \
1408                 -buffering full \
1409                 -buffersize 512 \
1410                 -translation binary
1411         fileevent $fd writable [list \
1412                 write_update_indexinfo \
1413                 $fd \
1414                 $pathList \
1415                 $totalCnt \
1416                 $batch \
1417                 $msg \
1418                 $after \
1419                 ]
1420 }
1421
1422 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1423         global update_index_cp ui_status_value
1424         global file_states current_diff
1425
1426         if {$update_index_cp >= $totalCnt} {
1427                 close $fd
1428                 unlock_index
1429                 uplevel #0 $after
1430                 return
1431         }
1432
1433         for {set i $batch} \
1434                 {$update_index_cp < $totalCnt && $i > 0} \
1435                 {incr i -1} {
1436                 set path [lindex $pathList $update_index_cp]
1437                 incr update_index_cp
1438
1439                 set s $file_states($path)
1440                 switch -glob -- [lindex $s 0] {
1441                 A? {set new _O}
1442                 M? {set new _M}
1443                 D_ {set new _D}
1444                 D? {set new _?}
1445                 ?? {continue}
1446                 }
1447                 set info [lindex $s 2]
1448                 if {$info eq {}} continue
1449
1450                 puts -nonewline $fd "$info\t$path\0"
1451                 display_file $path $new
1452         }
1453
1454         set ui_status_value [format \
1455                 "$msg... %i/%i files (%.2f%%)" \
1456                 $update_index_cp \
1457                 $totalCnt \
1458                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1459 }
1460
1461 proc update_index {msg pathList after} {
1462         global update_index_cp ui_status_value
1463
1464         if {![lock_index update]} return
1465
1466         set update_index_cp 0
1467         set pathList [lsort $pathList]
1468         set totalCnt [llength $pathList]
1469         set batch [expr {int($totalCnt * .01) + 1}]
1470         if {$batch > 25} {set batch 25}
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 0.0]
1477         set fd [open "| git update-index --add --remove -z --stdin" w]
1478         fconfigure $fd \
1479                 -blocking 0 \
1480                 -buffering full \
1481                 -buffersize 512 \
1482                 -translation binary
1483         fileevent $fd writable [list \
1484                 write_update_index \
1485                 $fd \
1486                 $pathList \
1487                 $totalCnt \
1488                 $batch \
1489                 $msg \
1490                 $after \
1491                 ]
1492 }
1493
1494 proc write_update_index {fd pathList totalCnt batch msg after} {
1495         global update_index_cp ui_status_value
1496         global file_states current_diff
1497
1498         if {$update_index_cp >= $totalCnt} {
1499                 close $fd
1500                 unlock_index
1501                 uplevel #0 $after
1502                 return
1503         }
1504
1505         for {set i $batch} \
1506                 {$update_index_cp < $totalCnt && $i > 0} \
1507                 {incr i -1} {
1508                 set path [lindex $pathList $update_index_cp]
1509                 incr update_index_cp
1510
1511                 switch -glob -- [lindex $file_states($path) 0] {
1512                 AD {set new __}
1513                 ?D {set new D_}
1514                 _O -
1515                 AM {set new A_}
1516                 U_ -
1517                 ?M {set new M_}
1518                 ?? {continue}
1519                 }
1520                 puts -nonewline $fd "$path\0"
1521                 display_file $path $new
1522         }
1523
1524         set ui_status_value [format \
1525                 "$msg... %i/%i files (%.2f%%)" \
1526                 $update_index_cp \
1527                 $totalCnt \
1528                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1529 }
1530
1531 proc checkout_index {msg pathList after} {
1532         global update_index_cp ui_status_value
1533
1534         if {![lock_index update]} return
1535
1536         set update_index_cp 0
1537         set pathList [lsort $pathList]
1538         set totalCnt [llength $pathList]
1539         set batch [expr {int($totalCnt * .01) + 1}]
1540         if {$batch > 25} {set batch 25}
1541
1542         set ui_status_value [format \
1543                 "$msg... %i/%i files (%.2f%%)" \
1544                 $update_index_cp \
1545                 $totalCnt \
1546                 0.0]
1547         set cmd [list git checkout-index]
1548         lappend cmd --index
1549         lappend cmd --quiet
1550         lappend cmd --force
1551         lappend cmd -z
1552         lappend cmd --stdin
1553         set fd [open "| $cmd " w]
1554         fconfigure $fd \
1555                 -blocking 0 \
1556                 -buffering full \
1557                 -buffersize 512 \
1558                 -translation binary
1559         fileevent $fd writable [list \
1560                 write_checkout_index \
1561                 $fd \
1562                 $pathList \
1563                 $totalCnt \
1564                 $batch \
1565                 $msg \
1566                 $after \
1567                 ]
1568 }
1569
1570 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1571         global update_index_cp ui_status_value
1572         global file_states current_diff
1573
1574         if {$update_index_cp >= $totalCnt} {
1575                 close $fd
1576                 unlock_index
1577                 uplevel #0 $after
1578                 return
1579         }
1580
1581         for {set i $batch} \
1582                 {$update_index_cp < $totalCnt && $i > 0} \
1583                 {incr i -1} {
1584                 set path [lindex $pathList $update_index_cp]
1585                 incr update_index_cp
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 U? {continue}
1588                 ?M -
1589                 ?D {
1590                         puts -nonewline $fd "$path\0"
1591                         display_file $path ?_
1592                 }
1593                 }
1594         }
1595
1596         set ui_status_value [format \
1597                 "$msg... %i/%i files (%.2f%%)" \
1598                 $update_index_cp \
1599                 $totalCnt \
1600                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1601 }
1602
1603 ######################################################################
1604 ##
1605 ## branch management
1606
1607 proc load_all_heads {} {
1608         global all_heads tracking_branches
1609
1610         set all_heads [list]
1611         set cmd [list git for-each-ref]
1612         lappend cmd --format=%(refname)
1613         lappend cmd refs/heads
1614         set fd [open "| $cmd" r]
1615         while {[gets $fd line] > 0} {
1616                 if {![catch {set info $tracking_branches($line)}]} continue
1617                 if {![regsub ^refs/heads/ $line {} name]} continue
1618                 lappend all_heads $name
1619         }
1620         close $fd
1621
1622         set all_heads [lsort $all_heads]
1623 }
1624
1625 proc populate_branch_menu {} {
1626         global all_heads disable_on_lock
1627
1628         set m .mbar.branch
1629         set last [$m index last]
1630         for {set i 0} {$i <= $last} {incr i} {
1631                 if {[$m type $i] eq {separator}} {
1632                         $m delete $i last
1633                         set new_dol [list]
1634                         foreach a $disable_on_lock {
1635                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1636                                         lappend new_dol $a
1637                                 }
1638                         }
1639                         set disable_on_lock $new_dol
1640                         break
1641                 }
1642         }
1643
1644         $m add separator
1645         foreach b $all_heads {
1646                 $m add radiobutton \
1647                         -label $b \
1648                         -command [list switch_branch $b] \
1649                         -variable current_branch \
1650                         -value $b \
1651                         -font font_ui
1652                 lappend disable_on_lock \
1653                         [list $m entryconf [$m index last] -state]
1654         }
1655 }
1656
1657 proc do_create_branch_action {w} {
1658         global all_heads null_sha1
1659         global create_branch_checkout create_branch_revtype create_branch_head
1660
1661         set newbranch [string trim [$w.name.t get 0.0 end]]
1662         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1663                 tk_messageBox \
1664                         -icon error \
1665                         -type ok \
1666                         -title [wm title $w] \
1667                         -parent $w \
1668                         -message "Branch '$newbranch' already exists."
1669                 focus $w.name.t
1670                 return
1671         }
1672         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1673                 tk_messageBox \
1674                         -icon error \
1675                         -type ok \
1676                         -title [wm title $w] \
1677                         -parent $w \
1678                         -message "We do not like '$newbranch' as a branch name."
1679                 focus $w.name.t
1680                 return
1681         }
1682
1683         set rev {}
1684         switch -- $create_branch_revtype {
1685         head {set rev $create_branch_head}
1686         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1687         }
1688         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1689                 tk_messageBox \
1690                         -icon error \
1691                         -type ok \
1692                         -title [wm title $w] \
1693                         -parent $w \
1694                         -message "Invalid starting revision: $rev"
1695                 return
1696         }
1697         set cmd [list git update-ref]
1698         lappend cmd -m
1699         lappend cmd "branch: Created from $rev"
1700         lappend cmd "refs/heads/$newbranch"
1701         lappend cmd $cmt
1702         lappend cmd $null_sha1
1703         if {[catch {eval exec $cmd} err]} {
1704                 tk_messageBox \
1705                         -icon error \
1706                         -type ok \
1707                         -title [wm title $w] \
1708                         -parent $w \
1709                         -message "Failed to create '$newbranch'.\n\n$err"
1710                 return
1711         }
1712
1713         lappend all_heads $newbranch
1714         set all_heads [lsort $all_heads]
1715         populate_branch_menu
1716         destroy $w
1717 }
1718
1719 proc do_create_branch {} {
1720         global all_heads current_branch
1721         global create_branch_checkout create_branch_revtype create_branch_head
1722
1723         set create_branch_checkout true
1724         set create_branch_revtype head
1725         set create_branch_head $current_branch
1726
1727         set w .branch_editor
1728         toplevel $w
1729         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1730
1731         label $w.header -text {Create New Branch} \
1732                 -font font_uibold
1733         pack $w.header -side top -fill x
1734
1735         frame $w.buttons
1736         button $w.buttons.create -text Create \
1737                 -font font_ui \
1738                 -default active \
1739                 -command [list do_create_branch_action $w]
1740         pack $w.buttons.create -side right
1741         button $w.buttons.cancel -text {Cancel} \
1742                 -font font_ui \
1743                 -command [list destroy $w]
1744         pack $w.buttons.cancel -side right -padx 5
1745         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1746
1747         labelframe $w.name \
1748                 -text {Branch Description} \
1749                 -font font_ui
1750         label $w.name.l -text {Name:} -font font_ui
1751         text $w.name.t \
1752                 -height 1 \
1753                 -width 40 \
1754                 -font font_ui
1755         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1756         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1757         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1758         bind $w.name.t <Key> {
1759                 if {{%K} ne {BackSpace}
1760                         && {%K} ne {Tab}
1761                         && {%K} ne {Escape}
1762                         && {%K} ne {Return}} {
1763                         if {%k <= 32} break
1764                         if {[string first %A {~^:?*[}] >= 0} break
1765                 }
1766         }
1767         pack $w.name.l -side left -padx 5
1768         pack $w.name.t -side left -fill x -expand 1
1769         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1770
1771         labelframe $w.from \
1772                 -text {Starting Revision} \
1773                 -font font_ui
1774         frame $w.from.head
1775         radiobutton $w.from.head.r \
1776                 -text {Local Branch:} \
1777                 -value head \
1778                 -variable create_branch_revtype \
1779                 -font font_ui
1780         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1781         pack $w.from.head.r -side left
1782         pack $w.from.head.m -side left
1783         frame $w.from.exp
1784         radiobutton $w.from.exp.r \
1785                 -text {Revision Expression:} \
1786                 -value expression \
1787                 -variable create_branch_revtype \
1788                 -font font_ui
1789         text $w.from.exp.t \
1790                 -height 1 \
1791                 -width 50 \
1792                 -font font_ui
1793         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1794         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1795         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1796         pack $w.from.exp.r -side left
1797         pack $w.from.exp.t -side left -fill x -expand 1
1798         pack $w.from.head -padx 5 -fill x -expand 1
1799         pack $w.from.exp -padx 5 -fill x -expand 1
1800         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1801
1802         labelframe $w.postActions \
1803                 -text {Post Creation Actions} \
1804                 -font font_ui
1805         checkbutton $w.postActions.checkout \
1806                 -text {Checkout after creation} \
1807                 -offvalue false \
1808                 -onvalue true \
1809                 -variable create_branch_checkout \
1810                 -font font_ui
1811         pack $w.postActions.checkout -anchor nw
1812         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1813
1814         bind $w <Visibility> "grab $w; focus $w.name.t"
1815         bind $w <Key-Escape> "destroy $w"
1816         bind $w <Key-Return> "do_create_branch_action $w;break"
1817         wm title $w "[appname] ([reponame]): Create Branch"
1818         tkwait window $w
1819 }
1820
1821 proc do_delete_branch_action {w} {
1822         global all_heads
1823         global delete_branch_checkhead delete_branch_head
1824
1825         set to_delete [list]
1826         set msg {Are you sure you want to delete the following branches?
1827
1828 }
1829         foreach i [$w.list.l curselection] {
1830                 set b [$w.list.l get $i]
1831                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1832                 if {$delete_branch_checkhead} {
1833                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1834                         if {$o ne $m} continue
1835                 }
1836                 lappend to_delete [list $b $o]
1837                 append msg " - $b\n"
1838         }
1839         if {$to_delete eq {}} {
1840                 tk_messageBox \
1841                         -icon info \
1842                         -type ok \
1843                         -title [wm title $w] \
1844                         -parent $w \
1845                         -message {No branches are able to be deleted.
1846
1847 This is likely because you did not select any branches,
1848 or all selected branches are not completely merged.
1849 }
1850                 return
1851         }
1852         append msg {
1853 It can be difficult to recover deleted branches.
1854
1855 Delete the above branches?}
1856         if {[tk_messageBox \
1857                 -icon warning \
1858                 -type yesno \
1859                 -title [wm title $w] \
1860                 -parent $w \
1861                 -message $msg] ne yes} {
1862                 return
1863         }
1864
1865         set failed {}
1866         foreach i $to_delete {
1867                 set b [lindex $i 0]
1868                 set o [lindex $i 1]
1869                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1870                         append failed " - $b: $err\n"
1871                 } else {
1872                         set x [lsearch -sorted $all_heads $b]
1873                         if {$x >= 0} {
1874                                 set all_heads [lreplace $all_heads $x $x]
1875                         }
1876                 }
1877         }
1878
1879         if {$failed ne {}} {
1880                 tk_messageBox \
1881                         -icon error \
1882                         -type ok \
1883                         -title [wm title $w] \
1884                         -parent $w \
1885                         -message "Failed to delete branches:\n$failed"
1886         }
1887
1888         set all_heads [lsort $all_heads]
1889         populate_branch_menu
1890         destroy $w
1891 }
1892
1893 proc do_delete_branch {} {
1894         global all_heads tracking_branches current_branch
1895         global delete_branch_checkhead delete_branch_head
1896
1897         set delete_branch_checkhead 1
1898         set delete_branch_head $current_branch
1899
1900         set w .branch_editor
1901         toplevel $w
1902         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1903
1904         label $w.header -text {Delete Local Branch} \
1905                 -font font_uibold
1906         pack $w.header -side top -fill x
1907
1908         frame $w.buttons
1909         button $w.buttons.create -text Delete \
1910                 -font font_ui \
1911                 -command [list do_delete_branch_action $w]
1912         pack $w.buttons.create -side right
1913         button $w.buttons.cancel -text {Cancel} \
1914                 -font font_ui \
1915                 -command [list destroy $w]
1916         pack $w.buttons.cancel -side right -padx 5
1917         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1918
1919         labelframe $w.list \
1920                 -text {Local Branches} \
1921                 -font font_ui
1922         listbox $w.list.l \
1923                 -height 10 \
1924                 -width 50 \
1925                 -selectmode extended \
1926                 -font font_ui
1927         foreach h $all_heads {
1928                 if {$h ne $current_branch} {
1929                         $w.list.l insert end $h
1930                 }
1931         }
1932         pack $w.list.l -fill both -pady 5 -padx 5
1933         pack $w.list -fill both -pady 5 -padx 5
1934
1935         set all_trackings [list]
1936         foreach b [array names tracking_branches] {
1937                 regsub ^refs/(heads|remotes)/ $b {} b
1938                 lappend all_trackings $b
1939         }
1940
1941         labelframe $w.validate \
1942                 -text {Only Delete If} \
1943                 -font font_ui
1944         frame $w.validate.head
1945         checkbutton $w.validate.head.r \
1946                 -text {Already Merged Into:} \
1947                 -variable delete_branch_checkhead \
1948                 -font font_ui
1949         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1950                 $all_heads \
1951                 [lsort -unique $all_trackings]
1952         pack $w.validate.head.r -side left
1953         pack $w.validate.head.m -side left
1954         pack $w.validate.head -padx 5 -fill x -expand 1
1955         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1956
1957         bind $w <Visibility> "grab $w; focus $w"
1958         bind $w <Key-Escape> "destroy $w"
1959         wm title $w "[appname] ([reponame]): Delete Branch"
1960         tkwait window $w
1961 }
1962
1963 proc switch_branch {b} {
1964         global HEAD commit_type file_states current_branch
1965         global selected_commit_type ui_comm
1966
1967         if {![lock_index switch]} return
1968
1969         # -- Backup the selected branch (repository_state resets it)
1970         #
1971         set new_branch $current_branch
1972
1973         # -- Our in memory state should match the repository.
1974         #
1975         repository_state curType curHEAD curMERGE_HEAD
1976         if {[string match amend* $commit_type]
1977                 && $curType eq {normal}
1978                 && $curHEAD eq $HEAD} {
1979         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1980                 info_popup {Last scanned state does not match repository state.
1981
1982 Another Git program has modified this repository
1983 since the last scan.  A rescan must be performed
1984 before the current branch can be changed.
1985
1986 The rescan will be automatically started now.
1987 }
1988                 unlock_index
1989                 rescan {set ui_status_value {Ready.}}
1990                 return
1991         }
1992
1993         # -- Toss the message buffer if we are in amend mode.
1994         #
1995         if {[string match amend* $curType]} {
1996                 $ui_comm delete 0.0 end
1997                 $ui_comm edit reset
1998                 $ui_comm edit modified false
1999         }
2000
2001         set selected_commit_type new
2002         set current_branch $new_branch
2003
2004         unlock_index
2005         error "NOT FINISHED"
2006 }
2007
2008 ######################################################################
2009 ##
2010 ## remote management
2011
2012 proc load_all_remotes {} {
2013         global repo_config
2014         global all_remotes tracking_branches
2015
2016         set all_remotes [list]
2017         array unset tracking_branches
2018
2019         set rm_dir [gitdir remotes]
2020         if {[file isdirectory $rm_dir]} {
2021                 set all_remotes [glob \
2022                         -types f \
2023                         -tails \
2024                         -nocomplain \
2025                         -directory $rm_dir *]
2026
2027                 foreach name $all_remotes {
2028                         catch {
2029                                 set fd [open [file join $rm_dir $name] r]
2030                                 while {[gets $fd line] >= 0} {
2031                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2032                                                 $line line src dst]} continue
2033                                         if {![regexp ^refs/ $dst]} {
2034                                                 set dst "refs/heads/$dst"
2035                                         }
2036                                         set tracking_branches($dst) [list $name $src]
2037                                 }
2038                                 close $fd
2039                         }
2040                 }
2041         }
2042
2043         foreach line [array names repo_config remote.*.url] {
2044                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2045                 lappend all_remotes $name
2046
2047                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2048                         set fl {}
2049                 }
2050                 foreach line $fl {
2051                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2052                         if {![regexp ^refs/ $dst]} {
2053                                 set dst "refs/heads/$dst"
2054                         }
2055                         set tracking_branches($dst) [list $name $src]
2056                 }
2057         }
2058
2059         set all_remotes [lsort -unique $all_remotes]
2060 }
2061
2062 proc populate_fetch_menu {m} {
2063         global all_remotes repo_config
2064
2065         foreach r $all_remotes {
2066                 set enable 0
2067                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2068                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2069                                 set enable 1
2070                         }
2071                 } else {
2072                         catch {
2073                                 set fd [open [gitdir remotes $r] r]
2074                                 while {[gets $fd n] >= 0} {
2075                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2076                                                 set enable 1
2077                                                 break
2078                                         }
2079                                 }
2080                                 close $fd
2081                         }
2082                 }
2083
2084                 if {$enable} {
2085                         $m add command \
2086                                 -label "Fetch from $r..." \
2087                                 -command [list fetch_from $r] \
2088                                 -font font_ui
2089                 }
2090         }
2091 }
2092
2093 proc populate_push_menu {m} {
2094         global all_remotes repo_config
2095
2096         foreach r $all_remotes {
2097                 set enable 0
2098                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2099                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2100                                 set enable 1
2101                         }
2102                 } else {
2103                         catch {
2104                                 set fd [open [gitdir remotes $r] r]
2105                                 while {[gets $fd n] >= 0} {
2106                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2107                                                 set enable 1
2108                                                 break
2109                                         }
2110                                 }
2111                                 close $fd
2112                         }
2113                 }
2114
2115                 if {$enable} {
2116                         $m add command \
2117                                 -label "Push to $r..." \
2118                                 -command [list push_to $r] \
2119                                 -font font_ui
2120                 }
2121         }
2122 }
2123
2124 proc populate_pull_menu {m} {
2125         global repo_config all_remotes disable_on_lock
2126
2127         foreach remote $all_remotes {
2128                 set rb_list [list]
2129                 if {[array get repo_config remote.$remote.url] ne {}} {
2130                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2131                                 foreach line $repo_config(remote.$remote.fetch) {
2132                                         if {[regexp {^([^:]+):} $line line rb]} {
2133                                                 lappend rb_list $rb
2134                                         }
2135                                 }
2136                         }
2137                 } else {
2138                         catch {
2139                                 set fd [open [gitdir remotes $remote] r]
2140                                 while {[gets $fd line] >= 0} {
2141                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2142                                                 lappend rb_list $rb
2143                                         }
2144                                 }
2145                                 close $fd
2146                         }
2147                 }
2148
2149                 foreach rb $rb_list {
2150                         regsub ^refs/heads/ $rb {} rb_short
2151                         $m add command \
2152                                 -label "Branch $rb_short from $remote..." \
2153                                 -command [list pull_remote $remote $rb] \
2154                                 -font font_ui
2155                         lappend disable_on_lock \
2156                                 [list $m entryconf [$m index last] -state]
2157                 }
2158         }
2159 }
2160
2161 ######################################################################
2162 ##
2163 ## icons
2164
2165 set filemask {
2166 #define mask_width 14
2167 #define mask_height 15
2168 static unsigned char mask_bits[] = {
2169    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2170    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2171    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2172 }
2173
2174 image create bitmap file_plain -background white -foreground black -data {
2175 #define plain_width 14
2176 #define plain_height 15
2177 static unsigned char plain_bits[] = {
2178    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2179    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2180    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2181 } -maskdata $filemask
2182
2183 image create bitmap file_mod -background white -foreground blue -data {
2184 #define mod_width 14
2185 #define mod_height 15
2186 static unsigned char mod_bits[] = {
2187    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2188    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2189    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2190 } -maskdata $filemask
2191
2192 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2193 #define file_fulltick_width 14
2194 #define file_fulltick_height 15
2195 static unsigned char file_fulltick_bits[] = {
2196    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2197    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2198    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2199 } -maskdata $filemask
2200
2201 image create bitmap file_parttick -background white -foreground "#005050" -data {
2202 #define parttick_width 14
2203 #define parttick_height 15
2204 static unsigned char parttick_bits[] = {
2205    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2206    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2207    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2208 } -maskdata $filemask
2209
2210 image create bitmap file_question -background white -foreground black -data {
2211 #define file_question_width 14
2212 #define file_question_height 15
2213 static unsigned char file_question_bits[] = {
2214    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2215    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2216    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2217 } -maskdata $filemask
2218
2219 image create bitmap file_removed -background white -foreground red -data {
2220 #define file_removed_width 14
2221 #define file_removed_height 15
2222 static unsigned char file_removed_bits[] = {
2223    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2224    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2225    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2226 } -maskdata $filemask
2227
2228 image create bitmap file_merge -background white -foreground blue -data {
2229 #define file_merge_width 14
2230 #define file_merge_height 15
2231 static unsigned char file_merge_bits[] = {
2232    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2233    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2234    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2235 } -maskdata $filemask
2236
2237 set ui_index .vpane.files.index.list
2238 set ui_workdir .vpane.files.workdir.list
2239
2240 set all_icons(_$ui_index)   file_plain
2241 set all_icons(A$ui_index)   file_fulltick
2242 set all_icons(M$ui_index)   file_fulltick
2243 set all_icons(D$ui_index)   file_removed
2244 set all_icons(U$ui_index)   file_merge
2245
2246 set all_icons(_$ui_workdir) file_plain
2247 set all_icons(M$ui_workdir) file_mod
2248 set all_icons(D$ui_workdir) file_question
2249 set all_icons(O$ui_workdir) file_plain
2250
2251 set max_status_desc 0
2252 foreach i {
2253                 {__ "Unmodified"}
2254
2255                 {_M "Modified, not staged"}
2256                 {M_ "Staged for commit"}
2257                 {MM "Portions staged for commit"}
2258                 {MD "Staged for commit, missing"}
2259
2260                 {_O "Untracked, not staged"}
2261                 {A_ "Staged for commit"}
2262                 {AM "Portions staged for commit"}
2263                 {AD "Staged for commit, missing"}
2264
2265                 {_D "Missing"}
2266                 {D_ "Staged for removal"}
2267                 {DO "Staged for removal, still present"}
2268
2269                 {U_ "Requires merge resolution"}
2270                 {UM "Requires merge resolution"}
2271                 {UD "Requires merge resolution"}
2272         } {
2273         if {$max_status_desc < [string length [lindex $i 1]]} {
2274                 set max_status_desc [string length [lindex $i 1]]
2275         }
2276         set all_descs([lindex $i 0]) [lindex $i 1]
2277 }
2278 unset i
2279
2280 ######################################################################
2281 ##
2282 ## util
2283
2284 proc is_MacOSX {} {
2285         global tcl_platform tk_library
2286         if {[tk windowingsystem] eq {aqua}} {
2287                 return 1
2288         }
2289         return 0
2290 }
2291
2292 proc is_Windows {} {
2293         global tcl_platform
2294         if {$tcl_platform(platform) eq {windows}} {
2295                 return 1
2296         }
2297         return 0
2298 }
2299
2300 proc bind_button3 {w cmd} {
2301         bind $w <Any-Button-3> $cmd
2302         if {[is_MacOSX]} {
2303                 bind $w <Control-Button-1> $cmd
2304         }
2305 }
2306
2307 proc incr_font_size {font {amt 1}} {
2308         set sz [font configure $font -size]
2309         incr sz $amt
2310         font configure $font -size $sz
2311         font configure ${font}bold -size $sz
2312 }
2313
2314 proc hook_failed_popup {hook msg} {
2315         set w .hookfail
2316         toplevel $w
2317
2318         frame $w.m
2319         label $w.m.l1 -text "$hook hook failed:" \
2320                 -anchor w \
2321                 -justify left \
2322                 -font font_uibold
2323         text $w.m.t \
2324                 -background white -borderwidth 1 \
2325                 -relief sunken \
2326                 -width 80 -height 10 \
2327                 -font font_diff \
2328                 -yscrollcommand [list $w.m.sby set]
2329         label $w.m.l2 \
2330                 -text {You must correct the above errors before committing.} \
2331                 -anchor w \
2332                 -justify left \
2333                 -font font_uibold
2334         scrollbar $w.m.sby -command [list $w.m.t yview]
2335         pack $w.m.l1 -side top -fill x
2336         pack $w.m.l2 -side bottom -fill x
2337         pack $w.m.sby -side right -fill y
2338         pack $w.m.t -side left -fill both -expand 1
2339         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2340
2341         $w.m.t insert 1.0 $msg
2342         $w.m.t conf -state disabled
2343
2344         button $w.ok -text OK \
2345                 -width 15 \
2346                 -font font_ui \
2347                 -command "destroy $w"
2348         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2349
2350         bind $w <Visibility> "grab $w; focus $w"
2351         bind $w <Key-Return> "destroy $w"
2352         wm title $w "[appname] ([reponame]): error"
2353         tkwait window $w
2354 }
2355
2356 set next_console_id 0
2357
2358 proc new_console {short_title long_title} {
2359         global next_console_id console_data
2360         set w .console[incr next_console_id]
2361         set console_data($w) [list $short_title $long_title]
2362         return [console_init $w]
2363 }
2364
2365 proc console_init {w} {
2366         global console_cr console_data M1B
2367
2368         set console_cr($w) 1.0
2369         toplevel $w
2370         frame $w.m
2371         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2372                 -anchor w \
2373                 -justify left \
2374                 -font font_uibold
2375         text $w.m.t \
2376                 -background white -borderwidth 1 \
2377                 -relief sunken \
2378                 -width 80 -height 10 \
2379                 -font font_diff \
2380                 -state disabled \
2381                 -yscrollcommand [list $w.m.sby set]
2382         label $w.m.s -text {Working... please wait...} \
2383                 -anchor w \
2384                 -justify left \
2385                 -font font_uibold
2386         scrollbar $w.m.sby -command [list $w.m.t yview]
2387         pack $w.m.l1 -side top -fill x
2388         pack $w.m.s -side bottom -fill x
2389         pack $w.m.sby -side right -fill y
2390         pack $w.m.t -side left -fill both -expand 1
2391         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2392
2393         menu $w.ctxm -tearoff 0
2394         $w.ctxm add command -label "Copy" \
2395                 -font font_ui \
2396                 -command "tk_textCopy $w.m.t"
2397         $w.ctxm add command -label "Select All" \
2398                 -font font_ui \
2399                 -command "$w.m.t tag add sel 0.0 end"
2400         $w.ctxm add command -label "Copy All" \
2401                 -font font_ui \
2402                 -command "
2403                         $w.m.t tag add sel 0.0 end
2404                         tk_textCopy $w.m.t
2405                         $w.m.t tag remove sel 0.0 end
2406                 "
2407
2408         button $w.ok -text {Close} \
2409                 -font font_ui \
2410                 -state disabled \
2411                 -command "destroy $w"
2412         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2413
2414         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2415         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2416         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2417         bind $w <Visibility> "focus $w"
2418         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2419         return $w
2420 }
2421
2422 proc console_exec {w cmd {after {}}} {
2423         # -- Windows tosses the enviroment when we exec our child.
2424         #    But most users need that so we have to relogin. :-(
2425         #
2426         if {[is_Windows]} {
2427                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2428         }
2429
2430         # -- Tcl won't let us redirect both stdout and stderr to
2431         #    the same pipe.  So pass it through cat...
2432         #
2433         set cmd [concat | $cmd |& cat]
2434
2435         set fd_f [open $cmd r]
2436         fconfigure $fd_f -blocking 0 -translation binary
2437         fileevent $fd_f readable [list console_read $w $fd_f $after]
2438 }
2439
2440 proc console_read {w fd after} {
2441         global console_cr console_data
2442
2443         set buf [read $fd]
2444         if {$buf ne {}} {
2445                 if {![winfo exists $w]} {console_init $w}
2446                 $w.m.t conf -state normal
2447                 set c 0
2448                 set n [string length $buf]
2449                 while {$c < $n} {
2450                         set cr [string first "\r" $buf $c]
2451                         set lf [string first "\n" $buf $c]
2452                         if {$cr < 0} {set cr [expr {$n + 1}]}
2453                         if {$lf < 0} {set lf [expr {$n + 1}]}
2454
2455                         if {$lf < $cr} {
2456                                 $w.m.t insert end [string range $buf $c $lf]
2457                                 set console_cr($w) [$w.m.t index {end -1c}]
2458                                 set c $lf
2459                                 incr c
2460                         } else {
2461                                 $w.m.t delete $console_cr($w) end
2462                                 $w.m.t insert end "\n"
2463                                 $w.m.t insert end [string range $buf $c $cr]
2464                                 set c $cr
2465                                 incr c
2466                         }
2467                 }
2468                 $w.m.t conf -state disabled
2469                 $w.m.t see end
2470         }
2471
2472         fconfigure $fd -blocking 1
2473         if {[eof $fd]} {
2474                 if {[catch {close $fd}]} {
2475                         if {![winfo exists $w]} {console_init $w}
2476                         $w.m.s conf -background red -text {Error: Command Failed}
2477                         $w.ok conf -state normal
2478                         set ok 0
2479                 } elseif {[winfo exists $w]} {
2480                         $w.m.s conf -background green -text {Success}
2481                         $w.ok conf -state normal
2482                         set ok 1
2483                 }
2484                 array unset console_cr $w
2485                 array unset console_data $w
2486                 if {$after ne {}} {
2487                         uplevel #0 $after $ok
2488                 }
2489                 return
2490         }
2491         fconfigure $fd -blocking 0
2492 }
2493
2494 ######################################################################
2495 ##
2496 ## ui commands
2497
2498 set starting_gitk_msg {Starting gitk... please wait...}
2499
2500 proc do_gitk {revs} {
2501         global ui_status_value starting_gitk_msg
2502
2503         set cmd gitk
2504         if {$revs ne {}} {
2505                 append cmd { }
2506                 append cmd $revs
2507         }
2508         if {[is_Windows]} {
2509                 set cmd "sh -c \"exec $cmd\""
2510         }
2511         append cmd { &}
2512
2513         if {[catch {eval exec $cmd} err]} {
2514                 error_popup "Failed to start gitk:\n\n$err"
2515         } else {
2516                 set ui_status_value $starting_gitk_msg
2517                 after 10000 {
2518                         if {$ui_status_value eq $starting_gitk_msg} {
2519                                 set ui_status_value {Ready.}
2520                         }
2521                 }
2522         }
2523 }
2524
2525 proc do_gc {} {
2526         set w [new_console {gc} {Compressing the object database}]
2527         console_exec $w {git gc}
2528 }
2529
2530 proc do_fsck_objects {} {
2531         set w [new_console {fsck-objects} \
2532                 {Verifying the object database with fsck-objects}]
2533         set cmd [list git fsck-objects]
2534         lappend cmd --full
2535         lappend cmd --cache
2536         lappend cmd --strict
2537         console_exec $w $cmd
2538 }
2539
2540 set is_quitting 0
2541
2542 proc do_quit {} {
2543         global ui_comm is_quitting repo_config commit_type
2544
2545         if {$is_quitting} return
2546         set is_quitting 1
2547
2548         # -- Stash our current commit buffer.
2549         #
2550         set save [gitdir GITGUI_MSG]
2551         set msg [string trim [$ui_comm get 0.0 end]]
2552         if {![string match amend* $commit_type]
2553                 && [$ui_comm edit modified]
2554                 && $msg ne {}} {
2555                 catch {
2556                         set fd [open $save w]
2557                         puts $fd [string trim [$ui_comm get 0.0 end]]
2558                         close $fd
2559                 }
2560         } else {
2561                 catch {file delete $save}
2562         }
2563
2564         # -- Stash our current window geometry into this repository.
2565         #
2566         set cfg_geometry [list]
2567         lappend cfg_geometry [wm geometry .]
2568         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2569         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2570         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2571                 set rc_geometry {}
2572         }
2573         if {$cfg_geometry ne $rc_geometry} {
2574                 catch {exec git repo-config gui.geometry $cfg_geometry}
2575         }
2576
2577         destroy .
2578 }
2579
2580 proc do_rescan {} {
2581         rescan {set ui_status_value {Ready.}}
2582 }
2583
2584 proc unstage_helper {txt paths} {
2585         global file_states current_diff
2586
2587         if {![lock_index begin-update]} return
2588
2589         set pathList [list]
2590         set after {}
2591         foreach path $paths {
2592                 switch -glob -- [lindex $file_states($path) 0] {
2593                 A? -
2594                 M? -
2595                 D? {
2596                         lappend pathList $path
2597                         if {$path eq $current_diff} {
2598                                 set after {reshow_diff;}
2599                         }
2600                 }
2601                 }
2602         }
2603         if {$pathList eq {}} {
2604                 unlock_index
2605         } else {
2606                 update_indexinfo \
2607                         $txt \
2608                         $pathList \
2609                         [concat $after {set ui_status_value {Ready.}}]
2610         }
2611 }
2612
2613 proc do_unstage_selection {} {
2614         global current_diff selected_paths
2615
2616         if {[array size selected_paths] > 0} {
2617                 unstage_helper \
2618                         {Unstaging selected files from commit} \
2619                         [array names selected_paths]
2620         } elseif {$current_diff ne {}} {
2621                 unstage_helper \
2622                         "Unstaging [short_path $current_diff] from commit" \
2623                         [list $current_diff]
2624         }
2625 }
2626
2627 proc add_helper {txt paths} {
2628         global file_states current_diff
2629
2630         if {![lock_index begin-update]} return
2631
2632         set pathList [list]
2633         set after {}
2634         foreach path $paths {
2635                 switch -glob -- [lindex $file_states($path) 0] {
2636                 _O -
2637                 ?M -
2638                 ?D -
2639                 U? {
2640                         lappend pathList $path
2641                         if {$path eq $current_diff} {
2642                                 set after {reshow_diff;}
2643                         }
2644                 }
2645                 }
2646         }
2647         if {$pathList eq {}} {
2648                 unlock_index
2649         } else {
2650                 update_index \
2651                         $txt \
2652                         $pathList \
2653                         [concat $after {set ui_status_value {Ready to commit.}}]
2654         }
2655 }
2656
2657 proc do_add_selection {} {
2658         global current_diff selected_paths
2659
2660         if {[array size selected_paths] > 0} {
2661                 add_helper \
2662                         {Adding selected files} \
2663                         [array names selected_paths]
2664         } elseif {$current_diff ne {}} {
2665                 add_helper \
2666                         "Adding [short_path $current_diff]" \
2667                         [list $current_diff]
2668         }
2669 }
2670
2671 proc do_add_all {} {
2672         global file_states
2673
2674         set paths [list]
2675         foreach path [array names file_states] {
2676                 switch -glob -- [lindex $file_states($path) 0] {
2677                 U? {continue}
2678                 ?M -
2679                 ?D {lappend paths $path}
2680                 }
2681         }
2682         add_helper {Adding all changed files} $paths
2683 }
2684
2685 proc revert_helper {txt paths} {
2686         global file_states current_diff
2687
2688         if {![lock_index begin-update]} return
2689
2690         set pathList [list]
2691         set after {}
2692         foreach path $paths {
2693                 switch -glob -- [lindex $file_states($path) 0] {
2694                 U? {continue}
2695                 ?M -
2696                 ?D {
2697                         lappend pathList $path
2698                         if {$path eq $current_diff} {
2699                                 set after {reshow_diff;}
2700                         }
2701                 }
2702                 }
2703         }
2704
2705         set n [llength $pathList]
2706         if {$n == 0} {
2707                 unlock_index
2708                 return
2709         } elseif {$n == 1} {
2710                 set s "[short_path [lindex $pathList]]"
2711         } else {
2712                 set s "these $n files"
2713         }
2714
2715         set reply [tk_dialog \
2716                 .confirm_revert \
2717                 "[appname] ([reponame])" \
2718                 "Revert changes in $s?
2719
2720 Any unadded changes will be permanently lost by the revert." \
2721                 question \
2722                 1 \
2723                 {Do Nothing} \
2724                 {Revert Changes} \
2725                 ]
2726         if {$reply == 1} {
2727                 checkout_index \
2728                         $txt \
2729                         $pathList \
2730                         [concat $after {set ui_status_value {Ready.}}]
2731         } else {
2732                 unlock_index
2733         }
2734 }
2735
2736 proc do_revert_selection {} {
2737         global current_diff selected_paths
2738
2739         if {[array size selected_paths] > 0} {
2740                 revert_helper \
2741                         {Reverting selected files} \
2742                         [array names selected_paths]
2743         } elseif {$current_diff ne {}} {
2744                 revert_helper \
2745                         "Reverting [short_path $current_diff]" \
2746                         [list $current_diff]
2747         }
2748 }
2749
2750 proc do_signoff {} {
2751         global ui_comm
2752
2753         set me [committer_ident]
2754         if {$me eq {}} return
2755
2756         set sob "Signed-off-by: $me"
2757         set last [$ui_comm get {end -1c linestart} {end -1c}]
2758         if {$last ne $sob} {
2759                 $ui_comm edit separator
2760                 if {$last ne {}
2761                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2762                         $ui_comm insert end "\n"
2763                 }
2764                 $ui_comm insert end "\n$sob"
2765                 $ui_comm edit separator
2766                 $ui_comm see end
2767         }
2768 }
2769
2770 proc do_select_commit_type {} {
2771         global commit_type selected_commit_type
2772
2773         if {$selected_commit_type eq {new}
2774                 && [string match amend* $commit_type]} {
2775                 create_new_commit
2776         } elseif {$selected_commit_type eq {amend}
2777                 && ![string match amend* $commit_type]} {
2778                 load_last_commit
2779
2780                 # The amend request was rejected...
2781                 #
2782                 if {![string match amend* $commit_type]} {
2783                         set selected_commit_type new
2784                 }
2785         }
2786 }
2787
2788 proc do_commit {} {
2789         commit_tree
2790 }
2791
2792 proc do_about {} {
2793         global appvers copyright
2794         global tcl_patchLevel tk_patchLevel
2795
2796         set w .about_dialog
2797         toplevel $w
2798         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2799
2800         label $w.header -text "About [appname]" \
2801                 -font font_uibold
2802         pack $w.header -side top -fill x
2803
2804         frame $w.buttons
2805         button $w.buttons.close -text {Close} \
2806                 -font font_ui \
2807                 -command [list destroy $w]
2808         pack $w.buttons.close -side right
2809         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2810
2811         label $w.desc \
2812                 -text "[appname] - a commit creation tool for Git.
2813 $copyright" \
2814                 -padx 5 -pady 5 \
2815                 -justify left \
2816                 -anchor w \
2817                 -borderwidth 1 \
2818                 -relief solid \
2819                 -font font_ui
2820         pack $w.desc -side top -fill x -padx 5 -pady 5
2821
2822         set v {}
2823         append v "[appname] version $appvers\n"
2824         append v "[exec git version]\n"
2825         append v "\n"
2826         if {$tcl_patchLevel eq $tk_patchLevel} {
2827                 append v "Tcl/Tk version $tcl_patchLevel"
2828         } else {
2829                 append v "Tcl version $tcl_patchLevel"
2830                 append v ", Tk version $tk_patchLevel"
2831         }
2832
2833         label $w.vers \
2834                 -text $v \
2835                 -padx 5 -pady 5 \
2836                 -justify left \
2837                 -anchor w \
2838                 -borderwidth 1 \
2839                 -relief solid \
2840                 -font font_ui
2841         pack $w.vers -side top -fill x -padx 5 -pady 5
2842
2843         menu $w.ctxm -tearoff 0
2844         $w.ctxm add command \
2845                 -label {Copy} \
2846                 -font font_ui \
2847                 -command "
2848                 clipboard clear
2849                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2850         "
2851
2852         bind $w <Visibility> "grab $w; focus $w"
2853         bind $w <Key-Escape> "destroy $w"
2854         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2855         wm title $w "About [appname]"
2856         tkwait window $w
2857 }
2858
2859 proc do_options {} {
2860         global repo_config global_config font_descs
2861         global repo_config_new global_config_new
2862
2863         array unset repo_config_new
2864         array unset global_config_new
2865         foreach name [array names repo_config] {
2866                 set repo_config_new($name) $repo_config($name)
2867         }
2868         load_config 1
2869         foreach name [array names repo_config] {
2870                 switch -- $name {
2871                 gui.diffcontext {continue}
2872                 }
2873                 set repo_config_new($name) $repo_config($name)
2874         }
2875         foreach name [array names global_config] {
2876                 set global_config_new($name) $global_config($name)
2877         }
2878
2879         set w .options_editor
2880         toplevel $w
2881         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2882
2883         label $w.header -text "[appname] Options" \
2884                 -font font_uibold
2885         pack $w.header -side top -fill x
2886
2887         frame $w.buttons
2888         button $w.buttons.restore -text {Restore Defaults} \
2889                 -font font_ui \
2890                 -command do_restore_defaults
2891         pack $w.buttons.restore -side left
2892         button $w.buttons.save -text Save \
2893                 -font font_ui \
2894                 -command [list do_save_config $w]
2895         pack $w.buttons.save -side right
2896         button $w.buttons.cancel -text {Cancel} \
2897                 -font font_ui \
2898                 -command [list destroy $w]
2899         pack $w.buttons.cancel -side right -padx 5
2900         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2901
2902         labelframe $w.repo -text "[reponame] Repository" \
2903                 -font font_ui \
2904                 -relief raised -borderwidth 2
2905         labelframe $w.global -text {Global (All Repositories)} \
2906                 -font font_ui \
2907                 -relief raised -borderwidth 2
2908         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2909         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2910
2911         foreach option {
2912                 {b partialinclude {Allow Partially Added Files}}
2913                 {b pullsummary {Show Pull Summary}}
2914                 {b trustmtime  {Trust File Modification Timestamps}}
2915                 {i diffcontext {Number of Diff Context Lines}}
2916                 } {
2917                 set type [lindex $option 0]
2918                 set name [lindex $option 1]
2919                 set text [lindex $option 2]
2920                 foreach f {repo global} {
2921                         switch $type {
2922                         b {
2923                                 checkbutton $w.$f.$name -text $text \
2924                                         -variable ${f}_config_new(gui.$name) \
2925                                         -onvalue true \
2926                                         -offvalue false \
2927                                         -font font_ui
2928                                 pack $w.$f.$name -side top -anchor w
2929                         }
2930                         i {
2931                                 frame $w.$f.$name
2932                                 label $w.$f.$name.l -text "$text:" -font font_ui
2933                                 pack $w.$f.$name.l -side left -anchor w -fill x
2934                                 spinbox $w.$f.$name.v \
2935                                         -textvariable ${f}_config_new(gui.$name) \
2936                                         -from 1 -to 99 -increment 1 \
2937                                         -width 3 \
2938                                         -font font_ui
2939                                 pack $w.$f.$name.v -side right -anchor e
2940                                 pack $w.$f.$name -side top -anchor w -fill x
2941                         }
2942                         }
2943                 }
2944         }
2945
2946         set all_fonts [lsort [font families]]
2947         foreach option $font_descs {
2948                 set name [lindex $option 0]
2949                 set font [lindex $option 1]
2950                 set text [lindex $option 2]
2951
2952                 set global_config_new(gui.$font^^family) \
2953                         [font configure $font -family]
2954                 set global_config_new(gui.$font^^size) \
2955                         [font configure $font -size]
2956
2957                 frame $w.global.$name
2958                 label $w.global.$name.l -text "$text:" -font font_ui
2959                 pack $w.global.$name.l -side left -anchor w -fill x
2960                 eval tk_optionMenu $w.global.$name.family \
2961                         global_config_new(gui.$font^^family) \
2962                         $all_fonts
2963                 spinbox $w.global.$name.size \
2964                         -textvariable global_config_new(gui.$font^^size) \
2965                         -from 2 -to 80 -increment 1 \
2966                         -width 3 \
2967                         -font font_ui
2968                 pack $w.global.$name.size -side right -anchor e
2969                 pack $w.global.$name.family -side right -anchor e
2970                 pack $w.global.$name -side top -anchor w -fill x
2971         }
2972
2973         bind $w <Visibility> "grab $w; focus $w"
2974         bind $w <Key-Escape> "destroy $w"
2975         wm title $w "[appname] ([reponame]): Options"
2976         tkwait window $w
2977 }
2978
2979 proc do_restore_defaults {} {
2980         global font_descs default_config repo_config
2981         global repo_config_new global_config_new
2982
2983         foreach name [array names default_config] {
2984                 set repo_config_new($name) $default_config($name)
2985                 set global_config_new($name) $default_config($name)
2986         }
2987
2988         foreach option $font_descs {
2989                 set name [lindex $option 0]
2990                 set repo_config(gui.$name) $default_config(gui.$name)
2991         }
2992         apply_config
2993
2994         foreach option $font_descs {
2995                 set name [lindex $option 0]
2996                 set font [lindex $option 1]
2997                 set global_config_new(gui.$font^^family) \
2998                         [font configure $font -family]
2999                 set global_config_new(gui.$font^^size) \
3000                         [font configure $font -size]
3001         }
3002 }
3003
3004 proc do_save_config {w} {
3005         if {[catch {save_config} err]} {
3006                 error_popup "Failed to completely save options:\n\n$err"
3007         }
3008         reshow_diff
3009         destroy $w
3010 }
3011
3012 proc do_windows_shortcut {} {
3013         global argv0
3014
3015         if {[catch {
3016                 set desktop [exec cygpath \
3017                         --windows \
3018                         --absolute \
3019                         --long-name \
3020                         --desktop]
3021                 }]} {
3022                         set desktop .
3023         }
3024         set fn [tk_getSaveFile \
3025                 -parent . \
3026                 -title "[appname] ([reponame]): Create Desktop Icon" \
3027                 -initialdir $desktop \
3028                 -initialfile "Git [reponame].bat"]
3029         if {$fn != {}} {
3030                 if {[catch {
3031                                 set fd [open $fn w]
3032                                 set sh [exec cygpath \
3033                                         --windows \
3034                                         --absolute \
3035                                         /bin/sh]
3036                                 set me [exec cygpath \
3037                                         --unix \
3038                                         --absolute \
3039                                         $argv0]
3040                                 set gd [exec cygpath \
3041                                         --unix \
3042                                         --absolute \
3043                                         [gitdir]]
3044                                 set gw [exec cygpath \
3045                                         --windows \
3046                                         --absolute \
3047                                         [file dirname [gitdir]]]
3048                                 regsub -all ' $me "'\\''" me
3049                                 regsub -all ' $gd "'\\''" gd
3050                                 puts $fd "@ECHO Entering $gw"
3051                                 puts $fd "@ECHO Starting git-gui... please wait..."
3052                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3053                                 puts -nonewline $fd "GIT_DIR='$gd'"
3054                                 puts -nonewline $fd " '$me'"
3055                                 puts $fd "&\""
3056                                 close $fd
3057                         } err]} {
3058                         error_popup "Cannot write script:\n\n$err"
3059                 }
3060         }
3061 }
3062
3063 proc do_macosx_app {} {
3064         global argv0 env
3065
3066         set fn [tk_getSaveFile \
3067                 -parent . \
3068                 -title "[appname] ([reponame]): Create Desktop Icon" \
3069                 -initialdir [file join $env(HOME) Desktop] \
3070                 -initialfile "Git [reponame].app"]
3071         if {$fn != {}} {
3072                 if {[catch {
3073                                 set Contents [file join $fn Contents]
3074                                 set MacOS [file join $Contents MacOS]
3075                                 set exe [file join $MacOS git-gui]
3076
3077                                 file mkdir $MacOS
3078
3079                                 set fd [open [file join $Contents Info.plist] w]
3080                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3081 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3082 <plist version="1.0">
3083 <dict>
3084         <key>CFBundleDevelopmentRegion</key>
3085         <string>English</string>
3086         <key>CFBundleExecutable</key>
3087         <string>git-gui</string>
3088         <key>CFBundleIdentifier</key>
3089         <string>org.spearce.git-gui</string>
3090         <key>CFBundleInfoDictionaryVersion</key>
3091         <string>6.0</string>
3092         <key>CFBundlePackageType</key>
3093         <string>APPL</string>
3094         <key>CFBundleSignature</key>
3095         <string>????</string>
3096         <key>CFBundleVersion</key>
3097         <string>1.0</string>
3098         <key>NSPrincipalClass</key>
3099         <string>NSApplication</string>
3100 </dict>
3101 </plist>}
3102                                 close $fd
3103
3104                                 set fd [open $exe w]
3105                                 set gd [file normalize [gitdir]]
3106                                 set ep [file normalize [exec git --exec-path]]
3107                                 regsub -all ' $gd "'\\''" gd
3108                                 regsub -all ' $ep "'\\''" ep
3109                                 puts $fd "#!/bin/sh"
3110                                 foreach name [array names env] {
3111                                         if {[string match GIT_* $name]} {
3112                                                 regsub -all ' $env($name) "'\\''" v
3113                                                 puts $fd "export $name='$v'"
3114                                         }
3115                                 }
3116                                 puts $fd "export PATH='$ep':\$PATH"
3117                                 puts $fd "export GIT_DIR='$gd'"
3118                                 puts $fd "exec [file normalize $argv0]"
3119                                 close $fd
3120
3121                                 file attributes $exe -permissions u+x,g+x,o+x
3122                         } err]} {
3123                         error_popup "Cannot write icon:\n\n$err"
3124                 }
3125         }
3126 }
3127
3128 proc toggle_or_diff {w x y} {
3129         global file_states file_lists current_diff ui_index ui_workdir
3130         global last_clicked selected_paths
3131
3132         set pos [split [$w index @$x,$y] .]
3133         set lno [lindex $pos 0]
3134         set col [lindex $pos 1]
3135         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3136         if {$path eq {}} {
3137                 set last_clicked {}
3138                 return
3139         }
3140
3141         set last_clicked [list $w $lno]
3142         array unset selected_paths
3143         $ui_index tag remove in_sel 0.0 end
3144         $ui_workdir tag remove in_sel 0.0 end
3145
3146         if {$col == 0} {
3147                 if {$current_diff eq $path} {
3148                         set after {reshow_diff;}
3149                 } else {
3150                         set after {}
3151                 }
3152                 if {$w eq $ui_index} {
3153                         update_indexinfo \
3154                                 "Unstaging [short_path $path] from commit" \
3155                                 [list $path] \
3156                                 [concat $after {set ui_status_value {Ready.}}]
3157                 } elseif {$w eq $ui_workdir} {
3158                         update_index \
3159                                 "Adding [short_path $path]" \
3160                                 [list $path] \
3161                                 [concat $after {set ui_status_value {Ready.}}]
3162                 }
3163         } else {
3164                 show_diff $path $w $lno
3165         }
3166 }
3167
3168 proc add_one_to_selection {w x y} {
3169         global file_lists last_clicked selected_paths
3170
3171         set lno [lindex [split [$w index @$x,$y] .] 0]
3172         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3173         if {$path eq {}} {
3174                 set last_clicked {}
3175                 return
3176         }
3177
3178         if {$last_clicked ne {}
3179                 && [lindex $last_clicked 0] ne $w} {
3180                 array unset selected_paths
3181                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3182         }
3183
3184         set last_clicked [list $w $lno]
3185         if {[catch {set in_sel $selected_paths($path)}]} {
3186                 set in_sel 0
3187         }
3188         if {$in_sel} {
3189                 unset selected_paths($path)
3190                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3191         } else {
3192                 set selected_paths($path) 1
3193                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3194         }
3195 }
3196
3197 proc add_range_to_selection {w x y} {
3198         global file_lists last_clicked selected_paths
3199
3200         if {[lindex $last_clicked 0] ne $w} {
3201                 toggle_or_diff $w $x $y
3202                 return
3203         }
3204
3205         set lno [lindex [split [$w index @$x,$y] .] 0]
3206         set lc [lindex $last_clicked 1]
3207         if {$lc < $lno} {
3208                 set begin $lc
3209                 set end $lno
3210         } else {
3211                 set begin $lno
3212                 set end $lc
3213         }
3214
3215         foreach path [lrange $file_lists($w) \
3216                 [expr {$begin - 1}] \
3217                 [expr {$end - 1}]] {
3218                 set selected_paths($path) 1
3219         }
3220         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3221 }
3222
3223 ######################################################################
3224 ##
3225 ## config defaults
3226
3227 set cursor_ptr arrow
3228 font create font_diff -family Courier -size 10
3229 font create font_ui
3230 catch {
3231         label .dummy
3232         eval font configure font_ui [font actual [.dummy cget -font]]
3233         destroy .dummy
3234 }
3235
3236 font create font_uibold
3237 font create font_diffbold
3238
3239 if {[is_Windows]} {
3240         set M1B Control
3241         set M1T Ctrl
3242 } elseif {[is_MacOSX]} {
3243         set M1B M1
3244         set M1T Cmd
3245 } else {
3246         set M1B M1
3247         set M1T M1
3248 }
3249
3250 proc apply_config {} {
3251         global repo_config font_descs
3252
3253         foreach option $font_descs {
3254                 set name [lindex $option 0]
3255                 set font [lindex $option 1]
3256                 if {[catch {
3257                         foreach {cn cv} $repo_config(gui.$name) {
3258                                 font configure $font $cn $cv
3259                         }
3260                         } err]} {
3261                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3262                 }
3263                 foreach {cn cv} [font configure $font] {
3264                         font configure ${font}bold $cn $cv
3265                 }
3266                 font configure ${font}bold -weight bold
3267         }
3268 }
3269
3270 set default_config(gui.trustmtime) false
3271 set default_config(gui.pullsummary) true
3272 set default_config(gui.partialinclude) false
3273 set default_config(gui.diffcontext) 5
3274 set default_config(gui.fontui) [font configure font_ui]
3275 set default_config(gui.fontdiff) [font configure font_diff]
3276 set font_descs {
3277         {fontui   font_ui   {Main Font}}
3278         {fontdiff font_diff {Diff/Console Font}}
3279 }
3280 load_config 0
3281 apply_config
3282
3283 ######################################################################
3284 ##
3285 ## ui construction
3286
3287 # -- Menu Bar
3288 #
3289 menu .mbar -tearoff 0
3290 .mbar add cascade -label Repository -menu .mbar.repository
3291 .mbar add cascade -label Edit -menu .mbar.edit
3292 if {!$single_commit} {
3293         .mbar add cascade -label Branch -menu .mbar.branch
3294 }
3295 .mbar add cascade -label Commit -menu .mbar.commit
3296 if {!$single_commit} {
3297         .mbar add cascade -label Fetch -menu .mbar.fetch
3298         .mbar add cascade -label Pull -menu .mbar.pull
3299         .mbar add cascade -label Push -menu .mbar.push
3300 }
3301 . configure -menu .mbar
3302
3303 # -- Repository Menu
3304 #
3305 menu .mbar.repository
3306 .mbar.repository add command \
3307         -label {Visualize Current Branch} \
3308         -command {do_gitk {}} \
3309         -font font_ui
3310 if {![is_MacOSX]} {
3311         .mbar.repository add command \
3312                 -label {Visualize All Branches} \
3313                 -command {do_gitk {--all}} \
3314                 -font font_ui
3315 }
3316 .mbar.repository add separator
3317
3318 if {!$single_commit} {
3319         .mbar.repository add command -label {Compress Database} \
3320                 -command do_gc \
3321                 -font font_ui
3322
3323         .mbar.repository add command -label {Verify Database} \
3324                 -command do_fsck_objects \
3325                 -font font_ui
3326
3327         .mbar.repository add separator
3328
3329         if {[is_Windows]} {
3330                 .mbar.repository add command \
3331                         -label {Create Desktop Icon} \
3332                         -command do_windows_shortcut \
3333                         -font font_ui
3334         } elseif {[is_MacOSX]} {
3335                 .mbar.repository add command \
3336                         -label {Create Desktop Icon} \
3337                         -command do_macosx_app \
3338                         -font font_ui
3339         }
3340 }
3341
3342 .mbar.repository add command -label Quit \
3343         -command do_quit \
3344         -accelerator $M1T-Q \
3345         -font font_ui
3346
3347 # -- Edit Menu
3348 #
3349 menu .mbar.edit
3350 .mbar.edit add command -label Undo \
3351         -command {catch {[focus] edit undo}} \
3352         -accelerator $M1T-Z \
3353         -font font_ui
3354 .mbar.edit add command -label Redo \
3355         -command {catch {[focus] edit redo}} \
3356         -accelerator $M1T-Y \
3357         -font font_ui
3358 .mbar.edit add separator
3359 .mbar.edit add command -label Cut \
3360         -command {catch {tk_textCut [focus]}} \
3361         -accelerator $M1T-X \
3362         -font font_ui
3363 .mbar.edit add command -label Copy \
3364         -command {catch {tk_textCopy [focus]}} \
3365         -accelerator $M1T-C \
3366         -font font_ui
3367 .mbar.edit add command -label Paste \
3368         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3369         -accelerator $M1T-V \
3370         -font font_ui
3371 .mbar.edit add command -label Delete \
3372         -command {catch {[focus] delete sel.first sel.last}} \
3373         -accelerator Del \
3374         -font font_ui
3375 .mbar.edit add separator
3376 .mbar.edit add command -label {Select All} \
3377         -command {catch {[focus] tag add sel 0.0 end}} \
3378         -accelerator $M1T-A \
3379         -font font_ui
3380
3381 # -- Branch Menu
3382 #
3383 if {!$single_commit} {
3384         menu .mbar.branch
3385
3386         .mbar.branch add command -label {Create...} \
3387                 -command do_create_branch \
3388                 -accelerator $M1T-N \
3389                 -font font_ui
3390         lappend disable_on_lock [list .mbar.branch entryconf \
3391                 [.mbar.branch index last] -state]
3392
3393         .mbar.branch add command -label {Delete...} \
3394                 -command do_delete_branch \
3395                 -font font_ui
3396         lappend disable_on_lock [list .mbar.branch entryconf \
3397                 [.mbar.branch index last] -state]
3398 }
3399
3400 # -- Commit Menu
3401 #
3402 menu .mbar.commit
3403
3404 .mbar.commit add radiobutton \
3405         -label {New Commit} \
3406         -command do_select_commit_type \
3407         -variable selected_commit_type \
3408         -value new \
3409         -font font_ui
3410 lappend disable_on_lock \
3411         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3412
3413 .mbar.commit add radiobutton \
3414         -label {Amend Last Commit} \
3415         -command do_select_commit_type \
3416         -variable selected_commit_type \
3417         -value amend \
3418         -font font_ui
3419 lappend disable_on_lock \
3420         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3421
3422 .mbar.commit add separator
3423
3424 .mbar.commit add command -label Rescan \
3425         -command do_rescan \
3426         -accelerator F5 \
3427         -font font_ui
3428 lappend disable_on_lock \
3429         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3430
3431 .mbar.commit add command -label {Add To Commit} \
3432         -command do_add_selection \
3433         -font font_ui
3434 lappend disable_on_lock \
3435         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3436
3437 .mbar.commit add command -label {Add All To Commit} \
3438         -command do_add_all \
3439         -accelerator $M1T-I \
3440         -font font_ui
3441 lappend disable_on_lock \
3442         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3443
3444 .mbar.commit add command -label {Unstage From Commit} \
3445         -command do_unstage_selection \
3446         -font font_ui
3447 lappend disable_on_lock \
3448         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3449
3450 .mbar.commit add command -label {Revert Changes} \
3451         -command do_revert_selection \
3452         -font font_ui
3453 lappend disable_on_lock \
3454         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3455
3456 .mbar.commit add separator
3457
3458 .mbar.commit add command -label {Sign Off} \
3459         -command do_signoff \
3460         -accelerator $M1T-S \
3461         -font font_ui
3462
3463 .mbar.commit add command -label Commit \
3464         -command do_commit \
3465         -accelerator $M1T-Return \
3466         -font font_ui
3467 lappend disable_on_lock \
3468         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3469
3470 # -- Transport menus
3471 #
3472 if {!$single_commit} {
3473         menu .mbar.fetch
3474         menu .mbar.pull
3475         menu .mbar.push
3476 }
3477
3478 if {[is_MacOSX]} {
3479         # -- Apple Menu (Mac OS X only)
3480         #
3481         .mbar add cascade -label Apple -menu .mbar.apple
3482         menu .mbar.apple
3483
3484         .mbar.apple add command -label "About [appname]" \
3485                 -command do_about \
3486                 -font font_ui
3487         .mbar.apple add command -label "[appname] Options..." \
3488                 -command do_options \
3489                 -font font_ui
3490 } else {
3491         # -- Edit Menu
3492         #
3493         .mbar.edit add separator
3494         .mbar.edit add command -label {Options...} \
3495                 -command do_options \
3496                 -font font_ui
3497
3498         # -- Tools Menu
3499         #
3500         if {[file exists /usr/local/miga/lib/gui-miga]
3501                 && [file exists .pvcsrc]} {
3502         proc do_miga {} {
3503                 global ui_status_value
3504                 if {![lock_index update]} return
3505                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3506                 set miga_fd [open "|$cmd" r]
3507                 fconfigure $miga_fd -blocking 0
3508                 fileevent $miga_fd readable [list miga_done $miga_fd]
3509                 set ui_status_value {Running miga...}
3510         }
3511         proc miga_done {fd} {
3512                 read $fd 512
3513                 if {[eof $fd]} {
3514                         close $fd
3515                         unlock_index
3516                         rescan [list set ui_status_value {Ready.}]
3517                 }
3518         }
3519         .mbar add cascade -label Tools -menu .mbar.tools
3520         menu .mbar.tools
3521         .mbar.tools add command -label "Migrate" \
3522                 -command do_miga \
3523                 -font font_ui
3524         lappend disable_on_lock \
3525                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3526         }
3527
3528         # -- Help Menu
3529         #
3530         .mbar add cascade -label Help -menu .mbar.help
3531         menu .mbar.help
3532
3533         .mbar.help add command -label "About [appname]" \
3534                 -command do_about \
3535                 -font font_ui
3536 }
3537
3538
3539 # -- Branch Control
3540 #
3541 frame .branch \
3542         -borderwidth 1 \
3543         -relief sunken
3544 label .branch.l1 \
3545         -text {Current Branch:} \
3546         -anchor w \
3547         -justify left \
3548         -font font_ui
3549 label .branch.cb \
3550         -textvariable current_branch \
3551         -anchor w \
3552         -justify left \
3553         -font font_ui
3554 pack .branch.l1 -side left
3555 pack .branch.cb -side left -fill x
3556 pack .branch -side top -fill x
3557
3558 # -- Main Window Layout
3559 #
3560 panedwindow .vpane -orient vertical
3561 panedwindow .vpane.files -orient horizontal
3562 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3563 pack .vpane -anchor n -side top -fill both -expand 1
3564
3565 # -- Index File List
3566 #
3567 frame .vpane.files.index -height 100 -width 400
3568 label .vpane.files.index.title -text {Changes To Be Committed} \
3569         -background green \
3570         -font font_ui
3571 text $ui_index -background white -borderwidth 0 \
3572         -width 40 -height 10 \
3573         -font font_ui \
3574         -cursor $cursor_ptr \
3575         -yscrollcommand {.vpane.files.index.sb set} \
3576         -state disabled
3577 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3578 pack .vpane.files.index.title -side top -fill x
3579 pack .vpane.files.index.sb -side right -fill y
3580 pack $ui_index -side left -fill both -expand 1
3581 .vpane.files add .vpane.files.index -sticky nsew
3582
3583 # -- Working Directory File List
3584 #
3585 frame .vpane.files.workdir -height 100 -width 100
3586 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3587         -background red \
3588         -font font_ui
3589 text $ui_workdir -background white -borderwidth 0 \
3590         -width 40 -height 10 \
3591         -font font_ui \
3592         -cursor $cursor_ptr \
3593         -yscrollcommand {.vpane.files.workdir.sb set} \
3594         -state disabled
3595 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3596 pack .vpane.files.workdir.title -side top -fill x
3597 pack .vpane.files.workdir.sb -side right -fill y
3598 pack $ui_workdir -side left -fill both -expand 1
3599 .vpane.files add .vpane.files.workdir -sticky nsew
3600
3601 foreach i [list $ui_index $ui_workdir] {
3602         $i tag conf in_diff -font font_uibold
3603         $i tag conf in_sel \
3604                 -background [$i cget -foreground] \
3605                 -foreground [$i cget -background]
3606 }
3607 unset i
3608
3609 # -- Diff and Commit Area
3610 #
3611 frame .vpane.lower -height 300 -width 400
3612 frame .vpane.lower.commarea
3613 frame .vpane.lower.diff -relief sunken -borderwidth 1
3614 pack .vpane.lower.commarea -side top -fill x
3615 pack .vpane.lower.diff -side bottom -fill both -expand 1
3616 .vpane add .vpane.lower -stick nsew
3617
3618 # -- Commit Area Buttons
3619 #
3620 frame .vpane.lower.commarea.buttons
3621 label .vpane.lower.commarea.buttons.l -text {} \
3622         -anchor w \
3623         -justify left \
3624         -font font_ui
3625 pack .vpane.lower.commarea.buttons.l -side top -fill x
3626 pack .vpane.lower.commarea.buttons -side left -fill y
3627
3628 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3629         -command do_rescan \
3630         -font font_ui
3631 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3632 lappend disable_on_lock \
3633         {.vpane.lower.commarea.buttons.rescan conf -state}
3634
3635 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3636         -command do_add_all \
3637         -font font_ui
3638 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3639 lappend disable_on_lock \
3640         {.vpane.lower.commarea.buttons.incall conf -state}
3641
3642 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3643         -command do_signoff \
3644         -font font_ui
3645 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3646
3647 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3648         -command do_commit \
3649         -font font_ui
3650 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3651 lappend disable_on_lock \
3652         {.vpane.lower.commarea.buttons.commit conf -state}
3653
3654 # -- Commit Message Buffer
3655 #
3656 frame .vpane.lower.commarea.buffer
3657 frame .vpane.lower.commarea.buffer.header
3658 set ui_comm .vpane.lower.commarea.buffer.t
3659 set ui_coml .vpane.lower.commarea.buffer.header.l
3660 radiobutton .vpane.lower.commarea.buffer.header.new \
3661         -text {New Commit} \
3662         -command do_select_commit_type \
3663         -variable selected_commit_type \
3664         -value new \
3665         -font font_ui
3666 lappend disable_on_lock \
3667         [list .vpane.lower.commarea.buffer.header.new conf -state]
3668 radiobutton .vpane.lower.commarea.buffer.header.amend \
3669         -text {Amend Last Commit} \
3670         -command do_select_commit_type \
3671         -variable selected_commit_type \
3672         -value amend \
3673         -font font_ui
3674 lappend disable_on_lock \
3675         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3676 label $ui_coml \
3677         -anchor w \
3678         -justify left \
3679         -font font_ui
3680 proc trace_commit_type {varname args} {
3681         global ui_coml commit_type
3682         switch -glob -- $commit_type {
3683         initial       {set txt {Initial Commit Message:}}
3684         amend         {set txt {Amended Commit Message:}}
3685         amend-initial {set txt {Amended Initial Commit Message:}}
3686         amend-merge   {set txt {Amended Merge Commit Message:}}
3687         merge         {set txt {Merge Commit Message:}}
3688         *             {set txt {Commit Message:}}
3689         }
3690         $ui_coml conf -text $txt
3691 }
3692 trace add variable commit_type write trace_commit_type
3693 pack $ui_coml -side left -fill x
3694 pack .vpane.lower.commarea.buffer.header.amend -side right
3695 pack .vpane.lower.commarea.buffer.header.new -side right
3696
3697 text $ui_comm -background white -borderwidth 1 \
3698         -undo true \
3699         -maxundo 20 \
3700         -autoseparators true \
3701         -relief sunken \
3702         -width 75 -height 9 -wrap none \
3703         -font font_diff \
3704         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3705 scrollbar .vpane.lower.commarea.buffer.sby \
3706         -command [list $ui_comm yview]
3707 pack .vpane.lower.commarea.buffer.header -side top -fill x
3708 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3709 pack $ui_comm -side left -fill y
3710 pack .vpane.lower.commarea.buffer -side left -fill y
3711
3712 # -- Commit Message Buffer Context Menu
3713 #
3714 set ctxm .vpane.lower.commarea.buffer.ctxm
3715 menu $ctxm -tearoff 0
3716 $ctxm add command \
3717         -label {Cut} \
3718         -font font_ui \
3719         -command {tk_textCut $ui_comm}
3720 $ctxm add command \
3721         -label {Copy} \
3722         -font font_ui \
3723         -command {tk_textCopy $ui_comm}
3724 $ctxm add command \
3725         -label {Paste} \
3726         -font font_ui \
3727         -command {tk_textPaste $ui_comm}
3728 $ctxm add command \
3729         -label {Delete} \
3730         -font font_ui \
3731         -command {$ui_comm delete sel.first sel.last}
3732 $ctxm add separator
3733 $ctxm add command \
3734         -label {Select All} \
3735         -font font_ui \
3736         -command {$ui_comm tag add sel 0.0 end}
3737 $ctxm add command \
3738         -label {Copy All} \
3739         -font font_ui \
3740         -command {
3741                 $ui_comm tag add sel 0.0 end
3742                 tk_textCopy $ui_comm
3743                 $ui_comm tag remove sel 0.0 end
3744         }
3745 $ctxm add separator
3746 $ctxm add command \
3747         -label {Sign Off} \
3748         -font font_ui \
3749         -command do_signoff
3750 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3751
3752 # -- Diff Header
3753 #
3754 set current_diff {}
3755 set diff_actions [list]
3756 proc trace_current_diff {varname args} {
3757         global current_diff diff_actions file_states
3758         if {$current_diff eq {}} {
3759                 set s {}
3760                 set f {}
3761                 set p {}
3762                 set o disabled
3763         } else {
3764                 set p $current_diff
3765                 set s [mapdesc [lindex $file_states($p) 0] $p]
3766                 set f {File:}
3767                 set p [escape_path $p]
3768                 set o normal
3769         }
3770
3771         .vpane.lower.diff.header.status configure -text $s
3772         .vpane.lower.diff.header.file configure -text $f
3773         .vpane.lower.diff.header.path configure -text $p
3774         foreach w $diff_actions {
3775                 uplevel #0 $w $o
3776         }
3777 }
3778 trace add variable current_diff write trace_current_diff
3779
3780 frame .vpane.lower.diff.header -background orange
3781 label .vpane.lower.diff.header.status \
3782         -background orange \
3783         -width $max_status_desc \
3784         -anchor w \
3785         -justify left \
3786         -font font_ui
3787 label .vpane.lower.diff.header.file \
3788         -background orange \
3789         -anchor w \
3790         -justify left \
3791         -font font_ui
3792 label .vpane.lower.diff.header.path \
3793         -background orange \
3794         -anchor w \
3795         -justify left \
3796         -font font_ui
3797 pack .vpane.lower.diff.header.status -side left
3798 pack .vpane.lower.diff.header.file -side left
3799 pack .vpane.lower.diff.header.path -fill x
3800 set ctxm .vpane.lower.diff.header.ctxm
3801 menu $ctxm -tearoff 0
3802 $ctxm add command \
3803         -label {Copy} \
3804         -font font_ui \
3805         -command {
3806                 clipboard clear
3807                 clipboard append \
3808                         -format STRING \
3809                         -type STRING \
3810                         -- $current_diff
3811         }
3812 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3813 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3814
3815 # -- Diff Body
3816 #
3817 frame .vpane.lower.diff.body
3818 set ui_diff .vpane.lower.diff.body.t
3819 text $ui_diff -background white -borderwidth 0 \
3820         -width 80 -height 15 -wrap none \
3821         -font font_diff \
3822         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3823         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3824         -state disabled
3825 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3826         -command [list $ui_diff xview]
3827 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3828         -command [list $ui_diff yview]
3829 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3830 pack .vpane.lower.diff.body.sby -side right -fill y
3831 pack $ui_diff -side left -fill both -expand 1
3832 pack .vpane.lower.diff.header -side top -fill x
3833 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3834
3835 $ui_diff tag conf d_@ -font font_diffbold
3836 $ui_diff tag conf d_+  -foreground blue
3837 $ui_diff tag conf d_-  -foreground red
3838 $ui_diff tag conf d_++ -foreground {#00a000}
3839 $ui_diff tag conf d_-- -foreground {#a000a0}
3840 $ui_diff tag conf d_+- \
3841         -foreground red \
3842         -background {light goldenrod yellow}
3843 $ui_diff tag conf d_-+ \
3844         -foreground blue \
3845         -background azure2
3846
3847 # -- Diff Body Context Menu
3848 #
3849 set ctxm .vpane.lower.diff.body.ctxm
3850 menu $ctxm -tearoff 0
3851 $ctxm add command \
3852         -label {Copy} \
3853         -font font_ui \
3854         -command {tk_textCopy $ui_diff}
3855 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3856 $ctxm add command \
3857         -label {Select All} \
3858         -font font_ui \
3859         -command {$ui_diff tag add sel 0.0 end}
3860 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3861 $ctxm add command \
3862         -label {Copy All} \
3863         -font font_ui \
3864         -command {
3865                 $ui_diff tag add sel 0.0 end
3866                 tk_textCopy $ui_diff
3867                 $ui_diff tag remove sel 0.0 end
3868         }
3869 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3870 $ctxm add separator
3871 $ctxm add command \
3872         -label {Decrease Font Size} \
3873         -font font_ui \
3874         -command {incr_font_size font_diff -1}
3875 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3876 $ctxm add command \
3877         -label {Increase Font Size} \
3878         -font font_ui \
3879         -command {incr_font_size font_diff 1}
3880 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3881 $ctxm add separator
3882 $ctxm add command \
3883         -label {Show Less Context} \
3884         -font font_ui \
3885         -command {if {$repo_config(gui.diffcontext) >= 2} {
3886                 incr repo_config(gui.diffcontext) -1
3887                 reshow_diff
3888         }}
3889 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3890 $ctxm add command \
3891         -label {Show More Context} \
3892         -font font_ui \
3893         -command {
3894                 incr repo_config(gui.diffcontext)
3895                 reshow_diff
3896         }
3897 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3898 $ctxm add separator
3899 $ctxm add command -label {Options...} \
3900         -font font_ui \
3901         -command do_options
3902 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3903
3904 # -- Status Bar
3905 #
3906 set ui_status_value {Initializing...}
3907 label .status -textvariable ui_status_value \
3908         -anchor w \
3909         -justify left \
3910         -borderwidth 1 \
3911         -relief sunken \
3912         -font font_ui
3913 pack .status -anchor w -side bottom -fill x
3914
3915 # -- Load geometry
3916 #
3917 catch {
3918 set gm $repo_config(gui.geometry)
3919 wm geometry . [lindex $gm 0]
3920 .vpane sash place 0 \
3921         [lindex [.vpane sash coord 0] 0] \
3922         [lindex $gm 1]
3923 .vpane.files sash place 0 \
3924         [lindex $gm 2] \
3925         [lindex [.vpane.files sash coord 0] 1]
3926 unset gm
3927 }
3928
3929 # -- Key Bindings
3930 #
3931 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3932 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3933 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3934 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3935 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3936 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3937 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3938 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3939 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3940 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3941 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3942
3943 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3944 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3945 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3946 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3947 bind $ui_diff <$M1B-Key-v> {break}
3948 bind $ui_diff <$M1B-Key-V> {break}
3949 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3950 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3951 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3952 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3953 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3954 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3955
3956 if {!$single_commit} {
3957         bind . <$M1B-Key-n> do_create_branch
3958         bind . <$M1B-Key-N> do_create_branch
3959 }
3960
3961 bind .   <Destroy> do_quit
3962 bind all <Key-F5> do_rescan
3963 bind all <$M1B-Key-r> do_rescan
3964 bind all <$M1B-Key-R> do_rescan
3965 bind .   <$M1B-Key-s> do_signoff
3966 bind .   <$M1B-Key-S> do_signoff
3967 bind .   <$M1B-Key-i> do_add_all
3968 bind .   <$M1B-Key-I> do_add_all
3969 bind .   <$M1B-Key-Return> do_commit
3970 bind all <$M1B-Key-q> do_quit
3971 bind all <$M1B-Key-Q> do_quit
3972 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3973 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3974 foreach i [list $ui_index $ui_workdir] {
3975         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3976         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3977         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3978 }
3979 unset i
3980
3981 set file_lists($ui_index) [list]
3982 set file_lists($ui_workdir) [list]
3983
3984 set HEAD {}
3985 set PARENT {}
3986 set MERGE_HEAD [list]
3987 set commit_type {}
3988 set empty_tree {}
3989 set current_branch {}
3990 set current_diff {}
3991 set selected_commit_type new
3992
3993 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3994 focus -force $ui_comm
3995
3996 # -- Warn the user about environmental problems.  Cygwin's Tcl
3997 #    does *not* pass its env array onto any processes it spawns.
3998 #    This means that git processes get none of our environment.
3999 #
4000 if {[is_Windows]} {
4001         set ignored_env 0
4002         set suggest_user {}
4003         set msg "Possible environment issues exist.
4004
4005 The following environment variables are probably
4006 going to be ignored by any Git subprocess run
4007 by [appname]:
4008
4009 "
4010         foreach name [array names env] {
4011                 switch -regexp -- $name {
4012                 {^GIT_INDEX_FILE$} -
4013                 {^GIT_OBJECT_DIRECTORY$} -
4014                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4015                 {^GIT_DIFF_OPTS$} -
4016                 {^GIT_EXTERNAL_DIFF$} -
4017                 {^GIT_PAGER$} -
4018                 {^GIT_TRACE$} -
4019                 {^GIT_CONFIG$} -
4020                 {^GIT_CONFIG_LOCAL$} -
4021                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4022                         append msg " - $name\n"
4023                         incr ignored_env
4024                 }
4025                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4026                         append msg " - $name\n"
4027                         incr ignored_env
4028                         set suggest_user $name
4029                 }
4030                 }
4031         }
4032         if {$ignored_env > 0} {
4033                 append msg "
4034 This is due to a known issue with the
4035 Tcl binary distributed by Cygwin."
4036
4037                 if {$suggest_user ne {}} {
4038                         append msg "
4039
4040 A good replacement for $suggest_user
4041 is placing values for the user.name and
4042 user.email settings into your personal
4043 ~/.gitconfig file.
4044 "
4045                 }
4046                 warn_popup $msg
4047         }
4048         unset ignored_env msg suggest_user name
4049 }
4050
4051 # -- Only initialize complex UI if we are going to stay running.
4052 #
4053 if {!$single_commit} {
4054         load_all_remotes
4055         load_all_heads
4056
4057         populate_branch_menu
4058         populate_fetch_menu .mbar.fetch
4059         populate_pull_menu .mbar.pull
4060         populate_push_menu .mbar.push
4061 }
4062
4063 # -- Only suggest a gc run if we are going to stay running.
4064 #
4065 if {!$single_commit} {
4066         set object_limit 2000
4067         if {[is_Windows]} {set object_limit 200}
4068         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4069         if {$objects_current >= $object_limit} {
4070                 if {[ask_popup \
4071                         "This repository currently has $objects_current loose objects.
4072
4073 To maintain optimal performance it is strongly
4074 recommended that you compress the database
4075 when more than $object_limit loose objects exist.
4076
4077 Compress the database now?"] eq yes} {
4078                         do_gc
4079                 }
4080         }
4081         unset object_limit _junk objects_current
4082 }
4083
4084 lock_index begin-read
4085 after 1 do_rescan