git-gui/lib/merge.tcl

   1 # git-gui branch merge support
   2 # Copyright (C) 2006, 2007 Shawn Pearce
   3
   4 namespace eval merge {
   5
   6 proc _can_merge {} {
   7         global HEAD commit_type file_states
   8
   9         if {[string match amend* $commit_type]} {
  10                 info_popup {Cannot merge while amending.
  11
  12 You must finish amending this commit before starting any type of merge.
  13 }
  14                 return 0
  15         }
  16
  17         if {[committer_ident] eq {}} {return 0}
  18         if {![lock_index merge]} {return 0}
  19
  20         # -- Our in memory state should match the repository.
  21         #
  22         repository_state curType curHEAD curMERGE_HEAD
  23         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
  24                 info_popup {Last scanned state does not match repository state.
  25
  26 Another Git program has modified this repository since the last scan.  A rescan must be performed before a merge can be performed.
  27
  28 The rescan will be automatically started now.
  29 }
  30                 unlock_index
  31                 rescan {set ui_status_value {Ready.}}
  32                 return 0
  33         }
  34
  35         foreach path [array names file_states] {
  36                 switch -glob -- [lindex $file_states($path) 0] {
  37                 _O {
  38                         continue; # and pray it works!
  39                 }
  40                 U? {
  41                         error_popup "You are in the middle of a conflicted merge.
  42
  43 File [short_path $path] has merge conflicts.
  44
  45 You must resolve them, add the file, and commit to complete the current merge.  Only then can you begin another merge.
  46 "
  47                         unlock_index
  48                         return 0
  49                 }
  50                 ?? {
  51                         error_popup "You are in the middle of a change.
  52
  53 File [short_path $path] is modified.
  54
  55 You should complete the current commit before starting a merge.  Doing so will help you abort a failed merge, should the need arise.
  56 "
  57                         unlock_index
  58                         return 0
  59                 }
  60                 }
  61         }
  62
  63         return 1
  64 }
  65
  66 proc _refs {w list} {
  67         set r {}
  68         foreach i [$w.source.l curselection] {
  69                 lappend r [lindex [lindex $list $i] 0]
  70         }
  71         return $r
  72 }
  73
  74 proc _visualize {w list} {
  75         set revs [_refs $w $list]
  76         if {$revs eq {}} return
  77         lappend revs --not HEAD
  78         do_gitk $revs
  79 }
  80
  81 proc _start {w list} {
  82         global HEAD ui_status_value current_branch
  83
  84         set cmd [list git merge]
  85         set names [_refs $w $list]
  86         set revcnt [llength $names]
  87         append cmd { } $names
  88
  89         if {$revcnt == 0} {
  90                 return
  91         } elseif {$revcnt == 1} {
  92                 set unit branch
  93         } elseif {$revcnt <= 15} {
  94                 set unit branches
  95
  96                 if {[tk_dialog \
  97                 $w.confirm_octopus \
  98                 [wm title $w] \
  99                 "Use octopus merge strategy?
 100
 101 You are merging $revcnt branches at once.  This requires using the octopus merge driver, which may not succeed if there are file-level conflicts.
 102 " \
 103                 question \
 104                 0 \
 105                 {Cancel} \
 106                 {Use octopus} \
 107                 ] != 1} return
 108         } else {
 109                 tk_messageBox \
 110                         -icon error \
 111                         -type ok \
 112                         -title [wm title $w] \
 113                         -parent $w \
 114                         -message "Too many branches selected.
 115
 116 You have requested to merge $revcnt branches in an octopus merge.  This exceeds Git's internal limit of 15 branches per merge.
 117
 118 Please select fewer branches.  To merge more than 15 branches, merge the branches in batches.
 119 "
 120                 return
 121         }
 122
 123         set msg "Merging $current_branch, [join $names {, }]"
 124         set ui_status_value "$msg..."
 125         set cons [console::new "Merge" $msg]
 126         console::exec $cons $cmd \
 127                 [namespace code [list _finish $revcnt $cons]]
 128
 129         wm protocol $w WM_DELETE_WINDOW {}
 130         destroy $w
 131 }
 132
 133 proc _finish {revcnt w ok} {
 134         console::done $w $ok
 135         if {$ok} {
 136                 set msg {Merge completed successfully.}
 137         } else {
 138                 if {$revcnt != 1} {
 139                         info_popup "Octopus merge failed.
 140
 141 Your merge of $revcnt branches has failed.
 142
 143 There are file-level conflicts between the branches which must be resolved manually.
 144
 145 The working directory will now be reset.
 146
 147 You can attempt this merge again by merging only one branch at a time." $w
 148
 149                         set fd [open "| git read-tree --reset -u HEAD" r]
 150                         fconfigure $fd -blocking 0 -translation binary
 151                         fileevent $fd readable \
 152                                 [namespace code [list _reset_wait $fd]]
 153                         set ui_status_value {Aborting... please wait...}
 154                         return
 155                 }
 156
 157                 set msg {Merge failed.  Conflict resolution is required.}
 158         }
 159         unlock_index
 160         rescan [list set ui_status_value $msg]
 161 }
 162
 163 proc dialog {} {
 164         global current_branch
 165         global M1B
 166
 167         if {![_can_merge]} return
 168
 169         set fmt {list %(objectname) %(*objectname) %(refname) %(subject)}
 170         set cmd [list git for-each-ref --tcl --format=$fmt]
 171         lappend cmd refs/heads
 172         lappend cmd refs/remotes
 173         lappend cmd refs/tags
 174         set fr_fd [open "| $cmd" r]
 175         fconfigure $fr_fd -translation binary
 176         while {[gets $fr_fd line] > 0} {
 177                 set line [eval $line]
 178                 set ref [lindex $line 2]
 179                 regsub ^refs/(heads|remotes|tags)/ $ref {} ref
 180                 set subj($ref) [lindex $line 3]
 181                 lappend sha1([lindex $line 0]) $ref
 182                 if {[lindex $line 1] ne {}} {
 183                         lappend sha1([lindex $line 1]) $ref
 184                 }
 185         }
 186         close $fr_fd
 187
 188         set to_show {}
 189         set fr_fd [open "| git rev-list --all --not HEAD"]
 190         while {[gets $fr_fd line] > 0} {
 191                 if {[catch {set ref $sha1($line)}]} continue
 192                 foreach n $ref {
 193                         lappend to_show [list $n $line]
 194                 }
 195         }
 196         close $fr_fd
 197         set to_show [lsort -unique $to_show]
 198
 199         set w .merge_setup
 200         toplevel $w
 201         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
 202
 203         set _visualize [namespace code [list _visualize $w $to_show]]
 204         set _start [namespace code [list _start $w $to_show]]
 205
 206         label $w.header \
 207                 -text "Merge Into $current_branch" \
 208                 -font font_uibold
 209         pack $w.header -side top -fill x
 210
 211         frame $w.buttons
 212         button $w.buttons.visualize -text Visualize -command $_visualize
 213         pack $w.buttons.visualize -side left
 214         button $w.buttons.create -text Merge -command $_start
 215         pack $w.buttons.create -side right
 216         button $w.buttons.cancel -text {Cancel} -command [list destroy $w]
 217         pack $w.buttons.cancel -side right -padx 5
 218         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
 219
 220         labelframe $w.source -text {Source Branches}
 221         listbox $w.source.l \
 222                 -height 10 \
 223                 -width 70 \
 224                 -font font_diff \
 225                 -selectmode extended \
 226                 -yscrollcommand [list $w.source.sby set]
 227         scrollbar $w.source.sby -command [list $w.source.l yview]
 228         pack $w.source.sby -side right -fill y
 229         pack $w.source.l -side left -fill both -expand 1
 230         pack $w.source -fill both -expand 1 -pady 5 -padx 5
 231
 232         foreach ref $to_show {
 233                 set n [lindex $ref 0]
 234                 if {[string length $n] > 20} {
 235                         set n "[string range $n 0 16]..."
 236                 }
 237                 $w.source.l insert end [format {%s %-20s %s} \
 238                         [string range [lindex $ref 1] 0 5] \
 239                         $n \
 240                         $subj([lindex $ref 0])]
 241         }
 242
 243         bind $w.source.l <Key-K> [list event generate %W <Shift-Key-Up>]
 244         bind $w.source.l <Key-J> [list event generate %W <Shift-Key-Down>]
 245         bind $w.source.l <Key-k> [list event generate %W <Key-Up>]
 246         bind $w.source.l <Key-j> [list event generate %W <Key-Down>]
 247         bind $w.source.l <Key-h> [list event generate %W <Key-Left>]
 248         bind $w.source.l <Key-l> [list event generate %W <Key-Right>]
 249         bind $w.source.l <Key-v> $_visualize
 250
 251         bind $w <$M1B-Key-Return> $_start
 252         bind $w <Visibility> "grab $w; focus $w.source.l"
 253         bind $w <Key-Escape> "unlock_index;destroy $w"
 254         wm protocol $w WM_DELETE_WINDOW "unlock_index;destroy $w"
 255         wm title $w "[appname] ([reponame]): Merge"
 256         tkwait window $w
 257 }
 258
 259 proc reset_hard {} {
 260         global HEAD commit_type file_states
 261
 262         if {[string match amend* $commit_type]} {
 263                 info_popup {Cannot abort while amending.
 264
 265 You must finish amending this commit.
 266 }
 267                 return
 268         }
 269
 270         if {![lock_index abort]} return
 271
 272         if {[string match *merge* $commit_type]} {
 273                 set op merge
 274         } else {
 275                 set op commit
 276         }
 277
 278         if {[ask_popup "Abort $op?
 279
 280 Aborting the current $op will cause *ALL* uncommitted changes to be lost.
 281
 282 Continue with aborting the current $op?"] eq {yes}} {
 283                 set fd [open "| git read-tree --reset -u HEAD" r]
 284                 fconfigure $fd -blocking 0 -translation binary
 285                 fileevent $fd readable [namespace code [list _reset_wait $fd]]
 286                 set ui_status_value {Aborting... please wait...}
 287         } else {
 288                 unlock_index
 289         }
 290 }
 291
 292 proc _reset_wait {fd} {
 293         global ui_comm
 294
 295         read $fd
 296         if {[eof $fd]} {
 297                 close $fd
 298                 unlock_index
 299
 300                 $ui_comm delete 0.0 end
 301                 $ui_comm edit modified false
 302
 303                 catch {file delete [gitdir MERGE_HEAD]}
 304                 catch {file delete [gitdir rr-cache MERGE_RR]}
 305                 catch {file delete [gitdir SQUASH_MSG]}
 306                 catch {file delete [gitdir MERGE_MSG]}
 307                 catch {file delete [gitdir GITGUI_MSG]}
 308
 309                 rescan {set ui_status_value {Abort completed.  Ready.}}
 310         }
 311 }
 312
 313 }