configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, 3.5.alpha1-quota)
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h src/libping/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 #
  11 # Checks for programs.
  12 #
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17 AC_PROG_MAKE_SET
  18
  19 dnl configure libtool
  20 AC_DISABLE_STATIC
  21 AC_LIBLTDL_CONVENIENCE
  22 AC_SUBST(LTDLINCL)
  23 AC_SUBST(LIBLTDL)
  24 AC_LIBTOOL_DLOPEN
  25 AC_PROG_LIBTOOL
  26 #AC_PROG_RANLIB
  27 AC_CONFIG_SUBDIRS(libltdl)
  28
  29 #
  30 # Checks for header files.
  31 #
  32 AC_HEADER_SYS_WAIT
  33 AC_CHECK_HEADERS(fcntl.h)
  34 AC_CHECK_HEADERS(signal.h)
  35 AC_CHECK_HEADERS(sys/socket.h)
  36 AC_CHECK_HEADERS(sys/select.h)
  37 AC_CHECK_HEADERS(netdb.h)
  38 AC_CHECK_HEADERS(sys/resource.h)
  39 AC_CHECK_HEADERS(errno.h)
  40 AC_CHECK_HEADERS(syslog.h)
  41
  42 # For cpu modules
  43 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
  44
  45 # For load module
  46 AC_CHECK_HEADERS(sys/loadavg.h)
  47
  48 # For ping module
  49 AC_CHECK_HEADERS(arpa/inet.h)
  50 AC_CHECK_HEADERS(netinet/in.h)
  51
  52 # For users module
  53 AC_CHECK_HEADERS(utmp.h)
  54 AC_CHECK_HEADERS(utmpx.h)
  55
  56 # For quota module
  57 AC_CHECK_HEADERS(grp.h pwd.h)
  58 AC_CHECK_HEADERS(ctype.h)
  59 AC_CHECK_HEADERS(limits.h)
  60 AC_CHECK_HEADERS(sys/quota.h)
  61 AC_CHECK_HEADERS(xfs/xqm.h)
  62
  63 # For mount interface
  64 AC_CHECK_HEADERS(paths.h)
  65 AC_CHECK_HEADERS(mntent.h)
  66 AC_CHECK_HEADERS(sys/fs_types.h)
  67 AC_CHECK_HEADERS(sys/mntent.h)
  68 AC_CHECK_HEADERS(sys/mnttab.h)
  69 AC_CHECK_HEADERS(sys/mount.h)
  70 AC_CHECK_HEADERS(sys/vfs.h)
  71 AC_CHECK_HEADERS(sys/vfstab.h)
  72
  73 # For debugging interface (variable number of arguments)
  74 AC_CHECK_HEADERS(stdarg.h)
  75
  76 dnl Checking for libraries
  77 AC_CHECK_LIB(m, ext)
  78
  79 #
  80 # Checks for typedefs, structures, and compiler characteristics.
  81 #
  82 AC_C_CONST
  83 AC_TYPE_PID_T
  84 AC_TYPE_SIZE_T
  85 AC_HEADER_TIME
  86
  87 #
  88 # Checks for library functions.
  89 #
  90 AC_PROG_GCC_TRADITIONAL
  91 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
  92 AC_CHECK_FUNCS(socket, , AC_CHECK_LIB(socket, socket))
  93 AC_CHECK_FUNCS(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname))
  94 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
  95 AC_CHECK_FUNCS(strncasecmp strcasecmp)
  96
  97 # For cpu module
  98 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
  99
 100 # For load module
 101 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 102
 103 # For users module
 104 have_getutent="no"
 105 AC_CHECK_FUNCS(getutent getutxent, [have_getutent="yes"])
 106
 107 # For quota module
 108 AC_CHECK_FUNCS(quotactl)
 109 AC_CHECK_FUNCS(getgrgid getpwuid)
 110
 111 # For mount interface
 112 AC_CHECK_FUNCS(getfsent getvfsent listmntent)
 113 AC_FUNC_GETMNTENT
 114 if test "x$ac_cv_func_getmntent" = 'xyes'; then
 115         saveCFLAGS="$CFLAGS"
 116         CFLAGS="-Wall -Werror $CFLAGS"
 117         AC_CACHE_CHECK([whether getmntent takes one argument],
 118                 [fu_cv_getmntent1],
 119                 AC_COMPILE_IFELSE(
 120                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 121 #include "$srcdir/src/utils_mount.h"]],
 122                                 [[(void)getmntent((FILE *)NULL);]]
 123                         ),
 124                         [fu_cv_getmntent1=yes],
 125                         [fu_cv_getmntent1=no]
 126                 )
 127         )
 128         if test "x$fu_cv_getmntent1" = 'xno'; then
 129                 AC_CACHE_CHECK([whether getmntent takes two arguments],
 130                         [fu_cv_getmntent2],
 131                         AC_COMPILE_IFELSE(
 132                                 AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 133 #include "$srcdir/src/utils_mount.h"]],
 134                                         [[(void)getmntent((FILE *)NULL,
 135                                                 (struct mnttab *)NULL);]]
 136                                 ),
 137                                 [fu_cv_getmntent2=yes],
 138                                 [fu_cv_getmntent2=no]
 139                         )
 140                 )
 141         fi
 142         CFLAGS="$saveCFLAGS"
 143 fi
 144 if test "x$fu_cv_getmntent1" = 'xyes'; then
 145         AC_DEFINE(HAVE_GETMNTENT1,
 146                 1,
 147                 [Define if there is a function named getmntent
 148                         for reading the list of mounted filesystems, and
 149                         that function takes a single argument. (4.3BSD,
 150                         SunOS, HP-UX, Dynix, Irix, Linux)]
 151                 )
 152 fi
 153 if test "x$fu_cv_getmntent2" = 'xyes'; then
 154         AC_DEFINE(HAVE_GETMNTENT2,
 155                 1,
 156                 [Define if there is a function named getmntent
 157                         for reading the list of mounted filesystems, and
 158                         that function takes two arguments. (SVR4)]
 159                 )
 160 fi
 161
 162 AC_MSG_CHECKING([for kernel type ($host_os)])
 163 case $host_os in
 164         *linux*)
 165         AC_DEFINE([KERNEL_LINUX], [], [True if program is to be compiled for a Linux kernel])
 166         ac_system="Linux"
 167         ;;
 168         *solaris*)
 169         AC_DEFINE([KERNEL_SOLARIS], [], [True if program is to be compiled for a Solaris kernel])
 170         ac_system="Solaris"
 171         ;;
 172         *)
 173         ac_system="unknown"
 174 esac
 175 AC_MSG_RESULT([$ac_system])
 176
 177 dnl Checks for libraries.
 178 AC_CHECK_LIB(socket, socket)
 179 AC_CHECK_LIB(resolv, res_search)
 180
 181 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 182 AC_ARG_WITH(rrdtool, AC_HELP_STRING([--with-rrdtool=PFX], [Path to rrdtool.]),
 183 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 184         then
 185                 LDFLAGS="$LDFLAGS -L$withval/lib"
 186                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 187                 with_rrdtool="yes"
 188         fi
 189 ], [with_rrdtool="yes"])
 190 if test "x$with_rrdtool" = "xyes"
 191 then
 192         AC_CHECK_LIB(rrd, rrd_update,, [with_rrdtool="no"], [-lm])
 193 fi
 194 if test "x$with_rrdtool" = "xyes"
 195 then
 196         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no"])
 197 fi
 198 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 199
 200 AC_ARG_WITH(pth, AC_HELP_STRING([--with-pth=PFX], [Path to pth (experimental).]),
 201 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 202         then
 203                 LDFLAGS="$LDFLAGS -L$withval/lib"
 204                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 205                 with_pth="yes"
 206         fi
 207 ], [with_pth="no"])
 208 if test "x$with_pth" = "xyes"
 209 then
 210         AC_CHECK_LIB(pth, pth_init,, [with_pth="no"], [])
 211 fi
 212 if test "x$with_pth" = "xyes"
 213 then
 214         AC_CHECK_HEADERS(pth.h,, [with_pth="no"])
 215 fi
 216 if test "x$with_pth" = "xyes"
 217 then
 218         collect_pth=1
 219 else
 220         collect_pth=0
 221 fi
 222 AC_DEFINE_UNQUOTED(COLLECT_PTH, [$collect_pth],
 223         [Wether or not to use pth (portable threads) library])
 224 AM_CONDITIONAL(BUILD_WITH_PTH, test "x$with_pth" = "xyes")
 225
 226 if test "$ac_system" = "Solaris"
 227 then
 228         with_kstat="yes"
 229         AC_CHECK_LIB(kstat, kstat_open,, [with_kstat="no (not found)"])
 230         AC_CHECK_LIB(devinfo, di_init)
 231         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 232 else
 233         with_kstat="no (Solaris only)"
 234 fi
 235
 236 AC_ARG_WITH(libstatgrab, AC_HELP_STRING([--with-libstatgrab@<:@=PFX@:>@], [Path to libstatgrab.]),
 237 [
 238         # given..
 239         if test "x$withval" != "xno"
 240         then
 241                 if test "x$withval" != "xyes"
 242                 then
 243                         LDFLAGS="$LDFLAGS -L$withval/lib"
 244                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 245                         with_libstatgrab="yes"
 246                 fi
 247         fi
 248 ],
 249 [
 250         # not given..
 251         if test "x$ac_system" != "xunknown"
 252         then
 253                 with_libstatgrab="no"
 254         else
 255                 with_libstatgrab="yes"
 256         fi
 257 ])
 258 if test "x$with_libstatgrab" = "xyes"
 259 then
 260         AC_CHECK_LIB(devstat, getdevs)
 261         AC_CHECK_LIB(kvm, kvm_getargv)
 262         AC_CHECK_LIB(statgrab, sg_init,, [with_libstatgrab="no (not found)"])
 263         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (not found)"])
 264 fi
 265
 266 AC_ARG_WITH(lm-sensors, AC_HELP_STRING([--with-lm-sensors@<:@=PFX@:>@], [Path to lm_sensors.]),
 267 [
 268         # given..
 269         if test "x$withval" != "xno"
 270         then
 271                 if test "x$withval" != "xyes"
 272                 then
 273                         LDFLAGS="$LDFLAGS -L$withval/lib"
 274                         CPPFLAGS="$CPPFLAGS -I$withval/include"
 275                         with_lm_sensors="yes"
 276                 fi
 277         fi
 278 ],
 279 [
 280         # not given..
 281         if test "x$ac_system" = "xLinux"
 282         then
 283                 with_lm_sensors="yes"
 284         else
 285                 with_lm_sensors="no"
 286         fi
 287 ])
 288 if test "x$with_lm_sensors" = "xyes"
 289 then
 290         AC_CHECK_LIB(sensors, sensors_init,
 291         [
 292                 with_lm_sensors="yes"
 293                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 294         ],
 295         [with_lm_sensors="no (not found)"])
 296         AC_CHECK_HEADERS(sensors/sensors.h,
 297         [
 298                 with_lm_sensors="yes"
 299                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 300         ],
 301         [with_lm_sensors="no (not found)"])
 302 fi
 303
 304
 305
 306 #
 307 # Check for enabled/disabled features
 308 #
 309 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug],
 310         [Enable debugging (disabled by default)]),
 311         [], [enable_debug="no"])
 312 if test "x$enable_debug" = "xno"
 313 then
 314         collect_debug=0
 315 else
 316         if test "x$enable_debug" = "xyes"
 317         then
 318                 collect_debug=1
 319         else
 320                 AC_MSG_NOTICE([Please specify either --enable-debug or --disable-debug; Enabling debugging.])
 321                 collect_debug=1
 322                 enable_debug="yes"
 323         fi
 324 fi
 325 AC_DEFINE_UNQUOTED(COLLECT_DEBUG, [$collect_debug],
 326         [Wether or not to enable debugging])
 327 AM_CONDITIONAL(BUILD_DEBUG, test "x$enable_debug" = "xyes")
 328
 329 AC_ARG_ENABLE(daemon, AC_HELP_STRING([--disable-daemon],
 330         [Disable daemon mode (enabled by default)]),
 331         [], [enable_daemon="yes"])
 332 if test "x$enable_daemon" = "xno"
 333 then
 334         collect_daemon=0
 335 else
 336         if test "x$enable_daemon" = "xyes"
 337         then
 338                 collect_daemon=1
 339         else
 340                 AC_MSG_NOTICE([Please specify either --enable-daemon or --disable-daemon; Enabling daemon mode.])
 341                 collect_daemon=1
 342                 enable_daemon="yes"
 343         fi
 344 fi
 345 AC_DEFINE_UNQUOTED(COLLECT_DAEMON, [$collect_daemon],
 346         [Wether or not to enable daemon mode])
 347 AM_CONDITIONAL(BUILD_DAEMON, test "x$enable_daemon" = "xyes")
 348
 349 AC_ARG_ENABLE(cpu, AC_HELP_STRING([--disable-cpu], [Disable CPU usage statistics]),, [enable_cpu="yes"])
 350 if test "x$enable_cpu" != "xno"
 351 then
 352         if test "x$ac_system" = "xLinux" -o "x$with_kstat" = "xyes" -o "x$have_sysctlbyname" = "xyes"
 353         then
 354                 enable_cpu="yes"
 355         else
 356                 enable_cpu="no"
 357         fi
 358 fi
 359 if test "x$enable_cpu" = "xno"
 360 then
 361         AC_DEFINE(COLLECT_CPU, 0, [Wether or not to collect CPU usage statistics])
 362 fi
 363 AM_CONDITIONAL(BUILD_MODULE_CPU, test "x$enable_cpu" = "xyes")
 364
 365 AC_ARG_ENABLE(cpufreq, AC_HELP_STRING([--disable-cpufreq], [Disable system cpu frequency statistics]),, [enable_cpufreq="yes"])
 366 if test "x$enable_cpufreq" != "xno"
 367 then
 368         if test "x$ac_system" = "xLinux"
 369         then
 370                 enable_cpufreq="yes"
 371         else
 372                 enable_cpufreq="no"
 373         fi
 374 fi
 375 if test "x$enable_cpufreq" = "xno"
 376 then
 377         AC_DEFINE(COLLECT_CPUFREQ, 0, [Wether or not to collect cpu frequency statistics])
 378 fi
 379 AM_CONDITIONAL(BUILD_MODULE_CPUFREQ, test "x$enable_cpufreq" = "xyes")
 380
 381 AC_ARG_ENABLE(disk, AC_HELP_STRING([--disable-disk], [Disable disk/partition statistics]),, [enable_disk="yes"])
 382 if test "x$enable_disk" != "xno"
 383 then
 384         if test "x$ac_system" = "xLinux" -o "x$with_kstat" = "xyes"
 385         then
 386                 enable_disk="yes"
 387         else
 388                 enable_disk="no"
 389         fi
 390 fi
 391 if test "x$enable_disk" = "xno"
 392 then
 393         AC_DEFINE(COLLECT_DISK, 0, [Wether or not to collect diskstats])
 394 fi
 395 AM_CONDITIONAL(BUILD_MODULE_DISK, test "x$enable_disk" = "xyes")
 396
 397 AC_ARG_ENABLE(quota, AC_HELP_STRING([--enable-quota],
 398         [Enable quota statistics (experimental, disabled by default)]),
 399         [], [enable_quota="no"])
 400 if test "x$enable_quota" = "xno"
 401 then
 402         collect_quota=0
 403 else
 404         if test "x$enable_quota" = "xyes"
 405         then
 406                 collect_quota=1
 407         else
 408                 AC_MSG_NOTICE([Please specify either --enable-quota or --disable-quota; Enabling quota statistics.])
 409                 collect_quota=1
 410                 enable_quota="yes"
 411         fi
 412 fi
 413 AC_DEFINE_UNQUOTED(COLLECT_QUOTA, [$collect_quota],
 414         [Wether or not to collect quota statistics])
 415 AM_CONDITIONAL(BUILD_MODULE_QUOTA, test "x$enable_quota" = "xyes")
 416
 417 AC_ARG_ENABLE(hddtemp, AC_HELP_STRING([--disable-hddtemp], [Disable hdd temperature statistics]),, [enable_hddtemp="yes"])
 418 if test "x$enable_hddtemp" = "xno"
 419 then
 420         AC_DEFINE(COLLECT_HDDTEMP, 0, [Wether or not to collect hdd temperature statistics])
 421 fi
 422 AM_CONDITIONAL(BUILD_MODULE_HDDTEMP, test "x$enable_hddtemp" = "xyes")
 423
 424 AC_ARG_ENABLE(load, AC_HELP_STRING([--disable-load], [Disable system load statistics]),, [enable_load="yes"])
 425 if test "x$enable_load" != "xno"
 426 then
 427         if test "x$have_getloadavg" = "xyes" -o "x$ac_system" = "xLinux" -o "x$with_libstatgrab" = "xyes"
 428         then
 429                 enable_load="yes"
 430         else
 431                 enable_load="no"
 432         fi
 433 fi
 434 if test "x$enable_load" = "xno"
 435 then
 436         AC_DEFINE(COLLECT_LOAD, 0, [Wether or not to collect system load statistics])
 437 fi
 438 AM_CONDITIONAL(BUILD_MODULE_LOAD, test "x$enable_load" = "xyes")
 439
 440 AC_ARG_ENABLE(memory, AC_HELP_STRING([--disable-memory], [Disable memory statistics]),, [enable_memory="yes"])
 441 if test "x$enable_memory" != "xno"
 442 then
 443         if test "x$ac_system" = "xLinux" -o "x$with_kstat" = "xyes" -o "x$with_libstatgrab" = "xyes"
 444         then
 445                 enable_memory="yes"
 446         else
 447                 enable_memory="no"
 448         fi
 449 fi
 450 if test "x$enable_memory" = "xno"
 451 then
 452         AC_DEFINE(COLLECT_MEMORY, 0, [Wether or not to collect memory statistics])
 453 fi
 454 AM_CONDITIONAL(BUILD_MODULE_MEMORY, test "x$enable_memory" = "xyes")
 455
 456 AC_ARG_ENABLE(nfs, AC_HELP_STRING([--disable-nfs], [Disable nfs statistics]),, [enable_nfs="yes"])
 457 if test "x$enable_nfs" != "xno"
 458 then
 459         if test "x$ac_system" = "xLinux"
 460         then
 461                 enable_nfs="yes"
 462         else
 463                 enable_nfs="no"
 464         fi
 465 fi
 466 if test "x$enable_nfs" = "xno"
 467 then
 468         AC_DEFINE(COLLECT_NFS, 0, [Wether or not to collect nfs statistics])
 469 fi
 470 AM_CONDITIONAL(BUILD_MODULE_NFS, test "x$enable_nfs" = "xyes")
 471
 472 AC_ARG_ENABLE(ping, AC_HELP_STRING([--disable-ping], [Disable ping statistics]),, [enable_ping="yes"])
 473 if test "x$enable_ping" != "xno"
 474 then
 475         enable_ping="yes"
 476 fi
 477 if test "x$enable_ping" = "xno"
 478 then
 479         AC_DEFINE(COLLECT_PING, 0, [Wether or not to collect ping statistics])
 480 fi
 481 AM_CONDITIONAL(BUILD_MODULE_PING, test "x$enable_ping" = "xyes")
 482
 483 AC_ARG_ENABLE(processes, AC_HELP_STRING([--disable-processes], [Disable processes statistics]),, [enable_processes="yes"])
 484 if test "x$enable_processes" != "xno"
 485 then
 486         if test "x$ac_system" = "xLinux"
 487         then
 488                 enable_processes="yes"
 489         else
 490                 enable_processes="no"
 491         fi
 492 fi
 493 if test "x$enable_processes" = "xno"
 494 then
 495         AC_DEFINE(COLLECT_PROCESSES, 0, [Wether or not to collect processes statistics])
 496 fi
 497 AM_CONDITIONAL(BUILD_MODULE_PROCESSES, test "x$enable_processes" = "xyes")
 498
 499 AC_ARG_ENABLE(sensors, AC_HELP_STRING([--disable-sensors], [Disable lm_sensors statistics]),, [enable_sensors=$with_lm_sensors])
 500 if test "x$enable_sensors" != "xno"
 501 then
 502         if test "x$with_lm_sensors" = "xyes"
 503         then
 504                 enable_sensors="yes"
 505         else
 506                 enable_sensors="no"
 507         fi
 508 fi
 509 if test "x$enable_sensors" = "xno"
 510 then
 511         AC_DEFINE(COLLECT_SENSORS, 0, [Wether or not to collect lm_sensors statistics])
 512 fi
 513 AM_CONDITIONAL(BUILD_MODULE_SENSORS, test "x$enable_sensors" = "xyes")
 514
 515 AC_ARG_ENABLE(serial, AC_HELP_STRING([--disable-serial], [Disable serial statistics]),, [enable_serial="yes"])
 516 if test "x$enable_serial" != "xno"
 517 then
 518         if test "x$ac_system" = "xLinux"
 519         then
 520                 enable_serial="yes"
 521         else
 522                 enable_serial="no"
 523         fi
 524 fi
 525 if test "x$enable_serial" = "xno"
 526 then
 527         AC_DEFINE(COLLECT_SERIAL, 0, [Wether or not to collect serial statistics])
 528 fi
 529 AM_CONDITIONAL(BUILD_MODULE_SERIAL, test "x$enable_serial" = "xyes")
 530
 531 AC_ARG_ENABLE(swap, AC_HELP_STRING([--disable-swap], [Disable swap statistics]),, [enable_swap="yes"])
 532 if test "x$enable_swap" != "xno"
 533 then
 534         if test "x$ac_system" = "xLinux" -o "x$with_kstat" = "xyes" -o "x$with_libstatgrab" = "xyes"
 535         then
 536                 enable_swap="yes"
 537         else
 538                 enable_swap="no"
 539         fi
 540 fi
 541 if test "x$enable_swap" = "xno"
 542 then
 543         AC_DEFINE(COLLECT_SWAP, 0, [Wether or not to collect swap statistics])
 544 fi
 545 AM_CONDITIONAL(BUILD_MODULE_SWAP, test "x$enable_swap" = "xyes")
 546
 547 AC_ARG_ENABLE(tape, AC_HELP_STRING([--disable-tape], [Disable tape statistics]),, [enable_tape="yes"])
 548 if test "x$enable_tape" != "xno"
 549 then
 550         if test "x$with_kstat" = "xyes"
 551         then
 552                 enable_tape="yes"
 553         else
 554                 enable_tape="no"
 555         fi
 556 fi
 557 if test "x$enable_tape" = "xno"
 558 then
 559         AC_DEFINE(COLLECT_TAPE, 0, [Wether or not to collect tape statistics])
 560 fi
 561 AM_CONDITIONAL(BUILD_MODULE_TAPE, test "x$enable_tape" = "xyes")
 562
 563 AC_ARG_ENABLE(traffic, AC_HELP_STRING([--disable-traffic], [Disable system traffic statistics]),, [enable_traffic="yes"])
 564 if test "x$enable_traffic" != "xno"
 565 then
 566         if test "x$ac_system" = "xLinux" -o "x$with_kstat" = "xyes" -o "x$with_libstatgrab" = "xyes"
 567         then
 568                 enable_traffic="yes"
 569         else
 570                 enable_traffic="no"
 571         fi
 572 fi
 573 if test "x$enable_traffic" = "xno"
 574 then
 575         AC_DEFINE(COLLECT_TRAFFIC, 0, [Wether or not to collect network traffic statistics])
 576 fi
 577 AM_CONDITIONAL(BUILD_MODULE_TRAFFIC, test "x$enable_traffic" = "xyes")
 578
 579 AC_ARG_ENABLE(users, AC_HELP_STRING([--disable-users], [Disable user count statistics]),, [enable_users="yes"])
 580 if test "x$enable_users" != "xno"
 581 then
 582        if test "x$have_getutent" = "xyes"
 583        then
 584                enable_users="yes"
 585        else
 586                enable_users="no"
 587        fi
 588 fi
 589 if test "x$enable_users" = "xno"
 590 then
 591        AC_DEFINE(COLLECT_USERS, 0, [Wether or not to collect user count statistics])
 592 fi
 593 AM_CONDITIONAL(BUILD_MODULE_USERS, test "x$enable_users" = "xyes")
 594
 595 AC_OUTPUT(Makefile src/libping/Makefile src/Makefile)
 596
 597 cat <<EOF;
 598
 599 Configuration:
 600   Libraries:
 601     librrd  . . . . . . $with_rrdtool
 602     libpth  . . . . . . $with_pth (experimental)
 603     lm_sensors  . . . . $with_lm_sensors
 604     libstatgrab . . . . $with_libstatgrab
 605     libkstat  . . . . . $with_kstat
 606
 607   Features:
 608     debug . . . . . . . $enable_debug
 609     daemon mode . . . . $enable_daemon
 610
 611   Modules:
 612     cpu . . . . . . . . $enable_cpu
 613     cpufreq . . . . . . $enable_cpufreq
 614     disk  . . . . . . . $enable_disk
 615     quota . . . . . . . $enable_quota (experimental)
 616     hddtemp . . . . . . $enable_hddtemp
 617     load  . . . . . . . $enable_load
 618     memory  . . . . . . $enable_memory
 619     nfs . . . . . . . . $enable_nfs
 620     ping  . . . . . . . $enable_ping
 621     processes . . . . . $enable_processes
 622     sensors . . . . . . $enable_sensors
 623     serial  . . . . . . $enable_serial
 624     swap  . . . . . . . $enable_swap
 625     tape  . . . . . . . $enable_tape
 626     traffic . . . . . . $enable_traffic
 627     users . . . . . . . $enable_users
 628
 629 EOF