configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.8])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2008
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29
  30 AC_SUBST(VERSION)
  31
  32 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  33
  34 dnl Minimum Autoconf version required.
  35 AC_PREREQ(2.59)
  36
  37 dnl At the TOP of the HEADER
  38
  39 AH_TOP([
  40
  41 #ifndef CONFIG_H
  42 #define CONFIG_H
  43 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  44 #undef MUST_DISABLE_FPMASK
  45
  46 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  47
  48 #undef MUST_DISABLE_SIGFPE
  49
  50 /* realloc does not support NULL as argument */
  51 #undef NO_NULL_REALLOC
  52
  53  ])
  54
  55 AH_BOTTOM([
  56
  57 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  58    make sure you are NOT using bcopy, index or rindex in the code */
  59
  60 #if STDC_HEADERS
  61 # include <string.h>
  62 #else
  63 # ifndef HAVE_STRCHR
  64 #  define strchr index
  65 #  define strrchr rindex
  66 # endif
  67 char *strchr (), *strrchr ();
  68 # ifndef HAVE_MEMMOVE
  69 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  70 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  71 # endif
  72 #endif
  73
  74
  75 #if NO_NULL_REALLOC
  76 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  77 #else
  78 # define rrd_realloc(a,b) realloc((a), (b))
  79 #endif
  80
  81 #if HAVE_MATH_H
  82 #  include <math.h>
  83 #endif
  84
  85 #if HAVE_FLOAT_H
  86 #  include <float.h>
  87 #endif
  88
  89 #if HAVE_IEEEFP_H
  90 #  include <ieeefp.h>
  91 #endif
  92
  93 #if HAVE_FP_CLASS_H
  94 #  include <fp_class.h>
  95 #endif
  96
  97 /* for Solaris */
  98 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
  99 #  define HAVE_ISINF 1
 100 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 101 #endif
 102
 103 /* for OSF1 Digital Unix */
 104 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 105 #  define HAVE_ISINF 1
 106 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 107 #endif
 108
 109 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 110 #  define HAVE_ISINF 1
 111 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 112 #endif
 113
 114 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 115 #  define HAVE_ISINF 1
 116 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 117 #endif
 118
 119 /* for AIX */
 120 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 121 #  define HAVE_ISINF 1
 122 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 123 #endif
 124
 125 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 126 #  define HAVE_FINITE 1
 127 #  define finite(a) isfinite(a)
 128 #endif
 129
 130 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 131 #  define HAVE_FINITE 1
 132 #  define finite(a) (! isnan(a) && ! isinf(a))
 133 #endif
 134
 135 #ifndef HAVE_FINITE
 136 #error "Can't compile without finite function"
 137 #endif
 138
 139 #ifndef HAVE_ISINF
 140 #error "Can't compile without isinf function"
 141 #endif
 142
 143 #endif /* CONFIG_H */
 144 ])
 145
 146
 147
 148 dnl Check for the compiler and static/shared library creation.
 149 AC_PROG_CC
 150 AC_PROG_CPP
 151 AC_PROG_LIBTOOL
 152
 153 dnl Check if we run on a system that has fonts
 154 AC_ARG_WITH(rrd-default-font,
 155 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 156 [RRD_DEFAULT_FONT=$withval],[
 157   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 158         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 159   else
 160         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 161   fi
 162 ])
 163
 164 AC_SUBST(RRD_DEFAULT_FONT)
 165
 166 dnl Checks for header files.
 167 AC_HEADER_STDC
 168 AC_HEADER_DIRENT
 169 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 170
 171 dnl Checks for typedefs, structures, and compiler characteristics.
 172 AC_C_CONST
 173 AC_HEADER_TIME
 174 AC_STRUCT_TM
 175
 176 dnl Checks for libraries.
 177 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 178 dnl Use libiconv if we have one but fall back to libc otherwhise
 179 AC_CHECK_LIB(iconv, iconv_open, , [
 180          AC_CHECK_FUNC(iconv_open,,)
 181          ])
 182
 183 dnl add pic flag in any case this makes sure all our code is relocatable
 184 eval `./libtool --config | grep pic_flag`
 185 CFLAGS="$CFLAGS $pic_flag"
 186
 187 dnl Checks for library functions.
 188 AC_FUNC_STRFTIME
 189 AC_FUNC_VPRINTF
 190
 191 AC_C_BIGENDIAN
 192
 193 dnl for each function found we get a definition in config.h
 194 dnl of the form HAVE_FUNCTION
 195
 196 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 197
 198 dnl Use mmap in rrd_update instead of seek+write
 199 AC_ARG_ENABLE([mmap],
 200 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 201 [],
 202 [enable_mmap=yes])
 203
 204 if test "x$enable_mmap" = xyes; then
 205   AC_FUNC_MMAP
 206 fi
 207
 208 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 209 dnl actual code to check if this works
 210 AC_CHECK_FUNCS(fpclassify, ,
 211   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; fpclassify(f)]])],[AC_MSG_RESULT(yes)
 213       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 214 AC_CHECK_FUNCS(finite, ,
 215   [AC_CHECK_FUNCS(isfinite, ,
 216     [AC_MSG_CHECKING(for isfinite with <math.h>)
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isfinite(f)]])],[AC_MSG_RESULT(yes)
 218       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 219 AC_CHECK_FUNCS(isinf, ,
 220   [AC_MSG_CHECKING(for isinf with <math.h>)
 221     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; isinf(f)]])],[AC_MSG_RESULT(yes)
 222       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 223
 224 AC_FULL_IEEE
 225
 226 dnl How the vertical axis label is printed
 227 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 228  [Vertical label angle: 90.0 (default) or 270.0])
 229 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 230  [Vertical label angle: 90.0 (default) or 270.0])
 231
 232
 233 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 234 [],[enable_rrdcgi=yes])
 235 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 236
 237 if test $enable_rrdcgi != no; then
 238 EX_CHECK_ALL(cgi,        cgiInit,                   cgi.h,                  cgilib,      0.5,    http://www.infodrom.org/projects/cgilib, "")
 239 fi
 240 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 241 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.2,  http://www.gzip.org/zlib/, "")
 242 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.8,  http://prdownloads.sourceforge.net/libpng/, "")
 243 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.9,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 244
 245 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 246   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 247 fi
 248
 249 AC_LANG_PUSH(C)
 250 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 251 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 252 AC_LINK_IFELSE(
 253     AC_LANG_PROGRAM(
 254            [[#include <time.h>]],
 255            [[ctime_r(NULL,NULL,0)]]
 256                    ),
 257     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 258       AC_LINK_IFELSE(
 259           AC_LANG_PROGRAM(
 260                 [[#include <time.h>]],
 261                 [[ctime_r(NULL,NULL)]]
 262                          ),
 263           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 264           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 265       )
 266     ],
 267     [ AC_LINK_IFELSE(
 268           AC_LANG_PROGRAM(
 269                 [[#include <time.h>]],
 270                 [[ctime_r(NULL,NULL)]]
 271                          ),
 272           [AC_MSG_RESULT(yes)],
 273           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 274       )
 275     ]
 276 )
 277 AC_LANG_POP(C)
 278
 279 dnl Check for pthreads
 280 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 281
 282 AC_SUBST(MULTITHREAD_CFLAGS)
 283 AC_SUBST(MULTITHREAD_LDFLAGS)
 284
 285
 286 AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 287 [],[enable_pthread=yes])
 288
 289
 290 if test $enable_pthread != no; then
 291  ACX_PTHREAD([
 292     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 293     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 294              ],
 295              [])
 296 fi
 297
 298 dnl since we use lots of *_r functions all over the code we better
 299 dnl make sure they are known
 300
 301 if test  "x$x_rflag" != "xno"; then
 302    CPPFLAGS="$CPPFLAGS $x_rflag"
 303 fi
 304
 305
 306 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 307
 308 dnl Check for Perl.
 309 AC_PATH_PROG(PERL, perl, no)
 310
 311 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 312 [],[enable_perl=yes])
 313
 314
 315 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 316         COMP_PERL=
 317 else
 318         COMP_PERL="perl_piped perl_shared"
 319         AC_MSG_CHECKING(for the perl version you are running)
 320         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 321         AC_MSG_RESULT($PERL_VERSION)
 322         AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 323         perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 324         AC_MSG_RESULT($perlcc)
 325         if test ! -x "$perlcc"; then
 326                AC_PATH_PROG(PERLCC, "${perlcc}", no)
 327                if test "$PERLCC" = "no"; then
 328                   AC_MSG_WARN([
 329 I would not find the Compiler ($perlcc) that was originally used to compile your
 330 perl binary. You should either make sure that this compiler is available on your
 331 system, or use a different perl setup that was compiled with $CC.
 332
 333 I will disable the compilation of the RRDs perl module.
 334 ])
 335                   COMP_PERL="perl_piped"
 336                fi
 337         fi
 338 fi
 339 AC_MSG_CHECKING(Perl Modules to build)
 340 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 341
 342 # Options to pass when configuring perl module
 343 ppref=$prefix
 344 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 345
 346 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 347
 348 dnl pass additional perl options when generating Makefile from Makefile.PL
 349 AC_ARG_ENABLE(perl-site-install,
 350 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 351                           together with rrdtool in $prefix/lib/perl. You have to
 352                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 353                           when you want to use them. When you set this option
 354                           the perl modules will get installed wherever
 355                           your perl setup thinks it is best.],
 356 [PERL_MAKE_OPTIONS=],[])
 357
 358 AC_ARG_WITH(perl-options,
 359 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 360                           generating Makefile from Makefile.PL. If you set this
 361                           option, interesting things may happen unless you know
 362                           what you are doing!],
 363 [PERL_MAKE_OPTIONS=$withval])
 364
 365 AC_SUBST(PERL_MAKE_OPTIONS)
 366 AC_SUBST(PERL)
 367 AC_SUBST(COMP_PERL)
 368 AC_SUBST(PERL_VERSION)
 369
 370 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 371 [],[enable_tcl=yes])
 372
 373 if test  "$enable_tcl" = "yes"; then
 374   dnl Check for Tcl.
 375   withval=""
 376   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 377   enable_tcl=no
 378   AC_MSG_CHECKING(for tclConfig.sh in $withval)
 379   if test -f "$withval/tclConfig.sh" ; then
 380         tcl_config=$withval/tclConfig.sh
 381         enable_tcl=yes
 382         AC_MSG_RESULT(yes)
 383         break
 384   else
 385         AC_MSG_RESULT(no)
 386   fi
 387
 388   if test "$enable_tcl" = "no"; then
 389         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 390   else
 391         . $tcl_config
 392   fi
 393 fi
 394
 395 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 396
 397 AC_SUBST(TCL_PREFIX)
 398 AC_SUBST(TCL_SHLIB_CFLAGS)
 399 AC_SUBST(TCL_SHLIB_LD)
 400 AC_SUBST(TCL_SHLIB_SUFFIX)
 401 AC_SUBST(TCL_PACKAGE_PATH)
 402 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 403
 404 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 405 [],[enable_python=yes])
 406
 407 if test  "$enable_python" = "yes"; then
 408 dnl Check for python
 409 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 410 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 411 fi
 412
 413 AM_CONDITIONAL(BUILD_PYTHON,[test "$enable_python" = "yes"])
 414
 415 dnl Check for nroff
 416 AC_PATH_PROGS(NROFF, gnroff nroff)
 417 AC_PATH_PROGS(TROFF, groff troff)
 418
 419 dnl Does the compiler like -Wall and -pedantic?
 420 if test "$GCC" = "yes"; then
 421   oCFLAGS=$CFLAGS
 422   CFLAGS="$CFLAGS -Wall -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W"
 423   AC_CACHE_CHECK(if we can use GCC-specific compiler options, rd_cv_gcc_opt,
 424                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[rd_cv_gcc_opt=yes],[rd_cv_gcc_opt=no ])
 425                ]
 426         )
 427   if test $rd_cv_gcc_opt = no; then
 428          CFLAGS=$oCFLAGS
 429   fi
 430 fi
 431
 432 dnl what does realloc do if it gets called with a NULL pointer
 433
 434 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 435 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 436               int main(void){
 437               char *x = NULL;
 438               x = realloc (x,10);
 439               if (x==NULL) return 1;
 440               return 0;
 441              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 442
 443 if test x"$rd_cv_null_realloc" = xnope; then
 444 AC_DEFINE(NO_NULL_REALLOC)
 445 fi
 446
 447 AC_CONFIG_FILES([examples/shared-demo.pl                        \
 448           examples/piped-demo.pl                        \
 449           examples/stripes.pl                           \
 450           examples/bigtops.pl                           \
 451           examples/minmax.pl                            \
 452           examples/cgi-demo.cgi                         \
 453           examples/4charts.pl                           \
 454           examples/Makefile                             \
 455           doc/Makefile                                  \
 456           src/Makefile                                  \
 457           bindings/Makefile                             \
 458           bindings/tcl/Makefile                         \
 459           bindings/python/Makefile                      \
 460           Makefile])
 461 AC_CONFIG_COMMANDS([default],[[\
 462           chmod +x examples/*.cgi examples/*.pl]],[[]])
 463 AC_OUTPUT
 464
 465 AC_MSG_CHECKING(in)
 466 AC_MSG_RESULT(and out again)
 467
 468 echo $ECHO_N "ordering CD from http://people.ee.ethz.ch/~oetiker/wish $ECHO_C" 1>&6
 469 sleep 1
 470 echo $ECHO_N ".$ECHO_C" 1>&6
 471 sleep 1
 472 echo $ECHO_N ".$ECHO_C" 1>&6
 473 sleep 1
 474 echo $ECHO_N ".$ECHO_C" 1>&6
 475 sleep 1
 476 echo $ECHO_N ".$ECHO_C" 1>&6
 477 sleep 1
 478 AC_MSG_RESULT([ just kidding ;-)])
 479 echo
 480 echo "----------------------------------------------------------------"
 481 echo "Config is DONE!"
 482 echo
 483 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 484 echo "          Perl Modules: $COMP_PERL"
 485 echo "           Perl Binary: $PERL"
 486 echo "          Perl Version: $PERL_VERSION"
 487 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 488 echo "    Build Tcl Bindings: $enable_tcl"
 489 echo " Build Python Bindings: $enable_python"
 490 echo "          Build rrdcgi: $enable_rrdcgi"
 491 echo "       Build librrd MT: $enable_pthread"
 492 echo
 493 echo
 494 echo "Type 'make' to compile the software and use 'make install' to "
 495 echo "install everything to: $prefix."
 496 echo
 497 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 498 echo "make me happy. Go to http://people.ee.ethz.ch/oetiker/wish and"
 499 echo "place an order."
 500 echo
 501 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 502 echo "----------------------------------------------------------------"