git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527         reshow_diff
 528         uplevel #0 $after
 529 }
 530
 531 proc prune_selection {} {
 532         global file_states selected_paths
 533
 534         foreach path [array names selected_paths] {
 535                 if {[catch {set still_here $file_states($path)}]} {
 536                         unset selected_paths($path)
 537                 }
 538         }
 539 }
 540
 541 ######################################################################
 542 ##
 543 ## diff
 544
 545 proc clear_diff {} {
 546         global ui_diff current_diff ui_index ui_workdir
 547
 548         $ui_diff conf -state normal
 549         $ui_diff delete 0.0 end
 550         $ui_diff conf -state disabled
 551
 552         set current_diff {}
 553
 554         $ui_index tag remove in_diff 0.0 end
 555         $ui_workdir tag remove in_diff 0.0 end
 556 }
 557
 558 proc reshow_diff {} {
 559         global current_diff ui_status_value file_states
 560
 561         if {$current_diff eq {}
 562                 || [catch {set s $file_states($current_diff)}]} {
 563                 clear_diff
 564         } else {
 565                 show_diff $current_diff
 566         }
 567 }
 568
 569 proc handle_empty_diff {} {
 570         global current_diff file_states file_lists
 571
 572         set path $current_diff
 573         set s $file_states($path)
 574         if {[lindex $s 0] ne {_M}} return
 575
 576         info_popup "No differences detected.
 577
 578 [short_path $path] has no changes.
 579
 580 The modification date of this file was updated
 581 by another application and you currently have
 582 the Trust File Modification Timestamps option
 583 enabled, so Git did not automatically detect
 584 that there are no content differences in this
 585 file.
 586
 587 This file will now be removed from the modified
 588 files list, to prevent possible confusion.
 589 "
 590         if {[catch {exec git update-index -- $path} err]} {
 591                 error_popup "Failed to refresh index:\n\n$err"
 592         }
 593
 594         clear_diff
 595         display_file $path __
 596 }
 597
 598 proc show_diff {path {w {}} {lno {}}} {
 599         global file_states file_lists
 600         global is_3way_diff diff_active repo_config
 601         global ui_diff current_diff ui_status_value
 602
 603         if {$diff_active || ![lock_index read]} return
 604
 605         clear_diff
 606         if {$w eq {} || $lno == {}} {
 607                 foreach w [array names file_lists] {
 608                         set lno [lsearch -sorted $file_lists($w) $path]
 609                         if {$lno >= 0} {
 610                                 incr lno
 611                                 break
 612                         }
 613                 }
 614         }
 615         if {$w ne {} && $lno >= 1} {
 616                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 617         }
 618
 619         set s $file_states($path)
 620         set m [lindex $s 0]
 621         set is_3way_diff 0
 622         set diff_active 1
 623         set current_diff $path
 624         set ui_status_value "Loading diff of [escape_path $path]..."
 625
 626         set cmd [list | git diff-index]
 627         lappend cmd --no-color
 628         if {$repo_config(gui.diffcontext) > 0} {
 629                 lappend cmd "-U$repo_config(gui.diffcontext)"
 630         }
 631         lappend cmd -p
 632
 633         switch $m {
 634         MM {
 635                 lappend cmd -c
 636         }
 637         _O {
 638                 if {[catch {
 639                                 set fd [open $path r]
 640                                 set content [read $fd]
 641                                 close $fd
 642                         } err ]} {
 643                         set diff_active 0
 644                         unlock_index
 645                         set ui_status_value "Unable to display [escape_path $path]"
 646                         error_popup "Error loading file:\n\n$err"
 647                         return
 648                 }
 649                 $ui_diff conf -state normal
 650                 $ui_diff insert end $content
 651                 $ui_diff conf -state disabled
 652                 set diff_active 0
 653                 unlock_index
 654                 set ui_status_value {Ready.}
 655                 return
 656         }
 657         }
 658
 659         lappend cmd [PARENT]
 660         lappend cmd --
 661         lappend cmd $path
 662
 663         if {[catch {set fd [open $cmd r]} err]} {
 664                 set diff_active 0
 665                 unlock_index
 666                 set ui_status_value "Unable to display [escape_path $path]"
 667                 error_popup "Error loading diff:\n\n$err"
 668                 return
 669         }
 670
 671         fconfigure $fd -blocking 0 -translation auto
 672         fileevent $fd readable [list read_diff $fd]
 673 }
 674
 675 proc read_diff {fd} {
 676         global ui_diff ui_status_value is_3way_diff diff_active
 677         global repo_config
 678
 679         $ui_diff conf -state normal
 680         while {[gets $fd line] >= 0} {
 681                 # -- Cleanup uninteresting diff header lines.
 682                 #
 683                 if {[string match {diff --git *}      $line]} continue
 684                 if {[string match {diff --combined *} $line]} continue
 685                 if {[string match {--- *}             $line]} continue
 686                 if {[string match {+++ *}             $line]} continue
 687                 if {$line eq {deleted file mode 120000}} {
 688                         set line "deleted symlink"
 689                 }
 690
 691                 # -- Automatically detect if this is a 3 way diff.
 692                 #
 693                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 694
 695                 # -- Reformat a 3 way diff, 'cause its too weird.
 696                 #
 697                 if {$is_3way_diff} {
 698                         set op [string range $line 0 1]
 699                         switch -- $op {
 700                         {@@} {set tags d_@}
 701                         {++} {set tags d_+ ; set op { +}}
 702                         {--} {set tags d_- ; set op { -}}
 703                         { +} {set tags d_++; set op {++}}
 704                         { -} {set tags d_--; set op {--}}
 705                         {+ } {set tags d_-+; set op {-+}}
 706                         {- } {set tags d_+-; set op {+-}}
 707                         default {set tags {}}
 708                         }
 709                         set line [string replace $line 0 1 $op]
 710                 } else {
 711                         switch -- [string index $line 0] {
 712                         @ {set tags d_@}
 713                         + {set tags d_+}
 714                         - {set tags d_-}
 715                         default {set tags {}}
 716                         }
 717                 }
 718                 $ui_diff insert end $line $tags
 719                 $ui_diff insert end "\n" $tags
 720         }
 721         $ui_diff conf -state disabled
 722
 723         if {[eof $fd]} {
 724                 close $fd
 725                 set diff_active 0
 726                 unlock_index
 727                 set ui_status_value {Ready.}
 728
 729                 if {$repo_config(gui.trustmtime) eq {true}
 730                         && [$ui_diff index end] eq {2.0}} {
 731                         handle_empty_diff
 732                 }
 733         }
 734 }
 735
 736 ######################################################################
 737 ##
 738 ## commit
 739
 740 proc load_last_commit {} {
 741         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 742
 743         if {[llength $PARENT] == 0} {
 744                 error_popup {There is nothing to amend.
 745
 746 You are about to create the initial commit.
 747 There is no commit before this to amend.
 748 }
 749                 return
 750         }
 751
 752         repository_state curType curHEAD curMERGE_HEAD
 753         if {$curType eq {merge}} {
 754                 error_popup {Cannot amend while merging.
 755
 756 You are currently in the middle of a merge that
 757 has not been fully completed.  You cannot amend
 758 the prior commit unless you first abort the
 759 current merge activity.
 760 }
 761                 return
 762         }
 763
 764         set msg {}
 765         set parents [list]
 766         if {[catch {
 767                         set fd [open "| git cat-file commit $curHEAD" r]
 768                         while {[gets $fd line] > 0} {
 769                                 if {[string match {parent *} $line]} {
 770                                         lappend parents [string range $line 7 end]
 771                                 }
 772                         }
 773                         set msg [string trim [read $fd]]
 774                         close $fd
 775                 } err]} {
 776                 error_popup "Error loading commit data for amend:\n\n$err"
 777                 return
 778         }
 779
 780         set HEAD $curHEAD
 781         set PARENT $parents
 782         set MERGE_HEAD [list]
 783         switch -- [llength $parents] {
 784         0       {set commit_type amend-initial}
 785         1       {set commit_type amend}
 786         default {set commit_type amend-merge}
 787         }
 788
 789         $ui_comm delete 0.0 end
 790         $ui_comm insert end $msg
 791         $ui_comm edit reset
 792         $ui_comm edit modified false
 793         rescan {set ui_status_value {Ready.}}
 794 }
 795
 796 proc create_new_commit {} {
 797         global commit_type ui_comm
 798
 799         set commit_type normal
 800         $ui_comm delete 0.0 end
 801         $ui_comm edit reset
 802         $ui_comm edit modified false
 803         rescan {set ui_status_value {Ready.}}
 804 }
 805
 806 set GIT_COMMITTER_IDENT {}
 807
 808 proc committer_ident {} {
 809         global GIT_COMMITTER_IDENT
 810
 811         if {$GIT_COMMITTER_IDENT eq {}} {
 812                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 813                         error_popup "Unable to obtain your identity:\n\n$err"
 814                         return {}
 815                 }
 816                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 817                         $me me GIT_COMMITTER_IDENT]} {
 818                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 819                         return {}
 820                 }
 821         }
 822
 823         return $GIT_COMMITTER_IDENT
 824 }
 825
 826 proc commit_tree {} {
 827         global HEAD commit_type file_states ui_comm repo_config
 828         global ui_status_value pch_error
 829
 830         if {![lock_index update]} return
 831         if {[committer_ident] eq {}} return
 832
 833         # -- Our in memory state should match the repository.
 834         #
 835         repository_state curType curHEAD curMERGE_HEAD
 836         if {[string match amend* $commit_type]
 837                 && $curType eq {normal}
 838                 && $curHEAD eq $HEAD} {
 839         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 840                 info_popup {Last scanned state does not match repository state.
 841
 842 Another Git program has modified this repository
 843 since the last scan.  A rescan must be performed
 844 before another commit can be created.
 845
 846 The rescan will be automatically started now.
 847 }
 848                 unlock_index
 849                 rescan {set ui_status_value {Ready.}}
 850                 return
 851         }
 852
 853         # -- At least one file should differ in the index.
 854         #
 855         set files_ready 0
 856         foreach path [array names file_states] {
 857                 switch -glob -- [lindex $file_states($path) 0] {
 858                 _? {continue}
 859                 A? -
 860                 D? -
 861                 M? {set files_ready 1; break}
 862                 U? {
 863                         error_popup "Unmerged files cannot be committed.
 864
 865 File [short_path $path] has merge conflicts.
 866 You must resolve them and include the file before committing.
 867 "
 868                         unlock_index
 869                         return
 870                 }
 871                 default {
 872                         error_popup "Unknown file state [lindex $s 0] detected.
 873
 874 File [short_path $path] cannot be committed by this program.
 875 "
 876                 }
 877                 }
 878         }
 879         if {!$files_ready} {
 880                 error_popup {No included files to commit.
 881
 882 You must include at least 1 file before you can commit.
 883 }
 884                 unlock_index
 885                 return
 886         }
 887
 888         # -- A message is required.
 889         #
 890         set msg [string trim [$ui_comm get 1.0 end]]
 891         if {$msg eq {}} {
 892                 error_popup {Please supply a commit message.
 893
 894 A good commit message has the following format:
 895
 896 - First line: Describe in one sentance what you did.
 897 - Second line: Blank
 898 - Remaining lines: Describe why this change is good.
 899 }
 900                 unlock_index
 901                 return
 902         }
 903
 904         # -- Run the pre-commit hook.
 905         #
 906         set pchook [gitdir hooks pre-commit]
 907
 908         # On Cygwin [file executable] might lie so we need to ask
 909         # the shell if the hook is executable.  Yes that's annoying.
 910         #
 911         if {[is_Windows] && [file isfile $pchook]} {
 912                 set pchook [list sh -c [concat \
 913                         "if test -x \"$pchook\";" \
 914                         "then exec \"$pchook\" 2>&1;" \
 915                         "fi"]]
 916         } elseif {[file executable $pchook]} {
 917                 set pchook [list $pchook |& cat]
 918         } else {
 919                 commit_writetree $curHEAD $msg
 920                 return
 921         }
 922
 923         set ui_status_value {Calling pre-commit hook...}
 924         set pch_error {}
 925         set fd_ph [open "| $pchook" r]
 926         fconfigure $fd_ph -blocking 0 -translation binary
 927         fileevent $fd_ph readable \
 928                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 929 }
 930
 931 proc commit_prehook_wait {fd_ph curHEAD msg} {
 932         global pch_error ui_status_value
 933
 934         append pch_error [read $fd_ph]
 935         fconfigure $fd_ph -blocking 1
 936         if {[eof $fd_ph]} {
 937                 if {[catch {close $fd_ph}]} {
 938                         set ui_status_value {Commit declined by pre-commit hook.}
 939                         hook_failed_popup pre-commit $pch_error
 940                         unlock_index
 941                 } else {
 942                         commit_writetree $curHEAD $msg
 943                 }
 944                 set pch_error {}
 945                 return
 946         }
 947         fconfigure $fd_ph -blocking 0
 948 }
 949
 950 proc commit_writetree {curHEAD msg} {
 951         global ui_status_value
 952
 953         set ui_status_value {Committing changes...}
 954         set fd_wt [open "| git write-tree" r]
 955         fileevent $fd_wt readable \
 956                 [list commit_committree $fd_wt $curHEAD $msg]
 957 }
 958
 959 proc commit_committree {fd_wt curHEAD msg} {
 960         global HEAD PARENT MERGE_HEAD commit_type
 961         global single_commit
 962         global ui_status_value ui_comm selected_commit_type
 963         global file_states selected_paths rescan_active
 964
 965         gets $fd_wt tree_id
 966         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
 967                 error_popup "write-tree failed:\n\n$err"
 968                 set ui_status_value {Commit failed.}
 969                 unlock_index
 970                 return
 971         }
 972
 973         # -- Create the commit.
 974         #
 975         set cmd [list git commit-tree $tree_id]
 976         set parents [concat $PARENT $MERGE_HEAD]
 977         if {[llength $parents] > 0} {
 978                 foreach p $parents {
 979                         lappend cmd -p $p
 980                 }
 981         } else {
 982                 # git commit-tree writes to stderr during initial commit.
 983                 lappend cmd 2>/dev/null
 984         }
 985         lappend cmd << $msg
 986         if {[catch {set cmt_id [eval exec $cmd]} err]} {
 987                 error_popup "commit-tree failed:\n\n$err"
 988                 set ui_status_value {Commit failed.}
 989                 unlock_index
 990                 return
 991         }
 992
 993         # -- Update the HEAD ref.
 994         #
 995         set reflogm commit
 996         if {$commit_type ne {normal}} {
 997                 append reflogm " ($commit_type)"
 998         }
 999         set i [string first "\n" $msg]
