0772a9b9b73e3913a1eb8452cb225cd56bfa7c32
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(collectd, 4.0.5)
3 AC_CONFIG_SRCDIR(src/collectd.c)
4 AC_CONFIG_HEADERS(src/config.h)
5 AM_INIT_AUTOMAKE(dist-bzip2)
6 AC_LANG(C)
8 AC_PREFIX_DEFAULT("/opt/collectd")
10 AC_SYS_LARGEFILE
12 #
13 # Checks for programs.
14 #
15 AC_PROG_CC
16 AC_PROG_CPP
17 AC_PROG_INSTALL
18 AC_PROG_LN_S
19 AC_PROG_MAKE_SET
20 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
22 dnl configure libtool
23 AC_DISABLE_STATIC
24 AC_LIBLTDL_CONVENIENCE
25 AC_SUBST(LTDLINCL)
26 AC_SUBST(LIBLTDL)
27 AC_LIBTOOL_DLOPEN
28 AC_PROG_LIBTOOL
29 AC_PROG_LEX
30 AC_PROG_YACC
31 AC_CONFIG_SUBDIRS(libltdl)
33 #
34 # Checks for header files.
35 #
36 AC_HEADER_STDC
37 AC_HEADER_SYS_WAIT
38 AC_HEADER_DIRENT
40 AC_CHECK_HEADERS(stdint.h stdio.h errno.h math.h stdarg.h syslog.h fcntl.h signal.h assert.h sys/types.h sys/socket.h sys/select.h poll.h netdb.h arpa/inet.h sys/resource.h sys/param.h kstat.h regex.h sys/ioctl.h)
42 # For ping library
43 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
44 [#if HAVE_STDINT_H
45 # include <stdint.h>
46 #endif
47 #if HAVE_SYS_TYPES_H
48 # include <sys/types.h>
49 #endif
50 ])
51 AC_CHECK_HEADERS(netinet/in.h, [], [],
52 [#if HAVE_STDINT_H
53 # include <stdint.h>
54 #endif
55 #if HAVE_SYS_TYPES_H
56 # include <sys/types.h>
57 #endif
58 #if HAVE_NETINET_IN_SYSTM_H
59 # include <netinet/in_systm.h>
60 #endif
61 ])
62 AC_CHECK_HEADERS(netinet/ip.h, [], [],
63 [#if HAVE_STDINT_H
64 # include <stdint.h>
65 #endif
66 #if HAVE_SYS_TYPES_H
67 # include <sys/types.h>
68 #endif
69 #if HAVE_NETINET_IN_SYSTM_H
70 # include <netinet/in_systm.h>
71 #endif
72 #if HAVE_NETINET_IN_H
73 # include <netinet/in.h>
74 #endif
75 ])
76 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
77 [#if HAVE_STDINT_H
78 # include <stdint.h>
79 #endif
80 #if HAVE_SYS_TYPES_H
81 # include <sys/types.h>
82 #endif
83 #if HAVE_NETINET_IN_SYSTM_H
84 # include <netinet/in_systm.h>
85 #endif
86 #if HAVE_NETINET_IN_H
87 # include <netinet/in.h>
88 #endif
89 #if HAVE_NETINET_IP_H
90 # include <netinet/ip.h>
91 #endif
92 ])
93 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
94 [#if HAVE_STDINT_H
95 # include <stdint.h>
96 #endif
97 #if HAVE_SYS_TYPES_H
98 # include <sys/types.h>
99 #endif
100 #if HAVE_NETINET_IN_SYSTM_H
101 # include <netinet/in_systm.h>
102 #endif
103 #if HAVE_NETINET_IN_H
104 # include <netinet/in.h>
105 #endif
106 #if HAVE_NETINET_IP_H
107 # include <netinet/ip.h>
108 #endif
109 ])
110 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
111 [#if HAVE_STDINT_H
112 # include <stdint.h>
113 #endif
114 #if HAVE_SYS_TYPES_H
115 # include <sys/types.h>
116 #endif
117 #if HAVE_NETINET_IN_SYSTM_H
118 # include <netinet/in_systm.h>
119 #endif
120 #if HAVE_NETINET_IN_H
121 # include <netinet/in.h>
122 #endif
123 ])
124 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
125 [#if HAVE_STDINT_H
126 # include <stdint.h>
127 #endif
128 #if HAVE_SYS_TYPES_H
129 # include <sys/types.h>
130 #endif
131 #if HAVE_NETINET_IN_SYSTM_H
132 # include <netinet/in_systm.h>
133 #endif
134 #if HAVE_NETINET_IN_H
135 # include <netinet/in.h>
136 #endif
137 #if HAVE_NETINET_IP6_H
138 # include <netinet/ip6.h>
139 #endif
140 ])
141 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
142 [#if HAVE_STDINT_H
143 # include <stdint.h>
144 #endif
145 #if HAVE_SYS_TYPES_H
146 # include <sys/types.h>
147 #endif
148 #if HAVE_NETINET_IN_SYSTM_H
149 # include <netinet/in_systm.h>
150 #endif
151 #if HAVE_NETINET_IN_H
152 # include <netinet/in.h>
153 #endif
154 #if HAVE_NETINET_IP_H
155 # include <netinet/ip.h>
156 #endif
157 ])
158 AC_CHECK_HEADERS(netinet/udp.h, [], [],
159 [#if HAVE_STDINT_H
160 # include <stdint.h>
161 #endif
162 #if HAVE_SYS_TYPES_H
163 # include <sys/types.h>
164 #endif
165 #if HAVE_NETINET_IN_SYSTM_H
166 # include <netinet/in_systm.h>
167 #endif
168 #if HAVE_NETINET_IN_H
169 # include <netinet/in.h>
170 #endif
171 #if HAVE_NETINET_IP_H
172 # include <netinet/ip.h>
173 #endif
174 ])
176 # For cpu modules
177 AC_CHECK_HEADERS(sys/dkstat.h mach/mach_init.h mach/host_priv.h mach/mach_error.h mach/mach_host.h mach/mach_port.h mach/mach_types.h mach/message.h mach/processor_set.h mach/processor.h mach/processor_info.h mach/task.h mach/thread_act.h mach/vm_region.h mach/vm_map.h mach/vm_prot.h mach/vm_statistics.h mach/kern_return.h)
178 AC_CHECK_HEADERS(sys/sysctl.h, [], [],
179 [
180 #if HAVE_SYS_TYPES_H
181 # include <sys/types.h>
182 #endif
183 #if HAVE_SYS_PARAM_H
184 # include <sys/param.h>
185 #endif
186 ])
188 # For hddtemp module
189 AC_CHECK_HEADERS(linux/major.h libgen.h)
191 # For the apple_sensors module
192 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h IOKit/IOKitLib.h IOKit/IOTypes.h IOKit/ps/IOPSKeys.h IOKit/IOBSD.h IOKit/storage/IOBlockStorageDriver.h)
194 # For the battery plugin
195 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
196 [
197 #if HAVE_IOKIT_IOKITLIB_H
198 # include <IOKit/IOKitLib.h>
199 #endif
200 #if HAVE_IOKIT_IOTYPES_H
201 # include <IOKit/IOTypes.h>
202 #endif
203 ])
205 # For the swap module
206 AC_CHECK_HEADERS(sys/swap.h, [], [],
207 [
208 #if HAVE_SYS_TYPES_H
209 # include <sys/types.h>
210 #endif
211 #if HAVE_SYS_PARAM_H
212 # include <sys/param.h>
213 #endif
214 ])
216 # For load module
217 # For the processes plugin
218 # For users module
219 AC_CHECK_HEADERS(sys/loadavg.h linux/config.h utmp.h utmpx.h)
221 # For interface plugin
222 AC_CHECK_HEADERS(ifaddrs.h)
223 AC_CHECK_HEADERS(net/if.h, [], [],
224 [
225 #if HAVE_SYS_TYPES_H
226 # include <sys/types.h>
227 #endif
228 #if HAVE_SYS_SOCKET_H
229 # include <sys/socket.h>
230 #endif
231 ])
232 AC_CHECK_HEADERS(linux/if.h, [], [],
233 [
234 #if HAVE_SYS_TYPES_H
235 # include <sys/types.h>
236 #endif
237 #if HAVE_SYS_SOCKET_H
238 # include <sys/socket.h>
239 #endif
240 ])
241 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
242 [
243 #if HAVE_SYS_TYPES_H
244 # include <sys/types.h>
245 #endif
246 #if HAVE_SYS_SOCKET_H
247 # include <sys/socket.h>
248 #endif
249 #if HAVE_LINUX_IF_H
250 # include <linux/if.h>
251 #endif
252 ])
254 # For quota module
255 AC_CHECK_HEADERS(sys/ucred.h, [], [],
256 [
257 #if HAVE_SYS_TYPES_H
258 # include <sys/types.h>
259 #endif
260 #if HAVE_SYS_PARAM_H
261 # include <sys/param.h>
262 #endif
263 ])
265 # For mount interface
266 AC_CHECK_HEADERS(sys/mount.h, [], [],
267 [
268 #if HAVE_SYS_TYPES_H
269 # include <sys/types.h>
270 #endif
271 #if HAVE_SYS_PARAM_H
272 # include <sys/param.h>
273 #endif
274 ])
276 # For the email plugin
277 AC_CHECK_HEADERS(linux/un.h, [], [],
278 [
279 #if HAVE_SYS_SOCKET_H
280 # include <sys/socket.h>
281 #endif
282 ])
284 AC_CHECK_HEADERS(curl/curl.h pwd.h grp.h sys/un.h ctype.h limits.h sys/quota.h xfs/xqm.h fs_info.h fshelp.h paths.h mntent.h mnttab.h sys/fstyp.h sys/fs_types.h sys/mntent.h sys/mnttab.h sys/statfs.h sys/statvfs.h sys/vfs.h sys/vfstab.h kvm.h)
286 # For the dns plugin
287 AC_CHECK_HEADERS(arpa/nameser.h)
288 AC_CHECK_HEADERS(arpa/nameser_compat.h, [], [],
289 [
290 #if HAVE_ARPA_NAMESER_H
291 # include <arpa/nameser.h>
292 #endif
293 ])
295 AC_CHECK_HEADERS(net/if_arp.h, [], [],
296 [#if HAVE_SYS_SOCKET_H
297 # include <sys/socket.h>
298 #endif
299 ])
300 AC_CHECK_HEADERS(net/ppp_defs.h)
301 AC_CHECK_HEADERS(net/if_ppp.h, [], [],
302 [#if HAVE_NET_PPP_DEFS_H
303 # include <net/ppp_defs.h>
304 #endif
305 ])
306 AC_CHECK_HEADERS(netinet/if_ether.h, [], [],
307 [#if HAVE_STDINT_H
308 # include <stdint.h>
309 #endif
310 #if HAVE_SYS_TYPES_H
311 # include <sys/types.h>
312 #endif
313 #if HAVE_SYS_SOCKET_H
314 # include <sys/socket.h>
315 #endif
316 #if HAVE_NET_IF_H
317 # include <net/if.h>
318 #endif
319 #if HAVE_NETINET_IN_H
320 # include <netinet/in.h>
321 #endif
322 ])
324 # For the multimeter plugin
325 have_termios_h="no"
326 AC_CHECK_HEADERS(termios.h, [have_termios_h="yes"])
328 #
329 # Checking for libraries
330 #
331 AC_CHECK_LIB(m, ext)
333 #
334 # Checks for typedefs, structures, and compiler characteristics.
335 #
336 AC_C_CONST
337 AC_TYPE_PID_T
338 AC_TYPE_SIZE_T
339 AC_TYPE_UID_T
340 AC_HEADER_TIME
342 #
343 # Checks for library functions.
344 #
345 AC_PROG_GCC_TRADITIONAL
346 AC_CHECK_FUNCS(gettimeofday select strdup strtol getaddrinfo getnameinfo strchr memcpy strstr strcmp strncmp strncpy strlen strncasecmp strcasecmp openlog closelog)
348 AC_CHECK_FUNCS(getpwnam_r)
349 AC_CHECK_FUNCS(getgrnam_r)
351 socket_needs_socket="no"
352 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
353 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
355 nanosleep_needs_rt="no"
356 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
357 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
359 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
361 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
362 AC_CHECK_FUNCS(host_statistics, [have_host_statistics="yes"], [have_host_statistics="no"])
363 AC_CHECK_FUNCS(processor_info, [have_processor_info="yes"], [have_processor_info="no"])
364 AC_CHECK_FUNCS(thread_info, [have_thread_info="yes"], [have_thread_info="no"])
365 AC_CHECK_FUNCS(statfs, [have_statfs="yes"], [have_statfs="no"])
366 AC_CHECK_FUNCS(statvfs, [have_statvfs="yes"], [have_statvfs="no"])
367 AC_CHECK_FUNCS(getifaddrs, [have_getifaddrs="yes"], [have_getifaddrs="no"])
368 AC_CHECK_FUNCS(syslog, [have_syslog="yes"], [have_syslog="no"])
369 AC_CHECK_FUNCS(getutent, [have_getutent="yes"], [have_getutent="no"])
370 AC_CHECK_FUNCS(getutxent, [have_getutxent="yes"], [have_getutxent="no"])
372 # For load module
373 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
375 # Check for NAN
376 AC_ARG_WITH(nan-emulation, [AS_HELP_STRING([--with-nan-emulation], [use emulated NAN. For crosscompiling only.])],
377 [
378 if test "x$withval" = "xno"; then
379 nan_type="none"
380 else if test "x$withval" = "xyes"; then
381 nan_type="zero"
382 else
383 nan_type="$withval"
384 fi; fi
385 ],
386 [nan_type="none"])
387 if test "x$nan_type" = "xnone"; then
388 AC_CACHE_CHECK([whether NAN is defined by default],
389 [have_nan_default],
390 AC_COMPILE_IFELSE(
391 AC_LANG_PROGRAM(
392 [[
393 #include <stdlib.h>
394 #include <math.h>
395 static float foo = NAN;
396 ]],
397 [[
398 if (isnan (foo))
399 return 0;
400 else
401 return 1;
402 ]]),
403 [have_nan_default="yes"],
404 [have_nan_default="no"]
405 )
406 )
407 if test "x$have_nan_default" = "xyes"
408 then
409 nan_type="default"
410 fi
411 fi
412 if test "x$nan_type" = "xnone"; then
413 AC_CACHE_CHECK([whether NAN is defined by __USE_ISOC99],
414 [have_nan_isoc],
415 AC_COMPILE_IFELSE(
416 AC_LANG_PROGRAM(
417 [[
418 #include <stdlib.h>
419 #define __USE_ISOC99 1
420 #include <math.h>
421 static float foo = NAN;
422 ]],
423 [[
424 if (isnan (foo))
425 return 0;
426 else
427 return 1;
428 ]]),
429 [have_nan_isoc="yes"],
430 [have_nan_isoc="no"]
431 )
432 )
433 if test "x$have_nan_isoc" = "xyes"
434 then
435 nan_type="isoc99"
436 fi
437 fi
438 if test "x$nan_type" = "xnone"; then
439 AC_CACHE_CHECK([whether NAN can be defined by 0/0],
440 [have_nan_zero],
441 AC_RUN_IFELSE(
442 AC_LANG_PROGRAM(
443 [[
444 #include <stdlib.h>
445 #include <math.h>
446 #ifdef NAN
447 # undef NAN
448 #endif
449 #define NAN (0.0 / 0.0)
450 #ifndef isnan
451 # define isnan(f) ((f) != (f))
452 #endif
453 static float foo = NAN;
454 ]],
455 [[
456 if (isnan (foo))
457 return 0;
458 else
459 return 1;
460 ]]),
461 [have_nan_zero="yes"],
462 [have_nan_zero="no"]
463 )
464 )
465 if test "x$have_nan_zero" = "xyes"
466 then
467 nan_type="zero"
468 fi
469 fi
471 if test "x$nan_type" = "xdefault"; then
472 AC_DEFINE(NAN_STATIC_DEFAULT, 1,
473 [Define if NAN is defined by default and can initialize static variables.])
474 else if test "x$nan_type" = "xisoc99"; then
475 AC_DEFINE(NAN_STATIC_ISOC, 1,
476 [Define if NAN is defined by __USE_ISOC99 and can initialize static variables.])
477 else if test "x$nan_type" = "xzero"; then
478 AC_DEFINE(NAN_ZERO_ZERO, 1,
479 [Define if NAN can be defined as (0.0 / 0.0)])
480 else
481 AC_MSG_ERROR([Didn't find out how to statically initialize variables to NAN. Sorry.])
482 fi; fi; fi
484 # For mount interface
485 #AC_CHECK_FUNCS(getfsent getvfsent)
487 have_getfsstat="no"
488 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
489 have_getvfsstat="no"
490 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
491 have_listmntent="no"
492 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
494 have_getmntent="no"
495 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
496 if test "x$have_getmntent" = "xno"; then
497 AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
498 fi
499 if test "x$have_getmntent" = "xno"; then
500 AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
501 fi
502 if test "x$have_getmntent" = "xno"; then
503 AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
504 fi
506 if test "x$have_getmntent" = "xc"; then
507 AC_CACHE_CHECK([whether getmntent takes one argument],
508 [have_one_getmntent],
509 AC_COMPILE_IFELSE(
510 AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
511 #include <mntent.h>
512 #include "$srcdir/src/utils_mount.h"]],
513 [[
514 FILE *fh;
515 struct mntent *me;
516 fh = setmntent ("/etc/mtab", "r");
517 me = getmntent (fh);
518 ]]
519 ),
520 [have_one_getmntent="yes"],
521 [have_one_getmntent="no"]
522 )
523 )
524 AC_CACHE_CHECK([whether getmntent takes two arguments],
525 [have_two_getmntent],
526 AC_COMPILE_IFELSE(
527 AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
528 #include <sys/mnttab.h>
529 #include "$srcdir/src/utils_mount.h"]],
530 [[
531 FILE *fh;
532 struct mnttab mt;
533 int status;
534 fh = fopen ("/etc/mnttab", "r");
535 status = getmntent (fh, &mt);
536 ]]
537 ),
538 [have_two_getmntent="yes"],
539 [have_two_getmntent="no"]
540 )
541 )
542 fi
544 # Check for different versions of `getmntent' here..
546 if test "x$have_getmntent" = "xc"; then
547 if test "x$have_one_getmntent" = "xyes"; then
548 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
549 [Define if the function getmntent exists and takes one argument.])
550 fi
551 if test "x$have_two_getmntent" = "xyes"; then
552 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
553 [Define if the function getmntent exists and takes two arguments.])
554 fi
555 fi
556 if test "x$have_getmntent" = "xsun"; then
557 AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
558 [Define if the function getmntent exists. It's the version from libsun.])
559 fi
560 if test "x$have_getmntent" = "xseq"; then
561 AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
562 [Define if the function getmntent exists. It's the version from libseq.])
563 fi
564 if test "x$have_getmntent" = "xgen"; then
565 AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
566 [Define if the function getmntent exists. It's the version from libgen.])
567 fi
569 # Check for structures
570 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
571 [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
572 [],
573 [
574 #include <sys/types.h>
575 #include <sys/socket.h>
576 #include <net/if.h>
577 ])
578 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
579 [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
580 [],
581 [
582 #include <sys/types.h>
583 #include <sys/socket.h>
584 #include <linux/if.h>
585 #include <linux/netdevice.h>
586 ])
588 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
589 [#if HAVE_STDINT_H
590 # include <stdint.h>
591 #endif
592 #if HAVE_SYS_TYPES_H
593 # include <sys/types.h>
594 #endif
595 #if HAVE_NETINET_IN_SYSTM_H
596 # include <netinet/in_systm.h>
597 #endif
598 #if HAVE_NETINET_IN_H
599 # include <netinet/in.h>
600 #endif
601 #if HAVE_NETINET_IP_H
602 # include <netinet/ip.h>
603 #endif
604 #if HAVE_NETINET_UDP_H
605 # include <netinet/udp.h>
606 #endif
607 ])
608 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
609 [#if HAVE_STDINT_H
610 # include <stdint.h>
611 #endif
612 #if HAVE_SYS_TYPES_H
613 # include <sys/types.h>
614 #endif
615 #if HAVE_NETINET_IN_SYSTM_H
616 # include <netinet/in_systm.h>
617 #endif
618 #if HAVE_NETINET_IN_H
619 # include <netinet/in.h>
620 #endif
621 #if HAVE_NETINET_IP_H
622 # include <netinet/ip.h>
623 #endif
624 #if HAVE_NETINET_UDP_H
625 # include <netinet/udp.h>
626 #endif
627 ])
629 AC_CHECK_MEMBERS([kstat_io_t.nwritten, kstat_io_t.writes, kstat_io_t.nwrites, kstat_io_t.wtime],
630 [],
631 [],
632 [
633 #if HAVE_KSTAT_H
634 # include <kstat.h>
635 #endif
636 ])
638 AC_MSG_CHECKING([for kernel type ($host_os)])
639 case $host_os in
640 *linux*)
641 AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
642 ac_system="Linux"
643 ;;
644 *solaris*)
645 AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
646 ac_system="Solaris"
647 ;;
648 *)
649 ac_system="unknown"
650 esac
651 AC_MSG_RESULT([$ac_system])
653 with_libresolv="yes"
654 AC_CHECK_LIB(resolv, res_search,
655 [
656 AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
657 ],
658 [with_libresolv="no"])
659 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
662 m4_divert_once([HELP_WITH], [
663 collectd additional packages:])
665 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
666 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
667 [ if test "x$withval" != "xno" && test "x$withval" != "xyes"
668 then
669 LDFLAGS="$LDFLAGS -L$withval/lib"
670 CPPFLAGS="$CPPFLAGS -I$withval/include"
671 with_rrdtool="yes"
672 fi
673 ], [with_rrdtool="yes"])
674 if test "x$with_rrdtool" = "xyes"
675 then
676 AC_CHECK_LIB(rrd, rrd_update,
677 [
678 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
679 ],
680 [with_rrdtool="no (librrd not found)"], [-lm])
681 fi
682 if test "x$with_rrdtool" = "xyes"
683 then
684 AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
685 fi
686 if test "x$with_rrdtool" = "xyes"
687 then
688 collect_rrdtool=1
689 else
690 collect_rrdtool=0
691 fi
692 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
693 [Wether or not to use rrdtool library])
694 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
696 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
697 [ if test "x$withval" != "xno" -a "x$withval" != "xyes"
698 then
699 LDFLAGS="$LDFLAGS -L$withval/lib"
700 CPPFLAGS="$CPPFLAGS -I$withval/include"
701 with_libpthread="yes"
702 else
703 if test "x$withval" = "xno"
704 then
705 with_libpthread="no (disabled)"
706 fi
707 fi
708 ], [with_libpthread="yes"])
709 if test "x$with_libpthread" = "xyes"
710 then
711 AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
712 fi
713 if test "x$with_libpthread" = "xyes"
714 then
715 AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
716 fi
717 if test "x$with_libpthread" = "xyes"
718 then
719 collect_pthread=1
720 else
721 collect_pthread=0
722 fi
723 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
724 [Wether or not to use pthread (POSIX threads) library])
725 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
727 if test "$ac_system" = "Solaris"
728 then
729 with_kstat="yes"
730 with_devinfo="yes"
731 else
732 with_kstat="no (Solaris only)"
733 with_devinfo="no (Solaris only)"
734 fi
736 if test "x$with_kstat" = "xyes"
737 then
738 AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
739 fi
740 if test "x$with_kstat" = "xyes"
741 then
742 AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
743 AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
744 fi
745 if test "x$with_kstat" = "xyes"
746 then
747 AC_DEFINE(HAVE_LIBKSTAT, 1,
748 [Define to 1 if you have the 'kstat' library (-lkstat)])
749 fi
750 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
751 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
753 ### BEGIN of check for libcurl ###
754 with_curl_config="curl-config"
755 with_curl_prefix=0
756 with_curl_libs=""
757 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
758 [
759 if test "x$withval" != "xno" -a "x$withval" != "xyes"
760 then
761 if test -x "$withval/bin/curl-config"
762 then
763 with_curl_config="$withval/bin/curl-config"
764 with_curl_prefix=1
765 fi
766 fi
767 if test "x$withval" = "xno"
768 then
769 with_libcurl="no"
770 else
771 with_libcurl="yes"
772 fi
773 ],
774 [
775 with_libcurl="yes"
776 ])
777 if test "x$with_libcurl" = "xyes"
778 then
779 with_curl_libs=`$with_curl_config --libs 2>/dev/null`
780 curl_config_status=$?
782 if test $curl_config_status -ne 0
783 then
784 with_libcurl="no"
785 else
786 AC_CHECK_LIB(curl, curl_easy_init,
787 [
788 BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
789 AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
790 ],
791 [
792 with_libcurl="no"
793 ],
794 [$with_curl_libs])
795 fi
796 fi
797 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
798 then
799 with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
800 curl_config_status=$?
802 if test $curl_config_status -ne 0
803 then
804 with_libcurl="no"
805 else
806 if test -d "$with_curl_prefix/include"
807 then
808 CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
809 fi
810 fi
811 fi
813 with_libcurl_numeric=0
814 if test "x$with_libcurl" = "xyes"
815 then
816 with_libcurl_numeric=1
817 fi
818 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
819 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
820 ### END of check for libcurl ###
822 with_libiokit="no"
823 collectd_libiokit=0
824 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
825 [
826 with_libiokit="yes"
827 collectd_libiokit=1
828 ],
829 [
830 with_libiokit="no"
831 collectd_libiokit=0
832 ])
833 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
834 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
836 with_libstatgrab="yes"
837 with_libdevstat="no"
838 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
839 [
840 if test "x$withval" != "xno" -a "x$withval" != "xyes"
841 then
842 LDFLAGS="$LDFLAGS -L$withval/lib"
843 CPPFLAGS="$CPPFLAGS -I$withval/include"
844 with_libstatgrab="yes"
845 fi
846 ],
847 [
848 if test "x$ac_system" == "xunknown"
849 then
850 with_libstatgrab="yes"
851 else
852 with_libstatgrab="no"
853 fi
854 ])
855 if test "x$with_libstatgrab" = "xyes"
856 then
857 AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
858 fi
859 if test "x$with_libstatgrab" = "xyes"
860 then
861 AC_CHECK_HEADERS(statgrab.h,, [with_libstatgrab="no (statgrab.h not found)"])
862 fi
863 if test "x$with_libstatgrab" = "xyes"
864 then
865 AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
866 fi
867 if test "x$with_libstatgrab" = "xyes"
868 then
869 collect_libstatgrab=1
870 else
871 collect_libstatgrab=0
872 fi
873 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
874 [Wether or not to use statgrab library])
875 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
876 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT, test "x$with_libdevstat" = "xyes")
878 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
879 if test "x$with_libkvm" = "xyes"
880 then
881 AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
882 fi
883 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
885 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
886 [
887 if test "x$withval" != "xno" && test "x$withval" != "xyes"
888 then
889 LDFLAGS="$LDFLAGS -L$withval/lib"
890 CPPFLAGS="$CPPFLAGS -I$withval/include"
891 with_lm_sensors="yes"
892 fi
893 ],
894 [
895 if test "x$ac_system" = "xLinux"
896 then
897 with_lm_sensors="yes"
898 else
899 with_lm_sensors="no"
900 fi
901 ])
902 if test "x$with_lm_sensors" = "xyes"
903 then
904 AC_CHECK_LIB(sensors, sensors_init,
905 [
906 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
907 ],
908 [with_lm_sensors="no (libsensors not found)"])
909 fi
910 if test "x$with_lm_sensors" = "xyes"
911 then
912 AC_CHECK_HEADERS(sensors/sensors.h,
913 [
914 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
915 ],
916 [with_lm_sensors="no (sensors/sensors.h not found)"])
917 fi
918 if test "x$with_lm_sensors" = "xyes"
919 then
920 collect_lm_sensors=1
921 else
922 collect_lm_sensors=0
923 fi
924 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
925 [Wether or not to use sensors library])
926 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
928 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
929 [
930 if test "x$withval" != "xno" && test "x$withval" != "xyes"
931 then
932 LDFLAGS="$LDFLAGS -L$withval/lib"
933 CPPFLAGS="$CPPFLAGS -I$withval/include"
934 with_libmysql="yes"
935 fi
936 ],
937 [
938 with_libmysql="yes"
939 ])
940 if test "x$with_libmysql" = "xyes"
941 then
942 AC_CHECK_LIB(mysqlclient, mysql_init,
943 [
944 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
945 ], [with_libmysql="no (libmysql not found)"])
946 fi
947 if test "x$with_libmysql" = "xyes"
948 then
949 AC_CHECK_HEADERS(mysql/mysql.h,
950 [
951 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
952 ], [with_libmysql="no (mysql/mysql.h not found)"])
953 fi
954 if test "x$with_libmysql" = "xyes"
955 then
956 collect_libmysql=1
957 else
958 collect_libmysql=0
959 fi
960 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
961 [Wether or not to use mysql library])
962 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
964 with_own_liboconfig="no"
965 liboconfig_LDFLAGS="$LDFLAGS"
966 liboconfig_CPPFLAGS="$CPPFLAGS"
967 AC_ARG_WITH(liboconfig, [AS_HELP_STRING([--with-liboconfig@<:@=PREFIX@:>@], [Path to liboconfig.])],
968 [
969 if test "x$withval" != "xno" && test "x$withval" != "xyes"
970 then
971 if test -d "$withval/lib"
972 then
973 liboconfig_LDFLAGS="$LDFLAGS -L$withval/lib"
974 fi
975 if test -d "$withval/include"
976 then
977 liboconfig_CPPFLAGS="$CPPFLAGS -I$withval/include"
978 fi
979 fi
980 if test "x$withval" = "xno"
981 then
982 AC_MSG_ERROR("liboconfig is required")
983 fi
984 ],
985 [
986 with_liboconfig="yes"
987 ])
989 save_LDFLAGS="$LDFLAGS"
990 save_CPPFLAGS="$CPPFLAGS"
991 LDFLAGS="$liboconfig_LDFLAGS"
992 CPPFLAGS="$liboconfig_CPPFLAGS"
993 AC_CHECK_LIB(oconfig, oconfig_parse_fh,
994 [
995 with_liboconfig="yes"
996 with_own_liboconfig="no"
997 ],
998 [
999 with_liboconfig="yes"
1000 with_own_liboconfig="yes"
1001 LDFLAGS="$save_LDFLAGS"
1002 CPPFLAGS="$save_CPPFLAGS"
1003 ])
1005 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOCONFIG, test "x$with_own_liboconfig" = "xyes")
1006 if test "x$with_own_liboconfig" = "xyes"
1007 then
1008 with_liboconfig="yes (shipped version)"
1009 fi
1011 #with_liboping="yes"
1012 with_own_liboping="no"
1013 liboping_LDFLAGS="$LDFLAGS"
1014 liboping_CPPFLAGS="$CPPFLAGS"
1015 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
1016 [
1017 if test "x$withval" != "xno" && test "x$withval" != "xyes"
1018 then
1019 if test -d "$withval/lib"
1020 then
1021 liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
1022 fi
1023 if test -d "$withval/include"
1024 then
1025 liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
1026 fi
1027 fi
1028 if test "x$withval" = "xno"
1029 then
1030 with_liboping="no"
1031 with_own_liboping="no"
1032 fi
1033 ],
1034 [
1035 #753
1036 with_liboping="yes"
1037 ])
1039 if test "x$with_liboping" = "xyes"
1040 then
1041 save_LDFLAGS="$LDFLAGS"
1042 save_CPPFLAGS="$CPPFLAGS"
1043 LDFLAGS="$liboping_LDFLAGS"
1044 CPPFLAGS="$liboping_CPPFLAGS"
1045 AC_CHECK_LIB(oping, ping_construct,
1046 [
1047 with_liboping="yes"
1048 with_own_liboping="no"
1049 ],
1050 [
1051 with_liboping="yes"
1052 with_own_liboping="yes"
1053 LDFLAGS="$save_LDFLAGS"
1054 CPPFLAGS="$save_CPPFLAGS"
1055 ])
1056 fi
1057 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
1058 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
1060 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
1061 [
1062 if test "x$withval" != "xno" && test "x$withval" != "xyes"
1063 then
1064 LDFLAGS="$LDFLAGS -L$withval/lib"
1065 CPPFLAGS="$CPPFLAGS -I$withval/include"
1066 with_libpcap="yes"
1067 fi
1068 ],
1069 [
1070 with_libpcap="yes"
1071 ])
1072 if test "x$with_libpcap" = "xyes"
1073 then
1074 AC_CHECK_LIB(pcap, pcap_open_live,
1075 [
1076 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
1077 ], [with_libpcap="no (libpcap not found)"])
1078 fi
1079 if test "x$with_libpcap" = "xyes"
1080 then
1081 AC_CHECK_HEADERS(pcap.h,
1082 [
1083 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1084 ], [with_libpcap="no (pcap.h not found)"])
1085 fi
1086 if test "x$with_libpcap" = "xyes"
1087 then
1088 collect_libpcap=1
1089 else
1090 collect_libpcap=0
1091 fi
1092 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
1093 [Wether or not to use the pcap library])
1094 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
1096 perl_interpreter="perl"
1097 AC_ARG_WITH(libperl, [AS_HELP_STRING([--with-libperl@<:@=PREFIX@:>@], [Path to libperl.])],
1098 [
1099 if test "x$withval" != "xno" && test "x$withval" != "xyes"
1100 then
1101 LDFLAGS="$LDFLAGS -L$withval/lib"
1102 CPPFLAGS="$CPPFLAGS -I$withval/include"
1103 perl_interpreter="$withval/bin/perl"
1104 with_libperl="yes"
1105 fi
1106 ],
1107 [
1108 with_libperl="yes"
1109 ])
1110 if test "x$with_libperl" = "xyes"
1111 then
1112 SAVE_CFLAGS=$CFLAGS
1113 SAVE_LDFLAGS=$LDFLAGS
1114 PERL_CFLAGS=`$perl_interpreter -MExtUtils::Embed -e ccopts`
1115 PERL_LDFLAGS=`$perl_interpreter -MExtUtils::Embed -e ldopts`
1116 CFLAGS="$CFLAGS $PERL_CFLAGS"
1117 LDFLAGS="$LDFLAGS $PERL_LDFLAGS"
1119 AC_CACHE_CHECK([for libperl],
1120 [have_libperl],
1121 AC_LINK_IFELSE(
1122 AC_LANG_PROGRAM(
1123 [[
1124 #include <EXTERN.h>
1125 #include <perl.h>
1126 #include <XSUB.h>
1127 ]],
1128 [[
1129 PerlInterpreter *perl = NULL;
1130 Perl_load_module (perl, PERL_LOADMOD_NOIMPORT,
1131 newSVpv ("Collectd::Plugin::FooBar", 24),
1132 Nullsv);
1133 ]]),
1134 [have_libperl="yes"],
1135 [have_libperl="no"]
1136 )
1137 )
1139 if test "x$have_libperl" = "xyes"
1140 then
1141 AC_DEFINE(HAVE_LIBPERL, 1, [Define if libperl is present and usable.])
1142 AC_SUBST(PERL_CFLAGS)
1143 AC_SUBST(PERL_LDFLAGS)
1144 else
1145 with_libperl="no"
1146 fi
1148 CFLAGS=$SAVE_CFLAGS
1149 LDFLAGS=$SAVE_LDFLAGS
1150 fi
1151 AM_CONDITIONAL(BUILD_WITH_LIBPERL, test "x$with_libperl" = "xyes")
1153 AC_ARG_WITH(libiptc, [AS_HELP_STRING([--with-libiptc@<:@=PREFIX@:>@], [Path to libiptc.])],
1154 [
1155 if test "x$withval" != "xno" && test "x$withval" != "xyes"
1156 then
1157 LDFLAGS="$LDFLAGS -L$withval/lib"
1158 CPPFLAGS="$CPPFLAGS -I$withval/include"
1159 with_libiptc="yes"
1160 fi
1161 ],
1162 [
1163 if test "x$ac_system" = "xLinux"
1164 then
1165 with_libiptc="yes"
1166 else
1167 with_libiptc="no (Linux only)"
1168 fi
1169 ])
1170 if test "x$with_libiptc" = "xyes"
1171 then
1172 AC_CHECK_LIB(iptc, iptc_init,
1173 [
1174 AC_DEFINE(HAVE_LIBIPTC, 1, [Define to 1 if you have the iptc library (-liptc).])
1175 ], [with_libiptc="no (libiptc not found)"])
1176 fi
1177 if test "x$with_libiptc" = "xyes"
1178 then
1179 AC_CHECK_HEADERS(libiptc/libiptc.h,
1180 [
1181 AC_DEFINE(HAVE_LIBIPTC_LIBIPTC_H, 1, [Define to 1 if you have the <libiptc/libiptc.h> header file.])
1182 ], [with_libiptc="no (libiptc/libiptc.h not found)"])
1183 fi
1184 if test "x$with_libiptc" = "xyes"
1185 then
1186 collect_libiptc=1
1187 else
1188 collect_libiptc=0
1189 fi
1190 AM_CONDITIONAL(BUILD_WITH_LIBIPTC, test "x$with_libiptc" = "xyes")
1192 AC_ARG_WITH(libnetsnmp, [AS_HELP_STRING([--with-libnetsnmp@<:@=PREFIX@:>@], [Path to the Net-SNMPD library.])],
1193 [
1194 if test "x$withval" != "xno" && test "x$withval" != "xyes"
1195 then
1196 LDFLAGS="$LDFLAGS -L$withval/lib"
1197 CPPFLAGS="$CPPFLAGS -I$withval/include"
1198 with_libnetsnmp="yes"
1199 fi
1200 ],
1201 [with_libnetsnmp="yes"])
1202 if test "x$with_libnetsnmp" = "xyes"
1203 then
1204 AC_CHECK_LIB(netsnmp, init_snmp,
1205 [
1206 AC_DEFINE(HAVE_LIBSNMP, 1, [Define to 1 if you have the Net-SNMP library (-lnetsnmp).])
1207 ], [with_libnetsnmp="no (libnetsnmp not found)"])
1208 fi
1209 if test "x$with_libnetsnmp" = "xyes"
1210 then
1211 AC_CHECK_HEADERS(net-snmp/net-snmp-config.h,
1212 [
1213 AC_DEFINE(HAVE_NET_SNMP_NET_SNMP_CONFIG_H, 1, [Define to 1 if you have the <net-snmp/net-snmp-config.h> header file.])
1214 ], [with_libnetsnmp="no (net-snmp/net-snmp-config.h not found)"])
1215 fi
1216 AM_CONDITIONAL(BUILD_WITH_LIBNETSNMP, test "x$with_libnetsnmp" = "xyes")
1218 with_upsclient_config="libupsclient-config"
1219 with_upsclient_cflags=""
1220 with_upsclient_libs=""
1221 AC_ARG_WITH(libupsclient, [AS_HELP_STRING([--with-libupsclient@<:@=PREFIX@:>@], [Path to libupsclient.])],
1222 [
1223 if test "x$withval" = "xno"
1224 then
1225 with_libupsclient="no"
1226 else
1227 with_libupsclient="yes"
1228 if "x$withval" != "xyes"
1229 then
1230 with_upsclient_config="$withval/bin/libupsclient-config"
1231 fi
1232 fi
1233 ],
1234 [
1235 with_libupsclient="yes"
1236 ])
1237 if test "x$with_libupsclient" = "xyes"
1238 then
1239 with_upsclient_cflags=`$with_upsclient_config --cflags 2>/dev/null`
1240 upsclient_config_status=$?
1242 if test $upsclient_config_status -ne 0
1243 then
1244 with_libupsclient="no"
1245 fi
1246 fi
1247 if test "x$with_libupsclient" = "xyes"
1248 then
1249 with_upsclient_libs=`$with_upsclient_config --libs 2>/dev/null`
1250 upsclient_config_status=$?
1252 if test $upsclient_config_status -ne 0
1253 then
1254 with_libupsclient="no"
1255 fi
1256 fi
1257 if test "x$with_libupsclient" = "xyes"
1258 then
1259 AC_CHECK_LIB(upsclient, upscli_connect,
1260 [
1261 BUILD_WITH_LIBUPSCLIENT_CFLAGS="$with_upsclient_cflags"
1262 BUILD_WITH_LIBUPSCLIENT_LIBS="$with_upsclient_libs"
1263 AC_SUBST(BUILD_WITH_LIBUPSCLIENT_CFLAGS)
1264 AC_SUBST(BUILD_WITH_LIBUPSCLIENT_LIBS)
1265 ],
1266 [
1267 with_libupsclient="no"
1268 ])
1269 fi
1270 if test "x$with_libupsclient" = "xyes"
1271 then
1272 AC_DEFINE(HAVE_LIBUPSCLIENT, 1, [Define to 1 if you have the upsclient library (-lupsclient).])
1273 fi
1274 AM_CONDITIONAL(BUILD_WITH_LIBUPSCLIENT, test "x$with_libupsclient" = "xyes")
1276 ### BEGIN of check for libxmms ###
1277 with_xmms_config="xmms-config"
1278 with_xmms_cflags=""
1279 with_xmms_libs=""
1280 AC_ARG_WITH(libxmms, [AS_HELP_STRING([--with-libxmms@<:@=PREFIX@:>@], [Path to libxmms.])],
1281 [
1282 if test "x$withval" != "xno" -a "x$withval" != "xyes"
1283 then
1284 if test -x "$withval/bin/xmms-config"
1285 then
1286 with_xmms_config="$withval/bin/xmms-config"
1287 fi
1288 fi
1289 if test "x$withval" = "xno"
1290 then
1291 with_libxmms="no"
1292 else
1293 with_libxmms="yes"
1294 fi
1295 ],
1296 [
1297 with_libxmms="yes"
1298 ])
1299 if test "x$with_libxmms" = "xyes"
1300 then
1301 with_xmms_cflags=`$with_xmms_config --cflags 2>/dev/null`
1302 xmms_config_status=$?
1304 if test $xmms_config_status -ne 0
1305 then
1306 with_libxmms="no"
1307 fi
1308 fi
1309 if test "x$with_libxmms" = "xyes"
1310 then
1311 with_xmms_libs=`$with_xmms_config --libs 2>/dev/null`
1312 xmms_config_status=$?
1314 if test $xmms_config_status -ne 0
1315 then
1316 with_libxmms="no"
1317 fi
1318 fi
1319 if test "x$with_libxmms" = "xyes"
1320 then
1321 AC_CHECK_LIB(xmms, xmms_remote_get_info,
1322 [
1323 BUILD_WITH_LIBXMMS_CFLAGS="$with_xmms_cflags"
1324 BUILD_WITH_LIBXMMS_LIBS="$with_xmms_libs"
1325 AC_SUBST(BUILD_WITH_LIBXMMS_CFLAGS)
1326 AC_SUBST(BUILD_WITH_LIBXMMS_LIBS)
1327 ],
1328 [
1329 with_libxmms="no"
1330 ],
1331 [$with_xmms_libs])
1332 fi
1333 with_libxmms_numeric=0
1334 if test "x$with_libxmms" = "xyes"
1335 then
1336 with_libxmms_numeric=1
1337 fi
1338 AC_DEFINE_UNQUOTED(HAVE_LIBXMMS, [$with_libxmms_numeric], [Define to 1 if you have the 'xmms' library (-lxmms).])
1339 AM_CONDITIONAL(BUILD_WITH_LIBXMMS, test "x$with_libxmms" = "xyes")
1340 ### END of check for libxmms ###
1342 # Check for enabled/disabled features
1343 #
1345 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
1346 # ------------------------------------------------------------
1347 dnl
1348 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
1349 dnl
1350 AC_DEFUN(
1351 [AC_COLLECTD],
1352 [
1353 m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
1354 m4_if(
1355 [$2],
1356 [enable],
1357 [dnl
1358 m4_define([EnDis],[disabled])dnl
1359 m4_define([YesNo],[no])dnl
1360 ],dnl
1361 [m4_if(
1362 [$2],
1363 [disable],
1364 [dnl
1365 m4_define([EnDis],[enabled])dnl
1366 m4_define([YesNo],[yes])dnl
1367 ],
1368 [dnl
1369 AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
1370 ]dnl
1371 )]dnl
1372 )dnl
1373 m4_if([$3], [feature], [],
1374 [m4_if(
1375 [$3], [module], [],
1376 [dnl
1377 AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
1378 ]dnl
1379 )]dnl
1380 )dnl
1381 AC_ARG_ENABLE(
1382 [$1],
1383 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
1384 [],
1385 enable_$1='[YesNo]'dnl
1386 )# AC_ARG_ENABLE
1387 if test "x$enable_$1" = "xno"
1388 then
1389 collectd_$1=0
1390 else
1391 if test "x$enable_$1" = "xyes"
1392 then
1393 collectd_$1=1
1394 else
1395 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
1396 collectd_$1=1
1397 enable_$1='yes'
1398 fi
1399 fi
1400 AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
1401 AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
1402 ]dnl
1403 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
1405 # AC_PLUGIN(name, default, info)
1406 # ------------------------------------------------------------
1407 dnl
1408 AC_DEFUN(
1409 [AC_PLUGIN],
1410 [
1411 enable_plugin="no"
1412 AC_ARG_ENABLE([$1], AC_HELP_STRING([--enable-$1], [$3]),
1413 [
1414 if test "x$enableval" = "xyes"
1415 then
1416 enable_plugin="yes"
1417 else
1418 enable_plugin="no"
1419 fi
1420 ],
1421 [
1422 if test "x$2" = "xyes"
1423 then
1424 enable_plugin="yes"
1425 else
1426 enable_plugin="no"
1427 fi
1428 ])
1429 if test "x$enable_plugin" = "xyes"
1430 then
1431 AC_DEFINE([HAVE_PLUGIN_]my_toupper([$1]), 1, [Define to 1 if the $1 plugin is enabled.])
1432 fi
1433 AM_CONDITIONAL([BUILD_PLUGIN_]my_toupper([$1]), test "x$enable_plugin" = "xyes")
1434 enable_$1="$enable_plugin"
1435 ]
1436 )# AC_PLUGIN(name, default, info)
1438 m4_divert_once([HELP_ENABLE], [
1439 collectd features:])
1440 # FIXME: Remove these calls to `AC_COLLECTD' and then remove that macro.
1441 AC_COLLECTD([debug], [enable], [feature], [debugging])
1442 AC_COLLECTD([daemon], [disable], [feature], [daemon mode])
1443 AC_COLLECTD([getifaddrs],[enable], [feature], [getifaddrs under Linux])
1445 plugin_battery="no"
1446 plugin_cpu="no"
1447 plugin_cpufreq="no"
1448 plugin_df="no"
1449 plugin_disk="no"
1450 plugin_entropy="no"
1451 plugin_interface="no"
1452 plugin_irq="no"
1453 plugin_load="no"
1454 plugin_memory="no"
1455 plugin_multimeter="no"
1456 plugin_nfs="no"
1457 plugin_processes="no"
1458 plugin_serial="no"
1459 plugin_swap="no"
1460 plugin_tape="no"
1461 plugin_users="no"
1462 plugin_vserver="no"
1463 plugin_wireless="no"
1465 # Linux
1466 if test "x$ac_system" = "xLinux"
1467 then
1468 plugin_battery="yes"
1469 plugin_cpu="yes"
1470 plugin_cpufreq="yes"
1471 plugin_disk="yes"
1472 plugin_entropy="yes"
1473 plugin_interface="yes"
1474 plugin_irq="yes"
1475 plugin_load="yes"
1476 plugin_memory="yes"
1477 plugin_nfs="yes"
1478 plugin_processes="yes"
1479 plugin_serial="yes"
1480 plugin_swap="yes"
1481 plugin_vserver="yes"
1482 plugin_wireless="yes"
1483 fi
1485 # Mac OS X devices
1486 if test "x$with_libiokit" = "xyes"
1487 then
1488 plugin_battery="yes"
1489 plugin_disk="yes"
1490 fi
1492 # Solaris
1493 if test "x$with_devinfo$with_kstat" = "xyesyes"
1494 then
1495 plugin_cpu="yes"
1496 plugin_disk="yes"
1497 plugin_interface="yes"
1498 plugin_memory="yes"
1499 plugin_swap="yes"
1500 plugin_tape="yes"
1501 fi
1503 # libstatgrab
1504 if test "x$with_libstatgrab" = "xyes"
1505 then
1506 plugin_interface="yes"
1507 plugin_load="yes"
1508 plugin_memory="yes"
1509 plugin_swap="yes"
1510 fi
1512 if test "x$have_processor_info" = "xyes"
1513 then
1514 plugin_cpu="yes"
1515 fi
1516 if test "x$have_sysctlbyname" = "xyes"
1517 then
1518 plugin_cpu="yes"
1519 plugin_memory="yes"
1520 fi
1522 if test "x$have_statfs" = "xyes"
1523 then
1524 plugin_df="yes"
1525 fi
1526 if test "x$have_statvfs" = "xyes"
1527 then
1528 plugin_df="yes"
1529 fi
1531 if test "x$have_getifaddrs" = "xyes"
1532 then
1533 plugin_interface="yes"
1534 fi
1536 if test "x$have_getloadavg" = "xyes"
1537 then
1538 plugin_load="yes"
1539 fi
1541 # Mac OS X memory interface
1542 if test "x$have_host_statistics" = "xyes"
1543 then
1544 plugin_memory="yes"
1545 fi
1547 if test "x$have_termios_h" = "xyes"
1548 then
1549 plugin_multimeter="yes"
1550 fi
1552 if test "x$have_thread_info" = "xyes"
1553 then
1554 plugin_processes="yes"
1555 fi
1557 if test "x$with_libkvm" = "xyes"
1558 then
1559 plugin_swap="yes"
1560 fi
1562 if test "x$have_getutent" = "xyes"
1563 then
1564 plugin_users="yes"
1565 fi
1566 if test "x$have_getutxent" = "xyes"
1567 then
1568 plugin_users="yes"
1569 fi
1571 # FIXME: sysctl for swap plugin
1573 m4_divert_once([HELP_ENABLE], [
1574 collectd plugins:])
1576 AC_PLUGIN([apache], [$with_libcurl], [Apache httpd statistics])
1577 AC_PLUGIN([apcups], [yes], [Statistics of UPSes by APC])
1578 AC_PLUGIN([apple_sensors], [$with_libiokit], [Apple's hardware sensors])
1579 AC_PLUGIN([battery], [$plugin_battery], [Battery statistics])
1580 AC_PLUGIN([cpu], [$plugin_cpu], [CPU usage statistics])
1581 AC_PLUGIN([cpufreq], [$plugin_cpufreq], [CPU frequency statistics])
1582 AC_PLUGIN([csv], [yes], [CSV output plugin])
1583 AC_PLUGIN([df], [$plugin_df], [Filesystem usage statistics])
1584 AC_PLUGIN([disk], [$plugin_disk], [Disk usage statistics])
1585 AC_PLUGIN([dns], [$with_libpcap], [DNS traffic analysis])
1586 AC_PLUGIN([email], [yes], [EMail statistics])
1587 AC_PLUGIN([entropy], [$plugin_entropy], [Entropy statistics])
1588 AC_PLUGIN([exec], [yes], [Execution of external programs])
1589 AC_PLUGIN([hddtemp], [yes], [Query hddtempd])
1590 AC_PLUGIN([interface], [$plugin_interface], [Interface traffic statistics])
1591 AC_PLUGIN([iptables], [$with_libiptc], [IPTables rule counters])
1592 AC_PLUGIN([irq], [$plugin_irq], [IRQ statistics])
1593 AC_PLUGIN([load], [$plugin_load], [System load])
1594 AC_PLUGIN([logfile], [yes], [File logging plugin])
1595 AC_PLUGIN([mbmon], [yes], [Query mbmond])
1596 AC_PLUGIN([memory], [$plugin_memory], [Memory usage])
1597 AC_PLUGIN([multimeter], [$plugin_multimeter], [Read multimeter values])
1598 AC_PLUGIN([mysql], [$with_libmysql], [MySQL statistics])
1599 AC_PLUGIN([network], [yes], [Network communication plugin])
1600 AC_PLUGIN([nfs], [$plugin_nfs], [NFS statistics])
1601 AC_PLUGIN([ntpd], [yes], [NTPd statistics])
1602 AC_PLUGIN([nut], [$with_libupsclient], [Network UPS tools statistics])
1603 AC_PLUGIN([perl], [$with_libperl], [Embed a Perl interpreter])
1604 AC_PLUGIN([ping], [$with_liboping], [Network latency statistics])
1605 AC_PLUGIN([processes], [$plugin_processes], [Process statistics])
1606 AC_PLUGIN([rrdtool], [$with_rrdtool], [RRDTool output plugin])
1607 AC_PLUGIN([sensors], [$with_lm_sensors], [lm_sensors statistics])
1608 AC_PLUGIN([serial], [$plugin_serial], [serial port traffic])
1609 AC_PLUGIN([snmp], [$with_libnetsnmp], [SNMP querying plugin])
1610 AC_PLUGIN([swap], [$plugin_swap], [Swap usage statistics])
1611 AC_PLUGIN([syslog], [$have_syslog], [Syslog logging plugin])
1612 AC_PLUGIN([tape], [$plugin_tape], [Tape drive statistics])
1613 AC_PLUGIN([unixsock], [yes], [Unixsock communication plugin])
1614 AC_PLUGIN([users], [$plugin_users], [User statistics])
1615 AC_PLUGIN([vserver], [$plugin_vserver], [Linux VServer statistics])
1616 AC_PLUGIN([wireless], [$plugin_wireless], [Wireless statistics])
1617 AC_PLUGIN([xmms], [$with_libxmms], [XMMS statistics])
1619 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/liboconfig/Makefile src/liboping/Makefile)
1621 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
1622 then
1623 with_liboping="yes (shipped version)"
1624 fi
1626 if test "x$with_libperl" = "xyes"
1627 then
1628 with_libperl="yes (version `perl -MConfig -e 'print $Config{version};'`)"
1629 else
1630 enable_perl="no (needs libperl)"
1631 fi
1633 cat <<EOF;
1635 Configuration:
1636 Libraries:
1637 libcurl . . . . . . $with_libcurl
1638 libiokit . . . . . $with_libiokit
1639 libiptc . . . . . . $with_libiptc
1640 libkstat . . . . . $with_kstat
1641 libkvm . . . . . . $with_libkvm
1642 libmysql . . . . . $with_libmysql
1643 libnetsnmp . . . . $with_libnetsnmp
1644 liboconfig . . . . $with_liboconfig
1645 liboping . . . . . $with_liboping
1646 libpcap . . . . . . $with_libpcap
1647 libperl . . . . . . $with_libperl
1648 libpthread . . . . $with_libpthread
1649 librrd . . . . . . $with_rrdtool
1650 libsensors . . . . $with_lm_sensors
1651 libstatgrab . . . . $with_libstatgrab
1652 libupsclient . . . $with_libupsclient
1653 libxmms . . . . . . $with_libxmms
1655 Features:
1656 daemon mode . . . . $enable_daemon
1657 debug . . . . . . . $enable_debug
1659 Modules:
1660 apache . . . . . . $enable_apache
1661 apcups . . . . . . $enable_apcups
1662 apple_sensors . . . $enable_apple_sensors
1663 battery . . . . . . $enable_battery
1664 cpu . . . . . . . . $enable_cpu
1665 cpufreq . . . . . . $enable_cpufreq
1666 csv . . . . . . . . $enable_csv
1667 df . . . . . . . . $enable_df
1668 disk . . . . . . . $enable_disk
1669 dns . . . . . . . . $enable_dns
1670 email . . . . . . . $enable_email
1671 entropy . . . . . . $enable_entropy
1672 exec . . . . . . . $enable_exec
1673 hddtemp . . . . . . $enable_hddtemp
1674 interface . . . . . $enable_interface
1675 iptables . . . . . $enable_iptables
1676 irq . . . . . . . . $enable_irq
1677 load . . . . . . . $enable_load
1678 logfile . . . . . . $enable_logfile
1679 mbmon . . . . . . . $enable_mbmon
1680 memory . . . . . . $enable_memory
1681 multimeter . . . . $enable_multimeter
1682 mysql . . . . . . . $enable_mysql
1683 network . . . . . . $enable_network
1684 nfs . . . . . . . . $enable_nfs
1685 ntpd . . . . . . . $enable_ntpd
1686 nut . . . . . . . . $enable_nut
1687 perl . . . . . . . $enable_perl
1688 ping . . . . . . . $enable_ping
1689 processes . . . . . $enable_processes
1690 sensors . . . . . . $enable_sensors
1691 serial . . . . . . $enable_serial
1692 snmp . . . . . . . $enable_snmp
1693 swap . . . . . . . $enable_swap
1694 syslog . . . . . . $enable_syslog
1695 tape . . . . . . . $enable_tape
1696 unixsock . . . . . $enable_unixsock
1697 users . . . . . . . $enable_users
1698 vserver . . . . . . $enable_vserver
1699 wireless . . . . . $enable_wireless
1700 xmms . . . . . . . $enable_xmms
1702 EOF