git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file dirname [file normalize $argv0]]]
  56         set oguilib [file join $oguilib share git-gui lib]
  57         set oguimsg [file join $oguilib msgs]
  58 } elseif {[string match @@* $oguirel]} {
  59         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  60         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  61 } else {
  62         set oguimsg [file join $oguilib msgs]
  63 }
  64 unset oguirel
  65
  66 ######################################################################
  67 ##
  68 ## enable verbose loading?
  69
  70 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  71         unset _verbose
  72         rename auto_load real__auto_load
  73         proc auto_load {name args} {
  74                 puts stderr "auto_load $name"
  75                 return [uplevel 1 real__auto_load $name $args]
  76         }
  77         rename source real__source
  78         proc source {name} {
  79                 puts stderr "source    $name"
  80                 uplevel 1 real__source $name
  81         }
  82 }
  83
  84 ######################################################################
  85 ##
  86 ## Internationalization (i18n) through msgcat and gettext. See
  87 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  88
  89 package require msgcat
  90
  91 proc mc {fmt args} {
  92         set fmt [::msgcat::mc $fmt]
  93         set cmk [string first @@ $fmt]
  94         if {$cmk > 0} {
  95                 set fmt [string range $fmt 0 [expr {$cmk - 1}]]
  96         }
  97         return [eval [list format $fmt] $args]
  98 }
  99
 100 proc strcat {args} {
 101         return [join $args {}]
 102 }
 103
 104 ::msgcat::mcload $oguimsg
 105 unset oguimsg
 106
 107 ######################################################################
 108 ##
 109 ## read only globals
 110
 111 set _appname {Git Gui}
 112 set _gitdir {}
 113 set _gitexec {}
 114 set _reponame {}
 115 set _iscygwin {}
 116 set _search_path {}
 117
 118 proc appname {} {
 119         global _appname
 120         return $_appname
 121 }
 122
 123 proc gitdir {args} {
 124         global _gitdir
 125         if {$args eq {}} {
 126                 return $_gitdir
 127         }
 128         return [eval [list file join $_gitdir] $args]
 129 }
 130
 131 proc gitexec {args} {
 132         global _gitexec
 133         if {$_gitexec eq {}} {
 134                 if {[catch {set _gitexec [git --exec-path]} err]} {
 135                         error "Git not installed?\n\n$err"
 136                 }
 137                 if {[is_Cygwin]} {
 138                         set _gitexec [exec cygpath \
 139                                 --windows \
 140                                 --absolute \
 141                                 $_gitexec]
 142                 } else {
 143                         set _gitexec [file normalize $_gitexec]
 144                 }
 145         }
 146         if {$args eq {}} {
 147                 return $_gitexec
 148         }
 149         return [eval [list file join $_gitexec] $args]
 150 }
 151
 152 proc reponame {} {
 153         return $::_reponame
 154 }
 155
 156 proc is_MacOSX {} {
 157         if {[tk windowingsystem] eq {aqua}} {
 158                 return 1
 159         }
 160         return 0
 161 }
 162
 163 proc is_Windows {} {
 164         if {$::tcl_platform(platform) eq {windows}} {
 165                 return 1
 166         }
 167         return 0
 168 }
 169
 170 proc is_Cygwin {} {
 171         global _iscygwin
 172         if {$_iscygwin eq {}} {
 173                 if {$::tcl_platform(platform) eq {windows}} {
 174                         if {[catch {set p [exec cygpath --windir]} err]} {
 175                                 set _iscygwin 0
 176                         } else {
 177                                 set _iscygwin 1
 178                         }
 179                 } else {
 180                         set _iscygwin 0
 181                 }
 182         }
 183         return $_iscygwin
 184 }
 185
 186 proc is_enabled {option} {
 187         global enabled_options
 188         if {[catch {set on $enabled_options($option)}]} {return 0}
 189         return $on
 190 }
 191
 192 proc enable_option {option} {
 193         global enabled_options
 194         set enabled_options($option) 1
 195 }
 196
 197 proc disable_option {option} {
 198         global enabled_options
 199         set enabled_options($option) 0
 200 }
 201
 202 ######################################################################
 203 ##
 204 ## config
 205
 206 proc is_many_config {name} {
 207         switch -glob -- $name {
 208         remote.*.fetch -
 209         remote.*.push
 210                 {return 1}
 211         *
 212                 {return 0}
 213         }
 214 }
 215
 216 proc is_config_true {name} {
 217         global repo_config
 218         if {[catch {set v $repo_config($name)}]} {
 219                 return 0
 220         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 221                 return 1
 222         } else {
 223                 return 0
 224         }
 225 }
 226
 227 proc get_config {name} {
 228         global repo_config
 229         if {[catch {set v $repo_config($name)}]} {
 230                 return {}
 231         } else {
 232                 return $v
 233         }
 234 }
 235
 236 proc load_config {include_global} {
 237         global repo_config global_config default_config
 238
 239         array unset global_config
 240         if {$include_global} {
 241                 catch {
 242                         set fd_rc [git_read config --global --list]
 243                         while {[gets $fd_rc line] >= 0} {
 244                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 245                                         if {[is_many_config $name]} {
 246                                                 lappend global_config($name) $value
 247                                         } else {
 248                                                 set global_config($name) $value
 249                                         }
 250                                 }
 251                         }
 252                         close $fd_rc
 253                 }
 254         }
 255
 256         array unset repo_config
 257         catch {
 258                 set fd_rc [git_read config --list]
 259                 while {[gets $fd_rc line] >= 0} {
 260                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 261                                 if {[is_many_config $name]} {
 262                                         lappend repo_config($name) $value
 263                                 } else {
 264                                         set repo_config($name) $value
 265                                 }
 266                         }
 267                 }
 268                 close $fd_rc
 269         }
 270
 271         foreach name [array names default_config] {
 272                 if {[catch {set v $global_config($name)}]} {
 273                         set global_config($name) $default_config($name)
 274                 }
 275                 if {[catch {set v $repo_config($name)}]} {
 276                         set repo_config($name) $default_config($name)
 277                 }
 278         }
 279 }
 280
 281 ######################################################################
 282 ##
 283 ## handy utils
 284
 285 proc _git_cmd {name} {
 286         global _git_cmd_path
 287
 288         if {[catch {set v $_git_cmd_path($name)}]} {
 289                 switch -- $name {
 290                   version   -
 291                 --version   -
 292                 --exec-path { return [list $::_git $name] }
 293                 }
 294
 295                 set p [gitexec git-$name$::_search_exe]
 296                 if {[file exists $p]} {
 297                         set v [list $p]
 298                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 299                         # Try to determine what sort of magic will make
 300                         # git-$name go and do its thing, because native
 301                         # Tcl on Windows doesn't know it.
 302                         #
 303                         set p [gitexec git-$name]
 304                         set f [open $p r]
 305                         set s [gets $f]
 306                         close $f
 307
 308                         switch -glob -- [lindex $s 0] {
 309                         #!*sh     { set i sh     }
 310                         #!*perl   { set i perl   }
 311                         #!*python { set i python }
 312                         default   { error "git-$name is not supported: $s" }
 313                         }
 314
 315                         upvar #0 _$i interp
 316                         if {![info exists interp]} {
 317                                 set interp [_which $i]
 318                         }
 319                         if {$interp eq {}} {
 320                                 error "git-$name requires $i (not in PATH)"
 321                         }
 322                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 323                 } else {
 324                         # Assume it is builtin to git somehow and we
 325                         # aren't actually able to see a file for it.
 326                         #
 327                         set v [list $::_git $name]
 328                 }
 329                 set _git_cmd_path($name) $v
 330         }
 331         return $v
 332 }
 333
 334 proc _which {what} {
 335         global env _search_exe _search_path
 336
 337         if {$_search_path eq {}} {
 338                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 339                         set _search_path [split [exec cygpath \
 340                                 --windows \
 341                                 --path \
 342                                 --absolute \
 343                                 $env(PATH)] {;}]
 344                         set _search_exe .exe
 345                 } elseif {[is_Windows]} {
 346                         set _search_path [split $env(PATH) {;}]
 347                         set _search_exe .exe
 348                 } else {
 349                         set _search_path [split $env(PATH) :]
 350                         set _search_exe {}
 351                 }
 352         }
 353
 354         foreach p $_search_path {
 355                 set p [file join $p $what$_search_exe]
 356                 if {[file exists $p]} {
 357                         return [file normalize $p]
 358                 }
 359         }
 360         return {}
 361 }
 362
 363 proc _lappend_nice {cmd_var} {
 364         global _nice
 365         upvar $cmd_var cmd
 366
 367         if {![info exists _nice]} {
 368                 set _nice [_which nice]
 369         }
 370         if {$_nice ne {}} {
 371                 lappend cmd $_nice
 372         }
 373 }
 374
 375 proc git {args} {
 376         set opt [list exec]
 377
 378         while {1} {
 379                 switch -- [lindex $args 0] {
 380                 --nice {
 381                         _lappend_nice opt
 382                 }
 383
 384                 default {
 385                         break
 386                 }
 387
 388                 }
 389
 390                 set args [lrange $args 1 end]
 391         }
 392
 393         set cmdp [_git_cmd [lindex $args 0]]
 394         set args [lrange $args 1 end]
 395
 396         return [eval $opt $cmdp $args]
 397 }
 398
 399 proc _open_stdout_stderr {cmd} {
 400         if {[catch {
 401                         set fd [open $cmd r]
 402                 } err]} {
 403                 if {   [lindex $cmd end] eq {2>@1}
 404                     && $err eq {can not find channel named "1"}
 405                         } {
 406                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 407                         # redirect operator.  Fallback to |& cat for those.
 408                         # The command was not actually started, so its safe
 409                         # to try to start it a second time.
 410                         #
 411                         set fd [open [concat \
 412                                 [lrange $cmd 0 end-1] \
 413                                 [list |& cat] \
 414                                 ] r]
 415                 } else {
 416                         error $err
 417                 }
 418         }
 419         fconfigure $fd -eofchar {}
 420         return $fd
 421 }
 422
 423 proc git_read {args} {
 424         set opt [list |]
 425
 426         while {1} {
 427                 switch -- [lindex $args 0] {
 428                 --nice {
 429                         _lappend_nice opt
 430                 }
 431
 432                 --stderr {
 433                         lappend args 2>@1
 434                 }
 435
 436                 default {
 437                         break
 438                 }
 439
 440                 }
 441
 442                 set args [lrange $args 1 end]
 443         }
 444
 445         set cmdp [_git_cmd [lindex $args 0]]
 446         set args [lrange $args 1 end]
 447
 448         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 449 }
 450
 451 proc git_write {args} {
 452         set opt [list |]
 453
 454         while {1} {
 455                 switch -- [lindex $args 0] {
 456                 --nice {
 457                         _lappend_nice opt
 458                 }
 459
 460                 default {
 461                         break
 462                 }
 463
 464                 }
 465
 466                 set args [lrange $args 1 end]
 467         }
 468
 469         set cmdp [_git_cmd [lindex $args 0]]
 470         set args [lrange $args 1 end]
 471
 472         return [open [concat $opt $cmdp $args] w]
 473 }
 474
 475 proc sq {value} {
 476         regsub -all ' $value "'\\''" value
 477         return "'$value'"
 478 }
 479
 480 proc load_current_branch {} {
 481         global current_branch is_detached
 482
 483         set fd [open [gitdir HEAD] r]
 484         if {[gets $fd ref] < 1} {
 485                 set ref {}
 486         }
 487         close $fd
 488
 489         set pfx {ref: refs/heads/}
 490         set len [string length $pfx]
 491         if {[string equal -length $len $pfx $ref]} {
 492                 # We're on a branch.  It might not exist.  But
 493                 # HEAD looks good enough to be a branch.
 494                 #
 495                 set current_branch [string range $ref $len end]
 496                 set is_detached 0
 497         } else {
 498                 # Assume this is a detached head.
 499                 #
 500                 set current_branch HEAD
 501                 set is_detached 1
 502         }
 503 }
 504
 505 auto_load tk_optionMenu
 506 rename tk_optionMenu real__tkOptionMenu
 507 proc tk_optionMenu {w varName args} {
 508         set m [eval real__tkOptionMenu $w $varName $args]
 509         $m configure -font font_ui
 510         $w configure -font font_ui
 511         return $m
 512 }
 513
 514 proc rmsel_tag {text} {
 515         $text tag conf sel \
 516                 -background [$text cget -background] \
 517                 -foreground [$text cget -foreground] \
 518                 -borderwidth 0
 519         $text tag conf in_sel -background lightgray
 520         bind $text <Motion> break
 521         return $text
 522 }
 523
 524 set root_exists 0
 525 bind . <Visibility> {
 526         bind . <Visibility> {}
 527         set root_exists 1
 528 }
 529
 530 if {[is_Windows]} {
 531         wm iconbitmap . -default $oguilib/git-gui.ico
 532 }
 533
 534 ######################################################################
 535 ##
 536 ## config defaults
 537
 538 set cursor_ptr arrow
 539 font create font_diff -family Courier -size 10
 540 font create font_ui
 541 catch {
 542         label .dummy
 543         eval font configure font_ui [font actual [.dummy cget -font]]
 544         destroy .dummy
 545 }
 546
 547 font create font_uiitalic
 548 font create font_uibold
 549 font create font_diffbold
 550 font create font_diffitalic
 551
 552 foreach class {Button Checkbutton Entry Label
 553                 Labelframe Listbox Menu Message
 554                 Radiobutton Spinbox Text} {
 555         option add *$class.font font_ui
 556 }
 557 unset class
 558
 559 if {[is_Windows] || [is_MacOSX]} {
 560         option add *Menu.tearOff 0
 561 }
 562
 563 if {[is_MacOSX]} {
 564         set M1B M1
 565         set M1T Cmd
 566 } else {
 567         set M1B Control
 568         set M1T Ctrl
 569 }
 570
 571 proc bind_button3 {w cmd} {
 572         bind $w <Any-Button-3> $cmd
 573         if {[is_MacOSX]} {
 574                 # Mac OS X sends Button-2 on right click through three-button mouse,
 575                 # or through trackpad right-clicking (two-finger touch + click).
 576                 bind $w <Any-Button-2> $cmd
 577                 bind $w <Control-Button-1> $cmd
 578         }
 579 }
 580
 581 proc apply_config {} {
 582         global repo_config font_descs
 583
 584         foreach option $font_descs {
 585                 set name [lindex $option 0]
 586                 set font [lindex $option 1]
 587                 if {[catch {
 588                         foreach {cn cv} $repo_config(gui.$name) {
 589                                 font configure $font $cn $cv -weight normal
 590                         }
 591                         } err]} {
 592                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 593                 }
 594                 foreach {cn cv} [font configure $font] {
 595                         font configure ${font}bold $cn $cv
 596                         font configure ${font}italic $cn $cv
 597                 }
 598                 font configure ${font}bold -weight bold
 599                 font configure ${font}italic -slant italic
 600         }
 601 }
 602
 603 set default_config(merge.diffstat) true
 604 set default_config(merge.summary) false
 605 set default_config(merge.verbosity) 2
 606 set default_config(user.name) {}
 607 set default_config(user.email) {}
 608
 609 set default_config(gui.matchtrackingbranch) false
 610 set default_config(gui.pruneduringfetch) false
 611 set default_config(gui.trustmtime) false
 612 set default_config(gui.diffcontext) 5
 613 set default_config(gui.newbranchtemplate) {}
 614 set default_config(gui.fontui) [font configure font_ui]
 615 set default_config(gui.fontdiff) [font configure font_diff]
 616 set font_descs {
 617         {fontui   font_ui   {mc "Main Font"}}
 618         {fontdiff font_diff {mc "Diff/Console Font"}}
 619 }
 620
 621 ######################################################################
 622 ##
 623 ## find git
 624
 625 set _git  [_which git]
 626 if {$_git eq {}} {
 627         catch {wm withdraw .}
 628         tk_messageBox \
 629                 -icon error \
 630                 -type ok \
 631                 -title [mc "git-gui: fatal error"] \
 632                 -message [mc "Cannot find git in PATH."]
 633         exit 1
 634 }
 635
 636 ######################################################################
 637 ##
 638 ## version check
 639
 640 if {[catch {set _git_version [git --version]} err]} {
 641         catch {wm withdraw .}
 642         tk_messageBox \
 643                 -icon error \
 644                 -type ok \
 645                 -title [mc "git-gui: fatal error"] \
 646                 -message "Cannot determine Git version:
 647
 648 $err
 649
 650 [appname] requires Git 1.5.0 or later."
 651         exit 1
 652 }
 653 if {![regsub {^git version } $_git_version {} _git_version]} {
 654         catch {wm withdraw .}
 655         tk_messageBox \
 656                 -icon error \
 657                 -type ok \
 658                 -title [mc "git-gui: fatal error"] \
 659                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 660         exit 1
 661 }
 662
 663 set _real_git_version $_git_version
 664 regsub -- {-dirty$} $_git_version {} _git_version
 665 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 666 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 667 regsub {\.GIT$} $_git_version {} _git_version
 668 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 669
 670 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 671         catch {wm withdraw .}
 672         if {[tk_messageBox \
 673                 -icon warning \
 674                 -type yesno \
 675                 -default no \
 676                 -title "[appname]: warning" \
 677                  -message [mc "Git version cannot be determined.
 678
 679 %s claims it is version '%s'.
 680
 681 %s requires at least Git 1.5.0 or later.
 682
 683 Assume '%s' is version 1.5.0?
 684 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 685                 set _git_version 1.5.0
 686         } else {
 687                 exit 1
 688         }
 689 }
 690 unset _real_git_version
 691
 692 proc git-version {args} {
 693         global _git_version
 694
 695         switch [llength $args] {
 696         0 {
 697                 return $_git_version
 698         }
 699
 700         2 {
 701                 set op [lindex $args 0]
 702                 set vr [lindex $args 1]
 703                 set cm [package vcompare $_git_version $vr]
 704                 return [expr $cm $op 0]
 705         }
 706
 707         4 {
 708                 set type [lindex $args 0]
 709                 set name [lindex $args 1]
 710                 set parm [lindex $args 2]
 711                 set body [lindex $args 3]
 712
 713                 if {($type ne {proc} && $type ne {method})} {
 714                         error "Invalid arguments to git-version"
 715                 }
 716                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 717                         error "Last arm of $type $name must be default"
 718                 }
 719
 720                 foreach {op vr cb} [lrange $body 0 end-2] {
 721                         if {[git-version $op $vr]} {
 722                                 return [uplevel [list $type $name $parm $cb]]
 723                         }
 724                 }
 725
 726                 return [uplevel [list $type $name $parm [lindex $body end]]]
 727         }
 728
 729         default {
 730                 error "git-version >= x"
 731         }
 732
 733         }
 734 }
 735
 736 if {[git-version < 1.5]} {
 737         catch {wm withdraw .}
 738         tk_messageBox \
 739                 -icon error \
 740                 -type ok \
 741                 -title [mc "git-gui: fatal error"] \
 742                 -message "[appname] requires Git 1.5.0 or later.
 743
 744 You are using [git-version]:
 745
 746 [git --version]"
 747         exit 1
 748 }
 749
 750 ######################################################################
 751 ##
 752 ## configure our library
 753
 754 set idx [file join $oguilib tclIndex]
 755 if {[catch {set fd [open $idx r]} err]} {
 756         catch {wm withdraw .}
 757         tk_messageBox \
 758                 -icon error \
 759                 -type ok \
 760                 -title [mc "git-gui: fatal error"] \
 761                 -message $err
 762         exit 1
 763 }
 764 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 765         set idx [list]
 766         while {[gets $fd n] >= 0} {
 767                 if {$n ne {} && ![string match #* $n]} {
 768                         lappend idx $n
 769                 }
 770         }
 771 } else {
 772         set idx {}
 773 }
 774 close $fd
 775
 776 if {$idx ne {}} {
 777         set loaded [list]
 778         foreach p $idx {
 779                 if {[lsearch -exact $loaded $p] >= 0} continue
 780                 source [file join $oguilib $p]
 781                 lappend loaded $p
 782         }
 783         unset loaded p
 784 } else {
 785         set auto_path [concat [list $oguilib] $auto_path]
 786 }
 787 unset -nocomplain idx fd
 788
 789 ######################################################################
 790 ##
 791 ## feature option selection
 792
 793 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 794         unset _junk
 795 } else {
 796         set subcommand gui
 797 }
 798 if {$subcommand eq {gui.sh}} {
 799         set subcommand gui
 800 }
 801 if {$subcommand eq {gui} && [llength $argv] > 0} {
 802         set subcommand [lindex $argv 0]
 803         set argv [lrange $argv 1 end]
 804 }
 805
 806 enable_option multicommit
 807 enable_option branch
 808 enable_option transport
 809 disable_option bare
 810
 811 switch -- $subcommand {
 812 browser -
 813 blame {
 814         enable_option bare
 815
 816         disable_option multicommit
 817         disable_option branch
 818         disable_option transport
 819 }
 820 citool {
 821         enable_option singlecommit
 822
 823         disable_option multicommit
 824         disable_option branch
 825         disable_option transport
 826 }
 827 }
 828
 829 ######################################################################
 830 ##
 831 ## repository setup
 832
 833 if {[catch {
 834                 set _gitdir $env(GIT_DIR)
 835                 set _prefix {}
 836                 }]
 837         && [catch {
 838                 set _gitdir [git rev-parse --git-dir]
 839                 set _prefix [git rev-parse --show-prefix]
 840         } err]} {
 841         load_config 1
 842         apply_config
 843         choose_repository::pick
 844 }
 845 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 846         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 847 }
 848 if {![file isdirectory $_gitdir]} {
 849         catch {wm withdraw .}
 850         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 851         exit 1
 852 }
 853 if {$_prefix ne {}} {
 854         regsub -all {[^/]+/} $_prefix ../ cdup
 855         if {[catch {cd $cdup} err]} {
 856                 catch {wm withdraw .}
 857                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 858                 exit 1
 859         }
 860         unset cdup
 861 } elseif {![is_enabled bare]} {
 862         if {[lindex [file split $_gitdir] end] ne {.git}} {
 863                 catch {wm withdraw .}
 864                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 865                 exit 1
 866         }
 867         if {[catch {cd [file dirname $_gitdir]} err]} {
 868                 catch {wm withdraw .}
 869                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 870                 exit 1
 871         }
 872 }
 873 set _reponame [file split [file normalize $_gitdir]]
 874 if {[lindex $_reponame end] eq {.git}} {
 875         set _reponame [lindex $_reponame end-1]
 876 } else {
 877         set _reponame [lindex $_reponame end]
 878 }
 879
 880 ######################################################################
 881 ##
 882 ## global init
 883
 884 set current_diff_path {}
 885 set current_diff_side {}
 886 set diff_actions [list]
 887
 888 set HEAD {}
 889 set PARENT {}
 890 set MERGE_HEAD [list]
 891 set commit_type {}
 892 set empty_tree {}
 893 set current_branch {}
 894 set is_detached 0
 895 set current_diff_path {}
 896 set is_3way_diff 0
 897 set selected_commit_type new
 898
 899 ######################################################################
 900 ##
 901 ## task management
 902
 903 set rescan_active 0
 904 set diff_active 0
 905 set last_clicked {}
 906
 907 set disable_on_lock [list]
 908 set index_lock_type none
 909
 910 proc lock_index {type} {
 911         global index_lock_type disable_on_lock
 912
 913         if {$index_lock_type eq {none}} {
 914                 set index_lock_type $type
 915                 foreach w $disable_on_lock {
 916                         uplevel #0 $w disabled
 917                 }
 918                 return 1
 919         } elseif {$index_lock_type eq "begin-$type"} {
 920                 set index_lock_type $type
 921                 return 1
 922         }
 923         return 0
 924 }
 925
 926 proc unlock_index {} {
 927         global index_lock_type disable_on_lock
 928
 929         set index_lock_type none
 930         foreach w $disable_on_lock {
 931                 uplevel #0 $w normal
 932         }
 933 }
 934
 935 ######################################################################
 936 ##
 937 ## status
 938
 939 proc repository_state {ctvar hdvar mhvar} {
 940         global current_branch
 941         upvar $ctvar ct $hdvar hd $mhvar mh
 942
 943         set mh [list]
 944
 945         load_current_branch
 946         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
 947                 set hd {}
 948                 set ct initial
 949                 return
 950         }
 951
 952         set merge_head [gitdir MERGE_HEAD]
 953         if {[file exists $merge_head]} {
 954                 set ct merge
 955                 set fd_mh [open $merge_head r]
 956                 while {[gets $fd_mh line] >= 0} {
 957                         lappend mh $line
 958                 }
 959                 close $fd_mh
 960                 return
 961         }
 962
 963         set ct normal
 964 }
 965
 966 proc PARENT {} {
 967         global PARENT empty_tree
 968
 969         set p [lindex $PARENT 0]
 970         if {$p ne {}} {
 971                 return $p
 972         }
 973         if {$empty_tree eq {}} {
 974                 set empty_tree [git mktree << {}]
 975         }
 976         return $empty_tree
 977 }
 978
 979 proc rescan {after {honor_trustmtime 1}} {
 980         global HEAD PARENT MERGE_HEAD commit_type
 981         global ui_index ui_workdir ui_comm
 982         global rescan_active file_states
 983         global repo_config
 984
 985         if {$rescan_active > 0 || ![lock_index read]} return
 986
 987         repository_state newType newHEAD newMERGE_HEAD
 988         if {[string match amend* $commit_type]
 989                 && $newType eq {normal}
 990                 && $newHEAD eq $HEAD} {
 991         } else {
 992                 set HEAD $newHEAD
 993                 set PARENT $newHEAD
 994                 set MERGE_HEAD $newMERGE_HEAD
 995                 set commit_type $newType
 996         }
 997
 998         array unset file_states
 999
1000         if {!$::GITGUI_BCK_exists &&
1001                 (![$ui_comm edit modified]
1002                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1003                 if {[string match amend* $commit_type]} {
1004                 } elseif {[load_message GITGUI_MSG]} {
1005                 } elseif {[load_message MERGE_MSG]} {
1006                 } elseif {[load_message SQUASH_MSG]} {
1007                 }
1008                 $ui_comm edit reset
1009                 $ui_comm edit modified false
1010         }
1011
1012         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1013                 rescan_stage2 {} $after
1014         } else {
1015                 set rescan_active 1
1016                 ui_status [mc "Refreshing file status..."]
1017                 set fd_rf [git_read update-index \
1018                         -q \
1019                         --unmerged \
1020                         --ignore-missing \
1021                         --refresh \
1022                         ]
1023                 fconfigure $fd_rf -blocking 0 -translation binary
1024                 fileevent $fd_rf readable \
1025                         [list rescan_stage2 $fd_rf $after]
1026         }
1027 }
1028
1029 if {[is_Cygwin]} {
1030         set is_git_info_link {}
1031         set is_git_info_exclude {}
1032         proc have_info_exclude {} {
1033                 global is_git_info_link is_git_info_exclude
1034
1035                 if {$is_git_info_link eq {}} {
1036                         set is_git_info_link [file isfile [gitdir info.lnk]]
1037                 }
1038
1039                 if {$is_git_info_link} {
1040                         if {$is_git_info_exclude eq {}} {
1041                                 if {[catch {exec test -f [gitdir info exclude]}]} {
1042                                         set is_git_info_exclude 0
1043                                 } else {
1044                                         set is_git_info_exclude 1
1045                                 }
1046                         }
1047                         return $is_git_info_exclude
1048                 } else {
1049                         return [file readable [gitdir info exclude]]
1050                 }
1051         }
1052 } else {
1053         proc have_info_exclude {} {
1054                 return [file readable [gitdir info exclude]]
1055         }
1056 }
1057
1058 proc rescan_stage2 {fd after} {
1059         global rescan_active buf_rdi buf_rdf buf_rlo
1060
1061         if {$fd ne {}} {
1062                 read $fd
1063                 if {![eof $fd]} return
1064                 close $fd
1065         }
1066
1067         set ls_others [list --exclude-per-directory=.gitignore]
1068         if {[have_info_exclude]} {
1069                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1070         }
1071         set user_exclude [get_config core.excludesfile]
1072         if {$user_exclude ne {} && [file readable $user_exclude]} {
1073                 lappend ls_others "--exclude-from=$user_exclude"
1074         }
1075
1076         set buf_rdi {}
1077         set buf_rdf {}
1078         set buf_rlo {}
1079
1080         set rescan_active 3
1081         ui_status [mc "Scanning for modified files ..."]
1082         set fd_di [git_read diff-index --cached -z [PARENT]]
1083         set fd_df [git_read diff-files -z]
1084         set fd_lo [eval git_read ls-files --others -z $ls_others]
1085
1086         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1087         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1088         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1089         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1090         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1091         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1092 }
1093
1094 proc load_message {file} {
1095         global ui_comm
1096
1097         set f [gitdir $file]
1098         if {[file isfile $f]} {
1099                 if {[catch {set fd [open $f r]}]} {
1100                         return 0
1101                 }
1102                 fconfigure $fd -eofchar {}
1103                 set content [string trim [read $fd]]
1104                 close $fd
1105                 regsub -all -line {[ \r\t]+$} $content {} content
1106                 $ui_comm delete 0.0 end
1107                 $ui_comm insert end $content
1108                 return 1
1109         }
1110         return 0
1111 }
1112
1113 proc read_diff_index {fd after} {
1114         global buf_rdi
1115
1116         append buf_rdi [read $fd]
1117         set c 0
1118         set n [string length $buf_rdi]
1119         while {$c < $n} {
1120                 set z1 [string first "\0" $buf_rdi $c]
1121                 if {$z1 == -1} break
1122                 incr z1
1123                 set z2 [string first "\0" $buf_rdi $z1]
1124                 if {$z2 == -1} break
1125
1126                 incr c
1127                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1128                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1129                 merge_state \
1130                         [encoding convertfrom $p] \
1131                         [lindex $i 4]? \
1132                         [list [lindex $i 0] [lindex $i 2]] \
1133                         [list]
1134                 set c $z2
1135                 incr c
1136         }
1137         if {$c < $n} {
1138                 set buf_rdi [string range $buf_rdi $c end]
1139         } else {
1140                 set buf_rdi {}
1141         }
1142
1143         rescan_done $fd buf_rdi $after
1144 }
1145
1146 proc read_diff_files {fd after} {
1147         global buf_rdf
1148
1149         append buf_rdf [read $fd]
1150         set c 0
1151         set n [string length $buf_rdf]
1152         while {$c < $n} {
1153                 set z1 [string first "\0" $buf_rdf $c]
1154                 if {$z1 == -1} break
1155                 incr z1
1156                 set z2 [string first "\0" $buf_rdf $z1]
1157                 if {$z2 == -1} break
1158
1159                 incr c
1160                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1161                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1162                 merge_state \
1163                         [encoding convertfrom $p] \
1164                         ?[lindex $i 4] \
1165                         [list] \
1166                         [list [lindex $i 0] [lindex $i 2]]
1167                 set c $z2
1168                 incr c
1169         }
1170         if {$c < $n} {
1171                 set buf_rdf [string range $buf_rdf $c end]
1172         } else {
1173                 set buf_rdf {}
1174         }
1175
1176         rescan_done $fd buf_rdf $after
1177 }
1178
1179 proc read_ls_others {fd after} {
1180         global buf_rlo
1181
1182         append buf_rlo [read $fd]
1183         set pck [split $buf_rlo "\0"]
1184         set buf_rlo [lindex $pck end]
1185         foreach p [lrange $pck 0 end-1] {
1186                 set p [encoding convertfrom $p]
1187                 if {[string index $p end] eq {/}} {
1188                         set p [string range $p 0 end-1]
1189                 }
1190                 merge_state $p ?O
1191         }
1192         rescan_done $fd buf_rlo $after
1193 }
1194
1195 proc rescan_done {fd buf after} {
1196         global rescan_active current_diff_path
1197         global file_states repo_config
1198         upvar $buf to_clear
1199
1200         if {![eof $fd]} return
1201         set to_clear {}
1202         close $fd
1203         if {[incr rescan_active -1] > 0} return
1204
1205         prune_selection
1206         unlock_index
1207         display_all_files
1208         if {$current_diff_path ne {}} reshow_diff
1209         uplevel #0 $after
1210 }
1211
1212 proc prune_selection {} {
1213         global file_states selected_paths
1214
1215         foreach path [array names selected_paths] {
1216                 if {[catch {set still_here $file_states($path)}]} {
1217                         unset selected_paths($path)
1218                 }
1219         }
1220 }
1221
1222 ######################################################################
1223 ##
1224 ## ui helpers
1225
1226 proc mapicon {w state path} {
1227         global all_icons
1228
1229         if {[catch {set r $all_icons($state$w)}]} {
1230                 puts "error: no icon for $w state={$state} $path"
1231                 return file_plain
1232         }
1233         return $r
1234 }
1235
1236 proc mapdesc {state path} {
1237         global all_descs
1238
1239         if {[catch {set r $all_descs($state)}]} {
1240                 puts "error: no desc for state={$state} $path"
1241                 return $state
1242         }
1243         return $r
1244 }
1245
1246 proc ui_status {msg} {
1247         global main_status
1248         if {[info exists main_status]} {
1249                 $main_status show $msg
1250         }
1251 }
1252
1253 proc ui_ready {{test {}}} {
1254         global main_status
1255         if {[info exists main_status]} {
1256                 $main_status show [mc "Ready."] $test
1257         }
1258 }
1259
1260 proc escape_path {path} {
1261         regsub -all {\\} $path "\\\\" path
1262         regsub -all "\n" $path "\\n" path
1263         return $path
1264 }
1265
1266 proc short_path {path} {
1267         return [escape_path [lindex [file split $path] end]]
1268 }
1269
1270 set next_icon_id 0
1271 set null_sha1 [string repeat 0 40]
1272
1273 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1274         global file_states next_icon_id null_sha1
1275
1276         set s0 [string index $new_state 0]
1277         set s1 [string index $new_state 1]
1278
1279         if {[catch {set info $file_states($path)}]} {
1280                 set state __
1281                 set icon n[incr next_icon_id]
1282         } else {
1283                 set state [lindex $info 0]
1284                 set icon [lindex $info 1]
1285                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1286                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1287         }
1288
1289         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1290         elseif {$s0 eq {_}} {set s0 _}
1291
1292         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1293         elseif {$s1 eq {_}} {set s1 _}
1294
1295         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1296                 set head_info [list 0 $null_sha1]
1297         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1298                 && $head_info eq {}} {
1299                 set head_info $index_info
1300         }
1301
1302         set file_states($path) [list $s0$s1 $icon \
1303                 $head_info $index_info \
1304                 ]
1305         return $state
1306 }
1307
1308 proc display_file_helper {w path icon_name old_m new_m} {
1309         global file_lists
1310
1311         if {$new_m eq {_}} {
1312                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1313                 if {$lno >= 0} {
1314                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1315                         incr lno
1316                         $w conf -state normal
1317                         $w delete $lno.0 [expr {$lno + 1}].0
1318                         $w conf -state disabled
1319                 }
1320         } elseif {$old_m eq {_} && $new_m ne {_}} {
1321                 lappend file_lists($w) $path
1322                 set file_lists($w) [lsort -unique $file_lists($w)]
1323                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1324                 incr lno
1325                 $w conf -state normal
1326                 $w image create $lno.0 \
1327                         -align center -padx 5 -pady 1 \
1328                         -name $icon_name \
1329                         -image [mapicon $w $new_m $path]
1330                 $w insert $lno.1 "[escape_path $path]\n"
1331                 $w conf -state disabled
1332         } elseif {$old_m ne $new_m} {
1333                 $w conf -state normal
1334                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1335                 $w conf -state disabled
1336         }
1337 }
1338
1339 proc display_file {path state} {
1340         global file_states selected_paths
1341         global ui_index ui_workdir
1342
1343         set old_m [merge_state $path $state]
1344         set s $file_states($path)
1345         set new_m [lindex $s 0]
1346         set icon_name [lindex $s 1]
1347
1348         set o [string index $old_m 0]
1349         set n [string index $new_m 0]
1350         if {$o eq {U}} {
1351                 set o _
1352         }
1353         if {$n eq {U}} {
1354                 set n _
1355         }
1356         display_file_helper     $ui_index $path $icon_name $o $n
1357
1358         if {[string index $old_m 0] eq {U}} {
1359                 set o U
1360         } else {
1361                 set o [string index $old_m 1]
1362         }
1363         if {[string index $new_m 0] eq {U}} {
1364                 set n U
1365         } else {
1366                 set n [string index $new_m 1]
1367         }
1368         display_file_helper     $ui_workdir $path $icon_name $o $n
1369
1370         if {$new_m eq {__}} {
1371                 unset file_states($path)
1372                 catch {unset selected_paths($path)}
1373         }
1374 }
1375
1376 proc display_all_files_helper {w path icon_name m} {
1377         global file_lists
1378
1379         lappend file_lists($w) $path
1380         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1381         $w image create end \
1382                 -align center -padx 5 -pady 1 \
1383                 -name $icon_name \
1384                 -image [mapicon $w $m $path]
1385         $w insert end "[escape_path $path]\n"
1386 }
1387
1388 proc display_all_files {} {
1389         global ui_index ui_workdir
1390         global file_states file_lists
1391         global last_clicked
1392
1393         $ui_index conf -state normal
1394         $ui_workdir conf -state normal
1395
1396         $ui_index delete 0.0 end
1397         $ui_workdir delete 0.0 end
1398         set last_clicked {}
1399
1400         set file_lists($ui_index) [list]
1401         set file_lists($ui_workdir) [list]
1402
1403         foreach path [lsort [array names file_states]] {
1404                 set s $file_states($path)
1405                 set m [lindex $s 0]
1406                 set icon_name [lindex $s 1]
1407
1408                 set s [string index $m 0]
1409                 if {$s ne {U} && $s ne {_}} {
1410                         display_all_files_helper $ui_index $path \
1411                                 $icon_name $s
1412                 }
1413
1414                 if {[string index $m 0] eq {U}} {
1415                         set s U
1416                 } else {
1417                         set s [string index $m 1]
1418                 }
1419                 if {$s ne {_}} {
1420                         display_all_files_helper $ui_workdir $path \
1421                                 $icon_name $s
1422                 }
1423         }
1424
1425         $ui_index conf -state disabled
1426         $ui_workdir conf -state disabled
1427 }
1428
1429 ######################################################################
1430 ##
1431 ## icons
1432
1433 set filemask {
1434 #define mask_width 14
1435 #define mask_height 15
1436 static unsigned char mask_bits[] = {
1437    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1438    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1439    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1440 }
1441
1442 image create bitmap file_plain -background white -foreground black -data {
1443 #define plain_width 14
1444 #define plain_height 15
1445 static unsigned char plain_bits[] = {
1446    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1447    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1448    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1449 } -maskdata $filemask
1450
1451 image create bitmap file_mod -background white -foreground blue -data {
1452 #define mod_width 14
1453 #define mod_height 15
1454 static unsigned char mod_bits[] = {
1455    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1456    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1457    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1458 } -maskdata $filemask
1459
1460 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1461 #define file_fulltick_width 14
1462 #define file_fulltick_height 15
1463 static unsigned char file_fulltick_bits[] = {
1464    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1465    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1466    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1467 } -maskdata $filemask
1468
1469 image create bitmap file_parttick -background white -foreground "#005050" -data {
1470 #define parttick_width 14
1471 #define parttick_height 15
1472 static unsigned char parttick_bits[] = {
1473    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1474    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1475    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1476 } -maskdata $filemask
1477
1478 image create bitmap file_question -background white -foreground black -data {
1479 #define file_question_width 14
1480 #define file_question_height 15
1481 static unsigned char file_question_bits[] = {
1482    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1483    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1484    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1485 } -maskdata $filemask
1486
1487 image create bitmap file_removed -background white -foreground red -data {
1488 #define file_removed_width 14
1489 #define file_removed_height 15
1490 static unsigned char file_removed_bits[] = {
1491    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1492    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1493    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1494 } -maskdata $filemask
1495
1496 image create bitmap file_merge -background white -foreground blue -data {
1497 #define file_merge_width 14
1498 #define file_merge_height 15
1499 static unsigned char file_merge_bits[] = {
1500    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1501    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1502    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1503 } -maskdata $filemask
1504
1505 set ui_index .vpane.files.index.list
1506 set ui_workdir .vpane.files.workdir.list
1507
1508 set all_icons(_$ui_index)   file_plain
1509 set all_icons(A$ui_index)   file_fulltick
1510 set all_icons(M$ui_index)   file_fulltick
1511 set all_icons(D$ui_index)   file_removed
1512 set all_icons(U$ui_index)   file_merge
1513
1514 set all_icons(_$ui_workdir) file_plain
1515 set all_icons(M$ui_workdir) file_mod
1516 set all_icons(D$ui_workdir) file_question
1517 set all_icons(U$ui_workdir) file_merge
1518 set all_icons(O$ui_workdir) file_plain
1519
1520 set max_status_desc 0
1521 foreach i {
1522                 {__ {mc "Unmodified"}}
1523
1524                 {_M {mc "Modified, not staged"}}
1525                 {M_ {mc "Staged for commit"}}
1526                 {MM {mc "Portions staged for commit"}}
1527                 {MD {mc "Staged for commit, missing"}}
1528
1529                 {_O {mc "Untracked, not staged"}}
1530                 {A_ {mc "Staged for commit"}}
1531                 {AM {mc "Portions staged for commit"}}
1532                 {AD {mc "Staged for commit, missing"}}
1533
1534                 {_D {mc "Missing"}}
1535                 {D_ {mc "Staged for removal"}}
1536                 {DO {mc "Staged for removal, still present"}}
1537
1538                 {U_ {mc "Requires merge resolution"}}
1539                 {UU {mc "Requires merge resolution"}}
1540                 {UM {mc "Requires merge resolution"}}
1541                 {UD {mc "Requires merge resolution"}}
1542         } {
1543         set text [eval [lindex $i 1]]
1544         if {$max_status_desc < [string length $text]} {
1545                 set max_status_desc [string length $text]
1546         }
1547         set all_descs([lindex $i 0]) $text
1548 }
1549 unset i
1550
1551 ######################################################################
1552 ##
1553 ## util
1554
1555 proc scrollbar2many {list mode args} {
1556         foreach w $list {eval $w $mode $args}
1557 }
1558
1559 proc many2scrollbar {list mode sb top bottom} {
1560         $sb set $top $bottom
1561         foreach w $list {$w $mode moveto $top}
1562 }
1563
1564 proc incr_font_size {font {amt 1}} {
1565         set sz [font configure $font -size]
1566         incr sz $amt
1567         font configure $font -size $sz
1568         font configure ${font}bold -size $sz
1569         font configure ${font}italic -size $sz
1570 }
1571
1572 ######################################################################
1573 ##
1574 ## ui commands
1575
1576 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1577
1578 proc do_gitk {revs} {
1579         # -- Always start gitk through whatever we were loaded with.  This
1580         #    lets us bypass using shell process on Windows systems.
1581         #
1582         set exe [file join [file dirname $::_git] gitk]
1583         set cmd [list [info nameofexecutable] $exe]
1584         if {! [file exists $exe]} {
1585                 error_popup [mc "Unable to start gitk:\n\n%s does not exist" $exe]
1586         } else {
1587                 global env
1588
1589                 if {[info exists env(GIT_DIR)]} {
1590                         set old_GIT_DIR $env(GIT_DIR)
1591                 } else {
1592                         set old_GIT_DIR {}
1593                 }
1594
1595                 set pwd [pwd]
1596                 cd [file dirname [gitdir]]
1597                 set env(GIT_DIR) [file tail [gitdir]]
1598
1599                 eval exec $cmd $revs &
1600
1601                 if {$old_GIT_DIR eq {}} {
1602                         unset env(GIT_DIR)
1603                 } else {
1604                         set env(GIT_DIR) $old_GIT_DIR
1605                 }
1606                 cd $pwd
1607
1608                 ui_status $::starting_gitk_msg
1609                 after 10000 {
1610                         ui_ready $starting_gitk_msg
1611                 }
1612         }
1613 }
1614
1615 set is_quitting 0
1616
1617 proc do_quit {} {
1618         global ui_comm is_quitting repo_config commit_type
1619         global GITGUI_BCK_exists GITGUI_BCK_i
1620
1621         if {$is_quitting} return
1622         set is_quitting 1
1623
1624         if {[winfo exists $ui_comm]} {
1625                 # -- Stash our current commit buffer.
1626                 #
1627                 set save [gitdir GITGUI_MSG]
1628                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1629                         file rename -force [gitdir GITGUI_BCK] $save
1630                         set GITGUI_BCK_exists 0
1631                 } else {
1632                         set msg [string trim [$ui_comm get 0.0 end]]
1633                         regsub -all -line {[ \r\t]+$} $msg {} msg
1634                         if {(![string match amend* $commit_type]
1635                                 || [$ui_comm edit modified])
1636                                 && $msg ne {}} {
1637                                 catch {
1638                                         set fd [open $save w]
1639                                         puts -nonewline $fd $msg
1640                                         close $fd
1641                                 }
1642                         } else {
1643                                 catch {file delete $save}
1644                         }
1645                 }
1646
1647                 # -- Remove our editor backup, its not needed.
1648                 #
1649                 after cancel $GITGUI_BCK_i
1650                 if {$GITGUI_BCK_exists} {
1651                         catch {file delete [gitdir GITGUI_BCK]}
1652                 }
1653
1654                 # -- Stash our current window geometry into this repository.
1655                 #
1656                 set cfg_geometry [list]
1657                 lappend cfg_geometry [wm geometry .]
1658                 lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
1659                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
1660                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1661                         set rc_geometry {}
1662                 }
1663                 if {$cfg_geometry ne $rc_geometry} {
1664                         catch {git config gui.geometry $cfg_geometry}
1665                 }
1666         }
1667
1668         destroy .
1669 }
1670
1671 proc do_rescan {} {
1672         rescan ui_ready
1673 }
1674
1675 proc do_commit {} {
1676         commit_tree
1677 }
1678
1679 proc toggle_or_diff {w x y} {
1680         global file_states file_lists current_diff_path ui_index ui_workdir
1681         global last_clicked selected_paths
1682
1683         set pos [split [$w index @$x,$y] .]
1684         set lno [lindex $pos 0]
1685         set col [lindex $pos 1]
1686         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1687         if {$path eq {}} {
1688                 set last_clicked {}
1689                 return
1690         }
1691
1692         set last_clicked [list $w $lno]
1693         array unset selected_paths
1694         $ui_index tag remove in_sel 0.0 end
1695         $ui_workdir tag remove in_sel 0.0 end
1696
1697         if {$col == 0} {
1698                 if {$current_diff_path eq $path} {
1699                         set after {reshow_diff;}
1700                 } else {
1701                         set after {}
1702                 }
1703                 if {$w eq $ui_index} {
1704                         update_indexinfo \
1705                                 "Unstaging [short_path $path] from commit" \
1706                                 [list $path] \
1707                                 [concat $after [list ui_ready]]
1708                 } elseif {$w eq $ui_workdir} {
1709                         update_index \
1710                                 "Adding [short_path $path]" \
1711                                 [list $path] \
1712                                 [concat $after [list ui_ready]]
1713                 }
1714         } else {
1715                 show_diff $path $w $lno
1716         }
1717 }
1718
1719 proc add_one_to_selection {w x y} {
1720         global file_lists last_clicked selected_paths
1721
1722         set lno [lindex [split [$w index @$x,$y] .] 0]
1723         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1724         if {$path eq {}} {
1725                 set last_clicked {}
1726                 return
1727         }
1728
1729         if {$last_clicked ne {}
1730                 && [lindex $last_clicked 0] ne $w} {
1731                 array unset selected_paths
1732                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1733         }
1734
1735         set last_clicked [list $w $lno]
1736         if {[catch {set in_sel $selected_paths($path)}]} {
1737                 set in_sel 0
1738         }
1739         if {$in_sel} {
1740                 unset selected_paths($path)
1741                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1742         } else {
1743                 set selected_paths($path) 1
1744                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1745         }
1746 }
1747
1748 proc add_range_to_selection {w x y} {
1749         global file_lists last_clicked selected_paths
1750
1751         if {[lindex $last_clicked 0] ne $w} {
1752                 toggle_or_diff $w $x $y
1753                 return
1754         }
1755
1756         set lno [lindex [split [$w index @$x,$y] .] 0]
1757         set lc [lindex $last_clicked 1]
1758         if {$lc < $lno} {
1759                 set begin $lc
1760                 set end $lno
1761         } else {
1762                 set begin $lno
1763                 set end $lc
1764         }
1765
1766         foreach path [lrange $file_lists($w) \
1767                 [expr {$begin - 1}] \
1768                 [expr {$end - 1}]] {
1769                 set selected_paths($path) 1
1770         }
1771         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1772 }
1773
1774 ######################################################################
1775 ##
1776 ## ui construction
1777
1778 load_config 0
1779 apply_config
1780 set ui_comm {}
1781
1782 # -- Menu Bar
1783 #
1784 menu .mbar -tearoff 0
1785 .mbar add cascade -label [mc Repository] -menu .mbar.repository
1786 .mbar add cascade -label [mc Edit] -menu .mbar.edit
1787 if {[is_enabled branch]} {
1788         .mbar add cascade -label [mc Branch] -menu .mbar.branch
1789 }
1790 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1791         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
1792 }
1793 if {[is_enabled transport]} {
1794         .mbar add cascade -label [mc Merge] -menu .mbar.merge
1795         .mbar add cascade -label [mc Fetch] -menu .mbar.fetch
1796         .mbar add cascade -label [mc Push] -menu .mbar.push
1797 }
1798 . configure -menu .mbar
1799
1800 # -- Repository Menu
1801 #
1802 menu .mbar.repository
1803
1804 .mbar.repository add command \
1805         -label [mc "Browse Current Branch's Files"] \
1806         -command {browser::new $current_branch}
1807 set ui_browse_current [.mbar.repository index last]
1808 .mbar.repository add command \
1809         -label [mc "Browse Branch Files..."] \
1810         -command browser_open::dialog
1811 .mbar.repository add separator
1812
1813 .mbar.repository add command \
1814         -label [mc "Visualize Current Branch's History"] \
1815         -command {do_gitk $current_branch}
1816 set ui_visualize_current [.mbar.repository index last]
1817 .mbar.repository add command \
1818         -label [mc "Visualize All Branch History"] \
1819         -command {do_gitk --all}
1820 .mbar.repository add separator
1821
1822 proc current_branch_write {args} {
1823         global current_branch
1824         .mbar.repository entryconf $::ui_browse_current \
1825                 -label [mc "Browse %s's Files" $current_branch]
1826         .mbar.repository entryconf $::ui_visualize_current \
1827                 -label [mc "Visualize %s's History" $current_branch]
1828 }
1829 trace add variable current_branch write current_branch_write
1830
1831 if {[is_enabled multicommit]} {
1832         .mbar.repository add command -label [mc "Database Statistics"] \
1833                 -command do_stats
1834
1835         .mbar.repository add command -label [mc "Compress Database"] \
1836                 -command do_gc
1837
1838         .mbar.repository add command -label [mc "Verify Database"] \
1839                 -command do_fsck_objects
1840
1841         .mbar.repository add separator
1842
1843         if {[is_Cygwin]} {
1844                 .mbar.repository add command \
1845                         -label [mc "Create Desktop Icon"] \
1846                         -command do_cygwin_shortcut
1847         } elseif {[is_Windows]} {
1848                 .mbar.repository add command \
1849                         -label [mc "Create Desktop Icon"] \
1850                         -command do_windows_shortcut
1851         } elseif {[is_MacOSX]} {
1852                 .mbar.repository add command \
1853                         -label [mc "Create Desktop Icon"] \
1854                         -command do_macosx_app
1855         }
1856 }
1857
1858 .mbar.repository add command -label [mc Quit] \
1859         -command do_quit \
1860         -accelerator $M1T-Q
1861
1862 # -- Edit Menu
1863 #
1864 menu .mbar.edit
1865 .mbar.edit add command -label [mc Undo] \
1866         -command {catch {[focus] edit undo}} \
1867         -accelerator $M1T-Z
1868 .mbar.edit add command -label [mc Redo] \
1869         -command {catch {[focus] edit redo}} \
1870         -accelerator $M1T-Y
1871 .mbar.edit add separator
1872 .mbar.edit add command -label [mc Cut] \
1873         -command {catch {tk_textCut [focus]}} \
1874         -accelerator $M1T-X
1875 .mbar.edit add command -label [mc Copy] \
1876         -command {catch {tk_textCopy [focus]}} \
1877         -accelerator $M1T-C
1878 .mbar.edit add command -label [mc Paste] \
1879         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
1880         -accelerator $M1T-V
1881 .mbar.edit add command -label [mc Delete] \
1882         -command {catch {[focus] delete sel.first sel.last}} \
1883         -accelerator Del
1884 .mbar.edit add separator
1885 .mbar.edit add command -label [mc "Select All"] \
1886         -command {catch {[focus] tag add sel 0.0 end}} \
1887         -accelerator $M1T-A
1888
1889 # -- Branch Menu
1890 #
1891 if {[is_enabled branch]} {
1892         menu .mbar.branch
1893
1894         .mbar.branch add command -label [mc "Create..."] \
1895                 -command branch_create::dialog \
1896                 -accelerator $M1T-N
1897         lappend disable_on_lock [list .mbar.branch entryconf \
1898                 [.mbar.branch index last] -state]
1899
1900         .mbar.branch add command -label [mc "Checkout..."] \
1901                 -command branch_checkout::dialog \
1902                 -accelerator $M1T-O
1903         lappend disable_on_lock [list .mbar.branch entryconf \
1904                 [.mbar.branch index last] -state]
1905
1906         .mbar.branch add command -label [mc "Rename..."] \
1907                 -command branch_rename::dialog
1908         lappend disable_on_lock [list .mbar.branch entryconf \
1909                 [.mbar.branch index last] -state]
1910
1911         .mbar.branch add command -label [mc "Delete..."] \
1912                 -command branch_delete::dialog
1913         lappend disable_on_lock [list .mbar.branch entryconf \
1914                 [.mbar.branch index last] -state]
1915
1916         .mbar.branch add command -label [mc "Reset..."] \
1917                 -command merge::reset_hard
1918         lappend disable_on_lock [list .mbar.branch entryconf \
1919                 [.mbar.branch index last] -state]
1920 }
1921
1922 # -- Commit Menu
1923 #
1924 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1925         menu .mbar.commit
1926
1927         .mbar.commit add radiobutton \
1928                 -label [mc "New Commit"] \
1929                 -command do_select_commit_type \
1930                 -variable selected_commit_type \
1931                 -value new
1932         lappend disable_on_lock \
1933                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1934
1935         .mbar.commit add radiobutton \
1936                 -label [mc "Amend Last Commit"] \
1937                 -command do_select_commit_type \
1938                 -variable selected_commit_type \
1939                 -value amend
1940         lappend disable_on_lock \
1941                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1942
1943         .mbar.commit add separator
1944
1945         .mbar.commit add command -label [mc Rescan] \
1946                 -command do_rescan \
1947                 -accelerator F5
1948         lappend disable_on_lock \
1949                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1950
1951         .mbar.commit add command -label [mc "Stage To Commit"] \
1952                 -command do_add_selection
1953         lappend disable_on_lock \
1954                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1955
1956         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
1957                 -command do_add_all \
1958                 -accelerator $M1T-I
1959         lappend disable_on_lock \
1960                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1961
1962         .mbar.commit add command -label [mc "Unstage From Commit"] \
1963                 -command do_unstage_selection
1964         lappend disable_on_lock \
1965                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1966
1967         .mbar.commit add command -label [mc "Revert Changes"] \
1968                 -command do_revert_selection
1969         lappend disable_on_lock \
1970                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1971
1972         .mbar.commit add separator
1973
1974         .mbar.commit add command -label [mc "Sign Off"] \
1975                 -command do_signoff \
1976                 -accelerator $M1T-S
1977
1978         .mbar.commit add command -label [mc Commit@@verb] \
1979                 -command do_commit \
1980                 -accelerator $M1T-Return
1981         lappend disable_on_lock \
1982                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1983 }
1984
1985 # -- Merge Menu
1986 #
1987 if {[is_enabled branch]} {
1988         menu .mbar.merge
1989         .mbar.merge add command -label [mc "Local Merge..."] \
1990                 -command merge::dialog \
1991                 -accelerator $M1T-M
1992         lappend disable_on_lock \
1993                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1994         .mbar.merge add command -label [mc "Abort Merge..."] \
1995                 -command merge::reset_hard
1996         lappend disable_on_lock \
1997                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1998 }
1999
2000 # -- Transport Menu
2001 #
2002 if {[is_enabled transport]} {
2003         menu .mbar.fetch
2004
2005         menu .mbar.push
2006         .mbar.push add command -label [mc "Push..."] \
2007                 -command do_push_anywhere \
2008                 -accelerator $M1T-P
2009         .mbar.push add command -label [mc "Delete..."] \
2010                 -command remote_branch_delete::dialog
2011 }
2012
2013 if {[is_MacOSX]} {
2014         # -- Apple Menu (Mac OS X only)
2015         #
2016         .mbar add cascade -label [mc Apple] -menu .mbar.apple
2017         menu .mbar.apple
2018
2019         .mbar.apple add command -label [mc "About %s" [appname]] \
2020                 -command do_about
2021         .mbar.apple add command -label [mc "Options..."] \
2022                 -command do_options
2023 } else {
2024         # -- Edit Menu
2025         #
2026         .mbar.edit add separator
2027         .mbar.edit add command -label [mc "Options..."] \
2028                 -command do_options
2029 }
2030
2031 # -- Help Menu
2032 #
2033 .mbar add cascade -label [mc Help] -menu .mbar.help
2034 menu .mbar.help
2035
2036 if {![is_MacOSX]} {
2037         .mbar.help add command -label [mc "About %s" [appname]] \
2038                 -command do_about
2039 }
2040
2041 set browser {}
2042 catch {set browser $repo_config(instaweb.browser)}
2043 set doc_path [file dirname [gitexec]]
2044 set doc_path [file join $doc_path Documentation index.html]
2045
2046 if {[is_Cygwin]} {
2047         set doc_path [exec cygpath --mixed $doc_path]
2048 }
2049
2050 if {$browser eq {}} {
2051         if {[is_MacOSX]} {
2052                 set browser open
2053         } elseif {[is_Cygwin]} {
2054                 set program_files [file dirname [exec cygpath --windir]]
2055                 set program_files [file join $program_files {Program Files}]
2056                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2057                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2058                 if {[file exists $firefox]} {
2059                         set browser $firefox
2060                 } elseif {[file exists $ie]} {
2061                         set browser $ie
2062                 }
2063                 unset program_files firefox ie
2064         }
2065 }
2066
2067 if {[file isfile $doc_path]} {
2068         set doc_url "file:$doc_path"
2069 } else {
2070         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2071 }
2072
2073 if {$browser ne {}} {
2074         .mbar.help add command -label [mc "Online Documentation"] \
2075                 -command [list exec $browser $doc_url &]
2076 }
2077 unset browser doc_path doc_url
2078
2079 # -- Standard bindings
2080 #
2081 wm protocol . WM_DELETE_WINDOW do_quit
2082 bind all <$M1B-Key-q> do_quit
2083 bind all <$M1B-Key-Q> do_quit
2084 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2085 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2086
2087 set subcommand_args {}
2088 proc usage {} {
2089         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2090         exit 1
2091 }
2092
2093 # -- Not a normal commit type invocation?  Do that instead!
2094 #
2095 switch -- $subcommand {
2096 browser -
2097 blame {
2098         set subcommand_args {rev? path}
2099         if {$argv eq {}} usage
2100         set head {}
2101         set path {}
2102         set is_path 0
2103         foreach a $argv {
2104                 if {$is_path || [file exists $_prefix$a]} {
2105                         if {$path ne {}} usage
2106                         set path $_prefix$a
2107                         break
2108                 } elseif {$a eq {--}} {
2109                         if {$path ne {}} {
2110                                 if {$head ne {}} usage
2111                                 set head $path
2112                                 set path {}
2113                         }
2114                         set is_path 1
2115                 } elseif {$head eq {}} {
2116                         if {$head ne {}} usage
2117                         set head $a
2118                         set is_path 1
2119                 } else {
2120                         usage
2121                 }
2122         }
2123         unset is_path
2124
2125         if {$head ne {} && $path eq {}} {
2126                 set path $_prefix$head
2127                 set head {}
2128         }
2129
2130         if {$head eq {}} {
2131                 load_current_branch
2132         } else {
2133                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2134                         if {[catch {
2135                                         set head [git rev-parse --verify $head]
2136                                 } err]} {
2137                                 puts stderr $err
2138                                 exit 1
2139                         }
2140                 }
2141                 set current_branch $head
2142         }
2143
2144         switch -- $subcommand {
2145         browser {
2146                 if {$head eq {}} {
2147                         if {$path ne {} && [file isdirectory $path]} {
2148                                 set head $current_branch
2149                         } else {
2150                                 set head $path
2151                                 set path {}
2152                         }
2153                 }
2154                 browser::new $head $path
2155         }
2156         blame   {
2157                 if {$head eq {} && ![file exists $path]} {
2158                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2159                         exit 1
2160                 }
2161                 blame::new $head $path
2162         }
2163         }
2164         return
2165 }
2166 citool -
2167 gui {
2168         if {[llength $argv] != 0} {
2169                 puts -nonewline stderr "usage: $argv0"
2170                 if {$subcommand ne {gui}
2171                         && [file tail $argv0] ne "git-$subcommand"} {
2172                         puts -nonewline stderr " $subcommand"
2173                 }
2174                 puts stderr {}
2175                 exit 1
2176         }
2177         # fall through to setup UI for commits
2178 }
2179 default {
2180         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2181         exit 1
2182 }
2183 }
2184
2185 # -- Branch Control
2186 #
2187 frame .branch \
2188         -borderwidth 1 \
2189         -relief sunken
2190 label .branch.l1 \
2191         -text [mc "Current Branch:"] \
2192         -anchor w \
2193         -justify left
2194 label .branch.cb \
2195         -textvariable current_branch \
2196         -anchor w \
2197         -justify left
2198 pack .branch.l1 -side left
2199 pack .branch.cb -side left -fill x
2200 pack .branch -side top -fill x
2201
2202 # -- Main Window Layout
2203 #
2204 panedwindow .vpane -orient vertical
2205 panedwindow .vpane.files -orient horizontal
2206 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2207 pack .vpane -anchor n -side top -fill both -expand 1
2208
2209 # -- Index File List
2210 #
2211 frame .vpane.files.index -height 100 -width 200
2212 label .vpane.files.index.title -text [mc "Staged Changes (Will Be Committed)"] \
2213         -background lightgreen
2214 text $ui_index -background white -borderwidth 0 \
2215         -width 20 -height 10 \
2216         -wrap none \
2217         -cursor $cursor_ptr \
2218         -xscrollcommand {.vpane.files.index.sx set} \
2219         -yscrollcommand {.vpane.files.index.sy set} \
2220         -state disabled
2221 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2222 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2223 pack .vpane.files.index.title -side top -fill x
2224 pack .vpane.files.index.sx -side bottom -fill x
2225 pack .vpane.files.index.sy -side right -fill y
2226 pack $ui_index -side left -fill both -expand 1
2227 .vpane.files add .vpane.files.index -sticky nsew
2228
2229 # -- Working Directory File List
2230 #
2231 frame .vpane.files.workdir -height 100 -width 200
2232 label .vpane.files.workdir.title -text [mc "Unstaged Changes (Will Not Be Committed)"] \
2233         -background lightsalmon
2234 text $ui_workdir -background white -borderwidth 0 \
2235         -width 20 -height 10 \
2236         -wrap none \
2237         -cursor $cursor_ptr \
2238         -xscrollcommand {.vpane.files.workdir.sx set} \
2239         -yscrollcommand {.vpane.files.workdir.sy set} \
2240         -state disabled
2241 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2242 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2243 pack .vpane.files.workdir.title -side top -fill x
2244 pack .vpane.files.workdir.sx -side bottom -fill x
2245 pack .vpane.files.workdir.sy -side right -fill y
2246 pack $ui_workdir -side left -fill both -expand 1
2247 .vpane.files add .vpane.files.workdir -sticky nsew
2248
2249 foreach i [list $ui_index $ui_workdir] {
2250         rmsel_tag $i
2251         $i tag conf in_diff -background [$i tag cget in_sel -background]
2252 }
2253 unset i
2254
2255 # -- Diff and Commit Area
2256 #
2257 frame .vpane.lower -height 300 -width 400
2258 frame .vpane.lower.commarea
2259 frame .vpane.lower.diff -relief sunken -borderwidth 1
2260 pack .vpane.lower.commarea -side top -fill x
2261 pack .vpane.lower.diff -side bottom -fill both -expand 1
2262 .vpane add .vpane.lower -sticky nsew
2263
2264 # -- Commit Area Buttons
2265 #
2266 frame .vpane.lower.commarea.buttons
2267 label .vpane.lower.commarea.buttons.l -text {} \
2268         -anchor w \
2269         -justify left
2270 pack .vpane.lower.commarea.buttons.l -side top -fill x
2271 pack .vpane.lower.commarea.buttons -side left -fill y
2272
2273 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2274         -command do_rescan
2275 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2276 lappend disable_on_lock \
2277         {.vpane.lower.commarea.buttons.rescan conf -state}
2278
2279 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2280         -command do_add_all
2281 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2282 lappend disable_on_lock \
2283         {.vpane.lower.commarea.buttons.incall conf -state}
2284
2285 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2286         -command do_signoff
2287 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2288
2289 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2290         -command do_commit
2291 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2292 lappend disable_on_lock \
2293         {.vpane.lower.commarea.buttons.commit conf -state}
2294
2295 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2296         -command do_push_anywhere
2297 pack .vpane.lower.commarea.buttons.push -side top -fill x
2298
2299 # -- Commit Message Buffer
2300 #
2301 frame .vpane.lower.commarea.buffer
2302 frame .vpane.lower.commarea.buffer.header
2303 set ui_comm .vpane.lower.commarea.buffer.t
2304 set ui_coml .vpane.lower.commarea.buffer.header.l
2305 radiobutton .vpane.lower.commarea.buffer.header.new \
2306         -text [mc "New Commit"] \
2307         -command do_select_commit_type \
2308         -variable selected_commit_type \
2309         -value new
2310 lappend disable_on_lock \
2311         [list .vpane.lower.commarea.buffer.header.new conf -state]
2312 radiobutton .vpane.lower.commarea.buffer.header.amend \
2313         -text [mc "Amend Last Commit"] \
2314         -command do_select_commit_type \
2315         -variable selected_commit_type \
2316         -value amend
2317 lappend disable_on_lock \
2318         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2319 label $ui_coml \
2320         -anchor w \
2321         -justify left
2322 proc trace_commit_type {varname args} {
2323         global ui_coml commit_type
2324         switch -glob -- $commit_type {
2325         initial       {set txt [mc "Initial Commit Message:"]}
2326         amend         {set txt [mc "Amended Commit Message:"]}
2327         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2328         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2329         merge         {set txt [mc "Merge Commit Message:"]}
2330         *             {set txt [mc "Commit Message:"]}
2331         }
2332         $ui_coml conf -text $txt
2333 }
2334 trace add variable commit_type write trace_commit_type
2335 pack $ui_coml -side left -fill x
2336 pack .vpane.lower.commarea.buffer.header.amend -side right
2337 pack .vpane.lower.commarea.buffer.header.new -side right
2338
2339 text $ui_comm -background white -borderwidth 1 \
2340         -undo true \
2341         -maxundo 20 \
2342         -autoseparators true \
2343         -relief sunken \
2344         -width 75 -height 9 -wrap none \
2345         -font font_diff \
2346         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2347 scrollbar .vpane.lower.commarea.buffer.sby \
2348         -command [list $ui_comm yview]
2349 pack .vpane.lower.commarea.buffer.header -side top -fill x
2350 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2351 pack $ui_comm -side left -fill y
2352 pack .vpane.lower.commarea.buffer -side left -fill y
2353
2354 # -- Commit Message Buffer Context Menu
2355 #
2356 set ctxm .vpane.lower.commarea.buffer.ctxm
2357 menu $ctxm -tearoff 0
2358 $ctxm add command \
2359         -label [mc Cut] \
2360         -command {tk_textCut $ui_comm}
2361 $ctxm add command \
2362         -label [mc Copy] \
2363         -command {tk_textCopy $ui_comm}
2364 $ctxm add command \
2365         -label [mc Paste] \
2366         -command {tk_textPaste $ui_comm}
2367 $ctxm add command \
2368         -label [mc Delete] \
2369         -command {$ui_comm delete sel.first sel.last}
2370 $ctxm add separator
2371 $ctxm add command \
2372         -label [mc "Select All"] \
2373         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2374 $ctxm add command \
2375         -label [mc "Copy All"] \
2376         -command {
2377                 $ui_comm tag add sel 0.0 end
2378                 tk_textCopy $ui_comm
2379                 $ui_comm tag remove sel 0.0 end
2380         }
2381 $ctxm add separator
2382 $ctxm add command \
2383         -label [mc "Sign Off"] \
2384         -command do_signoff
2385 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
2386
2387 # -- Diff Header
2388 #
2389 proc trace_current_diff_path {varname args} {
2390         global current_diff_path diff_actions file_states
2391         if {$current_diff_path eq {}} {
2392                 set s {}
2393                 set f {}
2394                 set p {}
2395                 set o disabled
2396         } else {
2397                 set p $current_diff_path
2398                 set s [mapdesc [lindex $file_states($p) 0] $p]
2399                 set f [mc "File:"]
2400                 set p [escape_path $p]
2401                 set o normal
2402         }
2403
2404         .vpane.lower.diff.header.status configure -text $s
2405         .vpane.lower.diff.header.file configure -text $f
2406         .vpane.lower.diff.header.path configure -text $p
2407         foreach w $diff_actions {
2408                 uplevel #0 $w $o
2409         }
2410 }
2411 trace add variable current_diff_path write trace_current_diff_path
2412
2413 frame .vpane.lower.diff.header -background gold
2414 label .vpane.lower.diff.header.status \
2415         -background gold \
2416         -width $max_status_desc \
2417         -anchor w \
2418         -justify left
2419 label .vpane.lower.diff.header.file \
2420         -background gold \
2421         -anchor w \
2422         -justify left
2423 label .vpane.lower.diff.header.path \
2424         -background gold \
2425         -anchor w \
2426         -justify left
2427 pack .vpane.lower.diff.header.status -side left
2428 pack .vpane.lower.diff.header.file -side left
2429 pack .vpane.lower.diff.header.path -fill x
2430 set ctxm .vpane.lower.diff.header.ctxm
2431 menu $ctxm -tearoff 0
2432 $ctxm add command \
2433         -label [mc Copy] \
2434         -command {
2435                 clipboard clear
2436                 clipboard append \
2437                         -format STRING \
2438                         -type STRING \
2439                         -- $current_diff_path
2440         }
2441 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2442 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2443
2444 # -- Diff Body
2445 #
2446 frame .vpane.lower.diff.body
2447 set ui_diff .vpane.lower.diff.body.t
2448 text $ui_diff -background white -borderwidth 0 \
2449         -width 80 -height 15 -wrap none \
2450         -font font_diff \
2451         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2452         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2453         -state disabled
2454 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2455         -command [list $ui_diff xview]
2456 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2457         -command [list $ui_diff yview]
2458 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2459 pack .vpane.lower.diff.body.sby -side right -fill y
2460 pack $ui_diff -side left -fill both -expand 1
2461 pack .vpane.lower.diff.header -side top -fill x
2462 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2463
2464 $ui_diff tag conf d_cr -elide true
2465 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2466 $ui_diff tag conf d_+ -foreground {#00a000}
2467 $ui_diff tag conf d_- -foreground red
2468
2469 $ui_diff tag conf d_++ -foreground {#00a000}
2470 $ui_diff tag conf d_-- -foreground red
2471 $ui_diff tag conf d_+s \
2472         -foreground {#00a000} \
2473         -background {#e2effa}
2474 $ui_diff tag conf d_-s \
2475         -foreground red \
2476         -background {#e2effa}
2477 $ui_diff tag conf d_s+ \
2478         -foreground {#00a000} \
2479         -background ivory1
2480 $ui_diff tag conf d_s- \
2481         -foreground red \
2482         -background ivory1
2483
2484 $ui_diff tag conf d<<<<<<< \
2485         -foreground orange \
2486         -font font_diffbold
2487 $ui_diff tag conf d======= \
2488         -foreground orange \
2489         -font font_diffbold
2490 $ui_diff tag conf d>>>>>>> \
2491         -foreground orange \
2492         -font font_diffbold
2493
2494 $ui_diff tag raise sel
2495
2496 # -- Diff Body Context Menu
2497 #
2498 set ctxm .vpane.lower.diff.body.ctxm
2499 menu $ctxm -tearoff 0
2500 $ctxm add command \
2501         -label [mc Refresh] \
2502         -command reshow_diff
2503 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2504 $ctxm add command \
2505         -label [mc Copy] \
2506         -command {tk_textCopy $ui_diff}
2507 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2508 $ctxm add command \
2509         -label [mc "Select All"] \
2510         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2511 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2512 $ctxm add command \
2513         -label [mc "Copy All"] \
2514         -command {
2515                 $ui_diff tag add sel 0.0 end
2516                 tk_textCopy $ui_diff
2517                 $ui_diff tag remove sel 0.0 end
2518         }
2519 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2520 $ctxm add separator
2521 $ctxm add command \
2522         -label [mc "Apply/Reverse Hunk"] \
2523         -command {apply_hunk $cursorX $cursorY}
2524 set ui_diff_applyhunk [$ctxm index last]
2525 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2526 $ctxm add separator
2527 $ctxm add command \
2528         -label [mc "Decrease Font Size"] \
2529         -command {incr_font_size font_diff -1}
2530 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2531 $ctxm add command \
2532         -label [mc "Increase Font Size"] \
2533         -command {incr_font_size font_diff 1}
2534 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2535 $ctxm add separator
2536 $ctxm add command \
2537         -label [mc "Show Less Context"] \
2538         -command {if {$repo_config(gui.diffcontext) >= 1} {
2539                 incr repo_config(gui.diffcontext) -1
2540                 reshow_diff
2541         }}
2542 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2543 $ctxm add command \
2544         -label [mc "Show More Context"] \
2545         -command {if {$repo_config(gui.diffcontext) < 99} {
2546                 incr repo_config(gui.diffcontext)
2547                 reshow_diff
2548         }}
2549 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2550 $ctxm add separator
2551 $ctxm add command -label [mc "Options..."] \
2552         -command do_options
2553 proc popup_diff_menu {ctxm x y X Y} {
2554         global current_diff_path file_states
2555         set ::cursorX $x
2556         set ::cursorY $y
2557         if {$::ui_index eq $::current_diff_side} {
2558                 set l [mc "Unstage Hunk From Commit"]
2559         } else {
2560                 set l [mc "Stage Hunk For Commit"]
2561         }
2562         if {$::is_3way_diff
2563                 || $current_diff_path eq {}
2564                 || ![info exists file_states($current_diff_path)]
2565                 || {_O} eq [lindex $file_states($current_diff_path) 0]} {
2566                 set s disabled
2567         } else {
2568                 set s normal
2569         }
2570         $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2571         tk_popup $ctxm $X $Y
2572 }
2573 bind_button3 $ui_diff [list popup_diff_menu $ctxm %x %y %X %Y]
2574
2575 # -- Status Bar
2576 #
2577 set main_status [::status_bar::new .status]
2578 pack .status -anchor w -side bottom -fill x
2579 $main_status show [mc "Initializing..."]
2580
2581 # -- Load geometry
2582 #
2583 catch {
2584 set gm $repo_config(gui.geometry)
2585 wm geometry . [lindex $gm 0]
2586 .vpane sash place 0 \
2587         [lindex [.vpane sash coord 0] 0] \
2588         [lindex $gm 1]
2589 .vpane.files sash place 0 \
2590         [lindex $gm 2] \
2591         [lindex [.vpane.files sash coord 0] 1]
2592 unset gm
2593 }
2594
2595 # -- Key Bindings
2596 #
2597 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2598 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2599 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2600 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2601 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2602 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2603 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2604 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2605 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2606 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2607 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2608
2609 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2610 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2611 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2612 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2613 bind $ui_diff <$M1B-Key-v> {break}
2614 bind $ui_diff <$M1B-Key-V> {break}
2615 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2616 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2617 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2618 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2619 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2620 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2621 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2622 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2623 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2624 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2625 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2626 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2627 bind $ui_diff <Button-1>   {focus %W}
2628
2629 if {[is_enabled branch]} {
2630         bind . <$M1B-Key-n> branch_create::dialog
2631         bind . <$M1B-Key-N> branch_create::dialog
2632         bind . <$M1B-Key-o> branch_checkout::dialog
2633         bind . <$M1B-Key-O> branch_checkout::dialog
2634         bind . <$M1B-Key-m> merge::dialog
2635         bind . <$M1B-Key-M> merge::dialog
2636 }
2637 if {[is_enabled transport]} {
2638         bind . <$M1B-Key-p> do_push_anywhere
2639         bind . <$M1B-Key-P> do_push_anywhere
2640 }
2641
2642 bind .   <Key-F5>     do_rescan
2643 bind .   <$M1B-Key-r> do_rescan
2644 bind .   <$M1B-Key-R> do_rescan
2645 bind .   <$M1B-Key-s> do_signoff
2646 bind .   <$M1B-Key-S> do_signoff
2647 bind .   <$M1B-Key-i> do_add_all
2648 bind .   <$M1B-Key-I> do_add_all
2649 bind .   <$M1B-Key-Return> do_commit
2650 foreach i [list $ui_index $ui_workdir] {
2651         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2652         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2653         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2654 }
2655 unset i
2656
2657 set file_lists($ui_index) [list]
2658 set file_lists($ui_workdir) [list]
2659
2660 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2661 focus -force $ui_comm
2662
2663 # -- Warn the user about environmental problems.  Cygwin's Tcl
2664 #    does *not* pass its env array onto any processes it spawns.
2665 #    This means that git processes get none of our environment.
2666 #
2667 if {[is_Cygwin]} {
2668         set ignored_env 0
2669         set suggest_user {}
2670         set msg [mc "Possible environment issues exist.
2671
2672 The following environment variables are probably
2673 going to be ignored by any Git subprocess run
2674 by %s:
2675
2676 " [appname]]
2677         foreach name [array names env] {
2678                 switch -regexp -- $name {
2679                 {^GIT_INDEX_FILE$} -
2680                 {^GIT_OBJECT_DIRECTORY$} -
2681                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2682                 {^GIT_DIFF_OPTS$} -
2683                 {^GIT_EXTERNAL_DIFF$} -
2684                 {^GIT_PAGER$} -
2685                 {^GIT_TRACE$} -
2686                 {^GIT_CONFIG$} -
2687                 {^GIT_CONFIG_LOCAL$} -
2688                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2689                         append msg " - $name\n"
2690                         incr ignored_env
2691                 }
2692                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2693                         append msg " - $name\n"
2694                         incr ignored_env
2695                         set suggest_user $name
2696                 }
2697                 }
2698         }
2699         if {$ignored_env > 0} {
2700                 append msg [mc "
2701 This is due to a known issue with the
2702 Tcl binary distributed by Cygwin."]
2703
2704                 if {$suggest_user ne {}} {
2705                         append msg [mc "
2706
2707 A good replacement for %s
2708 is placing values for the user.name and
2709 user.email settings into your personal
2710 ~/.gitconfig file.
2711 " $suggest_user]
2712                 }
2713                 warn_popup $msg
2714         }
2715         unset ignored_env msg suggest_user name
2716 }
2717
2718 # -- Only initialize complex UI if we are going to stay running.
2719 #
2720 if {[is_enabled transport]} {
2721         load_all_remotes
2722
2723         populate_fetch_menu
2724         populate_push_menu
2725 }
2726
2727 if {[winfo exists $ui_comm]} {
2728         set GITGUI_BCK_exists [load_message GITGUI_BCK]
2729
2730         # -- If both our backup and message files exist use the
2731         #    newer of the two files to initialize the buffer.
2732         #
2733         if {$GITGUI_BCK_exists} {
2734                 set m [gitdir GITGUI_MSG]
2735                 if {[file isfile $m]} {
2736                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
2737                                 catch {file delete [gitdir GITGUI_MSG]}
2738                         } else {
2739                                 $ui_comm delete 0.0 end
2740                                 $ui_comm edit reset
2741                                 $ui_comm edit modified false
2742                                 catch {file delete [gitdir GITGUI_BCK]}
2743                                 set GITGUI_BCK_exists 0
2744                         }
2745                 }
2746                 unset m
2747         }
2748
2749         proc backup_commit_buffer {} {
2750                 global ui_comm GITGUI_BCK_exists
2751
2752                 set m [$ui_comm edit modified]
2753                 if {$m || $GITGUI_BCK_exists} {
2754                         set msg [string trim [$ui_comm get 0.0 end]]
2755                         regsub -all -line {[ \r\t]+$} $msg {} msg
2756
2757                         if {$msg eq {}} {
2758                                 if {$GITGUI_BCK_exists} {
2759                                         catch {file delete [gitdir GITGUI_BCK]}
2760                                         set GITGUI_BCK_exists 0
2761                                 }
2762                         } elseif {$m} {
2763                                 catch {
2764                                         set fd [open [gitdir GITGUI_BCK] w]
2765                                         puts -nonewline $fd $msg
2766                                         close $fd
2767                                         set GITGUI_BCK_exists 1
2768                                 }
2769                         }
2770
2771                         $ui_comm edit modified false
2772                 }
2773
2774                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
2775         }
2776
2777         backup_commit_buffer
2778 }
2779
2780 lock_index begin-read
2781 if {![winfo ismapped .]} {
2782         wm deiconify .
2783 }
2784 after 1 do_rescan
2785 if {[is_enabled multicommit]} {
2786         after 1000 hint_gc
2787 }