contrib/emacs/git.el

   1 ;;; git.el --- A user interface for git
   2
   3 ;; Copyright (C) 2005, 2006, 2007 Alexandre Julliard <julliard@winehq.org>
   4
   5 ;; Version: 1.0
   6
   7 ;; This program is free software; you can redistribute it and/or
   8 ;; modify it under the terms of the GNU General Public License as
   9 ;; published by the Free Software Foundation; either version 2 of
  10 ;; the License, or (at your option) any later version.
  11 ;;
  12 ;; This program is distributed in the hope that it will be
  13 ;; useful, but WITHOUT ANY WARRANTY; without even the implied
  14 ;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
  15 ;; PURPOSE.  See the GNU General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public
  18 ;; License along with this program; if not, write to the Free
  19 ;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  20 ;; MA 02111-1307 USA
  21
  22 ;;; Commentary:
  23
  24 ;; This file contains an interface for the git version control
  25 ;; system. It provides easy access to the most frequently used git
  26 ;; commands. The user interface is as far as possible identical to
  27 ;; that of the PCL-CVS mode.
  28 ;;
  29 ;; To install: put this file on the load-path and place the following
  30 ;; in your .emacs file:
  31 ;;
  32 ;;    (require 'git)
  33 ;;
  34 ;; To start: `M-x git-status'
  35 ;;
  36 ;; TODO
  37 ;;  - portability to XEmacs
  38 ;;  - better handling of subprocess errors
  39 ;;  - diff against other branch
  40 ;;  - renaming files from the status buffer
  41 ;;  - creating tags
  42 ;;  - fetch/pull
  43 ;;  - switching branches
  44 ;;  - revlist browser
  45 ;;  - git-show-branch browser
  46 ;;  - menus
  47 ;;
  48
  49 (eval-when-compile (require 'cl))
  50 (require 'ewoc)
  51 (require 'log-edit)
  52 (require 'easymenu)
  53
  54
  55 ;;;; Customizations
  56 ;;;; ------------------------------------------------------------
  57
  58 (defgroup git nil
  59   "A user interface for the git versioning system."
  60   :group 'tools)
  61
  62 (defcustom git-committer-name nil
  63   "User name to use for commits.
  64 The default is to fall back to the repository config,
  65 then to `add-log-full-name' and then to `user-full-name'."
  66   :group 'git
  67   :type '(choice (const :tag "Default" nil)
  68                  (string :tag "Name")))
  69
  70 (defcustom git-committer-email nil
  71   "Email address to use for commits.
  72 The default is to fall back to the git repository config,
  73 then to `add-log-mailing-address' and then to `user-mail-address'."
  74   :group 'git
  75   :type '(choice (const :tag "Default" nil)
  76                  (string :tag "Email")))
  77
  78 (defcustom git-commits-coding-system nil
  79   "Default coding system for the log message of git commits."
  80   :group 'git
  81   :type '(choice (const :tag "From repository config" nil)
  82                  (coding-system)))
  83
  84 (defcustom git-append-signed-off-by nil
  85   "Whether to append a Signed-off-by line to the commit message before editing."
  86   :group 'git
  87   :type 'boolean)
  88
  89 (defcustom git-reuse-status-buffer t
  90   "Whether `git-status' should try to reuse an existing buffer
  91 if there is already one that displays the same directory."
  92   :group 'git
  93   :type 'boolean)
  94
  95 (defcustom git-per-dir-ignore-file ".gitignore"
  96   "Name of the per-directory ignore file."
  97   :group 'git
  98   :type 'string)
  99
 100 (defcustom git-show-uptodate nil
 101   "Whether to display up-to-date files."
 102   :group 'git
 103   :type 'boolean)
 104
 105 (defcustom git-show-ignored nil
 106   "Whether to display ignored files."
 107   :group 'git
 108   :type 'boolean)
 109
 110 (defcustom git-show-unknown t
 111   "Whether to display unknown files."
 112   :group 'git
 113   :type 'boolean)
 114
 115
 116 (defface git-status-face
 117   '((((class color) (background light)) (:foreground "purple"))
 118     (((class color) (background dark)) (:foreground "salmon")))
 119   "Git mode face used to highlight added and modified files."
 120   :group 'git)
 121
 122 (defface git-unmerged-face
 123   '((((class color) (background light)) (:foreground "red" :bold t))
 124     (((class color) (background dark)) (:foreground "red" :bold t)))
 125   "Git mode face used to highlight unmerged files."
 126   :group 'git)
 127
 128 (defface git-unknown-face
 129   '((((class color) (background light)) (:foreground "goldenrod" :bold t))
 130     (((class color) (background dark)) (:foreground "goldenrod" :bold t)))
 131   "Git mode face used to highlight unknown files."
 132   :group 'git)
 133
 134 (defface git-uptodate-face
 135   '((((class color) (background light)) (:foreground "grey60"))
 136     (((class color) (background dark)) (:foreground "grey40")))
 137   "Git mode face used to highlight up-to-date files."
 138   :group 'git)
 139
 140 (defface git-ignored-face
 141   '((((class color) (background light)) (:foreground "grey60"))
 142     (((class color) (background dark)) (:foreground "grey40")))
 143   "Git mode face used to highlight ignored files."
 144   :group 'git)
 145
 146 (defface git-mark-face
 147   '((((class color) (background light)) (:foreground "red" :bold t))
 148     (((class color) (background dark)) (:foreground "tomato" :bold t)))
 149   "Git mode face used for the file marks."
 150   :group 'git)
 151
 152 (defface git-header-face
 153   '((((class color) (background light)) (:foreground "blue"))
 154     (((class color) (background dark)) (:foreground "blue")))
 155   "Git mode face used for commit headers."
 156   :group 'git)
 157
 158 (defface git-separator-face
 159   '((((class color) (background light)) (:foreground "brown"))
 160     (((class color) (background dark)) (:foreground "brown")))
 161   "Git mode face used for commit separator."
 162   :group 'git)
 163
 164 (defface git-permission-face
 165   '((((class color) (background light)) (:foreground "green" :bold t))
 166     (((class color) (background dark)) (:foreground "green" :bold t)))
 167   "Git mode face used for permission changes."
 168   :group 'git)
 169
 170
 171 ;;;; Utilities
 172 ;;;; ------------------------------------------------------------
 173
 174 (defconst git-log-msg-separator "--- log message follows this line ---")
 175
 176 (defvar git-log-edit-font-lock-keywords
 177   `(("^\\(Author:\\|Date:\\|Parent:\\|Signed-off-by:\\)\\(.*\\)$"
 178      (1 font-lock-keyword-face)
 179      (2 font-lock-function-name-face))
 180     (,(concat "^\\(" (regexp-quote git-log-msg-separator) "\\)$")
 181      (1 font-lock-comment-face))))
 182
 183 (defun git-get-env-strings (env)
 184   "Build a list of NAME=VALUE strings from a list of environment strings."
 185   (mapcar (lambda (entry) (concat (car entry) "=" (cdr entry))) env))
 186
 187 (defun git-call-process-env (buffer env &rest args)
 188   "Wrapper for call-process that sets environment strings."
 189   (if env
 190       (apply #'call-process "env" nil buffer nil
 191              (append (git-get-env-strings env) (list "git") args))
 192     (apply #'call-process "git" nil buffer nil args)))
 193
 194 (defun git-call-process-env-string (env &rest args)
 195   "Wrapper for call-process that sets environment strings,
 196 and returns the process output as a string."
 197   (with-temp-buffer
 198     (and (eq 0 (apply #' git-call-process-env t env args))
 199          (buffer-string))))
 200
 201 (defun git-run-process-region (buffer start end program args)
 202   "Run a git process with a buffer region as input."
 203   (let ((output-buffer (current-buffer))
 204         (dir default-directory))
 205     (with-current-buffer buffer
 206       (cd dir)
 207       (apply #'call-process-region start end program
 208              nil (list output-buffer nil) nil args))))
 209
 210 (defun git-run-command-buffer (buffer-name &rest args)
 211   "Run a git command, sending the output to a buffer named BUFFER-NAME."
 212   (let ((dir default-directory)
 213         (buffer (get-buffer-create buffer-name)))
 214     (message "Running git %s..." (car args))
 215     (with-current-buffer buffer
 216       (let ((default-directory dir)
 217             (buffer-read-only nil))
 218         (erase-buffer)
 219         (apply #'git-call-process-env buffer nil args)))
 220     (message "Running git %s...done" (car args))
 221     buffer))
 222
 223 (defun git-run-command-region (buffer start end env &rest args)
 224   "Run a git command with specified buffer region as input."
 225   (unless (eq 0 (if env
 226                     (git-run-process-region
 227                      buffer start end "env"
 228                      (append (git-get-env-strings env) (list "git") args))
 229                   (git-run-process-region
 230                    buffer start end "git" args)))
 231     (error "Failed to run \"git %s\":\n%s" (mapconcat (lambda (x) x) args " ") (buffer-string))))
 232
 233 (defun git-run-hook (hook env &rest args)
 234   "Run a git hook and display its output if any."
 235   (let ((dir default-directory)
 236         (hook-name (expand-file-name (concat ".git/hooks/" hook))))
 237     (or (not (file-executable-p hook-name))
 238         (let (status (buffer (get-buffer-create "*Git Hook Output*")))
 239           (with-current-buffer buffer
 240             (erase-buffer)
 241             (cd dir)
 242             (setq status
 243                   (if env
 244                       (apply #'call-process "env" nil (list buffer t) nil
 245                              (append (git-get-env-strings env) (list hook-name) args))
 246                     (apply #'call-process hook-name nil (list buffer t) nil args))))
 247           (display-message-or-buffer buffer)
 248           (eq 0 status)))))
 249
 250 (defun git-get-string-sha1 (string)
 251   "Read a SHA1 from the specified string."
 252   (and string
 253        (string-match "[0-9a-f]\\{40\\}" string)
 254        (match-string 0 string)))
 255
 256 (defun git-get-committer-name ()
 257   "Return the name to use as GIT_COMMITTER_NAME."
 258   ; copied from log-edit
 259   (or git-committer-name
 260       (git-config "user.name")
 261       (and (boundp 'add-log-full-name) add-log-full-name)
 262       (and (fboundp 'user-full-name) (user-full-name))
 263       (and (boundp 'user-full-name) user-full-name)))
 264
 265 (defun git-get-committer-email ()
 266   "Return the email address to use as GIT_COMMITTER_EMAIL."
 267   ; copied from log-edit
 268   (or git-committer-email
 269       (git-config "user.email")
 270       (and (boundp 'add-log-mailing-address) add-log-mailing-address)
 271       (and (fboundp 'user-mail-address) (user-mail-address))
 272       (and (boundp 'user-mail-address) user-mail-address)))
 273
 274 (defun git-get-commits-coding-system ()
 275   "Return the coding system to use for commits."
 276   (let ((repo-config (git-config "i18n.commitencoding")))
 277     (or git-commits-coding-system
 278         (and repo-config
 279              (fboundp 'locale-charset-to-coding-system)
 280              (locale-charset-to-coding-system repo-config))
 281       'utf-8)))
 282
 283 (defun git-get-logoutput-coding-system ()
 284   "Return the coding system used for git-log output."
 285   (let ((repo-config (or (git-config "i18n.logoutputencoding")
 286                          (git-config "i18n.commitencoding"))))
 287     (or git-commits-coding-system
 288         (and repo-config
 289              (fboundp 'locale-charset-to-coding-system)
 290              (locale-charset-to-coding-system repo-config))
 291       'utf-8)))
 292
 293 (defun git-escape-file-name (name)
 294   "Escape a file name if necessary."
 295   (if (string-match "[\n\t\"\\]" name)
 296       (concat "\""
 297               (mapconcat (lambda (c)
 298                    (case c
 299                      (?\n "\\n")
 300                      (?\t "\\t")
 301                      (?\\ "\\\\")
 302                      (?\" "\\\"")
 303                      (t (char-to-string c))))
 304                  name "")
 305               "\"")
 306     name))
 307
 308 (defun git-success-message (text files)
 309   "Print a success message after having handled FILES."
 310   (let ((n (length files)))
 311     (if (equal n 1)
 312         (message "%s %s" text (car files))
 313       (message "%s %d files" text n))))
 314
 315 (defun git-get-top-dir (dir)
 316   "Retrieve the top-level directory of a git tree."
 317   (let ((cdup (with-output-to-string
 318                 (with-current-buffer standard-output
 319                   (cd dir)
 320                   (unless (eq 0 (call-process "git" nil t nil "rev-parse" "--show-cdup"))
 321                     (error "cannot find top-level git tree for %s." dir))))))
 322     (expand-file-name (concat (file-name-as-directory dir)
 323                               (car (split-string cdup "\n"))))))
 324
 325 ;stolen from pcl-cvs
 326 (defun git-append-to-ignore (file)
 327   "Add a file name to the ignore file in its directory."
 328   (let* ((fullname (expand-file-name file))
 329          (dir (file-name-directory fullname))
 330          (name (file-name-nondirectory fullname))
 331          (ignore-name (expand-file-name git-per-dir-ignore-file dir))
 332          (created (not (file-exists-p ignore-name))))
 333   (save-window-excursion
 334     (set-buffer (find-file-noselect ignore-name))
 335     (goto-char (point-max))
 336     (unless (zerop (current-column)) (insert "\n"))
 337     (insert "/" name "\n")
 338     (sort-lines nil (point-min) (point-max))
 339     (save-buffer))
 340   (when created
 341     (git-call-process-env nil nil "update-index" "--add" "--" (file-relative-name ignore-name)))
 342   (git-update-status-files (list (file-relative-name ignore-name)) 'unknown)))
 343
 344 ; propertize definition for XEmacs, stolen from erc-compat
 345 (eval-when-compile
 346   (unless (fboundp 'propertize)
 347     (defun propertize (string &rest props)
 348       (let ((string (copy-sequence string)))
 349         (while props
 350           (put-text-property 0 (length string) (nth 0 props) (nth 1 props) string)
 351           (setq props (cddr props)))
 352         string))))
 353
 354 ;;;; Wrappers for basic git commands
 355 ;;;; ------------------------------------------------------------
 356
 357 (defun git-rev-parse (rev)
 358   "Parse a revision name and return its SHA1."
 359   (git-get-string-sha1
 360    (git-call-process-env-string nil "rev-parse" rev)))
 361
 362 (defun git-config (key)
 363   "Retrieve the value associated to KEY in the git repository config file."
 364   (let ((str (git-call-process-env-string nil "config" key)))
 365     (and str (car (split-string str "\n")))))
 366
 367 (defun git-symbolic-ref (ref)
 368   "Wrapper for the git-symbolic-ref command."
 369   (let ((str (git-call-process-env-string nil "symbolic-ref" ref)))
 370     (and str (car (split-string str "\n")))))
 371
 372 (defun git-update-ref (ref newval &optional oldval reason)
 373   "Update a reference by calling git-update-ref."
 374   (let ((args (and oldval (list oldval))))
 375     (push newval args)
 376     (push ref args)
 377     (when reason
 378      (push reason args)
 379      (push "-m" args))
 380     (eq 0 (apply #'git-call-process-env nil nil "update-ref" args))))
 381
 382 (defun git-read-tree (tree &optional index-file)
 383   "Read a tree into the index file."
 384   (apply #'git-call-process-env nil
 385          (if index-file `(("GIT_INDEX_FILE" . ,index-file)) nil)
 386          "read-tree" (if tree (list tree))))
 387
 388 (defun git-write-tree (&optional index-file)
 389   "Call git-write-tree and return the resulting tree SHA1 as a string."
 390   (git-get-string-sha1
 391    (git-call-process-env-string (and index-file `(("GIT_INDEX_FILE" . ,index-file))) "write-tree")))
 392
 393 (defun git-commit-tree (buffer tree head)
 394   "Call git-commit-tree with buffer as input and return the resulting commit SHA1."
 395   (let ((author-name (git-get-committer-name))
 396         (author-email (git-get-committer-email))
 397         (subject "commit (initial): ")
 398         author-date log-start log-end args coding-system-for-write)
 399     (when head
 400       (setq subject "commit: ")
 401       (push "-p" args)
 402       (push head args))
 403     (with-current-buffer buffer
 404       (goto-char (point-min))
 405       (if
 406           (setq log-start (re-search-forward (concat "^" (regexp-quote git-log-msg-separator) "\n") nil t))
 407           (save-restriction
 408             (narrow-to-region (point-min) log-start)
 409             (goto-char (point-min))
 410             (when (re-search-forward "^Author: +\\(.*?\\) *<\\(.*\\)> *$" nil t)
 411               (setq author-name (match-string 1)
 412                     author-email (match-string 2)))
 413             (goto-char (point-min))
 414             (when (re-search-forward "^Date: +\\(.*\\)$" nil t)
 415               (setq author-date (match-string 1)))
 416             (goto-char (point-min))
 417             (while (re-search-forward "^Parent: +\\([0-9a-f]+\\)" nil t)
 418               (unless (string-equal head (match-string 1))
 419                 (setq subject "commit (merge): ")
 420                 (push "-p" args)
 421                 (push (match-string 1) args))))
 422         (setq log-start (point-min)))
 423       (setq log-end (point-max))
 424       (goto-char log-start)
 425       (when (re-search-forward ".*$" nil t)
 426         (setq subject (concat subject (match-string 0))))
 427       (setq coding-system-for-write buffer-file-coding-system))
 428     (let ((commit
 429            (git-get-string-sha1
 430             (with-output-to-string
 431               (with-current-buffer standard-output
 432                 (let ((env `(("GIT_AUTHOR_NAME" . ,author-name)
 433                              ("GIT_AUTHOR_EMAIL" . ,author-email)
 434                              ("GIT_COMMITTER_NAME" . ,(git-get-committer-name))
 435                              ("GIT_COMMITTER_EMAIL" . ,(git-get-committer-email)))))
 436                   (when author-date (push `("GIT_AUTHOR_DATE" . ,author-date) env))
 437                   (apply #'git-run-command-region
 438                          buffer log-start log-end env
 439                          "commit-tree" tree (nreverse args))))))))
 440       (and (git-update-ref "HEAD" commit head subject)
 441            commit))))
 442
 443 (defun git-empty-db-p ()
 444   "Check if the git db is empty (no commit done yet)."
 445   (not (eq 0 (call-process "git" nil nil nil "rev-parse" "--verify" "HEAD"))))
 446
 447 (defun git-get-merge-heads ()
 448   "Retrieve the merge heads from the MERGE_HEAD file if present."
 449   (let (heads)
 450     (when (file-readable-p ".git/MERGE_HEAD")
 451       (with-temp-buffer
 452         (insert-file-contents ".git/MERGE_HEAD" nil nil nil t)
 453         (goto-char (point-min))
 454         (while (re-search-forward "[0-9a-f]\\{40\\}" nil t)
 455           (push (match-string 0) heads))))
 456     (nreverse heads)))
 457
 458 (defun git-get-commit-description (commit)
 459   "Get a one-line description of COMMIT."
 460   (let ((coding-system-for-read (git-get-logoutput-coding-system)))
 461     (let ((descr (git-call-process-env-string nil "log" "--max-count=1" "--pretty=oneline" commit)))
 462       (if (and descr (string-match "\\`\\([0-9a-f]\\{40\\}\\) *\\(.*\\)$" descr))
 463           (concat (substring (match-string 1 descr) 0 10) " - " (match-string 2 descr))
 464         descr))))
 465
 466 ;;;; File info structure
 467 ;;;; ------------------------------------------------------------
 468
 469 ; fileinfo structure stolen from pcl-cvs
 470 (defstruct (git-fileinfo
 471             (:copier nil)
 472             (:constructor git-create-fileinfo (state name &optional old-perm new-perm rename-state orig-name marked))
 473             (:conc-name git-fileinfo->))
 474   marked              ;; t/nil
 475   state               ;; current state
 476   name                ;; file name
 477   old-perm new-perm   ;; permission flags
 478   rename-state        ;; rename or copy state
 479   orig-name           ;; original name for renames or copies
 480   needs-refresh)      ;; whether file needs to be refreshed
 481
 482 (defvar git-status nil)
 483
 484 (defun git-clear-status (status)
 485   "Remove everything from the status list."
 486   (ewoc-filter status (lambda (info) nil)))
 487
 488 (defun git-set-fileinfo-state (info state)
 489   "Set the state of a file info."
 490   (unless (eq (git-fileinfo->state info) state)
 491     (setf (git-fileinfo->state info) state
 492           (git-fileinfo->new-perm info) (git-fileinfo->old-perm info)
 493           (git-fileinfo->rename-state info) nil
 494           (git-fileinfo->orig-name info) nil
 495           (git-fileinfo->needs-refresh info) t)))
 496
 497 (defun git-status-filenames-map (status func files &rest args)
 498   "Apply FUNC to the status files names in the FILES list."
 499   (when files
 500     (setq files (sort files #'string-lessp))
 501     (let ((file (pop files))
 502           (node (ewoc-nth status 0)))
 503       (while (and file node)
 504         (let ((info (ewoc-data node)))
 505           (if (string-lessp (git-fileinfo->name info) file)
 506               (setq node (ewoc-next status node))
 507             (if (string-equal (git-fileinfo->name info) file)
 508                 (apply func info args))
 509             (setq file (pop files))))))))
 510
 511 (defun git-set-filenames-state (status files state)
 512   "Set the state of a list of named files."
 513   (when files
 514     (git-status-filenames-map status #'git-set-fileinfo-state files state)
 515     (unless state  ;; delete files whose state has been set to nil
 516       (ewoc-filter status (lambda (info) (git-fileinfo->state info))))))
 517
 518 (defun git-state-code (code)
 519   "Convert from a string to a added/deleted/modified state."
 520   (case (string-to-char code)
 521     (?M 'modified)
 522     (?? 'unknown)
 523     (?A 'added)
 524     (?D 'deleted)
 525     (?U 'unmerged)
 526     (?T 'modified)
 527     (t nil)))
 528
 529 (defun git-status-code-as-string (code)
 530   "Format a git status code as string."
 531   (case code
 532     ('modified (propertize "Modified" 'face 'git-status-face))
 533     ('unknown  (propertize "Unknown " 'face 'git-unknown-face))
 534     ('added    (propertize "Added   " 'face 'git-status-face))
 535     ('deleted  (propertize "Deleted " 'face 'git-status-face))
 536     ('unmerged (propertize "Unmerged" 'face 'git-unmerged-face))
 537     ('uptodate (propertize "Uptodate" 'face 'git-uptodate-face))
 538     ('ignored  (propertize "Ignored " 'face 'git-ignored-face))
 539     (t "?       ")))
 540
 541 (defun git-file-type-as-string (info)
 542   "Return a string describing the file type of INFO."
 543   (let* ((old-type (lsh (or (git-fileinfo->old-perm info) 0) -9))
 544          (new-type (lsh (or (git-fileinfo->new-perm info) 0) -9))
 545          (str (case new-type
 546                 (?\100  ;; file
 547                  (case old-type
 548                    (?\100 nil)
 549                    (?\120 "   (type change symlink -> file)")
 550                    (?\160 "   (type change subproject -> file)")))
 551                  (?\120  ;; symlink
 552                   (case old-type
 553                     (?\100 "   (type change file -> symlink)")
 554                     (?\160 "   (type change subproject -> symlink)")
 555                     (t "   (symlink)")))
 556                   (?\160  ;; subproject
 557                    (case old-type
 558                      (?\100 "   (type change file -> subproject)")
 559                      (?\120 "   (type change symlink -> subproject)")
 560                      (t "   (subproject)")))
 561                   (?\000  ;; deleted or unknown
 562                    (case old-type
 563                      (?\120 "   (symlink)")
 564                      (?\160 "   (subproject)")))
 565                   (t (format "   (unknown type %o)" new-type)))))
 566     (if str (propertize str 'face 'git-status-face) "")))
 567
 568 (defun git-rename-as-string (info)
 569   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 570   (let ((state (git-fileinfo->rename-state info)))
 571     (if state
 572         (propertize
 573          (concat "   ("
 574                  (if (eq state 'copy) "copied from "
 575                    (if (eq (git-fileinfo->state info) 'added) "renamed from "
 576                      "renamed to "))
 577                  (git-escape-file-name (git-fileinfo->orig-name info))
 578                  ")") 'face 'git-status-face)
 579       "")))
 580
 581 (defun git-permissions-as-string (old-perm new-perm)
 582   "Format a permission change as string."
 583   (propertize
 584    (if (or (not old-perm)
 585            (not new-perm)
 586            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 587        "  "
 588      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 589   'face 'git-permission-face))
 590
 591 (defun git-fileinfo-prettyprint (info)
 592   "Pretty-printer for the git-fileinfo structure."
 593   (insert (concat "   " (if (git-fileinfo->marked info) (propertize "*" 'face 'git-mark-face) " ")
 594                   " " (git-status-code-as-string (git-fileinfo->state info))
 595                   " " (git-permissions-as-string (git-fileinfo->old-perm info) (git-fileinfo->new-perm info))
 596                   "  " (git-escape-file-name (git-fileinfo->name info))
 597                   (git-file-type-as-string info)
 598                   (git-rename-as-string info))))
 599
 600 (defun git-insert-info-list (status infolist)
 601   "Insert a list of file infos in the status buffer, replacing existing ones if any."
 602   (setq infolist (sort infolist
 603                        (lambda (info1 info2)
 604                          (string-lessp (git-fileinfo->name info1)
 605                                        (git-fileinfo->name info2)))))
 606   (let ((info (pop infolist))
 607         (node (ewoc-nth status 0)))
 608     (while info
 609       (setf (git-fileinfo->needs-refresh info) t)
 610       (cond ((not node)
 611              (setq node (ewoc-enter-last status info))
 612              (setq info (pop infolist)))
 613             ((string-lessp (git-fileinfo->name (ewoc-data node))
 614                            (git-fileinfo->name info))
 615              (setq node (ewoc-next status node)))
 616             ((string-equal (git-fileinfo->name (ewoc-data node))
 617                            (git-fileinfo->name info))
 618               ;; preserve the marked flag
 619               (setf (git-fileinfo->marked info) (git-fileinfo->marked (ewoc-data node)))
 620               (setf (ewoc-data node) info)
 621               (setq info (pop infolist)))
 622             (t
 623              (setq node (ewoc-enter-before status node info))
 624              (setq info (pop infolist)))))))
 625
 626 (defun git-run-diff-index (status files)
 627   "Run git-diff-index on FILES and parse the results into STATUS.
 628 Return the list of files that haven't been handled."
 629   (let (infolist)
 630     (with-temp-buffer
 631       (apply #'git-call-process-env t nil "diff-index" "-z" "-M" "HEAD" "--" files)
 632       (goto-char (point-min))
 633       (while (re-search-forward
 634               ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 635               nil t 1)
 636         (let ((old-perm (string-to-number (match-string 1) 8))
 637               (new-perm (string-to-number (match-string 2) 8))
 638               (state (or (match-string 4) (match-string 6)))
 639               (name (or (match-string 5) (match-string 7)))
 640               (new-name (match-string 8)))
 641           (if new-name  ; copy or rename
 642               (if (eq ?C (string-to-char state))
 643                   (push (git-create-fileinfo 'added new-name old-perm new-perm 'copy name) infolist)
 644                 (push (git-create-fileinfo 'deleted name 0 0 'rename new-name) infolist)
 645                 (push (git-create-fileinfo 'added new-name old-perm new-perm 'rename name) infolist))
 646             (push (git-create-fileinfo (git-state-code state) name old-perm new-perm) infolist))
 647           (setq files (delete name files))
 648           (when new-name (setq files (delete new-name files))))))
 649     (git-insert-info-list status infolist)
 650     files))
 651
 652 (defun git-find-status-file (status file)
 653   "Find a given file in the status ewoc and return its node."
 654   (let ((node (ewoc-nth status 0)))
 655     (while (and node (not (string= file (git-fileinfo->name (ewoc-data node)))))
 656       (setq node (ewoc-next status node)))
 657     node))
 658
 659 (defun git-run-ls-files (status files default-state &rest options)
 660   "Run git-ls-files on FILES and parse the results into STATUS.
 661 Return the list of files that haven't been handled."
 662   (let (infolist)
 663     (with-temp-buffer
 664       (apply #'git-call-process-env t nil "ls-files" "-z" (append options (list "--") files))
 665       (goto-char (point-min))
 666       (while (re-search-forward "\\([^\0]*\\)\0" nil t 1)
 667         (let ((name (match-string 1)))
 668           (push (git-create-fileinfo default-state name) infolist)
 669           (setq files (delete name files)))))
 670     (git-insert-info-list status infolist)
 671     files))
 672
 673 (defun git-run-ls-files-cached (status files default-state)
 674   "Run git-ls-files -c on FILES and parse the results into STATUS.
 675 Return the list of files that haven't been handled."
 676   (let (infolist)
 677     (with-temp-buffer
 678       (apply #'git-call-process-env t nil "ls-files" "-z" "-s" "-c" "--" files)
 679       (goto-char (point-min))
 680       (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 681         (let* ((new-perm (string-to-number (match-string 1) 8))
 682                (old-perm (if (eq default-state 'added) 0 new-perm))
 683                (name (match-string 2)))
 684           (push (git-create-fileinfo default-state name old-perm new-perm) infolist)
 685           (setq files (delete name files)))))
 686     (git-insert-info-list status infolist)
 687     files))
 688
 689 (defun git-run-ls-unmerged (status files)
 690   "Run git-ls-files -u on FILES and parse the results into STATUS."
 691   (with-temp-buffer
 692     (apply #'git-call-process-env t nil "ls-files" "-z" "-u" "--" files)
 693     (goto-char (point-min))
 694     (let (unmerged-files)
 695       (while (re-search-forward "[0-7]\\{6\\} [0-9a-f]\\{40\\} [123]\t\\([^\0]+\\)\0" nil t)
 696         (push (match-string 1) unmerged-files))
 697       (git-set-filenames-state status unmerged-files 'unmerged))))
 698
 699 (defun git-get-exclude-files ()
 700   "Get the list of exclude files to pass to git-ls-files."
 701   (let (files
 702         (config (git-config "core.excludesfile")))
 703     (when (file-readable-p ".git/info/exclude")
 704       (push ".git/info/exclude" files))
 705     (when (and config (file-readable-p config))
 706       (push config files))
 707     files))
 708
 709 (defun git-run-ls-files-with-excludes (status files default-state &rest options)
 710   "Run git-ls-files on FILES with appropriate --exclude-from options."
 711   (let ((exclude-files (git-get-exclude-files)))
 712     (apply #'git-run-ls-files status files default-state
 713            (concat "--exclude-per-directory=" git-per-dir-ignore-file)
 714            (append options (mapcar (lambda (f) (concat "--exclude-from=" f)) exclude-files)))))
 715
 716 (defun git-update-status-files (files &optional default-state)
 717   "Update the status of FILES from the index."
 718   (unless git-status (error "Not in git-status buffer."))
 719   (unless files
 720     (when git-show-uptodate (git-run-ls-files-cached git-status nil 'uptodate)))
 721   (let* ((remaining-files
 722           (if (git-empty-db-p) ; we need some special handling for an empty db
 723               (git-run-ls-files-cached git-status files 'added)
 724             (git-run-diff-index git-status files))))
 725     (git-run-ls-unmerged git-status files)
 726     (when (or remaining-files (and git-show-unknown (not files)))
 727       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'unknown "-o")))
 728     (when (or remaining-files (and git-show-ignored (not files)))
 729       (setq remaining-files (git-run-ls-files-with-excludes git-status remaining-files 'ignored "-o" "-i")))
 730     (git-set-filenames-state git-status remaining-files default-state)
 731     (git-refresh-files)
 732     (git-refresh-ewoc-hf git-status)))
 733
 734 (defun git-marked-files ()
 735   "Return a list of all marked files, or if none a list containing just the file at cursor position."
 736   (unless git-status (error "Not in git-status buffer."))
 737   (or (ewoc-collect git-status (lambda (info) (git-fileinfo->marked info)))
 738       (list (ewoc-data (ewoc-locate git-status)))))
 739
 740 (defun git-marked-files-state (&rest states)
 741   "Return marked files that are in the specified states."
 742   (let ((files (git-marked-files))
 743         result)
 744     (dolist (info files)
 745       (when (memq (git-fileinfo->state info) states)
 746         (push info result)))
 747     result))
 748
 749 (defun git-refresh-files ()
 750   "Refresh all files that need it and clear the needs-refresh flag."
 751   (unless git-status (error "Not in git-status buffer."))
 752   (ewoc-map
 753    (lambda (info)
 754      (let ((refresh (git-fileinfo->needs-refresh info)))
 755        (setf (git-fileinfo->needs-refresh info) nil)
 756        refresh))
 757    git-status)
 758   ; move back to goal column
 759   (when goal-column (move-to-column goal-column)))
 760
 761 (defun git-refresh-ewoc-hf (status)
 762   "Refresh the ewoc header and footer."
 763   (let ((branch (git-symbolic-ref "HEAD"))
 764         (head (if (git-empty-db-p) "Nothing committed yet"
 765                 (git-get-commit-description "HEAD")))
 766         (merge-heads (git-get-merge-heads)))
 767     (ewoc-set-hf status
 768                  (format "Directory:  %s\nBranch:     %s\nHead:       %s%s\n"
 769                          default-directory
 770                          (if branch
 771                              (if (string-match "^refs/heads/" branch)
 772                                  (substring branch (match-end 0))
 773                                branch)
 774                            "none (detached HEAD)")
 775                          head
 776                          (if merge-heads
 777                              (concat "\nMerging:    "
 778                                      (mapconcat (lambda (str) (git-get-commit-description str)) merge-heads "\n            "))
 779                            ""))
 780                  (if (ewoc-nth status 0) "" "    No changes."))))
 781
 782 (defun git-get-filenames (files)
 783   (mapcar (lambda (info) (git-fileinfo->name info)) files))
 784
 785 (defun git-update-index (index-file files)
 786   "Run git-update-index on a list of files."
 787   (let ((env (and index-file `(("GIT_INDEX_FILE" . ,index-file))))
 788         added deleted modified)
 789     (dolist (info files)
 790       (case (git-fileinfo->state info)
 791         ('added (push info added))
 792         ('deleted (push info deleted))
 793         ('modified (push info modified))))
 794     (when added
 795       (apply #'git-call-process-env nil env "update-index" "--add" "--" (git-get-filenames added)))
 796     (when deleted
 797       (apply #'git-call-process-env nil env "update-index" "--remove" "--" (git-get-filenames deleted)))
 798     (when modified
 799       (apply #'git-call-process-env nil env "update-index" "--" (git-get-filenames modified)))))
 800
 801 (defun git-run-pre-commit-hook ()
 802   "Run the pre-commit hook if any."
 803   (unless git-status (error "Not in git-status buffer."))
 804   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
 805     (or (not files)
 806         (not (file-executable-p ".git/hooks/pre-commit"))
 807         (let ((index-file (make-temp-file "gitidx")))
 808           (unwind-protect
 809             (let ((head-tree (unless (git-empty-db-p) (git-rev-parse "HEAD^{tree}"))))
 810               (git-read-tree head-tree index-file)
 811               (git-update-index index-file files)
 812               (git-run-hook "pre-commit" `(("GIT_INDEX_FILE" . ,index-file))))
 813           (delete-file index-file))))))
 814
 815 (defun git-do-commit ()
 816   "Perform the actual commit using the current buffer as log message."
 817   (interactive)
 818   (let ((buffer (current-buffer))
 819         (index-file (make-temp-file "gitidx")))
 820     (with-current-buffer log-edit-parent-buffer
 821       (if (git-marked-files-state 'unmerged)
 822           (message "You cannot commit unmerged files, resolve them first.")
 823         (unwind-protect
 824             (let ((files (git-marked-files-state 'added 'deleted 'modified))
 825                   head head-tree)
 826               (unless (git-empty-db-p)
 827                 (setq head (git-rev-parse "HEAD")
 828                       head-tree (git-rev-parse "HEAD^{tree}")))
 829               (if files
 830                   (progn
 831                     (message "Running git commit...")
 832                     (git-read-tree head-tree index-file)
 833                     (git-update-index nil files)         ;update both the default index
 834                     (git-update-index index-file files)  ;and the temporary one
 835                     (let ((tree (git-write-tree index-file)))
 836                       (if (or (not (string-equal tree head-tree))
 837                               (yes-or-no-p "The tree was not modified, do you really want to perform an empty commit? "))
 838                           (let ((commit (git-commit-tree buffer tree head)))
 839                             (condition-case nil (delete-file ".git/MERGE_HEAD") (error nil))
 840                             (condition-case nil (delete-file ".git/MERGE_MSG") (error nil))
 841                             (with-current-buffer buffer (erase-buffer))
 842                             (dolist (info files) (git-set-fileinfo-state info 'uptodate))
 843                             (git-call-process-env nil nil "rerere")
 844                             (git-call-process-env nil nil "gc" "--auto")
 845                             (git-refresh-files)
 846                             (git-refresh-ewoc-hf git-status)
 847                             (message "Committed %s." commit)
 848                             (git-run-hook "post-commit" nil))
 849                         (message "Commit aborted."))))
 850                 (message "No files to commit.")))
 851           (delete-file index-file))))))
 852
 853
 854 ;;;; Interactive functions
 855 ;;;; ------------------------------------------------------------
 856
 857 (defun git-mark-file ()
 858   "Mark the file that the cursor is on and move to the next one."
 859   (interactive)
 860   (unless git-status (error "Not in git-status buffer."))
 861   (let* ((pos (ewoc-locate git-status))
 862          (info (ewoc-data pos)))
 863     (setf (git-fileinfo->marked info) t)
 864     (ewoc-invalidate git-status pos)
 865     (ewoc-goto-next git-status 1)))
 866
 867 (defun git-unmark-file ()
 868   "Unmark the file that the cursor is on and move to the next one."
 869   (interactive)
 870   (unless git-status (error "Not in git-status buffer."))
 871   (let* ((pos (ewoc-locate git-status))
 872          (info (ewoc-data pos)))
 873     (setf (git-fileinfo->marked info) nil)
 874     (ewoc-invalidate git-status pos)
 875     (ewoc-goto-next git-status 1)))
 876
 877 (defun git-unmark-file-up ()
 878   "Unmark the file that the cursor is on and move to the previous one."
 879   (interactive)
 880   (unless git-status (error "Not in git-status buffer."))
 881   (let* ((pos (ewoc-locate git-status))
 882          (info (ewoc-data pos)))
 883     (setf (git-fileinfo->marked info) nil)
 884     (ewoc-invalidate git-status pos)
 885     (ewoc-goto-prev git-status 1)))
 886
 887 (defun git-mark-all ()
 888   "Mark all files."
 889   (interactive)
 890   (unless git-status (error "Not in git-status buffer."))
 891   (ewoc-map (lambda (info) (unless (git-fileinfo->marked info)
 892                              (setf (git-fileinfo->marked info) t))) git-status)
 893   ; move back to goal column after invalidate
 894   (when goal-column (move-to-column goal-column)))
 895
 896 (defun git-unmark-all ()
 897   "Unmark all files."
 898   (interactive)
 899   (unless git-status (error "Not in git-status buffer."))
 900   (ewoc-map (lambda (info) (when (git-fileinfo->marked info)
 901                              (setf (git-fileinfo->marked info) nil)
 902                              t)) git-status)
 903   ; move back to goal column after invalidate
 904   (when goal-column (move-to-column goal-column)))
 905
 906 (defun git-toggle-all-marks ()
 907   "Toggle all file marks."
 908   (interactive)
 909   (unless git-status (error "Not in git-status buffer."))
 910   (ewoc-map (lambda (info) (setf (git-fileinfo->marked info) (not (git-fileinfo->marked info))) t) git-status)
 911   ; move back to goal column after invalidate
 912   (when goal-column (move-to-column goal-column)))
 913
 914 (defun git-next-file (&optional n)
 915   "Move the selection down N files."
 916   (interactive "p")
 917   (unless git-status (error "Not in git-status buffer."))
 918   (ewoc-goto-next git-status n))
 919
 920 (defun git-prev-file (&optional n)
 921   "Move the selection up N files."
 922   (interactive "p")
 923   (unless git-status (error "Not in git-status buffer."))
 924   (ewoc-goto-prev git-status n))
 925
 926 (defun git-next-unmerged-file (&optional n)
 927   "Move the selection down N unmerged files."
 928   (interactive "p")
 929   (unless git-status (error "Not in git-status buffer."))
 930   (let* ((last (ewoc-locate git-status))
 931          (node (ewoc-next git-status last)))
 932     (while (and node (> n 0))
 933       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 934         (setq n (1- n))
 935         (setq last node))
 936       (setq node (ewoc-next git-status node)))
 937     (ewoc-goto-node git-status last)))
 938
 939 (defun git-prev-unmerged-file (&optional n)
 940   "Move the selection up N unmerged files."
 941   (interactive "p")
 942   (unless git-status (error "Not in git-status buffer."))
 943   (let* ((last (ewoc-locate git-status))
 944          (node (ewoc-prev git-status last)))
 945     (while (and node (> n 0))
 946       (when (eq 'unmerged (git-fileinfo->state (ewoc-data node)))
 947         (setq n (1- n))
 948         (setq last node))
 949       (setq node (ewoc-prev git-status node)))
 950     (ewoc-goto-node git-status last)))
 951
 952 (defun git-add-file ()
 953   "Add marked file(s) to the index cache."
 954   (interactive)
 955   (let ((files (git-get-filenames (git-marked-files-state 'unknown 'ignored))))
 956     (unless files
 957       (push (file-relative-name (read-file-name "File to add: " nil nil t)) files))
 958     (apply #'git-call-process-env nil nil "update-index" "--add" "--" files)
 959     (git-update-status-files files 'uptodate)
 960     (git-success-message "Added" files)))
 961
 962 (defun git-ignore-file ()
 963   "Add marked file(s) to the ignore list."
 964   (interactive)
 965   (let ((files (git-get-filenames (git-marked-files-state 'unknown))))
 966     (unless files
 967       (push (file-relative-name (read-file-name "File to ignore: " nil nil t)) files))
 968     (dolist (f files) (git-append-to-ignore f))
 969     (git-update-status-files files 'ignored)
 970     (git-success-message "Ignored" files)))
 971
 972 (defun git-remove-file ()
 973   "Remove the marked file(s)."
 974   (interactive)
 975   (let ((files (git-get-filenames (git-marked-files-state 'added 'modified 'unknown 'uptodate 'ignored))))
 976     (unless files
 977       (push (file-relative-name (read-file-name "File to remove: " nil nil t)) files))
 978     (if (yes-or-no-p
 979          (format "Remove %d file%s? " (length files) (if (> (length files) 1) "s" "")))
 980         (progn
 981           (dolist (name files)
 982             (when (file-exists-p name) (delete-file name)))
 983           (apply #'git-call-process-env nil nil "update-index" "--remove" "--" files)
 984           (git-update-status-files files nil)
 985           (git-success-message "Removed" files))
 986       (message "Aborting"))))
 987
 988 (defun git-revert-file ()
 989   "Revert changes to the marked file(s)."
 990   (interactive)
 991   (let ((files (git-marked-files))
 992         added modified)
 993     (when (and files
 994                (yes-or-no-p
 995                 (format "Revert %d file%s? " (length files) (if (> (length files) 1) "s" ""))))
 996       (dolist (info files)
 997         (case (git-fileinfo->state info)
 998           ('added (push (git-fileinfo->name info) added))
 999           ('deleted (push (git-fileinfo->name info) modified))
1000           ('unmerged (push (git-fileinfo->name info) modified))
1001           ('modified (push (git-fileinfo->name info) modified))))
1002       (when added
1003         (apply #'git-call-process-env nil nil "update-index" "--force-remove" "--" added))
1004       (when modified
1005         (apply #'git-call-process-env nil nil "checkout" "HEAD" modified))
1006       (git-update-status-files (append added modified) 'uptodate)
1007       (git-success-message "Reverted" (git-get-filenames files)))))
1008
1009 (defun git-resolve-file ()
1010   "Resolve conflicts in marked file(s)."
1011   (interactive)
1012   (let ((files (git-get-filenames (git-marked-files-state 'unmerged))))
1013     (when files
1014       (apply #'git-call-process-env nil nil "update-index" "--" files)
1015       (git-update-status-files files 'uptodate)
1016       (git-success-message "Resolved" files))))
1017
1018 (defun git-remove-handled ()
1019   "Remove handled files from the status list."
1020   (interactive)
1021   (ewoc-filter git-status
1022                (lambda (info)
1023                  (case (git-fileinfo->state info)
1024                    ('ignored git-show-ignored)
1025                    ('uptodate git-show-uptodate)
1026                    ('unknown git-show-unknown)
1027                    (t t))))
1028   (unless (ewoc-nth git-status 0)  ; refresh header if list is empty
1029     (git-refresh-ewoc-hf git-status)))
1030
1031 (defun git-toggle-show-uptodate ()
1032   "Toogle the option for showing up-to-date files."
1033   (interactive)
1034   (if (setq git-show-uptodate (not git-show-uptodate))
1035       (git-refresh-status)
1036     (git-remove-handled)))
1037
1038 (defun git-toggle-show-ignored ()
1039   "Toogle the option for showing ignored files."
1040   (interactive)
1041   (if (setq git-show-ignored (not git-show-ignored))
1042       (progn
1043         (message "Inserting ignored files...")
1044         (git-run-ls-files-with-excludes git-status nil 'ignored "-o" "-i")
1045         (git-refresh-files)
1046         (git-refresh-ewoc-hf git-status)
1047         (message "Inserting ignored files...done"))
1048     (git-remove-handled)))
1049
1050 (defun git-toggle-show-unknown ()
1051   "Toogle the option for showing unknown files."
1052   (interactive)
1053   (if (setq git-show-unknown (not git-show-unknown))
1054       (progn
1055         (message "Inserting unknown files...")
1056         (git-run-ls-files-with-excludes git-status nil 'unknown "-o")
1057         (git-refresh-files)
1058         (git-refresh-ewoc-hf git-status)
1059         (message "Inserting unknown files...done"))
1060     (git-remove-handled)))
1061
1062 (defun git-setup-diff-buffer (buffer)
1063   "Setup a buffer for displaying a diff."
1064   (let ((dir default-directory))
1065     (with-current-buffer buffer
1066       (diff-mode)
1067       (goto-char (point-min))
1068       (setq default-directory dir)
1069       (setq buffer-read-only t)))
1070   (display-buffer buffer)
1071   ; shrink window only if it displays the status buffer
1072   (when (eq (window-buffer) (current-buffer))
1073     (shrink-window-if-larger-than-buffer)))
1074
1075 (defun git-diff-file ()
1076   "Diff the marked file(s) against HEAD."
1077   (interactive)
1078   (let ((files (git-marked-files)))
1079     (git-setup-diff-buffer
1080      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M" "HEAD" "--" (git-get-filenames files)))))
1081
1082 (defun git-diff-file-merge-head (arg)
1083   "Diff the marked file(s) against the first merge head (or the nth one with a numeric prefix)."
1084   (interactive "p")
1085   (let ((files (git-marked-files))
1086         (merge-heads (git-get-merge-heads)))
1087     (unless merge-heads (error "No merge in progress"))
1088     (git-setup-diff-buffer
1089      (apply #'git-run-command-buffer "*git-diff*" "diff-index" "-p" "-M"
1090             (or (nth (1- arg) merge-heads) "HEAD") "--" (git-get-filenames files)))))
1091
1092 (defun git-diff-unmerged-file (stage)
1093   "Diff the marked unmerged file(s) against the specified stage."
1094   (let ((files (git-marked-files)))
1095     (git-setup-diff-buffer
1096      (apply #'git-run-command-buffer "*git-diff*" "diff-files" "-p" stage "--" (git-get-filenames files)))))
1097
1098 (defun git-diff-file-base ()
1099   "Diff the marked unmerged file(s) against the common base file."
1100   (interactive)
1101   (git-diff-unmerged-file "-1"))
1102
1103 (defun git-diff-file-mine ()
1104   "Diff the marked unmerged file(s) against my pre-merge version."
1105   (interactive)
1106   (git-diff-unmerged-file "-2"))
1107
1108 (defun git-diff-file-other ()
1109   "Diff the marked unmerged file(s) against the other's pre-merge version."
1110   (interactive)
1111   (git-diff-unmerged-file "-3"))
1112
1113 (defun git-diff-file-combined ()
1114   "Do a combined diff of the marked unmerged file(s)."
1115   (interactive)
1116   (git-diff-unmerged-file "-c"))
1117
1118 (defun git-diff-file-idiff ()
1119   "Perform an interactive diff on the current file."
1120   (interactive)
1121   (let ((files (git-marked-files-state 'added 'deleted 'modified)))
1122     (unless (eq 1 (length files))
1123       (error "Cannot perform an interactive diff on multiple files."))
1124     (let* ((filename (car (git-get-filenames files)))
1125            (buff1 (find-file-noselect filename))
1126            (buff2 (git-run-command-buffer (concat filename ".~HEAD~") "cat-file" "blob" (concat "HEAD:" filename))))
1127       (ediff-buffers buff1 buff2))))
1128
1129 (defun git-log-file ()
1130   "Display a log of changes to the marked file(s)."
1131   (interactive)
1132   (let* ((files (git-marked-files))
1133          (coding-system-for-read git-commits-coding-system)
1134          (buffer (apply #'git-run-command-buffer "*git-log*" "rev-list" "--pretty" "HEAD" "--" (git-get-filenames files))))
1135     (with-current-buffer buffer
1136       ; (git-log-mode)  FIXME: implement log mode
1137       (goto-char (point-min))
1138       (setq buffer-read-only t))
1139     (display-buffer buffer)))
1140
1141 (defun git-log-edit-files ()
1142   "Return a list of marked files for use in the log-edit buffer."
1143   (with-current-buffer log-edit-parent-buffer
1144     (git-get-filenames (git-marked-files-state 'added 'deleted 'modified))))
1145
1146 (defun git-log-edit-diff ()
1147   "Run a diff of the current files being committed from a log-edit buffer."
1148   (with-current-buffer log-edit-parent-buffer
1149     (git-diff-file)))
1150
1151 (defun git-append-sign-off (name email)
1152   "Append a Signed-off-by entry to the current buffer, avoiding duplicates."
1153   (let ((sign-off (format "Signed-off-by: %s <%s>" name email))
1154         (case-fold-search t))
1155     (goto-char (point-min))
1156     (unless (re-search-forward (concat "^" (regexp-quote sign-off)) nil t)
1157       (goto-char (point-min))
1158       (unless (re-search-forward "^Signed-off-by: " nil t)
1159         (setq sign-off (concat "\n" sign-off)))
1160       (goto-char (point-max))
1161       (insert sign-off "\n"))))
1162
1163 (defun git-setup-log-buffer (buffer &optional author-name author-email subject date msg)
1164   "Setup the log buffer for a commit."
1165   (unless git-status (error "Not in git-status buffer."))
1166   (let ((merge-heads (git-get-merge-heads))
1167         (dir default-directory)
1168         (committer-name (git-get-committer-name))
1169         (committer-email (git-get-committer-email))
1170         (sign-off git-append-signed-off-by))
1171     (with-current-buffer buffer
1172       (cd dir)
1173       (erase-buffer)
1174       (insert
1175        (propertize
1176         (format "Author: %s <%s>\n%s%s"
1177                 (or author-name committer-name)
1178                 (or author-email committer-email)
1179                 (if date (format "Date: %s\n" date) "")
1180                 (if merge-heads
1181                     (format "Parent: %s\n%s\n"
1182                             (git-rev-parse "HEAD")
1183                             (mapconcat (lambda (str) (concat "Parent: " str)) merge-heads "\n"))
1184                   ""))
1185         'face 'git-header-face)
1186        (propertize git-log-msg-separator 'face 'git-separator-face)
1187        "\n")
1188       (when subject (insert subject "\n\n"))
1189       (cond (msg (insert msg "\n"))
1190             ((file-readable-p ".dotest/msg")
1191              (insert-file-contents ".dotest/msg"))
1192             ((file-readable-p ".git/MERGE_MSG")
1193              (insert-file-contents ".git/MERGE_MSG")))
1194       ; delete empty lines at end
1195       (goto-char (point-min))
1196       (when (re-search-forward "\n+\\'" nil t)
1197         (replace-match "\n" t t))
1198       (when sign-off (git-append-sign-off committer-name committer-email)))))
1199
1200 (defun git-commit-file ()
1201   "Commit the marked file(s), asking for a commit message."
1202   (interactive)
1203   (unless git-status (error "Not in git-status buffer."))
1204   (when (git-run-pre-commit-hook)
1205     (let ((buffer (get-buffer-create "*git-commit*"))
1206           (coding-system (git-get-commits-coding-system))
1207           author-name author-email subject date)
1208       (when (eq 0 (buffer-size buffer))
1209         (when (file-readable-p ".dotest/info")
1210           (with-temp-buffer
1211             (insert-file-contents ".dotest/info")
1212             (goto-char (point-min))
1213             (when (re-search-forward "^Author: \\(.*\\)\nEmail: \\(.*\\)$" nil t)
1214               (setq author-name (match-string 1))
1215               (setq author-email (match-string 2)))
1216             (goto-char (point-min))
1217             (when (re-search-forward "^Subject: \\(.*\\)$" nil t)
1218               (setq subject (match-string 1)))
1219             (goto-char (point-min))
1220             (when (re-search-forward "^Date: \\(.*\\)$" nil t)
1221               (setq date (match-string 1)))))
1222         (git-setup-log-buffer buffer author-name author-email subject date))
1223       (if (boundp 'log-edit-diff-function)
1224           (log-edit 'git-do-commit nil '((log-edit-listfun . git-log-edit-files)
1225                                          (log-edit-diff-function . git-log-edit-diff)) buffer)
1226         (log-edit 'git-do-commit nil 'git-log-edit-files buffer))
1227       (setq font-lock-keywords (font-lock-compile-keywords git-log-edit-font-lock-keywords))
1228       (setq buffer-file-coding-system coding-system)
1229       (re-search-forward (regexp-quote (concat git-log-msg-separator "\n")) nil t))))
1230
1231 (defun git-find-file ()
1232   "Visit the current file in its own buffer."
1233   (interactive)
1234   (unless git-status (error "Not in git-status buffer."))
1235   (let ((info (ewoc-data (ewoc-locate git-status))))
1236     (find-file (git-fileinfo->name info))
1237     (when (eq 'unmerged (git-fileinfo->state info))
1238       (smerge-mode 1))))
1239
1240 (defun git-find-file-other-window ()
1241   "Visit the current file in its own buffer in another window."
1242   (interactive)
1243   (unless git-status (error "Not in git-status buffer."))
1244   (let ((info (ewoc-data (ewoc-locate git-status))))
1245     (find-file-other-window (git-fileinfo->name info))
1246     (when (eq 'unmerged (git-fileinfo->state info))
1247       (smerge-mode))))
1248
1249 (defun git-find-file-imerge ()
1250   "Visit the current file in interactive merge mode."
1251   (interactive)
1252   (unless git-status (error "Not in git-status buffer."))
1253   (let ((info (ewoc-data (ewoc-locate git-status))))
1254     (find-file (git-fileinfo->name info))
1255     (smerge-ediff)))
1256
1257 (defun git-view-file ()
1258   "View the current file in its own buffer."
1259   (interactive)
1260   (unless git-status (error "Not in git-status buffer."))
1261   (let ((info (ewoc-data (ewoc-locate git-status))))
1262     (view-file (git-fileinfo->name info))))
1263
1264 (defun git-refresh-status ()
1265   "Refresh the git status buffer."
1266   (interactive)
1267   (let* ((status git-status)
1268          (pos (ewoc-locate status))
1269          (marked-files (git-get-filenames (ewoc-collect status (lambda (info) (git-fileinfo->marked info)))))
1270          (cur-name (and pos (git-fileinfo->name (ewoc-data pos)))))
1271     (unless status (error "Not in git-status buffer."))
1272     (message "Refreshing git status...")
1273     (git-call-process-env nil nil "update-index" "--refresh")
1274     (git-clear-status status)
1275     (git-update-status-files nil)
1276     ; restore file marks
1277     (when marked-files
1278       (git-status-filenames-map status
1279                                 (lambda (info)
1280                                         (setf (git-fileinfo->marked info) t)
1281                                         (setf (git-fileinfo->needs-refresh info) t))
1282                                 marked-files)
1283       (git-refresh-files))
1284     ; move point to the current file name if any
1285     (message "Refreshing git status...done")
1286     (let ((node (and cur-name (git-find-status-file status cur-name))))
1287       (when node (ewoc-goto-node status node)))))
1288
1289 (defun git-status-quit ()
1290   "Quit git-status mode."
1291   (interactive)
1292   (bury-buffer))
1293
1294 ;;;; Major Mode
1295 ;;;; ------------------------------------------------------------
1296
1297 (defvar git-status-mode-hook nil
1298   "Run after `git-status-mode' is setup.")
1299
1300 (defvar git-status-mode-map nil
1301   "Keymap for git major mode.")
1302
1303 (defvar git-status nil
1304   "List of all files managed by the git-status mode.")
1305
1306 (unless git-status-mode-map
1307   (let ((map (make-keymap))
1308         (diff-map (make-sparse-keymap))
1309         (toggle-map (make-sparse-keymap)))
1310     (suppress-keymap map)
1311     (define-key map "?"   'git-help)
1312     (define-key map "h"   'git-help)
1313     (define-key map " "   'git-next-file)
1314     (define-key map "a"   'git-add-file)
1315     (define-key map "c"   'git-commit-file)
1316     (define-key map "d"    diff-map)
1317     (define-key map "="   'git-diff-file)
1318     (define-key map "f"   'git-find-file)
1319     (define-key map "\r"  'git-find-file)
1320     (define-key map "g"   'git-refresh-status)
1321     (define-key map "i"   'git-ignore-file)
1322     (define-key map "l"   'git-log-file)
1323     (define-key map "m"   'git-mark-file)
1324     (define-key map "M"   'git-mark-all)
1325     (define-key map "n"   'git-next-file)
1326     (define-key map "N"   'git-next-unmerged-file)
1327     (define-key map "o"   'git-find-file-other-window)
1328     (define-key map "p"   'git-prev-file)
1329     (define-key map "P"   'git-prev-unmerged-file)
1330     (define-key map "q"   'git-status-quit)
1331     (define-key map "r"   'git-remove-file)
1332     (define-key map "R"   'git-resolve-file)
1333     (define-key map "t"    toggle-map)
1334     (define-key map "T"   'git-toggle-all-marks)
1335     (define-key map "u"   'git-unmark-file)
1336     (define-key map "U"   'git-revert-file)
1337     (define-key map "v"   'git-view-file)
1338     (define-key map "x"   'git-remove-handled)
1339     (define-key map "\C-?" 'git-unmark-file-up)
1340     (define-key map "\M-\C-?" 'git-unmark-all)
1341     ; the diff submap
1342     (define-key diff-map "b" 'git-diff-file-base)
1343     (define-key diff-map "c" 'git-diff-file-combined)
1344     (define-key diff-map "=" 'git-diff-file)
1345     (define-key diff-map "e" 'git-diff-file-idiff)
1346     (define-key diff-map "E" 'git-find-file-imerge)
1347     (define-key diff-map "h" 'git-diff-file-merge-head)
1348     (define-key diff-map "m" 'git-diff-file-mine)
1349     (define-key diff-map "o" 'git-diff-file-other)
1350     ; the toggle submap
1351     (define-key toggle-map "u" 'git-toggle-show-uptodate)
1352     (define-key toggle-map "i" 'git-toggle-show-ignored)
1353     (define-key toggle-map "k" 'git-toggle-show-unknown)
1354     (define-key toggle-map "m" 'git-toggle-all-marks)
1355     (setq git-status-mode-map map))
1356   (easy-menu-define git-menu git-status-mode-map
1357     "Git Menu"
1358     `("Git"
1359       ["Refresh" git-refresh-status t]
1360       ["Commit" git-commit-file t]
1361       ("Merge"
1362         ["Next Unmerged File" git-next-unmerged-file t]
1363         ["Prev Unmerged File" git-prev-unmerged-file t]
1364         ["Mark as Resolved" git-resolve-file t]
1365         ["Interactive Merge File" git-find-file-imerge t]
1366         ["Diff Against Common Base File" git-diff-file-base t]
1367         ["Diff Combined" git-diff-file-combined t]
1368         ["Diff Against Merge Head" git-diff-file-merge-head t]
1369         ["Diff Against Mine" git-diff-file-mine t]
1370         ["Diff Against Other" git-diff-file-other t])
1371       "--------"
1372       ["Add File" git-add-file t]
1373       ["Revert File" git-revert-file t]
1374       ["Ignore File" git-ignore-file t]
1375       ["Remove File" git-remove-file t]
1376       "--------"
1377       ["Find File" git-find-file t]
1378       ["View File" git-view-file t]
1379       ["Diff File" git-diff-file t]
1380       ["Interactive Diff File" git-diff-file-idiff t]
1381       ["Log" git-log-file t]
1382       "--------"
1383       ["Mark" git-mark-file t]
1384       ["Mark All" git-mark-all t]
1385       ["Unmark" git-unmark-file t]
1386       ["Unmark All" git-unmark-all t]
1387       ["Toggle All Marks" git-toggle-all-marks t]
1388       ["Hide Handled Files" git-remove-handled t]
1389       "--------"
1390       ["Show Uptodate Files" git-toggle-show-uptodate :style toggle :selected git-show-uptodate]
1391       ["Show Ignored Files" git-toggle-show-ignored :style toggle :selected git-show-ignored]
1392       ["Show Unknown Files" git-toggle-show-unknown :style toggle :selected git-show-unknown]
1393       "--------"
1394       ["Quit" git-status-quit t])))
1395
1396
1397 ;; git mode should only run in the *git status* buffer
1398 (put 'git-status-mode 'mode-class 'special)
1399
1400 (defun git-status-mode ()
1401   "Major mode for interacting with Git.
1402 Commands:
1403 \\{git-status-mode-map}"
1404   (kill-all-local-variables)
1405   (buffer-disable-undo)
1406   (setq mode-name "git status"
1407         major-mode 'git-status-mode
1408         goal-column 17
1409         buffer-read-only t)
1410   (use-local-map git-status-mode-map)
1411   (let ((buffer-read-only nil))
1412     (erase-buffer)
1413   (let ((status (ewoc-create 'git-fileinfo-prettyprint "" "")))
1414     (set (make-local-variable 'git-status) status))
1415   (set (make-local-variable 'list-buffers-directory) default-directory)
1416   (make-local-variable 'git-show-uptodate)
1417   (make-local-variable 'git-show-ignored)
1418   (make-local-variable 'git-show-unknown)
1419   (run-hooks 'git-status-mode-hook)))
1420
1421 (defun git-find-status-buffer (dir)
1422   "Find the git status buffer handling a specified directory."
1423   (let ((list (buffer-list))
1424         (fulldir (expand-file-name dir))
1425         found)
1426     (while (and list (not found))
1427       (let ((buffer (car list)))
1428         (with-current-buffer buffer
1429           (when (and list-buffers-directory
1430                      (string-equal fulldir (expand-file-name list-buffers-directory))
1431                      (string-match "\\*git-status\\*$" (buffer-name buffer)))
1432             (setq found buffer))))
1433       (setq list (cdr list)))
1434     found))
1435
1436 (defun git-status (dir)
1437   "Entry point into git-status mode."
1438   (interactive "DSelect directory: ")
1439   (setq dir (git-get-top-dir dir))
1440   (if (file-directory-p (concat (file-name-as-directory dir) ".git"))
1441       (let ((buffer (or (and git-reuse-status-buffer (git-find-status-buffer dir))
1442                         (create-file-buffer (expand-file-name "*git-status*" dir)))))
1443         (switch-to-buffer buffer)
1444         (cd dir)
1445         (git-status-mode)
1446         (git-refresh-status)
1447         (goto-char (point-min))
1448         (add-hook 'after-save-hook 'git-update-saved-file))
1449     (message "%s is not a git working tree." dir)))
1450
1451 (defun git-update-saved-file ()
1452   "Update the corresponding git-status buffer when a file is saved.
1453 Meant to be used in `after-save-hook'."
1454   (let* ((file (expand-file-name buffer-file-name))
1455          (dir (condition-case nil (git-get-top-dir (file-name-directory file)) (error nil)))
1456          (buffer (and dir (git-find-status-buffer dir))))
1457     (when buffer
1458       (with-current-buffer buffer
1459         (let ((filename (file-relative-name file dir)))
1460           ; skip files located inside the .git directory
1461           (unless (string-match "^\\.git/" filename)
1462             (git-call-process-env nil nil "add" "--refresh" "--" filename)
1463             (git-update-status-files (list filename) 'uptodate)))))))
1464
1465 (defun git-help ()
1466   "Display help for Git mode."
1467   (interactive)
1468   (describe-function 'git-status-mode))
1469
1470 (provide 'git)
1471 ;;; git.el ends here