1000         if {$i >= 0} {
1001                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1002         } else {
1003                 append reflogm {: } $msg
1004         }
1005         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1006         if {[catch {eval exec $cmd} err]} {
1007                 error_popup "update-ref failed:\n\n$err"
1008                 set ui_status_value {Commit failed.}
1009                 unlock_index
1010                 return
1011         }
1012
1013         # -- Cleanup after ourselves.
1014         #
1015         catch {file delete [gitdir MERGE_HEAD]}
1016         catch {file delete [gitdir MERGE_MSG]}
1017         catch {file delete [gitdir SQUASH_MSG]}
1018         catch {file delete [gitdir GITGUI_MSG]}
1019
1020         # -- Let rerere do its thing.
1021         #
1022         if {[file isdirectory [gitdir rr-cache]]} {
1023                 catch {exec git rerere}
1024         }
1025
1026         # -- Run the post-commit hook.
1027         #
1028         set pchook [gitdir hooks post-commit]
1029         if {[is_Windows] && [file isfile $pchook]} {
1030                 set pchook [list sh -c [concat \
1031                         "if test -x \"$pchook\";" \
1032                         "then exec \"$pchook\";" \
1033                         "fi"]]
1034         } elseif {![file executable $pchook]} {
1035                 set pchook {}
1036         }
1037         if {$pchook ne {}} {
1038                 catch {exec $pchook &}
1039         }
1040
1041         $ui_comm delete 0.0 end
1042         $ui_comm edit reset
1043         $ui_comm edit modified false
1044
1045         if {$single_commit} do_quit
1046
1047         # -- Update in memory status
1048         #
1049         set selected_commit_type new
1050         set commit_type normal
1051         set HEAD $cmt_id
1052         set PARENT $cmt_id
1053         set MERGE_HEAD [list]
1054
1055         foreach path [array names file_states] {
1056                 set s $file_states($path)
1057                 set m [lindex $s 0]
1058                 switch -glob -- $m {
1059                 _O -
1060                 _M -
1061                 _D {continue}
1062                 __ -
1063                 A_ -
1064                 M_ -
1065                 D_ {
1066                         unset file_states($path)
1067                         catch {unset selected_paths($path)}
1068                 }
1069                 DO {
1070                         set file_states($path) [list _O [lindex $s 1] {} {}]
1071                 }
1072                 AM -
1073                 AD -
1074                 MM -
1075                 MD {
1076                         set file_states($path) [list \
1077                                 _[string index $m 1] \
1078                                 [lindex $s 1] \
1079                                 [lindex $s 3] \
1080                                 {}]
1081                 }
1082                 }
1083         }
1084
1085         display_all_files
1086         unlock_index
1087         reshow_diff
1088         set ui_status_value \
1089                 "Changes committed as [string range $cmt_id 0 7]."
1090 }
1091
1092 ######################################################################
1093 ##
1094 ## fetch pull push
1095
1096 proc fetch_from {remote} {
1097         set w [new_console "fetch $remote" \
1098                 "Fetching new changes from $remote"]
1099         set cmd [list git fetch]
1100         lappend cmd $remote
1101         console_exec $w $cmd
1102 }
1103
1104 proc pull_remote {remote branch} {
1105         global HEAD commit_type file_states repo_config
1106
1107         if {![lock_index update]} return
1108
1109         # -- Our in memory state should match the repository.
1110         #
1111         repository_state curType curHEAD curMERGE_HEAD
1112         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1113                 info_popup {Last scanned state does not match repository state.
1114
1115 Another Git program has modified this repository
1116 since the last scan.  A rescan must be performed
1117 before a pull operation can be started.
1118
1119 The rescan will be automatically started now.
1120 }
1121                 unlock_index
1122                 rescan {set ui_status_value {Ready.}}
1123                 return
1124         }
1125
1126         # -- No differences should exist before a pull.
1127         #
1128         if {[array size file_states] != 0} {
1129                 error_popup {Uncommitted but modified files are present.
1130
1131 You should not perform a pull with unmodified
1132 files in your working directory as Git will be
1133 unable to recover from an incorrect merge.
1134
1135 You should commit or revert all changes before
1136 starting a pull operation.
1137 }
1138                 unlock_index
1139                 return
1140         }
1141
1142         set w [new_console "pull $remote $branch" \
1143                 "Pulling new changes from branch $branch in $remote"]
1144         set cmd [list git pull]
1145         if {$repo_config(gui.pullsummary) eq {false}} {
1146                 lappend cmd --no-summary
1147         }
1148         lappend cmd $remote
1149         lappend cmd $branch
1150         console_exec $w $cmd [list post_pull_remote $remote $branch]
1151 }
1152
1153 proc post_pull_remote {remote branch success} {
1154         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1155         global ui_status_value
1156
1157         unlock_index
1158         if {$success} {
1159                 repository_state commit_type HEAD MERGE_HEAD
1160                 set PARENT $HEAD
1161                 set selected_commit_type new
1162                 set ui_status_value "Pulling $branch from $remote complete."
1163         } else {
1164                 rescan [list set ui_status_value \
1165                         "Conflicts detected while pulling $branch from $remote."]
1166         }
1167 }
1168
1169 proc push_to {remote} {
1170         set w [new_console "push $remote" \
1171                 "Pushing changes to $remote"]
1172         set cmd [list git push]
1173         lappend cmd $remote
1174         console_exec $w $cmd
1175 }
1176
1177 ######################################################################
1178 ##
1179 ## ui helpers
1180
1181 proc mapicon {w state path} {
1182         global all_icons
1183
1184         if {[catch {set r $all_icons($state$w)}]} {
1185                 puts "error: no icon for $w state={$state} $path"
1186                 return file_plain
1187         }
1188         return $r
1189 }
1190
1191 proc mapdesc {state path} {
1192         global all_descs
1193
1194         if {[catch {set r $all_descs($state)}]} {
1195                 puts "error: no desc for state={$state} $path"
1196                 return $state
1197         }
1198         return $r
1199 }
1200
1201 proc escape_path {path} {
1202         regsub -all "\n" $path "\\n" path
1203         return $path
1204 }
1205
1206 proc short_path {path} {
1207         return [escape_path [lindex [file split $path] end]]
1208 }
1209
1210 set next_icon_id 0
1211 set null_sha1 [string repeat 0 40]
1212
1213 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1214         global file_states next_icon_id null_sha1
1215
1216         set s0 [string index $new_state 0]
1217         set s1 [string index $new_state 1]
1218
1219         if {[catch {set info $file_states($path)}]} {
1220                 set state __
1221                 set icon n[incr next_icon_id]
1222         } else {
1223                 set state [lindex $info 0]
1224                 set icon [lindex $info 1]
1225                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1226                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1227         }
1228
1229         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1230         elseif {$s0 eq {_}} {set s0 _}
1231
1232         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1233         elseif {$s1 eq {_}} {set s1 _}
1234
1235         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1236                 set head_info [list 0 $null_sha1]
1237         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1238                 && $head_info eq {}} {
1239                 set head_info $index_info
1240         }
1241
1242         set file_states($path) [list $s0$s1 $icon \
1243                 $head_info $index_info \
1244                 ]
1245         return $state
1246 }
1247
1248 proc display_file_helper {w path icon_name old_m new_m} {
1249         global file_lists
1250
1251         if {$new_m eq {_}} {
1252                 set lno [lsearch -sorted $file_lists($w) $path]
1253                 if {$lno >= 0} {
1254                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1255                         incr lno
1256                         $w conf -state normal
1257                         $w delete $lno.0 [expr {$lno + 1}].0
1258                         $w conf -state disabled
1259                 }
1260         } elseif {$old_m eq {_} && $new_m ne {_}} {
1261                 lappend file_lists($w) $path
1262                 set file_lists($w) [lsort -unique $file_lists($w)]
1263                 set lno [lsearch -sorted $file_lists($w) $path]
1264                 incr lno
1265                 $w conf -state normal
1266                 $w image create $lno.0 \
1267                         -align center -padx 5 -pady 1 \
1268                         -name $icon_name \
1269                         -image [mapicon $w $new_m $path]
1270                 $w insert $lno.1 "[escape_path $path]\n"
1271                 $w conf -state disabled
1272         } elseif {$old_m ne $new_m} {
1273                 $w conf -state normal
1274                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1275                 $w conf -state disabled
1276         }
1277 }
1278
1279 proc display_file {path state} {
1280         global file_states selected_paths
1281         global ui_index ui_workdir
1282
1283         set old_m [merge_state $path $state]
1284         set s $file_states($path)
1285         set new_m [lindex $s 0]
1286         set icon_name [lindex $s 1]
1287
1288         display_file_helper     $ui_index $path $icon_name \
1289                 [string index $old_m 0] \
1290                 [string index $new_m 0]
1291         display_file_helper     $ui_workdir $path $icon_name \
1292                 [string index $old_m 1] \
1293                 [string index $new_m 1]
1294
1295         if {$new_m eq {__}} {
1296                 unset file_states($path)
1297                 catch {unset selected_paths($path)}
1298         }
1299 }
1300
1301 proc display_all_files_helper {w path icon_name m} {
1302         global file_lists
1303
1304         lappend file_lists($w) $path
1305         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1306         $w image create end \
1307                 -align center -padx 5 -pady 1 \
1308                 -name $icon_name \
1309                 -image [mapicon $w $m $path]
1310         $w insert end "[escape_path $path]\n"
1311 }
1312
1313 proc display_all_files {} {
1314         global ui_index ui_workdir
1315         global file_states file_lists
1316         global last_clicked
1317
1318         $ui_index conf -state normal
1319         $ui_workdir conf -state normal
1320
1321         $ui_index delete 0.0 end
1322         $ui_workdir delete 0.0 end
1323         set last_clicked {}
1324
1325         set file_lists($ui_index) [list]
1326         set file_lists($ui_workdir) [list]
1327
1328         foreach path [lsort [array names file_states]] {
1329                 set s $file_states($path)
1330                 set m [lindex $s 0]
1331                 set icon_name [lindex $s 1]
1332
1333                 if {[string index $m 0] ne {_}} {
1334                         display_all_files_helper $ui_index $path \
1335                                 $icon_name [string index $m 0]
1336                 }
1337                 if {[string index $m 1] ne {_}} {
1338                         display_all_files_helper $ui_workdir $path \
1339                                 $icon_name [string index $m 1]
1340                 }
1341         }
1342
1343         $ui_index conf -state disabled
1344         $ui_workdir conf -state disabled
1345 }
1346
1347 proc update_indexinfo {msg pathList after} {
1348         global update_index_cp ui_status_value
1349
1350         if {![lock_index update]} return
1351
1352         set update_index_cp 0
1353         set pathList [lsort $pathList]
1354         set totalCnt [llength $pathList]
1355         set batch [expr {int($totalCnt * .01) + 1}]
1356         if {$batch > 25} {set batch 25}
1357
1358         set ui_status_value [format \
1359                 "$msg... %i/%i files (%.2f%%)" \
1360                 $update_index_cp \
1361                 $totalCnt \
1362                 0.0]
1363         set fd [open "| git update-index -z --index-info" w]
1364         fconfigure $fd \
1365                 -blocking 0 \
1366                 -buffering full \
1367                 -buffersize 512 \
1368                 -translation binary
1369         fileevent $fd writable [list \
1370                 write_update_indexinfo \
1371                 $fd \
1372                 $pathList \
1373                 $totalCnt \
1374                 $batch \
1375                 $msg \
1376                 $after \
1377                 ]
1378 }
1379
1380 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1381         global update_index_cp ui_status_value
1382         global file_states current_diff
1383
1384         if {$update_index_cp >= $totalCnt} {
1385                 close $fd
1386                 unlock_index
1387                 uplevel #0 $after
1388                 return
1389         }
1390
1391         for {set i $batch} \
1392                 {$update_index_cp < $totalCnt && $i > 0} \
1393                 {incr i -1} {
1394                 set path [lindex $pathList $update_index_cp]
1395                 incr update_index_cp
1396
1397                 set s $file_states($path)
1398                 switch -glob -- [lindex $s 0] {
1399                 A? {set new _O}
1400                 M? {set new _M}
1401                 D_ {set new _D}
1402                 D? {set new _?}
1403                 ?? {continue}
1404                 }
1405                 set info [lindex $s 2]
1406                 if {$info eq {}} continue
1407
1408                 puts -nonewline $fd "$info\t$path\0"
1409                 display_file $path $new
1410         }
1411
1412         set ui_status_value [format \
1413                 "$msg... %i/%i files (%.2f%%)" \
1414                 $update_index_cp \
1415                 $totalCnt \
1416                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1417 }
1418
1419 proc update_index {msg pathList after} {
1420         global update_index_cp ui_status_value
1421
1422         if {![lock_index update]} return
1423
1424         set update_index_cp 0
1425         set pathList [lsort $pathList]
1426         set totalCnt [llength $pathList]
1427         set batch [expr {int($totalCnt * .01) + 1}]
1428         if {$batch > 25} {set batch 25}
1429
1430         set ui_status_value [format \
1431                 "$msg... %i/%i files (%.2f%%)" \
1432                 $update_index_cp \
1433                 $totalCnt \
1434                 0.0]
1435         set fd [open "| git update-index --add --remove -z --stdin" w]
1436         fconfigure $fd \
1437                 -blocking 0 \
1438                 -buffering full \
1439                 -buffersize 512 \
1440                 -translation binary
1441         fileevent $fd writable [list \
1442                 write_update_index \
1443                 $fd \
1444                 $pathList \
1445                 $totalCnt \
1446                 $batch \
1447                 $msg \
1448                 $after \
1449                 ]
1450 }
1451
1452 proc write_update_index {fd pathList totalCnt batch msg after} {
1453         global update_index_cp ui_status_value
1454         global file_states current_diff
1455
1456         if {$update_index_cp >= $totalCnt} {
1457                 close $fd
1458                 unlock_index
1459                 uplevel #0 $after
1460                 return
1461         }
1462
1463         for {set i $batch} \
1464                 {$update_index_cp < $totalCnt && $i > 0} \
1465                 {incr i -1} {
1466                 set path [lindex $pathList $update_index_cp]
1467                 incr update_index_cp
1468
1469                 switch -glob -- [lindex $file_states($path) 0] {
1470                 AD {set new __}
1471                 ?D {set new D_}
1472                 _O -
1473                 AM {set new A_}
1474                 U_ -
1475                 ?M {set new M_}
1476                 ?? {continue}
1477                 }
1478                 puts -nonewline $fd "$path\0"
1479                 display_file $path $new
1480         }
1481
1482         set ui_status_value [format \
1483                 "$msg... %i/%i files (%.2f%%)" \
1484                 $update_index_cp \
1485                 $totalCnt \
1486                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1487 }
1488
1489 proc checkout_index {msg pathList after} {
1490         global update_index_cp ui_status_value
1491
1492         if {![lock_index update]} return
1493
1494         set update_index_cp 0
1495         set pathList [lsort $pathList]
1496         set totalCnt [llength $pathList]
1497         set batch [expr {int($totalCnt * .01) + 1}]
1498         if {$batch > 25} {set batch 25}
1499
1500         set ui_status_value [format \
1501                 "$msg... %i/%i files (%.2f%%)" \
1502                 $update_index_cp \
1503                 $totalCnt \
1504                 0.0]
1505         set cmd [list git checkout-index]
1506         lappend cmd --index
1507         lappend cmd --quiet
1508         lappend cmd --force
1509         lappend cmd -z
1510         lappend cmd --stdin
1511         set fd [open "| $cmd " w]
1512         fconfigure $fd \
1513                 -blocking 0 \
1514                 -buffering full \
1515                 -buffersize 512 \
1516                 -translation binary
1517         fileevent $fd writable [list \
1518                 write_checkout_index \
1519                 $fd \
1520                 $pathList \
1521                 $totalCnt \
1522                 $batch \
1523                 $msg \
1524                 $after \
1525                 ]
1526 }
1527
1528 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1529         global update_index_cp ui_status_value
1530         global file_states current_diff
1531
1532         if {$update_index_cp >= $totalCnt} {
1533                 close $fd
1534                 unlock_index
1535                 uplevel #0 $after
1536                 return
1537         }
1538
1539         for {set i $batch} \
1540                 {$update_index_cp < $totalCnt && $i > 0} \
1541                 {incr i -1} {
1542                 set path [lindex $pathList $update_index_cp]
1543                 incr update_index_cp
1544                 switch -glob -- [lindex $file_states($path) 0] {
1545                 U? {continue}
1546                 ?M -
1547                 ?D {
1548                         puts -nonewline $fd "$path\0"
1549                         display_file $path ?_
1550                 }
1551                 }
1552         }
1553
1554         set ui_status_value [format \
1555                 "$msg... %i/%i files (%.2f%%)" \
1556                 $update_index_cp \
1557                 $totalCnt \
1558                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1559 }
1560
1561 ######################################################################
1562 ##
1563 ## branch management
1564
1565 proc load_all_heads {} {
1566         global all_heads tracking_branches
1567
1568         set all_heads [list]
1569         set cmd [list git for-each-ref]
1570         lappend cmd --format=%(refname)
1571         lappend cmd refs/heads
1572         set fd [open "| $cmd" r]
1573         while {[gets $fd line] > 0} {
1574                 if {![catch {set info $tracking_branches($line)}]} continue
1575                 if {![regsub ^refs/heads/ $line {} name]} continue
1576                 lappend all_heads $name
1577         }
1578         close $fd
1579
1580         set all_heads [lsort $all_heads]
1581 }
1582
1583 proc populate_branch_menu {} {
1584         global all_heads disable_on_lock
1585
1586         set m .mbar.branch
1587         set last [$m index last]
1588         for {set i 0} {$i <= $last} {incr i} {
1589                 if {[$m type $i] eq {separator}} {
1590                         $m delete $i last
1591                         set new_dol [list]
1592                         foreach a $disable_on_lock {
1593                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1594                                         lappend new_dol $a
1595                                 }
1596                         }
1597                         set disable_on_lock $new_dol
1598                         break
1599                 }
1600         }
1601
1602         $m add separator
1603         foreach b $all_heads {
1604                 $m add radiobutton \
1605                         -label $b \
1606                         -command [list switch_branch $b] \
1607                         -variable current_branch \
1608                         -value $b \
1609                         -font font_ui
1610                 lappend disable_on_lock \
1611                         [list $m entryconf [$m index last] -state]
1612         }
1613 }
1614
1615 proc do_create_branch_action {w} {
1616         global all_heads null_sha1
1617         global create_branch_checkout create_branch_revtype
1618         global create_branch_head create_branch_trackinghead
1619
1620         set newbranch [string trim [$w.name.t get 0.0 end]]
1621         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1622                 tk_messageBox \
1623                         -icon error \
1624                         -type ok \
1625                         -title [wm title $w] \
1626                         -parent $w \
1627                         -message "Branch '$newbranch' already exists."
1628                 focus $w.name.t
1629                 return
1630         }
1631         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1632                 tk_messageBox \
1633                         -icon error \
1634                         -type ok \
1635                         -title [wm title $w] \
1636                         -parent $w \
1637                         -message "We do not like '$newbranch' as a branch name."
1638                 focus $w.name.t
1639                 return
1640         }
1641
1642         set rev {}
1643         switch -- $create_branch_revtype {
1644         head {set rev $create_branch_head}
1645         tracking {set rev $create_branch_trackinghead}
1646         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1647         }
1648         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1649                 tk_messageBox \
1650                         -icon error \
1651                         -type ok \
1652                         -title [wm title $w] \
1653                         -parent $w \
1654                         -message "Invalid starting revision: $rev"
1655                 return
1656         }
1657         set cmd [list git update-ref]
1658         lappend cmd -m
1659         lappend cmd "branch: Created from $rev"
1660         lappend cmd "refs/heads/$newbranch"
1661         lappend cmd $cmt
1662         lappend cmd $null_sha1
1663         if {[catch {eval exec $cmd} err]} {
1664                 tk_messageBox \
1665                         -icon error \
1666                         -type ok \
1667                         -title [wm title $w] \
1668                         -parent $w \
1669                         -message "Failed to create '$newbranch'.\n\n$err"
1670                 return
1671         }
1672
1673         lappend all_heads $newbranch
1674         set all_heads [lsort $all_heads]
1675         populate_branch_menu
1676         destroy $w
1677 }
1678
1679 proc do_create_branch {} {
1680         global all_heads current_branch tracking_branches
1681         global create_branch_checkout create_branch_revtype
1682         global create_branch_head create_branch_trackinghead
1683
1684         set create_branch_checkout true
1685         set create_branch_revtype head
1686         set create_branch_head $current_branch
1687         set create_branch_trackinghead {}
1688
1689         set w .branch_editor
1690         toplevel $w
1691         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1692
1693         label $w.header -text {Create New Branch} \
1694                 -font font_uibold
1695         pack $w.header -side top -fill x
1696
1697         frame $w.buttons
1698         button $w.buttons.create -text Create \
1699                 -font font_ui \
1700                 -default active \
1701                 -command [list do_create_branch_action $w]
1702         pack $w.buttons.create -side right
1703         button $w.buttons.cancel -text {Cancel} \
1704                 -font font_ui \
1705                 -command [list destroy $w]
1706         pack $w.buttons.cancel -side right -padx 5
1707         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1708
1709         labelframe $w.name \
1710                 -text {Branch Description} \
1711                 -font font_ui
1712         label $w.name.l -text {Name:} -font font_ui
1713         text $w.name.t \
1714                 -borderwidth 1 \
1715                 -relief sunken \
1716                 -height 1 \
1717                 -width 40 \
1718                 -font font_ui
1719         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1720         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1721         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1722         bind $w.name.t <Key> {
1723                 if {{%K} ne {BackSpace}
1724                         && {%K} ne {Tab}
1725                         && {%K} ne {Escape}
1726                         && {%K} ne {Return}} {
1727                         if {%k <= 32} break
1728                         if {[string first %A {~^:?*[}] >= 0} break
1729                 }
1730         }
1731         pack $w.name.l -side left -padx 5
1732         pack $w.name.t -side left -fill x -expand 1
1733         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1734
1735         set all_trackings [list]
1736         foreach b [array names tracking_branches] {
1737                 regsub ^refs/(heads|remotes)/ $b {} b
1738                 lappend all_trackings $b
1739         }
1740         set all_trackings [lsort -unique $all_trackings]
1741         if {$all_trackings ne {}} {
1742                 set create_branch_trackinghead [lindex $all_trackings 0]
1743         }
1744
1745         labelframe $w.from \
1746                 -text {Starting Revision} \
1747                 -font font_ui
1748         frame $w.from.head
1749         radiobutton $w.from.head.r \
1750                 -text {Local Branch:} \
1751                 -value head \
1752                 -variable create_branch_revtype \
1753                 -font font_ui
1754         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1755         pack $w.from.head.r -side left
1756         pack $w.from.head.m -side left
1757         frame $w.from.tracking
1758         radiobutton $w.from.tracking.r \
1759                 -text {Tracking Branch:} \
1760                 -value tracking \
1761                 -variable create_branch_revtype \
1762                 -font font_ui
1763         eval tk_optionMenu $w.from.tracking.m \
1764                 create_branch_trackinghead \
1765                 $all_trackings
1766         pack $w.from.tracking.r -side left
1767         pack $w.from.tracking.m -side left
1768         frame $w.from.exp
1769         radiobutton $w.from.exp.r \
1770                 -text {Revision Expression:} \
1771                 -value expression \
1772                 -variable create_branch_revtype \
1773                 -font font_ui
1774         text $w.from.exp.t \
1775                 -borderwidth 1 \
1776                 -relief sunken \
1777                 -height 1 \
1778                 -width 50 \
1779                 -font font_ui
1780         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1781         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1782         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1783         pack $w.from.exp.r -side left
1784         pack $w.from.exp.t -side left -fill x -expand 1
1785         pack $w.from.head -padx 5 -fill x -expand 1
1786         pack $w.from.tracking -padx 5 -fill x -expand 1
1787         pack $w.from.exp -padx 5 -fill x -expand 1
1788         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1789
1790         labelframe $w.postActions \
1791                 -text {Post Creation Actions} \
1792                 -font font_ui
1793         checkbutton $w.postActions.checkout \
1794                 -text {Checkout after creation} \
1795                 -offvalue false \
1796                 -onvalue true \
1797                 -variable create_branch_checkout \
1798                 -font font_ui
1799         pack $w.postActions.checkout -anchor nw
1800         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1801
1802         bind $w <Visibility> "grab $w; focus $w.name.t"
1803         bind $w <Key-Escape> "destroy $w"
1804         bind $w <Key-Return> "do_create_branch_action $w;break"
1805         wm title $w "[appname] ([reponame]): Create Branch"
1806         tkwait window $w
1807 }
1808
1809 proc do_delete_branch_action {w} {
1810         global all_heads
1811         global delete_branch_checkhead delete_branch_head
1812
1813         set to_delete [list]
1814         set not_merged [list]
1815         foreach i [$w.list.l curselection] {
1816                 set b [$w.list.l get $i]
1817                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1818                 if {$delete_branch_checkhead} {
1819                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1820                         if {$o ne $m} {
1821                                 lappend not_merged $b
1822                                 continue
1823                         }
1824                 }
1825                 lappend to_delete [list $b $o]
1826         }
1827         if {$not_merged ne {}} {
1828                 set msg "The following branches are not completely merged into $delete_branch_head:
1829
1830  - [join $not_merged "\n - "]"
1831                 tk_messageBox \
1832                         -icon info \
1833                         -type ok \
1834                         -title [wm title $w] \
1835                         -parent $w \
1836                         -message $msg
1837         }
1838         if {$to_delete eq {}} return
1839         if {!$delete_branch_checkhead} {
1840                 set msg {Recovering deleted branches is difficult.
1841
1842 Delete the selected branches?}
1843                 if {[tk_messageBox \
1844                         -icon warning \
1845                         -type yesno \
1846                         -title [wm title $w] \
1847                         -parent $w \
1848                         -message $msg] ne yes} {
1849                         return
1850                 }
1851         }
1852
1853         set failed {}
1854         foreach i $to_delete {
1855                 set b [lindex $i 0]
1856                 set o [lindex $i 1]
1857                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1858                         append failed " - $b: $err\n"
1859                 } else {
1860                         set x [lsearch -sorted $all_heads $b]
1861                         if {$x >= 0} {
1862                                 set all_heads [lreplace $all_heads $x $x]
1863                         }
1864                 }
1865         }
1866
1867         if {$failed ne {}} {
1868                 tk_messageBox \
1869                         -icon error \
1870                         -type ok \
1871                         -title [wm title $w] \
1872                         -parent $w \
1873                         -message "Failed to delete branches:\n$failed"
1874         }
1875
1876         set all_heads [lsort $all_heads]
1877         populate_branch_menu
1878         destroy $w
1879 }
1880
1881 proc do_delete_branch {} {
1882         global all_heads tracking_branches current_branch
1883         global delete_branch_checkhead delete_branch_head
1884
1885         set delete_branch_checkhead 1
1886         set delete_branch_head $current_branch
1887
1888         set w .branch_editor
1889         toplevel $w
1890         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1891
1892         label $w.header -text {Delete Local Branch} \
1893                 -font font_uibold
1894         pack $w.header -side top -fill x
1895
1896         frame $w.buttons
1897         button $w.buttons.create -text Delete \
1898                 -font font_ui \
1899                 -command [list do_delete_branch_action $w]
1900         pack $w.buttons.create -side right
1901         button $w.buttons.cancel -text {Cancel} \
1902                 -font font_ui \
1903                 -command [list destroy $w]
1904         pack $w.buttons.cancel -side right -padx 5
1905         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1906
1907         labelframe $w.list \
1908                 -text {Local Branches} \
1909                 -font font_ui
1910         listbox $w.list.l \
1911                 -height 10 \
1912                 -width 50 \
1913                 -selectmode extended \
1914                 -font font_ui
1915         foreach h $all_heads {
1916                 if {$h ne $current_branch} {
1917                         $w.list.l insert end $h
1918                 }
1919         }
1920         pack $w.list.l -fill both -pady 5 -padx 5
1921         pack $w.list -fill both -pady 5 -padx 5
1922
1923         set all_trackings [list]
1924         foreach b [array names tracking_branches] {
1925                 regsub ^refs/(heads|remotes)/ $b {} b
1926                 lappend all_trackings $b
1927         }
1928
1929         labelframe $w.validate \
1930                 -text {Only Delete If} \
1931                 -font font_ui
1932         frame $w.validate.head
1933         checkbutton $w.validate.head.r \
1934                 -text {Already Merged Into:} \
1935                 -variable delete_branch_checkhead \
1936                 -font font_ui
1937         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1938                 $all_heads \
1939                 [lsort -unique $all_trackings]
1940         pack $w.validate.head.r -side left
1941         pack $w.validate.head.m -side left
1942         pack $w.validate.head -padx 5 -fill x -expand 1
1943         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1944
1945         bind $w <Visibility> "grab $w; focus $w"
1946         bind $w <Key-Escape> "destroy $w"
1947         wm title $w "[appname] ([reponame]): Delete Branch"
1948         tkwait window $w
1949 }
1950
1951 proc switch_branch {b} {
1952         global HEAD commit_type file_states current_branch
1953         global selected_commit_type ui_comm
1954
1955         if {![lock_index switch]} return
1956
1957         # -- Backup the selected branch (repository_state resets it)
1958         #
1959         set new_branch $current_branch
1960
1961         # -- Our in memory state should match the repository.
1962         #
1963         repository_state curType curHEAD curMERGE_HEAD
1964         if {[string match amend* $commit_type]
1965                 && $curType eq {normal}
1966                 && $curHEAD eq $HEAD} {
1967         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
1968                 info_popup {Last scanned state does not match repository state.
1969
1970 Another Git program has modified this repository
1971 since the last scan.  A rescan must be performed
1972 before the current branch can be changed.
1973
1974 The rescan will be automatically started now.
1975 }
1976                 unlock_index
1977                 rescan {set ui_status_value {Ready.}}
1978                 return
1979         }
1980
1981         # -- Toss the message buffer if we are in amend mode.
1982         #
1983         if {[string match amend* $curType]} {
1984                 $ui_comm delete 0.0 end
1985                 $ui_comm edit reset
1986                 $ui_comm edit modified false
1987         }
1988
1989         set selected_commit_type new
1990         set current_branch $new_branch
1991
1992         unlock_index
1993         error "NOT FINISHED"
1994 }
1995
1996 ######################################################################
1997 ##
1998 ## remote management
1999
2000 proc load_all_remotes {} {
2001         global repo_config
2002         global all_remotes tracking_branches
2003
2004         set all_remotes [list]
2005         array unset tracking_branches
2006
2007         set rm_dir [gitdir remotes]
2008         if {[file isdirectory $rm_dir]} {
2009                 set all_remotes [glob \
2010                         -types f \
2011                         -tails \
2012                         -nocomplain \
2013                         -directory $rm_dir *]
2014
2015                 foreach name $all_remotes {
2016                         catch {
2017                                 set fd [open [file join $rm_dir $name] r]
2018                                 while {[gets $fd line] >= 0} {
2019                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2020                                                 $line line src dst]} continue
2021                                         if {![regexp ^refs/ $dst]} {
2022                                                 set dst "refs/heads/$dst"
2023                                         }
2024                                         set tracking_branches($dst) [list $name $src]
2025                                 }
2026                                 close $fd
2027                         }
2028                 }
2029         }
2030
2031         foreach line [array names repo_config remote.*.url] {
2032                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2033                 lappend all_remotes $name
2034
2035                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2036                         set fl {}
2037                 }
2038                 foreach line $fl {
2039                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2040                         if {![regexp ^refs/ $dst]} {
2041                                 set dst "refs/heads/$dst"
2042                         }
2043                         set tracking_branches($dst) [list $name $src]
2044                 }
2045         }
2046
2047         set all_remotes [lsort -unique $all_remotes]
2048 }
2049
2050 proc populate_fetch_menu {m} {
2051         global all_remotes repo_config
2052
2053         foreach r $all_remotes {
2054                 set enable 0
2055                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2056                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2057                                 set enable 1
2058                         }
2059                 } else {
2060                         catch {
2061                                 set fd [open [gitdir remotes $r] r]
2062                                 while {[gets $fd n] >= 0} {
2063                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2064                                                 set enable 1
2065                                                 break
2066                                         }
2067                                 }
2068                                 close $fd
2069                         }
2070                 }
2071
2072                 if {$enable} {
2073                         $m add command \
2074                                 -label "Fetch from $r..." \
2075                                 -command [list fetch_from $r] \
2076                                 -font font_ui
2077                 }
2078         }
2079 }
2080
2081 proc populate_push_menu {m} {
2082         global all_remotes repo_config
2083
2084         foreach r $all_remotes {
2085                 set enable 0
2086                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2087                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2088                                 set enable 1
2089                         }
2090                 } else {
2091                         catch {
2092                                 set fd [open [gitdir remotes $r] r]
2093                                 while {[gets $fd n] >= 0} {
2094                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2095                                                 set enable 1
2096                                                 break
2097                                         }
2098                                 }
2099                                 close $fd
2100                         }
2101                 }
2102
2103                 if {$enable} {
2104                         $m add command \
2105                                 -label "Push to $r..." \
2106                                 -command [list push_to $r] \
2107                                 -font font_ui
2108                 }
2109         }
2110 }
2111
2112 proc populate_pull_menu {m} {
2113         global repo_config all_remotes disable_on_lock
2114
2115         foreach remote $all_remotes {
2116                 set rb_list [list]
2117                 if {[array get repo_config remote.$remote.url] ne {}} {
2118                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2119                                 foreach line $repo_config(remote.$remote.fetch) {
2120                                         if {[regexp {^([^:]+):} $line line rb]} {
2121                                                 lappend rb_list $rb
2122                                         }
2123                                 }
2124                         }
2125                 } else {
2126                         catch {
2127                                 set fd [open [gitdir remotes $remote] r]
2128                                 while {[gets $fd line] >= 0} {
2129                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2130                                                 lappend rb_list $rb
2131                                         }
2132                                 }
2133                                 close $fd
2134                         }
2135                 }
2136
2137                 foreach rb $rb_list {
2138                         regsub ^refs/heads/ $rb {} rb_short
2139                         $m add command \
2140                                 -label "Branch $rb_short from $remote..." \
2141                                 -command [list pull_remote $remote $rb] \
2142                                 -font font_ui
2143                         lappend disable_on_lock \
2144                                 [list $m entryconf [$m index last] -state]
2145                 }
2146         }
2147 }
2148
2149 ######################################################################
2150 ##
2151 ## icons
2152
2153 set filemask {
2154 #define mask_width 14
2155 #define mask_height 15
2156 static unsigned char mask_bits[] = {
2157    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2158    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2159    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2160 }
2161
2162 image create bitmap file_plain -background white -foreground black -data {
2163 #define plain_width 14
2164 #define plain_height 15
2165 static unsigned char plain_bits[] = {
2166    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2167    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2168    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2169 } -maskdata $filemask
2170
2171 image create bitmap file_mod -background white -foreground blue -data {
2172 #define mod_width 14
2173 #define mod_height 15
2174 static unsigned char mod_bits[] = {
2175    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2176    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2177    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2178 } -maskdata $filemask
2179
2180 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2181 #define file_fulltick_width 14
2182 #define file_fulltick_height 15
2183 static unsigned char file_fulltick_bits[] = {
2184    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2185    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2186    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2187 } -maskdata $filemask
2188
2189 image create bitmap file_parttick -background white -foreground "#005050" -data {
2190 #define parttick_width 14
2191 #define parttick_height 15
2192 static unsigned char parttick_bits[] = {
2193    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2194    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2195    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2196 } -maskdata $filemask
2197
2198 image create bitmap file_question -background white -foreground black -data {
2199 #define file_question_width 14
2200 #define file_question_height 15
2201 static unsigned char file_question_bits[] = {
2202    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2203    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2204    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2205 } -maskdata $filemask
2206
2207 image create bitmap file_removed -background white -foreground red -data {
2208 #define file_removed_width 14
2209 #define file_removed_height 15
2210 static unsigned char file_removed_bits[] = {
2211    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2212    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2213    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2214 } -maskdata $filemask
2215
2216 image create bitmap file_merge -background white -foreground blue -data {
2217 #define file_merge_width 14
2218 #define file_merge_height 15
2219 static unsigned char file_merge_bits[] = {
2220    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2221    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2222    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2223 } -maskdata $filemask
2224
2225 set ui_index .vpane.files.index.list
2226 set ui_workdir .vpane.files.workdir.list
2227
2228 set all_icons(_$ui_index)   file_plain
2229 set all_icons(A$ui_index)   file_fulltick
2230 set all_icons(M$ui_index)   file_fulltick
2231 set all_icons(D$ui_index)   file_removed
2232 set all_icons(U$ui_index)   file_merge
2233
2234 set all_icons(_$ui_workdir) file_plain
2235 set all_icons(M$ui_workdir) file_mod
2236 set all_icons(D$ui_workdir) file_question
2237 set all_icons(O$ui_workdir) file_plain
2238
2239 set max_status_desc 0
2240 foreach i {
2241                 {__ "Unmodified"}
2242
2243                 {_M "Modified, not staged"}
2244                 {M_ "Staged for commit"}
2245                 {MM "Portions staged for commit"}
2246                 {MD "Staged for commit, missing"}
2247
2248                 {_O "Untracked, not staged"}
2249                 {A_ "Staged for commit"}
2250                 {AM "Portions staged for commit"}
2251                 {AD "Staged for commit, missing"}
2252
2253                 {_D "Missing"}
2254                 {D_ "Staged for removal"}
2255                 {DO "Staged for removal, still present"}
2256
2257                 {U_ "Requires merge resolution"}
2258                 {UM "Requires merge resolution"}
2259                 {UD "Requires merge resolution"}
2260         } {
2261         if {$max_status_desc < [string length [lindex $i 1]]} {
2262                 set max_status_desc [string length [lindex $i 1]]
2263         }
2264         set all_descs([lindex $i 0]) [lindex $i 1]
2265 }
2266 unset i
2267
2268 ######################################################################
2269 ##
2270 ## util
2271
2272 proc is_MacOSX {} {
2273         global tcl_platform tk_library
2274         if {[tk windowingsystem] eq {aqua}} {
2275                 return 1
2276         }
2277         return 0
2278 }
2279
2280 proc is_Windows {} {
2281         global tcl_platform
2282         if {$tcl_platform(platform) eq {windows}} {
2283                 return 1
2284         }
2285         return 0
2286 }
2287
2288 proc bind_button3 {w cmd} {
2289         bind $w <Any-Button-3> $cmd
2290         if {[is_MacOSX]} {
2291                 bind $w <Control-Button-1> $cmd
2292         }
2293 }
2294
2295 proc incr_font_size {font {amt 1}} {
2296         set sz [font configure $font -size]
2297         incr sz $amt
2298         font configure $font -size $sz
2299         font configure ${font}bold -size $sz
2300 }
2301
2302 proc hook_failed_popup {hook msg} {
2303         set w .hookfail
2304         toplevel $w
2305
2306         frame $w.m
2307         label $w.m.l1 -text "$hook hook failed:" \
2308                 -anchor w \
2309                 -justify left \
2310                 -font font_uibold
2311         text $w.m.t \
2312                 -background white -borderwidth 1 \
2313                 -relief sunken \
2314                 -width 80 -height 10 \
2315                 -font font_diff \
2316                 -yscrollcommand [list $w.m.sby set]
2317         label $w.m.l2 \
2318                 -text {You must correct the above errors before committing.} \
2319                 -anchor w \
2320                 -justify left \
2321                 -font font_uibold
2322         scrollbar $w.m.sby -command [list $w.m.t yview]
2323         pack $w.m.l1 -side top -fill x
2324         pack $w.m.l2 -side bottom -fill x
2325         pack $w.m.sby -side right -fill y
2326         pack $w.m.t -side left -fill both -expand 1
2327         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2328
2329         $w.m.t insert 1.0 $msg
2330         $w.m.t conf -state disabled
2331
2332         button $w.ok -text OK \
2333                 -width 15 \
2334                 -font font_ui \
2335                 -command "destroy $w"
2336         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2337
2338         bind $w <Visibility> "grab $w; focus $w"
2339         bind $w <Key-Return> "destroy $w"
2340         wm title $w "[appname] ([reponame]): error"
2341         tkwait window $w
2342 }
2343
2344 set next_console_id 0
2345
2346 proc new_console {short_title long_title} {
2347         global next_console_id console_data
2348         set w .console[incr next_console_id]
2349         set console_data($w) [list $short_title $long_title]
2350         return [console_init $w]
2351 }
2352
2353 proc console_init {w} {
2354         global console_cr console_data M1B
2355
2356         set console_cr($w) 1.0
2357         toplevel $w
2358         frame $w.m
2359         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2360                 -anchor w \
2361                 -justify left \
2362                 -font font_uibold
2363         text $w.m.t \
2364                 -background white -borderwidth 1 \
2365                 -relief sunken \
2366                 -width 80 -height 10 \
2367                 -font font_diff \
2368                 -state disabled \
2369                 -yscrollcommand [list $w.m.sby set]
2370         label $w.m.s -text {Working... please wait...} \
2371                 -anchor w \
2372                 -justify left \
2373                 -font font_uibold
2374         scrollbar $w.m.sby -command [list $w.m.t yview]
2375         pack $w.m.l1 -side top -fill x
2376         pack $w.m.s -side bottom -fill x
2377         pack $w.m.sby -side right -fill y
2378         pack $w.m.t -side left -fill both -expand 1
2379         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2380
2381         menu $w.ctxm -tearoff 0
2382         $w.ctxm add command -label "Copy" \
2383                 -font font_ui \
2384                 -command "tk_textCopy $w.m.t"
2385         $w.ctxm add command -label "Select All" \
2386                 -font font_ui \
2387                 -command "$w.m.t tag add sel 0.0 end"
2388         $w.ctxm add command -label "Copy All" \
2389                 -font font_ui \
2390                 -command "
2391                         $w.m.t tag add sel 0.0 end
2392                         tk_textCopy $w.m.t
2393                         $w.m.t tag remove sel 0.0 end
2394                 "
2395
2396         button $w.ok -text {Close} \
2397                 -font font_ui \
2398                 -state disabled \
2399                 -command "destroy $w"
2400         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2401
2402         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2403         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2404         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2405         bind $w <Visibility> "focus $w"
2406         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2407         return $w
2408 }
2409
2410 proc console_exec {w cmd {after {}}} {
2411         # -- Windows tosses the enviroment when we exec our child.
2412         #    But most users need that so we have to relogin. :-(
2413         #
2414         if {[is_Windows]} {
2415                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2416         }
2417
2418         # -- Tcl won't let us redirect both stdout and stderr to
2419         #    the same pipe.  So pass it through cat...
2420         #
2421         set cmd [concat | $cmd |& cat]
2422
2423         set fd_f [open $cmd r]
2424         fconfigure $fd_f -blocking 0 -translation binary
2425         fileevent $fd_f readable [list console_read $w $fd_f $after]
2426 }
2427
2428 proc console_read {w fd after} {
2429         global console_cr console_data
2430
2431         set buf [read $fd]
2432         if {$buf ne {}} {
2433                 if {![winfo exists $w]} {console_init $w}
2434                 $w.m.t conf -state normal
2435                 set c 0
2436                 set n [string length $buf]
2437                 while {$c < $n} {
2438                         set cr [string first "\r" $buf $c]
2439                         set lf [string first "\n" $buf $c]
2440                         if {$cr < 0} {set cr [expr {$n + 1}]}
2441                         if {$lf < 0} {set lf [expr {$n + 1}]}
2442
2443                         if {$lf < $cr} {
2444                                 $w.m.t insert end [string range $buf $c $lf]
2445                                 set console_cr($w) [$w.m.t index {end -1c}]
2446                                 set c $lf
2447                                 incr c
2448                         } else {
2449                                 $w.m.t delete $console_cr($w) end
2450                                 $w.m.t insert end "\n"
2451                                 $w.m.t insert end [string range $buf $c $cr]
2452                                 set c $cr
2453                                 incr c
2454                         }
2455                 }
2456                 $w.m.t conf -state disabled
2457                 $w.m.t see end
2458         }
2459
2460         fconfigure $fd -blocking 1
2461         if {[eof $fd]} {
2462                 if {[catch {close $fd}]} {
2463                         if {![winfo exists $w]} {console_init $w}
2464                         $w.m.s conf -background red -text {Error: Command Failed}
2465                         $w.ok conf -state normal
2466                         set ok 0
2467                 } elseif {[winfo exists $w]} {
2468                         $w.m.s conf -background green -text {Success}
2469                         $w.ok conf -state normal
2470                         set ok 1
2471                 }
2472                 array unset console_cr $w
2473                 array unset console_data $w
2474                 if {$after ne {}} {
2475                         uplevel #0 $after $ok
2476                 }
2477                 return
2478         }
2479         fconfigure $fd -blocking 0
2480 }
2481
2482 ######################################################################
2483 ##
2484 ## ui commands
2485
2486 set starting_gitk_msg {Starting gitk... please wait...}
2487
2488 proc do_gitk {revs} {
2489         global ui_status_value starting_gitk_msg
2490
2491         set cmd gitk
2492         if {$revs ne {}} {
2493                 append cmd { }
2494                 append cmd $revs
2495         }
2496         if {[is_Windows]} {
2497                 set cmd "sh -c \"exec $cmd\""
2498         }
2499         append cmd { &}
2500
2501         if {[catch {eval exec $cmd} err]} {
2502                 error_popup "Failed to start gitk:\n\n$err"
2503         } else {
2504                 set ui_status_value $starting_gitk_msg
2505                 after 10000 {
2506                         if {$ui_status_value eq $starting_gitk_msg} {
2507                                 set ui_status_value {Ready.}
2508                         }
2509                 }
2510         }
2511 }
2512
2513 proc do_gc {} {
2514         set w [new_console {gc} {Compressing the object database}]
2515         console_exec $w {git gc}
2516 }
2517
2518 proc do_fsck_objects {} {
2519         set w [new_console {fsck-objects} \
2520                 {Verifying the object database with fsck-objects}]
2521         set cmd [list git fsck-objects]
2522         lappend cmd --full
2523         lappend cmd --cache
2524         lappend cmd --strict
2525         console_exec $w $cmd
2526 }
2527
2528 set is_quitting 0
2529
2530 proc do_quit {} {
2531         global ui_comm is_quitting repo_config commit_type
2532
2533         if {$is_quitting} return
2534         set is_quitting 1
2535
2536         # -- Stash our current commit buffer.
2537         #
2538         set save [gitdir GITGUI_MSG]
2539         set msg [string trim [$ui_comm get 0.0 end]]
2540         if {![string match amend* $commit_type]
2541                 && [$ui_comm edit modified]
2542                 && $msg ne {}} {
2543                 catch {
2544                         set fd [open $save w]
2545                         puts $fd [string trim [$ui_comm get 0.0 end]]
2546                         close $fd
2547                 }
2548         } else {
2549                 catch {file delete $save}
2550         }
2551
2552         # -- Stash our current window geometry into this repository.
2553         #
2554         set cfg_geometry [list]
2555         lappend cfg_geometry [wm geometry .]
2556         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2557         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2558         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2559                 set rc_geometry {}
2560         }
2561         if {$cfg_geometry ne $rc_geometry} {
2562                 catch {exec git repo-config gui.geometry $cfg_geometry}
2563         }
2564
2565         destroy .
2566 }
2567
2568 proc do_rescan {} {
2569         rescan {set ui_status_value {Ready.}}
2570 }
2571
2572 proc unstage_helper {txt paths} {
2573         global file_states current_diff
2574
2575         if {![lock_index begin-update]} return
2576
2577         set pathList [list]
2578         set after {}
2579         foreach path $paths {
2580                 switch -glob -- [lindex $file_states($path) 0] {
2581                 A? -
2582                 M? -
2583                 D? {
2584                         lappend pathList $path
2585                         if {$path eq $current_diff} {
2586                                 set after {reshow_diff;}
2587                         }
2588                 }
2589                 }
2590         }
2591         if {$pathList eq {}} {
2592                 unlock_index
2593         } else {
2594                 update_indexinfo \
2595                         $txt \
2596                         $pathList \
2597                         [concat $after {set ui_status_value {Ready.}}]
2598         }
2599 }
2600
2601 proc do_unstage_selection {} {
2602         global current_diff selected_paths
2603
2604         if {[array size selected_paths] > 0} {
2605                 unstage_helper \
2606                         {Unstaging selected files from commit} \
2607                         [array names selected_paths]
2608         } elseif {$current_diff ne {}} {
2609                 unstage_helper \
2610                         "Unstaging [short_path $current_diff] from commit" \
2611                         [list $current_diff]
2612         }
2613 }
2614
2615 proc add_helper {txt paths} {
2616         global file_states current_diff
2617
2618         if {![lock_index begin-update]} return
2619
2620         set pathList [list]
2621         set after {}
2622         foreach path $paths {
2623                 switch -glob -- [lindex $file_states($path) 0] {
2624                 _O -
2625                 ?M -
2626                 ?D -
2627                 U? {
2628                         lappend pathList $path
2629                         if {$path eq $current_diff} {
2630                                 set after {reshow_diff;}
2631                         }
2632                 }
2633                 }
2634         }
2635         if {$pathList eq {}} {
2636                 unlock_index
2637         } else {
2638                 update_index \
2639                         $txt \
2640                         $pathList \
2641                         [concat $after {set ui_status_value {Ready to commit.}}]
2642         }
2643 }
2644
2645 proc do_add_selection {} {
2646         global current_diff selected_paths
2647
2648         if {[array size selected_paths] > 0} {
2649                 add_helper \
2650                         {Adding selected files} \
2651                         [array names selected_paths]
2652         } elseif {$current_diff ne {}} {
2653                 add_helper \
2654                         "Adding [short_path $current_diff]" \
2655                         [list $current_diff]
2656         }
2657 }
2658
2659 proc do_add_all {} {
2660         global file_states
2661
2662         set paths [list]
2663         foreach path [array names file_states] {
2664                 switch -glob -- [lindex $file_states($path) 0] {
2665                 U? {continue}
2666                 ?M -
2667                 ?D {lappend paths $path}
2668                 }
2669         }
2670         add_helper {Adding all changed files} $paths
2671 }
2672
2673 proc revert_helper {txt paths} {
2674         global file_states current_diff
2675
2676         if {![lock_index begin-update]} return
2677
2678         set pathList [list]
2679         set after {}
2680         foreach path $paths {
2681                 switch -glob -- [lindex $file_states($path) 0] {
2682                 U? {continue}
2683                 ?M -
2684                 ?D {
2685                         lappend pathList $path
2686                         if {$path eq $current_diff} {
2687                                 set after {reshow_diff;}
2688                         }
2689                 }
2690                 }
2691         }
2692
2693         set n [llength $pathList]
2694         if {$n == 0} {
2695                 unlock_index
2696                 return
2697         } elseif {$n == 1} {
2698                 set s "[short_path [lindex $pathList]]"
2699         } else {
2700                 set s "these $n files"
2701         }
2702
2703         set reply [tk_dialog \
2704                 .confirm_revert \
2705                 "[appname] ([reponame])" \
2706                 "Revert changes in $s?
2707
2708 Any unadded changes will be permanently lost by the revert." \
2709                 question \
2710                 1 \
2711                 {Do Nothing} \
2712                 {Revert Changes} \
2713                 ]
2714         if {$reply == 1} {
2715                 checkout_index \
2716                         $txt \
2717                         $pathList \
2718                         [concat $after {set ui_status_value {Ready.}}]
2719         } else {
2720                 unlock_index
2721         }
2722 }
2723
2724 proc do_revert_selection {} {
2725         global current_diff selected_paths
2726
2727         if {[array size selected_paths] > 0} {
2728                 revert_helper \
2729                         {Reverting selected files} \
2730                         [array names selected_paths]
2731         } elseif {$current_diff ne {}} {
2732                 revert_helper \
2733                         "Reverting [short_path $current_diff]" \
2734                         [list $current_diff]
2735         }
2736 }
2737
2738 proc do_signoff {} {
2739         global ui_comm
2740
2741         set me [committer_ident]
2742         if {$me eq {}} return
2743
2744         set sob "Signed-off-by: $me"
2745         set last [$ui_comm get {end -1c linestart} {end -1c}]
2746         if {$last ne $sob} {
2747                 $ui_comm edit separator
2748                 if {$last ne {}
2749                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2750                         $ui_comm insert end "\n"
2751                 }
2752                 $ui_comm insert end "\n$sob"
2753                 $ui_comm edit separator
2754                 $ui_comm see end
2755         }
2756 }
2757
2758 proc do_select_commit_type {} {
2759         global commit_type selected_commit_type
2760
2761         if {$selected_commit_type eq {new}
2762                 && [string match amend* $commit_type]} {
2763                 create_new_commit
2764         } elseif {$selected_commit_type eq {amend}
2765                 && ![string match amend* $commit_type]} {
2766                 load_last_commit
2767
2768                 # The amend request was rejected...
2769                 #
2770                 if {![string match amend* $commit_type]} {
2771                         set selected_commit_type new
2772                 }
2773         }
2774 }
2775
2776 proc do_commit {} {
2777         commit_tree
2778 }
2779
2780 proc do_about {} {
2781         global appvers copyright
2782         global tcl_patchLevel tk_patchLevel
2783
2784         set w .about_dialog
2785         toplevel $w
2786         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2787
2788         label $w.header -text "About [appname]" \
2789                 -font font_uibold
2790         pack $w.header -side top -fill x
2791
2792         frame $w.buttons
2793         button $w.buttons.close -text {Close} \
2794                 -font font_ui \
2795                 -command [list destroy $w]
2796         pack $w.buttons.close -side right
2797         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2798
2799         label $w.desc \
2800                 -text "[appname] - a commit creation tool for Git.
2801 $copyright" \
2802                 -padx 5 -pady 5 \
2803                 -justify left \
2804                 -anchor w \
2805                 -borderwidth 1 \
2806                 -relief solid \
2807                 -font font_ui
2808         pack $w.desc -side top -fill x -padx 5 -pady 5
2809
2810         set v {}
2811         append v "[appname] version $appvers\n"
2812         append v "[exec git version]\n"
2813         append v "\n"
2814         if {$tcl_patchLevel eq $tk_patchLevel} {
2815                 append v "Tcl/Tk version $tcl_patchLevel"
2816         } else {
2817                 append v "Tcl version $tcl_patchLevel"
2818                 append v ", Tk version $tk_patchLevel"
2819         }
2820
2821         label $w.vers \
2822                 -text $v \
2823                 -padx 5 -pady 5 \
2824                 -justify left \
2825                 -anchor w \
2826                 -borderwidth 1 \
2827                 -relief solid \
2828                 -font font_ui
2829         pack $w.vers -side top -fill x -padx 5 -pady 5
2830
2831         menu $w.ctxm -tearoff 0
2832         $w.ctxm add command \
2833                 -label {Copy} \
2834                 -font font_ui \
2835                 -command "
2836                 clipboard clear
2837                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2838         "
2839
2840         bind $w <Visibility> "grab $w; focus $w"
2841         bind $w <Key-Escape> "destroy $w"
2842         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2843         wm title $w "About [appname]"
2844         tkwait window $w
2845 }
2846
2847 proc do_options {} {
2848         global repo_config global_config font_descs
2849         global repo_config_new global_config_new
2850
2851         array unset repo_config_new
2852         array unset global_config_new
2853         foreach name [array names repo_config] {
2854                 set repo_config_new($name) $repo_config($name)
2855         }
2856         load_config 1
2857         foreach name [array names repo_config] {
2858                 switch -- $name {
2859                 gui.diffcontext {continue}
2860                 }
2861                 set repo_config_new($name) $repo_config($name)
2862         }
2863         foreach name [array names global_config] {
2864                 set global_config_new($name) $global_config($name)
2865         }
2866
2867         set w .options_editor
2868         toplevel $w
2869         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2870
2871         label $w.header -text "[appname] Options" \
2872                 -font font_uibold
2873         pack $w.header -side top -fill x
2874
2875         frame $w.buttons
2876         button $w.buttons.restore -text {Restore Defaults} \
2877                 -font font_ui \
2878                 -command do_restore_defaults
2879         pack $w.buttons.restore -side left
2880         button $w.buttons.save -text Save \
2881                 -font font_ui \
2882                 -command [list do_save_config $w]
2883         pack $w.buttons.save -side right
2884         button $w.buttons.cancel -text {Cancel} \
2885                 -font font_ui \
2886                 -command [list destroy $w]
2887         pack $w.buttons.cancel -side right -padx 5
2888         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2889
2890         labelframe $w.repo -text "[reponame] Repository" \
2891                 -font font_ui \
2892                 -relief raised -borderwidth 2
2893         labelframe $w.global -text {Global (All Repositories)} \
2894                 -font font_ui \
2895                 -relief raised -borderwidth 2
2896         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2897         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2898
2899         foreach option {
2900                 {b pullsummary {Show Pull Summary}}
2901                 {b trustmtime  {Trust File Modification Timestamps}}
2902                 {i diffcontext {Number of Diff Context Lines}}
2903                 } {
2904                 set type [lindex $option 0]
2905                 set name [lindex $option 1]
2906                 set text [lindex $option 2]
2907                 foreach f {repo global} {
2908                         switch $type {
2909                         b {
2910                                 checkbutton $w.$f.$name -text $text \
2911                                         -variable ${f}_config_new(gui.$name) \
2912                                         -onvalue true \
2913                                         -offvalue false \
2914                                         -font font_ui
2915                                 pack $w.$f.$name -side top -anchor w
2916                         }
2917                         i {
2918                                 frame $w.$f.$name
2919                                 label $w.$f.$name.l -text "$text:" -font font_ui
2920                                 pack $w.$f.$name.l -side left -anchor w -fill x
2921                                 spinbox $w.$f.$name.v \
2922                                         -textvariable ${f}_config_new(gui.$name) \
2923                                         -from 1 -to 99 -increment 1 \
2924                                         -width 3 \
2925                                         -font font_ui
2926                                 pack $w.$f.$name.v -side right -anchor e
2927                                 pack $w.$f.$name -side top -anchor w -fill x
2928                         }
2929                         }
2930                 }
2931         }
2932
2933         set all_fonts [lsort [font families]]
2934         foreach option $font_descs {
2935                 set name [lindex $option 0]
2936                 set font [lindex $option 1]
2937                 set text [lindex $option 2]
2938
2939                 set global_config_new(gui.$font^^family) \
2940                         [font configure $font -family]
2941                 set global_config_new(gui.$font^^size) \
2942                         [font configure $font -size]
2943
2944                 frame $w.global.$name
2945                 label $w.global.$name.l -text "$text:" -font font_ui
2946                 pack $w.global.$name.l -side left -anchor w -fill x
2947                 eval tk_optionMenu $w.global.$name.family \
2948                         global_config_new(gui.$font^^family) \
2949                         $all_fonts
2950                 spinbox $w.global.$name.size \
2951                         -textvariable global_config_new(gui.$font^^size) \
2952                         -from 2 -to 80 -increment 1 \
2953                         -width 3 \
2954                         -font font_ui
2955                 pack $w.global.$name.size -side right -anchor e
2956                 pack $w.global.$name.family -side right -anchor e
2957                 pack $w.global.$name -side top -anchor w -fill x
2958         }
2959
2960         bind $w <Visibility> "grab $w; focus $w"
2961         bind $w <Key-Escape> "destroy $w"
2962         wm title $w "[appname] ([reponame]): Options"
2963         tkwait window $w
2964 }
2965
2966 proc do_restore_defaults {} {
2967         global font_descs default_config repo_config
2968         global repo_config_new global_config_new
2969
2970         foreach name [array names default_config] {
2971                 set repo_config_new($name) $default_config($name)
2972                 set global_config_new($name) $default_config($name)
2973         }
2974
2975         foreach option $font_descs {
2976                 set name [lindex $option 0]
2977                 set repo_config(gui.$name) $default_config(gui.$name)
2978         }
2979         apply_config
2980
2981         foreach option $font_descs {
2982                 set name [lindex $option 0]
2983                 set font [lindex $option 1]
2984                 set global_config_new(gui.$font^^family) \
2985                         [font configure $font -family]
2986                 set global_config_new(gui.$font^^size) \
2987                         [font configure $font -size]
2988         }
2989 }
2990
2991 proc do_save_config {w} {
2992         if {[catch {save_config} err]} {
2993                 error_popup "Failed to completely save options:\n\n$err"
2994         }
2995         reshow_diff
2996         destroy $w
2997 }
2998
2999 proc do_windows_shortcut {} {
3000         global argv0
3001
3002         if {[catch {
3003                 set desktop [exec cygpath \
3004                         --windows \
3005                         --absolute \
3006                         --long-name \
3007                         --desktop]
3008                 }]} {
3009                         set desktop .
3010         }
3011         set fn [tk_getSaveFile \
3012                 -parent . \
3013                 -title "[appname] ([reponame]): Create Desktop Icon" \
3014                 -initialdir $desktop \
3015                 -initialfile "Git [reponame].bat"]
3016         if {$fn != {}} {
3017                 if {[catch {
3018                                 set fd [open $fn w]
3019                                 set sh [exec cygpath \
3020                                         --windows \
3021                                         --absolute \
3022                                         /bin/sh]
3023                                 set me [exec cygpath \
3024                                         --unix \
3025                                         --absolute \
3026                                         $argv0]
3027                                 set gd [exec cygpath \
3028                                         --unix \
3029                                         --absolute \
3030                                         [gitdir]]
3031                                 set gw [exec cygpath \
3032                                         --windows \
3033                                         --absolute \
3034                                         [file dirname [gitdir]]]
3035                                 regsub -all ' $me "'\\''" me
3036                                 regsub -all ' $gd "'\\''" gd
3037                                 puts $fd "@ECHO Entering $gw"
3038                                 puts $fd "@ECHO Starting git-gui... please wait..."
3039                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3040                                 puts -nonewline $fd "GIT_DIR='$gd'"
3041                                 puts -nonewline $fd " '$me'"
3042                                 puts $fd "&\""
3043                                 close $fd
3044                         } err]} {
3045                         error_popup "Cannot write script:\n\n$err"
3046                 }
3047         }
3048 }
3049
3050 proc do_macosx_app {} {
3051         global argv0 env
3052
3053         set fn [tk_getSaveFile \
3054                 -parent . \
3055                 -title "[appname] ([reponame]): Create Desktop Icon" \
3056                 -initialdir [file join $env(HOME) Desktop] \
3057                 -initialfile "Git [reponame].app"]
3058         if {$fn != {}} {
3059                 if {[catch {
3060                                 set Contents [file join $fn Contents]
3061                                 set MacOS [file join $Contents MacOS]
3062                                 set exe [file join $MacOS git-gui]
3063
3064                                 file mkdir $MacOS
3065
3066                                 set fd [open [file join $Contents Info.plist] w]
3067                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3068 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3069 <plist version="1.0">
3070 <dict>
3071         <key>CFBundleDevelopmentRegion</key>
3072         <string>English</string>
3073         <key>CFBundleExecutable</key>
3074         <string>git-gui</string>
3075         <key>CFBundleIdentifier</key>
3076         <string>org.spearce.git-gui</string>
3077         <key>CFBundleInfoDictionaryVersion</key>
3078         <string>6.0</string>
3079         <key>CFBundlePackageType</key>
3080         <string>APPL</string>
3081         <key>CFBundleSignature</key>
3082         <string>????</string>
3083         <key>CFBundleVersion</key>
3084         <string>1.0</string>
3085         <key>NSPrincipalClass</key>
3086         <string>NSApplication</string>
3087 </dict>
3088 </plist>}
3089                                 close $fd
3090
3091                                 set fd [open $exe w]
3092                                 set gd [file normalize [gitdir]]
3093                                 set ep [file normalize [exec git --exec-path]]
3094                                 regsub -all ' $gd "'\\''" gd
3095                                 regsub -all ' $ep "'\\''" ep
3096                                 puts $fd "#!/bin/sh"
3097                                 foreach name [array names env] {
3098                                         if {[string match GIT_* $name]} {
3099                                                 regsub -all ' $env($name) "'\\''" v
3100                                                 puts $fd "export $name='$v'"
3101                                         }
3102                                 }
3103                                 puts $fd "export PATH='$ep':\$PATH"
3104                                 puts $fd "export GIT_DIR='$gd'"
3105                                 puts $fd "exec [file normalize $argv0]"
3106                                 close $fd
3107
3108                                 file attributes $exe -permissions u+x,g+x,o+x
3109                         } err]} {
3110                         error_popup "Cannot write icon:\n\n$err"
3111                 }
3112         }
3113 }
3114
3115 proc toggle_or_diff {w x y} {
3116         global file_states file_lists current_diff ui_index ui_workdir
3117         global last_clicked selected_paths
3118
3119         set pos [split [$w index @$x,$y] .]
3120         set lno [lindex $pos 0]
3121         set col [lindex $pos 1]
3122         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3123         if {$path eq {}} {
3124                 set last_clicked {}
3125                 return
3126         }
3127
3128         set last_clicked [list $w $lno]
3129         array unset selected_paths
3130         $ui_index tag remove in_sel 0.0 end
3131         $ui_workdir tag remove in_sel 0.0 end
3132
3133         if {$col == 0} {
3134                 if {$current_diff eq $path} {
3135                         set after {reshow_diff;}
3136                 } else {
3137                         set after {}
3138                 }
3139                 if {$w eq $ui_index} {
3140                         update_indexinfo \
3141                                 "Unstaging [short_path $path] from commit" \
3142                                 [list $path] \
3143                                 [concat $after {set ui_status_value {Ready.}}]
3144                 } elseif {$w eq $ui_workdir} {
3145                         update_index \
3146                                 "Adding [short_path $path]" \
3147                                 [list $path] \
3148                                 [concat $after {set ui_status_value {Ready.}}]
3149                 }
3150         } else {
3151                 show_diff $path $w $lno
3152         }
3153 }
3154
3155 proc add_one_to_selection {w x y} {
3156         global file_lists last_clicked selected_paths
3157
3158         set lno [lindex [split [$w index @$x,$y] .] 0]
3159         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3160         if {$path eq {}} {
3161                 set last_clicked {}
3162                 return
3163         }
3164
3165         if {$last_clicked ne {}
3166                 && [lindex $last_clicked 0] ne $w} {
3167                 array unset selected_paths
3168                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3169         }
3170
3171         set last_clicked [list $w $lno]
3172         if {[catch {set in_sel $selected_paths($path)}]} {
3173                 set in_sel 0
3174         }
3175         if {$in_sel} {
3176                 unset selected_paths($path)
3177                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3178         } else {
3179                 set selected_paths($path) 1
3180                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3181         }
3182 }
3183
3184 proc add_range_to_selection {w x y} {
3185         global file_lists last_clicked selected_paths
3186
3187         if {[lindex $last_clicked 0] ne $w} {
3188                 toggle_or_diff $w $x $y
3189                 return
3190         }
3191
3192         set lno [lindex [split [$w index @$x,$y] .] 0]
3193         set lc [lindex $last_clicked 1]
3194         if {$lc < $lno} {
3195                 set begin $lc
3196                 set end $lno
3197         } else {
3198                 set begin $lno
3199                 set end $lc
3200         }
3201
3202         foreach path [lrange $file_lists($w) \
3203                 [expr {$begin - 1}] \
3204                 [expr {$end - 1}]] {
3205                 set selected_paths($path) 1
3206         }
3207         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3208 }
3209
3210 ######################################################################
3211 ##
3212 ## config defaults
3213
3214 set cursor_ptr arrow
3215 font create font_diff -family Courier -size 10
3216 font create font_ui
3217 catch {
3218         label .dummy
3219         eval font configure font_ui [font actual [.dummy cget -font]]
3220         destroy .dummy
3221 }
3222
3223 font create font_uibold
3224 font create font_diffbold
3225
3226 if {[is_Windows]} {
3227         set M1B Control
3228         set M1T Ctrl
3229 } elseif {[is_MacOSX]} {
3230         set M1B M1
3231         set M1T Cmd
3232 } else {
3233         set M1B M1
3234         set M1T M1
3235 }
3236
3237 proc apply_config {} {
3238         global repo_config font_descs
3239
3240         foreach option $font_descs {
3241                 set name [lindex $option 0]
3242                 set font [lindex $option 1]
3243                 if {[catch {
3244                         foreach {cn cv} $repo_config(gui.$name) {
3245                                 font configure $font $cn $cv
3246                         }
3247                         } err]} {
3248                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3249                 }
3250                 foreach {cn cv} [font configure $font] {
3251                         font configure ${font}bold $cn $cv
3252                 }
3253                 font configure ${font}bold -weight bold
3254         }
3255 }
3256
3257 set default_config(gui.trustmtime) false
3258 set default_config(gui.pullsummary) true
3259 set default_config(gui.diffcontext) 5
3260 set default_config(gui.fontui) [font configure font_ui]
3261 set default_config(gui.fontdiff) [font configure font_diff]
3262 set font_descs {
3263         {fontui   font_ui   {Main Font}}
3264         {fontdiff font_diff {Diff/Console Font}}
3265 }
3266 load_config 0
3267 apply_config
3268
3269 ######################################################################
3270 ##
3271 ## ui construction
3272
3273 # -- Menu Bar
3274 #
3275 menu .mbar -tearoff 0
3276 .mbar add cascade -label Repository -menu .mbar.repository
3277 .mbar add cascade -label Edit -menu .mbar.edit
3278 if {!$single_commit} {
3279         .mbar add cascade -label Branch -menu .mbar.branch
3280 }
3281 .mbar add cascade -label Commit -menu .mbar.commit
3282 if {!$single_commit} {
3283         .mbar add cascade -label Fetch -menu .mbar.fetch
3284         .mbar add cascade -label Pull -menu .mbar.pull
3285         .mbar add cascade -label Push -menu .mbar.push
3286 }
3287 . configure -menu .mbar
3288
3289 # -- Repository Menu
3290 #
3291 menu .mbar.repository
3292 .mbar.repository add command \
3293         -label {Visualize Current Branch} \
3294         -command {do_gitk {}} \
3295         -font font_ui
3296 if {![is_MacOSX]} {
3297         .mbar.repository add command \
3298                 -label {Visualize All Branches} \
3299                 -command {do_gitk {--all}} \
3300                 -font font_ui
3301 }
3302 .mbar.repository add separator
3303
3304 if {!$single_commit} {
3305         .mbar.repository add command -label {Compress Database} \
3306                 -command do_gc \
3307                 -font font_ui
3308
3309         .mbar.repository add command -label {Verify Database} \
3310                 -command do_fsck_objects \
3311                 -font font_ui
3312
3313         .mbar.repository add separator
3314
3315         if {[is_Windows]} {
3316                 .mbar.repository add command \
3317                         -label {Create Desktop Icon} \
3318                         -command do_windows_shortcut \
3319                         -font font_ui
3320         } elseif {[is_MacOSX]} {
3321                 .mbar.repository add command \
3322                         -label {Create Desktop Icon} \
3323                         -command do_macosx_app \
3324                         -font font_ui
3325         }
3326 }
3327
3328 .mbar.repository add command -label Quit \
3329         -command do_quit \
3330         -accelerator $M1T-Q \
3331         -font font_ui
3332
3333 # -- Edit Menu
3334 #
3335 menu .mbar.edit
3336 .mbar.edit add command -label Undo \
3337         -command {catch {[focus] edit undo}} \
3338         -accelerator $M1T-Z \
3339         -font font_ui
3340 .mbar.edit add command -label Redo \
3341         -command {catch {[focus] edit redo}} \
3342         -accelerator $M1T-Y \
3343         -font font_ui
3344 .mbar.edit add separator
3345 .mbar.edit add command -label Cut \
3346         -command {catch {tk_textCut [focus]}} \
3347         -accelerator $M1T-X \
3348         -font font_ui
3349 .mbar.edit add command -label Copy \
3350         -command {catch {tk_textCopy [focus]}} \
3351         -accelerator $M1T-C \
3352         -font font_ui
3353 .mbar.edit add command -label Paste \
3354         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3355         -accelerator $M1T-V \
3356         -font font_ui
3357 .mbar.edit add command -label Delete \
3358         -command {catch {[focus] delete sel.first sel.last}} \
3359         -accelerator Del \
3360         -font font_ui
3361 .mbar.edit add separator
3362 .mbar.edit add command -label {Select All} \
3363         -command {catch {[focus] tag add sel 0.0 end}} \
3364         -accelerator $M1T-A \
3365         -font font_ui
3366
3367 # -- Branch Menu
3368 #
3369 if {!$single_commit} {
3370         menu .mbar.branch
3371
3372         .mbar.branch add command -label {Create...} \
3373                 -command do_create_branch \
3374                 -accelerator $M1T-N \
3375                 -font font_ui
3376         lappend disable_on_lock [list .mbar.branch entryconf \
3377                 [.mbar.branch index last] -state]
3378
3379         .mbar.branch add command -label {Delete...} \
3380                 -command do_delete_branch \
3381                 -font font_ui
3382         lappend disable_on_lock [list .mbar.branch entryconf \
3383                 [.mbar.branch index last] -state]
3384 }
3385
3386 # -- Commit Menu
3387 #
3388 menu .mbar.commit
3389
3390 .mbar.commit add radiobutton \
3391         -label {New Commit} \
3392         -command do_select_commit_type \
3393         -variable selected_commit_type \
3394         -value new \
3395         -font font_ui
3396 lappend disable_on_lock \
3397         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3398
3399 .mbar.commit add radiobutton \
3400         -label {Amend Last Commit} \
3401         -command do_select_commit_type \
3402         -variable selected_commit_type \
3403         -value amend \
3404         -font font_ui
3405 lappend disable_on_lock \
3406         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3407
3408 .mbar.commit add separator
3409
3410 .mbar.commit add command -label Rescan \
3411         -command do_rescan \
3412         -accelerator F5 \
3413         -font font_ui
3414 lappend disable_on_lock \
3415         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3416
3417 .mbar.commit add command -label {Add To Commit} \
3418         -command do_add_selection \
3419         -font font_ui
3420 lappend disable_on_lock \
3421         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3422
3423 .mbar.commit add command -label {Add All To Commit} \
3424         -command do_add_all \
3425         -accelerator $M1T-I \
3426         -font font_ui
3427 lappend disable_on_lock \
3428         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3429
3430 .mbar.commit add command -label {Unstage From Commit} \
3431         -command do_unstage_selection \
3432         -font font_ui
3433 lappend disable_on_lock \
3434         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3435
3436 .mbar.commit add command -label {Revert Changes} \
3437         -command do_revert_selection \
3438         -font font_ui
3439 lappend disable_on_lock \
3440         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3441
3442 .mbar.commit add separator
3443
3444 .mbar.commit add command -label {Sign Off} \
3445         -command do_signoff \
3446         -accelerator $M1T-S \
3447         -font font_ui
3448
3449 .mbar.commit add command -label Commit \
3450         -command do_commit \
3451         -accelerator $M1T-Return \
3452         -font font_ui
3453 lappend disable_on_lock \
3454         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3455
3456 # -- Transport menus
3457 #
3458 if {!$single_commit} {
3459         menu .mbar.fetch
3460         menu .mbar.pull
3461         menu .mbar.push
3462 }
3463
3464 if {[is_MacOSX]} {
3465         # -- Apple Menu (Mac OS X only)
3466         #
3467         .mbar add cascade -label Apple -menu .mbar.apple
3468         menu .mbar.apple
3469
3470         .mbar.apple add command -label "About [appname]" \
3471                 -command do_about \
3472                 -font font_ui
3473         .mbar.apple add command -label "[appname] Options..." \
3474                 -command do_options \
3475                 -font font_ui
3476 } else {
3477         # -- Edit Menu
3478         #
3479         .mbar.edit add separator
3480         .mbar.edit add command -label {Options...} \
3481                 -command do_options \
3482                 -font font_ui
3483
3484         # -- Tools Menu
3485         #
3486         if {[file exists /usr/local/miga/lib/gui-miga]
3487                 && [file exists .pvcsrc]} {
3488         proc do_miga {} {
3489                 global ui_status_value
3490                 if {![lock_index update]} return
3491                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3492                 set miga_fd [open "|$cmd" r]
3493                 fconfigure $miga_fd -blocking 0
3494                 fileevent $miga_fd readable [list miga_done $miga_fd]
3495                 set ui_status_value {Running miga...}
3496         }
3497         proc miga_done {fd} {
3498                 read $fd 512
3499                 if {[eof $fd]} {
3500                         close $fd
3501                         unlock_index
3502                         rescan [list set ui_status_value {Ready.}]
3503                 }
3504         }
3505         .mbar add cascade -label Tools -menu .mbar.tools
3506         menu .mbar.tools
3507         .mbar.tools add command -label "Migrate" \
3508                 -command do_miga \
3509                 -font font_ui
3510         lappend disable_on_lock \
3511                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3512         }
3513
3514         # -- Help Menu
3515         #
3516         .mbar add cascade -label Help -menu .mbar.help
3517         menu .mbar.help
3518
3519         .mbar.help add command -label "About [appname]" \
3520                 -command do_about \
3521                 -font font_ui
3522 }
3523
3524
3525 # -- Branch Control
3526 #
3527 frame .branch \
3528         -borderwidth 1 \
3529         -relief sunken
3530 label .branch.l1 \
3531         -text {Current Branch:} \
3532         -anchor w \
3533         -justify left \
3534         -font font_ui
3535 label .branch.cb \
3536         -textvariable current_branch \
3537         -anchor w \
3538         -justify left \
3539         -font font_ui
3540 pack .branch.l1 -side left
3541 pack .branch.cb -side left -fill x
3542 pack .branch -side top -fill x
3543
3544 # -- Main Window Layout
3545 #
3546 panedwindow .vpane -orient vertical
3547 panedwindow .vpane.files -orient horizontal
3548 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3549 pack .vpane -anchor n -side top -fill both -expand 1
3550
3551 # -- Index File List
3552 #
3553 frame .vpane.files.index -height 100 -width 400
3554 label .vpane.files.index.title -text {Changes To Be Committed} \
3555         -background green \
3556         -font font_ui
3557 text $ui_index -background white -borderwidth 0 \
3558         -width 40 -height 10 \
3559         -font font_ui \
3560         -cursor $cursor_ptr \
3561         -yscrollcommand {.vpane.files.index.sb set} \
3562         -state disabled
3563 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3564 pack .vpane.files.index.title -side top -fill x
3565 pack .vpane.files.index.sb -side right -fill y
3566 pack $ui_index -side left -fill both -expand 1
3567 .vpane.files add .vpane.files.index -sticky nsew
3568
3569 # -- Working Directory File List
3570 #
3571 frame .vpane.files.workdir -height 100 -width 100
3572 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3573         -background red \
3574         -font font_ui
3575 text $ui_workdir -background white -borderwidth 0 \
3576         -width 40 -height 10 \
3577         -font font_ui \
3578         -cursor $cursor_ptr \
3579         -yscrollcommand {.vpane.files.workdir.sb set} \
3580         -state disabled
3581 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3582 pack .vpane.files.workdir.title -side top -fill x
3583 pack .vpane.files.workdir.sb -side right -fill y
3584 pack $ui_workdir -side left -fill both -expand 1
3585 .vpane.files add .vpane.files.workdir -sticky nsew
3586
3587 foreach i [list $ui_index $ui_workdir] {
3588         $i tag conf in_diff -font font_uibold
3589         $i tag conf in_sel \
3590                 -background [$i cget -foreground] \
3591                 -foreground [$i cget -background]
3592 }
3593 unset i
3594
3595 # -- Diff and Commit Area
3596 #
3597 frame .vpane.lower -height 300 -width 400
3598 frame .vpane.lower.commarea
3599 frame .vpane.lower.diff -relief sunken -borderwidth 1
3600 pack .vpane.lower.commarea -side top -fill x
3601 pack .vpane.lower.diff -side bottom -fill both -expand 1
3602 .vpane add .vpane.lower -stick nsew
3603
3604 # -- Commit Area Buttons
3605 #
3606 frame .vpane.lower.commarea.buttons
3607 label .vpane.lower.commarea.buttons.l -text {} \
3608         -anchor w \
3609         -justify left \
3610         -font font_ui
3611 pack .vpane.lower.commarea.buttons.l -side top -fill x
3612 pack .vpane.lower.commarea.buttons -side left -fill y
3613
3614 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3615         -command do_rescan \
3616         -font font_ui
3617 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3618 lappend disable_on_lock \
3619         {.vpane.lower.commarea.buttons.rescan conf -state}
3620
3621 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3622         -command do_add_all \
3623         -font font_ui
3624 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3625 lappend disable_on_lock \
3626         {.vpane.lower.commarea.buttons.incall conf -state}
3627
3628 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3629         -command do_signoff \
3630         -font font_ui
3631 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3632
3633 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3634         -command do_commit \
3635         -font font_ui
3636 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3637 lappend disable_on_lock \
3638         {.vpane.lower.commarea.buttons.commit conf -state}
3639
3640 # -- Commit Message Buffer
3641 #
3642 frame .vpane.lower.commarea.buffer
3643 frame .vpane.lower.commarea.buffer.header
3644 set ui_comm .vpane.lower.commarea.buffer.t
3645 set ui_coml .vpane.lower.commarea.buffer.header.l
3646 radiobutton .vpane.lower.commarea.buffer.header.new \
3647         -text {New Commit} \
3648         -command do_select_commit_type \
3649         -variable selected_commit_type \
3650         -value new \
3651         -font font_ui
3652 lappend disable_on_lock \
3653         [list .vpane.lower.commarea.buffer.header.new conf -state]
3654 radiobutton .vpane.lower.commarea.buffer.header.amend \
3655         -text {Amend Last Commit} \
3656         -command do_select_commit_type \
3657         -variable selected_commit_type \
3658         -value amend \
3659         -font font_ui
3660 lappend disable_on_lock \
3661         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3662 label $ui_coml \
3663         -anchor w \
3664         -justify left \
3665         -font font_ui
3666 proc trace_commit_type {varname args} {
3667         global ui_coml commit_type
3668         switch -glob -- $commit_type {
3669         initial       {set txt {Initial Commit Message:}}
3670         amend         {set txt {Amended Commit Message:}}
3671         amend-initial {set txt {Amended Initial Commit Message:}}
3672         amend-merge   {set txt {Amended Merge Commit Message:}}
3673         merge         {set txt {Merge Commit Message:}}
3674         *             {set txt {Commit Message:}}
3675         }
3676         $ui_coml conf -text $txt
3677 }
3678 trace add variable commit_type write trace_commit_type
3679 pack $ui_coml -side left -fill x
3680 pack .vpane.lower.commarea.buffer.header.amend -side right
3681 pack .vpane.lower.commarea.buffer.header.new -side right
3682
3683 text $ui_comm -background white -borderwidth 1 \
3684         -undo true \
3685         -maxundo 20 \
3686         -autoseparators true \
3687         -relief sunken \
3688         -width 75 -height 9 -wrap none \
3689         -font font_diff \
3690         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3691 scrollbar .vpane.lower.commarea.buffer.sby \
3692         -command [list $ui_comm yview]
3693 pack .vpane.lower.commarea.buffer.header -side top -fill x
3694 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3695 pack $ui_comm -side left -fill y
3696 pack .vpane.lower.commarea.buffer -side left -fill y
3697
3698 # -- Commit Message Buffer Context Menu
3699 #
3700 set ctxm .vpane.lower.commarea.buffer.ctxm
3701 menu $ctxm -tearoff 0
3702 $ctxm add command \
3703         -label {Cut} \
3704         -font font_ui \
3705         -command {tk_textCut $ui_comm}
3706 $ctxm add command \
3707         -label {Copy} \
3708         -font font_ui \
3709         -command {tk_textCopy $ui_comm}
3710 $ctxm add command \
3711         -label {Paste} \
3712         -font font_ui \
3713         -command {tk_textPaste $ui_comm}
3714 $ctxm add command \
3715         -label {Delete} \
3716         -font font_ui \
3717         -command {$ui_comm delete sel.first sel.last}
3718 $ctxm add separator
3719 $ctxm add command \
3720         -label {Select All} \
3721         -font font_ui \
3722         -command {$ui_comm tag add sel 0.0 end}
3723 $ctxm add command \
3724         -label {Copy All} \
3725         -font font_ui \
3726         -command {
3727                 $ui_comm tag add sel 0.0 end
3728                 tk_textCopy $ui_comm
3729                 $ui_comm tag remove sel 0.0 end
3730         }
3731 $ctxm add separator
3732 $ctxm add command \
3733         -label {Sign Off} \
3734         -font font_ui \
3735         -command do_signoff
3736 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3737
3738 # -- Diff Header
3739 #
3740 set current_diff {}
3741 set diff_actions [list]
3742 proc trace_current_diff {varname args} {
3743         global current_diff diff_actions file_states
3744         if {$current_diff eq {}} {
3745                 set s {}
3746                 set f {}
3747                 set p {}
3748                 set o disabled
3749         } else {
3750                 set p $current_diff
3751                 set s [mapdesc [lindex $file_states($p) 0] $p]
3752                 set f {File:}
3753                 set p [escape_path $p]
3754                 set o normal
3755         }
3756
3757         .vpane.lower.diff.header.status configure -text $s
3758         .vpane.lower.diff.header.file configure -text $f
3759         .vpane.lower.diff.header.path configure -text $p
3760         foreach w $diff_actions {
3761                 uplevel #0 $w $o
3762         }
3763 }
3764 trace add variable current_diff write trace_current_diff
3765
3766 frame .vpane.lower.diff.header -background orange
3767 label .vpane.lower.diff.header.status \
3768         -background orange \
3769         -width $max_status_desc \
3770         -anchor w \
3771         -justify left \
3772         -font font_ui
3773 label .vpane.lower.diff.header.file \
3774         -background orange \
3775         -anchor w \
3776         -justify left \
3777         -font font_ui
3778 label .vpane.lower.diff.header.path \
3779         -background orange \
3780         -anchor w \
3781         -justify left \
3782         -font font_ui
3783 pack .vpane.lower.diff.header.status -side left
3784 pack .vpane.lower.diff.header.file -side left
3785 pack .vpane.lower.diff.header.path -fill x
3786 set ctxm .vpane.lower.diff.header.ctxm
3787 menu $ctxm -tearoff 0
3788 $ctxm add command \
3789         -label {Copy} \
3790         -font font_ui \
3791         -command {
3792                 clipboard clear
3793                 clipboard append \
3794                         -format STRING \
3795                         -type STRING \
3796                         -- $current_diff
3797         }
3798 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3799 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3800
3801 # -- Diff Body
3802 #
3803 frame .vpane.lower.diff.body
3804 set ui_diff .vpane.lower.diff.body.t
3805 text $ui_diff -background white -borderwidth 0 \
3806         -width 80 -height 15 -wrap none \
3807         -font font_diff \
3808         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3809         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3810         -state disabled
3811 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3812         -command [list $ui_diff xview]
3813 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3814         -command [list $ui_diff yview]
3815 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3816 pack .vpane.lower.diff.body.sby -side right -fill y
3817 pack $ui_diff -side left -fill both -expand 1
3818 pack .vpane.lower.diff.header -side top -fill x
3819 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3820
3821 $ui_diff tag conf d_@ -font font_diffbold
3822 $ui_diff tag conf d_+  -foreground blue
3823 $ui_diff tag conf d_-  -foreground red
3824 $ui_diff tag conf d_++ -foreground {#00a000}
3825 $ui_diff tag conf d_-- -foreground {#a000a0}
3826 $ui_diff tag conf d_+- \
3827         -foreground red \
3828         -background {light goldenrod yellow}
3829 $ui_diff tag conf d_-+ \
3830         -foreground blue \
3831         -background azure2
3832
3833 # -- Diff Body Context Menu
3834 #
3835 set ctxm .vpane.lower.diff.body.ctxm
3836 menu $ctxm -tearoff 0
3837 $ctxm add command \
3838         -label {Copy} \
3839         -font font_ui \
3840         -command {tk_textCopy $ui_diff}
3841 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3842 $ctxm add command \
3843         -label {Select All} \
3844         -font font_ui \
3845         -command {$ui_diff tag add sel 0.0 end}
3846 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3847 $ctxm add command \
3848         -label {Copy All} \
3849         -font font_ui \
3850         -command {
3851                 $ui_diff tag add sel 0.0 end
3852                 tk_textCopy $ui_diff
3853                 $ui_diff tag remove sel 0.0 end
3854         }
3855 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3856 $ctxm add separator
3857 $ctxm add command \
3858         -label {Decrease Font Size} \
3859         -font font_ui \
3860         -command {incr_font_size font_diff -1}
3861 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3862 $ctxm add command \
3863         -label {Increase Font Size} \
3864         -font font_ui \
3865         -command {incr_font_size font_diff 1}
3866 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3867 $ctxm add separator
3868 $ctxm add command \
3869         -label {Show Less Context} \
3870         -font font_ui \
3871         -command {if {$repo_config(gui.diffcontext) >= 2} {
3872                 incr repo_config(gui.diffcontext) -1
3873                 reshow_diff
3874         }}
3875 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3876 $ctxm add command \
3877         -label {Show More Context} \
3878         -font font_ui \
3879         -command {
3880                 incr repo_config(gui.diffcontext)
3881                 reshow_diff
3882         }
3883 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3884 $ctxm add separator
3885 $ctxm add command -label {Options...} \
3886         -font font_ui \
3887         -command do_options
3888 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3889
3890 # -- Status Bar
3891 #
3892 set ui_status_value {Initializing...}
3893 label .status -textvariable ui_status_value \
3894         -anchor w \
3895         -justify left \
3896         -borderwidth 1 \
3897         -relief sunken \
3898         -font font_ui
3899 pack .status -anchor w -side bottom -fill x
3900
3901 # -- Load geometry
3902 #
3903 catch {
3904 set gm $repo_config(gui.geometry)
3905 wm geometry . [lindex $gm 0]
3906 .vpane sash place 0 \
3907         [lindex [.vpane sash coord 0] 0] \
3908         [lindex $gm 1]
3909 .vpane.files sash place 0 \
3910         [lindex $gm 2] \
3911         [lindex [.vpane.files sash coord 0] 1]
3912 unset gm
3913 }
3914
3915 # -- Key Bindings
3916 #
3917 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3918 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3919 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3920 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3921 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3922 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3923 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3924 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3925 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3926 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3927 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3928
3929 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3930 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3931 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3932 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3933 bind $ui_diff <$M1B-Key-v> {break}
3934 bind $ui_diff <$M1B-Key-V> {break}
3935 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3936 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3937 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3938 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3939 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3940 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3941
3942 if {!$single_commit} {
3943         bind . <$M1B-Key-n> do_create_branch
3944         bind . <$M1B-Key-N> do_create_branch
3945 }
3946
3947 bind .   <Destroy> do_quit
3948 bind all <Key-F5> do_rescan
3949 bind all <$M1B-Key-r> do_rescan
3950 bind all <$M1B-Key-R> do_rescan
3951 bind .   <$M1B-Key-s> do_signoff
3952 bind .   <$M1B-Key-S> do_signoff
3953 bind .   <$M1B-Key-i> do_add_all
3954 bind .   <$M1B-Key-I> do_add_all
3955 bind .   <$M1B-Key-Return> do_commit
3956 bind all <$M1B-Key-q> do_quit
3957 bind all <$M1B-Key-Q> do_quit
3958 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3959 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3960 foreach i [list $ui_index $ui_workdir] {
3961         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3962         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3963         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3964 }
3965 unset i
3966
3967 set file_lists($ui_index) [list]
3968 set file_lists($ui_workdir) [list]
3969
3970 set HEAD {}
3971 set PARENT {}
3972 set MERGE_HEAD [list]
3973 set commit_type {}
3974 set empty_tree {}
3975 set current_branch {}
3976 set current_diff {}
3977 set selected_commit_type new
3978
3979 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
3980 focus -force $ui_comm
3981
3982 # -- Warn the user about environmental problems.  Cygwin's Tcl
3983 #    does *not* pass its env array onto any processes it spawns.
3984 #    This means that git processes get none of our environment.
3985 #
3986 if {[is_Windows]} {
3987         set ignored_env 0
3988         set suggest_user {}
3989         set msg "Possible environment issues exist.
3990
3991 The following environment variables are probably
3992 going to be ignored by any Git subprocess run
3993 by [appname]:
3994
3995 "
3996         foreach name [array names env] {
3997                 switch -regexp -- $name {
3998                 {^GIT_INDEX_FILE$} -
3999                 {^GIT_OBJECT_DIRECTORY$} -
4000                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4001                 {^GIT_DIFF_OPTS$} -
4002                 {^GIT_EXTERNAL_DIFF$} -
4003                 {^GIT_PAGER$} -
4004                 {^GIT_TRACE$} -
4005                 {^GIT_CONFIG$} -
4006                 {^GIT_CONFIG_LOCAL$} -
4007                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4008                         append msg " - $name\n"
4009                         incr ignored_env
4010                 }
4011                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4012                         append msg " - $name\n"
4013                         incr ignored_env
4014                         set suggest_user $name
4015                 }
4016                 }
4017         }
4018         if {$ignored_env > 0} {
4019                 append msg "
4020 This is due to a known issue with the
4021 Tcl binary distributed by Cygwin."
4022
4023                 if {$suggest_user ne {}} {
4024                         append msg "
4025
4026 A good replacement for $suggest_user
4027 is placing values for the user.name and
4028 user.email settings into your personal
4029 ~/.gitconfig file.
4030 "
4031                 }
4032                 warn_popup $msg
4033         }
4034         unset ignored_env msg suggest_user name
4035 }
4036
4037 # -- Only initialize complex UI if we are going to stay running.
4038 #
4039 if {!$single_commit} {
4040         load_all_remotes
4041         load_all_heads
4042
4043         populate_branch_menu
4044         populate_fetch_menu .mbar.fetch
4045         populate_pull_menu .mbar.pull
4046         populate_push_menu .mbar.push
4047 }
4048
4049 # -- Only suggest a gc run if we are going to stay running.
4050 #
4051 if {!$single_commit} {
4052         set object_limit 2000
4053         if {[is_Windows]} {set object_limit 200}
4054         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4055         if {$objects_current >= $object_limit} {
4056                 if {[ask_popup \
4057                         "This repository currently has $objects_current loose objects.
4058
4059 To maintain optimal performance it is strongly
4060 recommended that you compress the database
4061 when more than $object_limit loose objects exist.
4062
4063 Compress the database now?"] eq yes} {
4064                         do_gc
4065                 }
4066         }
4067         unset object_limit _junk objects_current
4068 }
4069
4070 lock_index begin-read
4071 after 1 do_rescan