9b23d1f0169b8c9a1a9358ac4706b557634476ae
1 #!/usr/bin/perl -w
3 # This tool is copyright (c) 2005, Matthias Urlichs.
4 # It is released under the Gnu Public License, version 2.
5 #
6 # The basic idea is to aggregate CVS check-ins into related changes.
7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
8 # its output.
9 #
10 # Checking out the files is done by a single long-running CVS connection
11 # / server process.
12 #
13 # The head revision is on branch "origin" by default.
14 # You can change that with the '-o' option.
16 use strict;
17 use warnings;
18 use Getopt::Std;
19 use File::Path qw(mkpath);
20 use File::Basename qw(basename dirname);
21 use Time::Local;
22 use IO::Socket;
23 use IO::Pipe;
24 use POSIX qw(strftime dup2);
26 $SIG{'PIPE'}="IGNORE";
27 $ENV{'TZ'}="UTC";
29 our($opt_h,$opt_o,$opt_v,$opt_d);
31 sub usage() {
32 print STDERR <<END;
33 Usage: ${\basename $0} # fetch/update GIT from CVS
34 [ -o branch-for-HEAD ] [ -h ] [ -v ] [ -d CVSROOT ]
35 CVS_module [ GIT_repository ]
36 END
37 exit(1);
38 }
40 getopts("hqvo:d:") or usage();
41 usage if $opt_h;
43 @ARGV == 1 or @ARGV == 2 or usage();
45 my($cvs_tree, $git_tree) = @ARGV;
47 if($opt_d) {
48 $ENV{"CVSROOT"} = $opt_d;
49 } elsif($ENV{"CVSROOT"}) {
50 $opt_d = $ENV{"CVSROOT"};
51 } else {
52 die "CVSROOT needs to be set";
53 }
54 $opt_o ||= "origin";
55 $git_tree ||= ".";
57 select(STDERR); $|=1; select(STDOUT);
60 package CVSconn;
61 # Basic CVS dialog.
62 # We're only interested in connecting and downloading, so ...
64 use POSIX qw(strftime dup2);
66 sub new {
67 my($what,$repo,$subdir) = @_;
68 $what=ref($what) if ref($what);
70 my $self = {};
71 $self->{'buffer'} = "";
72 bless($self,$what);
74 $repo =~ s#/+$##;
75 $self->{'fullrep'} = $repo;
76 $self->conn();
78 $self->{'subdir'} = $subdir;
79 $self->{'lines'} = undef;
81 return $self;
82 }
84 sub conn {
85 my $self = shift;
86 my $repo = $self->{'fullrep'};
87 if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
88 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
89 $user="anonymous" unless defined $user;
90 my $rr2 = "-";
91 unless($port) {
92 $rr2 = ":pserver:$user\@$serv:$repo";
93 $port=2401;
94 }
95 my $rr = ":pserver:$user\@$serv:$port$repo";
97 unless($pass) {
98 open(H,$ENV{'HOME'}."/.cvspass") and do {
99 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
100 while(<H>) {
101 chomp;
102 s/^\/\d+\s+//;
103 my ($w,$p) = split(/\s/,$_,2);
104 if($w eq $rr or $w eq $rr2) {
105 $pass = $p;
106 last;
107 }
108 }
109 };
110 }
111 $pass="A" unless $pass;
113 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
114 die "Socket to $serv: $!\n" unless defined $s;
115 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
116 or die "Write to $serv: $!\n";
117 $s->flush();
119 my $rep = <$s>;
121 if($rep ne "I LOVE YOU\n") {
122 $rep="<unknown>" unless $rep;
123 die "AuthReply: $rep\n";
124 }
125 $self->{'socketo'} = $s;
126 $self->{'socketi'} = $s;
127 } else { # local: Fork off our own cvs server.
128 my $pr = IO::Pipe->new();
129 my $pw = IO::Pipe->new();
130 my $pid = fork();
131 die "Fork: $!\n" unless defined $pid;
132 unless($pid) {
133 $pr->writer();
134 $pw->reader();
135 dup2($pw->fileno(),0);
136 dup2($pr->fileno(),1);
137 $pr->close();
138 $pw->close();
139 exec("cvs","server");
140 }
141 $pw->writer();
142 $pr->reader();
143 $self->{'socketo'} = $pw;
144 $self->{'socketi'} = $pr;
145 }
146 $self->{'socketo'}->write("Root $repo\n");
148 # Trial and error says that this probably is the minimum set
149 $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E F Checked-in Created Updated Merged Removed\n");
151 $self->{'socketo'}->write("valid-requests\n");
152 $self->{'socketo'}->flush();
154 chomp(my $rep=$self->readline());
155 if($rep !~ s/^Valid-requests\s*//) {
156 $rep="<unknown>" unless $rep;
157 die "Expected Valid-requests from server, but got: $rep\n";
158 }
159 chomp(my $res=$self->readline());
160 die "validReply: $res\n" if $res ne "ok";
162 $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
163 $self->{'repo'} = $repo;
164 }
166 sub readline {
167 my($self) = @_;
168 return $self->{'socketi'}->getline();
169 }
171 sub _file {
172 # Request a file with a given revision.
173 # Trial and error says this is a good way to do it. :-/
174 my($self,$fn,$rev) = @_;
175 $self->{'socketo'}->write("Argument -N\n") or return undef;
176 $self->{'socketo'}->write("Argument -P\n") or return undef;
177 # $self->{'socketo'}->write("Argument -ko\n") or return undef;
178 # -ko: Linus' version doesn't use it
179 $self->{'socketo'}->write("Argument -r\n") or return undef;
180 $self->{'socketo'}->write("Argument $rev\n") or return undef;
181 $self->{'socketo'}->write("Argument --\n") or return undef;
182 $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
183 $self->{'socketo'}->write("Directory .\n") or return undef;
184 $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
185 # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
186 $self->{'socketo'}->write("co\n") or return undef;
187 $self->{'socketo'}->flush() or return undef;
188 $self->{'lines'} = 0;
189 return 1;
190 }
191 sub _line {
192 # Read a line from the server.
193 # ... except that 'line' may be an entire file. ;-)
194 my($self) = @_;
195 die "Not in lines" unless defined $self->{'lines'};
197 my $line;
198 my $res="";
199 while(defined($line = $self->readline())) {
200 # M U gnupg-cvs-rep/AUTHORS
201 # Updated gnupg-cvs-rep/
202 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
203 # /AUTHORS/1.1///T1.1
204 # u=rw,g=rw,o=rw
205 # 0
206 # ok
208 if($line =~ s/^(?:Created|Updated) //) {
209 $line = $self->readline(); # path
210 $line = $self->readline(); # Entries line
211 my $mode = $self->readline(); chomp $mode;
212 $self->{'mode'} = $mode;
213 defined (my $cnt = $self->readline())
214 or die "EOF from server after 'Changed'\n";
215 chomp $cnt;
216 die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
217 $line="";
218 $res="";
219 while($cnt) {
220 my $buf;
221 my $num = $self->{'socketi'}->read($buf,$cnt);
222 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
223 $res .= $buf;
224 $cnt -= $num;
225 }
226 } elsif($line =~ s/^ //) {
227 $res .= $line;
228 } elsif($line =~ /^M\b/) {
229 # output, do nothing
230 } elsif($line =~ /^Mbinary\b/) {
231 my $cnt;
232 die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
233 chomp $cnt;
234 die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
235 $line="";
236 while($cnt) {
237 my $buf;
238 my $num = $self->{'socketi'}->read($buf,$cnt);
239 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
240 $res .= $buf;
241 $cnt -= $num;
242 }
243 } else {
244 chomp $line;
245 if($line eq "ok") {
246 # print STDERR "S: ok (".length($res).")\n";
247 return $res;
248 } elsif($line =~ s/^E //) {
249 # print STDERR "S: $line\n";
250 } else {
251 die "Unknown: $line\n";
252 }
253 }
254 }
255 }
256 sub file {
257 my($self,$fn,$rev) = @_;
258 my $res;
260 if ($self->_file($fn,$rev)) {
261 $res = $self->_line();
262 return $res if defined $res;
263 }
265 # retry
266 $self->conn();
267 $self->_file($fn,$rev)
268 or die "No file command send\n";
269 $res = $self->_line();
270 die "No input: $fn $rev\n" unless defined $res;
271 return $res;
272 }
275 package main;
277 my $cvs = CVSconn->new($opt_d, $cvs_tree);
280 sub pdate($) {
281 my($d) = @_;
282 m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
283 or die "Unparseable date: $d\n";
284 my $y=$1; $y-=1900 if $y>1900;
285 return timegm($6||0,$5,$4,$3,$2-1,$y);
286 }
288 sub pmode($) {
289 my($mode) = @_;
290 my $m = 0;
291 my $mm = 0;
292 my $um = 0;
293 for my $x(split(//,$mode)) {
294 if($x eq ",") {
295 $m |= $mm&$um;
296 $mm = 0;
297 $um = 0;
298 } elsif($x eq "u") { $um |= 0700;
299 } elsif($x eq "g") { $um |= 0070;
300 } elsif($x eq "o") { $um |= 0007;
301 } elsif($x eq "r") { $mm |= 0444;
302 } elsif($x eq "w") { $mm |= 0222;
303 } elsif($x eq "x") { $mm |= 0111;
304 } elsif($x eq "=") { # do nothing
305 } else { die "Unknown mode: $mode\n";
306 }
307 }
308 $m |= $mm&$um;
309 return $m;
310 }
312 my $tmpcv = "/var/cache/cvs";
314 sub getwd() {
315 my $pwd = `pwd`;
316 chomp $pwd;
317 return $pwd;
318 }
320 -d $git_tree
321 or mkdir($git_tree,0777)
322 or die "Could not create $git_tree: $!";
323 chdir($git_tree);
325 my $last_branch = "";
326 my $orig_branch = "";
327 my %branch_date;
329 my $git_dir = $ENV{"GIT_DIR"} || ".git";
330 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
331 $ENV{"GIT_DIR"} = $git_dir;
332 unless(-d $git_dir) {
333 system("git-init-db");
334 die "Cannot init the GIT db at $git_tree: $?\n" if $?;
335 system("git-read-tree");
336 die "Cannot init an empty tree: $?\n" if $?;
338 $last_branch = $opt_o;
339 $orig_branch = "";
340 } else {
341 $last_branch = basename(readlink("$git_dir/HEAD"));
342 unless($last_branch) {
343 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
344 $last_branch = "master";
345 }
346 $orig_branch = $last_branch;
348 # Get the last import timestamps
349 opendir(D,"$git_dir/refs/heads");
350 while(defined(my $head = readdir(D))) {
351 next if $head =~ /^\./;
352 open(F,"$git_dir/refs/heads/$head")
353 or die "Bad head branch: $head: $!\n";
354 chomp(my $ftag = <F>);
355 close(F);
356 open(F,"git-cat-file commit $ftag |");
357 while(<F>) {
358 next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
359 $branch_date{$head} = $1;
360 last;
361 }
362 close(F);
363 }
364 closedir(D);
365 }
367 -d $git_dir
368 or die "Could not create git subdir ($git_dir).\n";
370 my $pid = open(CVS,"-|");
371 die "Cannot fork: $!\n" unless defined $pid;
372 unless($pid) {
373 exec("cvsps","-A","--cvs-direct",$cvs_tree);
374 die "Could not start cvsps: $!\n";
375 }
378 ## cvsps output:
379 #---------------------
380 #PatchSet 314
381 #Date: 1999/09/18 13:03:59
382 #Author: wkoch
383 #Branch: STABLE-BRANCH-1-0
384 #Ancestor branch: HEAD
385 #Tag: (none)
386 #Log:
387 # See ChangeLog: Sat Sep 18 13:03:28 CEST 1999 Werner Koch
388 #Members:
389 # README:1.57->1.57.2.1
390 # VERSION:1.96->1.96.2.1
391 #
392 #---------------------
394 my $state = 0;
396 my($patchset,$date,$author,$branch,$ancestor,$tag,$logmsg);
397 my(@old,@new);
398 my $commit = sub {
399 my $pid;
400 while(@old) {
401 my @o2;
402 if(@old > 55) {
403 @o2 = splice(@old,0,50);
404 } else {
405 @o2 = @old;
406 @old = ();
407 }
408 system("git-update-cache","--force-remove","--",@o2);
409 die "Cannot remove files: $?\n" if $?;
410 }
411 while(@new) {
412 my @n2;
413 if(@new > 55) {
414 @n2 = splice(@new,0,50);
415 } else {
416 @n2 = @new;
417 @new = ();
418 }
419 system("git-update-cache","--add","--",@n2);
420 die "Cannot add files: $?\n" if $?;
421 }
423 $pid = open(C,"-|");
424 die "Cannot fork: $!" unless defined $pid;
425 unless($pid) {
426 exec("git-write-tree");
427 die "Cannot exec git-write-tree: $!\n";
428 }
429 chomp(my $tree = <C>);
430 length($tree) == 40
431 or die "Cannot get tree id ($tree): $!\n";
432 close(C)
433 or die "Error running git-write-tree: $?\n";
434 print "Tree ID $tree\n" if $opt_v;
436 my $parent = "";
437 if(open(C,"$git_dir/refs/heads/$last_branch")) {
438 chomp($parent = <C>);
439 close(C);
440 length($parent) == 40
441 or die "Cannot get parent id ($parent): $!\n";
442 print "Parent ID $parent\n" if $opt_v;
443 }
445 my $pr = IO::Pipe->new();
446 my $pw = IO::Pipe->new();
447 $pid = fork();
448 die "Fork: $!\n" unless defined $pid;
449 unless($pid) {
450 $pr->writer();
451 $pw->reader();
452 dup2($pw->fileno(),0);
453 dup2($pr->fileno(),1);
454 $pr->close();
455 $pw->close();
457 my @par = ();
458 @par = ("-p",$parent) if $parent;
459 exec("env",
460 "GIT_AUTHOR_NAME=$author",
461 "GIT_AUTHOR_EMAIL=$author",
462 "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
463 "GIT_COMMITTER_NAME=$author",
464 "GIT_COMMITTER_EMAIL=$author",
465 "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
466 "git-commit-tree", $tree,@par);
467 die "Cannot exec git-commit-tree: $!\n";
468 }
469 $pw->writer();
470 $pr->reader();
471 print $pw $logmsg
472 or die "Error writing to git-commit-tree: $!\n";
473 $pw->close();
475 print "Committed patch $patchset ($branch)\n" if $opt_v;
476 chomp(my $cid = <$pr>);
477 length($cid) == 40
478 or die "Cannot get commit id ($cid): $!\n";
479 print "Commit ID $cid\n" if $opt_v;
480 $pr->close();
482 waitpid($pid,0);
483 die "Error running git-commit-tree: $?\n" if $?;
485 open(C,">$git_dir/refs/heads/$branch")
486 or die "Cannot open branch $branch for update: $!\n";
487 print C "$cid\n"
488 or die "Cannot write branch $branch for update: $!\n";
489 close(C)
490 or die "Cannot write branch $branch for update: $!\n";
492 if($tag) {
493 open(C,">$git_dir/refs/tags/$tag")
494 or die "Cannot create tag $tag: $!\n";
495 print C "$cid\n"
496 or die "Cannot write tag $branch: $!\n";
497 close(C)
498 or die "Cannot write tag $branch: $!\n";
499 print "Created tag '$tag' on '$branch'\n" if $opt_v;
500 }
502 @old = ();
503 @new = ();
504 };
506 while(<CVS>) {
507 chomp;
508 if($state == 0 and /^-+$/) {
509 $state = 1;
510 } elsif($state == 0) {
511 $state = 1;
512 redo;
513 } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
514 $patchset = 0+$_;
515 $state=2;
516 } elsif($state == 2 and s/^Date:\s+//) {
517 $date = pdate($_);
518 unless($date) {
519 print STDERR "Could not parse date: $_\n";
520 $state=0;
521 next;
522 }
523 $state=3;
524 } elsif($state == 3 and s/^Author:\s+//) {
525 s/\s+$//;
526 $author = $_;
527 $state = 4;
528 } elsif($state == 4 and s/^Branch:\s+//) {
529 s/\s+$//;
530 $branch = $_;
531 $state = 5;
532 } elsif($state == 5 and s/^Ancestor branch:\s+//) {
533 s/\s+$//;
534 $ancestor = $_;
535 $ancestor = $opt_o if $ancestor == "HEAD";
536 $state = 6;
537 } elsif($state == 5) {
538 $ancestor = undef;
539 $state = 6;
540 redo;
541 } elsif($state == 6 and s/^Tag:\s+//) {
542 s/\s+$//;
543 if($_ eq "(none)") {
544 $tag = undef;
545 } else {
546 $tag = $_;
547 }
548 $state = 7;
549 } elsif($state == 7 and /^Log:/) {
550 $logmsg = "";
551 $state = 8;
552 } elsif($state == 8 and /^Members:/) {
553 $branch = $opt_o if $branch eq "HEAD";
554 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
555 # skip
556 print "skip patchset $patchset: $date before $branch_date{$branch}\n";
557 $state = 11;
558 next;
559 }
560 if($ancestor) {
561 if(-f "$git_dir/refs/heads/$branch") {
562 print STDERR "Branch $branch already exists!\n";
563 $state=11;
564 next;
565 }
566 unless(open(H,"$git_dir/refs/heads/$ancestor")) {
567 print STDERR "Branch $ancestor does not exist!\n";
568 $state=11;
569 next;
570 }
571 chomp(my $id = <H>);
572 close(H);
573 unless(open(H,"> $git_dir/refs/heads/$branch")) {
574 print STDERR "Could not create branch $branch: $!\n";
575 $state=11;
576 next;
577 }
578 print H "$id\n"
579 or die "Could not write branch $branch: $!";
580 close(H)
581 or die "Could not write branch $branch: $!";
582 }
583 if(($ancestor || $branch) ne $last_branch) {
584 print "Switching from $last_branch to $branch\n" if $opt_v;
585 system("git-read-tree","-m","-u","$last_branch","$branch");
586 die "read-tree failed: $?\n" if $?;
587 }
588 if($branch ne $last_branch) {
589 unlink("$git_dir/HEAD");
590 symlink("refs/heads/$branch","$git_dir/HEAD");
591 $last_branch = $branch;
592 }
593 $state = 9;
594 } elsif($state == 8) {
595 $logmsg .= "$_\n";
596 } elsif($state == 9 and /^\s+(\S+):(INITIAL|\d(?:\.\d+)+)->(\d(?:\.\d+)+)\s*$/) {
597 # VERSION:1.96->1.96.2.1
598 my $init = ($2 eq "INITIAL");
599 my $fn = $1;
600 my $rev = $3;
601 $fn =~ s#^/+##;
602 my $data = $cvs->file($fn,$rev);
603 print "".($init ? "New" : "Update")." $fn: ".length($data)." bytes.\n";
604 mkpath(dirname($fn),$opt_v);
605 open(F,"> ./$fn")
606 or die "Cannot create '$fn': $!\n";
607 print F $data
608 or die "Cannot write to '$fn': $!\n";
609 close(F)
610 or die "Cannot write to '$fn': $!\n";
611 chmod(pmode($cvs->{'mode'}), $fn);
612 push(@new,$fn); # may be resurrected!
613 } elsif($state == 9 and /^\s+(\S+):\d(?:\.\d+)+->(\d(?:\.\d+)+)\(DEAD\)\s*$/) {
614 my $fn = $1;
615 $fn =~ s#^/+##;
616 push(@old,$fn);
617 } elsif($state == 9 and /^\s*$/) {
618 $state = 10;
619 } elsif(($state == 9 or $state == 10) and /^-+$/) {
620 &$commit();
621 $state = 1;
622 } elsif($state == 11 and /^-+$/) {
623 $state = 1;
624 } elsif(/^-+$/) { # end of unknown-line processing
625 $state = 1;
626 } elsif($state != 11) { # ignore stuff when skipping
627 print "* UNKNOWN LINE * $_\n";
628 }
629 }
630 &$commit() if $branch and $state != 11;
632 # Now switch back to the branch we were in before all of this happened
633 if($orig_branch) {
634 print "DONE; switching back to $orig_branch\n" if $opt_v;
635 } else {
636 $orig_branch = "master";
637 print "DONE; creating $orig_branch branch\n" if $opt_v;
638 system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
639 unless -f "$git_dir/refs/heads/master";
640 }
642 system("git-read-tree","-m","-u","$last_branch","$orig_branch");
643 die "read-tree failed: $?\n" if $?;
645 unlink("$git_dir/HEAD");
646 symlink("refs/heads/$orig_branch","$git_dir/HEAD");