contrib/emacs/git.el

   1 ;;; git.el --- A user interface for git
   2
   3 ;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5 ;; Version: 1.0
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation; either version 2 of
  10 ;; the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be
  13 ;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14 ;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 ;; PURPOSE.  See the GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public
  18 ;; License along with this program; if not, write to the Free
  19 ;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20 ;; MA 02111-1307 USA
  21
  22 ;;; Commentary:
  23
  24 ;; This file contains an interface for the git version control
  25 ;; system. It provides easy access to the most frequently used git
  26 ;; commands. The user interface is as far as possible identical to
  27 ;; that of the PCL-CVS mode.
  28 ;;
  29 ;; To install: put this file on the load-path and place the following
  30 ;; in your .emacs file:
  31 ;;
  32 ;;    (require 'git)
  33 ;;
  34 ;; To start: `M-x git-status'
  35 ;;
  36 ;; TODO
  37 ;;  - portability to XEmacs
  38 ;;  - better handling of subprocess errors
  39 ;;  - diff against other branch
  40 ;;  - renaming files from the status buffer
  41 ;;  - creating tags
  42 ;;  - fetch/pull
  43 ;;  - switching branches
  44 ;;  - revlist browser
  45 ;;  - git-show-branch browser
  46 ;;  - menus
  47 ;;
  48
  49 (eval-when-compile (require 'cl))
  50 (require 'ewoc)
  51 (require 'log-edit)
  52 (require 'easymenu)
  53
  54
  55 ;;;; Customizations
  56 ;;;; ------------------------------------------------------------
  57
  58 (defgroup git nil
  59   "A user interface for the git versioning system."
  60   :group 'tools)
  61
  62 (defcustom git-committer-name nil
  63   "User name to use for commits.
  64 The default is to fall back to the repository config,
  65 then to `add-log-full-name' and then to `user-full-name'."
  66   :group 'git
  67   :type '(choice (const :tag "Default" nil)
  68                  (string :tag "Name")))
  69
  70 (defcustom git-committer-email nil
  71   "Email address to use for commits.
  72 The default is to fall back to the git repository config,
  73 then to `add-log-mailing-address' and then to `user-mail-address'."
  74   :group 'git
  75   :type '(choice (const :tag "Default" nil)
  76                  (string :tag "Email")))
  77
  78 (defcustom git-commits-coding-system nil
  79   "Default coding system for the log message of git commits."
  80   :group 'git
  81   :type '(choice (const :tag "From repository config" nil)
  82                  (coding-system)))
  83
  84 (defcustom git-append-signed-off-by nil
  85   "Whether to append a Signed-off-by line to the commit message before editing."
  86   :group 'git
  87   :type 'boolean)
  88
  89 (defcustom git-reuse-status-buffer t
  90   "Whether `git-status' should try to reuse an existing buffer
  91 if there is already one that displays the same directory."
  92   :group 'git
  93   :type 'boolean)
  94
  95 (defcustom git-per-dir-ignore-file ".gitignore"
  96   "Name of the per-directory ignore file."
  97   :group 'git
  98   :type 'string)
  99
 100 (defcustom git-show-uptodate nil
 101   "Whether to display up-to-date files."
 102   :group 'git
 103   :type 'boolean)
 104
 105 (defcustom git-show-ignored nil
 106   "Whether to display ignored files."
 107   :group 'git
 108   :type 'boolean)
 109
 110 (defcustom git-show-unknown t
 111   "Whether to display unknown files."
 112   :group 'git
 113   :type 'boolean)
 114
 115
 116 (defface git-status-face
 117   '((((class color) (background light)) (:foreground "purple"))
 118     (((class color) (background dark)) (:foreground "salmon")))
 119   "Git mode face used to highlight added and modified files."
 120   :group 'git)
 121
 122 (defface git-unmerged-face
 123   '((((class color) (background light)) (:foreground "red" :bold t))
 124     (((class color) (background dark)) (:foreground "red" :bold t)))
 125   "Git mode face used to highlight unmerged files."
 126   :group 'git)
 127
 128 (defface git-unknown-face
 129   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 130     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 131   "Git mode face used to highlight unknown files."
 132   :group 'git)
 133
 134 (defface git-uptodate-face
 135   '((((class color) (background light)) (:foreground "grey60"))
 136     (((class color) (background dark)) (:foreground "grey40")))
 137   "Git mode face used to highlight up-to-date files."
 138   :group 'git)
 139
 140 (defface git-ignored-face
 141   '((((class color) (background light)) (:foreground "grey60"))
 142     (((class color) (background dark)) (:foreground "grey40")))
 143   "Git mode face used to highlight ignored files."
 144   :group 'git)
 145
 146 (defface git-mark-face
 147   '((((class color) (background light)) (:foreground "red" :bold t))
 148     (((class color) (background dark)) (:foreground "tomato" :bold t)))
 149   "Git mode face used for the file marks."
 150   :group 'git)
 151
 152 (defface git-header-face
 153   '((((class color) (background light)) (:foreground "blue"))
 154     (((class color) (background dark)) (:foreground "blue")))
 155   "Git mode face used for commit headers."
 156   :group 'git)
 157
 158 (defface git-separator-face
 159   '((((class color) (background light)) (:foreground "brown"))
 160     (((class color) (background dark)) (:foreground "brown")))
 161   "Git mode face used for commit separator."
 162   :group 'git)
 163
 164 (defface git-permission-face
 165   '((((class color) (background light)) (:foreground "green" :bold t))
 166     (((class color) (background dark)) (:foreground "green" :bold t)))
 167   "Git mode face used for permission changes."
 168   :group 'git)
 169
 170
 171 ;;;; Utilities
 172 ;;;; ------------------------------------------------------------
 173
 174 (defconst git-log-msg-separator "--- log message follows this line ---")
 175
 176 (defvar git-log-edit-font-lock-keywords
 177   `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 178      (1 font-lock-keyword-face)
 179      (2 font-lock-function-name-face))
 180     (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 181      (1 font-lock-comment-face))))
 182
 183 (defun git-get-env-strings (env)
 184   "Build a list of NAME=VALUE strings from a list of environment strings."
 185   (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 186
 187 (defun git-call-process-env (buffer env &rest args)
 188   "Wrapper for call-process that sets environment strings."
 189   (if env
 190       (apply #'call-process "env" nil buffer nil
 191              (append (git-get-env-strings env) (list "git") args))
 192     (apply #'call-process "git" nil buffer nil args)))
 193
 194 (defun git-call-process-env-string (env &rest args)
 195   "Wrapper for call-process that sets environment strings,
 196 and returns the process output as a string."
 197   (with-temp-buffer
 198     (and (eq 0 (apply #' git-call-process-env t env args))
 199          (buffer-string))))
 200
 201 (defun git-run-process-region (buffer start end program args)
 202   "Run a git process with a buffer region as input."
 203   (let ((output-buffer (current-buffer))
 204         (dir default-directory))
 205     (with-current-buffer buffer
 206       (cd dir)
 207       (apply #'call-process-region start end program
 208              nil (list output-buffer nil) nil args))))
 209
 210 (defun git-run-command-buffer (buffer-name &rest args)
 211   "Run a git command, sending the output to a buffer named BUFFER-NAME."
 212   (let ((dir default-directory)
 213         (buffer (get-buffer-create buffer-name)))
 214     (message "Running git %s..." (car args))
 215     (with-current-buffer buffer
 216       (let ((default-directory dir)
 217             (buffer-read-only nil))
 218         (erase-buffer)
 219         (apply #'git-call-process-env buffer nil args)))
 220     (message "Running git %s...done" (car args))
 221     buffer))
 222
 223 (defun git-run-command-region (buffer start end env &rest args)
 224   "Run a git command with specified buffer region as input."
 225   (unless (eq 0 (if env
 226                     (git-run-process-region
 227                      buffer start end "env"
 228                      (append (git-get-env-strings env) (list "git") args))
 229                   (git-run-process-region
 230                    buffer start end "git" args)))
 231     (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string))))
 232
 233 (defun git-run-hook (hook env &rest args)
 234   "Run a git hook and display its output if any."
 235   (let ((dir default-directory)
 236         (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 237     (or (not (file-executable-p hook-name))
 238         (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 239           (with-current-buffer buffer
 240             (erase-buffer)
 241             (cd dir)
 242             (setq status
 243                   (if env
 244                       (apply #'call-process "env" nil (list buffer t) nil
 245                              (append (git-get-env-strings env) (list hook-name) args))
 246                     (apply #'call-process hook-name nil (list buffer t) nil args))))
 247           (display-message-or-buffer buffer)
 248           (eq 0 status)))))
 249
 250 (defun git-get-string-sha1 (string)
 251   "Read a SHA1 from the specified string."
 252   (and string
 253        (string-match "[0-9a-f]\\{40\\}" string)
 254        (match-string 0 string)))
 255
 256 (defun git-get-committer-name ()
 257   "Return the name to use as GIT_COMMITTER_NAME."
 258   ; copied from log-edit
 259   (or git-committer-name
 260       (git-config "user.name")
 261       (and (boundp 'add-log-full-name) add-log-full-name)
 262       (and (fboundp 'user-full-name) (user-full-name))
 263       (and (boundp 'user-full-name) user-full-name)))
 264
 265 (defun git-get-committer-email ()
 266   "Return the email address to use as GIT_COMMITTER_EMAIL."
 267   ; copied from log-edit
 268   (or git-committer-email
 269       (git-config "user.email")
 270       (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 271       (and (fboundp 'user-mail-address) (user-mail-address))
 272       (and (boundp 'user-mail-address) user-mail-address)))
 273
 274 (defun git-get-commits-coding-system ()
 275   "Return the coding system to use for commits."
 276   (let ((repo-config (git-config "i18n.commitencoding")))
 277     (or git-commits-coding-system
 278         (and repo-config
 279              (fboundp 'locale-charset-to-coding-system)
 280              (locale-charset-to-coding-system repo-config))
 281       'utf-8)))
 282
 283 (defun git-get-logoutput-coding-system ()
 284   "Return the coding system used for git-log output."
 285   (let ((repo-config (or (git-config "i18n.logoutputencoding")
 286                          (git-config "i18n.commitencoding"))))
 287     (or git-commits-coding-system
 288         (and repo-config
 289              (fboundp 'locale-charset-to-coding-system)
 290              (locale-charset-to-coding-system repo-config))
 291       'utf-8)))
 292
 293 (defun git-escape-file-name (name)
 294   "Escape a file name if necessary."
 295   (if (string-match "[\n\t\"\\]" name)
 296       (concat "\""
 297               (mapconcat (lambda (c)
 298                    (case c
 299                      (?\n "\\n")
 300                      (?\t "\\t")
 301                      (?\\ "\\\\")
 302                      (?\" "\\\"")
 303                      (t (char-to-string c))))
 304                  name "")
 305               "\"")
 306     name))
 307
 308 (defun git-success-message (text files)
 309   "Print a success message after having handled FILES."
 310   (let ((n (length files)))
 311     (if (equal n 1)
 312         (message "%s %s" text (car files))
 313       (message "%s %d files" text n))))
 314
 315 (defun git-get-top-dir (dir)
 316   "Retrieve the top-level directory of a git tree."
 317   (let ((cdup (with-output-to-string
 318                 (with-current-buffer standard-output
 319                   (cd dir)
 320                   (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 321                     (error "cannot find top-level git tree for %s." dir))))))
 322     (expand-file-name (concat (file-name-as-directory dir)
 323                               (car (split-string cdup "\n"))))))
 324
 325 ;stolen from pcl-cvs
 326 (defun git-append-to-ignore (file)
 327   "Add a file name to the ignore file in its directory."
 328   (let* ((fullname (expand-file-name file))
 329          (dir (file-name-directory fullname))
 330          (name (file-name-nondirectory fullname))
 331          (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 332          (created (not (file-exists-p ignore-name))))
 333   (save-window-excursion
 334     (set-buffer (find-file-noselect ignore-name))
 335     (goto-char (point-max))
 336     (unless (zerop (current-column)) (insert "\n"))
 337     (insert "/" name "\n")
 338     (sort-lines nil (point-min) (point-max))
 339     (save-buffer))
 340   (when created
 341     (git-call-process-env nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 342   (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 343
 344 ; propertize definition for XEmacs, stolen from erc-compat
 345 (eval-when-compile
 346   (unless (fboundp 'propertize)
 347     (defun propertize (string &rest props)
 348       (let ((string (copy-sequence string)))
 349         (while props
 350           (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 351           (setq props (cddr props)))
 352         string))))
 353
 354 ;;;; Wrappers for basic git commands
 355 ;;;; ------------------------------------------------------------
 356
 357 (defun git-rev-parse (rev)
 358   "Parse a revision name and return its SHA1."
 359   (git-get-string-sha1
 360    (git-call-process-env-string nil "rev-parse" rev)))
 361
 362 (defun git-config (key)
 363   "Retrieve the value associated to KEY in the git repository config file."
 364   (let ((str (git-call-process-env-string nil "config" key)))
 365     (and str (car (split-string str "\n")))))
 366
 367 (defun git-symbolic-ref (ref)
 368   "Wrapper for the git-symbolic-ref command."
 369   (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 370     (and str (car (split-string str "\n")))))
 371
 372 (defun git-update-ref (ref newval &optional oldval reason)
 373   "Update a reference by calling git-update-ref."
 374   (let ((args (and oldval (list oldval))))
 375     (push newval args)
 376     (push ref args)
 377     (when reason
 378      (push reason args)
 379      (push "-m" args))
 380     (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 381
 382 (defun git-read-tree (tree &optional index-file)
 383   "Read a tree into the index file."
 384   (apply #'git-call-process-env nil
 385          (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 386          "read-tree" (if tree (list tree))))
 387
 388 (defun git-write-tree (&optional index-file)
 389   "Call git-write-tree and return the resulting tree SHA1 as a string."
 390   (git-get-string-sha1
 391    (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 392
 393 (defun git-commit-tree (buffer tree head)
 394   "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 395   (let ((author-name (git-get-committer-name))
 396         (author-email (git-get-committer-email))
 397         (subject "commit (initial): ")
 398         author-date log-start log-end args coding-system-for-write)
 399     (when head
 400       (setq subject "commit: ")
 401       (push "-p" args)
 402       (push head args))
 403     (with-current-buffer buffer
 404       (goto-char (point-min))
 405       (if
 406           (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 407           (save-restriction
 408             (narrow-to-region (point-min) log-start)
 409             (goto-char (point-min))
 410             (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 411               (setq author-name (match-string 1)
 412                     author-email (match-string 2)))
 413             (goto-char (point-min))
 414             (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 415               (setq author-date (match-string 1)))
 416             (goto-char (point-min))
 417             (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 418               (unless (string-equal head (match-string 1))
 419                 (setq subject "commit (merge): ")
 420                 (push "-p" args)
 421                 (push (match-string 1) args))))
 422         (setq log-start (point-min)))
 423       (setq log-end (point-max))
 424       (goto-char log-start)
 425       (when (re-search-forward ".*$" nil t)
 426         (setq subject (concat subject (match-string 0))))
 427       (setq coding-system-for-write buffer-file-coding-system))
 428     (let ((commit
 429            (git-get-string-sha1
 430             (with-output-to-string
 431               (with-current-buffer standard-output
 432                 (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 433                              ("GIT_AUTHOR_EMAIL" . ,author-email)
 434                              ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 435                              ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 436                   (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 437                   (apply #'git-run-command-region
 438                          buffer log-start log-end env
 439                          "commit-tree" tree (nreverse args))))))))
 440       (and (git-update-ref "HEAD" commit head subject)
 441            commit))))
 442
 443 (defun git-empty-db-p ()
 444   "Check if the git db is empty (no commit done yet)."
 445   (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 446
 447 (defun git-get-merge-heads ()
 448   "Retrieve the merge heads from the MERGE_HEAD file if present."
 449   (let (heads)
 450     (when (file-readable-p ".git/MERGE_HEAD")
 451       (with-temp-buffer
 452         (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 453         (goto-char (point-min))
 454         (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 455           (push (match-string 0) heads))))
 456     (nreverse heads)))
 457
 458 (defun git-get-commit-description (commit)
 459   "Get a one-line description of COMMIT."
 460   (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 461     (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 462       (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 463           (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 464         descr))))
 465
 466 ;;;; File info structure
 467 ;;;; ------------------------------------------------------------
 468
 469 ; fileinfo structure stolen from pcl-cvs
 470 (defstruct (git-fileinfo
 471             (:copier nil)
 472             (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 473             (:conc-name git-fileinfo->))
 474   marked              ;; t/nil
 475   state               ;; current state
 476   name                ;; file name
 477   old-perm new-perm   ;; permission flags
 478   rename-state        ;; rename or copy state
 479   orig-name           ;; original name for renames or copies
 480   needs-refresh)      ;; whether file needs to be refreshed
 481
 482 (defvar git-status nil)
 483
 484 (defun git-clear-status (status)
 485   "Remove everything from the status list."
 486   (ewoc-filter status (lambda (info) nil)))
 487
 488 (defun git-set-fileinfo-state (info state)
 489   "Set the state of a file info."
 490   (unless (eq (git-fileinfo->state info) state)
 491     (setf (git-fileinfo->state info) state
 492           (git-fileinfo->old-perm info) 0
 493           (git-fileinfo->new-perm info) 0
 494           (git-fileinfo->rename-state info) nil
 495           (git-fileinfo->orig-name info) nil
 496           (git-fileinfo->needs-refresh info) t)))
 497
 498 (defun git-status-filenames-map (status func files &rest args)
 499   "Apply FUNC to the status files names in the FILES list."
 500   (when files
 501     (setq files (sort files #'string-lessp))
 502     (let ((file (pop files))
 503           (node (ewoc-nth status 0)))
 504       (while (and file node)
 505         (let ((info (ewoc-data node)))
 506           (if (string-lessp (git-fileinfo->name info) file)
 507               (setq node (ewoc-next status node))
 508             (if (string-equal (git-fileinfo->name info) file)
 509                 (apply func info args))
 510             (setq file (pop files))))))))
 511
 512 (defun git-set-filenames-state (status files state)
 513   "Set the state of a list of named files."
 514   (when files
 515     (git-status-filenames-map status #'git-set-fileinfo-state files state)
 516     (unless state  ;; delete files whose state has been set to nil
 517       (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 518
 519 (defun git-state-code (code)
 520   "Convert from a string to a added/deleted/modified state."
 521   (case (string-to-char code)
 522     (?M 'modified)
 523     (?? 'unknown)
 524     (?A 'added)
 525     (?D 'deleted)
 526     (?U 'unmerged)
 527     (t nil)))
 528
 529 (defun git-status-code-as-string (code)
 530   "Format a git status code as string."
 531   (case code
 532     ('modified (propertize "Modified" 'face 'git-status-face))
 533     ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 534     ('added    (propertize "Added   " 'face 'git-status-face))
 535     ('deleted  (propertize "Deleted " 'face 'git-status-face))
 536     ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 537     ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 538     ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 539     (t "?       ")))
 540
 541 (defun git-rename-as-string (info)
 542   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 543   (let ((state (git-fileinfo->rename-state info)))
 544     (if state
 545         (propertize
 546          (concat "   ("
 547                  (if (eq state 'copy) "copied from "
 548                    (if (eq (git-fileinfo->state info) 'added) "renamed from "
 549                      "renamed to "))
 550                  (git-escape-file-name (git-fileinfo->orig-name info))
 551                  ")") 'face 'git-status-face)
 552       "")))
 553
 554 (defun git-permissions-as-string (old-perm new-perm)
 555   "Format a permission change as string."
 556   (propertize
 557    (if (or (not old-perm)
 558            (not new-perm)
 559            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 560        "  "
 561      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 562   'face 'git-permission-face))
 563
 564 (defun git-fileinfo-prettyprint (info)
 565   "Pretty-printer for the git-fileinfo structure."
 566   (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 567                   " " (git-status-code-as-string (git-fileinfo->state info))
 568                   " " (git-permissions-as-string (git-fileinfo->old-perm info) (git-fileinfo->new-perm info))
 569                   "  " (git-escape-file-name (git-fileinfo->name info))
 570                   (git-rename-as-string info))))
 571
 572 (defun git-insert-info-list (status infolist)
 573   "Insert a list of file infos in the status buffer, replacing existing ones if any."
 574   (setq infolist (sort infolist
 575                        (lambda (info1 info2)
 576                          (string-lessp (git-fileinfo->name info1)
 577                                        (git-fileinfo->name info2)))))
 578   (let ((info (pop infolist))
 579         (node (ewoc-nth status 0)))
 580     (while info
 581       (setf (git-fileinfo->needs-refresh info) t)
 582       (cond ((not node)
 583              (ewoc-enter-last status info)
 584              (setq info (pop infolist)))
 585             ((string-lessp (git-fileinfo->name (ewoc-data node))
 586                            (git-fileinfo->name info))
 587              (setq node (ewoc-next status node)))
 588             ((string-equal (git-fileinfo->name (ewoc-data node))
 589                            (git-fileinfo->name info))
 590               ;; preserve the marked flag
 591               (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 592               (setf (ewoc-data node) info)
 593               (setq info (pop infolist)))
 594             (t
 595              (ewoc-enter-before status node info)
 596              (setq info (pop infolist)))))))
 597
 598 (defun git-run-diff-index (status files)
 599   "Run git-diff-index on FILES and parse the results into STATUS.
 600 Return the list of files that haven't been handled."
 601   (let (infolist)
 602     (with-temp-buffer
 603       (apply #'git-call-process-env t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 604       (goto-char (point-min))
 605       (while (re-search-forward
 606               ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMU]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 607               nil t 1)
 608         (let ((old-perm (string-to-number (match-string 1) 8))
 609               (new-perm (string-to-number (match-string 2) 8))
 610               (state (or (match-string 4) (match-string 6)))
 611               (name (or (match-string 5) (match-string 7)))
 612               (new-name (match-string 8)))
 613           (if new-name  ; copy or rename
 614               (if (eq ?C (string-to-char state))
 615                   (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 616                 (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 617                 (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 618             (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 619           (setq files (delete name files))
 620           (when new-name (setq files (delete new-name files))))))
 621     (git-insert-info-list status infolist)
 622     files))
 623
 624 (defun git-find-status-file (status file)
 625   "Find a given file in the status ewoc and return its node."
 626   (let ((node (ewoc-nth status 0)))
 627     (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 628       (setq node (ewoc-next status node)))
 629     node))
 630
 631 (defun git-run-ls-files (status files default-state &rest options)
 632   "Run git-ls-files on FILES and parse the results into STATUS.
 633 Return the list of files that haven't been handled."
 634   (let (infolist)
 635     (with-temp-buffer
 636       (apply #'git-call-process-env t nil "ls-files" "-z" (append options (list "--") files))
 637       (goto-char (point-min))
 638       (while (re-search-forward "\\([^\0]*\\)\0" nil t 1)
 639         (let ((name (match-string 1)))
 640           (push (git-create-fileinfo default-state name) infolist)
 641           (setq files (delete name files)))))
 642     (git-insert-info-list status infolist)
 643     files))
 644
 645 (defun git-run-ls-unmerged (status files)
 646   "Run git-ls-files -u on FILES and parse the results into STATUS."
 647   (with-temp-buffer
 648     (apply #'git-call-process-env t nil "ls-files" "-z" "-u" "--" files)
 649     (goto-char (point-min))
 650     (let (unmerged-files)
 651       (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 652         (push (match-string 1) unmerged-files))
 653       (git-set-filenames-state status unmerged-files 'unmerged))))
 654
 655 (defun git-get-exclude-files ()
 656   "Get the list of exclude files to pass to git-ls-files."
 657   (let (files
 658         (config (git-config "core.excludesfile")))
 659     (when (file-readable-p ".git/info/exclude")
 660       (push ".git/info/exclude" files))
 661     (when (and config (file-readable-p config))
 662       (push config files))
 663     files))
 664
 665 (defun git-run-ls-files-with-excludes (status files default-state &rest options)
 666   "Run git-ls-files on FILES with appropriate --exclude-from options."
 667   (let ((exclude-files (git-get-exclude-files)))
 668     (apply #'git-run-ls-files status files default-state
 669            (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 670            (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 671
 672 (defun git-update-status-files (files &optional default-state)
 673   "Update the status of FILES from the index."
 674   (unless git-status (error "Not in git-status buffer."))
 675   (unless files
 676     (when git-show-uptodate (git-run-ls-files git-status nil 'uptodate "-c")))
 677   (let* ((remaining-files
 678           (if (git-empty-db-p) ; we need some special handling for an empty db
 679               (git-run-ls-files git-status files 'added "-c")
 680             (git-run-diff-index git-status files))))
 681     (git-run-ls-unmerged git-status files)
 682     (when (or remaining-files (and git-show-unknown (not files)))
 683       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 684     (when (or remaining-files (and git-show-ignored (not files)))
 685       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 686     (git-set-filenames-state git-status remaining-files default-state)
 687     (git-refresh-files)
 688     (git-refresh-ewoc-hf git-status)))
 689
 690 (defun git-marked-files ()
 691   "Return a list of all marked files, or if none a list containing just the file at cursor position."
 692   (unless git-status (error "Not in git-status buffer."))
 693   (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 694       (list (ewoc-data (ewoc-locate git-status)))))
 695
 696 (defun git-marked-files-state (&rest states)
 697   "Return marked files that are in the specified states."
 698   (let ((files (git-marked-files))
 699         result)
 700     (dolist (info files)
 701       (when (memq (git-fileinfo->state info) states)
 702         (push info result)))
 703     result))
 704
 705 (defun git-refresh-files ()
 706   "Refresh all files that need it and clear the needs-refresh flag."
 707   (unless git-status (error "Not in git-status buffer."))
 708   (ewoc-map
 709    (lambda (info)
 710      (let ((refresh (git-fileinfo->needs-refresh info)))
 711        (setf (git-fileinfo->needs-refresh info) nil)
 712        refresh))
 713    git-status)
 714   ; move back to goal column
 715   (when goal-column (move-to-column goal-column)))
 716
 717 (defun git-refresh-ewoc-hf (status)
 718   "Refresh the ewoc header and footer."
 719   (let ((branch (git-symbolic-ref "HEAD"))
 720         (head (if (git-empty-db-p) "Nothing committed yet"
 721                 (git-get-commit-description "HEAD")))
 722         (merge-heads (git-get-merge-heads)))
 723     (ewoc-set-hf status
 724                  (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 725                          default-directory
 726                          (if branch
 727                              (if (string-match "^refs/heads/" branch)
 728                                  (substring branch (match-end 0))
 729                                branch)
 730                            "none (detached HEAD)")
 731                          head
 732                          (if merge-heads
 733                              (concat "\nMerging:    "
 734                                      (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 735                            ""))
 736                  (if (ewoc-nth status 0) "" "    No changes."))))
 737
 738 (defun git-get-filenames (files)
 739   (mapcar (lambda (info) (git-fileinfo->name info)) files))
 740
 741 (defun git-update-index (index-file files)
 742   "Run git-update-index on a list of files."
 743   (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 744         added deleted modified)
 745     (dolist (info files)
 746       (case (git-fileinfo->state info)
 747         ('added (push info added))
 748         ('deleted (push info deleted))
 749         ('modified (push info modified))))
 750     (when added
 751       (apply #'git-call-process-env nil env "update-index" "--add" "--" (git-get-filenames added)))
 752     (when deleted
 753       (apply #'git-call-process-env nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 754     (when modified
 755       (apply #'git-call-process-env nil env "update-index" "--" (git-get-filenames modified)))))
 756
 757 (defun git-run-pre-commit-hook ()
 758   "Run the pre-commit hook if any."
 759   (unless git-status (error "Not in git-status buffer."))
 760   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 761     (or (not files)
 762         (not (file-executable-p ".git/hooks/pre-commit"))
 763         (let ((index-file (make-temp-file "gitidx")))
 764           (unwind-protect
 765             (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 766               (git-read-tree head-tree index-file)
 767               (git-update-index index-file files)
 768               (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 769           (delete-file index-file))))))
 770
 771 (defun git-do-commit ()
 772   "Perform the actual commit using the current buffer as log message."
 773   (interactive)
 774   (let ((buffer (current-buffer))
 775         (index-file (make-temp-file "gitidx")))
 776     (with-current-buffer log-edit-parent-buffer
 777       (if (git-marked-files-state 'unmerged)
 778           (message "You cannot commit unmerged files, resolve them first.")
 779         (unwind-protect
 780             (let ((files (git-marked-files-state 'added 'deleted 'modified))
 781                   head head-tree)
 782               (unless (git-empty-db-p)
 783                 (setq head (git-rev-parse "HEAD")
 784                       head-tree (git-rev-parse "HEAD^{tree}")))
 785               (if files
 786                   (progn
 787                     (message "Running git commit...")
 788                     (git-read-tree head-tree index-file)
 789                     (git-update-index nil files)         ;update both the default index
 790                     (git-update-index index-file files)  ;and the temporary one
 791                     (let ((tree (git-write-tree index-file)))
 792                       (if (or (not (string-equal tree head-tree))
 793                               (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 794                           (let ((commit (git-commit-tree buffer tree head)))
 795                             (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 796                             (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 797                             (with-current-buffer buffer (erase-buffer))
 798                             (dolist (info files) (git-set-fileinfo-state info 'uptodate))
 799                             (git-call-process-env nil nil "rerere")
 800                             (git-call-process-env nil nil "gc" "--auto")
 801                             (git-refresh-files)
 802                             (git-refresh-ewoc-hf git-status)
 803                             (message "Committed %s." commit)
 804                             (git-run-hook "post-commit" nil))
 805                         (message "Commit aborted."))))
 806                 (message "No files to commit.")))
 807           (delete-file index-file))))))
 808
 809
 810 ;;;; Interactive functions
 811 ;;;; ------------------------------------------------------------
 812
 813 (defun git-mark-file ()
 814   "Mark the file that the cursor is on and move to the next one."
 815   (interactive)
 816   (unless git-status (error "Not in git-status buffer."))
 817   (let* ((pos (ewoc-locate git-status))
 818          (info (ewoc-data pos)))
 819     (setf (git-fileinfo->marked info) t)
 820     (ewoc-invalidate git-status pos)
 821     (ewoc-goto-next git-status 1)))
 822
 823 (defun git-unmark-file ()
 824   "Unmark the file that the cursor is on and move to the next one."
 825   (interactive)
 826   (unless git-status (error "Not in git-status buffer."))
 827   (let* ((pos (ewoc-locate git-status))
 828          (info (ewoc-data pos)))
 829     (setf (git-fileinfo->marked info) nil)
 830     (ewoc-invalidate git-status pos)
 831     (ewoc-goto-next git-status 1)))
 832
 833 (defun git-unmark-file-up ()
 834   "Unmark the file that the cursor is on and move to the previous one."
 835   (interactive)
 836   (unless git-status (error "Not in git-status buffer."))
 837   (let* ((pos (ewoc-locate git-status))
 838          (info (ewoc-data pos)))
 839     (setf (git-fileinfo->marked info) nil)
 840     (ewoc-invalidate git-status pos)
 841     (ewoc-goto-prev git-status 1)))
 842
 843 (defun git-mark-all ()
 844   "Mark all files."
 845   (interactive)
 846   (unless git-status (error "Not in git-status buffer."))
 847   (ewoc-map (lambda (info) (unless (git-fileinfo->marked info)
 848                              (setf (git-fileinfo->marked info) t))) git-status)
 849   ; move back to goal column after invalidate
 850   (when goal-column (move-to-column goal-column)))
 851
 852 (defun git-unmark-all ()
 853   "Unmark all files."
 854   (interactive)
 855   (unless git-status (error "Not in git-status buffer."))
 856   (ewoc-map (lambda (info) (when (git-fileinfo->marked info)
 857                              (setf (git-fileinfo->marked info) nil)
 858                              t)) git-status)
 859   ; move back to goal column after invalidate
 860   (when goal-column (move-to-column goal-column)))
 861
 862 (defun git-toggle-all-marks ()
 863   "Toggle all file marks."
 864   (interactive)
 865   (unless git-status (error "Not in git-status buffer."))
 866   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 867   ; move back to goal column after invalidate
 868   (when goal-column (move-to-column goal-column)))
 869
 870 (defun git-next-file (&optional n)
 871   "Move the selection down N files."
 872   (interactive "p")
 873   (unless git-status (error "Not in git-status buffer."))
 874   (ewoc-goto-next git-status n))
 875
 876 (defun git-prev-file (&optional n)
 877   "Move the selection up N files."
 878   (interactive "p")
 879   (unless git-status (error "Not in git-status buffer."))
 880   (ewoc-goto-prev git-status n))
 881
 882 (defun git-next-unmerged-file (&optional n)
 883   "Move the selection down N unmerged files."
 884   (interactive "p")
 885   (unless git-status (error "Not in git-status buffer."))
 886   (let* ((last (ewoc-locate git-status))
 887          (node (ewoc-next git-status last)))
 888     (while (and node (> n 0))
 889       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 890         (setq n (1- n))
 891         (setq last node))
 892       (setq node (ewoc-next git-status node)))
 893     (ewoc-goto-node git-status last)))
 894
 895 (defun git-prev-unmerged-file (&optional n)
 896   "Move the selection up N unmerged files."
 897   (interactive "p")
 898   (unless git-status (error "Not in git-status buffer."))
 899   (let* ((last (ewoc-locate git-status))
 900          (node (ewoc-prev git-status last)))
 901     (while (and node (> n 0))
 902       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 903         (setq n (1- n))
 904         (setq last node))
 905       (setq node (ewoc-prev git-status node)))
 906     (ewoc-goto-node git-status last)))
 907
 908 (defun git-add-file ()
 909   "Add marked file(s) to the index cache."
 910   (interactive)
 911   (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 912     (unless files
 913       (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 914     (apply #'git-call-process-env nil nil "update-index" "--add" "--" files)
 915     (git-update-status-files files 'uptodate)
 916     (git-success-message "Added" files)))
 917
 918 (defun git-ignore-file ()
 919   "Add marked file(s) to the ignore list."
 920   (interactive)
 921   (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 922     (unless files
 923       (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 924     (dolist (f files) (git-append-to-ignore f))
 925     (git-update-status-files files 'ignored)
 926     (git-success-message "Ignored" files)))
 927
 928 (defun git-remove-file ()
 929   "Remove the marked file(s)."
 930   (interactive)
 931   (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 932     (unless files
 933       (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 934     (if (yes-or-no-p
 935          (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 936         (progn
 937           (dolist (name files)
 938             (when (file-exists-p name) (delete-file name)))
 939           (apply #'git-call-process-env nil nil "update-index" "--remove" "--" files)
 940           (git-update-status-files files nil)
 941           (git-success-message "Removed" files))
 942       (message "Aborting"))))
 943
 944 (defun git-revert-file ()
 945   "Revert changes to the marked file(s)."
 946   (interactive)
 947   (let ((files (git-marked-files))
 948         added modified)
 949     (when (and files
 950                (yes-or-no-p
 951                 (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
 952       (dolist (info files)
 953         (case (git-fileinfo->state info)
 954           ('added (push (git-fileinfo->name info) added))
 955           ('deleted (push (git-fileinfo->name info) modified))
 956           ('unmerged (push (git-fileinfo->name info) modified))
 957           ('modified (push (git-fileinfo->name info) modified))))
 958       (when added
 959         (apply #'git-call-process-env nil nil "update-index" "--force-remove" "--" added))
 960       (when modified
 961         (apply #'git-call-process-env nil nil "checkout" "HEAD" modified))
 962       (git-update-status-files (append added modified) 'uptodate)
 963       (git-success-message "Reverted" (git-get-filenames files)))))
 964
 965 (defun git-resolve-file ()
 966   "Resolve conflicts in marked file(s)."
 967   (interactive)
 968   (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
 969     (when files
 970       (apply #'git-call-process-env nil nil "update-index" "--" files)
 971       (git-update-status-files files 'uptodate)
 972       (git-success-message "Resolved" files))))
 973
 974 (defun git-remove-handled ()
 975   "Remove handled files from the status list."
 976   (interactive)
 977   (ewoc-filter git-status
 978                (lambda (info)
 979                  (case (git-fileinfo->state info)
 980                    ('ignored git-show-ignored)
 981                    ('uptodate git-show-uptodate)
 982                    ('unknown git-show-unknown)
 983                    (t t))))
 984   (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
 985     (git-refresh-ewoc-hf git-status)))
 986
 987 (defun git-toggle-show-uptodate ()
 988   "Toogle the option for showing up-to-date files."
 989   (interactive)
 990   (if (setq git-show-uptodate (not git-show-uptodate))
 991       (git-refresh-status)
 992     (git-remove-handled)))
 993
 994 (defun git-toggle-show-ignored ()
 995   "Toogle the option for showing ignored files."
 996   (interactive)
 997   (if (setq git-show-ignored (not git-show-ignored))
 998       (progn
 999         (message "Inserting ignored files...")
1000         (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
1001         (git-refresh-files)
1002         (git-refresh-ewoc-hf git-status)
1003         (message "Inserting ignored files...done"))
1004     (git-remove-handled)))
1005
1006 (defun git-toggle-show-unknown ()
1007   "Toogle the option for showing unknown files."
1008   (interactive)
1009   (if (setq git-show-unknown (not git-show-unknown))
1010       (progn
1011         (message "Inserting unknown files...")
1012         (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
1013         (git-refresh-files)
1014         (git-refresh-ewoc-hf git-status)
1015         (message "Inserting unknown files...done"))
1016     (git-remove-handled)))
1017
1018 (defun git-setup-diff-buffer (buffer)
1019   "Setup a buffer for displaying a diff."
1020   (let ((dir default-directory))
1021     (with-current-buffer buffer
1022       (diff-mode)
1023       (goto-char (point-min))
1024       (setq default-directory dir)
1025       (setq buffer-read-only t)))
1026   (display-buffer buffer)
1027   (shrink-window-if-larger-than-buffer))
1028
1029 (defun git-diff-file ()
1030   "Diff the marked file(s) against HEAD."
1031   (interactive)
1032   (let ((files (git-marked-files)))
1033     (git-setup-diff-buffer
1034      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1035
1036 (defun git-diff-file-merge-head (arg)
1037   "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1038   (interactive "p")
1039   (let ((files (git-marked-files))
1040         (merge-heads (git-get-merge-heads)))
1041     (unless merge-heads (error "No merge in progress"))
1042     (git-setup-diff-buffer
1043      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1044             (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1045
1046 (defun git-diff-unmerged-file (stage)
1047   "Diff the marked unmerged file(s) against the specified stage."
1048   (let ((files (git-marked-files)))
1049     (git-setup-diff-buffer
1050      (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1051
1052 (defun git-diff-file-base ()
1053   "Diff the marked unmerged file(s) against the common base file."
1054   (interactive)
1055   (git-diff-unmerged-file "-1"))
1056
1057 (defun git-diff-file-mine ()
1058   "Diff the marked unmerged file(s) against my pre-merge version."
1059   (interactive)
1060   (git-diff-unmerged-file "-2"))
1061
1062 (defun git-diff-file-other ()
1063   "Diff the marked unmerged file(s) against the other's pre-merge version."
1064   (interactive)
1065   (git-diff-unmerged-file "-3"))
1066
1067 (defun git-diff-file-combined ()
1068   "Do a combined diff of the marked unmerged file(s)."
1069   (interactive)
1070   (git-diff-unmerged-file "-c"))
1071
1072 (defun git-diff-file-idiff ()
1073   "Perform an interactive diff on the current file."
1074   (interactive)
1075   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1076     (unless (eq 1 (length files))
1077       (error "Cannot perform an interactive diff on multiple files."))
1078     (let* ((filename (car (git-get-filenames files)))
1079            (buff1 (find-file-noselect filename))
1080            (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1081       (ediff-buffers buff1 buff2))))
1082
1083 (defun git-log-file ()
1084   "Display a log of changes to the marked file(s)."
1085   (interactive)
1086   (let* ((files (git-marked-files))
1087          (coding-system-for-read git-commits-coding-system)
1088          (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1089     (with-current-buffer buffer
1090       ; (git-log-mode)  FIXME: implement log mode
1091       (goto-char (point-min))
1092       (setq buffer-read-only t))
1093     (display-buffer buffer)))
1094
1095 (defun git-log-edit-files ()
1096   "Return a list of marked files for use in the log-edit buffer."
1097   (with-current-buffer log-edit-parent-buffer
1098     (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1099
1100 (defun git-append-sign-off (name email)
1101   "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1102   (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1103         (case-fold-search t))
1104     (goto-char (point-min))
1105     (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1106       (goto-char (point-min))
1107       (unless (re-search-forward "^Signed-off-by: " nil t)
1108         (setq sign-off (concat "\n" sign-off)))
1109       (goto-char (point-max))
1110       (insert sign-off "\n"))))
1111
1112 (defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1113   "Setup the log buffer for a commit."
1114   (unless git-status (error "Not in git-status buffer."))
1115   (let ((merge-heads (git-get-merge-heads))
1116         (dir default-directory)
1117         (committer-name (git-get-committer-name))
1118         (committer-email (git-get-committer-email))
1119         (sign-off git-append-signed-off-by))
1120     (with-current-buffer buffer
1121       (cd dir)
1122       (erase-buffer)
1123       (insert
1124        (propertize
1125         (format "Author: %s <%s>\n%s%s"
1126                 (or author-name committer-name)
1127                 (or author-email committer-email)
1128                 (if date (format "Date: %s\n" date) "")
1129                 (if merge-heads
1130                     (format "Parent: %s\n%s\n"
1131                             (git-rev-parse "HEAD")
1132                             (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1133                   ""))
1134         'face 'git-header-face)
1135        (propertize git-log-msg-separator 'face 'git-separator-face)
1136        "\n")
1137       (when subject (insert subject "\n\n"))
1138       (cond (msg (insert msg "\n"))
1139             ((file-readable-p ".dotest/msg")
1140              (insert-file-contents ".dotest/msg"))
1141             ((file-readable-p ".git/MERGE_MSG")
1142              (insert-file-contents ".git/MERGE_MSG")))
1143       ; delete empty lines at end
1144       (goto-char (point-min))
1145       (when (re-search-forward "\n+\\'" nil t)
1146         (replace-match "\n" t t))
1147       (when sign-off (git-append-sign-off committer-name committer-email)))))
1148
1149 (defun git-commit-file ()
1150   "Commit the marked file(s), asking for a commit message."
1151   (interactive)
1152   (unless git-status (error "Not in git-status buffer."))
1153   (when (git-run-pre-commit-hook)
1154     (let ((buffer (get-buffer-create "*git-commit*"))
1155           (coding-system (git-get-commits-coding-system))
1156           author-name author-email subject date)
1157       (when (eq 0 (buffer-size buffer))
1158         (when (file-readable-p ".dotest/info")
1159           (with-temp-buffer
1160             (insert-file-contents ".dotest/info")
1161             (goto-char (point-min))
1162             (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1163               (setq author-name (match-string 1))
1164               (setq author-email (match-string 2)))
1165             (goto-char (point-min))
1166             (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1167               (setq subject (match-string 1)))
1168             (goto-char (point-min))
1169             (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1170               (setq date (match-string 1)))))
1171         (git-setup-log-buffer buffer author-name author-email subject date))
1172       (log-edit #'git-do-commit nil #'git-log-edit-files buffer)
1173       (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1174       (setq buffer-file-coding-system coding-system)
1175       (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1176
1177 (defun git-find-file ()
1178   "Visit the current file in its own buffer."
1179   (interactive)
1180   (unless git-status (error "Not in git-status buffer."))
1181   (let ((info (ewoc-data (ewoc-locate git-status))))
1182     (find-file (git-fileinfo->name info))
1183     (when (eq 'unmerged (git-fileinfo->state info))
1184       (smerge-mode 1))))
1185
1186 (defun git-find-file-other-window ()
1187   "Visit the current file in its own buffer in another window."
1188   (interactive)
1189   (unless git-status (error "Not in git-status buffer."))
1190   (let ((info (ewoc-data (ewoc-locate git-status))))
1191     (find-file-other-window (git-fileinfo->name info))
1192     (when (eq 'unmerged (git-fileinfo->state info))
1193       (smerge-mode))))
1194
1195 (defun git-find-file-imerge ()
1196   "Visit the current file in interactive merge mode."
1197   (interactive)
1198   (unless git-status (error "Not in git-status buffer."))
1199   (let ((info (ewoc-data (ewoc-locate git-status))))
1200     (find-file (git-fileinfo->name info))
1201     (smerge-ediff)))
1202
1203 (defun git-view-file ()
1204   "View the current file in its own buffer."
1205   (interactive)
1206   (unless git-status (error "Not in git-status buffer."))
1207   (let ((info (ewoc-data (ewoc-locate git-status))))
1208     (view-file (git-fileinfo->name info))))
1209
1210 (defun git-refresh-status ()
1211   "Refresh the git status buffer."
1212   (interactive)
1213   (let* ((status git-status)
1214          (pos (ewoc-locate status))
1215          (marked-files (git-get-filenames (ewoc-collect status (lambda (info) (git-fileinfo->marked info)))))
1216          (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1217     (unless status (error "Not in git-status buffer."))
1218     (message "Refreshing git status...")
1219     (git-call-process-env nil nil "update-index" "--refresh")
1220     (git-clear-status status)
1221     (git-update-status-files nil)
1222     ; restore file marks
1223     (when marked-files
1224       (git-status-filenames-map status
1225                                 (lambda (info)
1226                                         (setf (git-fileinfo->marked info) t)
1227                                         (setf (git-fileinfo->needs-refresh info) t))
1228                                 marked-files)
1229       (git-refresh-files))
1230     ; move point to the current file name if any
1231     (message "Refreshing git status...done")
1232     (let ((node (and cur-name (git-find-status-file status cur-name))))
1233       (when node (ewoc-goto-node status node)))))
1234
1235 (defun git-status-quit ()
1236   "Quit git-status mode."
1237   (interactive)
1238   (bury-buffer))
1239
1240 ;;;; Major Mode
1241 ;;;; ------------------------------------------------------------
1242
1243 (defvar git-status-mode-hook nil
1244   "Run after `git-status-mode' is setup.")
1245
1246 (defvar git-status-mode-map nil
1247   "Keymap for git major mode.")
1248
1249 (defvar git-status nil
1250   "List of all files managed by the git-status mode.")
1251
1252 (unless git-status-mode-map
1253   (let ((map (make-keymap))
1254         (diff-map (make-sparse-keymap))
1255         (toggle-map (make-sparse-keymap)))
1256     (suppress-keymap map)
1257     (define-key map "?"   'git-help)
1258     (define-key map "h"   'git-help)
1259     (define-key map " "   'git-next-file)
1260     (define-key map "a"   'git-add-file)
1261     (define-key map "c"   'git-commit-file)
1262     (define-key map "d"    diff-map)
1263     (define-key map "="   'git-diff-file)
1264     (define-key map "f"   'git-find-file)
1265     (define-key map "\r"  'git-find-file)
1266     (define-key map "g"   'git-refresh-status)
1267     (define-key map "i"   'git-ignore-file)
1268     (define-key map "l"   'git-log-file)
1269     (define-key map "m"   'git-mark-file)
1270     (define-key map "M"   'git-mark-all)
1271     (define-key map "n"   'git-next-file)
1272     (define-key map "N"   'git-next-unmerged-file)
1273     (define-key map "o"   'git-find-file-other-window)
1274     (define-key map "p"   'git-prev-file)
1275     (define-key map "P"   'git-prev-unmerged-file)
1276     (define-key map "q"   'git-status-quit)
1277     (define-key map "r"   'git-remove-file)
1278     (define-key map "R"   'git-resolve-file)
1279     (define-key map "t"    toggle-map)
1280     (define-key map "T"   'git-toggle-all-marks)
1281     (define-key map "u"   'git-unmark-file)
1282     (define-key map "U"   'git-revert-file)
1283     (define-key map "v"   'git-view-file)
1284     (define-key map "x"   'git-remove-handled)
1285     (define-key map "\C-?" 'git-unmark-file-up)
1286     (define-key map "\M-\C-?" 'git-unmark-all)
1287     ; the diff submap
1288     (define-key diff-map "b" 'git-diff-file-base)
1289     (define-key diff-map "c" 'git-diff-file-combined)
1290     (define-key diff-map "=" 'git-diff-file)
1291     (define-key diff-map "e" 'git-diff-file-idiff)
1292     (define-key diff-map "E" 'git-find-file-imerge)
1293     (define-key diff-map "h" 'git-diff-file-merge-head)
1294     (define-key diff-map "m" 'git-diff-file-mine)
1295     (define-key diff-map "o" 'git-diff-file-other)
1296     ; the toggle submap
1297     (define-key toggle-map "u" 'git-toggle-show-uptodate)
1298     (define-key toggle-map "i" 'git-toggle-show-ignored)
1299     (define-key toggle-map "k" 'git-toggle-show-unknown)
1300     (define-key toggle-map "m" 'git-toggle-all-marks)
1301     (setq git-status-mode-map map))
1302   (easy-menu-define git-menu git-status-mode-map
1303     "Git Menu"
1304     `("Git"
1305       ["Refresh" git-refresh-status t]
1306       ["Commit" git-commit-file t]
1307       ("Merge"
1308         ["Next Unmerged File" git-next-unmerged-file t]
1309         ["Prev Unmerged File" git-prev-unmerged-file t]
1310         ["Mark as Resolved" git-resolve-file t]
1311         ["Interactive Merge File" git-find-file-imerge t]
1312         ["Diff Against Common Base File" git-diff-file-base t]
1313         ["Diff Combined" git-diff-file-combined t]
1314         ["Diff Against Merge Head" git-diff-file-merge-head t]
1315         ["Diff Against Mine" git-diff-file-mine t]
1316         ["Diff Against Other" git-diff-file-other t])
1317       "--------"
1318       ["Add File" git-add-file t]
1319       ["Revert File" git-revert-file t]
1320       ["Ignore File" git-ignore-file t]
1321       ["Remove File" git-remove-file t]
1322       "--------"
1323       ["Find File" git-find-file t]
1324       ["View File" git-view-file t]
1325       ["Diff File" git-diff-file t]
1326       ["Interactive Diff File" git-diff-file-idiff t]
1327       ["Log" git-log-file t]
1328       "--------"
1329       ["Mark" git-mark-file t]
1330       ["Mark All" git-mark-all t]
1331       ["Unmark" git-unmark-file t]
1332       ["Unmark All" git-unmark-all t]
1333       ["Toggle All Marks" git-toggle-all-marks t]
1334       ["Hide Handled Files" git-remove-handled t]
1335       "--------"
1336       ["Show Uptodate Files" git-toggle-show-uptodate :style toggle :selected git-show-uptodate]
1337       ["Show Ignored Files" git-toggle-show-ignored :style toggle :selected git-show-ignored]
1338       ["Show Unknown Files" git-toggle-show-unknown :style toggle :selected git-show-unknown]
1339       "--------"
1340       ["Quit" git-status-quit t])))
1341
1342
1343 ;; git mode should only run in the *git status* buffer
1344 (put 'git-status-mode 'mode-class 'special)
1345
1346 (defun git-status-mode ()
1347   "Major mode for interacting with Git.
1348 Commands:
1349 \\{git-status-mode-map}"
1350   (kill-all-local-variables)
1351   (buffer-disable-undo)
1352   (setq mode-name "git status"
1353         major-mode 'git-status-mode
1354         goal-column 17
1355         buffer-read-only t)
1356   (use-local-map git-status-mode-map)
1357   (let ((buffer-read-only nil))
1358     (erase-buffer)
1359   (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1360     (set (make-local-variable 'git-status) status))
1361   (set (make-local-variable 'list-buffers-directory) default-directory)
1362   (make-local-variable 'git-show-uptodate)
1363   (make-local-variable 'git-show-ignored)
1364   (make-local-variable 'git-show-unknown)
1365   (run-hooks 'git-status-mode-hook)))
1366
1367 (defun git-find-status-buffer (dir)
1368   "Find the git status buffer handling a specified directory."
1369   (let ((list (buffer-list))
1370         (fulldir (expand-file-name dir))
1371         found)
1372     (while (and list (not found))
1373       (let ((buffer (car list)))
1374         (with-current-buffer buffer
1375           (when (and list-buffers-directory
1376                      (string-equal fulldir (expand-file-name list-buffers-directory))
1377                      (string-match "\\*git-status\\*$" (buffer-name buffer)))
1378             (setq found buffer))))
1379       (setq list (cdr list)))
1380     found))
1381
1382 (defun git-status (dir)
1383   "Entry point into git-status mode."
1384   (interactive "DSelect directory: ")
1385   (setq dir (git-get-top-dir dir))
1386   (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1387       (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1388                         (create-file-buffer (expand-file-name "*git-status*" dir)))))
1389         (switch-to-buffer buffer)
1390         (cd dir)
1391         (git-status-mode)
1392         (git-refresh-status)
1393         (goto-char (point-min))
1394         (add-hook 'after-save-hook 'git-update-saved-file))
1395     (message "%s is not a git working tree." dir)))
1396
1397 (defun git-update-saved-file ()
1398   "Update the corresponding git-status buffer when a file is saved.
1399 Meant to be used in `after-save-hook'."
1400   (let* ((file (expand-file-name buffer-file-name))
1401          (dir (condition-case nil (git-get-top-dir (file-name-directory file)) (error nil)))
1402          (buffer (and dir (git-find-status-buffer dir))))
1403     (when buffer
1404       (with-current-buffer buffer
1405         (let ((filename (file-relative-name file dir)))
1406           ; skip files located inside the .git directory
1407           (unless (string-match "^\\.git/" filename)
1408             (git-call-process-env nil nil "add" "--refresh" "--" filename)
1409             (git-update-status-files (list filename) 'uptodate)))))))
1410
1411 (defun git-help ()
1412   "Display help for Git mode."
1413   (interactive)
1414   (describe-function 'git-status-mode))
1415
1416 (provide 'git)
1417 ;;; git.el ends here