1 dnl RRDtool AutoConf script ...
2 dnl ---------------------------
3 dnl
4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
5 dnl
6 dnl Inspiration from http://autoconf-archive.cryp.to
8 dnl tell automake the this script is for rrdtool
10 dnl the official version number is
11 dnl a.b.c
12 AC_INIT([rrdtool],[1.3.3])
14 dnl for testing a numberical version number comes handy
15 dnl the released version are
16 dnl a.bccc
17 dnl the devel versions will be something like
18 dnl a.b999yymmddhh
19 NUMVERS=1.3003
20 AC_SUBST(NUMVERS)
22 dnl for the linker to understand which versions the library are compatible with
23 dnl each other we must keep a separate library version cout of the format c:r:a.
24 dnl - if only implementation changed but all interfaces are kept, do r++
25 dnl - if only functionality was added do c++,r=0,a++
26 dnl - if any functionality was removed do c++,r=0,a=0.
27 dnl
28 dnl see http://sourceware.org/autobook/autobook/autobook_91.html
29 dnl
30 LIBVERS=4:2:0
31 AC_SUBST(LIBVERS)
33 AC_CANONICAL_TARGET
34 AM_INIT_AUTOMAKE
35 AM_MAINTAINER_MODE
37 AC_CONFIG_HEADERS([rrd_config.h])
39 dnl all our local stuff like install scripts and include files
40 dnl is in there
43 dnl determine the type of system we are running on
45 AC_SUBST(VERSION)
47 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
49 dnl Minimum Autoconf version required.
50 AC_PREREQ(2.59)
52 dnl At the TOP of the HEADER
54 AH_TOP([
55 #ifndef RRD_CONFIG_H
56 #define RRD_CONFIG_H
58 /* IEEE can be prevented from raising signals with fpsetmask(0) */
59 #undef MUST_DISABLE_FPMASK
61 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
62 #undef MUST_DISABLE_SIGFPE
64 /* realloc does not support NULL as argument */
65 #undef NO_NULL_REALLOC
67 /* lets enable madvise defines in NetBSD */
68 #if defined(__NetBSD__)
69 # if !defined(_NETBSD_SOURCE)
70 # define _NETBSD_SOURCE
71 # endif
72 #endif
74 ])
76 AH_BOTTOM([
78 #ifdef MUST_HAVE_MALLOC_MALLOC_H
79 # include <malloc/malloc.h>
80 #endif
82 #include <rrd_config_bottom.h>
84 #endif
85 ])
87 dnl Process Special Options
88 dnl -----------------------------------
90 dnl How the vertical axis label is printed
91 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
92 [Vertical label angle: -90.0 (default) or 90.0])
93 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
94 [Vertical label angle: -90.0 (default) or 90.0])
96 AC_ARG_ENABLE(rrdcgi,[ --disable-rrdcgi disable building of rrdcgi],
97 [],[enable_rrdcgi=yes])
99 dnl Check if we run on a system that has fonts
100 AC_ARG_WITH(rrd-default-font,
101 [ --with-rrd-default-font=[OPTIONS] set the full path to your default font.],
102 [RRD_DEFAULT_FONT=$withval],[
103 if test -d ${WINDIR:-nodir}/cour.ttf ; then
104 RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
105 else
106 RRD_DEFAULT_FONT='"DejaVu Sans Mono,Bitstream Vera Sans Mono,monospace,Courier"'
107 fi
108 ])
110 dnl Use mmap in rrd_update instead of seek+write
111 AC_ARG_ENABLE([mmap],
112 [ --disable-mmap disable mmap in rrd_update, use seek+write instead],
113 [],
114 [enable_mmap=yes])
116 AC_ARG_ENABLE(pthread,[ --disable-pthread disable multithread support],
117 [],[enable_pthread=yes])
119 AC_ARG_ENABLE(static-programs,
120 [ --enable-static-programs Build static programs],
121 [case "${enableval}" in
122 yes) staticprogs=yes ;;
123 no) staticprogs=no ;;
124 *) AC_MSG_ERROR(bad value ${enableval} for --enable-static-programs) ;;
125 esac],[staticprogs=no])
126 AM_CONDITIONAL(STATIC_PROGRAMS,[test "x$staticprogs" = "xyes"])
129 CONFIGURE_PART(Audit Compilation Environment)
132 dnl Check for the compiler and static/shared library creation.
133 AC_PROG_CC
134 AC_PROG_CPP
135 AC_PROG_LIBTOOL
137 dnl Try to detect/use GNU features
138 CFLAGS="$CFLAGS -D_GNU_SOURCE"
140 dnl which flags does the compiler support?
141 if test "x$GCC" = "xyes"; then
142 for flag in -fno-strict-aliasing -Wall -std=c99 -pedantic -Wundef -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -Wold-style-definition -W; do
143 oCFLAGS="$CFLAGS"
144 CFLAGS="$CFLAGS $flag"
145 cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
146 AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
147 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
148 if eval test \$$cachename = no; then
149 CFLAGS="$oCFLAGS"
150 fi
151 done
152 fi
156 AC_SUBST(RRD_DEFAULT_FONT)
158 CONFIGURE_PART(Checking for Header Files)
160 dnl Checks for header files.
161 AC_HEADER_STDC
162 AC_HEADER_DIRENT
163 AC_CHECK_HEADERS(features.h sys/stat.h sys/types.h fcntl.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/times.h sys/param.h sys/resource.h signal.h float.h stdio.h stdlib.h errno.h string.h ctype.h)
165 dnl Checks for typedefs, structures, and compiler characteristics.
166 AC_C_CONST
167 AC_HEADER_TIME
168 AC_STRUCT_TM
170 CONFIGURE_PART(Test Library Functions)
172 dnl Checks for libraries.
173 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
176 dnl add pic flag in any case this makes sure all our code is relocatable
177 eval `./libtool --config | grep pic_flag`
178 CFLAGS="$CFLAGS $pic_flag"
181 dnl Checks for library functions.
182 AC_FUNC_STRFTIME
183 AC_FUNC_VPRINTF
185 AC_C_BIGENDIAN
187 dnl for each function found we get a definition in config.h
188 dnl of the form HAVE_FUNCTION
190 AC_CHECK_FUNCS(tzset fsync mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
192 CONFIGURE_PART(Map/Fadvis/Madvise checking)
194 dnl Could use these to know if we need to provide a prototype
195 dnl AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
197 dnl check for fdatasync. Solaris has fdatasync in the librt
199 AC_CHECK_FUNCS(fdatasync, [], AC_CHECK_LIB(rt, fdatasync, [LIBS="${LIBS} -lrt"; AC_DEFINE(HAVE_FDATASYNC)],[]))
200 dnl if there is no fdatasync we may get lucky with fsync
201 AC_CHECK_FUNCS(fsync)
204 dnl XXX: dunno about windows.. add AC_CHECK_FUNCS(munmap) there too?
205 if test "x$enable_mmap" = "xyes"; then
206 case "$host" in
207 *cygwin*)
208 # the normal mmap test does not work in cygwin
209 AC_CHECK_FUNCS(mmap)
210 if test "x$ac_cv_func_mmap" = "xyes"; then
211 ac_cv_func_mmap_fixed_mapped=yes
212 fi
213 ;;
214 *)
215 AC_CHECK_HEADERS(sys/mman.h)
216 AC_FUNC_MMAP
217 AC_CHECK_FUNCS(mmap munmap msync)
218 AC_CHECK_DECLS(madvise, [], [], [#ifdef HAVE_SYS_MMAN_H
219 # include <sys/mman.h>
220 #endif])
221 if test "x$ac_cv_have_decl_madvise" = "xyes";
222 then
223 AC_CHECK_FUNCS(madvise)
224 else
225 AC_CHECK_FUNCS(posix_madvise)
226 if test "x$ac_cv_func_posix_madvise" != "xyes"; then
227 AC_MSG_WARN([madvise() nor posix_madvise() found.])
228 fi
229 fi
230 ;;
231 esac
232 if test "x$ac_cv_func_mmap" != "xyes";
233 then
234 AC_MSG_ERROR([--enable-mmap requested but mmap() was not detected])
235 dnl enable_mmap="no"
236 fi
237 fi
239 dnl can we use posix_fadvise
240 AC_CHECK_DECLS(posix_fadvise, [], [], [#define _XOPEN_SOURCE 600
241 #include <fcntl.h>])
242 AC_CHECK_FUNCS(posix_fadvise)
244 CONFIGURE_PART(Libintl Processing)
247 dnl gettext
248 GETTEXT_PACKAGE=rrdtool
249 AC_SUBST(GETTEXT_PACKAGE)
250 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package])
252 AM_GLIB_GNU_GETTEXT()
254 AC_ARG_ENABLE(libintl,[ --disable-libintl i18n support (libintl)],
255 [],[enable_libintl=yes])
257 if test x$enable_libintl = xyes; then
258 IT_PROG_INTLTOOL([0.35.0],[no-xml])
259 fi
261 if test x$enable_libintl = xyes -a x$MSGFMT = xno; then
262 AC_MSG_WARN(I could not find msgfmt. Diabeling libintl build.)
263 enable_libintl=no
264 fi
266 if test x$enable_libintl = xyes; then
267 AC_CHECK_HEADERS(libintl.h,[],[AC_MSG_RESULT(disabeling libintl build); enable_libintl=no])
268 fi
270 if test x$enable_libintl = xyes ; then
271 dnl it seems bsd synstems need to link against libintl
272 dnl when compiling rrdupdate. lets check
273 AC_CHECK_LIB(intl, libintl_gettext,[LIB_LIBINTL="-lintl"])
274 fi
276 dnl use for linking rrdupdate
277 AC_SUBST(LIB_LIBINTL)
279 dnl do not touch the po stuff if we are not going to build intl
280 AM_CONDITIONAL(BUILD_LIBINTL,[test x$enable_libintl = xyes])
282 if test x$enable_libintl = xyes; then
283 AC_DEFINE([BUILD_LIBINTL], [], [Use this in code sections to mark them for libintl build])
284 fi
286 CONFIGURE_PART(IEEE Math Checks)
289 dnl actual code to check if this works
290 AC_CHECK_FUNCS(fpclassify, ,
291 [AC_MSG_CHECKING(for fpclassify with <math.h>)
292 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
293 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
294 AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
296 AC_CHECK_FUNCS(isinf, ,
297 [AC_MSG_CHECKING(for isinf with <math.h>)
298 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
299 volatile int x;volatile float f; ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
300 AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
302 dnl finite is BSD, isfinite is C99, so prefer the latter
303 AC_CACHE_CHECK([whether isfinite is broken],[ac_cv_have_broken_isfinite],[
304 AC_TRY_RUN([
305 #ifdef HAVE_MATH_H
306 #include <math.h>
307 #endif
308 #ifdef HAVE_FLOAT_H
309 #include <float.h>
310 #endif
311 int main ()
312 {
313 #ifdef isfinite
314 #ifdef LDBL_MAX
315 if (!isfinite(LDBL_MAX)) return 1;
316 #endif
317 #ifdef DBL_MAX
318 if (!isfinite(DBL_MAX)) return 1;
319 #endif
320 #endif
321 return 0;
322 }],[ac_cv_have_broken_isfinite=no],[ac_cv_have_broken_isfinite=yes],[
323 case "${target}" in
324 hppa*-*-hpux*) ac_cv_have_broken_isfinite=yes ;;
325 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
326 *) ac_cv_have_broken_isfinite=no ;;
327 esac])
328 ])
330 dnl the test does not seem to work on solaris 2.8
331 dnl so lets fix this by hand
332 case "${target}" in
333 *-sun-solaris2.8) ac_cv_have_broken_isfinite=yes ;;
334 esac
336 if test "x$ac_cv_have_broken_isfinite" = "xno"; then
337 AC_DEFINE(HAVE_ISFINITE)
338 else
339 AC_CHECK_FUNCS(finite,[],
340 [AC_CHECK_FUNCS(isfinite,[],
341 [AC_MSG_CHECKING(for isfinite with <math.h>)
342 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
343 volatile int x;volatile float f; ]],[[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
344 AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
345 fi
347 AC_FULL_IEEE
349 CONFIGURE_PART(Resolve Portability Issues)
351 dnl Do we need getopt_long
353 build_getopt=no
354 RRD_GETOPT_LONG="#"
355 AC_CHECK_FUNC(getopt_long,[],[
356 RRD_GETOPT_LONG="getopt_long"
357 build_getopt=yes
358 ])
359 AC_SUBST(RRD_GETOPT_LONG)
360 AM_CONDITIONAL(BUILD_GETOPT,[test $build_getopt = yes])
362 dnl what does realloc do if it gets called with a NULL pointer
364 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
365 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
366 int main(void){
367 char *x = NULL;
368 x = realloc (x,10);
369 if (x==NULL) return 1;
370 return 0;
371 }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
373 if test x"$rd_cv_null_realloc" = xnope; then
374 AC_DEFINE(NO_NULL_REALLOC)
375 fi
377 AC_LANG_PUSH(C)
378 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
379 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
380 AC_LINK_IFELSE(
381 AC_LANG_PROGRAM(
382 [[#include <time.h>]],
383 [[ctime_r(NULL,NULL,0)]]
384 ),
385 [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
386 AC_LINK_IFELSE(
387 AC_LANG_PROGRAM(
388 [[#include <time.h>]],
389 [[ctime_r(NULL,NULL)]]
390 ),
391 [AC_MSG_RESULT([yes, this seems to be solaris style])],
392 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
393 )
394 ],
395 [ AC_LINK_IFELSE(
396 AC_LANG_PROGRAM(
397 [[#include <time.h>]],
398 [[ctime_r(NULL,NULL)]]
399 ),
400 [AC_MSG_RESULT(no)],
401 [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
402 )
403 ]
404 )
405 AC_LANG_POP(C)
407 dnl Check for pthreads
408 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
410 AC_SUBST(MULTITHREAD_CFLAGS)
411 AC_SUBST(MULTITHREAD_LDFLAGS)
413 if test $enable_pthread != no; then
414 ACX_PTHREAD([
415 MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
416 MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
417 ],
418 [])
419 fi
421 dnl since we use lots of *_r functions all over the code we better
422 dnl make sure they are known
424 if test "x$x_rflag" != "xno"; then
425 CPPFLAGS="$CPPFLAGS $x_rflag"
426 fi
428 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
430 AC_LANG_PUSH(C)
431 dnl see if we have to include malloc/malloc.h
432 AC_MSG_CHECKING([do we need malloc/malloc.h])
433 AC_LINK_IFELSE(
434 AC_LANG_PROGRAM(
435 [[#include <stdlib.h>]],
436 [[malloc(1)]]
437 ),
438 [ AC_MSG_RESULT([nope, works out of the box]) ],
439 [ AC_LINK_IFELSE(
440 AC_LANG_PROGRAM(
441 [[#include <stdlib.h>
442 #include <malloc/malloc.h>]],
443 [[malloc(1)]]
444 ),[
445 AC_DEFINE([MUST_HAVE_MALLOC_MALLOC_H])
446 AC_MSG_RESULT([yes we do])],
447 [AC_MSG_ERROR([Can not figure how to compile malloc])]
448 )
449 ]
450 )
451 AC_LANG_POP(C)
453 CONFIGURE_PART(Find 3rd-Party Libraries)
456 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
459 CORE_LIBS="$LIBS"
461 dnl EX_CHECK_ALL(z, zlibVersion, zlib.h, zlib, 1.2.3, http://www.gzip.org/zlib/, "")
462 dnl EX_CHECK_ALL(png, png_access_version_number, png.h, libpng, 1.2.10, http://prdownloads.sourceforge.net/libpng/, "")
463 dnl EX_CHECK_ALL(freetype, FT_Init_FreeType, ft2build.h, freetype2, 2.1.10, http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
464 dnl EX_CHECK_ALL(fontconfig, FcInit, fontconfig.h, fontconfig, 2.3.1, http://fontconfig.org/release/, /usr/include)
465 EX_CHECK_ALL(cairo, cairo_font_options_create, cairo.h, cairo-png, 1.4.6, http://cairographics.org/releases/, "")
466 EX_CHECK_ALL(cairo, cairo_svg_surface_create, cairo-svg.h, cairo-svg, 1.4.6, http://cairographics.org/releases/, "")
467 EX_CHECK_ALL(cairo, cairo_pdf_surface_create, cairo-pdf.h, cairo-pdf, 1.4.6, http://cairographics.org/releases/, "")
468 EX_CHECK_ALL(cairo, cairo_ps_surface_create, cairo-ps.h, cairo-ps, 1.4.6, http://cairographics.org/releases/, "")
469 dnl EX_CHECK_ALL(glib-2.0, glib_check_version, glib.h, glib-2.0, 2.12.12, ftp://ftp.gtk.org/pub/glib/2.12/, "")
470 EX_CHECK_ALL(pango-1.0, pango_cairo_context_set_font_options, pango/pango.h, pangocairo, 1.17, http://ftp.gnome.org/pub/GNOME/sources/pango/1.17, "")
471 EX_CHECK_ALL(xml2, xmlParseFile, libxml/parser.h, libxml-2.0, 2.6.31, http://xmlsoft.org/downloads.html, /usr/include/libxml2)
473 if test "$EX_CHECK_ALL_ERR" = "YES"; then
474 AC_MSG_ERROR([Please fix the library issues listed above and try again.])
475 fi
477 ALL_LIBS="$LIBS"
478 LIBS=
480 AC_SUBST(CORE_LIBS)
481 AC_SUBST(ALL_LIBS)
483 CONFIGURE_PART(Prep for Building Language Bindings)
485 dnl Check for Perl and friends
486 PATH=$PATH:/usr/perl5/bin
487 export PATH
488 AC_PATH_PROG(PERL, perl, no)
489 AC_PATH_PROG(POD2MAN, pod2man, no)
490 AC_PATH_PROG(POD2HTML, pod2html, no)
493 AC_ARG_ENABLE(perl,[ --disable-perl do not build the perl modules],
494 [],[enable_perl=yes])
497 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
498 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
499 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
500 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
502 if test "x$PERL" = "xno" -o x$enable_perl = xno; then
503 COMP_PERL=
504 else
505 COMP_PERL="perl_piped perl_shared"
506 AC_MSG_CHECKING(for the perl version you are running)
507 PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
508 AC_MSG_RESULT($PERL_VERSION)
509 if test -z "$PERLCC"; then
510 AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
511 perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
512 AC_MSG_RESULT($perlcc)
513 if test ! -x "$perlcc"; then
514 AC_PATH_PROG(PERL_CC, ${perlcc}, no)
515 if test "$PERL_CC" = "no"; then
516 AC_MSG_WARN([
517 I would not find the Compiler ($perlcc) that was originally used to compile
518 your perl binary. You should either make sure that this compiler is
519 available on your system, pick an other compiler and set PERLCC
520 appropriately, or use a different perl setup that was compiled locally.
522 I will disable the compilation of the RRDs perl module for now.
523 ])
524 COMP_PERL="perl_piped"
525 fi
526 fi
527 fi
528 fi
530 AC_MSG_CHECKING(Perl Modules to build)
531 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
533 # Options to pass when configuring perl module
534 ppref=$prefix
535 test "$ppref" = 'NONE' && ppref=$ac_default_prefix
537 PERL_MAKE_OPTIONS="PREFIX="'$(DESTDIR)'"$ppref LIB="'$(DESTDIR)'"$ppref/lib/perl/$PERL_VERSION"
539 dnl pass additional perl options when generating Makefile from Makefile.PL
540 AC_ARG_ENABLE(perl-site-install,
541 [ --enable-perl-site-install by default the rrdtool perl modules are installed
542 together with rrdtool in $prefix/lib/perl. You have to
543 put a 'use lib qw($prefix/lib/perl)' into your scripts
544 when you want to use them. When you set this option
545 the perl modules will get installed wherever
546 your perl setup thinks it is best.],
547 [PERL_MAKE_OPTIONS=],[])
549 if test ! -z "$PERLCC"; then
550 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
552 if test ! -z "$PERLCCFLAGS"; then
553 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
554 fi
556 if test -z "$PERLLD"; then
557 PERLLD=$PERLCC
558 fi
559 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
561 if test ! -z "$PERLLDFLAGS"; then
562 PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
563 fi
564 fi
566 AC_ARG_WITH(perl-options,
567 [ --with-perl-options=[OPTIONS] options to pass on command-line when
568 generating Makefile from Makefile.PL. If you set this
569 option, interesting things may happen unless you know
570 what you are doing!],
571 [PERL_MAKE_OPTIONS=$withval])
573 AC_SUBST(PERL_MAKE_OPTIONS)
574 AC_SUBST(PERL)
575 AC_SUBST(COMP_PERL)
576 AC_SUBST(PERL_VERSION)
578 dnl Check for Ruby.
579 AC_PATH_PROG(RUBY, ruby, no)
581 AC_ARG_ENABLE(ruby,[ --disable-ruby do not build the ruby modules],
582 [],[enable_ruby=yes])
584 AC_MSG_CHECKING(if ruby modules can be built)
586 if test "x$RUBY" = "xno" -o x$enable_ruby = xno; then
587 COMP_RUBY=
588 AC_MSG_RESULT(No .. Ruby not found or disabled)
589 else
590 if $RUBY -e 'require "mkmf"' >/dev/null 2>&1; then
591 COMP_RUBY="ruby"
592 AC_MSG_RESULT(YES)
593 else
594 COMP_RUBY=
595 AC_MSG_RESULT(Ruby found but mkmf is missing! Install the -dev package)
596 fi
597 fi
599 rpref=$prefix
600 test "$rpref" = 'NONE' && rpref=$ac_default_prefix
602 dnl pass additional ruby options when generating Makefile from Makefile.PL
603 AC_ARG_ENABLE(ruby-site-install,
604 [ --enable-ruby-site-install by default the rrdtool ruby modules are installed
605 together with rrdtool in $prefix/lib/ruby. You have to
606 add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
607 for ruby to find the RRD.so file.],
608 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir="'$(DESTDIR)'"$rpref/lib/ruby"])
611 AC_ARG_WITH(ruby-options,
612 [ --with-ruby-options=[OPTIONS] options to pass on command-line when
613 generating Makefile from extconf.rb. If you set this
614 option, interesting things may happen unless you know
615 what you are doing!],
616 [RUBY_MAKE_OPTIONS=$withval])
618 AC_SUBST(RUBY_MAKE_OPTIONS)
619 AC_SUBST(RUBY)
620 AC_SUBST(COMP_RUBY)
623 enable_tcl_site=no
625 AC_ARG_ENABLE(tcl,[ --disable-tcl do not build the tcl modules],
626 [],[enable_tcl=yes])
628 if test "$enable_tcl" = "yes"; then
629 dnl Check for Tcl.
630 withval=""
631 AC_ARG_WITH(tcllib,[ --with-tcllib=DIR location of the tclConfig.sh])
632 enable_tcl=no
633 for dir in $withval /usr/lib /usr/local/lib /usr/lib/tcl8.4 /usr/lib/tcl8.3 ; do
634 AC_MSG_CHECKING(for tclConfig.sh in $dir)
635 if test -f "$dir/tclConfig.sh" ; then
636 tcl_config=$dir/tclConfig.sh
637 enable_tcl=yes
638 AC_MSG_RESULT(yes)
639 break
640 else
641 AC_MSG_RESULT(no)
642 fi
643 done
645 if test "$enable_tcl" = "no"; then
646 AC_MSG_WARN([tclConfig.sh not found - Tcl interface will not be built])
647 else
648 . $tcl_config
649 TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
650 if test -n "$TCL_INC_DIR"; then
651 TCL_INCLUDE_SPEC="$TCL_INCLUDE_SPEC -I$TCL_INC_DIR"
652 fi
653 fi
654 AC_ARG_ENABLE(tcl,[ --enable-tcl-site install the tcl extension in the tcl tree],
655 [],[enable_tcl_site=yes])
657 fi
659 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
660 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
663 AC_SUBST(TCL_PREFIX)
664 AC_SUBST(TCL_SHLIB_CFLAGS)
665 AC_SUBST(TCL_SHLIB_LD)
666 AC_SUBST(TCL_SHLIB_SUFFIX)
667 AC_SUBST(TCL_PACKAGE_PATH)
668 AC_SUBST(TCL_LD_SEARCH_FLAGS)
669 AC_SUBST(TCL_STUB_LIB_SPEC)
670 AC_SUBST(TCL_VERSION)
671 AC_SUBST(TCL_PACKAGE_DIR)
672 AC_SUBST(TCL_INCLUDE_SPEC)
674 AC_ARG_ENABLE(python,[ --disable-python do not build the python modules],
675 [],[enable_python=yes])
677 if test "$enable_python" = "yes"; then
678 dnl Check for python
679 AM_PATH_PYTHON(2.3,[],[enable_python=no])
680 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
681 fi
683 if test x$enable_python = xno; then
684 COMP_PYTHON=
685 else
686 COMP_PYTHON="python"
687 fi
689 AC_SUBST(COMP_PYTHON)
691 dnl Check for nroff
692 AC_PATH_PROGS(NROFF, gnroff nroff)
693 AC_PATH_PROGS(TROFF, groff troff)
695 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
696 if test -z "$RRDDOCDIR"; then
697 RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
700 CONFIGURE_PART(Apply Configuration Information)
702 AC_CONFIG_FILES([examples/shared-demo.pl])
703 AC_CONFIG_FILES([examples/piped-demo.pl])
704 AC_CONFIG_FILES([examples/stripes.pl])
705 AC_CONFIG_FILES([examples/bigtops.pl])
706 AC_CONFIG_FILES([examples/minmax.pl])
707 AC_CONFIG_FILES([examples/4charts.pl])
708 AC_CONFIG_FILES([examples/perftest.pl])
709 AC_CONFIG_FILES([examples/Makefile])
710 AC_CONFIG_FILES([doc/Makefile])
711 AC_CONFIG_FILES([po/Makefile.in])
712 AC_CONFIG_FILES([src/Makefile])
713 AC_CONFIG_FILES([src/librrd.sym])
714 AC_CONFIG_FILES([bindings/Makefile])
715 AC_CONFIG_FILES([bindings/tcl/Makefile])
716 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
717 AC_CONFIG_FILES([Makefile])
719 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
720 AC_OUTPUT
722 AC_MSG_CHECKING(in)
723 AC_MSG_RESULT(and out again)
725 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
726 sleep 1
727 echo $ECHO_N ".$ECHO_C" 1>&6
728 sleep 1
729 echo $ECHO_N ".$ECHO_C" 1>&6
730 sleep 1
731 echo $ECHO_N ".$ECHO_C" 1>&6
732 sleep 1
733 echo $ECHO_N ".$ECHO_C" 1>&6
734 sleep 1
735 AC_MSG_RESULT([ just kidding ;-)])
736 echo
737 echo "----------------------------------------------------------------"
738 echo "Config is DONE!"
739 echo
740 echo " With MMAP IO: $enable_mmap"
741 echo " Build rrd_getopt: $build_getopt"
742 echo " Static programs: $staticprogs"
743 echo " Perl Modules: $COMP_PERL"
744 echo " Perl Binary: $PERL"
745 echo " Perl Version: $PERL_VERSION"
746 echo " Perl Options: $PERL_MAKE_OPTIONS"
747 echo " Ruby Modules: $COMP_RUBY"
748 echo " Ruby Binary: $RUBY"
749 echo " Ruby Options: $RUBY_MAKE_OPTIONS"
750 echo " Build Tcl Bindings: $enable_tcl"
751 echo " Build Python Bindings: $enable_python"
752 echo " Build rrdcgi: $enable_rrdcgi"
753 echo " Build librrd MT: $enable_pthread"
754 echo " Link with libintl: $enable_libintl"
755 echo
756 echo " Libraries: $ALL_LIBS"
757 echo
758 echo "Type 'make' to compile the software and use 'make install' to "
759 echo "install everything to: $prefix."
760 echo
761 echo " ... that wishlist is NO JOKE. If you find RRDtool useful"
762 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
763 echo "place an order."
764 echo
765 echo " -- Tobi Oetiker <tobi@oetiker.ch>"
766 echo "----------------------------------------------------------------"