1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
9 AC_INIT([rrdtool],[1.1.9901])
10 AC_CANONICAL_TARGET
11 AM_INIT_AUTOMAKE
12 AC_CONFIG_HEADERS([config.h])
14 dnl all our local stuff like install scripts and include files
15 dnl is in there
18 dnl determine the type of system we are running on
21 AC_SUBST(VERSION)
23 dnl where we install our stuff ...
24 AC_PREFIX_DEFAULT( /usr/local/rrdtool-1.1.0 )
26 dnl Minimum Autoconf version required.
27 AC_PREREQ(2.59)
29 dnl At the TOP of the HEADER
31 AH_TOP([
33 #ifndef CONFIG_H
34 #define CONFIG_H
35 /* IEEE can be prevented from raising signals with fpsetmask(0) */
36 #undef MUST_DISABLE_FPMASK
38 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
40 #undef MUST_DISABLE_SIGFPE
42 /* realloc does not support NULL as argument */
43 #undef NO_NULL_REALLOC
44 ])
46 AH_BOTTOM([
48 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
49 make sure you are NOT using bcopy, index or rindex in the code */
51 #if STDC_HEADERS
52 # include <string.h>
53 #else
54 # ifndef HAVE_STRCHR
55 # define strchr index
56 # define strrchr rindex
57 # endif
58 char *strchr (), *strrchr ();
59 # ifndef HAVE_MEMMOVE
60 # define memcpy(d, s, n) bcopy ((s), (d), (n))
61 # define memmove(d, s, n) bcopy ((s), (d), (n))
62 # endif
63 #endif
66 #if NO_NULL_REALLOC
67 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
68 #else
69 # define rrd_realloc(a,b) realloc((a), (b))
70 #endif
72 #if HAVE_MATH_H
73 # include <math.h>
74 #endif
76 #if HAVE_FLOAT_H
77 # include <float.h>
78 #endif
80 #if HAVE_IEEEFP_H
81 # include <ieeefp.h>
82 #endif
84 #if HAVE_FP_CLASS_H
85 # include <fp_class.h>
86 #endif
88 /* for Solaris */
89 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
90 # define HAVE_ISINF 1
91 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
92 #endif
94 /* for OSF1 Digital Unix */
95 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
96 # define HAVE_ISINF 1
97 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
98 #endif
100 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
101 # define HAVE_ISINF 1
102 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
103 #endif
105 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
106 # define HAVE_ISINF 1
107 # define isinf(a) (fpclassify(a) == FP_INFINITE)
108 #endif
110 /* for AIX */
111 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
112 # define HAVE_ISINF 1
113 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
114 #endif
116 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
117 # define HAVE_FINITE 1
118 # define finite(a) isfinite(a)
119 #endif
121 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
122 # define HAVE_FINITE 1
123 # define finite(a) (! isnan(a) && ! isinf(a))
124 #endif
126 #ifndef HAVE_FINITE
127 #error "Can't compile without finite function"
128 #endif
130 #ifndef HAVE_ISINF
131 #error "Can't compile without isinf function"
132 #endif
134 #endif /* CONFIG_H */
135 ])
139 dnl Check for the compiler and static/shared library creation.
140 AC_PROG_CC
141 AC_PROG_CPP
142 AC_PROG_LIBTOOL
144 dnl Checks for header files.
145 AC_HEADER_STDC
146 AC_HEADER_DIRENT
147 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
149 dnl Checks for typedefs, structures, and compiler characteristics.
150 AC_C_CONST
151 AC_HEADER_TIME
152 AC_STRUCT_TM
154 dnl substitute them in all the files listed in AC_OUTPUT
155 AC_SUBST(PERLFLAGS)
157 dnl Checks for libraries.
158 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
160 dnl How the vertical axis label is printed
161 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
162 [Vertical label angle: 90.0 (default) or 270.0])
163 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
164 [Vertical label angle: 90.0 (default) or 270.0])
167 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
168 [],[enable_rrdcgi=yes])
169 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
171 if test $enable_rrdcgi != no; then
172 EX_CHECK_ALL(cgi, cgiInit, cgi.h, cgilib, 0.5, http://www.infodrom.org/projects/cgilib)
173 fi
174 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point, libart_lgpl/libart.h, libart_lgpl, 2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/)
175 EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.1, http://www.gzip.org/zlib/)
176 EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.8, http://prdownloads.sourceforge.net/libpng/)
177 EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype, 2.1.9, http://prdownloads.sourceforge.net/freetype/)
179 if test "$EX_CHECK_ALL_ERR" = "YES"; then
180 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
181 fi
183 dnl solaris has some odd define it need in order to propperly compile ctime_r
184 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
185 AC_LINK_IFELSE(
186 AC_LANG_PROGRAM(
187 [[#include <time.h>]],
188 [[ctime_r(NULL,NULL,0)]]
189 ),
190 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
191 AC_LINK_IFELSE(
192 AC_LANG_PROGRAM(
193 [[#include <time.h>]],
194 [[ctime_r(NULL,NULL)]]
195 ),
196 [AC_MSG_RESULT([yes, this seems to be solaris style])],
197 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
198 )
199 ],
200 [ AC_LINK_IFELSE(
201 AC_LANG_PROGRAM(
202 [[#include <time.h>]],
203 [[ctime_r(NULL,NULL)]]
204 ),
205 [AC_MSG_RESULT(yes)],
206 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
207 )
208 ]
209 )
211 dnl Check for pthreads
212 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
214 AC_SUBST(MULTITHREAD_CFLAGS)
215 AC_SUBST(MULTITHREAD_LDFLAGS)
218 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
219 [],[enable_pthread=yes])
221 if test $enable_pthread != no; then
222 ACX_PTHREAD([
223 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
224 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
225 ],
226 [])
227 fi
231 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
233 dnl Check for Perl.
234 AC_PATH_PROG(PERL, perl, no)
235 if test "x$PERL" = "xno"; then
236 COMP_PERL=
237 else
238 COMP_PERL="perl_piped perl_shared"
239 AC_MSG_CHECKING(for shared library extension)
240 SO_EXT=`$PERL -e 'use Config; if (defined $Config{so} and $Config{so} ne 'a') {print "$Config{so}\n"} else {print "so\n"};'`
241 AC_MSG_RESULT($SO_EXT)
242 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
243 PROBLEMCC=`$PERL -e 'use Config; ($cc = $Config{cc}) =~ s/\s.*//; exit 0 if -x $cc; map {if (-x "$_/$cc"){exit 0}} split /:/, $ENV{PATH};print $Config{cc}'`
244 if test x$PROBLEMCC != x; then
245 AC_MSG_RESULT(no)
246 echo Could not find the Compiler: '"'$PROBLEMCC'"'
247 echo which has been used to build perl. You may have to compile
248 echo your own copy of perl to make this work. Binary perls often
249 echo exhibit this problem
250 exit 1
251 else
252 AC_MSG_RESULT(found)
253 fi
254 fi
255 AC_SUBST(COMP_PERL)
256 AC_SUBST(SO_EXT)
258 dnl Check for Tcl.
259 withval=""
260 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
261 found=0
262 AC_MSG_CHECKING(for tclConfig.sh in $withval)
263 if test -f "$withval/tclConfig.sh" ; then
264 tcl_config=$withval/tclConfig.sh
265 found=1
266 AC_MSG_RESULT(yes)
267 break
268 else
269 AC_MSG_RESULT(no)
270 fi
272 if test $found -eq 0 ; then
273 AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
274 else
275 . $tcl_config
276 fi
278 dnl Pass additional perl options when generating Makefile from Makefile.PL
279 # Options to pass when configuring perl module
280 AC_ARG_WITH(perl-options,
281 [ --with-perl-options=[OPTIONS] options to pass on command-line when
282 generating Makefile from Makefile.PL],
283 [PERL_MAKE_OPTIONS=$withval])
284 AC_SUBST(PERL_MAKE_OPTIONS)
286 AM_CONDITIONAL(COMP_TCL, test x$found = x1 )
288 AC_SUBST(TCL_PREFIX)
289 AC_SUBST(TCL_SHLIB_CFLAGS)
290 AC_SUBST(TCL_SHLIB_LD)
291 AC_SUBST(TCL_SHLIB_SUFFIX)
292 AC_SUBST(TCL_PACKAGE_PATH)
293 AC_SUBST(TCL_LD_SEARCH_FLAGS)
297 dnl Check for nroff
298 AC_PATH_PROGS(NROFF, gnroff nroff)
299 AC_PATH_PROGS(TROFF, groff troff)
301 dnl Does the compiler like -Wall and -pedantic?
302 if test "x$GCC" = "xyes"; then
303 oCFLAGS=$CFLAGS
304 CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
305 AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
306 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
307 ]
308 )
309 if test $rd_cv_gcc_opt = no; then
310 CFLAGS=$oCFLAGS
311 fi
312 fi
314 dnl add pic flag in any case this makes sure all our code is relocatable
315 CFLAGS="$CFLAGS "`grep pic_flag= libtool | head -1|sed -e 's/.*pic_flag=//' -e 's/"//g'`
316 dnl" make joes highliter happy it does not grasp the quote in the line above
318 ZLIB_CFLAGS=$CFLAGS
319 dnl it seems that hpux chockes on -fPIC for some reason
320 case $target_os in
321 *hpux*)
322 ZLIB_CFLAGS=`echo $CFLAGS|sed -e 's/-fPIC/-fpic/g'`
323 ;;
324 esac
325 AC_SUBST(ZLIB_CFLAGS)
327 dnl Checks for library functions.
328 AC_FUNC_STRFTIME
329 AC_FUNC_VPRINTF
331 dnl for each function found we get a definition in config.h
332 dnl of the form HAVE_FUNCTION
334 AC_CHECK_FUNCS(tzset opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
336 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro
337 AC_CHECK_FUNCS(fpclassify, ,
338 [AC_MSG_CHECKING(for fpclassify with <math.h>)
339 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
340 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
341 AC_CHECK_FUNCS(finite, ,
342 [AC_CHECK_FUNCS(isfinite, ,
343 [AC_MSG_CHECKING(for isfinite with <math.h>)
344 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
345 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
346 AC_CHECK_FUNCS(isinf, ,
347 [AC_MSG_CHECKING(for isinf with <math.h>)
348 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
349 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
351 dnl what does realloc do if it gets called with a NULL pointer
353 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
354 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
355 int main(void){
356 char *x = NULL;
357 x = realloc (x,10);
358 if (x==NULL) return 1;
359 return 0;
360 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
362 if test x"$rd_cv_null_realloc" = xnope; then
363 AC_DEFINE(NO_NULL_REALLOC)
364 fi
366 dnl determine how to get IEEE math working
367 dnl AC_IEEE(MESSAGE, set rd_cv_ieee_[var] variable, INCLUDES,
368 dnl FUNCTION-BODY, [ACTION-IF-FOUND [,ACTION-IF-NOT-FOUND]])
370 AC_C_BIGENDIAN
372 AC_DEFUN([AC_IEEE],
373 AC_MSG_CHECKING([if IEEE math works $1])
374 AC_CACHE_VAL([rd_cv_ieee_$2],
375 [AC_RUN_IFELSE([AC_LANG_SOURCE([[$3
377 #if HAVE_MATH_H
378 # include <math.h>
379 #endif
381 #if HAVE_FLOAT_H
382 # include <float.h>
383 #endif
385 #if HAVE_IEEEFP_H
386 # include <ieeefp.h>
387 #endif
389 #if HAVE_FP_CLASS_H
390 # include <fp_class.h>
391 #endif
393 /* Solaris */
394 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
395 # define HAVE_ISINF 1
396 # define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
397 #endif
399 /* Digital UNIX */
400 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
401 # define HAVE_ISINF 1
402 # define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
403 #endif
405 /* AIX */
406 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
407 # define HAVE_ISINF 1
408 # define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
409 #endif
411 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
412 # define HAVE_ISINF 1
413 # define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
414 #endif
416 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
417 # define HAVE_ISINF 1
418 # define isinf(a) (fpclassify(a) == FP_INFINITE)
419 #endif
421 #include <stdio.h>
422 int main(void){
423 double nan,inf,c,zero;
424 $4;
425 /* some math to see if we get a floating point exception */
426 zero=sin(0.0); /* don't let the compiler optimize us away */
427 nan=0.0/zero; /* especially here */
428 inf=1.0/zero; /* and here. I want to know if it can do the magic */
429 /* at run time without sig fpe */
430 c = inf + nan;
431 c = inf / nan;
432 if (! isnan(nan)) {printf ("not isnan(NaN) ... "); return 1;}
433 if (nan == nan) {printf ("nan == nan ... "); return 1;}
434 if (! isinf(inf)) {printf ("not isinf(oo) ... "); return 1;}
435 if (! isinf(-inf)) {printf ("not isinf(-oo) ... "); return 1;}
436 if (! inf > 0) {printf ("not inf > 0 ... "); return 1;}
437 if (! -inf < 0) {printf ("not -inf < 0 ... "); return 1;}
438 return 0;
439 }]])],[rd_cv_ieee_$2=yes],[rd_cv_ieee_$2=no],[:])])
440 dnl these we run regardles is cached or not
441 if test x${rd_cv_ieee_$2} = "xyes"; then
442 AC_MSG_RESULT(yes)
443 $5
444 else
445 AC_MSG_RESULT(no)
446 $6
447 fi
449 )
451 _cflags=${CFLAGS}
452 AC_IEEE([out of the box], works, , , ,
453 [CFLAGS="$_cflags -ieee"
454 AC_IEEE([with the -ieee switch], switch, , , ,
455 [CFLAGS="$_cflags -qfloat=nofold"
456 AC_IEEE([with the -qfloat=nofold switch], nofold, , , ,
457 [CFLAGS="$_cflags -w -qflttrap=enable:zerodivide"
458 AC_IEEE([with the -w -qflttrap=enable:zerodivide], flttrap, , , ,
459 [CFLAGS="$_cflags -mieee"
460 AC_IEEE([with the -mieee switch], mswitch, , , ,
461 [CFLAGS="$_cflags -q float=rndsngl"
462 AC_IEEE([with the -q float=rndsngl switch], qswitch, , , ,
463 [CFLAGS="$_cflags -OPT:IEEE_NaN_inf=ON"
464 AC_IEEE([with the -OPT:IEEE_NaN_inf=ON switch], ieeenaninfswitch, , , ,
465 [CFLAGS="$_cflags -OPT:IEEE_comparisons=ON"
466 AC_IEEE([with the -OPT:IEEE_comparisons=ON switch], ieeecmpswitch, , , ,
467 [CFLAGS=$_cflags
468 AC_IEEE([with fpsetmask(0)], mask,
469 [#include <floatingpoint.h>], [fpsetmask(0)],
470 [AC_DEFINE(MUST_DISABLE_FPMASK)
471 PERLFLAGS="CCFLAGS=-DMUST_DISABLE_FPMASK"],
472 [AC_IEEE([with signal(SIGFPE,SIG_IGN)], sigfpe,
473 [#include <signal.h>], [signal(SIGFPE,SIG_IGN)],
474 [AC_DEFINE(MUST_DISABLE_SIGFPE)
475 PERLFLAGS="CCFLAGS=-DMUST_DISABLE_SIGFPE"],
476 AC_MSG_ERROR([
477 Your Compiler does not do propper IEEE math ... Please find out how to
478 make IEEE math work with your compiler and let me know (oetiker@ee.ethz.ch).
479 Check config.log to see what went wrong ...
480 ]))])])])])])])])])])
483 AC_CONFIG_FILES([examples/shared-demo.pl \
484 examples/piped-demo.pl \
485 examples/stripes.pl \
486 examples/bigtops.pl \
487 examples/minmax.pl \
488 examples/cgi-demo.cgi \
489 examples/4charts.pl \
490 examples/Makefile \
491 doc/Makefile \
492 src/Makefile \
493 bindings/Makefile \
494 bindings/tcl/Makefile \
495 Makefile])
496 AC_CONFIG_COMMANDS([default],[[\
497 chmod +x examples/*.cgi examples/*.pl]],[[]])
498 AC_OUTPUT
500 AC_MSG_CHECKING(in)
501 AC_MSG_RESULT(and out again)
503 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
504 sleep 1
505 echo $ECHO_N ".$ECHO_C" 1>&6
506 sleep 1
507 echo $ECHO_N ".$ECHO_C" 1>&6
508 sleep 1
509 echo $ECHO_N ".$ECHO_C" 1>&6
510 sleep 1
511 echo $ECHO_N ".$ECHO_C" 1>&6
512 sleep 1
513 AC_MSG_RESULT([ just kidding ;-)])
514 echo
515 echo "----------------------------------------------------------------"
516 echo "Config is DONE!"
517 echo
518 echo "Type 'make' to compile the software and use 'make install' to "
519 echo "install everything to: $prefix."
520 echo
521 echo "If you want to install the perl"
522 echo "modules in site-perl, try 'make site-perl-install'."
523 echo
524 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
525 echo "make me happy. Go to http://people.ee.ethz.ch/~oetiker/wish and"
526 echo "place an order."
527 echo
528 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
529 echo "----------------------------------------------------------------"