1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(collectd, 3.11.2)
3 AC_CONFIG_SRCDIR(src/collectd.c)
4 AC_CONFIG_HEADERS(src/config.h)
5 AM_INIT_AUTOMAKE(dist-bzip2)
6 AC_LANG(C)
8 AC_PREFIX_DEFAULT("/opt/collectd")
10 #
11 # Checks for programs.
12 #
13 AC_PROG_CC
14 AC_PROG_CPP
15 AC_PROG_INSTALL
16 AC_PROG_LN_S
17 AC_PROG_MAKE_SET
18 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
20 dnl configure libtool
21 AC_DISABLE_STATIC
22 AC_LIBLTDL_CONVENIENCE
23 AC_SUBST(LTDLINCL)
24 AC_SUBST(LIBLTDL)
25 AC_LIBTOOL_DLOPEN
26 AC_PROG_LIBTOOL
27 #AC_PROG_RANLIB
28 AC_CONFIG_SUBDIRS(libltdl)
30 #
31 # Checks for header files.
32 #
33 AC_HEADER_STDC
34 AC_HEADER_SYS_WAIT
35 AC_HEADER_DIRENT
36 AC_CHECK_HEADERS(stdint.h)
37 AC_CHECK_HEADERS(stdio.h)
38 AC_CHECK_HEADERS(errno.h)
39 AC_CHECK_HEADERS(math.h)
40 AC_CHECK_HEADERS(syslog.h)
41 AC_CHECK_HEADERS(fcntl.h)
42 AC_CHECK_HEADERS(signal.h)
43 AC_CHECK_HEADERS(assert.h)
44 AC_CHECK_HEADERS(sys/types.h)
45 AC_CHECK_HEADERS(sys/socket.h)
46 AC_CHECK_HEADERS(sys/select.h)
47 AC_CHECK_HEADERS(sys/poll.h)
48 AC_CHECK_HEADERS(netdb.h)
49 AC_CHECK_HEADERS(arpa/inet.h)
50 AC_CHECK_HEADERS(sys/resource.h)
51 AC_CHECK_HEADERS(sys/param.h)
53 # For ping library
54 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
55 [#if HAVE_STDINT_H
56 # include <stdint.h>
57 #endif
58 #if HAVE_SYS_TYPES_H
59 # include <sys/types.h>
60 #endif
61 ])
62 AC_CHECK_HEADERS(netinet/in.h, [], [],
63 [#if HAVE_STDINT_H
64 # include <stdint.h>
65 #endif
66 #if HAVE_SYS_TYPES_H
67 # include <sys/types.h>
68 #endif
69 #if HAVE_NETINET_IN_SYSTM_H
70 # include <netinet/in_systm.h>
71 #endif
72 ])
73 AC_CHECK_HEADERS(netinet/ip.h, [], [],
74 [#if HAVE_STDINT_H
75 # include <stdint.h>
76 #endif
77 #if HAVE_SYS_TYPES_H
78 # include <sys/types.h>
79 #endif
80 #if HAVE_NETINET_IN_SYSTM_H
81 # include <netinet/in_systm.h>
82 #endif
83 #if HAVE_NETINET_IN_H
84 # include <netinet/in.h>
85 #endif
86 ])
87 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
88 [#if HAVE_STDINT_H
89 # include <stdint.h>
90 #endif
91 #if HAVE_SYS_TYPES_H
92 # include <sys/types.h>
93 #endif
94 #if HAVE_NETINET_IN_SYSTM_H
95 # include <netinet/in_systm.h>
96 #endif
97 #if HAVE_NETINET_IN_H
98 # include <netinet/in.h>
99 #endif
100 #if HAVE_NETINET_IP_H
101 # include <netinet/ip.h>
102 #endif
103 ])
104 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
105 [#if HAVE_STDINT_H
106 # include <stdint.h>
107 #endif
108 #if HAVE_SYS_TYPES_H
109 # include <sys/types.h>
110 #endif
111 #if HAVE_NETINET_IN_SYSTM_H
112 # include <netinet/in_systm.h>
113 #endif
114 #if HAVE_NETINET_IN_H
115 # include <netinet/in.h>
116 #endif
117 #if HAVE_NETINET_IP_H
118 # include <netinet/ip.h>
119 #endif
120 ])
121 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
122 [#if HAVE_STDINT_H
123 # include <stdint.h>
124 #endif
125 #if HAVE_SYS_TYPES_H
126 # include <sys/types.h>
127 #endif
128 #if HAVE_NETINET_IN_SYSTM_H
129 # include <netinet/in_systm.h>
130 #endif
131 #if HAVE_NETINET_IN_H
132 # include <netinet/in.h>
133 #endif
134 ])
135 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
136 [#if HAVE_STDINT_H
137 # include <stdint.h>
138 #endif
139 #if HAVE_SYS_TYPES_H
140 # include <sys/types.h>
141 #endif
142 #if HAVE_NETINET_IN_SYSTM_H
143 # include <netinet/in_systm.h>
144 #endif
145 #if HAVE_NETINET_IN_H
146 # include <netinet/in.h>
147 #endif
148 #if HAVE_NETINET_IP6_H
149 # include <netinet/ip6.h>
150 #endif
151 ])
152 AC_CHECK_HEADERS(netinet/udp.h, [], [],
153 [#if HAVE_STDINT_H
154 # include <stdint.h>
155 #endif
156 #if HAVE_SYS_TYPES_H
157 # include <sys/types.h>
158 #endif
159 #if HAVE_NETINET_IN_SYSTM_H
160 # include <netinet/in_systm.h>
161 #endif
162 #if HAVE_NETINET_IN_H
163 # include <netinet/in.h>
164 #endif
165 #if HAVE_NETINET_IP_H
166 # include <netinet/ip.h>
167 #endif
168 ])
170 # For cpu modules
171 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
172 AC_CHECK_HEADERS(mach/mach_init.h)
173 AC_CHECK_HEADERS(mach/host_priv.h)
174 AC_CHECK_HEADERS(mach/mach_error.h)
175 AC_CHECK_HEADERS(mach/mach_host.h)
176 AC_CHECK_HEADERS(mach/mach_port.h)
177 AC_CHECK_HEADERS(mach/mach_types.h)
178 AC_CHECK_HEADERS(mach/message.h)
179 AC_CHECK_HEADERS(mach/processor_set.h)
180 AC_CHECK_HEADERS(mach/processor.h)
181 AC_CHECK_HEADERS(mach/processor_info.h)
182 AC_CHECK_HEADERS(mach/task.h)
183 AC_CHECK_HEADERS(mach/thread_act.h)
184 AC_CHECK_HEADERS(mach/vm_region.h)
185 AC_CHECK_HEADERS(mach/vm_map.h)
186 AC_CHECK_HEADERS(mach/vm_prot.h)
187 AC_CHECK_HEADERS(mach/vm_statistics.h)
188 AC_CHECK_HEADERS(mach/kern_return.h)
190 # For hddtemp module
191 AC_CHECK_HEADERS(linux/major.h)
193 # For the apple_sensors module
194 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h)
195 AC_CHECK_HEADERS(IOKit/IOKitLib.h)
196 AC_CHECK_HEADERS(IOKit/IOTypes.h)
198 # For the battery plugin
199 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
200 [
201 #if HAVE_IOKIT_IOKITLIB_H
202 # include <IOKit/IOKitLib.h>
203 #endif
204 #if HAVE_IOKIT_IOTYPES_H
205 # include <IOKit/IOTypes.h>
206 #endif
207 ])
208 AC_CHECK_HEADERS(IOKit/ps/IOPSKeys.h)
210 # For the `disk' plugin
211 AC_CHECK_HEADERS(IOKit/IOBSD.h)
212 AC_CHECK_HEADERS(IOKit/storage/IOBlockStorageDriver.h)
214 # For load module
215 AC_CHECK_HEADERS(sys/loadavg.h)
217 # For the processes plugin
218 AC_CHECK_HEADERS(linux/config.h)
220 # For the swap module
221 AC_CHECK_HEADERS(sys/swap.h)
223 # For users module
224 AC_CHECK_HEADERS(utmp.h)
225 AC_CHECK_HEADERS(utmpx.h)
227 # For traffic plugin
228 AC_CHECK_HEADERS(ifaddrs.h)
229 AC_CHECK_HEADERS(net/if.h, [], [],
230 [
231 #if HAVE_SYS_TYPES_H
232 # include <sys/types.h>
233 #endif
234 #if HAVE_SYS_SOCKET_H
235 # include <sys/socket.h>
236 #endif
237 ])
238 AC_CHECK_HEADERS(linux/if.h, [], [],
239 [
240 #if HAVE_SYS_TYPES_H
241 # include <sys/types.h>
242 #endif
243 #if HAVE_SYS_SOCKET_H
244 # include <sys/socket.h>
245 #endif
246 ])
247 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
248 [
249 #if HAVE_SYS_TYPES_H
250 # include <sys/types.h>
251 #endif
252 #if HAVE_SYS_SOCKET_H
253 # include <sys/socket.h>
254 #endif
255 #if HAVE_LINUX_IF_H
256 # include <linux/if.h>
257 #endif
258 ])
260 # For apache plugin
261 AC_CHECK_HEADERS(curl/curl.h)
263 # For quota module
264 AC_CHECK_HEADERS(grp.h pwd.h sys/ucred.h)
265 AC_CHECK_HEADERS(ctype.h)
266 AC_CHECK_HEADERS(limits.h)
267 AC_CHECK_HEADERS(sys/quota.h)
268 AC_CHECK_HEADERS(xfs/xqm.h)
270 # For mount interface
271 AC_CHECK_HEADERS(fs_info.h)
272 AC_CHECK_HEADERS(fshelp.h)
273 AC_CHECK_HEADERS(paths.h)
274 AC_CHECK_HEADERS(mntent.h)
275 AC_CHECK_HEADERS(mnttab.h)
276 AC_CHECK_HEADERS(sys/fstyp.h)
277 AC_CHECK_HEADERS(sys/fs_types.h)
278 AC_CHECK_HEADERS(sys/mntent.h)
279 AC_CHECK_HEADERS(sys/mnttab.h)
280 AC_CHECK_HEADERS(sys/mount.h)
281 AC_CHECK_HEADERS(sys/statfs.h)
282 AC_CHECK_HEADERS(sys/statvfs.h)
283 AC_CHECK_HEADERS(sys/vfs.h)
284 AC_CHECK_HEADERS(sys/vfstab.h)
286 # For the swap plugin, FreeBSD
287 AC_CHECK_HEADERS(kvm.h)
289 # For the email plugin
290 AC_CHECK_HEADERS(linux/un.h, [], [],
291 [
292 #if HAVE_SYS_SOCKET_H
293 # include <sys/socket.h>
294 #endif
295 ])
296 AC_CHECK_HEADERS(sys/un.h)
297 AC_CHECK_HEADERS(grp.h)
299 # For debugging interface (variable number of arguments)
300 AC_CHECK_HEADERS(stdarg.h)
302 # Regular expressions for the ignorelist.
303 AC_CHECK_HEADERS(regex.h)
305 # For the dns plugin
306 AC_CHECK_HEADERS(arpa/nameser.h arpa/nameser_compat.h)
308 AC_CHECK_HEADERS(net/if_arp.h)
309 AC_CHECK_HEADERS(net/if_ppp.h)
310 AC_CHECK_HEADERS(netinet/if_ether.h)
312 #
313 # Checking for libraries
314 #
315 AC_CHECK_LIB(m, ext)
317 #
318 # Checks for typedefs, structures, and compiler characteristics.
319 #
320 AC_C_CONST
321 AC_TYPE_PID_T
322 AC_TYPE_SIZE_T
323 AC_TYPE_UID_T
324 AC_HEADER_TIME
326 #
327 # Checks for library functions.
328 #
329 AC_PROG_GCC_TRADITIONAL
330 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
331 AC_CHECK_FUNCS(getaddrinfo getnameinfo)
332 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
333 AC_CHECK_FUNCS(strncasecmp strcasecmp)
334 AC_CHECK_FUNCS(openlog syslog closelog)
336 socket_needs_socket="no"
337 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
338 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
340 nanosleep_needs_rt="no"
341 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
342 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
344 # Regular expressions for the ignorelist.
345 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
347 # For cpu module
348 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
350 # For df module
351 AC_CHECK_FUNCS(statfs statvfs)
353 # For load module
354 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
356 # For the `processes' plugin
357 AC_CHECK_FUNCS(thread_info)
359 # For users module
360 AC_CHECK_FUNCS(getutent getutxent)
362 # For quota module
363 AC_CHECK_FUNCS(quotactl)
364 AC_CHECK_FUNCS(getgrgid getpwuid)
366 # For traffic module
367 AC_CHECK_FUNCS(getifaddrs)
369 # For mount interface
370 #AC_CHECK_FUNCS(getfsent getvfsent)
372 have_getfsstat="no"
373 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
374 have_getvfsstat="no"
375 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
376 have_listmntent="no"
377 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
379 have_getmntent="no"
380 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
381 if test "x$have_getmntent" = "xno"; then
382 AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
383 fi
384 if test "x$have_getmntent" = "xno"; then
385 AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
386 fi
387 if test "x$have_getmntent" = "xno"; then
388 AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
389 fi
391 if test "x$have_getmntent" = "xc"; then
392 AC_CACHE_CHECK([whether getmntent takes one argument],
393 [have_one_getmntent],
394 AC_COMPILE_IFELSE(
395 AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
396 #include <mntent.h>
397 #include "$srcdir/src/utils_mount.h"]],
398 [[
399 FILE *fh;
400 struct mntent *me;
401 fh = setmntent ("/etc/mtab", "r");
402 me = getmntent (fh);
403 ]]
404 ),
405 [have_one_getmntent="yes"],
406 [have_one_getmntent="no"]
407 )
408 )
409 AC_CACHE_CHECK([whether getmntent takes two arguments],
410 [have_two_getmntent],
411 AC_COMPILE_IFELSE(
412 AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
413 #include <sys/mnttab.h>
414 #include "$srcdir/src/utils_mount.h"]],
415 [[
416 FILE *fh;
417 struct mnttab mt;
418 int status;
419 fh = fopen ("/etc/mnttab", "r");
420 status = getmntent (fh, &mt);
421 ]]
422 ),
423 [have_two_getmntent="yes"],
424 [have_two_getmntent="no"]
425 )
426 )
427 fi
429 # Check for different versions of `getmntent' here..
431 if test "x$have_getmntent" = "xc"; then
432 if test "x$have_one_getmntent" = "xyes"; then
433 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
434 [Define if the function getmntent exists and takes one argument.])
435 fi
436 if test "x$have_two_getmntent" = "xyes"; then
437 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
438 [Define if the function getmntent exists and takes two arguments.])
439 fi
440 fi
441 if test "x$have_getmntent" = "xsun"; then
442 AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
443 [Define if the function getmntent exists. It's the version from libsun.])
444 fi
445 if test "x$have_getmntent" = "xseq"; then
446 AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
447 [Define if the function getmntent exists. It's the version from libseq.])
448 fi
449 if test "x$have_getmntent" = "xgen"; then
450 AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
451 [Define if the function getmntent exists. It's the version from libgen.])
452 fi
454 # Check for structures
455 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
456 [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
457 [],
458 [
459 #include <sys/types.h>
460 #include <sys/socket.h>
461 #include <net/if.h>
462 ])
463 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
464 [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
465 [],
466 [
467 #include <sys/types.h>
468 #include <sys/socket.h>
469 #include <linux/if.h>
470 #include <linux/netdevice.h>
471 ])
473 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
474 [#if HAVE_STDINT_H
475 # include <stdint.h>
476 #endif
477 #if HAVE_SYS_TYPES_H
478 # include <sys/types.h>
479 #endif
480 #if HAVE_NETINET_IN_SYSTM_H
481 # include <netinet/in_systm.h>
482 #endif
483 #if HAVE_NETINET_IN_H
484 # include <netinet/in.h>
485 #endif
486 #if HAVE_NETINET_IP_H
487 # include <netinet/ip.h>
488 #endif
489 #if HAVE_NETINET_UDP_H
490 # include <netinet/udp.h>
491 #endif
492 ])
493 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
494 [#if HAVE_STDINT_H
495 # include <stdint.h>
496 #endif
497 #if HAVE_SYS_TYPES_H
498 # include <sys/types.h>
499 #endif
500 #if HAVE_NETINET_IN_SYSTM_H
501 # include <netinet/in_systm.h>
502 #endif
503 #if HAVE_NETINET_IN_H
504 # include <netinet/in.h>
505 #endif
506 #if HAVE_NETINET_IP_H
507 # include <netinet/ip.h>
508 #endif
509 #if HAVE_NETINET_UDP_H
510 # include <netinet/udp.h>
511 #endif
512 ])
514 AC_MSG_CHECKING([for kernel type ($host_os)])
515 case $host_os in
516 *linux*)
517 AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
518 ac_system="Linux"
519 ;;
520 *solaris*)
521 AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
522 ac_system="Solaris"
523 ;;
524 *)
525 ac_system="unknown"
526 esac
527 AC_MSG_RESULT([$ac_system])
529 with_libresolv="yes"
530 AC_CHECK_LIB(resolv, res_search,
531 [
532 AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
533 ],
534 [with_libresolv="no"])
535 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
538 m4_divert_once([HELP_WITH], [
539 collectd additional packages:])
541 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
542 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
543 [ if test "x$withval" != "xno" && test "x$withval" != "xyes"
544 then
545 LDFLAGS="$LDFLAGS -L$withval/lib"
546 CPPFLAGS="$CPPFLAGS -I$withval/include"
547 with_rrdtool="yes"
548 fi
549 ], [with_rrdtool="yes"])
550 if test "x$with_rrdtool" = "xyes"
551 then
552 AC_CHECK_LIB(rrd, rrd_update,
553 [
554 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
555 ],
556 [with_rrdtool="no (librrd not found)"], [-lm])
557 fi
558 if test "x$with_rrdtool" = "xyes"
559 then
560 AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
561 fi
562 if test "x$with_rrdtool" = "xyes"
563 then
564 collect_rrdtool=1
565 else
566 collect_rrdtool=0
567 fi
568 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
569 [Wether or not to use rrdtool library])
570 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
572 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
573 [ if test "x$withval" != "xno" -a "x$withval" != "xyes"
574 then
575 LDFLAGS="$LDFLAGS -L$withval/lib"
576 CPPFLAGS="$CPPFLAGS -I$withval/include"
577 with_libpthread="yes"
578 else
579 if test "x$withval" = "xno"
580 then
581 with_libpthread="no (disabled)"
582 fi
583 fi
584 ], [with_libpthread="yes"])
585 if test "x$with_libpthread" = "xyes"
586 then
587 AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
588 fi
589 if test "x$with_libpthread" = "xyes"
590 then
591 AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
592 fi
593 if test "x$with_libpthread" = "xyes"
594 then
595 collect_pthread=1
596 else
597 collect_pthread=0
598 fi
599 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
600 [Wether or not to use pthread (POSIX threads) library])
601 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
603 if test "$ac_system" = "Solaris"
604 then
605 with_kstat="yes"
606 with_devinfo="yes"
607 else
608 with_kstat="no (Solaris only)"
609 with_devinfo="no (Solaris only)"
610 fi
612 if test "x$with_kstat" = "xyes"
613 then
614 AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
615 fi
616 if test "x$with_kstat" = "xyes"
617 then
618 AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
619 AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
620 fi
621 if test "x$with_kstat" = "xyes"
622 then
623 collect_kstat=1
624 else
625 collect_kstat=0
626 fi
627 AC_DEFINE_UNQUOTED(COLLECT_KSTAT, [$collect_kstat],
628 [Wether or not to use kstat library (Solaris)])
629 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
630 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
632 ### BEGIN of check for libcurl ###
633 with_curl_config="curl-config"
634 with_curl_prefix=0
635 with_curl_libs=""
636 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
637 [
638 if test "x$withval" != "xno" -a "x$withval" != "xyes"
639 then
640 if test -x "$withval/bin/curl-config"
641 then
642 with_curl_config="$withval/bin/curl-config"
643 with_curl_prefix=1
644 fi
645 fi
646 if test "x$withval" = "xno"
647 then
648 with_libcurl="no"
649 else
650 with_libcurl="yes"
651 fi
652 ],
653 [
654 with_libcurl="yes"
655 ])
656 if test "x$with_libcurl" = "xyes"
657 then
658 with_curl_libs=`$with_curl_config --libs 2>/dev/null`
659 curl_config_status=$?
661 if test $curl_config_status -ne 0
662 then
663 with_libcurl="no"
664 else
665 AC_CHECK_LIB(curl, curl_easy_init,
666 [
667 BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
668 AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
669 ],
670 [
671 with_libcurl="no"
672 ],
673 [$with_curl_libs])
674 fi
675 fi
676 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
677 then
678 with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
679 curl_config_status=$?
681 if test $curl_config_status -ne 0
682 then
683 with_libcurl="no"
684 else
685 if test -d "$with_curl_prefix/include"
686 then
687 CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
688 fi
689 fi
690 fi
692 with_libcurl_numeric=0
693 if test "x$with_libcurl" = "xyes"
694 then
695 with_libcurl_numeric=1
696 fi
697 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
698 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
699 ### END of check for libcurl ###
701 with_libiokit="no"
702 collectd_libiokit=0
703 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
704 [
705 with_libiokit="yes"
706 collectd_libiokit=1
707 ],
708 [
709 with_libiokit="no"
710 collectd_libiokit=0
711 ])
712 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
713 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
715 with_libstatgrab="yes"
716 with_libdevstat="no"
717 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
718 [
719 if test "x$withval" != "xno" -a "x$withval" != "xyes"
720 then
721 LDFLAGS="$LDFLAGS -L$withval/lib"
722 CPPFLAGS="$CPPFLAGS -I$withval/include"
723 with_libstatgrab="yes"
724 fi
725 ],
726 [
727 if test "x$ac_system" == "xunknown"
728 then
729 with_libstatgrab="yes"
730 else
731 with_libstatgrab="no"
732 fi
733 ])
734 if test "x$with_libstatgrab" = "xyes"
735 then
736 AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
737 fi
738 if test "x$with_libstatgrab" = "xyes"
739 then
740 AC_CHECK_HEADERS(statgrab.h,, [with_libstatgrab="no (statgrab.h not found)"])
741 fi
742 if test "x$with_libstatgrab" = "xyes"
743 then
744 AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
745 fi
746 if test "x$with_libstatgrab" = "xyes"
747 then
748 collect_libstatgrab=1
749 else
750 collect_libstatgrab=0
751 fi
752 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
753 [Wether or not to use statgrab library])
754 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
755 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT, test "x$with_libdevstat" = "xyes")
757 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
758 if test "x$with_libkvm" = "xyes"
759 then
760 AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
761 fi
762 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
764 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
765 [
766 if test "x$withval" != "xno" && test "x$withval" != "xyes"
767 then
768 LDFLAGS="$LDFLAGS -L$withval/lib"
769 CPPFLAGS="$CPPFLAGS -I$withval/include"
770 with_lm_sensors="yes"
771 fi
772 ],
773 [
774 if test "x$ac_system" = "xLinux"
775 then
776 with_lm_sensors="yes"
777 else
778 with_lm_sensors="no"
779 fi
780 ])
781 if test "x$with_lm_sensors" = "xyes"
782 then
783 AC_CHECK_LIB(sensors, sensors_init,
784 [
785 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
786 ],
787 [with_lm_sensors="no (libsensors not found)"])
788 fi
789 if test "x$with_lm_sensors" = "xyes"
790 then
791 AC_CHECK_HEADERS(sensors/sensors.h,
792 [
793 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
794 ],
795 [with_lm_sensors="no (sensors/sensors.h not found)"])
796 fi
797 if test "x$with_lm_sensors" = "xyes"
798 then
799 collect_lm_sensors=1
800 else
801 collect_lm_sensors=0
802 fi
803 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
804 [Wether or not to use sensors library])
805 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
807 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
808 [
809 if test "x$withval" != "xno" && test "x$withval" != "xyes"
810 then
811 LDFLAGS="$LDFLAGS -L$withval/lib"
812 CPPFLAGS="$CPPFLAGS -I$withval/include"
813 with_libmysql="yes"
814 fi
815 ],
816 [
817 with_libmysql="yes"
818 ])
819 if test "x$with_libmysql" = "xyes"
820 then
821 AC_CHECK_LIB(mysqlclient, mysql_init,
822 [
823 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
824 ], [with_libmysql="no (libmysql not found)"])
825 fi
826 if test "x$with_libmysql" = "xyes"
827 then
828 AC_CHECK_HEADERS(mysql/mysql.h,
829 [
830 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
831 ], [with_libmysql="no (mysql/mysql.h not found)"])
832 fi
833 if test "x$with_libmysql" = "xyes"
834 then
835 collect_libmysql=1
836 else
837 collect_libmysql=0
838 fi
839 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
840 [Wether or not to use mysql library])
841 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
843 #with_liboping="yes"
844 with_own_liboping="no"
845 liboping_LDFLAGS="$LDFLAGS"
846 liboping_CPPFLAGS="$CPPFLAGS"
847 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
848 [
849 if test "x$withval" != "xno" && test "x$withval" != "xyes"
850 then
851 if test -d "$withval/lib"
852 then
853 liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
854 fi
855 if test -d "$withval/include"
856 then
857 liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
858 fi
859 fi
860 if test "x$withval" = "xno"
861 then
862 with_liboping="no"
863 with_own_liboping="no"
864 fi
865 ],
866 [
867 #753
868 with_liboping="yes"
869 ])
871 if test "x$with_liboping" = "xyes"
872 then
873 save_LDFLAGS="$LDFLAGS"
874 save_CPPFLAGS="$CPPFLAGS"
875 LDFLAGS="$liboping_LDFLAGS"
876 CPPFLAGS="$liboping_CPPFLAGS"
877 AC_CHECK_LIB(oping, ping_construct,
878 [
879 with_liboping="yes"
880 with_own_liboping="no"
881 ],
882 [
883 with_liboping="yes"
884 with_own_liboping="yes"
885 LDFLAGS="$save_LDFLAGS"
886 CPPFLAGS="$save_CPPFLAGS"
887 ])
888 fi
889 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
890 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
891 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
892 then
893 with_liboping="yes (shipped version)"
894 fi
896 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
897 [
898 if test "x$withval" != "xno" && test "x$withval" != "xyes"
899 then
900 LDFLAGS="$LDFLAGS -L$withval/lib"
901 CPPFLAGS="$CPPFLAGS -I$withval/include"
902 with_libpcap="yes"
903 fi
904 ],
905 [
906 with_libpcap="yes"
907 ])
908 if test "x$with_libpcap" = "xyes"
909 then
910 AC_CHECK_LIB(pcap, pcap_open_live,
911 [
912 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
913 ], [with_libpcap="no (libpcap not found)"])
914 fi
915 if test "x$with_libpcap" = "xyes"
916 then
917 AC_CHECK_HEADERS(pcap.h,
918 [
919 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
920 ], [with_libpcap="no (pcap.h not found)"])
921 fi
922 if test "x$with_libpcap" = "xyes"
923 then
924 collect_libpcap=1
925 else
926 collect_libpcap=0
927 fi
928 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
929 [Wether or not to use the pcap library])
930 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
932 AC_ARG_WITH(libiptc, [AS_HELP_STRING([--with-libiptc@<:@=PREFIX@:>@], [Path to libiptc.])],
933 [
934 if test "x$withval" != "xno" && test "x$withval" != "xyes"
935 then
936 LDFLAGS="$LDFLAGS -L$withval/lib"
937 CPPFLAGS="$CPPFLAGS -I$withval/include"
938 with_libiptc="yes"
939 fi
940 ],
941 [
942 if test "x$ac_system" = "xLinux"
943 then
944 with_libiptc="yes"
945 else
946 with_libiptc="no (Linux only)"
947 fi
948 ])
949 if test "x$with_libiptc" = "xyes"
950 then
951 AC_CHECK_LIB(iptc, iptc_init,
952 [
953 AC_DEFINE(HAVE_LIBIPTC, 1, [Define to 1 if you have the iptc library (-liptc).])
954 ], [with_libiptc="no (libiptc not found)"])
955 fi
956 if test "x$with_libiptc" = "xyes"
957 then
958 AC_CHECK_HEADERS(libiptc/libiptc.h,
959 [
960 AC_DEFINE(HAVE_LIBIPTC_LIBIPTC_H, 1, [Define to 1 if you have the <libiptc/libiptc.h> header file.])
961 ], [with_libiptc="no (libiptc/libiptc.h not found)"])
962 fi
963 if test "x$with_libiptc" = "xyes"
964 then
965 collect_libiptc=1
966 else
967 collect_libiptc=0
968 fi
969 AM_CONDITIONAL(BUILD_WITH_LIBIPTC, test "x$with_libiptc" = "xyes")
971 # Define `step' and `hearbeat' values..
972 declare -i collectd_step=10
973 declare -i collectd_heartbeat=25
974 AC_ARG_WITH(step, [AS_HELP_STRING([--with-step=SECONDS], [Interval in which plugins are queried.])],
975 [
976 if test "x$withval" != "xno" -a "x$withval" != "xyes"
977 then
978 declare -i tmp_collectd_step="$withval"
979 if test $tmp_collectd_step -gt 0
980 then
981 collectd_step=$tmp_collectd_step
982 let "collectd_heartbeat=$collectd_step*2"
983 fi
984 fi
985 ], [])
986 AC_ARG_WITH(heartbeat, [AS_HELP_STRING([--with-heartbeat=SECONDS], [Heartbeat of the DS in generated RRD files.])],
987 [
988 if test "x$withval" != "xno" -a "x$withval" != "xyes"
989 then
990 declare -i tmp_collectd_heartbeat="$withval"
991 if test $tmp_collectd_heartbeat -gt 0
992 then
993 collectd_heartbeat=$tmp_collectd_heartbeat
994 fi
995 fi
996 ], [])
998 if test $collectd_step -ne 10
999 then
1000 AC_DEFINE_UNQUOTED(COLLECTD_STEP, "$collectd_step", [Interval in which plugins are queried.])
1001 fi
1002 if test $collectd_heartbeat -ne 25
1003 then
1004 AC_DEFINE_UNQUOTED(COLLECTD_HEARTBEAT, "$collectd_heartbeat", [Interval in which plugins are queried.])
1005 fi
1007 # Check for enabled/disabled features
1008 #
1010 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
1011 # ------------------------------------------------------------
1012 dnl
1013 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
1014 dnl
1015 AC_DEFUN(
1016 [AC_COLLECTD],
1017 [
1018 m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
1019 m4_if(
1020 [$2],
1021 [enable],
1022 [dnl
1023 m4_define([EnDis],[disabled])dnl
1024 m4_define([YesNo],[no])dnl
1025 ],dnl
1026 [m4_if(
1027 [$2],
1028 [disable],
1029 [dnl
1030 m4_define([EnDis],[enabled])dnl
1031 m4_define([YesNo],[yes])dnl
1032 ],
1033 [dnl
1034 AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
1035 ]dnl
1036 )]dnl
1037 )dnl
1038 m4_if([$3], [feature], [],
1039 [m4_if(
1040 [$3], [module], [],
1041 [dnl
1042 AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
1043 ]dnl
1044 )]dnl
1045 )dnl
1046 AC_ARG_ENABLE(
1047 [$1],
1048 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
1049 [],
1050 enable_$1='[YesNo]'dnl
1051 )# AC_ARG_ENABLE
1052 if test "x$enable_$1" = "xno"
1053 then
1054 collectd_$1=0
1055 else
1056 if test "x$enable_$1" = "xyes"
1057 then
1058 collectd_$1=1
1059 else
1060 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
1061 collectd_$1=1
1062 enable_$1='yes'
1063 fi
1064 fi
1065 AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
1066 AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
1067 ]dnl
1068 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
1070 m4_divert_once([HELP_ENABLE], [
1071 collectd features:])
1072 AC_COLLECTD([debug], [enable], [feature], [debugging])
1073 AC_COLLECTD([daemon], [disable], [feature], [daemon mode])
1074 AC_COLLECTD([getifaddrs],[enable], [feature], [getifaddrs under Linux])
1076 m4_divert_once([HELP_ENABLE], [
1077 collectd modules:])
1078 AC_COLLECTD([apache], [disable], [module], [Apache httpd statistics])
1079 AC_COLLECTD([apcups], [disable], [module], [Statistics of UPSes by APC])
1080 AC_COLLECTD([apple_sensors], [disable], [module], [Apple's hardware sensors])
1081 AC_COLLECTD([battery], [disable], [module], [battery statistics])
1082 AC_COLLECTD([cpu], [disable], [module], [cpu usage statistics])
1083 AC_COLLECTD([cpufreq], [disable], [module], [system cpu frequency statistics])
1084 AC_COLLECTD([disk], [disable], [module], [disk/partition statistics])
1085 AC_COLLECTD([df], [disable], [module], [df statistics])
1086 AC_COLLECTD([dns], [disable], [module], [dns statistics])
1087 AC_COLLECTD([email], [disable], [module], [email statistics])
1088 AC_COLLECTD([quota], [enable], [module], [quota statistics (experimental)])
1089 AC_COLLECTD([hddtemp], [disable], [module], [hdd temperature statistics])
1090 AC_COLLECTD([iptables], [disable], [module], [IPtables statistics])
1091 AC_COLLECTD([irq], [disable], [module], [irq statistics])
1092 AC_COLLECTD([load], [disable], [module], [system load statistics])
1093 AC_COLLECTD([mbmon], [disable], [module], [motherboard monitor statistics])
1094 AC_COLLECTD([memory], [disable], [module], [memory statistics])
1095 AC_COLLECTD([multimeter],[disable], [module], [multimeter statistics])
1096 AC_COLLECTD([mysql], [disable], [module], [mysql statistics])
1097 AC_COLLECTD([nfs], [disable], [module], [nfs statistics])
1098 AC_COLLECTD([ntpd], [disable], [module], [ntpd statistics])
1099 AC_COLLECTD([ping], [disable], [module], [ping statistics])
1100 AC_COLLECTD([processes], [disable], [module], [processes statistics])
1101 AC_COLLECTD([sensors], [disable], [module], [lm_sensors statistics])
1102 AC_COLLECTD([serial], [disable], [module], [serial statistics])
1103 AC_COLLECTD([swap], [disable], [module], [swap statistics])
1104 AC_COLLECTD([tape], [disable], [module], [tape statistics])
1105 AC_COLLECTD([traffic], [disable], [module], [system traffic statistics])
1106 AC_COLLECTD([users], [disable], [module], [user count statistics])
1107 AC_COLLECTD([vserver], [disable], [module], [vserver statistics])
1108 AC_COLLECTD([wireless], [disable], [module], [wireless link statistics])
1110 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/libconfig/Makefile src/liboping/Makefile)
1112 cat <<EOF;
1114 Configuration:
1115 Libraries:
1116 libcurl . . . . . . $with_libcurl
1117 libiokit . . . . . $with_libiokit
1118 liboping . . . . . $with_liboping
1119 librrd . . . . . . $with_rrdtool
1120 lm_sensors . . . . $with_lm_sensors
1121 libstatgrab . . . . $with_libstatgrab
1122 libkstat . . . . . $with_kstat
1123 libmysql . . . . . $with_libmysql
1124 libpcap . . . . . . $with_libpcap
1125 libiptc . . . . . . $with_libiptc
1126 libpthread . . . . $with_libpthread
1128 Features:
1129 debug . . . . . . . $enable_debug
1130 daemon mode . . . . $enable_daemon
1131 step . . . . . . . $collectd_step seconds
1132 heartbeat . . . . . $collectd_heartbeat seconds
1134 Modules:
1135 apache . . . . . . $enable_apache
1136 apcups . . . . . . $enable_apcups
1137 apple_sensors . . . $enable_apple_sensors
1138 battery . . . . . . $enable_battery
1139 cpu . . . . . . . . $enable_cpu
1140 cpufreq . . . . . . $enable_cpufreq
1141 df . . . . . . . . $enable_df
1142 disk . . . . . . . $enable_disk
1143 dns . . . . . . . . $enable_dns
1144 email . . . . . . . $enable_email
1145 hddtemp . . . . . . $enable_hddtemp
1146 irq . . . . . . . . $enable_irq
1147 iptables . . . . . $enable_iptables
1148 load . . . . . . . $enable_load
1149 mbmon . . . . . . . $enable_mbmon
1150 memory . . . . . . $enable_memory
1151 multimeter . . . . $enable_multimeter
1152 mysql . . . . . . . $enable_mysql
1153 nfs . . . . . . . . $enable_nfs
1154 ntpd . . . . . . . $enable_ntpd
1155 ping . . . . . . . $enable_ping
1156 processes . . . . . $enable_processes
1157 sensors . . . . . . $enable_sensors
1158 serial . . . . . . $enable_serial
1159 swap . . . . . . . $enable_swap
1160 tape . . . . . . . $enable_tape
1161 traffic . . . . . . $enable_traffic
1162 users . . . . . . . $enable_users
1163 vserver . . . . . . $enable_vserver
1164 wireless . . . . . $enable_wireless
1166 EOF