ae19a8f9cf3901a808c85f0c028fbf44813d30b5
1 # git-gui options editor
2 # Copyright (C) 2006, 2007 Shawn Pearce
4 proc save_config {} {
5 global default_config font_descs
6 global repo_config global_config
7 global repo_config_new global_config_new
9 foreach option $font_descs {
10 set name [lindex $option 0]
11 set font [lindex $option 1]
12 font configure $font \
13 -family $global_config_new(gui.$font^^family) \
14 -size $global_config_new(gui.$font^^size)
15 font configure ${font}bold \
16 -family $global_config_new(gui.$font^^family) \
17 -size $global_config_new(gui.$font^^size)
18 font configure ${font}italic \
19 -family $global_config_new(gui.$font^^family) \
20 -size $global_config_new(gui.$font^^size)
21 set global_config_new(gui.$name) [font configure $font]
22 unset global_config_new(gui.$font^^family)
23 unset global_config_new(gui.$font^^size)
24 }
26 foreach name [array names default_config] {
27 set value $global_config_new($name)
28 if {$value ne $global_config($name)} {
29 if {$value eq $default_config($name)} {
30 catch {git config --global --unset $name}
31 } else {
32 regsub -all "\[{}\]" $value {"} value
33 git config --global $name $value
34 }
35 set global_config($name) $value
36 if {$value eq $repo_config($name)} {
37 catch {git config --unset $name}
38 set repo_config($name) $value
39 }
40 }
41 }
43 foreach name [array names default_config] {
44 set value $repo_config_new($name)
45 if {$value ne $repo_config($name)} {
46 if {$value eq $global_config($name)} {
47 catch {git config --unset $name}
48 } else {
49 regsub -all "\[{}\]" $value {"} value
50 git config $name $value
51 }
52 set repo_config($name) $value
53 }
54 }
55 }
57 proc do_about {} {
58 global appvers copyright oguilib
59 global tcl_patchLevel tk_patchLevel
61 set w .about_dialog
62 toplevel $w
63 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
65 label $w.header -text "About [appname]" \
66 -font font_uibold
67 pack $w.header -side top -fill x
69 frame $w.buttons
70 button $w.buttons.close -text {Close} \
71 -default active \
72 -command [list destroy $w]
73 pack $w.buttons.close -side right
74 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
76 label $w.desc \
77 -text "git-gui - a graphical user interface for Git.
78 $copyright" \
79 -padx 5 -pady 5 \
80 -justify left \
81 -anchor w \
82 -borderwidth 1 \
83 -relief solid
84 pack $w.desc -side top -fill x -padx 5 -pady 5
86 set v {}
87 append v "git-gui version $appvers\n"
88 append v "[git version]\n"
89 append v "\n"
90 if {$tcl_patchLevel eq $tk_patchLevel} {
91 append v "Tcl/Tk version $tcl_patchLevel"
92 } else {
93 append v "Tcl version $tcl_patchLevel"
94 append v ", Tk version $tk_patchLevel"
95 }
97 set d {}
98 append d "git exec dir: [gitexec]\n"
99 append d "git-gui lib: $oguilib"
101 label $w.vers \
102 -text $v \
103 -padx 5 -pady 5 \
104 -justify left \
105 -anchor w \
106 -borderwidth 1 \
107 -relief solid
108 pack $w.vers -side top -fill x -padx 5 -pady 5
110 label $w.dirs \
111 -text $d \
112 -padx 5 -pady 5 \
113 -justify left \
114 -anchor w \
115 -borderwidth 1 \
116 -relief solid
117 pack $w.dirs -side top -fill x -padx 5 -pady 5
119 menu $w.ctxm -tearoff 0
120 $w.ctxm add command \
121 -label {Copy} \
122 -command "
123 clipboard clear
124 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
125 "
127 bind $w <Visibility> "grab $w; focus $w.buttons.close"
128 bind $w <Key-Escape> "destroy $w"
129 bind $w <Key-Return> "destroy $w"
130 bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
131 wm title $w "About [appname]"
132 tkwait window $w
133 }
135 proc do_options {} {
136 global repo_config global_config font_descs
137 global repo_config_new global_config_new
139 array unset repo_config_new
140 array unset global_config_new
141 foreach name [array names repo_config] {
142 set repo_config_new($name) $repo_config($name)
143 }
144 load_config 1
145 foreach name [array names repo_config] {
146 switch -- $name {
147 gui.diffcontext {continue}
148 }
149 set repo_config_new($name) $repo_config($name)
150 }
151 foreach name [array names global_config] {
152 set global_config_new($name) $global_config($name)
153 }
155 set w .options_editor
156 toplevel $w
157 wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
159 label $w.header -text "Options" \
160 -font font_uibold
161 pack $w.header -side top -fill x
163 frame $w.buttons
164 button $w.buttons.restore -text {Restore Defaults} \
165 -default normal \
166 -command do_restore_defaults
167 pack $w.buttons.restore -side left
168 button $w.buttons.save -text Save \
169 -default active \
170 -command [list do_save_config $w]
171 pack $w.buttons.save -side right
172 button $w.buttons.cancel -text {Cancel} \
173 -default normal \
174 -command [list destroy $w]
175 pack $w.buttons.cancel -side right -padx 5
176 pack $w.buttons -side bottom -fill x -pady 10 -padx 10
178 labelframe $w.repo -text "[reponame] Repository"
179 labelframe $w.global -text {Global (All Repositories)}
180 pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
181 pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
183 set optid 0
184 foreach option {
185 {t user.name {User Name}}
186 {t user.email {Email Address}}
188 {b merge.summary {Summarize Merge Commits}}
189 {i-1..5 merge.verbosity {Merge Verbosity}}
190 {b merge.diffstat {Show Diffstat After Merge}}
192 {b gui.trustmtime {Trust File Modification Timestamps}}
193 {b gui.pruneduringfetch {Prune Tracking Branches During Fetch}}
194 {i-0..99 gui.diffcontext {Number of Diff Context Lines}}
195 {t gui.newbranchtemplate {New Branch Name Template}}
196 } {
197 set type [lindex $option 0]
198 set name [lindex $option 1]
199 set text [lindex $option 2]
200 incr optid
201 foreach f {repo global} {
202 switch -glob -- $type {
203 b {
204 checkbutton $w.$f.$optid -text $text \
205 -variable ${f}_config_new($name) \
206 -onvalue true \
207 -offvalue false
208 pack $w.$f.$optid -side top -anchor w
209 }
210 i-* {
211 regexp -- {-(\d+)\.\.(\d+)$} $type _junk min max
212 frame $w.$f.$optid
213 label $w.$f.$optid.l -text "$text:"
214 pack $w.$f.$optid.l -side left -anchor w -fill x
215 spinbox $w.$f.$optid.v \
216 -textvariable ${f}_config_new($name) \
217 -from $min \
218 -to $max \
219 -increment 1 \
220 -width [expr {1 + [string length $max]}]
221 bind $w.$f.$optid.v <FocusIn> {%W selection range 0 end}
222 pack $w.$f.$optid.v -side right -anchor e -padx 5
223 pack $w.$f.$optid -side top -anchor w -fill x
224 }
225 t {
226 frame $w.$f.$optid
227 label $w.$f.$optid.l -text "$text:"
228 entry $w.$f.$optid.v \
229 -borderwidth 1 \
230 -relief sunken \
231 -width 20 \
232 -textvariable ${f}_config_new($name)
233 pack $w.$f.$optid.l -side left -anchor w
234 pack $w.$f.$optid.v -side left -anchor w \
235 -fill x -expand 1 \
236 -padx 5
237 pack $w.$f.$optid -side top -anchor w -fill x
238 }
239 }
240 }
241 }
243 set all_fonts [lsort [font families]]
244 foreach option $font_descs {
245 set name [lindex $option 0]
246 set font [lindex $option 1]
247 set text [lindex $option 2]
249 set global_config_new(gui.$font^^family) \
250 [font configure $font -family]
251 set global_config_new(gui.$font^^size) \
252 [font configure $font -size]
254 frame $w.global.$name
255 label $w.global.$name.l -text "$text:"
256 pack $w.global.$name.l -side left -anchor w -fill x
257 eval tk_optionMenu $w.global.$name.family \
258 global_config_new(gui.$font^^family) \
259 $all_fonts
260 spinbox $w.global.$name.size \
261 -textvariable global_config_new(gui.$font^^size) \
262 -from 2 -to 80 -increment 1 \
263 -width 3
264 bind $w.global.$name.size <FocusIn> {%W selection range 0 end}
265 pack $w.global.$name.size -side right -anchor e
266 pack $w.global.$name.family -side right -anchor e
267 pack $w.global.$name -side top -anchor w -fill x
268 }
270 bind $w <Visibility> "grab $w; focus $w.buttons.save"
271 bind $w <Key-Escape> "destroy $w"
272 bind $w <Key-Return> [list do_save_config $w]
273 wm title $w "[appname] ([reponame]): Options"
274 tkwait window $w
275 }
277 proc do_restore_defaults {} {
278 global font_descs default_config repo_config
279 global repo_config_new global_config_new
281 foreach name [array names default_config] {
282 set repo_config_new($name) $default_config($name)
283 set global_config_new($name) $default_config($name)
284 }
286 foreach option $font_descs {
287 set name [lindex $option 0]
288 set repo_config(gui.$name) $default_config(gui.$name)
289 }
290 apply_config
292 foreach option $font_descs {
293 set name [lindex $option 0]
294 set font [lindex $option 1]
295 set global_config_new(gui.$font^^family) \
296 [font configure $font -family]
297 set global_config_new(gui.$font^^size) \
298 [font configure $font -size]
299 }
300 }
302 proc do_save_config {w} {
303 if {[catch {save_config} err]} {
304 error_popup "Failed to completely save options:\n\n$err"
305 }
306 reshow_diff
307 destroy $w
308 }