contrib/fast-import/import-tars.perl

   1 #!/usr/bin/perl
   2
   3 ## tar archive frontend for git-fast-import
   4 ##
   5 ## For example:
   6 ##
   7 ##  mkdir project; cd project; git init
   8 ##  perl import-tars.perl *.tar.bz2
   9 ##  git whatchanged import-tars
  10 ##
  11
  12 use strict;
  13 die "usage: import-tars *.tar.{gz,bz2,Z}\n" unless @ARGV;
  14
  15 my $branch_name = 'import-tars';
  16 my $branch_ref = "refs/heads/$branch_name";
  17 my $committer_name = 'T Ar Creator';
  18 my $committer_email = 'tar@example.com';
  19
  20 open(FI, '|-', 'git', 'fast-import', '--quiet')
  21         or die "Unable to start git fast-import: $!\n";
  22 foreach my $tar_file (@ARGV)
  23 {
  24         $tar_file =~ m,([^/]+)$,;
  25         my $tar_name = $1;
  26
  27         if ($tar_name =~ s/\.(tar\.gz|tgz)$//) {
  28                 open(I, '-|', 'gunzip', '-c', $tar_file)
  29                         or die "Unable to gunzip -c $tar_file: $!\n";
  30         } elsif ($tar_name =~ s/\.(tar\.bz2|tbz2)$//) {
  31                 open(I, '-|', 'bunzip2', '-c', $tar_file)
  32                         or die "Unable to bunzip2 -c $tar_file: $!\n";
  33         } elsif ($tar_name =~ s/\.tar\.Z$//) {
  34                 open(I, '-|', 'uncompress', '-c', $tar_file)
  35                         or die "Unable to uncompress -c $tar_file: $!\n";
  36         } elsif ($tar_name =~ s/\.tar$//) {
  37                 open(I, $tar_file) or die "Unable to open $tar_file: $!\n";
  38         } else {
  39                 die "Unrecognized compression format: $tar_file\n";
  40         }
  41
  42         my $commit_time = 0;
  43         my $next_mark = 1;
  44         my $have_top_dir = 1;
  45         my ($top_dir, %files);
  46
  47         while (read(I, $_, 512) == 512) {
  48                 my ($name, $mode, $uid, $gid, $size, $mtime,
  49                         $chksum, $typeflag, $linkname, $magic,
  50                         $version, $uname, $gname, $devmajor, $devminor,
  51                         $prefix) = unpack 'Z100 Z8 Z8 Z8 Z12 Z12
  52                         Z8 Z1 Z100 Z6
  53                         Z2 Z32 Z32 Z8 Z8 Z*', $_;
  54                 last unless $name;
  55                 $mode = oct $mode;
  56                 $size = oct $size;
  57                 $mtime = oct $mtime;
  58                 next if $mode & 0040000;
  59
  60                 print FI "blob\n", "mark :$next_mark\n", "data $size\n";
  61                 while ($size > 0 && read(I, $_, 512) == 512) {
  62                         print FI substr($_, 0, $size);
  63                         $size -= 512;
  64                 }
  65                 print FI "\n";
  66
  67                 my $path = "$prefix$name";
  68                 $files{$path} = [$next_mark++, $mode];
  69
  70                 $commit_time = $mtime if $mtime > $commit_time;
  71                 $path =~ m,^([^/]+)/,;
  72                 $top_dir = $1 unless $top_dir;
  73                 $have_top_dir = 0 if $top_dir ne $1;
  74         }
  75
  76         print FI <<EOF;
  77 commit $branch_ref
  78 committer $committer_name <$committer_email> $commit_time +0000
  79 data <<END_OF_COMMIT_MESSAGE
  80 Imported from $tar_file.
  81 END_OF_COMMIT_MESSAGE
  82
  83 deleteall
  84 EOF
  85
  86         foreach my $path (keys %files)
  87         {
  88                 my ($mark, $mode) = @{$files{$path}};
  89                 $path =~ s,^([^/]+)/,, if $have_top_dir;
  90                 printf FI "M %o :%i %s\n", $mode & 0111 ? 0755 : 0644, $mark, $path;
  91         }
  92         print FI "\n";
  93
  94         print FI <<EOF;
  95 tag $tar_name
  96 from $branch_ref
  97 tagger $committer_name <$committer_email> $commit_time +0000
  98 data <<END_OF_TAG_MESSAGE
  99 Package $tar_name
 100 END_OF_TAG_MESSAGE
 101
 102 EOF
 103
 104         close I;
 105 }
 106 close FI;