git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file dirname [file normalize $argv0]]]
  56         set oguilib [file join $oguilib share git-gui lib]
  57         set oguimsg [file join $oguilib msgs]
  58 } elseif {[string match @@* $oguirel]} {
  59         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  60         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  61 } else {
  62         set oguimsg [file join $oguilib msgs]
  63 }
  64 unset oguirel
  65
  66 ######################################################################
  67 ##
  68 ## enable verbose loading?
  69
  70 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  71         unset _verbose
  72         rename auto_load real__auto_load
  73         proc auto_load {name args} {
  74                 puts stderr "auto_load $name"
  75                 return [uplevel 1 real__auto_load $name $args]
  76         }
  77         rename source real__source
  78         proc source {name} {
  79                 puts stderr "source    $name"
  80                 uplevel 1 real__source $name
  81         }
  82 }
  83
  84 ######################################################################
  85 ##
  86 ## Internationalization (i18n) through msgcat and gettext. See
  87 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  88
  89 package require msgcat
  90
  91 proc _mc_trim {fmt} {
  92         set cmk [string first @@ $fmt]
  93         if {$cmk > 0} {
  94                 return [string range $fmt 0 [expr {$cmk - 1}]]
  95         }
  96         return $fmt
  97 }
  98
  99 proc mc {en_fmt args} {
 100         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 101         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 102                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 103         }
 104         return $msg
 105 }
 106
 107 proc strcat {args} {
 108         return [join $args {}]
 109 }
 110
 111 ::msgcat::mcload $oguimsg
 112 unset oguimsg
 113
 114 ######################################################################
 115 ##
 116 ## read only globals
 117
 118 set _appname {Git Gui}
 119 set _gitdir {}
 120 set _gitexec {}
 121 set _reponame {}
 122 set _iscygwin {}
 123 set _search_path {}
 124
 125 proc appname {} {
 126         global _appname
 127         return $_appname
 128 }
 129
 130 proc gitdir {args} {
 131         global _gitdir
 132         if {$args eq {}} {
 133                 return $_gitdir
 134         }
 135         return [eval [list file join $_gitdir] $args]
 136 }
 137
 138 proc gitexec {args} {
 139         global _gitexec
 140         if {$_gitexec eq {}} {
 141                 if {[catch {set _gitexec [git --exec-path]} err]} {
 142                         error "Git not installed?\n\n$err"
 143                 }
 144                 if {[is_Cygwin]} {
 145                         set _gitexec [exec cygpath \
 146                                 --windows \
 147                                 --absolute \
 148                                 $_gitexec]
 149                 } else {
 150                         set _gitexec [file normalize $_gitexec]
 151                 }
 152         }
 153         if {$args eq {}} {
 154                 return $_gitexec
 155         }
 156         return [eval [list file join $_gitexec] $args]
 157 }
 158
 159 proc reponame {} {
 160         return $::_reponame
 161 }
 162
 163 proc is_MacOSX {} {
 164         if {[tk windowingsystem] eq {aqua}} {
 165                 return 1
 166         }
 167         return 0
 168 }
 169
 170 proc is_Windows {} {
 171         if {$::tcl_platform(platform) eq {windows}} {
 172                 return 1
 173         }
 174         return 0
 175 }
 176
 177 proc is_Cygwin {} {
 178         global _iscygwin
 179         if {$_iscygwin eq {}} {
 180                 if {$::tcl_platform(platform) eq {windows}} {
 181                         if {[catch {set p [exec cygpath --windir]} err]} {
 182                                 set _iscygwin 0
 183                         } else {
 184                                 set _iscygwin 1
 185                         }
 186                 } else {
 187                         set _iscygwin 0
 188                 }
 189         }
 190         return $_iscygwin
 191 }
 192
 193 proc is_enabled {option} {
 194         global enabled_options
 195         if {[catch {set on $enabled_options($option)}]} {return 0}
 196         return $on
 197 }
 198
 199 proc enable_option {option} {
 200         global enabled_options
 201         set enabled_options($option) 1
 202 }
 203
 204 proc disable_option {option} {
 205         global enabled_options
 206         set enabled_options($option) 0
 207 }
 208
 209 ######################################################################
 210 ##
 211 ## config
 212
 213 proc is_many_config {name} {
 214         switch -glob -- $name {
 215         gui.recentrepo -
 216         remote.*.fetch -
 217         remote.*.push
 218                 {return 1}
 219         *
 220                 {return 0}
 221         }
 222 }
 223
 224 proc is_config_true {name} {
 225         global repo_config
 226         if {[catch {set v $repo_config($name)}]} {
 227                 return 0
 228         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 229                 return 1
 230         } else {
 231                 return 0
 232         }
 233 }
 234
 235 proc get_config {name} {
 236         global repo_config
 237         if {[catch {set v $repo_config($name)}]} {
 238                 return {}
 239         } else {
 240                 return $v
 241         }
 242 }
 243
 244 ######################################################################
 245 ##
 246 ## handy utils
 247
 248 proc _git_cmd {name} {
 249         global _git_cmd_path
 250
 251         if {[catch {set v $_git_cmd_path($name)}]} {
 252                 switch -- $name {
 253                   version   -
 254                 --version   -
 255                 --exec-path { return [list $::_git $name] }
 256                 }
 257
 258                 set p [gitexec git-$name$::_search_exe]
 259                 if {[file exists $p]} {
 260                         set v [list $p]
 261                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 262                         # Try to determine what sort of magic will make
 263                         # git-$name go and do its thing, because native
 264                         # Tcl on Windows doesn't know it.
 265                         #
 266                         set p [gitexec git-$name]
 267                         set f [open $p r]
 268                         set s [gets $f]
 269                         close $f
 270
 271                         switch -glob -- [lindex $s 0] {
 272                         #!*sh     { set i sh     }
 273                         #!*perl   { set i perl   }
 274                         #!*python { set i python }
 275                         default   { error "git-$name is not supported: $s" }
 276                         }
 277
 278                         upvar #0 _$i interp
 279                         if {![info exists interp]} {
 280                                 set interp [_which $i]
 281                         }
 282                         if {$interp eq {}} {
 283                                 error "git-$name requires $i (not in PATH)"
 284                         }
 285                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 286                 } else {
 287                         # Assume it is builtin to git somehow and we
 288                         # aren't actually able to see a file for it.
 289                         #
 290                         set v [list $::_git $name]
 291                 }
 292                 set _git_cmd_path($name) $v
 293         }
 294         return $v
 295 }
 296
 297 proc _which {what} {
 298         global env _search_exe _search_path
 299
 300         if {$_search_path eq {}} {
 301                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 302                         set _search_path [split [exec cygpath \
 303                                 --windows \
 304                                 --path \
 305                                 --absolute \
 306                                 $env(PATH)] {;}]
 307                         set _search_exe .exe
 308                 } elseif {[is_Windows]} {
 309                         set gitguidir [file dirname [info script]]
 310                         regsub -all ";" $gitguidir "\\;" gitguidir
 311                         set env(PATH) "$gitguidir;$env(PATH)"
 312                         set _search_path [split $env(PATH) {;}]
 313                         set _search_exe .exe
 314                 } else {
 315                         set _search_path [split $env(PATH) :]
 316                         set _search_exe {}
 317                 }
 318         }
 319
 320         foreach p $_search_path {
 321                 set p [file join $p $what$_search_exe]
 322                 if {[file exists $p]} {
 323                         return [file normalize $p]
 324                 }
 325         }
 326         return {}
 327 }
 328
 329 proc _lappend_nice {cmd_var} {
 330         global _nice
 331         upvar $cmd_var cmd
 332
 333         if {![info exists _nice]} {
 334                 set _nice [_which nice]
 335         }
 336         if {$_nice ne {}} {
 337                 lappend cmd $_nice
 338         }
 339 }
 340
 341 proc git {args} {
 342         set opt [list exec]
 343
 344         while {1} {
 345                 switch -- [lindex $args 0] {
 346                 --nice {
 347                         _lappend_nice opt
 348                 }
 349
 350                 default {
 351                         break
 352                 }
 353
 354                 }
 355
 356                 set args [lrange $args 1 end]
 357         }
 358
 359         set cmdp [_git_cmd [lindex $args 0]]
 360         set args [lrange $args 1 end]
 361
 362         return [eval $opt $cmdp $args]
 363 }
 364
 365 proc _open_stdout_stderr {cmd} {
 366         if {[catch {
 367                         set fd [open $cmd r]
 368                 } err]} {
 369                 if {   [lindex $cmd end] eq {2>@1}
 370                     && $err eq {can not find channel named "1"}
 371                         } {
 372                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 373                         # redirect operator.  Fallback to |& cat for those.
 374                         # The command was not actually started, so its safe
 375                         # to try to start it a second time.
 376                         #
 377                         set fd [open [concat \
 378                                 [lrange $cmd 0 end-1] \
 379                                 [list |& cat] \
 380                                 ] r]
 381                 } else {
 382                         error $err
 383                 }
 384         }
 385         fconfigure $fd -eofchar {}
 386         return $fd
 387 }
 388
 389 proc git_read {args} {
 390         set opt [list |]
 391
 392         while {1} {
 393                 switch -- [lindex $args 0] {
 394                 --nice {
 395                         _lappend_nice opt
 396                 }
 397
 398                 --stderr {
 399                         lappend args 2>@1
 400                 }
 401
 402                 default {
 403                         break
 404                 }
 405
 406                 }
 407
 408                 set args [lrange $args 1 end]
 409         }
 410
 411         set cmdp [_git_cmd [lindex $args 0]]
 412         set args [lrange $args 1 end]
 413
 414         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 415 }
 416
 417 proc git_write {args} {
 418         set opt [list |]
 419
 420         while {1} {
 421                 switch -- [lindex $args 0] {
 422                 --nice {
 423                         _lappend_nice opt
 424                 }
 425
 426                 default {
 427                         break
 428                 }
 429
 430                 }
 431
 432                 set args [lrange $args 1 end]
 433         }
 434
 435         set cmdp [_git_cmd [lindex $args 0]]
 436         set args [lrange $args 1 end]
 437
 438         return [open [concat $opt $cmdp $args] w]
 439 }
 440
 441 proc githook_read {hook_name args} {
 442         set pchook [gitdir hooks $hook_name]
 443         lappend args 2>@1
 444
 445         # On Cygwin [file executable] might lie so we need to ask
 446         # the shell if the hook is executable.  Yes that's annoying.
 447         #
 448         if {[is_Cygwin]} {
 449                 upvar #0 _sh interp
 450                 if {![info exists interp]} {
 451                         set interp [_which sh]
 452                 }
 453                 if {$interp eq {}} {
 454                         error "hook execution requires sh (not in PATH)"
 455                 }
 456
 457                 set scr {if test -x "$1";then exec "$@";fi}
 458                 set sh_c [list | $interp -c $scr $interp $pchook]
 459                 return [_open_stdout_stderr [concat $sh_c $args]]
 460         }
 461
 462         if {[file executable $pchook]} {
 463                 return [_open_stdout_stderr [concat [list | $pchook] $args]]
 464         }
 465
 466         return {}
 467 }
 468
 469 proc sq {value} {
 470         regsub -all ' $value "'\\''" value
 471         return "'$value'"
 472 }
 473
 474 proc load_current_branch {} {
 475         global current_branch is_detached
 476
 477         set fd [open [gitdir HEAD] r]
 478         if {[gets $fd ref] < 1} {
 479                 set ref {}
 480         }
 481         close $fd
 482
 483         set pfx {ref: refs/heads/}
 484         set len [string length $pfx]
 485         if {[string equal -length $len $pfx $ref]} {
 486                 # We're on a branch.  It might not exist.  But
 487                 # HEAD looks good enough to be a branch.
 488                 #
 489                 set current_branch [string range $ref $len end]
 490                 set is_detached 0
 491         } else {
 492                 # Assume this is a detached head.
 493                 #
 494                 set current_branch HEAD
 495                 set is_detached 1
 496         }
 497 }
 498
 499 auto_load tk_optionMenu
 500 rename tk_optionMenu real__tkOptionMenu
 501 proc tk_optionMenu {w varName args} {
 502         set m [eval real__tkOptionMenu $w $varName $args]
 503         $m configure -font font_ui
 504         $w configure -font font_ui
 505         return $m
 506 }
 507
 508 proc rmsel_tag {text} {
 509         $text tag conf sel \
 510                 -background [$text cget -background] \
 511                 -foreground [$text cget -foreground] \
 512                 -borderwidth 0
 513         $text tag conf in_sel -background lightgray
 514         bind $text <Motion> break
 515         return $text
 516 }
 517
 518 set root_exists 0
 519 bind . <Visibility> {
 520         bind . <Visibility> {}
 521         set root_exists 1
 522 }
 523
 524 if {[is_Windows]} {
 525         wm iconbitmap . -default $oguilib/git-gui.ico
 526 }
 527
 528 ######################################################################
 529 ##
 530 ## config defaults
 531
 532 set cursor_ptr arrow
 533 font create font_diff -family Courier -size 10
 534 font create font_ui
 535 catch {
 536         label .dummy
 537         eval font configure font_ui [font actual [.dummy cget -font]]
 538         destroy .dummy
 539 }
 540
 541 font create font_uiitalic
 542 font create font_uibold
 543 font create font_diffbold
 544 font create font_diffitalic
 545
 546 foreach class {Button Checkbutton Entry Label
 547                 Labelframe Listbox Menu Message
 548                 Radiobutton Spinbox Text} {
 549         option add *$class.font font_ui
 550 }
 551 unset class
 552
 553 if {[is_Windows] || [is_MacOSX]} {
 554         option add *Menu.tearOff 0
 555 }
 556
 557 if {[is_MacOSX]} {
 558         set M1B M1
 559         set M1T Cmd
 560 } else {
 561         set M1B Control
 562         set M1T Ctrl
 563 }
 564
 565 proc bind_button3 {w cmd} {
 566         bind $w <Any-Button-3> $cmd
 567         if {[is_MacOSX]} {
 568                 # Mac OS X sends Button-2 on right click through three-button mouse,
 569                 # or through trackpad right-clicking (two-finger touch + click).
 570                 bind $w <Any-Button-2> $cmd
 571                 bind $w <Control-Button-1> $cmd
 572         }
 573 }
 574
 575 proc apply_config {} {
 576         global repo_config font_descs
 577
 578         foreach option $font_descs {
 579                 set name [lindex $option 0]
 580                 set font [lindex $option 1]
 581                 if {[catch {
 582                         set need_weight 1
 583                         foreach {cn cv} $repo_config(gui.$name) {
 584                                 if {$cn eq {-weight}} {
 585                                         set need_weight 0
 586                                 }
 587                                 font configure $font $cn $cv
 588                         }
 589                         if {$need_weight} {
 590                                 font configure $font -weight normal
 591                         }
 592                         } err]} {
 593                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 594                 }
 595                 foreach {cn cv} [font configure $font] {
 596                         font configure ${font}bold $cn $cv
 597                         font configure ${font}italic $cn $cv
 598                 }
 599                 font configure ${font}bold -weight bold
 600                 font configure ${font}italic -slant italic
 601         }
 602 }
 603
 604 set default_config(merge.diffstat) true
 605 set default_config(merge.summary) false
 606 set default_config(merge.verbosity) 2
 607 set default_config(user.name) {}
 608 set default_config(user.email) {}
 609
 610 set default_config(gui.matchtrackingbranch) false
 611 set default_config(gui.pruneduringfetch) false
 612 set default_config(gui.trustmtime) false
 613 set default_config(gui.diffcontext) 5
 614 set default_config(gui.commitmsgwidth) 75
 615 set default_config(gui.newbranchtemplate) {}
 616 set default_config(gui.spellingdictionary) {}
 617 set default_config(gui.fontui) [font configure font_ui]
 618 set default_config(gui.fontdiff) [font configure font_diff]
 619 set font_descs {
 620         {fontui   font_ui   {mc "Main Font"}}
 621         {fontdiff font_diff {mc "Diff/Console Font"}}
 622 }
 623
 624 ######################################################################
 625 ##
 626 ## find git
 627
 628 set _git  [_which git]
 629 if {$_git eq {}} {
 630         catch {wm withdraw .}
 631         tk_messageBox \
 632                 -icon error \
 633                 -type ok \
 634                 -title [mc "git-gui: fatal error"] \
 635                 -message [mc "Cannot find git in PATH."]
 636         exit 1
 637 }
 638
 639 ######################################################################
 640 ##
 641 ## version check
 642
 643 if {[catch {set _git_version [git --version]} err]} {
 644         catch {wm withdraw .}
 645         tk_messageBox \
 646                 -icon error \
 647                 -type ok \
 648                 -title [mc "git-gui: fatal error"] \
 649                 -message "Cannot determine Git version:
 650
 651 $err
 652
 653 [appname] requires Git 1.5.0 or later."
 654         exit 1
 655 }
 656 if {![regsub {^git version } $_git_version {} _git_version]} {
 657         catch {wm withdraw .}
 658         tk_messageBox \
 659                 -icon error \
 660                 -type ok \
 661                 -title [mc "git-gui: fatal error"] \
 662                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 663         exit 1
 664 }
 665
 666 set _real_git_version $_git_version
 667 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 668 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 669 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 670 regsub {\.GIT$} $_git_version {} _git_version
 671 regsub {\.[a-zA-Z]+\.[0-9]+$} $_git_version {} _git_version
 672
 673 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 674         catch {wm withdraw .}
 675         if {[tk_messageBox \
 676                 -icon warning \
 677                 -type yesno \
 678                 -default no \
 679                 -title "[appname]: warning" \
 680                  -message [mc "Git version cannot be determined.
 681
 682 %s claims it is version '%s'.
 683
 684 %s requires at least Git 1.5.0 or later.
 685
 686 Assume '%s' is version 1.5.0?
 687 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 688                 set _git_version 1.5.0
 689         } else {
 690                 exit 1
 691         }
 692 }
 693 unset _real_git_version
 694
 695 proc git-version {args} {
 696         global _git_version
 697
 698         switch [llength $args] {
 699         0 {
 700                 return $_git_version
 701         }
 702
 703         2 {
 704                 set op [lindex $args 0]
 705                 set vr [lindex $args 1]
 706                 set cm [package vcompare $_git_version $vr]
 707                 return [expr $cm $op 0]
 708         }
 709
 710         4 {
 711                 set type [lindex $args 0]
 712                 set name [lindex $args 1]
 713                 set parm [lindex $args 2]
 714                 set body [lindex $args 3]
 715
 716                 if {($type ne {proc} && $type ne {method})} {
 717                         error "Invalid arguments to git-version"
 718                 }
 719                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 720                         error "Last arm of $type $name must be default"
 721                 }
 722
 723                 foreach {op vr cb} [lrange $body 0 end-2] {
 724                         if {[git-version $op $vr]} {
 725                                 return [uplevel [list $type $name $parm $cb]]
 726                         }
 727                 }
 728
 729                 return [uplevel [list $type $name $parm [lindex $body end]]]
 730         }
 731
 732         default {
 733                 error "git-version >= x"
 734         }
 735
 736         }
 737 }
 738
 739 if {[git-version < 1.5]} {
 740         catch {wm withdraw .}
 741         tk_messageBox \
 742                 -icon error \
 743                 -type ok \
 744                 -title [mc "git-gui: fatal error"] \
 745                 -message "[appname] requires Git 1.5.0 or later.
 746
 747 You are using [git-version]:
 748
 749 [git --version]"
 750         exit 1
 751 }
 752
 753 ######################################################################
 754 ##
 755 ## configure our library
 756
 757 set idx [file join $oguilib tclIndex]
 758 if {[catch {set fd [open $idx r]} err]} {
 759         catch {wm withdraw .}
 760         tk_messageBox \
 761                 -icon error \
 762                 -type ok \
 763                 -title [mc "git-gui: fatal error"] \
 764                 -message $err
 765         exit 1
 766 }
 767 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 768         set idx [list]
 769         while {[gets $fd n] >= 0} {
 770                 if {$n ne {} && ![string match #* $n]} {
 771                         lappend idx $n
 772                 }
 773         }
 774 } else {
 775         set idx {}
 776 }
 777 close $fd
 778
 779 if {$idx ne {}} {
 780         set loaded [list]
 781         foreach p $idx {
 782                 if {[lsearch -exact $loaded $p] >= 0} continue
 783                 source [file join $oguilib $p]
 784                 lappend loaded $p
 785         }
 786         unset loaded p
 787 } else {
 788         set auto_path [concat [list $oguilib] $auto_path]
 789 }
 790 unset -nocomplain idx fd
 791
 792 ######################################################################
 793 ##
 794 ## config file parsing
 795
 796 git-version proc _parse_config {arr_name args} {
 797         >= 1.5.3 {
 798                 upvar $arr_name arr
 799                 array unset arr
 800                 set buf {}
 801                 catch {
 802                         set fd_rc [eval \
 803                                 [list git_read config] \
 804                                 $args \
 805                                 [list --null --list]]
 806                         fconfigure $fd_rc -translation binary
 807                         set buf [read $fd_rc]
 808                         close $fd_rc
 809                 }
 810                 foreach line [split $buf "\0"] {
 811                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 812                                 if {[is_many_config $name]} {
 813                                         lappend arr($name) $value
 814                                 } else {
 815                                         set arr($name) $value
 816                                 }
 817                         }
 818                 }
 819         }
 820         default {
 821                 upvar $arr_name arr
 822                 array unset arr
 823                 catch {
 824                         set fd_rc [eval [list git_read config --list] $args]
 825                         while {[gets $fd_rc line] >= 0} {
 826                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 827                                         if {[is_many_config $name]} {
 828                                                 lappend arr($name) $value
 829                                         } else {
 830                                                 set arr($name) $value
 831                                         }
 832                                 }
 833                         }
 834                         close $fd_rc
 835                 }
 836         }
 837 }
 838
 839 proc load_config {include_global} {
 840         global repo_config global_config default_config
 841
 842         if {$include_global} {
 843                 _parse_config global_config --global
 844         }
 845         _parse_config repo_config
 846
 847         foreach name [array names default_config] {
 848                 if {[catch {set v $global_config($name)}]} {
 849                         set global_config($name) $default_config($name)
 850                 }
 851                 if {[catch {set v $repo_config($name)}]} {
 852                         set repo_config($name) $default_config($name)
 853                 }
 854         }
 855 }
 856
 857 ######################################################################
 858 ##
 859 ## feature option selection
 860
 861 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
 862         unset _junk
 863 } else {
 864         set subcommand gui
 865 }
 866 if {$subcommand eq {gui.sh}} {
 867         set subcommand gui
 868 }
 869 if {$subcommand eq {gui} && [llength $argv] > 0} {
 870         set subcommand [lindex $argv 0]
 871         set argv [lrange $argv 1 end]
 872 }
 873
 874 enable_option multicommit
 875 enable_option branch
 876 enable_option transport
 877 disable_option bare
 878
 879 switch -- $subcommand {
 880 browser -
 881 blame {
 882         enable_option bare
 883
 884         disable_option multicommit
 885         disable_option branch
 886         disable_option transport
 887 }
 888 citool {
 889         enable_option singlecommit
 890
 891         disable_option multicommit
 892         disable_option branch
 893         disable_option transport
 894 }
 895 }
 896
 897 ######################################################################
 898 ##
 899 ## repository setup
 900
 901 if {[catch {
 902                 set _gitdir $env(GIT_DIR)
 903                 set _prefix {}
 904                 }]
 905         && [catch {
 906                 set _gitdir [git rev-parse --git-dir]
 907                 set _prefix [git rev-parse --show-prefix]
 908         } err]} {
 909         load_config 1
 910         apply_config
 911         choose_repository::pick
 912 }
 913 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 914         catch {set _gitdir [exec cygpath --windows $_gitdir]}
 915 }
 916 if {![file isdirectory $_gitdir]} {
 917         catch {wm withdraw .}
 918         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
 919         exit 1
 920 }
 921 if {$_prefix ne {}} {
 922         regsub -all {[^/]+/} $_prefix ../ cdup
 923         if {[catch {cd $cdup} err]} {
 924                 catch {wm withdraw .}
 925                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
 926                 exit 1
 927         }
 928         unset cdup
 929 } elseif {![is_enabled bare]} {
 930         if {[lindex [file split $_gitdir] end] ne {.git}} {
 931                 catch {wm withdraw .}
 932                 error_popup [strcat [mc "Cannot use funny .git directory:"] "\n\n$_gitdir"]
 933                 exit 1
 934         }
 935         if {[catch {cd [file dirname $_gitdir]} err]} {
 936                 catch {wm withdraw .}
 937                 error_popup [strcat [mc "No working directory"] " [file dirname $_gitdir]:\n\n$err"]
 938                 exit 1
 939         }
 940 }
 941 set _reponame [file split [file normalize $_gitdir]]
 942 if {[lindex $_reponame end] eq {.git}} {
 943         set _reponame [lindex $_reponame end-1]
 944 } else {
 945         set _reponame [lindex $_reponame end]
 946 }
 947
 948 ######################################################################
 949 ##
 950 ## global init
 951
 952 set current_diff_path {}
 953 set current_diff_side {}
 954 set diff_actions [list]
 955
 956 set HEAD {}
 957 set PARENT {}
 958 set MERGE_HEAD [list]
 959 set commit_type {}
 960 set empty_tree {}
 961 set current_branch {}
 962 set is_detached 0
 963 set current_diff_path {}
 964 set is_3way_diff 0
 965 set selected_commit_type new
 966
 967 ######################################################################
 968 ##
 969 ## task management
 970
 971 set rescan_active 0
 972 set diff_active 0
 973 set last_clicked {}
 974
 975 set disable_on_lock [list]
 976 set index_lock_type none
 977
 978 proc lock_index {type} {
 979         global index_lock_type disable_on_lock
 980
 981         if {$index_lock_type eq {none}} {
 982                 set index_lock_type $type
 983                 foreach w $disable_on_lock {
 984                         uplevel #0 $w disabled
 985                 }
 986                 return 1
 987         } elseif {$index_lock_type eq "begin-$type"} {
 988                 set index_lock_type $type
 989                 return 1
 990         }
 991         return 0
 992 }
 993
 994 proc unlock_index {} {
 995         global index_lock_type disable_on_lock
 996
 997         set index_lock_type none
 998         foreach w $disable_on_lock {
 999                 uplevel #0 $w normal
1000         }
1001 }
1002
1003 ######################################################################
1004 ##
1005 ## status
1006
1007 proc repository_state {ctvar hdvar mhvar} {
1008         global current_branch
1009         upvar $ctvar ct $hdvar hd $mhvar mh
1010
1011         set mh [list]
1012
1013         load_current_branch
1014         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1015                 set hd {}
1016                 set ct initial
1017                 return
1018         }
1019
1020         set merge_head [gitdir MERGE_HEAD]
1021         if {[file exists $merge_head]} {
1022                 set ct merge
1023                 set fd_mh [open $merge_head r]
1024                 while {[gets $fd_mh line] >= 0} {
1025                         lappend mh $line
1026                 }
1027                 close $fd_mh
1028                 return
1029         }
1030
1031         set ct normal
1032 }
1033
1034 proc PARENT {} {
1035         global PARENT empty_tree
1036
1037         set p [lindex $PARENT 0]
1038         if {$p ne {}} {
1039                 return $p
1040         }
1041         if {$empty_tree eq {}} {
1042                 set empty_tree [git mktree << {}]
1043         }
1044         return $empty_tree
1045 }
1046
1047 proc rescan {after {honor_trustmtime 1}} {
1048         global HEAD PARENT MERGE_HEAD commit_type
1049         global ui_index ui_workdir ui_comm
1050         global rescan_active file_states
1051         global repo_config
1052
1053         if {$rescan_active > 0 || ![lock_index read]} return
1054
1055         repository_state newType newHEAD newMERGE_HEAD
1056         if {[string match amend* $commit_type]
1057                 && $newType eq {normal}
1058                 && $newHEAD eq $HEAD} {
1059         } else {
1060                 set HEAD $newHEAD
1061                 set PARENT $newHEAD
1062                 set MERGE_HEAD $newMERGE_HEAD
1063                 set commit_type $newType
1064         }
1065
1066         array unset file_states
1067
1068         if {!$::GITGUI_BCK_exists &&
1069                 (![$ui_comm edit modified]
1070                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1071                 if {[string match amend* $commit_type]} {
1072                 } elseif {[load_message GITGUI_MSG]} {
1073                 } elseif {[load_message MERGE_MSG]} {
1074                 } elseif {[load_message SQUASH_MSG]} {
1075                 }
1076                 $ui_comm edit reset
1077                 $ui_comm edit modified false
1078         }
1079
1080         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1081                 rescan_stage2 {} $after
1082         } else {
1083                 set rescan_active 1
1084                 ui_status [mc "Refreshing file status..."]
1085                 set fd_rf [git_read update-index \
1086                         -q \
1087                         --unmerged \
1088                         --ignore-missing \
1089                         --refresh \
1090                         ]
1091                 fconfigure $fd_rf -blocking 0 -translation binary
1092                 fileevent $fd_rf readable \
1093                         [list rescan_stage2 $fd_rf $after]
1094         }
1095 }
1096
1097 if {[is_Cygwin]} {
1098         set is_git_info_link {}
1099         set is_git_info_exclude {}
1100         proc have_info_exclude {} {
1101                 global is_git_info_link is_git_info_exclude
1102
1103                 if {$is_git_info_link eq {}} {
1104                         set is_git_info_link [file isfile [gitdir info.lnk]]
1105                 }
1106
1107                 if {$is_git_info_link} {
1108                         if {$is_git_info_exclude eq {}} {
1109                                 if {[catch {exec test -f [gitdir info exclude]}]} {
1110                                         set is_git_info_exclude 0
1111                                 } else {
1112                                         set is_git_info_exclude 1
1113                                 }
1114                         }
1115                         return $is_git_info_exclude
1116                 } else {
1117                         return [file readable [gitdir info exclude]]
1118                 }
1119         }
1120 } else {
1121         proc have_info_exclude {} {
1122                 return [file readable [gitdir info exclude]]
1123         }
1124 }
1125
1126 proc rescan_stage2 {fd after} {
1127         global rescan_active buf_rdi buf_rdf buf_rlo
1128
1129         if {$fd ne {}} {
1130                 read $fd
1131                 if {![eof $fd]} return
1132                 close $fd
1133         }
1134
1135         set ls_others [list --exclude-per-directory=.gitignore]
1136         if {[have_info_exclude]} {
1137                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1138         }
1139         set user_exclude [get_config core.excludesfile]
1140         if {$user_exclude ne {} && [file readable $user_exclude]} {
1141                 lappend ls_others "--exclude-from=$user_exclude"
1142         }
1143
1144         set buf_rdi {}
1145         set buf_rdf {}
1146         set buf_rlo {}
1147
1148         set rescan_active 3
1149         ui_status [mc "Scanning for modified files ..."]
1150         set fd_di [git_read diff-index --cached -z [PARENT]]
1151         set fd_df [git_read diff-files -z]
1152         set fd_lo [eval git_read ls-files --others -z $ls_others]
1153
1154         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1155         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1156         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1157         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1158         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1159         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1160 }
1161
1162 proc load_message {file} {
1163         global ui_comm
1164
1165         set f [gitdir $file]
1166         if {[file isfile $f]} {
1167                 if {[catch {set fd [open $f r]}]} {
1168                         return 0
1169                 }
1170                 fconfigure $fd -eofchar {}
1171                 set content [string trim [read $fd]]
1172                 close $fd
1173                 regsub -all -line {[ \r\t]+$} $content {} content
1174                 $ui_comm delete 0.0 end
1175                 $ui_comm insert end $content
1176                 return 1
1177         }
1178         return 0
1179 }
1180
1181 proc read_diff_index {fd after} {
1182         global buf_rdi
1183
1184         append buf_rdi [read $fd]
1185         set c 0
1186         set n [string length $buf_rdi]
1187         while {$c < $n} {
1188                 set z1 [string first "\0" $buf_rdi $c]
1189                 if {$z1 == -1} break
1190                 incr z1
1191                 set z2 [string first "\0" $buf_rdi $z1]
1192                 if {$z2 == -1} break
1193
1194                 incr c
1195                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1196                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1197                 merge_state \
1198                         [encoding convertfrom $p] \
1199                         [lindex $i 4]? \
1200                         [list [lindex $i 0] [lindex $i 2]] \
1201                         [list]
1202                 set c $z2
1203                 incr c
1204         }
1205         if {$c < $n} {
1206                 set buf_rdi [string range $buf_rdi $c end]
1207         } else {
1208                 set buf_rdi {}
1209         }
1210
1211         rescan_done $fd buf_rdi $after
1212 }
1213
1214 proc read_diff_files {fd after} {
1215         global buf_rdf
1216
1217         append buf_rdf [read $fd]
1218         set c 0
1219         set n [string length $buf_rdf]
1220         while {$c < $n} {
1221                 set z1 [string first "\0" $buf_rdf $c]
1222                 if {$z1 == -1} break
1223                 incr z1
1224                 set z2 [string first "\0" $buf_rdf $z1]
1225                 if {$z2 == -1} break
1226
1227                 incr c
1228                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1229                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1230                 merge_state \
1231                         [encoding convertfrom $p] \
1232                         ?[lindex $i 4] \
1233                         [list] \
1234                         [list [lindex $i 0] [lindex $i 2]]
1235                 set c $z2
1236                 incr c
1237         }
1238         if {$c < $n} {
1239                 set buf_rdf [string range $buf_rdf $c end]
1240         } else {
1241                 set buf_rdf {}
1242         }
1243
1244         rescan_done $fd buf_rdf $after
1245 }
1246
1247 proc read_ls_others {fd after} {
1248         global buf_rlo
1249
1250         append buf_rlo [read $fd]
1251         set pck [split $buf_rlo "\0"]
1252         set buf_rlo [lindex $pck end]
1253         foreach p [lrange $pck 0 end-1] {
1254                 set p [encoding convertfrom $p]
1255                 if {[string index $p end] eq {/}} {
1256                         set p [string range $p 0 end-1]
1257                 }
1258                 merge_state $p ?O
1259         }
1260         rescan_done $fd buf_rlo $after
1261 }
1262
1263 proc rescan_done {fd buf after} {
1264         global rescan_active current_diff_path
1265         global file_states repo_config
1266         upvar $buf to_clear
1267
1268         if {![eof $fd]} return
1269         set to_clear {}
1270         close $fd
1271         if {[incr rescan_active -1] > 0} return
1272
1273         prune_selection
1274         unlock_index
1275         display_all_files
1276         if {$current_diff_path ne {}} reshow_diff
1277         uplevel #0 $after
1278 }
1279
1280 proc prune_selection {} {
1281         global file_states selected_paths
1282
1283         foreach path [array names selected_paths] {
1284                 if {[catch {set still_here $file_states($path)}]} {
1285                         unset selected_paths($path)
1286                 }
1287         }
1288 }
1289
1290 ######################################################################
1291 ##
1292 ## ui helpers
1293
1294 proc mapicon {w state path} {
1295         global all_icons
1296
1297         if {[catch {set r $all_icons($state$w)}]} {
1298                 puts "error: no icon for $w state={$state} $path"
1299                 return file_plain
1300         }
1301         return $r
1302 }
1303
1304 proc mapdesc {state path} {
1305         global all_descs
1306
1307         if {[catch {set r $all_descs($state)}]} {
1308                 puts "error: no desc for state={$state} $path"
1309                 return $state
1310         }
1311         return $r
1312 }
1313
1314 proc ui_status {msg} {
1315         global main_status
1316         if {[info exists main_status]} {
1317                 $main_status show $msg
1318         }
1319 }
1320
1321 proc ui_ready {{test {}}} {
1322         global main_status
1323         if {[info exists main_status]} {
1324                 $main_status show [mc "Ready."] $test
1325         }
1326 }
1327
1328 proc escape_path {path} {
1329         regsub -all {\\} $path "\\\\" path
1330         regsub -all "\n" $path "\\n" path
1331         return $path
1332 }
1333
1334 proc short_path {path} {
1335         return [escape_path [lindex [file split $path] end]]
1336 }
1337
1338 set next_icon_id 0
1339 set null_sha1 [string repeat 0 40]
1340
1341 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1342         global file_states next_icon_id null_sha1
1343
1344         set s0 [string index $new_state 0]
1345         set s1 [string index $new_state 1]
1346
1347         if {[catch {set info $file_states($path)}]} {
1348                 set state __
1349                 set icon n[incr next_icon_id]
1350         } else {
1351                 set state [lindex $info 0]
1352                 set icon [lindex $info 1]
1353                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1354                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1355         }
1356
1357         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1358         elseif {$s0 eq {_}} {set s0 _}
1359
1360         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1361         elseif {$s1 eq {_}} {set s1 _}
1362
1363         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1364                 set head_info [list 0 $null_sha1]
1365         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1366                 && $head_info eq {}} {
1367                 set head_info $index_info
1368         }
1369
1370         set file_states($path) [list $s0$s1 $icon \
1371                 $head_info $index_info \
1372                 ]
1373         return $state
1374 }
1375
1376 proc display_file_helper {w path icon_name old_m new_m} {
1377         global file_lists
1378
1379         if {$new_m eq {_}} {
1380                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1381                 if {$lno >= 0} {
1382                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1383                         incr lno
1384                         $w conf -state normal
1385                         $w delete $lno.0 [expr {$lno + 1}].0
1386                         $w conf -state disabled
1387                 }
1388         } elseif {$old_m eq {_} && $new_m ne {_}} {
1389                 lappend file_lists($w) $path
1390                 set file_lists($w) [lsort -unique $file_lists($w)]
1391                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1392                 incr lno
1393                 $w conf -state normal
1394                 $w image create $lno.0 \
1395                         -align center -padx 5 -pady 1 \
1396                         -name $icon_name \
1397                         -image [mapicon $w $new_m $path]
1398                 $w insert $lno.1 "[escape_path $path]\n"
1399                 $w conf -state disabled
1400         } elseif {$old_m ne $new_m} {
1401                 $w conf -state normal
1402                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1403                 $w conf -state disabled
1404         }
1405 }
1406
1407 proc display_file {path state} {
1408         global file_states selected_paths
1409         global ui_index ui_workdir
1410
1411         set old_m [merge_state $path $state]
1412         set s $file_states($path)
1413         set new_m [lindex $s 0]
1414         set icon_name [lindex $s 1]
1415
1416         set o [string index $old_m 0]
1417         set n [string index $new_m 0]
1418         if {$o eq {U}} {
1419                 set o _
1420         }
1421         if {$n eq {U}} {
1422                 set n _
1423         }
1424         display_file_helper     $ui_index $path $icon_name $o $n
1425
1426         if {[string index $old_m 0] eq {U}} {
1427                 set o U
1428         } else {
1429                 set o [string index $old_m 1]
1430         }
1431         if {[string index $new_m 0] eq {U}} {
1432                 set n U
1433         } else {
1434                 set n [string index $new_m 1]
1435         }
1436         display_file_helper     $ui_workdir $path $icon_name $o $n
1437
1438         if {$new_m eq {__}} {
1439                 unset file_states($path)
1440                 catch {unset selected_paths($path)}
1441         }
1442 }
1443
1444 proc display_all_files_helper {w path icon_name m} {
1445         global file_lists
1446
1447         lappend file_lists($w) $path
1448         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1449         $w image create end \
1450                 -align center -padx 5 -pady 1 \
1451                 -name $icon_name \
1452                 -image [mapicon $w $m $path]
1453         $w insert end "[escape_path $path]\n"
1454 }
1455
1456 proc display_all_files {} {
1457         global ui_index ui_workdir
1458         global file_states file_lists
1459         global last_clicked
1460
1461         $ui_index conf -state normal
1462         $ui_workdir conf -state normal
1463
1464         $ui_index delete 0.0 end
1465         $ui_workdir delete 0.0 end
1466         set last_clicked {}
1467
1468         set file_lists($ui_index) [list]
1469         set file_lists($ui_workdir) [list]
1470
1471         foreach path [lsort [array names file_states]] {
1472                 set s $file_states($path)
1473                 set m [lindex $s 0]
1474                 set icon_name [lindex $s 1]
1475
1476                 set s [string index $m 0]
1477                 if {$s ne {U} && $s ne {_}} {
1478                         display_all_files_helper $ui_index $path \
1479                                 $icon_name $s
1480                 }
1481
1482                 if {[string index $m 0] eq {U}} {
1483                         set s U
1484                 } else {
1485                         set s [string index $m 1]
1486                 }
1487                 if {$s ne {_}} {
1488                         display_all_files_helper $ui_workdir $path \
1489                                 $icon_name $s
1490                 }
1491         }
1492
1493         $ui_index conf -state disabled
1494         $ui_workdir conf -state disabled
1495 }
1496
1497 ######################################################################
1498 ##
1499 ## icons
1500
1501 set filemask {
1502 #define mask_width 14
1503 #define mask_height 15
1504 static unsigned char mask_bits[] = {
1505    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1506    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1507    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1508 }
1509
1510 image create bitmap file_plain -background white -foreground black -data {
1511 #define plain_width 14
1512 #define plain_height 15
1513 static unsigned char plain_bits[] = {
1514    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1515    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1516    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1517 } -maskdata $filemask
1518
1519 image create bitmap file_mod -background white -foreground blue -data {
1520 #define mod_width 14
1521 #define mod_height 15
1522 static unsigned char mod_bits[] = {
1523    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1524    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1525    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1526 } -maskdata $filemask
1527
1528 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1529 #define file_fulltick_width 14
1530 #define file_fulltick_height 15
1531 static unsigned char file_fulltick_bits[] = {
1532    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1533    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1534    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1535 } -maskdata $filemask
1536
1537 image create bitmap file_parttick -background white -foreground "#005050" -data {
1538 #define parttick_width 14
1539 #define parttick_height 15
1540 static unsigned char parttick_bits[] = {
1541    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1542    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
1543    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1544 } -maskdata $filemask
1545
1546 image create bitmap file_question -background white -foreground black -data {
1547 #define file_question_width 14
1548 #define file_question_height 15
1549 static unsigned char file_question_bits[] = {
1550    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1551    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1552    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1553 } -maskdata $filemask
1554
1555 image create bitmap file_removed -background white -foreground red -data {
1556 #define file_removed_width 14
1557 #define file_removed_height 15
1558 static unsigned char file_removed_bits[] = {
1559    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1560    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1561    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1562 } -maskdata $filemask
1563
1564 image create bitmap file_merge -background white -foreground blue -data {
1565 #define file_merge_width 14
1566 #define file_merge_height 15
1567 static unsigned char file_merge_bits[] = {
1568    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1569    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1570    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1571 } -maskdata $filemask
1572
1573 set ui_index .vpane.files.index.list
1574 set ui_workdir .vpane.files.workdir.list
1575
1576 set all_icons(_$ui_index)   file_plain
1577 set all_icons(A$ui_index)   file_fulltick
1578 set all_icons(M$ui_index)   file_fulltick
1579 set all_icons(D$ui_index)   file_removed
1580 set all_icons(U$ui_index)   file_merge
1581
1582 set all_icons(_$ui_workdir) file_plain
1583 set all_icons(M$ui_workdir) file_mod
1584 set all_icons(D$ui_workdir) file_question
1585 set all_icons(U$ui_workdir) file_merge
1586 set all_icons(O$ui_workdir) file_plain
1587
1588 set max_status_desc 0
1589 foreach i {
1590                 {__ {mc "Unmodified"}}
1591
1592                 {_M {mc "Modified, not staged"}}
1593                 {M_ {mc "Staged for commit"}}
1594                 {MM {mc "Portions staged for commit"}}
1595                 {MD {mc "Staged for commit, missing"}}
1596
1597                 {_O {mc "Untracked, not staged"}}
1598                 {A_ {mc "Staged for commit"}}
1599                 {AM {mc "Portions staged for commit"}}
1600                 {AD {mc "Staged for commit, missing"}}
1601
1602                 {_D {mc "Missing"}}
1603                 {D_ {mc "Staged for removal"}}
1604                 {DO {mc "Staged for removal, still present"}}
1605
1606                 {U_ {mc "Requires merge resolution"}}
1607                 {UU {mc "Requires merge resolution"}}
1608                 {UM {mc "Requires merge resolution"}}
1609                 {UD {mc "Requires merge resolution"}}
1610         } {
1611         set text [eval [lindex $i 1]]
1612         if {$max_status_desc < [string length $text]} {
1613                 set max_status_desc [string length $text]
1614         }
1615         set all_descs([lindex $i 0]) $text
1616 }
1617 unset i
1618
1619 ######################################################################
1620 ##
1621 ## util
1622
1623 proc scrollbar2many {list mode args} {
1624         foreach w $list {eval $w $mode $args}
1625 }
1626
1627 proc many2scrollbar {list mode sb top bottom} {
1628         $sb set $top $bottom
1629         foreach w $list {$w $mode moveto $top}
1630 }
1631
1632 proc incr_font_size {font {amt 1}} {
1633         set sz [font configure $font -size]
1634         incr sz $amt
1635         font configure $font -size $sz
1636         font configure ${font}bold -size $sz
1637         font configure ${font}italic -size $sz
1638 }
1639
1640 ######################################################################
1641 ##
1642 ## ui commands
1643
1644 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1645
1646 proc do_gitk {revs} {
1647         # -- Always start gitk through whatever we were loaded with.  This
1648         #    lets us bypass using shell process on Windows systems.
1649         #
1650         set exe [file join [file dirname $::_git] gitk]
1651         set cmd [list [info nameofexecutable] $exe]
1652         if {! [file exists $exe]} {
1653                 error_popup [mc "Unable to start gitk:\n\n%s does not exist" $exe]
1654         } else {
1655                 global env
1656
1657                 if {[info exists env(GIT_DIR)]} {
1658                         set old_GIT_DIR $env(GIT_DIR)
1659                 } else {
1660                         set old_GIT_DIR {}
1661                 }
1662
1663                 set pwd [pwd]
1664                 cd [file dirname [gitdir]]
1665                 set env(GIT_DIR) [file tail [gitdir]]
1666
1667                 eval exec $cmd $revs &
1668
1669                 if {$old_GIT_DIR eq {}} {
1670                         unset env(GIT_DIR)
1671                 } else {
1672                         set env(GIT_DIR) $old_GIT_DIR
1673                 }
1674                 cd $pwd
1675
1676                 ui_status $::starting_gitk_msg
1677                 after 10000 {
1678                         ui_ready $starting_gitk_msg
1679                 }
1680         }
1681 }
1682
1683 set is_quitting 0
1684
1685 proc do_quit {} {
1686         global ui_comm is_quitting repo_config commit_type
1687         global GITGUI_BCK_exists GITGUI_BCK_i
1688         global ui_comm_spell
1689
1690         if {$is_quitting} return
1691         set is_quitting 1
1692
1693         if {[winfo exists $ui_comm]} {
1694                 # -- Stash our current commit buffer.
1695                 #
1696                 set save [gitdir GITGUI_MSG]
1697                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
1698                         file rename -force [gitdir GITGUI_BCK] $save
1699                         set GITGUI_BCK_exists 0
1700                 } else {
1701                         set msg [string trim [$ui_comm get 0.0 end]]
1702                         regsub -all -line {[ \r\t]+$} $msg {} msg
1703                         if {(![string match amend* $commit_type]
1704                                 || [$ui_comm edit modified])
1705                                 && $msg ne {}} {
1706                                 catch {
1707                                         set fd [open $save w]
1708                                         puts -nonewline $fd $msg
1709                                         close $fd
1710                                 }
1711                         } else {
1712                                 catch {file delete $save}
1713                         }
1714                 }
1715
1716                 # -- Cancel our spellchecker if its running.
1717                 #
1718                 if {[info exists ui_comm_spell]} {
1719                         $ui_comm_spell stop
1720                 }
1721
1722                 # -- Remove our editor backup, its not needed.
1723                 #
1724                 after cancel $GITGUI_BCK_i
1725                 if {$GITGUI_BCK_exists} {
1726                         catch {file delete [gitdir GITGUI_BCK]}
1727                 }
1728
1729                 # -- Stash our current window geometry into this repository.
1730                 #
1731                 set cfg_geometry [list]
1732                 lappend cfg_geometry [wm geometry .]
1733                 lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
1734                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
1735                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1736                         set rc_geometry {}
1737                 }
1738                 if {$cfg_geometry ne $rc_geometry} {
1739                         catch {git config gui.geometry $cfg_geometry}
1740                 }
1741         }
1742
1743         destroy .
1744 }
1745
1746 proc do_rescan {} {
1747         rescan ui_ready
1748 }
1749
1750 proc do_commit {} {
1751         commit_tree
1752 }
1753
1754 proc toggle_or_diff {w x y} {
1755         global file_states file_lists current_diff_path ui_index ui_workdir
1756         global last_clicked selected_paths
1757
1758         set pos [split [$w index @$x,$y] .]
1759         set lno [lindex $pos 0]
1760         set col [lindex $pos 1]
1761         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1762         if {$path eq {}} {
1763                 set last_clicked {}
1764                 return
1765         }
1766
1767         set last_clicked [list $w $lno]
1768         array unset selected_paths
1769         $ui_index tag remove in_sel 0.0 end
1770         $ui_workdir tag remove in_sel 0.0 end
1771
1772         if {$col == 0} {
1773                 if {$current_diff_path eq $path} {
1774                         set after {reshow_diff;}
1775                 } else {
1776                         set after {}
1777                 }
1778                 if {$w eq $ui_index} {
1779                         update_indexinfo \
1780                                 "Unstaging [short_path $path] from commit" \
1781                                 [list $path] \
1782                                 [concat $after [list ui_ready]]
1783                 } elseif {$w eq $ui_workdir} {
1784                         update_index \
1785                                 "Adding [short_path $path]" \
1786                                 [list $path] \
1787                                 [concat $after [list ui_ready]]
1788                 }
1789         } else {
1790                 show_diff $path $w $lno
1791         }
1792 }
1793
1794 proc add_one_to_selection {w x y} {
1795         global file_lists last_clicked selected_paths
1796
1797         set lno [lindex [split [$w index @$x,$y] .] 0]
1798         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1799         if {$path eq {}} {
1800                 set last_clicked {}
1801                 return
1802         }
1803
1804         if {$last_clicked ne {}
1805                 && [lindex $last_clicked 0] ne $w} {
1806                 array unset selected_paths
1807                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1808         }
1809
1810         set last_clicked [list $w $lno]
1811         if {[catch {set in_sel $selected_paths($path)}]} {
1812                 set in_sel 0
1813         }
1814         if {$in_sel} {
1815                 unset selected_paths($path)
1816                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1817         } else {
1818                 set selected_paths($path) 1
1819                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1820         }
1821 }
1822
1823 proc add_range_to_selection {w x y} {
1824         global file_lists last_clicked selected_paths
1825
1826         if {[lindex $last_clicked 0] ne $w} {
1827                 toggle_or_diff $w $x $y
1828                 return
1829         }
1830
1831         set lno [lindex [split [$w index @$x,$y] .] 0]
1832         set lc [lindex $last_clicked 1]
1833         if {$lc < $lno} {
1834                 set begin $lc
1835                 set end $lno
1836         } else {
1837                 set begin $lno
1838                 set end $lc
1839         }
1840
1841         foreach path [lrange $file_lists($w) \
1842                 [expr {$begin - 1}] \
1843                 [expr {$end - 1}]] {
1844                 set selected_paths($path) 1
1845         }
1846         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1847 }
1848
1849 ######################################################################
1850 ##
1851 ## ui construction
1852
1853 load_config 0
1854 apply_config
1855 set ui_comm {}
1856
1857 # -- Menu Bar
1858 #
1859 menu .mbar -tearoff 0
1860 .mbar add cascade -label [mc Repository] -menu .mbar.repository
1861 .mbar add cascade -label [mc Edit] -menu .mbar.edit
1862 if {[is_enabled branch]} {
1863         .mbar add cascade -label [mc Branch] -menu .mbar.branch
1864 }
1865 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1866         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
1867 }
1868 if {[is_enabled transport]} {
1869         .mbar add cascade -label [mc Merge] -menu .mbar.merge
1870         .mbar add cascade -label [mc Remote] -menu .mbar.remote
1871 }
1872 . configure -menu .mbar
1873
1874 # -- Repository Menu
1875 #
1876 menu .mbar.repository
1877
1878 .mbar.repository add command \
1879         -label [mc "Browse Current Branch's Files"] \
1880         -command {browser::new $current_branch}
1881 set ui_browse_current [.mbar.repository index last]
1882 .mbar.repository add command \
1883         -label [mc "Browse Branch Files..."] \
1884         -command browser_open::dialog
1885 .mbar.repository add separator
1886
1887 .mbar.repository add command \
1888         -label [mc "Visualize Current Branch's History"] \
1889         -command {do_gitk $current_branch}
1890 set ui_visualize_current [.mbar.repository index last]
1891 .mbar.repository add command \
1892         -label [mc "Visualize All Branch History"] \
1893         -command {do_gitk --all}
1894 .mbar.repository add separator
1895
1896 proc current_branch_write {args} {
1897         global current_branch
1898         .mbar.repository entryconf $::ui_browse_current \
1899                 -label [mc "Browse %s's Files" $current_branch]
1900         .mbar.repository entryconf $::ui_visualize_current \
1901                 -label [mc "Visualize %s's History" $current_branch]
1902 }
1903 trace add variable current_branch write current_branch_write
1904
1905 if {[is_enabled multicommit]} {
1906         .mbar.repository add command -label [mc "Database Statistics"] \
1907                 -command do_stats
1908
1909         .mbar.repository add command -label [mc "Compress Database"] \
1910                 -command do_gc
1911
1912         .mbar.repository add command -label [mc "Verify Database"] \
1913                 -command do_fsck_objects
1914
1915         .mbar.repository add separator
1916
1917         if {[is_Cygwin]} {
1918                 .mbar.repository add command \
1919                         -label [mc "Create Desktop Icon"] \
1920                         -command do_cygwin_shortcut
1921         } elseif {[is_Windows]} {
1922                 .mbar.repository add command \
1923                         -label [mc "Create Desktop Icon"] \
1924                         -command do_windows_shortcut
1925         } elseif {[is_MacOSX]} {
1926                 .mbar.repository add command \
1927                         -label [mc "Create Desktop Icon"] \
1928                         -command do_macosx_app
1929         }
1930 }
1931
1932 .mbar.repository add command -label [mc Quit] \
1933         -command do_quit \
1934         -accelerator $M1T-Q
1935
1936 # -- Edit Menu
1937 #
1938 menu .mbar.edit
1939 .mbar.edit add command -label [mc Undo] \
1940         -command {catch {[focus] edit undo}} \
1941         -accelerator $M1T-Z
1942 .mbar.edit add command -label [mc Redo] \
1943         -command {catch {[focus] edit redo}} \
1944         -accelerator $M1T-Y
1945 .mbar.edit add separator
1946 .mbar.edit add command -label [mc Cut] \
1947         -command {catch {tk_textCut [focus]}} \
1948         -accelerator $M1T-X
1949 .mbar.edit add command -label [mc Copy] \
1950         -command {catch {tk_textCopy [focus]}} \
1951         -accelerator $M1T-C
1952 .mbar.edit add command -label [mc Paste] \
1953         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
1954         -accelerator $M1T-V
1955 .mbar.edit add command -label [mc Delete] \
1956         -command {catch {[focus] delete sel.first sel.last}} \
1957         -accelerator Del
1958 .mbar.edit add separator
1959 .mbar.edit add command -label [mc "Select All"] \
1960         -command {catch {[focus] tag add sel 0.0 end}} \
1961         -accelerator $M1T-A
1962
1963 # -- Branch Menu
1964 #
1965 if {[is_enabled branch]} {
1966         menu .mbar.branch
1967
1968         .mbar.branch add command -label [mc "Create..."] \
1969                 -command branch_create::dialog \
1970                 -accelerator $M1T-N
1971         lappend disable_on_lock [list .mbar.branch entryconf \
1972                 [.mbar.branch index last] -state]
1973
1974         .mbar.branch add command -label [mc "Checkout..."] \
1975                 -command branch_checkout::dialog \
1976                 -accelerator $M1T-O
1977         lappend disable_on_lock [list .mbar.branch entryconf \
1978                 [.mbar.branch index last] -state]
1979
1980         .mbar.branch add command -label [mc "Rename..."] \
1981                 -command branch_rename::dialog
1982         lappend disable_on_lock [list .mbar.branch entryconf \
1983                 [.mbar.branch index last] -state]
1984
1985         .mbar.branch add command -label [mc "Delete..."] \
1986                 -command branch_delete::dialog
1987         lappend disable_on_lock [list .mbar.branch entryconf \
1988                 [.mbar.branch index last] -state]
1989
1990         .mbar.branch add command -label [mc "Reset..."] \
1991                 -command merge::reset_hard
1992         lappend disable_on_lock [list .mbar.branch entryconf \
1993                 [.mbar.branch index last] -state]
1994 }
1995
1996 # -- Commit Menu
1997 #
1998 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1999         menu .mbar.commit
2000
2001         .mbar.commit add radiobutton \
2002                 -label [mc "New Commit"] \
2003                 -command do_select_commit_type \
2004                 -variable selected_commit_type \
2005                 -value new
2006         lappend disable_on_lock \
2007                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2008
2009         .mbar.commit add radiobutton \
2010                 -label [mc "Amend Last Commit"] \
2011                 -command do_select_commit_type \
2012                 -variable selected_commit_type \
2013                 -value amend
2014         lappend disable_on_lock \
2015                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2016
2017         .mbar.commit add separator
2018
2019         .mbar.commit add command -label [mc Rescan] \
2020                 -command do_rescan \
2021                 -accelerator F5
2022         lappend disable_on_lock \
2023                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2024
2025         .mbar.commit add command -label [mc "Stage To Commit"] \
2026                 -command do_add_selection \
2027                 -accelerator $M1T-T
2028         lappend disable_on_lock \
2029                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2030
2031         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2032                 -command do_add_all \
2033                 -accelerator $M1T-I
2034         lappend disable_on_lock \
2035                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2036
2037         .mbar.commit add command -label [mc "Unstage From Commit"] \
2038                 -command do_unstage_selection
2039         lappend disable_on_lock \
2040                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2041
2042         .mbar.commit add command -label [mc "Revert Changes"] \
2043                 -command do_revert_selection
2044         lappend disable_on_lock \
2045                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2046
2047         .mbar.commit add separator
2048
2049         .mbar.commit add command -label [mc "Sign Off"] \
2050                 -command do_signoff \
2051                 -accelerator $M1T-S
2052
2053         .mbar.commit add command -label [mc Commit@@verb] \
2054                 -command do_commit \
2055                 -accelerator $M1T-Return
2056         lappend disable_on_lock \
2057                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2058 }
2059
2060 # -- Merge Menu
2061 #
2062 if {[is_enabled branch]} {
2063         menu .mbar.merge
2064         .mbar.merge add command -label [mc "Local Merge..."] \
2065                 -command merge::dialog \
2066                 -accelerator $M1T-M
2067         lappend disable_on_lock \
2068                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2069         .mbar.merge add command -label [mc "Abort Merge..."] \
2070                 -command merge::reset_hard
2071         lappend disable_on_lock \
2072                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2073 }
2074
2075 # -- Transport Menu
2076 #
2077 if {[is_enabled transport]} {
2078         menu .mbar.remote
2079
2080         .mbar.remote add command \
2081                 -label [mc "Push..."] \
2082                 -command do_push_anywhere \
2083                 -accelerator $M1T-P
2084         .mbar.remote add command \
2085                 -label [mc "Delete..."] \
2086                 -command remote_branch_delete::dialog
2087 }
2088
2089 if {[is_MacOSX]} {
2090         # -- Apple Menu (Mac OS X only)
2091         #
2092         .mbar add cascade -label Apple -menu .mbar.apple
2093         menu .mbar.apple
2094
2095         .mbar.apple add command -label [mc "About %s" [appname]] \
2096                 -command do_about
2097         .mbar.apple add separator
2098         .mbar.apple add command \
2099                 -label [mc "Preferences..."] \
2100                 -command do_options \
2101                 -accelerator $M1T-,
2102         bind . <$M1B-,> do_options
2103 } else {
2104         # -- Edit Menu
2105         #
2106         .mbar.edit add separator
2107         .mbar.edit add command -label [mc "Options..."] \
2108                 -command do_options
2109 }
2110
2111 # -- Help Menu
2112 #
2113 .mbar add cascade -label [mc Help] -menu .mbar.help
2114 menu .mbar.help
2115
2116 if {![is_MacOSX]} {
2117         .mbar.help add command -label [mc "About %s" [appname]] \
2118                 -command do_about
2119 }
2120
2121 set browser {}
2122 catch {set browser $repo_config(instaweb.browser)}
2123 set doc_path [file dirname [gitexec]]
2124 set doc_path [file join $doc_path Documentation index.html]
2125
2126 if {[is_Cygwin]} {
2127         set doc_path [exec cygpath --mixed $doc_path]
2128 }
2129
2130 if {$browser eq {}} {
2131         if {[is_MacOSX]} {
2132                 set browser open
2133         } elseif {[is_Cygwin]} {
2134                 set program_files [file dirname [exec cygpath --windir]]
2135                 set program_files [file join $program_files {Program Files}]
2136                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
2137                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
2138                 if {[file exists $firefox]} {
2139                         set browser $firefox
2140                 } elseif {[file exists $ie]} {
2141                         set browser $ie
2142                 }
2143                 unset program_files firefox ie
2144         }
2145 }
2146
2147 if {[file isfile $doc_path]} {
2148         set doc_url "file:$doc_path"
2149 } else {
2150         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2151 }
2152
2153 if {$browser ne {}} {
2154         .mbar.help add command -label [mc "Online Documentation"] \
2155                 -command [list exec $browser $doc_url &]
2156 }
2157 unset browser doc_path doc_url
2158
2159 # -- Standard bindings
2160 #
2161 wm protocol . WM_DELETE_WINDOW do_quit
2162 bind all <$M1B-Key-q> do_quit
2163 bind all <$M1B-Key-Q> do_quit
2164 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2165 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2166
2167 set subcommand_args {}
2168 proc usage {} {
2169         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2170         exit 1
2171 }
2172
2173 # -- Not a normal commit type invocation?  Do that instead!
2174 #
2175 switch -- $subcommand {
2176 browser -
2177 blame {
2178         set subcommand_args {rev? path}
2179         if {$argv eq {}} usage
2180         set head {}
2181         set path {}
2182         set is_path 0
2183         foreach a $argv {
2184                 if {$is_path || [file exists $_prefix$a]} {
2185                         if {$path ne {}} usage
2186                         set path $_prefix$a
2187                         break
2188                 } elseif {$a eq {--}} {
2189                         if {$path ne {}} {
2190                                 if {$head ne {}} usage
2191                                 set head $path
2192                                 set path {}
2193                         }
2194                         set is_path 1
2195                 } elseif {$head eq {}} {
2196                         if {$head ne {}} usage
2197                         set head $a
2198                         set is_path 1
2199                 } else {
2200                         usage
2201                 }
2202         }
2203         unset is_path
2204
2205         if {$head ne {} && $path eq {}} {
2206                 set path $_prefix$head
2207                 set head {}
2208         }
2209
2210         if {$head eq {}} {
2211                 load_current_branch
2212         } else {
2213                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2214                         if {[catch {
2215                                         set head [git rev-parse --verify $head]
2216                                 } err]} {
2217                                 puts stderr $err
2218                                 exit 1
2219                         }
2220                 }
2221                 set current_branch $head
2222         }
2223
2224         switch -- $subcommand {
2225         browser {
2226                 if {$head eq {}} {
2227                         if {$path ne {} && [file isdirectory $path]} {
2228                                 set head $current_branch
2229                         } else {
2230                                 set head $path
2231                                 set path {}
2232                         }
2233                 }
2234                 browser::new $head $path
2235         }
2236         blame   {
2237                 if {$head eq {} && ![file exists $path]} {
2238                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2239                         exit 1
2240                 }
2241                 blame::new $head $path
2242         }
2243         }
2244         return
2245 }
2246 citool -
2247 gui {
2248         if {[llength $argv] != 0} {
2249                 puts -nonewline stderr "usage: $argv0"
2250                 if {$subcommand ne {gui}
2251                         && [file tail $argv0] ne "git-$subcommand"} {
2252                         puts -nonewline stderr " $subcommand"
2253                 }
2254                 puts stderr {}
2255                 exit 1
2256         }
2257         # fall through to setup UI for commits
2258 }
2259 default {
2260         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2261         exit 1
2262 }
2263 }
2264
2265 # -- Branch Control
2266 #
2267 frame .branch \
2268         -borderwidth 1 \
2269         -relief sunken
2270 label .branch.l1 \
2271         -text [mc "Current Branch:"] \
2272         -anchor w \
2273         -justify left
2274 label .branch.cb \
2275         -textvariable current_branch \
2276         -anchor w \
2277         -justify left
2278 pack .branch.l1 -side left
2279 pack .branch.cb -side left -fill x
2280 pack .branch -side top -fill x
2281
2282 # -- Main Window Layout
2283 #
2284 panedwindow .vpane -orient horizontal
2285 panedwindow .vpane.files -orient vertical
2286 .vpane add .vpane.files -sticky nsew -height 100 -width 200
2287 pack .vpane -anchor n -side top -fill both -expand 1
2288
2289 # -- Index File List
2290 #
2291 frame .vpane.files.index -height 100 -width 200
2292 label .vpane.files.index.title -text [mc "Staged Changes (Will Commit)"] \
2293         -background lightgreen -foreground black
2294 text $ui_index -background white -foreground black \
2295         -borderwidth 0 \
2296         -width 20 -height 10 \
2297         -wrap none \
2298         -cursor $cursor_ptr \
2299         -xscrollcommand {.vpane.files.index.sx set} \
2300         -yscrollcommand {.vpane.files.index.sy set} \
2301         -state disabled
2302 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2303 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2304 pack .vpane.files.index.title -side top -fill x
2305 pack .vpane.files.index.sx -side bottom -fill x
2306 pack .vpane.files.index.sy -side right -fill y
2307 pack $ui_index -side left -fill both -expand 1
2308
2309 # -- Working Directory File List
2310 #
2311 frame .vpane.files.workdir -height 100 -width 200
2312 label .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2313         -background lightsalmon -foreground black
2314 text $ui_workdir -background white -foreground black \
2315         -borderwidth 0 \
2316         -width 20 -height 10 \
2317         -wrap none \
2318         -cursor $cursor_ptr \
2319         -xscrollcommand {.vpane.files.workdir.sx set} \
2320         -yscrollcommand {.vpane.files.workdir.sy set} \
2321         -state disabled
2322 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
2323 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
2324 pack .vpane.files.workdir.title -side top -fill x
2325 pack .vpane.files.workdir.sx -side bottom -fill x
2326 pack .vpane.files.workdir.sy -side right -fill y
2327 pack $ui_workdir -side left -fill both -expand 1
2328
2329 .vpane.files add .vpane.files.workdir -sticky nsew
2330 .vpane.files add .vpane.files.index -sticky nsew
2331
2332 foreach i [list $ui_index $ui_workdir] {
2333         rmsel_tag $i
2334         $i tag conf in_diff -background [$i tag cget in_sel -background]
2335 }
2336 unset i
2337
2338 # -- Diff and Commit Area
2339 #
2340 frame .vpane.lower -height 300 -width 400
2341 frame .vpane.lower.commarea
2342 frame .vpane.lower.diff -relief sunken -borderwidth 1
2343 pack .vpane.lower.diff -fill both -expand 1
2344 pack .vpane.lower.commarea -side bottom -fill x
2345 .vpane add .vpane.lower -sticky nsew
2346
2347 # -- Commit Area Buttons
2348 #
2349 frame .vpane.lower.commarea.buttons
2350 label .vpane.lower.commarea.buttons.l -text {} \
2351         -anchor w \
2352         -justify left
2353 pack .vpane.lower.commarea.buttons.l -side top -fill x
2354 pack .vpane.lower.commarea.buttons -side left -fill y
2355
2356 button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
2357         -command do_rescan
2358 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
2359 lappend disable_on_lock \
2360         {.vpane.lower.commarea.buttons.rescan conf -state}
2361
2362 button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
2363         -command do_add_all
2364 pack .vpane.lower.commarea.buttons.incall -side top -fill x
2365 lappend disable_on_lock \
2366         {.vpane.lower.commarea.buttons.incall conf -state}
2367
2368 button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
2369         -command do_signoff
2370 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
2371
2372 button .vpane.lower.commarea.buttons.commit -text [mc Commit@@verb] \
2373         -command do_commit
2374 pack .vpane.lower.commarea.buttons.commit -side top -fill x
2375 lappend disable_on_lock \
2376         {.vpane.lower.commarea.buttons.commit conf -state}
2377
2378 button .vpane.lower.commarea.buttons.push -text [mc Push] \
2379         -command do_push_anywhere
2380 pack .vpane.lower.commarea.buttons.push -side top -fill x
2381
2382 # -- Commit Message Buffer
2383 #
2384 frame .vpane.lower.commarea.buffer
2385 frame .vpane.lower.commarea.buffer.header
2386 set ui_comm .vpane.lower.commarea.buffer.t
2387 set ui_coml .vpane.lower.commarea.buffer.header.l
2388 radiobutton .vpane.lower.commarea.buffer.header.new \
2389         -text [mc "New Commit"] \
2390         -command do_select_commit_type \
2391         -variable selected_commit_type \
2392         -value new
2393 lappend disable_on_lock \
2394         [list .vpane.lower.commarea.buffer.header.new conf -state]
2395 radiobutton .vpane.lower.commarea.buffer.header.amend \
2396         -text [mc "Amend Last Commit"] \
2397         -command do_select_commit_type \
2398         -variable selected_commit_type \
2399         -value amend
2400 lappend disable_on_lock \
2401         [list .vpane.lower.commarea.buffer.header.amend conf -state]
2402 label $ui_coml \
2403         -anchor w \
2404         -justify left
2405 proc trace_commit_type {varname args} {
2406         global ui_coml commit_type
2407         switch -glob -- $commit_type {
2408         initial       {set txt [mc "Initial Commit Message:"]}
2409         amend         {set txt [mc "Amended Commit Message:"]}
2410         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
2411         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
2412         merge         {set txt [mc "Merge Commit Message:"]}
2413         *             {set txt [mc "Commit Message:"]}
2414         }
2415         $ui_coml conf -text $txt
2416 }
2417 trace add variable commit_type write trace_commit_type
2418 pack $ui_coml -side left -fill x
2419 pack .vpane.lower.commarea.buffer.header.amend -side right
2420 pack .vpane.lower.commarea.buffer.header.new -side right
2421
2422 text $ui_comm -background white -foreground black \
2423         -borderwidth 1 \
2424         -undo true \
2425         -maxundo 20 \
2426         -autoseparators true \
2427         -relief sunken \
2428         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
2429         -font font_diff \
2430         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
2431 scrollbar .vpane.lower.commarea.buffer.sby \
2432         -command [list $ui_comm yview]
2433 pack .vpane.lower.commarea.buffer.header -side top -fill x
2434 pack .vpane.lower.commarea.buffer.sby -side right -fill y
2435 pack $ui_comm -side left -fill y
2436 pack .vpane.lower.commarea.buffer -side left -fill y
2437
2438 # -- Commit Message Buffer Context Menu
2439 #
2440 set ctxm .vpane.lower.commarea.buffer.ctxm
2441 menu $ctxm -tearoff 0
2442 $ctxm add command \
2443         -label [mc Cut] \
2444         -command {tk_textCut $ui_comm}
2445 $ctxm add command \
2446         -label [mc Copy] \
2447         -command {tk_textCopy $ui_comm}
2448 $ctxm add command \
2449         -label [mc Paste] \
2450         -command {tk_textPaste $ui_comm}
2451 $ctxm add command \
2452         -label [mc Delete] \
2453         -command {$ui_comm delete sel.first sel.last}
2454 $ctxm add separator
2455 $ctxm add command \
2456         -label [mc "Select All"] \
2457         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
2458 $ctxm add command \
2459         -label [mc "Copy All"] \
2460         -command {
2461                 $ui_comm tag add sel 0.0 end
2462                 tk_textCopy $ui_comm
2463                 $ui_comm tag remove sel 0.0 end
2464         }
2465 $ctxm add separator
2466 $ctxm add command \
2467         -label [mc "Sign Off"] \
2468         -command do_signoff
2469 set ui_comm_ctxm $ctxm
2470
2471 # -- Diff Header
2472 #
2473 proc trace_current_diff_path {varname args} {
2474         global current_diff_path diff_actions file_states
2475         if {$current_diff_path eq {}} {
2476                 set s {}
2477                 set f {}
2478                 set p {}
2479                 set o disabled
2480         } else {
2481                 set p $current_diff_path
2482                 set s [mapdesc [lindex $file_states($p) 0] $p]
2483                 set f [mc "File:"]
2484                 set p [escape_path $p]
2485                 set o normal
2486         }
2487
2488         .vpane.lower.diff.header.status configure -text $s
2489         .vpane.lower.diff.header.file configure -text $f
2490         .vpane.lower.diff.header.path configure -text $p
2491         foreach w $diff_actions {
2492                 uplevel #0 $w $o
2493         }
2494 }
2495 trace add variable current_diff_path write trace_current_diff_path
2496
2497 frame .vpane.lower.diff.header -background gold
2498 label .vpane.lower.diff.header.status \
2499         -background gold \
2500         -foreground black \
2501         -width $max_status_desc \
2502         -anchor w \
2503         -justify left
2504 label .vpane.lower.diff.header.file \
2505         -background gold \
2506         -foreground black \
2507         -anchor w \
2508         -justify left
2509 label .vpane.lower.diff.header.path \
2510         -background gold \
2511         -foreground black \
2512         -anchor w \
2513         -justify left
2514 pack .vpane.lower.diff.header.status -side left
2515 pack .vpane.lower.diff.header.file -side left
2516 pack .vpane.lower.diff.header.path -fill x
2517 set ctxm .vpane.lower.diff.header.ctxm
2518 menu $ctxm -tearoff 0
2519 $ctxm add command \
2520         -label [mc Copy] \
2521         -command {
2522                 clipboard clear
2523                 clipboard append \
2524                         -format STRING \
2525                         -type STRING \
2526                         -- $current_diff_path
2527         }
2528 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2529 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2530
2531 # -- Diff Body
2532 #
2533 frame .vpane.lower.diff.body
2534 set ui_diff .vpane.lower.diff.body.t
2535 text $ui_diff -background white -foreground black \
2536         -borderwidth 0 \
2537         -width 80 -height 15 -wrap none \
2538         -font font_diff \
2539         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2540         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2541         -state disabled
2542 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2543         -command [list $ui_diff xview]
2544 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2545         -command [list $ui_diff yview]
2546 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2547 pack .vpane.lower.diff.body.sby -side right -fill y
2548 pack $ui_diff -side left -fill both -expand 1
2549 pack .vpane.lower.diff.header -side top -fill x
2550 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2551
2552 $ui_diff tag conf d_cr -elide true
2553 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2554 $ui_diff tag conf d_+ -foreground {#00a000}
2555 $ui_diff tag conf d_- -foreground red
2556
2557 $ui_diff tag conf d_++ -foreground {#00a000}
2558 $ui_diff tag conf d_-- -foreground red
2559 $ui_diff tag conf d_+s \
2560         -foreground {#00a000} \
2561         -background {#e2effa}
2562 $ui_diff tag conf d_-s \
2563         -foreground red \
2564         -background {#e2effa}
2565 $ui_diff tag conf d_s+ \
2566         -foreground {#00a000} \
2567         -background ivory1
2568 $ui_diff tag conf d_s- \
2569         -foreground red \
2570         -background ivory1
2571
2572 $ui_diff tag conf d<<<<<<< \
2573         -foreground orange \
2574         -font font_diffbold
2575 $ui_diff tag conf d======= \
2576         -foreground orange \
2577         -font font_diffbold
2578 $ui_diff tag conf d>>>>>>> \
2579         -foreground orange \
2580         -font font_diffbold
2581
2582 $ui_diff tag raise sel
2583
2584 # -- Diff Body Context Menu
2585 #
2586 set ctxm .vpane.lower.diff.body.ctxm
2587 menu $ctxm -tearoff 0
2588 $ctxm add command \
2589         -label [mc "Apply/Reverse Hunk"] \
2590         -command {apply_hunk $cursorX $cursorY}
2591 set ui_diff_applyhunk [$ctxm index last]
2592 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2593 $ctxm add separator
2594 $ctxm add command \
2595         -label [mc "Show Less Context"] \
2596         -command {if {$repo_config(gui.diffcontext) >= 1} {
2597                 incr repo_config(gui.diffcontext) -1
2598                 reshow_diff
2599         }}
2600 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2601 $ctxm add command \
2602         -label [mc "Show More Context"] \
2603         -command {if {$repo_config(gui.diffcontext) < 99} {
2604                 incr repo_config(gui.diffcontext)
2605                 reshow_diff
2606         }}
2607 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2608 $ctxm add separator
2609 $ctxm add command \
2610         -label [mc Refresh] \
2611         -command reshow_diff
2612 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2613 $ctxm add command \
2614         -label [mc Copy] \
2615         -command {tk_textCopy $ui_diff}
2616 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2617 $ctxm add command \
2618         -label [mc "Select All"] \
2619         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2620 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2621 $ctxm add command \
2622         -label [mc "Copy All"] \
2623         -command {
2624                 $ui_diff tag add sel 0.0 end
2625                 tk_textCopy $ui_diff
2626                 $ui_diff tag remove sel 0.0 end
2627         }
2628 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2629 $ctxm add separator
2630 $ctxm add command \
2631         -label [mc "Decrease Font Size"] \
2632         -command {incr_font_size font_diff -1}
2633 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2634 $ctxm add command \
2635         -label [mc "Increase Font Size"] \
2636         -command {incr_font_size font_diff 1}
2637 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2638 $ctxm add separator
2639 $ctxm add command -label [mc "Options..."] \
2640         -command do_options
2641 proc popup_diff_menu {ctxm x y X Y} {
2642         global current_diff_path file_states
2643         set ::cursorX $x
2644         set ::cursorY $y
2645         if {$::ui_index eq $::current_diff_side} {
2646                 set l [mc "Unstage Hunk From Commit"]
2647         } else {
2648                 set l [mc "Stage Hunk For Commit"]
2649         }
2650         if {$::is_3way_diff
2651                 || $current_diff_path eq {}
2652                 || ![info exists file_states($current_diff_path)]
2653                 || {_O} eq [lindex $file_states($current_diff_path) 0]} {
2654                 set s disabled
2655         } else {
2656                 set s normal
2657         }
2658         $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
2659         tk_popup $ctxm $X $Y
2660 }
2661 bind_button3 $ui_diff [list popup_diff_menu $ctxm %x %y %X %Y]
2662
2663 # -- Status Bar
2664 #
2665 set main_status [::status_bar::new .status]
2666 pack .status -anchor w -side bottom -fill x
2667 $main_status show [mc "Initializing..."]
2668
2669 # -- Load geometry
2670 #
2671 catch {
2672 set gm $repo_config(gui.geometry)
2673 wm geometry . [lindex $gm 0]
2674 .vpane sash place 0 \
2675         [lindex $gm 1] \
2676         [lindex [.vpane sash coord 0] 1]
2677 .vpane.files sash place 0 \
2678         [lindex [.vpane.files sash coord 0] 0] \
2679         [lindex $gm 2]
2680 unset gm
2681 }
2682
2683 # -- Key Bindings
2684 #
2685 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2686 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
2687 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
2688 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2689 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2690 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2691 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2692 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2693 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2694 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2695 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2696 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2697 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2698
2699 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2700 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2701 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2702 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2703 bind $ui_diff <$M1B-Key-v> {break}
2704 bind $ui_diff <$M1B-Key-V> {break}
2705 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2706 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2707 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2708 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2709 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2710 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2711 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2712 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2713 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2714 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2715 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2716 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2717 bind $ui_diff <Button-1>   {focus %W}
2718
2719 if {[is_enabled branch]} {
2720         bind . <$M1B-Key-n> branch_create::dialog
2721         bind . <$M1B-Key-N> branch_create::dialog
2722         bind . <$M1B-Key-o> branch_checkout::dialog
2723         bind . <$M1B-Key-O> branch_checkout::dialog
2724         bind . <$M1B-Key-m> merge::dialog
2725         bind . <$M1B-Key-M> merge::dialog
2726 }
2727 if {[is_enabled transport]} {
2728         bind . <$M1B-Key-p> do_push_anywhere
2729         bind . <$M1B-Key-P> do_push_anywhere
2730 }
2731
2732 bind .   <Key-F5>     do_rescan
2733 bind .   <$M1B-Key-r> do_rescan
2734 bind .   <$M1B-Key-R> do_rescan
2735 bind .   <$M1B-Key-s> do_signoff
2736 bind .   <$M1B-Key-S> do_signoff
2737 bind .   <$M1B-Key-t> do_add_selection
2738 bind .   <$M1B-Key-T> do_add_selection
2739 bind .   <$M1B-Key-i> do_add_all
2740 bind .   <$M1B-Key-I> do_add_all
2741 bind .   <$M1B-Key-Return> do_commit
2742 foreach i [list $ui_index $ui_workdir] {
2743         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2744         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2745         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2746 }
2747 unset i
2748
2749 set file_lists($ui_index) [list]
2750 set file_lists($ui_workdir) [list]
2751
2752 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2753 focus -force $ui_comm
2754
2755 # -- Warn the user about environmental problems.  Cygwin's Tcl
2756 #    does *not* pass its env array onto any processes it spawns.
2757 #    This means that git processes get none of our environment.
2758 #
2759 if {[is_Cygwin]} {
2760         set ignored_env 0
2761         set suggest_user {}
2762         set msg [mc "Possible environment issues exist.
2763
2764 The following environment variables are probably
2765 going to be ignored by any Git subprocess run
2766 by %s:
2767
2768 " [appname]]
2769         foreach name [array names env] {
2770                 switch -regexp -- $name {
2771                 {^GIT_INDEX_FILE$} -
2772                 {^GIT_OBJECT_DIRECTORY$} -
2773                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2774                 {^GIT_DIFF_OPTS$} -
2775                 {^GIT_EXTERNAL_DIFF$} -
2776                 {^GIT_PAGER$} -
2777                 {^GIT_TRACE$} -
2778                 {^GIT_CONFIG$} -
2779                 {^GIT_CONFIG_LOCAL$} -
2780                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2781                         append msg " - $name\n"
2782                         incr ignored_env
2783                 }
2784                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2785                         append msg " - $name\n"
2786                         incr ignored_env
2787                         set suggest_user $name
2788                 }
2789                 }
2790         }
2791         if {$ignored_env > 0} {
2792                 append msg [mc "
2793 This is due to a known issue with the
2794 Tcl binary distributed by Cygwin."]
2795
2796                 if {$suggest_user ne {}} {
2797                         append msg [mc "
2798
2799 A good replacement for %s
2800 is placing values for the user.name and
2801 user.email settings into your personal
2802 ~/.gitconfig file.
2803 " $suggest_user]
2804                 }
2805                 warn_popup $msg
2806         }
2807         unset ignored_env msg suggest_user name
2808 }
2809
2810 # -- Only initialize complex UI if we are going to stay running.
2811 #
2812 if {[is_enabled transport]} {
2813         load_all_remotes
2814
2815         set n [.mbar.remote index end]
2816         populate_push_menu
2817         populate_fetch_menu
2818         set n [expr {[.mbar.remote index end] - $n}]
2819         if {$n > 0} {
2820                 .mbar.remote insert $n separator
2821         }
2822         unset n
2823 }
2824
2825 if {[winfo exists $ui_comm]} {
2826         set GITGUI_BCK_exists [load_message GITGUI_BCK]
2827
2828         # -- If both our backup and message files exist use the
2829         #    newer of the two files to initialize the buffer.
2830         #
2831         if {$GITGUI_BCK_exists} {
2832                 set m [gitdir GITGUI_MSG]
2833                 if {[file isfile $m]} {
2834                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
2835                                 catch {file delete [gitdir GITGUI_MSG]}
2836                         } else {
2837                                 $ui_comm delete 0.0 end
2838                                 $ui_comm edit reset
2839                                 $ui_comm edit modified false
2840                                 catch {file delete [gitdir GITGUI_BCK]}
2841                                 set GITGUI_BCK_exists 0
2842                         }
2843                 }
2844                 unset m
2845         }
2846
2847         proc backup_commit_buffer {} {
2848                 global ui_comm GITGUI_BCK_exists
2849
2850                 set m [$ui_comm edit modified]
2851                 if {$m || $GITGUI_BCK_exists} {
2852                         set msg [string trim [$ui_comm get 0.0 end]]
2853                         regsub -all -line {[ \r\t]+$} $msg {} msg
2854
2855                         if {$msg eq {}} {
2856                                 if {$GITGUI_BCK_exists} {
2857                                         catch {file delete [gitdir GITGUI_BCK]}
2858                                         set GITGUI_BCK_exists 0
2859                                 }
2860                         } elseif {$m} {
2861                                 catch {
2862                                         set fd [open [gitdir GITGUI_BCK] w]
2863                                         puts -nonewline $fd $msg
2864                                         close $fd
2865                                         set GITGUI_BCK_exists 1
2866                                 }
2867                         }
2868
2869                         $ui_comm edit modified false
2870                 }
2871
2872                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
2873         }
2874
2875         backup_commit_buffer
2876
2877         # -- If the user has aspell available we can drive it
2878         #    in pipe mode to spellcheck the commit message.
2879         #
2880         set spell_cmd [list |]
2881         set spell_dict [get_config gui.spellingdictionary]
2882         lappend spell_cmd aspell
2883         if {$spell_dict ne {}} {
2884                 lappend spell_cmd --master=$spell_dict
2885         }
2886         lappend spell_cmd --mode=none
2887         lappend spell_cmd --encoding=utf-8
2888         lappend spell_cmd pipe
2889         if {$spell_dict eq {none}
2890          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
2891                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
2892         } else {
2893                 set ui_comm_spell [spellcheck::init \
2894                         $spell_fd \
2895                         $ui_comm \
2896                         $ui_comm_ctxm \
2897                 ]
2898         }
2899         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
2900 }
2901
2902 lock_index begin-read
2903 if {![winfo ismapped .]} {
2904         wm deiconify .
2905 }
2906 after 1 do_rescan
2907 if {[is_enabled multicommit]} {
2908         after 1000 hint_gc
2909 }