contrib/emacs/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006 Alexandre Julliard
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the GNU General Public License as
   7 ;; published by the Free Software Foundation; either version 2 of
   8 ;; the License, or (at your option) any later version.
   9 ;;
  10 ;; This program is distributed in the hope that it will be
  11 ;; useful, but WITHOUT ANY WARRANTY; without even the implied
  12 ;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  13 ;; PURPOSE.  See the GNU General Public License for more details.
  14 ;;
  15 ;; You should have received a copy of the GNU General Public
  16 ;; License along with this program; if not, write to the Free
  17 ;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  18 ;; MA 02111-1307 USA
  19
  20 ;;; Commentary:
  21
  22 ;; This file contains a VC backend for the git version control
  23 ;; system.
  24 ;;
  25 ;; To install: put this file on the load-path and add GIT to the list
  26 ;; of supported backends in `vc-handled-backends'; the following line,
  27 ;; placed in your ~/.emacs, will accomplish this:
  28 ;;
  29 ;;     (add-to-list 'vc-handled-backends 'GIT)
  30 ;;
  31 ;; TODO
  32 ;;  - changelog generation
  33 ;;  - working with revisions other than HEAD
  34 ;;
  35
  36 (eval-when-compile (require 'cl))
  37
  38 (defvar git-commits-coding-system 'utf-8
  39   "Default coding system for git commits.")
  40
  41 (defun vc-git--run-command-string (file &rest args)
  42   "Run a git command on FILE and return its output as string."
  43   (let* ((ok t)
  44          (str (with-output-to-string
  45                 (with-current-buffer standard-output
  46                   (unless (eq 0 (apply #'call-process "git" nil '(t nil) nil
  47                                        (append args (list (file-relative-name file)))))
  48                     (setq ok nil))))))
  49     (and ok str)))
  50
  51 (defun vc-git--run-command (file &rest args)
  52   "Run a git command on FILE, discarding any output."
  53   (let ((name (file-relative-name file)))
  54     (eq 0 (apply #'call-process "git" nil (get-buffer "*Messages") nil (append args (list name))))))
  55
  56 (defun vc-git-registered (file)
  57   "Check whether FILE is registered with git."
  58   (with-temp-buffer
  59     (let* ((dir (file-name-directory file))
  60            (name (file-relative-name file dir)))
  61       (when dir (cd dir))
  62       (and (ignore-errors (eq 0 (call-process "git" nil '(t nil) nil "ls-files" "-c" "-z" "--" name)))
  63            (let ((str (buffer-string)))
  64              (and (> (length str) (length name))
  65                   (string= (substring str 0 (1+ (length name))) (concat name "\0"))))))))
  66
  67 (defun vc-git-state (file)
  68   "git-specific version of `vc-state'."
  69   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
  70     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0" diff))
  71         'edited
  72       'up-to-date)))
  73
  74 (defun vc-git-workfile-version (file)
  75   "git-specific version of `vc-workfile-version'."
  76   (let ((str (with-output-to-string
  77                (with-current-buffer standard-output
  78                  (call-process "git" nil '(t nil) nil "symbolic-ref" "HEAD")))))
  79     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
  80         (match-string 2 str)
  81       str)))
  82
  83 (defun vc-git-revert (file &optional contents-done)
  84   "Revert FILE to the version stored in the git repository."
  85   (if contents-done
  86       (vc-git--run-command file "update-index" "--")
  87     (vc-git--run-command file "checkout" "HEAD")))
  88
  89 (defun vc-git-checkout-model (file)
  90   'implicit)
  91
  92 (defun vc-git-workfile-unchanged-p (file)
  93   (let ((sha1 (vc-git--run-command-string file "hash-object" "--"))
  94         (head (vc-git--run-command-string file "ls-tree" "-z" "HEAD" "--")))
  95     (and head
  96          (string-match "[0-7]\\{6\\} blob \\([0-9a-f]\\{40\\}\\)\t[^\0]+\0" head)
  97          (string= (car (split-string sha1 "\n")) (match-string 1 head)))))
  98
  99 (defun vc-git-register (file &optional rev comment)
 100   "Register FILE into the git version-control system."
 101   (vc-git--run-command file "update-index" "--add" "--"))
 102
 103 (defun vc-git-print-log (file &optional buffer)
 104   (let ((name (file-relative-name file))
 105         (coding-system-for-read git-commits-coding-system))
 106     (vc-do-command buffer 'async "git" name "rev-list" "--pretty" "HEAD" "--")))
 107
 108 (defun vc-git-diff (file &optional rev1 rev2 buffer)
 109   (let ((name (file-relative-name file))
 110         (buf (or buffer "*vc-diff*")))
 111     (if (and rev1 rev2)
 112         (vc-do-command buf 0 "git" name "diff-tree" "-p" rev1 rev2 "--")
 113       (vc-do-command buf 0 "git" name "diff-index" "-p" (or rev1 "HEAD") "--"))
 114     ; git-diff-index doesn't set exit status like diff does
 115     (if (vc-git-workfile-unchanged-p file) 0 1)))
 116
 117 (defun vc-git-checkin (file rev comment)
 118   (let ((coding-system-for-write git-commits-coding-system))
 119     (vc-git--run-command file "commit" "-m" comment "--only" "--")))
 120
 121 (defun vc-git-checkout (file &optional editable rev destfile)
 122   (vc-git--run-command file "checkout" (or rev "HEAD")))
 123
 124 (defun vc-git-annotate-command (file buf &optional rev)
 125   ; FIXME: rev is ignored
 126   (let ((name (file-relative-name file)))
 127     (call-process "git" nil buf nil "blame" name)))
 128
 129 (defun vc-git-annotate-time ()
 130   (and (re-search-forward "[0-9a-f]+ (.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+)" nil t)
 131        (vc-annotate-convert-time
 132         (apply #'encode-time (mapcar (lambda (match) (string-to-number (match-string match))) '(6 5 4 3 2 1 7))))))
 133
 134 ;; Not really useful since we can't do anything with the revision yet
 135 ;;(defun vc-annotate-extract-revision-at-line ()
 136 ;;  (save-excursion
 137 ;;    (move-beginning-of-line 1)
 138 ;;    (and (looking-at "[0-9a-f]+")
 139 ;;         (buffer-substring (match-beginning 0) (match-end 0)))))
 140
 141 (provide 'vc-git)