contrib/fast-import/import-tars.perl

   1 #!/usr/bin/perl
   2
   3 ## tar archive frontend for git-fast-import
   4 ##
   5 ## For example:
   6 ##
   7 ##  mkdir project; cd project; git init
   8 ##  perl import-tars.perl *.tar.bz2
   9 ##  git whatchanged import-tars
  10 ##
  11
  12 use strict;
  13 die "usage: import-tars *.tar.{gz,bz2,Z}\n" unless @ARGV;
  14
  15 my $branch_name = 'import-tars';
  16 my $branch_ref = "refs/heads/$branch_name";
  17 my $committer_name = 'T Ar Creator';
  18 my $committer_email = 'tar@example.com';
  19
  20 open(FI, '|-', 'git', 'fast-import', '--quiet')
  21         or die "Unable to start git fast-import: $!\n";
  22 foreach my $tar_file (@ARGV)
  23 {
  24         $tar_file =~ m,([^/]+)$,;
  25         my $tar_name = $1;
  26
  27         if ($tar_name =~ s/\.(tar\.gz|tgz)$//) {
  28                 open(I, '-|', 'gunzip', '-c', $tar_file)
  29                         or die "Unable to gunzip -c $tar_file: $!\n";
  30         } elsif ($tar_name =~ s/\.(tar\.bz2|tbz2)$//) {
  31                 open(I, '-|', 'bunzip2', '-c', $tar_file)
  32                         or die "Unable to bunzip2 -c $tar_file: $!\n";
  33         } elsif ($tar_name =~ s/\.tar\.Z$//) {
  34                 open(I, '-|', 'uncompress', '-c', $tar_file)
  35                         or die "Unable to uncompress -c $tar_file: $!\n";
  36         } elsif ($tar_name =~ s/\.tar$//) {
  37                 open(I, $tar_file) or die "Unable to open $tar_file: $!\n";
  38         } else {
  39                 die "Unrecognized compression format: $tar_file\n";
  40         }
  41
  42         my $commit_time = 0;
  43         my $next_mark = 1;
  44         my $have_top_dir = 1;
  45         my ($top_dir, %files);
  46
  47         while (read(I, $_, 512) == 512) {
  48                 my ($name, $mode, $uid, $gid, $size, $mtime,
  49                         $chksum, $typeflag, $linkname, $magic,
  50                         $version, $uname, $gname, $devmajor, $devminor,
  51                         $prefix) = unpack 'Z100 Z8 Z8 Z8 Z12 Z12
  52                         Z8 Z1 Z100 Z6
  53                         Z2 Z32 Z32 Z8 Z8 Z*', $_;
  54                 last unless $name;
  55                 next if $name =~ m{/\z};
  56                 $mode = oct $mode;
  57                 $size = oct $size;
  58                 $mtime = oct $mtime;
  59                 next if $mode & 0040000;
  60
  61                 print FI "blob\n", "mark :$next_mark\n", "data $size\n";
  62                 while ($size > 0 && read(I, $_, 512) == 512) {
  63                         print FI substr($_, 0, $size);
  64                         $size -= 512;
  65                 }
  66                 print FI "\n";
  67
  68                 my $path;
  69                 if ($prefix) {
  70                         $path = "$prefix/$name";
  71                 } else {
  72                         $path = "$name";
  73                 }
  74                 $files{$path} = [$next_mark++, $mode];
  75
  76                 $commit_time = $mtime if $mtime > $commit_time;
  77                 $path =~ m,^([^/]+)/,;
  78                 $top_dir = $1 unless $top_dir;
  79                 $have_top_dir = 0 if $top_dir ne $1;
  80         }
  81
  82         print FI <<EOF;
  83 commit $branch_ref
  84 committer $committer_name <$committer_email> $commit_time +0000
  85 data <<END_OF_COMMIT_MESSAGE
  86 Imported from $tar_file.
  87 END_OF_COMMIT_MESSAGE
  88
  89 deleteall
  90 EOF
  91
  92         foreach my $path (keys %files)
  93         {
  94                 my ($mark, $mode) = @{$files{$path}};
  95                 $path =~ s,^([^/]+)/,, if $have_top_dir;
  96                 printf FI "M %o :%i %s\n", $mode & 0111 ? 0755 : 0644, $mark, $path;
  97         }
  98         print FI "\n";
  99
 100         print FI <<EOF;
 101 tag $tar_name
 102 from $branch_ref
 103 tagger $committer_name <$committer_email> $commit_time +0000
 104 data <<END_OF_TAG_MESSAGE
 105 Package $tar_name
 106 END_OF_TAG_MESSAGE
 107
 108 EOF
 109
 110         close I;
 111 }
 112 close FI;